         MACRO                                                          00100019
         IGFDDR  &MCS                                                   00200019
         SPACE 2                                                        00280019
IGFDDRSR CSECT                                                          00370019
         SPACE 2                                                        00380019
*********************************************************************** 00400019
*                                                                     * 00500019
*                                                                     * 00600019
*                            SYSRES DDR                               * 00700019
*                                                                     * 00800019
*                                                                     * 00900019
*********************************************************************** 01000019
*                                                                     * 01100019
*                                                                     * 01200019
*STATUS                                                               * 01202019
*                                                                     * 01204019
*     RELEASE 21.8                                                      01206021
*                                                                     * 01208019
*FUNCTION                                                             * 01210019
*                                                                     * 01212019
*   TO RECOVER SVC FETCH OPERATIONS BY SWAPPING SYSRES TO ANOTHER     * 01214019
*   DEVICE,AND TO PERFORM SWAP AT THE REQUEST OF THE OPERATOR.VERY    * 01216019
*   BRIEFLY SPEAKING,THE OPERATIONS ARE AS FOLLOWS,                   * 01218019
*   1) TIE UP SYSRES UCB,                                             * 01220019
*   2) LOCK OUT ALLOCATION,                                           * 01222019
*   3) TEST AND TIE UP 'TO' DEVICE,                                   * 01224019
*   4) SWAP UCB INFORMATION,ETC.,                                     * 01226019
*   5) WRITE MESSAGES TO OPERATOR,                                    * 01228019
*   6) VERIFY VOLID AFTER A SWAP,                                     * 01230019
*   7) RECYCLE THE SWAP,IF NECESSARY.                                 * 01232019
*                                                                     * 01234019
*ENTRY POINTS                                                         * 01236019
*                                                                     * 01238019
*   FOR SYSTEM INITIATED SWAP,FROM IEAATC00 IN MFT,FROM IEAQTR33 OR   * 01240019
*   IEAQNU00 IN MVT,FROM IEAQTAMP OR IEAQNU00 IN MP.                  * 01242019
*   FOR OPERATOR INITIATED SWAP,FROM IGFDDR01.                        * 01244019
*   FROM ALL THESE CALLING ROUTINES,THE ENTRY POINT IS                * 01246019
*        IGFDDRSR                                                       01248019
*   FOR SYSTEM INITIATED SWAP,THE RESIDENT DISK ERP ALSO CALLS SYSRES * 01250019
*   DDR.THE ENTRY POINT IS                                            * 01252019
*        IGFDDR05                                                     * 01254019
*                                                                     * 01256019
*EXTERNAL REFERENCES                                                  * 01258019
*                                                                     * 01260019
*   RQE USED EXCLUSIVELY BY SYSRES DDR                                * 01262019
*        DDRRQESR                                                     * 01264019
*   DDR APPENDAGE VECTOR TABLE IN IOS                                 * 01266019
*        DDRAPNVT                                                     * 01268019
*   I/O ERROR RECYCLE COUNT UPDATED BY IEAATC00 OR IEAQNU00           * 01270019
*        ERCOUNT                                                      * 01272019
*   SAVE AREA IN IOS FOR THE UCB OF 'TO' DEVICE CANDIDATE             * 01274019
*        DDRSRTO                                                      * 01276019
*   FIRST TCB OF THE TCB CHAIN                                        * 01278019
*        IEAHEAD                                                      * 01280019
*                                                                     * 01282019
*INPUT                                                                * 01284019
*                                                                     * 01286019
*   FROM IGFDDR01 REGISTER 11 POINTS TO DDR COMM AREA                 * 01288019
*                                                                     * 01290019
*OUTPUT                                                               * 01292019
*                                                                     * 01294019
*   MESSAGES                                                          * 01296019
*                                                                     * 01298019
*EXITS,NORMAL                                                         * 01300019
*   TO CALLER WITH RETURN CODE 0 IN REGISTER 15,INDICATING SWAP DONE  * 01302019
*                                                                     * 01304019
*EXITS,ERROR                                                          * 01306019
*                                                                     * 01308019
*   TO CALLER WITH RETURN CODE 4 IN REGISTER 15,INDICATING SWAP FAILED* 01310019
*                                                                     * 01312019
*TABLES/WORK AREA                                                     * 01314019
*                                                                     * 01316019
*   THE TABLES USED ARE CVT,IORMS COMM AREA,UCM BASE,UCM PREFIX,      * 01318019
*   UCM BASE,UCM ENTRY,AND DCM.                                       * 01320019
*   WORK AREA INCLUDES ONE BYTE OF SWITCHES.                          * 01322019
*                                                                     * 01324019
*ATTRIBUTES                                                           * 01326019
*   DISABLED,SUPERVISOR MODE,PROTECTION KEY 0,SERIALLY REUSABLE,      * 01328019
*   AND RESIDENT.                                                     * 01330019
*                                                                     * 01332019
*NOTES                                                                * 01334019
*                                                                     * 01336019
*   IBM I/O RECOVERY STANDARDS ARE NOT FOLLOWED DUE TO THE FACT THAT  * 01338019
*   SYSRES IS NOT ACCESSIBLE DURING THE SWAP OPERATION                * 01340019
*                                                                     * 04100019
*                                                                     * 04200019
*********************************************************************** 04300019
         EJECT                                                          04400019
*********************************************************************** 04500019
*                                                                     * 04600019
*                            ENTRY POINTS                             * 04700019
*                                                                     * 04800019
*********************************************************************** 04900019
   SPACE    1                                                           05000019
         ENTRY IGFDDR05            SYSRES DDR COUNT ROUTINE             05100019
         ENTRY IGF0IOB             IOB ADDR                             05200019
         ENTRY IGF0DEB             DEB ADDR                             05300019
   SPACE    1                                                           05400019
*********************************************************************** 05500019
*                                                                     * 05600019
*                              REGISTERS                              * 05700019
*                                                                     * 05800019
*********************************************************************** 05900019
   SPACE    1                                                           06000019
RG0      EQU   0                   REGISTER 0                           06100019
RQERG    EQU   1                   PTS TO SYSRES DDR RQE                06200019
RG1      EQU   1                   REG 1                                06250019
IOBRG    EQU   2                   POINTS TO IOB                        06300019
DEBRG    EQU   3                   PTS TO A DEB                         06400019
CVTRG    EQU   3                   PTS TO CVT                           06500019
WORKRG2  EQU   4                        SECOND WORK REGISTER            06600019
WORKRG3  EQU   5                        THIRD WORK REGISTER             06700019
         AIF   (&MCS NE 1).AB1                                          06900019
MSGPTR   EQU   2                   PTS TO A MESSAGE                     07000019
.AB1     ANOP                                                           07100019
FROMUCB  EQU   6                   SYSRES UCB PTR                       07200019
RG6      EQU   6                   REGISTER 6                           07250019
UCBRG    EQU   7                   PTS TO A UCB                         07300019
UCMPTR   EQU   8                   PTS TO UCM BASE                      07400019
MCSPTR   EQU   8                   PTS TO MCS PREFIX                    07500019
LINKRG   EQU   8                        MAIN LINKRG                     07550019
DCMPTR   EQU   9                   PTS TO DCM                           07600019
LINKRG1  EQU   9                   SECOND LINKRG                        07700019
WORKRG4  EQU   10                  WORK REGISTER                        07800019
UCMENTRY EQU   10                  PTS TO A UCM ENTRY                   07900019
COUNT    EQU   10                  COUNT REG USED IN APPENDAGES         08000019
DDRCMPTR EQU   11                  DDR COMM AREA PTR                    08100019
WORKRG5  EQU   11                  WORK REGISTER IN COUNT ROUTINE       08200019
VTABPTR  EQU   11                                                       08250019
BASE     EQU   12                  BASE REGISTER                        08300019
WORKRG1  EQU   13                  MAIN WORK REG                        08370019
RG13     EQU   13                  REG 13                               08450019
TDCMPTR  EQU   13                  GRAPHICS TRANSIENT DCM PTR           08500000
LINKRG2  EQU   14                  SECOND LINK REG                      08520019
RTN      EQU   14                  RETURN REGISTER                      08600019
RG15     EQU   15                  REGISTER 15                          08650019
         AIF   (&MCS  NE  0).AB2                                        08700019
MSGPTR   EQU   15                  PTS TO A MESSAGE                     08800019
.AB2     ANOP                                                           08900019
         EJECT                                                          09000019
*********************************************************************** 09100019
*                       UCB FLAGS AND OFFSETS                         * 09200019
*********************************************************************** 09300019
   SPACE    1                                                           09400019
UCBFL1   EQU   6                   UCB FLAG FLD OFFSET                  09700019
UCBNAME  EQU   13                  EBCIDIC UNIT NAME FLD OFFSET         09900019
UNITYP   EQU   16                  UNIT TYPE FLD OFFSET                 10000019
UCBSNS   EQU   22                  UCB SENSE FLD                        10200019
SRTEVOLI EQU   28                  UCB VOLID FLD OFFSET                 10300019
UCBNRY   EQU   X'40'               UCB NOT READY FLAG                   10400019
UCBERR   EQU   X'01'               UCB ERROR FLAG                       10500019
   SPACE    1                                                           10600019
*********************************************************************** 10700019
*                       IOB FLAGS AND OFFSETS                         * 10800019
*********************************************************************** 10900019
  SPACE 1                                                               11000019
IOBFL1   EQU   0                   IOB FLAG 1 OFFSET                    11100019
IOBCOD   EQU   4                   IOB ECB CODE FLD OFFSET              11200019
IOBCSW   EQU   9                   IOB CSW FLD                          11300019
IOBSIOCC EQU   16                  SIO CONDITION CODE                   11400019
IOBURL   EQU   X'02'               IOB UNRELATED FLAG                   11500019
IOBEX    EQU   X'04'               EXEPTIONAL CONDITION                 11600019
DEBTCB   EQU   0                   OFFSET OF TCB FLD IN DEB             11700019
  SPACE 1                                                               11800019
*********************************************************************** 11900019
*                       WORK SWITCHES                                 * 12000019
*********************************************************************** 12100019
  SPACE 1                                                               12200019
WTO      EQU   X'80'               SWITCH FOR WTO REQUEST               12300019
NOP      EQU   X'40'               SWITCH FOR NOP REQUEST               12400019
READD    EQU   X'20'               SWITCH FOR READ REQUEST              12500019
SWAPP    EQU   X'10'               SWITCH FOR SWAPP REQUEST             12600019
OPFIRST  EQU   X'08'               FIRST OPER.SWAP RECOVERY             12700019
SCNDNTRY EQU   X'04'               APPENDAGE 2ND ENTRY SWITCH           12800019
INTERVN  EQU   X'02'               INTERVENTION REQUIRED                12900019
HARDCOPY EQU   X'01'               HARD COPY SWITCH                     13000019
         EJECT                                                          13100019
*********************************************************************** 13200019
*                       MISCELLANEOUS MASKS AND OFFSETS               * 13300019
*********************************************************************** 13400019
     SPACE  2                                                           13500019
ZERO     EQU   0                   OFFSET 0                             13600019
O        EQU   0                   ZERO                                 13630019
EXCP     EQU   0                   ZERO                                 13660019
L1       EQU   1                   ONE                                  13710019
I        EQU   1                   ONE                                  13760019
II       EQU   2                   TWO                                  13810019
L2       EQU   2                   TWO                                  13820019
L3       EQU   3                   THREE                                13840019
III      EQU   3                   THREE                                13850019
FOUR     EQU   4                   CURRENT TCB OFFSET                   13900019
IV       EQU   4                   FOUR                                 13930019
L4       EQU   4                   FOUR                                 13960019
FIVE     EQU   5                   FETCH RECYCLE COUNT                  14000019
V        EQU   5                   FIVE                                 14010019
L6       EQU   6                   SIX                                  14020019
VII      EQU   7                   SEVEN                                14030019
EIGHT    EQU   8                   DECIMAL 8                            14050019
NOTZERO  EQU   7                                                        14051019
OFF      EQU   8                                                        14052019
ON       EQU   1                                                        14053019
HEADTCB  EQU   160                 ADDRESS OF FIRST TCB IN SYSTEM       14055019
VIII     EQU   8                   EIGHT                                14060019
L8       EQU   8                   EIGHT                                14070019
TEN      EQU   10                  TEN TIMES                            14100019
XII      EQU   12                  DECIMAL 12                           14108019
XVI      EQU   16                  DECIMAL 16                           14116019
XXVIII   EQU   28                  DECIMAL 28                           14124019
XSTAB    EQU   10                  STATUS AND ATTRIBUTE BYTES OFFSET    14132019
XVIII    EQU   18                  DECIMAL 18                           14140019
XX       EQU   20                  DECIMAL 20                           14148019
XXV      EQU   25                  DECIMAL 25                           14156019
XXXII    EQU   32                  DECIMAL 32                           14164019
XL       EQU   40                  DECIMAL 40                           14172019
D0       EQU   X'D0'              TRANSIENT SVRB MASK                   14182020
LII      EQU   52                  DECIMAL 52                           14190019
PERMEROR EQU   X'41'               PERM I/O ERROR                       14300019
CC3      EQU   X'30'               CONDITION CODE 3                     14600019
GRAPHICS EQU   X'10'               GRAPHIC DEVICE                       14800019
NONDISP  EQU   1                   ALLOCATION NON-DISPATCHABLE          15000019
ACTIVE   EQU   X'10'               DEVICE IS ACTIVE                     15400019
A2311    EQU   X'01'                   2311 DEV TYPE MASK         00226 15450021
A2321    EQU   X'05'                   2321 DEV TYPE MASK         00226 15460021
A2314    EQU   X'08'               DASD,2314                            15500021
FF       EQU   X'FF'               HEX FF                               15600019
COMPLET  EQU   X'7F'               ECB COMPLETION CODE                  15700019
RQEUCB   EQU   2                   RQE UCB FLD OFFSET                   15900019
RQETCB   EQU   13                  RQE TCB FLD OFFSET                   16300019
TCBDSP   EQU   35                  TCB DISPATCHING PRIORITY FLD OFFSET  16500019
TCBPKE   EQU   28                  TCB PROTECTION KEY FLD OFFSET        16600019
TCBFLGS  EQU   33                  DECIMAL 33                           16700019
UNITRCOD EQU   X'08'               UNIT RECORD DEVICE                   17000019
MFT      EQU   X'20'               MFT FLAG IN CVT                      17100019
NIPIN    EQU   X'10'                                                    17150019
Z        EQU   X'E9'               CHARACTER Z                          17210019
CHANCHK  EQU   X'0F'             CHANNEL CHECKS BIT SETTING             17220019
EROREXCP EQU   15                  DECIMAL 15                           17230019
ZEROFOX  EQU   15                  HEX F                                17240019
SIRB     EQU   X'80'               BIT SETTING FOR SIRB                 17250019
UNITYPII EQU   UNITYP+III                                               17251019
UNITYPI  EQU   UNITYP+II                                                17252019
RQETCBF  EQU   12                  TCB FLD OFFSET IN RQE                17253019
IOBCSW2  EQU   IOBCSW+III                                               17254019
IOBCSW3  EQU   IOBCSW+IV                                                17255019
INTREQ   EQU   X'40'           BIT SETTING FOR INTERVENTION-REQUIRED    17260019
TCBRG12  EQU   97                  REG 12 SAVE AREA OFFSET              17265019
TCBRG14  EQU   105                 REG 14 SAVE AREA OFFSET              17270019
RBOPSW   EQU   21                  RESUME PSW FLD IN RB                 17275019
RBWCT    EQU   28                  RB WAIT COUNT FLD                    17280019
XXIV     EQU   24                                                       17285019
OPSWAP1  EQU   X'01'               OP INIT NOP PREEMPTION SWITCH        17288019
OPSWAP2  EQU   X'02'               OP INIT READ PREEMPTION SWITCH       17291019
VOLID    EQU   X'04'               WHEN ON, VOLID'S DO NOT MATCH        17294019
N1       EQU   1                                                        17294121
N2       EQU   2                                                        17294221
N3       EQU   3                                                        17294321
N19      EQU   19                                                       17300121
N26      EQU   26                                                       17307221
N228     EQU   228                                                      17313021
N0       EQU   0                                                        17318821
TCBADDR  EQU   4                 REG 4  ADDR ALLOC TCB                  17324621
TJBSIZE  EQU   4                  REG 4  TJB SIZE                       17330421
TJOBID   EQU   5                  REG 5  TJID OF TSO TASK               17336221
TJBADDR  EQU   13                 REG 13  BASE FOR TJB DSECT            17342021
TSCVTPTR EQU   13                 REG 13  TSO CVT PTR                   17347821
R5       EQU   5                  REG 5   =TJB SIZE X TJID              17353621
TCBFLGS5 EQU   33                 DISPL FOR PRIMARY NON DISP BIT        17359421
TCBNDSP1 EQU   173                DISPL FOR OTHER NON-DISP BITS         17365221
TSOREADY EQU   X'80'              TSO READY BIT                         17371021
NDCTL    EQU   X'01'              TCB PRIMARY NON-DISP BIT              17376821
TCBDDRND EQU   X'08'              TCB NON-DISP BIT FOR DDR              17382621
DDRXCPSR EQU   36                                                       17388421
         EJECT                                                          17394221
*********************************************************************** 17400019
*                                                                     * 17500019
*                  SYSRES EFFECTOR                                    * 17600019
*                                                                     * 17700019
*********************************************************************** 17800019
   SPACE  2                                                             17900019
         USING *,RG15              USE REG 15 AS TEMPORARY BASE         17970019
         STM   RG0,RTN,REGSAVE     SAVE REGISTERS                       18040019
         BALR  BASE,RG0            SET UP BASE REG                      18110019
         USING *,BASE              USE REGISTER 12 AS BASE              18400019
  SPACE  1                                                              18500019
IGF100   NI    SYSFLG1,ZERO        INITIALIZE SWITCHES                  18600019
         MVI   SWAPCNT,EIGHT       INITIALIZE SWAP COUNT                18700019
         L     CVTRG,CVTPTR        PICK UP PT TO CVT                    18800019
         USING IGF00CVT,CVTRG           SET CVT ADDRESSABILITY          18900019
         L     WORKRG1,CVTDCB      PICK UP PT TO LOGREC DCB             19000019
         L     DDRCMPTR,O(WORKRG1)  REG 11 PTS TO DDR COMM AREA         19100019
         USING IORMS,DDRCMPTR      USE REG 11 AS IORMS DSECT BASE       19200019
   SPACE  1                                                             19300019
*                                                                       19310021
*       PREVENT ALLOCATION FROM PROCESSING                              19320021
*      DETERMINE IF ALLOCATION IS ACTIVE                                19330021
*        IF NO INITIALIZE ALLOC. ECB SO ALLOCATION WILL WAIT            19340021
*        IF YES,DDR OR TSO SUPERVISOR SETS TCB IN ALLOC. NON-DISP.      19350021
*                                                                       19360021
IGF101    NC    ALLOCTCB+N1(N3),ALLOCTCB+N1  DID ALLOC STORE A TCB      19370021
          BNZ   CHKTSO                        YES,IS IT A TSO TASK      19380021
*                                                                       19390021
ZEROECB   EQU   *                             INITIALIZE ALLOC ECB      19400021
*                                                                       19410021
          MVI   ALLOCECB,ZERO              ALLOC WILL WAIT ON THIS ECB  19420021
          B     IGF102             GO GET SYSRES UCB                    19430021
*                                                                       19440021
CHKTSO    EQU   *                IS TSO TASK IN ALLOCATION              19450021
*                                                                       19460021
         NC    ALLOTJID(N2),ALLOTJID                        IS TASK TSO 19470021
         BZ    SETNDISP           NO,SET IT NON-DISP                    19480021
         TM    N228(CVTRG),TSOREADY      YES,IS TSO READY               19490021
         BZ    ZEROECB            NO,THEN ZERO ALLOC. ECB               19500021
*                                                                       19510021
*      TSO IS READY. LOCATE TJB FOR TSO TASK                            19520021
*                                                                       19530021
         L     TSCVTPTR,N228(CVTRG)    GET TSO CVT PTR                  19540021
         LH    TJBSIZE,N26(TSCVTPTR)   GET TJBSIZE                      19550021
         N     TJBSIZE,ZEROHIGH        CLEAR 2 H.O. BYTES               19560021
         MH   TJBSIZE,ALLOTJID        TJB SIZE  X  TJID                 19570021
         A     TJBSIZE,N0(TSCVTPTR)      + TJB TABLE ORIGIN             19580021
         LR    TJBADDR,TJBSIZE           = TJB ADDR                     19590021
         ST    TJBADDR,TJBSAVE          SAVE TJB ADDRESS                19600021
*                                                                       19610021
         USING TJB,TJBADDR         MAKE TJB ADDRESSABLE                 19620021
         TM    TJBSTAT,TJBINCOR         IS TASK IN CORE                 19630021
         BZ    TSOSETND           NO,TELL TSO WHAT TO DO                19640021
*                                                                       19650021
*      TASK IS IN CORE DDR WILL SET IT NON DISPATCHABLE                 19660021
*                                                                       19670021
         L      TCBADDR,ALLOCTCB     GET TCB ADDR                       19680021
         OI    TCBFLGS5(TCBADDR),NDCTL  SET PRIMARY NON-DISP BIT        19690021
         OI    TCBNDSP1(TCBADDR),TCBDDRND  SET BIT FOR DDR              19700021
*                                                                       19710021
         TSEVENT ENQWAIT,TJID=(TJOBID) TSO SWAP TASK OUT NOW ID  21048  19720021
         B     IGF102             GO GET SYSRES UCB                     19730021
*                                                                       19740021
TSOSETND EQU   *                                                        19750021
*                                                                       19760021
*                                                                       19770021
*      TSO WILL SET TASK NON-DISP IF IT IS PUT INTO CORE                19780021
*                                                                       19790021
         OI    TJBRSTOR,TJBDDRND  INFORM TSO RESTORE MODULE             19800021
         B     IGF102             GO GET SYSRES UCB                     19810021
*                                                                       19820021
SETNDISP EQU   *                  DDR WILL SET TASK NON-DISP.           19830021
         L     TCBADDR,ALLOCTCB   GET ALLOC TCB ADDR                    19840021
         OI    TCBFLGS5(TCBADDR),NDCTL  SET PRIMARY BIT                 19850021
         OI    TCBNDSP1(TCBADDR),TCBDDRND  SET BIT FOR DDR              19860021
*                                                                       19870021
   SPACE  1                                                             20000019
IGF102   L     FROMUCB,CVTSYSAD    PICK UP SYSRES UCB                   20100019
         MVC   MSG1B(L3),UCBNAME(FROMUCB)  SET MSG1 'FROM' ADDR         20200019
         C     DDRCMPTR,RG11SAV    IS SWAP OPERATOR INITIATED           20300019
         BNE   IGF111              NO,BRANCH OUT                        20400019
         LA    LINKRG,IGF107       YES,SET UP LINK REGISTER             20500019
         OI    SYSFLG2,OPSWAP1     SET OP INIT NOP PREEMPT SWITCH       20550019
         LR    UCBRG,FROMUCB       REG 7 PTS TO SYSRES UCB              20600019
   SPACE  1                                                             20700019
IGF103   LA    WORKRG1,NOPCCW      PICK UP NOP CCW                      20800019
         OI    SYSFLG1,NOP         SET INDICATOR FOR APPENDAGES         20900019
         L     WORKRG2,ADDRSRTO    PICK UP UCB SAVE AREA ADDR IN IOS    21000019
         STH   UCBRG,O(WORKRG2)    SAVE 'TO' CANDIDATE UCB ADDR FOR IOS 21100019
  SPACE 1                                                               21200019
IGF104   ST    WORKRG1,IOBSTART    SET IOB START FLD                    21300019
IGF105   LA    WORKRG2,TEN         INITIALIZE SIO CC 3 RETRY COUNTER    21400019
IGF105A  STH   UCBRG,DEBUCB        SET DEB UCB FLD                      21500019
         L     WORKRG1,CVTTCBP     PICK UP NEW AND CURRENT TCB FLD PTR  21600019
         MVC   DEBTCBAD(L3),V(WORKRG1)  SET DEB TCB FLD                 21800019
         MVI   COUNTSAV,TEN        RESET APPENDAGE RETRY COUNTER        22200019
         NI    IGF0ECB,ZERO        RE-INITIALIZE ECB                    22300019
         TM    SYSFLG1,WTO         IS I/O FOR WTO                       22400019
         BCR   I,LINKRG            YES,RETURN TO CALLING SUBROUTINE     22500019
     SPACE 2                                                            22600019
         L     RQERG,IGF0RQE       PICK UP SYSRES RQE ADDR              22700019
         TM    CVTDCB,MFT          IS THIS AN MFT SYSTEM                22800019
         BO    IGF105B             YES,SKIP NEXT INSTRUCTION            22900019
         MVC   RQETCB(L3,RQERG),V(WORKRG1)  SET RQE TCB FLD             23000019
IGF105B  STH   UCBRG,RQEUCB(RQERG) SET RQE UCB FLD                      23100019
         NI    SYSFLG1,FF-SCNDNTRY-INTERVN  RESET SWITCHES              23200019
   SPACE    1                                                           23300019
         SVC   EROREXCP            ISSUE ERROR EXCP                     23400019
   SPACE    1                                                           23500019
         TM    SYSFLG1,SWAPP       IS SWAP SWITCH ON                    23600019
         BCR   I,LINKRG            YES,RETURN TO CALLING SUBROUTINE     23700019
   SPACE  1                                                             23800019
IGF106   WAIT  ECB=IGF0ECB         WAIT ON I/O                          23900019
   SPACE  2                                                             24000019
*   REGAINING CONTROL AFTER COMPLETION OF I/O                           24010019
         SPACE 1                                                        24020019
         NI    SYSFLG2,FF-OPSWAP1  TURN OFF NOP PREEMPT SWITCH          24080019
IGF106B  SSM   BUFADR              DISABLE I/O INTERRUPT AGAIN          24150019
         TM    IOBSIOCD,CC3    IS SIO CONDITION CODE 3                  24300019
         BNO   IGF106A             NO,BRANCH OUT                        24400019
         BCT   WORKRG2,IGF105A     YES,RETRY 10 TIMES                   24500019
IGF106A  L     WORKRG2,ADDRSRTO    PICK UP UCB SAVE AREA ADDR IN IOS    24560019
         XC    0(2,WORKRG2),0(WORKRG2)   RESET UCB SAVER IN IOS         24660019
         NI    SYSFLG1,FF-NOP-READD-WTO  TURN OFF SWITCHES              24800019
         CLI   IGF0ECB,COMPLET     IS I/O SUCCESSFUL                    24900019
         BR    LINKRG              RETURN TO CALLING SUBROUTINE         25000019
     SPACE  1                                                           25100019
IGF107   LH    UCBRG,DDRTOUCB      PICK UP OPERATOR SPECIFIED UCB       25200019
         BNE   IGF215              I/O ERROR BRANCH OUT                 25260020
         OI    SYSFLG2,OPSWAP2     SET OP INIT READ PREEMPT FLAG        25320020
   SPACE  1                                                             25400019
IGF108   BAL   LINKRG,IGF103       GO TO TEST 'TO' DEVICE               25500019
         BE    IGF109              I/O SUCCESSFUL,GO TO SWAP UCB INFO   25600019
         C     DDRCMPTR,RG11SAV    IS SWAP OPERATOR INITIATED           25700019
         BNE   IGF204A             NO,READY QUIT                        25800021
         NI    UCBFL1(FROMUCB),FF-UCBERR  RESET UCBERR ON SYSRES        25850021
         B     IGF215              GET READY TO QUIT                    25860021
   SPACE  1                                                             26200019
IGF109   LA    LINKRG1,IGF114      SET UP 2ND LINK REG                  26300019
IGF109A  STH   UCBRG,IGFTOUCB      SET UP 'TO' SWAP PARAMETER           26400019
         STH   FROMUCB,IGFRMUCB    SET 'FROM' UCB FLD FOR SWAP          26500019
IGF110   OI    SYSFLG1,SWAPP       SET SWITCH FOR SWAP                  26600019
         BAL   LINKRG,IGF105A      GO TO SWAP UCB INFO                  26700019
         NI    SYSFLG1,FF-SWAPP    TURN OFF SWITCH FOR SWAP             26800019
         OI    UCBFL1(UCBRG),UCBERR  TIE UP FOR POSSIBLE RECOVERY       26850019
         BR    LINKRG1             RETURN TO CALLING SUBROUTINE         26900019
   SPACE  1                                                             27000019
IGF111   TM    SYSFLG2,OPSWAP1     WAS OP INIT NOP PREEMPTED            27010019
         BZ    IGF111B             NO, BRANCH OUT                       27020019
         LR    UCBRG,FROMUCB       PUT SYSRES UCB ADDR IN REG 7         27030019
         BAL   LINKRG1,IGF110      GO TO DEQUEUE THE RQE                27040019
IGF111B  TM    SYSFLG2,OPSWAP1+OPSWAP2  WAS NOP OR READ PREEMPTED       27043019
         BZ    IGF111A             NO, BRANCH OUT                       27046019
         L     WORKRG1,RMSTCB      PICK UP DDR TCB ADDR                 27050019
         L     WORKRG2,O(WORKRG1)  PICK UP DDR RB ADDR                  27060019
         MVC   TCBRG12(3,WORKRG1),TCBRG14(WORKRG1)  FIX UP REG 12       27070019
         MVC   RBOPSW(3,WORKRG2),TCBRG14(WORKRG1)  FIX UP RESUME PSW    27080019
         NI    RBWCT(WORKRG2),ZERO   FIX UP WAIT COUNT                  27090019
         MVI   DDRFLGSB,EIGHT  SET CODE FOR DDR SVC                     27100019
         NI    DDRFLGSD,FF-DDRMSG  TURN OFF DDR MSG SWITCH              27110019
         TM    SYSFLG2,OPSWAP2     WAS OP INIT READ PREEMPTED           27112019
         BZ    IGF111A              NO, BRANCH OUT                      27114019
         NI    DDRFLGSD,FF-SYSRESBR  CONSIDER OP INIT COMPLETED         27116019
IGF111A  LH    UCBRG,ALTCUASR+II   PICK UP ALTERNATE UCB ADDR           27120019
         CR    FROMUCB,UCBRG       IS THERE AN ALT DEVICE               27200019
         BE    IGF109              NO,SWAP TO ITSELF                    27400021
*   VALIDATE ALT SYSRES                                                 27450021
         CLI   UNITYPII(UCBRG),A2311  IS DEVICE A 2311                  27460021
         BE    IGF111A1            YES, 2311- USE IT                    27470021
         CLI   UNITYPII(UCBRG),A2321  IS DEVICE A 2321                  27480021
         BE    IGF111A1            YES,CONTINUE DDR                     27490021
         CLI   UNITYPII(UCBRG),A2314  IS DEVICE A 2314 OR 3330          27492021
         BL    IGF204A             NO, QUIT                             27494021
IGF111A1 CLC   N19(N1,FROMUCB),N19(UCBRG)  ARE DRIVES THE SAME          27496021
         BNE   IGF204A             NO,QUIT                              27498021
         B     IGF108              YES, GO TEST ALT SYSRES              27498421
   SPACE  1                                                             27500019
IGF114   MVC   MSG1C(L3),UCBNAME(FROMUCB)  MOVE 'TO' ADDR TO MSG1       27600019
         LA    MSGPTR,MSG1A        SET MSGPTR                           27700019
         EJECT                                                          27800019
*********************************************************************** 27900019
*                                                                     * 28000019
*                  NOTIFY OPERATOR                                    * 28100019
*********************************************************************** 28200019
   SPACE  2                                                             28300019
IGF200   L     UCMPTR,CVTCUCB      PICK UP UCM BASE                     28400019
         USING UCMBASE,UCMPTR      DSECT ADDRESSABILITY FOR UCM BASE    28500019
         USING UCMNTRY,UCMENTRY    DSECT ADDRESSABILITY FOR UCM ENTRY   28600019
         AIF   (&MCS NE 1).A201                                         28700019
         LA    WORKRG1,FOUR        PUT 4 IN WORK REG                    28800019
         SR    UCMPTR,WORKRG1      SUBTRACT UCMPTR BY 4                 28900019
         L     MCSPTR,O(UCMPTR)    PICK UP UCM PREFIX PT                29000019
         USING UCMPRFIX,MCSPTR     DSECT ADDRESSABILITY FOR UCM PREFIX  29100019
         L     UCMENTRY,UCMMCENT   PICK UP MASTER CONSOLE UCM ENTRY     29200019
         SPACE 1                                                        29300019
         AGO   .A202                                                    29400019
  SPACE  1                                                              29500019
.A201    ANOP                                                           29600019
IGF201   L     UCMENTRY,UCMVEA     NO,PICK UP FIRST UCM ENTRY           29700019
         L     WORKRG2,UCMVEZ      PICK UP UCM ENTRY SIZE               29800019
         L     WORKRG3,UCMVEL      PICK UP LAST UCM ENTRY               29900019
         SPACE 1                                                        30000019
.A202    ANOP                                                           30100019
IGF202   TM    UCMATR,ACTIVE       IS THIS CONSOLE ACTIVE               30200019
         BO    IGF206              YES,GO TO USE IT                     30300019
         SPACE 1                                                        30400019
         AIF   (&MCS  NE  1).A203                                       30500019
IGF209   CLC   UCMMCENT(L4),UCMALTEN  IS MASTER CNSL CHAIN EXHAUSTED    30600019
         BE    IGF204              YES,READY TO QUIT                    30700019
         L     UCMENTRY,UCMALTEN   NO,PICK UP ITS ALTERNATE             30800019
         B     IGF202              TRY TO WRITE ON IT                   30900019
         AGO   .A204                                                    31000019
.A203    ANOP                                                           31100019
IGF203   BXLE  UCMENTRY,WORKRG2,IGF202  NO,GET NEXT UCM ENTRY           31200019
.A204    ANOP                                                           31300019
   SPACE  1                                                             31400019
IGF204   LH    UCBRG,IGFTOUCB      PICK UP 'TO' UCB ADDR                31500019
         BAL   LINKRG1,IGF110      GO TO SWAP BACK UCB INFORMATION      31600019
IGF204A  LA    LINKRG1,IGF301A     SET UP LINK REG FOR SYSTEM SWAP      31700019
  SPACE  1                                                              31800019
IGF215   LA    RG15,FOUR           SET ERROR RETURN CODE                31900019
IGF215A  LA    LINKRG2,IGF302      SET UP LINKRG FOR OPER. SWAP         32000019
         C     DDRCMPTR,RG11SAV    IS SWAP OPERATOR INITIATED           32100019
         BE    IGF215B             YES,BRANCH OUT                       32200019
         LR    LINKRG2,LINKRG1     RESET LINKRG2                        32250019
         TM    DDRFLGSD,SYSRESBR   WAS THERE AN OPER SWAP PRE-EMPTED    32320019
         BCR   VIII,LINKRG1        NO,BRANCH OUT                        32400019
         B     IGF215C             SKIP NEXT INSTRUCTION                32500019
     SPACE  1                                                           32600019
IGF215B  NI    DDRFLGSD,FF-SYSRESBR  SET OPER SWAP SWITCH OFF           32660019
IGF215C  MVI   DDRFLGSB,EIGHT      SET INDEX FOR DDR ROUTER SVC         32720019
         BR    LINKRG2             BRANCH OUT                           33100019
     SPACE 2                                                            33200019
         AIF   (&MCS NE 1).A205                                         33300019
IGF206   L     UCBRG,UCMUCB        PICK UP IT'S UCB                     33400019
         CLI   UNITYPI(UCBRG),GRAPHICS  IS CNSL A GRAPHIC DEVICE        33500019
         BE    IGF208              YES,BRANCH OUT                       33600019
         BH    IGF209              TP DEVICE BRANCH OUT                 33700019
         LA    WORKRG1,WRITECCW    UNIT RECORD,PICK UP CCW              33800019
         LR    WORKRG2,WORKRG1     PUT THE SAME VALUE IN WORKRG2        33900019
         AGO   .A206                                                    34000019
.A205    ANOP                                                           34100019
IGF206   L     UCBRG,UCMUCB        PICK UP CONSOLE UCB                  34200019
         CLI   UNITYPI(UCBRG),UNITRCOD  IS IT A UNIT RECORD DEVICE      34300019
         BNE   IGF203              NO,BRANCH OUT                        34400019
         LA    WORKRG1,WRITECCW    UNIT RECORD,PICK UP CHANNEL PROG     34500019
         LR    WORKRG2,WORKRG1     SET WORKRG2=WORKRG1                  34600019
.A206    ANOP                                                           34700019
         SPACE 1                                                        34800019
IGF207   MVC   I(L3,WORKRG2),I(MSGPTR)  SET MSG ADDRESS IN CCW          34860019
         MVC   VII(L1,WORKRG2),O(MSGPTR)  SET BYTE COUNT IN CCW         34920019
         OI    SYSFLG1,WTO+SCNDNTRY  SET SWITCHES                       35100019
         AIF   (&MCS NE 1).A2061                                        35110019
         LR    WORKRG4,MCSPTR      SAVE PREFIX ADDRESSIBILITY           35120019
.A2061   ANOP                                                           35140019
         BAL   LINKRG,IGF104       GO SET UP CONTROL BLOCKS             35150019
         LA    RG1,IGF0IOB         PUT IOB ADDR IN REG 1                35300019
   SPACE  1                                                             35400019
         SVC   EXCP                ISSUE EXCP                           35500019
   SPACE  1                                                             35600019
         LA    WORKRG2,N1           SET RETRY LOOP CNT TO ONE           35610021
         BAL   LINKRG,IGF106       GO WAIT ON I/O                       35650019
         SPACE 1                                                        35800019
         AIF   (&MCS  NE  1).A207                                       35900019
         LR    MCSPTR,WORKRG4      RESTORE PREFIX ADDRESSIBILITY        35950019
         TM    SYSFLG1,HARDCOPY    IS HARDCOPY SWITCH ON                36000019
         BO    IGF210              YES,READY TO GO TO ATTENTION ROUTINE 36100019
         CLI   IGF0ECB,COMPLET     IS I/O SUCCESSFUL                    36200019
          BE     IGFTHCU               YES, GO TEST FOR HARD COPY       36300021
          L      UCMENTRY,UCMMCENT     LOAD MASTER CONSOLE UCM          36320021
          B      IGF209                GO TRY ALTERNATE                 36340021
IGFTHCU   L      UCMENTRY,UCMHCUCM     LOAD HARD COPY UCM ADDR          36360021
         LTR   UCMENTRY,UCMENTRY   IS IT ZERO                           36500019
         BZ    IGF300              YES,GO TO ATTENTION ROUTINE          36600019
         OI    SYSFLG1,HARDCOPY    NO,SET HARD COPY SWITCH              36700019
         B     IGF206              GO TO WRITE HARD COPY                36800019
         SPACE 1                                                        36900019
         AGO   .A210                                                    37000019
.A207    ANOP                                                           37100019
         BNE   IGF204              I/O NOT SUCCESSFUL,BRANCH OUT        37200019
         AGO   .A300                                                    37300019
  SPACE  1                                                              37400019
.A210    ANOP                                                           37500019
IGF208   L     DCMPTR,UCMXB        PICK UP PTR TO DCM                   37600019
         USING RDCM,DCMPTR          ADDRESSABILITY FOR RESIDENT DCM     37650000
          LTR    DCMPTR,DCMPTR    DOES DCM EXIST?                 69874 37660021
          BZ     IGF300           NO, GO TO ATTENTION RTN         69874 37670021
         L     TDCMPTR,0(DCMPTR)    GET TRANSIENT DCM BASE        21003 37700000
         USING TDCM,TDCMPTR                                       21003 37750000
*                                                                       37800000
         TM    DCMRFLGS,DCMTYPE     IS DCM TRANSIENT              21003 37850000
         BZ    FULLSCRN             NO,SET FULL SCREEN IND        21003 37900000
*                                                                       37950000
         LR    WORKRG2,TDCMPTR      DCM IS TRANSIENT              21003 38000000
         SH    WORKRG2,XFOUR        POINT TO DCM PREFIX           21003 38050021
         L     WORKRG2,0(WORKRG2)   POINT TO CONSOLE USING DCM    21003 38060000
         LA    WORKRG2,0(WORKRG2)   CLEAR FLAG BYTE               21003 38070000
         CR    WORKRG2,UCMENTRY     IS DCM IN CORE                21003 38080000
         BNE   PURJSTAT             NO,SET PURGE STATUS DISPLAYS        38090000
*                                                                       38092000
FULLSCRN OI    DCMDSTAT,DCMDSTFL    SET FULL SCREEN IND           21003 38094000
         MVI   DCMRQDEL,C'Z'        INDICATE DELETE PENDING       21003 38096000
PURJSTAT OI    DCMR3FLG,DCMRXSCN    PURGE STATUS DISPLAYS         21003 38098000
         OI    DCMR2FLG,DCMRXSFL+DCMRXDEL  INDICATE DELETE PENDING      38098400
         L     WORKRG1,XX(DCMPTR)  PICK UP CHANNEL PROG ADDR            38100019
      XR    WORKRG2,WORKRG2     ZERO OUT INSERT CHARACTER REG           38200019
         IC    WORKRG2,XX(DCMPTR)  GET INDEX VALUE                      38250019
         BCTR  WORKRG2,RG0         DECREMENT 27 BY 1                    38300019
         SLL   WORKRG2,III         MULTIPLY BY EIGHT                    38350019
         AR    WORKRG2,WORKRG1     GET CCW ADRS FOR MSG                 38600019
         B     IGF207              GO TO WRITE ON GRAPHIC DEVICE        38700019
IGF210   NI    SYSFLG1,FF-HARDCOPY TURN OFF HARD COPY SWITCH            38800019
.A300    ANOP                                                           38900019
         EJECT                                                          39000019
*********************************************************************** 39100019
*                                                                     * 39200019
*                  SYSRES ATTENTION ROUTINE                           * 39300019
*                                                                     * 39400019
*********************************************************************** 39500019
         SPACE    2                                                     39600019
IGF300   DS    0H                                                       39650019
         LH    FROMUCB,IGFRMUCB         REINITIALIZE UCB REG            39700019
         LR    UCBRG,FROMUCB            REINITIALIZE UCB REGISTER       39750019
         LA    WORKRG1,READCCW     WORKRG1 PTS TO CCW CHAIN             39800019
         OI    SYSFLG1,READD       SET INDICATOR FOR APPENDAGES         39900019
         NI    SYSFLG2,FF-VOLID    CLEAR VOLID NOT MATCH FLAG           39950019
         BAL   LINKRG,IGF104       SET UP CONTROL BLOCKS,SVC 15 & WAIT  40000019
  SPACE  1                                                              40100019
         BNE   IGF306              I/O ERROR,BRANCH OUT                 40300019
         TM    SYSFLG1,INTERVN     IS INTERVENTION REQUIRED             40400019
         BO    IGF308              YES,BRANCH OUT                       40500019
         TM    SYSFLG2,VOLID       DID VOLID'S MATCH                    40570019
         BO    IGF307              NO, BRANCH OUT                       40640019
         NI    SYSFLG2,FF-OPSWAP2  CLEAR OP INIT READ PREEMPT SWITCH    40710019
  SPACE  1                                                              40800019
         NI    DDRFLGSD,FF-DDRMSG  SET OPER. SWAP CANCELLED SWITCH OFF  40900019
         BAL   LINKRG1,IGF215A     SEE IF OPER.SWAP WAS PRE-EMPTED      41000019
         MVC   ALTCUASR+II(L2),IGFTOUCB RESET ALTERNATE SYSRES UCB      41060019
         XR    RG15,RG15           SET RETURN CODE                      41120019
IGF301A  TM    DDRFLGSA,DDRBUSY    IS NON-SYSRES DDR IN PROCESS         41300019
         BO    IGF304              YES,BRANCH OUT                       41400019
  SPACE  1                                                              41500019
*                                                                       41520021
*      ALLOW ALLOCATION TO PROCEED                                      41540021
*      POST ALLOCATION ECB COMPLETE                                     41560021
*      DETERMINE IF ALLOCATION HAD BEEN PROCESSING                      41580021
*        NO,THEN RESTORE REGS AND RETIRN TO CALLER                      41600021
*        YES,DDR OR TSO SUPERVISOR WILL MARK TSSK DISPATCHABLE AGAIN    41620021
*                                                                       41640021
IGF302   LA    TJOBID,ALLOTJID    GET TJID ADDR                         41660021
         POST  ALLOCECB,TJID=(TJOBID)  POST ALLOC ECB         ID  21048 41680021
         L     TCBADDR,ALLOCTCB   GET ALLOC TCB ADDR          ID  21048 41700021
         LTR   TCBADDR,TCBADDR    WAS A TASK USING ALLOC      ID  21048 41720021
         BZ    IGF304             NO,GO RESTORE REGS          ID  21048 41740021
*                                                                       41760021
         NC    ALLOTJID(N2),ALLOTJID    YES,IS TASK TSO                 41780021
         BZ    RESETDSP           NO,SET TASK DISP            ID  21048 41800021
*                                                                       41820021
         L     TJBADDR,TJBSAVE    RESTORE TJB BASE            ID  21048 41840021
         USING TJB,TJBADDR        MAKE TJB ADDRESSABLE        ID  21048 41860021
         TM    TJBSTAT,TJBINCOR   YES,IS TASK IN CORE         ID  21048 41880021
         BO    RESETDSP           YES,SET IT DISPATCHABLE     ID  21048 41900021
*                                                                       41920021
         OI    TJBRSTOR,TJBDDRD    NO,TSO WILL SET IT DISP    ID  21048 41940021
         LH    TJOBID,ALLOTJID    GET TJID                              41960021
         N     TJOBID,ZEROHIGH    CLEAR 2 H.O. BYTES                    41980021
         TSEVENT USERRDY,TJID=(TJOBID)  TSO BRING IT TO CORE  ID  21048 42000021
         B     IGF304             GO RESTORE REGS             ID  21048 42020021
*                                                                       42040021
RESETDSP EQU   *                  RESET TCB NON-DISP BITS               42060021
         NI    TCBNDSP1(TCBADDR),FF-TCBDDRND  RESET DDR BIT   ID  21048 42080021
         NC    TCBNDSP1(N3,TCBADDR),TCBNDSP1(TCBADDR)         ID  21048 42100021
         BO    IGF304                                                   42120021
         NI    TCBFLGS5(TCBADDR),FF-NDCTL  RESET PRIMARY BIT  ID 21048  42140021
*                                                                       42160021
*        RESTORE REGS AND RETURN TO CALLER                              42180021
*                                                                       42200021
   SPACE  1                                                             42300019
IGF304   LM    RG0,RTN,REGSAVE     RESTORE REGISTERS                    42400019
  SPACE  1                                                              42600019
RETURN   BR    RTN                 RETURN TO CALLER                     42700019
     SPACE 2                                                            42800019
IGF306   C     DDRCMPTR,RG11SAV    IS SWAP OPERATOR INITIATED           42900019
         BE    IGF308B             YES,SWAP SYSRES BACK                 43000019
         CLI   UNITYPII(UCBRG),A2311     NO,IS IT 2311            00226 43100021
         BE    IGF306A                 YES CONTINUE DDR                 43150021
         CLI   UNITYPII(UCBRG),A2321   IS DEVICE A 2321           00226 43160021
         BE    IGF306A                 YES,CONTINUE DDR           00226 43170021
         CLI   UNITYPII(UCBRG),A2314   IS DEVICE A 2314           00226 43180021
         BL    IGF204              NO,BRANCH OUT                  00226 43200021
*                                                                       43250021
IGF306A  EQU   *                                                        43260021
         XR    WORKRG1,WORKRG1     CLEAR WORK REG                       43300019
         IC    WORKRG1,SWAPCNT     PICK UP SWAP COUNTER                 43400019
         BCT   WORKRG1,IGF309      RETRY SWAP                           43500019
         B     IGF204              RETRY 8 TIMES AND FAILED             43600019
IGF309   STC   WORKRG1,SWAPCNT     STORE SWAP COUNT                     43700019
         SPACE  2                                                       43800019
IGF308   MVC   MSG3B(L3),UCBNAME(FROMUCB)  MOVE IN 'FROM' ADDR          43860019
IGF308A  MVC   MSG3C(L3),UCBNAME(FROMUCB)  MOVE IN 'TO' ADDR            43960019
         LA    MSGPTR,MSG3A        SET MSGPTR                           44100019
         B     IGF200              GO TO NOTIFY OPERATOR                44200019
  SPACE  1                                                              44300019
IGF308B  TM    SYSFLG1,OPFIRST     IS THIS THE 1ST SWAP BACK            44400019
         BO    IGF308              NO,BRANCH OUT                        44500019
         OI    SYSFLG1,OPFIRST     SET SECOND SWAP BACK SWITCH          44600019
         EX    RG0,IGF308          MOVE IN 'FROM' ADDR                  44700019
         BAL   LINKRG1,IGF110      GO TO SWAP BACK UCB INFO             44800019
         B     IGF308A             BRANCH OUT                           44900019
   SPACE  1                                                             45000019
IGF307   MVC   MSG2B(L3),UCBNAME(FROMUCB)  MOVE 'TO' ADDR TO MSG 2      45100019
         LA    MSGPTR,MSG2A        SET MSGPTR                           45200019
         B     IGF200              GO TO NOTIFY OPERATOR                45300019
         EJECT                                                          45400019
*********************************************************************** 45500019
*                                                                     * 45600019
*                  APPENDAGE ROUTINE                                  * 45700019
*                                                                     * 45800019
*********************************************************************** 45900019
*                                                                     * 46000019
*                                                                     * 46100019
*   THE APPENDAGE ROUTINE GETS CONTROL FROM IOS. ITS FUNCTION IS TO   * 46140019
*   ROUTE CONTROL FOR 1ST ENTRIES,TO CHECK FOR GENUINE INTERVENTION-  * 46180019
*   REQUIRED CONDITIONS,TO RETRY ERROR FOR 10 TIMES,TO TAKE C1RE OF   * 46220019
*   CONDITION CODE 3 SITUATIONS,AND TO SCHEDULE THE POSTING OF TASKS. * 46260019
*                                                                     * 46700019
*********************************************************************** 46800019
   SPACE  2                                                             46900019
         USING *,RG15              USE REG 15 AS BASE                   47000019
IGF400   DS    0H                                                       47070019
         LA    RG13,IGF506              INITIALIZE BRANCH REGISTER      47140019
         L     VTABPTR,IGFRVT           PICK UP DDR RETURN TABLE ADDR   47210019
         TM    SYSFLG1,SCNDNTRY    TEST FOR 2ND ENTRY                   47300019
         BO    IGF401              YES,BRANCH OUT                       47390019
         OI    SYSFLG1,SCNDNTRY    NO,SET SECOND ENTRY SWITCH           47480019
         TM    SYSFLG1,NOP         IS REQUEST FOR NOP                   47570019
         BO    VIII(VTABPTR)           YES,RE-EXCP WITHOUT CONTROL      47660019
         TM    SYSFLG1,READD       IS REQUEST FOR READ                  47750019
         BO    IV(VTABPTR)             YES,RE-EXCP WITH CONTROL         47840019
         TM    SYSFLG2,OPSWAP1     IS REQUEST FOR DEQUEUE               47930019
         BO    XXXII(VTABPTR)          YES,TAKE DEQUEUE ENTRY           48020019
         LA    RG0,IGFRMUCB        SWAP REQUEST,PICK UP PARAMETER       48110019
         B     XXIV(VTABPTR)           TAKE SWAP EXIT                   48200019
  SPACE  1                                                              48290019
IGF401   TM    IOBFL1(IOBRG),IOBEX  IS IOB EXCEPTION FLAG ON            48380019
         BO    IGF503              YES,BRANCH OUT                       48470019
IGF402   MVI   IOBCOD(IOBRG),COMPLET  SET I/O SUCCESSFUL CODE           48560019
         TM    SYSFLG1,READD       IS THIS FOR A READ                   48590019
         BO    IGF508              YES, CHECK VOLID'S                   48620019
         TM    SYSFLG1,NOP         IS THIS FOR A NOP                    48650019
         BZ    ZERO(RTN)           NO, POST FOR WTO                     48690020
         B     XVI(VTABPTR)        YES, POST TASK WITH CONTROL          48760020
  SPACE 1                                                               48920019
IGF502   MVI   IOBCOD(IOBRG),PERMEROR  SET PERMANENT ERROR CODE         49010019
         TM    SYSFLG1,NOP         TEST FOR NOP                         49100019
         BO    XII(VTABPTR)            POST TASK WITHOUT CONTROL        49190019
         TM    SYSFLG1,READD       IS REQUEST FOR READ                  49280019
         BO    XVI(VTABPTR)            YES,POST WITH CONTROL            49370019
         BR    RTN             POST FOR WTO                             49460019
     SPACE 2                                                            49550019
IGF503   LH    WORKRG4,IOBCSW2(IOBRG)  NO,PICK UP IOB CSW               49640019
         N     WORKRG4,BUFADR      ANY ERROR OTHER THAN UNIT CHECK      49730019
         BCR   NOTZERO,RG13             YES,GO TO RETRY                 49830019
         TM    UCBSNS(UCBRG),INTREQ     IS INTERVENTION REQUIRED        49930019
         BCR   OFF,RG13                 NO, GO TO RETRY                 50030019
         TM    IOBSIOCC(IOBRG),CC3 IS SIO CC 3                          50200019
         BCR   ON,RG13                  YES, GO TO RETRY                50300019
         TM    SYSFLG1,WTO         IS I/O FOR WTO                       50400019
         BO    IGF502              YES,POST PERM. ERROR                 50500019
IGF504   NI    IOBFL1(IOBRG),FF-IOBEX TURN OFF IOB EXCEPTION FLAG       50600019
         OI    SYSFLG1,INTERVN     SET INTERVENTION REQUIRED SWITCH     50700019
         B     IGF402              POST TASK WITH CONTROL               50800019
  SPACE 1                                                               50900019
IGF506   XR    COUNT,COUNT         ZERO OUT COUNT REG                   51000019
         IC    COUNT,COUNTSAV      PICK UP SAVED COUNT                  51100019
         BCT   COUNT,IGF507        RETRY 10 TIMES                       51200019
         B     IGF502              POST PERM. ERROR                     51300019
IGF507   STC   COUNT,COUNTSAV      SAVE RETRY COUNT                     51400019
         B     DDRXCPSR(VTABPTR)        DO NOT ALLOW RE-SEEK            51500019
         SPACE 1                                                        51510019
IGF508   LH    WORKRG4,IGFRMUCB    RESTORE SYSRES UCB ADDRESS           51520019
         CLC   BUFFER(L6),SRTEVOLI(WORKRG4) DO VOLID'S MATCH            51530019
         BNE   IGF509              N/, BRANCH OUT                       51540019
         LH    WORKRG4,IGFTOUCB    RESTORE FROM UCB ADDRESS             51550019
         NI    UCBFL1(WORKRG4),FF-UCBERR  FREE FROM UCB                 51560019
         B     XII(VTABPTR)        POST TASK WITHOUT CONTROL            51570019
IGF509   OI    SYSFLG2,VOLID       INDICATE VOLID'S DON'T MATCH         51580019
         LH    WORKRG4,IGFRMUCB          GET NEW UCB ADDR         62155 51582021
         OI    L6(WORKRG4),INTREQ       SET NOT READY             62155 51584021
         B     XVI(VTABPTR)         POST WITH CONTROL                   51590019
         EJECT                                                          51650019
*********************************************************************** 51700019
*                  SYSRES COUNT ROUTINE                               * 51800019
*********************************************************************** 51900019
*                                                                     * 52000019
*   THIS ROUTINE RECEIVES CONTROL FROM THE DISK ERP.                  * 52010019
*                                                                     * 52020019
*   WHEN THE RECYCLE COUNT KEPT BY THE ROUTINE RESPONSIBLE FOR THE    * 52030019
*   SVC FETCH OPERATION REACHES 5,THIS ROUTINE CHECKS THE ERROR       * 52040019
*   CONDITION.IF DDR IS APPLICABLE,RETURN CODE IS SET TO 4.IF NOT,    * 52050019
*   THE COUNT IS SET TO X'0F' WITH A RETURN CODE 0.IF THE COUNT IS NOT* 52060019
*   5,CONTROL IS PASSED BACK WITH A RETURN CODE 0.LOADING OF          * 52070019
*   APPENDAGES IS SCREENED OUT BY CHECKING FOR SYSTEM TASKS.          * 52080019
*                                                                     * 52090019
*   ERROR CONDITIONS APPLICABLE TO DDR ARE AS FOLLOWS,                * 52100019
*   CHANNEL CONTROL CHECK,CHANNEL DATA CHECK,INTERFACE CONTROL        * 52110019
*   CHECK,UNIT CHECK,DATA CHECK,SEEK CHECK,EQUIPMENT CHECK,BUS OUT    * 52120019
*   CHECK,OVERRUN,COUNT AREA CHECK,UNSAFE,ALU CHECK,UNSELECTED CHECK, * 52130019
*   END OF CYLINDER,MULTIPLE MODULE SELECT,SEEK INCOMPLETE.           * 52140019
*                                                                     * 53900019
*********************************************************************** 54000019
  SPACE 1                                                               54100019
         USING *,BASE              USE REG 12 AS BASE                   54200019
IGFDDR05 STM   13,11,REGSAVE       SAVE ALL REGS BUT REG12              54250020
         L     RG6,CVTPTR          GET CVT PTR                          54260020
         USING IGF00CVT,RG6        ESTABLISH CVT ADDRESSIBILITY         54340019
         TM    CVTDCB,MFT          IS THIS AN MFT SYSTEM                54420019
         BO    IGF607              YES,BRANCH OUT                       54500019
         L     WORKRG2,RQETCBF(RQERG)   PICK UP TCB ADDR                54600019
         TM    TCBDSP(WORKRG2),FF  IS IT A SYSTEM TASK                  54700019
         BNO   IGF601              NO,RETURN                            54800019
         L     WORKRG2,O(WORKRG2)  PICK UP RB ADDR                      54860019
         TM    XSTAB(WORKRG2),SIRB      IS IT THE SIRB                  54920020
         BO    IGF605              YES,BRANCH OUT                       55100020
         TM     XSTAB(WORKRG2),D0        IS THIS AN SVRB(TRANSIENT)     55150020
         BNO    IGF601                 RETURN TO DISK ERP               55160020
         L      WORKRG2,XL(WORKRG2)    PICK UP TACT ENTRY ADDR.         55210020
IGF600   TM    CVTOPTA,NIPIN       IS NIP IN PROCESS                    55220019
         BO    IGF606              YES, DDR SHOULD NOT APPLY            55280019
         CLI   XII(WORKRG2),FIVE   IS COUNT FIVE?                       55340019
         BE    IGF603              YES,BRANCH OUT                       55400019
IGF601   LM    13,11,REGSAVE      RESTORE REGS EXCEPT 12                55450021
         XR    BASE,BASE          SET RETURN CODE = 0                   55480021
         BR    RG13                RETURN TO DISK ERP                   55520020
  SPACE 1                                                               55700019
IGF603   LH    WORKRG3,IOBCSW2(IOBRG)  PICK UP CSW BYTES                55800019
         N     WORKRG3,IGF707      IS THERE ANY ABNORMAL STATUS         55900019
         BZ    IGF606              DDR DO NOT APPLY,RETURN              56000019
         TM    IOBCSW3(IOBRG),CHANCHK  CHANNEL CHK OR CHAINING CHK      56100019
         BNZ   IGF604              YES,BRANCH OUT                       56200019
         MVC   BUFFER(L4),UCBSNS(UCBRG) MOVE SENSE INFO INTO WORK AREA  56300019
         NC    BUFFER(L4),IGF708   EXAMINE SENSE INFO                   56400019
         BZ    IGF606              DDR DO NOT APPLY,RETURN              56500019
IGF604   LM    13,11,REGSAVE      RESTORE REGS EXCEPT 12                56570021
         LA    BASE,FOUR          SET RETURN CODE = 4                   56670021
         BR    RG13               RETURN TO DISK ERP                    56770021
  SPACE 1                                                               56900019
IGF607   L     WORKRG2,DEBTCB(DEBRG)  PICK TCB ADDR                     57000019
         CLC   I(L3,DEBRG),CVTHEAD+I   IS THIS SYSTEM FETCH TCB?        57100019
         BNE   IGF601              NO,RETURN                            57200019
IGF605   L     WORKRG2,AERCOUNT    PICK UP ERROR COUNT ADRS             57300019
         B     IGF600              GO TO TEST COUNT                     57400019
IGF606   MVI   XII(WORKRG2),ZEROFOX     SET COUNT TO X'0F'              57500019
         B     IGF601              RETURN                               57600019
         EJECT                                                          57700019
*********************************************************************** 57800019
*                  READ,WRITE AND NOP CHANNEL PROGRAMS                * 57900019
*********************************************************************** 58000019
   SPACE    1                                                           58100019
         DS    0D                                                       58200019
READCCW  DC    X'31'               READ VOLID SEARCH COMMAND            58300019
         DC    AL3(IOBSEEK+3)      PTS TO RECORD ADDR                   58400019
         DC    X'60'               CHAINED COMMAND,SUPPRESS LENGTH      58500019
         DC    XL3'05'             BYTE COUNT=5                         58600019
         DC    X'08'               TIC COMMAND                          58700019
         DC    AL3(READCCW)        LOOP BACK IF NOT FOUND               58800019
         DC    X'60'               CHAINED COMMAND,SUPPRESS LENGTH      58900019
         DC    XL3'08'             BYTE COUNT=8                         59000019
         DC    X'06'               READ COMMAND                         59100019
         DC    AL3(BUFFER-4)       BUFFER ADDRESS                       59200019
         DC    X'20'               SUPPRESS WRONG LENGTH                59300019
         DC    X'00000A'           BYTE COUNT 10                        59400019
  SPACE  2                                                              59500019
WRITECCW DC    X'09'               WRITE COMMAND FOR UNIT RECORD        59600019
         DC    3X'0'               PTS TO MSG                           59700019
         DC    X'60'               CHAINED COMMAND,SUPPRESS LENGTH      59800019
         DC    3X'0'               BYTE COUNT                           59900019
  SPACE  2                                                              60000019
NOPCCW   DC    X'03'               NOP COMMAND                          60100019
         DC    AL3(BUFADR)         ANY ADDRESS                          60200019
         DC    X'20'               SUPPRESS WRONG LENGTH                60300019
         DC    XL3'1'              BYTE COUNT=1                         60400019
         EJECT                                                          60500019
*********************************************************************** 60600019
*                                 IOB                                 * 60700019
*********************************************************************** 60800019
         DS    0D                                                       60900019
   SPACE  1                                                             61000019
IGF0IOB  DC    X'02'               UNRELATED                            61100019
         DC    4X'0'                                                    61200019
         DC    AL3(IGF0ECB)        ADDR OF ECB                          61300019
IOBCSWFD DC    2F'0'               IOB CSW FLD                          61400019
IOBSTART DC    F'0'                CHANNEL PROG START FLD               61500019
IOBSIOCD EQU   IOBSTART            IOB SIO CONDITION CODE               61700019
IOBDCB   DC    A(IGF0DCB)          DCB ADDRESS                          61800019
         DC    2F'0'                                                    61900019
IOBSEEK  DC    X'0000000000000003' MBBCCHHR OF DASD VOLUME LABEL        62000019
*********************************************************************** 62100019
*                                 DCB                                 * 62200019
*********************************************************************** 62300019
   SPACE  1                                                             62400019
IGF0DCB  EQU   *-44                                                     62500019
         DC    X'0C'               IBM SUPPLIED ERP NOT NEEDED          62600019
         DC    AL3(IGF0DEB)        PT TO DEB                            62700019
*********************************************************************** 62800019
*                              DEB                                    * 62900019
*********************************************************************** 63000019
  SPACE  1                                                              63100019
DEBAPNDG DC    A(RETURN)           END OF EXTENT APPDGE                 63200019
         DC    A(RETURN)           SIO APPENDAGE                        63300019
         DC    A(RETURN)           PCI APPENDAGE                        63400019
         DC    A(IGF400)           PTS TO DDR APPENDAGE RTN             63500019
         DC    A(IGF400)           PTS TO DDR APPENDAGE RTN             63600019
   SPACE  1                                                             63700019
IGF0DEB  DC    X'0'                                                     63800019
DEBTCBAD DC    XL3'0'              DEB TCB FIELD                        63900019
         DC    F'0'                                                     64000019
         DC    X'40'               DATA SET STATUS ,OLD                 64100019
         DC    XL3'0'                                                   64200019
         DC    X'10'               TYPE OF I/O                          64300019
         DC    XL3'0'                                                   64400019
         DC    X'01'               NO OF EXTENTS,1                      64500019
         DC    XL3'0'                                                   64600019
DEBPRTY  DC    X'FF'               DEB PRIORITY                         64700019
         DC    XL3'0'                                                   64800019
         DC    X'0F'               PROTECTION KEY 0,DEBID,F             64900019
         DC    AL3(IGF0DCB)        DEB DCB FIELD                        65000019
         DC    X'04'               EXTENT SCALE,FOR DASD                65100019
         DC    AL3(DEBAPNDG)       PTS TO DEB APPENDAGE TABLE           65200019
         DC    X'C000'             FILE MASK,ALL ALLOWED                65300019
DEBUCB   DC    XL2'0'              DEB UCB FIELD                        65400019
         DC    X'000000000000000000000001' BBCCHHCCHH & NO OF TRACKS    65500019
*********************************************************************** 65600019
*                                 ECB                                 * 65700019
*********************************************************************** 65800019
  SPACE  1                                                              65900019
IGF0ECB  DC    F'0'                ECB                                  66000019
         EJECT                                                          66100019
*********************************************************************** 66200019
*                  CONSTANTS AND WORK AREA                            * 66300019
*********************************************************************** 66400019
   SPACE  2                                                             66500019
REGSAVE  DC    11F'0'              REGISTER SAVE AREA                   66550019
RG11SAV  DC    F'0'                REGISTER SAVE AREA                   66600019
         DC    3F'0'               REGISTER SAVE AREA                   66650019
IGF0RQE  DC    V(DDRRQESR)         SYSRES DDR RQE                       66700019
IGFRVT   DC    V(DDRAPNVT)         DDR RETURN VECTOR TABLE ADDR         66800019
AERCOUNT DC    V(ERCOUNT)          ERROR FETCH SEQUENCE COUNT SAVE FLD  66900019
ADDRSRTO DC    V(DDRSRTO)          'TO' CANDIDATE UCB SAVE AREA ADDR    66980019
BUFADR   DC    XL2'0'              TWO BYTES OF ZERO                    67210019
         DC    X'01FF'             USED TO TEST CSW STATUS              67300019
IGFRMUCB DC    H'0'                'FROM' UCB ADDR                      67400019
IGFTOUCB DC    H'0'                'TO' UCB ADDR                        67500019
IGF707   DC    X'0000020F'         UNIT CHK AND CHANNEL CHK             67600019
IGF708   DC    X'3D808C27'         USED TO EXAMINE SENSE INFO           67700019
BUFFER   DC    6X'0'               BUFFER AND WORK AREA                 67800019
SYSFLG1  DC    X'0'                WORK SWITCHES                        68000019
SWAPCNT  DC    X'08'               SWAP COUNTER                         68100019
COUNTSAV DC    X'0A'               APPDGE COUNT SAVE AREA               68200019
SYSFLG2  DC    X'0'                WORK SWITCH                          68250019
         DS    0F                                                       68260021
ZEROHIGH DC    X'0000FFFF'                                              68270021
TJBSAVE  DS    1F                 TJB ADDR SAVE AREA                    68280021
         DS    0H                                                       68282021
XFOUR    DC    X'0004'                                                  68290021
   SPACE  2                                                             68300019
*********************************************************************** 68400019
*                       MESSAGES                                      * 68500019
*********************************************************************** 68600019
   SPACE  2                                                             68700019
MSG1A    DC    X'23'               BYTE COUNT OF MSG 1         @S68605P 68800021
         DC    AL3(MSG1)           ADDRESS OF MSG 1                     68900019
MSG1     DC    C'IGF501D SWAP SYSRES FROM '                             68950019
MSG1B    DC    C'XXX TO '                                               69000019
MSG1C    DC    C'YYY'                                                   69050019
     SPACE  1                                                           69100019
MSG2A    DC    X'23'               BYTE COUNT OF MSG 2         @S68605P 69200021
         DC    AL3(MSG2)           ADDRESS OF MSG 2                     69300019
MSG2     DC    C'IGF511A WRONG VOLUME MOUNTED ON '                      69360019
MSG2B    DC    C'YYY'                                                   69430019
     SPACE  1                                                           69500019
MSG3A    DC    X'37'               BYTE COUNT OF MSG 3         @S68605P 69600021
         DC    AL3(MSG3)           ADDRESS OF MSG 3                     69700019
MSG3     DC    C'IGF507A VOLUME ON '                                    69740019
MSG3B    DC    C'YYY '                                                  69780019
         DC    C'UNIDENTIFIABLE,SWAP SYSRES TO '                        69820019
MSG3C    DC    C'ZZZ'                                                   69910019
         EJECT                                                          70000019
*********************************************************************** 70100019
*                            CVT DSECT                                * 70200019
*********************************************************************** 70300019
  SPACE 1                                                               70400019
IGF00CVT DSECT                                                          70500019
   CVT                                                                  70600019
         EJECT                                                          70700019
*********************************************************************** 70800019
*                  IORMS COMMUNICATIONS AREA DSECT                    * 70900019
*********************************************************************** 71000019
  SPACE 1                                                               71100019
         IORMSCOM                                                       71200019
         EJECT                                                          71300019
         IKJTJB                                                         71330021
         EJECT                                                          71360021
*                       MCS PREFIX DSECT                              * 71400019
  SPACE 1                                                               71500019
UCMPRFIX DSECT                                                          71600019
UCMMCENT DS    F                   MASTER CONSOLE UCM ENTRY             71700019
         DS    20F                                                      71800019
UCMSFLGS DS    F                   SYSTEM CONTROL FLAGS                 71900019
         DS    F                                                        72000019
UCMHCUCM DS    F                   HARDCOPY UCM ENTRY OR 0 IF SYSLOG    72100019
  SPACE 1                                                               72200019
*                       UCM BASE DSECT                                * 72300019
  SPACE 1                                                               72400019
UCMBASE  DSECT                                                          72500019
UCMXECB  DS    17F                                                      72600021
UCMMODE  DS    X                   MODE FLAGS                           72700019
         DS    3X                                                       72800019
UCMVEA   DS    F                   FIRST UCM ENTRY                      72850019
UCMVEZ   DS    F                   SIZE OF UCM ENTRY                    72900019
UCMVEL   DS    F                   LAST UCM ENTRY                       72950019
  SPACE 1                                                               73200019
*                       UCM ENTRY DSECT                               * 73300019
  SPACE 1                                                               73400019
UCMNTRY  DSECT                                                          73500019
         DS    3F                                                       73600019
UCMUCB   DS    F                   UCB FLD                              73700019
         DS    2F                                                       73800019
UCMSTS   DS    X                   STATUS FLAGS                         73860019
UCMATR   DS    X                   ATTRIBUTE FLAGS                      73920019
         DS    2X                                                       74100019
UCMXB    DS    F              DCM OR ZERO                               74200019
         DS    10X                                                      74300019
UCMDISP  DS    2X             DISPOSITION FLAGS                         74350019
UCMALTEN DS    F              ALTERNATE INPUT UCM ENTRY                 74400019
UCMOAOEN DS    F              ALTERNATE OUTPUT UCM ENTRY                74450019
     AIF  (&MCS  NE  1).XY1                                             74800019
         SPACE  2                                                       74900019
*                       GRAPHICS DCM DSECT                            * 75000019
     SPACE  1                                                           75100019
RDCM     DSECT                      GRAPHICS RESIDENT DCM         21003 75150000
         DS    F                                                  21003 75200021
         DS    C                                                  21003 75250021
DCMRFLGS DS    C                                                  21003 75300021
DCMTYPE  EQU   X'40'                DCM IS TRANSIENT              21003 75350000
         DS    38C                                                21003 75400021
DCMR2FLG DS    C                                                  21003 75450021
DCMRXSFL EQU   X'80'      SCREEN IS FULL                          21003 75500021
DCMRXDEL EQU   X'08'                DELETE IS PENDING             21003 75550000
DCMR3FLG DS    C                                                  21003 75810021
DCMRXSCN EQU   X'10'                PURGE STATUS DISPLAYS         21003 75860021
*                                                                       75870021
*                                                                       75872021
TDCM     DSECT                      GRAPHICS TRANSIENT DCM        21003 75880021
         DS    60F                                                21003 75890021
DCMRQDEL DS    54C                  DELETE REQUEST BUFFER         21003 75892021
DCMDSTAT DS    C                                                  21003 75894021
DCMDSTFL EQU   X'80'                SCREEN FULL INDICATOR         21003 75896021
.XY1     ANOP                                                           75900019
         MEND                                                           76000019
