         MACRO                                                          010000V5
&NAME    IEMKLVE &NORC,&TYPE=,&RC=,&RP=                                 020000V5
.* THIS MACRO GENERATES TYPE 1, 2 OR 3 EXIT LINKAGES. IF                030000V5
.* DEFAULT VALUES FOR THE TYPE ARE PASSED FROM THE LAST IEMKENT MACRO   040000V5
.* BY MEANS OF GLOBAL VARIABLES.                                        050000V5
         GBLB  &GBASAV1                                                 060000V5
         GBLB  &GBALLSW                                                 070000V5
         GBLC  &GCATYPE                                                 080000V5
         LCLB  &LBLLSW                                                  090000V5
         LCLB  &LBERSW                                                  100000V5
         LCLC  &LCTYPE                                                  110000V5
&NAME    DS    0H                                                       120000V5
.* GENERATE CONDITION CODE SETTING CODE                                 130000V5
         AIF   ('&NORC' EQ 'NORC').SS0000                               140000V5
         AIF   (T'&RC EQ 'O').SSZERO                                    150000V5
         IEMKLRG RC,&RC                                                 160000V5
         AGO   .SS0000                                                  170000V5
.SSZERO  SR    RC,RC .                  SET ZERO RETURN CODE            180000V5
.SS0000  ANOP                                                           190000V5
.* GENERATE EXIT LINKAGE CODE                                           200000V5
&LBLLSW  SETB  (&GBALLSW)               SET DEFAULT VALUES              210000V5
&LCTYPE  SETC  '&GCATYPE'                 FOR TYPE                      220000V5
         AIF   (T'&TYPE EQ 'O').SS0002    TEST IF TYPE OMITTED          230000V5
         AIF   (K'&TYPE EQ 1).SS0001                                    240000V5
&LBLLSW  SETB  ('&TYPE'(1,2) EQ 'LL')                                   250000V5
         AIF   (K'&TYPE EQ 2).SS0002                                    260000V5
&LCTYPE  SETC  '&TYPE'(3,1)                                             270000V5
         AGO   .SS0002                                                  280000V5
.SS0001  ANOP                                                           290000V5
&LCTYPE  SETC   '&TYPE'                                                 300000V5
.SS0002  AIF   ('&LCTYPE' EQ '1').SSTYP1  TEST TYPE OF                  310000V5
         AIF   ('&LCTYPE' EQ '2').SSTYP2    LINKAGE TO BE               320000V5
         AIF   ('&LCTYPE' EQ '3').SSTYP3    GENERATED                   330000V5
         AIF   (&LBERSW).SSERRR                                         340000V5
       MNOTE 8,'INVALID TYPE PARAMETER - TYPE OF LAST IEMKAENT ASSUMED' 350000V5
&LBERSW  SETB  1                                                        360000V5
&LBLLSW  SETB  (&GBALLSW)                                               370000V5
&LCTYPE  SETC  '&GCATYPE'                                               380000V5
         AGO   .SS0002                                                  390000V5
.SSERRR MNOTE 12,'TYPE (&LCTYPE,&LBLLSW) STILL IN ERROR - NO GEN.'      400000V5
         MEXIT                                                          410000V5
.* GENERATE TYPE 1 LINKAGE                                              420000V5
.SSTYP1  ANOP                                                           430000V5
         AIF   (&LBLLSW).SS0003                                         440000V5
         L     SAREG,0(0,SAREG) .       RESET SAVE AREA POINTER         450000V5
.SS0003  AIF   (&GBASAV1).SSTYP11                                       460000V5
         LM    GR2,GR9,8(SAREG) . RESTORE GENERAL REGS.                 470000V5
         AGO   .SSTYP12                                                 480000V5
.SSTYP11 LM    PR1,GR9,8(SAREG) .  RESTORE GENERAL REGS.                490000V5
.SSTYP12 ANOP                                                           500000V5
         AIF   (T'&RP EQ 'O').SS0004                                    510000V5
         IEMKLRG RR,&RP                                                 520000V5
         AGO   .SS0005                                                  530000V5
.SS0004  L     RR,4(0,SAREG) .          LOAD RETURN POINT               540000V5
.SS0005  BR    RR .                     EXIT                            550000V5
         AGO   .SSEND                                                   560000V5
.* GENERATE TYPE 2 LINKAGE                                              570000V5
.SSTYP2  ANOP                                                           580000V5
         AIF   (&LBLLSW).SS0006                                         590000V5
         SH    SAREG,*+10 .             RESET SAVE AREA POINTER         600000V5
.SS0006  L     RR,4(0,SAREG) .          LOAD RETURN POINT               610000V5
         BR    RR .                     RETURN                          620000V5
         AIF   (&LBLLSW).SSEND                                          630000V5
         DC    H'4'                                                     640000V5
         AGO   .SSEND                                                   650000V5
.* GENERATE TYPE 3 LINKAGE                                              660000V5
.SSTYP3  ANOP                                                           670000V5
         AIF   (T'&RP EQ 'O').SSEND                                     680000V5
         AIF   ('&RP'(1,1) EQ '(').SSREG                                690000V5
         B     &RP                                                      700000V5
         AGO   .SSEND                                                   710000V5
.SSREG   BR     &RP                                                     720000V5
.SSEND   ANOP                                                           730000V5
         MEND                                                           740000V5
