*%       GOTO JSXLBSL;                                                  00200020
* /*******************************************************************/ 00400020
* /*                                                                 */ 00600020
* /* STATUS --                                                       */ 00800020
* /*    RELEASE 20, MODIFICATION LEVEL 00                            */ 01000020
* /*    A 0-999999                                            S20029 */ 01200020
* /*    C 12000,396000,584000                                  M0759 */ 01350021
* /*    A 584000-585960                                        M0759 */ 01360021
* /*                                                                 */ 01400020
* /* FUNCTION --                                                     */ 01600020
* /*    DEFINE THE JOB SCHEDULING EXIT LIST (JSXL) WHICH SPECIFIES   */ 01800020
* /*    OPTIONAL EXITS TO BE GIVEN CONTROL DURING JOB SCHEDULING     */ 02000020
* /*    SUBROUTINE PROCESSING                                        */ 02200020
* /*                                                                 */ 02400020
* /* ENTRY POINTS --                                                 */ 02600020
* /*         NONE                                                    */ 02800020
* /*                                                                 */ 03000020
* /* INPUT --                                                        */ 03200020
* /*    NONE                                                         */ 03400020
* /*                                                                 */ 03600020
* /* OUTPUT --                                                       */ 03800020
* /*    DATA CONSTANTS (ASSEMBLER) OR DECLARATIONS (BSL) DEFINING    */ 04000020
* /*    THE JSXL                                                     */ 04200020
* /*                                                                 */ 04400020
* /* EXTERNAL REFERENCES --                                          */ 04600020
* /*         NONE                                                    */ 04800020
* /*                                                                 */ 05000020
* /* EXITS, NORMAL --                                                */ 05200020
* /*         NONE                                                    */ 05400020
* /*                                                                 */ 05600020
* /* EXITS, ERROR --                                                 */ 05800020
* /*         NONE                                                    */ 06000020
* /*                                                                 */ 06200020
* /* TABLE/WORK AREAS --                                             */ 06400020
* /*         NONE                                                    */ 06600020
* /*                                                                 */ 06800020
* /* ATTRIBUTES --                                                   */ 07000020
* /*         NOT APPLICABLE                                          */ 07200020
* /*                                                                 */ 07400020
* /* NOTES --                                                        */ 07600020
* /*    NONE                                                         */ 07800020
* /*                                                                 */ 08000020
* /*******************************************************************/ 08200020
* /* START OF SPECIFICATIONS ****                                       08400020
* 1MODULE-NAME = IEFVJSXL                                               08600020
* 1DESCRIPTIVE-NAME = JOB SCHEDULING EXIT LIST                          08800020
* 1DESCRIPTION = VEHICLE FOR SPECIFICATION OF SPECIAL EXIT ROUTINES  -  09000020
*             TO BE INVOKED DURING THE EXECUTION OF THE MVT JOB      -  09200020
*             SCHEDULING SUBROUTINE                                     09400020
* 1FUNCTION = DESCRIBE THE ROUTINES TO WHICH CONTROL IS TO BE GIVEN  -  09600020
*             DURING JOB SCHEDULING SUBROUTINE PROCESSING, THE POINT -  09800020
*             AT WHICH THEY ARE TO BE GIVEN CONTROL, AND THE METHOD  -  10000020
*             OF LINKAGE TO BE USED WHEN PASSING CONTROL TO THEM.    -  10200020
*             PROVIDE A MEANS THROUGH WHICH THE EXIT ROUTINES MAY    -  10400020
*             SHARE A COMMON DATA AREA.                                 10600020
* 1MODULE-TYPE = TABLE                                                  10800020
*   2PROCESSOR = ASSEMBLER AND BSL                                      11000020
*   2TABLE-SIZE = * BYTES                                               11200020
*   2FIELD = JSXLLGTH                                                   11400020
*     3DISPLACEMENT = 0 BYTES                                           11600020
*     3TYPE = ARITHMETIC                                                11800020
*       4MODE = BINARY                                                  12000020
*       4LENGTH = 15 BITS                                               12200020
*       4SCALING = 0                                                    12400020
*       4VALUE = LENGTH OF JSXL                                         12600020
*   2FIELD = JSXLRCOD                                                   12800020
*     3DISPLACEMENT = 2 BYTES                                           13000020
*     3TYPE = ARITHMETIC                                                13200020
*       4MODE = BINARY                                                  13400020
*       4LENGTH = 8 BITS                                                13600020
*       4SCALING = 0                                                    13800020
*       4VALUE = RETURN CODE FROM THE JOB SCHEDULING SUBROUTINE         14000020
*   2FIELD = JSXLRCXT                                                   14200020
*     3DISPLACEMENT = 3 BYTES                                           14400020
*     3TYPE = ARITHMETIC                                                14600020
*       4MODE = BINARY                                                  14800020
*       4LENGTH = 8 BITS                                                15000020
*       4SCALING = 0                                                    15200020
*       4VALUE = CODE INDICATING THE SOURCE OF THE RETURN CODE IN    -  15400020
*       THE JSXLRCOD FIELD. THE VALUES THAT THIS FIELD MAY CURRENTLY -  15600020
*       ASSUME ARE JSXLJSS, JSXLSCAN, JSXLRI, AND JSXLINIT           -  15800020
*       INDICATING THE SOURCE OF THE RETURN CODE TO BE THE JOB       -  16000020
*       SCHEDULING SUBROUTINE ITSELF, IEFVSCAN, THE                  -  16200020
*       READER/INTERPRETER, OR THE INITIATOR RESPECTIVELY.              16400020
*   2FIELD = JSXLCOMM                                                   16600020
*     3DISPLACEMENT = 4 BYTES                                           16800020
*     3TYPE = ADDRESS                                                   17000020
*   2FIELD = JSXLLDEF                                                   17200020
*     3DISPLACEMENT = 8 BYTES                                           17400020
*     3REPLICATION = *                                                  17600020
*     3TYPE = TABLE                                                     17800020
*       4TABLE-SIZE = 8 BYTES                                           18000020
*       4FIELD = JSXLLINK                                               18200020
*         5DISPLACEMENT = 0 BYTES                                       18400020
*         5TYPE = ARITHMETIC                                            18600020
*           6MODE = BINARY                                              18800020
*           6LENGTH = 8 BITS                                            19000020
*           6SCALING = 0                                                19200020
*           6VALUE =    X'00'     -- NO EXIT SPECIFICATION           -  19400020
*                       X'40'     -- BRANCH TO ADDRESS               -  19600020
*                       X'80'     -- LINK TO NAME                    -  19800020
*                       X'C0'     -- XCTL TO NAME                       20000020
*       4FIELD = JSXLID                                                 20200020
*         5DISPLACEMENT = 1 BYTE                                        20400020
*         5TYPE = BIT STRING                                            20600020
*           6BITS-USED = BIT 1                                          20800020
*             7FUNCTION = INDICATE WHETHER THIS EXIT ROUTINE IS TO   -  21000020
*                  BE INVOKED AS A POST-PROCESSING EXIT ROUTINE         21200020
*             7VALUE = IF THIS BIT IS ON, THIS EXIT ROUTINE SHOULD   -  21400020
*                  BE INVOKED AS A POST-PROCESSING EXIT ROUTINE         21600020
*           6BITS-USED = BIT 2                                          21800020
*             7FUNCTION = INDICATE WHETHER THIS EXIT ROUTINE IS TO   -  22000020
*                  BE INVOKED AS A PRE-INVOCATION EXIT ROUTINE          22200020
*             7VALUE = IF THIS BIT IS ON, THIS EXIT ROUTINE SHOULD   -  22400020
*                  BE INVOKED AS A PRE-INVOCATION EXIT ROUTINE          22600020
*           6BITS-USED = BIT 3                                          22800020
*             7FUNCTION = INDICATE WHETHER THIS EXIT ROUTINE IS TO   -  23000020
*                  BE INVOKED AS A POST-PORCESSING EXIT ROUTINE         23200020
*             7VALUE = IF THIS BIT IS ON, THIS EXIT ROUTINE SHOULD   -  23400020
*                  BE INVOKED AS A POST-INVOCATION EXIT ROUTINE         23600020
*           6BITS-USED = BIT 4                                          23800020
*             7FUNCTION = INDICATE WHETHER THIS EXIT ROUTINE IS TO   -  24000020
*                  BE INVOKED AS A SPECIAL ACCESS METHOD FOR         -  24200020
*                  READER/INTERPRETER INPUT                             24400020
*             7VALUE = IF THIS BIT IS ON, THIS EXIT ROUTINE SHOULD   -  24600020
*                  BE INVOKED AS A SPECIAL ACCESS METHOD FOR         -  24800020
*                  READER/INTERPETER INPUT                              25000020
*           6BITS-USED = BIT 5                                          25200020
*             7FUNCTION = INDICATE WHETHER THIS EXIT ROUTINE IS TO   -  25400020
*                  BE INVOKED AS A POST-SCAN EXIT ROUTINE FROM THE   -  25600020
*                  READER/INTERPRETER                                   25800020
*             7VALUE = IF THIS BIT IS ON, THIS EXIT ROUTINE SHOULD   -  26000020
*                  BE INVOKED AS A POST-SCAN EXIT ROUTINE FROM THE   -  26200020
*                  READER/INTERPRETER                                   26400020
*           6BITS-USED = BITS 6 TO 8                                    26600020
*             7FUNCTION = RESERVED                                      26800020
*             7VALUE = SHOULD BE ZERO TO PROVIDE COMPATIBILITY WITH  -  27000020
*                  FUTURE EXTENSIONS OF THE EXIT LIST FACILITY.         27200020
*       4FIELD = JSXLDATA                                               27400020
*         5DISPLACEMENT = 4 BYTES                                       27600020
*         5TYPE = CHARACTER STRING                                      27800020
*           6LENGTH+MODE = 6 CHARACTERS                                 28000020
*           6VALUE = IF THE SPECIFIED LINKAGE IS 'LINK' OR 'XCTL',   -  28200020
*             THEN THE 6-BYTE EBCDIC NAME OF THE ROUTINE TO BE GIVEN -  28400020
*             CONTROL SHOULD BE PLACED IN THIS FIELD, LEFT-JUSTIFIED -  28600020
*             AND PADDED WITH BLANKS IF NECESSARY. IF THE SPECIFIED  -  28800020
*             LINKAGE IS A 'BRANCH', THEN THE ADDRESS OF THE ROUTINE -  29000020
*             TO RECEIVE CONTROL SHOULD BE PLACED IN THIS FIELD, AND -  29200020
*             THE HIGH-ORDER BYTES OF THIS FIELD SHOULD BE SET TO    -  29400020
*             HEXIDECIMAL ZEROS.                                        29600020
*                                                                       29800020
**** END OF SPECIFICATIONS ***/                                         30000020
         MACRO                                                          30200020
&NAME    IEFVJSXL &PREFIX,&COMM /*                                      30400020
         LCLA  &A,&B,&C,&D,&LENJSXL                                     30600020
         LCLB  &POST,&PRINI,&PTINI,&RDRAM,&PTRDR                        30800020
         LCLC  &P,&PL,&LINKAGE,&ROUTINE,&F1,&F2,&F3,&F4,&F5,&F6,&F7,&F8 31000020
         LCLC  &G1,&G2,&G3,&G4,&G5,&G6,&G7,&G8,&COMMUN                  31200020
&NAME    DS    0D                 ALIGN JSXL                            31400020
&LENJSXL SETA  8*N'&SYSLIST-8     COMPUTE LENGTH OF THIS JSXL           31600020
&P       SETC  'JSX'              ASSUME STANDARD PREFIX FOR LABELS     31800020
         AIF   (T'&PREFIX EQ 'O').JSX0010  TEST FOR SUPPLIED PREFIX     32000020
&P       SETC  '&PREFIX'          USE SUPPLIED PREFIX IF PRESENT        32200020
.JSX0010 ANOP                                                           32400020
&PL      SETC  '&P.L'             SET EXTENDED PREFIX                   32600020
&PL      DS    CL&LENJSXL         JOB SCHEDULING EXIT LIST (JSXL)       32800020
         ORG   &PL                                                      33000020
&PL.LGTH DC    AL2(&LENJSXL)      LENGTH                                33200020
&PL.RCOD DC    AL1(0)             RETURN CODE                           33400020
&PL.RNRM    EQU  X'00'               NORMAL COMPLETION                  33450020
&PL.RAUT    EQU  X'04'               UNAUTHORIZED COMBINATION OF       *33500020
                                     PROGRAMS REFERENCED                33550020
&PL.RCXT DC    AL1(0)             RETURN CODE EXTENSION FIELD.          33600020
&PL.JSS  EQU   0                  RETURN CODE FROM JSS MODULE           33800020
&PL.SCAN EQU   1                  RETURN CODE FROM IEFVSCAN             34000020
&PL.RI   EQU   2                  RETURN CODE FROM READER/INTERPRETER   34200020
&PL.INIT EQU   3                  RETURN CODE FROM INITIATOR            34400020
*        EQU   4-255              RESERVED                              34600020
&COMMUN  SETC  '0'                ASSUME STANDARD VALUE FOR            *34800020
                                  COMMUNICATIONS POINTER                35000020
         AIF  (T'&COMM EQ 'O').JSX0020 TEST FOR SUPPLIED COMMUNICATIONS*35200020
                             POINTER                                    35400020
&COMMUN  SETC '&COMM'   USE SUPPLIED COMMUNICATIONS POINTER IF PRESENT  35600020
.JSX0020 ANOP                                                           35800020
&PL.COMM DC   A(&COMMUN)     COMMUNICATIONS POINTER BETWEEN EXIT       *36000020
                             ROUTINES                                   36200020
&PL.LDEF DS   1D             FIRST ELEMENT IN ARRAY OF EXIT DEFINITIONS 36400020
         ORG  &PL.LDEF                                                  36600020
&PL.LINK DS   XL1            LINKAGE INFORMATION                        36800020
&P.LNK   EQU  X'80'          CODE FOR LINKAGE TO NAME                   37000020
&P.XCTL  EQU  X'C0'          CODE FOR XCTL TO NAME                      37200020
&P.BR    EQU  X'40'          CODE FOR BRANCH TO ADDRESS                 37400020
&P.NULL  EQU  X'00'          CODE FOR NO EXIT SPECIFICATION             37600020
&PL.ID   DS   XL1            EXIT IDENTIFICATION                        37800020
&P.POST  EQU  X'80'          CODE FOR JOB SCHEDULING ROUTINE           *38000020
                             POST-PROCESSING EXIT ROUTINE               38200020
&P.PRINI EQU  X'40'          CODE FOR INITIATOR PRE-INVOCATION EXIT    *38400020
                             ROUTINE                                    38600020
&P.PTINI EQU  X'20'          CODE FOR INITIATOR POST-INVOCATION EXIT   *38800020
                             ROUTINE                                    39000020
&P.RDRAM EQU  X'10'          CODE FOR READER/INTERPRETER SPECIAL       *39200020
                             INPUT ACCESS METHOD                        39400020
&P.PTRDR EQU  X'08'          POST SCAN EXIT BIT                   M0759 39600021
*        EQU  X'04'          RESERVED. MUST BE ZERO TO ASSURE           40200020
*                            COMPATIBILITY WITH FUTURE EXTENSIONS       40400020
*                            TO THE EXIT LIST FACILITY.                 40600020
*        EQU  X'02'          RESERVED. MUST BE ZERO TO ASSURE           40800020
*                            COMPATIBILITY WITH FUTURE EXTENSIONS       41000020
*                            TO THE EXIT LIST FACILITY.                 41200020
*        EQU  X'01'          RESERVED. MUST BE ZERO TO ASSURE           41400020
*                            COMPATIBILITY WITH FUTURE EXTENSIONS       41600020
*                            TO THE EXIT LIST FACILITY.                 41800020
&PL.DATA DS   CL6                                                       42000020
.********************************************************************** 42200020
.*       GENERATE AN INITIALIZED EXIT LIST IMAGE IF REQUESTED         * 42400020
.********************************************************************** 42600020
         ORG  &PL.LDEF                                                  42800020
         AIF  (N'&SYSLIST LT 3).J30 BY-PASS INITIALIZATION IF NOT      *43000020
                        REQUESTED                                       43200020
&A       SETA 3         START SCAN AT THE THIRD POSITIONAL OPERAND      43400020
&C       SETA 1         START WITH THE FIRST POSITIONAL SUBOPERAND      43600020
.J1      ANOP                                                           43800020
&LINKAGE SETC '&P.NULL' ASSUME NO LINKAGE HAS BEEN SPECIFIED            44000020
&B       SETA 3                                                         44200020
&D       SETA 1                                                         44400020
&F1      SETC ''                                                        44600020
&F2      SETC ''                                                        44800020
&F3      SETC ''                                                        45000020
&F4      SETC ''                                                        45200020
&F5      SETC ''                                                        45400020
&F6      SETC ''                                                        45600020
&F7      SETC ''                                                        45800020
&F8      SETC ''                                                        46000020
&G1      SETC ''                                                        46200020
&G2      SETC ''                                                        46400020
&G3      SETC ''                                                        46600020
&G4      SETC ''                                                        46800020
&G5      SETC ''                                                        47000020
&G6      SETC ''                                                        47200020
&G7      SETC ''                                                        47400020
&G8      SETC ''                                                        47600020
         AIF  (N'&SYSLIST(&A) LT 1).J6                                  47800020
         AIF  ('&SYSLIST(&A,1)' NE '').J2                               48000020
         AGO  .J6                                                       48200020
.J2      AIF  ('&SYSLIST(&A,1)' NE 'CALL').J3                           48400020
&LINKAGE SETC '&P.BR'                                                   48600020
         AGO  .J6                                                       48800020
.J3      AIF  ('&SYSLIST(&A,1)' NE 'LINK').J4                           49000020
&LINKAGE SETC '&P.LNK'                                                  49200020
         AGO  .J6                                                       49400020
.J4      AIF  ('&SYSLIST(&A,1)' NE 'XCTL').J5                           49600020
&LINKAGE SETC '&P.XCTL'                                                 49800020
         AGO  .J6                                                       50000020
.J5      MNOTE *,'INVALID LINKAGE FOR EXIT(&C) IN LIST'                 50200020
.J6      ANOP                                                           50400020
&P.X&C   DC   AL1(&LINKAGE)       SPECIFY EXIT LINKAGE                  50600020
.J7      AIF  (N'&SYSLIST(&A) LT &B).J25                                50800020
         AIF  ('&SYSLIST(&A,&B)' EQ '').J25                             51000020
         AIF  ('&SYSLIST(&A,&B)' NE 'POST').J9                          51200020
         AIF  (&POST EQ 0).J8                                           51400020
         MNOTE *,'POST-PROCESSING EXIT SPECIFIED BEFORE -- PROBABLE ERR*51600020
               OR'                                                      51800020
.J8      ANOP                                                           52000020
&POST    SETB 1                                                         52200020
&F1      SETC '+'                                                       52400020
&G1      SETC '&P.POST'                                                 52600020
         AGO  .J24                                                      52800020
.J9      AIF  ('&SYSLIST(&A,&B)' NE 'PRINI').J11                        53000020
         AIF  (&PRINI EQ 0).J10                                         53200020
         MNOTE *,'PRE-INVOCATION EXIT SPECIFIED BEFORE -- PROBABLE ERRO*53400020
               R'                                                       53600020
.J10     ANOP                                                           53800020
&PRINI   SETB 1                                                         54000020
&F2      SETC '+'                                                       54200020
&G2      SETC '&P.PRINI'                                                54400020
         AGO  .J24                                                      54600020
.J11     AIF  ('&SYSLIST(&A,&B)' NE 'PTINI').J13                        54800020
         AIF  (&PTINI EQ 0).J12                                         55000020
         MNOTE *,'POST-INVOCATION EXIT SPECIFIED BEFORE -- PROBABLE ERR*55200020
               OR'                                                      55400020
.J12     ANOP                                                           55600020
&PTINI   SETB 1                                                         55800020
&F3      SETC '+'                                                       56000020
&G3      SETC '&P.PTINI'                                                56200020
         AGO  .J24                                                      56400020
.J13     AIF  ('&SYSLIST(&A,&B)' NE 'RDRAM').J15                        56600020
         AIF  (&RDRAM EQ 0).J14                                         56800020
         MNOTE *,'SPECIAL ACCESS METHOD SPECIFIED BEFORE -- PROBABLE ER*57000020
               ROR'                                                     57200020
.J14     ANOP                                                           57400020
&RDRAM   SETB 1                                                         57600020
&F4      SETC '+'                                                       57800020
&G4      SETC '&P.RDRAM'                                                58000020
         AGO  .J24                                                      58200020
.J15     AIF   ('&SYSLIST(&A,&B)' NE 'PTRDR').J17                 M0759 58400021
         AIF   (&PTRDR EQ 0).J16                                  M0759 58450021
.*                                                                M0759 58460021
         MNOTE *,'POST SCAN EXIT SPECIFIED BEFORE--PROBABLE ERROR'      58500021
.J16     ANOP                                                     M0759 58570021
&PTRDR   SETB  1                                                  M0759 58580021
&F5      SETC  '+'                                                M0759 58590021
&G5      SETC  '&P.PTRDR'                                         M0759 58592021
         AGO   .J24                                               M0759 58594021
.J17     ANOP                                                     M0759 58596021
.J23     MNOTE *,'EXIT CODE(&D) INVALID FOR EXIT(&C) IN LIST'           58600020
.J24     ANOP                                                           58800020
&B       SETA &B+1                                                      59000020
&D       SETA &D+1                                                      59200020
         AGO  .J7                                                       59400020
.J25     DC   AL1(0&F1&G1&F2&G2&F3&G3&F4&G4&F5&G5&F6&G6&F7&G7&F8&G8)   *59600020
                             SPECIFY EXIT CODE                          59800020
         AIF  ('&LINKAGE' NE '&P.NULL' AND                             *60000020
               '&LINKAGE' NE '&P.BR').J27                               60200020
&ROUTINE SETC '0'                                                       60400020
         AIF  (N'&SYSLIST(&A) LT 2).J26                                 60600020
         AIF  ('&SYSLIST(&A,2)' EQ '').J26                              60800020
&ROUTINE SETC '&SYSLIST(&A,2)'                                          61000020
.J26     DC   XL2'0000'                                                 61200020
         DC   A(&ROUTINE)    ADDRESS OF EXIT ROUTINE                    61400020
         AGO  .J29                                                      61600020
.J27     ANOP                                                           61800020
&ROUTINE SETC ''                                                        62000020
         AIF  (N'&SYSLIST(&A) LT 2).J28                                 62200020
&ROUTINE SETC '&SYSLIST(&A,2)'                                          62400020
.J28     DC   CL6'&ROUTINE ' NAME OF EXIT ROUTINE                       62600020
.J29     ANOP                                                           62800020
&A       SETA &A+1                                                      63000020
&C       SETA &C+1                                                      63200020
         AIF  (&A LE N'&SYSLIST).J1                                     63400020
.J30     ANOP                                                           63600020
         MEND                                                           63800020
**/ %    JSXLBSL: ;                                                     64000020
* /******************************************************************** 64200020
*         DEFINE THE JOB SCHEDULING EXIT LIST                           64400020
* ********************************************************************/ 64600020
* DECLARE                                                               64800020
* 1       JSXL BASED(JSXLPTR) BOUNDARY(WORD),                           65000020
*         /************************************************************ 65200020
*               LENGTH OF JSXL                                          65400020
*         ************************************************************/ 65600020
*         2     JSXLLGTH FIXED(15),                                     65800020
*         /************************************************************ 66000020
*               RETURN CODE                                             66200020
*         ************************************************************/ 66400020
*         2     JSXLRCOD POINTER(8),                                    66600020
*%     DECLARE                                                          66620020
*      JSXLRNRM FIXED,                                                  66640020
*      JSXLRAUT FIXED;                                                  66660020
*%     /* NORMAL COMPLETION */                                          66680020
*      JSXLRNRM = 0;                                                    66700020
*%     /* UNAUTHORIZED COMBINATION OF PROGRAMS REFERENCED */            66720020
*      JSXLRAUT = 4;                                                    66740020
*         /************************************************************ 66800020
*               RETURN CODE EXTENSION FIELD -- INDICATES ORIGIN OF      67000020
*               RETURN CODE                                             67200020
*         ************************************************************/ 67400020
*         2     JSXLRCXT POINTER(8),                                    67600020
*         /************************************************************ 67800020
*               COMMON POINTER FOR COMMUNICATION BETWEEN EXIT           68000020
*               ROUTINES                                                68200020
*         ************************************************************/ 68400020
*         2     JSXLCOMM POINTER(32),                                   68600020
*         /************************************************************ 68800020
*               ARRAY OF EXIT DEFINITIONS                               69000020
*         ************************************************************/ 69200020
*         2     JSXLLDEF(256),                                          69400020
*               /****************************************************** 69600020
*                  DEFINITION OF LINKAGE TO BE USED -- THE FOLLOWING    69800020
*                  VALUES MAY BE USED IN THIS FIELD:                    70000020
*                  JSXNULL -- NO EXIT SPECIFICATION                     70200020
*                  JSXBR   -- BRANCH TO ADDRESS                         70400020
*                  JSXLNK  -- LINK TO NAME                              70600020
*                  JSXXCTL -- XCTL TO NAME                              70800020
*               ******************************************************/ 71000020
*               3  JSXLLINK POINTER(8),                                 71200020
*               /****************************************************** 71400020
*                  EXIT IDENTIFIER                                      71600020
*               ******************************************************/ 71800020
*               3  JSXLID BIT(8),                                       72000020
*                  /*************************************************** 72200020
*                     POST-PROCESSING EXIT BIT                          72400020
*                  ***************************************************/ 72600020
*                  4  JSXPOST BIT(1),                                   72800020
*                  /*************************************************** 73000020
*                     PRE-INVOCATION EXIT BIT                           73200020
*                  ***************************************************/ 73400020
*                  4  JSXPRINI BIT(1),                                  73600020
*                  /*************************************************** 73800020
*                     POST-INVOCATION EXIT BIT                          74000020
*                  ***************************************************/ 74200020
*                  4  JSXPTINI BIT(1),                                  74400020
*                  /*************************************************** 74600020
*                     SPECIAL ACCESS METHOD BIT                         74800020
*                  ***************************************************/ 75000020
*                  4  JSXRDRAM BIT(1),                                  75200020
*                  /*************************************************** 75400020
*                     POST-SCAN EXIT BIT                                75600020
*                  ***************************************************/ 75800020
*                  4  JSXPTRDR BIT(1),                                  76000020
*                  /*************************************************** 76200020
*                     RESERVED                                          76400020
*                  ***************************************************/ 76600020
*                  4  * BIT(3),                                         76800020
*               /****************************************************** 77000020
*                  LINKAGE DATA -- THE FOLLOWING VALUES MAY BE USED IN  77200020
*                  THIS FIELD:                                          77400020
*                  1. IF THE SPECIFIED LINKAGE IS 'LINK' OR 'XCTL',     77600020
*                     THEN THE 6-BYTE EBCDIC NAME OF THE ROUTINE TO BE  77800020
*                     GIVEN CONTROL SHOULD BE PLACED IN THIS FIELD,     78000020
*                     LEFT-JUSTIFIED AND PADDED WITH BLANKS IF          78200020
*                     NECESSARY.                                        78400020
*                  2. IF THE SPECIFIED LINKAGE IS A 'BRANCH', THEN THE  78600020
*                     ADDRESS OF THE ROUTINE TO RECEIVE CONTROL SHOULD  78800020
*                     BE PLACED IN THIS FIELD, AND THE HIGH-ORDER       79000020
*                     BYTES OF THIS FIELD SHOULD BE SET TO HEXIDECIMAL  79200020
*                     ZEROS.                                            79400020
*               ******************************************************/ 79600020
*               3  JSXLDATA CHARACTER(6);                               79800020
*%        DECLARE   /* JSXLLINK CODE INDICATING XCTL LINKAGE */         80000020
*         JSXXCTL FIXED;                                                80200020
*%        JSXXCTL = 192;                                                80400020
*%        DECLARE  /* JSXLLINK CODE INDICATING LINK LINKAGE */          80600020
*         JSXLNK FIXED;                                                 80800020
*%        JSXLNK = 128;                                                 81000020
*%        DECLARE  /* JSXLLINK CODE INDICATING CALL LINKAGE */          81200020
*         JSXBR FIXED;                                                  81400020
*%        JSXBR = 64;                                                   81600020
*%        DECLARE  /* JSXLLINK CODE INDICATING NO LINKAGE */            81800020
*         JSXNULL FIXED;                                                82000020
*%        JSXNULL = 0;                                                  82200020
*%        DECLARE  /* JSXLRCXT CODE INDICATING JSS RETURN CODE */       82400020
*         JSXLJSS FIXED;                                                82600020
*%        JSXLJSS = 0;                                                  82800020
*%        DECLARE  /* JSXLRCXT CODE INDICATING IEFVSCAN RETURN CODE */  83000020
*         JSXLSCAN FIXED;                                               83200020
*%        JSXLSCAN = 1;                                                 83400020
*%        DECLARE  /* JSXLRCXT CODE INDICATING READER/INTERPRETER    */ 83600020
*         JSXLRI FIXED;  /* CODE                                     */ 83800020
*%        JSXLRI = 2;                                                   84000020
*%        DECLARE  /* JSXLRCXT CODE INDICATING INITIATOR RETURN CODE */ 84200020
*         JSXLINIT FIXED;                                               84400020
*%        JSXLINIT = 3;                                                 84600020
