* %      GOTO JSWABSL;                                                  00200020
* /*******************************************************************/ 00400020
* /*                                                                 */ 00600020
* /* STATUS --                                                       */ 00800020
* /*    RELEASE 20, MODIFICATION LEVEL 00                            */ 01000020
* /*    LAST MODIFIED ON OCTOBER 6, 1970                            */  01010020
* /*    A 0-999999                                            S20029 */ 01200020
* /*                                                                 */ 01400020
* /* FUNCTION --                                                     */ 01600020
* /*    DEFINE THE JOB SCHEDULING WORK AREA (JSWA) USED BY ROUTINES  */ 01800020
* /*    OF THE JOB SCHEDULING SUBROUTINE                             */ 02000020
* /*                                                                 */ 02200020
* /* ENTRY POINTS --                                                 */ 02400020
* /*         NONE                                                    */ 02600020
* /*                                                                 */ 02800020
* /* INPUT --                                                        */ 03000020
* /*    NONE                                                         */ 03200020
* /*                                                                 */ 03400020
* /* OUTPUT --                                                       */ 03600020
* /*    DATA CONSTANTS (ASSEMBLER) OR DECLARATIONS (BSL) DEFINING    */ 03800020
* /*    THE JSWA                                                     */ 04000020
* /*                                                                 */ 04200020
* /* EXTERNAL REFERENCES --                                          */ 04400020
* /*         NONE                                                    */ 04600020
* /*                                                                 */ 04800020
* /* EXITS, NORMAL --                                                */ 05000020
* /*         NONE                                                    */ 05200020
* /*                                                                 */ 05400020
* /* EXITS, ERROR --                                                 */ 05600020
* /*         NONE                                                    */ 05800020
* /*                                                                 */ 06000020
* /* TABLE/WORK AREAS --                                             */ 06200020
* /*         NONE                                                    */ 06400020
* /*                                                                 */ 06600020
* /* ATTRIBUTES --                                                   */ 06800020
* /*         NOT APPLICABLE                                          */ 07000020
* /*                                                                 */ 07200020
* /* NOTES --                                                        */ 07400020
* /*    NONE                                                         */ 07600020
* /*                                                                 */ 07800020
* /*******************************************************************/ 08000020
* /* START OF SPECIFICATIONS ****                                       08200020
* 1MODULE-NAME = IEFVJSWA                                               08400020
* 1DESCRIPTIVE-NAME = JOB SCHEDULING WORK AREA                          08600020
* 1DESCRIPTION = MAPPING MACRO-INSTRUCTION FOR THE MVT JOB           -  08800020
*             SCHEDULING SUBROUTINE WORK AREA                           09000020
* 1FUNCTION = WORK AREA TO PASS VARIOUS PARAMETERS BETWEEN THE       -  09200020
*             MODULES OF THE MVT JOB SCHEDULING SUBROUTINE              09400020
* 1MODULE-TYPE = TABLE                                                  09600020
*   2PROCESSOR = ASSEMBLER AND BSL                                      09800020
*   2TABLE-SIZE = * BYTES                                               10000020
*   2FIELD = JSWALGTH                                                   10200020
*     3DISPLACEMENT = 0 BYTES                                           10400020
*     3TYPE = ARITHMETIC                                                10600020
*       4MODE = BINARY                                                  10800020
*       4LENGTH = 15 BITS                                               11000020
*       4SCALING = 0                                                    11200020
*       4VALUE = LENGTH OF THE JOB SCHEDULING WORK AREA IN BYTES        11400020
*   2FIELD = JSWAOPT                                                    11600020
*     3DISPLACEMENT = 2 BYTES                                           11800020
*     3TYPE = BIT STRING                                                12000020
*       4BITS-USED = BIT 1                                              12200020
*         5FUNCTION = INDICATE WHETHER A 'TERM=TS' OPERAND IS TO BE  -  12400020
*             PROCESSED OR WHETHER IT IS TO BE IGNORED                  12600020
*         5VALUE = IF THIS BIT IS ON, THE OPERAND IS TO BE           -  12800020
*             PROCESSED.  THE DEFAULT IS TO IGNORE THE OPERAND.         13000020
*       4BITS-USED = BIT 2                                              13200020
*         5FUNCTION = INDICATE WHETHER TRACK STACKING IS TO BE       -  13400020
*             EMPLOYED DURING THE JOB SCHEDULING PROCESS                13600020
*         5VALUE = IF THIS BIT IS ON, TRACK STACKING IS EMPLOYED.    -  13800020
*             THE DEFAULT IS NOT TO USE TRACK STACKING.                 14000020
*       4BITS-USED = BIT 3                                              14200020
*         5FUNCTION = INDICATE WHETHER DEDICATED WORKFILES ARE TO BE -  14400020
*             SUPPORTED                                                 14600020
*         5VALUE = IF THIS BIT IS ON, DEDICATED WORKFILES WILL BE    -  14800020
*             SUPPORTED.  THE DEFAULT IS NOT TO SUPPORT DEDICATED    -  15000020
*             WORKFILES.                                                15200020
*       4BITS-USED = BIT 4                                              15400020
*         5FUNCTION = RESERVED                                          15600020
*         5VALUE = MUST BE ZERO TO PROVIDE COMPATIBILITY WITH LATER  -  15800020
*             EXTENSIONS TO THE JOB SCHEDULING SUBROUTINE.              16000020
*       4BITS-USED = BIT 5                                              16200020
*         5FUNCTION = INDICATE WHETHER THE INVOKER OF THE JOB        -  16400020
*             SCHEDULING SUBROUTINE PROVIDED A PROTECTION KEY TO BE  -  16600020
*             USED IF THE PROGRAM TO BE INVOKED WAS NOT NAMED IN THE -  16800020
*             LINKAGE TABLE.                                            17000020
*         5VALUE = IF THIS BIT IS ON, THE INVOKER OF THE JOB         -  17200020
*             SCHEDULING SUBROUTINE PROVIDED A PROTECTION KEY TO BE  -  17400020
*             USED. THE DEFAULT IS TO ACQUIRE A PROTECTION KEY       -  17600020
*             WITHIN THE INITIATOR SUBROUTINE IF THE PROGRAM(S)      -  17800020
*             NAMED DO NOT APPEAR IN THE LINKAGE TABLE.                 18000020
*       4BITS-USED = BIT 6                                              18200020
*         5FUNCTION = INDICATE WHETHER ALLOCATION RECOVERY SHOULD BE -  18400020
*             ATTEMPTED OR WHETHER A JOB SHOULD BE AUTOMATICALLY     -  18600020
*             FAILED IF ALLOCATION RECOVERY WOULD OTHERWISE BE       -  18800020
*             NECESSARY.                                                19000020
*         5VALUE = IF THIS BIT IS ON, ANY JOB RUN BY THE JOB         -  19200020
*             SCHEDULING SUBROUTINE WILL BE INELIGIBLE FOR           -  19400020
*             ALLOCATION RECOVERY. THE DEFAULT IS TO ALLOW           -  19600020
*             ALLOCATION RECOVERY.                                      19800020
*       4BITS-USED = BIT 7                                              20000020
*         5FUNCTION = INDICATE WHETHER THE JOB(S) RUN BY THE JOB     -  20200020
*             SCHEDULING SUBROUTINE ARE TO BE ELIGIBLE TO WAIT FOR   -  20400020
*             SYSJOBQE SPACE.                                           20600020
*         5VALUE = IF THIS BIT IS ON, THE JOB(S) ARE NOT ELIGIBLE TO -  20800020
*             WAIT FOR SYSJOBQE SPACE.  THE DEFAULT IS THAT JOBS ARE -  21000020
*             ELIGIBLE.                                                 21200020
*       4BITS-USED = BIT 8                                              21400020
*         5FUNCTION = INDICATE WHETHER THE JOB(S) RUN BY THE JOB     -  21600020
*             SCHEDULING SUBROUTINE ARE ELIGIBLE TO WAIT FOR THE     -  21800020
*             AVAILABILITY OF DATA SETS.                                22000020
*         5VALUE = IF THIS BIT IS ON, THE DATA SETS REQUIRED BY A    -  22200020
*             JOB MUST BE IMMEDIATELY AVAILABLE OR THE JOB WILL BE   -  22400020
*             FAILED. THE DEFAULT IS TO ALLOW JOBS TO WAIT FOR THE   -  22600020
*             DATA SETS THEY REQUIRE.                                   22800020
*   2FIELD = JSWASMF                                                    23000020
*     3DISPLACEMENT = 3 BYTES                                           23200020
*     3TYPE = BIT STRING                                                23400020
*       4BITS-USED = BIT 1                                              23600020
*         5FUNCTION = INDICATE WHETHER SMF DATA COLLECTION           -  23800020
*             FACILITIES ARE TO BE ACTIVE DURING JOB SCHEDULING.        24000020
*         5VALUE = IF THIS BIT IS ON, SMF DATA COLLECTION FACILITES  -  24200020
*             WILL BE ACTIVE.  THE DEFAULT IS THAT NO DATA           -  24400020
*             COLLECTION WILL TAKE PLACE.                               24600020
*       4BITS-USED = BIT 2                                              24800020
*         5FUNCTION = INDICATE WHETHER SMF EXIT ROUTINES ARE TO BE   -  25000020
*             ACTIVE DURING JOB SCHEDULING.                             25200020
*         5VALUE = IF THIS BIT IS ON, SMF EXIT ROUTINES WILL BE      -  25400020
*             ACTIVE DURING JOB SCHEDULING. THE DEFAULT IS THAT NO   -  25600020
*             EXIT ROUTINES WILL BE ACTIVE.                             25800020
*       4BITS-USED = BIT 3                                              26000020
*         5FUNCTION = INDICATE HOW TIMING INFORMATION FOR THE JOB IS -  26200020
*             TO BE ACQUIRED, USING TIMER MANAGEMENT OR USING THE    -  26400020
*             TIMING FIELDS OF THE PROTECTED STEP CONTROL BLOCK (PSCB). 26600020
*         5VALUE = IF THIS BIT IS ON, TIMING INFORMATION WILL BE     -  26800020
*             ACQUIRED FROM THE PSCB.  THE DEFAULT IS TO UTILIZE     -  27000020
*             TIMER MANAGEMENT'S FACILITIES.                            27200020
*       4BITS-USED = BITS 4 TO 8                                        27400020
*         5FUNCTION = RESERVED                                          27600020
*         5VALUE = MUST BE ZERO TO ALLOW FOR EXTENSION OF THE JOB    -  27800020
*             SCHEDULING SUBROUTINE                                     28000020
*   2FIELD = JSWAJSEL                                                   28010020
*     3DISPLACEMENT = 4 BYTES                                           28020020
*     3TYPE = ADDRESS/TABLE                                             28030020
*     3TABLE-SIZE = 4 BYTES                                             28040020
*       4FIELD = JSWAOPT2                                               28200020
*         5DISPLACEMENT = 0 BYTES                                       28400020
*         5TYPE = BIT STRING                                            28600020
*           6BITS-USED = BIT 1                                          28800020
*             7FUNCTION = INDICATE WHETHER SYSTEM TASKS ARE PROHIBITED  29000020
*             7VALUE = IF THIS BIT IS ON, SYSTEM TASKS ARE PROHIBITED   29200020
*           6BITS USED = BIT 2                                          29400020
*             7FUNCTION = INDICATE WHETHER SYSTEM TASK CONTROL       -  29600020
*             MESSAGES ARE TO BE SUPPRESSED                             29800020
*             7VALUE = IF THIS BIT IS ON, SYSTEM TASK CONTROL        -  30000020
*             MESSAGES ARE SUPPRESSED                                   30200020
*           6BITS-USED = BIT 3                                          30400020
*             7FUNCTION = INDICATE WHETHER THE WARM START MESSAGE    -  30600020
*             'INIT=JOBNAME' SHOULD BE SUPPRESSED                       30800020
*             7VALUE = IF THIS BIT IS ON, THE MESSAGE IS SUPPRESSED     31000020
*       4FIELD = JSWAJSEL                                               31200020
*         5DISPLACEMENT = 1 BYTE                                        31400020
*         5TYPE = ADDRESS                                               31600020
*           6OF = JOB SCHEDULING ENTRANCE LIST (JSEL)                   31800020
*   2FIELD = JSWAMOD                                                    32000020
*     3DISPLACEMENT = 8 BYTES                                           32200020
*     3TYPE = CHARACTER STRING                                          32400020
*       4LENGTH+MODE = 8 CHARACTERS                                     32600020
*           6VALUE = THE NAME OF THE MODULE TO WHICH THE LAST XCTL   -  32800020
*                  WAS MADE IN THE JOB SCHEDULING SUBROUTINE            33000020
*   2FIELD = JSWATSTK                                                   33200020
*     3DISPLACEMENT = 16 BYTES                                          33400020
*     3TYPE = TABLE                                                     33600020
*       4TABLE-SIZE = 4 BYTES                                           33800020
*       4FIELD = JSWANTRK                                               34000020
*         5DISPLACEMENT = 0 BYTES                                       34200020
*         5TYPE = ARITHMETIC                                            34400020
*           6MODE = BINARY                                              34600020
*           6LENGTH = 8 BITS                                            34800020
*           6SCALING = 0                                                35000020
*       4FIELD = JSWATSTK                                               35400020
*         5DISPLACEMENT = 1 BYTE                                        35600020
*         5TYPE = ADDRESS                                               35800020
*   2FIELD = JSWAPKEY                                                   36000020
*     3DISPLACEMENT = 20 BYTES                                          36200020
*     3TYPE = ARITHMETIC                                                36400020
*       4MODE = BINARY                                                  36600020
*       4LENGTH = 8 BITS                                                36800020
*       4SCALING = 0                                                    37000020
*       4VALUE = THE PROTECTION KEY TO BE USED IF THE PROGRAM(S)     -  37200020
*             INVOKED FOR THIS JOB ARE NOT MENTIONED IN THE LINKAGE  -  37400020
*             TABLE.                                                    37600020
*   2FIELD = JSWATIOT                                                   37800020
*     3DISPLACEMENT = 21 BYTES                                          38000020
*     3TYPE = ADDRESS                                                   38200020
*       4OF = THE TIOT INDICATED IN ITS TCB WHEN THE JOB SCHEDULING  -  38400020
*             SUBROUTINE WAS INVOKED                                    38600020
*   2FIELD = JSWAXCTL                                                   38800020
*     3DISPLACEMENT = 24 BYTES                                          39000020
*     3TYPE = BIT STRING                                                39200020
*       4BITS-USED = BITS 1 TO *                                        39400020
*         5FUNCTION = THE L-FORM OF THE XCTL MACRO-INSTRUCTION IS    -  39600020
*             MOVED TO THIS AREA FOR LINKAGE BETWEEN JOB SCHEDULING  -  39800020
*             MODULES                                                   40000020
*         5VALUE = ESTABLISHED BY THE MAPPING MACRO-INSTRUCTION      -  40200020
*             FOR XCTL                                                  40400020
*                                                                       40600020
**** END OF SPECIFICATIONS ***/                                         40800020
         MACRO                                                          41000020
&NAME    IEFVJSWA  &PREFIX=JSWA,&PLIST=(NOTSTACK,NOWKFILE,RCVRY,QWAIT),*41200020
               &DDTERM=IGNORE,&HIARCHY=0,&ENQ=HAVE,&DCB=,&MODULE=,     *41400020
               &JSEL=0,&JSOL=(SYSTASK,STCMSG,WSMSG) /*                  41600020
         LCLA  &A1,&A2                                                  41800020
         LCLC  &P                                                       42000020
         LCLC  &X0,&X1,&X2,&X3,&X4,&X5,&X6,&X7,&X8,&X9,&XA,&XB,&XC,&XD  42200020
         LCLC  &XE,&XF                                                  42400020
         LCLC  &Y0,&Y1,&Y2,&Y3,&Y4,&Y5,&Y6,&Y7,&Y8,&Y9,&YA,&YB,&YC,&YD  42600020
         LCLC  &YE,&YF                                                  42800020
&NAME    DS    0D           ALIGN JSWA                                  43000020
&P       SETC  '&PREFIX'                                                43200020
&P.LGTH  DC    Y(&P.END-&P) LENGTH OF JSWA                              43400020
         AIF   (T'&DDTERM EQ 'O').JSW0020                               43600020
         AIF   ('&DDTERM' EQ 'IGNORE').JSW0020                          43800020
         AIF   ('&DDTERM' EQ 'TERM').JSW0010                            44000020
         MNOTE *,'INVALID DDTERM OPTION -- &DDTERM -- IGNORED'          44200020
         AGO   .JSW0020                                                 44400020
.JSW0010 ANOP                                                           44600020
&X0      SETC  '+'                                                      44800020
&X1      SETC  '&P.TERM'                                                45000020
.JSW0020 AIF   (N'&PLIST EQ 0).JSW0170                                  45200020
.JSW0030 ANOP                                                           45400020
&A1      SETA  &A1+1                                                    45600020
         AIF   (K'&PLIST(&A1) EQ 4).JSW0050                             45800020
         AIF   (K'&PLIST(&A1) EQ 5).JSW0070                             46000020
         AIF   (K'&PLIST(&A1) EQ 6).JSW0090                             46200020
         AIF   (K'&PLIST(&A1) EQ 7).JSW0120                             46400020
         AIF   (K'&PLIST(&A1) EQ 8).JSW0140                             46600020
.JSW0040 MNOTE *,'PLIST OPERAND &A1 INVALID -- IGNORED'                 46800020
         AGO   .JSW0160                                                 47000020
.JSW0050 AIF   ('&PLIST(&A1)' NE 'QWAIT').JSW0060                       47200020
&XC      SETC  ''                                                       47400020
&XD      SETC  ''                                                       47600020
         AGO   .JSW0160                                                 47800020
.JSW0060 AIF   ('&PLIST(&A1)' NE 'PKEY').JSW0040                        48000020
&X8      SETC  '+'                                                      48200020
&X9      SETC  '&P.PKO'                                                 48400020
         AGO   .JSW0160                                                 48600020
.JSW0070 AIF   ('&PLIST(&A1)' NE 'RCVRY').JSW0080                       48800020
&XA      SETC  ''                                                       49000020
&XB      SETC  ''                                                       49200020
         AGO   .JSW0160                                                 49400020
.JSW0080 AIF   ('&PLIST(&A1)' NE 'QWAIT').JSW0040                       49600020
&XC      SETC  ''                                                       49800020
&XD      SETC  ''                                                       50000020
         AGO   .JSW0160                                                 50200020
.JSW0090 AIF   ('&PLIST(&A1)' NE 'NOPKEY').JSW0100                      50400020
&X8      SETC  ''                                                       50600020
&X9      SETC  ''                                                       50800020
         AGO   .JSW0160                                                 51000020
.JSW0100 AIF   ('&PLIST(&A1)' NE 'TSTACK').JSW0110                      51200020
&X4      SETC  '+'                                                      51400020
&X5      SETC  '&P.TRST'                                                51600020
         AGO   .JSW0160                                                 51800020
.JSW0110 AIF   ('&PLIST(&A1)' NE 'WKFILE').JSW0040                      52000020
&X6      SETC  '+'                                                      52200020
&X7      SETC  '&P.WKFI'                                                52400020
         AGO   .JSW0160                                                 52600020
.JSW0120 AIF   ('&PLIST(&A1)' NE 'NORCVRY').JSW0130                     52800020
&XA      SETC  '+'                                                      53000020
&XB      SETC  '&P.NORC'                                                53200020
         AGO   .JSW0160                                                 53400020
.JSW0130 AIF   ('&PLIST(&A1)' NE 'NOQWAIT').JSW0040                     53600020
&XC      SETC  '+'                                                      53800020
&XD      SETC  '&P.NOQW'                                                54000020
         AGO   .JSW0160                                                 54200020
.JSW0140 AIF   ('&PLIST(&A1)' NE 'NOTSTACK').JSW0150                    54400020
&X2      SETC  ''                                                       54600020
&X3      SETC  ''                                                       54800020
         AGO   .JSW0160                                                 55000020
.JSW0150 AIF   ('&PLIST(&A1)' NE 'NOWKFILE').JSW0040                    55200020
&X4      SETC  ''                                                       55400020
&X5      SETC  ''                                                       55600020
.JSW0160 AIF   (&A1 LT N'&PLIST).JSW0030                                55800020
.JSW0170 AIF   (T'&ENQ EQ 'O').JSW0190                                  56000020
         AIF   ('&ENQ' EQ 'HAVE').JSW0190                               56200020
         AIF   ('&ENQ' NE 'USE').JSW0180                                56400020
&XE      SETC  '+'                                                      56600020
&XF      SETC  '&P.ENQU'                                                56800020
         AGO   .JSW0190                                                 57000020
.JSW0180 MNOTE *,'INVALID ENQ OPTION -- &ENQ -- IGNORED'                57200020
.JSW0190 ANOP                                                           57400020
*        OPTIONS FLAG FIELD                                             57600020
&P.OPT   DC    AL1(0&X0&X1&X2&X3&X4&X5&X6&X7&X8&X9&XA&XB&XC&XD&XE&XF)   57800020
&P.TERM  EQU   B'10000000' PROCESS 'TERM=TS' FLAG                       58000020
&P.TRST  EQU   B'01000000' TRACK STACKING FLAG                          58200020
&P.WKFI  EQU   B'00100000' DEDICATED WORKFILES FLAG                     58400020
*        EQU   B'00010000' RESERVED                                     58600020
&P.PKO   EQU   B'00001000' PROTECT KEY OPTION FLAG                      58800020
&P.NORC  EQU   B'00000100' BY-PASS ALLOCATION RECOVERY FLAG             59000020
&P.NOQW  EQU   B'00000010' NO WAIT FOR QUEUE SPACE FLAG                *59200020
               (CURRENTLY ONLY SUPPORTED BY THE READER/INTERPRETER)     59400020
&P.ENQU  EQU   B'00000001' FLAG TO REQUEST USE OPTION FOR THE INITIATOR*59600020
                   ENQ ON DATA SETS.  IF THE ENQ FAILS, THE JOB IS TO  *59800020
                   BE FAILED.                                           60000020
*        SMF OPTIONS FIELD                                              60200020
&P.SMF   DC    AL1(0)                                                   60400020
         AIF   (N'&JSOL EQ 0).JSW0340                                   60600020
.JSW0250 ANOP                                                           60800020
&A2      SETA  &A2+1                                                    61000020
         AIF   (K'&JSOL(&A2) EQ 5).JSW0270                              61200020
         AIF   (K'&JSOL(&A2) EQ 6).JSW0280                              61400020
         AIF   (K'&JSOL(&A2) EQ 7).JSW0290                              61600020
         AIF   (K'&JSOL(&A2) EQ 8).JSW0310                              61800020
         AIF   (K'&JSOL(&A2) EQ 9).JSW0320                              62000020
.JSW0260 MNOTE *,'JSOL OPERAND &A2 INVALID -- IGNORED'                  62200020
         AGO   .JSW0330                                                 62400020
.JSW0270 AIF   ('&JSOL(&A2)' NE 'WSMSG').JSW0260                        62600020
&Y0      SETC  ''                                                       62800020
&Y1      SETC  ''                                                       63000020
         AGO   .JSW0330                                                 63200020
.JSW0280 AIF   ('&JSOL(&A2)' NE 'STCMSG').JSW0260                       63400020
&Y2      SETC  ''                                                       63600020
&Y3      SETC  ''                                                       63800020
         AGO   .JSW0330                                                 64000020
.JSW0290 AIF   ('&JSOL(&A2)' NE 'SYSTASK').JSW0300                      64200020
&Y4      SETC  ''                                                       64400020
&Y5      SETC  ''                                                       64600020
         AGO   .JSW0330                                                 64800020
.JSW0300 AIF   ('&JSOL(&A2)' NE 'NOWSMSG').JSW0260                      65000020
&Y0      SETC  '+'                                                      65200020
&Y1      SETC  '&P.PSYS'                                                65400020
         AGO   .JSW0330                                                 65600020
.JSW0310 AIF   ('&JSOL(&A2)' NE 'NOSTCMSG').JSW0260                     65800020
&Y2      SETC  '+'                                                      66000020
&Y3      SETC  '&P.SMS1'                                                66200020
         AGO   .JSW0330                                                 66400020
.JSW0320 AIF   ('&JSOL(&A2)' NE 'NOSYSTASK').JSW0260                    66600020
&Y4      SETC  '+'                                                      66800020
&Y5      SETC  '&P.SMS2'                                                67000020
.*       AGO   .JSW0330                                                 67200020
.JSW0330 AIF   (&A2 LT N'&JSOL).JSW0250                                 67400020
.JSW0340 ANOP                                                           67600020
&P.JSEL  DS    A                  COMPOSITE FIELD                       67610020
         ORG   &P.JSEL                                                  67620020
&P.OPT2  DC    AL1(0&Y0&Y1&Y2&Y3&Y4&Y5&Y6&Y7&Y8&Y9&YA&YB&YC&YD&YE&YF)   67800020
&P.PSYS  EQU   B'10000000' PROHIBIT SYSTEM TASK FLAG                    68000020
&P.SMS1  EQU   B'01000000' SUPPRESS SYSTEM TASK CONTROL MESSAGE FLAG    68200020
&P.SMS2  EQU   B'00100000' SUPPRESS 'INIT=JOBNAME' WARM START MESSAGE  *68400020
                           FLAG                                         68410020
*        EQU   B'00010000' RESERVED                                     68600020
*        EQU   B'00001000' RESERVED                                     68800020
*        EQU   B'00000100' RESERVED                                     69000020
*        EQU   B'00000010' RESERVED                                     69200020
*        EQU   B'00000001' RESERVED                                     69400020
&P.JSE1  DC    AL3(&JSEL) POINTER TO THE JOB SCHEDULING ENTRANCE LIST   69600020
&P.MOD   DC    CL8'&MODULE ' NAME OF JOB SCHEDULING MODULE TO WHICH THE*69800020
                   LAST XCTL OR LINK WAS MADE.                          70000020
&P.TSTK  DC    A(0) POINTER TO THE TRACK STACK IF TRACK STACKING HAS   *70200020
                   BEEN SPECIFIED                                       70400020
         ORG   &P.TSTK                                                  70600020
&P.NTRK  DS    AL1                                                      70800020
&P.TKST  DS    AL3                                                      71000020
&P.PKEY  DC    AL1(0) THE PROTECTION KEY TO BE USED IF THE PROGRAM(S)   71200020
*        INVOKED FOR THIS JOB ARE NOT MENTIONED IN THE LINKAGE TABLE    71400020
*        AND IF THE PROTECTION KEY OPTION HAS BEEN SELECTED BY          71600020
*        THE INVOKER OF THE JOB SCHEDULING SUBROUTINE.                  71800020
&P.TIOT  DC    AL3(0)   TIOT ADDRESS FOR THE TIOT POINTED TO BY ITS TCB*72000020
                        WHEN THE JOB SCHEDULING SUBROUTINE GAINED      *72200020
                        CONTROL                                         72400020
&P&SYSNDX XCTL EPLOC=0,HIARCHY=&HIARCHY,DCB=&DCB,SF=L                   72600020
&P.END   EQU   *                                                        72800020
         ORG   &P&SYSNDX                                                73000020
&P.XCTL  DS    CL(&P.END-&P&SYSNDX)                                     73200020
         ORG   &P&SYSNDX                                                73400020
&P.NEL   DS    A(0)      NEL POINTER USED INTERNALLY BY IEEVRCTL        73600020
         ORG   &P.LGTH                                                  73800020
&P       DS    CL(&P.END-&P.LGTH)  JOB SCHEDULING WORK AREA             74000020
         MEND                                                           74200020
**/ %    JSWABSL: ;                                                     74400020
* /******************************************************************** 74600020
*          DEFINE THE JOB SCHEDULING WORK AREA                          74800020
* ********************************************************************/ 75000020
* DECLARE                                                               75200020
* 1       JSWA BASED(JSWAPTR) BOUNDARY(DWORD),                          75400020
*         /************************************************************ 75600020
*               LENGTH FIELD                                            75800020
*         ************************************************************/ 76000020
*         2     JSWALGTH FIXED(15),                                     76200020
*         /************************************************************ 76400020
*               PRIMARY OPTIONS FLAG FIELD                              76600020
*         ************************************************************/ 76800020
*         2     JSWAOPT BIT(8),                                         77000020
*               /* PROCESS 'TERM=TS' FLAG */                            77200020
*               3  JSWATERM BIT(1),                                     77400020
*               /* TRACK STACKING FLAG */                               77600020
*               3  JSWATRST BIT(1),                                     77800020
*               /* DEDICATED WORKFILES FLAG */                          78000020
*               3  JSWAWKFI BIT(1),                                     78200020
*               /* RESERVED */                                          78400020
*               3  * BIT(1),                                            78600020
*               /* PROTECTION KEY OPTION FLAG */                        78800020
*               3  JSWAPKO BIT(1),                                      79000020
*               /* BY-PASS ALLOCATION RECOVERY FLAG */                  79200020
*               3  JSWANORC BIT(1),                                     79400020
*               /* FLAG TO INDICATE WHETHER THE JOB SCHEDULING       */ 79600020
*               /* SUBROUTINE IS TO CANCEL A JOB AUTOMATICALLY       */ 79800020
*               /* RATHER THAN WAITING FOR JOBQ SPACE.               */ 80000020
*               3  JSWANOQW BIT(1),                                     80200020
*               /* FLAG TO INDICATE WHETHER THE JOB SCHEDULING       */ 80400020
*               /* SUBROUTINE IS TO CANCEL A JOB AUTOMATICALLY       */ 80600020
*               /* FOR A DATA SET TO BECOME AVAILABLE FOR THE        */ 80800020
*               /* JOB.                                              */ 81000020
*               3  JSWAENQU BIT(1),                                     81200020
*         /************************************************************ 81400020
*               SMF OPTIONS FLAG FIELD                                  81600020
*         ************************************************************/ 81800020
*         2     JSWASMF BIT(8),                                         82000020
*         /************************************************************ 82010020
*               COMPOSITE FIELD                                         82020020
*         ************************************************************/ 82030020
*         2     JSWAJSEL POINTER(32),                                   82040020
*               /****************************************************** 82200020
*                  SECONDARY OPTIONS FLAG FIELD                         82400020
*               ******************************************************/ 82600020
*               3  JSWAOPT2 BIT(8),                                     82800020
*                  /* PROHIBIT SYSTEM TASK FLAG */                      83000020
*                  4  JSWAPSYS BIT(1),                                  83200020
*                  /* SUPPRESS SYSTEM TASK CONTROL MESSAGE FLAG */      83400020
*                  4  JSWASMS1 BIT(1),                                  83600020
*                  /* SUPPRESS 'INIT=JOBNAME' WARM START MESSAGE */     83800020
*                  4  JSWASMS2 BIT(1),                                  84000020
*                  /* RESERVED */                                       84200020
*                  4  * BIT(5),                                         84400020
*               /****************************************************** 84600020
*                  POINTER TO THE JOB SCHEDULING ENTRANCE LIST          84800020
*               ******************************************************/ 85000020
*               3  JSWAJSE1 POINTER(24),                                85200020
*         /************************************************************ 85400020
*               NAME OF THE JOB SCHEDULING SUBROUTINE MODULE TO WHICH   85600020
*               THE LAST XCTL WAS MADE                                  85800020
*         ************************************************************/ 86000020
*         2     JSWAMOD CHARACTER(8),                                   86200020
*         /************************************************************ 86400020
*               POINTER TO THE TRACK STACK IF TRACK STACKING HAS BEEN   86600020
*               SPECIFIED.                                              86800020
*         ************************************************************/ 87000020
*         2     JSWATSTK POINTER(32),                                   87200020
*               3  JSWANTRK POINTER(8),                                 87400020
*               3  JSWATKST POINTER(24),                                87600020
*         /************************************************************ 87800020
*               THE PROTECTION KEY TO BE USED IF THE PROGRAM(S) INVOKED 88000020
*               FOR THIS JOB ARE NOT MENTIONED IN THE LINKAGE TABLE AND 88200020
*               IF THE PROTECTION KEY OPTION HAS BEEN SELECTED BY THE   88400020
*               INVOKER OF THE JOB SCHEDULING SUBROUTINE.               88600020
*         ************************************************************/ 88800020
*         2     JSWAPKEY POINTER(8),                                    89000020
*         /************************************************************ 89200020
*               POINTER TO THE INPUT TIOT FOR THE JOB SCHEDULING        89400020
*               SUBROUTINE                                              89600020
*         ************************************************************/ 89800020
*         2     JSWATIOT POINTER(24),                                   90000020
*         /************************************************************ 90200020
*               L-FORM OF THE XCTL MACRO-INSTRUCTION -- USED BY THE     90400020
*               MODULES OF THE JOB SCHEDULING SUBROUTINE WHICH USE XCTL 90600020
*               TO PASS CONTROL TO ONE ANOTHER.                         90800020
*         ************************************************************/ 91000020
*         2     JSWAXCTL BIT(64),                                       91200020
*               /* NEL POINTER USED INTERNALLY BY IEEVRCTL   */         91400020
*               3  JSWANEL POINTER(32);                                 91600020
