         MACRO                                                          00020000
         IEEGIFCH &F,&D,&N,&A,&L,&S                                     00040000
         GBLC  &SCHDLR                                                  00060000
         SPACE                                                          00080000
FETCH    EQU   *                                                        00100000
*                       SUCCESSOR DETERMINATOR                          00120000
*                       VERSION 3  5/7/65                               00140000
*  REPLACEABLE SYMBOLS DIRECT APPROPRIATE CODE FOR VARIOUS POSSIBLE     00160000
*  LINKAGE EXITS. IN USE, SYMBOLS ARE INCLUDED FOR EACH POSSIBLE        00180000
*  CONDITION.                                                           00200000
*                                                                       00220000
*   F    FAULT     MESSAGE GENERATION.                                  00240000
*   D    DEFER     PPS DEFERRAL CONDITION.                              00260000
*   N    NAME      USER HAS SUPPLIED NAME OF EXPLICITE SUCCESSOR.       00280000
*   A    AUXILARY  NAME PREVIOUSLY SPECIFIED.                           00300000
*   L    LOCATE    PROCESSING READER SUPPLIED COMMAND.                  00320000
*   S    SOURCE    RETURN TO BASE MODULE.                               00340000
*                                                                       00360000
         SPACE                                                          00380000
.FETCHFA AIF   ('&F' NE 'F').FETCHDA                                    00400000
*                                           IS MESSAGE TO BE ASSEMBLED. 00420000
*                       F    FAULT                                      00440000
         TM    MSERM,F                      TEST FOR ERROR CODE.        00460000
         BZ    *+18                         NO.                         00480000
FETCHF   EQU   *                            FOR DIRECT ENTRANCE.        00500000
         NI    MSFHF,F-MSCSD-MSNMF-MSFAX    KILL FLAGS.                 00520000
         MVC   FHFHP(8),FHFER               LOAD MODULE NAME.           00540000
         B     FETCHG                       TO LINKAGE AFFECTOR.        00560000
.FETCHDA AIF   ('&D' NE 'D').FETCHNA                                    00580000
*                                           SEQUENCE DEFERRED.          00600000
*                       D    DEFER                                      00620000
         TM    MSFHF,MSCSD                  TEST FOR DEFERRAL REQUEST.  00640000
         BZ    *+26                         NO.                         00660000
FETCHD   EQU   *                            FOR DIRECT ENTRANCE.        00680000
         NI    MSFHF,F-MSCSD-MSNMF-MSFAX    KILL FLAGS.                 00700000
         OI    MSPFG,MSCCS                  OPERATOR PENDING ON.        00720000
         MVI   MSERM,MSMSG011               TELL HIM ABOUT REJECTION.   00740000
         MVC   FHFHP(8),FHFER               MODULE NAME.                00760000
         B     FETCHG                       TO LINKAGE AFFECTOR.        00780000
.FETCHNA AIF   ('&N' NE 'N').FETCHAA                                    00800000
*                                           EXPLICITE NAME GIVEN.       00820000
*                       N    NAME                                       00840000
         TM    MSFHF,MSNMF                  TEST FLAG FOR NAME SUPPLIED 00860000
         BZ    *+12                                                     00880000
FETCHN   EQU   *                            FOR DIRECT ENTRANCE.        00900000
         NI    MSFHF,F-MSCSD-MSNMF          KILL FLAGS.                 00920000
         B     FETCHG                       TO LINKAGE AFFECTOR.        00940000
.FETCHAA AIF   ('&A' NE 'A').FETCHLA                                    00960000
*                                           AUXILARY (SECOND SUCCESSOR) 00980000
*                       A    AUXILARY                                   01000000
         TM    MSFHF,MSFAX                  TEST.                       01020000
         BZ    *+18                         NO.                         01040000
FETCHA   EQU   *                            DIRECT ENTRANCE.            01060000
         NI    MSFHF,F-MSCSD-MSNMF-MSFAX    KILL FLAGS.                 01080000
         MVC   FHFHP(8),MSFAL               MODULE NAME FROM RESIDENT.  01100000
         B     FETCHG                       TO LINKAGE AFFECTOR.        01120000
.FETCHLA AIF   ('&L' NE 'L').FETCHSA                                    01140000
*                                           LOCATE PENDING REQUESTS.    01160000
*                       L    LOCATE                                     01180000
         TM    MSFHF,MSTTT                                              01200000
         BZ    *+26                                                     01220000
FETCHL   EQU   *                                                        01240000
         NI    MSFHF,F-MSCSD-MSNMF-MSFAX    KILL FLAGS.                 01260000
         MVC   FHFHP(8),FHFLC                                           01280000
         B     FETCHG                                                   01300000
         AIF   ('&SCHDLR' EQ 'PSS').FETCHL1                             01320000
FHFLC    DC    CL8'IEEG21GM'                PPS AND PSS DEPENDENT.      01340000
         AGO   .FETCHSA                                                 01360000
.FETCHL1 ANOP                                                           01380000
FHFLC    DC    CL8'IEEGA1GM'                LOCATE PSS                  01400000
.FETCHSA AIF   ('&S' NE 'S').FETCHXA                                    01420000
*                                           EXECUTION COMPLETION.       01440000
*                       S    SOURCE                                     01460000
*                                                                       01480000
         AIF   ('&SCHDLR' EQ 'SSS').FETCHSR                             01500000
*                                                                       01520000
FETCHS   EQU   *                                                        01540000
         NI    MSFHF,F-MSCSD-MSNMF-MSFAX                                01560000
         MVC   FHFHP(8),FHSRC                                           01580000
         B     FETCHG                                                   01600000
FHSRC    DC    CL8'IEEFA001'                SOURCE MODULE.              01620000
*                                                                       01640000
         AGO   .FETCHXA                                                 01660000
.FETCHSR ANOP                                                           01680000
         SVC   EXIT                                                     01700000
*                                                                       01720000
.FETCHXA ANOP                                                           01740000
FETCHG   EQU   *                                                        01760000
*                                           ISSUE XCTL.                 01780000
         LA    BASE,FXCTLP                                              01800000
         SVC   XCTL                                                     01820000
XCTL     EQU   7                                                        01840000
*                                                                       01860000
*                            XCTL PARAMETER LIST.                       01880000
FXCTLP   DS    0D                                                       01900000
         DC    A(FHFHP)                     POINTS TO MODULE NAME.      01920000
         DC    F'0'                         DCB ADDRESS=0.              01940000
FHFHP    DC    CL8' '                       NAME ARGUMENT FOR XCTL.     01960000
         AIF   ('&F' NE 'F' AND '&D' NE 'D').FETCHEA                    01980000
         AIF   ('&SCHDLR' NE 'SSS').FETCHE1                             02000000
FHFER    DC    CL8'IEEGK1GM'                MESSAGE GENERATION MODULE.  02020000
         AGO   .FETCHEA                                                 02040000
.FETCHE1 ANOP                                                           02060000
FHFER    DC    CL8'IEEGK2GM'                FAULT PPS-PSS.              02080000
.FETCHEA ANOP                                                           02100000
         MEND                                                           02120000
