         MACRO                                                          01000020
&LABEL   BRREAD  &REG,&TYPE,&TJID=                                      02000020
.***  GLOBAL VARIABLE &PLIST CONTROL GENERATION OF PARMETER LIST  ***   03000020
         GBLB  &PARMLST                                                 04000020
         GBLC  &PLIST                                                   05000020
         LCLC  &TLAB                                                    06000020
.***  TEST FOR P-REG  ***                                               07000020
         AIF   ('&REG' NE '').OK1                                       08000020
         MNOTE 12,'MISSIMG ADDR REG'                                    09000020
         MEXIT                                                          10000020
.OK1     ANOP                                                           11000020
.***  TEST FOR DEMAND P-LIST  ***                                       12000020
         AIF   (&PARMLST).EXTGEN                                        13000020
.***  TEST FOR FIRST CALL OF BRREAD IN THIS CSECT  ***                  14000020
         AIF   ('&PLIST' EQ 'RDL'.'&SYSECT'(4,5)).NOLIST                15000020
.***  IF FIRST CALL GENERATE PARAMETER LIST  ***                        16000020
&PLIST   SETC  'RDL'.'&SYSECT'(4,5)                                     17000020
         AGO   .NOEXTGN                                                 18000020
.EXTGEN  ANOP                                                           19000020
&PLIST   SETC  'TMP'.'&SYSNDX'                                          20000020
.NOEXTGN ANOP                                                           21000020
         CNOP  0,4                 ALLIGN ON WORD BOUNDARY              22000020
&LABEL   ST    &REG(1),&PLIST      STORE ADDRESS OF STORAGE REQUIRED    23000020
.ST11    ANOP                                                           24000020
.***  GENERATE STORE OF REQUESTED ADDRESS BEFORE POINT TO P-LIST  ***   25000020
&TLAB    SETC  'RDL'.'&SYSNDX'                                          26000020
         BAL   1,&TLAB             POINT TO PARAMETER LIST              27000020
&PLIST   DS    F                   ADDRESS OF STORAGE REQUIRED          28000020
         DS    H                   TJID OF THIS STORAGE                 29000020
         DS    C                   FUNCTION CODE FOR READ ROUTINE       30000020
         DS    C                   RESERVED                             31000020
&TLAB    EQU   *                                                        32000020
         AGO   .TESTID                                                  33000020
.NOLIST  ANOP                                                           34000020
&LABEL   ST    &REG(1),&PLIST      STORE ADDRESS OF STORAGE REQUIRED    35000020
.ST12    ANOP                                                           36000020
         LA    1,&PLIST            POINT TO PARAMETER LIST              37000020
.TESTID  ANOP                                                           38000020
.***  IF TJID IS NOT SPECIFIED, LEAVE PARAMETER LIST AS IS  ***         39000020
         AIF   ('&TJID' EQ '').TSTTYPE                                  40000020
.***  DISTINGUISH BETWEEN TJID REG AND TJID ABSOLUTE NUMBER  ***        41000020
         AIF   ('&TJID'(1,1) EQ '(').REG                                42000020
         AIF   ('&TJID' EQ '0').GENSR                                   43000020
         MVC   &PLIST+4(2),&TJID . GET VALUE OF TJID FROM STORAGE       44000020
         AGO   .TSTTYPE                                                 45000020
.GENSR   ANOP                                                           46000020
         SR    15,15                                                    47000020
.STORID  ANOP                                                           48000020
         STH   15,&PLIST+4         STORE TJID IN PARAMETER LIST         49000020
         AGO   .TSTTYPE                                                 50000020
.REG     ANOP                                                           51000020
         STH   &TJID(1),&PLIST+4   STORE TJID IN PARAMETER LIST         52000020
.TSTTYPE AIF   ('&TYPE' EQ 'INIT').SETINIT                              53000020
         AIF   ('&TYPE' EQ 'ADJUST').SETFREE                            54000020
         AIF   ('&TYPE' EQ 'DATA' OR '&TYPE' EQ '').SETDATA             55000020
         MNOTE 12,'INVALID READ FUNCTION'                               56000020
         MEXIT                                                          57000020
.SETINIT ANOP                                                           58000020
         LA    15,4                FUNCTION CODE FOR INITIALIZATION     59000020
         AGO   .STORE                                                   60000020
.SETFREE ANOP                                                           61000020
         LA    15,8                FUNCTION CODE TO INDICATE            62000020
*                                  RELEASE READ SWAP ROUTINE            63000020
.STORE   ANOP                                                           64000020
         STC   15,&PLIST+6         STORE FUNCTION CODE IN               65000020
*                                  PARAMETER LIST                       66000020
         AGO   .CALL                                                    67000020
.SETDATA ANOP                                                           68000020
         XC    &PLIST+6(1),&PLIST+6  ZERO FUNCTION CODE TO INDICATE     69000020
*                                  DATA REQUIRED                        70000020
.CALL    ANOP                                                           71000020
         L     15,READADDR         FETCH READ ROUTINE ADDRESS FROM      72000020
*                                  COMMON CSECT                         73000020
         BALR  14,15               LINK TO READ                         74000020
         AIF   (NOT(&PARMLST)).OUT                                      75000020
&PLIST   SETC  'RDL'.'&SYSECT'(4,5)                                     76000020
&PARMLST SETB  0                                                        77000020
.OUT     ANOP                                                           78000020
         MEND                                                           79000020
