         MACRO                                                          00030020
         IEAQWT &TSO=                                             20021 00040020
         LCLB   &B(1)             LOCAL SWITCH                    20021 00050020
&B(1)    SETB    ('&TSO' EQ 'YES')                                20021 00060020
         TITLE '**WAIT * POST * TCB SWITCHING **'                       00070020
IGC001   START                                                          00080020
         SPACE 2                                                        00090020
*WAITING ECB                                                            00100020
*************************                                               00110020
* S     *               *                                               00120020
*  BIT  * WAITING RB'S  *                                               00130020
*   ON  *   ADDRESS     *                                               00140020
*************************                                               00150020
         SPACE 1                                                        00160020
*POSTED ECB                                                             00170020
*************************                                               00180020
* 1       BITS 2-31     *                                               00190020
*  BIT     COMPLETION   *                                               00200020
*   ON      CODE        *                                               00210020
*************************                                               00220020
         SPACE 2                                                        00230020
* KEYS FOR OPERATIONAL SYMBOLS.                                         00240020
*        INITIATE                       $                               00250020
*        EXIT-NORMAL                    *                               00260020
*        EXIT-SUBROUTINE                **                              00270020
*        EXIT-ERROR                     ***                             00280020
*        SPECIAL ENTRY POINT            /                               00290020
*        INTERROGATE                    Q.                              00300020
         SPACE 1                                                        00310020
* TCB DISPLACEMENTS.                                                    00320020
TCBRBP   EQU   0         POINTER TO TOP RB OF TCB'S RB QUEUE            00330020
TCBPKF   EQU   28                      PROTECT KEY FIELD           MTS0 00340020
TCBFLG   EQU   29                      BEGINNING TCB FLAG BYTES    MTS0 00350020
TCBGRS1  EQU   52        TCB'S GENERAL REG. 1 SAVE AREA                 00360020
TCBTME   EQU   120                     ADDRESS OF TIMER QUEUE ELEM MTS0 00370020
TCBJSTCB EQU   124                     ADDRESS OF JOB STEP TCB     MTS0 00380020
TCBNTC   EQU   128                     ADDRESS OF SISTER TCB       MTS0 00390020
TCBOTC   EQU   132                     ADDRESS OF ORIGIN TCB       MTS0 00400020
TCBLTC   EQU   136                     ADDRESS OF DAUGHTER TCB     MTS0 00410020
TCBTCT   EQU   164      TCT OFFSET                                  SMF 00420020
TCBABTRM EQU   X'20'    BIT SET DURING ABTERM PROCESSING         A22207 00430020
TCBFA    EQU   X'80'    BIT SET DURING ABEND PROCESSING          A22207 00440020
TCBFLGS  EQU   X'1D'                                               4868 00450020
TCBJSCB  EQU   X'B4'     DISP TO JSCB PTR                         20002 00460020
         SPACE 1                                                        00470020
* RB DISPLACEMENT.                                                      00480020
RBSTAB   EQU   10        STATUS AND ATTRIBUTE FIELD                     00490020
WCTSAVE  EQU   X'18' .  OFFSET TO XSNT-SVRB WAIT COUNT FIELD     A33247 00495020
RBWCF    EQU   28        WAIT COUNT FIELD                               00500020
RBLINK   EQU   28        LINK FIELD (POINTS TO NEXT RB OR TCB)          00510020
SVRBXR1  EQU   36        SVRB REGISTER 1 SAVE AREA                      00520020
IRBXR1   EQU   36       IRB REG.1 SAVE AREA                             00530020
         SPACE 1                                                        00540020
* TQE DISPLACEMENTS.                                               MTS0 00550020
TQEFLGS  EQU   0                       FLAG BYTE IN THE TQE        MTS0 00560020
TQEVAL   EQU   12                      TOX/TIME REMAINING          MTS0 00570020
TQESAV   EQU   20                      CPU TIME REMAINING S.A.     MTS0 00580020
         SPACE 1                                                   MTS0 00590020
* TQE FLAG DESCRIPTIONS                                            MTS0 00600020
* BIT 0 - TQE OFF TIMER QUEUE                                      MTS0 00610020
* BIT 1 - TOD OPTION SPECIFIED                                     MTS0 00620020
* BITS 2 AND 3                                                     MTS0 00630020
*   00  - TUINTVL REQUESTED                                        MTS0 00640020
*   10  - RESERVED                                                 MTS0 00650020
*   01  - BINTVL REQUESTED                                         MTS0 00660020
*   11  - DECINTVL REQUESTED                                       MTS0 00670020
* BIT 4 - INTERVAL IS COMPLETE                                     MTS0 00680020
* BIT 5 - EXIT SPECIFIED                                           MTS0 00690020
* BITS 6 AND 7                                                     MTS0 00700020
*   00  - TASK OPTION                                              MTS0 00710020
*   10  - SUPERVISOR ELEMENT                                       MTS0 00720020
*   01  - WAIT REQUEST                                             MTS0 00730020
*   11  - REAL OPTION                                              MTS0 00740020
         SPACE 1                                                   MTS0 00750020
* GENERAL EQUATES                                                       00760020
CVTPTR   EQU   X'10' .                 ADDRESS OF CVT POINTER     20021 00770020
NEWPTR   EQU   0         LOGICAL ADDRESS TO 'NEW'                       00780020
ERRWAIT1 EQU   X'0101'   WAIT'S, WAIT COUNT TO BIG                      00790020
ERRWAIT2 EQU   X'0201'   WAIT ECB ADDRESS INVALID                       00800020
ERRWAIT3 EQU   X'0301'   WAIT TRYING TO PUT WAITING ECB IN WAIT         00810020
ERRPOST1 EQU   X'0102'   POST ECB ADDRESS INVALID                       00820020
ERRPOST2 EQU   X'0202'   POST ECB'S RB ADDRESS INVALID                  00830020
RBECBWT  EQU   X'01'     RB'S ECB SEARCH INDICATOR                      00840020
RBWAITP  EQU   X'08' .                 RB WAITING ON ECB      CI A45983 00842021
XSNTSVRB EQU   X'D0' .  RBSTAB BITS TO TEST FOR XSNT SVRB        A33247 00845020
LHOPSW   EQU   16        OPSW DISPLACEMENT                              00850020
RHOPSW   EQU   20        RIGHT HALF OPSW DISPLACEMENT                   00860020
SVCOPSW  EQU   32                      LOW CORE ADDR SVC OLD PSW   MTS0 00870020
ECBPTFLG EQU   X'40'     ECB POST FLAG                                  00880020
CVTQTE00 EQU   104                     ADDRESS ENQUEUE TIMER RTN   MTS0 00890020
RECBWTF  EQU   X'7F'     RESET ECB'S WAIT FLAG/LAST ECB PTR             00900020
LSTIND   EQU   X'80'     LAST ECB INDICATOR                             00910020
TCBIND   EQU   X'80'     RBLINK INDICATES TCB ADDRESS                   00920020
ECBWTFLG EQU   X'80'     ECB WAIT FLAG                                  00930020
RBFTP    EQU   X'C0'     RB TYPE INDICATOR                              00940020
MACHSIZE EQU   X'A4'     CVT DISP. FOR MACHINE SIZE                     00950020
SUPTST   EQU   X'F0'     PSW AMWP                                       00960020
RRBECBWT EQU   X'FE'     RESET RB'S ECB SEARCH FLAG                     00970020
ANYONE   EQU   X'FF'     TEST FOR ANY BIT IN A GIVEN BYTE               00980020
TCTWLMT  EQU   44       TCT JOB/STEP MAX WAIT TIME LIMIT            SMF 00990020
TSCVTPTR EQU   228 .                   CVT DISP FOR TSCVT PTR     20021 01000020
CVTTSRDY EQU   X'80' .                 TIME SHARING ACTIVE FLAG   20021 01010020
TSTASK   EQU   X'80' .                 INDICATES SWAPPED TIME-    20021 01020020
*                                      SHARING TASK               20021 01030020
TCBTSFLG EQU   148 .                   DISP TO TIME SHARING FLAG  20021 01040020
FOUR     EQU   4 .                                                20021 01050020
L16      EQU   16 .                    LENGTH OF IPPB             20021 01060020
R15SAV   EQU   60 .                    DISP IN SVC SAVE AREA TO   20021 01070020
*                                      REGISTER 15 WORD           20021 01080020
TRSVRB   EQU   X'D0' .                 INDICATE TRANS. SVRB       20021 01090020
ZERO     EQU   0 .                     CONSTANT                   20021 01100020
ONE      EQU   1 .                     SHIFT OUT TJID INDICATOR   20021 01110020
TJIDTEST EQU   6                       TEST TJID BIT REGISTER     20021 01120020
         SPACE 2                                                        01130020
* REGISTER EQUATES.                                                     01140020
         SPACE 1                                                        01150020
* WAIT AND POST                                                         01160020
XRECB    EQU   1         INPUT ECB OR ECB LIST ADDRESS                  01170020
XRERCODE EQU   1         ERROR CODE                                     01180020
XRTSTADR EQU   2         ADDRESS OF VALIDITY CHECK ROUTINE              01190020
TQELNKRG EQU   2                       LINK REG FOR TQE DEQ RTN    MTS0 01200020
TCTPTR   EQU   2        TCT ADDRESS                                 SMF 01210020
COMMREG  EQU   2         DSECT REG TO FIND COMMUNICATION'S ECB    20002 01220020
XRCVT    EQU   3         CVT TABLE ADDRESS                              01230020
ERRBASE  EQU   3 .       BASE TO ALLOW USE OF ERROR SUBROUTINE    M3988 01232020
XROTCB   EQU   4         ADDRESS OF 'OLD' TCB OR WAITING TCB            01240020
TCBREG   EQU   4                       ADDRESS OF 'OLD' TCB        MTS0 01250020
XRSAV6   EQU   6                                                   MTS0 01260020
CHECKREG EQU   6         ECB ADDR REG FOR COMMCHEK SUBROUTINE     20002 01270020
SELREG   EQU   9                       WORK REGISTER               MTS0 01280020
XRECBPTR EQU   10        UPDATED ECB ADDRESS                            01290020
ATCBREG  EQU   10                      ALTERNATE TCB REGISTER      MTS0 01300020
XRSAVE   EQU   11        SAVE REGISTER FOR REG. 1                       01310020
XRLINK   EQU   12        LINK REGISTER                                  01320020
LINKREG  EQU   12                      LINK REGISTER               MTS0 01330020
XRABTERM EQU   13        ABTERM ROUTINE ADDRESS                         01340020
XRRETURN EQU   14        TYPE 1 SVC HANDLER ADDRESS (SVCXT)             01350020
XRBASE   EQU   15        BASE REGISTER                                  01360020
         SPACE 1                                                        01370020
* WAIT ROUTINE                                                          01380020
XRWAITCT EQU   0         INPUT WAIT COUNT                               01390020
XRTESTWD EQU   1         ADDRESS TO BE VALIDATED                        01400020
XRNEW    EQU   3         ADDRESS OF 'NEW'                               01410020
XRORB    EQU   5         ADDRESS OF CURRENT RB                          01420020
XRECBCTR EQU   7         ECB COUNTER                                    01430020
XRZERO   EQU   7         ZERO REGISTER                                  01440020
XRWTCT   EQU   8         WORK, WAIT COUNT                               01450020
XRWECB   EQU   9         WORK, ECB ADDRESS                              01460020
         SPACE 1                                                        01470020
* POST ROUTINE                                                          01480020
XR0      EQU   0         WORK,SAVE REGISTER                             01490020
XRPTCODE EQU   0         INPUT POST CODE                                01500020
XRM0     EQU   0 .                                                20021 01510020
PARMECB  EQU   0         PARM LIST DISPLACEMENT FOR IPP ECB       21B72 01515021
XRM1     EQU   1 .                                                20021 01520020
NEWIPPB  EQU   5 .                     ADDRESS OF NEW IPPB        20021 01530020
XRQUIT   EQU   2         ERROR CODE REGISTER                            01540020
XRRB     EQU   2         ECB'S RB ADDRESS                               01550020
XRTSCVT  EQU   2 .                 TIME-SHARING CVT ADDRESS       20021 01560020
XRTJB    EQU   2 .                 ADDRESS OF TJB TABLE           20021 01570020
PARMTJID EQU   4         PARM LIST DISPLACEMENT FOR IPP TJID      21B72 01575021
XRWORK5  EQU   5         WORK,GENERAL REGISTER                          01580020
XRTJID   EQU   5 .                 TJID REGISTER                  20021 01590020
XRSVCS   EQU   5 .                 SVC REGISTER SAVE AREA ADDR    20021 01600020
XRWORK   EQU   6         WORK, GENERAL REGISTER                         01610020
IPPBREG  EQU   7 .                  IPPB SCAN REG.                20021 01620020
XTEMPBAS EQU   7 .                  SAVE BASE ACROSS GETMAIN      20021 01630020
XRNUSE   EQU   8 .                  NUMBER OF USERS -MAX TJID     20021 01640020
PARMTCB  EQU   8         PARM LIST DISPLACEMENT FOR IPP TCB       21B72 01645021
XRWRB    EQU   10        WORK, RB ADDRESS                               01650020
XRWTCT1  EQU   11        WORK, WAIT COUNT                               01660020
XRCHCK1  EQU   11        WORK,REG FOR RB CHECK                          01670020
XRCHCK2  EQU   12        WORK,REG FOR RB CHECK                          01680020
XRWRB1   EQU   12        WORK, RB ADDRESS                               01690020
XRBTJID  EQU   13 .                    BRANCH ENTRY TJID REGISTER 20021 01700020
XRREGM   EQU   15 .                    LINK REGISTER TO REGMAIN   20021 01710020
XRTSIP   EQU   15 .                    ENTRY POINT OF TSIP        20021 01720020
         SPACE 1                                                        01730020
* TCB SWITCHING                                                         01740020
REGRTCB  EQU   10        READY TCB                                      01750020
REGSWTCH EQU   11        TASK SWITCH ROUTINE                            01760020
         SPACE 2                                                        01770020
* ENTRY AND EXTRN STATMENTS.                                            01780020
         EXTRN IEA0XE00                                                 01790020
         ENTRY IEA0PT01                                                 01800020
         ENTRY IEA0PT02                                                 01810020
         ENTRY IGC002                                                   01820020
         EXTRN IEA0DS02                                                 01830020
         EXTRN IEAQTD01                                            MTS0 01840020
         EXTRN IEATCBP                                                  01850020
         EXTRN IEA0AB01                                                 01860020
         EXTRN IEA0VL01                                                 01870020
         EXTRN IORGSW .                                       BD A37037 01872021
         ENTRY IEAQJSTM .                                     BD A38869 01876021
         EJECT                                                          01880020
*ROUTINE NAME-           IGC001, WAIT SVC ROUTINE                       01890020
*                                                                       01900020
*FUNCTIONS-            1.CAUSES THE ISSUING RB CONTROL LEVEL TO         01910020
*                        STOP PROCESSING AND WAIT ON THE OCCURANCE      01920020
*                        OF ONE OR MORE EVENTS.                         01930020
*                        2.CAUSES THE JOB STEP TQE TO BE DEQUEUED  MTS0 01940020
*                          AND CONVERTED FROM TASK (CPU) TIME TO   MTS0 01950020
*                          REAL (30 MIN VALUE) TIME IF ALL TCBS IN MTS0 01960020
*                          THE JOB STEP ARE IN AN SVC WAIT AND ARE MTS0 01970020
*                        PROBLEM PROGRAM TCBS.                     MTS0 01980020
*                                                                       01990020
*ENTRY POINT NAMES-      IGC001, WAIT SVC ENTRY POINT                   02000020
*                                                                       02010020
*CONTAINED IN MODULE-    IEAQSY00- WAIT/POST SYNCHRONIZATION MODULE     02020020
*                                                                       02030020
*ATTRIBUTES-             RESIDENT,RE-ENTRANT,SUPERVISOR STATE,          02040020
*                        TYPE 1 SVC.                                    02050020
*                                                                       02060020
*APPLICABILITY-          OPTION 4 ONLY                                  02070020
*                                                                       02080020
*EXTERNAL REFERENCES-    IEATCBP-ADDRESS OF BOTH THE NEXT TCB           02090020
*                                TO BE DISPATCHED,LOCATION 'NEW'        02100020
*                                AND THE CURRENT TCB ADDRESS            02110020
*                                LOCATION 'OLD'.                        02120020
*                                                                       02130020
*                        IEABTERM- ADDRESS OF ABTERM ROUTINE            02140020
*                                                                       02150020
*                        IEA0XE00- ADDRESS OF TYPE 1 SVC EXIT           02160020
*                              HANDLER.                                 02170020
*                                                                       02180020
*                        IEA0VL01- VALIDITY CHECK ROUTINE               02190020
*                        IEAQTD01 - BRANCH ENTRY POINT OF TQE      MTS0 02200020
*                                   DEQUEUE ROUTINE                MTS0 02210020
*                                                                  MTS0 02220020
*                                                                       02230020
*SVC'S USED-             NONE                                           02240020
*                                                                       02250020
*INPUT-                  REGISTER 0 CONTAINS A COUNT OF THE NUMBER      02260020
*                        OF EVENTS THAT MUST OCCUR BEFORE THE           02270020
*                        ISSUING TASK CAN CONTINUE IN CONTROL           02280020
*                                                                       02290020
*                        REGISTER 1 CONTAINS THE ADDRESS OF A           02300020
*                        SINGLE ECB(EVENT CONTROL BLOCK) OR             02310020
*                        THE ADDRESS OF A LIST OF ECB'S TO BE           02320020
*                        WAITED UPON.  A COMPLEMENTED REGISTER, IF SET  02330020
*                        SIGNALS THE PRESENCE OF A LIST.                02340020
*                                                                       02350020
*                                                                       02360020
*MACRO EXPANSION EXAMPLES                                               02370020
*                                                                       02380020
WAIT     DSECT                                                          02390020
         USING *,1                                                      02400020
         SPACE 2                                                        02410020
*  EXAMPLE 1........SPECIFIES THAT ONE EVENT REPRESENTED BY A SINGLE    02420020
*                   ECB AT LOCATION ECBFOUR WILL BE WAITED UPON.        02430020
         SPACE 2                                                        02440020
         WAIT  1,ECB=ECBFOUR                                            02450020
         SPACE 2                                                        02460020
*  EXAMPLE 2........SPECIFIES A WAIT FOR 5 EVENTS REPRESENTED BY ANY    02470020
*                   OF THE EVENT CONTROL BLOCKS POINTED TO BY THE       02480020
*                   LIST OF ADDRESSES LOCATED AT THE ADDRESS CONTAINED  02490020
*                   IN REGISTER 5.                                      02500020
         SPACE 2                                                        02510020
         WAIT  5,ECBLIST=(5)                                            02520020
         SPACE 2                                                        02530020
*  EXAMPLE 3........SPECIFIES A WAIT FOR 2 EVENTS REPRESENTED BY ANY    02540020
*                   OF THE EVENT CONTROL BLOCKS POINTED TO BY THE       02550020
*                   LIST OF ADDRESSES LOCATED AT LOCATION MANYECBS.     02560020
         SPACE 2                                                        02570020
         WAIT  2,ECBLIST=MANYECBS                                       02580020
         SPACE 2                                                        02590020
MANYECBS DC    A(ECBTWO)                                                02600020
         DC    A(ECBFOUR)                                               02610020
ECBTWO   DC    F'0'                                                     02620020
ECBFOUR  DC    F'0'                                                     02630020
*              THE ABOVE MACRO EXPANSIONS ARE NOT TO BE MISCONSTRUED    02640020
* AS BEING AN EXECUTABLE PORTION OF THIS WAIT SVC SERVICE ROUTINE.      02650020
* THESE MACRO EXPANSIONS SERVE ONLY TO ILLUSTRATE WHAT SOME OF          02660020
* THE VARIOUS FORMS OF THE EXPANSION LOOK LIKE.                         02670020
*                                                                       02680020
*OUTPUT-                 NONE                                           02690020
*                                                                       02700020
*ENTRY POINTS-         1.IGC001,GIVEN CONTROL VIA THE SVC               02710020
*                        FIRST LEVEL INTERRUPT HANDLER(FLIH).           02720020
*                                                                       02730020
*                      2.THE PSW MUST BE.                               02740020
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           02750020
*                        EXCEPT FOR MACHINE CHECK, IN SUPERVISOR        02760020
*                        MODE AND HAVE SUPERVISOR PROTECT KEY.          02770020
*                                                                       02780020
*                      3.THE REGISTERS CONTAIN.                         02790020
*                                                                       02800020
*                        REGISTER 0 CONTAINS THE INPUT NUMBER           02810020
*                                   OF EVENTS TO BE WAITED              02820020
*                                   UPON BEFORE THE ISSUING             02830020
*                                   TASK CAN CONTINUE.                  02840020
*                                                                       02850020
*                        REGISTER 1 CONTAINS THE INPUT ADDRESS          02860020
*                                   OF EITHER A SINGLE ECB OR           02870020
*                                   LIST OF ECBS TO BE WAITED           02880020
*                                   UPON. THE LIST IS DENOTED           02890020
*                                   BY A COMPLEMENTED ADDRESS.          02900020
*                                                                       02910020
*                        REGISTER 3 CONTAINS THE ADDRESS OF             02920020
*                                   THE CVT TABLE.                      02930020
*                                                                       02940020
*                        REGISTER 4 CONTAINS THE ADDRESS OF             02950020
*                                   THE CURRENT TCB.                    02960020
*                                                                       02970020
*                        REGISTER 5 CONTAINS THE ADDRESS OF             02980020
*                                   THE RB AT THE TOP OF THE            02990020
*                                   RB QUEUE.                           03000020
*                                                                       03010020
*                        REGISTER 14 CONTAINS THE RETURN                03020020
*                        ADDRESS OF THE CALLER.IN THE                   03030020
*                        CASE OF THE SVC FLIH BEING THE                 03040020
*                        CALLER REGISTER 14 CONTAINS                    03050020
*                        THE ADDRESS OF THE TYPE 1 SVC                  03060020
*                        EXIT ROUTINE.(IEA0XE00)                        03070020
*                                                                       03080020
*EXIT POINT-           1.TO THE CALLING ROUTINE VIA                     03090020
*                        BRANCH REG 14.                                 03100020
*                                                                       03110020
*                      2.THE PSW IS.                                    03120020
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           03130020
*                        EXCEPT FOR MACHINE CHECK,IN SUPERVISOR         03140020
*                        MODE AND HAVE SUPERVISOR PROTECT KEY.          03150020
*                                                                       03160020
*                      3.REGISTERS. 0,1,3-6,11,AND 14 ARE UNALTERED,    03170020
*                        ALL THE REMAINING CONTAIN MEANINGLESS          03180020
*                        INFORMATION.                                   03190020
*                                                                       03200020
*                                                                       03210020
*ERROR EXIT POINTS-    1.TO ABTERM-10 IN ORDER TO CAUSE THE ISSUING     03220020
*                        TASK TO BE TERMINATED.                         03230020
*                                                                       03240020
*                      2.THE PSW IS.                                    03250020
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           03260020
*                        EXCEPT FOR MACHINE CHECK,IN SUPERVISOR         03270020
*                        MODE AND HAVE SUPERVISOR PROTECT KEY 0.        03280020
*                                                                       03290020
*                      3.REGISTERS 0,3-6    AND 14 WILL                 03300020
*                        CONTAIN THE INFORMATION IN THEM                03310020
*                        AT THE TIME THE SVC 01 WAS GIVEN               03320020
*                        CONTROL.                                       03330020
*                                                                       03340020
*                        REGISTER 1 WILL CONTAIN THE ERROR CODE.        03350020
*                                                                       03360020
*                        REGISTERS 2,7-12 AND 15 WILL CONTAIN           03370020
*                        MEANINGLESS INFORMATION.                       03380020
*                                                                       03390020
*                        REGISTER 13 CONTAINS THE ADDRESS OF THE        03400020
*                        ABTERM ROUTINE.                                03410020
*                                                                       03420020
*                      4.THE ERROR CODES ARE.                           03430020
*                        X'0101' ERROR CODE #1 NUMBER OF ECBS TO        03440020
*                                              BE WAITED UPON EX-       03450020
*                                              CEEDS THE NUMBER OF      03460020
*                                              ECBS GIVEN.              03470020
*                        X'0201' ERROR CODE #2 THE ECB ADDRESS IS       03480020
*                                              INVALID.                 03490020
*                        X'0301' ERROR CODE #3 AN ATTEMPT IS BEING      03500020
*                                              MADE TO SET THE WAIT     03510020
*                                              FLAG IN AN ECB WHICH     03520020
*                                              IS ALREADY SET.          03530020
*                                                                       03540020
*TABLES AND CONTROL    1.RB-REQUEST BLOCK                               03550020
*BLOCKS REFERENCED-      THE CONTROLING BLOCK UNDER WHICH THE           03560020
*                        ISSUING ROUTINE IS OPERATING.                  03570020
*                                                                       03580020
*                        RBWCF- RB'S WAIT COUNT FIELD. SET IN ORDER     03590020
*                               PLACE ISSUING TASK IN A WAIT            03600020
*                               STATE UNTIL THE SPECIFIED NUMBER        03610020
*                               OF EVENTS OCCUR.                        03620020
*                                                                       03630020
*                        RBECBWT- NUMBER OF ECBS WAITING.SET BY         03640020
*                                 WAIT TO INDICATE THAT THE NUMBER      03650020
*                            OF EVENTS SPECIFIED IS LESS THAN           03660020
*                            THE NUMBER OF ECBS SPECIFIED.              03670020
*                                                                       03680020
*                         RBOPSW- RESUME PSW.  TESTED BY WAIT FOR  MTS0 03690020
*                            AN SVC 1 IN TASK'S TREE               MTS0 03700020
*                                                                  MTS0 03710020
*                      2.CVT- COMMUNICATIONS VECTOR TABLE               03720020
*                                 USED BY WAIT TO LOCATE LOCATION       03730020
*                                 'NEW'AND VALIDITY CHECK ADDRESS.      03740020
*                                                                       03750020
*                                  ALSO ENQUEUE ROUTINE IN TIMER   MTS0 03760020
*                                  SLIH                            MTS0 03770020
*                                                                  MTS0 03780020
*                      3.ECB - EVENT CONTROL BLOCK                      03790020
*                                                                       03800020
*                        WAIT FLAG -A BIT INDICATOR THAT SIGNALS        03810020
*                                   THAT THE LAST VALID REFERENCE       03820020
*                                   TO THE ECB WAS BY WAIT.             03830020
*                                                                       03840020
*                        COMPLETE FLAG- A BIT INDICATOR THAT SIGNALS    03850020
*                        THAT THE EVENT ASSOCIATED WITH THE ECB         03860020
*                        HAS COMPLETED.                                 03870020
*                                                                       03880020
*                        RB ADDRESS- THE RB ADDRESS OF THE ROUTINE      03890020
*                                    ISSUING THE WAIT IS PLACED         03900020
*                                    IN TO THIS FIELD BY WAIT.          03910020
*                                                                       03920020
*                      4. OPSW- LOCATION 32 DEC. -  ALTERED TO          03930020
*                        ENABLE REQUESTOR.                              03940020
*                         ALSO LOCATION 35 DEC. - TESTED FOR AN    MTS0 03950020
*                         SVC 1                                    MTS0 03960020
*                                                                       03970020
*LIST ORIGINS,TABLES                                                    03980020
*AND CONTROL BLOCKS                                                     03990020
*INCLUDED-               NONE                                           04000020
*                                                                       04010020
*RESTRICTIONS ON                                                        04020020
*USE OF ROUTINE-       1.A PERMANENT INTERLOCK WILL OCCUR UNDER         04030020
*                        THE FOLLOWING CONDITIONS.                      04040020
*                        TASK(A) ISSUES A WAIT MACRO INSTRUCTION        04050020
*                        FOR THE COMPLETION OF ANOTHER TASK(B).         04060020
*                        ONCE IN CONTROL (B) ISSUES A WAIT MACRO        04070020
*                        INSTRUCTION FOR THE COMPLETION OF AN           04080020
*                        EVENT ONLY (A) CAN FURNISH.                    04090020
*                                                                       04100020
*NOTES                   NONE                                           04110020
*                                                                       04120020
         EJECT                                                          04130020
* WAIT ROUTINE. (SVC 1)                                                 04140020
*  ENTER WITH WAIT COUNT IN REGISTER 0                                  04150020
*  ENTER WITH ECB ADDRESS OR ECB LIST ADDRESS IN REGISTER 1             04160020
*                                                                       04170020
* FUNCTION.                                                             04180020
*     THE WAIT SVC ROUTINE WILL PLACE THE RB (REQUEST BLOCK)            04190020
*  OF THE REQUESTING ROUTINE INTO A WAIT STATE.  THIS IS                04200020
*  ACCOMPLISHED BY SETTING THE WAIT COUNT FIELD IN THE RB.              04210020
*  AN RB WAIT STATE WILL PREVAIL UNTIL THE WAIT COUNT IS REDUCED        04220020
*  TO ZERO BY THE SVC POST ROUTINE.  THE WAIT FLAG AND REQUESTING       04230020
*  RB ADDRESS ARE SET IN EACH ECB.  FOR EVERY ECB WHOSE POST            04240020
*  FLAG IS ALREADY SET, THE WAIT COUNT IN REGISTER 0 IS                 04250020
*  DECREMENTED.  IF THIS COUNT GOES TO ZERO,(INDICATING THAT            04260020
*  POSTING HAS ALREADY COMPLETED) WAIT RESETS ALL PROCESSED ECBS        04270020
*  AND RETURNS.  THE WAIT COUNT IS ALWAYS STORED IN THE REQUESTORS      04280020
*  RB.                                                                  04290020
         SPACE 2                                                        04300020
IGC001   CSECT                                                          04310020
*0722085836                                                        MP65 04320020
*168400,168600,179000                                             19472 04330020
*082400,175800                                                    20002 04340020
*108800                                                          A33247 04345020
*095600,098400,100000,106700,107300,118500,119000,124700,129300,  M0113 04346020
*130400                                                           M0113 04347020
*114460-114480                                                   A51848 04349021
         CNOP  0,8                                                      04350020
         BALR  XRBASE,0                                                 04360020
         USING *,XRBASE                                                 04370020
         OI    32(0),X'FF'             ENABLE OPSW                      04380020
         LPR   XRWAITCT,XRWAITCT       INSURE THAT WAIT COUNT IS        04390020
*                                      POSITIVE IF WAIT REQUEST IS      04400020
*                                      WAITR TYPE                       04410020
         LTR   XRWTCT,XRWAITCT         Q.REQUESTOR WAIT COUNT ZERO      04420020
         BCR   8,XRRETURN              *YES GO TO TYPE 1 SVC HANDLER    04430020
         SPACE 1                                                        04440020
*  REGISTER 1 IS TESTED IF IT IS NEGATIVE. IF NEGATIVE, THE COMPLIMENT  04450020
* OF THE REGISTER IS THE ADDRESS OF A LIST OF POINTERS TO THE ECBS. A   04460020
* POSITIVE REGISTER IS THE ADDRESS OF AN ECB. THE LAST ECB POINTER IN   04470020
* THE LIST IS FLAGGED WITH THE SIGN BIT ON.                             04480020
         SPACE 2                                                        04490020
         LA    XRECBCTR,1             $INITIALIZE ECB COUNTER TO 1      04500020
         LR    XRSAVE,XRECB            DUP. INPUT ECB PARAMETER         04510020
         LTR   XRECBPTR,XRECB          Q.ADR OF ECB LIST                04520020
         BM    LIST                     YES,TAKE BRANCH                 04530020
         TM    0(XRECBPTR),ECBPTFLG     Q.IS ECB'S POST FLAG SET        04540020
         BCR   1,XRRETURN               YES,TAKE BRANCH                 04550020
         LR    XRWECB,XRECBPTR          DUP. ECB ADDRESS                04560020
         B     WTTEST                   UNCONDITIONALLY BRANCH          04570020
         SPACE 2                                                        04580020
*     HAVING DETERMINED THAT A LIST HAS BEEN INPUT THE LIST             04590020
*  ADDRESS MUST BE VALIDATED IF THE REQUESTOR IS NOT A SUPERVISORY      04600020
*  TASK.                                                                04610020
         SPACE 2                                                        04620020
LIST     LCR   XRECBPTR,XRECB           COMPLEMENT ECB ADDRESS          04630020
         TM    33(0),SUPTST            Q. IS ENTRY VIA SUP. TASK        04640020
         BZ    LOOP                    YES, TAKE BRANCH                 04650020
         LCR   XRECB,XRECB             COMPLEMENT ECB ADDRESS(LIST)     04660020
         LA    XRABTERM,ERRWAIT2       LOAD INVALID ECB CODE            04670020
         L     XRTSTADR,CHECK          LOAD VALID. CHECK R. ADDR.       04680020
         BAL   XRLINK,4(XRTSTADR)      Q. IS ECB LIST VALID             04690020
         BNE   ERROR                   NO, TAKE BRANCH                  04700020
         LR    XRECB,XRSAVE            RESTORE REG1.                    04710020
LOOP     TM    0(XRECBPTR),LSTIND      Q.IS THIS LAST ECB IN LIST       04720020
         BO    ECBWT                    YES BRANCH                      04730020
         LR    XRLINK,XRECBCTR                                   A68615 04740021
         LA    XRECBCTR,1(XRLINK)      UPDATE COUNTER            A68615 04740221
         LA    XRECBPTR,4(XRECBPTR)     UPDATE ECB LIST ADR             04750020
         B     LOOP                                                     04760020
         SPACE 1                                                        04770020
*  THE INPUT WAIT COUNT (REGISTER 0) IS COMPARED AGAINST THE COUNT OF   04780020
* ECBS FOUND. IF THE WAIT COUNT IS HIGHER GO TO ABTERM. IF THE COUNTS   04790020
* ARE EQUAL, GO TO NEXT SECTION. IF THE ECB COUNT IS HIGHER SET THE ECB 04800020
* SEARCH FLAG IN THE REQUESTING ECB.                                    04810020
         SPACE 2                                                        04820020
ECBWT    LCR   XRECBPTR,XRECB          $LD TRUE ECB LIST ADR            04830020
         CR    XRECBCTR,XRWTCT          Q.ECB CT. LT WAIT CT.           04840020
         BE    PKEY                     EQUAL, TAKE BRANCH              04850020
         LA    XRABTERM,ERRWAIT1        WAIT CT. TOO GREAT              04860020
         BL    ERROR                 *** YES, TAKE BRANCH               04870020
         OI    RBSTAB+1(XRORB),RBECBWT  SET RB'S ECB SEARCH FLAG        04880020
         SPACE 1                                                        04890020
*  TEST IF ECB'S POST FLAG IS ON. YES, ON GO TO DECREMENT WAIT COUNT    04900020
* SECTION. NEXT TEST IF ECB'S WAIT FLAG ON. YES, ON GO TO ABTERM. IF    04910020
* NEITHER FLAG ON STORE REQUESTING RB'S ADDRESS IN ECB AND SET ECB'S    04920020
* WAIT FLAG AFTER VALIDITY CHECKING THE ECB ADDRESS.  OTHERWISE ABTERM  04930020
         SPACE 2                                                        04940020
PKEY     L     XRWECB,0(XRECBPTR)       LD ECB ADR.(LIST)               04950020
         LR    XRTESTWD,XRWECB          LOAD CURRENT ECB                04960020
         TM    0(XRWECB),ECBPTFLG        Q.ECB'S POST FLAG SET          04970020
         BO    CFLAGON                  YES,TAKE BRANCH                 04980020
WTTEST   LA    XRABTERM,ERRWAIT3        ATTEMPTING TO PLACE A WAITING   04990020
*                                      RB INTO WAIT.                    05000020
         TM    33(0),SUPTST            IS ENTRY VIA SUP TASK     A67736 05010021
         BZ    COMPFLAG                YES                       A67736 05020021
         TM    0(XRWECB),ECBWTFLG      IS ECB WAIT FLAG SET      A67736 05030021
         BO    ERROR                   BRANCH TO ABTERM          A67736 05040021
         LA    XRABTERM,ERRWAIT2       LOAD INVALID ECB CODE            05050020
         L     XRTSTADR,CHECK           LOAD VALIDITY CHECK ADR.        05060020
         BAL   XRLINK,4(XRTSTADR)       Q. IS ECB VALID                 05070020
         BE    COMPFLAG                 BR IF ECB IS VALID        20002 05080020
         LR    CHECKREG,XRWECB          SET UP ECB CHECK REG      20002 05090020
         BAL   XRLINK,COMMCHEK          CHECK FOR COMM. ECB       20002 05100020
COMPFLAG ST    XRORB,0(XRWECB)          ST.REQUESTING RB'S ADR. IN ECB  05110020
         MVI   0(XRWECB),ECBWTFLG       SET ECB WAIT FLAG               05120020
         SPACE 1                                                        05130020
*  GET NEXT ECB POINTER. DECREMENT ECB COUNTER. ECB COUNTER NOT ZERO    05140020
* GO AND PROCESS NEXT ECB. ECB COUNTER ZERO STORE CALCULATED WAIT COUNT 05150020
* IN REQUESTING RB AND SET 'NEW' TO ZERO. THEN RETURN TO TYPE 1 SVC     05160020
* HANDLER.                                                              05170020
         SPACE 2                                                        05180020
UPDATE   LR    XRLINK,XRECBPTR                                   A68615 05190021
         LA    XRECBPTR,4(XRLINK)                                A68615 05190221
         BCT   XRECBCTR,PKEY           Q.DECREMENT ECB CTR (NOT 0 BR)   05200020
         LR    XRECB,XRSAVE             RESTORE ECB ADR.                05210020
         L     XRNEW,NEWPTR(XRCVT)      LD ADR OF 'NEW'                 05220020
         C     XROTCB,0(XRNEW)        Q.IS CURRENT TCB EQ TO NEW        05230020
         BC    7,NOZERO                DONT ZERO NEW A TASK SWTCH IND   05240020
         ST    XRZERO,0(XRNEW)          ST 0 IN 'NEW'                   05250020
NOZERO   STC   XRWTCT,RBWCF(XRORB)     ST WAIT COUNT IN REQUESTING RB   05260020
         OI    RBSTAB(XRORB),RBWAITP . MARK RB WAITING ON ECB CI A45983 05263021
         SPACE 2                                                        05266021
* GET INITIATOR TQE.  IF NO TQE GO TO RETURN TO CALLER.  PERFORM   MTS0 05270020
* TASK SELECT TO EXAMINE EVERY TOP RB FOR AN SVC WAIT (0A01) AND   MTS0 05280020
* PROBLEM PROGRAM MODE. IF RB DOES NOT MEET CONDITIONS, RETURN TO  MTS0 05290020
* CALLER.  WHEN ALL TCBS CHECKED, DEQUEUE TQE, CHANGE TQE TYPE AND MTS0 05300020
* TIME VALUE, ENQUEUE THE TQE AND RETURN TO CALLER                 MTS0 05310020
JSTIME   EQU   *                                                   MTS0 05320020
*   THE FOLLOWING CODE IS USED BY WAIT AND EXIT               BD A38869 05321021
*   TO DETERMINE IF THE JOB STEP IS IN A WAIT                 BD A38869 05322021
*   CONDITION. IF SO THE JS TQE IS ENQUEUED AS A WAIT/REAL TQE.  A38869 05323021
IEAQJSTM EQU   * .                                            BD A38869 05324021
         SR    XRZERO,XRZERO .    ZERO REG 7                  BD A38869 05325021
         BALR  XRBASE,0 .         SET BASE ADDR               BD A38869 05326021
         USING *,XRBASE .                                     BD A38869 05327021
         L     XRBASE,BASEWT .    RELOAD WAIT BASE            BD A38869 05328021
         USING IGC001+2,XRBASE .                              BD A38869 05329021
         L     ATCBREG,TCBJSTCB(TCBREG) PICK UP JOB STEP TCB       MTS0 05330020
         L     XRWTCT,TCBOTC(ATCBREG)  PICK UP INITIATOR TCB       MTS0 05340020
         LTR   XRWTCT,XRWTCT           IS ORIGIN TCB = 0           MTS0 05350020
         BCR   8,XRRETURN              YES, GO TO TYPE 1 SVC HANDL MTS0 05360020
         TM    TCBTSFLG(TCBREG),TSTASK .   Q. TS TASK             M2197 05370020
         BCR   1,XRRETURN .            YES, GO TO TYPE 1 SVC HNDL 20021 05380020
         TM    TCBPKF(XRWTCT),X'F0'    IS IT NON ZERO KEY          MTS0 05390020
         BCR   8,XRRETURN              NO, GO TO TYPE1 SVC HANDLER MTSO 05400020
         L     LINKREG,TCBTME(ATCBREG) .GET J/S TQE                 SMF 05410020
         LTR   LINKREG,LINKREG         .Q.IS THERE A J/S TQE        SMF 05420020
         BZ    NOJSTQE                 .BR IF NO                    SMF 05430020
         TM    TQEFLGS(LINKREG),X'03'  .Q. REAL TQE                 SMF 05440020
         BNO   NOJSTQE                 .BR IF NO                    SMF 05450020
         TM    TQEFLGS(LINKREG),X'80'  .Q. TQE ON QUEUE             SMF 05460020
         BCR   0,XRRETURN                                        A69700 05470021
NOJSTQE  C     XRZERO,TCBTME(XRWTCT)   DOES INITIATOR HAVE A TQE   MTSO 05480020
         BCR   8,XRRETURN              NO, GO TO TYPE 1 SVC HANDL  MTS0 05490020
         LR    XRSAV6,ATCBREG           SAVE JSTCB FOR END TEST    MP65 05500020
         B     EXAMINE                  START SCAN WITH JSTCB      MP65 05510020
CONTSRCH EQU   *                                                   MTS0 05520020
         BAL   LINKREG,SELECT          GO TO TASK SELECT RTN       MTS0 05530020
* THE DEQUEUE ROUTINE EXPECTS -                                    MTS0 05540020
*        REG 1 = TQE                                               MTS0 05550020
*        REG 2 = RETURN ADDRESS                                    MTS0 05560020
*        REG 15 = BASE ADDRESS OF DEQUEUE ROUTINE                  MTS0 05570020
* REGISTERS 0, 2, 9 - 12 ARE TRANSPARENT OVER DEQUEUE ROUTINE      MTS0 05580020
         LR    XRWECB,XRECB            SAVE REGISTER 1             MTS0 05590020
         L     XRECB,TCBTME(XRWTCT)    GET ADDRESS OF TQE          MTS0 05600020
         LR    XRECBPTR,XROTCB         SAVE REG 4                  MTS0 05610020
         LR    XRSAVE,XRRETURN         SAVE REG 14                 MTS0 05620020
         LR    XRLINK,XRSAV6           SAVE REG 6                  MTS0 05630020
         L     XRBASE,BASEDEQ          GET ADDRESS DEQUEUE RTN     MTS0 05640020
         BALR  XRTSTADR,XRBASE         GO TO DEQUEUE TQE           MTS0 05650020
         USING *,XRTSTADR              REESTABLISH ADDRESSABILITY  MTS0 05660020
         L     XRBASE,BASEWT                                       MTS0 05670020
         LR    XRRETURN,XRSAVE                                     MTS0 05680020
         USING IGC001+2,XRBASE                                     MTS0 05690020
         DROP  XRTSTADR                                            MTS0 05700020
         L     XRCVT,16                ADDRESS CVT                 MTS0 05710020
         L     XRABTERM,CVTQTE00(XRCVT)                            MTS0 05720020
         LR    XRCVT,XRECBPTR          SAVE TCB                    MTS0 05730020
         L     ATCBREG,TCBJSTCB(XRCVT) GET J/S TCB                 MTS0 05740020
         L     XRWTCT,TCBOTC(ATCBREG)  INITIATOR TCB               MTS0 05750020
         L     XRECB,TCBTME(XRWTCT)    TQE                         MTS0 05760020
         MVC   TQESAV(4,XRECB),TQEVAL(XRECB) SAVE CPU VALUE        MTS0 05770020
         L     TCTPTR,TCBTCT(XRWTCT)   .TCB'S TCT ADDR              SMF 05780020
         LTR   TCTPTR,TCTPTR           .Q. IS THERE A TCT           SMF 05790020
         BZ    NOSMF                   .BR IF NO SMF                SMF 05800020
         MVC   TQEVAL(4,XRECB),TCTWLMT(TCTPTR) .INSERT WAIT VALUE   SMF 05810020
         B     TQEREAL                 .MAKE TQE REAL VALUE         SMF 05820020
NOSMF    MVC   TQEVAL(4,XRECB),W30MIN  .INSERT 30 MINUTE VALUE     MTSO 05830020
TQEREAL  OI    TQEFLGS(XRECB),X'03'    .MAKE TQE REAL VALUE        MTSO 05840020
* THE ENQUEUE ROUTINE EXPECTS -                                    MTS0 05850020
*        REG 1 = TQE                                               MTS0 05860020
*        REG 2 = RETURN ADDRESS                                    MTS0 05870020
* REGISTERS 4, 5, 6, AND  13 ARE NOT TRANSPARENT OVER              MTS0 05880020
* THE ENQUEUE ROUTINE                                              MTS0 05890020
         LR    XRZERO,XRLINK           REG 6                       MTS0 05900020
         BALR  XRTSTADR,XRABTERM                                   MTS0 05910020
         LR    XROTCB,XRCVT                                        MTS0 05920020
         L     XRORB,TCBRBP(XROTCB)    RESTORE RB ADDRESS          MTS0 05930020
         LR    XRSAV6,XRZERO                                       MTS0 05940020
         LR    XRECB,XRWECB                                        MTS0 05950020
         BR    XRRETURN                GO TO TYPE 1 SVC HANDLER    MTS0 05960020
SELECT   L     SELREG,TCBLTC(ATCBREG)  GET DAUGHTER                MTS0 05970020
SELECT1  LTR   SELREG,SELREG           DOES DAUGHTER EXIST         MTS0 05980020
         BC    7,SELECT2               YES, TCB FOUND              MTS0 05990020
         L     SELREG,TCBNTC(ATCBREG)  NO, GET SISTER              MTS0 06000020
         CR    ATCBREG,XRSAV6           IS SCAN COMPLETE           MP65 06010020
         BCR   8,LINKREG               YES, LAST TIME RETURN       MTS0 06020020
         L     ATCBREG,TCBOTC(ATCBREG) NO, GET MOTHER              MTS0 06030020
         B     SELECT1                 CONTINUE SCAN               MTS0 06040020
SELECT2  LR    ATCBREG,SELREG          MODIFY TCB REGISTER         MTS0 06050020
EXAMINE  EQU   *                                                   MTS0 06060020
         CR    ATCBREG,TCBREG          IS THIS THE ISSUER OF WAIT  MTS0 06070020
         BE    CONTSRCH .         YES                         BD A38869 06080021
         TM    TCBFLG+4(ATCBREG),X'80' HAS THIS TASK ENDED         MTS0 06090020
         BO    CONTSRCH                YES, FIND NEXT TCB          MTS0 06100020
         TM    TCBFLG+0(ATCBREG),X'80' Q.TASK ABENDING           A21968 06110020
         BCR   1,XRRETURN                                        A69869 06120021
         TM    TCBFLG+2(ATCBREG),X'20' Q.TASK IN ABTERM          A21968 06130020
         BCR   1,XRRETURN                                        A69869 06140021
         L     SELREG,TCBRBP(ATCBREG)  PICK UP TOP RB ON CHAIN     MTS0 06150020
         CLI   RBWCF(SELREG),X'00'     IS THE WAIT COUNT ZERO      MTS0 06160020
         BCR   8,XRRETURN              YES, GO TO TYPE 1 SVC HANDL MTS0 06170020
         L     SELREG,RHOPSW(SELREG)   PICK UP RIGHT-HALF OF PSW   MTS0 06180020
         S     SELREG,KTWO             GET LAST EXECUTED INSTR.    MTS0 06190020
         LTR   SELREG,SELREG           VALIDITY CHECK              MTS0 06200020
         BCR   12,XRRETURN                                         MTS0 06210020
         CLC   KTEST+6(2),0(SELREG)    WAS SVC WAIT ISSUED(0A01)   MTS0 06220020
         BE    CONTSRCH                YES, GO TO PICK UP NEXT TCB MTS0 06230020
NOJSTME  EQU   *                       ENTIRE TREE IS NOT IN SVC   MTS0 06240020
*                                      WAIT                        MTS0 06250020
         BR    XRRETURN                *GO TO TYPE 1 SVC HANDLER        06260020
         SPACE 1                                                        06310020
*  DECREMENT WAIT COUNTER. COUNTER NOT ZERO GO TO PROCESS NEXT ECB.     06320020
* COUNTER ZERO TEST IF REQUESTING RB HAS SEARCH ECB FLAG ON. NO, NOT    06330020
* ON RETURN TO TYPE 1 SVC HANDLER. YES ON, RESET SEARCH ECB FLAG IN RB  06340020
* AND TURN OFF ALL WAIT FLAGS IN ECBS.                                  06350020
         SPACE 2                                                        06360020
CFLAGON  BCT   XRWTCT,UPDATE           Q.DECREMENT WAIT COUNT NOT 0 BR  06370020
         TM    RBSTAB+1(XRORB),RBECBWT Q.IS RB'S ECB SEARCH FLAG SET    06380020
         BCR   8,XRRETURN              *NO GO TO TYPE 1 SVC HANDLER     06390020
         NI    RBSTAB+1(XRORB),RRBECBWT RESET RB ECB SEARCH FLAG        06400020
         LCR   XRECBPTR,XRSAVE          OBTAIN TRUE ECB LIST ADR        06410020
LOOP1    L     XRWECB,0(XRECBPTR)       OBTAIN ECB ADDRESS              06420020
         TM    33(0),SUPTST            IS ENTRY BY SUP TASK      A63871 06420221
         BZ    SKP                     YES                       A63871 06420421
         LA    XRABTERM,ERRWAIT2       INVALID ECB               A63871 06420621
         LR    XRECB,XRWECB            INIT ECB REG              A63871 06420821
         LA    XRECB,0(XRECB)          HI BYTE                   A63871 06421021
         L     XRTSTADR,CHECK          LOAD CHECK ROUTINE ADR    A63871 06421221
         BAL   XRLINK,4(XRTSTADR)      IS ECB VALID              A63871 06421421
         BE    NOERR                   YES                       A63871 06421621
         LR    CHECKREG,XRWECB         ECB ADDRESS               A63871 06421821
         BAL   XRLINK,COMMCHEK         COMM TASK ECB             A63871 06422021
NOERR    LR    XRECB,XRSAVE            RESTORE                   A63871 06422221
SKP      EQU   *                                                 A63871 06422421
         NI    0(XRWECB),RECBWTF        RESET ECB'S WAIT FLAG           06430020
         TM    0(XRECBPTR),LSTIND      Q.IS THIS LAST ENTRY             06440020
         BCR   1,XRRETURN              **YES GO TO TYPE 1 SVC HANDLER   06450020
         LA    XRECBPTR,4(XRECBPTR)    UPDATE LIST POINTER              06460020
         B     LOOP1                   BRANCH UNCONDITIONALLY           06470020
         EJECT                                                          06480020
*ROUTINE NAME-           IGC002,POST SVC SERVICE ROUTINE                06490020
*                                                                       06500020
*FUNCTIONS-            1.POST WILL SIGNAL THE COMPLETION OF AN EVENT    06510020
*                          SPECIFIED BY AN EVENT CONTROL BLOCK(ECB)     06520020
*                          BY SETTING IT APPROPRIATELY.                 06530020
*                                                                       06540020
*                      2.POST WILL DETERMINE IF THE TASK IN A WAIT      06550020
*                          STATE SHOULD BE MADE READY AND IN SOME       06560020
*                          CASES INDICATE THAT CONTROL SHOULD BE        06570020
*                          GIVEN TO THIS READIED TASK.                  06580020
*                                                                       06590020
*                       3.POST WILL DETERMINE IF THE JOB STEP TQE  MTS0 06600020
*                           SHOULD BE DEQUEUED AND CONVERTED FROM  MTS0 06610020
*                           A REAL TQE TO A TASK TQE (FOR J/S      MTS0 06620020
*                           TIMING ONLY).                          MTS0 06630020
*                                                                  MTS0 06640020
*ENTRY POINT NAMES-    1.IGC002,ENTRY POINT VIA SVC 02                  06650020
*                                                                       06660020
*                      2.IGC002+6, BRANCH ENTRY TO POST                 06670020
*                                                                       06680020
*                      3. IEA0PT01, IOS AND NON-RESIDENT ROUTINES       06690020
*                        BRANCH ENTRY TO POST.                          06700020
*                                                                       06710020
*                      4. IEA0PT02, IOS AND RESIDENT ROUTINES           06720020
*                        BRANCH ENTRY TO POST.                          06730020
*                                                                       06740020
*CONTAINED IN MODULE-    IEAQSY00- WAIT/POST SYNCHRONIZATION MODULE     06750020
*                                                                       06760020
*ATTRIBUTES-             RESIDENT,RE-ENTRANT,SUPERVISOR STATE,          06770020
*                        TYPE 1 SVC ROUTINE.                            06780020
*                                                                       06790020
*APPLICABILITY-          OPTION 4 ONLY                                  06800020
*                                                                       06810020
*EXTERNAL REFERENCES-    IEATCBP- LOCATION 'NEW' AND 'OLD'              06820020
*                        IEABTERM- ABTERM                               06830020
*                        IEA0XE00 - TYPE 1 SVC EXIT ROUTINE             06840020
*                         IEAQTD01- DEQUEUE ROUTINE IN TIMER SLIH  MTS0 06850020
*                         IEA0DS02 - TASK SWITCH ROUTINE           MTS0 06860020
*                                                                       06870020
*SVC'S USED-             NONE                                           06880020
*                                                                       06890020
*INPUT-                  POST CODE IN REGISTER 0                        06900020
*                        THE LOW ORDER BYTE CONTAINS 0.                 06910020
*                        ADDRESS OF ECB IN REGISTER 1                   06920020
*                        OR IF HIGH ORDER BIT IS ON THEN IT       21B72 06921021
*                        CONTAINS THE ADDRESS OF A PARM LIST      21B72 06922021
*                        FOR INTER-PARTITION POST. FORMAT AS      21B72 06923021
*                        FOLLOWS: REG1 ************--->*******    21B72 06924021
*                                      *1  ' 8-31 *    *@ECB *    21B72 06925021
*                                      *BIT'@ PARM*    *@TJID*    21B72 06926021
*                                      *ON '  LIST*    *@TCB *    21B72 06927021
*                                      ************    *******    21B72 06928021
*                                                                       06930020
*MACRO EXPANSION EXAMPLES                                               06940020
*                                                                       06950020
POST     DSECT                                                          06960020
         USING *,1                                                      06970020
         SPACE 2                                                        06980020
*  EXAMPLE 1........SPECIFIES A SINGLE ECB AT LOCATION TEN TO BE        06990020
*                   POSTED. A ZERO POST CODE IS SET IN THE ECB.         07000020
         SPACE 2                                                        07010020
         POST  TEN                                                      07020020
         SPACE 2                                                        07030020
*  EXAMPLE 2........SPECIFIES A SINGLE ECB AT AN ADDRESS SPECIFIED      07040020
*                   IN REGISTER 6 TO BE POSTED . THE POST CODE          07050020
*                   SPECIFIED AT LOCATION ERROR+2 IS RETURNED IN        07060020
*                   THE POSTED ECB.                                     07070020
         SPACE 2                                                        07080020
         POST  ERROR+2,(6)                                              07090020
         SPACE 2                                                        07100020
*  EXAMPLE 3........SPECIFIES THE POSTING OF THE ECB WHOSE ADDRESS      07110020
*                   IS IN REGISTER 5, AND SETS THE POST CODE FIELD      07120020
*                   WITH THE VALUE SPECIFIED IN REGISTER 6.             07130020
         SPACE 2                                                        07140020
         POST  (6),(5)                                                  07150020
         SPACE 2                                                        07160020
TEN      DC    F'0'                                                     07170020
         SPACE 2                                                        07180020
*              THE ABOVE MACRO EXPANSIONS ARE NOT TO BE MISCONSTRUED    07190020
* AS BEING AN EXECUTABLE PORTION OF THIS POST SVC SERVICE ROUTINE.      07200020
* THESE MACRO EXPANSIONS SERVE ONLY TO ILLUSTRATE WHAT SOME OF          07210020
* THE VARIOUS FORMS OF THE EXPANSION LOOK LIKE.                         07220020
*                                                                       07230020
*OUTPUT-                 NONE                                           07240020
*                                                                       07250020
*ENTRY POINTS-        1A.IGC002,POST SVC ROUTINE ENTRY POINT            07260020
*                        GIVEN CONTROL BY THE SVC FIRST LEVEL           07270020
*                        INTERRUPT HANDLER(FLIH).                       07280020
*                                                                       07290020
*                      B.THE PSW MUST BE.                               07300020
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           07310020
*                        EXCEPT MACHINE CHECK,IN SUPERVISOR             07320020
*                        MODE AND HAVE SUPERVISOR PROTECT KEY.          07330020
*                                                                       07340020
*                      C.THE REGISTERS CONTAIN.                         07350020
*                        REGISTER 0 CONTAINS THE COMPLETION CODE        07360020
*                                                                       07370020
*                        REGISTER 1 CONTAINS THE ADDRESS OF THE         07380020
*                                   ECB OR,IF THE HIGH ORDER      21B72 07382021
*                                   BIT IS ON,THE ADDRESS OF      21B72 07384021
*                                   A THREE WORD PARM LIST FOR    21B72 07386021
*                                   INTER-PARTITION POST. PARM    21B72 07388021
*                                   LIST CONTAINS @ECB,@TJID,     21B72 07390021
*                                   @TCB.                         21B72 07392021
*                        REGISTERS  2,6-12 AND 15 CONTAIN THE           07400020
*                                   CONTENTS IN THEM AT THE TIME        07410020
*                                   SVC 02 WAS GIVEN.                   07420020
*                                                                       07430020
*                        REGISTER 3 CONTAINS THE ADDRESS OF THE         07440020
*                                  CVT TABLE.                           07450020
*                                                                       07460020
*                        REGISTER 4 CONTAINS THE ADDRESS OF THE         07470020
*                                   CURRENT TCB.                        07480020
*                                                                       07490020
*                        REGISTER 5 CONTAINS THE ADDRESS OF THE         07500020
*                                   RB AT THE TOP OF THE RB QUEUE.      07510020
*                                                                       07520020
*                        REGISTER 14 CONTAINS THE RETURN                07530020
*                        ADDRESS OF THE CALLER.IN THE                   07540020
*                        CASE OF THE SVC FLIH BEING THE                 07550020
*                        CALLER REGISTER 14 CONTAINS                    07560020
*                        THE ADDRESS OF THE TYPE 1 SVC                  07570020
*                        EXIT ROUTINE.(IEA0XE00)                        07580020
*                                                                       07590020
*                     2A.(IGC002+6) BRANCH ENTRY TO POST. SEE NOTES     07600020
*                                                                       07610020
*                       3A. (IEA0PT01) IOS AND NON-RESIDENT             07620020
*                        ROUTINES BRANCH ENTRY TO POST.  THE            07630020
*                        ADDRESS IS REFERENCED OUT OF THE CVT           07640020
*                        TABLE.                                         07650020
*                       THE USER MUST PROVIDE THE FOLLOWING.            07660020
*                        1. ADDRESS OF POST IN REGISTER 15              07670020
*                        2. RETURN ADDRESS IN REGISTER 14               07680020
*                        3. WAITING TCB ADDRESS IN REGISTER 12          07690020
*                        4. THE ECB ADDRESS IN REGISTER 11              07700020
*                        4A. AND IF HIGH ORDER BIT IS ON          21B72 07703021
*                            THIS SPECIFIES INTER-PARTITION POST  21B72 07706021
*                        5. THE COMPLETION CODE IN REGISTER 10          07710020
*                        6. THE REQUESTOR MUST BE DISABLED              07720020
*                                                                       07730020
*                        NO VALIDITITY CHECKING WILL BE DONE.           07740020
*                                                                       07750020
*                     B. (IEA0PT02) RESIDENT ROUTINES BRANCH            07760020
*                        ENTRY TO POST. PERFORMS THE SAME               07770020
*                        FUNCTION AS IEA0PT01 WITH THE ADDED            07780020
*                        FUNCTION OF RB VALIDATION.                     07790020
*                                                                       07800020
*EXIT POINT-           1.TO THE CALLING ROUTINE VIA                     07810020
*                        REGISTER  14.                                  07820020
*                                                                       07830020
*                      2.THE PSW IS.                                    07840020
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           07850020
*                        EXCEPT MACHINE CHECK,IN SUPERVISOR             07860020
*                        MODE,HAVE SUPERVISOR PROTECT KEY.              07870020
*                                                                       07880020
*                        (IGC002) SVC TO POST .                         07890020
*                                                                       07900020
*                        REGISTERS 2-14 ARE TRANSPARENT ACROSS POST     07910020
*                        REGISTERS 0,1 AND 15 ARE VOLATILE              07920020
*                                                                       07930020
*                        (IGC002+6) BRANCH ENTRY TO POST                07940020
*                                                                       07950020
*                        REGISTERS 0-9 AND 14 ARE TRANSPARENT           07960020
*                        REGISTERS 10-13 AND 15 ARE VOLATILE            07970020
*                                                                       07980020
*                        (IEA0PT01) NON-RESIDENT (IOS) BRANCH           07990020
*                        ENTRY TO POST                                  08000020
*                                                                       08010020
*                        REGISTERS 0-9 AND 14 ARE TRANSPARENT           08020020
*                        REGISTERS 10-13 AND 15 ARE VOLATILE            08030020
*                                                                       08040020
*                        (IEA0PT02) RESIDENT ROUTINE BRANCH ENTRY       08050020
*                        TO POST                                        08060020
*                        REGISTERS 0-9 AND 14 ARE TRANSPARENT           08070020
*                        REGISTERS 10-13 AND 15 ARE VOLATILE            08080020
*                                                                       08090020
*                                                                       08100020
*                                                                       08110020
*ERROR EXIT POINTS-    1. TO ABTERM INORDER TO CAUSE THE                08120020
*                        ISSUING TASK TO BE TERMINATED.                 08130020
*                                                                       08140020
*                      2. THE PSW IS.                                   08150020
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           08160020
*                        EXCEPT FOR MACHINE CHECK,IN SUPERVISOR         08170020
*                        MODE AND HAS A SUPERVISOR PROTECT KEY OF       08180020
*                        0.                                             08190020
*                                                                       08200020
*                                                                       08210020
*                      3. REGISTER 1 CONTAINS THE ERROR CODE            08220020
*                                                                       08230020
*                      4. REGISTER 13 IS USED TO BRANCH TO ABTERM       08240020
*                                                                       08250020
*                        5. ALL OTHER REGISTER  CONTENTS ARE NON-       08260020
*                          MEANINGFUL.                                  08270020
*                                                                       08280020
*                      6.THE ERROR CODES ARE.                           08290020
*                        X'0102' ERROR CODE #1 POST ECB ADDRESS         08300020
*                                              INVALID.                 08310020
*                        X'0202' ERROR CODE #2 POST ECB'S RB            08320020
*                                              ADDRESS INVALID.         08330020
*                                                                       08340020
*                      7.REGISTER 13 CONTAINS THE ADDRESS OF THE        08350020
*                                   ABTERM ROUTINE.                     08360020
*                                                                       08370020
*TABLES AND CONTROL    1. TCB-TASK CONTROL BLOCK                        08380020
*BLOCKS REFERENCED-      THE CONTROLLING BLOCK UNDER WHICH THE          08390020
*                        TASK IS OPERATING.                             08400020
*                                                                       08410020
*                        TCBRBP- POINTER TO THE RB FOR THE              08420020
*                                ROUTINE POSTING. USED BY POST.         08430020
*                                                                       08440020
*                        TCBTCB- POINTER TO NEXT TCB ON READY           08450020
*                                QUEUE. USED BY POST.                   08460020
*                                                                       08470020
*                        TCBDSP- DISPATCHING PRIORITY OF TASK.          08480020
*                                USED BY POST.                          08490020
*                                                                       08500020
*                         TCBJSTCB- POINTER TO THE JOB STEP TCB    MTS0 08510020
*                                                                  MTS0 08520020
*                         TCBOTC- POINTER TO MOTHER OF TCB         MTS0 08530020
*                                                                  MTS0 08540020
*                         TCBPKF- PROTECT KEY OF TASK              MTS0 08550020
*                                                                  MTS0 08560020
*                         TCBTME- POINTER TO TIMER QUEUE ELEMENT        08570020
*                                                                       08580020
*                      2.RB-REQUEST BLOCK                               08590020
*                         THE CONTROLING BLOCK UNDER WHICH THE          08600020
*                         POSTING ROUTINE IS OPERATING.                 08610020
*                        RBECBWT- BIT SETTING THAT INDICATES            08620020
*                                 THAT MORE ECB'S WERE SPECIFIED        08630020
*                                 THAN THE NUMBER TO BE WAITED          08640020
*                                 UPON. SET TO ZERO WHEN RB WAIT        08650020
*                                 COUNT IS ZERO.                        08660020
*                                                                       08670020
*                        RBWCF- NUMBER OF ECB'S TO BE WAITED UPON.      08680020
*                               DECREMENTED EACH TIME ANY ECB           08690020
*                               WHICH POINTS TO THIS RB IS POSTED.      08700020
*                                                                       08710020
*                      3.ECB-EVENT CONTROL BLOCK                        08720020
*                            BLOCK REPRESENTING AN EVENT.               08730020
*                                                                       08740020
*                        COMPLETION FLAG- SET BY POST TO INDICATE       08750020
*                                         THE EVENT ASSOCIATED          08760020
*                                         WITH THIS ECB HAS OCCURRED.   08770020
*                                                                       08780020
*                        RB ADDRESS FIELD- SET BY WAIT TO IDENTIFY      08790020
*                                          THE RB IN CONTROL WHEN       08800020
*                                          THE WAIT WAS GIVEN.USED      08810020
*                                          BY POST TO REFERENCE RB      08820020
*                                          TO ADJUST WAIT COUNT.        08830020
*                                                                       08840020
*                        COMPLETION CODE - A CODE NUMBER RANGING        08850020
*                                                      30               08860020
*                                           FROM 0 TO 2  -1.            08870020
*                                          POST PLACES THE COMPLETION   08880020
*                                          CODE SUPPLIED IN THE CALLING 08890020
*                                          SEQUENCE IN TO THIS FIELD.   08900020
*                                                                       08910020
*                      4.IEATCBP- DOUBLE WORD CONTAINS TCB POINTERS.    08920020
*                                 FIRST WORD 'NEW' USED AND SET BY      08930020
*                                 POST SHOULD POSTED TASKS PRIORITY     08940020
*                                 BE GREATER THAN THE TASK SPECIFIED    08950020
*                                 BY 'NEW'.                             08960020
*                                 SECOND WORD'OLD' USED BY POST         08970020
*                                 TO DETERMINE WHETHER OR NOT TO        08980020
*                                 ALTER 'NEW'. IF THE CURRENT           08990020
*                                 TASK SPECIFIED BY'OLD' IS OF A        09000020
*                                 LOWER PRIORITY THAN THE TASK          09010020
*                                 BEING POSTED, LOCATION 'NEW'          09020020
*                                 WILL BE SET TO THE POSTED TASK.       09030020
*                                                                       09040020
*                       5.TQE-TIMER QUEUE ELEMENT                  MTS0 09050020
*                           BLOCK REPRESENTING A TIMER INTERVAL    MTS0 09060020
*                                                                  MTS0 09070020
*                         TQEFLGS- SET BY POST WHEN A REAL TQE IS  MTS0 09080020
*                                  TO BE CONVERTED TO A TASK TQE   MTS0 09090020
*                                                                  MTS0 09100020
*                         TQEVAL- SET BY POST TO REINSTATE THE CPU MTS0 09110020
*                                 TIME REMAINING FOR A STEP        MTS0 09120020
*                                                                  MTS0 09130020
*LIST ORIGINS,TABLES                                                    09140020
*RESTRICTIONS ON USE                                                    09150020
*AND CONTROL BLOCKS                                                     09160020
*INCLUDED-               NONE                                           09170020
*                                                                       09180020
*OF ROUTINE-             THE ECB'S COMPLETION FLAG SHOULD BE            09190020
*                        0 WHEN POST MACRO IS GIVEN. IF NOT             09200020
*                        POSTING WILL HAVE THE EFFECT OF A NOP.         09210020
*                                                                       09220020
* NOTES                  IF A SUPERVISORY ROUTINE WISHES TO USE         09230020
* NOTES                  POST AS A SUBROUTINE, A BRANCH                 09240020
*                        ENTRY SHOULD BE USED.  THAT IS                 09250020
*                        POST'S ADDRESS (IGC002+2) +4.                  09260020
*                        FURTHER, THE CALLING ROUTINE MUST SET THE      09270020
*                        PSW AND GENERAL REGISTERS 3,4,5 AND            09280020
*                        14 PRIOR TO ENTERING SVC POST                  09290020
*                        AS PRESCRIBED UNDER ENTRY POINT VIA SVC.       09300020
*                        NO VALIDITY CHECKING WILL BE DONE.             09310020
         EJECT                                                          09320020
* SVC POST (SVC 2)                                                      09330020
*  ENTER WITH ECB ADDRESS IN REGISTER 1 OR THE ADDRESS OF A       21B72 09336021
*   THREE WORD PARM LIST FOR IPP.                                 21B72 09342021
*  ENTER WITH POST CODE IN REGISTER 0.                                  09350020
* FUNCTION.                                                             09360020
*  POST WILL SET COMPLETION FLAG AND CODE IN ECB. IF POST TRIES TO POST 09370020
* A POSTED TCB, IT IGNORES POSTING AND EXITS.                           09380020
*  INPUT ECB'S PROTECT KEY IS TESTED IF EQUAL TO WAITING TCB, IF ENTRY  09390020
* BY NON SUPERVISER. IF ECB'S PROTECT KEY IS NOT CORRECT GO TO ABTERM.  09400020
*  STORE POST CODE AND POST FLAG IS ECB. THAN DECREMENT WAITING RB'S    09410020
* WAIT COUNT. IF DECREMENTED WAIT COUNT IS ZERO, CHECK THE SEARCH ECB   09420020
* FLAG IN THE RB. IF THE FLAG IS ON, FIND OUT THE POSITION OF THE RB    09430020
* IN ITS QUEUE. IF RB IS THE TOP RB, GET ECB LIST ADDRESS FROM TCB      09440020
* SAVE REGISTER 1. IF RB IS NOT TOP OF IT'S QUEUE, GET THE RB JUST      09450020
* ABOVE THE REQUESTING RB. FIND OUT THE TYPE OF RB IT IS, AND GET THE   09460020
* ECB LIST ADDRESS FROM REGISTER 1 SAVE AREA ACCORDANTLY. AFTER LIST    09470020
* ADDRESS HAS BEEN FOUND, RESET ALL ECB WAIT FLAG.                      09480020
         SPACE 2                                                        09490020
IGC001   CSECT                                                          09500020
         SPACE 2                                                        09510020
         CNOP  0,8                                                      09520020
IGC002   BALR  XRBASE,0                                                 09530020
         USING *,XRBASE                                                 09540020
         B     SVCENTRY                BRANCH UNCONDITIONALLY           09550020
         STM   XRPTCODE,SELREG,SAVEXR  SAVE REGISTERS 0-9         M0113 09560020
         B     POSTTEST                UNCONDITIONALLY BRANCH           09570020
SVCENTRY EQU   * .                                                20021 09580020
         TM    33(0),SUPTST .          Q ENTRY BY SUPERVISOR      20021 09620020
         BZ    TJIDREQ                 YES, TAKE BRANCH           20021 09630020
         SPACE 2                                                        09640020
*  VALIDITY CHECK THE INPUT ECB ADDRESS.                                09650020
         SPACE 2                                                        09660020
         LA    XRABTERM,ERRPOST1       ECB ADDRESS INVALID              09670020
         LR    XRSAVE,XRECB             SAVE REGISTER 1                 09680020
         L     XRTSTADR,CHECK           $LOAD VALIDITY C. ADR.          09690020
         BAL   XRLINK,4(XRTSTADR)       Q. ECB ADDRESS VALID            09700020
         LR    XRECB,XRSAVE             RESET REGISTER 1                09710020
         BNE   ERROR                   BRANCH TO ABTERM                 09720020
         B     RBCHECK                 UNCONDITIONALLY BRANCH           09730020
         EJECT                                                          09750020
         SPACE 2                                                        09780020
*  ENTRY POINT IEA0PT01                                                 09790020
         SPACE 1                                                        09800020
         USING *,XRBASE                                                 09810020
IEA0PT01 L     XRBASE,BASE                                              09820020
         USING IGC002+2,XRBASE                                          09830020
         STM   XRPTCODE,SELREG,SAVEXR  SAVE REGISTERS 0-9         M0113 09842020
         LR    XRPTCODE,XRECBPTR       LOAD POST CODE                   09850020
         LR    XROTCB,XRLINK           LOAD TCB ADDRESS                 09862020
         LTR   XRECB,XRSAVE            INTER-PARTITION POST ?     21B72 09882021
         BNM   POSTTEST                NO.BRANCH TO POST PROPER   M1173 09910020
         LR    XRTJID,XRBTJID .        YES.GET TJID               20021 09930020
         B     TSTTJID .               GO CHECK TJID              20021 09931020
         SPACE 2                                                        09940020
*   ENTRY POINT IEA0PT02                                                09950020
         SPACE 1                                                        09960020
         USING *,XRBASE                                                 09970020
IEA0PT02 L     XRBASE,BASE                                              09980020
         USING IGC002+2,XRBASE                                          09990020
         STM   XRPTCODE,SELREG,SAVEXR  SAVE REGISTERS 0-9         M0113 10002020
         LR    XRPTCODE,XRECBPTR       LOAD POST CODE                   10010020
         LR    XRECB,XRSAVE            LOAD ECB ADDRESS                 10020020
         LR    XROTCB,XRLINK           LOAD TCB ADDRESS                 10030020
         L     XRCVT,X'10'             LOAD CVT POINTER                 10040020
         SPACE 2                                                        10050020
*  ECB'S RB ADDRESS IS CHECKED TO SEE IF IT IS VALID.                   10060020
*  THE TESTS ARE COMPOSED OF                                            10070020
*  1. IS RB ADDRESS ON A FULL WORD BOUNDRY                              10080020
*  2. IS THE SYSTEM MASK IN THE RB'S OPSW ENABLED.                      10090020
*  3. DOES THE STORAGE KEY OF THE ECB EQUAL THE KEY OF THE RB'S OPSW.   10100020
*  4. DOES THE ADDRESS FIELD OF THE OPSW -2 POINT TO SVC 1 (WAIT)       10110020
*    INSTRUCTION.                                                       10120020
         SPACE 2                                                        10130020
RBCHECK  EQU   * .                                            CI A45983 10134021
         TM    ZERO(XRECB),ECBPTFLG .  Q. ECB ALREADY POSTED  CI A45983 10138021
         BO    EXIT .                  YES, RETURN            CI A45983 10142021
         TM    ZERO(XRECB),ECBWTFLG .  Q. ECB BEING WAITED ON CI A45983 10146021
         BZ    SETPCODE .              NO, BRANCH - POST      CI A45983 10150021
*                                          ISSUED BEFORE WAIT CI A45983 10154021
         SR    XRWORK5,XRWORK5         $INITIALIZE REG. TO ZERO         10160020
         L     XRWRB,0(XRECB)          LD ECB'S RB ADR.                 10170020
         LA    XRWRB,0(XRWRB)          CLEAR HI BYTE                    10180020
         LA    XRQUIT,ERRPOST2         LOAD INVALID RB CODE             10190020
         TM    3(XRECB),X'03'          RB ON FULL WORD BOUNDRY          10200020
         BC    7,ERROR1                NO, TAKE BRANCH                  10210020
         L     XRWORK,MACHSIZE(XRCVT)  OBTAIN MACHINE SIZE              10220020
         CR    XRWRB,XRWORK           Q.IS RB ADDRESS WITHIN MACH.      10230020
         BC    10,ERROR1               NO, TAKE BRANCH                  10240020
         TM    LHOPSW+1(XRWRB),SUPTST     SUPV TASK              M0012  10240221
         BZ    BYP                                               M0039  10240421
         CLI   LHOPSW(XRWRB),X'FF'     Q. OPSW ENABLED IN RB            10250020
         BC    7,ERROR1                NO, TAKE BRANCH                  10260020
BYP      EQU   *                                                 M0039  10260221
         SR    XRWORK,XRWORK           INITIALIZED TO ZERO              10270020
         N     XRECB,RBVALID            AND OFF 4 HI ORDER BITS         10280020
         ISK   XRWORK,XRECB            OBTAIN STORAGE KEY OF ECB        10290020
         LR    XRECB,XRSAVE             RESTORE ECB ADDRESS             10300020
         LM    XRCHCK1,XRCHCK2,KTEST   INITIALIZE REGS FOR RB TEST      10310020
         IC    XRWORK5,LHOPSW+1(XRWRB) LOAD OPSW KEY FROM RB            10320020
         NR    XRWORK5,XRCHCK1         AND OFF AMWP BITS OF OPSW        10330020
         LTR   XRWORK5,XRWORK5         Q.  SUPV PROTECT KEY        0297 10340020
         BC    8,ZEROKEY               YES, TAKE BRANCH            0297 10350020
         CR    XRWORK,XRWORK5          Q. ARE KEYS ALIKE                10360020
         BC    7,ERROR1                NO, TAKE BRANCH                  10370020
ZEROKEY  L     XRWORK5,RHOPSW(XRWRB)   LOAD OPSW ADDRESS FIELD     0297 10380020
         S     XRWORK5,KTWO            SUBTRACT 2 FROM ADDRESS          10390020
         CH    XRCHCK2,0(0,XRWORK5)    Q. IS SVC INST. PRESENT (0A01)   10400020
         BC    8,POSTTEST              YES,TAKE BRANCH                  10410020
         SPACE 2                                                        10420020
         S     XRWORK5,KTWO            SUBTRACT 2 MORE FROM OPSW ADR.   10430020
         CLI   0(XRWORK5),X'44'        Q. WAS SVC 1 EXECUTED            10440020
         BE    POSTTEST                YES. CONTINUE               0854 10450020
         L     XRWORK5,ZERO(XRECB) .   GET ADDR OF RB TO POST     20021 10460020
         TM    RBSTAB(XRWORK5),TRSVRB .Q  TRANSIENT RTN ?         20021 10470020
         BO    POSTTEST .              YES - TAKE BRANCH          20021 10480020
         LR    XROTCB,XRWRB            DUP ECB-RB ADDRESS        A22207 10490020
TCBSRCH  TM    RBSTAB+1(XROTCB),TCBIND Q.LNK FLD POINTS TO TCB   A22207 10500020
         L     XROTCB,RBLINK(XROTCB)   GET NEXT RB OR TCB ADDR   A22207 10510020
         BZ    TCBSRCH                                           A22207 10520020
         TM    TCBFLGS+2(XROTCB),TCBABTRM   Q.ABTERM IN PROCESS  A22207 10530020
         BO    EXIT                         YES.DON'T CONTINUE   A22207 10540020
         TM    TCBFLGS+0(XROTCB),TCBFA      Q.ABEND IN PROCESS   A22207 10550020
         BO    EXIT                         YES.DON'T CONTINUE   A22207 10560020
         B     ERROR1                  NO. GO TO ABTERM THIS TASK  0854 10570020
         SPACE 1                                                        10580020
TJIDREQ  LTR   TJIDTEST,XRECB          INTER-PARTITION POST ?     21B72 10583021
         BM    CKTJID                    YES.CHECK TJID           20021 10586020
         SPACE 2                                                        10590020
*  TEST IF POST FLAG IN ECB ON. YES ON, GO TO EXIT SECTION. NO NOT ON,  10600020
* STORE POST CODE AND SET POST FLAG IN ECB.                             10610020
*  DECREMENT RB'S WAIT COUNT. DECREMENTED WAIT COUNT ZERO GO TO EXIT    10620020
* SECTION. COUNT NOT ZERO CONTINUE PROCESS.                             10630020
         SPACE 2                                                        10640020
POSTTEST TM    0(XRECB),ECBPTFLG     Q. ECB'S POST FLAG SET             10650020
         BC    12,CONTINUE             NO, TAKE BRANCH                  10660020
         LM    XRPTCODE,SELREG,SAVEXR  RESTORE REGISTERS 0-9      M0113 10670020
         BR    XRRETURN                RETURN                           10680020
CONTINUE TM    0(XRECB),ECBWTFLG       Q. POST BEFOR WAIT               10690020
         BC    1,DECOUNT               NO BRANCH TO DECREMENT COUNT     10700020
SETPCODE EQU   * .                                            CI A45983 10705021
         ST    XRPTCODE,0(XRECB)       STORE POST CODE                  10710020
         NI    0(XRECB),RECBWTF .      TURN OFF HIGH BIT IN       20472 10712020
*                                    CASE ON DUE TO LARGE PCODE   20472 10714020
         OI    0(XRECB),ECBPTFLG       SET POST FLAG                    10720020
         LM    XRPTCODE,SELREG,SAVEXR  RESTORE REGISTERS 0-9      M0113 10732020
         BR    XRRETURN                RETURN                           10740020
DECOUNT  L     XRRB,0(XRECB)           GET RB ADDRESS                   10750020
         LA    XRRB,0(XRRB)            ZERO BITS 0-7                    10760020
         ST    XRPTCODE,0(XRECB)       STORE POST CODE                  10810020
         OI    0(XRECB),ECBPTFLG .     SET POST FLAG              M5407 10820020
         NI    0(XRECB),RECBWTF .      TURN OFF WAIT FLAG         M5407 10830020
         SR    XRWTCT1,XRWTCT1         INIT REG TO ZERO           19472 10840020
         TM    RBWCF(XRRB),ANYONE      Q. IS WAIT COUNT ZERO            10850020
         BZ    EXIT .                                            A38447 10860020
         IC    XRWTCT1,RBWCF(XRRB)     LOAD ECBS RB WAIT COUNT          10870020
         BNO   NORMAL .                BRANCH IF WT CT NOT 255   A33247 10871020
         SPACE 1                                                        10872020
*    A WAIT COUNT OF 255 IN A TYPE 3 OR 4 SVRB MEANS THAT THE    A33247 10873020
*        TRANSIENT ROUTINE HAS BEEN PREEMPTED (OVERLAID).        A33247 10874020
         SPACE 1                                                        10875020
         TM    RBSTAB(XRRB),XSNTSVRB . Q.XSNT ROUTINE            A33247 10876020
         BNO   NORMAL .                NO.DO NORMAL PROCESSING   A33247 10877020
         IC    XRWTCT1,WCTSAVE(XRRB) . YES.USE SAVED WAIT CT     A33247 10878020
         LTR   XRWTCT1,XRWTCT1 .       Q.SAVED COUNT = 0         A33247 10879020
         BZ    EXIT .                  YES.EXIT                  A33247 10880020
NORMAL   EQU   * .                                               A33247 10881020
         BCTR  XRWTCT1,0 .          DECREMENT COUNT              A38447 10885020
         SPACE 1                                                        10890020
*  WAIT COUNT IS ZERO. TEST RB'S ECB SEARCH FLAG. IF FLAG NOT ON GO TO  10900020
* NEXT SECTION. IF FLAG IS ON RESET IT AND TEST IF RB ON TOP OF IT'S    10910020
* QUEUE. IF RB IS TOP OF IT'S QUEUE GET ECB LIST ADDRESS FROM TCB'S     10920020
* REGISTER 1 SAVE AREA. IF RB NOT TOP OF IT'S QUEUE FIND OUT WHAT TYPE  10930020
* OF RB IS ON TOP OF IT. THEN GET ECB LIST ADDRESS FROM WHEREVER THE    10940020
* REGISTER 1 IS SAVED IN THAT TYPE OF RB. AFTER GETTING ECB LIST        10950020
* ADDRESS, GO AND RESET  ALL THE ECB'S WAIT FLAGS TO ZERO.              10960020
         SPACE 2                                                        10970020
         TM    RBWCF(XRRB),ANYONE .  WAIT COUNT = 255            A38447 10970820
         BNO   QENTRY .         NO                               A38447 10971620
         STC   XRWTCT1,WCTSAVE(XRRB) .STORE WAIT CT IN SAVE FLD  A38447 10972420
         B     TRANS .                                           A38447 10973220
QENTRY   STC   XRWTCT1,RBWCF(XRRB) .  STORE IN NORMAL FLD        A38447 10974020
TRANS    LTR   XRWTCT1,XRWTCT1 .      IS COUNT ZERO              A38447 10974820
         BNZ   EXIT .                                            A38447 10975620
         NI    RBSTAB(XRRB),X'FF'-RBWAITP RESET RB WAITING    CI A45983 10976021
         LR    XROTCB,XRRB .       DUP RB REG                    A38447 10976420
CHECKECB TM    RBSTAB+1(XROTCB),TCBIND .. TCB OR RB              A38447 10977220
         L     XROTCB,RBLINK(XROTCB) .  LD NEXT RB OR TCB        A38447 10978020
         BZ    CHECKECB .          TEST THIS ONE                 A38447 10978820
         TM    RBSTAB+1(XRRB),RBECBWT  Q.ECB'S SEARCH FLAG SET          10980020
         BZ    TCBREADY                 NO BRANCH                       10990020
         NI    RBSTAB+1(XRRB),RRBECBWT  RESET RB ECB SEARCH FLAG        11000020
         C     XRRB,TCBRBP(XROTCB)     Q.ECB'S RB TOP OF QUEUE          11010020
         BE    TCBXR1         YES BRANCH                                11020020
         L     XRWRB,TCBRBP(XROTCB)     LD TOP RB'S ADR                 11030020
LOOP3    L     XRWRB1,RBLINK(XRWRB)     LD NEXT RB'S ADR                11040020
         LA    XRWRB1,0(XRWRB1)         ZERO BITS S-7                   11050020
         CR    XRRB,XRWRB1             Q.FOUND WAITING RB               11060020
         BE    RBTYPE                   YES BRANCH                      11070020
         LR    XRWRB,XRWRB1             SAVE HIGHER RB'S ADR            11080020
         B     LOOP3                                                    11090020
RBTYPE   LA    XRECBPTR,IRBXR1(XRWRB)  SIRB IRB REG PTR          A68359 11100021
         B     RESETWT                                                  11110020
TCBXR1   LA    XRECBPTR,TCBGRS1(XROTCB) TCB REG PTR              A68359 11120021
RESETWT  TM    0(XRECBPTR),X'FF'       COMP REG                  A68359 11120221
         BC    1,RESETWT2              YES                       A68359 11120421
         L     XRECBPTR,0(XRECBPTR)    TRUE LIST                 A68359 11120621
         B     RESETWT4                                          A68359 11120821
RESETWT2 L     XRECBPTR,0(XRECBPTR)    REG 1                     A68359 11121021
         LCR   XRECBPTR,XRECBPTR                                 A68359 11121221
RESETWT4 EQU   *                                                 A68359 11130021
         LA    XRABTERM,ERRPOST1       ECB ADDRESS INVALID              11140020
         LR    XR0,XRRB                SAVE RB ADDRESS                  11150020
LOOP4    L     XRWORK,0(XRECBPTR)      LOAD ECB ADDRESS                 11160020
         TM    LHOPSW+1(XRRB),SUPTST   Q. REQUESTOR SUPERVISOR          11170020
         BC    8,NOCHECK               YES, TAKE BRANCH                 11180020
         LR    XRECB,XRWORK            DUP. ECB ADDRESS                 11190020
         L     XRCVT,X'10'             VAL CHECK PARAMETER              11200020
         L     XRTSTADR,CHECK          LOAD VALIDITY C. ROUTINE ADR.    11210020
         BAL   XRLINK,4(XRTSTADR)      Q. IS ECB ADDRESS VALID          11220020
         BE    NOCHECK                 BRANCH IF ECB IS VALID     20002 11230020
         LA    XRLINK,NOCHECK          SET RETURN ADDR            20002 11240020
COMMCHEK L     COMMREG,TCBJSCB(TCBREG) GET JSCB ADDR              20002 11250020
         USING IEZJSCB,COMMREG                                    20002 11260020
         L     COMMREG,JSCBCSCB        GET CSCB ADDR              20002 11270020
         USING CSCB,COMMREG                                       20002 11280020
         L     COMMREG,CHECBP          GET COMMUNICATION'S        20002 11290020
*                                           ECB ADDRESS           20002 11300020
         LA    CHECKREG,0(CHECKREG)    CLEAR THE HIGH BYTE        20002 11310020
         CR    COMMREG,CHECKREG        Q.ECB EQUAL TO COMM. ECB   20002 11320020
         BCR   8,XRLINK                YES.CONTINUE               20002 11330020
         BALR  ERRBASE,0 .        COMMON BASE FOR WAIT OR POST    M3988 11332020
         USING *,ERRBASE .                                        M3988 11334020
         B     ERROR                   NO.GO TO ABTERM            20002 11340020
         DROP  ERRBASE .                                          M3988 11342020
NOCHECK  NI    0(XRWORK),RECBWTF       ZERO WT. FLAG                    11350020
         TM    0(XRECBPTR),LSTIND      Q.LAST ECB PTR                   11360020
         BO    TCBOK                   YES,TAKE BRANCH                  11370020
         LA    XRECBPTR,4(XRECBPTR)     UPDATE ECB LIST                 11380020
         B     LOOP4                                                    11390020
         SPACE 1                                                        11400020
*            RB'S WAIT COUNT HAS GONE TO ZERO                           11410020
*                                                                       11420020
TCBOK    LR    XRRB,XR0                RESTORE RB ADDRESS               11430020
TCBREADY LA    REGRTCB,0(XROTCB)        $LOAD TCB ADDRESS               11440020
         SPACE 1                                                 A33247 11441020
*    A NON-ZERO WAIT COUNT AT THIS POINT MEANS THAT THE RB IS    A33247 11442020
*        FOR A TRANSIENT ROUTINE WHICH WAS OVERLAID.  THE REAL   A33247 11443020
*        WAIT COUNT IS IN THE SVRB AT OFFSET X'18'.              A33247 11444020
         SPACE 1                                                 A33247 11445020
* GET INITIATOR TQE,  IF NO TQE GO TO TASK SWITCH ROUTINE.  IF TQE MTS0 11460020
* IS NOT REAL AND ON QUEUE GO TO TASK SWITCH ROUTINE.  DEQUEUE TQE MTS0 11470020
* RESTORE CPU VALUE AND MARK AS TASK TQE.  GO TO TASK SWITCH       MTS0 11480020
* ROUTINE.                                                         MTS0 11490020
JSTMEP   EQU   *                                                   MTS0 11500020
         L     XRWTCT1,TCBJSTCB(REGRTCB) GET J/S TCB               MTS0 11510020
         L     XRNEW,TCBOTC(XRWTCT1)   GET MOTHER OF J/S           MTS0 11520020
         LA    XRWTCT1,NOJSTMPT        SET UP BRANCH REGISTER      MTS0 11530020
         LTR   XRNEW,XRNEW             IS TCB A SYSTEM TASK        MTS0 11540020
         BCR   8,XRWTCT1               YES, EXIT                   MTS0 11550020
         TM    TCBTSFLG(XRNEW),TSTASK .Q  TS TASK?                20021 11560020
         BCR   1,XRWTCT1 .             YES, EXIT                  20021 11570020
         TM    TCBPKF(XRNEW),X'F0'     IS PROTECT KEY = 0          MTS0 11580020
         BCR   8,XRWTCT1               YES, SYSTEM TASK            MTS0 11590020
         L     XRTESTWD,TCBTME(XRNEW)  ADDRESS OF TQE              MTS0 11600020
         LTR   XRTESTWD,XRTESTWD       IS THERE A TQE              MTS0 11610020
         BCR   8,XRWTCT1               NO, EXIT FROM J/S TIMING    MTS0 11620020
         TM    TQEFLGS(XRTESTWD),X'03' IS TQE REAL                 MTS0 11630020
         BCR   14,XRWTCT1              NO, EXIT FROM J/S TIMING    MTS0 11640020
         TM    TQEFLGS(XRTESTWD),X'80' IS TQE OFF QUEUE            MTS0 11650020
         BCR   1,XRWTCT1               YES, EXIT FROM J/S TIMING   MTS0 11660020
         LR    XR0,XRZERO              SAVE REGISTERS 7,8,14       MTS0 11670020
         LR    XRWTCT1,XRRETURN                                    MTS0 11680020
         LR    XRWRB1,XRWTCT                                       MTS0 11690020
         L     XRBASE,BASEDEQ          ADDRESS DEQUEUE ROUTINE     MTS0 11700020
         BALR  XRRB,XRBASE             GO TO DEQUEUE TQE           MTS0 11710020
         USING *,XRRB                  REESTABLISH ADDRESSABILITY  MTS0 11720020
         L     XRBASE,BASE                                         MTS0 11730020
         USING IGC002+2,XRBASE                                     MTS0 11740020
         DROP  XRRB                                                MTS0 11750020
         LR    XRZERO,XR0              RESTORE REGS 7,8,14         MTS0 11760020
         LR    XRRETURN,XRWTCT1                                    MTS0 11770020
         LR    XRWTCT,XRWRB1                                       MTS0 11780020
         L     XRWTCT1,TCBJSTCB(XRWRB)                             MTS0 11790020
         L     XRWTCT1,TCBOTC(XRWTCT1)                             MTS0 11800020
         L     XRWTCT1,TCBTME(XRWTCT1)                             MTS0 11810020
         MVC   TQEVAL(4,XRWTCT1),TQESAV(XRWTCT1) RESTORE CPU VAL   MTS0 11820020
         NI    TQEFLGS(XRWTCT1),X'FC'  MARK AS TASK TIME           MTS0 11830020
NOJSTMPT EQU   *                                                   MTS0 11840020
         LM    XRPTCODE,SELREG,SAVEXR  RESTORE REGISTERS 0-9      M0113 11852020
         L     REGSWTCH,SWTEST          $LOAD ADR. OF TASK SWITCH R.    11860020
         BR    REGSWTCH                 BRANCH TO T.S. ROUTINE          11870020
         SPACE 1                                                 A33247 11872020
EXIT     LM    XRPTCODE,SELREG,SAVEXR  RESTORE REGS 0-9           M0113 11900020
         BR    XRRETURN                                                 11910020
*  ERROR EXIT                                                           11920020
ERROR1   LR    XRABTERM,XRQUIT         LOAD ERROR CODE                  11930020
*                                                                       11940020
ERROR    LR    XRERCODE,XRABTERM       LOAD ERROR CODE                  11950020
         LR    XRCVT,XRRETURN          SAVE RETURN REG                  11960020
         BALR  XRBASE,0                RE-ESTABLISH                     11970020
         USING *,XRBASE                ADDRESSING                       11980020
         L     XRBASE,BASE             FOR WAIT                         11990020
         USING IGC002+2,XRBASE         AND POST                         12000020
         LR    XRQUIT,XRBASE           SAVE BASE XR                0854 12010020
         L     XRABTERM,ABTERM         LOAD E P                         12020020
         L     XRRETURN,IOSWADDR .ADDR OF I/O SW IN FLIH      BD A37037 12021021
         TM    ONE(XRRETURN),X'F0' IS ENTRY FROM IOS-SW ON    BD A37037 12022021
         BO    IOENTRY .          YES-SET RETURN TO HERE      BD A37037 12023021
         L     XRRETURN,TYP1EXIT .SET RETURN TO TYPE 1 EXIT   BD A37037 12024021
         BR    XRABTERM .         GO TO ABTERM                BD A37037 12025021
IOENTRY  EQU   * .                                            BD A37037 12026021
         BALR  XRRETURN,XRABTERM       GO TO ABTERM                     12030020
         LR    XRRETURN,XRCVT          RESTORE RETURN REG               12040020
         LR    XRBASE,XRQUIT           RESTORE BASE XR             0854 12050020
         BC    15,EXIT                                                  12060020
         AIF   (NOT &B(1)).TSO001                                 20021 12061020
*********************************************************************** 12070020
*                                                                       12080020
*     THIS CODE IS ENTERED IF A TJID WAS SPECIFIED.  IT ALLOWS    20021 12090020
*     THE POSTING OF TIME SHARING USER'S THAT MAY OR MAY NOT BE   20021 12100020
*     IN CORE.  IF THE ECB IS NOT IN CORE, CORE IS GOTTEN VIA     20021 12110020
*     BRANCH ENTRY TO REGMAIN FOR AN INTER-PARTITION POST BLOCK.  20021 12120020
*     THIS IPPB IS INITIALIZED AND CONTROL IS PASSED TO THE TIME  20021 12130020
*     SHARING INTERFACE PROGRAM (TSIP)    WHICH WILL BRING THE    20021 12140020
*     USER TO BE POSTED INTO CORE.                                20021 12150020
*                                                                       12160020
*********************************************************************** 12170020
.TSO001  ANOP                                                     20021 12180020
CKTJID   EQU   * .                                                20021 12190020
         L     XRECB,PARMTCB(XRECB)     TCB OF POSTEE IF ANY      21B72 12199021
         LR    XRLINK,XROTCB      SAVE POSTERS TCB                21B72 12208021
         LTR   XRECB,XRECB              TCB = 0 ?                 21B72 12217021
         BZ    TCBZERO                  USE POSTERS TCB           21B72 12226021
         LR    TCBREG,XRECB             USE TCB OF ECB OWNER      21B72 12235021
TCBZERO  L     XRECB,PARMECB(TJIDTEST) @ECB FROM IPP PARM LIST    21B72 12244021
         L     XRTJID,PARMTJID(TJIDTEST) @TJID FROM IPP PARM LIST 21B72 12253021
         LH    XRTJID,ZERO(XRTJID)      TJID                      21B72 12262021
TSTTJID  EQU   * .                                                21B72 12266021
         LR    TJIDTEST,XRTJID          SAVE FOR TSIP             21B72 12271021
         LTR   XRTJID,XRTJID .    Q. TJID = 0                     21B72 12280021
         L     XRCVT,CVTPTR .          GET ADDRESS OF CVT         20021 12290020
         BZ    POSTTEST .              YES- BACKGROUND TASK       20021 12300020
         AIF   (&B(1)).TSO004                                     20021 12310020
         LA    XRABTERM,ERRPOST1 .     ECB ADDRESS INVALID        20021 12310420
         B     ERROR .                 BRANCH - INVALID IPP       20021 12310820
         AGO   .TSO002                                            20021 12312020
.TSO004  ANOP                                                     20021 12314020
         TM    TSCVTPTR(XRCVT),CVTTSRDY Q IS TIME SHARING ACTIVE  20021 12320020
         BNZ   TSOACT             YES                             21B72 12323021
         LR    XROTCB,XRLINK      POSTERS TCB FOR ABTERM          21B72 12326021
         LA    XRABTERM,ERRPOST1 .     ECB ADDRESS INVALID        20021 12330020
         BZ    ERROR .                 BRANCH - INVALID IPP       20021 12340020
TSOACT   L     XRTSCVT,TSCVTPTR(XRCVT)  GET POINTER TO TSCVT            12350021
         USING TSCVT,XRTSCVT                                      20021 12360020
         MH    XRTJID,TSCVTSZU .       COMPUTE DISPLACEMENT IN    20021 12370020
*                                      TJB LIST                   20021 12380020
         L     XRTJB,TSCVTTJB .        GET ADDRESS OF TJB LIST    20021 12390020
         AR    XRTJB,XRTJID .          GET ADDRESS OF THE TJB OF  20021 12400020
*                                      USER TO BE POSTED          20021 12410020
         DROP  XRTSCVT .                                          20021 12420020
         USING TJB,XRTJB .                                        20021 12430020
         TM    TJBSTAT,TJBNJB .    Q. TJB NOT ACTIVE              M3813 12432020
         BO    EXIT .              YES-RETURN W/O POSTING ECB     M3813 12434020
         TM    TJBSTAT,TJBINCOR .  Q IS USER TO BE POSTED         20021 12440020
*                                  IN CORE ?                      20021 12450020
         BO    POSTTEST .          YES - NORMAL POST PROCESSING   20021 12460020
         ST    XRRETURN,IPRG14SA . SAVE REG 14 BEFORE GETMAIN     20021 12480020
         STM   XRPTCODE,XRECB,IPPSAV .SAVE POST CODE AND ECB ADR  20021 12490020
         L     XRM0,GMIPPB .       SUBPOOL& LENGTH FOR REGMAIN    20021 12500020
         LR    XRM1,XRM0 .         NEGATIVE NUMBER FOR REGMAIN    20021 12510020
         LR    XTEMPBAS,XRBASE .   SAVE BASE REG ACROSS GM        20021 12520020
         L     XRREGM,REGMAIN .    GETMAIN BRANCH ENTRY           20021 12530020
         BALR  XRRETURN,XRREGM .   TO GETMAIN 16 BYTES FOR IPPB   20021 12540020
         LR    XRBASE,XTEMPBAS .       RESTORE BASE REGISTER      20021 12550020
         LR    NEWIPPB,XRM1 .          SET UP NEWIPPB REG         20021 12560020
         USING IPPB,NEWIPPB .                                     20021 12570020
         XC    IPPBTJQ(L16),IPPBTJQ .  CLEAR NEW IPPB             20021 12580020
         LM    XRPTCODE,XRECB,IPPSAV . RESTORE POST CODE AND ECB  20021 12590020
         ST    XRECB,IPPBECB .         PUT ECB ADDR IN IPPB       20021 12600020
         ST    XRPTCODE,IPPBCODE .     PUT POST CODE IN IPPB      20021 12610020
         L     IPPBREG,TJBIPPB .       GET ADDR. OF FIRST IPPB    20021 12620020
         LTR   IPPBREG,IPPBREG .       Q ANY IPPB'S ?             20021 12630020
         BZ    FSTIPPB .               NO-GO QUEUE IPPB           20021 12640020
NEXTIPPB EQU   * .                                                20021 12650020
         DROP  NEWIPPB .                                          20021 12660020
         USING IPPB,IPPBREG .                                     20021 12670020
         NC    IPPBTJQ(FOUR),IPPBTJQ . Q LAST IPPB ?              20021 12680020
         BZ    QIPPB .                 YES  -  TAKE BRANCH        20021 12690020
         L     IPPBREG,IPPBTJQ .       NO - GET ADR.OF NEXT IPPB  20021 12700020
         B     NEXTIPPB .              PROCESS NEXT IPPB          20021 12710020
FSTIPPB  EQU   * .                                                20021 12720020
         ST    NEWIPPB,TJBIPPB .       QUEUE IPPB OFF TJB         20021 12730020
         B     TOTSIP .                PREPARE FOR TSIP           20021 12740020
QIPPB    ST    NEWIPPB,IPPBTJQ .       PUT NEW IPPB ON QUEUE      20021 12750020
TOTSIP   EQU   * .                                                20021 12760020
         DROP  IPPBREG .                                          M1070 12762020
         DROP  XRBASE .                                           M1070 12764020
         DROP  XRTJB .                                            20021 12770020
         L     XRTSCVT,TSCVTPTR(XRCVT) GET ADDR. OF TSCVT         20021 12780020
         LR    XTEMPBAS,XRBASE .       SAVE BASE ACROSS TSIP      20021 12790020
         USING IGC002+2,XTEMPBAS .                                20021 12800020
         USING TSCVT,XRTSCVT .                                    20021 12810020
         L     XRTSIP,TSCVTI01 .       GET ENTRY PT. OF TSIP      20021 12820020
         DROP  XRTSCVT .                                          20021 12830020
         SPACE                                                          12840020
*    TAKE BRANCH ENTRY TO TSIP TO REQUEST USER TO BE POSTED TO    20021 12850020
*                   BE SWAPPED INTO CORE                          20021 12860020
         SPACE                                                          12870020
         TSEVENT  USERRDY,TJID=(6),ENTRY=BRANCH                         12880020
         LR    XRBASE,XTEMPBAS .       RESTORE BASE REG           20021 12890020
         DROP  XTEMPBAS .                                         20021 12900020
         USING IGC002+2,XRBASE .                                  20021 12910020
         L     XRRETURN,IPRG14SA .     RESTORE RETURN REG         20021 12920020
         B     EXIT .                                             20021 12940020
.TSO002  ANOP                                                     20021 12950020
         SPACE 2                                                        12960020
ABTERM   DC    A(IEA0AB01)              ADDRESS OF ABTERM               12970020
CHECK    DC    A(IEA0VL01)              ADDRESS OF VALIDITY CHECK       12980020
SWTEST   DC    A(IEA0DS02)              ADR OF SWITCHING ROUTINE        12990020
BASE     DC    A(IGC002+2)                                              13000020
BASEDEQ  DC    A(IEAQTD01)             DEQUEUE ROUTINE             MTS0 13010020
BASEWT   DC    A(IGC001+2)                                         MTS0 13020020
W30MIN   DC    X'041EC148'         WAIT VALUE IN TIMER UNITS       8165 13030020
SAVEXR   DC    10F'0'                  REGISTER SAVE AREA         M0113 13040020
KTEST    DC    X'000000F0'             USED TO AND OFF AMWP BITS        13050020
         DC    X'00000A01'             USED TO VALIDATE RB              13060020
RBVALID  DC    X'FFFFFFF0'              USED TO AND OFF LAST 4 BITS     13070020
KTWO     DC    X'00000002'             RB CHECK VALUE 2.                13080020
IOSWADDR DC    A(IORGSW) .        I/O SW IN I/O FLIH(QNU)     BD A37037 13083021
TYP1EXIT DC    A(IEA0XE00) .      ADDR OF TYPE 1 EXIT(QNU)    BD A37037 13086021
         AIF   (NOT &B(1)).TSO003                                 20021 13090020
IPRG8SAV DC    1F'0' .             REG 8 SAVE ACROSS IPPB GM      20021 13100020
IPRG14SA DC    1F'0' .             REG 14 SAVE ACROSS IPPB GM     20021 13110020
IPPSAV   DC    2F'0' .             CODE AND WAIT CNT FOR GM       20021 13120020
GMIPPB   DC    X'F5000010'         TO GET 16 BYTE FROM SP 255     20021 13130020
.TSO003  ANOP                                                     20021 13140020
ADIEASAV DC    V(IEASCSAV) .       ADDR SVC REGISTER SAVE AREA    20021 13150020
REGMAIN  DC    V(RMBRANCH) .       REGMAIN BRANCH ENTRY           20021 13160020
TJIDBIT  DC    A(1)                TJID INDICATOR BIT             20021 13161020
         IKJIPPB                                                        13170020
         EJECT                                                          13180020
         IKJTJB                                                         13190020
         EJECT                                                          13200020
         IKJTSCVT                                                       13210020
CSCB     DSECT                                                    20002 13220020
         IEECHAIN                                                 20002 13230020
         IEZJSCB                                                  20002 13240020
         MEND                                                           13260020
