         MACRO                                                          00200013
         CTLPROGD                                                       00400013
         TITLE 'IECKQQ01 (CONTROL PROGRAM)--ENTRY INTERFACE ROUTINE'    00600013
* ENTRY INTERFACE SUBROUTINE                                            00800013
*                                                                       01000013
*                                                                       01200013
*      THIS SUBR IS ENTERED FROM THE SUPERVISOR'S SVC                   01400013
* FLIH WHENEVER A QTAM SUPERVISOR CALL IS ISSUED.  THE                  01600013
* SUBR PERFORMS INITIALIZATION FOR THE QTAM CONTROL                     01800013
* ROUTINE.                                                              02000013
*                                                                       02200013
*                                                                       02400013
*      ASSOCIATED WITH EACH ENTRY TO THE SUBR IS A                      02600013
* SVRB CREATED BY THE SUPERVISOR. THIS SVRB IS CONVERTED TO A QTAM      02800013
* SUBTASK CONTROL BLOCK. ONE OTHERWISE UNUSED WORD IN THE SVRB IS       03000013
* ZEROED AND LATER USED AS AN ECB FOR CONTROLING THE DISPATCHING        03200013
* OF THE SUBTASK IT IS ASSOCIATED WITH.                                 03400013
*                                                                       03600013
*                                                                       03800013
*      THIS 'NEW' STCB IS PLACED AT THE HEAD OF THE STCB                04000013
* CHAIN OF THE QCB FOR THE LAST DISPATCHED QUEUE (THE QUEUE             04200013
* FROM WHICH A SUBTASK WAS LAST ACTIVATED BY QTAM) IF THAT              04400013
* QCB IS STILL ON THE READY QUEUE.  IF THE LAST DISPATCHED              04600013
* QUEUE IS NO LONGER ON THE READY QUEUE, THE NEW STCB IS                04800013
* ITSELF PLACED AT THE TOP OF THE READY QUEUE.  THE ENTRY               05000013
* INTERFACE SUBR THEN EXITS TO THE WAIT OR THE POST                     05200013
* SUBROUTINE, DEPENDING ON WHICH SVC HAS BEEN ISSUED.                   05400013
* 724000                                                         A36508 05500020
*C678000-682000,A697000,A964100-964600                           A49840 05550021
         SPACE                                                          05600013
IGC065   DS    0X                                                       05800013
IGC067   DS    0X                                                       06000013
         BALR  BREG,0                                                   06200013
         USING *,BREG                                                   06400013
         MVI   IOSSAVE,255             SET SVC ENTRY FLAG               06600013
*                                                                       06800013
*      LOAD ADDRESSES OF THE TCB, ENTRY SVRB AND MODULE IGG019NG        07000013
*                                                                       07200013
         L     13,16                   LOAD ADDRESS OF THE CVT          07400013
         L     TCBREG,0(0,13)          LOAD ADDRESS OF TCB POINTERS     07600013
         L     TCBREG,4(TCBREG)        LOAD OLD TCB ADDRESS             07800013
         L     13,156(0,13)            ADDRESS OF THE TERMINAL TABLE    08000013
         L     13,4(0,13)              ADDRESS OF IGG019NG              08200013
         L     Y,TCBRBP ADDR OF RB AT TOP OF PUSH-DOWN LIST             08400013
         XC    XRBQ(4),XRBQ            ZERO ECB FOR WAIT                08600013
         L     QREG,QSAVE              LOAD LAST QUEUE ADDRESS          08800013
*                                                                       09000013
*        PLACE NEW STCB (ENTRY RB) IN STCB CHAIN OF LAST DISPATCHED     09200013
*        QUEUE.                                                         09400013
*                                                                       09600013
         MVC   QSAVE+1(3),DUMMY        WAITRB ADDRESS TO QSAVE          09800013
         MVC   TPRI(4),QTRAN           NEXT STCB ADDRESS TO NEW STCB    10000013
         MVC   TFILL(4),DUMMY-1        QUEUE ADDRESS TO THE STCB        10200013
         MVC   QTRAN+1(3),TCBRBP+1     NEW STCB ADDRESS TO LAST QUEUE   10400013
*                                                                       10600013
*        SET THE PRIORITY OF THE NEW STCB                               10800013
*                                                                       11000013
         MVI   TPRI,X'DC'         SET LOW PRIORITY IN STCB       A25336 11200019
         L     TCBREG,0(13)            LPS QUEUE ADDRESS                11400013
         NC    TPRI,288(TCBREG)   SET TO ZERO FOR CLOSEDOWN             11600019
         MVC   RQSAVE(5),READY                                     00PS 11800019
         B     ZEROPRI                                             00PS 12000019
RQSAVE   DC    6X'00'             ADDRESS AT TOP OF READY QUEUE    00PS 12200019
*                                                                       12600013
*      EXIT TO POST OR WAIT ROUTINES                                    12800013
*                                                                       13000013
ZEROPRI  L     TCBREG,XRBREG+8         LOAD PASSED REGISTER 2           13200013
         LA    TREG,0(TCBREG)          COPY REGISTER AND CLEAR HI ORDER 13400013
         L     X,XRBLNK-1         GET POINTER TO PRECEDING RB           13600013
         CLI   XRBPSW+3-TBLOCK(X),QWAIT     EXAMINE SVC CODE            13800013
         BE    WAIT      FALL THRU IF POST                              14000013
         TITLE 'IECKQQ01 (CONTROL PROGRAM)--POST SUBROUTINE'            14200013
* QTAM POST SUBROUTINE                                                  14400013
*      THE POST SUBR PLACES THE ADDR OF THE QCB NAMED BY THE CALLING    14600013
* ROUTINE INTO THE QCB ADDR FIELD OF THE SPECIFIED ELEMENT.  THE POST   14800013
* ROUTINE BRANCHES TO THE PRIORITY SEARCH SUBR TO CAUSE THE ELEMENT TO  15000013
* BE PLACED ON THE READY QUEUE IN PRIORITY ORDER.                       15200013
         SPACE                                                          15400013
*                                                                       15600013
*      ASSIGN ELEMENT PRIORITY IF REQUESTED                             15800013
*                                                                       16000013
         MVI   QKEY,2                  SET QUEUE NOT WAITING            16200013
         CR    TREG,TCBREG             WAS PRIORITY PASSED              16400013
         BE    POST                    BRANCH IF NO PRIORITY PASSED     16600013
         MVC   FPRI,XRBREG+8           SET ELEMENT PRIORITY             16800013
*                                                                       17000013
*      INITIALIZE FOR PRIORITY INSERT ROUTINE                           17200013
*                                                                       17400013
POST     ST    TREG,FKEY          PUT QCB'S ADDR IN ELEMENT             17600013
         LA    QREG,READY         POINT QREG TO HEAD OF READY QUEUE     17800013
         B     PRIORITY            BRANCH TO PRIORITY WITH--            18000013
*                                      QREG EQ. READY QUEUE HEAD        18200013
*                                      FREG EQ. ELEMENT ADDRESS         18400013
         TITLE 'IECKQQ01 (CONTROL PROGRAM)--WAIT SUBROUTINE'            18600013
* QTAM WAIT SUBROUTINE                                                  18800013
*      WHEN THE WAIT SUBR IS ENTERED, THE STCB REPRESENTING RE-ENTRY    19000013
* TO THE CALLING ROUTINE (WHEN THE WAIT CONDITION IS SATISFIED) HAS     19200013
* ALREADY BEEN CHAINED INTO A QCB BY THE ENTRY INTERFACE SUBR.          19400013
* THE WAIT SUBR DETERMINES WHAT FURTHER DISPOSITION SHOULD BE MADE,     19600013
* BASED ON CURR CONDITIONS, TO SCHED THE SUBTASK FOR ACTIVATION.  FOUR  19800013
* SETS OF CONDITIONS DETERMINE THE DISPOSITION.                         20000013
* 1.   IF THE SPECIFIED QCB HAS A KEY OF 2, THE WAIT SUBR MAKES NO      20200013
* FURTHER DISPOSITION BUT BRANCHES IMMEDIATELY TO THE DEFER-ENTRY SUBR. 20400013
* 2.   IF THE SPECIFIED QCB HAS AN ELEMENT AVAILABLE ON ITS ECB THE     20600013
* STCB IS LEFT LINKED INTO WHATEVER QCB THE ENTRY INTERFACE SUBR HAD    20800013
* CHAINED IT INTO.  THE WAIT SUBR THEN BRANCHES TO THE EXIT SELECT      21000013
* SUBR.  THIS CAUSES THE ADDR OF THE ELEMENT FOUND ON THE USER-         21200013
* SPECIFIED QCB'S ELEMENT CHAIN TO BE PLACED IN THE CALLING ROUTINE'S   21400013
* PARAMETER REGISTER, WHICH IS ITSELF STORED IN THE SAVE AREA OF THE    21600013
* STCB.  THE NET EFFECT IS THAT AT THE TIME THE SUBTASK IS ACTIVATED,   21800013
* IT APPEARS IN THE STCB CHAIN OF THE QATTACH QCB, OR THE STCB CHAIN    22000013
* OF THE DISPATCHED QUEUE.  THE ELEMENT CHAIN FROM WHICH IT IS DRAWING  22200013
* ELEMENTS, HOWEVER, IS THAT OF THE QCB SPECIFIED BY THE CALLING        22400013
* ROUTINE.                                                              22600013
* 3.   IF THE SPECIFIED QCB HAS NO ELEMENTS AVAILABLE, BUT THE LAST-    22800013
* DISPATCHED QUEUE AND THE QUEUE SPECIFIED BY THE CALLING ROUTINE ARE   23000013
* THE SAME, THE STCB IS ALREADY CHAINED INTO THE CORRECT QCB AND THAT   23200013
* QCB IS ALREADY WAITING ON THE READY QUEUE.  THE WAIT SUBR BRANCHES TO 23400013
* THE DISPATCH SUBR.                                                    23600013
* 4.   IF THE SPECIFIED QCB HAS NO ELEMENTS AVAILABLE AND IS NOT THE    23800013
* QCB FOR THE LAST-DISPATCHED QUEUE, THE STCB MUST BE LINKED INTO THE   24000013
* SPECIFIED QCB'S STCB CHAIN. THEREFORE, THE WAIT SUBR FALLS THRU TO    24200013
* THE DEFER-ENTRY SUBR.                                                 24400013
         SPACE                                                          24600013
         DROP  Y                                                        24800013
         USING TBLOCK,TREG                                              25000013
WAIT     MVI   QATTACH,0                                                25200013
         TM    QKEY-QBLOCK(TREG),1     IS QWAIT QUEUE NOT WAITING       25400013
         BZ    UNAVAIL                 BR. YES UNABLE TO ASSIGN ELEMENT 25600013
*                                                                       25800013
*      IF AN ELEMENT IS AVAILABLE ASSIGN IT TO STCB WHICH ISSUED QWAIT  26000013
*                                                                       26200013
         L     FREG,QKEY-QBLOCK(0,TREG) ADDRESS OF FIRST ELEMENT IN     26400013
*                                      THE ELEMENT CHAIN OF THE QUEUE   26600013
*                                      BEING WAITED ON.                 26800013
         MVC   QFAC-QBLOCK(,TREG),FLINK REMOVE FIRST ELEMENT FROM CHAIN 27000013
         CL    FREG,QKEY-QBLOCK(0,TREG) IS ELEMENT DUMMY END ELEMENT    27200013
         BNE   RETURNX                 NO- BRANCH TO DISPATCH SUBTASK   27400013
*                                      WHICH ISSUED QWAIT               27600013
*                                                                       27800013
*      EXIT TO QDISPATCH IF ENTRY INTERFACE ROUTINE PUT STCB IN THE     28000013
*      CORRECT QUEUE.                                                   28200013
*                                                                       28400013
         CLR   TREG,QREG               IS QWAIT QUEUE EQUAL TO LAST     28600013
*                                      DISPATCHED QUEUE.                28800013
         BE    DISPATCH                BRANCH IF YES THE STCB IS IN THE 29000013
*                                      CORRECT QUEUE.                   29200013
*                      FALL THRU TO DEFER-ENTRY RTN WHEN DIFFERENT.     29400013
         TITLE 'IECKQQ01 (CONTROL PROGRAM)--DEFER ENTRY ROUTINE'        29600013
* DEFER-ENTRY SUBROUTINE                                                29800013
*      THIS SUBR CAUSES ENTRY TO A SUBTASK TO BE DEFERRED.  WHEN A      30000013
* CONTROL SUBR ENCOUNTERS AN STCB FOR A SUBTASK THAT CANNOT BE          30200013
* ACTIVATED, A BRANCH TO THE DEFER-ENTRY SUBR IS TAKEN.  THIS SUBR      30400013
* CAUSES THE STCB TO BE REMOVED FROM THE POSITION AT WHICH IT WAS       30600013
* ENCOUNTERED AND LINKED INTO THE APPROPRIATE STCB CHAIN.               30800013
*      AFTER RETRIEVING THE POINTER TO THE STCB FROM THE LOCATION WHERE 31000013
* IT WAS ENCOUNTERED AND RESTORING THAT LOCATION TO ITS FORMER STATE,   31200013
* THE DEFER-ENTRY SUBR BRANCHES TO PRIORITY.  THIS CAUSES THE STCB TO   31400013
* BE PLACED, BY PRIORITY ORDER, INTO THE STCB CHAIN OF THE QCB          31600013
* SPECIFIED BY THE CALLING ROUTINE.                                     31800013
*      AN EXCEPTION ARISES IF THE KEY OF THE QCB SPECIFIED BY THE       32000013
* CALLING ROUTINE IS 2.  THIS CONDITION INDICATES THAT THE HIGHEST-     32200013
* PRIORITY SUBTASK ON THE QCB'S STCB CHAIN IS NOT WAITING FOR ELEMENTS  32400013
* AND IS READY TO RECEIVE CONTROL.  THE STCB BEING PROCESSED, HOWEVER,  32600013
* IS NOT READY. IF IT IS OF HIGHER PRIORITY THAN THE READY SUBTASK IT   32800013
* CANNOT BE PLACED AT THE HEAD OF THE STCB CHAIN WITHOUT PRE-EMPTING    33000013
* THE 'READY' STATUS THAT APPLIES TO THE CURR TOP STCB AND THAT SHOULD  33200013
* BE HONORED FIRST FOR MAX EFFICIENCY.  THEREFORE, THE DEFER-ENTRY SUBR 33400013
* ENTERS PRIORITY BY A PATH THAT ENSURES THAT THE NEW STCB IS ENQUEUED  33600013
* BY PRIORITY ORDER BELOW THE CURRENT TOP STCB.                         33800013
         SPACE                                                          34000013
UNAVAIL  L     FREG,QTRAN         POINT TO HEAD OF STCB CHAIN           34200013
         MVC   QTRAN+1(3),TLINK-TBLOCK(FREG)    REMOVE STCB FROM CHAIN  34400013
         LA    QREG,QTRAN-QBLOCK(0,TREG)   POINT TO NEXT STCB IN CHAIN  34600013
         CLI   QKEY-QBLOCK(TREG),2     IS PASSED QCB ON READY QUEUE     34800013
*                                      NOT WAITING.                     35000013
         BNE   PRIORITY                BRANCH NO TO ENQUEUE NEW STCB    35200013
*                                      IN STCB CHAIN BY PRIORITY.       35400013
*                                                                       35600013
*      ENSURE NEW STCB WILL BE ENQUEUED BELOW STCB AT HEAD OF QUEUE     35800013
*                                                                       36000013
         L     TREG,QKEY          POINT TREG TO FIRST STCB IN CHAIN     36200013
SCAN     LA    QREG,TPRI          POINT QREG TO LINK FIELD OF ITEM      36400013
*                                                                       36600013
*                                                                       36800013
         TITLE 'IECKQQ01 (CONTROL PROGRAM)--PRIORITY SEARCH SUBR'       37000013
* PRIORITY SEARCH SUBROUTINE                                            37200013
*      THIS IS A GENERALIZED SUBR THAT DETERMINES THE POSITION WITHIN A 37400013
* CHAIN THAT AN ITEM SHOULD ASSUME IN ORDER TO BE IN CORRECT PRIORITY   37600013
* SEQUENCE.  ITEMS IN THE CHAIN ARE ARRANGED IN DESCENDING ORDER OF     37800013
* PRIORITIES FROM THE TOP OF THE CHAIN.  THE SUBR ACTS ON ALL CHAINS    38000013
* INCLUDING THE READY QUEUE.                                            38200013
*      THE SUBR EXAMINES EACH ITEM ON THE CHAIN UNTIL IT FINDS EITHER   38400013
* AN ITEM WITH LOWER PRIORITY THAN THAT OF THE SEARCH ARGUMENT, OR THE  38600013
* LAST ITEM ON THE CHAIN (SIGNALLED BY PRIORITY 255).  WHEN EITHER      38800013
* CONDITION IS MET, THE SUBR EXITS TO THE QUEUE INSERT SUBR.            39000013
* FOR THE PRIORITY SEARCH SUBROUTINE, FREG POINTS TO THE ITEM TO BE     39200013
* ORDERED,QREG POINTS INITIALLY TO THE HEAD OF A QUEUE AND THEREAFTER   39400013
* TO SUCCESSIVE ITEMS ON THE QUEUE, AND TREG POINTS TO THE ITEM THAT    39600013
* PRECEDES THE ITEM IN QREG.  WHEN THE ITEM IN TREG HAS A LOWER PRI-    39800013
* ORITY THAN THE SEARCH ARGUMENT IN FREG, OR IS THE LAST ITEM ON THE    40000013
* CHAIN, THE SEARCH ARGUMENT IS TO BE LINKED UPWARD TO THE ITEM IN      40200013
* QREG, AND DOWNWARD TO THE ITEM IN TREG.                               40400013
         SPACE                                                          40600013
PRIORITY L     TREG,QKEY          POINT TO ITEM ON QUEUE                40800013
         CLI   TPRI,255           PRIORITY 255 SIGNALS END OF CHAIN     41000013
         BE    LIFO   IF FOUND,LINK ITEM AHEAD OF LAST.                 41200013
         CLC   TPRI,FPRI  IS PRI LOWER THAN QUEUED ITEM'S.              41400013
         BC    10,SCAN            NO -- GET NEXT ITEM ON QUEUE          41600013
*                                 YES -- ITEM IN FREG LINKS INTO QUEUE  41800013
*                                 BELOW THE ITEM IN QREG.               42000013
*                                                                       42200013
* FALL THRU TO QUEUE INSERT RTN                                         42400013
         TITLE 'IECKQQ01 (CONTROL PROGRAM)--QUEUE INSERT SUBROUTINE'    42600013
* QUEUE INSERT SUBROUTINE                                               42800013
*      THIS IS A GENERALIZED SUBR THAT LINKS ITEMS INTO A CHAIN. IT IS  43000013
* APPLIED TO ALL CHAINS INCLUDING THAT OF THE READY QUEUE.  WHEN THIS   43200013
* SUBR IS ENTERED, A REGISTER CONTAINS A POINTER TO THE LINK ADDR       43400013
* PORTION OF THE ITEM AT THE POINT IN THE CHAIN AT WHICH THE NEW ITEM   43600013
* IS TO BE INSERTED.  A SECOND REGISTER HOLDS THE ADDRESS OF THE ITEM   43800013
* TO BE INSERTED.  (THE POINT OF INSERTION IS THE HEAD OF THE CHAIN     44000013
* EXCEPT WHEN THIS SUBROUTINE IS ENTERED FROM THE PRIORITY SEARCH       44200013
* SUBR WHICH SELECTS THE INSERTION POINT ACCORDING TO THE ITEM'S        44400013
* PRIORITY.)  THE SUBR PLACES THE OLD LINK ADDR IN THE NEW ITEM,        44600013
* REPLACES THE OLD LINK ADDR WITH THE NEW ITEM'S ADDR, AND EXITS TO THE 44800013
* QDISPATCH RTN (DISPATCH).                                             45000013
         SPACE                                                          45200013
LIFO     MVC   FLINK,QFAC              LINK ADDRESS OF OLD ITEM TO NEW  45400013
         IC    TREG,QFAC-1             SAVE BYTE OF OLD LINK FIELD      45600013
         ST    FREG,QFAC-1             NEW ITEM ADDRESS TO OLD          45800013
         STC   TREG,QFAC-1             RESTORE BYTE OF OLD LINK FIELD   46000013
*                                                                       46200013
* FALL THRU TO DISPATCH RTN.                                            46400013
         TITLE 'IECKQQ01 (CONTROL PROGRAM)--DISPATCH SUBROUTINE'        46600013
* DISPATCH SUBROUTINE                                                   46800013
*      THIS SUBR PERFORMS THE PRIMARY INTERNAL MANAGEMENT               47000013
* FUNCTION WITHIN QTAM.  EXCEPT FOR THOSE CASES IN                      47200013
* WHICH ANOTHER SUBR IS ABLE TO DETERMINE THE SUBTASK                   47400013
* TO BE ACTIVATED NEXT (AS, FOR EXAMPLE, WHEN THE WAIT                  47600013
* SUBROUTINE FINDS THAT ELEMENTS ARE ALREADY AVAILABLE TO A             47800013
* SUBTASK REQUESTING ELEMENTS AND THAT THE DISPATCH SUBR                48000013
* CAN BE BYPASSED), THE DISPATCH SUBR MAINTAINS                         48200013
* CONTINUITY BY RECEIVING CONTROL FROM A COMPLETED SUBTASK              48400013
* AND SELECTING ANOTHER SUBTASK WHICH IS TO RECEIVE CONTROL.            48600013
*      THE DISPATCH SUBR EXAMINES THE ITEM AT THE HEAD                  48800013
* OF THE READY QUEUE AND TAKES ONE OF FOUR COURSES OF                   49000013
* ACTION, DEPENDING ON THE TYPE OF ITEM ENCOUNTERED.  ITEMS             49200013
* THAT CAN APPEAR ON THE READY QUEUE ARE--                              49400013
*  1.  QCB'S FOR WHICH THE HIGHEST-PRIORITY                             49600013
*      SUBTASK IS NOT WAITING FOR ELEMENTS (QCB KEY IS 2).              49800013
*  2.  QCB'S WAITING FOR ELEMENTS(KEY IS 3).                            50000013
*  3.  ECB'S CONTAINING THE ADDR OF                                     50200013
*      THE QCB TO WHICH THE ELEMENT HAS BEEN POSTED (KEY IS 0).         50400013
*  4.  FULL STCBS, FOR WHICH THE KEY VALUE IS ALSO ZERO.                50600013
*      THE FIRST WORD OF A FULL STCB CONTAINS THE ADDRESS               50800013
*      OF THE QATTACH QCB.                                              51000013
*      THE EFFECT OF THE APPEARANCE OF EACH TYPE AT THE HEAD            51200013
* OF THE READY QUEUE IS DESCRIBED BELOW.                                51400013
         SPACE                                                          51600013
* QCB--NOTWAITING (KEY=2).                                              51800013
*      WHEN THE ITEM AT THE HEAD OF THE READY QUEUE IS A 'NOT WAITING'  52000013
* QCB, CONTROL IS GIVEN TO THE FIRST (HIGHEST PRIORITY)                 52200013
* SUBTASK REPRESENTED IN THE QCB'S STCB CHAIN AND THE QCB'S             52400013
* KEY IS SET TO 3.                                                      52600013
         SPACE                                                          52800013
* QCB--WAITING (KEY 3).                                                 53000013
*      A 'WAITING' QCB AT THE HEAD OF THE READY QUEUE IS REMOVED FROM   53200013
* THE READY QUEUE (I.E., IS REPLACED BY THE ITEM IT LINKED TO) AND      53400013
* ITS KEY IS SET TO 1.  A QCB WAITING FOR ELEMENTS CANNOT               53600013
* CONTEND FOR CONTROL; HOWEVER, IT WILL AUTOMATICALLY BE                53800013
* RETURNED TO THE READY QUEUE WHEN AN ELEMENT BECOMES AVAILABLE.        54000013
*      AN EXCEPTION ARISES WHEN A SUBTASK REQUIRES MORE THAN            54200013
* ONE ELEMENT (FOR EXAMPLE, A SERIES OF BUFFERS) TO                     54400013
* ACCOMPLISH ITS FUNCTION.  WHEN WUCH A SUBTASK RECEIVES                54600013
* CONTROL, THE QCB WITH WHICH IT IS ASSOCIATED CONTINUES TO             54800013
* APPEAR AS 'WAITING' (KEY IS 3) UNTIL ALL REQUIRED                     55000013
* ELEMENTS HAVE BEEN RECEIVED.  BEFORE A WAITING QCB IS                 55200013
* REMOVED, IT IS DETERMINED WHETHER THE QTAM SUBTASK FROM               55400013
* WHICH CONTROL WAS LAST RETURNED WAS ASSOCIATED WITH THAT              55600013
* QCB.  IF IT WAS, THAT SUBTASK IS AGAIN GIVEN CONTROL.                 55800013
* THIS CYCLE CONTINUES UNTIL THE SUBTASK FULFILLS ALL OF                56000013
* ITS REQUIREMENTS OR UNTIL THE SUBTASK EXHAUSTS THE                    56200013
* QUEUE'S ELEMENT CHAIN.                                                56400013
         SPACE                                                          56600013
* ELEMENT CONTROL BLOCK.                                                56800013
*      AN ECB (UNLESS ASSEMBLED AS AN ITEM IN THE READY QUEUE)          57000013
*  APPEARS ON THE                                                       57200013
* READY QUEUE AS A RESULT OF AN SVC 67, AS EXPLAINED BELOW,             57400013
* AND CONTAINS THE ADDRESS OF THE QCB FOR THE QUEUE TO                  57600013
* WHICH THE ELEMENT HAS BEEN POSTED.  AN ELEMENT APPEARING              57800013
* AT THE TOP OF THE READY QUEUE IS IMMEDIATELY REPLACED BY              58000013
* THE NEXT ITEM ON THE READY QUEUE.  HOWEVER, THE QCB                   58200013
* POINTER IN THE ECB IS RETAINED.  THAT QCB IS THEN TREATED AS THOUGH   58400013
* IT, RATHER THAN AN ELEMENT ASSOCIATED WITHIT, HAD BEEN ENCOUNTERED;   58600013
* ITS HIGHEST PRIORITY SUBTASK IS ACTIVATED, AND ITS KEY IS SET TO 3.   58800013
*      THIS CONVENTION HAS SEVERAL SIGNIFICANT ASPECTS...               59000013
*  1.  IT IS THE MEANS BY WHICH A REMOVED 'WAITING' QCB IS              59200013
*      RETURNED TO THE READY QUEUE.                                     59400013
*  2.  IT ILLUSTRATES THE CASE WHERE THE ACTIVE QCB -- THAT             59600013
*      IS, THE QCB WITH WHICH THE ACTIVE SUBTASK CONTROL                59800013
*      BLOCK IS ASSOCIATED -- IS NOT NECESSARILY AT THE                 60000013
*      HEAD OF THE READY QUEUE.                                         60200013
*  3.  IT EXPLAINS THE FACT THAT AN ECB NEED NOT BE PHYSICALLY CHAINED  60400013
*      INTO A QCB TO BECOME ASSOCIATED WITH THAT QCB.  SPECIFICALLY, IT 60600013
*      ENSURES THAT AN ELEMENT IS IMMEDIATELY ACTED UPON, EXCEPT IN     60800013
*      THE CASE WHERE THE QUEUE INVOLVED ALREADY HAS AT                 61000013
*      LEAST ONE OTHER 'REAL' ELEMENT AND IS ALREADY                    61200013
*      CONTENDING FOR COMPUTING TIME.                                   61400013
         SPACE                                                          61600013
* FULL SUBTASK CONTROL BLOCK                                            61800013
*      THIS IS THE ONLY FORM OF STCB THAT APPEARS ON THE READY QUEUE.   62000013
* ITS APPEARANCE AT THE HEAD OF THE READY QUEUE HAS EXACTLY THE SAME    62200013
* EFFECT AS THE APPEARANCE THERE OF A 'NOT WAITING' (KEY IS 2) QCB      62400013
* WITH THIS STCB AT THE HEAD OF ITS STCB CHAIN, THE SUBTASK             62600013
* IS ACTIVATED AND THE KEY OF THE QCB WITH WHICH IT IS                  62800013
* ASSOCIATED (QATTACH) IS SET TO 3.                                     63000013
*      THE MECHANISM BY WHICH THIS IS ACCOMPLISHED IS AS FOLLOWS...     63200013
*  1.  LOCATION READY CONTAINS A POINTER TO THE STCB; THIS              63400013
*      SITUATION IS THE PHYSICAL COUNTERPART OF THE STCB'S              63600013
*      BEING AT THE HEAD OF READY QUEUE.                                63800013
*  2.  THE STCB ITSELF HAS THE APPEARANCE (TO THE QTAM                  64000013
*      CONTROL ROUTINES) OF AN ELEMENT.  ITS QCB ADDR IS QATTACH.       64200013
*  3.  QATTACH IS A STORAGE LOCATION EQUIVALENT TO READY                64400013
*      MINUS 8 BYTES. IT ALSO APPEARS TO BE THE FIRST WORD              64600013
*      OF A 'NOT WAITING' QCB.                                          64800013
*  4.  SINCE THE STCB IS APPARENTLY AN ECB ASSOCIATED                   65000013
*      WITH A 'NOT WAITING' QCB, THE FIRST STCB IN THAT QCB'S CHAIN     65200013
*      SHOULD BE SELECTED FOR ACTIVATION.  THE ADDR OF THE FIRST STCB   65400013
*      IS TO BE FOUND IN THE THIRD FULLWORD OF THE QCB.                 65600013
*  5.  THE THIRD FULLWORD OF THE QATTACH WHICH APPEARS AS A             65800013
*      QCB IS THE LOCATION READY.  THEREFORE, THE FULL                  66000013
*      SUBTASK, WHOSE ADDRESS IS AT READY, IS SELECTED FOR CONTROL.     66200013
         SPACE                                                          66400013
* FETCH HEAD OF READY QUEUE                                             66600013
         SPACE 2                                                        66800013
DISPATCH MVI   QATTACH,2          RESET QATTACH QCB TO NOT WAITING      67000013
         L     FREG,READY         POINT FREG TO ITEM AT RDY Q HEAD      67200013
         LA    QREG,FKEY          POINT QREG TO 1ST WORD OF READY ITEM  67400013
         CLC   READY+1(3),QSAVE+1      MAY THIS READY ITEM BE DISP.     67600013
         B     DISPSUBR      TO SUBROUTINE TO SEE IF ITEM CAN BE A49840 67800021
*     DISPATCHED.    IF SUBROUTINE GOES TO 'EXIT', ITEM WILL NOT A49840 68000021
*     BE DISPATCHED BECAUSE ONE OF 3 CASES EXIST AS FOLLOWS      A49840 68200021
*                                   1. ENTRY TO QDISPATCH WAS FROM AN   68400013
*                                      SVC AND THIS READY ITEM IS THE   68600013
*                                      DUMMY END ITEM.                  68800013
*                                   2. ENTRY TO QDISPATCH WAS FROM AN   69000013
*                                      ASYNCHRONOUS INTERRUPT AND THIS  69200013
*                                      IS THE QUEUE LAST DISPATCHED ON  69400013
*                                      AN SVC ENTRY TO QDISPATCH.       69600013
*                                3.  MCP IS ABENDING             A49840 69700021
         CLI   QKEY,2             IS ITEM A QCB -- KEY EQ 2 OR 3        69800013
         BC    10,A   BR WHEN KEY EQUAL/HIGHER THAN 2                   70000013
*                                 NO  -- CONSIDER IT AN ELEMENT         70200013
         SPACE                                                          70400013
*                                                                       70600013
* REMOVE FOLDED QCB FROM READY QUEUE WHEN ENABLED SUBTASK IS WATING     70800013
*                                                                       71000013
         CL    QREG,QFAC-1             IS ELEMENT POST TO ITSELF        71200013
         BNE   DISABLE                 BRANCH NO                        71400013
         MVC   READY+1(3),FLINK        REMOVE ELEMENT FROM READY QUEUE  71600013
         L     TREG,QTRAN              LOAD STCB ADDRESS                71800013
         CLI   TFILL,0                 IS STCB FULL STCB (SVRB)         72000013
         LA    TREG,QATTACH           QATTACH ADDRESS IN CASE OF BR.    72200013
         BE    WAIT                BRANCH TO PUT STCB ON THE     A36508 72400020
*                                      READY QUEUE.                     72600013
*                                                                       72800013
* FACILITY AT HEAD -- FETCH QUEUE                                       73000013
*                                                                       73200013
DISABLE  EQU   *                                                        73400013
         L     QREG,FKEY    GET ECB'S QCB ADDR                          73600013
         CLI   QKEY,2     IS ECB'S QCB ALREADY ON RDY Q                 73800013
         BC    10,A      BRANCH IF YES                                  74000013
         SPACE                                                          74200013
*                                                                       74400013
* ITEM IS AN ELEMENT POINTING TO A QCB NOT ON THE READY QUEUE.          74600013
*                                                                       74800013
         MVC   QPRI(4),FPRI       REMOVE ELEMENT FROM TOP OF READY Q    75000013
         ST    QREG,READY         REPLACE ELEMENT WITH ITS QCB          75200013
*                                 BRANCH TO BD NOW UNCONDITIONAL        75400013
         SPACE                                                          75600013
A        BC    12,BD              THIS INSTRUCTION IS A BRANCH ON QCB   75800013
*                                 KEY EQ 2 WHEN REACHED VIA A BRANCH    76000013
         SPACE                                                          76200013
*                                                                       76400013
* ITEM IS A WAITING QCB OR AN ELEMENT POINTING TO A WAITING QCB         76600013
*                                                                       76800013
         MVC   READY+1(3),FLINK   REMOVE ITEM FROM HEAD OF READY QUEUE  77000013
         NI    FKEY,X'FD' IF ITEM IS A QCB, THIS SETS KEY=2 (NOT WAIT)  77200013
         BC    4,DISPATCH  BRANCH IF QCB                                77400013
*                                 OTHERWISE, ITEM IS AN ELEMENT POINT-  77600013
*                                 ING TO A QCB WITH A WAITING SUBTASK   77800013
*                                                                       78000013
* FALL THRU TO EXIT SELECT RTN WITH ELEMENT REMOVED FROM HEAD OF RDY Q  78200013
         TITLE 'IECKQQ01 (CONTROL PROGRAM)--EXIT SELECT SUBROUTINE'     78400013
* EXIT SELECT SUBROUTINE                                                78600013
*      THIS SUBR ACTIVATES SUBTASKS REPRESENTED BY                      78800013
* TRUNCATED STCB'S, OR FALLS THROUGH TO THE EXIT INTERFACE              79000013
* SUBROUTINE IF THE STCB IS NOT TRUNCATED.                              79200013
*      THE FIRST BYTE OF A TRUNCATED STCB IS A BRANCH                   79400013
* MODIFIER OF THE FORM (ENTRYPT-NRET), WHERE ENTRYPT IS THE             79600013
* ADDR OF THE DESIRED ENTRY POINT.  NRET IS THE LOCATION                79800013
* FROM WHICH THE BRANCH OFFSET IS APPLIED.  WHEN THE EXIT               80000013
* SELECT SUBR ENCOUNTERS A NON-ZERO RETURN CODE, IT                     80200013
* COMPUTES THE BRANCH ADDRESS AND BRANCHES TO THE COMPUTED              80400013
* ENTRY POINT.                                                          80600013
         LR    TREG,QREG               QUEUE ADDRESS TO TREG            80800013
         SPACE 2                                                        81000013
RETURNX  ST    TREG,FKEY                                                81200013
BD       MVI   QKEY,3             SET QCB'S KEY TO 'WAITING'            81400013
RETURN   L     TREG,QTRAN         GET STCB ADDRESS FROM QCB             81600013
         SR    X,X                CLEAR WORK REG                        81800013
         IC    X,TFILL            GET STCB,S RETURN CODE                82000013
         LTR   X,X                ZERO CODE SHOWS AUGMENTED SUBTASK     82200013
         BNZ   NRET(X)  BRANCH TO NON-AUGMENTED SUBTASK IN IGG019NG     82400013
*                                                                       82600013
* FALL THRU TO EXIT INTERFACE RTN IF ITEM A FULL STCB.                  82800013
         TITLE 'IECKQQ01 (CONTROL PROGRAM)--EXIT INTERFACE SUBROUTINE'  83000013
* EXIT INTERFACE SUBROUTINE                                             83200013
*      THIS SUBR IS ENTERED TO PROCESS FULL STCB'S.                     83400013
* BEFORE TAKING ANY OTHER ACTION, THE SUBR DETERMINES                   83600013
* WHETHER THE SUBTASK IS BEING SCHEDULED FOR ACTIVATION                 83800013
* BECAUSE IT WAS REPRESENTED IN THE STCB CHAIN OF A WAITING             84000013
* QCB FOR WHICH AN ELEMENT HAS BEEN ENCOUNTERED.  IF THIS               84200013
* CONDITION EXISTS, THE ELEMENT'S ADDR IS PLACED IN THE                 84400013
* PARAMETER REGISTER IN THE SAVE AREA OF THE FULL STCB.                 84600013
*                                                                       84800013
*                                                                       85000013
*      A BRANCH IS TAKEN TO THE O/S POST ROUTINE TO POST COMPLETION     85200013
* IN THE ECB OF THE STCB (SVRB) BEING DISPATCHED. THE SUBR THEN CAUSES  85400013
* ONE OF TWO EXITS TO BE TAKEN DEPENDING ON THE MODE OF ENTRY, (SVC     85600013
* OR ASYNCHRONOUS INTERRUPT) TO THE QDISPATCH SUBR.                     85800013
*                                                                       86000013
*  1.  IF ENTRY TO QDISPATCH WAS AS THE RESULT OF AN ASYNCHRONOUS       86200013
*      INTERRUPT A RETURN IS MADE TO IOS VIA A BRANCH.                  86400013
*                                                                       86600013
*  2.  IF ENTRY TO QDISPATCH WAS FROM AN SVC A WAIT IS ISSUED ON THE    86800013
*      ECB OF THE ENTRY SVRB. AFTER THE WAIT IS SATISFIED A RETURN IS   87000013
*      EFFECTED TO THE ROUTINE WHICH ISSUED THE SVC.                    87200013
         SPACE 2                                                        87400013
*                                                                       87600013
*      STORE RETURN PARAMETER IF WAITING STCB BEING DISPATCHED          87800013
*                                                                       88000013
         CL    FREG,READY              WAS ENTRY TO THIS ROUTINE THE    88200013
*                                      RESULT OF AN ELEMENT FOUND ON    88400013
*                                      THE READY QUEUE.                 88600013
         BE    *+8                     BRANCH IF ENTRY DUE TO QCB OR    88800013
*                                      STCB FOUND ON READY QUEUE.       89000013
         ST    FREG,XRBREG+4           STORE RETURN PARAMETER           89200013
         ST    QREG,QSAVE              SAVE THIS QUEUE ADDRESS          89400013
*                                                                       89600013
*      POST ECB COMPLETE                                                89800013
*                                                                       90000013
         MVC   QTRAN+1(3),TLINK        REMOVE STCB FROM QUEUE           90200013
         LA    11,XRBQ                 LOAD ECB ADDRESS FOR POST        90400013
LNKLOOP  TM    XSTZB+1,X'80'           TEST FOR LINK FIELD = TCB        90600013
         L     TREG,XRBLNK-1           LOAD RB LINK ADDRESS             90800013
         BC    8,LNKLOOP               BRANCH NOT TCB ADDRESS           91000013
         LR    X,BREG                  SAVE BASE OF QQ01                91200013
         L     15,POSTCON              LOAD POST ENTRY POINT            91400013
         LR    BREG,TREG               LOAD TCB ADDRESS FOR POST        91600013
         BALR  14,15                   TO THE POST ROUTINT              91800013
         LR    BREG,X                  RESTORE QQ01 BASE                92000013
EXIT     CLI   IOSSAVE,255             ENTRY FROM SVC                   92200013
         BNE   REENT                   BRANCH ENTRY FROM I/O INTERRUPT  92400013
*                                                                       92600013
*      WAIT ON ENTRY RB                                                 92800013
*                                                                       93000013
         L     TREG,16                 LOAD CVT ADDRESS                 93200013
         L     TREG,0(TREG)            TCB TABLE ADDRESS                93400013
         L     TREG,4(TREG)            LOAD OLD TCB ADDRESS             93600013
         L     TREG,0(TREG)            LOAD ADDRESS OF ENTRY RB         93800013
         WAIT  1,ECB=XRBQ                                               94000013
*                                                                       94200013
*      RETURN TO ROUTINE WHICH ISSUED THE SVC                           94400013
*                                                                       94600013
         LM    0,15,XRBREG             LOAD CALLERS REGISTERS           94800013
         SVC   3                                                        95000013
*                                                                       95200013
*      RETURN TO IOS                                                    95400013
*                                                                       95600013
REENT    LM    14,13,IOSSAVE           RELOAD REGISTERS                 95800013
         BR    14                      RETURN                           96000013
POSTCON  DC    V(IEA0PT01)             ENTRY ADDRESS FOR OS POST RT.    96200013
IOSSAVE  DS    16A                                                      96400013
DISPSUBR BE    EXIT        CASE 1 OR 2, DO NOT DISPATCH          A49840 96420021
         L     TCBREG,0(13)            LPSQ ADDRESS              A49840 96440021
         L     TCBREG,288(TCBREG)      MCP TCB ADDRESS           A49840 96460021
         TM    29(TCBREG),X'80'  MCP ABENDING?                   A49840 96480021
         BO    EXIT              YES, DO NOT DISPATCH ITEM       A49840 96500021
         B     DISPATCH+22       NO, RETURN TO DISPATCH          A49840 96520021
         MEND                                                           96600013
