         MACRO                                                          00040020
         IEAENQ &SYSTEM=,&SHARED=,&TSO=                                 00080020
.*2271  129600,845640,845660,845680,845720,845740,845840,846110,867830, 00140017
.*      867848,867872   11-4-68  CHANGES TO LCS CODE FOR R17 PTM 112    00160017
.*1874 117160,117320,118800,862800-863400,878500-879600,880960,881200  G00164018
                                REFRESHABILITY                          00168018
.*1874 114600,727360,881040,881400-881700     MAINTENANCE               00172018
.*                                                                 I275 00172819
.*    699700-699800,881160                                         I275 00173619
.*  MFT TRANSIENT AREA CONTENTION PROBLEM                   19088  I275 00174419
.*                                                                19772 00175219
.*286440,357620-357648,357852,357858-357860                       19772 00176019
.*OWNERSHIP                                                       19772 00176819
.*                                                                 I250 00177619
.*698100,721620,845580                                            19054 00178419
.*MFT ATTACH                                                19054  I250 00179219
.*CHANGE TO AUTO PURGE                                           A29065 00179619
.*846710,846720                                                  A35042 00180020
         LCLB  &B(3)                             LOCAL SWITCHES   20021 00209620
         AIF   ('&SYSTEM' EQ '').E1                    KEYWORD MISSING  00240016
         AIF   ('&SHARED' EQ '').E2                    KEYWORD MISSING  00300016
&B(1)    SETB  ('&SYSTEM' EQ 'MVT')                                     00360016
         AIF   (NOT &B(1) AND '&SYSTEM' NE 'MFT').E1   KEYWORD INVALID  00420016
&B(2)    SETB  ('&SHARED' EQ 'YES')                                     00480016
         AIF   (NOT &B(2) AND '&SHARED' NE 'NO').E2    KEYWORD INVALID  00540016
&B(3)    SETB  ('&TSO' EQ 'YES')                                  20021 00570020
.*                                                                      00600016
.* SWITCH &B(1) SET TO 0 - SYSTEM IS MFT-II                             00660016
.* SWITCH &B(1) SET TO 1 - SYSTEM IS MVT                                00720016
.*                                                                      00780016
.* SWITCH &B(2) SET TO 0 - SHARED DASD SUPPORT IS NOT INCLUDED          00840016
.* SWITCH &B(2) SET TO 1 - SHARED DASD SUPPORT IS INCLUDED              00900016
.*                                                                      00960016
.* SWITCH &B(3) SET TO 0 - TIME SHARING OPTION NOT INCLUDED       20021 00970020
.* SWITCH &B(3) SET TO 1 - TIME SHARING OPTION INCLUDED.          20021 00980020
.*                                                                      00990020
         AGO   .GEN1                                                    01020016
         MEXIT                                                          01080016
.E1      MNOTE 'SYSTEM KEYWORD MISSING OR INVALID'                      01140016
         MEXIT                                                          01200016
.E2      MNOTE 'SHARED KEYWORD MISSING OR INVALID'                      01260016
.GEN1    ANOP                                                           01320016
         TITLE '         DEQ SERVICE ROUTINE          '                 01380016
IGC048   START                                                          01440016
         SPACE 2                                                        01500016
* ROUTINE NAME                                                          01560016
         AIF   (NOT &B(1) AND NOT &B(2)).C1                             01568017
         AIF   (NOT &B(1)).C2                                           01576017
         AIF   (&B(1) AND NOT &B(2)).C3                                 01584017
*              IEAQENQ3-ENQ AND DEQ SERVICE ROUTINE WITH SDASD          01592017
         AGO   .GEN2                                                    01600017
.C1      ANOP                                                           01608017
*              IEAGENQ1-ENQUEUE AND DEQUEUE SERVICE ROUTINE             01616017
         AGO   .GEN2                                                    01624017
.C2      ANOP                                                           01632017
*              IEAGENQ2-ENQ AND DEQ SERVICE ROUTINE WITH SDASD          01640017
         AGO   .GEN2                                                    01648017
.C3      ANOP                                                           01656017
*              IEAQENQ2-ENQUEUE AND DEQUEUE SERVICE ROUTINE             01664017
.GEN2    ANOP                                                           01672017
         SPACE 2                                                        01680016
* FUNCTIONS                                                             01740016
*              1-ENQUEUE A REQUEST FOR A SERIALLY REUSABLE RESOURCE     01800016
*              2-DEQUEUE A REQUEST FOR A SERIALLY REUSABLE RESOURCE     01860016
*              3-PERFORM SET MUST COMPLETE OR RESET MUST COMPLETE       01880017
*                OPERATIONS INCLUDING SYSTEM OR STEP WIDE               01900017
*                NON-DISPATCHABILITY AS REQUIRED                        01920017
         AIF   (&B(1)).C4                                               01940017
*              4-PERFORM A TASK SWITCH FOR TASKS NO LONGER              01960017
*                WAITING FOR A RESOURCE                                 01980017
         AGO   .GEN3                                                    02000017
.C4      ANOP                                                           02020017
*              4-INVOKE TASK SWITCH ROUTINE FOR TASKS                   02040017
*                NO LONGER WAITING FOR RESOURCE                         02060017
*              5-PERFORM 'AUTO PURGE' FOR ABTERM TASKS                  02080017
*              6-PURGE QUEUES AT END OF TASK OR ABEND AS REQUIRED       02100017
.GEN3    AIF   (NOT &B(2)).GEN4                                         02120017
*               -RESERVE AND RELEASE DEVICES AS REQUESTED BY THE        02140017
*                RESERVE MACRO                                          02160017
.GEN4    ANOP                                                           02180017
         SPACE 2                                                        02340016
* ENTRY POINT NAMES                                                     02400016
*              IGC048-DEQUEUE SERVICE ROUTINE                           02460016
*              IGC056-ENQUEUE SERVICE ROUTINE                           02520016
*              IEA0SMC-MUST COMPLETE ROUTINE                            02540017
         AIF   (NOT &B(1)).GEN5                                         02560017
*              IEA0EQ01-MANUAL PURGE ROUTINE                            02580016
*              IEAQQCB0-TOP OF MAJOR QCB QUEUE                          02600017
*              IEAQENA0-START OF REFRESHABLE CODE                 19772 02606019
*              IEAQENA1-END OF REFRESHABLE CODE                   19772 02612019
         AGO   .GEN6                                                    02620017
.GEN5    ANOP                                                           02640017
*              IEA0EQ01-TOP OF MAJOR QCB QUEUE                          02660017
*              IEA0QCB0-TOP OF MAJOR QCB QUEUE                          02680017
*              ABENTRY - ABEND BRANCH ENTRY                       19054 02685019
*              IEAGENA0-START OF REFRESHABLE CODE                 19772 02690019
*              IEAGENA1-END OF REFRESHABLE CODE                   19772 02695019
         SPACE 2                                                        02700016
.GEN6    ANOP                                                           02730017
* CONTAINED IN MODULE                                                   02760016
*              MODULE NAME SAME AS ROUTINE NAME                         02820017
         SPACE 2                                                        02880016
* ATTRIBUTES                                                            02940016
*              RESIDENT                                                 03000016
*              REENTRANT                                                03060016
*              REFRESHABLE                                        19772 03090019
*              IN SUPERVISOR STATE                                      03120016
*              TYPE 2 SVC                                               03180016
*              DISABLED                                                 03240016
         SPACE 2                                                        03300016
* APPLICABILITY                                                         03360016
         AIF   (&B(1)).GEN7                                             03370017
*              OPTION 2                                                 03380017
         AGO   .GEN8                                                    03390017
.GEN7    ANOP                                                           03400017
*              OPTION 4                                                 03420016
.GEN8    AIF   (NOT &B(2)).GEN9                                         03428017
*                 WITH SDASD                                            03436017
         AGO   .GEN10                                                   03444017
.GEN9    ANOP                                                           03452017
*                 WITHOUT SDASD                                         03460017
.GEN10   ANOP                                                           03468017
         SPACE 2                                                        03480016
* EXTERNAL REFERENCES                                                   03540016
*              IEATCBP     ADDRESS OF 'NEW' TCB                         03600016
*              IEA0DS      DISPATCHER                                   03720016
         AIF   (NOT &B(1)).GEN11                                        03750017
*              IEA0DS02    TASK SWITCH ROUTINE                          03780016
*              IEAMSTCB    MASTER SCHEDULER TCB                         03800017
.GEN11   ANOP                                                           03820017
         EJECT                                                          03840016
* SVC'S USED                                                            03900016
*              SVC 3  EXIT                                              03930017
*              SVC 10 REGISTER FORM OF GETMAIN AND FREEMAIN             03960016
*              SVC 13 ABEND                                             04020016
         SPACE 2                                                        04080016
* INPUT                                                                 04140016
*              PARAMETER LIST IN CALLERS STORAGE AREA                   04200016
*              BEGINNING ON A FULL WORD BOUNDRY                         04260016
*              PARAMETER LIST ENTRY SHOWN BELOW                         04320016
         SPACE 2                                                        04380016
* MACRO EXPANSION EXAMPLES                                              04440016
         SPACE 2                                                        04500016
MACSEC   DSECT                                                          04560016
         USING *,1                                                      04620016
         SPACE 2                                                        04680016
IGC048   CSECT                                                          04740016
         SPACE 2                                                        04800016
         AIF   (&B(1)).GEN12A                                     19772 04808019
IEAGENA0 EQU   *                                                  19772 04816019
         AGO   .GEN12B                                            19772 04824019
.GEN12A  ANOP                                                     19772 04832019
IEAQENA0 EQU   *                                                  19772 04840019
.GEN12B  ANOP                                                     19772 04848019
* OUTPUT FOR ENQ                                                        04860016
*              A MAJOR QUEUE CONTROL BLOCK (FORMAT BELOW) IF            04920016
*              THE RESOURCE WAS NOT PREVIOUSLY REQUESTED                04980016
*              AND THE MASK FIELD WAS SUCH TO ALLOW                     05040016
*              AN ENQUEUE. THIS ELEMENT CREATED IN SUBPOOL 255          05100016
         SPACE 1                                                        05160016
*              A MINOR QUEUE CONTROL BLOCK (FORMAT BELOW) IF            05220016
*              THE RESOURCE WAS NOT PREVIOUSLY REQUESTED                05280016
*              AND THE MASK FIELD WAS SUCH TO ALLOW                     05340016
*              AN ENQUEUE. THIS ELEMENT CREATED IN SUBPOOL 255          05400016
         SPACE 1                                                        05460016
*              A QUEUE ELEMENT TO REPRESENT THE REQUESTOR               05520016
*              ON THE QUEUE FOR THAT RESOURCE.                          05580016
*              THIS ELEMENT CREATED IN SUBPOOL 255                      05640016
         SPACE 2                                                        05700016
         AIF   (NOT &B(2)).GEN12                                        05707017
*              WITH SDASD AND IF A RESERVE WERE ISSUED (WHICH RE-       05714017
*              SULTED IN EXECUTION OF ENQUEUE), A SPECIFIED DEVICE      05721017
*              WOULD BE LOGICALLY RESERVED BY AN INCREMENT IN THE       05728017
*              UCB RESERVE COUNT                                        05735017
.GEN12   ANOP                                                           05742017
         SPACE 2                                                        05749017
* OUTPUT FOR DEQUEUE                                                    05760016
*              THE REMOVAL OF AND FREEING OF THE SPACE                  05820016
*              FOR THE ELEMENTS CREATED DURING ENQUEUE.                 05880016
         AIF   (NOT &B(2)).GEN13                                        05890017
*              IF THE SDASD OPTION HAS BEEN SELECTED, AN EXCP WILL      05900016
*              BE ISSUED TO RELEASE A DEVICE WHEN APPROPRIATE           05920016
.GEN13   ANOP                                                           05930017
         EJECT                                                          05940016
* ENTRY POINTS                                                          06000016
*              IGC048 DEQUEUE                                           06060016
*              ENTERED FROM THE SVC FLIH BY A LPSW INSTRUCTION.         06120016
*              THE PSW MUST BE                                          06180016
*              1-DISABLED FOR ALL MASKABLE INTERRUPTS                   06240016
*              EXCEPT MACHINE CHECK                                     06300016
*              2-BE IN SUPERVISOR MODE                                  06360016
*              3-HAVE A PROTECT KEY=0                                   06420016
*              REGISTER 1 POINTS TO THE FIRST ENTRY IN                  06480016
*              THE PARAMETER LIST                                       06540016
*              REGISTER 14 TO THE RETURN POINT                          06600016
         SPACE 1                                                        06660016
*              IGC056-ENQUEUE                                           06720016
*              ENTERED FROM THE SVC FLIH BY A LPSW INSTRUCTION.         06780016
*              THE PSW MUST BE                                          06840016
*              1-DISABLED FOR ALL MASKABLE INTERRUPTS                   06900016
*              EXCEPT MACHINE CHECK                                     06960016
*              2-BE IN SUPERVISOR MODE                                  07020016
*              3-HAVE A PROTECT KEY=0                                   07080016
*              REGISTER 1-POINTS TO THE FIRST ENTRY IN                  07140016
*              THE PARAMETER LIST                                       07200016
*              REGISTER 14-TO THE RETURN POINT                          07260016
         SPACE 1                                                        08940016
         AIF   (NOT &B(1)).GEN14                                        08970017
*              IEA0EQ01-MANUAL PURGE ROUTINE                            09000016
*              ENTERED ON A BRANCH FROM EITHER END OF                   09060016
*              TASK OR ABEND TO REMOVE ALL QEL'S                        09120016
*              ASSOCIATED WITH THE TCB SPECIFIED                        09180016
*              IN REGISTER 4                                            09240016
.GEN14   ANOP                                                           09270017
         EJECT                                                          09300016
* EXIT POINTS                                                           09360016
*              1-TO THE CALLER VIA A BRANCH ON REGISTER 14              09420016
*              2-TO THE DISPATCHER WHEN THE CALLER CANNOT               09480016
*              HAVE IMMEDIATE USE OF THE RESOURCES ON                   09540016
*              WHICH HE ENQUEUED.                                       09600016
*              3-TO A TASK OF HIGHER PRIORITY THEN THE                  09660016
*              CALLER IF THE CALLER FREE'S RESOURCES                    09720016
*              HERETOFORE HOLDING UP THE HIGHER PRIORITY TASK           09780016
         SPACE 2                                                        09840016
* ERROR EXIT POINTS                                                     09900016
*              TO ABEND WITH THE FOLLOWING ERROR CODES                  09960016
*              FROM DEQUEUE                                             10020016
*              130-A DEQUEUE WAS ISSUED FOR A RESOURCE                  10080016
*                  ON WHICH THE CALLER HAD NOT                          10140016
*                  PREVIOUSLY ENQUEUED.                                 10200016
*              230-INVALID MINOR NAME LENGTH                            10260017
*              330-RMC ISSUED IN PROBLEM PROGRAM STATE                  10320017
*              430-INVALID PARAMETER LIST                               10380017
*              530-DEQ ISSUED FOR QEL NOT IN CONTROL                    10440017
         SPACE 1                                                        10500016
*              FROM ENQUEUE                                             10560016
*              138-AN ENQ WAS ISSUED FROM A TASK                        10620016
*                  FOR A RESOURCE ON WHICH THAT                         10680016
*                  TASK ALREADY HAS A REQUEST.                          10740016
*              238-THE 'RNAME' LENGTH IS INVALID                        10800016
*              338-A SET MUST COMPLETE WAS ISSUED                       10860016
*                  BY A PROBLEM PROGRAM.  I.E., THE                     10920016
*                  SVC OLD PSW PROTECT KEY WAS NOT                      10980016
*                  EQUAL TO ZERO                                        11040016
*              438-INVALID PARAMETER LIST                               11070017
         EJECT                                                          11100016
* TABLES AND CONTROL BLOCKS REFERENCED                                  11160016
         SPACE 2                                                        11220016
*        EXTERNAL/INTERNAL SYMBOLS                                      11280016
         SPACE 1                                                        11340016
         EXTRN IEATCBP                  ADDRESS OF 'NEW' TCB            11400016
         EXTRN IEA0DS             ENTRY POINT TO DISPATCHER             11420016
         AIF   (NOT &B(1)).SHRD000                                      11440016
         EXTRN IEA0DS02                 ENTRY POINT TO TASK SWITCH      11580016
.SHRD000 ANOP                                                           11610016
         SPACE 3                                                        11640016
         ENTRY IGC056                   ENTRY POINT TO ENQ              11700016
         AIF   (&B(1)).SHRD010                                          11708016
         ENTRY IEA0SMC            ENTRY POINT TO MUST COMPLETE          11724016
         ENTRY ABENTRY         ENTRY TO DEQ FOR ABEND IN MFT ATTH 19054 11732019
         AGO   .SHRD020                                                 11740016
.SHRD010 ANOP                                                           11748016
         ENTRY IEA0EQ01                 ENTRY POINT TO MANUAL PURGE     11760016
.SHRD020 ANOP                                                           11910016
         AIF   (&B(1)).SHRD022                                    19772 11913019
         ENTRY IEAGENA0                                           19772 11916019
         ENTRY IEAGENA1                                           19772 11919019
         AGO   .SHRD021                                           19772 11922019
.SHRD022 ANOP                                                     19772 11925019
         ENTRY IEAQENA0                                           19772 11928019
         ENTRY IEAQENA1                                           19772 11931019
.SHRD021 ANOP                                                     19772 11934019
         EJECT                                                          11940016
*        GENERAL REGISTER EQUATES                                       12000016
         SPACE 1                                                        12060016
GMREG    EQU   0                        FOR REGISTER GETMAIN            12120016
WORKREG0 EQU   0                        GENERAL WORK REGISTER           12180016
REG1     EQU   1                   WORK REG                      A34816 12180120
REG0     EQU   0                       PARAMETER REGISTER         20021 12200020
FMREG    EQU   1                        FOR REGISTER FREEMAIN           12240016
INPUTREG EQU   1                        POINTER TO INPUT LIST           12300016
SUMREG   EQU   1                        FOR REGMAIN CALCULATIONS        12360016
GMRETREG EQU   1                        RETURN REGISTER FROM GETMAIN    12420016
ABENDREG EQU   1                        WHEN ABENDING CURRENT REQUESTOR 12480016
MCTCBRG  EQU   1                        THE ADDR OF THE MC TASK         12540016
BASEREG  EQU   2                        BASE REGISTER                   12600016
CHKBASE  EQU   2             VALIDITY CHECK BASE                        12630016
WORKREG3 EQU   3                        GENERAL WORK REGISTER           12660016
UCBREG   EQU   3                                                        12680016
ZENREG   EQU   3                                                        12700016
CURTCB   EQU   4                        CURRENT TCB ADDRESS             12720016
CURRB    EQU   5                        CURRENT RB ADDRESS              12780016
WORKREG4 EQU   6                        GENERAL WORK REGISTER           12840016
TOPPARM  EQU   6                        ADDRESS OF 1ST LIST ELEMENT     12900016
PURGEREG EQU   6                                                        12930016
CURMIN   EQU   7                        CURRENT MINOR QCB ADDRESS       12960016
WORKREG7 EQU   7                       REGISTER FOR VALIDITY CHECK RTN  12990017
CURMAJ   EQU   8                        CURRENT MAJOR QCB ADDRESS       13020016
TIOEREG  EQU   8                                                        13050016
CURQEL   EQU   9                        CURRENT QEL ADDRESS             13080016
BRCHECK  EQU   9                                                    LCS 13110017
TASKTCB  EQU   10                       TCB ADDR FOR TASK SWITCH        13140016
CURPARM  EQU   10                       CURRENT LIST ELEMENT            13200016
WORKREG1 EQU   11                       GENERAL WORK REGISTER           13260016
WKRG1    EQU   11                       GENERAL WORK REGISTER           13320016
TCBREG   EQU   11                       FOR RIPPLING DOWN TCB QUEUE     13380016
TIOUCBRG EQU   11                                                       13410016
JSTCBRG  EQU   12                       ADDRESS OF JOB STEP TCB         13440016
WORKREG2 EQU   12                       GENERAL WORK REGISTER           13500016
WKRG2    EQU   12                       GENERAL WORK REGISTER           13560016
TIOTREG  EQU   12                                                       13570016
TIODVRG  EQU   12                                                       13580016
RELWK1   EQU   12                                                       13590016
LINKREG  EQU   13                       INTERNAL LINK REGISTER          13620016
RETREG   EQU   14                       RETURN REGISTER                 13680016
WKRG3    EQU   14                       WORK REGISTER              SDA2 13686017
WKRG4    EQU   15                       WORK REGISTER              SDA2 13692017
RE       EQU   14                                                   LCS 13700017
RF       EQU   15                                                   LCS 13720017
GENREG   EQU   15                       SELECTED USE                    13740016
MASKREG  EQU   15                       DISPATCHABILITY MODIFIER        13800016
HILOPTR  EQU   16                  DISP VALUE TO PICK UP LCS PTR   4027 13830019
         EJECT                                                          13860016
*        TCB EQUATES                                                    13920016
         SPACE 1                                                        13980016
TCBPKF   EQU   28                       TCB PROTECT KEY FIELD           14040016
TCBFLG   EQU   29                       *                               14100016
TCBFLG1  EQU   30                       * TCB FLAGS                     14160016
TCBFLG2  EQU   31                       *                               14220016
TCBDISP  EQU   33                       TCB DISPATCHABILITY FLAGS       14280016
TCBGRS0  EQU   48                       OFFSET TO TCB REGISTER SAVE     14340016
TCBGRS   EQU   48                 OFFSET TO REGISTER SAVE AREA          14348016
         AIF   (&B(1)).SHRD030                                          14356016
TCBCT    EQU   34                 ENQ COUNT FIELD IN TCB                14364016
TCBDSP   EQU   35                 OFFSET FOR PRIORITY CODE              14372016
         AIF   (NOT &B(2)).NOSDASB                                      14373019
TCBPRGBT EQU   X'99'               BYTE CONTAINING DEQ PURGE FLAG  I250 14374019
TCBDUMPG EQU   X'01'               TEST PURGE FROM DUMP DATASET    I250 14375019
.NOSDASB ANOP                                                           14376019
TCBBYBOX EQU   24                  BOUNDARY BOX DISP. IN TCB       I250 14377019
TCBJSTEP EQU   44                  JOB STEP TCB DISP. IN TCB       I250 14378019
         AGO   .SHRD040                                                 14380016
.SHRD030 ANOP                                                           14388016
TCBCT    EQU   112                      ENQ COUNT FIELD IN TCB          14400016
.SHRD040 ANOP                                                           14430016
TCBTCB   EQU   116                      NEXT LOWER TCB ON READY QUEUE   14460016
JSPTR    EQU   124                      ADDR OF JOB STEP TCB IN TCB     14520016
TCBNTC   EQU   128                      ADDRESS OF SISTER TCB           14580016
TCBOTC   EQU   132                      ADDRESS OF MOTHER TCB           14640016
TCBLTC   EQU   136                      ADDRESS OF DAUGHTER TCB         14700016
         AIF   (NOT &B(3)).TSO0100                                20021 14706020
TCBTSFLG EQU   148                     TIME-SHARING STATUS FLAGS  20021 14712020
TCBJSCB  EQU   180                     ADDRS OF JOB STEP CTL-BLK  20021 14718020
         SPACE 1                                                  20021 14724020
TCBTSTSK EQU   X'80'                   STATUS BIT INDICATING A    20021 14730020
*                                      TIME-SHARING TASK.         20021 14736020
         AGO   .TSO0105                                           20021 14742020
.TSO0100 ANOP                                                     20021 14748020
         SPACE 1                                                        14760016
.TSO0105 ANOP                                                     20021 14790020
ABTERM   EQU   X'80'                    ABTERM BIT IN TCB               14820016
TCBFJMC  EQU   X'08'                    TO SET TCB MUST COMPLETE        14880016
TCBRJMC  EQU   X'F7'                    TO RESET STEP MUST COMPLETE     14940016
TCBFSMC  EQU   X'10'                    TO SET TCB SYS MUST COMPLETE    15000016
TCBRSMC  EQU   X'EF'                    TO RESET SYS MUST COMPLETE      15060016
TCBFXS   EQU   X'01'                    SET TO DEFER ASYNC EXITS        15120016
TCBFXR   EQU   X'FE'                    RESET ASYNC EXIT FLAG           15180016
PKEY0    EQU   X'F0'                    PROTECT KEY PORTION OF TCBPKF   15240016
         SPACE 3                                                        15300016
*        RB EQUATES                                                     15360016
         SPACE 1                                                        15420016
RBPSW    EQU   16            RESUME PSW IN RB                           15450016
PSWADR   EQU   16                       RESUME PSW IN RB                15480016
RBLINK   EQU   28                 SVRB LINK FIELD                       15510016
RBWCF    EQU   28                       WAIT COUNT FIELD IN RB          15540016
SVCOPSW  EQU   33                       SECOND BYTE OF SVC OLD PSW      15600016
XSAV     EQU   96                       EXTENDED SAVE AREA              15660016
RBSAVUCB EQU   X'80'               UCB SAVE FOR SHARED DASDI     A30097 15661020
SEPLP    EQU  X'84' .              SVRB DISP FOR PARM LIST PTR   3123   15663020
SEPLP1   EQU   X'88' . SAVE AREA FOR REG 10                  BJ A50045  15666021
         AIF   (&B(1)).MFTA40                                           15670019
RBNAME   EQU   6                   PTR TO LAST TWO BYTES OF NAME   I250 15680019
TWO      EQU   2                   COMPARE LENGTH FOR ABEND SVRB   I250 15690019
RG14INRB EQU   124                 RET REG STORED IN ABEND SVRB    I250 15700019
.MFTA40  ANOP                                                           15710019
         SPACE 3                                                        15720016
*        GENERALIZED EQUATES                                            15780016
         SPACE 1                                                        15840016
DCELBBNR EQU   0                        BIN # IN SUB-UCB           SDA2 15870017
D0       EQU   0 .                DISP VALUE OF 0           BJ 44371    15877021
D3       EQU   3 .                DISP VALUE OF 3           BJ 44371    15884021
D5       EQU   5 .                DISP VALUE OF 5           BJ 44371    15891021
ONE      EQU   1                        VALUE OF ONE                    15900016
UCBID    EQU   2                        ID IN UCB                  SDA2 15920017
UCBSIZE  EQU   56                       SIZE OF MAIN UCB           SDA2 15940017
LPSW     EQU   8                        LENGTH OF PSW                   15960016
PREVIOUS EQU   5                        DISPLACEMENT TO PREVIOUS FIELD  16020016
LNEW     EQU   4                  LENGTH FOR COMPARE OF NEW AND OLD     16050016
         SPACE 1                                                        16080016
WAITIND  EQU   X'00'                    FOR TESTING                     16140016
ANYON    EQU   X'FF'                    BYTE VALUES                     16200016
SYSTEMS  EQU   X'08'                                                    16203016
SYSKEY   EQU   X'FE'                                                    16206016
RESERVE  EQU   X'48'                                                    16209016
NORESRVE EQU  X'BF'                                           BJ  M2508 16210021
RESERVED EQU   X'40'                                                    16212016
ONERESV  EQU   X'01'               USE TO TEST FOR RELEASE        19772 16212520
UCBIDMSK EQU   255                 MASK TO TEST FOR A UCB         4531  16212720
UCBNAME  EQU   13                  DISP FOR THE EBCDIC DEVICE NAME 4531 16212820
UCBNMEMK EQU   192                 MASK TO TEST FOR UCB           4531  16212920
DB0      EQU   0 .                 STANDARD VALUE OF 0           A34816 16213020
DB4      EQU   4 .                 STANDARD VALUE OF 4           A34816 16217020
DB16     EQU   16 .                STANDARD DISP. EQUATES        A34816 16217420
DB20     EQU   20 .                STANDARD DISP. EQUATE OF 20   A34816 16217820
         AIF   (&B(1)).MFTA50                                           16221620
CVTADDR  EQU   16                  ADDR OF CVT                     I250 16225720
MFTATTCH EQU   X'08'               TEST FOR MFT ATTACH IN CVT      I250 16229820
.MFTA50  ANOP                                                           16233920
SHARED   EQU   X'20'                                                    16238020
QELUCB   EQU   12                                                       16242120
PTRUCB   EQU   12                                                       16246220
UCBRSCT  EQU   40                                                       16250320
RESINDIC EQU   41            UCB RESERVE INDICATOR                      16254420
TIOELNGH EQU   24                                                       16258520
TIODDLNG EQU   16                                                       16262620
TIOEFSRT EQU   0                                                        16266720
TIOTEND  EQU   0                                                        16270820
TCBTIOT  EQU   12                                                       16274920
DEVTYP   EQU   18                                                       16279020
DIRACCS  EQU   X'20'                                                    16283120
         AIF   (&B(1)).SHRD045                                          16287220
CURPRG   EQU   104           OFFSET TO XR8 IN TCB                       16291320
         AGO   .SHRD046                                                 16295420
.SHRD045 ANOP                                                           16299520
CURPRG   EQU   80                                                       16303620
.SHRD046 ANOP                                                           16307720
UCBSKA   EQU   48                                                       16311820
         EJECT                                                          16315920
*        PARAMETER LIST ELEMENT                                         16320016
         SPACE 3                                                        16380016
*******************************************                             16440016
* 0       * 1        * 2       * 3        *                             16500016
* LISTEND *  LMINOR  * PARMCDS *  RETURN  *                             16560016
*         *          *         *          *                             16620016
*******************************************                             16680016
* 4                                       *                             16740016
*    ADDRESS OF MAJOR RESOURCE NAME       *                             16800016
*                                         *                             16860016
*******************************************                             16920016
* 8                                       *                             16980016
*    ADDRESS OF MINOR RESOURCE NAME       *                             17040016
*                                         *                             17100016
*******************************************                             17160016
*12  POINTER TO THE UCB ADDRESS           *                             17162016
*   FOR RELEASE REQUESTS                  *                             17164016
*                                         *                             17166016
*******************************************                       20021 17168020
         SPACE 2                                                        17170016
*  DEFINITION OF FLAGS AT OFFSET 2                                      17172016
*  BIT 0 - IF SET TO ONE, INDICATES SHARED REQUEST                      17174016
*        - IF SET TO ZERO, INDICATES EXCLUSIVE REQUEST                  17176016
*  BIT 1 - SEE BELOW                                                    17178016
*  BIT 2 - IF SET TO ONE, INDICATES REQUEST FOR SYSTEM MUST COMPLETE    17180016
*  BIT 3 - IF SET TO ONE, INDICATES REQUEST FOR STEP MUST COMPLETE      17182016
* BIT 4 - SEE BELOW                                                     17184016
* BITS 5,6, AND 7                                                       17186016
*          001 - RET=HAVE                                               17188016
*          010 - RET=CHNG                                        20021  17189020
*          011 - RET=USE                                                17190016
*          111 - RET=TEST                                               17192016
*  BITS 1 AND 4 PERTAIN TOTHE SCOPE OF THE REQUEST AND HAVE THE FOLL    17194016
*          OWING MEANING                                                17196016
*        BIT 1     BIT 4     MEANING                                    17198016
*          0         0       STEP                                       17200016
*          0         1       RESERVE                                    17202016
*          1         0       SYSTEM                                     17204016
*          1         1       SYSTEMS                                    17206016
*  ON A RESERVE REQUEST, THE SCOPE IS AUTOMATICALLY CONVERTED TO        17208016
*  SYSTEMS.(KNOWN ACROSS SYSTEMS).                                      17210016
         SPACE 3                                                        17220016
*        WHERE:                                                         17280016
         SPACE 1                                                        17340016
LISTEND  EQU   0                        OFFSET TO LIST END INDICATOR    17400016
LMINOR   EQU   1                        OFFSET TO LENGTH OF MINOR NAME  17460016
PARMCDS  EQU   2                        OFFSET TO PARAMETER CODES       17520016
RETURN   EQU   3                        OFFSET TO RETURN CODE FIELD     17580016
PTRMAJ   EQU   4                        OFFSET TO ADDR OF MAJOR NAME    17640016
PTRMIN   EQU   8                        OFFSET TO ADDR OF MINOR NAME    17700016
         SPACE 1                                                        17760016
ENDIND   EQU   128                      END OF LIST INDICATOR  @JK68363 17820021
PLMI     EQU   X'80'                    PLUS OR MINUS INDICATOR         17880016
SHARE    EQU   X'40'                    SHARED RESOURCE INDICATOR       17940016
SMC      EQU   X'30'                    SET MUST COMPLETE INDICATORS    18000016
SMCSYS   EQU   X'20'                    SYSTEM MUST COMPLETE            18060016
SMCSTP   EQU   X'10'                    STEP MUST COMPLETE              18120016
HAVE     EQU   X'01'                    TO TEST 'HAVE' MASK             18180016
CHNG     EQU   X'02'                    TO TEST CHNG MASK         20021 18210020
USE      EQU   X'03'                    TO TEST 'USE' MASK              18240016
TEST     EQU   X'07'                    TO TEST 'TEST' MASK             18300016
AVAIL    EQU   X'00'                    RETURN CODE OF ZERO             18360016
INUSE    EQU   X'04'                    RETURN CODE OF FOUR             18420016
HAS      EQU   X'08'                    RETURN CODE OF EIGHT            18480016
         SPACE 1                                                        18540016
PARMSIZE EQU   12                       LENGTH OF ELEMENT               18600016
PLASTBYT EQU   11                       PTR TO LAST BYTE       @JK67730 18630021
LPARM    EQU   12                       LENGTH OF ELEMENT               18660016
RESVSIZE EQU   16            SIZE OF RESERVE PARAMETER LIST             18690016
         EJECT                                                          18720016
*****    CONTROL BLOCK FORMATS    *****                                 18780016
         SPACE 3                                                        18840016
*        MAJOR QUEUE CONTROL BLOCK                                      18900016
         SPACE 1                                                        18960016
*******************************************                             19020016
* 0                                       *                             19080016
*        ADDRESS OF NEXT MAJOR QCB        *                             19140016
*                                         *                             19200016
*******************************************                             19260016
* 4                                       *                             19320016
*       ADDRESS OF PREVIOUS MAJOR QCB     *                             19380016
*                                         *                             19440016
*******************************************                             19500016
* 8                                       *                             19560016
*        ADDRESS OF FIRST MINOR QCB       *                             19620016
*                                         *                             19680016
*******************************************                             19740016
* 12                                      *                             19800016
*             MAJOR QCB NAME              *                             19860016
*                                         *                             19920016
*******************************************                             19980016
* 16                                      *                             20040016
*             MAJOR QCB NAME              *                             20100016
*                                         *                             20160016
*******************************************                             20220016
         SPACE 2                                                        20280016
NXMAJ    EQU   0                        POINTER TO NEXT MAJOR QCB       20340016
PREVMAJ  EQU   4                        POINTER TO PREVIOUS MAJOR QCB   20400016
FSTMIN   EQU   8                        POINTER TO FIRST MINOR QCB      20460016
LMAJ     EQU   8                        LENGTH OF MAJOR NAME            20520016
MAJNAME  EQU   12                       MAJOR QCB NAME                  20580016
MAJSIZE  EQU   24                       SIZE OF MAJOR TO A DBL WORD     20640016
MAJCLR   EQU   12                  PORTION TO CLEAR IN MAJOR QCB   2926 20700018
         EJECT                                                          20760016
*        MINOR QUEUE CONTROL BLOCK                                      20820016
         SPACE 1                                                        20880016
*******************************************                             20940016
         AIF   (NOT &B(3)).TSO0111                                20021 20950020
* 0        * 1                            *                       20021 20960020
* MIN      * ADDRESS OF FIRST QEL         *                       20021 20970020
* TJID1    *                              *                       20021 20980020
*******************************************                       20021 20990020
* 4        * 5                            *                       20021 20991020
* MIN      * ADDRESS OF PREVIOUS          *                       20021 20992020
* TJID2    * MINOR QCB                    *                       20021 20993020
         AGO   .TSO0112                                           20021 20994020
.TSO0111 ANOP                                                     20021 20995020
* 0                                       *                             21000016
*          ADDRESS OF FIRST QEL           *                             21060016
*                                         *                             21120016
*******************************************                             21180016
* 4                                       *                             21240016
*      ADDRESS OF PREVIOUS MINOR QCB      *                             21300016
*                                         *                             21360016
.TSO0112 ANOP                                                     20021 21370020
*******************************************                             21420016
* 8                                       *                             21480016
*        ADDRESS OF NEXT MINOR QCB        *                             21540016
*                                         *                             21600016
*******************************************                             21660016
* 12      * 13       * 14                 *                             21720016
* LENGTH  *  QCBPKF  *   MINOR QCB NAME   *                             21780016
*         *          *                    *                             21840016
*******************************************                             21900016
* 16                                      *                             21960016
*           MINOR QCB NAME                *                             22020016
*         (VARIABLE LENGTH)               *                             22080016
*******************************************                             22140016
         SPACE 3                                                        22200016
FSTQEL   EQU   0                        ADDRESS OF FIRST QEL            22260016
PREVMIN  EQU   4                        ADDRESS OF PREVIOUS MINOR QCB   22320016
PREVMIN1 EQU  PREVMIN+1 .               ADDRESS OF PREVIOUS M/QCB M0852 22370020
NXMIN    EQU   8                        ADDRES OF NEXT MINOR QCB        22380016
ELEVEN   EQU   11                       DISPLACEMENT TO LENGTH -1       22440016
LMINAME  EQU   12                       LENGTH OF MINOR NAME            22500016
QCBPKF   EQU   13                       TCB PROTECT KEY FIELD IN QCB    22560016
MINAME   EQU   14                       MINOR NAME                      22620016
         SPACE 1                                                        22680016
NOKEY    EQU   X'FF'                    INDICATES A SHARED RESOURCE     22740016
         SPACE 1                                                        22800016
MINCLR   EQU   12                  PORTION TO CLEAR IN MINOR QCB   2926 22860018
FULLSIZE EQU   21                       ALLOW ROUNDING TO A DBL WORD    22920016
         EJECT                                                          22980016
*              QUEUE ELEMENT              *                             23040016
         SPACE 1                                                        23100016
*******************************************                             23160016
* 0       * 1                             *                             23220016
*   SMC   *    ADDRESS OF NEXT QEL        *                             23280016
*         *                               *                             23340016
*******************************************                             23400016
* 4       * 5                             *                             23460016
*  CODE   *   ADDRESS OF PREVIOUS QEL     *                             23520016
*         *                               *                             23580016
*******************************************                             23640016
         AIF   (NOT &B(3)).TSO0120                                20021 23645020
* 8       *                               *                       20021 23650020
*  TJID0  *   ADDRESS OF ENQUEUEING TCB   *                       20021 23655020
*         *                               *                       20021 23660020
*******************************************                       20021 23665020
* 12      *                               *                       20021 23670020
*  TJID1  *   ADDRESS OF SVRB FOR ENQ     *                       20021 23675020
*         *                               *                       20021 23680020
*******************************************                       20021 23685020
         AGO   .TSO0130                                           20021 23690020
.TSO0120 ANOP                                                     20021 23695020
* 8                                       *                             23700016
*      ADDRESS OF ENQUEUEING TCB          *                             23760016
*                                         *                             23820016
*******************************************                             23880016
* 12                                      *                             23940016
*      ADDRESS OF SVRB FOR ENQ            *                             24000016
*                                         *                             24060016
*******************************************                             24120016
.TSO0130 ANOP                                                     20021 24123020
         SPACE 2                                                        24127016
*  IF THE QEL REPRESENTS A RESERVE REQUEST AND THE REQUESTOR WAS GIVEN  24134016
*  CONTROL OF THE RESOURCE, OFFSET 12 WILL CONTAIN THE UCB ADDRESS      24141016
*  OFFSET 4 FLAG DEFINITIONS                                            24148016
*  X'00' - INDICATES EXCLUSIVE REQUEST                                  24155016
*  X'40' - INDICATES RESERVE REQUEST                                    24162016
*  X'80' - INDICATES SHARED REQUEST                                     24169016
         SPACE 2                                                        24180016
NXQEL    EQU   0                        POINTER TO NEXT QEL             24240016
QELSMC   EQU   0                        SMC INDICATOR IN QEL            24300016
PREVQEL  EQU   4                        POINTER TO PREVIOUS QEL         24360016
QELCDS   EQU   4                        QEL CODE BYTE                   24420016
QELCLR   EQU   4                        PORTION TO BE CLEARED IN QEL    24480016
QELTCB   EQU   8                        POINTER TO TCB                  24540016
         AIF   (NOT &B(3)).TSO0140                                20021 24546020
QELTJID0 EQU   8                       1ST HALF OF TIME-SHRNG     20021 24552020
*                                      JOB IDENTIFICATION.        20021 24558020
*..............1ST BIT OF QELTJID0 IS A FLAG BIT THAT IS SET      20021 24564020
*..............ON FOR ALL QELS FOR A SWAPPED TIME-SHARING USER.   20021 24570020
QELTJID1 EQU   12                      2ND HALF OF TIME-SHRNG     20021 24576020
*                                      JOB IDENTIFICATION.        20021 24582020
.TSO0140 ANOP                                                     20021 24588020
SVRBPTR  EQU   12                       POINTER TO SVRB OF ENQ          24600016
QELSIZE  EQU   16                       LENGTH OF QEL                   24660016
NEGCODE  EQU   X'80'                    INDICATES MINUS QEL REQUEST     24720016
         AIF   (NOT &B(3)).TSO0145                                20021 24730020
QELRBWT  EQU   X'20'                   INDICATES THAT SVRB        20021 24740020
*                                      PROCESSNG IS TO BE         20021 24750020
*                                      DELAYED UNTIL SWAPIN.      20021 24760020
.TSO0145 ANOP                                                     20021 24770020
         EJECT                                                          24780016
         AIF   (&B(1)).NMFTA1                                           24790019
ABENTRY  EQU   *                   BR ENTRY POINT FOR MFT ATTACH   I250 24800019
.NMFTA1  ANOP                                                           24810019
         BALR  BASEREG,0                                                24840016
         USING *,BASEREG                                                24900016
         SPACE 3                                                        24960016
***  HOUSEKEEPING AND INITIALIZATION                                    25020016
         SPACE 1                                                        25080016
         AIF   (&B(1)).SHRD050                                          25090016
         AIF   (NOT &B(2)).NOSDASA                                      25091019
         CLC   RBNAME(TWO,CURRB),ABSVRBNM  BR ENTRY FROM ABEND     I250 25092019
         BNE   REGDEQ                      NO, PROCESS AS REG DEQ  I250 25093019
         TM    TCBPRGBT(PURGEREG),TCBDUMPG  PURGE TCB FROM DUMP DS I250 25094019
         BO    REGDEQ                      YES,DO PURGE DEQ        I250 25095019
*        IF NOT MUST BE RELEASE OF SDASD REQUEST NOT DEQ           I250 25096019
         B     RLSETEST                    DO RELEASE NO DEQ       I250 25097019
REGDEQ   EQU   *                                                   I250 25098019
.NOSDASA ANOP                                                           25099019
         LA    CURPARM,0(INPUTREG)   INITIALIZE LOOP THROUTH PARAM LIST 25100016
         LR    TOPPARM,CURPARM    SAVE POINTER TO FIRST ELEMENT         25110016
         AGO   .SHRD060                                                 25120016
.SHRD050 ANOP                                                           25130016
         LR    CURPARM,INPUTREG         INITIALIZE LOOP THROUGH P.LIST  25140016
         LR    TOPPARM,INPUTREG         SAVE POINTER TO FIRST ELEMENT   25200016
.SHRD060 ANOP                                                           25230016
         SPACE 3                                                        25260016
***  INVOKE VALIDITY CHECK ROUTINE.                                     25320016
         SPACE 1                                                        25380016
         BAL   LINKREG,CHKLIST          GO TO VALIDITY CHECK INTERFACE  25440016
         SPACE 1                                                        25500016
         AIF   (NOT &B(1)).SHRD070                                      25530016
***  VALIDITY CHECK NO GOOD, ABEND THE REQUESTOR.                       25560016
         BC    15,DRRX4                 BAD RETURN, ABEND THE TASK      25620016
         BC    15,DRRX3                 BAD RETURN, ABEND THE TASK      25680016
         BC   15,DRRX2                  BAD RETURN, ABEND THE TASK      25740016
*    RETURN TO NEXT INSTRUCTION IF LIST OK                              25800016
         SPACE 3                                                        25860016
.SHRD070 ANOP                                                           25890016
***  LINK TO 'FINDMAJ' IN AN ATTEMPT TO FIND A                          25920016
*    MAJOR QCB OF THE SAME NAME AS THAT PASSED                          25980016
*    IN THE SUBLIST.                                                    26040016
         SPACE 1                                                        26100016
PARMLOOP BAL   LINKREG,FINDMAJ          LOCATE MAJOR QCB                26160016
         LTR   CURMAJ,CURMAJ            Q.IS MAJOR QCB PRESENT          26220016
         BC    4,DQERR1                 NO, TEST FOR RETURN OR ABEND    26280016
         SPACE 3                                                        26340016
***  LINK TO 'FINDMIN' IN AN ATTEMPT TO FIND A                          26400016
*    MINOR QCB OF THE SAME NAME AS THAT PASSED                          26460016
*    IN THE SUBLIST.  ONLY THE MINORS ON THE                            26520016
*    PREVIOUSLY FOUND MAJOR ARE SEARCHED.                               26580016
         SPACE 1                                                        26640016
         BAL   LINKREG,FINDMIN          LOCATE MINOR QCB                26700016
         LTR   CURMIN,CURMIN            Q.IS MINOR QCB PRESENT          26760016
         BC    4,DQERR1                 NO, TEST FOR RETURN OR ABEND    26820016
         EJECT                                                          26880016
***  A MAJOR QCB AND MINOR QCB OF THE SAME NAMES                        26940016
*    AS THAT PASSED IN THE SUBLIST HAVE BEEN FOUND.                     27000016
*    WE NOW DETERMINE THAT A QEL FOR THIS TASK                          27060016
*    CAN BE LEGALLY DEQUEUED.                                           27120016
         SPACE 1                                                        27180016
*    CONSIDERATION OF THE EXCLUSIVE (PLUS) AND                          27240016
*    SHARED (MINUS) ATTRIBUTES OF THE QEL IS GIVEN                      27300016
*    IN DETERMINING THE LEGALITY OF THE DEQUEUE.                        27360016
         SPACE 1                                                        27420016
         L     CURQEL,FSTQEL(CURMIN)    OBTAIN CURRENT QEL              27480016
         CL    CURTCB,QELTCB(CURQEL)    Q.IS DEQ FROM SAME TASK         27540016
         BC    8,TOPQEL                 YES, TAKE BRANCH                27600016
QELLIST  TM    4(CURQEL),PLMI           Q. IS CUR. QEL + OR - .         27660016
         BC    8,DQERR2                 PLUS, TEST FOR RETURN OR ABEND  27720016
GETNEXT  L     CURQEL,NXQEL(CURQEL)     OBTAIN NEXT QEL                 27780016
         LA    CURQEL,0(CURQEL)         CLEAR HIGH ORDER BYTE           27840016
         LTR   CURQEL,CURQEL            Q. IS NEXT QEL PRESENT          27900016
         BC    8,DQERR1                 NO, TEST FOR RETURN OR ABEND    27960016
QELNEXT  CL    CURTCB,QELTCB(CURQEL)    Q. IS CUR TCB DEQ'UEUING        28020016
         BC    7,QELLIST                NO, TAKE BRANCH                 28080016
         TM    4(CURQEL),PLMI           Q. IS CR. QEL + OR - .          28140016
         BC    8,DQERR2A .         PLUS, TEST FOR RETURN OR ABEND  5173 28200020
         SPACE 3                                                        28260016
***  A QEL HAS BEEN FOUND THAT CAN BE LEGALLY                           28320016
*    DEQUEUED.  IT IS EITHER A EXCLUSIVE                                28380016
*    REQUEST ON THE TOP OF THE QUEUE, OR                                28440016
*    A SHARED REQUEST WITH NO EXCLUSIVE REQUESTS                        28500016
*    ABOVE IT.                                                          28560016
         SPACE 1                                                        28620016
         AIF   (NOT &B(2)).SHRDA24                                      28626016
TOPQEL   TM    QELCDS(CURQEL),RESERVED  Q. IS THIS QEL RESERVE QEL      28632016
         BC    8,TOPQEL2                NO - SKIP RELEASE TEST          28638016
         L     UCBREG,QELUCB(CURQEL)    YES - TEST FOR RELEASE          28650016
         BAL   LINKREG,RLSETEST         RELEASE IF COUNT IS ZERO        28656016
TOPQEL2  TM    PARMCDS(TOPPARM),HAVE    Q. ARE RETURN CODES REQUESTED   28662016
         AGO   .SHRDA25                                                 28668016
.SHRDA24 ANOP                                                           28674016
TOPQEL   TM    PARMCDS(TOPPARM),HAVE    Q. ARE RETURN CODES REQUESTED   28680016
.SHRDA25 ANOP                                                           28710016
         BC    8,NORET                  NO, SKIP RETURNS                28740016
         MVI   RETURN(CURPARM),AVAIL    GIVE RETURN CODE OF ZERO        28800016
NORET    BAL   LINKREG,DECTCB           DECREMENT TCBCT FIELD           28860016
         LR    WORKREG1,CURQEL          LOAD CUR QEL ADDRESS            28920016
         LR    WORKREG2,CURQEL          ASSUME PLUS REQUEST             28980016
         TM    4(CURQEL),PLMI           Q. IS QEL + OR -                29040016
         BC    8,REMOVE                 +, TAKE BRANCH                  29100016
         LCR   WORKREG2,CURQEL          COMPLEMENT, INDICATING SHARED   29160016
         SPACE 3                                                        29220016
*    LINK TO 'DQELEMNT' WHICH WILL DEQUEUE THE QEL                      29280016
         SPACE 1                                                        29340016
REMOVE   BAL   LINKREG,DQELEMNT         DEQUEUE THE QEL                 29400016
         EJECT                                                          29460016
***  SET SIZE OF THE QEL AND LINK TO THE FREEMAIN ROUTINE.              29520016
         SPACE 1                                                        29580016
         LA    WORKREG0,QELSIZE         OBTAIN QEL SIZE                 29640016
         LR    FMREG,CURQEL             LOAD ADR. OF QEL FOR FREEMAIN   29700016
         BAL   LINKREG,FREEUP           BRANCH TO FREEMAIN INTERFACE    29760016
         SPACE 3                                                        29820016
***  QEL HAS BEEN REMOVED AND THE SPACE FREED.  IF ANOTHER              29880016
*    QEL IS NOT ON THE QUEUE GO TO PROCESS THE MINOR                    29940016
*    QCB.  IF ANOTHER QEL HAS POPPED UP DETERMINE IF                    30000016
*    ITS SVRB WAIT COUNT SHOULD BE DECREMENTED                          30060016
*    AND THE TASK SWITCH ROUTINE INVOKED.                               30120016
         SPACE 1                                                        30180016
         L     LINKREG,FSTQEL(CURMIN) .     SET ADDR OF NEXT QEL  M0852 30240020
         LA    LINKREG,0(,LINKREG) .        CLEAR HI-ORDER BYTE   M0852 30290020
         CR   WORKREG0,LINKREG .     Q  HAS A QEL POPPED TO TOP   M0852 30292020
         BC    8,PROCMIN                NO, PROCESS MINOR               30300016
         L     CURQEL,FSTQEL(CURMIN)    GET NEW TOP QEL                 30360016
         AIF   (NOT &B(3)).TSO0500                                20021 30362020
         SPACE 2                                                  20021 30364020
***                                                               20021 30366020
*   THIS CODE TESTS TO SEE IF THE NEW TOP QEL BELONGS TO A        20021 30368020
*    SWAPPED TIME-SHARING USER.  IF SO, THE TIME-SHARING          20021 30370020
*    DRIVER IS NOTIFIED TO SWAP THIS USER IN.  SVRB PROCESSING    20021 30372020
*    IS DELAYED UNTIL THE TIME-SHARING USER IS SWAPPED IN.        20021 30374020
         TM    QELTJID0(CURQEL),ANYON  QEL FOR TIME-SHRNG TASK?   20021 30376020
         BZ    NOTTSQEL                NO. CONTINUE.              20021 30378020
         TM    QELCDS(CURQEL),PLMI     Q. IS QEL SHARED.          20021 30380020
         BZ    ROLLIN                  NO. ROLLIN USER.           20021 30382020
         LTR   WORKREG2,WORKREG2       WAS REMOVED QEL SHARED?    20021 30384020
         BM    NXTINPUT                YES. CHK NXT PARAM LIST.   20021 30386020
ROLLIN   OI    QELCDS(CURQEL),QELRBWT  FLAG QEL FOR SVRB PRO-     20021 30388020
*                                      CESSING AFTER ROLLIN.      20021 30390020
         LH    REG0,QELTJID0(CURQEL)   OBTAIN TIME-SHRNG USER'S   20021 30392020
         IC    REG0,QELTJID1(CURQEL)   TERMINAL JOB ID.           20021 30394020
         N     REG0,TSDRVMSK           CLEAR HIGH-ORDER BITS.     20021 30396020
         SR    REG1,REG1                                          20021 30398020
         TSEVENT  USERRDY,TJID=(0)                                20021 30400020
         TM    QELCDS(CURQEL),PLMI     Q. IS QEL SHARED.          20021 30402020
         BZ    NXTINPUT                NO. CHK NXT PARAM LIST.    20021 30404020
         B     NEXTQEL                                            20021 30406020
*                                                                 20021 30408020
***                                                               20021 30410020
NOTTSQEL EQU   *                                                  20021 30412020
         SPACE 2                                                  20021 30414020
.TSO0500 ANOP                                                     20021 30416020
         TM    QELCDS(CURQEL),PLMI      Q. IS QEL SHARED                30420016
         BC    8,PLUSQEL                EXCLUSIVE, TAKE BRANCH          30480016
         LTR   WORKREG2,WORKREG2        Q. WAS REMOVED QEL SHARED       30540016
         BC    4,NXTINPUT               YES, TAKE BRANCH                30600016
REPQEL   BAL   LINKREG,DECSVRB          DECREMENT SVRB/ TASK SWITCH     30660016
         AIF   (NOT &B(3)).TSO0505                                20021 30670020
NEXTQEL  EQU   *                                                  20021 30680020
.TSO0505 ANOP                                                     20021 30690020
         L     CURQEL,NXQEL(CURQEL)     OBTAIN NEXT QEL                 30720016
         LTR   CURQEL,CURQEL            Q. IS THERE A NEXT QEL          30780016
         BC    8,NXTINPUT               NO, TAKE BRANCH                 30840016
         AIF   (NOT &B(3)).TSO0510                                20021 30843020
         SPACE 2                                                  20021 30846020
***                                                               20021 30849020
*    THIS CODE TESTS TO SEE IF THE NEXT QEL BELONGS TO A          20021 30852020
*    SWAPPED TIME-SHARING USER.                                   20021 30855020
         TM    QELTJID0(CURQEL),ANYON  QEL FOR  A SWAPPED         20021 30858020
*                                       TIME-SHARING TASK?        20021 30861020
         BZ    NOTTSQL                 NO. CONTINUE NORMALLY.     20021 30864020
         TM    QELCDS(CURQEL),PLMI     Q. IS QEL SHARED.          20021 30867020
         BZ    NXTINPUT                NO. CHK NXT PARAM LIST.    20021 30870020
         B     ROLLIN                  YES. TELL TIME-SHARING     20021 30873020
*                                      DRIVER TO SWAPIN USER.     20021 30876020
*                                                                 20021 30879020
********                                                          20021 30882020
NOTTSQL  EQU   *                                                  20021 30885020
         SPACE 2                                                  20021 30888020
.TSO0510 ANOP                                                     20021 30891020
         TM    QELCDS(CURQEL),PLMI      Q. IS NEXT QEL SHARED           30900016
         BC    1,REPQEL                 YES, TAKE BRANCH                30960016
         BC    15,NXTINPUT              TAKE BRANCH                     31020016
PLUSQEL  BAL   LINKREG,DECSVRB          DECREMENT SVRB/ TASK SWITCH     31080016
         BC    15,NXTINPUT              TAKE BRANCH                     31140016
         EJECT                                                          31200016
***  A QEL HAS BEEN REMOVED AND ITS SPACE FREED.                        31260016
*    IT WAS THE ONLY QEL ON THE MINOR.  THEREFORE,                      31320016
*    WE WANT TO REMOVE THE MINOR AND FREE THE SPACE.                    31380016
*    THE MAJOR WILL ALSO BE REMOVED AND ITS SPACE FREED                 31440016
*    IF THE MINOR WAS THE ONLY ONE ON THE CHAIN.                        31500016
         SPACE 1                                                        31560016
PROCMIN  BAL   LINKREG,ADDMINOR         SPACE 1                         31620016
         BAL   LINKREG,DQMINOR          DE-QUEUE MINOR QCB              31680016
         LR    WORKREG0,SUMREG          LOAD MINOR SIZE                 31740016
         LR    FMREG,CURMIN             LOAD ADR. OF MINOR FOR FREEMAIN 31800016
         BAL   LINKREG,FREEUP           BRANCH TO FREEMAIN INTERFACE    31860016
         CL    WORKREG0,FSTMIN(CURMAJ)  Q. IS THERE ANY MORE MINORS     31920016
         BC    7,NXTINPUT               YES, TAKE BRANCH                31980016
         LR    WORKREG1,CURMAJ          LOAD CURRENT MAJOR              32040016
         BAL   LINKREG,DQELEMNT         DE-QUEUE MAJOR QCB              32100016
         LA    WORKREG0,MAJSIZE         OBTAIN MAJOR SIZE               32160016
         LR    FMREG,CURMAJ             LOAD ADR. OF MAJOR FOR FMAIN    32220016
         BAL   LINKREG,FREEUP           BRANCH TO FREEMAIN INTERFACE    32280016
         SPACE 3                                                        32340016
***  DETERMINE IF THE SUBLIST PROCESSING IS COMPLETE.                   32400016
*    IF NOT, GET THE NEXT AND GO BACK TO THE TOP.                       32460016
*    IF YES, THE RESET MUST COMPLETE INTERFACE                          32520016
*    IS ENTERED AND THE ROUTINE INVOKED IF REQUESTED.                   32580016
*    WHEN COMPLETE RETURN VIA THE RETURN INTERFACE                      32640016
*    TO SET REGISTER FIFTEEN PROPERLY.                                  32700016
         SPACE 1                                                        32760016
NXTINPUT TM    0(CURPARM),ENDIND        Q. IS THIS LAST INPUT ENTRY     32820016
         LA    CURPARM,LPARM(CURPARM)   GET NEXT INPUT ENTRY            32880016
         BZ    PARMLOOP                 NO TAKE BRANCH         @JK68363 32940021
         BAL   LINKREG,RMCOMP           GO RESET MUST COMPLETE          33000016
RMCRET   LR    CURPARM,TOPPARM          RESET FOR EXIT                  33060016
         AIF   (&B(1)).SHRD080                                          33064016
         BAL   LINKREG,MCRET2                                           33068016
         CLC   RBNAME(TWO,CURRB),ABSVRBNM  BR ENTRY FROM ABEND     I250 33068619
         BNE   CONTIII              CONTINUE NORMALLY             19054 33069219
         L     RETREG,RG14INRB(CURRB)     RETURN REGISTER          I250 33069819
         BR    RETREG              YES - RETURN TO ABEND          19054 33070419
CONTIII  EQU   *                                                  19054 33071019
         L     WORKREG1,NEW       DOES CURRENT TASK REGAIN CONTROL      33072016
         CLC   0(LNEW,WORKREG1),4(WORKREG1)                             33076016
         BC    8,GOEXIT           YES.  EXIT                            33080016
         MVC   PSWADR(LPSW,CURRB),EXITPSW  NO, SET UP PSW TO            33084016
*                                 ISSUE SVC EXIT                        33088016
         STM   10,9,TCBGRS(CURTCB)     SAVE REGS                        33092016
         L     WORKREG2,DISPATCH  AND GO TO THE DISPATCHER              33096016
         BCR   15,WORKREG2                                              33100016
         AGO   .SHRD090                                                 33104016
.SHRD080 ANOP                                                           33108016
         BC    15,MCRET2                GO TO EXIT INTERFACE            33120016
.SHRD090 ANOP                                                           33150016
         EJECT                                                          33180016
         SPACE 1                                                        33240016
***  GET THE WAIT COUNT FIELD FROM THE SVRB.                            33300016
*    IF EQUAL TO ZERO, GET THE NEXT PARAMETER LIST ELEMENT.             33360016
*    IF NOT EQUAL TO ZERO, DECREMENT THE WAIT COUNT BY ONE              33420016
         SPACE 1                                                        33480016
DECSVRB  SR    WORKREG2,WORKREG2        SET TO ZERO                     33540016
         L     GENREG,SVRBPTR(CURQEL)   OBTAIN SVRB POINTER             33600016
*    A WAIT COUNT OF ZERO INDICATES THE TASK REPRESENTED BY             33660016
*    THIS SVRB IS BEING ABENDED.  IN THIS CASE DO NOT                   33720016
*    DECREMENT THE WAIT COUNT.                                          33780016
         CLI   RBWCF(GENREG),WAITIND    Q. IS WAIT COUNT ZERO           33840016
         BCR   8,LINKREG                YES, RETURN TO MAINLINE         33900016
         IC    WORKREG2,RBWCF(GENREG)   GET WAIT COUNT                  33960016
         BCTR  WORKREG2,0               DECREMENT IT                    34020016
         STC   WORKREG2,RBWCF(GENREG)   AND PUT IT BACK                 34080016
         AIF   (NOT &B(2)).SHRDA45                                      34084016
         TM    QELCDS(CURQEL),RESERVED                                  34088016
         BC    8,NOTRSV                                                 34092016
         L     WORKREG2,QELUCB(CURQEL)  GET UCB PTR FROM QEL BJ 60112   34096021
         L     WORKREG2,RBSAVUCB(WORKREG2) GET PARM PTR FOR THIS QEL    34100021
         ST    WORKREG2,QELUCB(CURQEL)  SET UCB POINTER IN QEL          34107016
         SR    WORKREG1,WORKREG1         CLEAR REG FOR IC               34108016
         IC    WORKREG1,UCBRSCT(WORKREG2) GET UCB RESERVE COUNT         34112016
         LA    WORKREG1,1(WORKREG1)                                     34116016
         STC   WORKREG1,UCBRSCT(WORKREG2) REPLACE NEW COUNT             34120016
NOTRSV   CLI   RBWCF(GENREG),WAITIND    Q. IS SVRB STILL WAITING        34124016
         AGO   .SHRDA46                                                 34128016
.SHRDA45 ANOP                                                           34132016
         CLI   RBWCF(GENREG),WAITIND    Q. IS SVRB STILL WAITING        34140016
.SHRDA46 ANOP                                                           34170016
         BCR   7,LINKREG                YES, RETURN TO MAINLINE         34200016
         EJECT                                                          34260016
         SPACE 2                                                        34320016
***  IF WE FALL THROUGH TO THIS CODE THE TASK WHOSE WAIT COUNT          34380016
*    WAS DECREMENTED CAN NOW HAVE CONTROL OF THE RESOURCES              34440016
*    ON WHICH HE ENQUEUED.                                              34500016
         AIF   (&B(1)).SHRD100                                          34502016
*    BUT WE MUST DETERMINE IF A HIGHER PRIORITY TASK IS TO BE           34504016
*    DISPATCHED.  IF SO, THE HIGHER PRIORITY TCB ADDRESS IN 'NEW'       34506016
*    IS LEFT UNDISTURBED.  OTHERWISE, THEENQUEUEING TASK'S TCB          34508016
*    ADDRESS IS PLACED IN 'NEW'.                                        34510016
TASKSWTH L     WORKREG1,QELTCB(CURQEL) GET TCB ADDRESS                  34512016
         TM    TCBDISP(WORKREG1),X'FF' IS TASK DISPATCHABLE             34514016
         BCR   7,LINKREG          NO                                    34516016
TASKSWT2 L     WORKREG3,0(WORKREG1)  YES                                34518016
         TM    RBWCF(WORKREG3),X'FF'   IS RB IN WAIT                    34520016
         BCR   7,LINKREG          YES                                   34522016
         L     WORKREG3,NEW       NO. UPDATE 'NEW' ACCORDING            34524016
         L     WORKREG3,0(WORKREG3)    TO PRIORITY                      34526016
         CLC  TCBDSP(ONE,WORKREG3),TCBDSP(WORKREG1) COMPARE PRIOR BJ    34527021
          BH  D0(LINKREG)           BRANCH HI                 BJ 40409  34528021
          BE  TSTSCH                BRANCH EQ                 BJ  40409 34529021
CHNGNEW  EQU   *                                              BJ  40409 34530021
         L     WORKREG3,NEW                                             34532016
         ST    WORKREG1,0(WORKREG3)                                     34534016
         L    CURTCB,LNEW(WORKREG3)  RESORE THE CURRENT TCB PTR BJ40409 34535021
         BCR   15,LINKREG                                               34536016
TSTSCH   EQU   *                                              BJ 40409  34536121
         L     CURTCB,TCBTCB(WORKREG1) SEARCH CHAIN           BJ 40409  34536221
TSTZRO   LTR   CURTCB,CURTCB       BEGINNING WITH             BJ 40409  34536321
         BNZ   COMPTCB             TCB FROM NEW TOP QEL       BJ 40409  34536421
         L     WORKREG3,NEW        RETURN TO MAINLINE         BJ 40409  34536521
         L     CURTCB,LNEW(WORKREG3)                                    34536621
         BR    LINKREG                                        BJ 40409  34536721
COMPTCB  EQU   *                                              BJ 40409  34536821
         CR    CURTCB,WORKREG3     IF EQUAL, NEW TCB IS       BJ 40409  34536921
         BE    CHNGNEW             HIGHER SCHED. PRIORITY     BJ 40409  34537021
         L     CURTCB,TCBTCB(CURTCB) GET NEXT TCB             BJ 40409  34537121
         B     TSTZRO              CONTINUE SEARCH            BJ 40409  34537221
         AGO   .SHRD110                                                 34538016
.SHRD100 ANOP                                                           34540016
*    THE TASK SWITCH ROUTINE IS INVOKED, AND IF THE READY               34560016
*    TASK IS OF HIGHER PRIORITY THAN THE CURRENT TASK,                  34620016
*    'NEW' WILL BE MODIFIED TO REFLECT THE TASK SWITCH.                 34680016
*    NOTE THAT THE TASK WHOSE DEQUEUE REQUEST WE                        34740016
*    ARE NOW HANDLING MAY OR MAY NOT GET CONTROL NEXT.                  34800016
         SPACE 1                                                        34860016
*              PREPARATION FOR TASK SWITCH ROUTINE                      34920016
* 1.REGISTER 10  MUST CONTAIN THE ADDRESS OF THE READY TCB              34980016
* 2.REGISTER 11  CONTAINS THE ADDRESS OF THE TASK SWITCH ROUTINE        35040016
* 3.REGISTER 14  IS THE RETURN REGISTER                                 35100016
         SPACE 2                                                        35160016
TASKSWTH LR    WORKREG2,CURPARM         SAVE POINTER TO PARAMETER LIST  35220016
         L     TASKTCB,QELTCB(CURQEL)   GET TCB ADDRESS                 35280016
TASKSW1  L     WORKREG1,TASKSWT         GET EP OF TASK SWITCH ROUTINE   35340016
         LR    GENREG,RETREG            SAVE RETURN REGISTER            35400016
         BALR  RETREG,WORKREG1          GO TO TASK SWITCH ROUTINE       35460016
         SPACE 2                                                        35520016
*   UPON RETURNING FROM THE TASK SWITCH ROUTINE.                        35580016
         LR    CURPARM,WORKREG2         RESTORE PARAMETER LIST PTR      35640016
         LR    RETREG,GENREG            RESTORE RETURN REGISTER         35700016
         BCR   15,LINKREG               RETURN TO MAINLINE              35760016
.SHRD110 AIF   (NOT &B(2)).SHRDA43                                      35760516
         SPACE 3                                                        35761016
RLSETEST SR    WORKREG1,WORKREG1    CLEAR FOR UCB COUNT           19772 35761319
         IC    WORKREG1,UCBRSCT(ZENREG)  GET UCB RESERVE COUNT    19772 35761619
         CLI   UCBRSCT(ZENREG),ONERESV  IS THIS LAST QEL RESVING  19772 35761919
         BE    RELEASE             YES GO TO RELEASE DEVICE       19772 35762221
         LTR   WORKREG1,WORKREG1   IS RESERVE CNT ZERO                  35762321
         BNZ   NOTRES              NO CONTINUE                          35762421
         LA    WORKREG1,1          PREVENT POSSIBLE DECRMT PAST ZERO    35762521
         B     RELEASE             CHECK POSSIBLE RELEASE         19772 35762621
NOTRES   BCTR  WORKREG1,0          DECRMT UCB RES CNT AND               35762721
         STC   WORKREG1,UCBRSCT(ZENREG)   STORE IT BACK           19772 35762819
         BR    LINKREG             RETURN TO MAINLINE             19772 35763419
RELEASE  CLI   RESINDIC(ZENREG),WAITIND  IS DEVICE RESERVED       19772 35763719
         BC    8,NOTRES            NO, BYPASS RELEASE             19772 35764019
*                                  YES, DO RELEASE                19772 35764319
*  NOTE:  ANY CHANGE TO THE FOLLOWING RELEASE EXCP ROUTINE OR ITS       35765016
*  ASSOCIATED INTERFACE WILL REQUIRE THE SAME CHANGE IN MFT-II          35765216
*  MANUAL PURGE WHICH RESIDES IN MODULE, IEFSD597                       35765416
         EJECT                                                          35766016
*  FUNCTION                                                          *  35766516
*                                                                    *  35767016
*          1. GET 100 BYTES FROM SUBPOOL 0                           *  35767516
*                                                                    *  35768016
*          2. INITIALIZE A DEB, DCB, IOB, ECB, AND CHANNEL PROGRAM   *  35768516
*             IN SUBPOOL 0                                           *  35769016
*                                                                    *  35769516
*          3. ISSUE AN SVC 0 TO CAUSE A DEVICE RELEASE               *  35770016
*                                                                    *  35770516
*          4. WAIT FOR THE RELEASE TO COMPLETE                       *  35771016
*                                                                    *  35771516
*          5. FREE CORE FROM SUBPOOL 0                               *  35772016
*                                                                    *  35772516
*          6. RETURN TO THE DEQUEUE ROUTINE                          *  35773016
*                                                                    *  35773516
*  ENTRY                                                             *  35774016
*                                                                    *  35774516
*          FROM DEQUEUE VIA A BRANCH                                 *  35775016
*                                                                    *  35775516
*  EXIT                                                              *  35776016
*          BACK TO DEQUEUE                                           *  35776516
*                                                                    *  35777016
*  INPUT                                                             *  35777516
*                                                                    *  35778016
*          PTR TO CURRENT TCB IN REG TCBREG                          *  35778516
*          PTR TO UCB OF DEVICE REQUIRING A RELEASE IN REG UCBREG    *  35779016
*  OUTPUT                                                            *  35779516
*          NONE                                                      *  35780016
*                                                                    *  35780516
*  OPERATION                                                         *  35781016
*                                                                    *  35781516
*          SEE COMMENTS AND REMARKS ASSOCIATED WITH CODE             *  35782016
*                                                                    *  35782521
**********************************************************************  35782621
*                                                                    *  35782721
         SPACE 3                                                        35782821
*   OBTAIN CORE REQUIRED FOR THE DCB, ECB, IOB, CCW AND DEB             35782921
         SPACE 1                                                        35783021
         LR    WORKREG2,GENREG     PRESERVE REG 15                19772 35783121
         XR    CURRB,CURRB         CLEAR SP REG                @JK69690 35783221
         TM    TCBFLG,ABTERM       IS TASK ABENDING            @JK69690 35783321
         BZ    NOTABING            NO                          @JK69690 35783421
          GETMAIN  EC,A=RLWKADD,LV=100                         @JK69690 35783521
         L     GMRETREG,RLWKADD    GET ADDR OF GOTTEN CORE     @JK69690 35783621
         LTR   GENREG,GENREG       WAS REQUEST SATISFIED       @JK69690 35783721
         BZ    GOON                YES                         @JK69690 35783821
         LA    CURRB,253           NO-PREPARE FOR SQS REQUEST  @JK69690 35783921
NOTABING    GETMAIN   R,SP=(CURRB),LV=100                      @JK69690 35784021
         SLL   CURRB,24            SHIFT SPID TO HO BYTE       @JK69690 35784121
         OR    FMREG,CURRB         SAVE SPID FOR FREEING       @JK69690 35784221
GOON     EQU   *                                               @JK69690 35784321
         LR    GENREG,WORKREG2     RESTORE WORKREG3               19772 35785819
         BCTR  WORKREG1,0                DECR UCB COUNT AND       19772 35785919
         STC   WORKREG1,UCBRSCT(ZENREG)    STORE IT               19772 35786019
         LR    WORKREG1,GMRETREG    GET ADDRESS OF GOTTEN CORE    19772 35786219
         USING RLDCB,WORKREG1           USE AS BASE FOR DSECT           35786516
*   INITIALIZE DEB                                                      35787016
         XC    0(100,WORKREG1),0(WORKREG1) CLEAR GOTTEN CORE            35787516
         MVI   DENEXT,X'02'             NUMBER OF EXTENTS               35789516
         ST    WORKREG1,DEDCBAD        POINT DEB TO DCB                 35791016
         MVI   DEPKID,X'0F'            SET DEB ID                       35791516
         MVZ   DEPKID,TCBPKF(TCBREG)    SET DEB PROTECT KEY             35792016
         L     RELWK1,CVTPTR      GET ADDR OF CVT                       35792316
         L     RELWK1,CVTXAPG-CVT(RELWK1)  GET ADDR OF IOS APP TABLE    35792616
         ST    RELWK1,DEAPPAD           STORE IN TBL POINTER SLOT       35793016
         MVI   DEEXTSCL,X'04'           SET SIZE OF EXTENTS             35793516
         ST    UCBREG,DEUCBAD-2         SET POINTER TO UCB              35794016
         MVI   DEFM,X'18'               SET FILE MASK                   35794516
         MVC   DEBB(2),UCBSKA+1(UCBREG) SET BIN NUMBER OF DEVICE        35795016
         MVI   DEEND,X'FF'              INIT END C TO 'FF'              35796016
         MVC   DEEND+1(3),DEEND         PROPAGATE 'FF' TO REMAINING CHH 35796516
         LA    RELWK1,X'01'             SET NO. ALLOCATED TRACKS TO 1   35797016
         STH   RELWK1,DETRKS            STORE IN DEB                    35797516
*   INITIALIZE IOB                                                      35798016
         MVI   IOBFL1,X'02'             SET IOB FLAGS                   35798516
         MVI   IOBFL2,X'00'                                             35799016
         ST    WORKREG1,IOBECBAD       SET ADDRESS OF ECB               35799516
         LA    RELWK1,RLCCW             GET ADDRESS OF CHANNEL PROGRAM  35800016
         ST    RELWK1,IOBSTART          POINT IOB TO CHANNEL PROGRAM    35800516
         ST    WORKREG1,IOBDCBAD       POINT IOB TODCB                  35801016
         MVC   IOBSK(4),UCBSKA+1(UCBREG) MOVE IN SEEK ADDRESS FOR UCB   35802021
*                            THIS STMT DELETED THEN REINSERTED @SA63281 35802221
*   INITIALIZE DCB                                                      35802516
         LA    RELWK1,DEAPGV            GET ADDRESS OF DEB              35803016
         ST    RELWK1,DCBDEBAD          POINT DCB TO DEB                35803516
*   INITIALIZE CHANNEL PROGRAM                                          35804016
         MVI   RLCCW,X'03'              NOP COMMAND CODE                35804516
         MVI   RLCCW+4,X'20'            SUPPRESS INCORRECT LENGTH IND.  35805016
         MVI   RLCCW+7,X'EE'            IDENTIFICATION, NORMALLY COUNT  35805516
         LR    WORKREG2,GENREG          PRESERVE WORKREG3               35805716
         EXCP  RLIOB                   ISSUE RELEASE                    35806516
*                                                                       35807016
         WAIT  ECB=RLECB               WAIT FOR RELEASE                 35807516
         SSM   *+1                DISABLE                               35807816
         LR    GMRETREG,WORKREG1   SET UP ADDR FOR FREEMAIN             35808121
         SLDL  GMREG,8             GET SPID IN REG0            @JK69690 35808221
         SRL   FMREG,8             SHIFT ADDR OF CORE BACK     @JK69690 35808321
         LR    GENREG,REG0         SPID TO WORKREG             @JK69690 35808421
         SLL   GENREG,24           SPID IN HO BYTE             @JK69690 35808521
         LA    REG0,100            LENGTH OF ACQUIRED CORE     @JK69690 35808621
         OR    REG0,GENREG         ADDR & SPID TOGETHR FOR FM  @JK69690 35808721
         FREEMAIN   R,LV=(0),A=(1)                             @JK69690 35808828
*                                                                       35808921
         L     CURRB,D0(CURTCB)    RESTORE SVRB POINTER        @JK69690 35809021
         LR    GENREG,WORKREG2          RESTORE WORKREG3                35809216
         BCR   15,LINKREG               RETURN TO CALLER                35809516
.SHRDA43 ANOP                                                           35810016
         EJECT                                                          35820016
***  DETERMINE IF A RESET MUST COMPLETE OPERATION HAS BEEN              35880016
*    REQUESTED.                                                         35940016
*    IF YES, INTERFACE INTERNALLY WITH THE SMC/RMC ROUTINE.             36000016
*    IF NO, RETURN.                                                     36060016
         SPACE 1                                                        36120016
RMCOMP   TM    PARMCDS(TOPPARM),SMC     Q. RMC REQUESTED                36180016
         BCR   8,LINKREG                NO, RETURN                      36240016
         LR    WORKREG3,RETREG          YES, SAVE LINKREG               36300016
         TM    PARMCDS(TOPPARM),SMCSYS  Q. IS SYSTEM RESET REQUESTED    36360016
         BC    8,STEPRMC                NO, BRANCH TO STEP PROCESS      36420016
         AIF   (&B(1)).SHRD120                                          36450016
         LCR   INPUTREG,CURTCB          COMPLIMENT TCB FOR SYSTEM       36480016
         LH    WORKREG0,RMCSYSMK        LOAD SYSTEM MASK                36540016
         NI    TCBFLG1(CURTCB),TCBRSMC  RESET MUST COMPLETE             36600016
MCSTPSYS   EQU    *                                               19054 36604019
         BAL   RETREG,SETRSMC     GO TO SMC ROUTINE                     36608016
         LR    RETREG,WORKREG3                                          36612016
         L     WORKREG3,ADSYMCSW                                        36616016
         OI    1(WORKREG3),X'F0'  RESET SWITCH FOR EXITING FROM SIRB    36620016
         BC    15,ALLOWAX                                               36624016
STEPRMC  NI    TCBFLG1(CURTCB),TCBRJMC TURN OFF SMC FLAG                36628016
         LH    WORKREG0,RMCSTPMK       LOAD STEP MASK             19054 36629019
         LR    INPUTREG,CURTCB                                    19054 36630019
         B     MCSTPSYS                                           19054 36631019
ALLOWAX  NI    TCBFLG(CURTCB),TCBFXR  ALLOW ASYNCHRONOUS EXITS          36632016
         BCR   15,LINKREG         RETURN TO MAINLINE                    36636016
         EJECT                                                          36640016
         AGO   .SHRD130                                                 36644016
.SHRD120 ANOP                                                           36648016
         STATUS RESET,MC,SYSTEM    RESET SYSTEM MUST COMPLETE           36738016
         BC    15,DORMC           BRANCH TO BRANCH                      36828016
STEPRMC  STATUS RESET,MC,STEP      RESET STEP MUST COMPLETE             36918016
DORMC    EQU   *                                                  20021 36927020
         AIF   (NOT &B(3)).TSO0600                                20021 36936020
         SPACE 2                                                  20021 36945020
***                                                               20021 36954020
*    TEST TO SEE IF THE RESET MUST COMPLETE WAS DONE FOR A        20021 36963020
*    TIME-SHARING TASK. IF SO, NOTIFY THE TIME-SHARING DRIVER.    20021 36972020
         TM    PARMCDS(TOPPARM),SMCSYS REQUEST FOR SYSTEM MC?     20021 36981020
         BZ    NOTTSRMC                NO. CONTINUE.              20021 36990020
         TM    TCBTSFLG(CURTCB),TCBTSTSK IS THIS A TIME-          20021 36999020
*                                      SHARING TASK?              20021 37008020
         BZ    NOTTSRMC                NO. CONTINUE.              20021 37017020
         L     REG1,TCBJSCB(CURTCB)    ACCESS JOB STEP CTL BLK    20021 37026020
         USING IEZJSCB,REG1                                       20021 37035020
         LH    REG0,JSCBTJID           OBTAIN TERMINAL JOB ID.    20021 37044020
         DROP  REG1                                               20021 37053020
         SR    REG1,REG1                                          20021 37062020
         TSEVENT  RELMC,TJID=(0)                                  20021 37071020
*                                                                 20021 37080020
***                                                               20021 37089020
NOTTSRMC EQU   *                                                  20021 37098020
         SPACE 2                                                  20021 37107020
.TSO0600 ANOP                                                     20021 37116020
         B     RMCRET                   RETURN TO MAINLINE        20021 37125020
         EJECT                                                          37140016
IEA0EQ01 BALR  BASEREG,0                ESTABLISH BASE                  37200016
         LA    GENREG,IEA0EQ01-IGC048   GET DIFFERENCE                  37260016
         SR    BASEREG,GENREG           RESET BASE                      37320016
         SPACE 1                                                        37380016
         SR    WORKREG0,WORKREG0        INITIALIZE COMPERAND            37440016
         L     WORKREG3,ENTNQDQ                                    REFR 37460018
         USING  NQDQQCB,WORKREG3                                   REFR 37480018
         LA    CURMAJ,HEADQCB           GET ADDRESS OF HEAD             37500016
         DROP   WORKREG3                                           REFR 37530018
         SPACE 1                                                        37560016
LOADMAJ  CL    WORKREG0,NXMAJ(CURMAJ)   Q. IS MAJOR PRESENT             37620016
         BCR   8,RETREG                 NO, RETURN TO CALLER            37680016
         SPACE 1                                                        37740016
REPTEMAJ L     CURMAJ,NXMAJ(CURMAJ)     GET ADDRESS OF MAJOR QCB        37800016
         CL    WORKREG0,FSTMIN(CURMAJ)  Q. IS THERE A MINOR             37860016
         BC    8,FREMAJ                 NO MINOR, DEQUEUE MAJOR         37920016
         SPACE 1                                                        37980016
*    THE SITUATION TESTED FOR ABOVE, A MAJOR QCB WITHOUT A              38040016
*    MINOR QCB, CAN ARISE IF THE TASK WAS ABENDED FROM ENQ.             38100016
*    IF WE FALL THROUGH TO HERE, THERE IS A MINOR QCB.                  38160016
*    NOTE THAT THERE CANNOT BE A MINOR QCB WITHOUT A QEL.               38220016
         SPACE 1                                                        38280016
         LA    WORKREG3,TESTMIN         SET EXIT ADDRESS                38340016
         L     CURMIN,FSTMIN(CURMAJ)    GET THE ADDRESS OF THE MINOR    38400016
REPTEMIN SR    WORKREG1,WORKREG1        INITIALIZE INDICATOR            38460016
         L     CURQEL,FSTQEL(CURMIN)    GET FIRST QEL                   38520016
         LTR   CURQEL,CURQEL . IS THERE A QEL                BJ A55316  38570021
         BZ    TESTMIN                                       BJ A55316  38575021
         CL    CURTCB,QELTCB(CURQEL)    Q. SHOULD IT BE DEQUEUED        38580016
         LR    WORKREG4,CURQEL          YES, SAVE ADDRESS OF QEL  M1336 38640020
         BC    8,TSTNXT                 YES, TAKE BRANCH                38700016
TSTSHR   TM    QELCDS(CURQEL),NEGCODE   Q. IS IT SHARED                 38760016
         BC    7,SKIP1                  YES                             38820016
         BALR  WORKREG1,0               NO, SET INDICATOR               38880016
SKIP1    BAL   LINKREG,ISNXT            GO GET NEXT                     38940016
         BCR   15,WORKREG3              EXIT, NO MORE QEL'S             39000016
         BCR   0,0                      PAD FOR VECTOR RETURN           39060016
         LR    CURQEL,WORKREG2          XFR QEL ADDRESS                 39120016
         CL    CURTCB,QELTCB(CURQEL)    Q. SHOULD IT BE DEQUEUED        39180016
         BC    7,TSTSHR                 NO, TEST CODE AND GET NEXT      39240016
         LR    WORKREG4,CURQEL          YES, SAVE ADDRESS OF QEL  M1336 39300020
         AIF   (NOT &B(2)).SHRDA54                                      39307016
         LTR   WORKREG1,WORKREG1       Q. IS INDICATOR ON               39315016
         BC    7,REMVE                 YES REMOVE THE QEL               39320016
         TM    QELCDS(CURQEL),RESERVED  NO IS QEL A RESERVE             39325016
         BC    8,SKIP2                 NO TREAT NORMALLY                39330016
         LR    GENREG,UCBREG            SAVE WORKREG3                   39332016
         L     UCBREG,QELUCB(CURQEL)    GET UCB POINTER                 39333016
         TM    UCBID(UCBREG),UCBIDMSK   UCB ADDR IN THE QEL       4531  39333420
         BNO   NOTUCB              NO, THE SVRB IS STILL THERE    4531  39333820
         CLI   UCBNAME(UCBREG),UCBNMEMK IS THERE A DEV NAME       4531  39333920
         BNH   NOTUCB              NO, THE SVRB STILL THERE       4531  39336820
         BAL   LINKREG,RLSETEST         DECREMENT UCB COUNT             39339720
NOTUCB   LR    CURQEL,WORKREG4      RESTORE SAVED QEL POINTER M1336     39342620
         LR    WORKREG3,GENREG          RESTORE WORKREG3                39345520
         SR    WORKREG1,WORKREG1        RESTORE INDICATOR TO ZERO       39348420
SKIP2    BAL   LINKREG,ISNXT           GO GET NEXT                      39351320
         AGO   .SHRDA55                                                 39354220
.SHRDA54 ANOP                                                           39357120
         LTR   WORKREG1,WORKREG1        Q. IS INDICATOR ON              39360016
         BC    7,REMVE                  YES, GO DIRECTLY TO DEQUEUE IT  39420016
         BAL   LINKREG,ISNXT            GO GET NEXT                     39480016
.SHRDA55 ANOP                                                           39510016
         BC    15,REMVE                 NO MORE QELS, REMOVE LAST       39540016
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           39600016
         BC    7,REMVE                  NO, GO DIRECTLY TO REMOVE       39660016
         LTR   WORKREG1,WORKREG1        Q. IS INDICATOR ON              39720016
         BC    7,LOOP1                  YES, RIPPLE DOWN AND ADJUST     39780016
         TM    QELCDS(CURQEL),NEGCODE   Q. IS THIS QEL SHARED           39840016
         BC    1,REMVE                  YES, GO REMOVE IT               39900016
LOOP1    BAL   LINKREG,ISNXT            GO GET NEXT                     39960016
         BC    15,REMVE                 NO MORE QELS, DEQUEUE CURRENT   40020016
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           40080016
         BC    7,REMVE                  NO, RIPPLE DONE, DQ CURRENT     40140016
         L     GENREG,SVRBPTR(WORKREG2) GET SVRB ADDRESS                40260016
         LA    LINKREG,LOOP1            SET RETURN REGISTER             40320016
REDUCE   DS    0H                                                 20021 40338020
         LR    CURQEL,WORKREG2          XFR QEL ADDR FOR INTERFCE 39399 40338420
         AIF   (NOT &B(3)).TSO0650                                20021 40340020
         TM    QELTJID0(WORKREG2),ANYON QEL FOR TIME-SHARING USER 20021 40350020
         BZ    DECREMET            NO DECREMENT COUNT             20021 40360020
*                                       FLAG QEL FOR SVRB         20021 40361020
         OI    QELCDS(WORKREG2),QELRBWT PROCESSING AFTER SWAP     20021 40362020
         LH    REG0,QELTJID0(WORKREG2) GET TIME-SHARING USER'S    20021 40430020
         IC    REG0,QELTJID1(WORKREG2) IDENTIFICATION             20021 40431020
         N     REG0,TSDRVMSK       CLEAR HIGH ORDER BYTE          20021 40432020
         TSEVENT USERRDY,TJID=(0)                                 20021 40434020
         BR    LINKREG             EXIT FOR DELAYED SVRB PROC     20021 40434120
DECREMET DS    0H                                                 20021 40435020
.TSO0650 ANOP                                                     20021 40436020
         CLI   RBWCF(GENREG),WAITIND Q. IS WAIT COUNT ZERO              40437020
         BCR   8,LINKREG                YES, DON'T DECREMENT            40440016
         IC    TASKTCB,RBWCF(GENREG)    GET WAIT COUNT                  40500016
         BCTR  TASKTCB,0                DECREMENT IT                    40560016
         STC   TASKTCB,RBWCF(GENREG)    PUT IT BACK                     40620016
         AIF   (NOT &B(2)).SHRDA51                                      40624016
         TM    QELCDS(CURQEL),RESERVED  Q. IS THIS QEL RESERVE QEL      40628016
         BC    8,NORESV                NO DO NOT INCREMENT UCB COUNT    40632016
         L     TASKTCB,QELUCB(CURQEL)   YES GET SVRB PTR   BJ 60112     40636021
         L     WORKREG2,RBSAVUCB(TASKTCB) GET PARM POINTER BJ 60112     40640021
         ST    WORKREG2,QELUCB(CURQEL)  SET UCB POINTER IN QEL          40647016
         SR    WORKREG1,WORKREG1       CLEAR REG FOR IC                 40648016
         IC    WORKREG1,UCBRSCT(WORKREG2) GET UCB RESERVE COUNT         40652016
         LA    WORKREG1,1(WORKREG1)    BY ONE AND                       40656016
         STC   WORKREG1,UCBRSCT(WORKREG2) REPLACE NEW RESERVE COUNT     40660016
         LR    WORKREG2,CURQEL          RESTORE QEL SAVE REG            40662016
NORESV   CLI   RBWCF(GENREG),WAITIND    Q. IS IT STILL WAITING          40664016
         AGO   .SHRDA52                                                 40668016
.SHRDA51 ANOP                                                           40672016
         CLI   RBWCF(GENREG),WAITIND    Q. IS IT STILL WAITING          40680016
.SHRDA52 ANOP                                                           40710016
         BCR   7,LINKREG                YES, CONTINUE LOOP              40740016
         L     TASKTCB,QELTCB(WORKREG2) GET TCB ADDRESS                 40800016
         BC    15,TASKSW1               GO TO TASK SWITCH INTERFACE     40860016
         AIF   (NOT &B(2)).SHRDA48                                      40866016
TSTNXT   TM    QELCDS(CURQEL),RESERVED  Q. IS THIS QEL RESERVE QEL      40872016
         BC    8,TSTNXTBB               NO - TREAT NORMALLY             40876016
         NI    QELCDS(CURQEL),X'BF'     YES SET NON-RESERVE FOR RELEASE 40880016
         LR    GENREG,UCBREG            SAVE WORKREG3                   40884016
         L     UCBREG,QELUCB(CURQEL)    GET UCB POINTER                 40888016
         BAL   LINKREG,RLSETEST         DECREMENT UCB COUNT             40892016
         LR    CURQEL,WORKREG4          RESTORE SAVED QEL POINTER M1336 40894020
         LR    WORKREG3,GENREG          RESTORE WORKREG3                40896016
TSTNXTBB TM    QELCDS(CURQEL),NEGCODE   Q. IS THE QEL SHARED            40902016
         AGO   .SHRDA49                                                 40908016
.SHRDA48 ANOP                                                           40914016
TSTNXT   TM    QELCDS(CURQEL),NEGCODE   Q. IS THE QEL SHARED            40920016
.SHRDA49 ANOP                                                           40950016
         BC    1,TSTNXT1                YES, TAKE BRANCH                40980016
         BAL   LINKREG,ISNXT            GO GET NEXT                     41040016
         BC    15,REMVE                 NO MORE, REMOVE CURRENT         41100016
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           41160016
         BC    8,LOOP1                  YES, GO RIPPLE DOWN             41220016
DECR1    L     GENREG,SVRBPTR(WORKREG2) GET SVRB ADDRESS                41280016
         LA    LINKREG,REMVE            LOAD RETURN ADDRESS             41340016
         BC    15,REDUCE                GO ADJUST WAIT COUNT AND        41400016
*                                       INVOKE TASK SWITCH              41460016
TSTNXT1  BAL   LINKREG,ISNXT            GO GET NEXT                     41520016
         BC    15,REMVE                 NO MORE, DEQUEUE THIS QEL       41580016
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           41640016
         BC    8,REMVE                  YES, GO TO DEQUEUE              41700016
         BC    15,DECR1                 NO, DECR THEN DEQUEUE           41760016
ISNXT    SR    GENREG,GENREG            INITIALIZE TO SHARED            41820016
         L     WORKREG2,NXQEL(CURQEL)   GET NEXT QEL                    41880016
         LA    WORKREG2,0(WORKREG2)     CLEAR HIGH ORDER BYTE           41940016
         LTR   WORKREG2,WORKREG2        Q. IS THERE A QEL               42000016
         BCR   8,LINKREG                NO, RETURN TO NEXT IN LINE      42060016
         TM    QELCDS(WORKREG2),NEGCODE YES, NOW TEST FOR SHARED        42120016
         BC    1,4(LINKREG)             REQUEST IS SHARED, RETURN       42180016
         BALR  GENREG,0                 SET INDICATOR EXCLUSIVE         42240016
         BC    15,4(LINKREG)            AND RETURN                      42300016
         SPACE 1                                                        42360016
***  GO DEQUEUE THE QEL                                                 42420016
REMVE    LR    CURQEL,WORKREG4          RESTORE QEL REGISTER      M1336 42480020
         LR    WORKREG1,CURQEL          SET FOR INTERFACE               42540016
         BAL   LINKREG,DECTCB           DECREMENT TCB COUNT        3447 42570018
         BAL   LINKREG,DQELEMNT         AND GO DEQUEUE IT               42600016
***  FREE THE SPACE FOR THE QEL                                         42660016
         LA    WORKREG0,QELSIZE         OBTAIN QEL SIZE                 42720016
         LR    FMREG,CURQEL             LOAD ADDRESS FOR FREEMAIN       42780016
         BAL   LINKREG,FREEUP           GO TO FREEMAIN INTERFACE        42840016
         BCR   15,WORKREG3              EXIT                            42960016
         SPACE 1                                                        43020016
***  SEE IF THE MINOR QCB CAN BE FREED                                  43080016
         SPACE 1                                                        43140016
TESTMIN  SR    WORKREG0,WORKREG0        CLEAR FOR TEST                  43200016
         L     LINKREG,FSTQEL(CURMIN) GET FIRST QEL               20021 43230020
         LA    LINKREG,0(LINKREG)  CLEAR HIGH ORDER BYTE          20021 43260020
         CR    LINKREG,WORKREG0    IS THERE A QEL                 20021 43290020
         BC    7,LOADMIN                YES, MINOR CAN'T BE FREED       43320016
         LA    CURPARM,ELEVEN(CURMIN)   GET MINOR ADDRESS PLUS 11       43380016
         BAL   LINKREG,ADDMINOR         GET MINOR SIZE                  43440016
         BAL   LINKREG,DQMINOR          AND GO DEQUEUE IT               43500016
         LR    WORKREG0,SUMREG          XFR SIZE OF MINOR               43560016
         LR    FMREG,CURMIN             LOAD ADDRESS FOR FREEMAIN       43620016
         BAL   LINKREG,FREEUP           GO TO FREEMAIN INTERFACE        43680016
         SPACE 3                                                        43740016
***  SEE IF THERE ARE MORE MINORS TO SEARCH                             43800016
         SPACE 1                                                        43860016
LOADMIN  L     CURMIN,NXMIN(CURMIN)     GET NEXT MINOR                  43920016
         CLR   WORKREG0,CURMIN          Q. IS NEXT MINOR PRESENT        43980016
         BC    7,REPTEMIN               YES, TRY TO FIND A QEL          44040016
         SPACE 3                                                        44100016
***  SEE IF THE MAJOR CAN BE FREED                                      44160016
         SPACE 1                                                        44220016
         CL    WORKREG0,FSTMIN(CURMAJ)  Q. DOES MAJOR POINT TO MINOR    44280016
         BC    7,LOADMAJ                YES, GET THE NEXT ONE           44340016
FREMAJ   LR    WORKREG1,CURMAJ          GET ADDRESS FOR DEQUEUEING      44400016
         BAL   LINKREG,DQELEMNT         AND GO TO DEQUEUE               44460016
         SPACE 1                                                        44520016
         LA    WORKREG0,MAJSIZE         GET SIZE OF MAJOR               44580016
         LR    FMREG,CURMAJ             GET ADDRESS FOR FREEMAIN        44640016
*    THE NEXT INSTRUCTION PREVENTS PICKING UP AN INVALID LINK FIELD.    44700016
         L     CURMAJ,PREVMAJ(CURMAJ)   GET PREVIOUS MAJOR QCB          44760016
         LA    LINKREG,LOADMAJ          LOAD RETURN ADDRESS             44820016
         BC    15,FREEUP                GO TO FREEMAIN INTERFACE        44880016
         EJECT                                                          44940016
.SHRD130 ANOP                                                           44970016
***  DEQUEUE SUBROUTINE                                                 45000016
*    THIS ROUTINE WILL DEQUEUE THE MAJOR QCB'S AND QEL'S                45060016
*    INPUT-    WORKREG1-ADDRESS OF ELEMENT TO BE DEQUEUED               45120016
*    USES--    WORKREG1,GENREG                                          45180016
         SPACE 1                                                        45240016
DQELEMNT L     GENREG,0(WORKREG1)       GET ADDRESS OF NEXT ELEMENT     45300016
         LA    GENREG,0(GENREG)         CLEAR HIGH ORDER BYTE           45360016
         LTR   GENREG,GENREG            Q. IS NEXT ELEMENT PRESENT      45420016
         BC    8,ONLYONE                NO, SKIP NEXT INST              45480016
         MVC   PREVIOUS(3,GENREG),PREVIOUS(WORKREG1)                    45540016
ONLYONE  L     GENREG,4(WORKREG1)       GET PREVIOUS FIELD              45600016
         MVC   ONE(3,GENREG),ONE(WORKREG1) MOVE IN NEXT FIELD           45660016
         BCR   15,LINKREG               RETURN                          45720016
         SPACE 3                                                        45780016
***  DEQUEUE SUBROUTINE                                                 45840016
*    THIS ROUTINE WILL DEQUEUE MINOR QCB'S                              45900016
*    INPUT-    CURMIN-ADDRESS OF MINOR TO BE DEQUEUED                   45960016
*    USES--    CURMIN,GENREG                                            46020016
         SPACE 1                                                        46080016
DQMINOR  L     GENREG,NXMIN(CURMIN)     GET ADDRESS OF NEXT MINOR       46140016
         LTR   GENREG,GENREG            Q. IS NEXT MINOR PRESENT        46200016
         BC    8,SINGLE                 NO TAKE BRANCH                  46260016
         MVC   PREVMIN1(3,GENREG),PREVMIN1(CURMIN) .  UPDATE PTR  M0852 46320020
SINGLE   L     GENREG,PREVMIN(CURMIN)   LOAD PREVIOUS MINOR             46380016
         MVC   NXMIN(4,GENREG),NXMIN(CURMIN)  UPDATE NEXT FIELD         46440016
         BCR   15,LINKREG               RETURN TO MAIN LINE             46500016
         SPACE 3                                                        46560016
***  DECREMENT ENQUEUE COUNT FIELD IN TCB.                              46620016
*    INPUT-    CURTCB-ADDRESS OF CURRENT TCB                            46680016
*    USES--    GENREG                                                   46740016
         SPACE 1                                                        46800016
DECTCB   IC    GENREG,TCBCT(CURTCB)     GET TCB COUNT                   46860016
         BCTR  GENREG,0                 DECREMENT IT                    46920016
         STC   GENREG,TCBCT(CURTCB)     PUT IT BACK                     46980016
         AIF   (NOT &B(1)).SHRD135                                      46990016
         STATUS RESET,NR,'S'       DECREMENT NONROLLOUTABLE COUNT       47000016
.SHRD135 ANOP                                                           47010016
         BCR   15,LINKREG               RETURN                          47040016
         EJECT                                                          47100016
*    FREEUP ROUTINE                                                     47160016
*                                                                       47220016
*   THIS ROUTINE FREES CORE FOR MAJOR AND MINOR QCBS, AND QELS.         47280016
*  THIS ROUTINE ENVOKES THE FREEMAIN SVC ROUTINE. IT FURTHER            47340016
*  EXPECTS THAT REGISTER 0 HAS BEEN INITIALIZED WITH THE NUMBER         47400016
*  OF BYTES TO BE FREED.  REGISTER 1 MUST ALSO CONTAIN THE ADDRESS      47460016
*  OF THE BLOCK TO BE FREED.                                            47520016
FREEUP   O     WORKREG0,SP255          INDICATE SUBPOOL                 47580016
         AIF   (&B(1)).SHRD140                                          47590016
         FREEMAIN R,LV=(0),A=(1)                                        47600016
         AGO   .SHRD150                                                 47610016
.SHRD140 ANOP                                                           47620016
         L     WORKREG1,ENTNQDQ                                    REFR 47626018
         USING   NQDQQCB,WORKREG1                                  REFR 47632018
         STM   RETREG,GENREG,SAVEA     SAVE GRS ACROSS FREEMAIN    0205 47640016
         ST    WORKREG3,SAVEB                                      0205 47700016
         L     WORKREG3,16             INITIALIZE CVT REG          0205 47760016
         L     GENREG,ADFREE                                       0205 47820016
         BALR  RETREG,GENREG           GO TO FREEMAIN              0205 47880016
         LM    RETREG,GENREG,SAVEA      RESTORE GRS                0205 47940016
         L     WORKREG3,SAVEB                                      0205 48000016
         DROP   WORKREG1                                           REFR 48010018
.SHRD150 ANOP                                                           48030016
         SR    WORKREG0,WORKREG0       INITIALIZE REG TO 0              48060016
         BCR   15,LINKREG              RETURN                           48120016
         SPACE 3                                                        48180016
DQERR1   TM    PARMCDS(TOPPARM),HAVE    Q. IS RETURN REQUESTED          48240016
         BC    8,DRRX1                  NO, ABEND THE TASK              48300016
         MVI   RETURN(CURPARM),HAS      YES, GIVE RETURN CODE           48360016
         BC    15,NXTINPUT              AND GET NEXT ELEMENT            48420016
        SPACE 3                                                         48480016
DQERR2  L     CURQEL,NXQEL(CURQEL)     GET ADDRESS OF NEXT              48540016
        LA    CURQEL,0(CURQEL)         CLEAR HIGH ORDER BYTE            48600016
        LTR   CURQEL,CURQEL            Q. IS THERE A NEXT QEL           48660016
        BC    8,DQERR1                 NO, TEST FOR ABEND OR RETURN     48720016
        CL    CURTCB,QELTCB(CURQEL)    Q. DOES TCB ADDRESS MATCH        48780016
        BC    7,DQERR2                 NO, TRY NEXT                     48840016
        SPACE 3                                                         48900016
DQERR2A  TM    PARMCDS(TOPPARM),HAVE    Q. IS RETURN REQUESTED          48960016
         BC    8,DRRX5                  NO, ABEND THE TASK              49020016
         MVI   RETURN(CURPARM),INUSE    YES, GIVE RETURN CODE           49080016
         BC    15,NXTINPUT              AND GET NEXT ELEMENT            49140016
         EJECT                                                          49200016
         AIF   (NOT &B(1)).SHRD160                                      49230016
***  AUTO PURGE ROUTINE                                                 49260016
*    THIS ROUTINE IS ENTERED FROM ENQ WHEN A TASK SCHEDULED             49320016
*    FOR ABTERM (BYTE 29, BIT 0=1) ISSUES AN ENQ.  QEL'S                49380016
*    ASSOCIATED WITH ANY TASK IN THE SAME FAMILY WILL                   49440016
*    BE REMOVED.  THE INITIATOR IS NOT INCLUDED.                        49500016
*    INPUT-    CURMAJ-ADDRESS OF THE MAJOR QCB                          49560016
*              CURMIN-ADDRESS OF THE MINOR QCB                          49620016
*              CURTCB-ADDRESS OF THE CURRENT TCB                        49680016
*              CURRB-ADDRESS OF TOP RB                           A29065 49710019
         SPACE 1                                                        49740016
GRS3     EQU   XSAV+8                   REGISTER SAVE IN SVRB           49800016
ABENDTCB EQU   XSAV+16            SAVEAREA FOR TOP ABENDING TCB  A29065 49830019
         SPACE 3                                                        49860016
AUTOPRG  LR    WORKREG3,CURTCB          XFR TCB ADDRESS                 49920016
PRGLOOP  L     WORKREG1,TCBOTC(WORKREG3) GET MOTHER TCB                 49980016
         ST    WORKREG3,ABENDTCB(CURRB)  SAVE TOP ABENDING TCB   A29065 50010019
         TM    TCBFLG(WORKREG1),ABTERM  Q. IS IT SCHEDULED FOR ABEND    50040016
         BC    8,GETFST                 NO, EXIT FROM LOOP WITH         50100016
*                                           HIGHEST TASK IN FAMILY      50160016
*                                           TREE SCHEDULED FOR ABEND    50220016
         LR    WORKREG3,WORKREG1        XFR ABENDING TASK               50280016
         BC    15,PRGLOOP               AND GO BACK                     50340016
         SPACE 1                                                        50400016
GETFST   L     CURQEL,FSTQEL(CURMIN)    GET THE FIRST QEL               50460016
         LA    CURQEL,0(CURQEL)    CLEAR HI ORDER BYTE            20021 50490020
         LTR   CURQEL,CURQEL            Q. IS THERE A QEL               50520016
         BC    8,PRGRETA               NO, EXIT FROM AUTOPRG       0445 50580016
         SPACE 3                                                        50640016
***  IF WE FALL THROUGH THERE IS A POSSIBILITY OF PURGING               50700016
         SPACE 1                                                        50760016
         STM   WORKREG3,CURTCB,GRS3(CURRB)  SAVE THE REGISTERS          50820016
         LR    CURTCB,WORKREG3          XFR REGS                        50880016
         ST   WORKREG4,SEPLP(CURRB) . SAVE PARM LIST PTR         3123   50930020
         ST    CURPARM,SEPLP1(CURRB)  . SAVE REG 10          BJ A50045  50935021
         BAL   WORKREG3,REPTEMIN        GO TO DEQUEUEING ROUTINE        50940016
         L    WORKREG4,SEPLP(CURRB) .  RESTORE THE PARM LIST PTR 3123   50990020
         L     CURPARM,SEPLP1(CURRB) . RESTORE REG 10        BJ A50045  50995021
         LM    WORKREG3,CURTCB,GRS3(CURRB)  RESTORE REGISTERS           51000016
         SPACE 3                                                        51060016
***  IF WE FALL THROUGH ALL QELS HAVE BEEN COMPARED                     51120016
*    WITH THE PRESENT TCB.                                              51180016
*    WE ARE NOW GOING TO ATTEMPT TO FIND ANOTHER DESCENDENT             51240016
         SPACE 1                                                        51300016
FINDTCB  LR    WORKREG2,WORKREG3        XFR TCB ADDRESS                 51360016
         L     WORKREG3,TCBLTC(WORKREG2) GET DAUGHTER                   51420016
TESTTCB  LTR   WORKREG3,WORKREG3        Q. IS THERE A TCB               51480016
         BC    7,GETFST                 YES, RETURN WITH IT             51540016
         L     WORKREG3,TCBNTC(WORKREG2) GET SISTER                     51600016
         C     WORKREG2,ABENDTCB(CURRB)  Q. ARE WE FINISHED      A29065 51660019
         BC    8,PRGRET                 YES, EXIT FROM AUTOPRG          51720016
         L     WORKREG2,TCBOTC(WORKREG2) GET MOTHER                     51780016
         BC    15,TESTTCB               GO BACK THROUGH LOOP            51840016
         TITLE 'ENQ SERVICE ROUTINE'                                    51900016
PRGRET   L     CURQEL,FSTQEL(CURMIN)    GET FIRST QEL                   51960016
         LA    CURQEL,0(CURQEL)    CLEAR HIGH ORDER BYTE          20021 51990020
         LTR   CURQEL,CURQEL            Q. ARE ANY QEL'S LEFT           52020016
         BC    7,ENQTOP2A               YES, RETURN TO MAINLINE         52080016
PRGRETA  LR    CURQEL,CURMIN           SET REG FOR CREATE RTN      0445 52140016
         BC    15,CALC3                 GO TO CREATE                    52200016
.SHRD160 ANOP                                                           52230016
         EJECT                                                          52240020
***                                                               ***   52250020
***  ESTABLISH ADDRESSABILITY FOR THE ENQUEUE SERVICE ROUTINE     ***   52260020
***                                                               ***   52310020
         SPACE 3                                                        52320020
IGC048   CSECT                                                          52380016
         CNOP  0,8                                                      52440016
         SPACE 3                                                        52490020
IGC056   BALR  BASEREG,0                                                52500016
         LA    GENREG,IGC056-IGC048     RESET BASE REGISTER             52560016
         SR    BASEREG,GENREG           FOR ENQ                         52620016
         SPACE 3                                                        52680016
***  HOUSEKEEPING                                                       52740016
         SPACE 1                                                        52800016
         AIF   (&B(1)).SHRD170                                          52810016
         LA    TOPPARM,0(INPUTREG)  SAVE POINTER TO FIRST ELEMENT       52820016
         AGO   .SHRD180                                                 52830016
.SHRD170 ANOP                                                           52840016
         LR    TOPPARM,INPUTREG         SAVE POINTER TO TOP OF LIST     52860016
.SHRD180 ANOP                                                           52890016
         LR    CURPARM,TOPPARM          INITIALIZE CURRENT PARM REG     52920016
         SPACE 3                                                        52980016
***  INVOKE VALIDITY CHECK ROUTINE.                                     53040016
         SPACE 1                                                        53100016
         BAL   LINKREG,CHKLIST          GO TO VALIDITY CHECK INTERFACE  53160016
         SPACE 1                                                        53220016
         AIF   (NOT &B(1)).SHRD190                                      53250016
***  VALIDITY CHECK NO GOOD, ABEND THE REQUESTOR.                       53280016
         BC    15,ERRX4                 BAD RETURN, ABEND THE TASK      53340016
         BC    15,ERRX3                 BAD RETURN, ABEND THE TASK      53400016
         BC   15,ERRX2                  BAD RETURN, ABEND THE TASK      53460016
*    RETURN TO NEXT INSTRUCTION IF LIST OK                              53520016
         SPACE 3                                                        53580016
.SHRD190 ANOP                                                           53610016
***  START OF ENQUEUE PROCEDURE.                                        53640016
*    DETERMINE WHAT LEVEL OF CREATION IS NECESSARY TO                   53700016
*    SATISFY EACH ELEMENT IN THE USERS PARAMETER LIST.                  53760016
         SPACE 1                                                        53820016
*    FIRST STEP.                                                        53880016
*    TRY TO FIND A MAJOR QCB ON THE QUEUE OF MAJORS                     53940016
*    WITH THE SAME NAME AS THAT PASSED IN                               54000016
*    THE USERS PARAMETER LIST.                                          54060016
         SPACE 1                                                        54120016
         SPACE 1                                                        54180016
ENQTOP   BAL   LINKREG,FINDMAJ          GO TO INITIALIZE CURRENT MAJOR  54240016
         LTR   CURMAJ,CURMAJ            Q. DOES A MAJOR QCB OF THE      54300016
*                                          SAME NAME ALREADY EXIST      54360016
         BC    2,ENQTOP1                YES, SEE IF THERE IS A MINOR    54420016
         TM    PARMCDS(TOPPARM),TEST    Q. IS THIS AN INQUIRY           54480016
         BC    1,RET0                   YES, GIVE RETURN, DON'T CREATE  54540016
         BC    8,CALC1                  RET=0, DON'T SET CODE, CREATE   54600016
         TM    PARMCDS(TOPPARM),HAVE    Q. IS THIS RET=CHNG      20021  54620020
         BZ    RET8CHNG                 YES, RC=8,DON'T CREATE   20021  54640020
         MVI   RETURN(CURPARM),AVAIL    GIVE ''AVAILABLE'' CODE         54660016
         SPACE 3                                                        54720016
***  IF ENTERED HERE A MAJOR QCB WAS NOT FOUND.                         54780016
*    A MAJOR QCB, A MINOR QCB, AND A QEL                                54840016
*    WILL BE CREATED AND CHAINED TO                                     54900016
*    EXISTING ELEMENTS.                                                 54960016
         SPACE 1                                                        55020016
CALC1    LA    GMREG,MAJSIZE            SET LENGTH FOR A MAJOR          55080016
         BAL   LINKREG,GETCORE          AND GO GET IT                   55140016
         BAL   LINKREG,CREATE3          GO TO CREATE IT                 55200016
         SPACE 3                                                        55260016
***  IF ENTERED HERE EITHER                                             55320016
*    1-A MAJOR QCB HAS JUST BEEN CREATED, OR                            55380016
*    2-A MAJOR QCB WAS PREVIOUSLY CREATED.                              55440016
*    IN EITHER CASE NO MINOR QCB WAS FOUND                              55500016
*    A MINOR QCB AND A QEL WILL BE CREATED                              55560016
*    AND CHAINED TO THE MAJOR QCB.                                      55620016
         SPACE 1                                                        55680016
CALC2    BAL   LINKREG,ADDMINOR         CALCULATE CORE FOR MINOR        55740016
         LR    GMREG,SUMREG             XFR IT                          55800016
         BAL   LINKREG,GETCORE          AND GO GET IT                   55860016
         BAL   LINKREG,CREATE2          GO CREATE THE MINOR             55920016
         SPACE 3                                                        55980016
***  A MAJOR QCB AND A MINOR QCB ARE IN EXISTENCE.                      56040016
*    A QEL TO REPRESENT THE REQUESTOR ON THE QUEUE                      56100016
*    WILL NOW BE CREATED AND PLACED AT THE BOTTOM OF THE                56160016
*    QUEUE ELEMENT QUEUE                                                56220016
         SPACE 1                                                        56280016
CALC3    LA    GMREG,QELSIZE            SET LENGTH FOR A QEL            56340016
         BAL   LINKREG,GETCORE          GO GET CORE                     56400016
         BC    15,CREATE1               GO CREATE THE QEL               56460016
         SPACE 3                                                        56520016
***  A MAJOR QCB OF THE SAME NAME AS THAT PASSED                        56580016
*    IN THE PARAMETER LIST WAS FOUND.  WE WILL                          56640016
*    NOW ATTEMPT TO FIND A MINOR QCB WITH                               56700016
*    THE SAME NAME AND ATTRIBUTES AS THAT PASSED                        56760016
*    IN THE LIST                                                        56820016
         SPACE 1                                                        56880016
ENQTOP1  BAL   LINKREG,FINDMIN          GO TO INITIALIZE CURRENT MINOR  56940016
         LTR   CURMIN,CURMIN            Q. DOES A MINOR QCB OF THE      57000016
*                                          SAME NAME ALREADY EXIST      57060016
         BC    2,ENQTOP2                YES, FIND QEL                   57120016
         TM    PARMCDS(TOPPARM),TEST    Q. IS THIS AN INQUIRY           57180016
         BC    1,RET0                   YES, GIVE RETURN, DON'T CREATE  57240016
         BC    8,CALC2                  RET=0, DON'T SET CODE, CREATE   57300016
         TM    PARMCDS(TOPPARM),HAVE    Q. IS THIS RET=CHNG      20021  57320020
         BZ    RET8CHNG                 YES, RC=8,DON'T CREATE   20021  57340020
         MVI   RETURN(CURPARM),AVAIL    GIVE ''AVAILABLE'' CODE         57360016
         BC    15,CALC2                 GO MAKE A MINOR                 57420016
         SPACE 3                                                        57480016
***  A MAJOR QCB AND A MINOR QCB WITH THE SAME                          57540016
*    NAMES AND ATTRIBUTES AS THOSE PASSED IN                            57600016
*    THE PARAMETER LIST WERE FOUND.                                     57660016
*    THIS SECTION OF CODE DOES THE FOLLOWING                            57720016
*    1-SEE IF THE TASK IS SCHEDULED FOR ABTERM.                         57780016
*      IF IT IS GO TO THE 'AUTO PURGE' ROUTINE                          57840016
*      AND PURGE THE QUEUE OF ANY QELS FOR THE TASK                     57900016
*    (ABOVE FUNCTION DOES NOT EXIST FOR MFT-II).                        57930016
*    2-TEST IF THE QUEUE CONTAINS A PREVIOUS                            57960016
*      REQUEST FROM THE SAME TCB                                        58020016
*      IF IT DOES EITHER GIVE A RETURN CODE OR                          58080016
*      ABEND THE REQUESTOR DEPENDING ON THE 'RET'                       58140016
*      SPECIFIED                                                        58200016
*    3-DETERMINE WHETHER OR NOT TO PUT THE                              58260016
*      SVRB IN A WAIT STATE.                                            58320016
*      IF THIS IS A SHARED REQUEST, AND ALL                             58380016
*      PREVIOUS REQUESTS ON THE QUEUE ARE                               58440016
*      SHARED, WE WILL NOT INCREMENT THE SVRB                           58500016
*      WAIT COUNT.                                                      58560016
*      ALL OTHER CONDITIONS WILL RESULT IN                              58620016
*      INCREMENTING THE WAIT COUNT BY ONE.                              58680016
*    4-RETURN CODES MAY OR MAY NOT BE GIVEN                             58740016
*      DEPENDING ON THE 'RET' SPECIFIED                                 58800016
         SPACE 1                                                        58860016
         AIF   (&B(1)).SHRD200                                          58870016
ENQTOP2  DS    0H                                                       58880016
         AGO   .SHRD210                                                 58890016
.SHRD200 ANOP                                                           58900016
ENQTOP2  TM    TCBFLG(CURTCB),ABTERM    Q. IS TCB SCHEDULED FOR ABTERM  58920016
         BC    7,AUTOPRG                YES, PURGE QEL'S FOR JOB STEP   58980016
.SHRD210 ANOP                                                           59010016
ENQTOP2A BAL   LINKREG,FINDQEL          GO VALIDATE REQUEST             59040016
         LTR   CURQEL,CURQEL            Q. HAS SAME TASK ALREADY        59100016
*                                          REQUESTED RESOURCE           59160016
         BC    4,ABTEST                 YES, TEST FOR ABEND EXIT        59220016
         TM    PARMCDS(TOPPARM),HAVE    Q. IS BIT 7 ON           20021  59230020
         BO    ENQTOP2B                 YES, NOY CHNG OR NONE    20021  59240020
         TM    PARMCDS(TOPPARM),CHNG    Q. IS THIS RET=CHNG      20021  59250020
         BO    RET8CHNG                 YES, RC=8,DON'T CREATE   20021  59260020
ENQTOP2B LTR   WORKREG2,WORKREG2        ARE ALL QEL'S MINUS      20021  59300020
         BC    7,ENQT4                  NO, A PLUS ON THE QUEUE         59340016
         TM    PARMCDS(CURPARM),PLMI    Q. IS REQUESTOR PLUS/MINUS      59400016
         BC    8,ENQT4                  PLUS, SEE ABOUT ENQUEUEING      59460016
ENQT1    TM    PARMCDS(TOPPARM),TEST    Q. IS THIS AN INQUIRY           59520016
         BC    1,RET0                   YES, GIVE RETURN, DON'T CREATE  59580016
         BC    8,CALC3                  RET=0, DON'T RETURN, CREATE     59640016
         MVI   RETURN(CURPARM),AVAIL    SET AVAILABLE CODE              59700016
         BC    15,CALC3                 AND GO CREATE                   59760016
ABTEST   TM    PARMCDS(TOPPARM),HAVE    Q. DOES MASK ALLOW ABEND        59820016
         BC    1,RET8                   NO, GO TO SET CODE              59880016
         TM    PARMCDS(TOPPARM),CHNG    Q. IS RET=CHNG            20021 59883020
         BZ    ERRX1                    NO-GO TO ABEND INTERFACE  20021 59886020
         LCR   CURQEL,CURQEL            RESET CURQEL REG POSITIVE 20021 59889020
         TM    QELCDS(CURQEL),NEGCODE   Q. IS CURR QEL 'SHARE'    20021 59892020
         BZ    RET0                     NO-EXCL. SET RC=0-AVAIL.  20021 59895020
         LTR   WORKREG1,WORKREG1        IS CALLER TOP QEL ON QUE  20021 59898020
         BM    RET4                     NO,SHARING-SET RC=4       20021 59901020
         L     WORKREG2,NXQEL(CURQEL)   GET POINTER TO NEXT QEL   20021 59904020
         LA    WORKREG2,0(WORKREG2)   ZERO HI ORDER BYTE FOR TEST 20021 59907020
         LTR   WORKREG2,WORKREG2        IS THIS ONLY QEL ON QUEUE 20021 59910020
         BZ    ENQSETEX                 YES-REQ CAN BE HONORED   20021  59913020
         TM    QELCDS(WORKREG2),NEGCODE Q. IS NEXT QEL 'SHARE'   20021  59916020
         BO    RET4                     YES-CAN'T HONOR REQ.RC=4 20021  59919020
ENQSETEX NI    QELCDS(CURQEL),ANYON-NEGCODE NO-SET QEL EXCLUSIVE 20021  59922020
         B     RET0                     SET RC=0- AVAILABLE.     20021  59925020
         SPACE 1                                                        60000016
ENQT4    TM    PARMCDS(TOPPARM),USE     Q. DOES MASK ALLOW ENQUEUE      60060016
         BC    1,RET4                   NO, GIVE RETURN, DON'T CREATE   60120016
         BAL   LINKREG,UPSVRB           INCREMENT THE SVRB WAIT COUNT   60180016
         BC    15,ENQT1                 AND TEST FOR RET SPECIFIED      60240016
         SPACE 3                                                        60300016
***  THIS CODE SETS RETURN CODES BASED UPON THE QUEUE STATUS            60360016
*    AND THE MASK SET IN THE USERS PARAMETER LIST ELEMENT.              60420016
*    NO CREATION TAKES PLACE.                                           60480016
*    THE USERS MASK SPECIFIED IN THE 'RET' FIELD                        60540016
*    WAS FOR INQUIRY ONLY.                                              60600016
*    I.E., RET=TEST WAS SPECIFIED.                                      60660016
         SPACE 1                                                        60720016
RET0     MVI   RETURN(CURPARM),AVAIL    SET AVAILABLE CODE              60780016
         BC    15,TESTEND1              GO GET NEXT                     60840016
RET4     MVI   RETURN(CURPARM),INUSE    SET ''IN USE'' CODE             60900016
         BC    15,TESTEND1              GO GET NEXT                     60960016
RET8CHNG MVI   RETURN(CURPARM),HAS      ERROR- NOT ENQUED * CHNG *20021 60980020
         B     TESTEND1                 GO GET NEXT PARAM ELEMENT 20021 61000020
RET8     MVI   RETURN(CURPARM),HAS      SET ''HAVE'' CODE               61020016
         LCR   CURQEL,CURQEL            RESET QEL INDICATION            61080016
         BAL   LINKREG,TESTSMC          TEST FOR MUST COMPLETE REQ      61140016
         AIF   (NOT &B(2)).SHRDA4                                       61145016
         TM    PARMCDS(CURPARM),RESERVE Q. IS THIS A RESERVE REQUEST    61150016
         BC    11,TESTEND1              NO, GO GET NEXT ELEMENT         61155016
         TM    PARMCDS(CURPARM),X'08'   Q. IS IT DEFINITELY RESERVE     61160016
         BC    8,TESTEND1               NO, GO GET NEXT ELEMENT         61165016
         TM    QELCDS(CURQEL),RESERVED  Q. IS RESERVE ALREADY IN EFFECT 61170016
         BC    1,OPRSMC                 YES, DO SMC IF NECESSARY        61175016
         OI    QELCDS(CURQEL),RESERVED  SET RESERVE FLAG IN QEL         61180016
         BC    15,LOGRSV                NO, PERFORM LOGICAL RESERVATION 61185016
         AGO   .SHRDA5                                                  61190016
.SHRDA4  ANOP                                                           61195016
         BC    15,TESTEND1              GO GET NEXT                     61200016
.SHRDA5  ANOP                                                           61230016
         SPACE 3                                                        61260016
***  INTERFACE WITH THE MAIN STORAGE SUPERVISOR.                        61320016
*    AMOUNT OF CORE REQUIRED IS PASSED IN REGISTER 0                    61380016
         SPACE 1                                                        61440016
GETCORE  O     GMREG,SP255              INDICATE SUBPOOL 255            61500016
         AIF   (&B(1)).A16A                                      A34816 61550020
         GETMAIN R,LV=(0)                                               61560016
         CL    GENREG,GETFOUR      WAS REQUEST SATISFIED           1874 61590018
         BE    GETERR                NO                            1874 61620018
         AGO   .A16B                                             A34816 61630020
.A16A    ANOP                                                    A34816 61640020
         LR    REG1,PARMCDS .      PROTECT BASE REG (REG 2)      A34816 61642420
         USING IGC048+2,REG1                                      2867  61642520
         DROP  PARMCDS                                                  61642620
         L     PARMCDS,ENTNQDQ     PTR TO DSECT SAVE AREA        A34816 61642820
         ST    REG1,DB16(PARMCDS) . PROTECT BASE REG (REG 2)     A34816 61643720
         STM   WORKREG3,GENREG,DB20(PARMCDS) SAVE REGS 3-15      A34816 61644020
         L     GENREG,ADFREE .     PTR TO GM BRANCH ENTRY        A34816 61646020
         DROP  REG1                                                     61646420
         L     WORKREG3,CVTPTR .   POINTER TO THE CVT           PTM     61646820
         L     INUSE,DB0(WORKREG3) . TCB QUEUE PTRS (OLD-NEW)    A34816 61648020
         L     INUSE,DB4(INUSE) .  PTR TO OLD TCB                A34816 61648420
         LCR   REG1,REG1 .         INDICATE A GM REQUEST         A34816 61648520
         BALR  RETREG,GENREG .     GO GET ME SOME CORE           A34816 61648620
         LM    PARMCDS,GENREG,DB16(PARMCDS) RESTORE  3-15       A34816  61648720
         USING IGC048+2,PARMCDS .  RE-ESTABLISH ADDRESSABILITY          61649120
         BR    LINKREG .           RETURN TO REQUESTOR           A34816 61649220
.A16B    ANOP                                                    A34816 61664420
         BCR   15,LINKREG                  RETURN TO CALLER             61672220
         SPACE 3                                                        61680016
***  ENTERED IF QUEUE STATUS INDICATES THAT                             61740016
*    THE SVRB WAIT COUNT SHOULD BE INCREMENTED                          61800016
         SPACE 1                                                        61860016
UPSVRB   IC    WORKREG1,RBWCF(CURRB)    GET WAIT COUNT FROM THE SVRB    61920016
         LA    WORKREG1,1(WORKREG1)     INCREMENT IT BY ONE             61980016
         STC   WORKREG1,RBWCF(CURRB)    PUT IT BACK                     62040016
         BCR   15,LINKREG               RETURN                          62100016
         EJECT                                                          62160016
***  TOP OF CREATE ELEMENTS ROUTINES.                                   62220016
*    CREATE3... CREATES AND EFFECTS LINKAGES FOR A MAJOR QCB.           62280016
*    CREATE2... CREATES AND EFFECTS LINKAGES FOR A MINOR QCB.           62340016
*    CREATE1... CREATES AND EFFECTS LINKAGES FOR A QEL.                 62400016
         SPACE 3                                                        62460016
***  CREATE3 ROUTINE.                                                   62520016
*    ENTERED FROM MAINLINE WHEN IT HAS BEEN DETERMINED THAT             62580016
*    THE 'QNAME' SPECIFIED IN THE USERS PARAMETER LIST WAS              62640016
*    NOT FOUND IN THE SEARCH OF MAJOR QCB'S IN THE SYSTEM.              62700016
*    THE MAJOR QCB ABOUT TO BE CREATED WILL BE CHAINED TO               62760016
*    THE LAST MAJOR ON THE CHAIN.  IF NONE PRESENTLY EXIST              62820016
*    IT IS CHAINED TO 'HEADQCB'.                                        62880016
*    RETURN IS TO MAINLINE.                                             62940016
         SPACE 1                                                        63000016
CREATE3  XC    0(MAJCLR,GMRETREG),0(GMRETREG)  CLEAR PORTION OF         63060016
*                                              NEW MAJOR QCB            63120016
         STM   WKRG1,WKRG2,MAJNAME(GMRETREG) PUT MAJOR NAME IN QCB      63180016
         LCR   CURMAJ,CURMAJ            POINTER TO LAST MAJOR           63240016
*                                       IN TRUE FORM                    63300016
         ST    GMRETREG,NXMAJ(CURMAJ)   POINTER TO NEW IN PREVIOUS      63360016
         ST    CURMAJ,PREVMAJ(GMRETREG) SET POINTER TO PREVIOUS MAJOR   63420016
         LR    CURMAJ,GMRETREG          POINT AT NEW MAJOR              63480016
         LCR   CURMIN,CURMAJ            SET REG FOR CREATE2 ROUTINE     63540016
         BCR   15,LINKREG               RETURN TO MAINLINE              63600016
         EJECT                                                          63660016
***  CREATE2 ROUTINE.                                                   63720016
*    ENTERED FROM MAINLINE TO CREATE A MINOR QCB WITH THE               63780016
*    NAME AND ATTRIBUTES AS SPECIFIED IN THE PARAMETER LIST.            63840016
*    'SYSTEM' RESOURCES (SCOPE OF THE NAME IS ACROSS THE                63900016
*    ENTIRE SYSTEM) HAVE A QCB PROTECT KEY FIELD=X'FF'.                 63960016
*    'STEP' RESOURCES (SCOPE OF THE NAME ACROSS THE JOB                 64020016
*    STEP ONLY) HAVE A QCB PROTECT KEY=TO THE PROTECT KEY               64080016
*    OF THE CURRENT TCB, I.E., THE REQUESTORS TCB.                      64140016
*    'SYSTEMS' RESOURCES (SCOPE OF THE NAME WILL BE KNOWN ACROSS        64160016
*    SYSTEMS) AND RESERVE REQUESTS HAVE A QCB PROTECT KEY OF X'FE'.     64180016
*    THE NAME LENGTH CAN                                                64200016
*    1-BE SPECIFIED IN THE LIST OR BE ZERO. IF ZERO                     64260016
*    2-BE THE FIRST BYTE OF THE NAME POINTED TO BY THE LIST.            64320016
*    IF BOTH FIELDS ARE ZERO AN ABEND OCCURS.                           64380016
*    WHEN THE FIRST BYTE OF THE NAME IS USED AS THE LENGTH              64440016
*    IT DOES NOT INCLUDE THE LENGTH BYTE, I.E., DOES NOT                64500016
*    INCLUDE ITSELF.                                                    64560016
*    THIS MINOR IS CHAINED TO THE MAJOR IN 'CURMAJ'.                    64620016
*    RETURN IS TO MAINLINE.                                             64680016
         SPACE 1                                                        64740016
CREATE2  XC    0(MINCLR,GMRETREG),0(GMRETREG) CLEAR PORTION OF QCB 2926 64800018
         SR    WORKREG2,WORKREG2        ZERO FOR IC                     64860016
         TM    PARMCDS(CURPARM),RESERVE Q. WHAT LEVEL IS REQUESTED      64920016
         BC    7,CREATE2B              SYSTEM OR SYSTEMS                64980016
         IC    WORKREG2,TCBPKF(CURTCB)  NO, GET THE PROTECT KEY         65040016
         STC   WORKREG2,QCBPKF(GMRETREG)  AND STORE IT IN THE QCB       65100016
         BC    15,CREATE2A              GO INITIALIZE REMAINDER         65160016
CREATE2B TM    PARMCDS(CURPARM),SYSTEMS Q. IS IT SYSTEMS REQUEST        65180016
         BC    8,CREATE2C              NO - IT IS SYSTEM REQUEST        65200016
         MVI   QCBPKF(GMRETREG),SYSKEY  YES SET SYSTEMS KEY IN QCB      65220016
         BC    15,CREATE2A             INITIALIZE REMAINDER             65240016
CREATE2C MVI   QCBPKF(GMRETREG),NOKEY   INDICATE SHARED                 65260016
CREATE2A L     GENREG,PTRMIN(CURPARM)   GET ADDRESS OF MINOR NAME       65280016
         IC    WORKREG2,LMINOR(CURPARM) GET MINOR NAME LENGTH           65340016
         LTR   WORKREG2,WORKREG2        Q. IS LENGTH FIELD ZERO         65400016
         BC    7,SETLTH                 NO, GO STORE IT                 65460016
         IC    WORKREG2,0(GENREG)       YES, GET FIRST BYTE OF NAME     65520016
*                                            USE IT AS LENGTH           65580016
         LA    GENREG,1(GENREG)         ADVANCE POINTER TO NAME         65640016
SETLTH   STC   WORKREG2,LMINAME(GMRETREG)  PUT LENGTH INTO MINOR        65700016
         BCTR  WORKREG2,0               SUBTRACT ONE                    65760016
         EX    WORKREG2,MOVENAME        MOVE NAME TO NEW MINOR QCB      65820016
         LCR   CURMIN,CURMIN            SET POINTER TO PREV IN TRUE     65880016
         ST    GMRETREG,NXMIN(CURMIN)   PUT NEW ADDR IN PREV ELEMENT    65940016
         LA    CURMIN,NXQEL(CURMIN) .     CLEAR THE HI-ORDER BYTE  5170 65992020
         ST    CURMIN,PREVMIN(GMRETREG) ADDR OF PREV IN NEW             66000016
         LR    CURMIN,GMRETREG          POINT AT NEW MINOR              66060016
         AIF   (NOT &B(3)).MIN4                                   20021 66064020
MINTJID1 EQU   0                                                  20021 66068020
MINTJID2 EQU   4                                                  20021 66072020
         TM    TCBTSFLG(CURTCB),TCBTSTSK TS TASK TCB              20021 66076020
         BZ    TSOEXIT             NO EXIT                        20021 66080020
         TM    PARMCDS(CURPARM),RESERVE STEP ENQ REQUESTED        20021 66084020
         BNZ   TSOEXIT             NO EXIT                        20021 66088020
         L     GENREG,TCBJSCB(CURTCB) GET JSCB FOR TS TCB         20021 66092020
         USING IEZJSCB,GENREG                                     20021 66096020
         MVC   MINTJID1(1,CURMIN),JSCBTJID MOVE 1ST PART OF TJID  20021 66100020
         MVC   MINTJID2(1,CURMIN),JSCBTJID+1 MOVE 2ND PART OF TJID20021 66104020
         DROP  GENREG                                             20021 66108020
TSOEXIT  EQU   *                                                  20021 66112020
.MIN4    ANOP                                                     20021 66116020
         LR    CURQEL,CURMIN            SET REG FOR CREATE1 ROUTINE     66120016
         BCR   15,LINKREG               RETURN TO MAINLINE              66180016
         EJECT                                                          66240016
***  CREATE1 ROUTINE.                                                   66300016
*    ENTERED FROM MAINLINE TO CREATE A QEL WITH ATTRIBUTES              66360016
*    AS SPECIFIED IN THE PARAMETER LIST.  IT IS CHAINED TO              66420016
*    THE MINOR QCB SPECIFIED IN 'CURMIN'.                               66480016
*    THE ENQ COUNT FIELD IN THE TCB IS INCREMENTED.                     66540016
*    IF THE QEL CREATED IS 'SHARED' MUST COMPLETE TESTS ARE             66600016
*    IGNORED.  IF IT IS 'EXCLUSIVE' A TEST ROUTINE IS ENTERED.          66660016
*    IN EITHER CASE CONTROL RETURNS TO AN ENDING ROUTINE TO             66720016
*    SEE IF ALL ELEMENTS IN THE LIST HAVE BEEN PROCESSED.               66780016
         SPACE 1                                                        66840016
CREATE1  XC    0(QELCLR,GMRETREG),0(GMRETREG)  CLEAR PORTION OF NEW QEL 66900016
         O     GMRETREG,NXQEL(CURQEL)   POINTER TO NEW IN PREVIOUS 5170 66960020
         ST    GMRETREG,NXQEL(CURQEL) . CHAIN THEM TOGETHER        5170 67010020
         LA    GMRETREG,NXQEL(GMRETREG) . CLEAR THE HI-ORDER BYTE  5170 67014020
         ST    CURQEL,PREVQEL(GMRETREG) SET POINTER TO PREV ELEMENT     67020016
         ST    CURRB,SVRBPTR(GMRETREG)  SET POINTER TO SVRB             67080016
         ST    CURTCB,QELTCB(GMRETREG)  SET POINTER TO TCB              67140016
         LR    CURQEL,GMRETREG          POINT TO NEW QEL                67200016
         SR    WORKREG1,WORKREG1        CLEAR FOR IC                    67260016
         IC    WORKREG1,TCBCT(CURTCB)   GET TCB ENQ COUNT BYTE          67320016
         LA    WORKREG1,1(WORKREG1)     INCREMENT IT BY ONE             67380016
         STC   WORKREG1,TCBCT(CURTCB)   AND STORE IT                    67440016
         AIF   (NOT &B(1)).SHRD215                                      67450016
         STATUS SET,NR,'S'         INCREMENT NONROLLOUTABLE COUNT       67460016
.SHRD215 ANOP                                                           67470016
         TM    PARMCDS(CURPARM),PLMI    Q. IS REQUESTOR PLUS            67500016
         BC    8,SMCLINK                YES, LEAVE PLUS, MAKE SMC TESTS 67560016
         OI    QELCDS(CURQEL),NEGCODE   NO, SET QEL MINUS               67620016
         AIF   (NOT &B(2)).SHRDA7                                       67630016
         BC    15,RSVTEST               SKIP SMC TESTS                  67640016
         AGO   .SHRDA8                                                  67650016
.SHRDA7  ANOP                                                           67660016
         BC    15,TESTEND2              SKIP SMC TESTS                  67680016
.SHRDA8  ANOP                                                           67710016
SMCLINK  BAL   LINKREG,TESTSMC          LINK TO TEST SMC STATUS         67740016
         AIF   (NOT &B(2)).SHRDA10                                      67743016
RSVTEST  TM    PARMCDS(CURPARM),RESERVE Q. IS THIS A RESERVE REQUEST    67746016
         BC    11,TESTEND2              NO, GO GET NEXT ELEMENT         67749016
         TM    PARMCDS(CURPARM),X'08'   Q. IS IT DEFINITELY RESERVE     67752016
         BC    8,TESTEND2               NO, GO GET NEXT ELEMENT         67755016
         OI    QELCDS(CURQEL),RESERVED  SET RESERVE FLAG IN QEL         67758016
         TM    RBWCF(CURRB),X'FF'       Q. HAS SVRB BEEN PLACED IN WAIT 67761016
         BC    8,LOGRSV                 NO - REFLECT UCB POINTER IN QEL 67762016
         L     CURMAJ,RBSAVUCB(CURRB)   GET UCB POINTER          A30097 67763020
         LA    CURMAJ,0(CURMAJ)         WHEN RESOURCE BECOMES AVAILABLE 67765016
         B     OPRSMC                                                   67766016
LOGRSV   L     UCBREG,RBSAVUCB(CURRB)   GET UCB POINTER          A30097 67769020
         LA    UCBREG,0(UCBREG)        CLEAR HI ORDER BYTE              67773016
         TM    DEVTYP-ONE(UCBREG),SHARED SHARED DEV...        BJ 38410  67774021
         BO   SETUCB                                          BJ  M2508 67774321
         NI   QELCDS(CURQEL),NORESRVE                         BJ  M2508 67774621
         B     OPRSMC .            NOT SHARED BRANCH          BJ  M2508 67775321
SETUCB   ST   UCBREG,QELUCB(CURQEL) . SET UCB POINTER IN QEL  BJ  M2508 67775521
         SR    WORKREG1,WORKREG1       CLEAR REG FOR IC                 67779016
         IC    WORKREG1,UCBRSCT(UCBREG) GET UCB RESERVE COUNT           67782016
         LA    WORKREG1,1(WORKREG1)     INCREMENT COUNT BY 1            67785016
         STC   WORKREG1,UCBRSCT(UCBREG) REPLACE NEW RESERVE COUNT       67788016
         BC    15,OPRSMC                DO SMC IF NECESSARY             67791016
         AGO   .SHRDA14                                                 67794016
.SHRDA10 ANOP                                                           67797016
*        RETURN GOES TO TESTEND1/TESTEND2                               67800016
.SHRDA14 ANOP                                                           67830016
         EJECT                                                          67860016
***  END PROCESSING                                                     67920016
*    DETERMINE IF ALL ELEMENTS IN THE PARAMETER LIST HAVE               67980016
*    BEEN PROCESSED.  IF NOT, GET NEXT AND GO BACK TO THE               68040016
*    TOP.                                                               68100016
*    WHEN ALL ELEMENTS HAVE BEEN PROCESSED DETERMINE IF                 68160016
*    THE MUST COMPLETE ROUTINE SHOULD BE ENTERED.                       68220016
*    THE ROUTINE WILL BE ENTERED IF                                     68280016
*    1-THIS WAS NOT A RET=TEST LIST.                                    68340016
*    2-THE SVRB WAIT COUNT WAS NOT INCREMENTED.                         68400016
*    3-MUST COMPLETE WAS SPECIFIED.                                     68460016
*    IN EITHER CASE REGISTER 15 WILL BE SET ON EXIT AS FOLLOWS          68520016
*    IF ALL RETURN CODES=0, REGISTER 15=0.                              68580016
*    OTHERWISE REGISTER 15 POINTS TO THE TOP OF THE LIST.               68640016
         SPACE 1                                                        68700016
TESTEND1 DS    0C                       EQUAL TO TESTEND2               68760016
TESTEND2 TM    LISTEND(CURPARM),ENDIND  Q. ALL ELEMENTS PROCESSED       68820016
         LA    CURPARM,PARMSIZE(CURPARM)  POINT TO NEXT ANYWAY          68880016
         BZ    ENQTOP                   NO, GO PROCESS NEXT    @JK68363 68940021
         AIF   (&B(1)).SHRD220                                          68945016
OPRSMC   SSM   *+1           DISABLE                                    68947016
         LR    CURPARM,TOPPARM                                          68950016
         TM    PARMCDS(TOPPARM),TEST   IS MC LEGAL                      68955016
         BC    1,EXIT             NO                                    68960016
         CLI   RBWCF(CURRB),WAITIND  IS THE SVRB IN WAIT                68965016
         BC    7,EXITWAIT         YES. GO TO DISPATCHER                 68970016
         TM    PARMCDS(TOPPARM),SMC  WERE REQUESTS MUST COMPLETE        68980016
         BC    8,EXIT             NO.  EXIT                             68985016
         AGO   .SHRD230                                                 68990016
.SHRD220 ANOP                                                           68995016
OPRSMC   LR    CURPARM,TOPPARM          RESET TO TOP OF LIST            69000016
         TM    PARMCDS(TOPPARM),TEST    Q. IS MC LEGAL                  69060016
         BC    1,MCRET2                 NO, EXIT WITHOUT SETTING        69120016
         CLI   RBWCF(CURRB),WAITIND     Q. IS THE SVRB IN A WAIT        69180016
         BC    7,MCRET2                 YES, DONT SET NON-DISPATCHABLE  69240016
         TM    PARMCDS(TOPPARM),SMC     Q. WERE REQUESTS MUST COMPLETE  69300016
         BC    8,MCRET2                 NO, GO TO EXIT                  69360016
         LR    WORKREG3,RETREG          SAVE RETURN REGISTER            69420016
         AIF   (NOT &B(3)).TSO0700                                20021 69420520
         SPACE 2                                                  20021 69421020
***                                                               20021 69421520
*    NOTIDFY THE OS/TS DRIVER IF SET MUST COMPLETE PROCESSING     20021 69422020
*    HAS BEEN REQUESTED BY A TIME-SHARING TASK.                   20021 69422520
         TM    PARMCDS(TOPPARM),SMCSYS REQUEST FOR SYSTEM MC?     20021 69423020
         BZ    NOTTSSMC                NO. CONTINUE.              20021 69423520
         TM    TCBTSFLG(CURTCB),TCBTSTSK IS THIS A TIME-          20021 69424020
*                                      SHARING TASK?              20021 69424520
         BZ    NOTTSSMC                NO. CONTINUE.              20021 69425020
         L     REG1,TCBJSCB(CURTCB)    ACCESS JOB STEP CTL BLK    20021 69425520
         USING IEZJSCB,REG1                                       20021 69426020
         LH    REG0,JSCBTJID           OBTAIN TERMINAL JOB ID.    20021 69426520
         DROP  REG1                                               20021 69427020
         SR    REG1,REG1                                          20021 69427520
         TSEVENT  REQSTMC,TJID=(0)                                20021 69428020
NOTTSSMC EQU   *                                                  20021 69428520
         SPACE 2                                                  20021 69429020
.TSO0700 ANOP                                                     20021 69429520
         AGO   .SHRD235                                                 69430016
.SHRD230 ANOP                                                           69450016
         LR    MCTCBRG,CURTCB           XFR TCB FOR SMC INTERFACE       69480016
         LA    RETREG,MCRET             SET ADDR FOR RETURN             69540016
.SHRD235 ANOP                                                           69570016
         TM    PARMCDS(TOPPARM),SMCSYS  Q. IS IT SYSTEM MC              69600016
         BC    1,SETCOMP                YES                             69660016
         AIF   (&B(1)).SHRD260                                          69710016
         OI    TCBFLG1(CURTCB),TCBFJMC  SET TCB MUST COMPLETE           69760016
         LH    WORKREG0,STEPMSK        LO AD  STEP MASK           19054 69790019
         B     STPSYS                                             19054 69820019
SETCOMP  LCR   MCTCBRG,MCTCBRG     INDICATE SYSTEM LEVEL                69860016
         OI    TCBFLG1(CURTCB),TCBFSMC  SET TCB SYSTEM MUST COMPLETE    69910016
         LH    WORKREG0,SYSMASK    LOAD SYSTEM MASK                     69960016
STPSYS   EQU   *                                                  19054 69965019
         B     SETRSMC             TAKE CARE OF DISPATCHING             70010016
MCRET    OI    TCBFLG(CURTCB),TCBFXS  DEFER ASYNCHRONOUS EXITS          70088016
EXIT     BAL   LINKREG,MCRET2                                           70092016
GOEXIT   SVC   3                                                        70096016
EXITWAIT STM   10,9,TCBGRS(CURTCB)  SAVE XRS IN TCB                     70100016
         MVC   PSWADR(LPSW,CURRB),MCOP  SET UP PSW TO REENTER ATOPRSMC  70104016
         SR    GENREG,GENREG                                            70108016
         LM    WORKREG1,WORKREG2,NEW                                    70112016
         CLC   ONE(D3,WORKREG1),D5(WORKREG1) TASK SW.         BJ 44371  70113021
         BNE   D0(WORKREG2)        YES BRANCH                 BJ 44371  70114021
         ST    GENREG,0(WORKREG1)   ZERO NEW                            70116016
         BCR   15,WORKREG2        GO TO DISPATCHER                      70120016
         AGO   .SHRD270                                                 70124016
.SHRD260 ANOP                                                           70128016
         STATUS SET,MC,STEP        SET MUST COMPLETE STEP               70148016
         B     MCRET              BRANCH AROUND SMC                     70168016
SETCOMP  STATUS SET,MC,SYSTEM      SET SYSTEM MUST COMPLETE             70188016
MCRET    LR    RETREG,WORKREG3     RESET RETURN REGISTER                70208016
.SHRD270 ANOP                                                           70230016
MCRET2   SR    GENREG,GENREG            ASSUME ALL ZERO RETURN CODES    70260016
SETRET   TM    RETURN(CURPARM),ANYON    Q. ANY RETURN CODE              70320016
         BC    7,TAKEXIT                YES, EXIT WITH REG 15           70380016
*                                       POINTING TO THE FIRST ELEMENT   70440016
         TM    LISTEND(CURPARM),ENDIND  Q. END OF PARAMETER LIST        70500016
         AIF   (&B(1)).SHRD280                                          70510016
         BCR   1,LINKREG          EXIT                                  70520016
         AGO   .SHRD290                                                 70530016
.SHRD280 ANOP                                                           70540016
         BC    1,EXIT                   YES, GO TO EXIT                 70560016
.SHRD290 ANOP                                                           70590016
         LA    CURPARM,PARMSIZE(CURPARM)  NO, GET NEXT ELEMENT          70620016
         BC    15,SETRET                GO THRU AGAIN                   70680016
TAKEXIT  LR    GENREG,TOPPARM           POINT TO FIRST LIST ELEMENT     70740016
         AIF   (&B(1)).SHRD300                                          70750016
         BCR   15,LINKREG         EXIT                                  70760016
         AGO   .SHRD310                                                 70770016
.SHRD300 ANOP                                                           70780016
         BC    15,EXIT                  GO TO EXIT                      70800016
.SHRD310 ANOP                                                           70830016
         EJECT                                                          70860016
***  ENTER THIS ROUTINE ONLY FOR THE CREATION OF EXCLUSIVE              70920016
*    QELS.  ONLY EXCLUSIVE REQUESTS MAY SPECIFY SET MUST                70980016
*    COMPLETE.                                                          71040016
*    IF THE REQUESTOR DOES NOT HAVE AN SVC OLD PSW PROTECT              71100016
*    KEY EQUAL TO ZERO, AND SMC WAS SPECIFIED, HE WILL BE               71160016
*    ABNORMALLY TERMINATED.                                             71220016
         SPACE 1                                                        71280016
TESTSMC  TM    PARMCDS(TOPPARM),SMC     Q. IS REQUEST MUST COMPLETE     71340016
         BCR   8,LINKREG                NO, RETURN WITHOUT SETTING MC   71400016
         TM    PARMCDS(TOPPARM),SMCSYS  Q. IS IT SYSTEM MC              71460016
         BC    1,SYS                    YES                             71520016
         OI    QELSMC(CURQEL),SMCSTP    NO, SET QEL STEP MUST COMPLETE  71580016
         BCR   15,LINKREG               RETURN                          71640016
SYS      OI    QELSMC(CURQEL),SMCSYS    SET QEL SYSTEM MUST COMP        71700016
         BCR   15,LINKREG               RETURN                          71760016
         AIF   (&B(1)).SHRD390                                          71790016
         EJECT                                                          71820016
***  EXECUTED INSTRUCTIONS FOR MODIFYING THE DISPATCHABILITY            71880016
*    OF THE TCB PASSED IN THE 'TCBREG' BY THE BYTE PASSED               71940016
*    IN THE 'MASKREG'.                                                  72000016
*    THE SUBJECT TCB IS MADE EITHER DISPATCHABLE OR NON-DISPATCHABLE.   72060016
         SPACE 1                                                        72120016
IEA0SMC  BALR  BASEREG,0          SET UP ADDRESSING                     72132016
         LA    GENREG,IEA0SMC-IGC048   RESET BASE REGISTER              72138016
         SR    BASEREG,GENREG                                           72144016
SETRSMC  LR    MASKREG,WORKREG0   XFR MASK BYTE                         72150016
         LA    WORKREG7,SYSTEM                                    19054 72153019
         LTR   MCTCBRG,MCTCBRG    IS IT SYSTEM OR STEP MUST COMPLETE    72156016
         BC    13,SYSLEVEL      REGISTER IS NEGATIVE AND SIGNALS  19054 72206019
*                                  REQUEST IS SYSTEM WIDE         19054 72256019
         L     WORKREG2,CVTADDR    LOAD PTR TO CVT                 I250 72306019
         USING CVT,WORKREG2                                        I250 72356019
         TM    CVTOPTA,MFTATTCH    IS THIS MFT ATTACH              I250 72406019
         BCR   8,RETREG            NO,RETURN                       I250 72456019
         DROP  WORKREG2                                            I250 72506019
         LA    WORKREG7,STEP                                      19054 72556019
         B     SYSSTEP      SKIP RESETTING REGISTER               19054 72606019
SYSLEVEL LCR   MCTCBRG,MCTCBRG          SYSTEM, PUT ADDR IN TRUE FORM   72660016
SYSSTEP  EQU   *                                                  19054 72690019
         L     TCBREG,MASTER            GET ADDRESS OF MASTER TCB       72720016
MCTST    CLR   MCTCBRG,TCBREG     IS THIS THE MC TASK                   72744016
         BC    8,GETTCB           YES. SKIP IT AND GET NEXT TCB         72752016
         BCR   15,WORKREG7             GO TO PROCESS STEP OR SYS  19054 72952019
STEP     CLC   45(3,MCTCBRG),45(TCBREG)    ARE TCBS IN SAME STEP  19054 73152019
         BNE   GETTCB                   NO                        19054 73352019
SYSTEM   LTR   MASKREG,MASKREG          Q. IS IT SMC OR RMC             73680016
         BC    4,EXRMC                  RMC                             73740016
EXSMC    EX    MASKREG,SMCINST          DO A SET MUST COMPLETE          73800016
         BC    15,GETTCB                TRY NEXT TCB                    73860016
EXRMC    EX    MASKREG,RMCINST          DO A RESET MUST COMPLETE        73920016
         LR    WORKREG2,WORKREG3  SAVE XRS ACROSS TASK SWITCH           73922016
         LR    WORKREG0,LINKREG                                         73924016
         BAL   LINKREG,TASKSWT2   GO TO TASK SWITCH                     73926016
         LR    LINKREG,WORKREG0   RESTORE XRS                           73928016
         LR    WORKREG3,WORKREG2                                        73930016
         TM    TCBFLG2(TCBREG),X'20'  IS SIRB ACTIVE FOR TASK           73932016
         BC    8,GETTCB           NO                                    73938016
         L     WORKREG2,ADSYMCSW  YES. SET SWITCH FOR EXIT              73944016
         NI    1(WORKREG2),X'0F'  TO MAKE TASK NON-DISPATCHABLE         73950016
         NI    TCBDISP(TCBREG),X'F7'  MAKE TASK DISPATCHABLE            73956016
GETTCB   L     TCBREG,TCBTCB(TCBREG)    GET NEXT TCB ON READY QUEUE     74220016
         LTR   TCBREG,TCBREG            Q. HAVE WE FINISHED             74280016
         BCR   8,RETREG           YES.  EXIT                            74300016
         BC    15,MCTST           NO. PROCESS NEXT TCB                  74310016
.SHRD390 ANOP                                                           74490016
         EJECT                                                          74520016
***  DETERMINE LENGTH OF MINOR QCB, INCLUDING NAME, AND                 74580016
*    ROUND UP TO A FULL WORD BOUNDRY.  NOTE SUMREG=GMRETREG=1           74640016
         SPACE 1                                                        74700016
ADDMINOR SR    SUMREG,SUMREG            CLEAR ACCUMULATOR               74760016
         IC    SUMREG,LMINOR(CURPARM)   GET LENGTH OF MINOR             74820016
         LTR   SUMREG,SUMREG            Q. IS IT ZERO                   74880016
         BC    7,NMLTH                  NO, USE IT AS THE LENTH         74940016
         L     GENREG,PTRMIN(CURPARM)   GET ADDRESS OF MINOR NAME       75000016
         IC    SUMREG,0(GENREG)         GET FIRST BYTE OF NAME          75060016
         LTR   SUMREG,SUMREG            Q. IS IT ZERO                   75120016
         BC    8,ERRX2                  YES, ABEND                      75180016
NMLTH    LA    SUMREG,FULLSIZE(SUMREG)  ROUND UP                        75240016
         N     SUMREG,MASKFULL          TO DOUBLE WORD                  75300016
         BCR   15,LINKREG               RETURN                          75360016
         EJECT                                                          75420016
***  THIS ROUTINE ATTEMPTS TO FIND A MAJOR QCB BY THE SAME              75480016
*    NAME AS THAT GIVEN IN THE CURRENT PARAMETER LIST ENTRY.            75540016
*    IF SUCCESSFUL: THE ROUTINE EXITS WITH 'CURMAJ'                     75600016
*                   POINTING TO THE MAJOR QCB WITH                      75660016
*                   THE SAME NAME.                                      75720016
*    IF NOT SUCCESSFUL: THE ROUTINE EXITS WITH THE                      75780016
*                   COMPLIMENT OF THE ADDRESS OF THE                    75840016
*                   LAST MAJOR QCB.                                     75900016
         SPACE 1                                                        75960016
FINDMAJ  L     WORKREG2,PTRMAJ(CURPARM)  GET PTR TO MAJOR NAME          76050018
*                                       FROM PARM LIST                  76140016
         MVC   XSAV(LMAJ,CURRB),0(WORKREG2) MOVE NAME TO WORD BOUNDRY   76200016
         LM    WORKREG1,WORKREG2,XSAV(CURRB) PICK UP NAME               76260016
         L     WORKREG3,ENTNQDQ                                    REFR 76280018
         USING   NQDQQCB,WORKREG3                                  REFR 76300018
         LA    CURMAJ,HEADQCB           INITIALIZE                      76320016
         DROP   WORKREG3                                           REFR 76340018
         SR    WORKREG3,WORKREG3                                   REFR 76360018
CHKLINK  CL    WORKREG3,NXMAJ(CURMAJ)   Q. IS NEXT MAJOR QCB PRESENT    76380016
         BC    8,NEGOUT                 NO, EXIT POINTING TO LAST MAJOR 76440016
         L     CURMAJ,NXMAJ(CURMAJ)     GET POINTER TO NEXT MAJOR       76500016
         CL    WORKREG1,MAJNAME(CURMAJ) Q. 1ST HALF NAMES EQUAL         76560016
         BC    7,CHKLINK                NO, GET NEXT MAJOR QCB          76620016
         CL    WORKREG2,MAJNAME+4(CURMAJ) Q. 2ND HALF NAMES EQUAL       76680016
         BCR   8,LINKREG                YES, RETURN POINTING TO         76740016
*                                       MAJOR QCB OF SAME NAME          76800016
         BC    15,CHKLINK               NOT SAME NAME, TRY AGAIN        76860016
NEGOUT   LCR   CURMAJ,CURMAJ            INDICATE MAJOR NOT FOUND        76920016
POSOUT   BCR   15,LINKREG               RETURN TO CALLER                76980016
         SPACE 3                                                        77040016
***  THIS ROUTINE ATTEMPTS TO FIND A MINOR QCB BY THE SAME              77100016
*    NAME AS THAT GIVEN IN THE CURRENT PARAMETER LIST ENTRY.            77160016
*    IT IS ENTERED ONLY IF A MAJOR QCB HAS BEEN FOUND.                  77220016
*    IF SUCCESSFUL: EXIT WITH 'CURMIN' POINTING TO MINOR QCB.           77280016
*    IF NOT SUCCESSFUL: EXIT WITH 'CURMIN' CONTAINING THE               77340016
*                   COMPLIMENT ADDRESS OF THE LAST MINOR                77400016
*                   QCB ON THE PREVIOUSLY FOUND MAJOR QCB.              77460016
         SPACE 1                                                        77520016
FINDMIN  SR    WORKREG1,WORKREG1        INITIALIZE REG TO ZERO          77580016
         LR    WORKREG2,WORKREG1        ZERO FOR IC                     77640016
         L     CURMIN,FSTMIN(CURMAJ)    OBTAIN MINOR ADDRESS            77700016
         LA    CURMIN,DB0(CURMIN) .CLEAR THE HI-ORDER BYTE       M3481  77702020
         LTR   CURMIN,CURMIN .     DO WE HAVE A MAJOR WITHOUT A MINOR   77710020
         BNZ   SHARET .            NO, CONTINUE PROCESSING        1853  77720020
         LCR   CURMIN,CURMAJ .     COMPLEMENT THE MAJOR ADDR      1853  77722020
         BR    LINKREG .           RETURN                         1853  77724020
SHARET   TM    PARMCDS(CURPARM),RESERVE Q. WHAT LEVEL IS REQUESTED      77730016
         BC    8,PKFCHK2               STEP LEVEL                       77760016
         BC    1,PKFCHK3               SYSTEMS LEVEL                    77790016
         TM    PARMCDS(CURPARM),SHARE   Q. SYSTEM OR RESERVE            77820016
         BC    8,PKFCHK3               RESERVE HENCE SYSTEMS            77850016
PKFCHK   CLI   QCBPKF(CURMIN),NOKEY     Q. IS THE QCB SHARED            77880016
         BC    7,GETNXMIN              NO,GET THE NEXT MINOR            77940016
         BC    15,LTHEQ                 YES, GO TEST THE LENGTHS        78000016
PKFCHK2  CLC   TCBPKF(1,CURTCB),QCBPKF(CURMIN)  Q. ARE THE PROTECT      78060016
*                                                  KEYS EQUAL           78120016
         BC    7,GETNXMIN               NO, GET THE NEXT MINOR          78180016
         BC    15,LTHEQ                YES TEST THE LENGTHS             78190016
PKFCHK3  CLI   QCBPKF(CURMIN),SYSKEY    Q. IS THIS A SYSTEMS QCB        78200016
         BC    7,GETNXMIN              NO - GET THE NEXT MINOR QCB      78210016
LTHEQ    L     GENREG,PTRMIN(CURPARM)   GET ADDRESS OF MINOR NAME       78240016
         IC    WORKREG2,LMINOR(CURPARM) GET LENGTH FIELD FROM LIST      78300016
         LTR   WORKREG2,WORKREG2        Q. IS IT EQUAL TO ZERO          78360016
         BC    7,LTHTEST                NO, GO TEST FOR EQUAL LENGTHS   78420016
         IC    WORKREG2,0(GENREG)       YES, GET LENGTH FROM FIRST      78480016
*                                  BYTE OF NAME FIELD                   78530020
         LA    GENREG,1(GENREG)         ADVANCE POINTER TO NAME         78720016
LTHTEST  EX    WORKREG2,LTHINST         Q. ARE LENGTHS EQUAL            78780016
         BC    7,GETNXMIN               NO, GET NEXT MINOR QCB          78840016
         BCTR  WORKREG2,0               DECREMENT BY ONE                78900016
         EX    WORKREG2,COMPNAME                                        78960016
         AIF   (NOT &B(3)).MIN1                                   20021 78966020
         BNE   GETNXMIN            NO GET NEXT MINOR QCB          20021 78972020
         AGO   .MIN2                                              20021 78978020
.MIN1    BC    8,PLOUT             NAME IS THE SAME               20021 78984020
         AGO   .MIN3                                              20021 78990020
.MIN2    ANOP                                                     20021 78996020
TSOFIX   TM    TCBTSFLG(CURTCB),TCBTSTSK TS TASK                  20021 79002020
         BZ    PLOUT               NO EXIT                        20021 79008020
         TM    PARMCDS(CURPARM),RESERVE STEP ENQ REQESTED         20021 79014020
         BNZ   PLOUT               NO EXIT                        20021 79020020
         L     GENREG,TCBJSCB(CURTCB) GET JSCB ADDRESS            20021 79026020
         USING IEZJSCB,GENREG                                     20021 79032020
         CLC   MINTJID1(1,CURMIN),JSCBTJID 1ST TJID EQUAL         20021 79038020
         BNE   GETNXMIN            NO GET NEXT MINOR QCB          20021 79044020
         CLC   MINTJID2(1,CURMIN),JSCBTJID+1 2ND TJID EQUAL       20021 79050020
         BE    PLOUT               YES MINOR QCB FOUND            20021 79056020
.MIN3    ANOP                                                     20021 79062020
GETNXMIN L     WORKREG1,NXMIN(CURMIN) .GET NEXT MINOR             38396 79130020
         LA    WORKREG1,DB0(WORKREG1) .CLEAR THE HI-ORDER BYTE    38396 79132020
         LTR   WORKREG1,WORKREG1 .    IS THERE ANOTHER MINOR THERE38396 79134020
         BC    8,MIOUT                  NO,TAKE BRANCH                  79140016
         LR    CURMIN,WORKREG1 .   SET UP REG 7 FOR ANOTHER SCAN  M4290 79250020
         BC    15,SHARET                REPEAT MINOR SEARCH             79260016
MIOUT    LCR   CURMIN,CURMIN            COMPLEMENT MINOR ADR.           79320016
PLOUT    SR    WORKREG1,WORKREG1 . CLEAR IT FOR POSS. INTERFACE PROB    79370020
         BCR   15,LINKREG .              RETURN                   38396 79380020
         EJECT                                                          79440016
***  THIS ROUTINE PERFORMS A TWO PART FUNCTION.                         79500016
*    1-INITIALLY TO VALIDATE A REQUEST (TEST FOR SAME                   79560016
*       REQUESTOR ALREADY QUEUED ON THE RESOURCE).                      79620016
*    2-TO FIND THE QEL BELOW WHICH THE CURRENT                          79680016
*       REQUESTOR IS TO BE ENQUEUED, AND INDICATE                       79740016
*       WHETHER OR NOT TO PLACE THE REQUESTOR IN                        79800016
*       A WAIT STATE.                                                   79860016
         SPACE 1                                                        79920016
FINDQEL  SR    WORKREG1,WORKREG1        INITIALIZE COMPERAND            79980016
         SR    WORKREG2,WORKREG2        ASSUME A MINUS QUEUE            80040016
         L     CURQEL,FSTQEL(CURMIN)    GET ADDRESS OF 1ST QEL          80100016
         LA    CURQEL,DB0(CURQEL) .CLEAR THE HI-ORDER BYTE       M3481  80110020
         LTR   CURQEL,CURQEL .     DO WE HAVE A MINOR WITHOUT A QEL1853 80150020
         BNZ   CHKCODE .           NO, CONTINUE PROCESSING         1853 80152020
         LR    CURQEL,CURMIN .     RETURN MINORS ADDR              1853 80154020
         BR    LINKREG .           RETURN                          1853 80156020
CHKCODE  TM    QELCDS(CURQEL),PLMI      Q. IS QUEUE PLUS OR MINUS       80160016
         BC    1,CHKTCB                 MINUS, DONT SET INDICATOR       80220016
         BALR  WORKREG2,0               PLUS, SET INDICATOR             80280016
CHKTCB   CL    CURTCB,QELTCB(CURQEL)    Q. HAS SAME TASK REQUESTED      80340016
         BC    8,BAD                    YES, EXIT INDICATING BAD REQ    80400016
         OC    NXQEL+1(3,CURQEL),NXQEL+1(CURQEL)  Q. MORE TO CHECK      80460016
         BC    8,GOOD                   NO, EXIT INDICATING GOOD REQ    80520016
         L     CURQEL,NXQEL(CURQEL)     GET ADDRESS OF NEXT QEL         80580016
         BCTR  WORKREG1,0            SET WORKREG1 NEG-NOT TOP QEL 20021 80610020
         BC    15,CHKCODE               TEST AND VALIDATE IT            80640016
BAD      LCR   CURQEL,CURQEL            SET BAD INDICATION              80700016
GOOD     BCR   15,LINKREG               RETURN TO CALLER                80760016
         EJECT                                                          80820016
         AIF   (NOT &B(1)).SHRD400                                      80850016
***  EXIT INTERFACE                                                     80880016
EXIT     TM    RBWCF(CURRB),ANYON       Q. IS WAIT COUNT EQUAL TO ZERO  80940016
         BC    7,EXITWAIT               NO, GO TO DISPATCHER            81000016
EXITNORM BCR   15,RETREG                NOT IN WAIT RETURN TO CALLER    81060016
EXITWAIT EQU   *                                                  20021 81065020
         AIF   (NOT &B(3)).TSO0800                                20021 81070020
         TM    TCBTSFLG(CURTCB),TCBTSTSK TS USER                  20021 81075020
         BNO   WAITEXIT            NO RESUME PROCESSING           20021 81080020
         L     REG1,TCBJSCB(CURTCB) YES GET JSCB ASSOCIATED       20021 81085020
         DROP  GENREG                                           M1861   81087020
         USING IEZJSCB,REG1        BASE FOR DSECT                 20021 81090020
         LH    REG0,JSCBTJID       GET TJID FOR ASSOC USER        20021 81095020
         DROP  REG1                                               20021 81100020
         L     REG1,CVTPTR         .GET CVT ADDRESS               20021 81105020
         USING CVT,REG1                                           20021 81110020
         L     REG1,CVTTSCVT       GET TSCVT ADDRESS              20021 81115020
         DROP  REG1                                               20021 81120020
         USING TSCVT,REG1                                         20021 81125020
         LR    WORKREG3,RETREG     SAVE EXIT ADDRESS              20021 81130020
         L     GENREG,TSCVTI01     GET BRANCH ENTRY PT            20021 81135020
         DROP  REG1                                               20021 81140020
         XR    REG1,REG1           CLEAR REG                      20021 81145020
         TSEVENT ENQWAIT,TJID=(0),ENTRY=BRANCH                    20021 81150020
         LR    RETREG,WORKREG3     RESTORE EXIT ADDR              20021 81155020
WAITEXIT EQU   *                                                  20021 81160020
.TSO0800 ANOP                                                     20021 81165020
         TM    PARMCDS(TOPPARM),SMC Q. IS MUST COMPLETE REQUESTED 20021 81170020
         BC    8,NOMC                   NO, SKIP MC CODING              81180016
         MVC   PSWADR(LPSW,CURRB),MCOP  YES, POINT RESUME PSW TO        81240016
*                                            MUST COMPLETE CODE         81300016
         BC    15,EXIT1                 SKIP                            81360016
NOMC     MVC   PSWADR(LPSW,CURRB),ADREXIT    PUT ADDRESS OF 'EXITNORM'  81420016
*                                            IN RESUME PSW              81480016
EXIT1    STM   0,15,TCBGRS0(CURTCB)     PUT REGS IN TCB                 81540016
         SR    GENREG,GENREG            CLEAR                           81600016
         LM    WORKREG1,WORKREG2,NEW    GET ADDR OF NEW AND DISPATCHER  81660016
        CLC    ONE(D3,WORKREG1),D5(WORKREG1) TASK SW.         BJ 44371  81680021
         BNE   D0(WORKREG2)         YES BRANCH                BJ 44371  81700021
         ST    GENREG,0(WORKREG1)       ZERO NEW                        81720016
         BCR   15,WORKREG2              GO TO DISPATCHER                81780016
         EJECT                                                          81840016
***  THIS ROUTINE INTERFACES WITH THE SUPERVISORS VALIDITY              81900016
*    CHECK ROUTINE, IEA0VL00.                                           81960016
*    IT CHECKS FOR                                                      82020016
*    FULL WORD ALIGNMENT OF LIST                                        82080016
*    IS LIST ADDRESS WITHIN MACHINE SIZE                                82140016
*    PROPER PROTECT KEY                                                 82200016
         SPACE 1                                                        82260016
         EXTRN IEA0VL01                 VALIDITY CHECK ROUTINE          82320016
         SPACE 1                                                        82560016
CHKLIST  L     GENREG,RBLINK(CURRB)     GET ISSUING RB                  82620016
         TM    RBPSW+1(GENREG),PKEY0    Q. IS PROTECT KEY ZERO          82680016
         AIF   (NOT &B(2)).SHRDA71                                      82683016
         BC    7,LDBASE                NON SYSTEM INVOKED-CHECK IT      82686016
         TM    PARMCDS(CURPARM),RESERVE Q. IS THIS SYSTEMS REQUEST      82689016
         BC    11,12(LINKREG)          NO RETURN TO CALLER              82692016
         TM    PARMCDS(CURPARM),X'08'  IS IT RESERVE REQUEST            82695016
         BC    8,12(LINKREG)           NO RETURN TO CALLER              82698016
         L     UCBREG,PTRUCB(CURPARM)  GET PNTR TO UCB PNTR             82701016
         L     UCBREG,0(UCBREG)        GET UCB POINTER                  82704016
         ST    UCBREG,RBSAVUCB(CURRB)   SAVE UCB POINTER         A30097 82707020
         BC    15,12(LINKREG)          AND RETURN TO CALLER             82719016
         AGO   .SHRDA72                                                 82722016
.SHRDA71 ANOP                                                           82725016
         BC    8,12(LINKREG)            YES, RETURN OK                  82740016
.SHRDA72 ANOP                                                           82770016
         SPACE 1                                                        82800016
***  NON-SYSTEM ROUTINE, INVOKE VALIDITY CHECK.                         82860016
LDBASE   LA    GENREG,LDBASE            SET INTERFACE BASE              82920016
         USING LDBASE,GENREG                                            82980016
         SPACE 1                                                        83040016
         L     CHKBASE,VALIDCHK         SET VALIDITY CHECK BASE         83100016
CHKFRNT  BAL   WORKREG2,4(CHKBASE)      GO TO VALIDITY CHECK ROUTINE    83160016
         BC    7,INVALID                FAILED VALIDITY CHECK           83220016
         SPACE 1                                                        83280016
         LA    INPUTREG,11(CURPARM)     GET LAST BYTE OF ENTRY          83340016
         BALR  WORKREG2,CHKBASE         VALIDITY CHECK THE ADDRESS      83380016
         BC    7,INVALID                INVALID ADDRESS                 83420016
         SPACE 1                                                        83460016
         L     INPUTREG,PTRMAJ(CURPARM) GET ADDRESS OF MAJOR NAME       83520016
         BAL   WORKREG1,ENTER           GO CHECK IT                     83580016
         LA    INPUTREG,7(INPUTREG)     GET LAST BYTE OF NAME           83700016
         BAL   WORKREG1,ENTER           GO CHECK IT                     83760016
         SPACE 1                                                        83820016
         L     INPUTREG,PTRMIN(CURPARM) GET ADDRESS OF MINOR NAME       83880016
         BAL   WORKREG1,ENTER           GO CHECK IT                     83940016
         SR    WORKREG1,WORKREG1  CLEAR FOR IC                          84010016
         IC    WORKREG1,LMINOR(CURPARM)  GET LENGTH OF MINOR            84080016
         LTR   WORKREG1,WORKREG1  IS IT ZERO                            84150016
         BC    7,ADDIT                  NO, ADD IT TO ADDRESS           84240016
         IC    WORKREG1,0(INPUTREG)  GET LENGTH FROM MINOR FIELD        84300016
         LTR   WORKREG1,WORKREG1  IS IT ZERO                            84360016
         BC    8,BADLTH                 YES, ABEND THE TASK             84420016
         BC    15,NOSUB                 NOT ZERO SKIP DECREMENT         84480016
ADDIT    BCTR  WORKREG1,0         REDUCE IT BY ONE                      84510016
NOSUB    AR    INPUTREG,WORKREG1  ADD IT TO ADDRESS                     84542016
         BAL   WORKREG1,ENTER                                           84544016
.SHRD400 AIF   (&B(1)).SHRD410                                          84546016
CHKLIST  L     GENREG,RBLINK(CURRB)                                     84548016
         TM    PSWADR+1(GENREG),X'F0'                                   84550016
         BZ    SMALLDSI           P. K. IS ZERO, CHECK SMALL TCB        84552016
         TM    PARMCDS(TOPPARM),SMC  SMC IN PROBLEM PROGRAM             84554016
         BC    7,ERRX3            MODE IS INVALID                       84556016
         LR    RE,CURTCB                                           I250 84556319
         L     WORKREG1,CVTADDR    GET ADDRESS OF CVT              I250 84556619
         USING CVT,WORKREG1                                        I250 84556919
         TM    CVTOPTA,MFTATTCH    IS THIS MFT ATTACH              I250 84557219
         BC    8,BBOX              NO, GET PTR TO BBOX             I250 84557519
         DROP  WORKREG1                                            I250 84557819
         L     RE,TCBJSTEP(CURTCB) GET PTR TO JOB STEP TCB         I250 84558119
BBOX     L     WORKREG1,TCBBYBOX(RE)  GET PTR TO BOUNDARY BOX      I250 84558419
         SR    RE,RE                   CLEAR REG FOR LATER LCS TEST LCS 84559017
         TM    0(WORKREG1),X'01'       TEST FOR LCS                 LCS 84560017
         BC    8,ONEBOUND              NO LCS                       LCS 84561017
         LM    RE,RF,16(WORKREG1)      LCS - GET HI,LO LCS ADDR     LCS 84562017
ONEBOUND LM    WORKREG1,WORKREG2,4(WORKREG1)  GET HI,LO ADDR        LCS 84563017
CHKFRNT  LA    WORKREG7,CHECK           GET ADR CHECK ROUTNLCS @JK67730 84564021
         LR    WORKREG3,CURPARM        SET UP INITIAL ADR-PASS TO   LCS 84565017
         BALR  BRCHECK,WORKREG7        CHECK BEG PARM ENTRIES       LCS 84566017
         LA    WORKREG3,PLASTBYT(WORKREG3)   LAST PARM BYTE    @JK67730 84567021
         BALR  BRCHECK,WORKREG7        CHECK END PARM ENTRY         LCS 84568017
         EX    CURPARM,WDTEST          TEST ALIGNMENT               LCS 84569017
         BC    5,INVALID               NOT ALIGNED                  LCS 84570017
         L     WORKREG3,PTRMAJ(CURPARM)  GET ADR MAJOR NAME         LCS 84571017
         BALR  BRCHECK,WORKREG7        CHECK BEG MAJOR NAME         LCS 84572017
         LA    WORKREG3,8(WORKREG3)                                 LCS 84573017
         BALR  BRCHECK,WORKREG7         CHECK END MAJOR NAME        LCS 84574017
         L     WORKREG3,PTRMIN(CURPARM)                             LCS 84575017
         BALR  BRCHECK,WORKREG7        CHECK BEG MINOR NAME         LCS 84584017
         SR    CURQEL,CURQEL                                            84594016
         IC    CURQEL,LMINOR(CURPARM)  GET LENGTH OF MINOR              84596016
         LTR   CURQEL,CURQEL      IS IT ZERO                            84598016
         BC    7,ADDIT            NO. COMPUTE UPPER BOUND               84600016
         IC    CURQEL,0(WORKREG3)  IS LENGTH PREFIXED TO MINOR          84602016
         LTR   CURQEL,CURQEL                                            84604016
         BC    8,ERRX2            NO                                    84606016
ADDIT    AR    WORKREG3,CURQEL    ADD LENGTH TO ADDRESS FO MINOR        84608016
         BALR  BRCHECK,WORKREG7        CHECK END MINOR NAME         LCS 84611017
         AIF   (NOT &B(2)).SHRDA2                                       84614016
         L     REG1,RBLINK(CURRB) POINTER TO ENQ SVRB BJ 57060   4027   84616021
         CLI   RBPSW+3(REG1),X'38'  IS THIS A REQUEST FOR ENQ(SVC38)    84618021
         AGO   .SHRD420                                                 84622016
.SHRD410 AIF   (NOT &B(2)).SHRDA2                                       84624016
         L     WORKREG1,RBLINK(CURRB)   GET ISSUING RB ADDRESS          84662016
         CLI   RBPSW+3(WORKREG1),X'38'  IS THIS A REQUEST FOR ENQ       84663016
.SHRD420 ANOP                                                           84665516
         BC    7,CHKEND                 NO, SKIP RESERVE CHECK          84666016
         TM    PARMCDS(CURPARM),RESERVE Q. IS THIS A RESERVE REQUEST    84667016
         BC    11,CHKEND                NO, GO GET NEXT ELEMENT         84668016
         TM    PARMCDS(CURPARM),X'08'   Q. IS IT DEFINITELY RESERVE     84669016
         BC    8,CHKEND                 NO, GO GET NEXT ELEMENT         84670016
         TM    LISTEND(CURPARM),ENDIND  Q. IS THIS LAST PARM ELEMENT    84673016
         BZ    INVALID                  NO, ERROR              @JK68363 84673121
         AIF   (&B(1)).SHRD430                                          84673216
         LA    WORKREG3,RESVSIZE(CURPARM)  GET END OF LIST              84673316
         BALR  BRCHECK,WORKREG7   VALIDITY CHECK              BJ 35042  84673621
         BALR  BRCHECK,WORKREG7   VALIDITY CHECK              BJ 35042  84673921
         AGO   .SHRD440                                                 84674216
.SHRD430 ANOP                                                           84674316
         LA    INPUTREG,15(CURPARM)     GET LAST BYTE OF ENTRY+12       84677016
         BALR  WORKREG2,CHKBASE         VALIDITY CHECK THE ADDRESS      84677616
         BC    7,INVALID                INVALID ADDRESS                 84678216
.SHRD440 ANOP                                                           84678616
         L     WORKREG7,ENTNQDQ                                    REFR 84678718
         USING   NQDQQCB,WORKREG7                                  REFR 84678818
         L     INPUTREG,PTRUCB(CURPARM) GET ADDRESS OF UCB POINTER      84679016
         BAL   WORKREG1,ENTER           VALIDITY CHECK THE ADDRESS      84680016
         EX    INPUTREG,WDTEST          YES - TEST FOR FULL WORD BOUND  84681516
         BC    5,INVALID                NOT FULL WORD - INVALID         84682016
         L     UCBREG,0(INPUTREG)  GET ADDR OF UCB                      84683016
         LA    UCBREG,0(UCBREG)           CLEAR UPPER BYTE              84685016
         AIF   (&B(1)).SHRD445                                          84685216
         L     TIOTREG,TCBTIOT(CURTCB)  GET TIOT ADDR                   84685416
         AGO   .SHRD446                                                 84685616
.SHRD445 ANOP                                                           84685816
         L     JSTCBRG,JSPTR(CURTCB)    GET JOB STEP TCB ADDRESS        84686016
         L     TIOTREG,TCBTIOT(JSTCBRG) GET TIOT ADDRESS                84687016
.SHRD446 ANOP                                                           84687516
         LA    TIOTREG,TIOELNGH(TIOTREG)  TREG = POINTR TO FIRST DD     84688016
NEXTDD   L     TIOEREG,TIOTEND(TIOTREG)   EREG = FIRST WORD OF THIS DD  84689016
         LTR   TIOEREG,TIOEREG            Q IS THIS THE END OF TIOT     84690016
         BC    8,INVALID                  YES UCB WAS NOT FOUND         84691016
         SR    TIOEREG,TIOEREG            THERE IS ANOTHER DD ENTRY     84692016
         IC    TIOEREG,TIOTEND(TIOTREG)   GET ITS LENGTH AND COMPUTE    84693016
         LA    TIOEREG,0(TIOEREG,TIOTREG) TOP END OF DD IN EREG         84694016
         LA    TIODVRG,TIODDLNG(TIOTREG)  DVRG = POINTR TO FIRST DEV    84695016
NEXTDEVC CR    TIODVRG,TIOEREG         Q IS THIS END OF DEVICE ENTRY    84696016
         BE    TIONXTDD                   YES TRY NEXT DD ENTRY         84697016
         BC    2,INVALID                  IF DD SIZE WAS WRONG - ERROR  84698016
         L     TIOUCBRG,TIOEFSRT(TIODVRG) UCBRG = UCB POINTER           84699016
         LA    TIOUCBRG,0(TIOUCBRG)       CLEAR UPPER BYTE              84700016
         CR    TIOUCBRG,UCBREG            Q IS THIS THE UCB             84701016
         BE    UCBTEST                    YES TEST IT FOR PROPERTIES    84702016
         BH    SUBUCB                   TEST IT FOR SUBUCB         SDA2 84702617
NEXTIOT  LA    TIODVRG,4(TIODVRG) NO POINT TO NEXT UCB PTR         SDA2 84703217
         B     NEXTDEVC                 IF THERE IS ONE            SDA2 84703317
SUBUCB   TM    UCBID(TIOUCBRG),X'FF'    IS THIS SUB OR MAIN UCB    SDA2 84703417
         BC    1,NEXTIOT                MAIN UCB CHECK NEXT        SDA2 84703517
         ST    WKRG3,SAVEA              SAVE REGISTER              SDA2 84703617
         LH    WKRG3,DCELBBNR(TIOUCBRG) GET BIN NO. FROM SUB UCB   SDA2 84703717
         SLL   WKRG3,4                  MULTIPLY BY 16             SDA2 84703817
         LA    WKRG3,UCBSIZE(WKRG3) ADD SIZE OF MAIN               SDA2 84703917
         SR    TIOUCBRG,WKRG3                                      SDA2 84704017
         CR    TIOUCBRG,UCBREG                                     SDA2 84704117
         L     WKRG3,SAVEA              RESTORE REGISTER           SDA2 84704217
         BNE   NEXTIOT                                             SDA2 84704317
         B     UCBTEST                  TEST UCB PROPERTIES        SDA2 84704417
TIONXTDD LR    TIOTREG,TIOEREG            UPDATE DD POINTR TO NEXT      84705016
         B     NEXTDD                     ENTRY IF THERE IS ONE         84706016
UCBTEST  TM    UCBID(UCBREG),X'FF'      WAS SUB-UCB PASSED         SDA2 84706117
         BC    1,UCBOK                  MAIN UCB DON'T ALTER       SDA2 84706217
         ST    WKRG3,SAVEA              SAVE WORK REGISTER         SDA2 84706317
         LH    WKRG3,DCELBBNR(UCBREG)   GET BIN # FROM SUB UCB     SDA2 84706417
         SLL   WKRG3,4                  MULTIPLY SIZE OF SUB UCB   SDA2 84706517
         LA    WKRG3,UCBSIZE(WKRG3)     ADD SIZE OF MAIN           SDA2 84706617
         SR    UCBREG,WKRG3             COMPUTE START OF MAIN      SDA2 84706717
         L     WKRG3,SAVEA              RESTORE WORK REG           SDA2 84707017
UCBOK    ST    UCBREG,RBSAVUCB(CURRB)   SAVE REAL UCB POINTER    A30097 84707120
         DROP  WORKREG7                                            REFR 84707518
CHKEND   TM    LISTEND(CURPARM),ENDIND  Q. LAST ELEMENT CHECKED@JK68363 84712021
         AGO   .SHRDA15                                                 84713016
.SHRDA2  ANOP                                                           84714016
         SPACE 1                                                        84720016
         TM    LISTEND(CURPARM),ENDIND  Q. LAST ELEMENT CHECKED@JK68363 84780021
.SHRDA15 ANOP                                                           84810016
         LA    CURPARM,PARMSIZE(CURPARM) ADVANCE TO NEXT ANYWAY         84840016
         LR    INPUTREG,CURPARM         SET INPUT REG FOR VALID CHK     84870016
         BZ    CHKFRNT                  GO CHECK LIST ELEMENT  @JK68363 84900021
         AIF   (&B(1)).SHRD460                                          84902016
         LR    CURPARM,TOPPARM    RESET FOR MAINLINE                    84908016
         BCR   15,LINKREG         RETURN TO MAINLINE                    84910016
SMALLDSI DS    0H            DATA SET INTEGRITY SUPPORT (IEFSD541       84912016
*                            ENQS DISABLED).                            84914016
         AIF   (NOT &B(2)).SHRD450                                      84916016
         TM    PARMCDS(CURPARM),RESERVE  IS THIS SYSTEMS REQUEST        84918016
         BC    11,COMPMAJ         NO. CHECK FOR DSI                     84920016
         TM    PARMCDS(CURPARM),X'08'  IS IT RESERVE REQUEST            84922016
         BC    8,COMPMAJ          NO                                    84924016
         L     UCBREG,PTRUCB(CURPARM)  GET UCB PARAMETER                84926016
         L     UCBREG,0(UCBREG)   GET UCB ADDRESS                       84928016
         ST    UCBREG,RBSAVUCB(CURRB)   SAVE UCB POINTER         A30097 84930020
         TM    DEVTYP-1(UCBREG),SHARED  IS THIS A SHAREABLE DEVICE      84932016
         BC    1,COMPMAJ          YES                                   84934016
         OI    PARMCDS(CURPARM),RESERVE  NO. CHANGE REQUEST TO SYSTEMS  84936016
COMPMAJ  DS    0H                                                       84938016
.SHRD450 ANOP                                                           84940016
         L     WORKREG3,PTRMAJ(TOPPARM)  GET ADDR OF MAJOR              84942016
         CLC   0(8,WORKREG3),DSIMAJ  IS DATA SET INTEGRITY ENQ'G        84944016
         BCR   7,LINKREG          NO, RETURN TO MAINLINE                84946016
         L     CURTCB,8(WORKREG3)  PICK UP TCB ADDR FOR ENQ PROC.       84948016
         BCR   15,LINKREG         RETURN TO MAINLINE                    84950016
DSIMAJ   DC    CL8'SYSDSN  '                                            84952016
         AIF   (&B(2)).SHRD461                                          84953016
         AGO   .SHRD462                                                 84954016
.SHRD460 ANOP                                                           84956016
         TM    PARMCDS(TOPPARM),SMC     Q. IS IT MUST COMPLETE          84960016
         BC    7,SMCINPP                YES, ABEND THE TASK             85020016
***  VALID LIST, FALL THROUGH                                           85080016
         LR    CURPARM,TOPPARM          RESET FOR MAINLINE              85140016
         L     BASEREG,BASESET          RESET BASE REGISTER             85200016
         BC    15,12(LINKREG)           RETURN OK                       85260016
.SHRD461 ANOP                                                           85270016
ENTER    L     WORKREG2,16              POINTER TO CVT                  85290016
         LA    INPUTREG,0(INPUTREG)     CLEAR HIGH ORDER BYTE           85320016
         CL    INPUTREG,CVTMZ00-CVT(WORKREG2)  TEST FOR IN CORE         85350016
         BCR   13,WORKREG1              ADDRESS IS OK                   85380016
         AIF   (&B(1)).SHRD463                                          85390016
         B     INVALID       BAD PARAM LIST.  ABEND                     85400016
         AGO   .SHRD462                                                 85410016
.SHRD463 ANOP                                                           85420016
INVALID  L     BASEREG,BASESET          RESET BASE REGISTER             85440016
         BCR   15,LINKREG               RETURN TO MAINLINE              85500016
BADLTH   L     BASEREG,BASESET          RESET BASE REGISTER             85560016
         BC    15,8(LINKREG)            GO TO ABEND                     85620016
SMCINPP  L     BASEREG,BASESET          RESET BASE REGISTER             85680016
         BC    15,4(LINKREG)            GO TO ABEND                     85740016
.SHRD462 ANOP                                                           85750016
WDTEST   TM    WORD,X'00'               TEST FOR WORD BOUNDARY          85760016
WORD     DC    X'03'                    MASK FOR BOUNDARY TEST          85770016
         AIF   (NOT &B(1)).SHRD470                                      85780016
         SPACE 1                                                        85800016
         DROP  GENREG                                                   85860016
         USING IGC048+2,BASEREG                                         85920016
         SPACE 1                                                        85980016
         SPACE 3                                                        86040016
VALIDCHK DC    A(IEA0VL01)              EP OF VALIDITY CHECK ROUTINE    86100016
BASESET  DC    A(IGC048+2)              TO RESET BASE REGISTER          86160016
ADFREE   DC    V(RMBRANCH)              EP TO FREEMAIN                  86220016
.SHRD470 ANOP                                                      SDA2 86250017
         EJECT                                                          86400016
GETERR   LA    ABENDREG,X'80A' .   GET MAIN FAILED                1874  86414020
         BC    15,ABEND22          ABEND THE GUY                  1874  86416020
ERRX1    DS    0H            ENQ ISSUED WITH QEL ON QUEUE - CODE IS     86420016
*                            X'138'                                     86440016
DRRX1    LA    ABENDREG,X'130'          NO QEL PRESENT FOR A DEQ        86460016
         BC    15,ABEND2                                                86520016
ERRX2    DS    0H  INVALID NAME LENGTH ON ENQ - CODE IS X'238'          86550016
DRRX2    LA    ABENDREG,X'230'          INVALID NAME LENGTH ON DEQ      86580016
         BC    15,ABEND2                                                86640016
ERRX3    DS    0H  SMC SPECIFIED WITH KEY N. E. 0 - CODE IS X'338'      86670016
DRRX3    LA    ABENDREG,X'330'          RMC ISSUED IN PP MODE           86700016
         BC    15,ABEND2                                                86760016
         AIF   (&B(1)).SHRD472                                          86780016
CHECK    CR    WORKREG3,WORKREG1       IS ADR ABOVE LOW BOUNDARY    LCS 86780617
         BC    4,INVALID               NO - IT IS BELOW             LCS 86781217
         LTR   RE,RE                   IS LCS IN EFFECT             LCS 86781817
         BNZ   CHECK2                  YES                          LCS 86782417
CHK3     BALR  WORKREG7,BRCHECK        SO CHECK WILL PICK UP HERE   LCS 86783017
         CR    WORKREG3,WORKREG2       IS ADR BELOW HI BOUND        LCS 86783617
         BC    2,INVALID               NO                           LCS 86784217
CHK4     LA    WORKREG7,CHECK          SET SO WITH NEXT NEW ADR     LCS 86784817
         BCR   15,BRCHECK                 WILL START AT BEG SUBRTN  LCS 86785417
CHECK2   CR    WORKREG3,RE             LCS - IS ADR ABOVE LO BOUND  LCS 86786017
         BC    4,CHK3                  NO-SET SO WONT CHECK LCS HE  LCS 86786617
         BALR  WORKREG7,BRCHECK        SET SO CHECKS AGAINST LCS HI LCS 86787217
         CR    WORKREG3,RF             IS ADR BELOW HI LCS BOUND    LCS 86787817
         BC    13,CHK4                 YES-SET                      LCS 86788417
INVALID  DS    0H                                                       86790016
.SHRD472 ANOP                                                           86800016
ERRX4    DS    0H           BAD INPUT LIST FOR ENQ - X'438'             86810018
DRRX4    LA    ABENDREG,X'430'          INVALID PARAMETER LIST          86820016
         BC    15,ABEND2                                                86880016
DRRX5    LA    ABENDREG,X'530'          DEQ FOR ELEMENT NOT IN CONTROL  86940016
ABEND2   L     GENREG,RBLINK(CURRB)                                     87040016
         IC    ABENDREG,PSWADR+3(GENREG)  INSERT SVC CODE TO            87140016
         SLL   ABENDREG,12        DEVELOP ERRO CODE FOR ABEND           87240016
ABEND22  EQU   *                                                   1874 87440018
         ABEND (1),DUMP                                                 87720016
         EJECT                                                          87780016
         DS    0F                                                       87840016
NEW      DC    AL4(IEATCBP)             ADDRESS OF NEW     * MUST BE    88020016
DISPATCH DC    AL4(IEA0DS)              ADDR OF DISPATCHER * CONTIG.    88080016
MASTER    DC   V(IEAMSTCB)      ADDRESS OF MASTER TCB                   88084018
         AIF   (&B(1)).SHRD480                                          88088016
ADSYMCSW DC    V(DSYMCSW)                                               88112016
.SHRD480 ANOP                                                           88128016
         SPACE 3                                                        88200016
SP255    DC    X'F5000000'             GM/FM FOR SUBPOOL 245      20021 88260020
MASKFULL DC    X'FFFFFFF8'              FOR ROUNDING TO A DBL WORD      88320016
         AIF   (NOT &B(3)).TSO1005                                20021 88330020
TSDRVMSK DC    X'00007FFF'        MASK FOR TIME SHARING          20021  88340020
*                                      DRIVER INPUT REG 0.        20021 88350020
.TSO1005 ANOP                                                     20021 88360020
         AIF   (&B(1)).SHRD495                                          88390016
SYSMASK  DC    X'0008'       NOT DISPATCHABLE MASK                      88460016
STEPMSK  DC    X'0004'                  STEP MUST COMPLETE        19054 88470019
RMCSTPMK DC    X'FFFB'                 RESET STEP MUST COMPLETE   19054 88480019
ABSVRBNM DC    X'F1C3'              ABEND IDENTIFIER              19054 88490019
RMCSYSMK DC    X'FFF7'       RESET MUST COMPLEYE MASK                   88530016
.SHRD495 ANOP                                                           88600016
GETFOUR  DC    F'4'     TEST FOR RETURN CODE FROM GETMAIN          1874 88640018
RLWKADD  DC    F'0'                ADDR RETURNED OF GM'D CORE  @JK69690 88660021
         SPACE 3                                                        88680016
COMPNAME CLC   0(0,GENREG),MINAME(CURMIN)  EXECUTED TO COMP MINOR NAMES 88740016
MOVENAME MVC   MINAME(0,GMRETREG),0(GENREG)  EX TO MOVE MINOR NAME      88800016
LTHINST  CLI   LMINAME(CURMIN),X'00'    EXECUTED TO COMPARE MINOR       88860016
*                                       NAME LENGTHS                    88920016
         AIF   (&B(1)).SHRD500                                          88950016
SMCINST  OI    TCBDISP(TCBREG),X'00'    FOR SETTING NON-DISPATCHABLE    88980016
RMCINST  NI    TCBDISP(TCBREG),X'00'    FOR SETTING DISPATCHABLE        89040016
         SPACE 3                                                        89100016
EXITPSW  DC    X'FF04000000'   PSW FOR WAITING TASKS                    89114016
         DC    AL3(GOEXIT)                                              89121016
MCOP     DC    X'FF04000000'      PSW FOR MC TASKS                      89128016
         DC    AL3(OPRSMC)                                              89135016
         AGO   .SHRD510                                                 89142016
.SHRD500 ANOP                                                           89149016
TASKSWT  DC    A(IEA0DS02)             TASK SWITCH ROUTINE ADDRESS      89160016
ADREXIT  DC    X'00040000'              PSW FOR                         89220016
         DC    A(EXITNORM)              WAITING TASKS                   89280016
MCOP     DC    X'00040000'              PSW FOR                         89340016
         DC    A(OPRSMC)                MC TCBS                         89400016
.SHRD510 ANOP                                                           89430016
         AIF   (&B(1)).SHRD999                                     REFR 89434018
ENTNQDQ  DC    V(IEAQCB01)                                         REFR 89438018
         AGO   .SHRD998                                            REFR 89442018
.SHRD999 ANOP                                                      REFR 89446018
ENTNQDQ  DC    V(IEAQCB02)                                         REFR 89450018
.SHRD998  ANOP                                                     REFR 89454018
         AIF   (&B(1)).GEN70                                      19772 89454819
IEAGENA1 EQU   *                                                  19772 89455619
         AGO   .GEN80                                             19772 89456419
.GEN70   ANOP                                                     19772 89457219
IEAQENA1 EQU   *                                                  19772 89458019
.GEN80   ANOP                                                     19772 89458819
         SPACE 2                                                        89460016
         AIF   (NOT &B(2)).SHRDA19                                      89581016
RLDCB    DSECT          DCB,ECB, IOB, AND DEB USED FOR RELEASE EXCP     89582016
RLECB    DS    F                  ECB TO WAIT ON                        89583016
RLIOB    DS    0F                 START OF IOB                          89584016
IOBFL1   DS    X                  IOB FLAGS                             89585016
IOBFL2   DS    X                  IOB FLAGS                             89586016
         DS    H                  FILLER                                89587016
IOBECBAD DS    F                  ADR OF ECB TO BE POSTED               89588016
         DS    2F                 FILLER                                89589016
IOBSTART DS    F                  ADR OF CHANNEL PROGRAM                89590016
IOBDCBAD DS    F                  ADR OF ASSOCIATED DCB                 89591016
         DS    2F                 FILLER                                89592016
IOBMOD   DS    X                  MODIFIER - DEB EXTENT NUMBER          89593016
IOBSK    DS    CL4                BBCC TO SEEK TO                       89594016
         DS    CL3                FILLER                                89595016
DCBDEBAD DS    F                  I FLAGS AND SDR OF ASSOC. DEB         89596016
RLCCW    DS    X                  CCW OP CODE                           89597016
         DS    CL3                FILLER                                89598016
         DS    X                  CCW GLAGS                             89599016
         DS    CL2                FILLER                                89600016
         DS    X                  BYTE COUNT -END OF IOB INDICATOR      89601016
DEAPGV   DS    4F                 APPENDAGE VECTOR TABLE                89602016
DENEXT   DS    X                  NUMBER OF EXTENTS                     89603016
         DS    CL3                REMAINDER OF APG VECT TABLE           89604016
DEPRIOR  DS    X                  DEB PRIORITY                          89605016
         DS    X                  FILLER BYTE                           89606016
DEVRET   DS    H                  APG VECT TABLE RETURN                 89607016
DEPKID   DS    0X                 USERS PROT KEY AND DEB ID             89608016
DEDCBAD  DS    F                  ADR OF ASSOCIATED DCB                 89609016
DEEXTSCL DS    0X                 SIZE OF EXTENTS                       89610016
DEAPPAD  DS    F                  ADR OF APG VECT TABLE                 89611016
DEFM     DS    X                  FILE MASK                             89612016
         DS    X                  FILLER BYTE                           89613016
DEUCBAD  DS    H                  ADR OF UCB                            89614016
DEBB     DS    H                  BIN OF DEVICE                         89615016
DESTART  DS    2H                 START CCHH OF EXTENT                  89616016
DEEND    DS    2H                 END CCHH OF EXTENT                    89617016
DETRKS   DS    H                  NO OF TRACKS ALLOCATED                89618016
.SHRDA19 ANOP                                                           89619016
         AIF   (&B(1)).SHRD700                                     REFR 89621018
         IEAQCB  MFT,D                                             REFR 89623018
         AGO    .SHRD710                                           REFR 89625018
.SHRD700     ANOP                                                  REFR 89627018
         IEAQCB  MVT,D                                             REFR 89631018
.SHRD710    ANOP                                                        89635018
*   COMMUNICATION VECTOR TABLE DEFINITION                               89639016
CVT      DSECT                                                          89659016
         CVT   SYS=MVT                                            20021 89663020
         AIF   (NOT &B(3)).TSO1010                                20021 89667020
         EJECT                                                    20021 89671020
         IKJTSCVT                                                 20021 89675020
         EJECT                                                    20021 89679020
*        JOB STEP CONTROL BLOCK                                   20021 89683020
         IEZJSCB                                                  20021 89687020
         SPACE 3                                                  20021 89691020
.TSO1010 ANOP                                                     20021 89695020
         MEND                                                           89700016
