         MACRO                                                          00020000
        IEAAPL &PA                                                      00040000
         LCLB  &ONETASK                                                 00060000
&ONETASK SETB  (T'&PA EQ 'O')                                           00080000
         AIF   (&ONETASK EQ 0).SKIPD                                    00100000
         TITLE 'ROUTINE NAME - PROLOG.  MODULE NAME - IEAAPL00.'        00120000
*GENERATION- DEC65,CHANGE LEVEL 000                                     00140000
*    ROUTINE NAME - PROLOG.  MODULE NAME - IEAAPL00.                    00160000
         AGO   .SKIPE                                                   00180000
.SKIPD   ANOP                                                           00200000
         TITLE 'ROUTINE NAME - PROLOG.  MODULE NAME - IEAGPL00.'        00220000
*GENERATION- DEC65,CHANGE LEVEL 000                                     00240000
*    ROUTINE NAME - PROLOG.  MODULE NAME - IEAGPL00.                    00260000
.SKIPE   ANOP                                                           00280000
*                                                                       00300000
*                                                                       00320000
*    FUNCTION - PROLOG DETERMINES THE TASK WITH WHICH THIS PROGRAM      00340000
*    INTERRUPT IS ASSOCIATED. IT THEN SETS UP THE ABTERM LINKAGE AND    00360000
*    BRANCHES TO THE ABTERM MODULE.                                     00380000
*                                                                       00400000
*                                                                       00420000
*    ENTRY - THE PROLOG ENTRY POINT NAME IS IEA0PL00. PROLOG MAY BE     00440000
*    ENTERED USING A BRANCH INSTRUCTION. PROLOG MUST BE ENTERED IN      00460000
*    SUPERVISOR STATE, WITH SUPERVISOR PROTECTION KEY, AND WITH INPUT/  00480000
*    OUTPUT AND EXTERNAL INTERRUPTS DISABLED.                           00500000
*                                                                       00520000
*                                                                       00540000
*    INPUT - THE PROGRAM INTERRUPT OPSW MUST NOT HAVE BEEN MODIFIED.    00560000
*    REGISTERS 10 THROUGH 1 AT THE TIME OF PROGRAM INTERRUPT MUST BE    00580000
*    SAVED IN THE PROGRAM INTERRUPT FLIH SAVE AREA (PDSAV).             00600000
*                                                                       00620000
*                                                                       00640000
*    OUTPUT -                                                           00660000
*    REGISTER 0 CONTAINS THE ADDRESS OF THE TASK TO BE ABNORMALLY       00680000
*               TERMINATED.                                             00700000
*    REGISTER 1 CONTAINS THE COMPLETION CODE.                           00720000
*    REGISTER 14 CONTAINS THE ADDRESS OF THE LOCATION TO WHICH ABTERM   00740000
*                WILL RETURN CONTROL.                                   00760000
*    IN THE CASE OF A PROGRAM INTERRUPT FROM A PROGRAM HAVING A         00780000
*    SCHEDULED REQUEST BLOCK,                                           00800000
*    . THE PIOPSW IS SAVED IN THE RESUME PSW SLOT IN THE REQUEST BLOCK. 00820000
*    . REGISTERS 10 THROUGH 1 AT THE TIME OF PROGRAM INTERRUPT ARE      00840000
*      SAVED IN THE TCB REGISTER SAVE AREA.                             00860000
*                                                                       00880000
*                                                                       00900000
*                                                                       00920000
*                                                                       00940000
*    EXTERNAL REFERENCES -                                              00960000
*    . DISMISS - AN ENTRY POINT IN THE I/O FLIH.                        00980000
*    . IEA0DS - AN ENTRY POINT IN THE DISPATCHER                        01000000
*    . IEA0AB00 - THE ENTRY POINT IN ABTERM.                            01020000
         AIF   (&ONETASK EQ 1).SKIPF                                    01040000
*    . IEATCBLK - A TABLE WHICH CONTAINS THE ADDRESSES OF THE TCB'S.    01060000
.SKIPF   ANOP                                                           01080000
*    . IORGSW - ADDRESS OF THE I/O FLIH SWITCH.                         01100000
*    . IEATCBP - ADDR. OF CURRENTLY DISPATCHED TASK IS AT IEATCBP+4     01120000
*    . PISAV-ADDRESS OF THE PROGRAM INTERRUPT FLIH SAVE AREA            01140000
*    . IEA0XE00 - AN ENTRY POINT IN THE SVC INTERRUPT HANDLER.          01160000
*    . SVF - ADDRESS OF THE SVC TYPE I SWITCH.                          01180000
*                                                                       01200000
*                                                                       01220000
*    ERROR MESSAGES - NONE.                                             01240000
*                                                                       01260000
*                                                                       01280000
*    NOTES - PROLOG NEED NOT RESIDE IN THE FIRST 4096 BYTES OF MAIN     01300000
*    STORAGE.                                                           01320000
*                                                                       01340000
*                                                                       01360000
*    OPERATION -                                                        01380000
*    IF THE PROGRAM INTERRUPT OCCURED WITH THE I/O FLIH, PROLOG         01400000
*    PERFORMS THE FOLLOWING FUNCTIONS -                                 01420000
*    . LOADS REGISTER 0 WITH THE ADDRESS OF THE TASK             A29774 01440019
*       TO BE TERMINATED.                                        A29774 01450019
*      (THIS IS THE TASK WITH WHICH THE I/O IS ASSOCIATED).             01460000
*    . LOADS REGISTER 1 WITH A COMPLETION CODE TO INDICATE THAT THE     01480000
*      PROGRAM INTERRUPT OCCURED IN THE I/O FLIH.                       01500000
*    . LOADS REGISTER 14 WITH THE ADDRESS OF AN ENTRY POINT IN THE I/O  01520000
*    . FLITH.                                                           01540000
*    . BRANCHES TO ABTERM.                                              01560000
*    IF THE PROGRAM INTERRUPT OCCURED IN A TYPE 1 SVC ROUTINE, PROLOG   01580000
*    PERFORMS THE FOLLOWING FUNCTIONS -                                 01600000
*    . LOADS REGISTER 0 WITH THE ADDRESS OF THE TASK WHICH ISSUED THE   01620000
*      SVC.                                                             01640000
*    . LOADS REGISTER 1 WITH A COMPLETION CODE WHICH INDICATES THAT THE 01660000
*      PROGRAM INTERRUPT OCCURED IN A TYPE 1 SVC.                       01680000
*    . LOADS REGISTER 14 WITH THE ADDRESS OF AN ENTRY POINT IN THE SVC  01700000
*      INTERRUPT HANDLER.                                               01720000
*    . BRANCHES TO ABTERM.                                              01740000
*    OTHERWISE PROLOG PERFORMS THE FOLLOWING FUNCTIONS -                01760000
*    . LOADS REGISTER 0 WITH THE ADDRESS OF THE TASK WHICH WAS LAST     01780000
*      DISPATCHED.                                                      01800000
*    . LOADS REGISTER 1 WITH A COMPLETION WHICH INDICATES THE PROGRAM   01820000
*      INTERRUPT TYPE.                                                  01840000
*    . LOADS REGISTER 14 WITH THE ADDRESS OF AN ENTRY POINT IN THE      01860000
*      DISPATCHER.                                                      01880000
*    . SAVES THE PROGRAM INTERRUPT OPSW IN THE RESUME PSW SLOT IN THE   01900000
*      REQUEST BLOCK.                                                   01920000
*    . SAVES REGISTERS 10 THROUGH 1 AT THE TIME OF PROGRAM INTERRUPT    01940000
*      IN THE TASK CONTROL BLOCK.                                       01960000
*    . BRANCHES TO ABTERM.                                              01980000
*                                                                       02000000
*                                                                       02020000
*REMARKS:          CERTAIN UNIQUE SEPARATOR CARDS ARE USED THROUGH OUT  02040000
*              THE ASSEMBLY,AS FOLLOWS:                                 02060000
*              1.  THE FOLLOWING CARD PRECEDES AND SUCCEEDS A           02080000
*              CONDITIONAL ASSEMBLY INSTRUCTION.                        02100000
*CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC 02120000
*              2.  THE FOLLOWING CARD PRECEDES AND SUCCEEDS A           02140000
*              TEMPORARY OR DEBUGGING INSTRUCTION OR SET OF             02160000
*              INSTRUCTIONS.                                            02180000
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT 02200000
*              3.  THE FOLLOWING CARD PRECEDES AND SUCCEEDS A           02220000
*              SEQUENCE OF 'DC-ORG' OPERATIONS REQUIRED TO SIMULATE     02240000
*              INSTRUCTIONS WITH ADDRESSES AS EXTERNAL SYMBOLS WHERE    02260000
*              THESE SYMBOLS ARE KNOWN TO BE WITHIN THE FIRST 4095      02280000
*              BYTES OF THE MACHINE.                                    02300000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 02320000
*                                                                       02340000
*                                                                       02360000
         EXTRN IEA0DS                                                   02400000
         EXTRN IEA0AB00                                                 02420000
         AIF   (&ONETASK EQ 1).SKIPA                                    02440000
         EXTRN IECCPL00 .                                        A24739 02450019
         AGO   .SKIPA1                                           A24739 02460019
.SKIPA   ANOP                                                           02480000
         EXTRN DISMISS .                                         A24739 02486019
.SKIPA1  ANOP                                                    A24739 02492019
         EXTRN IORGSW                                                   02500000
         EXTRN IEATCBP                                                  02520000
         EXTRN PISAV                                                    02540000
         EXTRN IEA0XE00                                                 02560000
         EXTRN SVF                                                      02580000
ADREG    EQU   15                                                       02600000
COMREG   EQU   1                                                        02620000
         AIF   (&ONETASK NE 1).IO5                               A24739 02630019
IOSCODE  EQU   X'0F1'                   IOS PROGRAM CHECK CODE          02640000
.IO5     ANOP                                                    A24739 02650019
PIOPSW   EQU   40                                                       02660000
SVCOPSW  EQU   32 .                                              A24739 02670019
PRBREG   EQU   11                                                       02680000
RETREG   EQU   14                                                       02700000
SVCCODE   EQU   X'0F2'          TYPE 1 SVC PROG. CHECK                  02720000
TCBGRS   EQU   48                                                       02760000
TCBRBP   EQU   0                                                        02780000
TCBREG   EQU   12                                                       02800000
TCBREG0  EQU   0                                                        02820000
WKREG    EQU   13                                                       02840000
XRBPSW   EQU   16                                                       02860000
*                                                                       02880000
*                                                                       02900000
         DS    0D                                                       02920000
         BALR  ADREG,0             ESTABLISH ADDRESSABILITY.            02940000
         USING *,ADREG                                                  02960000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 02980000
*        L     TCBREG,IEATCBP+4        GET TCB ADDRESS FROM OLD.        03000000
*                                                                       03020000
         DC    AL4(IEATCBP+4)                                           03040000
         ORG   *-4                                                      03060000
         BALR  TCBREG,0                                                 03080000
         ORG   *-2                                                      03100000
         DC    X'58'                                                    03120000
         ORG   *+3                                                      03140000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 03160000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 03180000
*        TM    IORGSW+1,X'F0'      IS IO SWITCH ON...                   03200000
*                                                                       03220000
         DC    AL4(IORGSW+1)                                            03240000
         ORG   *-4                                                      03260000
         DC    X'91F0'                                                  03280000
         ORG   *+2                                                      03300000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 03320000
         AIF   (&ONETASK EQ 1).IO2                               A24739 03324019
         BNZ   TOIOS .                  HANDLE IOS PROG CK       A24739 03328019
         AGO   .IO3                                              A24739 03332019
.IO2     ANOP                                                    A24739 03336019
         BC    7,APIO              YES,BRANCH TO APIO.                  03340000
.IO3     ANOP                                                    A24739 03350019
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 03360000
*        TM    SVF+1,X'F0'     NO. IS SVC TYPE I SWITCH ON...           03380000
*                                                                       03400000
         DC    AL4(SVF+1)                                               03420000
         ORG   *-4                                                      03440000
         DC    X'91F0'                                                  03460000
         ORG   *+2                                                      03480000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 03500000
         BC    7,APTI              YES, BRANCH TO APTI.                 03520000
         L     PRBREG,TCBRBP(TCBREG) NO. GET ADDR OF CURRENT RB.        03540000
         MVC   XRBPSW(8,PRBREG),PIOPSW MOVE PIOPSW TO RESUME PSW SLOT   03560000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 03580000
*        MVC   TCBGRS(32,TCBREG),PDSAV SAVE REGISTERS 10-1 IN TCB.      03600000
*                                                                       03620000
         ORG   *+2                                                      03640000
         DC    AL4(PISAV)                                               03660000
         ORG   *-6                                                      03680000
         MVI   TCBGRS(TCBREG),31                                        03700000
         ORG   *-4                                                      03720000
         DC    X'D2'                                                    03740000
         ORG   *+5                                                      03760000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 03780000
         LH    COMREG,PIOPSW+2     COMPL. CODE IS INTERRUPT TYPE.       03800000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 03820000
*        LA    RETREG,IEA0DS           ABTERM WILL RETURN TO DISPATCH.  03840000
*                                                                       03860000
         DC    AL4(IEA0DS)                                              03880000
         ORG   *-4                                                      03900000
         BALR  RETREG,0                                                 03920000
         ORG   *-2                                                      03940000
         DC    X'41'                                                    03960000
         ORG   *+3                                                      03980000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 04000000
APOUT    LR    TCBREG0,TCBREG      FINISH ABTERM LINKAGE.               04020000
         SLL   COMREG,12               POSITION COMPLETION CODE.        04040000
         O     COMREG,APAND            SET DUMP BIT                     04060000
         L     WKREG,ABTCON                                             04080000
         BCR   15,WKREG            BRANCH TO ABTERM.                    04100000
*                                                                       04120000
APTI     EQU   * .                                               A24739 04140019
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 04160000
*        LA    RETREG,IEA0XE00         ABTERM WILL RETURN TO TYPE I XT. 04180000
*                                                                       04200000
         DC    AL4(IEA0XE00)                                            04220000
         ORG   *-4                                                      04240000
         BALR  RETREG,0                                                 04260000
         ORG   *-2                                                      04280000
         DC    X'41'                                                    04300000
         ORG   *+3                                                      04320000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 04340000
         AIF   (&ONETASK EQ 1).IO4                               A24739 04360019
*                                                                       04380000
         CLI   SVCOPSW+3,X'00' .        Q. SVC 0                 A24739 04380819
         BE    TOIOS .                  YES-BRANCH               A24739 04381619
         CLI   SVCOPSW+3,X'0F' .        Q. SVC 15                A24739 04382419
         BE    TOIOS .                  YES-BRANCH               A24739 04383219
.IO4     ANOP                                                    A24739 04384019
         LA    COMREG,SVCCODE .         SET UP COMP CODE         A24739 04384819
         B     APOUT .                  TO EXIT                  A24739 04385619
         AIF   (&ONETASK EQ 1).IO1                               A24739 04386419
TOIOS    EQU   * .                                               A24739 04387219
         L     WKREG,ADICCPL0 .                                   M4075 04389219
         BR    WKREG .                  GO TO IOS PGM CK HNDLR    M4075 04391219
ADICCPL0 DC    A(IECCPL00) .            IOS PGM CK HANDLER       M4075  04393219
         AGO   .SKIPG                                            A24739 04396819
.IO1     ANOP                                                    A24739 04397619
APIO     DS    0H                                                       04400000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 04420000
*       LA     RETREG,DISMISS          RETURN ADDRESS TO DISMISS   7928 04440000
*                                                                       04460000
         DC    AL4(DISMISS)                                        7928 04480000
         ORG   *-4                                                 7928 04500000
         BALR  RETREG,0                                            7928 04520000
         ORG   *-2                                                 7928 04540000
         DC    X'41'                                               7928 04560000
         ORG   *+3                                                 7928 04580000
*XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX 04600000
         LA    COMREG,IOSCODE      GET COMPLETION CODE.                 04820000
         BC    15,APOUT            BRANCH TO APOUT.                     04840000
.SKIPG   ANOP                                                           04890017
ABTCON   DC    A(IEA0AB00)                                              04900000
APAND    DC    X'800C0000'         CONSTANT TO OR DUMP BIT.             04920000
         MEND                                                           05000000
