         MACRO                                                          00500019
         IEANQPRG                                                       01000019
* DISPLACEMENTS                                                         01500019
HEADPTR  EQU   12                                                       02000019
RETREG   EQU   14                                                       02500019
CVTAD    EQU   16                                                       03000019
TWENTY8  EQU   28                                                       03500019
ABENDAD  EQU   52                                                       04000019
* REG EQU'S                                                             04500019
R3       EQU   3                                                        05000019
CURMAJ   EQU   7                                                        05500019
CURMIN   EQU   8                                                        06000019
CURQEL   EQU   9                                                        06500019
WORKREG  EQU   10                                                       07000019
SVRBRG   EQU   11                                                       07500019
WAITCT   EQU   12                                                       08000019
WORKREG2 EQU   12                                                       08500019
LINKREG  EQU   13                                                       09000019
IEAATPRG EQU   *                                                        09500019
         LA    TEMPTCB,0(TEMPTCB)                                       10000019
         L     CURMAJ,CVTAD             GET PTR                         10500019
         L     CURMAJ,ABENDAD(CURMAJ)       TO FIRST QCB THRU CVT       11000019
         L     CURMAJ,HEADPTR(CURMAJ)          AND ABTERM               11500019
MAJLOOP  L     CURMAJ,ZERO(CURMAJ)      GET NEXT MAJOR                  12000019
         LTR   CURMAJ,CURMAJ            IS THERE ANOTHER                12500019
         BC    8,GETTCB                 NO                              13000019
         L     CURMIN,EIGHT(CURMAJ)     GET NEXT MINOR                  13500019
MINLOOP  LTR   CURMIN,CURMIN            IS THERE ANOTHER                14000019
         BC    EIGHT,ENDMAJOR           NO                              14500019
         L     CURQEL,ZERO(CURMIN)                                      15000019
QELLOOP  LA    CURQEL,ZERO(CURQEL)      CLEAR HIGH ORDER BYTE           15500019
         LTR   CURQEL,CURQEL            IS THERE ANOTHER                16000019
         BC    EIGHT,ENDMINOR           NO                              16500019
         CL    TEMPTCB,EIGHT(CURQEL)    DOES QEL BELONG TO TCB          17000019
         BE    FOUNDQEL                 YES                             17500019
         L     CURQEL,ZERO(CURQEL)                                      18000019
         B     QELLOOP                                                  18500019
FOUNDQEL L     WORKREG,FOUR(CURQEL)     GET BACK PTR                    19000019
         LA    WORKREG,ZERO(WORKREG)                                    19500019
         CR    WORKREG,CURMIN           IS BACK PTR A MINOR             20000019
         BE    NEXTQEL                  YES -BELOW QEL WAS NOT FIRST    20500019
         TM    FOUR(CURQEL),X'80'       IS CURQEL SHARED                21000019
         BC    ONE,DEQQEL               YES                 X,S         21500019
         TM    FOUR(WORKREG),X'80'      IS LAST QEL EXCLUSIVE ALSO      22000019
         BC    ZERO,DEQQEL              YES                 E,E         22500019
         L     WORKREG,ZERO(CURQEL)     GET NEXT QEL        S,E         23000019
         LA    WORKREG,ZERO(WORKREG)    IS IT ALSO                      23500019
         LTR   WORKREG,WORKREG                                          24000019
         BZ    DEQQEL                                                   24500019
         TM    FOUR(WORKREG),X'80'         SHARED                       25000019
         BZ    DEQQEL      S,E,E                                        25500019
SEARCHQ  L     WORKREG,FOUR(CURQEL)     GET BACK PTR X,S,E,S            26000019
LOOP     TM    FOUR(WORKREG),X'80'      IS IT SHARED                    26500019
         BC    EIGHT,DEQQEL             NO                              27000019
         L     WORKREG,FOUR(WORKREG)    GET NEXT BACK PTR               27500019
         CR    WORKREG,CURMIN           HAVE I GONE BACK TO MINOR YET   28000019
         BNE   LOOP                     NO                              28500019
         L     WORKREG,ZERO(CURQEL)                                     29000019
         LA    WORKREG,ZERO(WORKREG)    CLEAR HI BYTE                   29500019
         B     NEXTQEL2                                                 30000019
NEXTQEL  TM    FOUR(CURQEL),X'80'       IS CURRENT SHARED               30500019
         L     WORKREG,ZERO(CURQEL)     GET NEXT                        31000019
         BC    ONE,TESTNEXT            YES      S,X                     31500019
NEXTQEL2 EQU   *                                                        32000019
         LTR   WORKREG,WORKREG          QEL EXIST                       32500019
         BZ    DEQQEL                   NO                              33000019
         L     SVRBRG,TWELVE(WORKREG)   GET SVRB FROM NEXT QEL CURQEL   33500019
*                                       . IS EXCLUSIVE                  34000019
         SR    WAITCT,WAITCT                                            34500019
         IC    WAITCT,TWENTY8(SVRBRG)   GET WAIT COUNT                  35000019
         LTR   WAITCT,WAITCT            IS IT 0                         35500019
         BC    EIGHT,NOSWTCH            YES                             36000019
         BCTR  WAITCT,0                 DECREMENT                       36500019
         STC   WAITCT,TWENTY8(SVRBRG)   STORE                           37000019
TESTRESV TM    FOUR(WORKREG),X'40'      IS WORKING QEL RESERVED         37500019
         BC    EIGHT,NORESV             NO                              38000019
         L     WORKREG2,EIGHT(WORKREG)  GET TCB                         38500019
         L     WORKREG2,104(WORKREG2)   GET PARM POINTER                39000019
         ST    WORKREG2,TWELVE(WORKREG)                                 39500019
         IC    SVRBRG,40(WORKREG2)      INC.                            40000019
         LA    SVRBRG,ONE(SVRBRG)          RESERVE                      40500019
         STC   SVRBRG,40(WORKREG2)            COUNT                     41000019
NORESV   EQU    *                                                       41500019
         LTR   WAITCT,WAITCT            IS IT 0                         42000019
         BNZ    NOSWTCH                                                 42500019
SWITCH   L     WORKREG2,EIGHT(WORKREG)                                  43000019
         CLC   35(ONE,TEMPTCB),35(WORKREG2) IS THIS TCB OF HIGHER PIROR 43500019
         BC    10,NOSWTCH               NO                              44000019
         L     SVRBRG,CVTAD                                             44500019
         L     SVRBRG,ZERO(SVRBRG)      GET NEW/OLD @                   45000019
         ST    WORKREG2,ZERO(SVRBRG)                                    45500019
NOSWTCH  L     WORKREG2,ZERO(WORKREG)        GET NEW  NEXT              46000019
         TM    FOUR(WORKREG),X'80'      IS LAST 'NEXT'EXCLUSIVE         46500019
         BC    ZERO,DEQQEL              YES, DO NO MORE                 47000019
         LR    WORKREG,WORKREG2         SET REG TO                      47500019
         LA    WORKREG,ZERO(WORKREG)                                    48000019
         LTR   WORKREG,WORKREG                                          48500019
         BZ    DEQQEL                                                   49000019
         TM    FOUR(WORKREG),X'80'                                      49500019
         BC    8,DEQQEL                                                 50000019
         B     NEXTQEL2                   REPEAT LOOP                   50500019
TESTNEXT EQU   *                                                        51000019
         LA    WORKREG,ZERO(WORKREG)                                    51500019
         LTR   WORKREG,WORKREG                                          52000019
         BZ    DEQQEL                                                   52500019
         TM    FOUR(WORKREG),X'80'      IS NEXT ALSO SHARED             53000019
         BC    EIGHT,NEXTQEL2            NO       S,E                   53500019
         B     DEQQEL                  YES       S,S                    54000019
ENDMINOR L     WORKREG,ZERO(CURMIN)     DOES MINOR                      54500019
         LTR   WORKREG,WORKREG            HAVE ANY QELS                 55000019
         BC    EIGHT,DEQMIN             NO                              55500019
         L     CURMIN,EIGHT(CURMIN)      GET NEXT MINOR                 56000019
         B     MINLOOP                                                  56500019
ENDMAJOR L     WORKREG,EIGHT(CURMAJ)    DOES MAJOR                      57000019
         LTR   WORKREG,WORKREG            HAVE ANY MINORS               57500019
         BC    EIGHT,DEQMAJ             NO                              58000019
         B     MAJLOOP                                                  58500019
DEQ      L     WORKREG,ZERO(WORKREG2)         SUBROUTINE                59000019
         LA    WORKREG,ZERO(WORKREG)               TO                   59500019
         LTR   WORKREG,WORKREG                                          60000019
         BC    EIGHT,ENDCHAIN                       REMOVE  A           60500019
         MVC   FOUR(FOUR,WORKREG),FOUR(WORKREG2)           CONTROL      61000019
ENDCHAIN L     WORKREG,FOUR(WORKREG2)                   BLOCK           61500019
         MVC   ONE(3,WORKREG),ONE(WORKREG2)               FROM A        62000019
         BR    SVRBRG                                       QUEUE       62500019
DEQQEL   LR    WORKREG2,CURQEL       GO TO REMOVE                       63000019
         BAL   SVRBRG,DEQ                QEL FROM QUEUE                 63500019
         TM    FOUR(WORKREG2),X'40'  IS DEQ'D QEL RESERVED              64000019
         BC    EIGHT,NOTRESV                                            64500019
         STM   1,3,XRBESA               QEL IS RESERVED SO MUST GO TO   65000019
         STM   6,14,XRBESA+12             RESIDENT CORE TO RELEASE      65500019
         L     R3,TWELVE(CURQEL)                                        66000019
         BALR  LINKREG,DEQADDR                                          66500019
         LM    1,3,XRBESA               RESTORE                         67000019
         LM    6,14,XRBESA+12               REGS                        67500019
NOTRESV  LR    ONE,CURQEL               GET NEXT QEL AND                68000019
         L     CURQEL,ZERO(CURQEL)                                      68500019
         L     ZERO,FREEQEL               PREPARE TO FREE CORE          69000019
         SVC   10                                                       69500019
         B      QELLOOP                 BRANCH BACK TO MAINLINE         70000019
DEQMIN   L     WORKREG2,EIGHT(CURMIN)                                   70500019
         LTR   WORKREG2,WORKREG2                                        71000019
         BC    EIGHT,ONLY                                               71500019
         MVC   FOUR(FOUR,WORKREG2),FOUR(CURMIN)                         72000019
ONLY     L     WORKREG2,FOUR(CURMIN)                                    72500019
         MVC   EIGHT(FOUR,WORKREG2),EIGHT(CURMIN)                       73000019
         LR    ONE,CURMIN               GET NEXT MINOR                  73500019
         L     CURMIN,EIGHT(CURMIN)        AND PREPARE FOR FREEMAIN     74000019
         SR    ZERO,ZERO                                                74500019
         IC    ZERO,TWELVE(CURMIN)      GET SIZE OF                     75000019
         LA    ZERO,21(ZERO)          MINOR                             75500019
         N     ZERO,DOUBRND                                             76000019
         O     ZERO,FREEMIN                                             76500019
         SVC   10                                                       77000019
         B     MINLOOP                                                  77500019
DEQMAJ   LR    WORKREG2,CURMAJ          BRANCH TO                       78000019
         BAL   SVRBRG,DEQ                  DEQ MAJOR                    78500019
         LR    ONE,CURMAJ               GET NEXT MAJOR                  79000019
         L     CURMAJ,ZERO(CURMAJ)         AND FREE                     79500019
         L     ZERO,FREEMAJ                  CORE                       80000019
         SVC   10                                                       80500019
         B     MAJLOOP+FOUR             RETURN TO MAINLINE              81000019
         DS    0F                                                       81500019
DOUBRND  DC    X'FFFFFFF8'                                              82000019
FREEMAJ  DC    X'FF000018'              INDICATES                       82500019
FREEMIN  DC    X'FF000000'                 SUBPOOLS AND                 83000019
FREEQEL  DC    X'FF000010'                   SIZES FOR FREEMAINS        83500019
         MEND                                                           84000019
