         MACRO                                                          00005021
&NAME    IECRPS &WKAREA=,&RDEB=,&WKREG1=                                00010001
.*                                                                      00015001
.*       MACRO DELETIONS/CHANGES FOR VS1 RELEASE 2                      00020001
.*       MACRO DELETIONS/CHANGES FOR VS2 RELEASE 1.6                    00025001
.*       MACRO DELETIONS/CHANGES FOR OS  RELEASE 21.7                   00030001
.*                                                                      00035001
.*                                                                      00040001
.********************************************************************** 00045001
.*                                                                      00050001
.* MODULE NAME = IECRPS                                                 00055001
.*                                                                      00060001
.* DESCRIPTIVE NAME = DADSM RPS SETUP MACRO                             00065001
.*                                                                      00070001
.* COPYRIGHT = NONE                                                     00075001
.* STATUS = CHANGE LEVEL 000                                            00080001
.* FUNCTION = THIS MACRO ISSUES A GETMAIN FOR AN RPS WORKAREA AND       00085001
.*            LOADS IGG019EK, THE RPS SIO APPENDAGE.                    00090001
.*            FOR VS THE GETMAIN IS UNCONDITIONAL, FOR OS THE GETMAIN   00095001
.*            IS CONDITIONAL AND IF NOT FULFILLED, RPS CHANNEL PROGRAMS 00100001
.*            WILL NOT BE USED.                                         00105001
.* NOTES = THIS IS AN INTERNAL MACRO USED IN THE FOLLOWING DADSM        00110001
.*         FUNCTIONS:                                                   00115001
.*                                                                      00120001
.*             ALLOCATE                                                 00125001
.*             SCRATCH                                                  00130001
.*             EXTEND                                                   00135001
.*             PARTIAL RELEASE                                          00140001
.*                                                                      00145001
.*    DEPENDENCIES = NONE                                               00150001
.*                                                                      00155001
.*    RESTRICTIONS = NONE                                               00160001
.*                                                                      00165001
.*    REGISTER CONVENTIONS = NOT APPLICABLE                             00170001
.*                                                                      00175001
.*    PATCH LABEL = NOT APPLICABLE                                      00180001
.*                                                                      00185001
.* MODULE TYPE = MACRO                                                  00190001
.*                                                                      00195001
.*    PROCESSOR = ASSEMBLER                                             00200001
.*                                                                      00205001
.*    MODULE SIZE = 100 BYTES FOR VS                                    00210001
.*                  104 BYTES FOR OS                                    00215001
.*                                                                      00220001
.*    ATTRIBUTES = NOT APPLICABLE                                       00225001
.*                                                                      00230001
.* ENTRY POINT = NOT APPLICABLE                                         00235001
.*                                                                      00240001
.*    PURPOSE = SEE FUNCTION                                            00245001
.*                                                                      00250001
.*    LINKAGE =                                                         00255001
.*             NAME    IECRPS WKAREA=ADDRESS,RDEB=R1,WKREG1=R2          00260001
.*                                                                      00265001
.*    INPUT = NAME SPECIFIED AS AN ACCEPTABLE ASSEMBLER LANGUAGE        00270001
.*            SYMBOL.                                                   00275001
.*                                                                      00280001
.*            WKAREA= IS A KEYWORD PARAMETER THAT MAY BE AN ADDRESS     00285001
.*            OF A 12 BYTE WORK AREA TO BE USED BY THE MACRO, OR        00290001
.*            A REGISTER NAME ENCLOSED IN PARENTHESES WHICH CONTAINS    00295001
.*            THE ADDRESS OF A 12 BYTE WORKAREA.                        00300001
.*                                                                      00305001
.*            RDEB= IS A KEYWORD PARAMETER THAT IS A REGISTER NAME OF   00310001
.*            A REGISTER THAT CONTAINS THE ADDRESS OF THE DEB THAT IS   00315001
.*            TO BE USED FOR RPS.                                       00320001
.*                                                                      00325001
.*            WKREG1= IS A KEYWORD PARAMETER THAT IS A REGISTER NAME    00330001
.*            OF A REGISTER THAT MAY BE USED BY THE MACRO AS A WORK     00335001
.*            REGISTER                                                  00340001
.*                                                                      00345001
.*    OUTPUT = RPS WORKAREA IS OBTAINED, RPS SIO/PAGE FIX/CE/ABE/EOE    00350001
.*             APPENDAGE IS LOADED                                      00355001
.*                                                                      00360001
.* EXIT-NORMAL = MEND STATEMENT                                         00365001
.*                                                                      00370001
.* EXIT-ERROR = NOT APPLICABLE                                          00375001
.*                                                                      00380001
.* EXTERNAL REFERENCES = NONE                                           00385001
.*                                                                      00390001
.*    ROUTINES = NONE                                                   00395001
.*                                                                      00400001
.*    DATA AREAS = NONE                                                 00405001
.*                                                                      00410001
.*    CONTROL BLOCKS = DEB                                              00415001
.*                     APPENDAGE VECTOR TABLE                           00420001
.*                                                                      00425001
.* MACROS = GETMAIN                                                     00430001
.*          LOAD                                                        00435001
.*                                                                      00440001
.* CHANGE ACTIVITY = SEE DELETIONS/CHANGES PRECEDING MACRO              00445001
.*                                                                      00450001
.*                                                                      00455001
.********************************************************************** 05540001
         GBLC  &LIB                                                     05545001
         LA    0,128                    LENGTH OF RPS WORK AREA         05550001
         AIF   ('&LIB' EQ 'LIB1').LIB1PS1                               05555001
.*                                      GETMAIN FOR VS IS               05560001
.*                                      UNCONDITIONAL                   05565001
*        GETMAIN R,LV=(0)               GET RPS WKAREA                  05570001
         GETMAIN R,LV=(0)               GET RPS WKAREA                  05575001
         LR    &WKREG1,1                SAVE PTR TO RPS WKAREA          05580001
.LIB1PS1 ANOP                                                           05585001
         AIF   ('&LIB' NE 'LIB1').LIB2PS2                               05590001
         AIF   ('&WKAREA'(1,1) EQ '(').GENREG1                          05595001
.*                                      IF REGISTER NOTATION IS USED,   05600001
.*                                      GENERATE AN LR INSTRUCTION      05605001
.*                                      INSTEAD OF AN LA INSTRUCTION.   05610001
         LA    1,&WKAREA                REGISTER 1 POINTS TO PARM LIST  05615001
         AGO   .SKPREG1                                                 05620001
.GENREG1 ANOP                                                           05625001
         LR    1,&WKAREA                LOAD R1 WITH PTR TO PARM LIST   05630001
.SKPREG1 ANOP                                                           05635001
         MVC   0(EPM&SYSNDX,1),GMP&SYSNDX                               05640001
*                                       MOVE GETMAIN PARAMETER LIST     05645001
*                                       TO DYNAMIC AREA                 05650001
*        GETMAIN EC,LV=(0),A=(1),MF=(E,(1))  GET RPS WORK AREA          05655001
         GETMAIN EC,LV=(0),A=(1),MF=(E,(1))                            *05660001
                                        GET RPS WORK AREA               05665001
         LTR   15,15                    WAS REQUEST SUCCESSFUL          05670001
         BNZ   OUT&SYSNDX               NO, RPS WILL NOT BE USED        05675001
         AIF   ('&WKAREA'(1,1) EQ '(').GENREG2                          05680001
.*                                      IF REGISTER NOTATION IS USED,   05685001
.*                                      GENERATE LA USING OFFSET OF     05690001
.*                                      REG INSTEAD OF SYMBOLIC NAME.   05695001
         L     &WKREG1,&WKAREA          LOAD WKREG1 WITH PTR TO         05700001
*                                       RPS WORK AREA                   05705001
         AGO   .SKPREG2                                                 05710001
.GENREG2 ANOP                                                           05715001
         L     &WKREG1,0(&WKAREA)       LOAD WKREG1 WITH PTR TO         05720001
*                                       RPS WORK AREA                   05725001
.SKPREG2 ANOP                                                           05730001
.LIB2PS2 ANOP                                                           05735001
         L     15,28(&RDEB)             PTR TO APPENDAGE VECTOR TABLE   05740001
         MVC   0(20,&WKREG1),0(15)      COPY AVT INTO RPS WORK AREA     05745001
         ST    15,120(&WKREG1)          SAVE PTR TO OLD AVT IN RPS      05750001
*                                       WORK AREA                       05755001
         L     1,16                     PTR TO CVT                      05760001
         L     1,84(1)                  PTR TO SVCLIB DCB               05765001
         AIF   ('&WKAREA'(1,1) EQ '(').GENREG3                          05770001
.*                                      IF REGISTER NOTATION IS USED,   05775001
.*                                      USE OFFSET FROM REGISTER        05780001
.*                                      INSTEAD OF SYMBOLIC NAME.       05785001
         MVC   &WKAREA+4(L'APP&SYSNDX),APP&SYSNDX                       05790001
         AGO   .SKPREG3                                                 05795001
.GENREG3 ANOP                                                           05800001
         MVC   4(L'APP&SYSNDX,&WKAREA),APP&SYSNDX                       05805001
.SKPREG3 ANOP                                                           05810001
*                                       MOVE SIO APPEND NAME TO WKAREA  05815001
         AIF   ('&WKAREA'(1,1) EQ '(').GENREG4                          05820001
         LA    0,&WKAREA+4              POINT REGISTER 0 TO NAME        05825001
         AGO   .SKPREG4                                                 05830001
.GENREG4 ANOP                                                           05835001
         LA    0,4(&WKAREA)             POINT REGISTER 0 TO NAME        05840001
.SKPREG4 ANOP                                                           05845001
*        LOAD  EPLOC=(0),DCB=(1)        LOAD SIO APPENDAGE              05850001
         LOAD  EPLOC=(0),DCB=(1)        LOAD SIO APPENDAGE              05855001
         ST    0,4(&WKREG1)             STORE PTR TO SIO APPENDAGE      05860001
*                                       IN NEW AVT                      05865001
         ST    &WKREG1,28(&RDEB)        STORE PTR TO NEW AVT IN DEB     05870001
         AIF   ('&LIB' EQ 'LIB1').LIB1PS3                               05875001
.*                                      IF OS, BYPASS GENERATING PAGE   05880001
.*                                      FIXING CODE                     05885001
*                                       ON RETURN FROM LOAD, REG 1      05890001
*                                       CONTAINS LENGTH OF MODULE IN    05895001
*                                       DOUBLE WORDS                    05900001
         SLL   1,3                      CONVERT LENGTH TO BYTES         05905001
         AR    1,0                      REG 1 POINTS TO END ADDR OF     05910001
*                                       MODULE PLUS 1                   05915001
         BCTR  1,0                      REG 1 POINTS TO LAST BYTE       05920001
*                                       OF MODULE                       05925001
         LA    0,2048                   SIZE OF PAGE                    05930001
         MVI   4(&WKREG1),X'81'         ASSUME ONLY ONE PAGE            05935001
         NR    0,1                      DOES IT CROSS PAGE BOUNDARY     05940001
         BZ    OUT&SYSNDX               NO, EXIT FROM RPS SETUP         05945001
         MVI   4(&WKREG1),X'82'         INDICATE 2 PAGES NEEDED TO FIX  05950001
*                                       OFFSET OF APPENDAGE ENTRY POINT 05955001
.LIB1PS3 ANOP                                                           05960001
         B     OUT&SYSNDX               EXIT FROM RPS SETUP             05965001
APP&SYSNDX DC  C'IGG019EK'              SIO APPENDAGE NAME              05970001
         AIF   ('&LIB' NE 'LIB1').LIB2PS4                               05975001
.*                                      IF NOT OS, THEN GETMAIN         05980001
.*                                      PARM LIST IS NOT REQUIRED       05985001
GMP&SYSNDX EQU *                                                        05990001
*        GETMAIN EC,SP=252,MF=L         GETMAIN PARAMETER LIST          05995001
         GETMAIN EC,SP=252,MF=L         GETMAIN PARAMETER LIST          06000001
EPM&SYSNDX EQU *-GMP&SYSNDX             LENGTH OF GETMAIN PARM LIST     06005001
.LIB2PS4 ANOP                                                           06010001
OUT&SYSNDX EQU *                                                        06015001
         MEND                                                           06020001
