         MACRO                                                          00040015
         IGFASRN1   &MFTASR,&M65MP,&MCSASR                          MCS 00100018
IGFNUC00 CSECT                                                          00160015
         EJECT                                                          00160315
* MACRO NAME.. IGFASRN1  (MCH RESIDENT NUCLEUS)                         00160615
*                                                                       00160915
*                                                                       00161215
* FUNCTIONS...                                                          00161515
*    THE MCH RESIDENT NUCLEUS SERVES AS THE CONTROL PROGRAM FOR THE     00161821
*    TOTAL MCH OPERATION.  ITS MAJOR FUNCTIONS ARE...                   00162115
*    1. RECEIVES CONTROL VIA THE MCK NEW PSW.                           00162415
*    2. DETERMINES TYPE OF ENTRY--NORMAL MCI, MCI IN CCH, CATASTROPHIC  00162715
*       I/O ERROR IN IOS(CCH NOT IN SYSTEM)                             00163015
*    3. SAVE INITIAL CPU OR I/O ENVIRONMENT UPON ENTRY                  00163315
*    4. INITIALIZES COMMUNICATION AND RECORD ENTRY BUILD AREA           00163615
*    5. LOADS MCH MODULES                                               00163915
*    6. PRINTS CONSOLE MESSAGES                                         00164215
*    7. RECOGNIZES AND IGNORES MONITOR CALL INTERRUPTS IN MCH     GTF   00164521
*    8. HANDLES ANY UNEXPECTED ERRORS (E.G. MCI OR PGM INT              00164621
*       IN MCH, I/O PROBLEMS IN MCH)                                    00164815
*    NOTE...A SHORT NARRATIVE IS GIVEN BEFORE EACH ROUTINE IN THIS      00165115
*           LISTING DESCRIBING THE OPERATION OF THE RESPECTIVE ROUTINE  00165415
*                                                                       00165715
*                                                                       00166015
* ATTRIBUTES...                                                         00166315
*     PERMANENTLY RESIDENT, SERIALLY REUSABLE, OPERATES IN SUPERVISOR   00166621
*     MODE, AND USES PRIVILEGED INSTRUCTIONS                            00166721
*                                                                       00167215
*                                                                       00167515
* ENTRY POINTS...                                                       00167815
* IGFN0000--ENTERED VIA MCK NEW PSW. THE ADDRESS OF THIS LABEL IS       00168115
*              CONTAINED IN THE MCK NEW PSW                             00168415
*                                                                       00168715
*                                                                       00169015
* EXITS...                                                              00169315
*    RESIDENT MCH NUC HAS THE FOLLOWING EXITS...                        00169615
*    EXITS TO DISABLED WAIT STATE                                       00169915
*       1. UNEXPECTED MCI OR PGM INTERRUPT IN MCH CODE                  00170215
*    2. CHANNEL PATH TO SYSRES COULD NTO BE CLEARED                     00170515
*    3. 10 RETRYS DURING MODULE LOADING HAVE FAILED                     00170815
*    4. WHEN MCH IS RUN ON OTHER THAN A MODEL 65                        00171115
*    5. WHEN MCH WAS NOT SUCCESSFULLY INITIALIZED BY NIP                00171415
*    EXITS TO LOADED MCH MODULES                                        00171715
*       AFTER EACH MCH MODULE IS SUCCESSFULLY LOADED, MCH NUC GIVES     00172015
*       CONTROL TO THE MODULE AT THE BEGINNING OG THE TRANSIENT AREA    00172315
*                                                                       00172615
*                                                                       00172915
* INPUTS...                                                             00173215
*    THE INPUTS TO MCH NUC CAN BE CLASSIFIED AS...                      00173515
*    1. HARDWARE GENERATED---THIS CONSISTS OF THE FAILING ENVIRONMENT   00173815
*       (GPR'S, FPR'S, CPU OR I/O LOG-OUT AND CONTENTS OF THE PERMANENT 00174115
*       STORAGE ASSIGNMENT(PSA) LOCATIONS 0 TO 128 DECIMAL)             00174415
*    2. SOFTWARE GENERATED                                              00174715
*       A) BBCCHHR OF IGFASR0B IS SUPPLIED BY NIP IN COMDCB             00175015
*       B) SYSRES AND CONSOLE  CHNNL/UNIT ADDR(CUA) AND UNIT TYPE IS    00175315
*          SUPPLIED BY IGFASR0A IN COMSYSRS AND COMCNSL                 00175615
*       C) THE SUCCESSOR MODULE'S TTR IS PASSED IN COMNUC, BY EACH      00175915
*          LOADED MCH MODULE AT ITS COMPLETION (EXCEPT IGFASR0A)        00176215
*                                                                       00176515
*                                                                       00176815
* OUTPUTS...                                                            00177115
*    TO ALL MCH MODULES...                                              00177415
*    1. BASE REG IN GPR 15                                              00177715
*    2. RETURN ADDRESS TO MCH NUC IN GPR 13                             00178015
*    3. ADDR OF COMM AREA IN GPR 12                                     00178315
*    4. ENVIRONMENT OF CPU IN COMM/REC ENTRY BUILD AREA                 00178615
*    TO MODULE IGFASR0A...                                              00178915
*    1. MCH NUC RETURN ADDR FOR SUCCESSFUL CLR CHNNL IN COMNUC          00179215
*    2. MCH NUC RETURN ADDR FOR UNSUCCESSFUL CLR CHNNL IN COMNUC+4      00179515
*    3. BEGINNING ADDR OF I/O INTRPT SAVE QUEUE IN GPR 2                00179815
*                                                                       00180115
*                                                                       00180415
* ENTRY REFERENCES AND V-TYPE ADDRESS CONSTANTS...                      00180715
*    THE FOLLOWING ARE ENTRY REFERENCES AND V-TYPE ADCONS FROM THE MCH  00181015
*    COMM AREA                                                          00181315
*    REFERENCE TYPE COMM AREA TAG    MEANING                            00181615
*    ********* **** *************    ********                           00181915
*                                                                       00182215
*    IGFRES    E    COMRAM           POINTER TO RAM (MFT ONLY)          00182515
*    IGFBLDL   E    COMBLDL          POINTER TO BLDL TABLE              00182815
*    IGFSVBLD  E    COMSVBLD         POINTER TO SVC BLDL TABLE          00182921
*    IGFDCB    E    COMDCB           DCB FOR SYS1.ASRLIB                00183115
*    IGFUNC01  E    IGFNUC01         MBBCCHHR OF NUC REFRESH TABLE      00183415
*    IEACVT    V    COMCVT           POINTER TO CVT                     00183715
*    IEAASNT2  V    COMERXNT         ERROR XSNT AREA(MFT ONLY)          00184015
*    IFBACTA   V    COMCHASG         POINTER TO CHNNL ASSIGNMENT        00184315
*    IEAAXSNT  V    COMTRANS         POINTER TO XSNT AREA NAME (MFT)    00184615
*    IEAERWA   V    COMERIOB         POINTER TO ERROR XSNT AREA (MVT)   00184915
*    IEA0IO01  V    COMNEST          IOS NEST SWTICH 7MVT)              00185215
*    IORGSW    V    COMNEST          IOS NEST SWTICH 7MFT)              00185515
*    IGFSVCQ   E    COMSCCQ          ADDR OF Q OF RES 3,4 SVC'S         00185815
*    IGFMOD    E    COMCVT           MODEL NUMBER OF CPU                00186115
*                                                                       00186415
*                                                                       00186715
* ERROR CONDITIONS...                                                   00187015
*    REFER TO EXITS                                                     00187315
*                                                                       00187615
* TABLES AND WORKAREAS...                                               00187915
*    MCH COMMUNICATION AND RECORD ENTRY BUILD AREAS                     00188215
*                                                                       00188515
*                                                                       00188815
* RESTRICTONS/CONVENTIONS...                                            00189115
*    1. MCH PROGRAM AND ITS CORE STORAGE MAY NOT BE USED BY OS/360 OR   00189415
*       ANY PROBLEM PROGRAM                                             00189715
*    2. MCH SUPPORTS ONLY                                               00190015
*       A) MODEL 65 SIMPLEX                                             00190315
*       B) MFT2/MVT VERSIONS OF OS                                      00190615
*       C) 2311,2314,2301,2303 AS PRIMARY SYSRES DEVICES, CONNECTED BY  00190915
*          WAY OF THE 2680 SELECTOR CHANNEL                             00191215
         EJECT                                                          00191515
         ENTRY IGFN0000                                                 00200015
         ENTRY IGFDCB                                                   00240015
         ENTRY IGFSVCQ                                                  00280015
         ENTRY IGFMOD                                                   00320015
         ENTRY IGFBLDL                                                  00360015
         ENTRY IGFSVBLD                                                 00370021
         ENTRY IGFNUC01                                                 00400015
         AIF   (&MFTASR NE 1).MVT                                       00440015
         ENTRY IGFRES                                                   00480015
.MVT     ANOP                                                           00520015
*                  DUMMY DEB DEFINITION                            MEXT 00523018
IHADEB   DSECT                                                     MEXT 00526018
         DC    F'0'          TCB ADDR                              MEXT 00529018
DEBAMIND DC    12X'0'        NEXT DEB                              MEXT 00532018
DEBNMEXT DC    16X'0'        NO. OF EXTENTS                        MEXT 00535018
DEBDVMOD DC    F'0'          UCB ADDR                              MEXT 00538018
DEBBINUM DC    H'0'          BIN                                   MEXT 00541018
DEBSTRCC DC    H'0'          START CYL                             MEXT 00544018
DEBSTRHH DC    H'0'          START TRACK                           MEXT 00547018
DEBENDCC DC    H'0'          END CYL                               MEXT 00550018
DEBENDHH DC    H'0'          END TRACK                             MEXT 00553018
DEBNMTRK DC    H'0'          NO. OF TT'S FOR THIS EXTENT           MEXT 00556018
         USING CVTDSECT,CVTREG                                          00560015
CVTDSECT DSECT                                                          00600015
         CVT                                                            00640015
         AIF   (&M65MP NE 1).NMP9                                    MP 00650017
         IEAQFX     65,MCH,1,GENCODE=NO                              MP 00660017
.NMP9    ANOP                                                        MP 00670017
IGFNUC00 CSECT                                                          00680015
         EJECT                                                          00720015
****************  INITIAL ENTRY POINT INTO MCH NUCLEUS  *************** 00760021
*                                                                     * 00800015
* ENTER HERE ON THE OCCURRENCE OF A MCK VIA THE MCK NEW PSW           * 00840015
* POSSIBLE TYPES OF ENTRY INTO ASRNUC ARE...                          * 00880015
* 1. MCI OCCURRING IN THE CHANNEL CHECK HANDLER (CCH). BYTE 115 WILL  * 00920015
*    CONTAIN X'01' IF THIS OCCURS.                                    * 00960015
* 2. CATASTROPHIC I/O ERROR (ICC,CCC OR CDC) OCCURRING IN IOS AND CCH * 01000015
*    IS NOT IN THE SYSTEM. BYTE 50 WILL CONTAIN X'FF' IF THIS OCCURS. * 01040015
* 3. LEGITIMATE MCI. BYTES 115 AND 50 WILL CONTAIN X'00'.             * 01080015
* INITIAL RUNNING STATE IS DISABLED FORALL INTERRUPTS                 * 01120015
*                                                                     * 01160015
*********************************************************************** 01200015
         SPACE 3                                                        01240015
         USING *,BRNUC                                                  01280015
         AIF   (&MCSASR NE 0).NMCS13                                MCS 01290018
         USING *+2048,BRMOD                                             01300018
.NMCS13  ANOP                                                       MCS 01310018
         AIF   (&MCSASR NE 1).NMCS1                                 MCS 01320018
         USING *+2448,BRMOD                                         MCS 01330018
.NMCS1   ANOP                                                       MCS 01340018
IGFN0000 DS    0H                                                       01400015
         ST  WKR14,X'170'          SAVE GR14 IN LOW CORE                01440015
         AIF   (&M65MP NE 1).NMP7                                    MP 01450017
         L     BRNUC,EDSMCH        SET NUC BASE FROM PREFIX POINTER  MP 01460017
         AGO   .NMP8                                                 MP 01470017
.NMP7    ANOP                                                        MP 01480017
         L     BRNUC,116           SET NUC BASE FROM MCK NEW PSW     MP 01490017
.NMP8    ANOP                                                        MP 01500017
         AIF   (&M65MP NE 0).NU67                                       01502020
         B     AROUND                  TO SKIP THE NEXT CONSTANT   M67  01504020
         SPACE 3                                                        01506020
**     THIS CONSTANT MUST BE AT THIS LOCATED FOR THE               M67  01508020
****              MODEL 67 INSTRUCTION STMC.                            01510020
MOD67    DC    D'0'                     WORK AREA FOR 67 TESTING   M67  01512020
         SPACE 3                                                        01514020
AROUND   EQU   *                                                   M67  01516020
.NU67    ANOP                                                      M67  01518020
         ST    BRNUC,NBASESV       SAVE NUC BASE REG IN LOWER CORE      01520015
         MVC   NSVCKSUM(1),CKSUMLOC     SAVE CHK SUM BIT                01560015
         NI    CKSUMLOC,X'BF'      CLEAR CHK SUM BIT IN LOG-OUT         01600015
         ST    WKR15,X'174'        SAVE GR15 IN LOW CORE                01640015
         L     BRMOD,NMODBASE      SET MODULE BASE REG                  01680015
         OI    NSWITCH,X'80'       SET ASRNUC IN CONTROL BIT            01760015
         OI    COMCNSL+3,X'80'     SET CNSL CUA NOT YET FOUND           01800015
         SPACE 2                                                        01840015
*                                                                       01960015
* BEGIN  SAVING ENVIRONMENT OF THE CPU INTO THE RECORD ENTRY IMAGE      02000015
* SAVE AREA AND THE MODULE COMMUNICATIONS AREA                          02040015
*                                                                       02080015
NSVENV   MVC   COMPSA(PSASIZE),PSABEGIN      SAVE PSA                   02120015
         MVC   RECPULOG(LOGSIZE),LOGBEGIN    SAVE CPU LOG OUT           02160015
         MVC   RECPULOG+38(1),NSVCKSUM  SAVE ORIG CHK SUM BIT           02200015
         STM   0,13,REGSGPR        SAVE GPR'S 0-13                      02240015
         MVC   REGSGPR+56(8),X'170'     SAVE GR14 AND 15                02300015
         STD   0,REGSFPR           SAVE                                 02360015
         STD   2,REGSFPR+8              FLOAT                           02400015
         STD   4,REGSFPR+16                  POINT                      02440015
         STD   6,REGSFPR+24                       REGS                  02480015
         SPACE 4                                                        02482021
         AIF    (&MCSASR NE 1).NOMCS                          IE  50588 02490021
         XC    MSCCWADR(D14),MSCCWADR   ZERO CCW ADDR AREA    IE  50588 02500021
.NOMCS   ANOP                                                           02510021
         XC   COMLEV0A(N16),COMLEV0A CLEAR LEVEL INDS + COMMSF   M67    02512021
         AIF   (&M65MP NE 0).NMPVD9                               M67   02514021
         CLI   50,X'FF'            CATASTROPHIC CHANNEL ERROR  @S67856P 02516021
         BE    CPUID               YES                         @S67856P 02518021
         TM    LOG4,X3                  TEST EXT MASK PARITY BITS  M67  02520620
         BNO   CPUID                    NOT A 67                   M67  02520820
*                                       YES,IT IS A 67             M67  02521020
         DC    X'B089E010'             STMC INST. FOR M67 TEST     M67  02521220
         XC    NABSADR(N8),NABSADR      CLEAR COMPARE AREA         M67  02521420
         CLC   MOD67(N8),NABSADR        ARE REGS 8-9 ZEROS         M67  02521620
         BE    MOD671                   YES,MOD67-1                M67  02521820
         TM    X32,X80                  IS IT EXTERNAL MACH CHECK  M67  02522020
         BZ    SKIPNEXT                 NO                         M67  02522220
         LPSW  48                       YES-RETURN TO SYSTEM       M67  02522420
SKIPNEXT EQU   *                                                   M67  02522620
         OI    COMMSF,X20               SET MOD 67-2 BIT           M67  02522820
         B     NCPUIDIN                 CONTINUE                   M67  02523020
MOD671   EQU   *                                                   M67  02523220
         OI    COMMSF,X40               SET MOD 67-1 BIT           M67  02523420
         B     NCPUIDIN                 CONTINUE                   M67  02523620
CPUID    EQU   *                                                   M67  02523820
.NMPVD9  ANOP                                                      M67  02524020
* PLACE CPU ID NUMBER IN CPU ID PRINT FIELD                        MP1  02526018
*                                                                  MP1  02529018
         TM    LOGVD,TWOVD        CPU ID 2                         MP1  02532018
         BO    NCNSL06            YES BRANCH                       MP1  02535018
         TM    LOGJE,VDOCT   CPU ID 1                              MP1  02538018
       BZ      NCPUIDIN                APAR 26973                       02541019
         MVI   NIDBUF1,X'F1'      MOVE CPU ID 1                    MP1  02544018
       B       NCPUIDIN                APAR 26973                       02547019
NCNSL06  MVI   NIDBUF1,X'F2'      MOVE CPU ID 2                    MP1  02550018
NCPUIDIN EQU   *                       APAR 26973                       02551019
         SPACE 3                                                        02553018
         CLI   COMBLDL,X'FF'       ASR SUCCESSFULLY INITIALIZED         02560015
         BC    NOTEQ,NIBAD0        NO                                   02600015
         CLI   50,X'FF'            TEST FOR CAT ENTRY FROM IOS          02602018
SIGNAL   EQU   *-3                 DATA FOR SYSTEM CAL OPERATION     MP 02604018
         BC    EQ,NIOSCAT0         BR IF YES                            02606018
         L     CVTREG,COMCVT       SET CVT BASE REG                     02610019
         LA    CVTREG,N0(CVTREG)                                        02612019
         SH    CVTREG,VALUE6       SET DISP. FOR MOD ID                 02614021
         CLC   N0(N2,CVTREG),MOD65  MODEL 65                  IE  21961 02616021
         L     CVTREG,COMCVT       RESET CVT REG                        02618019
         BNE   NNOT65                    NO-NOT 65                      02668000
* CLEAR ANY PENDING MCI THAT MAY HAVE OCCURRED AS A RESULT OF THE       02680015
* PREVIOUS ENVIRONMENT SAVING OPERATION                                 02720015
         SPACE 1                                                        02760015
NU0004   EQU   *                                                        02800015
         MVI   PGMOPSW+X03,X0      ERASE PRIOR MONIT. CALL INT CODE-GTF 02810021
         MVC   112(8),NMKENAB      SET NEW MCK PSW-ENABLED ONLY FOR MCI 02840015
         LPSW  NMKENAB             ENABLE MCI'S--GO TO NEXT SEQ INSTR   02880015
NU0001   MVC   112(8),NMKEXPSW     SET NEW MCK PSW-POINTS TO EMGY EXIT  02920015
         MVC    104(8),NPGMPSW     SET PGM NEW PSW--ASRNUC WILL HANDLE  02960015
*                                  PGM INTERRUPTS IN ASR CODE--PRINT    03000015
*                                  ERROR MSG AND GO  INTO WAIT STATE    03040015
*                                  ENABLED FOR MCI'S              GTF   03050021
         SPACE 3                                                        03080021
******************  INITIALIZATION FOR MCH MODULES  ******************* 03120021
         SPACE 1                                                        03160015
NU0003   EQU   *                                                        03200015
         L     WKR12,NCOMAREA      SET GR12 TO BEGINNING OF COMM AREA   03240015
         L     CVTREG,COMCVT       ADDR OF COMM VECTOR TABLE            03280015
         XC    COMNUC(16),COMNUC   CLEAR COMNUC AREA                    03320015
         SPACE 1                                                        03360015
* ACCESS THE STARTING CCHH OF SYS1.SVCLIB (MCH MODULES EXIST IN THIS    03400021
* DATA SET). THIS CCHH IS USED IN THE RELATIVE TO ABSOLUTE TRACK        03440015
* CONVERSION ROUTINE.                                                   03480015
         SPACE 1                                                        03520015
         L     WKR3,CVTSVDCB       ADDR OF SYS1.SVCLIB DCB              03560015
         LA    WKR3,44(WKR3)       DCB+44 IS POINTER TO DEB             03600015
         L     WKR3,0(WKR3)        GET DEB POINTER                      03640015
         LA    WKR3,38(WKR3)       DEB+38 IS STARTING CCHH OF SVCLIB    03680015
         MVC   NABSADR+2(4),0(WKR3)     SAVE THIS CCHH                  03720015
         MVI   COMMSG0,X5C         MOVE * TO WAIT OUTPUT BUFFER     MCS 03730018
         MVC   COMMSG1+X1(X9),NIDBUF  MOVE CPU ID TO OUTPUT BUFFER  MCS 03740018
         LA    WKR3,WTOBUF         ADDR OF WTO BUFFER               MCS 03750018
         ST    WKR3,COMMSG1+D12    STARTING POINT OF WTO BUFFER     MCS 03760018
         ST    WKR3,COMPRNT         IN ASR COMMUNICATION AREA           03800015
         LA    WKR3,OBREXIT      GET ADDRESS OF OBR EXIT RTN            03840015
         ST    WKR3,COMOBREX     STORE IN COMMUNICATIONS AREA FOR USE   03880015
*                                   BY THE ERROR RECORDER MODULE        03920015
         MVC   COMNUC+4(4),NADCLEME     SET EMGY EXIT IN COMM AREA      03960015
         XC    NSAVEIO(200),NSAVEIO     ZERO I/O INTRPT SAVE QUEUE      04000015
         AIF   (&M65MP NE 1).NMPVD                                 MEXT 04006018
         SR    WKR2,WKR2          CLEAR LOCATION 4 IN MP SYSTEMS   MEXT 04012018
         ST    WKR2,X4            TO PREVENT FURTHER BRANCHING     MEXT 04018018
***                           AFTER GOING TO LOCATION 0            MEXT 04024018
.NMPVD   ANOP                                                      MEXT 04030018
         LA    WKR2,NSAVEIO        ADDR OF I/O INTRPT SAVE QUEUE        04040015
         ST    WKR2,COMIOQ         SAVE IT IN COMMUNICATION AREA        04080015
         MVC   COMNUC(4),NADPTHCL  SET PATH CLEAR EXIT IN COMM AREA     04120015
N16      EQU    16                                                 2K   04128018
         AIF   (&M65MP NE 1).NMP12                                   MP 04132017
         MVC   COMMSF(1),CPUSTAT        MOVE IN CPUSTAT INFO         MP 04138017
         NI    COMMSF,SOLID            CLEAR SOLID INDICATOR       2K   04140018
SOLID    EQU   X'FB'             MASK OUT SOLID STG IND.           2K   04142018
         OI    COMMSF,X'10'             SET MULTIPROCESSOR INDICATOR MP 04144017
.NMP12   ANOP                                                        MP 04150017
         CLI   RETYPE,C'I'         IS THIS CAT ENTRY                    04160015
         BC    8,NIOSCAT1          YES                                  04200015
         XC    CTFLDID(256),CTFLDID     CLEAR SELECTED                  04240015
         XC    ISUMBAD+2(2),ISUMBAD+2    FIELDS IN                      04280015
         XC    REGPARGP(16),REGPARGP     RE BUILD AREA                  04320015
         TM    CKSUMLOC,CKSUMBIT   IS CHECK SUM BIT ON                  04360015
         BC    ON,NCKSUM1          YES                                  04400015
NU0005   EQU   *                                                        04440015
         MVI   RETYPE,C'C'         SET RE TYPE TO MCK TYPE              04480015
         BC    15,4(BRMOD)         GO TO CLR CHNNL MODULE               04520015
         SPACE 2                                                        04560015
NIOSCAT0 EQU   *                                                        04600015
         AIF   (&M65MP NE 1).NMP6                                    MP 04604017
         TM    CPUSTAT,3           CHECK RECONFIGURED OR PARTITIONED MP 04608017
         BNZ   NIOSCAT2            GO IF EITHER CASE                 MP 04612017
         OI    STMASK,MASK         SET MASK IN PREFIX AREA           MP 04616017
MASK     EQU   X'90'               ACTION MASK                       MP 04620017
         WRD   SIGNAL,X'10'        SIGNAL                            MP 04624017
NIOSCAT2 EQU   *                                                     MP 04628017
.NMP6    ANOP                                                        MP 04632017
         MVI   RETYPE,C'I'         SET RE TYPE TO CHANNEL (CAT) TYPE    04640015
         MVC   REIOLOG(IOLOGSIZ),IOLOGBEG    MOVE I/O LOG TO RE         04680015
         BC    15,NU0004                                                04720015
         SPACE 1                                                        04760015
NIOSCAT1 XC    RECTLIND(70),RECTLIND    CLEAR INB REC IMAGE AREA        04800015
         MVC   RECSW(8),64         MOVE CSW TO RE AREA                  04840015
         MVC   RECUA(2),58         MOVE CUA INTO RECORD ENTRY AREA      04880015
         BC    15,4(BRMOD)         GO CLR CHNNL                         04920015
         SPACE 3                                                        04960015
NIBAD0   EQU   *                                                        05000015
         LA    WKR0,X'A0E'         GET WAIT STATE CODE                  05080015
         MVC   COMMSG0+X1(D16),NNIPMSG   MOVE MSG TO BUFFER         MCS 05100018
         B     STANDAIO                                             MCS 05120018
*                                                                       05160015
NNOT65   EQU   *                                                    MCS 05200018
         LA    WKR0,X'A0D'         GET WAIT STATE CODE                  05240015
         MVC   COMMSG0+X1(D16),N65MSG    MOVE MSG TO BUFFER         MCS 05260018
         B     STANDAIO                                             MCS 05280018
         SPACE 1                                                        05320015
NCKSUM1  MVI   REENVCHK,X'FF'      SET INDICATOR FOR IGFASR0B           05360015
         BC    15,NU0005           CONTINUE                             05400015
         EJECT                                                          05440015
***************  M O D U L E   S C H E D U L I N G  ******************* 05480015
*********************************************************************** 05520015
*                                                                     * 05560015
*                                                                     * 05600015
* THIS ROUTINE PROVIDES THE INITIAL SETUP FOR CALLING THE ENVIRONMENT * 05640015
* CHECKER MODULE, AND SUBSEQUENTLY FOR CALLING THOSE ASR MODULES NEED-* 05680015
* ED TO PERFORM THE RECOVERY FUNCTIONS FOR THE CURRENT ERROR.         * 05720015
* ALL ASR MODULES WILL RETURN CONTROL TO THIS ROUTINE AT 'NMODRTRN'   * 05760015
* THIS ROUTINE THEN ACCESSES THE NEXT MODULES ID AND TTR FROM THE COM-* 05800015
* MUNICATION AREA (PUT THERE BY THE PREVIOUS RUN MODULE). THE TTR IS  * 05840015
* CONVERTED TO MBBCCHHR (RELATIVE TO ABSOLUTE) AND PLACED IN THE SEEK/* 05880015
* SEARCH ARGUEMENT OF MODULE LOADER CHANNEL PGM. THE ID IS PLACED IN  * 05920015
* 'NMODSEQ'.  THE PROGRAM THEN GIVES CONTROL TO THE MODULE LOADER     * 05960015
* ROUTINE WHICH LOADS THE REQUESTED MODULE AND PASSES CONTROL TO IT.  * 06000015
*                                                                     * 06040015
*********************************************************************** 06080015
         SPACE 5                                                        06120015
* INITIAL CALL FOR ENVIRONMENT CHECKER MODULE                           06160015
* ENTER HERE FROM A SUCCESSFUL CLEAR CHANNEL FUNCTION                   06200015
         SPACE 2                                                        06240015
         DS    0H                                                       06280015
NSCHED00 EQU   *                                                        06320015
         SPACE 1                                                        06360015
NCLEX01  EQU   *                                                        06400015
         SPACE 2                                                        06440015
         LA    WKR13,NMODRTRN      PUT MOD RETURN ADDR IN GR13          06520015
         MVC   NSEEKARG(7),COMDCB+1     SET ENV CKR BBCCHHR FOR MODLDR  06560015
         MVC   NMODSEQ(2),XECKID   SET ENV CKR ID IN MOD SEQ            06600015
         BC    15,NMODLDR          GO TO LOADER ROUTINE                 06640015
         SPACE 3                                                        06680015
*********************  MODULE COMMON RETURN POINT  ******************** 06720015
         SPACE 1                                                        06760015
NMODRTRN OI    NSWITCH,X'80'       SET ASRNUC IN CONTROL BIT            06800015
         L     BRMOD,NMODBASE      SET MOD BASE REG                     06840015
         STH   WKR1,NMODSEQ        SAVE NEXT MOD'S ID                   06880015
         SPACE 2                                                        06920015
*********** RELATIVE TO ABSOLUTE TRACK CONVERSION ROUTINE  ************ 06960015
*                                                                     * 07000015
* CONVERTS RELATIVE TTR TO ABSOLUTE BBCCHHR.  TTR IS PASSED TO ASRNUC * 07040015
* BY THE PREVIOUSLY RUN ASR MODULE VIA COMMUNICATION AREA--'COMNUC'.  * 07080015
* AFTER CALCULATION OF BBCCHHR, IT IS PLACED IN THE SEEK/SEARCH ARGU- * 07120015
* MENT OF THE ASR MODULE LOADER CHANNEL PROGRAM--NSEEKARG.            * 07160015
*                                                                     * 07200015
* THIS ROUTINE SUPPORTS THE 2311, 2314, 2301 AND 2303                 * 07240015
* REGISTER USAGE                                                   MEXT 07244018
*        REG 2  CONTAINS TTR WHICH IS PASSED                       MEXT 07248018
*        REG 6  ADDRESS OF DEB                                     MEXT 07252018
*                                                                       07256018
*                                                                       07260018
* FOR EACH EXTENT OF SVCLIB, THE AMOUNT OF TT IN THE PASSED REL.   MEXT 07264018
* ADDR IS REDUCED BY THE NUMBER OF TRACKS IN THE EXTENT.THE PROPER MEXT 07268018
* EXTENT IS REACHED WHEN BALANCE IS NEGATIVE.                      MEXT 07272018
*                                                                       07276018
*                                                                     * 07280015
*********************************************************************** 07320015
         SPACE 3                                                        07360015
TTRCNVT  EQU   *                                                   MEXT 07380018
         USING IHADEB,DEBREG                                       MEXT 07400018
         L     CVTREG,COMCVT          RELOAD CVT BASE REG          MEXT 07420018
         LA    CVTREG,ZEROVD(CVTREG)    ZERO HI BYTE                    07440018
         L     DEBREG,CVTSVDCB          ADDR OF SYS1.SVCLIB DCB    MEXT 07460018
         L     DEBREG,D44(DEBREG)       ADDR OF DEB                MEXT 07480018
         LA    DEBREG,ZEROVD(DEBREG)    ZERO HI BYTE               MEXT 07500018
         SR    WKR4,WKR4                                           MEXT 07520018
         L     WKR2,COMNUC         GET PASSED TTR                  MEXT 07540018
         CR    WKR4,WKR2           IS IT ZERO                      MEXT 07560018
         BE    NLDFAIL2            YES-INVALID - WAIT STATE        MEXT 07580018
         IC    WKR4,DEBNMEXT            NUMBER OF EXTENTS          MEXT 07600018
         SR    WKR2,WKR2                                           MEXT 07620018
         LA    WKR1,D32(DEBREG)         GET DEB EXTENT ADDR        MEXT 07640018
         LA    WKR7,NSRCHARG            CCW FOR ABSOLUTE ADDR      MEXT 07660018
         MVC   X4(1,WKR7),COMNUC+X2     PUT R INTO ADDR            MEXT 07680018
         LH    WKR2,COMNUC              TT FROM COMM AREA-IN LOW 2 MEXT 07700018
CNVTB    EQU   *                                                   MEXT 07720018
         SH    WKR2,D14(WKR1)           DECREASE BY TRKS IN EXTENT MEXT 07740018
         BM    CNVTC              BR IF LESS THAN 0, IT IS RIGHT EXT.   07760018
         LA    WKR1,X10(WKR1)        OR GO TO NEXT EXTENT          MEXT 07780018
         BCT   WKR4,CNVTB               MORE EXTENT POSSIBLE       MEXT 07800018
         B     NLDFAIL2       WAITSTATE,MODULE NOT FOUND IN AN EXT.MEXT 07820018
CNVTC    EQU   *                                                   MEXT 07840018
         AH    WKR2,D14(WKR1)      ADD BACK LAST EXTENT NO.OF TT   MEXT 07860018
         MVC   NSEEKARG(X6),X4(WKR1)   GET BBCCHH FROM EXTENT      MEXT 07880018
         BE    NMODLDR                 IF REG2=0,GO TO LOAD MODULE MEXT 07900018
* IF NOT 0, FIND THE DISPLACEMENT IN THIS EXTENT PER DEVICE TYPE   MEXT 07920018
         L     WKR5,ZEROVD(WKR1)       GET UCB ADDRESS             MEXT 07940018
         IC    WKR5,D19(WKR5)          GET DEVICE TYPE CODE        MEXT 07960018
         LA    WKR3,D15                MASK                        MEXT 07980018
         NR    WKR5,WKR3               LEAVE 4 L.O.BITS            MEXT 08000018
         L     WKR3,CVTZDTAB           DISPLACEMENTS OF IO INDEX   MEXT 08020018
         IC    WKR5,ZEROVD(WKR5,WKR3)  USE INDEX FOR DEVICE FACTOR MEXT 08040018
         LH    WKR4,X2(WKR5,WKR3)      GET TT CONVERSION FACTOR    MEXT 08060018
         LR    WKR3,WKR2               TT NO IN DIVIDE REG         MEXT 08080018
         AH    WKR3,X8(WKR1)           ADD STARTING HH (TRACKS)    MEXT 08100018
         LA    WKR2,ZEROVD             SET EVEN TO 0               MEXT 08120018
         DR    WKR2,WKR4               AS A RESULT OF THIS DIVISIONMEXT 08140018
*                             THE QUOTIENT IS THE CYLINDER DISP.   MEXT 08160018
*                             AND THE REMAINDER(IN GPR2) IS THE HEAD(T) 08180018
*                             DISPLACEMENT FROM THE ABSOLUTE START MEXT 08200018
*                          OF THE DATA SET                         MEXT 08220018
         STC   WKR2,X3(WKR7)      STORE H(T)                       MEXT 08240018
         AH    WKR3,X6(WKR1)      ADD CYL EXTENT START             MEXT 08260018
         STC   WKR3,X1(WKR7)       STORE C                         MEXT 08280018
         DROP  DEBREG                                              MEXT 08300018
         EJECT                                                          08320015
*********************************************************************** 08360015
*                                                                     * 08400015
*******************  MCH MODULE LOADER SUBROUTINE  ******************** 08440021
*                                                                     * 08480015
* INPUT PARAMETERS REQUIRED FROM CALLER...                            * 08520015
*        1. THE BBCCHHR ADDRESS MUST BE PUT INTO THE SEEK/SEARCH ARG- * 08560015
*           UEMENT (LABEL IS 'NSEEKARG')                              * 08600015
*                                                                     * 08640015
*********************************************************************** 08680015
         SPACE 3                                                        08720015
         DS    0H                                                       08760015
* ENTER HERE FROM MODULE SCHEDULER                                      08800015
         SPACE 1                                                        08840015
NMODLDR  EQU   *                                                        08880015
         LA    WKR7,10             INITIALIZE RETRY COUNT               08920015
         LH    WKR1,COMSYSRS       GET CUA OF SYSRES                    08960015
NLDAGAIN LA    WKR3,NCHPGM1        SET UP                               09000015
         ST    WKR3,72                   CAW                            09040015
         SPACE 1                                                        09080015
* ISSUE SIO TO SYSRES--INITIATES LOADING OF THE ASR MODULE              09120015
         SPACE 1                                                        09160015
NLDRSIO  SIO   0(WKR1)             SIO TO SYSRES                        09200015
         BC    SIOGO,NLDRTIO       --SIO INITIATED                      09240015
NLDRTRY1 BCT   WKR7,NLDAGAIN       --CC=1,2,OR3-TRY 10 TIMES            09280015
         BC    15,NLDFAIL1         10TH RETRY FAILED-ASR HAS HAD IT     09320015
         SPACE 1                                                        09360015
* SIO IS AOK--CHANNEL PROGRAM IS PROCEEDING NORMALLY. NOW ISSUE TIO TO  09400015
* CHECK AND CLEAR THE NORMAL OR ENDING STATUS OF THE I/O OPERATION.     09440015
         SPACE 1                                                        09480015
NLDRTIO  EQU   *                                                        09520015
         L     WKR5,NLOOPC         INITIALIZE TIO BUSY LOOP COUNT       09560015
NLDRTIOA TIO   0(WKR1)             TIO TO SYSRES                        09600015
         BC    9,NLDRTRY1          --CC=0 OR 3-TRY SIO AGAIN            09640015
         BC    BUSY,NLDRCHK1       --BUSY-CHK TIO TIMEOUT LOOP COUNT    09680015
*        CSW STORED--NOW CHECK ENDING STATUS                            09720015
         MVC   NSVCSW(8),64        SAVE CSW                             09760015
         TM    NSVCSW+5,X'FF'      ANY ERRORS (EXCEPT US,UE)            09800015
         BC    5,NLDRTIOE          BR IF AT LEAST ONE IS ON             09840015
         TM    NSVCSW+4,X'0D'      TEST CE,DE,UE                        09880015
         BC    ALLOFF,NLDRTIOA     --ALL OFF-DO TIO AGAIN               09920015
         BC    ALLON,NLDRTIOB      --ALL ON-CHK FOR ALTERNATE TRACK     09960015
         TM    NSVCSW+4,X'02'      TEST UC ON/OFF                       10000015
         BC    ON,NLDRTIOD         //ON-DO SENSE                        10040015
         TM    NSVCSW+4,X'04'      TEST DE ON/OFF                       10080015
         BC    OFF,NLDRTIOA        --OFF--DEVICE STILL BUSY-DO TIO      10120015
*        DE IS  ON--I/O IS COMPLETELY FINISHED                          10160015
         TM    NSNSSW,X'80'        TEST IF SENSE WAS ISSUED             10200015
         BC    ON,NLDRTIOC         --YES-CHK FOR ALTERNATE TRACK        10240015
         SPACE 1                                                        10280015
         LA    WKR2,COMNUC             ADDR WHERE TTR TABLE PUT IN      10290020
         LA    WKR9,REMEST+48        ADDR SS MCH COMMON AREA CD   42247 10300021
*        I/O FINISHED--MODULE LOADED OK                                 10320015
         NI    NSWITCH,X'00'       SET MOD IN CONTROL BIT               10400015
         BCR   15,BRMOD            GIVE CONTROL TO ASR MODULE ********* 10440015
         SPACE 2                                                        10480015
NLDRTIOB CLC   NRECORD0(4),NSRCHARG                                     10520015
         BC    EQ,NLDRTRY1         BR EQUAL--ERROR--TRY AGAIN           10560015
*        NOT EQUAL MEANS A SWITCH TO AN ALTERNATE TRACK IS NECESSARY    10600015
*        THE CCHH IN RECORD 0 IS THE NEW SEEK ADDR FOR THE ALT TRK      10640015
NLDRALTK MVC   NSRCHARG(4),NRECORD0     SET ALT TRK SEEK ADDR           10680015
         BC    15,NLDAGAIN         DO I/O ALL OVER AGAIN                10720015
         SPACE 1                                                        10760015
NLDRTIOC NI    NSNSSW,X'00'        RESET SENSE FOR ALT TRK SWITCH       10800015
         TM    NLDRSNS,X'02'       IS TRK CONDITION CHK ON/OFF          10840015
         BC    ON,NLDRALTK         --ON-SWITCH TO ALT TRK               10880015
         BC    15,NLDRTRY1         //OFF-ERROR--RETRY                   10920015
         SPACE 1                                                        10960015
NLDRTIOD TM    NSNSSW,X'80'        WAS SENSE JUST ISSUED                11000015
         BC    OFF,NLDRTIOG        --NO--SETUP FOR SENSE                11040015
*        UC WAS RECEIVED FROM SENSE                                     11080015
NLDRTIOE BCT   WKR7,NLDRTIOF       CHK RETRY COUNT                      11120015
         BC    15,NLDFAIL1         10TH RETRY FAILED--ASR HAS HAD IT    11160015
         SPACE 1                                                        11200015
*        A TIO IS NOW ISSUED TO CLEAR ENDING STATUS FOR A RETRY ATTEMPT 11240015
NLDRTIOF L     WKR5,NLOOPC         INITIALIZE TIO LOOP COUNT            11280015
NLDRTIOH TIO   0(WKR1)             ISSUE TIO                            11320015
         BC    7,NLDRCHK2          CC=3,2 OR 1--CHK LOOP COUNT          11360015
*        CC=0 AVAILABLE                                                 11400015
         TM    NSNSSW,X'80'        SHOULD SENSE BE ISSUED               11440015
         BC    OFF,NLDAGAIN        --NO-DO READ AGAIN                   11480015
         LA    WKR3,NSNSPGM        SET SENSE                            11520015
         ST    WKR3,72                      CAW                         11560015
         BC    15,NLDRSIO          GO DO SENSE                          11600015
         SPACE 2                                                        11640015
NLDRTIOG OI    NSNSSW,X'80'        SET SENSE SWITCH                     11680015
         BC    15,NLDRTIOF                                              11720015
         SPACE 1                                                        11760015
NLDRCHK1 BCT   WKR5,NLDRTIOA       BR IF BUSY TIO LOOP COUNT NOT ZERO   11800015
         BC    15,NLDFAIL2                                              11840015
         SPACE 1                                                        11880015
NLDRCHK2 BCT   WKR5,NLDRTIOH       BR IF TIO LOOP COUNT NOT ZERO        11920015
         BC    15,NLDFAIL2                                              11960015
         EJECT                                                          12000015
NLDFAIL1 EQU   *                                                    MCS 12300018
NLDFAIL2 EQU   *                                                    MCS 12600018
         LA    WORK0,X'A04'        SET WAIT STATE CODE              MCS 12900018
ENT0AM   EQU   *                                                    MCS 13200018
         TM    COMNUC+4,X'80'      ERROR RECORD WRITTEN ?           MCS 13500018
         BC    ON,NLDFAIL3         YES, LEAVE MSG ALONE             MCS 13800018
         MVI   NLDRMSG+6,C'S'      SET SEREP CODE                   MCS 14100018
NLDFAIL3 EQU   *                                                    MCS 14400018
         MVC   COMMSG0+X1(D16),NLDRMSG   MOVE MSG TO BUFFER         MCS 14700018
         B     STANDAIO                                             MCS 15000018
*********************************************************************** 16200015
*                                                                     * 16240015
**************  SECOND MACHINE CHECK INTERRUPT HANDLER  *************** 16280015
*                                                                     * 16320015
* THIS ROUTINE GAINS CONTROL WHENEVER AN UNEXPECTED MACHINE CHECK IN- * 16360015
* TERRUPT OCCURS IN MCH CODE. SUCH A CONDITION IS CONSIDERED CATASTRO-* 16400021
* PHIC TO ASR OPERATION. MCH MUST TERMINATE THE OPERATING SYSTEM.     * 16440021
* ALL DEVICES ARE HALTED AND THE SEREP INTERFACE IS SET UP AND      MCS 16500018
* THE UNIQUE WAIT STATE CODE OF 'A01' IS SET INTO THE WAIT STATE PSW. * 16560015
* THE SYSTEM IS THEN PLACED INTO THE DISABLED WAIT STATE.             * 16600015
* THIS ROUTINE WILL BE ENABLED FOR MCI'S. IF ONE OCCURS, CONTROL WILL * 16640015
* GO TO THE 3RD MCI HANDLER,WHICH EFFECTIVELY WILL PLACE THE SYSTEM   * 16680015
* IN THE WAIT STATE.                                                  * 16720015
*                                                                     * 16760015
*********************************************************************** 16800015
         SPACE 5                                                        16840015
         DS    0H                                                       16880015
NMKEX1   EQU   *                                                        16920015
         L     BRNUC,NBASESV       SET ASRNUC BASE REG                  16960015
         MVC   116(4),N3MKAD       SET MCK NEW PSW IN CASE OF 3RD MCI   17000015
         LPSW  NMK2ENAB            ENABLE FOR MCI ONLY (GO TO NSI)      17040015
         SPACE 1                                                        17080015
NMK2ND00 EQU   *                                                        17120015
         LM    WKR15,WKR13,0       CLEAR POTENTIAL BAD PARITY IN REGS   17160015
         L     WKR15,NMODBASE      SET MOD BASE REG                     17200015
         MVC   RESPARE(8),48       SAVE MCK OLD PSW                     17240015
         LA    WKR0,X'A01'         UNIQUE WAIT STSTE CODE               17280015
         TM    COMNUC+4,X'80'      HAS ERROR RECORD BEEN WRITTEN    MCS 17370018
         BC    ON,NMK2ND06         BRANCH YES LEAVE MSG ALONE       MCS 17460018
         MVI   NMK2MS+6,C'S'       SET SEREP CODE                   MCS 17550018
NMK2ND06 EQU   *                                                    MCS 17640018
         MVC   COMMSG0+X1(D16),NMK2MS    MOVE MSG TO BUFFER         MCS 17730018
         B     STANDAIO                                             MCS 17820018
NMK2ND02 EQU   *                                                    MCS 17910018
NSEREP00 EQU   *                                                    MCS 18000018
         SPACE 1                                                        18160015
* SET UP SEREP INTERFACE                                                18200015
         SPACE 1                                                        18240015
         MVC   LOGBEGIN(LOGSIZE),RECPULOG RESTORE ORIGINAL LOG OUT  MCS 18280018
         MVC   IOLOGBEG(IOLOGSIZ),REIOLOG  RESTORE I/O LOG         MCS0 18365018
         CLI   RETYPE,C'I'              CHK IF CHANNEL RECORD      MCS0 18370018
         BNE   CPUREC                  GOM  IF NOT                 MCS0 18375018
         MVI   MCICODE,IOFLG           MOVE SEREP INDICATOR        MCS0 18380018
         B     RECCOM                  CONTINUE                    MCS0 18385018
CPUREC   EQU   *                                                   MCS0 18390018
         MVI   115,X'00'           CLEAR SEREP INTERFACE BYTE           18400015
RECCOM   EQU   *                                                   MCS0 18420018
         ST    WKR0,NWAITPSW+4     SET UNIQUE WAIT STATE CODE           18440015
         MVC   LOCOR170(8),NWAITPSW     SET WAIT PSW IN LOW CORE        18480015
         LPSW  LOCOR170            ENTER DISABLED WAIT STATE*********** 18560015
         SPACE 2                                                        18600015
         SPACE 5                                                        19040015
*********************************************************************** 19080015
*                                                                     * 19120015
***************  THIRD MACHINE CHECK INTERRUPT HANDLER  *************** 19160015
*                                                                     * 19200015
* THIS ROUTINE GAINS CONTROL WHENEVER A MCI OCCURS IN THE ASR 2ND MCI * 19240015
* HANDLER. IT RUNS COMPLETELY DISABLED FOR MCI'S. AN ATTEMPT IS MADE  * 19280015
* TO RING THE BELL. THE UNIQUE WAIT STATE CODE OF 'A02' IS SET AND    * 19320015
* THE SYSTEM IS PLACED INTO THE DISABLED WAIT STATE                   * 19360015
*                                                                     * 19400015
*********************************************************************** 19440015
         SPACE 5                                                        19480015
         DS    0H                                                       19520015
NMK3RD   L     BRNUC,NBASESV       SET ASRNUC BASE REG                  19560015
         LA    WKR0,X'A02'         SET UNIQUE WAIT STATE CODE           19640015
         BC    15,NMK2ND02         CONTINUE                             19680015
         EJECT                                                          19720015
*********************************************************************** 19760015
*                                                                     * 19800015
*******************  MCH PROGRAM INTERRUPT HANDLER  ******************* 19840021
*                                                                     * 19880015
* THIS ROUTINE GAINS CONTROL WHENEVER AN  PROGRAM  CHECK INTERRUPT    * 19920021
* OCCURS IN MCH CODE. A REGULAR PROG CHECK INT. IS CATASTROPHIC TO MCH* 19960021
* OPERATION. THE OPERATING SYSTEM MUST BE TERMINATED. A MSG IS PRINTED* 20000015
*  AND THE SYSTEM IS THEN PLACED INTO A DISABLED                      * 20050021
* WAIT STATE. THE UNIQUE WAIT STATE CODE IS 'A03'.                    * 20080015
********  PGM OLD PSW IS SAVED IN 'RESPARE'                           * 20170015
********  GPR'S SAVED BEGINNING AT 'RESPARE+8'                        * 20260015
*   GTF MONTIOR CALLS ARE RECOGNIZED AND NO-OP IN THIS ROUTINE        * 20310021
          AIF   (&M65MP NE 1).NOSSM                                     20320021
*   DURING MP THE SET SYSTEM MASK (SSM) PROGRAM CHECK INTERRUPT IS    * 20330021
*     RECOGNIZED AND IS NO-OP IN THIS ROUTINE                         * 20340021
.NOSSM    ANOP                                                          20350021
*                                                                     * 20360015
*********************************************************************** 20400015
         SPACE 5                                                        20440015
         DS    0H                                                       20480015
NPGMINT  EQU   *                                                        20520015
X34      EQU   X'34'                                                    20528018
X6C      EQU   X'6C'                                                    20536018
X2B      EQU   X'2B'                                                    20544018
         STM   14,15,LOCOR170                                           20552018
         L     BRNUC,NBASESV       SET ASRNUC BASE                      20560021
         L     BRMOD,NMODBASE      SET MOD BASE                         20570021
*                                                               * GTF   20580021
* THIS ROUTINE INTERCEPTS PGM CHK NEW PSW                       * GTF   20590021
*  1- TO DETERMINE IF A MONITOR CALL.                           * GTF   20600021
*  2- TO ALLOW PROCESSING TO CONTINUE AT NSI IF IT IS.          * GTF   20602021
*  3- TO PROCEED TO UNUSUAL PGM INTERRUPT HANDLER IF IT IS NOT  * GTF   20602421
*                                                               * GTF   20602821
*                                                               * GTF   20603221
         STM   WKR12,WKR13,RESPARE  SAVE WORK REGS IN COMREG       GTF  20603721
         LA    WKR12,MCEXIT        POINT TO REGULAR PC ROUTINE    GTF   20603821
          ST    WKR12,X6C      SET PROG NPSW TO               IE   1718 20603921
*                              REGULAR MCH PROG CHECK HANDLER IE   1718 20604521
         CLI   PGMOPSW+X3,X1       OPERATION EXCEPTION?          GTF    20607021
         BCR   PCUNEQ,WKR12        NO, TRUE PGM CHK               GTF   20608021
MCNOP    TM    PGMOPSW+X04,XC0     INSTR LNG SIX, PGM CHK         GTF   20610021
         BCR   X01,WKR12           NOT ILC FOUR                   GTF   20612021
         TM    PGMOPSW+X04,X40     INSTR LNG TWO?                 GTF   20612421
         BCR   X01,WKR12           ELIMINATE TWO-BYTE INSTR       GTF   20612821
*                                  (BOTH AF & 44 4-BYTE INSTR)    GTF   20612921
         L     WKR13,PGMOPSW+X04   2ND HALF OF OLD PSW IS NSI     GTF   20613021
         SH    WKR13,PCK4          BACK UP TO INSPECT OP CODE     GTF   20614021
* TEST THE CONTEXT: AF0-C-0-DDD, 470-C-0-DDD ONLY GOOD COMBINATION GTF  20614421
         CLI   X4(WKR13),PCBRANCH  IS NXT INSTR BRANCH-NOP?    GTF 0625 20614821
         BCR   PCUNEQ,WKR12        NO,GO TO TRUE PROG. CHK        GTF   20615221
         TM    X5(WKR13),XF0       ARE BITS 8-11 ZERO             GTF   20615621
         BCR   X5,WKR12            NON-ZERO, NOT A NO-OP          GTF   20615721
         CLI   N0(WKR13),PCMONCAL  IF OP CODE X'AF'?              GTF   20615821
         BE    PCGONSI             AF OP CODE, THEN NOP BRANCH    GTF   20616021
*                                  IS PROOF OF MONITOR CALL       GTF   20616921
* TEST THE CONTEXT: 44-00-0-PTR, 47-00-0-DDD ONLY GOOD COMBINATION GTF  20617021
         CLC   N0(X2,WKR13),PCEXEC NO- IS IT THE EXECUTE?         GTF   20617121
         BCR   PCUNEQ,WKR12        NOT EXECUTE, NO MONITOR CALL   GTF   20617221
         TM    X2(WKR13),XF0       BASE MUST BE ZERO FOR CMT      GTF   20617621
         BCR   X5,WKR12            NON ZERO, BAD CMT              GTF   20618021
         LH    WKR13,X2(WKR13)     GET CMT PTR (2ND HW)           GTF   20618421
         CLC   N0(X2,WKR13),PCKAF00   2ND HALF WD INDICATE CMT?   GTF   20618821
         BCR   PCUNEQ,WKR12        NO- NOT A MONITOR CALL         GTF   20618921
* GOOD MONITOR CALL ASSUMED AT THIS TIME; TREATED AS NO-OP.       GTF   20619921
PCGONSI  EQU   *                                                  GTF   20620021
         MVC   104(8),NPGMPSW      SEND PGM CHKS TO NPGMINT       GTF   20620421
         LM    WKR12,WKR13,RESPARE   RESTORE REG 12 & 13          GTF   20620821
         LM    14,15,LOCOR170      RESTOR  REG 14 & 15            GTF   20621221
         LPSW   PGMOPSW            RETURN TO NSI                  GTF   20621321
MCEXIT   EQU   *                   ORDINARY PGM CHECK             GTF   20621721
         AIF   (&M65MP NE 1).MPIC12                                     20622021
         CLI   X2B,X12             IS INTERRUPT CODE = 12           MCS 20623021
         BNE    NOT12IC                                                 20624021
         MVC   X34(X4),COMPSA+X6C  SET PGM NEW IN MCH OLD           MCS 20625421
          MVC   X68(X8),NPGMPSW   SEND PGM CHKS TO NPGMINT    IE   1718 20628421
         LM    WKR12,WKR13,RESPARE   RESTORE REG 12 & 13      IE   1718 20628821
         LM    14,15,LOCOR170                                           20629521
         LPSW  X30                                                      20633621
NOT12IC  EQU   *                                                        20637721
.MPIC12  ANOP                                                           20641821
         STM   0,13,RESPARE+8      SAVE GPR'S IN RE SPARE AREA          20645921
         MVC   RESPARE+D64(X8),LOCOR170    SAVE ORIG REGS               20655921
         MVC   RESPARE(8),40       SAVE PGM OLD PSW                     20680015
         SPACE 1                                                        20720015
         LA    WKR0,X'A03'         SET UNIQUE WAIT STATE CODE           21480015
         TM    COMNUC+4,X'80'      HAS ERROR RECORD BEEN WRITTEN    MCS 21481018
         BC    ON,NPGM03           BRANCH YES LEAVE MSG ALONE       MCS 21482018
         MVI   NPGMSG+6,C'S'       SET SEREP CODE                   MCS 21483018
NPGM03   EQU   *                                                    MCS 21484018
         MVC   COMMSG0+X1(D16),NPGMSG    MOVE MSG TO BUFFER         MCS 21485018
         EJECT                                                          21486021
******************************************************************  MCS 21489018
*                      STAND ALONE I/O ROUTINE                    * MCS 21490018
*                                                                 * MCS 21491018
*        ISSUE I/O TO MASTER OR ALTERNATE CONSOLE                 * MCS 21492018
*                                                                 * MCS 21493018
*        ENTRY FROM - 0A AND 1A TO ISSUE 6W/S                     * MCS 21494018
*                                                                 * MCS 21495018
*                   - 20 TO ISSUE 1W AND 2W                       * MCS 21496018
*                                                                 * MCS 21497018
*                   - NUC TO ISSUE 3W/S, 4W/S, 6W/S, 10W/S, 11W/S * MCS 21498018
*                                                                 * MCS 21499018
*                   - 01 TO ISSUE 13W/S, 14W/S                    * MCS 21500018
*                                                                 * MCS 21501018
*            MESSAGE IS PLACED IN COMMSG0 BUFFER -- 16 BYTES      * MCS 21502018
*                                                                 * MCS 21503018
*            WAIT STATE CODE IS PLACED IN REG 0            S      * MCS 21504018
*                                                                 * MCS 21505018
******************************************************************  MCS 21506018
NEMCEX01 EQU   *                                                    MCS 21507018
STANDAIO EQU   *                                                        21508018
         L     CVTREG,COMCVT       CVT PTR                          MCS 21516018
         USING UCMDSECT,WKR1                                       1450 21516520
         L     WKR1,CVTCUCB        ADDR OF CONSOLE UCM              MCS 21517018
         SPACE 3                                                        21518021
         AIF   (&MCSASR EQ 1).MCS3                                      21520021
         LM    WKR3,WKR5,UCMVEA        ENTRY POINT& SIZE FIELDS    1450 21522520
         DROP  WKR1                                                     21523020
         USING UCMLIST,WKR3                                        1450 21523520
NXTENTRY EQU   *                                                    MCS 21524018
         TM    UCMATR,X90              COMPARE WTO SUPPORT+ DEV    1450 21525020
         BO    GETCUAA             YES BRANCH                       MCS 21526018
NXTMPENT EQU   *                                              IE  50588 21526521
         BXLE  WKR3,WKR4,NXTENTRY  GET NEXT ENTRY                   MCS 21527018
         B     NSEREP00            EXIT                             MCS 21528018
GETCUAA  EQU   *                                                    MCS 21529018
         L     WKR7,UCMUCB         GET UCB                    IE  50588 21529421
         AIF   (&M65MP NE 1).NMCS2D                                     21529521
         TM    COMMSF,X3           CHECK FOR MULTI-SYSTEM MODE CD 50588 21529721
         BNZ   GETCUAA1            NO-ONE CPU (PARTITIONED)   CD  50588 21529821
*   MULTIPROCESSING SYSTEM                                              21530221
         TM    COMMSF,X3           CHECK FOR SHARED MODE      IE  50588 21530321
         BNZ   GETCUAA1            NO-ONE CPU                 IE  50588 21530421
*   MULTISYSTEM- THERE IS TWO ACTIVE CONSOLES,IF MULTISYSTEM AND NO MCS 21530521
         SH    WKR7,PCK4            FOR UCB MPFLAGS=UCB-4     IE  50588 21530621
         CLI   CPUID,XC1           EXECUTING ON CPU A         IE  50588 21530721
         BNE   NEXTCPU             NO-TEST OTHER CPU          IE  50588 21530821
         TM    X0(WKR7),X01        CPUA HAS THIS DEVICE PATH  IE  50588 21530921
         BZ    GETCUAA1            YES - GET CUA              IE  50588 21531021
NEXTUCME EQU   *                                              IE  50588 21531121
         TM    IORCC,X01           BOTH UCMS TESTED           IE  50588 21531221
         BO    NSEREP00            YES-NO AVAIL MP PATH       IE  50588 21531321
         OI    IORCC,X01           SET FIRST UCM TESTED       IE  50588 21531421
         B     NXTMPENT            GET NEXT MP UCM            IE  50588 21531521
NEXTCPU  EQU   *                                                        21531621
         CLI   CPUID,XC2           EXECUTING ON CPU B         IE  50588 21531721
         BNE   NEXTUCME            NO - NEXT UCM              IE  50588 21531821
         TM    X0(WKR7),X2         CPUB HAS THIS DEVICE PATH  IE  50588 21531921
         BO    NEXTUCME            NO - NEXT UCM              IE  50588 21532021
GETCUAA1 EQU   *                                              IE  50588 21532221
.NMCS2D  ANOP                                                           21532421
         LA    WKR1,TYPEWRIT       1052 CCW                   IE  50588 21533221
         LH    WKR7,X4(WKR7)       CUA OF CONSOLE DEVICE      IE  50588 21533421
         N     WKR7,CON7FF         REMOVE UNUSED BITS         IE  50588 21533621
         AGO   .NMCS6           NO MCS                                  21533821
.MCS3    ANOP                                                           21534021
         EJECT                                                          21564521
*        MCS   CUA SEARCH ROUTINE                                   MCS 21565018
MCSSUPT  EQU   *                                                    MCS 21566018
         OI    IORCC,SWITCH2       MCS IN SYSTEM                    MCS 21567018
         S     WKR1,DFOUR          GET ADDR UCM BASE                MCS 21568018
         L     WKR1,X0(WKR1)       LOAD ADDR INTO REG               MCS 21569018
         LTR   WKR1,WKR1           ADDR NOT ZERO                    MCS 21570018
         BZ    NSEREP00            IF ZERO ERROR BRANCH             MCS 21571018
         USING MCSUCM,WKR1             PREFIX BASE                 1450 21572020
         L     WKR3,UCMMCENT     GET MSTR CONSOLE UCM ENTRY        1450 21573020
         USING UCMLIST,WKR3                                             21573521
         CLC   UCMCOMPC+X1(X3),HCCCWADR IS MASTER COMPOSITE?       1450 21574020
         BE    NMSTCOM             NO, BRANCH                       MCS 21575018
         L     WKR3,UCMCOMPC           ADDR OF OUTPUT COMPOSITE    1450 21576020
NMSTCOM  EQU   *                                                    MCS 21577018
         LA    WKR6,MSCCWADR       MASTR OR ALT CCW ADDR            MCS 21578018
         BAL   WKR5,CHKAVAIL       CHECK CONSOLE AVAILABLE          MCS 21579018
         TM    IORCC,SWITCH1       IS CONSOLE SWITCH OFF            MCS 21580018
         BZ    HARDCOPY            NO BRANCH BYPASS--BYPASS ALT     MCS 21581018
         L     WKR3,UCMMCENT     GET MSTR CONSOLE UCM ENTRY        1450 21581620
         CLC   UCMOAOEN+X1,HCCCWADR    CHK FOR COMPOSITE CONSOLE   1450 21582220
         BNE   COMPOSIT            BRANCH IF NOT ZERO               MCS 21583018
         L     WKR3,UCMALTEN           GET ALTERNATE CONSOLE UCM   1450 21584020
         B     ARCOMP                                               MCS 21585018
COMPOSIT EQU   *                                                    MCS 21586018
         L     WKR3,UCMOAOEN           GET ALTERNATE OUTPUT UCM    1450 21587020
ARCOMP   EQU   *                                                        21588018
         BAL   WKR5,CHKAVAIL       CONSOLE AVAILABLE                MCS 21589018
HARDCOPY EQU   *                                                    MCS 21590018
         TM    UCMSFLGS,UCMSYSB        HARDCOPY REQUIRED           1450 21590620
         BZ    CUACHK           NO, TO PRINT                       2124 21591218
         TM    UCMSFLGS,UCMSYSG        IS SYSLOG HARDCOPY          1450 21591820
         BO    CUACHK              YES, TO PRINT                   2124 21592418
         NI    IORCC,SWITOFF       CLEAR CONSOLE SWITCH             MCS 21593018
         L     WKR3,UCMHCUCM           GET HARDCOPY UCM ENTRY      1450 21594020
         LA    WKR6,HCCCWADR       HARDCOPY CCW ADDR                MCS 21595018
         BAL   WKR5,CHKAVAIL       CHECK AVAILABLE                  MCS 21596018
         TM    IORCC,SWITCH1       CONSOLE AVAILABLE                MCS 21597018
         BO    CUACHK              GET CUA                          MCS 21598018
         L     WKR1,HCCCWADR       HARDCOPY CCW ADDR                MCS 21599018
         LA    WKR1,X8(WKR1)       SKIP RING CCW ADDR               MCS 21600018
         ST    WKR1,HCCCWADR       STORE IT                         MCS 21601018
CUACHK   EQU   *                                                    MCS 21601420
         L     WKR1,MSCCWADR       MASTER CCW                       MCS 21601820
         LTR   WKR1,WKR1           IS IT ZERO ?               CD  50588 21601921
         BZ    WPRNTHCY            YES-CHECK HARDCOPY         CD  50588 21602021
         LH    WKR7,MSTMCS         CUA                              MCS 21602220
         B     WPRNT               WAIT PRINT ROUTINE               MCS 21602620
CHKAVAIL EQU   *                                                    MCS 21603018
         LTR   WKR3,WKR3           TEST FOR ZERO                    MCS 21604018
         BZ    HARDCOPY            YES, CHECK HARD COPY             MCS 21605018
CHKAVAI  EQU   *                                                    MCS 21606018
         LR    WKR4,WKR1           SAVE MCS PREFIX                  MCS 21607018
         TM    UCMSTS,UCMTA            OPEN PENDING                1450 21608020
         BO    UCBADD              YES BRANCH                       MCS 21609018
         TM    UCMATR,UCMUF            DEVICE ACTIVE               1450 21610020
         BO    UCBADD              YES BRANCH                       MCS 21611018
         OI    IORCC,SWITCH1       TURN SWITCH ON                   MCS 21612018
         BR    WKR5                RETURN                           MCS 21613018
UCBADD   EQU   *                                                    MCS 21614018
         BAL   WKR2,GETCUA         GET CUA                          MCS 21615018
         STH   WKR9,X4(WKR6)       STORE CONSOLE CUA                MCS 21616018
         CLI   X12(WKR3),X40       CONSOLE=COMMUNICATIONS     IE  50588 21617021
         BE    CLCCWADR            YES-CLEAR CCW ADDRESS AREA CD  50588 21619021
         ST    WKR1,0(WKR6)        STORE CCW ADDR                   MCS 21621018
CCWADCLD LR    WKR1,WKR4           RESTORE MCS PREFIX         CD  50588 21622021
         BR    WKR5                RETURN                           MCS 21623018
CLCCWADR EQU   *                                                        21623421
         SR    WKR2,WKR2           CLEAR REG FOR CCW STORE    CD  50588 21623821
         ST    WKR2,0(WKR6)        STORE ZERO IN CCW ADDRESS  CD  50588 21624221
         B     CCWADCLD            CONTINUE PROCESSING        CD  50588 21624621
         SPACE 3                                                        21625020
GETCUA   EQU   *                                                        21627819
         L     WKR8,UCMXB              ADDR OF GRAPHICS DCM        1450 21628620
* THE ID=19GR IN COLUMNS 67-71 IDENTIFIES THE CHANGES TO IGFASRN1       21628919
* MACRO REQUIRED TO SUPPORT ANY GRAPHICS CONSOLE. THE DCM CONTAINS      21629219
* A POINTER FO THE CCW LIST OF A PARTICULAR GRAPHICS DEVICE SUCH        21629519
* AS A 2250,2260 OR ANY FUTURE DEVICES TO BE SUPPORTED AS CONSOLES      21629819
* ON THE MODEL 65-UNIPROCESSOR OR MULTIPROCESSOR. THIS CHANGE           21630119
* ALLOWS THE STAND ALONE I/O METHOD OF THE MCH/65 COMPONENTS TO BE      21630419
* INDEPENDENT OF THE GRAPHICS DEVICE BEING USED AS A CONSOLE.           21630719
         L     WKR3,UCMUCB             GET CONSOLE UCB                  21631320
         LA    WKR1,TYPEWRIT           CONSOLE PRINTER                  21631619
         CLI   D18(WKR3),X10       IS CONSOLE A DISPLAY DEVICE      MCS 21633018
         BNE   GETCUA10            NO, BRANCH                       MCS 21634018
         LTR   WKR8,WKR8     TEST FOR VALID ADDRESS               60894 21634521
         BZ    NODCM               NO DCM FOR GRAPHICS DEVICE  @S67856P 21636521
         L     WKR1,N20(WKR8)          ADDR OF 1ST CCW             19GR 21644321
         SR    WKR9,WKR9               CLEAR REG                   19GR 21644821
         IC    WKR9,N20(WKR8)          OFFSET OF CCW TO BE        36641 21645321
         LR    WKR8,WKR1               MODIFIED BY MCH.            19GR 21645821
         BCT   WKR9,GETCCW             DECREASE BY 1 TO GET PROPER 19GR 21646321
GETCCW   EQU   *                                                   19GR 21646821
         LA    WKR8,N8(WKR8)           POINT TO NEXT CCW                21647621
         BCT   WKR9,GETCCW             CORRECT ONE REACHED.        19GR 21647821
         LA    WKR9,COMMSG0       ADDR OF BUFFER-3 BYRES          36641 21648321
         STH   WKR9,N2(WKR8)           IS NOW SET INTO            36641 21648821
         SRL   WKR9,N16                PROPER CCW                 36641 21649321
         STC   WKR9,N1(WKR8)           SET HIGH BYTE OF ADDR      36641 21649821
         MVI   N7(WKR8),N28            LAST BYTE CCW=COUNT OF 28   19GR 21650321
GETCUA10 EQU   *                                                    MCS 21650821
         LH    WKR9,X4(WKR3)       CUA OF CONSOLE DEVICE            MCS 21651321
         N     WKR9,CON7FF         REMOVE UNUSED BITS               MCS 21651821
         BR    WKR2                RETURN                           MCS 21652321
NODCM    OI    IORCC,SWITCH1       SET NOT AVAILABLE IND       @S67856P 21652421
         B     CCWADCLD            RETURN TO MAINLINE          @S67856P 21652521
.NMCS6   ANOP                                                           21652821
         EJECT                                                          21653321
*        WAIT STATE MESSAGES TEST - START I/O ROUTINE               MCS 21653821
*        ENTRY CRITERIA -- REG 7 = CUA                              MCS 21654321
*                            REG 1 = ADDRESS OF CCW                 MCS 21654821
WPRNT    EQU   *                                                    MCS 21655321
  AIF  ((&MCSASR NE 1) OR (&M65MP NE 1)).NMCPVD  BOTH ON                21655721
         SH    WKR3,PCK4           GET UCB MP FLAGS               62299 21655821
WPRNT1   EQU   *                                                  62299 21656021
.NMCPVD   ANOP                                                    62299 21656121
         XC    COMMSG0+N26(N2),COMMSG0+N26   CLR LAST TWO BYTES         21656221
         CLI   COMMSG0+N6,CS                 IS IT S MSG                21656321
         BNE   WPRNT2                        NO                         21656821
         MVC   NSAVEIO(N22),COMMSG0+N6       MOVE S                     21657321
         MVC   COMMSG0+N8(N22),NSAVEIO        AND TEXT                  21657821
         MVI   COMMSG0+N6,CW                 SET W IN MSG               21658321
WPRNT2   EQU   *                                                        21658821
  AIF  ((&MCSASR NE 1) OR (&M65MP NE 1)).NMCSMP  BOTH ON                21659321
         CLI   CPUID,XC1           EXECUTING ON CPU A         IE  50588 21659821
         BNE   NEXTCPU1            NO - NEXT CPU              IE  50588 21660321
         TM    X0(WKR3),X01        CPUA HAS THIS DEVICE PATH  IE  50588 21661321
         BZ    WPRNT3              YES - WRITE MSG            IE  50588 21661821
         B     WPRNT2A            CONTINUE                    IE  50588 21662321
NEXTCPU1 EQU   *                                              IE  50588 21662821
         CLI   CPUID,XC2           EXECUTING ON CPU B         IE  50588 21663321
         BNE   WPRNT2A            CONTINUE                    IE  50588 21663821
         TM    X0(WKR3),X2         CPUB HAS THIS DEVICE PATH  IE  50588 21664321
WPRNT2A  EQU   *                                                        21664821
         AIF   (&MCSASR NE 1).NMCS2V                                    21665321
         BNZ   TRYHCY             TEST FOR HARDCOPY           IE  50588 21665821
.NMCS2V  ANOP                                                           21666321
         AIF   (&MCSASR EQ 1).MCS2                                      21666821
         BNZ   NEXTUCME           NEXT UCM IN MP              IE  50588 21667321
.MCS2    ANOP                                                           21667821
WPRNT3   EQU   *                                                        21668321
.NMCSMP  ANOP                                                           21668821
***   ISSUE WAIT STATE MESSAGE                                          21669321
         L     WKR3,NLCNT         SET LOOP TIO COUNT               MCS  21669821
         LA    WKR1,N0(WKR1)      CLEAR HI-ORDER BYTE         IE  44631 21670321
         ST    WKR1,D72           SET CCW ADDR IN CAW              MCS  21670821
WTIORTN  EQU   *                                                        21671321
         TIO   X0(WKR7)            TEST I/O                         MCS 21671821
         BC    BUSY,WTIOBUSY       BUSY-LOOP                        MCS 21672321
         BC    X9,WSIORTN          AVAIL OR NOT-OPER --TRY SIO      MCS 21672821
*        CSW   STORED                                               MCS 21673321
         TM    D68,X38             CUE,BUSY OR CE                 21961 21673821
         BNZ   WTIOBUSY            YES - SENSE ERROR          IE  50588 21674321
WSIORTN  EQU   *                                                    MCS 21674821
         SIO   X0(WKR7)            START I/O                        MCS 21675321
         AIF   (&MCSASR NE 1).NMCS4                                 MCS 21675821
TRYHCY   EQU   *                                                        21676321
         TM    IORCC,SWITCH2       MCS IN SYSTEM                    MCS 21676821
         BO    WPRNTHCY            YES, BRANCH PRINT HARDCOPY       MCS 21677321
.NMCS4   ANOP                                                       MCS 21677821
         B     NSEREP00            NO, EXIT                         MCS 21678321
WTIOBUSY EQU   *                                                    MCS 21678821
         BCT   WKR3,WTIORTN        LOOP TILL ZERO COUNT             MCS 21679321
         B     WSIORTN             TRY SIO                          MCS 21679821
         AIF   (&MCSASR NE 1).NMCS5                                 MCS 21680321
WPRNTHCY EQU   *                                                    MCS 21680821
         L     WKR1,HCCCWADR       HARD COPY CCW                    MCS 21681321
         LTR   WKR1,WKR1           IS IT ZERO                       MCS 21681821
         BZ    NSEREP00            YES, BRANCH                      MCS 21682321
         LH    WKR7,HCTMCS         HARD COPY CUA                    MCS 21682821
         MVI   IORCC,X0            TURN SWITCH OFF                  MCS 21683321
  AIF  ((&MCSASR NE 1) OR (&M65MP NE 1)).NMCPEN  BOTH ON          62299 21683721
         B     WPRNT1              PRINT TO HARD COPY             62299 21683821
     AGO .NMCS5                                                   62299 21683921
.NMCPEN   ANOP                                                    62299 21684021
         B     WPRNT               PRINT TO HARD COPY               MCS 21684221
.NMCS5   ANOP                                                           21684321
         SPACE 3                                                        21684821
*              MESSAGE CCW@S                                        MCS 21685321
*              1052 CONSOLE   PRINTER                               MCS 21685821
TYPEWRIT CCW   X'0B',0,X'60',1     RING CONSOLE ALARM               MCS 21686321
         CCW   X'09',COMMSG0,X'20',28   TYPE MSG                    MCS 21686821
         AIF   (&MCSASR NE 1).NMSCVD                                    21687321
         DS    0F                                                   MCS 21687821
DFOUR    DC    XL4'4'                                                   21688321
MSCCWADR DC    XL4'0'              4 BYTES MC CCW LIST              MCS 21688821
MSTMCS   DC    XL2'0'              MCS CUA MASTER CONSOLE           MCS 21689321
         DS    0F                                                   MCS 21689821
HCCCWADR DC    XL4'0'              4 BYTES HC CCW LIST              MCS 21690321
HCTMCS   DC    XL2'0'              HARD COPY CUA                    MCS 21690821
.NMSCVD  ANOP                                                           21691321
D64      EQU   64                                                   MCS 21691821
X90      EQU   X'90'                                                MCS 21693121
X4       EQU   4                                                    MCS 21694421
SWITCH2  EQU   X'04'                                                MCS 21695721
SWITOFF  EQU   X'7F'                                                MCS 21697021
X30      EQU   X'30'                                                MCS 21698321
X9       EQU   9                                                    MCS 21700921
X5C      EQU   X'5C'                                                MCS 21702221
X68       EQU   X'68'                                         IE   1718 21703521
X8       EQU   8                                                    MCS 21706121
X38      EQU   X'38'                                                    21712621
X10      EQU   X'10'                                                MCS 21713921
X12      EQU   X'12'                                                MCS 21715221
X40      EQU   X'40'                                                MCS 21716521
D18      EQU   18                                                   MCS 21717821
X1       EQU   1                                                        21720421
X0       EQU   0                                                    MCS 21721721
X2       EQU   2                                                    MCS 21723021
X7       EQU   7                                                    MCS 21724321
D72      EQU   72                                                   MCS 21725621
D68      EQU   68                                                   MCS 21726921
SWITCH1  EQU   X'80'                                                    21729521
XC       EQU   X'0C'                                                    21730821
D12      EQU   12                                                       21732121
X3       EQU   3                                                        21733421
X80      EQU   X'80'                                               M67  21736020
X32      EQU   X'32'                                                    21756020
X20      EQU   X'20'                                               M67  21776020
D14      EQU   14                                                  MEXT 21817018
D44      EQU   44                                                  MEXT 21917018
DEBREG   EQU   6                                                   MEXT 22017018
D32      EQU   32                                                  MEXT 22117018
X6       EQU   6                                                   MEXT 22217018
D19      EQU   19                                                  MEXT 22317018
D15      EQU   15                                                  MEXT 22417018
N0       EQU   0                                                        22467019
N1       EQU   1                                                        22517019
N2       EQU   2                                                        22567019
N7       EQU   7                                                        22617019
N6       EQU   6                                                        22637019
N8       EQU   8                                                        22667019
N20      EQU   20                                                       22717019
N22      EQU   22                                                       22727019
N26      EQU   26                                                       22737019
N28      EQU   28                                                       22767019
CS       EQU   C'S'                                                     22787019
CW       EQU   C'W'                                                     22807019
XC1      EQU   X'C1'                                                    22817021
XC2      EQU   X'C2'                                                    22827021
         SPACE 3                                                        22840015
*********************************************************************** 23680015
         EJECT                                                          23720015
*      OBR EXIT ROUTINE                                                 23760015
*                                                                       23800015
*  THIS ROUTINE IS USED WHEN OBR HAS BEEN IN CONTROL AND A MCI THEN     23840015
*  OCCURRED.  OBR MAY HAVE BEEN THE CURRENT TCB OR THERE COULD HAVE     23880015
*  BEEN A TASK SWITCH.  IN EITHER CASE, THIS ROUTINE IS EXECUTED.       23920015
*  IT SIMULATES THE TERMINATION (RETURNS REQUEST ELEMENT  TO FREELIST)  23960015
*  OF OBR, SO THAT THE MCI RECORD WRITTEN BY ASR IS NOT OVERLAID BY     24000015
*  THE RECORD TO BE WRITTEN BY OBR.                                     24040015
         SPACE                                                          24080015
OBREXIT  EQU   *                                                        24120015
         L     BRNUC,116            GET ASR BASE FOR ADDRESSABILITY     24160015
         L     WKR1,COMSIRB          PUT RQE IN PARM REG 1              24200015
         L     WKR1,XRBQ(WKR1)                                          24240015
         SVC   15                                                       24280015
         SVC   3                                                        24320015
         EJECT                                                          24360015
**************************  E Q U A T E S  **************************** 24400015
         SPACE 3                                                        24440015
TWOVD    EQU   2                                                   MP1  24445017
VDOCT    EQU   X'80'                                               MP1  24450017
ZEROVD   EQU   0                                                   MP1  24465017
IOFLG    EQU   X'F'               I/O SEREP INDICATOR              MCS0 24473018
MCICODE  EQU   115                LOCATION OF MCI INTERRUPT CODE   MCS0 24476018
WKR0     EQU   0                                                        24480015
WKR1     EQU   1                                                        24520015
WKR2     EQU   2                                                        24560015
WKR3     EQU   3                                                        24600015
WKR4     EQU   4                                                        24640015
WKR5     EQU   5                                                        24680015
WKR6     EQU   6                                                        24720015
WKR7     EQU   7                                                        24760015
WKR8     EQU   8                                                        24800015
WKR9     EQU   9                                                        24840015
WKR10    EQU   10                                                       24880015
WKR11    EQU   11                                                       24920015
WKR12    EQU   12                                                       24960015
WKR13    EQU   13                                                       25000015
WKR14    EQU   14                                                       25040015
WKR15    EQU   15                                                       25080015
BRMOD    EQU   15                  BASE REG FOR ASR MODULES             25120015
BRNUC    EQU   14                  BASE REG FOR ASR NUCLEUS             25160015
CVTREG   EQU   10                  POINTER TO COMM VECTOR TABLE         25200015
X01      EQU   1                                                        25210021
X03      EQU   3                                                        25220021
X04      EQU   4                                                        25230021
X5       EQU   5                                                        25232021
PCUNEQ   EQU   7                   NOT EQUAL (AFTER COMPARE)            25234021
PGMOPSW  EQU   X'28'                                                    25236021
PCBRANCH EQU   X'47'               BRANCH OP CODE                 GTF   25238021
PCMONCAL EQU   X'AF'               MONITOR CALL AF                GTF   25238821
XC0      EQU   X'C0'                                                    25239221
XF0      EQU   X'F0'                                                    25239621
LOCOR170 EQU   X'170'              LOW CORE WORK AREA                   25240015
NRSV     EQU   X'174'              SV AREA FOR GR14 AT ENTRY TO ASRNUC  25280015
NBASESV  EQU   X'178'              SV AREA FOR ASRNUC BASE REG          25320015
LOGSIZE  EQU   176                 SIZE OF CPU LOG-OUT FOR MODEL 65     25360015
PSASIZE  EQU   128                 SIZE OF PSA AREA                     25400015
PSABEGIN EQU   0                   BEGINNING OF PSA AREA                25440015
LOGBEGIN EQU   128                 BEGINNING OF CPU LOG-OUT AREA        25480015
IOLOGSIZ EQU   24                  I/O LOG SIZE                         25520015
IOLOGBEG EQU   LOGBEGIN+LOGSIZE    BEGINNING OF I/O LOG-FOLLOWS CPU LOG 25560015
CKSUMLOC EQU   X'A6'               CHECK SUM LOCATION IN THE LOG-OUT    25600015
CKSUMBIT EQU   X'40'               CHECK SUM BIT IS BIT 1 IN THE BYTE   25640015
XRBQ     EQU   24             ADDR OF REQUEST ELEMENT IN SIRB           25680015
* CONSTANTS FOR ASR MODULE LOADER ROUTINE                               25720015
SEEK     EQU   07                  SEEK COMMAND CODE                    25760015
READR0   EQU   22                  READ RECORD ZERO COMMAND CODE        25800015
SRCHIDEQ EQU   49                  SEARCH ID EQUAL COMMAND CODE         25840015
TIC      EQU   08                  TRANSFER IN CHANNEL COMMAND CODE     25880015
READDATA EQU   06                  READ DATA COMMAND CODE               25920015
SIOGO    EQU   8                                                        25960015
         SPACE 5                                                        26000015
********************  D O U B L E   W O R D S  ************************ 26040015
         SPACE 3                                                        26080015
         DS    0D                                                       26120015
NMKENAB  DC    XL5'0004000000'     ONLY MCK                             26160015
         DC    AL3(NU0001)                 ENABLED PSW                  26200015
NPGMPSW  DC    XL5'0004000000'     ENABLED  PROGRAM NEW                 26240021
         DC    AL3(NPGMINT)                   PSW FOR ASR PGM INTRPTS   26280015
NMKEXPSW DC    XL5'0'              MCK NEW PSW POINTING TO ASR          26320015
         DC    AL3(NMKEX1)           NUCLEUS EMERGENCY EXIT             26360015
WORK0    EQU   0                                                        26365018
NABSADR  DC    XL8'0'              ABSOLUTE BBCCHHR OF THE BEGINNING OF 27040015
*                                  THE ASR MODULE DATA SET              27080015
NCHPGM1  CCW   SEEK,NSEEKARG,X'60',6         CCW LIST--SEEK             27240015
         CCW   READR0,NRECORD0,X'60',4               --READ RECORD ZERO 27280015
NCHPGM1A CCW   SRCHIDEQ,NSRCHARG,X'60',5             --SEARCH ID EQUAL  27320015
         CCW   TIC,NCHPGM1A,X'60',1                  --TIC              27360015
         CCW   READDATA,NMODENT,X'20',3072           --READ DATA        27400015
         SPACE 1                                                        27440015
NSNSPGM  CCW   4,NLDRSNS,X'20',6   SENSE CCW                            27480015
         SPACE 2                                                        27520015
NSVCSW   DC    1D'0'               CSW SAVE AREA FOR MOD LDR SUBRTN.    27560015
NSEEKARG DC    XL8'0'              BBCCHHR ADDRESS FOR CCW LIST         27600015
NSRCHARG EQU   NSEEKARG+2                                               27640015
NMK2ENAB DC    XL5'0004000000'     ENABLE FOR MCI ONLY PSW              27680015
         DC    AL3(NMK2ND00)       IN 2ND MCI HANDLER ROUTINE           27720015
NWAITPSW DC    XL8'0002000000000000'    WAIT PSW                        27760015
         SPACE 5                                                        27800015
****************************  W O R D S  ****************************** 27840015
         SPACE 3                                                        27880015
         DS    0F                                                       27920015
NADPTHCL DC    A(NCLEX01)          EXITS FOR PATH CLEAR                 28000015
NADCLEME DC    A(NEMCEX01)         EMERGENCY EXIT FROM CLR SYSRES CHNNL 28040015
NMODBASE DC    A(NMODENT)          MODULE ENTRY POINT                   28080015
NLCNT    DC    XL4'00A0000'        LOOP TIO COUNT 10 MILLION            28120015
NCOMAREA DC    A(NMODENT+3072)     BEGINNING ADDR OF COMM AREA          28200015
NLOOPC   DC    XL4'000FFFFF'       TIO LOOP COUNT FOR MOD LDR SUBRTN    28280015
N3MKAD   DC    A(NMK3RD)           ADDR OF 3RD MCK HANDLER              28320015
WTOBUF   DC    50F'0'              WTO BUFFER AREA         DR       MCS 28330021
CON7FF   DC    X'000007FF'                                              28340021
         SPACE 5                                                        28360015
***************************  T A B L E S  ***************************** 28400015
         SPACE 3                                                        28440015
         DS    0D                                                       28480015
NMODSEQ  DC    XL2'0'         *****                                     28560015
NSAVEIO  DC    XL200'0'            I/O INTERRUPT SAVE QUEUE             28600015
VALUE6   DC    H'6'                                                     28610021
PCK4     DC    H'4'                CONSTANT OF 4                        28612021
         SPACE 5                                                        28620015
NMK2MS   DC    C'IGF003W UNEX MCI'                                  MCS 28660018
NPGMSG   DC    C'IGF004W PGM CHCK'                                  MCS 28700018
NLDRMSG  DC    C'IGF006W I/O ERR '                                  MCS 28740018
N65MSG   DC    C'IGF010S NOT M/65'                                  MCS 28780018
NNIPMSG  DC    C'IGF011S MCI NIP '                                  MCI 28820018
* MCH NUCLEUS  WAIT STATE MESSAGE SWITCH                                28830021
IORCC    DC    X'00'                                                    28840021
**             BIT 0     CONSOLE NOT AVAILABLE (MCS)                    28850021
**             BIT 1-4   UNUSED                                         28852021
**             BIT 5     MCS IN SYSTEM                                  28854021
**             BIT 6     UNUSED                                         28856021
**             BIT 7     FIRST UCM IN A NON-MCS MULTISYSTEM IS TESTED   28858021
         SPACE 3                                                        29000015
NIDBUF   DC    C' CPU ID '                  MESSAGES               MP1  29050021
NIDBUF1  DC    X'F1'                   CPU ID NUMBER               MP1  29060021
NSVCKSUM DC    X'00'               SAVE AREA FOR CHECK SUM BIT          29120015
XECKID   DC    C'0B'        ********                                    29160015
NSWITCH  DC    XL1'0'    BIT       FUNCTION FOR ON CONDITION            29200015
*                        0         ASRNUC IN CONTROL                    29240015
         SPACE 2                                                        29280015
NLDRSNS  DC    XL6'0'              READ IN AREA FOR SENSE DATA          29320015
NRECORD0 DC    XL4'0'              READ IN AREA FOR RECORD 0            29360015
NSNSSW   DC    X'00'     BIT       MEANING FOR ON CONDITION             29400015
*                        0         SENSE FOR ALTERNATE TRACK            29440015
PCKAF00  DC    X'AF00'             CLASS MASK TABLE ENTRY         GTF   29450021
PCEXEC   DC    X'4400'             EXECUTE IS FOLLOWED BY ZEROES  GTF   29460021
MOD65    DC    X'0065'            MODEL ID                              29465021
****  MAINTENANCE  AREA  ***                                            29470021
MAINTID DC CL8'IGFNUC00' CORE IDENTIFIER                                29472021
MAINT    DC S(*) MODULE DISPLACEMENT                                    29474021
LEVEL  DC  X'51'  MODULE LEVEL                                          29476021
RELE DC  X'21' RELEASE NUMBER                                           29478021
         DC 10F'0' ADDITIONAL SPACE                                     29478421
         EJECT                                                          29520015
         AIF   (&MCSASR NE 0).NMCS14                                MCS 30420018
         ORG   IGFN0000+2048                                            31320018
.NMCS14  ANOP                                                       MCS 32220018
         AIF   (&MCSASR NE 1).NMCS2                                 MCS 33120018
         ORG   IGFN0000+2448                                        MCS 34020018
.NMCS2   ANOP                                                       MCS 34920018
NMODENT  EQU   *                                                        36480015
         EJECT                                                          36520015
*********************************************************************** 36560015
*                                                                     * 36600015
*****  CLEAR CHANNEL PATH TO SYSRES AND CONSOLE/ASR TERMINATOR  ******* 36640015
*                                                                     * 36680015
*********************************************************************** 36720015
         SPACE 2                                                        36760015
         DS    0H                                                       36810015
IGFN0002 EQU   *                   THIS IS DUMMY ENTRY--MCH NUCLEUS     36860015
         BC    0,*+4               ENTERS CLR CHNNL ENTRY POINT         36910015
         SPACE 3                                                        36960015
********  ENTRY FOR CLEAR CHANNEL PATH TO SYSRES AND CONSOLE  ********* 37040015
         SPACE 1                                                        37080015
* GPR USAGES FOR THIS ROUTINE ARE...                                  * 37120015
* GPR 1 --CONTAINS CUA OF CURRENT DEVICE UNDER TIO OPERATION          * 37160015
* GPR 2 --CONTAINS CURRENT POINTER TO I/O INTERRUPT SAVE QUEUE        * 37200015
* GPR 3 --CONTAINS CURRENT TIO LOOP COUNT                             * 37240015
* GPR 4 --LINK REG TO QUEUE SAVED I/O INTERRUPT SUBROUTINE            * 37280015
* GPR 7 --LINK REG TO CSW ERROR CHECK SUBROUTINE                      * 37320015
* GPR 8 --CONTAINS ADDRESS OF CURRENT UCB                             * 37360015
* GPR 9 --CONTAINS ADDRESS OF CURRENT UCB POINTER                     * 37400015
* GPR 10--BASE REG FOR THE CVT DSECT                                  * 37440015
* GPR 14--BASE REG FOR ASR NUCLEUS                                    * 37480015
* GPR 15--BASE REG FOR THIS ROUTINE                                   * 37520015
*********************************************************************** 37560015
         SPACE 1                                                        37600015
* INITIALIZATION                                                        37640015
IGFN0001 EQU   *                                                        37680015
         L     WKR6,CVTSYSAD       GET SYSRES UCB ADDR FROM CVT         37720015
         MVC   NDEVICE(2),UCBCUA(WKR6)       GET SYSRES CUA             37760015
         NI    NDEVICE,X'07'       CLEAR HI-ORDER BITS IN CHNNL BYTE    37800015
         MVC   NDEVICE+2(1),UNITTYPE(WKR6)   SAVE UNIT TYPE             37840015
         MVC   COMSYSRS(4),NDEVICE      SAVE CUA IN COMM AREA           37880015
         AIF   (&M65MP NE 1).NMP20                                   MP 37883017
         TM    COMMSF,3            CHK PARTITIONED OR RECONFIGURED   MP 37886017
         BNZ   NCLR080             GO IF SO                          MP 37889017
         SR    WKR3,WKR3                                             MP 37892017
         IC    WKR3,NDEVICE        GET CHL NUMBER FROM CUA           MP 37895017
         SLL   WKR3,1              AND DOUBLE                        MP 37898017
         TM    CHRECNUC-IPLPSW(WKR3),X'78' CHK IND. OF NOT-AVAIL.    MP 37901017
         BNZ   NEROUT1             GO IF NOT AVAILABLE              MCS 37904018
NCLR080  EQU   *                                                     MP 37907017
.NMP20   ANOP                                                        MP 37910017
         ST    WKR2,NIOQADDR       SAVE STARTING IOQ ADDR               37920015
         L     WKR9,CVTILK2        ADDR OF 1ST TWO BYTE UCB POINTER     37960015
         MVI   NSW2,X'00'          CLEAR PGM SWITCH                     38000015
         XC    NSTATSV(2),NSTATSV  CLEAR CSW STATUS SAVE AREA           38040015
         MVC   NCUTEST,NDEVICE+1   GET UA PORTION                       38160015
         CLI   NDEVICE+2,N2301     IS SYSRES A 2301 DRUM                38200015
         BC    EQ,NCU5BITS         --YES-CU ADDR IS HI-ORDER 5 BITS     38240015
*                                  --NO-CU ADDR IS HI-ORDER 4 BITS      38280015
         NI    NCUTEST,X'F0'       SET CU ADDR                          38320015
         MVI   NCUMASK,X'F0'        AND CU MASK                         38360015
         SPACE 2                                                        38440015
*                                                                       38480015
         SPACE 5                                                        39280015
NCLR2860 LH    WKR1,NDEVICE        SET CUA IN WORK REG                  39320015
****************                                                        39360015
* ISSUE TIO TO DEVICE--DETERMINE INITIAL STATUS                         39400015
         TIO   0(WKR1)             TIO TO DEVICE                        39440015
         BC    NOTOPER,NEROUT1   -- NOT OPERATIONAL                 MCS 39480018
         BC    BUSY,NSCNUCB0       --BUSY--GO TO SCAN UCB SUBR          39520015
         BC    AVAIL,NCLROK01      --AVAILABLE--PATH IS CLEAR           39560015
*                                  --CSW STORED--BEGIN CSW ANALYSIS     39600015
NCLR015  BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHK SUBROUTINE       39640015
         SPACE 1                                                        39680015
*        RETURN TO HERE--CSW HAS NO CATASTROPHIC ERRORS                 39720015
         TM    NCSWUS1,X'2C'       TEST CE,CUE,DE--ON/OFF/MOXED         39760015
         BC    ALLON,NCLR023         ALL ARE ON                         39800015
         BC    ALLOFF,NCLR002        ALL ARE OFF--NOW CHK FOR B,SM      39840015
*                                                                       39880015
         TM    NCSWUS1,X'0C'       TEST CE,DE--ON/OFF/MIXED             39920015
         BC    ALLON,NCLR023         BOTH ARE ON (CE,DE,NOT CUE)        39960015
         BC    ALLOFF,NCLR003        BOTH ARE OFF (CUE ON ALONE)        40000015
*                                                                       40040015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      40080015
         BC    ALLON,NCLR023         ON (DE,NOT CE,CUE DON'T CARE)      40120015
*        DE IS OFF, CE IS ON, CUE DON'T KNOW YES                        40160015
         TM    NCSWUS1,X'20'       TEST CUE--ON/OFF                     40200015
         BC    ALLON,NCLR004         ON (CE,CUE,NOT DE)                 40240015
         SPACE 1                                                        40280015
*        CE IS ON ALONE--MUST NOW GIVE TIO TO DEVICE FOR DE             40320015
         OI    NUSSAVE,X'08'       SET CE IN CSW UNIT STATUS SAVE BYTE  40360015
         SPACE 2                                                        40400015
* NOW ISSUE TIO TO DEVICE FOR POSSIBLE PENDING DE                       40440015
         SPACE 1                                                        40480015
NTIOSYS1 L     WKR3,NCNTR1         INITIALIZE LOOP COUNT                40520015
NTIOSYS2 TIO   0(WKR1)             TIO TO DEVICE                        40560015
         BC    NOTOPER,NEROUT1   -- NOT OPERATIONAL                 MCS 40600018
         BC    BUSY,NEROUT1      -- ERROR                           MCS 40640018
         BC    AVAIL,NCLR031       --AVAILABLE                          40680015
         SPACE 1                                                        40720015
*        CSW STORED--BEGIN CSW ANALYSIS                                 40760015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHK SUBROUTINE       40800015
         SPACE 1                                                        40840015
*        RETURN TO HERE--CSW HAS NO CATASTROPHIC ERRORS                 40880015
         SPACE 1                                                        40920015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      40960015
         BC    ALLOFF,NCLR006        OFF--GO CHK LOOP COUNT             41000015
NCLR032  EQU   *                                                        41020015
         OC    NCSWUS1(2),NUSSAVE  OR STATUS SAVE BYTES INTO CSW        41040015
NCLR001  BC    15,NCLR023          GO Q THE INTRPT                      41100015
         SPACE 1                                                        41160015
NCLR006  BCT   WKR3,NTIOSYS2       REPEAT IF COUNT NOT ZERO             41200015
         SPACE 2                                                        41240015
         BC    15,NEROUT1          COUNT ZERO                       MCS 41260018
         SPACE 2                                                        41286015
NCLR031  EQU   *                                                        41292015
         CLC   NSTATSV(2),CLEARUA  ANY STATUS TO Q                      41298015
         BC    EQ,NCLROK03         BR IF NO                             41304015
         BC    15,NCLR032          Q THE STATUS                         41310015
         SPACE 1                                                        41320015
NCU5BITS NI    NCUTEST,X'F8'       SET CU ADDR                          41360015
         MVI   NCUMASK,X'F8'        AND CU MASK                         41400015
         B     NCLR2860                                             MCS 41440018
         SPACE 1                                                        41480015
         EJECT                                                          41600015
* CUE ON ALONE--MUST TIO DEVICE FOR POSSIBLE AVAILABLE OR DE            41640015
         SPACE 2                                                        41680015
NCLR003  OI    NUSSAVE,X'20'       SET CUE IN CSW UNIT STATUS SAVE BYTE 41720015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE               41760015
         SPACE 2                                                        41800015
*        CUE AND CE ON--MUST NOW GIVE TIO TO DEVICE FOR DE              41840015
NCLR004  OI    NUSSAVE,X'28'       SET CE+CUE IN CSW STATUS SAVE BYTE   41880015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE               41920015
         SPACE 2                                                        41960015
         SPACE 2                                                        42160015
* INITIAL TIO TO DEVICE FOUND CE,CUE,DE ALL OFF.                        42200015
* MUST NOW CHECK THE BUSY(B) AND STATUS MODIFIER(SM) BITS.              42240015
         SPACE 1                                                        42280015
NCLR002  TM    NCSWUS1,X'50'       TEST B,SM--ON/OFF/MIXED              42320015
         BC    ALLOFF,NEROUT1    -- ERROR                           MCS 42360018
         BC    ALLON,NCUSCAN         BOTH ON--GO TO CNTRL UNIT SCAN     42400015
         TM    NCSWUS1,X'10'       TEST B--ON/OFF                       42440015
         BC    OFF,NEROUT1       -- ERROR                           MCS 42480018
         SPACE 1                                                        42520015
*        BUSY IS ON ALONE--THIS IMPLIES THAT THERE WILL BE A DE FROM    42560015
*        DEVICE. MUST GIVE TIO TO DEVICE FOR DE.                        42600015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE FOR DE        42640015
         EJECT                                                          42680015
*********************************************************************** 42720015
* THE INITIAL TIO TO DEVICE GAVE B+SM BITS. IF THE DEVICE DOES NOT    * 42760015
* SHARE A CONTROL UNIT, THEN THIS CU/DEVICE IS BUSY AND THE PGM MUST  * 42800015
* ISSUE TIO'S TILL DE COMES IN. IF CU IS SHARED, THIS MEANS...        * 42840015
* 1. CHANNEL IS AVAILABLE                                             * 42880015
* 2. CONTROL UNIT IS BUSY WITH EITHER...                              * 42920015
*        A. DEVICE                                                    * 42960015
*        B. SOME OTHER DEVICE ATTAHCHED TO THIS CONTROL UNIT          * 43000015
*                                                                     * 43040015
* THE PROGRAM MUST NOW FIND WHICH DEVICE IS KEEPING THE CU BUSY, BY   * 43080015
* ISSUING TIO'S TO ALL DEVICES ON THIS CU. THE CU SCAN IS MAINTAINED  * 43120015
* UNTIL ONE OF THE FOLLOWING OCCURS...                                * 43160015
* 1. CUE AND/OR DE IS RECEIVED                                        * 43200015
* 2. DEVICE IS FOUND NOT OPERATIONAL (CC=3)                           * 43240015
* 3. SCAN COUNT IS EXHAUSTED                                          * 43280015
*********************************************************************** 43320015
         SPACE 3                                                        43360015
NCUSCAN  CLI   NCUTEST,X'FF'       DOES DEVICE SHARE A CU               43400015
         BC    EQ,NTIOSYS1         --NO                                 43440015
         L     WKR3,NCNTR1         INITIALIZE SCAN LOOP COUNT           43480015
         OI    NSW2,X'20'          SET SAME CU AS DEVICE BIT            43520015
NCUSCAN1 BC    15,NSCNUCB1         GO TO SCAN UCB SUBR                  43560015
         SPACE 2                                                        43600015
*        RETURN TO HERE--CUA IS IN WKR1                                 43640015
NCUSCAN2 TIO   0(WKR1)             ISSUE TIO                            43680015
         BC    NOTOPER,NCLR007       NOT OPERATIONAL                    43720015
         BC    BUSY,NEROUT1      -- ERROR                           MCS 43760018
         BC    AVAIL,NCLR008         AVAILABLE                          43800015
         SPACE 1                                                        43840015
*        CSW STORED--BEGIN CSW ANALYSIS                                 43880015
         BAL   WKR7,NCSWERCK       GOT O CSW ERROR CHK SUBROUTINE       43920015
         SPACE 1                                                        43960015
*        RETURN TO HERE-CSW HAS NO CATASTROPHIC ERRORS                  44000015
         TM    NCSWUS1,X'50'       TEST B,SM--ON/OFF                    44040015
         BC    ALLON,NCUSCAN1        BOTH ON--CU STILL BUSY OR DEVICE   44080015
*                                    KEEPING CU BUSY HASN'T YET         44120015
*                                    BEEN FOUND.                        44160015
         TM    NCSWUS1,X'24'       TEST CUE,DE--ON/OFF/MIXED            44200015
         BC    ALLOFF,NCLR030        BOTH OFF                           44240015
         BC    ALLON,NCLR009         BOTH ON--CU AND DEVICE ARE FREE    44280015
*                                                                       44320015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      44360015
         BC    OFF,NCLR010           OFF--CUE ON ALONE                  44400015
         SPACE 1                                                        44440015
*        DE IS ON--DEVICE IS NOW FREE                                   44480015
NCLR009  BAL   WKR4,NIOQ           GO TO QUEUE I/O INTRPT SUBR.         44520015
         CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEAR           44560015
         BC    EQ,NCLR050          BR IF YES                            44600015
NCLR021  LA    WKR2,10(WKR2)         NO-STEP I/O QUEUE POINTER          44640015
NCLR011  XC    NSTATSV(2),NSTATSV  CLEAR CSW STATUS SAVE AREA           44680015
         LH    WKR1,NDEVICE        GET DEVICE CUA                       44760015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE (POSSIBLE DE) 44800015
         SPACE 2                                                        44840015
NCLR010  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         44880015
         BC    NOTEQ,NCLR009       BR IF NO                             44910015
         OI    NUSSAVE,X'20'       SET CUE IN CSW UNIT STATUS SAVE BYTE 44940015
         BC    15,NTIOSYS1         TIO TO DEVICE FOR POSSIBLE DE        44980015
         SPACE 2                                                        45040015
NCLR007  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         45080015
         BC    EQ,NEROUT1          NOT OPERATIONAL                  MCS 45120018
         BC    15,NCUSCAN1         NO--GO TO CU SCAN                    45160015
         SPACE 2                                                        45200015
NCLR008  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         45280015
         BC    NOTEQ,NCUSCAN1        NO--GO TO CU SCAN                  45360015
         BC    15,NCLROK05         YES--PATH IS CLEAR                   45400015
         SPACE 2                                                        45405015
NCLR030  EQU   *                                                        45410015
         TM    NCSWUS1,X'03'       TEST UC/UE                           45415015
         BC    5,NCLR009           BR IF MIXED OR ONES                  45420015
         TM    NCSWCS1,X'F1'       TEST PCI,IL,PGM-PROT-CHAIN CHECK     45425015
         BC    5,NCLR009           BR IF MIXED OR ONES                  45430015
         B     NEROUT1           --ERROR                            MCS 45435018
         EJECT                                                          45440015
***************  U C B   S C A N   R O U T I N E  ********************* 45480015
*                                                                     * 45520015
* THIS ROUTINE IS ENTERED WHENEVER...                                 * 45560015
* A.  A CC=2 (BUSY) WAS RECEIVED FROM THE INITIAL TIO TO DEVICE.      * 45600015
* B.  ALL DEVICES ATTACHED TO SAME CU AS DEVICE ARE TO BE SCANNED.    * 45640015
*                                                                     * 45680015
* FOR CASE A, ONE OF THE FOLLOWING IS POSSIBLE...                     * 45720015
*     1. THE CHANNEL IS BUSY (BURST MODE OPERATION) WITH EITHER       * 45760015
*        DEVICE TO BE CLEARED OR SOME OTHER DEVICE.                   * 45800015
*     2. THERE IS A PENDING CHANNEL INTERRUPT FROM A DEVICE OTHER     * 45840015
*        THAN THE ONE TO BE CLEARED.                                  * 45880015
* IN EITHER CASE, THE ACTION TO TAKE IS TO CONTINUALLY GIVE TIO'S TO  * 45920015
* ALL DEVICES UNTIL A CSW IS STORED (CC=1). THE CUA'S OF ALL THESE    * 45960015
* DEVICES ARE FOUND BY SCANNING THE UCB TABLES. A SCAN LOOP COUNT IS  * 46000015
* MAINTAINED. IF IT IS EXHAUSTED BEFORE A CC=1 IS RECEIVED, THE PGM   * 46040015
* COULD NOT FIND THE DEVICE KEEPING THE CHANNEL BUSY.                 * 46080015
*                                                                     * 46120015
*********************************************************************** 46160015
         SPACE 3                                                        46200015
NSCNUCB0 L     WKR3,NCNTR1         INITIALIZE SCAN LOOP COUNT           46240015
NSCNUCB1 LH    WKR8,0(WKR9)        LOAD ADDR OF UCB                     46280015
        LA    WKR9,2(WKR9)        STEP TO NEXT UCB POINTER ADDR         46320015
         LTR   WKR8,WKR8           TEST FOR END OF UCB ADDR TABLE       46360015
         BC    4,NCLR012              BR--END OF TABLE                  46400015
         BC    8,NSCNUCB1             BR--ZERO ENTRY--GET NEXT UCB      46440015
         MVC   NUCBCUA(2),UCBCUA(WKR8)  GET CUA FROM UCB                46480015
         NI    NUCBCUA,X'07'       CLEAR HI-ORDER BITS IN CHNNL BYTE    46520015
         LH    WKR1,NUCBCUA        PUT CUA INTO REG                     46560015
         CLC   NUCBCUA(1),NDEVICE  IS THIS SAME CHANNEL AS DEVICE       46600015
         BC    NOTEQ,NSCNUCB1             NO--GET NEXT UCB              46640015
         TM    NSW2,X'20'          SAME CUA AS DEVICE SWITCH-ON/OFF     46680015
         BC    OFF,NCLR013           OFF--ISSUE TIO TO THIS DEVICE      46720015
         NC    NUCBCUA+1(1),NCUMASK  ON--ZERO DEVICE ADDR--CU INTACT    46760015
         CLC   NUCBCUA+1(1),NCUTEST     IS THIS SAME CU AS DEVICE       46800015
         BC    NOTEQ,NSCNUCB1             NO--GET NEXT UCB              46840015
         BC    15,NCUSCAN2              YES--GO BACK TO CU SCAN TIO     46880015
         SPACE 2                                                        46920015
* DEVICE IS ON SAME CHNNL AS DEVICE TO BE CLEARED -GIVE IT A TIO        46960015
         SPACE 1                                                        47000015
NCLR013  TIO   0(WKR1)             ISSUE TIO                            47040015
         BC    NOTOPER,NCLR014       NOT OPERATIONAL                    47080015
         BC    BUSY,NSCNUCB1         BUSY--GET NEXT UCB                 47120015
         BC    AVAIL,NEROUT1       ERROR                            MCS 47160018
* CSW STORED--CHNNL INTRPT HAS BEEN FOUND--BEGIN CSW ANALYSIS           47200015
         CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         47240015
         BC    EQ,NCLR015            YES--GO BACK TO DEVICE CSW ANALYS. 47280015
* CHNNL INTERRUPT CAUSED BY DEVICE OTHER THAN ONE TO BE CLEARED         47320015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHECK SUBROUTINE     47360015
         SPACE 1                                                        47400015
* RETURN HERE IF--NO CATASTROPHIC ERRORS IN CSW                         47440015
         TM    NCSWUS1,X'0C'       TEST CE,DE--ON/OFF/MIXED             47480015
         BC    ALLOFF,NEROUT1      ERROR                            MCS 47520018
         BC    ALLON,NCLR023         BOTH ON--GO SAVE INTRPT            47560015
         SPACE 1                                                        47600015
         TM    NCSWUS1,X'08'       TEST CE--ON/OFF                      47640015
         BC    OFF,NEROUT1         ERROR                            MCS 47680018
         SPACE 1                                                        47720015
* CE ON, DE OFF--DETERMINE IF DEVICE IS ON SAME CU AS DEVICE TO BE CLRD 47760015
         NC    NUCBCUA+1(1),NCUMASK     ZERO DEVICE ADDR-CU INTACT      47800015
         CLC   NUCBCUA+1(1),NCUTEST     ON SAME CU                      47840015
         BC    NOTEQ,NCLR017            --NO                            47880015
         SPACE 1                                                        47920015
* CE WAS RECEIVED FROM DEVICE ON SAME CU--NOW CHECK FOR CUE             47960015
         TM    NCSWUS1,X'20'       TEST CUE--ON/OFF                     48000015
         BC    ON,NCLR023            ON--CE+CUE ON                      48040015
         SPACE 1                                                        48080015
* CE IS ON ALONE. CU IS STILL BUSY. MUST GIVE TIO'S TO THIS DEVICE      48120015
* UNTIL CUE AND/OR DE IS RECEIVED. THEN CHECK FOR A POSSIBLE PENDING    48160015
* DE FROM DEVICE TO BE CLEARED.                                         48200015
         SPACE 1                                                        48240015
         OI    NUSSAVE,X'08'       SET CE IN UNIT STATUS SAVE BYTE      48280015
         MVC   NCSWWK2(8),NCSWWK1  MOVE SAVED CSW TO WORK AREA 2        48320015
NCLR019  TIO   0(WKR1)             TIO TO THIS DEVICE                   48360015
         BC    NOTOPER,NCLR018       NOT OPERATIONAL                    48400015
         BC    10,NEROUT1          ERROR                            MCS 48440018
         SPACE 1                                                        48480015
* CSW STORED-BEGIN ANALYSIS                                             48520015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHECK SUBR.          48560015
* RETURN HERE--CSW HAS NO CATASTROPHIC ERRORS                           48600015
         TM    NCSWUS1,X'50'       TEST B,SM-NOTH ON                    48640015
         BC    ALLON,NCLR019         BOTH ON--CU IS STILL BUSY          48680015
         TM    NCSWUS1,X'24'       TEST CUE,DE--ON/OFF/MIXED            48720015
         BC    ALLOFF,NEROUT1      ERROR                            MCS 48760018
         BC    ALLON,NCLR018         BOTH ON-CE,CUE,DE WERE ALL RECEIVD 48800015
         SPACE 1                                                        48840015
         TM    NCSWUS1,X'20'       TEST CUE--ON/OFF                     48880015
         BC    ON,NCLR020            ON                                 48920015
* DE WAS RECEIVED (CE WAS PREVIOUSLY RECEIVED)                          48960015
NCLR018  OC    NCSWUS1(2),NUSSAVE  OR STATUS BYTES INTO CSW             49000015
NCLR016  BC    15,NCLR023          Q THE INTRPT                         49060015
         SPACE 2                                                        49120015
* CUE ON,DE OFF (CE WAS PREVIOUSLY RECEIVED)                            49160015
NCLR020  OI    NCSWWK2+4,X'20'     OR CUE INTO SAVED CSW IN WORK AREA 2 49200015
         OC    NCSWWK2+4(2),NSTATSV  PLUS ANY OTHER SAVED STATUS        49240015
         MVC   NCSWWK1(8),NCSWWK2    PUT INTO WORK AREA 1               49280015
         BC    15,NCLR023          Q THE INTRPT                         49320015
         SPACE 3                                                        49360015
* TIO TO DEVICE IN UCB SCAN RTN GAVE CC=3 (NOT OPERATIONAL)             49400015
NCLR014  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         49440015
         BC    EQ,NEROUT1          ERROR                            MCS 49480018
         BC    15,NSCNUCB1           NO--GET NEXT UCB                   49520015
         SPACE 3                                                        49560015
* CE ON ALONE--DEVICE NOT ON SAME CU AS DEVICE TO BE CLEARED            49600015
NCLR017  CH    WKR1,CNSLADDR       IS THIS CONSOLE                      49640015
         BC    NOTEQ,NCLR023       --NO-GO QUEUE THIS INTERRUPT         49680015
         SPACE 1                                                        49720015
* IF THE ABOVE CONDITION IS EQUAL,THIS MEANS THAT THIS 2860 CLEAR CHNNL 49760015
* ROUTINE IS CURRENTLY CLEARING TO THE SYSRES DEVICE AND THE CONSOLE    49800015
* IS ON THE SAME CHNNL AS SYSRES. CONSOLE PRESENTED A CE ONLY--MUST NOW 49840015
* ISSUE A TIO AND WAIT FOR DE TO COME IN.                               49880015
         OI    NUSSAVE,X'08'       SET CE IN STATUS SAVE                49920015
         L     WKR3,NCNTR1         INITIALIZE TIMING LOOP COUNT         49960015
NCLR025  TIO   0(WKR1)             TIO TO CONSOLE                       50000015
         BC    11,NEROUT1          ERROR                            MCS 50040018
*        CSW STORED                                                     50080015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHECK SUBR.          50120015
*        RETURN HERE IF NO CATASTROPHIC ERRORS OR NO UC                 50160015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      50200015
         BC    OFF,NCLR024         --OFF-GO CHECK LOOP COUNT            50240015
         OC    NCSWUS1(2),NSTATSV  'OR' SAVED STATUS INTO CSW           50280015
         OI    NSW2,X'10'          SET CONSOLE CLEARED SWITCH           50320015
NCLR023  BAL   WKR4,NIOQ           QUEUE I/O INTERPT                    50360015
NCLR050  LA    WKR2,10(WKR2)       STEP IOQ POINTER                     50380015
         CLI   NCUTEST,X'FF'       DOES NDEVICE SHARS A CTL UNIT        50400015
         BC    EQ,NTIOSYS1         BR IF NO                             50420015
NCLR022  OI    NSW2,X'20'          SET SAME CU AS NDEVICE SWITCH        50440015
         LH    WKR1,NDEVICE        GET DEVICE CUA                       50480015
         L     WKR3,NCNTR1         SET TIO LOOP COUNT                   50520015
         XC    NSTATSV(2),NSTATSV  CLEAR CSW STATUS SAVE BYTES          50540015
         BC    15,NCUSCAN2         GO TO CU SCAN                        50560015
         SPACE 3                                                        50600015
NCLR024  BCT   WKR3,NCLR025        BR IF LOOP COUNT NOT ZERO            50640015
         B     NEROUT1             COUNT ZERO                       MCS 50680018
         SPACE 1                                                        50720015
* END OF UCB TABLES--GO CHECK LOOP COUNT                                50760015
NCLR012  BCT   WKR3,*+8            IS LOOP COUNT EXHAUSTED              50800015
         B     NEROUT1             COUNT ZERO                       MCS 50840018
         L     WKR9,CVTILK2        BO--RESET UCB POINTER TO 1ST UCB     50880015
         BC    15,NSCNUCB1         GO BACK TO SCAN                      50920015
         EJECT                                                          50960015
*********************************************************************** 51000015
*                                                                     * 51040015
*******  C S W   E R R O R   C H E C K   S U B R O U T I N E  ********* 51080015
*                                                                     * 51120015
*********************************************************************** 51160015
* CSW ERROR CHECK SUBROUTINE (NEW)                                      51200015
NCSWERCK MVC   NCSWWK1(8),64       SAVE CSW                             51240015
         TM    NCSWCS1,X'0E'       TEST CCC,ICC,CDC--MIXED,ON/OFF       51280015
         BC    5,NEROUT1           ERROR                            MCS 51320018
         TM    NCSWUS1,X'02'       TEST UC--ON/OFF                      51360015
         BC    ON,NCSWER2          --ON                                 51400015
         TM    NCSWUS1,X'80'       TEST ATTENTION                       51520015
         BC    ON,NCSWATT          BR IF ON                             51560015
NCSWEREX NI    68,X'01'            CLEAR UNIT STATUS EXCEPT UE IF ON    51600015
         OC    NSTATSV(2),68       SAVE CSW STATUS                      51640015
         BCR   15,WKR7             RETURN TO CALLER                     51680015
NCSWER2  CH    WKR1,NDEVICE        DID UC OCCUR ON DEVICE TO BE CLEARED 51720015
         BC    EQ,NSNS1            --YES--GO TO SENSE                   51760015
         CH    WKR1,CNSLADDR       DID UC OCCUR ON CONSOLE              51800015
         BC    NOTEQ,NCSWEREX      --NO--EXIT ROUTINE                   51840015
         SPACE 1                                                        51880015
*        SENSE ROUTINE                                                  51920015
         SPACE 1                                                        51960015
NSNS1    OC    NCSWUS1(2),NSTATSV  'OR' STATUS SAVE BYTES AND           52000015
         BAL   WKR4,NIOQ           QUEUE THE INTRPT                     52040015
         LA    WKR5,NSNSRD         GET SENSE READ IN AREA ADDRESS       52080015
         ST    WKR5,NSNSCCW         PUT ADDR INTO CSW                   52120015
         MVI   NSNSCCW,SENSE       SET SENSE OP IN CCW                  52160015
NSNS3    LA    WKR6,NSNSCCW        SET                                  52200015
         ST    WKR6,72                CAW                               52240015
         SIO   0(WKR1)             ISSUE SENSE                          52280015
         BC    NOTOPER,NEROUT1     NOT OPERATIONAL                  MCS 52320018
         BC    AVAIL,NSNS2         --AVAILABLE--SIO IS OK               52360015
*        CSW STORED--ONLY POSSIBLE CORRECT STATUS AT THIS TIME IS DE.   52400015
*        IF DE NOT ON, ASR MUST TERMINATE                               52440015
         TM    68,X'04'            DE--ON/OFF                           52480015
         BC    OFF,NEROUT1                                          MCS 52520018
         OI    6(WKR2),X'04'       SET DE IN PREVIOUSLY SAVED CSW       52560015
         BC    15,NSNS3            DO SENSE AGAIN                       52600015
         SPACE 1                                                        52640015
* SENSE STARTED--NOW GIVE TIO TILL SENSE IS FINISHED                    52680015
         SPACE 1                                                        52720015
NSNS2    TIO   0(WKR1)             TIO                                  52760015
         BC    NOTOPER,NEROUT1     NOT OPERATIONAL                  MCS 52800018
         BC    BUSY,NSNS2          --BUSY                               52840015
         BC    AVAIL,NSNS7         --AVAILABLE                          52880015
*        CSW STORED                                                     52920015
         TM    VD68,VDSIX          TEST DE AND UC                  MP   52960017
         BZ    NSNS2               OFF, LOOP                       MP   53000017
VD68     EQU    68                                                  MP  53040017
VDSIX    EQU   6                                                    MP  53080017
NSNS7    EQU   *                                                        53120015
         LA    WKR2,10(WKR2)       STEP IOQ POINTER                     53160015
         CH    WKR1,NDEVICE        WAS SENSE ISSUED TO DEVICE TO BE CLR 53200015
         BC    EQ,NCLREXA          --YES                            MCS 53240018
         OI    NSW2,X'11'          --NO-SET CNSL CLR+1ST MSG BUFRD SW   53280015
         BC    15,NCLR022          CONTINUE                             53520015
         SPACE 1                                                        53560015
         SPACE 1                                                        54720015
NCSWATT  BAL   WKR4,NIOQ           Q THE INTERRUPT                      54760015
         LA    WKR2,10(WKR2)       STEP IOQ POINTER                     54780015
         BC    15,NCLREXA                                               54800015
         SPACE 1                                                        54840015
         EJECT                                                          54880015
*************  QUEUE SAVED I/O INTERRUPT SUBROUTINE  ****************** 54920015
*                                                                       54960015
NIOQ     MVC   2(8,WKR2),NCSWWK1   QUEUE THIS CSW                       55000015
         STH   WKR1,0(WKR2)          AND CORRESPONDING CUA              55040015
         BCR   15,WKR4             GO BACK TO CALLER                    55080015
         SPACE 5                                                        55120015
***************  P A T H   C L E A R   E X I T S  ********************* 56120015
         SPACE 3                                                        56160015
NCLREXA  EQU   *                                                        56200015
NCLROK01 EQU   NCLREXA                                                  56240015
NCLROK03 EQU   NCLREXA                                                  56280015
NCLROK05 EQU   NCLREXA                                                  56320015
         SPACE 1                                                        56360015
         MVI   0(WKR2),X'FF'       SET END-OF-QUEUE INDICATOR           56400015
         SPACE 1                                                        57640015
NCLROUT2 L     WKR6,COMNUC         GET ASRNUC RETURN ADDRESS            57680015
         BCR   15,WKR6             RETURN TO ASRNUC                     57720015
NEROUT1  EQU   *                                                    MCS 59720018
         LA    WKR0,XA10           WAIT STATE CODE                  MCS 61720018
         MVC   COMMSG0+X1(D16),NIOMSG    MOVE MSG TO BUFFER         MCS 63720018
NEROUT2  EQU   *                                                    MCS 65720018
         L     WKR3,COMNUC+X4      ERROR RETURN ADDR OF NUC         MCS 67720018
         BCR   15,WKR3             RETURN TO ASRNUC                 MCS 69720018
XA10     EQU   X'A10'                                                   71720018
D16      EQU   16                                                       73720018
**************************  E Q U A T E S  **************************** 81840015
         SPACE 3                                                        81880015
NOTOPER  EQU   1                   NOT OPERATIONAL                      81920015
BUSY     EQU   2                   BUSY                                 81960015
CSWSTORE EQU   4                   CSW STORED                           82000015
AVAIL    EQU   8                   AVAILABLE                            82040015
ALLON    EQU   1                   ALL BITS ON                          82080015
ALLOFF   EQU   8                   ALL BITS OFF                         82120015
MIXED    EQU   4                   BITS ARE MIXED ONES/ZEROES           82160015
ON       EQU   1                   ON                                   82200015
OFF      EQU   8                   OFF                                  82240015
EQ       EQU   8                   EQUAL                                82280015
NOTEQ    EQU   7                   NOT EQUAL                            82320015
UCBCUA   EQU   4                   UCB DISPLACEMENT FOR CHANNEL/UNIT    82360015
SENSE    EQU   4                   SENSE COMMAND CODE                   82400015
UNITTYPE EQU   19                                                       82440015
N2301    EQU   2                   UCB UNIT TYPE FOR 2301 DRUM          82520015
         SPACE 5                                                        83160015
********************  D O U B L E   W O R D S  ************************ 83200015
         SPACE 3                                                        83240015
         DS    0D                                                       83280015
NCSWWK1  DC    1D'0'               CSW WORK AREA 1                      83320015
NCSWUS1  EQU   NCSWWK1+4             UNIT STATUS BYTE OF CSW            83360015
NCSWCS1  EQU   NCSWWK1+5             CHANNEL STATUS BYTE OF CSW         83400015
NCSWWK2  DC    1D'0'               CSW WORK AREA 2                      83440015
NSNSCCW  DC    XL8'0400000020000006'    SENSE CCW                       83480015
NSKCCW1  DC    XL8'0000000060000006'    CCW'S TO CAUSE                  83520015
NSKCCW2  DC    XL8'0000000020000006'                  CE,DE INTERRUPT   83560015
NPOSCCW  DC    XL8'0000000020000006'    REPOSITION SYSRES ARM CCW       83600015
NCSWSAVE DC    XL8'0'              CSW SV AREA                          83640015
NCTBL    DC    C'0123456789ABCDEF'      CONVERSION TABLE                83680015
NRBPSW   DC    D'0'                SAVE AREA FOR RESUME PSW IN RB       83720015
         SPACE 5                                                        83760015
****************************  W O R D S  ****************************** 83800015
         SPACE 3                                                        83840015
         DS    0F                                                       83880015
NCNTR1  DC  XL4'00005000'              TIO LOOP COUNT               19A 83900019
* COUNT WAS REDUCED FROM X'BFFFF' TO X'5000' SINCE IT COULD TAKE    19A 83920019
*  UP TO 8 OR 10 MINUTES TO ACTUALLY TIME OUT  OF THIS LOOP.            83940019
NDEVICE  DC    F'0'                DEVICE TO BE CLEARED                 83960015
NIOQADDR DC    1F'0'               SAVE AREA FOR IOQ ADDRESS            84000015
CLEARUA  DC    X'000000F8'    MASK TO GET CONTROL UNIT ADDRESS          84040015
CLEAR21  DC    X'000007FF'    MASK TO CLEAR SIGN AND ISOLATE CUA        84080015
* CONSOLE ADDRESS AND DEVICE TYPE                                       84120015
CNSLADDR DC    F'0'                                                     84160015
CNSLTYPE EQU   CNSLADDR+2                                               84200015
NCURTCB  DC    F'0'                SV AREA FOR CURRENT TCB ADDRESS      84240015
NSVR12   DC    F'0'                SV AREA FOR GR12                     84280015
NSV7     DC    F'0'                SAVE GR7                             84320015
         SPACE 5                                                        84400015
**********************  H A L F   W O R D S  ************************** 84440015
         SPACE 3                                                        84480015
         DS    0H                                                       84520015
NUCBCUA  DC    XL2'0'              SV AREA FOR CURRENT CUA FROM UCB     84560015
NSTATSV  DC    XL2'0'              CSW STAUTS SAVE BYTES                84600015
NUSSAVE  EQU   NSTATSV                                                  84640015
NCSSAVE  EQU   NSTATSV+1                                                84680015
         SPACE 5                                                        84720015
*************************  M E S S A G E S  *************************** 84760015
NIOMSG   DC    C'IGF006S I/O ERR '                                  MCS 84960018
****************************  B Y T E S  ****************************** 85160015
         SPACE 3                                                        85200015
NSNSRD   DC    XL6'0'              SENSE READ IN AREA                   85240015
NCUMASK  DC    XL1'0'              CU ADDR MASK                         85280015
NSW2     DC    XL1'0'    BIT       FUNCTION                             85320015
*                        0         CC=0OK IN TIO TO SYSRES FOR DE       85360015
*                        1         QUEUE SYSRES DE REQUIRED             85400015
*                        2         SAME CU AS SYSRES FOR UCB SCAN RTN   85440015
*                        3         CLEAR SYSRES CLEARED CONSOLE ALSO    85480015
*                        4         PCI MESSAGES ARE BUFFERED            85520015
*                        5                                              85560015
*                        6         2ND UNIT CHECK MSG BUFFERED          85600015
*                        7         1ST UNIT CHECK MSG BUFFERED          85640015
NCUTEST  DC    XL1'0'              SYSRES CU SAVE TEST AREA             85680015
NSVFLGS  DC    XL1'0'              CURRENT TCBFLGS+1 SAVE AREA          85720015
         EJECT                                                          85800015
         ORG   NMODENT+3072                                             85840015
*****   A S R  C O M M U N I C A T I O N  A R E A     *****             85880015
*                                                         *             85920015
         DS    0D                                                       85960015
IGFDCB   EQU   *   ENTRY FOR 1ST LOAD MODULE                            86000015
COMENVCK DC    CL8'IGFASR0B'       1ST LOAD MODULE OF ASR               86040015
COMPDAR  EQU   *                   START PDAR AREA                      86080015
PDARSTAT DC    X'0'                                                     86120015
PDARTCB  DC    3X'0'                                                    86160015
PDARTAB  DC    8F'0'                                                    86170015
         AIF   (&MFTASR NE 1).M7                                        86180015
COMNEST  DC    V(IORGSW)           MFT-IOS-NEST SWITCH                  86190015
         AGO   .M8                                                      86200015
.M7      ANOP                                                           86210015
COMNEST  DC    V(IEA0IO01)         MVT-IOS NEST SWITCH                  86220015
.M8      ANOP                                                           86230015
PDARCUA  DC    9F'0'                                                    86240015
         AIF   (&MFTASR NE 1).M5                                        86245015
COMERXNT DC    V(IEAASNT2)         PTR TO ERROR XSNT AREA--MFT          86250015
         AGO   .M6                                                      86255015
.M5      ANOP                                                           86260015
COMERXNT DC    A(0)                                                     86265015
.M6      ANOP                                                           86270015
IGFMOD   EQU   *  1ST BYTE OF NEXT FIELD IS CPU MODEL NUMBER            86320015
COMCVT   DC    V(IEACVT)     ADDR OF CVT                                86360015
COMCHASG DC    V(IFBACTA)          POINTER TO CHANNEL ASSIGNMENT MODU   86400015
         AIF   (&MFTASR NE 1).M1                                        86440015
IGFRES   EQU   *                   ADDRESS OF MFT RAM                   86480015
COMRAM   DC    A(0)                                                     86520015
         AGO   .M2                                                      86560015
.M1      ANOP                                                           86600015
         DC    A(0)                                                     86640015
.M2      ANOP                                                           86680015
IGFBLDL  EQU   *                   ADDRESS OF BLDL                      86720015
COMBLDL  DC    A(0)                                                     86760015
IGFSVBLD EQU *            ADDRESS OF SVC BLDL                           86770000
COMSVBLD DC  A(0)                                                       86780000
IGFSVCQ  EQU   *                   ADDRESS OF QUEUE                     86800015
COMSVCQ  DC    A(0)                    OF RESIDENT 3 AND 4 SVCS         86840015
         AIF   (&MFTASR NE 1).M3                                        86880015
COMTRANS DC    V(IEAAXSNT)         MFT-NAME OF XSNT ROUTINE             86920015
         AGO   .M4                                                      86960015
.M3      ANOP                                                           87000015
COMERIOB DC    V(IEAERWA)          MVT-IOB FOR ERROR XSNT AREA          87040015
.M4      ANOP                                                           87080015
COMSBAD  DC    F'0'                ADDR OF FAILING STORAGE LOCATION     87090015
COMSIRB  DC    V(SIRB)             SYSTEM SIRB POINTER                  87100015
         DC    F'0'           SPARE  WORD                               87110000
IGFNUC01 EQU   *                   LIST OF REFRESHABLE NUCLEUS MODULES  87120015
         AIF   (&MFTASR NE 1).VMVT                                      87160015
         DC    F'0'                                                     87200015
         DC    V(IGC009)                                                87240015
         DC    F'0'                                                     87280015
         DC    F'0'                                                     87320015
         DC    X'FFFFFFFF'                                              87360015
         AGO   .C1                                                      87400015
.VMVT    ANOP                                                           87440015
         DC    F'0'               FILLER                           MP1  87441017
         DC    V(IGC043)           STAGE 1 EXIT EFFECTOR            MP1 87442018
         DC    F'0'               FILLER                           MP1  87443017
         DC    F'0'               FILLER                           MP1  87444017
         DC    V(IGC046)           SVC 46,47 TTIMER,STIMER          MP1 87445018
         DC    F'0'               FILLER                           MP1  87446017
         DC    F'0'               FILLER                           MP1  87447017
         DC    V(IGC011)           SVC 11, TIME ROUTINE             MP1 87448018
         DC    F'0'               FILLER                           MP1  87449017
         DC    F'0'               FILLER                           MP1  87450017
         DC    V(IEAQTI00)        TIMER SLIH                       MP1  87451017
         DC    F'0'               FILLER                           MP1  87452017
         DC    F'0'               FILLER                           MP1  87453017
         DC    V(IEEBA1)           ATTENTION INTERRUPT HANDLER      MP1 87454018
         DC    F'0'               FILLER                           MP1  87455017
         DC    F'0'               FILLER                           MP1  87456017
         DC    V(IEECVCTW)         COMMUNICATIONS TASK TCB          MP1 87457018
         DC    F'0'               FILLER                           MP1  87458017
         DC    F'0'               FILLER                           MP1  87459017
         DC    V(IEEBC1PE)         COMM. TASK EXT INTERRUPT HANDLER MP1 87460018
         DC    F'0'               FILLER                           MP1  87461017
         DC    F'0'               FILLER                           MP1  87462017
         DC    V(IEECVPRG)         WTOR PURGE ROUTINE               MP1 87463018
         DC    F'0'               FILLER                           MP1  87464017
         DC    F'0'                                                     87480015
         DC    X'FFFFFFFF'                                              87520015
.C1      ANOP                                                           87560015
*                                                                       87600015
         SPACE 1                                                        87640015
COMNUC   EQU   IGFNUC01+8          NUCLEUS DATA                         87680015
COMPSA   EQU   IGFNUC01+24         PERMANENT STORAGE SAVE AREA          87720015
COMSYSRS EQU   IGFNUC01+152        SYSRES ADDR AND DEVICE TYPE          87760015
COMCNSL  EQU   IGFNUC01+156        ACTIVE SYSTEM CONSOLE AND TYPE       87800015
COMIOQ   EQU   IGFNUC01+160        POINTER TO I/O INTERRUPT SAVE QUEUE  87840015
COMPRNT  EQU   IGFNUC01+164        ADDRESS OF CONSOLE PRINT ROUTINE     87880015
COMMSG0  EQU   IGFNUC01+168        CONSOLE PRINT ROUTINE                87920015
COMMSG1  EQU   IGFNUC01+184          MESSAGE BUFFERS                    87960015
COMEXADR EQU   IGFNUC01+200        EXECUTE INSTR ADDR FOR IRE           88000015
COMOBREX EQU   IGFNUC01+204                                             88060015
COMLEV0A EQU   IGFNUC01+208                                             88066015
COMLEV1A EQU   IGFNUC01+209                                             88072015
COMLEV0B EQU   IGFNUC01+210                                             88078015
COMLEV0C EQU   IGFNUC01+211                                             88084015
COMLEV1C EQU   IGFNUC01+212                                             88090015
COMLEV2C EQU   IGFNUC01+213                                             88096015
COMLEV3C EQU   IGFNUC01+214                                             88102015
COMLEV0D EQU   IGFNUC01+215                                             88108015
COMLEV1D EQU   IGFNUC01+216                                             88114015
COMLEV2D EQU   IGFNUC01+217                                             88120015
COMLEV00 EQU   IGFNUC01+218                                             88126015
COMLEV01 EQU   IGFNUC01+219                                             88132015
COMLEV02 EQU    IGFNUC01+220                                            88134000
COMLEV10 EQU   IGFNUC01+221                                             88138000
COMLEV20 EQU   IGFNUC01+222                                             88144000
COMMSF   EQU   IGFNUC01+223                                          MP 88164000
         SPACE 1                                                     MP 88184017
COMLEV2K EQU   IGFNUC01+224                                        2K   88194000
COMSPARE EQU   IGFNUC01+225                                        2K   88204000
         SPACE 3                                                        88240015
*****  A S R   R E C O R D   E N T R Y   B U I L D   A R E A  ********* 88280015
         SPACE 1                                                        88320015
CTFLDID  EQU   IGFDCB+406          COUNT FIELD                          88360021
CTFLDKEY EQU   CTFLDID+5           KEY LENGTH                           88400015
CTFLDDL  EQU   CTFLDID+6           DATA LENGTH FOR RECORD ENTRY         88440015
*                                                                       88480015
REKEY    EQU   CTFLDID+8           RECORD ENTRY KEY                     88520015
RELABEL  EQU   CTFLDID+10          LABEL                                88560015
REFORMT  EQU   CTFLDID+13          RECORD ENTRY FORMAT TYPE             88600015
REMODNUM EQU   CTFLDID+14          CPU MODEL NUMBER                     88640015
RETYPE   EQU   CTFLDID+15          TYPE OF ERROR                        88680015
RECTLIND EQU   CTFLDID+16          EREP CONTROL INDICATORS              88720015
REDATE   EQU   CTFLDID+18          DATE OF RECORD                       88760015
RETIME   EQU   CTFLDID+22          TIME OF RECORD                       88800015
REPROGID EQU   CTFLDID+26          ACTIVE PROGRAM ID                    88840015
REMCOPSW EQU   CTFLDID+34          MACHINE CHECK OLD PSW                88880015
REAIOU   EQU   CTFLDID+42          CH/UNIT ADR OF ACTIVE UNITS (MAX 8)  88920000
RECHASSG EQU   CTFLDID+58          CHANNEL TYPE ASSIGNMENTS             88960000
REENVCHK EQU   CTFLDID+66          ENVIRONMENT CHECK DATA               89000015
REROSCHK EQU   CTFLDID+74          ROS CHECK DATA                       89040015
REMEST   EQU   CTFLDID+98          MEMORY ERROR STATUS TABLE            89080015
REPDAR   EQU   CTFLDID+210         PROGRAM DAMAGE ASSESSMENT DATA       89120015
RERETRY  EQU   CTFLDID+234         INSTRUCTION RETRY DATA               89160015
ISUM1    EQU   CTFLDID+234         TABLE 1 AREA                         89200015
ISUMFAIL EQU   CTFLDID+236         FAILING INSTRUCTION                  89240015
ISUM2    EQU   CTFLDID+242         TABLE 2 AREA                         89280015
ISUMROS  EQU   CTFLDID+244         ROS ADDRESS                          89320015
ISUMFADR EQU   CTFLDID+246         FAILING INSTRUCTION ADDRESS          89360015
ISUMBAL  EQU   CTFLDID+250         ALT INSTR ADDR OR BAL                89400015
ISUMBAD  EQU   CTFLDID+254         BAD OPERAND ADDRESS                  89440015
REGSGPR  EQU   CTFLDID+258         GPR CONTENTS                         89480015
REGSFPR  EQU   CTFLDID+322         FPR CONTENTS                         89520015
REGPARGP EQU   CTFLDID+354         GPR PARITY INDICATORS                89560015
REGPARFP EQU   CTFLDID+362         FPR PARITY INDICATORS                89600015
TEMPSPRE EQU   CTFLDID+366         TEMPROAY SPARE TO INSURE DBLWRD      89640015
RECPULOG EQU   CTFLDID+370         CPU HARDWARE LOGOUT AREA             89680015
*                                                                       89720015
*****  E X P A N S I O N   A R E A   F O R   L O G O U T  ************* 89760015
*                                                                       89800015
RESPARE  EQU   CTFLDID+546                                              89840015
*                                                                       89880015
*                                                                       89920015
*                                                                       89960015
*                                                                       90000015
*****    C H A N N E L  I N B O A R D  R E  P O S I T I O N S     ***** 90040015
*                                                                       90080015
*  THESE POSITIONS ARE USED WHEN HANDLING A  CHANNEL INBOARD ERROR,     90120015
*  WITH ASR IN THE SYSTEM, BUT NO CCH.  ASR FORMS AND RECORDS A SER-    90160015
*  TYPE RECORD VIA ITS ERROR RECORDER MODULE.                           90200015
         SPACE 2                                                        90240015
RECCW1   EQU   RELABEL+24          FIRST CCW OF FAILING CHAIN           90280015
RECCW2   EQU   RELABEL+32          FAILING CCW                          90320015
RECSW    EQU   RELABEL+40          CHANNEL STATUS WORD                  90360015
REACTIO  EQU   RELABEL+48          ACTIVE I/O UNITS                     90400015
RECHASG  EQU   RELABEL+64          CHANNEL TYPE ASSIGNMENTS             90440000
REERPIB  EQU   RELABEL+72                                            MP 90460017
RECUA    EQU   RELABEL+80                                            MP 90480017
RECHSTAT EQU   RELABEL+82                                            MP 90500017
REIOLOG  EQU   RELABEL+84                                            MP 90520017
         SPACE 1                                                        90560015
         ORG   IGFDCB+1024                                              90600015
COMDCB   EQU   COMENVCK                                                 90640015
LOGJE    EQU   RECPULOG+66                                         MP1  90650017
LOGVD    EQU   RECPULOG+12                                         MP1  90660017
TAVD     EQU   COMNUC+8                                            MP   90670017
LOG4     EQU   RECPULOG+4                                          M67  90675020
         EJECT                                                          90676020
UCMDSECT DSECT                                                     1450 90677020
         IEECUCM                                                        90678020
         MEND                                                           90680015
