         MACRO                                                          01000020
&NAME    XLATE &AREA,&LENGTH,&TO=E                                      02000020
.*       THIS MACRO IS DESIGNED TO LOAD REGISTER 0 WITH A BYTE COUNT,   03000020
.*       REGISTER 1 WITH AN ADDRESS OF DATA TO BE TRANSLATED, AND BIT 0 04000020
.*       OF REGISTER 1 IS SET TO INDICATE THE DIRECT OF TRANSLATION.    05000020
.*       AREA ARGUMENT MAY BE (1) NAME OF DATA AREA, (2) ADCON WHICH    06000020
.*       POINTS TO DATA AREA, (3) REGISTER CONTAINING THE ADDRESS OF    07000020
.*       THE DATA AREA. THE LENGTH ARGUMENT MAY (1) NAME OF LOCATION    08000020
.*       CONTAINING BYTE COUNT, (2) REGISTER CONTAINING BYTE COUNT.     09000020
.*       REGISTERS USED AS ARGUMENTS MUST BE IN THE FORM (R), WHERE R   10000020
.*       MAY BE ANY REGISTER NUMBER,2 THRU 12                           11000020
         LCLA  &K                                                       12000020
         AIF   ('&AREA' EQ '&LENGTH').ERR                               13000020
         AIF   (N'&SYSLIST LT 2).ERR1                                   14000020
         AIF   ('&AREA' EQ '(0)' OR '&LENGTH' EQ '(1)').ERR2            15000020
         AIF   ('&TO' EQ 'E').START                                     16000020
         CNOP  0,4                                                      17000020
&K       SETA  &SYSNDX                                                  18000020
&NAME    B     *+8 BRANCH AROUND CONSTANT                               19000020
IHB&K    DC    X'80000000' MASK TO TRANSLATE ASCII                      20000020
.* TEST FOR PROPER NUMBER AND TYPE OF OPERANDS                          21000020
.START   AIF   ('&NAME' EQ '' OR '&TO' NE 'E').REGS                     22000020
&NAME    DS    0H                                                       23000020
.* DETERMINE REGISTER FORMAT                                            24000020
.REGS    AIF   ('&AREA'(1,1) EQ '(').REG1                               25000020
         AIF   (T'&AREA EQ 'A' OR T'&AREA EQ 'F').NOREG1                26000020
         LA    1,&AREA ADDRESS OF TRANSLATE AREA                        27000020
         AGO   .LEN1                                                    28000020
.REG1    AIF   ('&AREA'(2,2) EQ '1)').LEN1                              29000020
         LR    1,&AREA(1) ADDRESS OF TRANSLATE AREA                     30000020
         AGO   .LEN1                                                    31000020
.NOREG1  L     1,&AREA ADDRESS OF TRANSLATE AREA                        32000020
.LEN1    AIF   ('&LENGTH'(1,1) EQ '(').REG2                             33000020
         AIF   (T'&LENGTH EQ 'A' OR T'&LENGTH EQ 'F').REG3              34000020
         AIF   (T'&LENGTH EQ 'H').REG4                                  35000020
         LA    0,&LENGTH LENGTH TO TRANSLATE                            36000020
.CALL    AIF   ('&TO' EQ 'E').SVC                                       37000020
         O     1,IHB&K INDICATE TRANSLATE TO ASCII                      38000020
.SVC     SVC   103 ISSUE TRANSLATE SVC                                  39000020
         AGO   .END                                                     40000020
.REG2    AIF   ('&LENGTH'(2,2) EQ '0)').CALL                            41000020
         LR    0,&LENGTH(1) LENGTH TO TRANSLATE                         42000020
         AGO   .CALL                                                    43000020
.REG3    L     0,&LENGTH LENGTH TO TRANSLATE                            44000020
         AGO   .CALL                                                    45000020
.REG4    LH    0,&LENGTH LENGTH TO TRANSLATE                            46000020
         AGO   .CALL                                                    47000020
.ERR     MNOTE 8,'SPECIFIED REGISTERS ARE EQUAL'                        48000020
         MEXIT                                                          49000020
.ERR1    MNOTE 8,'TOO FEW POSITIONAL PARAMETERS IN MACRO INSTRUCTION'   50000020
         MEXIT                                                          51000020
.ERR2    MNOTE 8,'INVALID REGISTER SPECIFICATION'                       52000020
.END     MEND                                                           53000020
