         MACRO                                                          00200055
&LABEL   IEMKTAB &CODE,&TABID,&AENT,&SA=,&AATO=,&SATO=,&OPT=,          -00400055
               &PTR=,&ETA=,&TRTAB=,&FBTO=,&NTA=,&PSATO=                 00600055
.*                                                                      00800055
.*  THIS MACRO GENERATES LINKAGES TO THE TABLE HANDLING ROUTINES IN     01000055
.*  PHASE KA. THE LINKAGES ARE GENERATED ACCORDING TO PARAMETERS        01200055
.*  SUPPLIED IN THE MACRO-INSTRUCTION TOGETHER WITH INFORMATION         01400055
.*  OBTAINED FROM THE DTCA. THIS INFORMATION IS PASSED FROM THE DTCA    01600055
.*  MACRO TO THE HTAB MACRO BY MEANS OF GLOBAL VARIABLES.               01800055
.*  CHECKS ARE MADE TO ENSURE THAT THE TABLE HANDLING OPERATIONS        02000055
.*  REQUESTED ARE CONSISTENT WITH THE DECLARATIONS IN THE DTCA. THE     02200055
.*  TABLE SPECIFIED BY &TABID IS MATCHED WITH ITS CORRESPONDING DTCA    02400055
.*  BY MEANS OF THE GLOBAL ARRAY &GCAIDS. EACH ELEMENT OF &GCAIDS UP    02600055
.*  TO &GCAIDS(&N) CONTAINS THE TABLE IDENTIFIER FROM THE LABEL FIELD   02800055
.*  OF A DTCA MACRO-INSTRUCTION PREVIOUSLY ENCOUNTERED. (&N CONTAINS    03000055
.*  THE NUMBER OF DTCAS SO FAR ENCOUNTERED). &GCAIDS IS SCANNED TO      03200055
.*  FIND AN ELEMENT MATCHING &TABID. WHEN ONE IS FOUND, THE             03400055
.*  CORRESPONDING ELEMENTS OF THE OTHER GLOBAL ARRAYS CONTAIN THE       03600055
.*  INFORMATION PERTAINING TO THAT TABLE.                               03800055
.*                                                                      04000055
         GBLA  &N                  COUNT OF DTCAS                       04200055
         GBLA  &GAANPTS(15)        NPTRS PARAMETER FROM DTCA            04400055
         GBLB  &GBAETF(15)         BIT ON IF ET=F CODED IN DTCA         04600055
         GBLB  &GBAETV(15)         BIT ON IF ET=V CODED IN DTCA         04800055
         GBLB  &GBAOPSR(15)        BIT ON IF OPS=R CODED IN DTCA        05000055
         GBLB  &GBAOPSS(15)        BIT ON IF OPS=S CODED IN DTCA        05200055
         GBLC  &GCAIDS(15)         TABLE IDENTIFIERS                    05400055
.*                                                                      05600055
         LCLA  &I                                                       05800055
         LCLA  &LAACNT,&LAADSP                                          06000055
         LCLA  &LAADSP2                                                 06100000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB001-TSS 06130019
*        ----------------------------------------------------TAB001-TSS 06160019
         LCLB  &LBATEMP                                                 06200055
.*                                                                      06400055
.*  THE FOLLOWING SECTION PERFORMS AN INITIAL VALIDITY CHECK ON THE     06600055
.*  PARAMETERS, SCANS &GCAIDS FOR AN ELEMENT MATCHING &TABID AND        06800055
.*  SELECTS THE APPROPRIATE SECTION OF THE MACRO DEPENDING ON THE       07000055
.*  OPERATION CODE PARAMETER &CODE.                                     07200055
.*                                                                      07400055
*                                                                       07600055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB002-TSS 07700019
         AIF   (T'&LABEL EQ 'O').SSIC01                                 07800055
&LABEL   DS    0H                                                       08000055
*        ----------------------------------------------------TAB002-TSS 08100019
.SSIC01  ANOP                                                           08200055
&LAACNT  SETA  &LAACNT+1           POINT TO NEXT &TABID SUBLIST ITEM    08400055
         AIF   (T'&CODE NE 'O').SSIC02                                  08600055
         MNOTE 12,'NO OPERATION CODE PARAMETER'                         08800055
*                                                                       09000055
         MEXIT                                                          09200055
.SSIC02  AIF   (T'&TABID NE 'O').SSIC03                                 09400055
         MNOTE 12,'NO TABLE IDENTIFIER'                                 09600055
*                                                                       09800055
         MEXIT                                                          10000055
.SSIC03  ANOP                                                           10200055
&I       SETA  0                   INITIALISE ARRAY SUBSCRIPT           10400055
.SSIC04  AIF   (&I LT &N).SSIC05                                        10600055
         MNOTE 12,'NO DTCA FOR TABLE &TABID(&LAACNT)'                   10800055
*                                                                       11000055
         MEXIT                                                          11200055
.SSIC05  ANOP                                                           11400055
&I       SETA  &I+1                UPDATE SUBSCRIPT                     11600055
         AIF   ('&TABID(&LAACNT)' NE '&GCAIDS(&I)').SSIC04              11800055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB003-TSS 11860019
*        ----------------------------------------------------TAB003-TSS 11920019
         AIF   ((NOT &GBAETF(&I)) AND (NOT &GBAETV(&I))).SSTX01         12000055
         AIF   ('&CODE' EQ 'ULDR').SSFD01                               12200055
         AIF   ('&CODE' EQ 'FREE').SSFD02                               12400055
         AIF   ('&CODE' EQ 'DEACT').SSFD02                              12600055
         AIF   ('&CODE' EQ 'BLDC').SSBD01                               12800055
         AIF   ('&CODE' EQ 'BLDT').SSBD03                               13000055
         AIF   ('&CODE' EQ 'DR').SSDR01                                 13200055
         AIF   ('&CODE' EQ 'SET').SSST01                                13400055
         AIF   ('&CODE' EQ 'SETZ').SSST01                               13600055
         AIF   ('&CODE' EQ 'SCAN').SSSC01                               13800055
         AIF   ('&CODE' EQ 'TEST').SSTS01                               14000055
         MNOTE 12,'INVALID OPERATION CODE'                              14200055
*                                                                       14400055
         MEXIT                                                          14600055
.*                                                                      14800055
.*  THE FOLLOWING SECTION GENERATES CODE FOR TEST                       15000055
.SSTS01  AIF   (T'&NTA NE 'O').SSTS011                                  15200055
         MNOTE 12,'NO NTA PARAMETER SUPPLIED'                           15400055
*                                                                       15600055
         MEXIT                                                          15800055
.SSTS011 ANOP                                                           16000055
&LBATEMP SETB  (T'&AENT EQ 'O' AND T'&SA EQ 'O' AND T'&AATO EQ 'O')     16200055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB004-TSS 16300019
         AIF   (&LBATEMP AND T'&SATO EQ 'O' AND T'&OPT EQ 'O' AND      -16400055
               T'&PTR EQ 'O' AND T'&ETA EQ 'O' AND T'&TRTAB EQ 'O' AND -16600055
               T'&FBTO EQ 'O').SSTS02                                   16800055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        17000055
*        ----------------------------------------------------TAB004-TSS 17100019
.SSTS02  L     PR1,&TABID(&LAACNT)                                      17200055
         TM    4(PR1),X'80'                                             17400055
         AIF   ('&NTA'(1,1) EQ '(').SSTS03                              17600055
         BO    &NTA                                                     17800055
         AGO   .SSEX01                                                  18000055
.SSTS03  BO    0(0,&NTA(1))                                             18200055
         AGO   .SSEX01                                                  18400055
.*                                                                      18600055
.*  THE FOLLOWING SECTION GENERATES CODE FOR ULDR, FREE AND DEACT.      18800055
.*                                                                      19000055
.SSFD01  AIF   (&GBAOPSR(&I)).SSFD02                                    19200055
         MNOTE 12,'DIRECT REFERENCES NOT SPECIFIED IN DTCA OPS PARAM.'  19400055
*                                                                       19600055
         MEXIT                                                          19800055
.SSFD02  ANOP                                                           20000055
&LBATEMP SETB  (T'&FBTO EQ 'O' AND T'&NTA EQ 'O')                       20200055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB005-TSS 20300019
         AIF   (T'&AENT EQ 'O' AND T'&SA EQ 'O' AND T'&AATO EQ 'O' AND -20400055
               T'&SATO EQ 'O' AND T'&OPT EQ 'O' AND T'&PTR EQ 'O' AND  -20600055
               T'&ETA EQ 'O' AND T'&TRTAB EQ 'O' AND &LBATEMP).SSFD03   20800055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        21000055
*        ----------------------------------------------------TAB005-TSS 21100019
.SSFD03  L     PR1,&TABID(&LAACNT)                                      21200055
         AIF   ('&CODE' NE 'ULDR').SSFD04                               21400055
         BAL   RR,KAHUDR                                                21600055
         AGO   .SSFD06                                                  21800055
.SSFD04  AIF   ('&CODE' NE 'FREE').SSFD05                               22000055
         BAL   RR,KAHFRE                                                22200055
         AGO   .SSFD06                                                  22400055
.SSFD05  BAL   RR,KAHDAC                                                22600055
.SSFD06  AIF   (T'&TABID(&LAACNT+1) NE 'O').SSIC01                      22800055
*                                                                       23000055
         MEXIT                                                          23200055
.*                                                                      23400055
.*  THE FOLLOWING SECTION GENERATES CODE FOR BLDC AND BLDT.             23600055
.*                                                                      23800055
.SSBD01  AIF   (T'&AENT NE 'O').SSBD02                                  24000055
         MNOTE 12,'NO ENTRY ADDRESS SUPPLIED FOR BLDC'                  24200055
*                                                                       24400055
         MEXIT                                                          24600055
.SSBD02  IEMKLRG PR0,&AENT                                              24800055
         AGO   .SSBD06                                                  25000055
.SSBD03  AIF   (&GBAETF(&I)).SSBD04                                     25200055
         MNOTE 12,'BLDT ILLEGAL - ET=V IN DTCA'                         25400055
*                                                                       25600055
         MEXIT                                                          25800055
.SSBD04  AIF   (T'&AENT EQ 'O').SSBD05                                  26000055
         MNOTE 8,'ENTRY ADDRESS PARAMETER ILLEGAL FOR BLDT - IGNORED'   26200055
.SSBD05  SR    PR0,PR0                                                  26400055
.SSBD06  L     PR1,&TABID(&LAACNT)                                      26600055
         BAL   RR,KAHBLD                                                26800055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB006-TSS 26900019
         AIF   (T'&SA EQ 'O' AND T'&OPT EQ 'O' AND T'&PTR EQ 'O' AND   -27000055
               T'&ETA EQ 'O' AND T'&TRTAB EQ 'O' AND T'&FBTO EQ 'O'    -27200055
               AND T'&NTA EQ 'O').SSRP01                                27400055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        27600055
*        ----------------------------------------------------TAB006-TSS 27700019
.*                                                                      27800055
.*  THE FOLLOWING SECTION IS USED BY BLDC, BLDT, DR AND SCAN FOR        28000055
.*  GENERATING THE RETURNED PARAMETER HANDLING INSTRUCTIONS             28200055
.*                                                                      28400055
.SSRP01  AIF   (T'&AATO EQ 'O').SSRP03                                  28600055
         AIF   ('&AATO'(1,1) EQ '(').SSRP02                             28800055
         ST    PR0,&AATO                                                29000055
         AGO   .SSRP03                                                  29200055
.SSRP02  ANOP                                                           29400055
         LR    &AATO(1),PR0                                             29600055
.SSRP03  AIF   (T'&SATO EQ 'O').SSEX01                                  29800055
         AIF   ('&SATO'(1,1) EQ '(').SSRP04                             30000055
         MVC   &SATO.(3),0(PR1)                                         30200055
         AGO   .SSEX01                                                  30400055
.SSRP04  ANOP                                                           30600055
         MVC   0(3,&SATO(1)),0(PR1)                                     30800055
.*                                                                      31000055
.*  THE FOLLOWING SECTION IS USED AS AN EXIT ROUTINE BY BLDC, BLDT,     31200055
.*  DR, SET, SETZ AND SCAN. IT CHECKS THAT ONLY ONE TABLE WAS SPECIFIED 31400055
.*  IN THE &TABID PARAMETER AND GENERATES THE FINAL BLANK COMMENTS LINE 31600055
.*                                                                      31800055
.SSEX01  AIF   (N'&TABID EQ 1).SSEX02                                   32000055
         MNOTE 8,'ONLY ONE TABLE MAY BE SPECIFIED FOR &CODE'            32200055
.SSEX02  ANOP                                                           32400055
*                                                                       32600055
         MEXIT                                                          32800055
.*                                                                      33000055
.*  THE FOLLOWING SECTION GENERATES CODE FOR DR.                        33200055
.*                                                                      33400055
.SSDR01  AIF   (&GBAOPSR(&I)).SSDR02                                    33600055
         MNOTE 12,'DIRECT REFERENCES NOT SPECIFIED IN DTCA OPS PARAM.'  33800055
*                                                                       34000055
         MEXIT                                                          34200055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB007-TSS 34300019
.SSDR02  AIF   (T'&AENT EQ 'O' AND T'&PTR EQ 'O' AND T'&ETA EQ 'O' AND -34400055
               T'&TRTAB EQ 'O' AND T'&FBTO EQ 'O' AND T'&NTA EQ 'O'    -34600055
               ).SSDR03                                                 34800055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        35000055
*        ----------------------------------------------------TAB007-TSS 35100019
.SSDR03  AIF   (T'&SA NE 'O').SSDR04                                    35200055
         MNOTE 12,'NO SA PARAMETER'                                     35400055
*                                                                       35600055
         MEXIT                                                          35800055
.SSDR04  IEMKLRG PR0,&SA                                                36000055
         L     PR1,&TABID(&LAACNT)                                      36200055
         AIF   (T'&OPT EQ 'O' OR '&OPT' EQ 'N').SSDR06                  36400055
         AIF   ('&OPT' EQ 'L').SSDR05                                   36600055
         MNOTE 8,'INVALID OPT PARAMETER - OPT=L ASSUMED'                36800055
.SSDR05  OI    36(PR1),X'04'                                            37000055
.SSDR06  BAL   RR,KAHMDR                                                37200055
         AGO   .SSRP01                                                  37400055
.*                                                                      37600055
.*  THE FOLLOWING SECTION GENERATES CODE FOR SET AND SETZ               37800055
.*                                                                      38000055
.SSST01  AIF   (&GBAOPSS(&I)).SSST02                                    38200055
         MNOTE 12,'SEQUENTIAL SCANS NOT SPECIFIED IN DTCA OPS PARAM.'   38400055
*                                                                       38600055
         MEXIT                                                          38800055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB008-TSS 38900019
.SSST02  AIF   (T'&AENT EQ 'O' AND T'&ETA EQ 'O' AND T'&NTA EQ 'O' AND -39000055
               T'&TRTAB EQ 'O' AND T'&FBTO EQ 'O').SSST03               39200055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        39400055
*        ----------------------------------------------------TAB008-TSS 39500019
.SSST03  AIF   (NOT &GBAOPSR(&I)).SSST04                                39600055
&LAADSP  SETA  12                                                       39800055
.SSST04  AIF   (T'&PTR EQ 'O').SSST07                                   40000055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB009-TSS 40100019
         AIF   ('&PTR' EQ '1' OR '&PTR' EQ '2' OR '&PTR' EQ '3' OR     -40200055
               '&PTR' EQ '4').SSST05                                    40400055
         MNOTE 12,'INVALID PTR PARAMETER'                               40600055
*                                                                       40800055
         MEXIT                                                          41000055
*        ----------------------------------------------------TAB009-TSS 41100019
.SSST05  AIF   (&PTR LE &GAANPTS(&I)).SSST06                            41200055
         MNOTE 12,'PTR PARAMETER GREATER THAN DTCA NPTRS PARAMETER'     41400055
*                                                                       41600055
         MEXIT                                                          41800055
.SSST06  ANOP                                                           42000055
&LAADSP  SETA  &LAADSP+12*(&PTR-1)                                      42200055
.SSST07  ANOP                                                           42250001
&LAADSP2 SETA  &LAADSP                                                  42300000
         AIF   ('&CODE' EQ 'SETZ').SSST10                               42400001
         AIF   (T'&OPT EQ 'O').SSST08                                   42600055
         MNOTE 8,'OPT PARAMETER ILLEGAL FOR SET - IGNORED'              42800055
.SSST08  AIF   (T'&SA NE 'O').SSST09                                    43000055
         MNOTE 12,'SA PARAMETER OMITTED'                                43200055
*                                                                       43400055
         MEXIT                                                          43600055
.SSST09  IEMKLRG PR0,&SA                                                43800055
         AGO   .SSST13                                                  44000055
.SSST10  AIF   (T'&OPT EQ 'O' OR '&OPT' EQ 'F' OR '&OPT' EQ 'B').SSST11 44200055
         MNOTE 12,'INVALID OPT PARAMETER'                               44400055
*                                                                       44600055
         MEXIT                                                          44800055
.SSST11  AIF   (NOT('&OPT' EQ 'B' AND &GBAETV(&I))).SSST111             45000055
         MNOTE 12,'OPT=B NOT PERMITTED FOR ET=V'                        45200055
*                                                                       45400055
         MEXIT                                                          45600055
.SSST111 AIF   (T'&SA EQ 'O').SSST12                                    45800055
         MNOTE 8,'SA PARAMETER ILLEGAL FOR SETZ - IGNORED'              46000055
.SSST12  SR    PR0,PR0                                                  46200055
.SSST13  L     PR1,&TABID(&LAACNT)                                      46400055
.SSST14  AIF   (NOT('&CODE' EQ 'SETZ' AND '&OPT' EQ 'B')).SSST15        47000055
&LAADSP  SETA  36+&LAADSP                                               47200055
         OI    &LAADSP.(PR1),X'02'                                      47400055
.SSST15  BAL   RR,KAHSET                                                47600055
         DC    H'&LAADSP2'                                              47700000
         AGO   .SSEX01                                                  47800055
.*                                                                      48000055
.*  THE FOLLOWING SECTION GENERATES CODE FOR SCAN                       48200055
.*                                                                      48400055
.SSSC01  AIF   (&GBAOPSS(&I)).SSSC02                                    48600055
         MNOTE 12,'SEQUENTIAL SCANS NOT SPECIFIED IN DTCA OPS PARAM.'   48800055
*                                                                       49000055
         MEXIT                                                          49200055
.SSSC02  AIF   (T'&OPT EQ 'O' OR '&OPT' EQ 'F' OR '&OPT' EQ 'B').SSSC03 49400055
         MNOTE 12,'INVALID OPT PARAMETER'                               49600055
*                                                                       49800055
         MEXIT                                                          50000055
.SSSC03  AIF   (NOT('&OPT' EQ 'B' AND &GBAETV(&I))).SSSC04              50200055
         MNOTE 12,'OPT=B NOT PERMITTED FOR ET=V'                        50400055
*                                                                       50600055
         MEXIT                                                          50800055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB010-TSS 50900019
.SSSC04  AIF   (T'&PTR EQ 'O' OR '&PTR' EQ '1' OR '&PTR' EQ '2' OR     -51000055
               '&PTR' EQ '3' OR '&PTR' EQ '4').SSSC05                   51200055
         MNOTE 12,'INVALID PTR PARAMETER'                               51400055
*                                                                       51600055
         MEXIT                                                          51800055
*        ----------------------------------------------------TAB010-TSS 51900019
.SSSC05  AIF   (T'&PTR EQ 'O').SSSC06                                   52000055
         AIF   (&PTR LE &GAANPTS(&I)).SSSC06                            52200055
         MNOTE 12,'PTR PARAMETER GREATER THAN DTCA NPTRS PARAMETER'     52400055
*                                                                       52600055
         MEXIT                                                          52800055
.SSSC06  AIF   (T'&TRTAB EQ 'O').SSSC07                                 53000055
         MNOTE 8,'SELECTIVE SCAN ONLY AVAILABLE FOR TEXT TABLES. TRTAB -53200055
               OPERAND IGNORED'                                         53400055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB011-TSS 53500019
.SSSC07  AIF   (T'&AENT EQ 'O' AND T'&SA EQ 'O' AND                    -53600055
               T'&FBTO EQ 'O' AND T'&NTA EQ 'O').SSSC08                 53800055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        54000055
*        ----------------------------------------------------TAB011-TSS 54100019
.SSSC08  AIF   (NOT &GBAOPSR(&I)).SSSC09                                54200055
&LAADSP  SETA  12                                                       54400055
.SSSC09  AIF   (T'&PTR EQ 'O').SSSC10                                   54600055
&LAADSP  SETA  &LAADSP+12*(&PTR-1)                                      54800055
.SSSC10  ANOP                                                           54850001
&LAADSP2 SETA  &LAADSP                                                  54900000
         L     PR1,&TABID(&LAACNT)                                      55200001
.SSSC11  AIF   ('&OPT' NE 'B').SSSC12                                   55600055
&LAADSP  SETA  36+&LAADSP                                               55800055
         OI    &LAADSP.(PR1),X'02'                                      56000055
.SSSC12  BAL   RR,KAHSCN                                                56200055
         DC    H'&LAADSP2'                                              56400000
         AIF   (T'&ETA EQ 'O').SSSC14                                   56600055
         AIF   ('&ETA'(1,1) EQ 'C').SSSC13                              56800055
         B     &ETA                                                     57000055
         AGO   .SSRP01                                                  57200055
.SSSC13  ANOP                                                           57400055
         B     0(0,&ETA(1))                                             57600055
         AGO   .SSRP01                                                  57800055
.SSSC14  B     KAHERR                                                   58000055
         AGO   .SSRP01                                                  58200055
.*                                                                      58400055
.*  THE FOLLOWING SECTION GENERATES LINKAGES TO THE TEXT TABLE          58600055
.*  HANDLING ROUTINE                                                    58800055
.*                                                                      59000055
.SSTX01  AIF   ('&CODE' EQ 'DR').SSTX03                                 59200055
         AIF   ('&CODE' EQ 'SET').SSTX10                                59400055
         AIF   ('&CODE' EQ 'SETZ').SSTX13                               59600055
         AIF   ('&CODE' EQ 'SCAN').SSTX19                               59800055
         AIF   ('&CODE' EQ 'DEACT').SSTX34                              60000055
         AIF   ('&CODE' EQ 'BLDC').SSTX02                               60200055
         AIF   ('&CODE' EQ 'BLDT').SSTX02                               60400055
         AIF   ('&CODE' EQ 'ULDR').SSTX02                               60600055
         AIF   ('&CODE' EQ 'FREE').SSTX02                               60800055
         AIF   ('&CODE' EQ 'TEST').SSTX02                               61000055
         MNOTE 12,'INVALID OPERATION CODE'                              61200055
*                                                                       61400055
         MEXIT                                                          61600055
.SSTX02  MNOTE 12,'&CODE OPERATION NOT PERMITTED FOR ET=T'              61800055
*                                                                       62000055
         MEXIT                                                          62200055
.*                                                                      62400055
.*  GENERATE CODE FOR DR                                                62600055
.*                                                                      62800055
.SSTX03  AIF   (T'&SA NE 'O').SSTX04                                    63000055
         MNOTE 12,'NO SA PARAMETER SUPPLIED'                            63200055
*                                                                       63400055
         MEXIT                                                          63600055
.SSTX04  AIF   (T'&AATO NE 'O').SSTX05                                  63800055
         MNOTE 8,'NO AATO PARAMETER SUPPLIED'                           64000055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB012-TSS 64100019
.SSTX05  AIF   (T'&AENT EQ 'O' AND T'&SATO EQ 'O' AND T'&OPT EQ 'O'    -64200055
               AND T'&PTR EQ 'O' AND T'&ETA EQ 'O' AND T'&TRTAB EQ 'O' -64400055
               AND T'&FBTO EQ 'O').SSTX06                               64600055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        64800055
*        ----------------------------------------------------TAB012-TSS 64900019
.SSTX06  AIF   ('&SA'(1,1) EQ '(').SSTX07                               65000055
         MVC   PAR1+1(3),&SA                                            65200055
         AGO   .SSTX08                                                  65400055
.SSTX07  MVC   PAR1+1(3),0&SA                                           65600055
.SSTX08  MVI   PAR1,X'80'                                               65800055
         L     LR,ZTXTAB                                                66000055
         BALR  RR,LR                                                    66200055
         AIF   (T'&AATO EQ 'O').SSEX01                                  66400055
         AIF   ('&AATO'(1,1) EQ '(').SSTX09                             66600055
         MVC   &AATO.(4),PAR1                                           66800055
         AGO   .SSEX01                                                  67000055
.SSTX09  L     &AATO(1),PAR1                                            67200055
         AGO   .SSEX01                                                  67400055
.*                                                                      67600055
.*  GENERATE CODE FOR SET/SETZ                                          67800055
.*                                                                      68000055
.SSTX10  AIF   (T'&SA NE 'O').SSTX11                                    68200055
         MNOTE 12,'NO SA PARAMETER SUPPLIED'                            68400055
*                                                                       68600055
         MEXIT                                                          68800055
.SSTX11  ANOP                                                           69000000
         IEMKLRG PR0,&SA                                                69600000
         AGO   .SSTX16                                                  70200055
.SSTX13  AIF   (T'&SA EQ 'O').SSTX14                                    70400055
         MNOTE 8,'SA PARAMETER ILLEGAL FOR SETZ - IGNORED'              70600055
.SSTX14  AIF   (T'&OPT EQ 'O').SSTX15                                   70800055
         MNOTE 8,'OPT PARAMETER ILLEGAL FOR ET=T - IGNORED'             71000055
.SSTX15  SR    PR0,PR0                                                  71200000
.SSTX16  AIF   (T'&PTR EQ 'O').SSTX17                                   71400055
         MNOTE 8,'PTR PARAMETER ILLEGAL FOR ET=T - IGNORED'             71600055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB013-TSS 71700019
.SSTX17  AIF   (T'&AENT EQ 'O' AND T'&AATO EQ 'O' AND T'&SATO EQ 'O'   -71800055
               AND T'&ETA EQ 'O' AND T'&TRTAB EQ 'O' AND T'&FBTO EQ    -72000055
               'O' AND(NOT('&CODE' EQ 'SET' AND T'&OPT NE 'O'))).SSTX18 72200055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        72400055
*        ----------------------------------------------------TAB013-TSS 72500019
.SSTX18  ANOP                                                           72600000
         BAL   RR,KAHTST                                                72800000
         AGO   .SSEX01                                                  73000055
.*                                                                      73200055
.SSTX20  AIF   (T'&PTR EQ 'O').SSTX21                                   73400055
.*  GENERATE CODE FOR SCAN                                              73600055
.*                                                                      73800055
.SSTX19  AIF   (T'&OPT EQ 'O').SSTX20                                   74000055
         MNOTE 8,'OPT PARAMETER ILLEGAL FOR ET=T - IGNORED'             74200055
         MNOTE 8,'PTR PARAMETER ILLEGAL FOR ET=T - IGNORED'             74400055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB014-TSS 74500019
.SSTX21  AIF   ((T'&TRTAB EQ 'O' AND T'&FBTO EQ 'O') OR (T'&TRTAB NE   -74600055
               'O' AND T'&FBTO NE 'O')).SSTX22                          74800055
         MNOTE 12,'TRTAB AND FBTO MUST BOTH BE INCLUDED.'               75000055
*                                                                       75200055
         MEXIT                                                          75400055
*        ----------------------------------------------------TAB014-TSS 75500019
.SSTX22  AIF   (T'&AENT EQ 'O' AND T'&SA EQ 'O').SSTX23                 75600055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        75800055
.SSTX23  ANOP                                                           76100000
         AIF   (T'&TRTAB EQ 'O').SSTX24                                 76400000
         IEMKLRG PR0,&TRTAB                                             76700000
         AGO   .SSTX25                                                  77000000
.SSTX24  SR    GR0,GR0                                                  77300000
.SSTX25  BAL   RR,KAHTSC                                                77600000
         AIF   (T'&ETA EQ 'O').SSTX27                                   78000055
         AIF   ('&ETA'(1,1) EQ '(').SSTX26                              78200055
         B     &ETA                                                     78400055
         AGO   .SSTX28                                                  78600055
.SSTX26  B     0(0,&ETA(1))                                             78800055
         AGO   .SSTX28                                                  79000055
.SSTX27  B     KAHERR                                                   79200055
.SSTX28  AIF   (T'&AATO EQ 'O').SSTX30                                  79400055
         AIF   ('&AATO'(1,1) EQ '(').SSTX29                             79600055
         MVC   &AATO.(4),12(PR1)                                        79800055
         AGO   .SSTX30                                                  80000055
.SSTX29  L     &AATO(1),12(PR1)                                         80200055
.SSTX30  AIF   (T'&SATO EQ 'O').SSTX32                                  80400055
         AIF   ('&SATO'(1,1) EQ '(').SSTX31                             80600055
         MVC   &SATO.(3),17(PR1)                                        80800055
         AGO   .SSTX32                                                  81000055
.SSTX31  MVC   0(3,&SATO(1)),17(PR1)                                    81200055
.SSTX32  AIF   (T'&FBTO EQ 'O').SSEX01                                  81400055
         AIF   ('&FBTO'(1,1) EQ '(').SSTX33                             81600055
         STC   PR0,&FBTO                                                81800055
         AGO   .SSTX332                                                 82000055
.SSTX33  LR    &FBTO(1),PR0                                             82200055
.SSTX332 AIF   (T'&PSATO EQ 'O').SSEX01                                 82400055
         AIF   ('&PSATO'(1,1) EQ '(').SSTX334                           82600055
         MVC   &PSATO.(3),21(PR1)                                       82800055
         AGO   .SSEX01                                                  83000055
.SSTX334 MVC   0(3,&PSATO(1)),21(PR1)                                   83200055
         AGO   .SSEX01                                                  83400055
.*                                                                      83600055
.*  GENERATE CODE FOR DEACT                                             83800055
.*                                                                      84000055
.SSTX34  ANOP                                                           84200055
&LBATEMP SETB  (T'&AENT EQ 'O' AND T'&SA EQ 'O' AND T'&AATO EQ 'O')     84400055
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*TAB015-TSS 84500019
         AIF   (&LBATEMP AND T'&SATO EQ 'O' AND T'&OPT EQ 'O' AND      -84600055
               T'&PTR EQ 'O' AND T'&ETA EQ 'O' AND T'&TRTAB EQ 'O' AND -84800055
               T'&FBTO EQ 'O').SSTX35                                   85000055
         MNOTE 8,'SURPLUS PARAMETER(S) SUPPLIED'                        85200055
*        ----------------------------------------------------TAB015-TSS 85300019
.SSTX35  ANOP                                                           85400000
       BAL   RR,KAHTDA                                                  85600000
         AIF   (T'&TABID(&LAACNT+1) NE 'O').SSIC01                      86000055
*                                                                       86200055
         MEND                                                           86400055
