         MACRO                                                          00200018
&NAME    DUMPMAC  &SYS=PCP                                              00400018
.*516000,544000                                                   M3240 00410019
         TITLE 'IGC0801C - WRITE DUMP SUBROUTINE'                       00600018
*********************************************************************** 00620018
* MACRO NAME:    DUMPMAC                                              * 00640018
*                                                                     * 00660018
* FUNCTION:      1. DETERMINE DEVICE TO BE WRITTEN UPON.              * 00680018
*                2. FOR DIRECT ACCESS, INSURE DATA SET EMPTY.         * 00700018
*                3. ATTEMPT WRITING OF CORE IMAGE DUMP.               * 00720018
*                4. OUTPUT STATUS MESSAGE TO CONSOLE.                 * 00740018
*                                                                     * 00760018
* APPLICABILITY: ALL VERSIONS OF OS/360 ASSEMBLED WITHIN THE FOLLOW-  * 00780018
*                ING MODULES:                                         * 00800018
*                                                                     * 00820018
*                1. IEAATM08 - PCP DAR                                * 00840018
*                2. IEADTM22 - MFT DAR                             I250 00860019
*                3. IEAQTM08 - MVT/M65MP DAR                          * 00880018
*                                                                     * 00900018
* ATTRIBUTES:    ASSUMES THOSE OF CALLING ROUTINE.                    * 00920018
*                                                                     * 00940018
* ENTRY POINT:   ASSIGNED BY CALLER AS:                               * 00960018
*                                                                     * 00980018
*                NAME    DUMPMAC  SYS=XXX                             * 01000018
*                                                                     * 01020018
*                KEYWORD PARAMETER VALUES:                            * 01040018
*                  1. MVT - FOR MVT AND M65MP SYSTEMS                   01060018
*                  2. MFT - FOR MFT SYSTEMS                             01080018
*                  3. PCP, BLANK OR OTHER - FOR PCP SYSTEMS           * 01100018
*                                                                       01120018
*                ENTRY IS BY BALR, BAL OR B WITH REG 14 THE RETURN    * 01140018
*                REG.                                                 * 01160018
*                                                                     * 01180018
* EXITS:         NORMAL - BRANCH ON REG 14.                           * 01200018
*                ABNORMAL - NONE                                      * 01220018
*                                                                     * 01240018
* INPUT :                                                             * 01260018
*                                                                       01280018
* SUCCESSFUL UTILIZATION OF THIS MACRO/SUBROUTINE DEPENDS UPON THE      01600018
* PROPER INITIALIZATION OF THE FOLLOWING REGISTERS -                    01800018
*                                                                       02000018
*        1. REG 2 - CVT ADDRESS - USING STMNT TO CVTSECT REQ'D.         02200018
*        2. REG 9 - SVRB ADDRESS E.G. DAR'S SVRB ADDRESS                02400018
*        3. REG 12 - CURRENT TCB ADDRESS - USING STMNT TO TCBSECT REQ'D 02600018
*        4. REG 14 - RETURN ADDRESS                                     02800018
*                                                                       03000018
* REGISTERS DESTROYED BY THIS ROUTINE ( NOTE CALLERS REG'S ARE NOT      03200018
*        SAVED).                                                        03400018
*                                                                       03600018
*        1. REG 4 - WORK REG                                            03800018
*       2. REG 7 & 8 - INTERNAL LINK REG'S.                             04000018
*        4. REG 11 - LOADED WITH UCB ADDR OF DEVICE HOUSING SYS1.DUMP   04200018
*        3. REG 10 - LOADED WITH I/O CONTROL BLOCK ADDR FOR WRITING     04400018
*                   OF THE CORE IMAGE DUMP                              04480018
*       4. REG 13 - USED AS A SECOND BASE REG. IF SYS1.DUMP IS ON TAPE. 04560018
*       5. REG 11 - USED AS AN INTERNAL LINK REG IF SYS1.DUMP ON TAPE   04640018
* REMAINING REGISTERS NOT ALTERED.                                      04720018
*                                                                       04800018
* CAUTION SHOULD BE TAKEN IN THE USE OF A BASE REG - INSURE IT IS NOT   05000018
* ONE OF THOSE REGISTERS DESTROYED BY THIS MACRO/SUBROUTINE             05200018
*                                                                     * 05201018
* OUTPUT:        STATUS MESSAGES WRITTEN TO THE CONSOLE ARE AS FOLLOWS* 05202018
*                                                                     * 05203018
*         IEA022I JOBNAME STEPNAME CORE IMAGE FAILED -1               * 05204018
*                                                    -2               * 05205018
*                                                    -3               * 05206018
*                                                                     * 05207018
*         1. IEA022I - 1: SYS1.DUMP DATA SET FULL                     * 05208018
*                                                                     * 05209018
*         2. IEA022I - 2: AN I/O ERROR OCCURRED DURING DATA SET       * 05210018
*                         INITIALIZATION (DIRECT ACCESS ONLY)         * 05211018
*                                                                     * 05212018
*         3. IEA022I - 3: AN I/O ERROR OCCURRED DURING THE ACTUAL     * 05213018
*                         WRITING OF THE CORE IMAGE DUMP.             * 05214018
*                                                                     * 05215018
*                                                                     * 05216018
*         IEA023I JOBNAME STEPNAME CORE IMAGE COMPLETE -1             * 05217018
*                                                                     * 05218018
*                                                                     * 05219018
* EXTERNAL REFERENCES:                                                * 05220018
*                                                                     * 05221018
*                1. CVT                                               * 05222018
*                2. UCB                                               * 05223018
*                3. TCB                                               * 05224018
*                4. SVRB                                              * 05225018
*                                                                     * 05226018
* SVC'S USED:                                                         * 05227018
*                1. WTO - SVC 35                                      * 05228018
*                2. EXCP - SVC 0                                      * 05229018
*                3. WAIT - SVC 1                                      * 05230018
*                                                                     * 05231018
* EXTERNAL DEPENDENCIES:                                              * 05232018
*                                                                     * 05233018
*                DURING IPL/NIP PROCESSING, NIP OBTAINS SPACE FOR AND * 05234018
*                PARTIALLY INITIALZES A SET OF CONTROL BLOCKS USED BY * 05235018
*                THIS SUBROUTINE TO WRITE THE CORE IMAGE DUMP. THESE  * 05236018
*                CONTROL BLOCKS ARE POINTED TO BY THE CVTDAR FIELD.   * 05237018
*                IF NO PROVISIONS FOR SYS1.DUMP WERE MADE DURING IPL, * 05238018
*                NIP SETS THE CVTDAR FIELD TO ZERO. A DIAGRAM OF THE  * 05239018
*                CONTROL BLOCKS FOLLOWS:                              * 05240018
*                                                                     * 05241018
 EJECT                                                                  05242018
*                                                                       05243018
*     MAP OF I/O CONTROL BLOCKS SET UP BY NIP FOR DAR                 * 05244018
*                                                                       05245018
*                         CVT                                         * 05246018
*                             ********************                    * 05247018
*                           0 *                  *                    * 05248018
*                             *                  *                    * 05249018
*                             ********************                    * 05250018
*                          72 *                  *                    * 05251018
*                             * CVTDAR - ADDR OF *                    * 05252018
*                             *   DAR'S CONTROL  **********           * 05253018
*                             *   BLOCKS         *        *           * 05254018
*                             *                  *        *           * 05255018
*                             ********************        *           * 05256018
*                             *                  *        *           * 05257018
*                             *                  *        *           * 05258018
*                             *                  *        *           * 05259018
*                             *                  *        *           * 05260018
*                             ********************        *           * 05261018
*                                                         *           * 05262018
*                                                         *           * 05263018
*                                                         *           * 05264018
*                                                         *           * 05265018
*           ***********************************************           * 05266018
*           *                                                         * 05267018
*           *                                                         * 05268018
*           *                                                         * 05269018
*           *                                                         * 05270018
*         *****                                                       * 05271018
*          ***                                                        * 05272018
*           *                                                         * 05273018
*                                                                     * 05274018
*  DUMMY   0***********************                                   * 05275018
*  DCB      *  DEB ADDRESS        *                                   * 05276018
*           **********************************************            * 05277018
*  DEB     4*                                            *            * 05278018
*           *                                            *            * 05279018
*           *                                            *            * 05280018
*           *                                            *            * 05281018
*           *                                            *            * 05282018
*           **********************************************            * 05283018
*  ECB    52*                     *                                   * 05284018
*           **********************************************            * 05285018
*  IOB    54*                                            *            * 05286018
*           *                                            *            * 05287018
*           *                                            *            * 05288018
*           *                                            *            * 05289018
*           *                                            *            * 05290018
*           **********************************************            * 05291018
 EJECT                                                                  05292018
*           **********************************************            * 05293018
*         96*   CCW 1             *   CCW 2              *            * 05294018
*           **********************************************            * 05295018
*        112*   CCW 3             *   CCW 4              *            * 05296018
*           **********************************************            * 05297018
*        128*   CCW 5             *   CCW 6              *            * 05298018
*           **********************************************            * 05299018
*        114*   CCW 7             *   CCW 8              *            * 05300018
*           **********************************************            * 05301018
*        160*   FAILING TCB ADDR  *   SPARE SPACE        *            * 05302018
*           **********************************************            * 05303018
*                                                                     * 05304018
*          TOTAL LENGTH = 168 BYTES                                   * 05305018
*                                                                     * 05306018
* MOTE:  MACRO DARMAC, EXPANDS TO PROVIDE A MAPPING DSECT OF THE ABOVE* 05307018
*        CONTROL BLOCK COMPLEX. DARMAC IS CALLED BY DUMPMAC FOR JUST  * 05308018
*        THAT PURPOSE.                                                * 05309018
 EJECT                                                                  05310018
*                                                                     * 05311018
* OPERATION:                                                          * 05312018
*                THIS SUBROUTINE IS BASICALLY AN I/O ROUTINE, CAPABLE * 05313018
*                OF WRITING A CORE IMAGE DUMP TO A PRE-ALLOCAGED      * 05314018
*                DATA SET (SYS1.DUMP) WHICH MAY RESIDE ON TAPE OR A   * 05315018
*                DIRECT ADDESS DEVICE.                                * 05316018
*                                                                     * 05317018
*                INITIALLY, THE UCB ADDRESS OF THE DEVICE UPON WHICH  * 05318018
*                SYS1.DUMP RESIDES IS OBTAINED FROM DAR'S IOB (PROVID-* 05319018
*                ED BY NIP). IT CAN THEN BE DETERMINED WEATHER THE    * 05320018
*                DATA SET IS UPON TAPE OR DIRECT ACCESS.              * 05321018
*                                                                     * 05322018
*                DIRECT ACCESS:                                       * 05323018
*                                                                     * 05324018
*                A CHANNEL PROGRAM IS SET UP TO READ THE FIRST RECORD * 05325018
*                ON THE DATA SET. IF THE DATA SET IS EMPTY, AN END OF * 05326018
*                FILE RECORD WILL BE READ CAUSING A UNIT CHECK        * 05327018
*                CONDITION. THE ABSENCE OF A UNIT CHECK MEANS THE DATA* 05328018
*                SET IS FULL AND MESSAGE IEA022I-1 IS OUTPUTTED  TO   * 05329018
*                THE CONSOLE. NO FURTHER I/O ATTEMPT IS MADE.         * 05330018
*                                                                     * 05331018
*                IF THE DATA SET IS EMPTY THE EOF RECORD NEEDS TO BE  * 05332018
*                OVERLAID WITH A FORMAT RECORD. A CHANNEL PROGRAM IS  * 05333018
*                INITIALIZED TO PERFORM A WRITE COUNT KEY DATA TO     * 05334018
*                'REFORMAT' THE FIRST RECORD. UPON COMPLETION, SHOULD * 05335018
*                AN I/O ERROR OCCUR, MESSAGE IEA022I-2 IS WRITTEN AND * 05336018
*                I/O ACTIVITY ENDS.                                   * 05337018
*                                                                     * 05338018
*                EXCP AND WAIT ARE USED TO EXECUTE THE ABOVE TWO      * 05339018
*                CHANNEL PROGRAMS.                                    * 05340018
*                                                                     * 05341018
*                THE ACTUAL WRITING OF THE CORE IMAGE DUMP IS NOW     * 05342018
*                ATTEMPTED USING TWO CHANNEL PROGRAMS AND A PCI       * 05343018
*                APPENDAGE. SIMILIARLY  A CHANNEL END APPENDAGE       * 05344018
*                AND AN ABNORMAL END APPENDAGE ARE PROVIDED TO HANDLE * 05345018
*                      1. LAST WRITE                                  * 05346018
*                      2. TIMING DELAYS                               * 05347018
*                      3. END OF  CYLINDER CONDITIONS                 * 05348018
*                                                                     * 05349018
*                EXCP AND WAIT ARE USED TO EXECUTE THE CHANNEL PGM.   * 05350018
*                                                                     * 05351018
*                UPON COMPLETION, THE ECB IS EXAMINED TO DETERMINE    * 05352018
*                IF A SUCCESS OR FAILURE MESSAGE IS TO BE ISSUED.     * 05353018
*                                                                     * 05354018
*                TAPE:                                                * 05355018
*                                                                     * 05356018
*                WRITING TO TAPE IS SIMILIAR TO THAT ALREADY DESCRIBED* 05357018
*                WITH THE EXCEPTION THAT ONLY ONE CCW IS USED AND NO  * 05358018
*                APPENDAGES ARE PROVIDED. EACH RECORD IS WRITTEN      * 05359018
*                SEQUENTIALLY, CHECKING THE ECB AFTER EACH WRITE.     * 05360018
*                DEPENDING UPON THE COMPLETION CODE IN THE ECB, A     * 05361018
*                SUCCESS OR FAILURE MESSAGE IS WRITTEN TO THE CONSOLE.* 05362018
*                                                                     * 05363018
*                TERMINATION:                                         * 05364018
*                                                                     * 05365018
*                AFTER OUTPUTTING THE FINAL STATUS MESSAGE, THE CALLER* 05366018
*                IS RETURNED TO VIA BRANCH REG 14.                    * 05367018
*********************************************************************** 05368018
 EJECT                                                                  05400018
*                             REGISTER EQUATES                          05600018
CVTREG   EQU   2                                                        05800018
BASEREG  EQU   3                                                        06000018
WORK     EQU   4                                                        06200018
XRET2    EQU   7                                                        06400018
XRET     EQU   8                                                        06600018
SVRBREG  EQU   9                                                        06800018
DARREG   EQU   10                                                       07000018
UCBREG   EQU   11                                                       07200018
LNKREG   EQU   11                                                       07400018
TCBREG   EQU   12                                                       07600018
BASE2    EQU   13                                                       07800018
RETREG   EQU   14                                                       08000018
XREG     EQU   15                                                       08200018
         EJECT                                                          08400018
*                             FLAG MASKS                                08600018
RWUNL    EQU   X'0F'                   REWIND & UNLOAD OP CODE (TAPE)   08800018
SUPPL    EQU   X'20'                   SUPPRESS WRONG LENGTH MASK       09000018
MISCMSK  EQU   X'3F'                   CHAN ERROR, ETC.                 09200018
PCIFLAG  EQU   X'80'                   CCW USAGE INDICATOR              09400018
WRITECOD EQU   X'05'                   WRITE DATA TO D.A. OP CODE       09600018
MASK1    EQU   X'68' .                 CCW FLAGS - C.C.,S.L.I.,P.C.I.   09800018
MASK2    EQU   X'42'                   IOB FLAG MASK                    10000018
MASK3    EQU   X'70'                   CCW FLAGS                        10200018
SUCCESS  EQU   X'7F'                   ECB POST CODE FOR GOOD I/O       10400018
XZERO    EQU   X'00'                                                    10600018
DARREC   EQU   X'80'                   DAR RECURSION FLAG               10800018
UCBREADY EQU   X'40'                   UCB READY FLAG                   11000018
DEVMSKT  EQU   X'80'                   TAPE DEVICE FLAG                 11200018
UNITCK   EQU   X'02'                   I/O DEVICE ERROR FLAG            11400018
SRCHIDEQ EQU   X'31'                   OP CODE FOR SEARCH ID EQUAL CCW  11600018
TIC      EQU   X'08'                   OP CODE FOR TRANS. IN CHAN. CCW  11800018
NOP      EQU   X'03'                   OP CODE FOR NOP CCW              12000018
UNITPXP  EQU   X'01'                   UNIT EXCEPTION FLAG IN CSW       12200018
CON2     EQU   X'20'                   SUPPRESS WRONG LENGTH IN CCW     12400018
WCKD     EQU   X'1D'                   WRITE COUNT KEY DATA OP CODE     12600018
DATACHN  EQU   X'60'                   CCW CHAIN & SLI FLAGS            12800018
READ     EQU   X'06'                   READ DATA OP CODE                13000018
FOX1     EQU   C'1'                                                     13200018
FOX2     EQU   C'2' .                   NO SYS1.DUMP WAS ALLOCATED      13400018
FOX3     EQU   C'3'                                                     13600018
FOX4     EQU   C'4'                                                     13800018
FOX5     EQU   C'5'                                                     14000018
FOX6     EQU   C'6'                                                     14200018
FOX7     EQU   C'7'                                                     14400018
WAIT     EQU   1                                                        14600018
R1       EQU   X'01'                                                    14800018
RUNMASK  EQU   X'0F'                                                    15000018
TAPEMASK EQU   X'F3'                                                    15200018
WTM      EQU   X'1F'                                                    15400018
IOFLAG   EQU   X'42'                                                    15600018
ENDCYL   EQU   X'20'                                                    15800018
NOPCICC  EQU   X'B7' .                  FOR LAST WRITE                  16000018
MTBIT    EQU   X'80'                                                    16200018
SYSERTNS EQU   X'0C'                                                    16400018
ZERO     EQU   0                                                        16600018
INDEX4   EQU   4                                                        16800018
COUNT    EQU   8                                                        17000018
ESANDX   EQU   96                                                       17200018
L4       EQU   4                                                        17400018
L5       EQU   5                                                        17600018
L2       EQU   2                                                        17800018
ESAFLG   EQU   104                                                      18000018
ESAHICNT EQU   100                                                      18200018
L3       EQU   3                                                        18400018
PARMREG  EQU   1                                                        18600018
L9       EQU   9                                                        18800018
C113     EQU   113                                                      18820018
C124     EQU   124                     CONSTANT OF 124                  18840018
C128     EQU   128                     CONSTANT OF 128                  18860018
C132     EQU   132                     CONSTANT OF 132                  18880018
C136     EQU   136                     CONSTANT OF 136                  18900018
LEN8     EQU   8                                                        18920018
ESAADR   EQU   98                                                       19000018
K1       EQU   1                                                        19200018
K32      EQU   32                                                       19400018
ESACNT   EQU   97                                                       19600018
COUNT2   EQU   16                                                       19800018
WTO      EQU   35                                                       20000018
MSGLOC   EQU   88                                                       20200018
DARPTR   EQU   72                                                       20400018
         EJECT                                                          20600018
*                        CONTROL BLOCK DISPLACEMENTS                    20800018
UCBFL1   EQU   6                                                        21000018
UCBTYP   EQU   16                                                       21200018
DEVTYPE  EQU   18                                                       21300018
         EJECT                                                          21400018
*                                                                       21600018
*                   WRITE DUMP SUBROUTINE                               21800018
*                                                                       22000018
&NAME    EQU   *                                                        22200018
         L     DARREG,CVTDAR           ADDRESS I/O CONTROL BLOCK        22400018
*                                           COMPLEX SET UP BY NIP       22600018
         USING DARSECT,DARREG          BASE TO ADDRESS C.B. COMPLEX     22800018
         L     UCBREG,DARUCBAD .       GET UCB ADDR OF SYS1.DUMP DEVICE 22900018
         BAL   XRET2,IOBFIX .          REFRESH IOB FIELDS               23000018
* LAST 5 WORDS IN SVRB TO BE USED AS I/O APP. VECTOR TABLE              23020018
         LA    WORK,C124(SVRBREG) .    GET APP. TAB. ADDR.              23040018
         ST    WORK,RBEXSAVE .         TEMP STORAGE                     23060018
         MVC   DARIOAPT(L3),RBEXSAVE+K1 TO MOVE INTO CONT. BLK.         23080018
         LA    WORK,CVTBRET            GET ADDR OF BR14 INSTR IN CVT    23100018
         ST    WORK,C124(SVRBREG) .    DUMMY END OF EXTENT APP.         23120018
         ST    WORK,C128(SVRBREG) .    DUMMY SIO APPENDAGE              23140018
         MVC   C136(LEN8,SVRBREG),C124(SVRBREG)                         23160018
*                                      DUMMY CE AND ABNORMAL END APP.   23180018
         AIF   (('&SYS' EQ 'MVT') OR ('&SYS' EQ 'MFT')).DO1             23182018
         AGO   .SKIP4                                                   23184018
.DO1     ANOP                                                           23186018
         L     WORK,CVTBTERM .         GET ADDR OF ABTERM               23188018
         USING TERMSECT,WORK .         ADDRESS ABTERM LOCATOR FIELDS    23190018
         L     WORK,PCI1 .             GET ADDR OF PCI APPENDAGE RTN    23192018
         DROP  WORK                                                     23194018
         AGO   .SKIP5                                                   23196018
.SKIP4   ANOP                                                           23198018
         LA    WORK,PCIAPP .           GET REAL PCI APP. ADDR           23200018
.SKIP5   ANOP                                                           23210018
         ST    WORK,C132(SVRBREG) .    STORE IN APP. TAB.               23220018
*                                      INITIALIZATION COMPLETE          23240018
         ST    TCBREG,DARTCBSV .       SAVE THE TCB ADDRESS             23260018
         TM    DEVTYPE(UCBREG),DEVMSKT IS DEVICE TYPE TAPE              23400018
         BO    DOTAPE .                 IF TAPE, BRANCH                 23600018
* DEVICE IS DIRECT ACCESS - INITIALIZE CONTROL BLOCKS                   23800018
         EJECT                                                          24000018
* INITIALIZE 1ST SET OF CCW'S FOR READ                                  24200018
         MVI   DARCCW3,READ .           SET OP CODE TO READ             24400018
         MVC   CCW3FLG(L4),CON1 .       SET FLAGS FOR READ              24600018
         MVI   DARCCW4,NOP .            SET OP CODE FOR NOP             24800018
         MVI   CCW4FLG,CON2 .           ADJUST FLAGS                    25000018
         MVI   CCW4CNT,READ .          SET COUNT TO POS NO.             25200018
         BAL   XRET,DOEXCP .            GO READ DATA                    25400018
         TM    CSWSTAT1,UNITPXP .       DID UNIT EXCEPTION RESULT FROM  25600018
*                                      READ. (IF DATA SET IS AVAILABLE, 25800018
*                                      THE FIRST RECORD WILL BE AN EOF  26000018
*                                      CAUSING A UNIT EXCEPTION).       26200018
         MVI   NUMBER,FOX2 .           SET MSG NUMBER                   26300018
         MVI   CODENO,FOX1 .           SET MSG ID                       26400018
         BZ    DUMP .                  NO, DATA SET FULL                26600018
 EJECT                                                                  26800018
* INIT CCW TO REWRITE 1ST FORMAT RECORD                                 27000018
* SEARCH & TIC REMAIN THE SAME FOR THIS WRITE                           27200018
         MVC   DARVOID1(L5),SEARCHAD .  GET CCHHR FOR COUNT FIELD       27400018
         MVI   RECDNO,XZERO .           SEARCH RECORD = R0              27600018
         MVI   KEY,XZERO .              ZERO KEY                        27800018
         MVC   DATALNGH(L2),DARRSIZE .  DATA LENGTH = TRACK SIZE        28000018
         LA    WORK,DARVOID1 .         GET WORK AREA ADDR               28200018
         ST    WORK,DARCCW3 .           CCW POINTS TO WORK AREA         28400018
         MVI   DARCCW3,WCKD .           OP CODE FOR WRITE CT,KEY,DATA   28600018
         LH    WORK,DARRSIZE .          GET RECORD SIZE                 28800018
         LA    WORK,COUNT(WORK) .       ADD 8 - COUNT FIELD SIZE        29000018
         STH   WORK,CCW3CNT .           SET COUNT                       29200018
         MVI   CCW3FLG,DATACHN .        SET FLAGS                       29400018
* NOP CCW OK FROM LAST EXCP                                             29600018
         BAL   XRET,DOEXCP              WRITE COUNT,KEY,DATA            29800018
         TM    CSWSTAT1,UNITCK .        SEE IF UNIT CHECK OCCURED       30000018
         MVI   CODENO,FOX2 .           SET MSG ID                       30200018
         BO    DUMP .                   GO IF UNIT CHECK                30400018
         TM    CSWSTAT2,MISCMSK .       SEE IF CHANNEL OR ANOTHER ERROR 30600018
         BM    DUMP .                  IF SO, GO PRINT MSG.             30800018
         LA    WORK,CEAPP .            GET CHAN. END APP. ADDR.         30900018
         ST    WORK,C136(SVRBREG) .    ADJUST APP. VECTOR TAB. TO       31100018
*                                      POINT TO PROPER CE APP ROUTINE   31200018
         AIF   (('&SYS' EQ 'PCP') OR ('&SYS' EQ 'MFT')).SKIP10          31240018
         ST    WORK,C140(SVRBREG) .    SET ADDR OF ABNORMAL END APP.    31280018
C140     EQU   140                                                      31320018
.SKIP10  ANOP                                                           31360018
         BAL   XRET,FIXAREA .           GO SET UP TO WRITE CORE         31400018
         OI    ESAFLG(SVRBREG),PCIFLAG .SET INDICATOR FOR PCI           31600018
* INITIALIZE FIRST SET OF CHAN PGMS TO  WRITE DATA                      31800018
         MVI   RECDNO,R1 .              SET SEARCH ARGUMENT (R1)        32000018
         XC    DARCCW3,DARCCW3 .        SET DATA ADDR TO LOC 0          32200018
         MVI   DARCCW3,WRITECOD .       SET OP CODE FOR WRITE DATA      32400018
         MVI   CCW3FLG,MASK1 .          SET FLAGS - CC,PCI, SLI         32600018
         MVI   CCW7FLG,MASK1 .          REFRESH FLAGS                   32800018
         MVC   CCW3CNT(L2),DARRSIZE .   SET COUNT                       33000018
         MVC   CCW7CNT(L2),DARRSIZE .   SET COUNT IN CASE LAST PASS HAD 33200018
*                                           A SHORT RECORD              33400018
         LA    WORK,DARCCW5 .          SET TIC                          33600018
         ST    WORK,DARCCW4 .               CCW                         33800018
         MVI   DARCCW4,TIC .           SET OP CODE FOR TIC              34000018
         MVI   CCW4FLG,DATACHN .        SET CCW FLAGS                   34200018
         AIF   ('&SYS' EQ 'PCP').SKIPER                           M3240 34210019
         TM    TCBDAR,EDAR .            Q.SURPRESS ERPS           M3240 34220019
         BO    NODERP .                 YES-BRANCH                M3240 34230019
.SKIPER  ANOP                                                     M3240 34240019
         MVI   DARERCTL,XZERO .        ALLOW USE OF SYS ERROR RTNS      34400018
NODERP   EQU   * .                                                M3240 34410019
         BAL   XRET,DOEXCP .            WRITE DATA                      34600018
         MVI   DARERCTL,SYSERTNS .     PROHIBIT USE OF SYS ERROR RTNS   34800018
         MVC   SEARCHAD(L4),DARCYLST .  REFRESH START ADDR OF DATA SET  35000018
         MVC   SEEKAD(L4),DARCYLST .    REFRESH IOB SEEK ADDRESS        35200018
         MVI   DARCCW1,SRCHIDEQ .      REFRESH SEARCH CCW (NO M-T)      35400018
         CLI   DARECB,SUCCESS .         SEE IF I/O WAS GOOD             35600018
         MVI   NUMBER,FOX3 .           SET MSG CODE NO                  35800018
         MVI   CODENO,FOX1 .           SET MSG ID                       36000018
         BE    GOODDUMP .               DUMP WAS WRITTEN CORRECTLY      36200018
DUMPENT1 EQU   *                                                        36400018
         MVI   NUMBER,FOX2 .           RESET MESSAGE NO                 36600018
         EJECT                                                          36800018
DUMPFAIL EQU   *                                                        37000018
         MVI   CODENO,FOX3 .           SET MSG ID                       37200018
DUMP     EQU   *                                                        37400018
         MVC   STATUSG(COUNT),STATUSB . SET MESSAGE TEXT                37600018
GOODDUMP EQU   *                                                        37800018
         L     TCBREG,DARTCBSV .       RESTORE TCB ADDR                 37880018
DUMPENT2 EQU   *                                                        37920018
         MVC   C88(MSGLEN1,SVRBREG),MSGCON MOVE IN MSG                  37960018
C88      EQU   88                                                       38000018
         MVC   C100(LEN17,SVRBREG),C99(SVRBREG)    BLANK OUT            38060018
*                                      JOBNAME/STEPNAME IN MESSAGE      38120018
C109     EQU   109                                                      38140018
C100     EQU   100                                                      38160018
C99      EQU   99                                                       38180018
         AIF   ('&SYS' EQ 'MVT').SKTIOT                           M3355 38190019
         TM    TCBCMP,TCBIND .          Q. TCBTIOT VALID          M3355 38191019
         BO    NONAME .                 NO-BRANCH                 M3355 38192019
TCBIND   EQU   X'02' .                  INDICATIVE DUMP BIT       M3355 38193019
.SKTIOT  ANOP                                                     M3355 38194019
         L     WORK,TCBTIO             GET TIOT ADDR                    38200018
         LTR   WORK,WORK .             IS THERE A TIOT FOR THIS TASK    38400018
         BZ    NONAME                  NO, BRANCH TO FIX MSG            38600018
         MVC   C100(LNAMES,SVRBREG),ZERO(WORK) PUT IN JOBNAME/STEP-     38800018
         MVC   C109(LNAMES,SVRBREG),LEN8(WORK)  NAME INTO MSG           39000018
NONAME   EQU   *                                                        39200018
         LA    PARMREG,C88(SVRBREG) .  SET PTR TO MSG FOR WTO           39400018
         AIF   ('&SYS' EQ 'MVT').SKIPP                                  39420018
         TM    TCBFLGS,STEAL           HAS CORE BEEN STOLEN TO PROCESS  39440018
*                                      ABEND                            39460018
STEAL    EQU   X'02'                                                    39480018
         BCR   1,RETREG                YES, SKIP WTO                    39500018
.SKIPP   ANOP                                                           39520018
         SVC   WTO .                   WRITE MESSAGE TO CONSOLE         39600018
BR14     BR    RETREG .                RETURN                           39800018
MSGCON   DC    AL2(MSGLEN)             OVERALL LENGTH OF MESSAGE        40000018
         DC    X'8000'                                                  40200018
MSGCODE  DC    C'IEA021I '             MSG CODE NUMBER                  40400018
STATUSB  DC    C'FAILED   ' FAILURE PORTION OF MSG                      40500018
STATUSA  DC    C'BYPASSED'             DUMP SUBROUTINE BYPASS           40600018
         DC    C' CORE IMAGE '         MSG CONSTANT                     40700018
STATUSG  DC    C'COMPLETE '            SUCCESS PART OF MSG              40800018
         DC    C'-'                                                     40900018
CODENO   DC    C'1'                                                     41000018
MSGEND   EQU   *                                                        41100018
         DC    X'10008000' .           MCS - ROUTING CODE, DESCRIPTOR   41120018
*                                      CODE                             41140018
MSGEND1  EQU   *                                                        41160018
MSGLEN1  EQU   MSGEND1-MSGCON                                           41180018
ONE      EQU   1                                                        41200018
C92      EQU   92                                                       41300018
C104     EQU   104                                                      41400018
C103     EQU   103                                                      41500018
LEN17    EQU   17                                                       41600018
LNAMES   EQU   8 .                     LENGTH OF JOB AND STEP NAMES     41700018
MSGLEN   EQU   MSGEND-MSGCON           MESSAGE LENGTH                   42400018
NUMBER   EQU   MSGCODE+5                                                42600018
         EJECT                                                          42800018
DOTAPE   DS    0H                                                       43000018
         LA    WORK,DARCCW3 .          GET TAPE CCW ADDR                43200018
         ST    WORK,DARCCWAD .          STORE IN IOB                    43400018
         MVC   DARRSIZE(L2),CCW3CNT .  INIT RECORD SIZE FIELD           43600018
         BAL   XRET,FIXAREA .           SET UP COUNTERS                 43800018
         AIF   ('&SYS' EQ 'PCP').SKIPER2                          M3240 43810019
         TM    TCBDAR,EDAR .            Q.SURPRESS ERPS           M3240 43820019
         BO    NOTERP .                 YES-BRANCH                M3240 43830019
.SKIPER2 ANOP                                                     M3240 43840019
         MVI   DARERCTL,XZERO .        ALLOW USE OF SYS ERR RTNS  M3240 43850019
NOTERP   EQU   * .                                                M3240 43860019
         BAL   XRET,TAPEEXCP .          WRITE CORE                      44000018
         CLI   DARECB,SUCCESS .         SEE IF I/O WAS SUCCESSFUL       44200018
         BNE   RUN .                     SET UP FAIL MSG          M3240 44400019
         CLC   ESANDX(L4,SVRBREG),ESAHICNT(SVRBREG) SEE IF ALL WRITTEN  44600018
         BE    DUMPRAN .                  DONE, GO CLEAN UP       M3240 44800019
         AIF   (('&SYS' EQ 'MVT') OR ('&SYS' EQ 'MFT')).DO2             44810018
         AGO   .SKIP6                                                   44820018
.DO2     ANOP                                                           44830018
         L     BASE2,CVTBTERM .        GET ADDR OF ABTERM               44840018
         USING TERMSECT,BASE2 .        ADDRESS ABTERM LOCATOR FIELDS    44850018
         L     WORK,PCI2 .             SET BRANCH REG TO UPDATE RTN     44860018
         L     BASE2,PCI1 .            SET BASE REG FOR UPDATE RTN      44870018
         DROP  BASE2                                                    44880018
         LA    BASE2,L2(BASE2) .       BUMP PAST 1ST BALR INSTR         44890018
         BALR  LNKREG,WORK .           LINK TO UPDATE RTN               44900018
         AGO   .SKIP7                                                   44910018
.SKIP6   ANOP                                                           44920018
         LA    BASE2,PCIAPP2 .          SET UP SUBROUTINE BASE REG      45000018
         BAL   LNKREG,UPDATE .         USE SUB RTN TO UPDATE CTR        45200018
.SKIP7   ANOP                                                           45300018
         B     TAPEEXCP .              DO NEXT WRITE - RET REG STILL OK 45400018
RUN      EQU   *                                                        45600018
         MVC   CCW3CNT(L2),DARRSIZE .  REFRESH COUNT                    45800018
         XC    CCW3ADR(L3),CCW3ADR .    REFRESH WRITE ADDR TO ZERO      46000018
         LA    WORK,TAPECCW .          SET IOB TO REWIND/UNLOAD CCW     46200018
         ST    WORK,DARCCWAD .          SET IOB CCW PTR                 46400018
         MVI   TAPECCW,WTM .           SET OP CODE FOR WRITE TAPE MARK  46600018
         MVI   DARTMODE,WTM .          SET MODE CODE IN CONT BLOCK      46800018
         BAL   XRET,TAPEEXCP .         WRITE TAPE MARK                  47000018
         MVI   TAPECCW,RUNMASK .       SET FOR REWIND/UNLOAD            47200018
         MVI   DARTMODE,RUNMASK .      SET MODE BITS FOR RUN            47400018
         BAL   XRET,TAPEEXCP .         DO REWIND/UNLOAD                 47600018
         AIF   ('&SYS' EQ 'PCP').SKIPER3                          M3240 47601019
         MVI   DARERCTL,SYSERTNS .      REFRESH ERR FLAGS         M3240 47610019
.SKIPER3 ANOP                                                     M3240 47620019
         MVI   DARTMODE,TAPEMASK .     RESET MODE BITS FOR WRITE        47800018
         CLI   NUMBER,FOX3 .            Q. GOOD DUMP              M3240 47810019
         BE    GOODDUMP .               YES-WRITE SUCCESS MESSAGE M3240 47820019
         B     DUMPENT1 .               DUMP FAILED               M3240 47830019
DUMPRAN  MVI   NUMBER,FOX3 .           SET SUCCESS MSG            M3240 48000019
         MVI   CODENO,FOX1 .           SET MSG ID                       48200018
         B     RUN .                    GO CLEAN UP               M3240 48400019
CON1     DC    X'70000005' .           CCW CONSTANT               M3355 48410019
         DS    0D                                                       48600018
TAPECCW  EQU   *                                                        48800018
         DC    X'0F' .                 REWIND/UNLOAD COMMAND            49000018
         DC    AL3(0) .                DUMMY DATA ADDR                  49200018
         DC    X'2000'                 SUPPRESS INCORRECT LENGTH        49400018
         DC    H'0'                                                     49600018
         TITLE 'IGC0801C - COMMON SUBROUTINES'                          49800018
DOEXCP   EQU   *                                                        50000018
         LA    WORK,DARCCW1 .          GET CHAN PGM ADDR                50200018
         ST    WORK,DARCCWAD .         STORE IN IOB                     50400018
         MVI   DARIOBF1,IOFLAG .        HOUSEKEEP IO FLAGS              50600018
TAPEEXCP EQU   *                                                        50800018
         LA    PARMREG,DARIOB .         GET IOB ADDR FOR EXCP           51000018
         MVI   DARECB,XZERO .           CLEAR ECB                       51200018
         SVC   ZERO .                   ISSUE EXCP                      51400018
         LA    PARMREG,DARECB .        GET ECB ADDR                     51800018
         LA    ZERO,K1(ZERO) .         SET COUNT TO ONE                 52000018
         SVC   WAIT .                  WAIT FOR I/O TO CPT.             52200018
         SSM   DISABLE .               PREVENT INTERRUPTS               52400018
         BR    XRET .                   RETURN TO CALLER                52600018
FIXAREA  EQU   *                                                        52800018
         XC    ESANDX(L9,SVRBREG),ESANDX(SVRBREG) . CLEAR WORK AREA     53000018
         MVC   ESAADR(L2,SVRBREG),DARRSIZE . SET UP FOR SECOND WRITE    53200018
         MVC   ESAHICNT(L4,SVRBREG),CVTMZ00 . SAVE HI ADDR IN MACHINE   53400018
         AIF   ('&SYS' NE 'MVT').SKIP1                                  53410018
         CLI   CVTDCB,M65MP .          IS THIS MP65                     53420018
         BCR   NOTEQ,XRET .            NOT MP, RETURN                   53430018
         OI    ESAHICNT+L2(SVRBREG),FOXS IF THIS IS MP65, THE HI        53440018
*                                      ADDR IN THE CVT WILL BE LESS THE 53450018
*                                      SECOND PREFIX AREA. THIS OR WILL 53460018
*                                      CONVERT THE ADDR TO A THE REAL   53470018
*                                      HI MACH ADDR.                    53480018
M65MP    EQU   X'14' .                 M65MP MODE MASK                  53490018
FOXS     EQU   X'FF'                                                    53495018
NOTEQ    EQU   7                                                        53500018
.SKIP1   ANOP                                                           53510018
         BR    XRET .                   RETURN TO CALLER                53600018
         EJECT                                                          53800018
*                             CONSTANTS                                 54000018
DISABLE  EQU   CON1+1                                                   56800018
 TITLE 'IGC0801C - CHAN. END / ABNORMAL END APPENDAGE ROUTINE'          57100018
         DROP BASEREG                                                   57400018
CEAPP    DS    0H                                                       57600018
CECVT    EQU   11                                                       57800018
CESVRB   EQU   12                                                       58000018
CEBASE   EQU   13                                                       58200018
CEDAR    EQU   DARREG                                                   58400018
         BALR  CEBASE,ZERO .            SET UP ADDRESSABILITY           58600018
         USING *,CEBASE .              FOR SUBROUTINE                   58800018
         L     CECVT,CVTPTR .           GET CVT ADDR                    59000018
         L     CEDAR,DARPTR(CECVT) .   GET CONTROL BLOCK ADDR           59200018
         L     CESVRB,DARTCBSV .       GET THE ACTIVE TCB ADDR          59400018
         L     CESVRB,ZERO(CESVRB) .    GET SVRB ADDRESS                59600018
         AIF   (('&SYS' EQ 'PCP') OR ('&SYS' EQ 'MFT')).SKIP11          59610018
         TM    DARCSW+L3,UNITCK .      HAS UNIT CHECK OCCURRED          59620018
         BZ    TSTCORE .               NO, TREAT AS CHAN. END           59630018
         TM    DARIOBS2,ENDCYL .       HAS END OF CYLINDER BEEN REACHED 59640018
         BCR   NOENDCYL,RETREG .       NOT END OF CYL - NO RESTART      59650018
NOENDCYL EQU   8                                                        59660018
         NI    DARIOBF1,NOEXCP .       TURN OFF EXCEPTION FLAG          59670018
NOEXCP   EQU   X'FB'                                                    59680018
         L     CECVT,DARUCBAD .        ADDRESS UCB FOR SYS1.DUMP        59690018
         MVC   UCBCCHH(L4,CECVT),DARVOID1 UPDATE UCB CCHH FOR RESTART   59700018
UCBCCHH  EQU   51                                                       59710018
         B     IOBCCHH .               UPDATE IOB CCHH FOR RESTART.     59720018
.SKIP11  ANOP                                                           59730018
TSTCORE  EQU   *                                                        59740018
         CLC   ESANDX(L4,CESVRB),ESAHICNT(CESVRB) SEE IF ALL WRITTEN    59800018
         BCR   COUNT,RETREG .           YES, RETURN TO IOS              60000018
IOBCCHH  EQU   *                                                        60200018
         ST    WORK,DARSPARE .         SAVE IOS INFO                    60400018
         LA    WORK,DARCCW5 .          GET ADDR OF CHAN PGM NO 2        60600018
         TM    ESAFLG(CESVRB),PCIFLAG . SEE IF FIRST CP IS IN USE       60800018
         BZ    STORECCW .              NO, SET CCW TO POINT TO CCW1     61000018
         LA    WORK,DARCCW1 .          GET ADDR OF CHAN PGM NO 1        61200018
STORECCW EQU   *                                                        61400018
         ST    WORK,DARCCWAD .         SET IOB TO APPROPRIATE CP        61600018
         NI    ZERO(WORK),SUCCESS .    PREVENT MULTI TRK SEARCH         61660018
         L     WORK,DARSPARE .         RESTORE IOS INFO                 61720018
         TM    DARIOBS2,ENDCYL .       END OF CYLINDER                  61820018
         BZ    GOON .                  SKIP IOB CCHH UPDATE             62000018
         MVC   SEEKAD(L4),DARVOID1 .    UPDATE IOB CCHH PTR FOR RESTART 62200018
*                                      SYSTEM TO DO SEEK TO NEXT CYL    62400018
GOON     EQU   *                                                        62440018
         LR    CECVT,XRET2 .           SAVE IOS INFO                    62480018
         BAL   XRET2,IOBFIX .          REFRESH IOB FIELDS               62520018
         LR    XRET2,CECVT .           RESTORE IOS INFO                 62560018
         B     COUNT(RETREG) .          RETURN FOR RESTART              62600018
IOBFIX   EQU   *                                                        62800018
         MVI   DARIOBF1,MASK2 .        RESET FLAGS                      63000018
         XC    DARIOBF2(L3),DARIOBF2 . CLEAR FLAGS2 AND SENSE FLAGS     63100018
         XC    DARIOBF3(COUNT),DARIOBF3  CLEAR FLAG3 AND CSW FIELDS     63200018
         XC    ERRCT(L2),ERRCT .       ZERO ERROR COUNT FIELD           63400018
         BR    XRET2 .                 RETURN                           63600018
         DROP  CEBASE                                                   63800018
         AIF   (('&SYS' EQ 'MVT') OR ('&SYS' EQ 'MFT')).SKIP8           63900018
         TITLE 'IGC0801C - PROGRAM CONTROLLED INTERRUPT ROUTINE'        64000018
PCIAPP   EQU   *                                                        64200018
APPBASE  EQU   13                                                       64400018
WORK2    EQU   12                                                       64600018
         BALR  APPBASE,ZERO .          ESTABLISH ADDRESSABITY           64800018
         USING *,APPBASE .             SET BASE REG                     65000018
PCIAPP2  EQU   *                                                        65200018
         L     DARREG,CVTPTR .         GET CVT ADDR                     65400018
         L     DARREG,DARPTR(DARREG) . GET CONTROL BLOCK PTR            65800018
         L     SVRBREG,DARTCBSV .      GET THE ACTIVE TCB ADDR          66000018
         L     SVRBREG,ZERO(SVRBREG) .  GET THIS RTNS SVRB ADDR         66200018
TEST1    EQU   *                                                        66400018
         MVC   SEEKAD(L4),DARVOID1 .    UPDATE SEEK ADDR IN IOB         66600018
         OI    DARCCW1,MTBIT .         MAKE SEARCH FOR MULTI-TRACK      66800018
         IC    WORK2,HEADNUM .          GET HEAD NUMBER                 67000018
         LA    WORK2,K1(WORK2) .        ADD ONE TO GET NEXT HEAD        67200018
         STC   WORK2,HEADNUM .          RESTORE                         67400018
         CLC   TRKCNT(L2),DARNOTRK .    SEE IF LAST TRK ON CYL          67600018
         BNE   SETIOB .                NOT LAST TRK                     67800018
SETCYL   EQU   *                                                        68000018
         MVI   HEADNUM,XZERO .          SET HEAD TO ZERO                68200018
         LH    WORK2,DARVOID1 .        GET CYL NO.                      68400018
         LA    WORK2,K1(WORK2) .        UPDATE TO NEXT CYLINDER         68600018
         STH   WORK2,DARVOID1 .        RESTORE                          68800018
SETIOB   EQU   *                                                        69000018
         MVC   SEARCHAD(L4),DARVOID1 .  SET SEARCH ADDR (CCHH)          69200018
         TM    ESAFLG(SVRBREG),PCIFLAG .SEE IF 1ST SET OF CCW'S IN USE  69400018
         BZ    SETUP2 .                NO, BRANCH                       69600018
         LA    DARREG,K32(DARREG) .     BUMP DARREG TO ACCESS 2ND SET   69800018
*                                      OF CCW'S                         70000018
SETUP2   EQU   *                                                        70200018
         XI    ESAFLG(SVRBREG),PCIFLAG .HOUSEKEEP CCW USE FLAG          70400018
 EJECT                                                                  70600018
*                                                                       70800018
* SUBROUTINE TO UPDATE WRITE COUNTER AND WRITE CCW                      71000018
*                                                                       71200018
 SPACE 3                                                                71400018
         LA    LNKREG,ESCAPE .         SET RETURN REG                   71600018
UPDATE   EQU   *                                                        71800018
         L     WORK2,ESANDX(SVRBREG) .  GET ADDR OF THIS WRITE          72000018
         AH    WORK2,CCW3CNT .          ADD RECORD SIZE                 72200018
         C     WORK2,ESAHICNT(SVRBREG) .SEE IF ADDR IS VALID            72400018
         BNH   OK                      YES, OK, BRANCH                  72600018
         L     WORK2,ESAHICNT(SVRBREG) .GET HI MACH ADDR                72800018
         S     WORK2,ESANDX(SVRBREG) .  SUBTRACT LAST ADDR WRITTEN      73000018
*                                      RESULT IS REMAINING BYTES TO     73200018
*                                      WRITE                            73400018
         STH   WORK2,CCW3CNT .         SET COUNT FOR SHORT RECORD       73600018
         MVC   CCW3ADR(L3),ESACNT(SVRBREG) SET WRITE ADDR               73800018
         MVC   ESANDX(L4,SVRBREG),ESAHICNT(SVRBREG) COUNT'S EQUAL       74000018
         NI    CCW3FLG,NOPCICC .        NO COMMAND CHAINING OR PCI      74200018
         BR    LNKREG .                RETURN                           74400018
OK       EQU   *                                                        74600018
         MVC   CCW3ADR(L3),ESACNT(SVRBREG) SET ADDR FOR WRITE           74800018
         ST    WORK2,ESANDX(SVRBREG) . SAVE ADDR OF WRITE FOR NEXT      75000018
*                                           PASS THROUGH                75200018
         BR    LNKREG .                RETURN                           75400018
ESCAPE   EQU   *                                                        75600018
         SR    SVRBREG,SVRBREG .        CLEAR FOR IOS                   75800018
         BR    RETREG .                RETURN TO IOS                    75900018
.SKIP8   ANOP                                                           76000018
         TITLE 'IGC0801C - DSECT''S, EQUATES, ETC.'                     76200018
         AIF   ('&SYS' NE 'MVT').SKIP9                                  76210018
TERMSECT DSECT                                                          76220018
* MAPS THE LOCATOR FIELDS IN ABTERM - MVT                               76230018
         DS    D .                     ABTERM INSTRS                    76240018
PCI1     DS    AL4 .                   DAR PCI APPENDAGE ADDR           76250018
PCI2     DS    AL4 .                   DAR TAPE CTR UPDATE PTR          76260018
.SKIP9   ANOP                                                           76270018
         AIF   ('&SYS' NE 'MFT').SKIP2                                  76280018
TERMSECT DSECT                                                          76290018
* MAPS THE LOCATOR FIELDS IN ABTERM - MFT                               76300018
         DS    D .                     ABTERM INSTRS                    76310018
         DS    AL4 .                   IEEMSIRB                         76320018
         DS    AL4 .                   IEA0EQ01                         76330018
         DS    AL4 .                   LEQC                             76340018
         DS    AL4 .                   TRSTOPER                         76350018
PCI1     DS    AL4 .                   DAR - PCI APP RTN                76360018
PCI2     DS    AL4 .                   DAR - TAPE UPDATE RTN            76370018
.SKIP2   ANOP                                                           76380018
 DARMAC                                                                 76400018
         MEND                                                           76600018
