         MACRO                                                          00030019
&NAME    IOSGEN &FUNC,&PARM,&REG,&VAR,&AUTH=CSECTNME,&LINKR=14          00060019
         GBLB  &EXECN,&EXECF            MULTIPLE EXPANSION SWITCHES     00090019
         GBLB  &EXECS                   MULTI SWITCH FOR SKUPDT   20001 00100020
         LCLC  &HEX,&SUFFIX             CHARACTER VARIABLES             00110019
         LCLC  &LBL                                               20001 00120020
.* 367090,368730                                                 M5464  00125020
.* 805200---CORRECT 'END OF LCH'  TEST,REL21                     A43241 00126021
.*                                                                M0100 00127021
&SUFFIX  SETC  '&SYSNDX'(2,4)           SET 3 CHARACTER SYSNDX VALUE    00130019
         AIF   ('&FUNC' EQ 'PTHAVL').PTH010                             00150019
         AIF   ('&FUNC' EQ 'DOM').DOM010                                00180019
         AIF   ('&FUNC' EQ 'SELSSM').SSM000                             00210019
         AIF   ('&FUNC' EQ 'UCBCHM').NIP010                             00240019
         AIF   ('&FUNC' EQ 'MAP').MAP040                                00270019
         AIF   ('&FUNC' EQ 'VARY').VAR010                               00330019
         AIF   ('&FUNC' EQ 'UCBFL1').FLGS010                            00360019
         AIF   ('&FUNC' EQ 'DETECTOR').DTCT001                          00390019
         AIF   ('&FUNC' EQ 'ENQUE').FIFONQ                              00420019
         AIF   ('&FUNC' EQ 'TP').TPGEN  TEST FOR TP               20002 00423020
         AIF   ('&FUNC' EQ 'RESTORE').IECRES                      20001 00426020
         AIF   ('&FUNC' EQ 'SIMINT').SIMINT                             00430019
         AIF   ('&FUNC' EQ 'SKUPDT').SKUPDT                       20001 00440020
         AIF   ('&FUNC' EQ 'GETQRQE').RQE00                             00445021
         AGO   .IOSNG3                  SKIP TO MNOTE/INVALID FUNC.     00450019
.MAP040  AIF   ('&AUTH' EQ 'IEAMP650').MAP040A                    19026 00460020
         AIF   ('&AUTH' EQ 'IEEMPVCH').MAP040A                    19026 00470020
         AIF   ('&AUTH' EQ 'IEEMPVCP').MAP040A                    19026 00480020
         AIF   ('&AUTH' EQ 'IEE3603D').MAP040A                    M0404 00485020
         AIF   ('&AUTH' EQ 'IGC6203D').MAP040A                    19026 00490020
         AIF   ('&AUTH' EQ 'IGC0405I').MAP040A                    19026 00500020
         AIF   ('&AUTH' EQ 'ICFBDE00').MAP040A                   S21167 00502000
         AIF   ('&AUTH' EQ 'ICFBIE00').MAP040A                   S21167 00504000
         AGO   .IOSNG1                  UNAUTHORIZED USE MNOTE.   19026 00510020
.MAP040A SPACE 1                                                  19026 00520020
*********************************************************************** 00540019
         AIF   (&VAR(1) EQ 1).MAP041                                    00570019
         AIF   (N'&REG LT 7).IOSNG2  IF CALLER SKIMPS ON WKREGS, MNOTE. 00600019
*        MACRO DEFINITION - PATH MAPPING FOR UNIPROCESSING              00630019
*                                                                     * 00660019
*        THIS MACRO, OWNED AND MAINTAINED BY IOS PERSONNEL, CREATES   * 00690019
*             A 1 - 4 ENTRY MAP WITH EACH 2 - BYTE ENTRY HAVING THE   * 00720019
*             FOLLOWING FORM:                                         * 00750019
*             *****************************************************   * 00780019
*             * 4 BIT      * 4 BIT      * 4 BIT      * 4 BIT      *   * 00810019
*             * ONLINE /   * CHANNEL    * CONTROL    * DEVICE     *   * 00840019
*             * OFFLINE    * ADDRESS    * UNIT       * ADDRESS    *   * 00870019
*             * INDICATOR  *            * ADDRESS    *            *   * 00900019
*             *****************************************************   * 00930019
*              WHERE 0000 = ONLINE (PATH AVAILABLE)                   * 00950020
*                    0001 = LAST ENTRY IN MAP                         * 00970020
*                    0010 = OFFLINE (PATH NOT AVAILABLE)              * 00990020
*                                                                     * 01020019
         AGO   .MAP042                                                  01050019
.MAP041  AIF   (N'&REG LT 4).IOSNG2  IF CALLER SKIMPS ON WKREGS, MNOTE. 01080019
*        MACRO DEFINITION-PATH MAPPING FOR MULTIPROCESSING            * 01110019
*              THIS MACRO,OWNED AND MAINTAINED BY IOS PERSONNEL,      * 01200019
*                  CREATES A 2 ENTRY MAP OF THE FOLLOWING FORM;       * 01230019
*                                     (CPUA)   (CPUB)                 * 01260019
*                  ************************************               * 01290019
*                  *       *        *        *        *               * 01320019
*   PRIMARY PATHS  *  DEVICE NAME   *   00   *   01   *               * 01350019
*                  ************************************               * 01380019
*                  *       *        *        *        *               * 01410019
* SECONDARY PATHS  *  DEVICE NAME   *   01   *   00   *               * 01440019
*                  ************************************               * 01470019
*                  WHERE:  00 MEANS PATH NOT AVAILABLE                * 01500019
*                          01 MEANS PATH AVAILABLE                      01530019
*              WHEN THERE ARE ONLY TWO PATHS (ONE FROM EACH CPU),     * 01560019
*              DEVICE NAME IN THE FIRST AND SECOND ENTRIES ARE        * 01590019
*              THE SAME AND PATHS FROM EACH CPU FOR THE SECOND ENTRY  * 01620019
*              ARE MARKED NOT AVAILABLE.                              * 01650019
.MAP042  ANOP                                                           01680019
*              FOLLOWING ARE THE PARAMETERS WHICH MUST BE             * 01710019
*              SPECIFIED IN THE 'IOSGEN' CALL --                      * 01740019
*        IOSGEN  &FUNC,&PARM,(&REG(1),&REG(2),&REG(3),&REG(4)),&VAR   * 01770019
*              OR THE SAME WITH THE EXCEPTION '...,(&VAR(1),&VAR(2))' * 01800019
*              WHERE --                                               * 01830019
*                  1.&FUNC-MAP                                        * 01860019
*                  2.&PARM-NUMBER OF A REG WHICH POINTS TO 2 WORD     * 01890019
*                      AREA IN WHICH MAP IS TO BE CREATED,FOLLOWED    * 01920019
*                      BY A SIXTEEN WORD AREA IN WHICH THE REGS       * 01950019
*                      ARE TO BE SAVED.                               * 01980019
*                  3. &REG-OPERAND SUBLIST WHICH DEFINES FOUR TO SEVEN* 02010019
*                      REGISTERS WHICH MAY BE USED BY THE ROUTINE --  * 02040019
*                      UNIPROCESSING REQUIRES 7 REGISTERS, MULTI-     * 02070019
*                      PROCESSING REQUIRES FOUR REGISTERS.            * 02100019
*                      THE FIRST (&REG(1)) MUST CONTAIN THE ADDRESS   * 02130019
*                      OF THE UCB FOR WHICH PATHS ARE TO BE DETERMINED* 02160019
*                      THE LAST OF THE REQ'D REGS MUST SPECIFY THE REG* 02190019
*                      TO BE USED AS THE BASE FOR THIS ROUTINE.       * 02220019
*                      *** CAUTION -- IT IS ADVISED THAT THE CALLER   * 02250019
*                      NOT SPECIFY HIS OWN BASE REGISTER, AS A 'DROP' * 02280019
*                      IS ISSUED AT THE END OF THIS EXPANSION.        * 02310019
*                                                                     * 02320020
*                      THE OTHER REGISTERS SPECIFIED ARE ONLY NEEDED  * 02330020
*                      TO PREVENT CONFLICTS WITHIN THIS CODE.         * 02340020
*                      THEIR USE WILL BE TRANSPARENT TO THE INVOKING  * 02350020
*                      CSECT.                                         * 02360020
*                  4.&VAR - A SINGLE OPERAND, '0', FOR UNIPROCESSING, * 02370020
*                           OR AN OPERAND SUBLIST OF TWO PARAMETERS - * 02380020
*                      &VAR(1), '1', FOR MULTIPROCESSING AND ...      * 02390020
*                      &VAR(2),IF ZERO OR OMITTED, RESULTS IN NORMAL  * 02430019
*                              CODE GENERATION.                       * 02460019
*                              IF ONE = SPECIFIC REQUEST FOR EXTRA    * 02490019
*                                       CODE TO ENSURE THAT CHANNEL   * 02520019
*                                       IS STARTED FROM THE 'LCH'     * 02550019
*                                       RATHER THAN FROM 'EXCP'.      * 02580019
*                  THE RETURN REGISTER FOR THIS SUBROUTINE MAY BE     * 02583020
*                  SPECIFIED BY ADDING THE KEYWORD PARM 'LINKR=XX',   * 02586020
*                  WHERE 'XX' DENOTES THE REGISTER TO BE USED.        * 02589020
*                  DEFAULT IS 'LINKR=14'.                             * 02592020
*                                                                     * 02595020
***            THE KEYWORD PARAMETER 'AUTH=CSECTNME' MUST ALSO BE   *** 02598020
***            SPECIFIED, NOTING THE CSECT NAME INVOKING THE MACRO. *** 02601020
*********************************************************************** 02610019
         SPACE 1                                                        02640019
         AIF   (&VAR(1) EQ 0).MAP030        ('UNI-PROC')                02660020
         SPACE 1                                                        02680020
*********************************************************************** 02700020
*        REGISTER DEFINITION                                          * 02720020
*********************************************************************** 02740020
         SPACE 1                                                        02760020
IECIMPAR EQU   &PARM                    PARAMETER REGISTER              02780020
IECIMUCB EQU   &REG(1)                  UCB REGISTER                    02800020
IECIMWK1 EQU   &REG(2)                  WORK REGISTER                   02820020
IECIMWK2 EQU   &REG(3)                  WORK REGISTER                   02840020
IECIMBAS EQU   &REG(4)                  BASE REGISTER                   02860020
         SPACE 1                                                        02880020
*********************************************************************** 02900020
*        UCB DEFINITION AND FLAGS                                     * 02920020
*********************************************************************** 02940020
         SPACE 1                                                        02960020
IECIMALC EQU   1                        UCB ALLOCATION CHAN MASK        02980020
IECIMCHN EQU   4                        CHAN ADDR FIELD IN UCB          03000020
IECIMUNT EQU   5                        UNIT ADDR FIELD IN UCB          03020020
IECIMLCI EQU   10                       LOGICAL CHAN INDEX IN UCB       03040020
IECIMCHM EQU   12                       UCB CHAN MASK FIELD             03060020
IECIMMLT EQU   X'01'                    MULTIPLE PATH INDICATOR         03080020
         SPACE 1                                                        03100020
*********************************************************************** 03120020
*        PATH MAP LAYOUT AND FLAGS                                    * 03140020
*********************************************************************** 03160020
         SPACE 1                                                        03180020
IECIMNT1 EQU   0                        MAP-ENTRY1                      03200020
IECIMNT2 EQU   4                        MAP ENTRY2                      03220020
IECIMAVL EQU   X'01'                    PATH AVAILABLE FLAG             03240020
IECIMPRM EQU   2                        PRIMARY PATH - EITHER ENTRY     03260020
IECIMSEC EQU   3                        SECONDARY PATH - EITHER ENTRY   03280020
         SPACE 1                                                        03300020
*********************************************************************** 03320020
*        MISCELLANEOUS FLAGS AND PTRS                                 * 03340020
*********************************************************************** 03360020
         SPACE 1                                                        03380020
IECIMCVT EQU   16                       CVT PTR                         03400020
IECIMLCH EQU   140                      PTR TO LOG CHAN TBL IN CVT      03420020
IECIMTCH EQU   6                        OFFSET IN TCH TAB TO TCH CODE   03440020
IECIMIND EQU   1                        PATH IND FLD IN TCH PREFX TBL   03460020
IECIMPRA EQU   X'08'                    PRIMARY PATH IND-CPUA           03480020
IECIMPRB EQU   X'02'                    PRIMARY PATH IND-CPUB           03500020
IECIMSCA EQU   X'04'                    SECONDARY PATH IND/CPUA         03520020
IECIMSCB EQU   X'01'                    SECONDARY PATH IND/CPUB         03540020
IECIMCUI EQU   X'F0'                    CONT UNIT MASK FOR TCH CU FIELD 03560020
IECIMCAA EQU   X'02'                    CPUA ACCESSABILITY BIT          03580020
IECIMCBB EQU   X'01'                    CPUB ACCESSABILITY BIT          03600020
IECIMNAV EQU   X'00'                    PATH NOT AVAIL                  03620020
IECIMCHA EQU   20                       CHANMSK FIELD IN IOS            03640020
IECIMNXT EQU   124                      NEXT AVAILABLE                  03660020
         EJECT                                                          03680020
         STM   0,15,8(IECIMPAR)         SAVE REGS                       03700020
         BALR  IECIMBAS,0               ESTABLISH                       03720020
         USING *,IECIMBAS                        ADDRESSABILITY         03740020
         XC    IECIMNT1(8,IECIMPAR),IECIMNT1(IECIMPAR) ZERO MAP         03760020
         SPACE 1                                                        03780020
         AIF   (T'&VAR(2) EQ 'O').MAP010 IF PARM MISSING OR IF CHANL    03800020
         AIF   (&VAR(2) EQ 0).MAP010 START CODE EXPLICTLY REFUSED, SKIP 03820020
         LTR   IECIMUCB,IECIMUCB        CHK FOR NEGATIVE CONTENTS       03840020
         BC    2,IECIM005               BR IF CONTENTS ARE POSITIVE     03860020
*                                                                       03880020
         LCR   IECIMUCB,IECIMUCB        TEST COMPLETE, RESTR CNTNTS     03900020
         IC    IECIMWK1,IECIMCHN(IECIMUCB) GET CHANNL ADDR FROM UCB     03920020
         N     IECIMWK1,IECIMZFM        ZERO FLAG BITS                  03940020
         L     IECIMWK2,IECIMZCH        SET UP TO CALC CHANMSK          03960020
         SRL   IECIMWK2,0(IECIMWK1)     CALCULATE CHANMSK               03980020
         L     IECIMWK1,IECIMCVT        GET PTR TO CVT                  04000020
         L     IECIMWK1,IECIMNXT(IECIMWK1) GET PTR TO NXT AVAILABLE     04020020
         LA    IECIMWK1,IECIMCHA(IECIMWK1) LOAD CHNMSK POINTER          04040020
         O     IECIMWK2,0(IECIMWK1)     SET NEW CHMSK IN REG            04060020
         ST    IECIMWK2,0(IECIMWK1)     SET NEW CHANMSK                 04080020
.MAP010  ANOP                                                           04100020
IECIM005 TM    IECIMCHM(IECIMUCB),IECIMPRA PRIM PATH FR CPUA AVAIL      04120020
         BC    1,IECIM010               NO-BYPASS SET OF AVAIL BIT      04140020
*                                                                       04160020
         OI    IECIMNT1+IECIMPRM(IECIMPAR),IECIMAVL MARK PATH AVAIL     04180020
IECIM010 TM    IECIMCHM(IECIMUCB),IECIMPRB PRIM PATH FR CPUB AVAIL      04200020
         BC    1,IECIM020               NO-TEST FOR ASYMMETRIC DEVICE   04220020
*                                                                       04240020
         OI    IECIMNT1+IECIMSEC(IECIMPAR),IECIMAVL MARK PATH AVAIL     04260020
IECIM020 TM    IECIMALC(IECIMUCB),IECIMMLT FOUR PATHS TO DEV            04280020
         BC    1,IECIM030               YES-ACCESS TCH TABL             04300020
*                                                                       04320020
         MVN   IECIMNT1(1,IECIMPAR),IECIMCHN(IECIMUCB) NO-SET CHAN ADD  04340020
         MVC   IECIMNT1+1(1,IECIMPAR),IECIMUNT(IECIMUCB) SET UNIT ADDR  04360020
         MVC   IECIMNT2(2,IECIMPAR),IECIMNT1(IECIMPAR) SET SECON ADDR   04380020
         BC    15,IECIMRST              RESTORE REGS                    04400020
************************                                                04420020
         SPACE 1                                                        04440020
IECIM030 L     IECIMWK1,IECIMCVT        GET CVT ADDRESS                 04460020
         SR    IECIMWK2,IECIMWK2        PREPARE WORK REG                04480020
         IC    IECIMWK2,IECIMLCI(IECIMUCB) GET LCH INDEX FROM UCB       04500020
         SLL   IECIMWK2,3              MULTIPLY BY 8                    04520020
         L     IECIMWK1,IECIMLCH(IECIMWK1) GET ADDR LCHTAB IN IOS       04540020
         LH    IECIMWK1,IECIMTCH(IECIMWK1,IECIMWK2) TEST CHAN ADDR      04560020
         N     IECIMWK1,IECIMMSK       MASK UNNEEDED BITS               04580020
         SH    IECIMWK1,IECIMSIX        BEGIN TCH TABLE                 04600020
         TM    IECIMIND(IECIMWK1),IECIMPRA IS THIS PRIM PATH IND        04620020
         BC    8,IECIM040               NO-SET ADDRS IN REVERSE         04640020
*                                                                       04660020
         MVC   IECIMNT1(2,IECIMPAR),0(IECIMWK1) MOVE PRIM DEV ADDR      04680020
         MVC   IECIMNT2(2,IECIMPAR),2(IECIMWK1) MOVE SECN DEV ADDR      04700020
         BC    15,IECIM050              TEST CU FIELD                   04720020
************************                                                04740020
         SPACE 1                                                        04760020
IECIM040 MVC   IECIMNT2(2,IECIMPAR),0(IECIMWK1) MOVE SECN DEV ADDR      04780020
         MVC   IECIMNT1(2,IECIMPAR),2(IECIMWK1) MOVE PRIM DEV ADDR      04800020
IECIM050 TM    IECIMNT1+1(IECIMPAR),IECIMCUI ALT CONTROL UNITS          04820020
         BC    8,IECIM060               NO-SET CU/DEV NAME              04840020
*                                                                       04860020
         MVN   IECIMNT1+1(1,IECIMPAR),IECIMUNT(IECIMUCB) MOVE DEV NAM   04880020
         MVN   IECIMNT2+1(1,IECIMPAR),IECIMUNT(IECIMUCB) MOVE DEV NAM   04900020
         BC    15,IECIM070              TEST SECNDRY PATH CPUA          04920020
************************                                                04940020
         SPACE 1                                                        04960020
IECIM060 MVC   IECIMNT1+1(1,IECIMPAR),IECIMUNT(IECIMUCB) MOV CU/DEV NA  04980020
         MVC   IECIMNT2+1(1,IECIMPAR),IECIMUNT(IECIMUCB) MV CU/DV NAM   05000020
IECIM070 TM    IECIMCHM(IECIMUCB),IECIMSCA SECN PATH CPUA AVAIL         05020020
         BC    1,IECIM080               NO-CK CPUB PATH                 05040020
*                                                                       05060020
         OI    IECIMNT2+IECIMPRM(IECIMPAR),IECIMAVL MARK PATH AVAIL     05080020
IECIM080 TM    IECIMCHM(IECIMUCB),IECIMSCB SECN PATH CPUB AVAIL         05100020
         BC    1,IECIMRST               NO-RESTORE REGS                 05120020
*                                                                       05140020
         OI    IECIMNT2+IECIMSEC(IECIMPAR),IECIMAVL MARK PATH AVAIL     05160020
IECIMRST LM    0,15,8(IECIMPAR)         RESTORE REGS                    05180020
         BCR   15,&LINKR                RETURN                          05200020
************************                                                05220020
         SPACE 1                                                        05240020
         DS    0F                                                       05260020
IECIMMSK DC    X'0000FFFF'              HALFWORD MASK                   05280020
         AIF   (T'&VAR(2) EQ 'O').MAP020 IF TYPE OF PRCSSING NOT SPECFD 05300020
         AIF   (&VAR(2) EQ 0).MAP020    OR IF UNI-PRC SPECFD,SKIP CODE  05320020
IECIMZCH DC    X'80000000'              ZERO CHANNEL MASK               05340020
IECIMZFM DC    X'0000000F'              CHANNEL ADDR FIELD MASK         05360020
.MAP020  ANOP                                                           05380020
IECIMSIX DC    H'0006'                                                  05400020
         DROP  IECIMBAS                                                 05420020
         SPACE 5                                                        05440020
         AGO   .IOSGEND                                                 05460020
.MAP030  ANOP                                                           05480020
         SPACE 1                                                        05500020
*********************************************************************** 05520020
*        THIS IS PATH MAPPING ROUTINE FOR UNIPROCESSING               * 05540020
*********************************************************************** 05560020
         SPACE 1                                                        05580020
*********************************************************************** 05600020
*        REGISTER DEFINITION                                          * 05620020
*********************************************************************** 05640020
         SPACE 1                                                        05660020
IECIMPAR EQU   &PARM                    PARAMETER REGISTER              05680020
IECIMUCB EQU   &REG(1)                  UCB REGISTER                    05700020
IECIMWK1 EQU   &REG(2)                  WORK REGISTER                   05720020
IECIMWK2 EQU   &REG(3)                  WORK REGISTER                   05740020
IECIMWK3 EQU   &REG(4)                  WORK REGISTER                   05760020
IECIMWK4 EQU   &REG(5)                  WORK REGISTER                   05780020
IECIMWK5 EQU   &REG(6)                  WORK REGISTER                   05800020
IECIMBAS EQU   &REG(7)                  BASE REGISTER                   05820020
         SPACE 1                                                        05840020
*********************************************************************** 05860020
*        UCB DEFINITION AND FLAGS                                     * 05880020
*********************************************************************** 05900020
         SPACE 1                                                        05920020
IECIMALC EQU   1                        UCB ALLOCATION CHAN MSK         05940020
IECIMCHN EQU   4                        CHAN ADDR FIELD IN UCB          05960020
IECIMUNT EQU   5                        UNIT ADDR FIELD IN UCB          05980020
IECIMLCI EQU   10                       LOGICAL CHAN INDEX IN UCB       06000020
IECIMCHM EQU   12                       UCB CHANNEL MASK                06020020
IECIMMLT EQU   X'01'                    MULTIPLE PATH INDICATOR         06040020
         SPACE 1                                                        06060020
*********************************************************************** 06080020
*        PATH MAP LAYOUT AND FLAGS                                    * 06100020
*********************************************************************** 06120020
         SPACE 1                                                        06140020
IECIMNT1 EQU   0                        OFFSET TO BEGIN MAP ENTRY       06160020
IECIMUP  EQU   0                        UCB PTR IN PARALIST             06180020
IECIMNXT EQU   2                        INCR TO NEXT MAP ENTRY          06200020
IECIMNTY EQU   X'10'                    LAST ENTRY INDICATOR            06220020
IECIMNAV EQU   X'20'                    PATH NOT AVAIL BIT IN MAP       06240020
         SPACE 1                                                        06260020
*********************************************************************** 06280020
*        MISCELLANEOUS FLAGS AND PTRS                                 * 06300020
*********************************************************************** 06320020
         SPACE 1                                                        06340020
IECIMCVT EQU   16                       CVT PTR                         06360020
IECIMLCH EQU   140                      PTR TO LOG CHAN TBL IN CVT      06380020
IECIMTCH EQU   6                        OFFSET IN TCH TAB TO TCH CODE   06400020
IECIMTWO EQU   2                                                        06420020
IECIMCTR EQU   0                        PATH CTR IN PATH COMPOSITE      06440020
IECIMPIN EQU   X'08'                    PRIM PATH IND FOR TM INSTR      06460020
IECIMCHA EQU   0                        CHAN ADDR FROM TCH PREFIX       06480020
IECIMUCM EQU   X'F0'                    TCH TABLE CU MASK               06500020
IECIMIN8 EQU   1                        PATH INDICATOR FIELD            06520020
         EJECT                                                          08100019
         STM   0,15,8(IECIMPAR)         SAVE REGISTERS            19026 08110020
         BALR  IECIMBAS,0                                               08130020
         USING *,IECIMBAS                                               08150020
         XC    IECIMNT1(8,IECIMPAR),IECIMNT1(IECIMPAR)  ZERO MAP        08170020
         TM    IECIMALC(IECIMUCB),IECIMMLT  MORE THAN 1 PATH TO DEV     08190020
         BC    1,IECIM01A               YES-ACCESS TCH TABLE            08210020
         SPACE 1                                                        08230020
*        THIS CODING CREATES A ONE ENTRY MAP WHEN ONLY ONE PATH       * 08250020
*              IS AVAILABLE TO THE DEVICE. THERE IS NO WAY TO TEST    * 08270020
*              FOR PATH UNAVAILABILITY AT THIS POINT, SO THE          * 08290020
*              AVAILABILITY BIT IS NEVER SET (PATH ALWAYS CONSIDERED  * 08310020
*              AVAILABLE).                                            * 08330020
*********************************************************************** 08350020
         SPACE 1                                                        08370020
         MVN   IECIMNT1(1,IECIMPAR),IECIMCHN(IECIMUCB) NO-SET CHAN ADR  08390020
         MVC   IECIMNT1+1(1,IECIMPAR),IECIMUNT(IECIMUCB) SET UNIT ADDR  08410020
         OI    IECIMNT1(IECIMPAR),IECIMNTY  SET LAST ENTRY BIT          08430020
         BC    15,IECIMEND              RETURN                          08450020
         SPACE 1                                                        08470020
*********************************************************************** 08490020
*        THIS CODING ACCESSES THE TEST CHANNEL PREFIX TABLE AND       * 08510020
*              SEARCHES FOR THE ENTRY WHICH CORRESPONDS TO THE        * 08530020
*              PRIMARY ADDRESS OF THE DEVICE. IT DECIDES,FROM THIS    * 08550020
*              TABLE,WHETHER ALTERNATE PATHS TO THIS DEVICE ARE       * 08570020
*              ALTERNATE CHANNEL PATHS OR PATHS THROUGH ALTERNATE     * 08590020
*              CONTROL UNITS.  IF ALTERNATE CHANNELS,THE CONTROL      * 08610020
*              UNIT AND DEVICE NAMES ARE MOVED FROM THE UCBUNIT       * 08630020
*              ADDRESS FIELD. IF ALTERNATE CONTROL UNITS,THE CONTROL  * 08650020
*              UNIT NAME IS TAKEN FROM THE TCH PREFIX TABLE AND       * 08670020
*              THE DEVICE NAME IS TAKEN FROM THE UCB. THEN THE        * 08690020
*              PATH INDICATOR IN THE TCH PREFIX TABLE IS COMPARED     * 08710020
*              AGAINST THE UCB CHANNEL MASK TO DETERMINE IF THE       * 08730020
*              PATH IS OFFLINE. IF SO,THE OFFLINE INDICATOR BIT       * 08750020
*              IS SET IN THE AVAILABILITY BYTE OF THE MAP. THIS       * 08770020
*              PROCESS IS REPEATED FOR ALL PATHS TO THE DEVICE.       * 08790020
*              WHEN THE LAST PATH IS PROCESSED, THE LAST ENTRY        * 08810020
*              BIT IS SET IN THE AVAILABILITY BYTE.                   * 08830020
*********************************************************************** 08850020
         SPACE 1                                                        08870020
IECIM01A L     IECIMWK1,IECIMCVT        GET CVT ADDRESS                 08890020
         L     IECIMWK1,IECIMLCH(IECIMWK1)  LOAD ADDR LCH TAB IN IOS    08910020
         SR    IECIMWK2,IECIMWK2        PREPARE WORK REG                08930020
         IC    IECIMWK2,IECIMLCI(IECIMUCB)  GET LCH INDEX FROM UCB      08950020
         SLL   IECIMWK2,3               MULTIPLY BY 8                   08970020
         LH    IECIMWK1,IECIMTCH(IECIMWK1,IECIMWK2)  TEST CHAN ADDR     08990020
         N     IECIMWK1,IECIMMSK        MASK OUT UNNEEDED BITS          09010020
         LA    IECIMWK2,IECIMTWO        SET UP FOR SUBTRACT             09030020
         SR    IECIMWK1,IECIMWK2        POINT TO PATH COMPOSITE         09050020
         SR    IECIMWK3,IECIMWK3        PREPARE INSERT CHAR REG         09070020
         IC    IECIMWK3,IECIMCTR(IECIMWK1)  SET PATH COUNTER            09090020
         SR    IECIMWK1,IECIMWK2        POINT TO TCHCODE TABLE ENTRY    09110020
         LR    IECIMWK5,IECIMWK3        SAVE PATH COUNTER               09130020
         AR    IECIMWK5,IECIMWK5        DOUBLE CTR FOR PARMREG CLAC     09150020
         SR    IECIMWK5,IECIMWK2        ADJUST REG DOWNWARD FOR SUBTR   09170020
         SR    IECIMWK4,IECIMWK4        PREPARE REG FOR INSERT CHAR     09190020
IECIM01B IC    IECIMWK4,IECIMIN8(IECIMWK1) SET PATH IND FOR EX INSTR    09210020
         MVN   IECIMNT1(1,IECIMPAR),IECIMCHA(IECIMWK1) MOVE CHAN ADDR   09230020
         TM    IECIMIN8(IECIMWK1),IECIMUCM VARIABLE CONTROL UNIT ADDRS  09250020
         BC    7,IECIM02B               YES-SET CU FIELD FROM TCH TAB   09270020
*                                                                       09290020
         MVC   IECIMNT1+1(1,IECIMPAR),IECIMUNT(IECIMUCB) SET UA FROM UC 09310020
         BC    15,IECIM02C              BR-TEST IF PATH OFFLINE         09330020
************************                                                09350020
         SPACE 1                                                        09370020
IECIM02B N     IECIMWK4,IECIMBYT        AND CU ADDR FIELD OUT OF REG    09390020
         MVZ   IECIMNT1+1(1,IECIMPAR),IECIMIN8(IECIMWK1)  SET CU FIELD  09410020
         MVN   IECIMNT1+1(1,IECIMPAR),IECIMUNT(IECIMUCB) SET DEV NUMB   09430020
IECIM02C EX    IECIMWK4,IECIMOFT        TEST IF PATH OFFLINE            09450020
         BC    8,IECIM02D               PATH ONLINE-BRANCH              09470020
*                                                                       09490020
         OI    IECIMNT1(IECIMPAR),IECIMNAV  SET PATH NOT AVAIL BIT      09510020
IECIM02D LA    IECIMPAR,IECIMNXT(IECIMPAR)  LOOK AT NEXT ENTRY IN MAP   09530020
         SR    IECIMWK1,IECIMWK2        POINT TO NEXT TCH TAB ENTRY     09550020
         BCT   IECIMWK3,IECIM01B        FIND NEXT ADDR IF ANY           09570020
*                                                                       09590020
         SR    IECIMPAR,IECIMWK2        POINT TO LAST ENTRY IN MAP      09610020
         OI    IECIMNT1(IECIMPAR),IECIMNTY  SET LAST ENTRY BIT IN MAP   09630020
         SR    IECIMPAR,IECIMWK5        RESET MAP PTR FOR CALLER        09650020
         BC    15,IECIMEND              RETURN                          09670020
************************                                                09690020
         SPACE 2                                                        09710020
         DS    0F                                                       09730020
IECIMBYT DC    X'0000000F'              HALF-BYTE MASK FOR AND INSTR    09750020
IECIMMSK DC    X'0000FFFF'              HALFWORD MASK                   09770020
IECIMOFT TM    IECIMCHM(IECIMUCB),X'00' TEST IF PATH OFFLINE            09790020
IECIMEND LM    0,15,8(IECIMPAR)         RESTORE REGISTERS         19026 09990020
         BCR   15,&LINKR                RETURN TO CALLER          19026 10190020
         DROP  IECIMBAS                                                 10530019
         SPACE 5                                                        10540019
         AGO   .IOSGEND                                                 10560019
.VAR010  ANOP                                                           10570019
.*   IF M.P. USER SKIMPS ON WORKREGS, ABORT - -                       * 10580019
         AIF   (N'&REG LT 9 AND &VAR(1) EQ 1).IOSNG2                    10590019
.*                                                                    * 10600019
.*  IF UNI-PROC USER SKIMPS, ALSO ABORT                               * 10610019
         AIF   (N'&REG LT 8 AND &VAR(1) EQ 0).IOSNG2                    10620019
.*                                                                    * 10630019
         SPACE 1                                                        10640019
*********************************************************************** 10650019
         AIF   (&VAR(1) EQ 0).VAR011    'UNI-PROC'                      10660019
         AIF   ('&AUTH' NE 'IGF24MPD').IOSNG1 UNAUTHORIZED USE MNOTE.   10710019
*        MACRO DEFINITION - VARY PATH FOR MULTIPROCESSING             * 10770019
         AGO   .VAR012                                                  10800019
.VAR011  AIF   ('&AUTH' NE 'IGF2403D').IOSNG1 UNAUTHORIZED USE MNOTE.   10830019
*        MACRO DEFINITION - VARY PATH FOR UNIPROCESSING               * 10860019
.VAR012  ANOP                                                           10890019
*              THIS MACRO, OWNED AND MAINTAINED BY IOS PERSONNEL,     * 10920019
*                  MAY BE USED TO VARY A PATH ONLINE OR OFFLINE       * 10950019
*                  (IF NOT THE LAST PATH TO THE DEVICE) FOR DEVICES     10980019
*                  WHICH MAY BE REACHED THROUGH MULTIPLE CHANNELS     * 11010019
*                  OR ALTERNATE SELECTOR SUBCHANNELS.                 * 11040019
*                                                                     * 11070019
         AIF   (&VAR EQ 0).VAR013A      IF ZERO, SKIP M.P. INFO         11100019
*              THE MODULE THAT CALLS THIS MACRO IS IGF24MPD           * 11130019
         AGO   .VAR013B                                                 11160019
.VAR013A ANOP                                                           11190019
*              THE MODULE THAT CALLS THIS MACRO IS IGF2403D           * 11220019
.VAR013B ANOP                                                           11250019
*                                                                     * 11280019
*              THIS CODE IS GENERATED WHEN THE 'IOSGEN' CALL IS CODED * 11310019
*                  WITH THE VARIABLES SET ACCORDING TO THE FOLLOWING  * 11340019
*                  FORMAT --                                          * 11370019
*        IOSGEN &FUNC,(&PARM(1),&PARM(2),&PARM(3)),(&REG(1),&REG(2), +* 11390019
*              &REG(3), --- &REG(N)),&VAR,&AUTH=CSECTNME   WHERE --   * 11410019
*                                                                     * 11430019
*              FOLLOWING ARE THE PARAMETERS WHICH MUST BE SPECIFIED:    11460019
*                  1.&FUNC-VARY                                         11490019
*                  2.&PARM(1)- A REGISTER WHICH POINTS TO A 2 WORD    * 11520019
*                         PARAMETER LIST IN THE FOLLOWING FORM --     * 11550019
*                    ***********************************              * 11580019
         AIF   (&VAR(1) EQ 0).VAR015    'UNI-PROCESSING'                11610019
*                  +0*                * VARY   * MP -  *              * 11640019
*                    *  DEVICE  ADDR. * OFF/ON * CPU   *              * 11670019
*                    *                * REQ IND*  ID   *              * 11700019
         AGO   .VAR020                                                  11730019
.VAR015  ANOP                                                           11760019
*                  +0*                * VARY   *       *              * 11790019
*                    *  DEVICE  ADDR. * OFF/ON * NULL  *              * 11820019
*                    *                * REQ IND*       *              * 11850019
.VAR020  ANOP                                                           11880019
*                    ***********************************              * 11910019
*                  +4* BASE ADDRESS OF DEVICE IN       *              * 11940019
*                    * EBCDIC, RIGHT ADJUSTED.         *              * 11970019
*                    *                                 *              * 12000019
*                    ***********************************              * 12030019
*                    .. 2 BYTES .......                               * 12060019
*                    ............... 4 BYTES ..........               * 12090019
*                    FOR EXAMPLE --                                   * 12120019
*                                       DEVICE ADDR. - X'0193'        * 12150019
*                                       VARY OFF/ON INDICATOR -       * 12180019
*                                         X'00' = OFFLINE             * 12210019
*                                         X'04' = ONLINE              * 12240019
         AIF   (&VAR(1) EQ 0).VAR025    'UNI-PROCESSING'                12270019
*                                       MP CPU ID = X'C1' FOR CPUA OR,* 12300019
*                                                   X'C2' FOR CPUB.   * 12330019
.VAR025  ANOP                                                           12360019
*                                       EBCDIC DEVICE ADDRESS, FOR    * 12390019
*                                       EXAMPLE COULD BE --           * 12420019
*                                            X'F0F2F9F3'.             * 12450019
*                                    *** NOTE -- THIS FIELD IS CON-   * 12480019
*                                       SIDERED AS INPUT ONLY, AND    * 12510019
*                                       IS NOT PRESERVED ACROSS THE   * 12540019
*                                       INTERFACE.                    * 12570019
*                                                                     * 12575019
*                    &PARM(2)- A REG WHICH POINTS TO THE CVT          * 12580020
*                                                                     * 12600020
*                    &PARM(3)- A WORK REGISTER, REG 0 BEING VALID     * 12620020
*                                                                     * 12640020
         AIF   ('&FUNC' EQ 'VARY' AND &VAR(1) EQ 1).VAR030  'MULTI'     12660020
*                  3.&REG-OPERAND SUBLIST WHICH DEFINES EIGHT REGS    * 12680020
         AGO   .VAR035                                                  12700020
.VAR030  ANOP                                                           12720020
*                  3.&REG-OPERAND SUBLIST WHICH DEFINES NINE REGS     * 12740020
.VAR035  ANOP                                                           12760020
*                        TO BE USED AS WORK REGISTERS                   12780020
*                  4.&VAR--                                           * 12800020
*                     A.ZERO-UNIPROCESSING                            * 12820020
*                     B.ONE-MULTIPROCESSING                           * 12840020
*                                                                     * 12860020
*                  5.&AUTH=XXXXXXXX IS A KEYWORD PARAMETER SPECIFYING * 12880020
*                                   THE INVOKING CSECT NAME.          * 12900020
*                                                                     * 12920020
*              POSSIBLE CODES ( BASE 10 ) IN RETURN CODE REGISTER     * 12940020
*                   0 = SUCCESSFUL COMPLETION OF VARY REQUEST         * 12960020
         AIF   (&VAR(1) EQ 1).VAR036    'MULTI-PROCESSING'              12970021
*                   4 = T.P. DEVICE - CANNOT VARY                     * 12980020
         AGO   .VAR037                                                  12984021
.VAR036  ANOP                                                           12988021
*                   4 = RESERVED FOR FUTURE USE                  A46458 12992021
.VAR037  ANOP                                                           12996021
*                   8 = THIS IS LAST PATH - CANNOT VARY               * 13000020
*                  12 = PATH DOES NOT EXIST - CANNOT VARY             * 13020020
*                  16 = INVALID BASE ADDRESS - CANNOT VARY            * 13040020
*                  20 = RESERVED DEVICE - CANNOT VARY                 * 13060020
*                  24 = ONLY ONE PATH - CANNOT VARY                   * 13080020
*                                                                     * 13100020
**********************************************************************  13120020
         SPACE 1                                                        13140020
         SPACE 1                                                        13160020
*********************************************************************** 13180020
*        REGISTER DEFINITIONS                                         * 13200020
*********************************************************************** 13220020
         SPACE 1                                                        13240020
IECIVPAR EQU   &PARM(1)                 PARAMETER REGISTER              13260020
IECIVCVT EQU   &PARM(2)                 CVT POINTER                     13280020
IECIVWK1 EQU   &PARM(3)                 NON - ADDRESSING WORK REGISTER  13300020
IECIVRTN EQU   &REG(1)                  RETURN CODE REGISTER            13320020
IECIVUCB EQU   &REG(2)                  UCB REGISTER                    13340020
IECIVXIT EQU   &REG(3)                  EXIT POINTER REGISTER           13360020
IECIVWK2 EQU   &REG(4)                  WORK REGISTER                   13380020
IECIVWK3 EQU   &REG(5)                  WORK REGISTER                   13400020
IECIVWK4 EQU   &REG(6)                  WORK REGISTER                   13420020
IECIVWK5 EQU   &REG(7)                  WORK REGISTER                   13440020
IECIVWK6 EQU   IECIVRTN                 WORK REGISTER                   13460020
IECIVBAS EQU   &REG(8)                  BASE REGISTER                   13480020
         AIF   (&VAR(1) EQ 0).VAR026    'UNI-PROCESSING'                13500020
IECIVPFX EQU   &REG(9)                  PREFIX REGISTER                 13520020
IECIVNUL EQU   0                        NULL REGISTER                   13540020
.VAR026  ANOP                                                           13560020
         SPACE 1                                                        13580020
*********************************************************************** 13600020
*        CHANNEL ERROR BLOCK DEFINITION AND FLAGS                     * 13620020
*********************************************************************** 13640020
         SPACE 1                                                        13660020
IECIVINA EQU   0                        CEB ACT/INACT FIELD             13680020
IECIVCCH EQU   1                        CEB CHANMSK FIELD               13700020
IECIVRQE EQU   2                        CEB RQE FIELD                   13720020
*                                                                     * 13740020
IECIVFRE EQU   X'FE'                    CEB INACTIVE INDICATOR          13760020
IECIVNEX EQU   4                        INCR TO NEXT CEB                13780020
IECIVACI EQU   0                        CEB ACTIVE IND FIELD            13800020
IECIVACT EQU   X'01'                    ACTIVE CEB INDICATOR            13820020
         SPACE 1                                                        13840020
*********************************************************************** 13860020
*        PARAMETER LIST TO VARY PATH                                  * 13880020
*********************************************************************** 13900020
         SPACE 1                                                        13920020
IECIVCHN EQU   0                        CHANNEL FIELD                   13940020
IECIVUA  EQU   1                        UNIT ADDRESS FIELD              13960020
IECIVOFL EQU   2                        OFFLINE/ONLINE INDICATOR        13980020
IECIVINC EQU   3                        OFFSET TO INPUT CPUID           14000020
IECIVEBC EQU   4                        EBCDIC NAME FIELD IN PARM LIST  14020020
IECIVSV1 EQU   4                        SAVE 1 WORKAREA OFFSET          14040020
IECIVSV2 EQU   5                        SAVE 2 WORKAREA OFFSET          14060020
IECIVSV3 EQU   6                        SAVE 3 WORKAREA OFFSET          14080020
IECIVSV4 EQU   7                        SAVE 4 WORKAREA OFFSET          14100020
IECIVWKA EQU   IECIVEBC                 ROUTINE WORK AREA               14120020
         SPACE 1                                                        14140020
*********************************************************************** 14160020
*        VARY PATH RETURN CODES                                       * 14180020
*********************************************************************** 14200020
         SPACE 1                                                        14220020
IECIVSUC EQU   0                        VARY COMPLETED SUCCESSFULLY     14240020
         AIF   (&VAR(1) EQ 1).VAR038    'MULTI-PROCESSING'              14250021
IECIVTPN EQU   4                        CANNOT VARY-TP DEVICE           14260020
.VAR038  ANOP                                                           14270021
IECIVLPO EQU   8                        CANNOT VARY-LAST PATH           14280020
IECIVNXS EQU   12                       PATH DOES NOT EXIST-CANNOT VARY 14300020
IECIVBAI EQU   16                       INVALID BASE ADDR-CANNOT VARY   14320020
IECIVRES EQU   20                       RSRVD DEV REQ CANCELLED         14340020
IECIVO1P EQU   24                       ONLY ONE PATH                   14360020
         SPACE 1                                                        14380020
*********************************************************************** 14400020
*        UCB DEFINITION AND FLAGS                                     * 14420020
*********************************************************************** 14440020
         SPACE 1                                                        14460020
IECIVFL3 EQU   0                        FLAG IN UCB PREFIX        21063 14470021
IECIVALC EQU   1                        UCB ALLOCATION CHANNEL MASK     14480020
IECIVSTA EQU   3                        UCB STATUS BYTE A DISP          14500020
IECIVUCH EQU   4                        UCB CHANNEL FIELD               14520020
IECIVFL1 EQU   6                        UCB FLAGS 1 FIELD               14540020
IECIVCHM EQU   12                       UCB CHANNEL MASK                14560020
IECIVUEB EQU   13                       UCB EBCDIC FIELD                14580020
IECIVDVT EQU   18                       UCB DEV TYPE FIELD              14600020
IECIVLTS EQU   20                       UCB LAST RQE FIELD              14620020
IECIVMLT EQU   X'01'                    MULTIPLE PATH INDICATOR         14640020
IECIVITF EQU   X'10'                    UCB INTERCEPT FLAG              14660020
IECIVDAD EQU   X'20'                    DIRECT ACCESS DEVICE CLASS FLAG 14680020
IECIVTPT EQU   X'40'                    TP DEVICE CLASS                 14700020
IECIV27A EQU   X'15'                    27RN UNIT TYPE A                14706021
IECIV27B EQU   X'25'                    27RN UNIT TYPE B                14712021
IECRSRVD EQU   X'20'                    IS THIS DEVICE RSRVD            14720020
IECIVSQC EQU   40                       RESERVE COUNT OFFSET            14740020
IECIVRSV EQU   41                       STATUS -- RESERVED OFFSET       14760020
IECIVASK EQU   X'02'                    ARM SEEKING                     14780020
IECIVDX  EQU   X'04'                    DATA TRANSFER                   14800020
IECIVCUB EQU   X'08'                    CONTROL UNIT BUSY               14820020
IECIVSDA EQU   X'20'                    SHARED DIRECT ACCESS            14840020
         SPACE 1                                                        14860020
*********************************************************************** 14880020
*        MISCELLANEOUS FLAGS AND PTRS                                 * 14900020
*********************************************************************** 14920020
IECIVONL EQU   X'04'                    ONLINE INDICATOR IN PARALIST    14940020
IECIVCEB EQU   24                       CEB PTR DISPLACE FROM NXTAVL    14960020
IECIVNXT EQU   124                      NEXT AVAILABLE                  14980020
IECIVLCH EQU   140                      OFFSET TO LCH TABLE PTR IN CVT  15000020
IECIVTCH EQU   6                        OFFSET IN TCH TAB TO TCH CODE   15020020
IECIVENT EQU   0                        NO ENTRIES IN TCH PREFIX TABLE  15040020
IECIVTCP EQU   0                        CHAN ADDR IN TCH PREFIX TABLE   15060020
IECIVPIN EQU   1                        PATH IND FLD IN TCH PRFX TABLE  15080020
IECIVCUZ EQU   X'0F'                    CONT UNIT ADDR ZERO MASK        15100020
IECIVCMP EQU   1                        TCH PATH COMPOSITE MASK         15120020
IECIVIMK EQU   X'FF'                    PATH INDICATOR MASK             15140020
IECIVQUE EQU   X'01'                    QUEUE RQE FLAG (FOR IOS)        15160020
IECIVLCI EQU   10                       LOGICAL CHANNEL INDEX IN UCB    15180020
IECIVILK EQU   X'28'                    CVT PTR TO UCB TAB IN IOS       15200020
IECIVCTR EQU   X'FF'                    CEB CTR MSK                     15220020
IECIVCHA EQU   20                      CHANMSK FIELD IN IOS             15240020
IECIVCUA EQU   X'F0'                    TCH CUA MASK                    15260020
IECIVNX  EQU   2                        INCR TO NEXT UCB IN UCBTAB      15280020
IECIVUC0 EQU   0                        DISPLACE TO UCBADDR IN TAB      15300020
IECIVCNT EQU   X'FF'                    COUNT TEST MASK                 15320020
         AIF   (&VAR(1) EQ 0).VAR027    'UNI-PROCESSING'                15340020
IECIVCPB EQU   X'08'                    WHICH CPU LAST ISSUED SIO 21063 15350021
IECIVPXL EQU   4                        MP UCB PREFIX LENGTH      21063 15352021
IECIVCPA EQU   C'A'                     CPU 'A' IDENTIFIER              15360020
IECIV2PI EQU   X'0A'                    2 PATH INDICATOR                15380020
IECIV4PI EQU   X'0F'                    4 PATH INDICATOR                15400020
IECIVPIB EQU   X'08'                    PATH INDICATOR BIT              15420020
IECIVMCT EQU   X'2A0'                   MULTIPROCESSING PSA CHAN TABLE  15440020
IECIVPX2 EQU   X'2B0'                   ADDRESS IN  PSA(A) OF PSA(B)    15460020
IECIVCID EQU   X'2B8'                   CPUID OFFSET IN PSA             15480020
IECIVRCF EQU   X'70'                    CHAN RECONFIGUATION MASK        15500020
IECIVOFF EQU   X'01'                    ONLINE/OFFLINE BIT       A46458 15510021
.VAR027  ANOP                                                           15520020
IECIVACM EQU   X'F00'                   ALTERNATE CHANNEL MASK          15540020
IECIVACU EQU   X'0F0'                   ALTERNATE CONTROL UNIT MASK     15560020
         EJECT                                                          15580020
         BALR  IECIVBAS,0                                               15600020
         USING *,IECIVBAS                                               15620020
         LA    IECIVXIT,IECIVEND                                        15640020
         L     IECIVWK2,IECIVILK(IECIVCVT) ADDR UCB TAB IN IOS          15660020
         SPACE 1                                                        15680020
*        FIND UCB                                                     * 15700020
         SPACE 1                                                        15720020
IECIV010 LH    IECIVUCB,0(IECIVWK2)     PTR TO UCB                      15740020
         LTR   IECIVUCB,IECIVUCB        TEST UCB ADDRESS                15760020
         BC    8,IECIV011              IF ZERO, LOOK AT NEXT UCB        15780020
*                                                                       15800020
         BC    4,IECIV012               IF NEG, END OF TBL -- ERROR     15820020
*                                       POSITVE  -- VALID ADDRESS       15840020
         CLC   IECIVEBC+1(3,IECIVPAR),IECIVUEB(IECIVUCB) EBCDIC NAME EQ 15860020
         BC   8,IECIV015               CHECK FOR MULT PATHS             15880020
*                                                                       15900020
IECIV011 LA    IECIVWK2,IECIVNX(IECIVWK2) BUMP TO NEXT UCB              15920020
         BC    15,IECIV010              CHECK NEXT UCB                  15940020
************************                                                15960020
         SPACE 1                                                        15980020
*        ERROR-INVALID BASE ADDRESS                                   * 16000020
         SPACE 1                                                        16020020
IECIV012 LA    IECIVRTN,IECIVBAI        SET RETRN CODE-INVAL BASE ADDR  16040020
         BCR   15,IECIVXIT              YES, RETURN INVALID REQUEST     16060020
************************                                                16080020
         SPACE 1                                                        16100020
*        TEST UCBALLC FOR MULTIPLE PATHS TO THE DEVICE                * 16120020
         SPACE 1                                                        16140020
IECIV015 XC    IECIVWKA(4,IECIVPAR),IECIVWKA(IECIVPAR) CLEAR WORK AREA  16160020
         AIF   (&VAR(1) EQ 1).VAR110    'MULTIPROC'                     16180020
         TM    IECIVALC(IECIVUCB),IECIVMLT MORE THAN 1 PATH TO DEV      16200020
         BC    8,IECIV042               IF NOT, BR TO INDICATE 1 PATH   16220020
         SPACE 1                                                        16260020
*        TEST DEVICE CLASS FIELD IN UCB FOR TP DEVICE                 * 16280020
         SPACE 1                                                        16300020
         TM    IECIVDVT(IECIVUCB),IECIVTPT IS THIS A TP DEVICE          16320020
         BC    14,IECIV016              NO, VALID REQUEST               16340021
         CLI   IECIVDVT+1(IECIVUCB),IECIV27A  Q. IS THIS A 27RN-15      16344021
         BE    IECIV016                 YES, VALID REQUEST              16348021
         CLI   IECIVDVT+1(IECIVUCB),IECIV27B  Q. IS THIS A 27RN-25      16352021
         BNE   IECIV045                 NO, RETURN INVALID REQUEST      16356021
.VAR110  SPACE 1                                                        16360021
*                                                                       16380020
IECIV016 TM    IECIVOFL(IECIVPAR),IECIVONL  Q. IS REQ. FOR 'V ONLINE'   16400021
         BC    1,IECIV020               A.  YES, SKIP RSVD DASD CODE.   16420020
         SPACE 1                                                        16440020
*    SHARED DASD'S NEED SPECIAL CONSIDERATION...                        16460020
*    THE VARY PATH OFFLINE FUNCTION IS CANCELLED UNDER THE CONDITION    16480020
*    THAT THIS CPU HAS ACCESS TO THE RESERVED DEVICE THROUGH THAT       16500020
*    PARTICULAR PATH SPECIFIED FOR THE VARY....                         16520020
         SPACE 2                                                        16540020
         TM    IECIVDVT(IECIVUCB),IECIVDAD  Q.  IS THIS A DASD.         16560020
         BC    8,IECIV020               A.  NO, BRANCH TO TEST PATHS.   16580020
*                                                                       16600020
         TM    IECIVDVT-1(IECIVUCB),IECIVSDA Q.  IS IT SHARED.          16620020
         BC    8,IECIV020               A.  NO, BRANCH TO TEST PATHS.   16640020
         SPACE 1                                                        16660020
*    DEVICE IS SHARED DASD.                                             16680020
         SPACE 1                                                        16700020
         MVC   IECIVSV1(2,IECIVPAR),IECIVUCH(IECIVUCB) MOVE LSTPTH21063 16720021
         NI    IECIVSV1(IECIVPAR),IECIVCUZ AND OFF FLAG BITS            16740020
         CLC   IECIVSV1(2,IECIVPAR),IECIVCHN(IECIVPAR) PATHS EQUAL21063 16760021
         BNE   IECIV020                 NO, SET UP FOR PATH SRCH  21063 16770021
         SPACE 1                                                        16780021
         AIF   (&VAR EQ 0).VAR111       'UNI-PROCESSING'          21063 16790021
*              CHECK IF PATH TO BE VARIED OFFLINE IS IN SAME CPU  21063 16800021
*              AS THE PATH IN THE VARY REQUEST                    21063 16810021
         SPACE 1                                                  21063 16820021
         LR    IECIVWK3,IECIVUCB        COPY UCB ADDRESS          21063 16830021
         SH    IECIVWK3,IECIVNEG        BACK OFF TO MP PREFIS     21063 16840021
         TM    IECIVFL3(IECIVWK3),IECIVCPB LAST SIO FROM CPU B    21063 16850021
         BZ    IECIV018                 NO-LAST SIO WAS FROM CPU A21063 16860021
         SPACE 1                                                  21063 16870021
*              LAST SIO WAS FOR CPU B                             21063 16880021
         SPACE 1                                                  21063 16890021
         CLI   IECIVINC(IECIVPAR),IECIVCPA VARY REQUEST FOR CPU A 21063 16900021
         BE    IECIV020                 YES GO DO PATH SEARCH     21063 16910021
.VAR111  SPACE 1                                                  21063 16920021
*              CHECK RESERVE COUNT AND ARM SEEK + DATA TRANSFER   21063 16930021
         SPACE 1                                                  21063 16940021
IECIV017 TM    IECIVRSV(IECIVUCB),IECIVCNT RESERVE CNT G.T. ZERO  21063 16950021
         BNZ   IECIV049                 YES-SET RC=X'20' - EXIT   21063 16960021
         TM    IECIVFL1(IECIVUCB),IECIVASK+IECIVDX ARMSK OR DTR ON21063 16970021
         BM    IECIV049                 YES-CANNOT VARY PATH-EXIT 21063 16980021
         AIF   (&VAR EQ 0).VAR111A      'UNI-PROCESSING'          21063 16990021
         B     IECIV020                 GO DO PATH SEARCH         21063 16992021
         SPACE 1                                                  21063 16994021
*              LAST SIO WAS FOR CPU A                             21063 16996021
         SPACE 1                                                  21063 16998021
IECIV018 CLI   IECIVINC(IECIVPAR),IECIVCPA VARY REQUEST FOR CPU A 21063 16998421
         BE    IECIV017                 YES-GO CHK RESERVE CNT    21063 16998821
.VAR111A SPACE 2                                                  21063 16999221
*    THIS CODE WILL DETERMINE WHETHER DEVICE CONTAINS SPECIFIED PATH  * 17000020
         SPACE 1                                                        17020020
IECIV020 DS    0H                                                       17040020
         AIF   (&VAR(1) EQ 0).VAR112    'UNI-PROCESSING'                17060020
         SR    IECIVWK1,IECIVWK1        CLEAR ORING REGISTER            17080020
         TM    IECIVALC(IECIVUCB),IECIVMLT  Q.  MORE THAN TWO PATHS.    17100020
         BC    1,IECIV021               A.  YES, SKIP '2-PATH' CODE.    17120020
*                                                                       17140020
         MVC   IECIVSV1(2,IECIVPAR),IECIVUCH(IECIVUCB) COPY UCBCHA FLD. 17160020
         NI    IECIVSV1(IECIVPAR),IECIVCUZ  AND OFF FLAG BITS.          17180020
         CLC   0(2,IECIVPAR),IECIVSV1(IECIVPAR)  Q.  ADDRS. EQUAL.      17200020
         BC    7,IECIV02C               A.  NO, EXIT - CANCEL VARY.     17220020
         SPACE 1                                                        17240020
*    ADDRESSES EQUAL - CONTINUE 'TWO-PATH' LOGIC--                      17260020
         SPACE 1                                                        17280020
         MVI   IECIVSV1(IECIVPAR),IECIV2PI  INDICATE TWO PATHS          17300020
         MVI   IECIVSV2(IECIVPAR),IECIVPIB  INITIALIZE PATH BIT         17320020
         MVI   IECIVSV3(IECIVPAR),IECIVPIB  INITIALIZE 'PATH-TO-BE' BIT 17340020
         IC    IECIVPFX,IECIVUCH(IECIVUCB)  PICK UP CHANNEL ADDRESS...  17360020
         BC    15,IECIV023              SKIP 'MORE-THAN-TWO-PATH' CODE. 17380020
************************                                                17400020
         SPACE 2                                                        17420020
IECIV021 MVI   IECIVSV1(IECIVPAR),IECIV4PI   SHOW 2 PATHS FOR EACH CPU. 17440020
.VAR112  ANOP                                                           17460020
         SPACE 1                                                        17480020
*    DETERMINE HOW MANY, AND WHAT, PATHS EXIST FROM TCH PREFIX TABLE  * 17500020
         SPACE 1                                                        17520020
         L     IECIVWK3,IECIVLCH(IECIVCVT) GET ADDR OF LCH TABLE        17540020
         SR    IECIVWK4,IECIVWK4        CLEAR WORKREG                   17560020
         IC    IECIVWK4,IECIVLCI(IECIVUCB)   GET LCH INDEX FROM UCB...  17580020
         SLL   IECIVWK4,3               IECIVWK4 = IECIVWK4 * 8         17600020
         LH    IECIVWK3,IECIVTCH(IECIVWK3,IECIVWK4) GET TCH CODE ADDR.  17620020
         N     IECIVWK3,IECIVHMK        AND OFF UNWANTED BITS.          17640020
         BCTR  IECIVWK3,0               * BACK UP ONE HALFWORD          17660020
         BCTR  IECIVWK3,0               * TO POINT TO TCH COMPOSITE...  17680020
         LR    IECIVWK5,IECIVWK3        SAVE POINTER                    17700020
         IC    IECIVWK4,0(IECIVWK3)     GET NUMBER OF PATHS.            17720020
         AR    IECIVWK4,IECIVWK4        DOUBLE TO GET OFFSET TO TOP..   17740020
         SR    IECIVWK5,IECIVWK4        GET POINTER TO TOP....          17760020
IECIV022 DS    0H                                                       17780020
         AIF   (&VAR(1) EQ 0).VAR113    'UNI-PROCESSING'                17800020
         SPACE 1                                                        17820020
*    SET UP SAVE INDICATORS FROM TCH SETTINGS...                        17840020
         SPACE 1                                                        17860020
         MVN   IECIVSV2(1,IECIVPAR),IECIVPIN(IECIVWK5) INIT PATH BIT    17880020
         IC    IECIVPFX,0(IECIVWK5)     GET CHANNEL ADDRESS             17900020
IECIV023 N     IECIVPFX,IECIVFOX        CLEAR FLAG BITS                 17920020
         LA    IECIVPFX,IECIVMCT(IECIVPFX,IECIVPFX) 2 * CHN + CHTAB ADR 17940020
         IC    IECIVWK4,IECIVSV2(IECIVPAR)  PICK UP PATH BIT            17960020
         CLI   IECIVCID(IECIVNUL),IECIVCPA Q.  IS THIS CPUA.            17980020
         BC    8,IECIV024               A.  YES, PATH PROPERLY SET      18000020
*                                                                       18020020
         SRL   IECIVWK4,2               A.  NO, MOVE TO CPU-B SLOT.     18040020
IECIV024 TM    0(IECIVPFX),IECIVRCF     Q.  IS CHANNEL OFFLINE. (CPUA)  18060020
         BC    8,IECIV025               A.  NO,SKIP OFFLINE SETTING.    18080020
*                                                                       18100020
         OR    IECIVWK1,IECIVWK4        OR IN OFFLINE BIT               18120020
IECIV025 A     IECIVPFX,IECIVPX2(IECIVNUL) GET CHANNEL OFFSET IN PSA(B) 18140020
         IC    IECIVWK4,IECIVSV2(IECIVPAR)  PICK UP PATH BIT.           18160020
         CLI   IECIVCID(IECIVNUL),IECIVCPA Q.  IS THIS CPUA.            18180020
         BC    7,IECIV026               A.  NO, SKIP RESHUFFLE SHIFT    18200020
*                                                                       18220020
         SRL   IECIVWK4,2               SHIFT MASK TO 'B' SIDE          18240020
IECIV026 TM    0(IECIVPFX),IECIVRCF     Q.  IS CHANNEL OFFLINE  (CPUB). 18260020
         BC    8,IECIV027               A.  NO, SKIP OFFLINE SETTING.   18280020
*                                                                       18300020
         OR    IECIVWK1,IECIVWK4        OR IN OFFLINE BIT               18320020
IECIV027 TM    IECIVALC(IECIVUCB),IECIVMLT  Q.  ALTERNATE PATH.         18340020
         BC    8,IECIV02A               A.  NO, IECIVWK1 SET UP AS IS.  18360020
*                                                                       18380020
.VAR113  LH    IECIVWK2,0(IECIVWK5)     GET TCHTAB ENTRY...             18400020
         LH    IECIVWK4,0(IECIVPAR)     GET PATHS TO GO OFF.            18420020
         LA    IECIVWK6,IECIVACM        PUT X'F00' IN REGISTER          18440020
         TM    IECIVUA(IECIVWK5),IECIVACU   Q.  ALTERNATE CU.           18460020
         BC    8,IECIV028               A.  NO, SKIP ALT CU CODE.       18480020
*                                                                       18500020
         LA    IECIVWK6,IECIVACU(IECIVWK6)  CHANGE MASK TO X'FF0'.      18520020
IECIV028 XR    IECIVWK2,IECIVWK4        COMBINE PATH AND TCHTAB ENTRY   18540020
         NR    IECIVWK2,IECIVWK6        AND OFF WITH SPECIAL MASK       18560020
         BC    7,IECIV029               BRANCH IF RESULT NOT ZERO       18580020
         SPACE 2                                                        18600020
*    EXECUTION OF FOLLOWING, IS BECAUSE SELECTED TCHTAB ENTRY PROVES    18620020
*                                       THERE IS A PATH.                18640020
         SPACE 1                                                        18660020
         MVN   IECIVSV3(1,IECIVPAR),IECIVPIN(IECIVWK5) SAVE PATH-TO-BE. 18680020
IECIV029 LA    IECIVWK5,IECIVNX(IECIVWK5) BUMP TO NEXT ENTRY            18700020
         CR    IECIVWK5,IECIVWK3        Q.  END OF TCH TABLE.           18720020
         BC    4,IECIV022               A.  NO, REITERATE.              18740020
*                                                                       18760020
IECIV02A SR    IECIVWK4,IECIVWK4        CLEAR WORK REGISTER             18780020
         IC    IECIVWK4,IECIVSV3(IECIVPAR) PICK UP PATH TO BE VARIED    18800020
         LTR   IECIVWK4,IECIVWK4        Q.  WAS A PATH FOUND...         18820020
         BC    8,IECIV02C               A.  NO, CANCEL VARY FUNCTION    18840020
*                                                                       18860020
         AIF   (&VAR(1) EQ 0).VAR014    'UNI-PROCESSING'                18880020
         CLI   IECIVINC(IECIVPAR),IECIVCPA  Q.  WAS REQUEST FROM CPUA.  18900020
         BC    8,IECIV030               A.  YES, SKIP ADJUSTMENT.       18920020
*                                                                       18940020
         SRL   IECIVWK4,2               ADJUST TO HIT CPUB PATH.        18960020
         STC   IECIVWK4,IECIVSV3(IECIVPAR) STORE ADJUSTED PATH.         18980020
IECIV030 STC   IECIVWK1,IECIVSV4(IECIVPAR) SAVE OFFLINE CHANNEL IND.    19000020
.VAR014  TM    IECIVOFL(IECIVPAR),IECIVONL  Q.  IS REQ FOR 'V ONLINE'.  19020020
         BC    1,IECIV02B               A.  YES, SKIP OFFLINE CODE.     19040020
*                                                                       19060020
         OC    IECIVSV4(1,IECIVPAR),IECIVCHM(IECIVUCB) OR WITH UCBCHM & 19080020
         OC    IECIVSV4(1,IECIVPAR),IECIVSV3(IECIVPAR)    WITH ADJ.PATH 19100020
         NI    IECIVSV4(IECIVPAR),IECIVCUZ   AND OFF ZONE BITS...       19120020
         AIF   (&VAR(1) EQ 0).VAR015A   'UNI-PROCESSING'                19140020
         XC    IECIVSV4(1,IECIVPAR),IECIVSV1(IECIVPAR) PATH REPRESENTED 19160020
         AGO   .VAR016                  SKIP UNI-PROCESSING INSTRUCTION 19180020
.VAR015A XC    IECIVSV4(1,IECIVPAR),IECIVPIN(IECIVWK3) PATH REPRESENTED 19200020
.VAR016  BC    8,IECIV02D               YES, GO TEST FOR APR.           19220020
*                                                                       19240020
         OC    IECIVCHM(1,IECIVUCB),IECIVSV3(IECIVPAR) SET PATH OFFLINE 19260020
         BC    15,IECIV130              SET RC AND RETURN               19280020
************************                                                19300020
         SPACE 2                                                        19320020
*    VARY PATH ONLINE                                                 * 19340020
         SPACE 1                                                        19360020
IECIV02B EQU   *                                                 A46458 19380021
         AIF   (&VAR(1) EQ 0).VAR014A   'UNI-PROCESSING'         A46458 19381021
         LR    IECIVWK2,IECIVUCB        GET UCB ADDRESS          A46458 19382021
         BCTR  IECIVWK2,0               BACK UP TO M65MP PREFIX  A46458 19383021
         SR    IECIVPFX,IECIVPFX        CLEAR REG                A46458 19384021
         IC    IECIVPFX,IECIVCHN(IECIVPAR) GET CHANNEL ADDRESS   A46458 19385021
         LA    IECIVPFX,IECIVMCT(IECIVPFX,IECIVPFX) 2*CHN+CHTAB  A46458 19386021
         CLC   IECIVCID(1,IECIVNUL),IECIVINC(IECIVPAR) IS PATH   A46458 19387021
*                                       IN THIS CPU              A46458 19388021
         BE    IECIV031                 YES,MAKE OFFLINE TEST    A46458 19389021
         A     IECIVPFX,IECIVPX2(IECIVNUL) NO, GET OTHER PREFIX  A46458 19390021
IECIV031 TM    IECIVNUL(IECIVPFX),IECIVRCF IS CHANNEL OFFLINE    A46458 19391021
         BC    4+2+1,IECIV02E           YES, LEAVE UCBMPFLK SET  A46458 19392021
         NI    IECIVNUL(IECIVWK2),X'FF'-IECIVOFF TURN UCBMPFLG   A46458 19393021
*                                       OFFLINE BIT OFF (ONLINE) A46458 19394021
.VAR014A ANOP                                                           19395021
IECIV02E XC    IECIVSV3(1,IECIVPAR),IECIVHMK+2 INVRT PTH BITS WITH 'FF' 19396021
         NC    IECIVCHM(1,IECIVUCB),IECIVSV3(IECIVPAR) BIT OFF=ONLINPTH 19400020
         L     IECIVWK2,IECIVNXT(IECIVCVT) PICK UP NXT AVLBL PTR IN IOS 19420020
         BC    15,IECIV121              ENSURE RESTART FROM 'LCH'.      19440020
************************                                                19460020
         SPACE 1                                                        19480020
IECIV02C LA    IECIVRTN,IECIVNXS        SET RC, INVALID REQUEST         19500020
         BCR   15,IECIVXIT              RETURN, VARY CANCELED           19520020
************************                                                19540020
         SPACE 2                                                        19560020
*    LOOK FOR ACTIVE CHANNEL ERROR BLOCK FOR THIS DEVICE...             19580020
         SPACE 1                                                        19600020
IECIV02D L     IECIVWK2,IECIVNXT(IECIVCVT) PICK UP NXT AVL PTR IN IOS   19620020
         XR    IECIVWK5,IECIVWK5        ZERO THE CEB COUNT REG          19640020
         IC    IECIVWK5,IECIVCEB(IECIVWK2) LOAD CEB CTR                 19660020
         L     IECIVWK6,IECIVCEB(IECIVWK2) LOAD CEB POINTER             19680020
         TM    IECIVACI(IECIVWK6),IECIVACT Q. ANY ACTIVE CEBS           19700020
         BC    8,IECIV041               NO SET LAST PATH RETCODE        19720020
*                                                                       19740020
IECIV035 TM    IECIVINA(IECIVWK6),IECIVFRE  Q. IS THIS CEB FREE         19760020
         BC    8,IECIV050               NO-CHECK IF RETRY IN PROCESS    19780020
*                                                                       19800020
IECIV040 LA    IECIVWK6,IECIVNEX(IECIVWK6) YES-LOOK AT NEXT CEB         19820020
         BCT   IECIVWK5,IECIV035        BRANCH, IF MORE CEB'S TO CHECK. 19840020
*                                                                       19860020
IECIV041 LA    IECIVRTN,IECIVLPO       RETURN LAST PATH                 19880020
         BCR   15,IECIVXIT              RETURN INVALID REQUEST          19900020
         AIF   (&VAR(1) EQ 1).VAR016A   'MULTI-PROCESSING'              19910021
************************                                                19920020
*                                                                       19940020
IECIV045 LA    IECIVRTN,IECIVTPN        SET CODE - CANNOT VARY TP DEV   19960020
         BCR   15,IECIVXIT              RETURN INVALID REQUEST          19980020
.VAR016A ANOP                                                           19990021
************************                                                20000020
*                                                                       20020020
IECIV042 LA    IECIVRTN,IECIVO1P        RETURN ONLY PATH CODE           20040020
         BCR   15,IECIVXIT              RETURN, VARY CANCELLED          20060020
************************                                                20080020
         SPACE 1                                                        20100020
IECIV049 LA    IECIVRTN,IECIVRES        SET RC, RESERVED DEVICE         20120020
         BCR   15,IECIVXIT              RETURN, VARY CANCELLED          20140020
************************                                                20160020
         SPACE 2                                                        20180020
IECIV050 CLC   IECIVLTS(2,IECIVUCB),IECIVRQE(IECIVWK6) Q.RETRY UNDERWAY 20200020
         BC    7,IECIV040               NO-LOOK AT NEXT CEB             20220020
*                                                                       20240020
         OI    IECIVINA(IECIVWK6),IECIVFRE  YES-DEACTIVATE CEB          20260020
         NC    IECIVCHM(1,IECIVUCB),IECIVCCH(IECIVWK6) CANCEL APR       20280020
         OC    IECIVCHM(1,IECIVUCB),IECIVSV3(IECIVPAR) SET PATH OFFLINE 20300020
         SPACE 1                                                        20320020
*********      ******************************************************** 20340020
*        THE FOLLOWING REQUIRED FOR INTERFACE WITH IOS                * 20360020
*              1.  SET IOS CHANMSK FIELD (AT NEXAVL+20) SO QUEUE WILL * 20380020
*                  BE SEARCHED BY IOS FOR REQUEST TO BE STARTED ON    * 20400020
*                  THIS PATH WHEN NEXT I/O INTERRUPT COMES IN         * 20420020
*********      ******************************************************** 20440020
         SPACE 1                                                        20460020
IECIV121 IC    IECIVWK5,IECIVUCH(IECIVUCB)  RESTORE CHANNEL ADDRESS.    20480020
         N     IECIVWK5,IECIVFOX        ZERO OUT FLAGS                  20500020
         L     IECIVWK4,IECIVZCH        SET UP TO CALC CHANMSK          20520020
         SRL   IECIVWK4,0(IECIVWK5)     CALCULATE CHANMSK               20540020
         LA    IECIVWK3,IECIVCHA(IECIVWK2) LOAD CHMSK PTR               20560020
         O     IECIVWK4,0(IECIVWK3)     SET NEW CHMSK IN REG            20580020
         ST    IECIVWK4,0(IECIVWK3)     SET NEW CHANMSK                 20600020
         SPACE 1                                                        20620020
IECIV130 LA    IECIVRTN,IECIVSUC        SET CODE SUCCESSFUL COMP        20640020
         BCR   15,IECIVXIT              RETURN                          20660020
************************                                                20680020
         SPACE 1                                                        20700020
         DS    0F                                                       20720020
IECIVFOX DC    X'0000000F'              CHAN ADDR MSK CONS              20740020
IECIVHMK DC    X'0000FFFF'              HALFWORD MASK                   20760020
IECIVZCH DC    X'80000000'              ZERO CHANNEL MASK               20780020
         AIF   (&VAR EQ 0).VAR015B                                21063 20790021
IECIVNEG DC    Y(IECIVPXL)              CONSTANT UCB MP65 PRFX LEN21063 20792021
.VAR015B ANOP                                                           20794021
IECIVEND DS    0H                                                       20800020
         SPACE 5                                                        20820020
         DROP  IECIVBAS                                                 20840020
         MEXIT                          EXIT MACRO                      21840020
.DOM010  AIF   (N'&REG LT 3).IOSNG2     IF INSUFFICIENT WKREGS, MNOTE.  24690019
         AIF   ('&AUTH' NE 'IEECVET7').IOSNG1    CHECK AUTH / MNOTE...  24700020
         EJECT                                                          24720019
*     THIS ROUTINE, PROVIDED AND MAINTAINED BY IOS PERSONNEL,           24750019
*     DETERMINES WHICH PREVIOUSLY ISSUED INTERVENTION REQUIRED          24780019
*     MESSAGES CAN BE DELETED.                                          24810019
*                                                                       24840019
*     A POINTER TO A LIST OF UNIT ADDRESSES IS PROVIDED.  THIS          24870019
*     ROUTINE FINDS THE UCB FOR EACH UNIT ADDRESS, DETERMINES           24900019
*     WHETHER OR NOT THE INT REQ MESSAGE HAS BEEN SATISFIED VIA         24930019
*     THE READY/NOT READY FLAG, AND MARKS THE LIST ENTRY AS BEING       24960019
*     (NOT) DOM-ABLE.                                                   24990019
         SPACE 2                                                        25020019
*              REGISTER DEFINITION                                      25040020
IECIDINP EQU   &PARM                    POINTER TO LIST                 25060020
IECIDLST EQU   &REG(1)                  REG USED FOR LIST SCAN          25080020
IECIDWK1 EQU   &REG(2)                  WORK REGISTER                   25100020
IECIDWK2 EQU   &REG(3)                  WORK REGISTER                   25120020
         SPACE 1                                                        25140020
*              MISCELLANEOUS EQUATES                                    25160020
IECIDCVT EQU   16                       POINTER TO CVT                  25180020
IECIDLK2 EQU   40                       CVT OFFSET TO UCB LIST          25200020
IECIDUCB EQU   0                        DISP TO UCB PTR IN SCAN TBL     25220020
IECIDIN2 EQU   2                        UCB SCAN TBL INCREMENT          25240020
IECIDIN4 EQU   4                        DOM LIST INCREMENT              25260020
IECIDSP0 EQU   0                        DISPLACEMENT OF 0               25280020
IECIDSP1 EQU   1                        DISPLACEMENT OF 1               25300020
IECIDSP2 EQU   2                        DISPLACEMENT OF 2               25320020
IECIDFL1 EQU   6                        DISP IN UCB OF FLAGS 1          25340020
IECIDUTN EQU   13                       DISP IN UCB OF UNIT NAME        25360020
IECIDTYP EQU   16                       DISP IN UCB OF UCB TYPE         25380020
IECIDTAP EQU   X'80'                    TAPE DEVICE TYPE INDICATOR      25400020
IECIDNRY EQU   X'40'                    UCB NOT READY FLAG              25420020
IECIDITF EQU   X'10'                    UCB INTERCEPT FLAG              25440020
IECIDDOM EQU   X'40'                    DOM INDICATOR                   25460020
IECIDEND EQU   X'80'                    END OF LIST INDICATOR           25480020
         SPACE 2                                                        25500020
         LR    IECIDLST,IECIDINP        PUT LIST ADR IN WORK REG        25520020
         BC    15,IECID002              FIRST TIME BRANCH               25540020
************************                                                25560020
         SPACE 1                                                        25580020
IECID000 LR    IECIDWK1,IECIDLST        INIT REG FOR SCAN               25600020
         LA    IECIDWK2,IECIDIN4        INIT REG FOR DECREMENT          25620020
IECID001 SR    IECIDWK1,IECIDWK2        POINT TO PREV ENTRY             25640020
         CLC   IECIDSP1(3,IECIDLST),IECIDSP1(IECIDWK1) EQ UNIT ADR      25660020
         BC    8,IECID007               YES, GO TO HANDLE               25680020
*                                                                       25700020
         CR    IECIDWK1,IECIDINP        LAST ENTRY TESTED               25720020
         BC    2,IECID001               NO, CONTINUE TEST               25740020
*                                                                       25760020
IECID002 L     IECIDWK1,IECIDCVT        GET CVT ADDR                    25780020
         L     IECIDWK1,IECIDLK2(0,IECIDWK1)  UCB SCAN TABLE            25800020
IECID003 LH    IECIDWK2,IECIDSP0(0,IECIDWK1)  GET UCB PTR               25820020
         LTR   IECIDWK2,IECIDWK2        TEST FOR VALID UCB              25840020
         BC    4+2,IECID005             YES, GO TO TEST                 25860020
*                                                                       25880020
IECID004 LA    IECIDWK1,IECIDIN2(0,IECIDWK1)  UPDATE TABLE PTR          25900020
         CLI   IECIDSP1(IECIDWK1),X'FF'  TEST FOR END OF TABLE          25920020
         BC    8,IECID006               YES, NO DOM FOR THIS MSG        25940020
*                                                                       25960020
         BC    15,IECID003              CONTINUE SEARCH                 25980020
************************                                                26000020
         SPACE 1                                                        26020020
IECID005 N     IECIDWK2,IECIDMSK        INSURE HALF WORD PTR            26040020
         CLC   IECIDSP1(3,IECIDLST),IECIDUTN(IECIDWK2) EQ UNIT NAME     26060020
         BC    7,IECID004               NO, CONTINUE SEARCH             26080020
*                                                                       26100020
         TM    IECIDFL1(IECIDWK2),IECIDNRY  TEST IF DEVICE READY        26120020
         BC    8,IECID008               YES, GO TO INDICATE DOM         26140020
*                                                                       26160020
         CLI   IECIDTYP+2(IECIDWK2),IECIDTAP  TEST FOR TAPE DEVICE      26180020
         BC    7,IECID006               NO, INDICATE NO DOM             26200020
*                                                                       26220020
         TM    IECIDFL1(IECIDWK2),IECIDITF  TEST REWIND,UNLOAD COND     26240020
         BC    1,IECID008               YES, INDICATE DOM               26260020
*                                                                       26280020
IECID006 NI    IECIDSP0(IECIDLST),X'FF'-IECIDDOM  INDICATE NO DOM       26300020
         BC    15,IECID009              GO TO UPDATE LIST PTR           26320020
************************                                                26340020
         SPACE 1                                                        26360020
IECID007 OC    IECIDSP0(1,IECIDLST),IECIDSP0(IECIDWK1) DOM EQ PREV      26380020
         OI    IECIDSP0(IECIDWK1),IECIDDOM  SET DOM FOR PREV            26400020
         BC    15,IECID009              GO TO UPDATE LIST PTR           26420020
************************                                                26440020
         SPACE 1                                                        26460020
IECID008 OI    IECIDSP0(IECIDLST),IECIDDOM  INDICATE DOM                26480020
IECID009 TM    IECIDSP0(IECIDLST),IECIDEND  TEST FOR LIST END           26500020
         BC    1,IECID010               YES, LEAVE ROUTINE              26520020
*                                                                       26540020
         LA    IECIDLST,IECIDIN4(0,IECIDLST)  POINT TO NEXT ENTRY       26560020
         BC    15,IECID000              GO TO HANDLE                    26580020
************************                                                26600020
         SPACE 1                                                        26620020
         DS    0F                                                       26640020
IECIDMSK DC    X'0000FFFF'              HALF WORD UCB PTR MASK          26660020
IECID010 DS    0H                       END OF ROUTINE                  26680020
         SPACE 2                                                        26700020
         MEXIT                          EXIT MACRO                      26720020
.PTH010  AIF   (N'&REG LT 7).IOSNG2     IF INSUFFICIENT WKREGS, MNOTE.  26740020
         AIF   ('&AUTH' NE 'IEE1C03D').PTH011 CHECK AUTHORIZATION.      27162019
         AGO   .PTH014                  SKIP NEXT STATEMENT.            27168019
.PTH011  AIF   ('&AUTH' NE 'IEE3603D').IOSNG1  GOTO MNOTE.              27174019
.PTH014  ANOP                                                           27180019
         EJECT                                                          27190019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27210019
*                                                                     * 27230019
*     THIS ROUTINE, PROVIDED AND MAINTAINED BY IOS PERSONNEL,         * 27250019
*     DETERMINES WHETHER OR NOT A PATH IS AVAILABLE TO A DEVICE.      * 27270019
*                                                                     * 27290019
*     THIS FUNCTION ASSUMES THAT IT WILL RUN IN AN ENVIRONMENT WHERE  * 27295019
*     ALL INTERRUPTS ARE DISABLED...                                  * 27300019
*                                                                     * 27305019
*     THIS FUNCTION IS INVOKED BY CODING TO THE FOLLOWING FORMAT --   * 27310020
*        IOSGEN PTHAVL,&PARM,(&REG(1),&REG(2),... ,&REG(7)),&VAR,   + * 27315020
*                  AUTH=CSECTNME                                      * 27320020
*                                                                     * 27325020
*     WHERE -  1. &PARM MUST SPECIFY A REGISTER WHICH POINTS TO THE   * 27330020
*                  UCB FOR THE DEVICE TO BE CHECKED FOR PATH          * 27335020
*                  AVAILIBILITY.                                      * 27340020
*              2. &REG(1) MUST SPECIFY A REGISTER WHICH POINTS TO A   * 27345020
*                  ONE WORD WORKAREA.                                 * 27350020
*              3. &REG(2) THROUGH &REG(7) MUST SPECIFY SIX REGISTERS  * 27355020
*                  THAT MAY BE USED BY THIS ROUTINE.                  * 27360020
*              4. &VAR MUST BE A '1', FOR ONLY IN MULTIPROCESSING MAY * 27365020
*                  ALL PATHS BE VARY'ED OFFLINE.                      * 27370020
*              5. THE KEYWORD PARAMETER, 'AUTH=CSECTNME' MUST SPECIFY * 27375020
*                  THE OFFICIAL NAME OF THE CSECT INVOKING THIS FUNCTN* 27380020
*                                                                     * 27385020
*                                                                     * 27405020
*     THIS ROUTINE WILL DETERMINE PATH AVAILABILITY VIA A COMPARISON  * 27425020
*     OF THE UCBCHM FIELD (REPRESENTING PATHS HAVING PREVIOUSLY       * 27445020
*     BEEN FOUND TO BE NOT OPERATIONAL) AND AN IOS TCHCODE TABLE      * 27465020
*     CONSTANT (CALLED THE PATH COMPOSITE AND REPRESENTING THE TOTAL  * 27485020
*     NUMBER OF PATHS TO THE DEVICE). IN ADDITION, CHANNEL AVAILABIL- * 27505020
*     ITY IS CHECKED IN BOTH PSA CHANNEL TABLES.                      * 27525020
*                                                                     * 27545020
*     THE OUTPUT OF THIS MACRO IS A CONDITION CODE SETTING:           * 27565020
*          C.C. = ZERO, IF A PATH IS NOT AVAILABLE                    * 27585020
*          C.C. = OTHER THAN ZERO, IF A PATH IS AVAILABLE             * 27605020
*                                                                     * 27625020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27645020
         SPACE 2                                                        27665020
*                    REGISTER DEFINITION                              * 27685020
IECIPUCB EQU   &PARM                    UCB POINTER                     27705020
IECIPWK0 EQU   &REG(1)                  WORKAREA POINTER                27725020
IECIPWK1 EQU   &REG(2)                  WORK REGISTER                   27745020
IECIPWK2 EQU   &REG(3)                  WORK REGISTER                   27765020
IECIPWK3 EQU   &REG(4)                  WORK REGISTER                   27785020
IECIPWK4 EQU   &REG(5)                  WORK REGISTER                   27805020
IECIPWK5 EQU   &REG(6)                  WORK REGISTER                   27825020
IECIPWK6 EQU   &REG(7)                  WORK REGISTER                   27845020
         SPACE 1                                                        27865020
*                    MISCELLANEOUS EQUATES                            * 27885020
IECIPCVT EQU   16                       POINTER TO CVT                  27905020
IECIPSYS EQU   116                      DISP IN CVT OF SYSTEM TYPE      27925020
IECIPLCH EQU   140                      DISP IN CVT OF LCH TAB PTR      27945020
IECIPMP  EQU   X'14'                    MULTI-PROCESSING FLAG           27965020
IECIPLCI EQU   10                       DISP IN UCB OF LCH INDEX        27985020
IECIPCHM EQU   12                       DISP IN UCB OF UCBCHM           28005020
IECIPABL EQU   X'0A'                    MASK FOR TESTING UCBCHM         28025020
IECIPMPF EQU   X'01'                    UCB ALLOC CHN MSK MULT PATH FLG 28045020
IECIPMCT EQU   X'2A0'                   M.P. PSA CHAN TABLE             28065020
IECIPRCF EQU   X'70'                    CHANNEL RECONFIG MASK           28085020
IECIPCHA EQU   4                        OFFSET TO CHANNL ADDRESS IN UCB 28105020
IECIPCPA EQU   C'A'                     CPU-A IDENTIFIER                28125020
IECIPPTR EQU   X'2B0'         OFFSET IN EACH PSA TO THE OTHERS PTR      28145020
IECIPTCH EQU   6                        DISP IN LCH WORD OF TCH CD PTR  28165020
IECIPMAX EQU   X'0F'                    MASK FOR ALL POSSIBLE PATHS     28185020
IECIPCID EQU   X'2B8'                   OFFSET IN EA PSA TO CPU - ID    28205020
IECIP0   EQU   0                        DISP OF ZERO                    28225020
IECIP1   EQU   1                        DISP OF ONE                     28245020
IECIP2   EQU   2                        DISPLACEMENT OF 2               28265020
IECIP3   EQU   3                        DISPLACEMENT OF 3               28285020
IECIP8   EQU   8                        DISPLACEMENT OF 8               28305020
         SPACE 2                                                        28325020
         AIF   (&VAR(1) EQ 0).IOSNG3    IF 'UNI-PROC' SPECIFIED, MNOTE. 28345020
         SR    IECIPWK2,IECIPWK2        CLEAR REGISTER                  28365020
         ST    IECIPWK2,IECIP0(IECIPWK0) CLEAR WORKAREA           M1000 28385020
         MVN   IECIP3(IECIP1,IECIPWK0),IECIPCHM(IECIPUCB) MOVE PTH BITS 28405020
         MVI   IECIP2(IECIPWK0),IECIPMAX MOVE A HEX '0F' INTO BYTE      28425020
         LA    IECIPWK4,IECIP2(IECIP0)  INITIALIZE BCT REG WITH A 2     28445020
         LR    IECIPWK5,IECIPWK4        INITIALIZE BCT REG WITH A 2     28465020
         TM    IECIP1(IECIPUCB),IECIPMPF Q.ARE THERE MULTI-PATHS        28485020
         BC    1,IECIP005               A.YES, BRANCH TO TCHTBL CODING  28505020
*                                                                       28525020
         LA    IECIPWK4,IECIP1(IECIP0)  A.NO, INIT BCT REG WITH A 1     28545020
         LA    IECIPWK1,IECIP8          INIT WITH AN 8 FOR PRIMARY PATH 28565020
         MVI   IECIP2(IECIPWK0),IECIPABL INITIALIZE BYTE 1 TO 0A        28585020
         IC    IECIPWK6,IECIPCHA(IECIPUCB) INSERT CHANNL ADR FROM UCB   28605020
         BC    15,IECIP021              BR AROUND TCHTBL CODE           28625020
************************                                                28645020
IECIP005 IC    IECIPWK2,IECIPLCI(0,IECIPUCB) GET LCH INDEX              28665020
         SLL   IECIPWK2,IECIP3          MULT BY 8 FOR CORRECT INDEX     28685020
         L     IECIPWK1,IECIPCVT        GET CVT POINTER AT LOCATION 16  28705020
         A     IECIPWK2,IECIPLCH(0,IECIPWK1) POINTER TO PROPER LCH      28725020
         LH    IECIPWK2,IECIPTCH(0,IECIPWK2) POINTER TO TCH CODE        28745020
         N     IECIPWK2,IECIPMSK        INSURE HALF WORD POINTER        28765020
         SH    IECIPWK2,IECIPSIX        SUB 6 TO POINT TO TOP OF TCHTBL 28785020
IECIP006 IC    IECIPWK6,IECIP0(IECIPWK2) GET CHAN ADDR FROM TCHCODE TBL 28805020
         IC    IECIPWK1,IECIP1(IECIPWK2) GET 4 PTHBITS FROM TCHCODE TBL 28825020
         N     IECIPWK1,IECIPWRD        TURN OFF PRECEDING FLAG BITS    28845020
IECIP021 N     IECIPWK6,IECIPWRD        CLEAR PRECDNG FLGS IN CHNNL ADR 28865020
         STC   IECIPWK1,IECIP0(IECIP0,IECIPWK0) STORE PTH INDCATR BYTE  28885020
         SPACE 1                                                        28905020
*     M.P. CHANNEL TABLE POINTER IN THE PSA PLUS 2 TIMES CHANNEL =    * 28925020
*     PTR TO PROPR ELEMNT IN THE CHNNL TBL IN THE LO-CORE PSA AREA    * 28945020
         SPACE 1                                                        28965020
         LA    IECIPWK6,IECIPMCT(IECIPWK6,IECIPWK6) 2 * CHN + CHTBL PTR 28985020
         SR    IECIPWK3,IECIPWK3        CLEAR REG FOR PSA INDEX USE     29005020
IECIP011 TM    IECIP0(IECIPWK6),IECIPRCF Q.IS CHNNL OFFLINE(CPU-A OR B) 29025020
         BC    8,IECIP013               A.IF NO,BR.WE GOT AT LEAST 1 CH 29045020
*                                                                       29065020
IECIP012 CLI   IECIPCID(IECIPWK3),IECIPCPA Q.IS THIS CPU-A (HIORLO COR) 29085020
         BC    8,IECIP004               A. IF YES, SKIP ADJUSTMNT       29105020
*                                                                       29125020
         SRL   IECIPWK1,2               ADJUST TO HIT CPU-B PATH        29145020
IECIP004 O     IECIPWK1,IECIP0(IECIP0,IECIPWK0) TURN ON DOWN PATH BITS  29165020
         ST    IECIPWK1,IECIP0(IECIP0,IECIPWK0)  STORE INTO BYTES 1&2   29185020
IECIP013 BCT   IECIPWK5,IECIP014        DECREMNT CNTR & BR OR FALL THRO 29205020
*                                                                       29225020
         LA    IECIPWK5,IECIP2(IECIP0)  REINITIALIZE BCT REG WITH A 2   29245020
         LA    IECIPWK2,IECIP2(IECIPWK2) UPDTE TCHTBL PTR TO NXT CH PTH 29265020
         BCT   IECIPWK4,IECIP006        DECREMNT CNTR & BR OR FALL THRO 29285020
*                                                                       29305020
         CLC   IECIP2(IECIP1,IECIPWK0),IECIP3(IECIPWK0) IS BYTE1=BYTE2  29325020
         BC    15,IECIP003              BR TO EXIT                      29345020
************************                                                29365020
IECIP014 A     IECIPWK6,IECIPPTR(IECIP0) ADD HI-CORE PSAPTR TO PREV PTR 29385020
         A     IECIPWK3,IECIPPTR(IECIP0) INSERT HI-COR PSAPTR IN REG    29405020
         IC    IECIPWK1,IECIP0(IECIPWK0) REINIT PATH INDICATOR BYTE     29425020
         BC    15,IECIP011              CONTINUE BCT LOOP               29445020
************************                                                29465020
         DS    0F                       BOUNDARY ALIGNMENT              29485020
IECIPWRD DC    X'0000000F'              FOR CLEARING REGS 1ST 3.5 BYTES 29505020
IECIPMSK DC    X'0000FFFF'                                              29525020
IECIPSIX DC    H'6'                     HALFWORD SIX                    29545020
IECIP003 DS    0H                       EXIT FROM ROUTINE               29565020
         SPACE 2                                                        29585020
         MEXIT                                                          29605020
.SSM000  AIF   ('&AUTH' EQ 'IGFMCH10').SSM0A0                     M0402 29705020
         AIF   ('&AUTH' EQ 'IGFMCHE0').SSM0A0                     M0402 29805020
         AGO   .IOSNG1                  UNAUTHORIZED USE MNOTE.         29905020
.SSM0A0  AIF   (&VAR EQ 1).SSM001       OTHER OPTION                    30005020
         AIF   (N'&REG LT 4).IOSNG2     IF INSUFFICIENT WKREGS, MNOTE.  30105020
         EJECT                                                          30780019
*    THIS ROUTINE, PROVIDED AND MAINTAINED BY IOS PERSONNEL,            30810019
*    SELECTIVELY ENABLES ALL CHANNELS BY WHICH A GIVEN DEVICE           30840019
*    CAN BE ACCESSED.FOR 360 MACHINES CHANNELS 0-5 ARE SELECT-  SA53991 30870021
*    IVELY ENABLED BY TURNING ON BITS 0-5 OF THE PSW. CHANNELS  SA53991 30872021
*    6-N ARE COLLECTIVELY ENABLED BY TURNING ON BIT 6 OF THE    SA53991 30874021
*    PSW.FOR 370 MACHINES RUNNING IN BC MODE CHANNELS 0-5 ARE   SA53991 30876021
*    HANDLED THE SAME AS WITH 360 MACHINES. CHANNELS 6-N ARE    SA53991 30878021
*    SELECTIVELY ENABLED BY TURNING ON CORRESPONDING BITS IN    SA53991 30880021
*    CONTROL REGISTER 2. BIT 6 IN THE PSW IS TURNED ON TO       SA53991 30882021
*    INDICATE THAT I/O INTERRUPTS ON CHANNEL 6 AND HIGHER ARE   SA53991 30884021
*    UNDER CONTROL OF THE BIT SETTINGS IN CONTROL REGISTER 2.   SA53991 30886021
*    CSECT IGFMCHEO IS UNIQUE TO 370 AND IS USED TO INVOKE THE  SA53991 30888021
*    370 LOGIC. IF IN THE FUTURE OTHER CSECTS ARE AUTHORISED    SA53991 30890021
*    THE LOGIC SHOULD BE REVIEWED.                              SA53991 30892021
*                                                                       30900019
*        THIS FUNCTION IS INVOKED BY CODING ACCORDING TO THE FOLLOWING  30908020
*        FORMAT --                                                      30916020
*        IOSGEN SELSSM,&PARM,(&REG(1),&REG(2),&REG(3),&REG(4)),&VAR, +  30924020
*              AUTH=CSECTNME            WHERE --                        30932020
*       1. &PARM MUST SPECIFY A REGISTER WHICH POINTS TO THE UCB FOR    30940020
*              THE DEVICE FOR WHICH CHANNEL PATHS MUST BE ENABLED.      30948020
*       2. &REG(1) THROUGH &REG(4) MUST SPECIFY FOUR REGISTERS WHICH    30956020
*              MAY BE USED BY THIS ROUTINE.                             30964020
*       3. &VAR MUST, FOR THIS VARIATION, BE '0'.                       30972020
*       4. THE KEYWORD PARAMETER 'AUTH=CSECTNME' MUST SPECIFY THE NAME  30980020
*              OF THE CSECT INVOKING THIS MACRO.                        30988020
*                                                                       30996020
*        THIS ROUTINE, USING BOTH THE UCB AND THE TCH PREFIX TABLE,     31004020
*    FORMATS THE SYSTEM MASK OF A PSW PROVIDED WITHIN THIS ROUTINE.     31020019
*    THE ADDRESS PORTION OF THE PSW POINTS TO THE FIRST BYTE            31050019
*    AFTER THIS ROUTINE.  A LPSW INSTRUCTION PROVIDES THE               31080019
*    SELECTIVE ENABLE AND CAUSES THE CALLER'S NEXT SEQUENTIAL           31110019
*    INSTRUCTION TO BE EXECUTED.                                        31140019
         SPACE 1                                                        31170019
*********************************************************************** 31200019
         AIF   ('&AUTH' EQ 'IGFMCHE0').SSM370                   SA53991 31210021
         SPACE 2                                                        31230020
*        REGISTER DEFINITION                                            31260020
IECISUCB EQU   &PARM                    POINTER TO UCB                  31290020
IECISWK1 EQU   &REG(1)                  WORK REGISTER                   31320020
IECISWK2 EQU   &REG(2)                  WORK REGISTER                   31350020
IECISWK3 EQU   &REG(3)                  WORK REGISTER                   31380020
IECISWK4 EQU   &REG(4)                  WORK REGISTER                   31410020
         SPACE 1                                                        31440020
*        MISCELLANEOUS EQUATES                                          31470020
IECIS0   EQU   0                        ZERO MASK AND DISPLACEMENT      31500020
IECIS2   EQU   2                        DISPLACEMENT OF 2               31530020
IECIS3   EQU   3                        DISPLACEMENT OF 3               31560020
IECIS6   EQU   6                        DISPLACEMENT OF 6               31590020
IECIS8   EQU   8                        DISPLACEMENT OF 8               31620020
IECISCVT EQU   16                       ADDRESS OF CVT POINTER          31650020
IECISLCH EQU   140                      DISPL INTO CVT OF LCH TBL PTR   31680020
IECISLCI EQU   10                       DISPL INTO UCB OF LCH INX       31710020
IECISACM EQU   1                        DISPL INTO UCB OF ALLC CHN MSK  31740020
IECISCUA EQU   4                        DISPL INTO UCB OF DEV ADDR      31770020
IECISPTH EQU   X'01'                    MULTI-PATH INDIC IN UCB         31800020
IECISSM0 EQU   X'80'                    SYSTEM MASK FOR CHAN 0          31830020
         SPACE 2                                                        31860020
         MVI   IECISMSK+1,IECIS0        INIT MASK FOR PSW SYST MASK     31890020
         LH    IECISWK1,IECISCUA(0,IECISUCB) GET DEV ADDRESS            31920020
         SR    IECISWK4,IECISWK4        INIT REG FOR 1 CHN PATH TO DEV  31950020
         LA    IECISWK3,IECIS2          INIT REG FOR 1 CHN PATH TO DEV  31980020
         TM    IECISACM(IECISUCB),IECISPTH TEST IF MORE THAN ONE PATH   32010020
         BC    8,IECIS001               NO, GO TO SET SYSTEM MASK       32040020
*                                                                       32070020
         L     IECISWK1,IECISCVT        GET PTR TO CVT                  32100020
         L     IECISWK1,IECISLCH(0,IECISWK1) GET LCH TBL POINTER        32130020
         SR    IECISWK2,IECISWK2        CLEAR REGISTER                  32160020
         IC    IECISWK2,IECISLCI(0,IECISUCB) GET LCH INDEX INTO TBL     32190020
         SLL   IECISWK2,IECIS3          MULT BY 8 TO FORM DISPL         32220020
         LH    IECISWK3,IECIS6(IECISWK1,IECISWK2) GET PTR TO TCH CODE   32250020
         N     IECISWK3,IECISHWD        INSURE TWO BYTE ADDRESS         32280020
         SH    IECISWK3,IECISTWO        BACK UP BY 2 - PT TO PTH SUMMRY 32310020
         IC    IECISWK2,IECIS0(0,IECISWK3) GET TOTAL NO. OF PATHS       32340020
         AR    IECISWK2,IECISWK2        DOUBLE TO GET START OF PTH TBL  32370020
         LR    IECISWK4,IECISWK3        GET BACK UP TBL PTR             32400020
         SR    IECISWK4,IECISWK2        POINT TO PATH TBL ORIGIN        32430020
IECIS000 LH    IECISWK1,IECIS0(0,IECISWK4) GET PATH TO DEVICE           32460020
IECIS001 N     IECISWK1,IECISADR        INSURE VALID PATH ADDRESS       32490020
         SRL   IECISWK1,IECIS8          ISOLATE CHANNEL                 32520020
         LA    IECISWK2,IECISSM0        INIT SYST MASK FOR CHAN 0       32550020
         SRL   IECISWK2,IECIS0(IECISWK1) SHIFT BIT BY AMT = CHAN NO.    32580020
*                                       TO GET BIT IN PROPER POSITN     32610020
         CH    IECISWK2,IECISTWO        TEST FOR CHANNEL GT SIX         32640020
         BC    8+2,IECIS002             NO, BRANCH                      32670020
*                                                                       32700020
         LH    IECISWK2,IECISTWO        YES, RESET TO CHAN SIX          32730020
IECIS002 STC   IECISWK2,IECISMSK        SET APPROP CHN BIT FOR SYS MASK 32760020
         OC    IECISMSK+1(1),IECISMSK   OR INTO MASK                    32790020
         LA    IECISWK4,IECIS2(0,IECISWK4) UPDATE PTH TBL POINTER       32820020
         CR    IECISWK4,IECISWK3        TEST IF ALL POSS CHN PTHS PROC  32850020
         BC    7,IECIS000               NO, GO TO GET NEXT PATH         32880020
*                                                                       32910020
         MVC   IECISPSW(1),IECISMSK+1   INIT THE SYS MASK IN THE PSW    32940020
         LPSW  IECISPSW                 PERFORM THE SSM VIA LPSW        32970020
************************                                                33000020
         SPACE 2                                                        33030020
*        CONSTANTS                                                      33060020
IECISPSW DS    0D                       PSW USED TO SET SYS MASK        33090020
         DC    X'0004'                  SYSTEM MASK, KEY, AMWP,         33120020
         DC    H'0'                     INTERRUPTION CODE               33150020
         DC    A(IECISEND)              ILC, CC, PGM MSK, ADDR OF NSI   33180020
IECISHWD DC    X'0000FFFF'              HALF WORD MASK                  33210020
IECISADR DC    X'00000FFF'              VALID DEV ADDR MASK             33240020
IECISMSK DC    X'0000'                  MASK USED TO FORM SYS MASK      33270020
IECISTWO DC    H'2'                     COMPARAND FOR VALID SYS MASK    33300020
IECISEND DS    0C                                                       33330020
         MEXIT                          EXIT MACRO                      33360020
.SSM370  ANOP                                                   SA53991 33360321
         SPACE 2                                                SA53991 33360621
*        REGISTER DEFINITION                                    SA53991 33360921
IECISUCB EQU   &PARM                    POINTER TO UCB          SA53991 33361221
IECISWK1 EQU   &REG(1)                  WORK REGISTER           SA53991 33361521
IECISWK2 EQU   &REG(2)                  WORK REGISTER           SA53991 33361821
IECISWK3 EQU   &REG(3)                  WORK REGISTER           SA53991 33362121
IECISWK4 EQU   &REG(4)                  WORK REGISTER           SA53991 33362421
IECCTLR2 EQU   2                        CHANL MASK CONTROL REG2 SA53991 33362721
IECCTLR3 EQU   3                        CHNL MASK CONTROL REG3  SA53991 33363021
         SPACE 1                                                SA53991 33363321
*        MISCELLANEOUS EQUATES                                  SA53991 33363621
IECIS0   EQU   0                   ZERO MASK AND DISPLACEMENT   SA53991 33363921
IECIS2   EQU   2                        DISPLACEMENT OF 2       SA53991 33364221
IECIS3   EQU   3                        DISPLACEMENT OF 3       SA53991 33364521
IECIS4   EQU   4                        DISPLACEMENT OF 4       SA53991 33364821
IECIS6   EQU   6                        DISPLACEMENT OF 6       SA53991 33365121
IECIS8   EQU   8                        DISPLACEMENT OF 8       SA53991 33365421
IECISCVT EQU   16                       ADDRESS OF CVT POINTER  SA53991 33365721
IECISLCH EQU   140                 DISP INTO CVT OF LCH TBL PTR SA53991 33366021
IECISLCI EQU   10                  DISP INTO UCB OF LCH INX     SA53991 33366321
IECISACM EQU   1                   DISP INTO UCB OF ALLC CHN MSKSA53991 33366621
IECISCUA EQU   4                   DISP INTO UCB OF DEV ADDR    SA53991 33366921
IECISPTH EQU   X'01'               MULTI-PATH INDIC IN UCB      SA53991 33367221
         SPACE 2                                                SA53991 33367521
         XC    IECISMSK+2(2),IECISMSK+2 INIT MASK FOR CTRL REG2 SA53991 33367821
         LH    IECISWK1,IECISCUA(0,IECISUCB) GET DEV ADDRESS    SA53991 33368121
         SR    IECISWK4,IECISWK4 INIT REG FOR 1 CHN PATH TO DEV SA53991 33368421
         LA    IECISWK3,IECIS2   INIT REG FOR 1 CHN PATH TO DEV SA53991 33368721
         TM    IECISACM(IECISUCB),IECISPTH TST IF MORE THN 1 PTHSA53991 33369021
         BC    8,IECIS001          NO, GO TO SET SYSTEM MASK    SA53991 33369321
*                                                                       33369621
         L     IECISWK1,IECISCVT   GET PTR TO CVT               SA53991 33369921
         L     IECISWK1,IECISLCH(0,IECISWK1) GET LCH TBL PTR    SA53991 33370221
         SR    IECISWK2,IECISWK2   CLEAR REGISTER               SA53991 33370521
         IC    IECISWK2,IECISLCI(0,IECISUCB) GET LCH INX INTO TBSA53991 33370821
         SLL   IECISWK2,IECIS3     MULT BY 8 TO FORM DISPL      SA53991 33371121
         LH    IECISWK3,IECIS6(IECISWK1,IECISWK2) PTR TO TCH CDESA53991 33371421
         N     IECISWK3,IECISHWD   ENSURE TWO BYTE ADDRESS      SA53991 33371721
         SH    IECISWK3,IECISTWO   BACK UP BY 2-PT TO PTH SUMMRYSA53991 33372021
         IC    IECISWK2,IECIS0(0,IECISWK3) GET TOTAL NO OF PATHSSA53991 33372321
         AR    IECISWK2,IECISWK2   DOUBLE TO GET START OF PTH RBSA53991 33372621
         LR    IECISWK4,IECISWK3   GET BACK UP TBL PTR          SA53991 33372921
         SR    IECISWK4,IECISWK2   POINT TO PATH TBL ORIGIN     SA53991 33373221
IECIS000 LH    IECISWK1,IECIS0(0,IECISWK4) GET PATH TO DEVICE   SA53991 33373521
IECIS001 N     IECISWK1,IECISADR   ENSURE VALID PATH ADDRESS    SA53991 33373821
         SRL   IECISWK1,IECIS8     ISOLATE CHANNEL              SA53991 33374121
         ICM   IECISWK2,IECIS3,IECISSM0 INIT SYSMASK FOR CHAN 0 SA53991 33374421
         SRL   IECISWK2,IECIS0(IECISWK1) SHFT BIT BY AMT= CHN NOSA53991 33374721
*                                        TO POSITN BIT CORRECTLYSA53991 33375021
IECIS002 STH   IECISWK2,IECISMSK SET UP APPROP CHAN BIT FOR     SA53991 33375321
*                                       I/O MASK                SA53991 33375621
         OC    IECISMSK+IECIS2(IECIS2),IECISMSK OR INTO MASK    SA53991 33375921
         LA    IECISWK4,IECIS2(0,IECISWK4) UPDTE PTH TBL PTR    SA53991 33376221
         CR    IECISWK4,IECISWK3   TEST IF ALL POSS PATHS PROCSDSA53991 33376521
         BC    7,IECIS000          NO GO TO NEXT PATH           SA53991 33376821
*        STCTL IECCTLR2,IECCTLR3,IECCNTWK    SAVE CHANNEL MASK  SA53991 33377121
         XC    IECCNTW2(8),IECCNTW2          CLEAR MASK FIELD   SA53991 33377421
         OC    IECCNTW2(IECIS2),IECISMSK+2   SET UP I/O MASK    SA53991 33377721
         LCTL  IECCTLR2,IECCTLR3,IECCNTW2    LOAD NEW CHAN MASK SA53991 33378021
         MVC   IECISPSW(1),IECCNTW2    LOW BYTE INTO PSW        SA53991 33378321
         NI    IECISPSW,X'FC'          RETAIN 0-5 CH BITS       SA53991 33378621
         OI    IECISPSW,X'02'          SET BIT 6 ON             SA53991 33378921
IECISNSA LA    IECISWK2,IECISEND       NSI                      SA53991 33379221
         ST    IECISWK2,IECISPSW+IECIS4 ST IN PSW               SA53991 33379521
         LPSW  IECISPSW                                         SA53991 33379821
************************                                                33380121
         SPACE 2                                                SA53991 33380421
*        CONSTANTS                                              SA53991 33380721
IECCNTWK DC    D'0'                     SAVE-I/O NEW CHAN MASK          33381021
IECCNTW2 DC    D'0'                     BUILD NEW I/O MASK              33381321
IECISPSW DS    0D                                                       33381621
         DC    X'0004'                 SYS MASK,KEY,MODE,MWP    SA53991 33381921
         DC    H'0'                    INTERRUPTION CODE        SA53991 33382221
         DC    A(IECISEND)             ILC,CC,PGM MASK,NSI      SA53991 33382521
IECISHWD DC    X'0000FFFF'              HALF WORD MASK                  33382821
IECISADR DC    X'00000FFF'              VALID DEV ADDR MASK             33383121
IECISMSK DC    F'0'           MASK USED TO FORM SYS MASK                33383421
IECISSM0 DC    XL2'8000'      SYSMASK FOR CHANNEL 0                     33383721
IECISTWO DC    H'2'           COMPARAND FOR VALID SYS MASK              33384021
IECISEND DS    0C                                                       33384321
         MEXIT                                                          33384621
.SSM001  ANOP                                                           33390019
         EJECT                                                          33420019
*    THIS ROUTINE, PROVIDED AND MAINTAINED BY IOS PERSONNEL, DISABLES   33450019
*    ALL CHANNELS.                                                      33480019
         SPACE 1                                                        33510019
*        THIS FUNCTION IS INVOKED BY CODING TO THE FOLLOWING FORMAT --  33520020
*                                                                       33530020
*        IOSGEN SELSSM,,,&VAR,AUTH=CSECTNME       WHERE --              33540020
*              1. &VAR FOR THIS VARIATION MUST BE A '1'.                33550020
*              2. THE KEYWORD PARAMETER 'AUTH=CSECTNME' MUST SPECIFY    33560020
*                  THE OFFICIAL NAME OF THE INVOKING CSECT.             33570020
*                                                                       33600019
         SPACE 1                                                        33630019
         AIF   ('&AUTH' EQ 'IGFMCHE0').SSM002                   SA53991 33640021
         LPSW  IECISDIS                 DISABLE VIA LPSW                33660019
         SPACE 1                                                        33690019
IECISDIS DS    0D                       PSW USED TO DISABLE             33720019
         DC    X'0004'                  SYSTEM MASK, KEY, AMWP,         33750019
         DC    H'0'                     INTERRUPTION CODE               33780019
         DC    A(IECISNSI)              ILC, CC PGM MSK, ADDR OF NSI    33810019
IECISNSI DS    0C                                                       33840019
         MEXIT                          EXIT MACRO                      33870020
.SSM002  ANOP                                                   SA53991 33872021
         SPACE 2                                                        33874021
IECCNTR2 EQU   2                  CONTROL REG 2 CHN MASK        SA53991 33876021
IECCNTR3 EQU   3                  CONTROL REG 3 CHN MASK        SA53991 33878021
         LA    IECISWK2,IECISNSI  ADDR OF NSI                   SA53991 33880021
         ST    IECISWK2,IECISNSI+IECIS4     STORE IN PSW        SA53991 33882021
         LPSW  IECISDIS                     LOAD DISABLE PSW    SA53991 33884021
IECISDIS DS    0D                 PSW USED TO DISABLE           SA53991 33886021
         DC    X'0004'            SYS MASK,KEY,MODE,MWP         SA53991 33888021
         DC    H'0'               INTERRUPTION CODE             SA53991 33890021
         DC    A(IECISNSI)        ADDR OF NSI                   SA53991 33892021
IECISNSI DS    0C                                               SA53991 33894021
         LCTL  IECCNTR2,IECCNTR3,IECCNTWK   RESTORE CONTR REG   SA53991 33896021
         MEXIT                                                  SA53991 33898021
.NIP010  ANOP                                                           33900019
         AIF   ('&AUTH' EQ 'IEEMPVCH').NIP010A                          33930019
         AIF   ('&AUTH' EQ 'IEEMPVCP').NIP010A                          33960019
         AIF   ('&AUTH' EQ 'IEAMP650').NIP010A                          33990019
         AGO   .IOSNG1                  UNAUTHORIZED USE MNOTE          34020019
.NIP010A ANOP                                                           34050019
*********************************************************************** 34080019
***      MACRO DEFINITION - UCBCHM FUNCTION OF IOSGEN               *** 34110019
***            THIS MACRO, OWNED AND MAINTAINED BY IOS PERSONNEL,   *** 34140019
***            INSERTS THE PATH MASK CREATED BY MP6500 INTO THE     *** 34170019
***            'UCBCHM' FIELD.                                      *** 34200019
***                                                                 *** 34230019
         AIF   (&EXECN EQ 1).NIP101                                     34240019
***            FOLLOWING ARE THE PARAMETERS WHICH MUST BE SPECIFIED *** 34260019
***                1.&FUNC-UCBCHM                                   *** 34290019
***                2.&PARM-NUMBER OF A REGISTER WHICH POINTS TO     *** 34320019
***                  THE UCB.                                       *** 34350019
***                3.&REG-SPECIFIES THE NUMBER OF A REGISTER WHICH  *** 34380019
***                  POINTS TO THE PATH MASK BYTE. IF NOT SPECIFIED *** 34410019
***                  THE VAR PARAMETER WILL BE USED TO LOCATE THE   *** 34440019
***                  UCB PATH MASK.                                 *** 34470019
***                4.&VAR-LABEL OF THE BYTE CONTAINING THE UCB PATH *** 34500019
***                  MASK                                           *** 34530019
***            THE KEYWORD PARAMETER 'AUTH=CSECTNME' MUST ALSO BE   *** 34533020
***            SPECIFIED, NOTING THE CSECT NAME INVOKING THE MACRO. *** 34536020
.NIP101  ANOP                                                           34540019
*********************************************************************** 34560019
         SPACE 1                                                        34590019
         AIF   ('&REG' NE '').NIP110    USING REGISTER FORM...          34610019
         SPACE 1                                                        34650019
*********************************************************************** 34680019
***            REGISTER DEFINITION                                  *** 34710019
*********************************************************************** 34740019
IECIU&SUFFIX EQU &PARM                  UCB POINTER REGISTER            34750020
         AIF   (&EXECN EQ 1).NIP102     NOT FIRST TIME - SKIP           34760020
&EXECN   SETB  1                        SET FIRST TIME SWITCH           34770020
*********************************************************************** 34800019
***            UCB DEFINITION                                       *** 34830019
*********************************************************************** 34860019
IECIWCHM EQU   12                       DISP TO PATH MSK IN UCB         34890019
.NIP102  ANOP                                                           34900019
         SPACE 3                                                        34920019
&NAME    MVN   IECIWCHM(1,IECIU&SUFFIX),&VAR MOVE PATH MASK INTO UCBCHM 34950020
         AGO   .IOSGEND                                                 34980019
.NIP110  ANOP                                                           35010019
         SPACE 1                                                        35040019
*********************************************************************** 35070019
***     THIS FUNCTION OF IOSGEN USES A REGISTER TO POINT TO PTHMSK  *** 35100019
*********************************************************************** 35130019
         SPACE 1                                                        35160019
*********************************************************************** 35190019
***            REGISTER DEFINITION                                  *** 35220019
*********************************************************************** 35250019
IECIW&SUFFIX EQU &REG                  PATH MASK POINTER REGISTER       35257019
IECIU&SUFFIX EQU &PARM                  UCB POINTER REGISTER            35277020
         AIF   (&EXECN EQ 1).NIP103     NOT FIRST TIME - SKIP           35297020
&EXECN   SETB  1                        SET FIRST TIME SWITCH           35317020
*********************************************************************** 35340019
***            UCB DEFINITION                                       *** 35370019
*********************************************************************** 35400019
IECIWCHM EQU   12                       DISP TO PATH MSK IN UCB         35430019
.NIP103  ANOP                                                           35440019
         SPACE 3                                                        35460019
&NAME    MVN   IECIWCHM(1,IECIU&SUFFIX),0(IECIW&SUFFIX) PUT MASK IN UCB 35490020
         MEXIT                          EXIT MACRO                      35500020
.*                                                                      35510020
.*   TP ATNTAB AND ERRTAB                                               35520020
.*                                                                      35530020
.TPGEN   AIF   ('&AUTH' EQ 'IGG01938').TPGENOK  CHECK AUTHORITY         35540020
         AIF   ('&AUTH' EQ 'IGG02036').TPGENOK  CHECK AUTHORITY         35550020
         AGO   .IOSNG1                  UNAUTHORIZED USE - MNOTE.       35560020
.TPGENOK ANOP                                                           35570020
*********************************************************************** 35580020
*        MACRO DEFINITION - ERRTAB AND ATNTAB MODIFICATION FOR TCAM   * 35590020
*              THIS MACRO OWNED AND MAINTAINED BY IOS PERSONNEL.      * 35600020
*              GENERATES CODE TO MODIFY ATNTAB AND ERRTAB IN UCB      * 35610020
*                                                                     * 35620020
*              THIS CODE IS GENERATED WHEN THE 'IOSGEN' CALL IS CODED * 35630020
*              BY TCAM. WHERE VARIABLES ARE SET ACCORDING TO THE      * 35640020
*              FORMAT BELOW  --                                       * 35650020
*&NAME   IOSGEN &FUNC,&PARM,&REG,AUTH=CSECTNME  -- WHERE ...          * 35660020
*              &NAME = LABEL                                          * 35670020
*              &FUNC = TP                                             * 35680020
*              &PARM = UCB REGISTER ASSIGNMENT                        * 35690020
*              &REG  = ERRTAB INDEX IN HEX                            * 35700020
*                    = ATNTABT - USE TP ATNTAB IN UCB                 * 35710020
*                    = ATNTABG - USE GR ATNTAB IN UCB                 * 35720020
*              AUTH=CSECTNME... SPECIFIES THE NAME OF THE CSECT THAT  * 35730020
*                               INVOKES THIS MACRO.                   * 35740020
*********************************************************************** 35750020
         SPACE 1                                                        35760020
         AIF   ('&REG' EQ 'ATNTABT').TPATN   TEST FOR TP ATNTAB   20002 35770020
         AIF   ('&REG' EQ 'ATNTABG').GRATN   TEST FOR GR ATNTAB   20002 35780020
&NAME    MVI   8(&PARM),X'&REG'         MODIFY ERRTAB IN UCB      20002 35790020
         AGO   .IOSGEND                 GO TO END                 20002 35800020
.TPATN   ANOP                                                     20002 35810020
&NAME    MVI   11(&PARM),X'14'          MODIFY ATNTAB FOR TP      20002 35820020
         MEXIT                          EXIT MACRO                      35830020
.GRATN   ANOP                                                     20002 35840020
&NAME    MVI   11(&PARM),X'10'          MODIFY ATNTAB FOR GR      20002 35850020
         MEXIT                          EXIT MACRO                      35860020
.*                                                                      35870020
.*   TCB RESTORE                                                        35880020
.*                                                                      35890020
.IECRES  AIF  ('&AUTH' NE 'IKJEAR03').IOSNG1 UNAUTHORIZED USE - MNOTE.  35900020
         AIF   ('&NAME' EQ '').NONAME   CHECK FOR LABEL           20001 35910020
&LBL     SETC  '&NAME'                                            20001 35920020
         AGO   .NAME                    BRANCH AROUND             20001 35930020
.NONAME  ANOP                                                     20001 35940020
&LBL     SETC  'IECIRS'                 SET IOS LABEL             20001 35950020
.NAME    ANOP                                                     20001 35960020
*********************************************************************** 35970020
*        MACRO DEFINITION - INLINE RESTORE CODING FOR TSO             * 35980020
*              THIS MACRO OWNED AND MAINTAINED BY IOS PERSONNEL,      * 35990020
*                                                                     * 36000020
*              THIS CODE IS GENERATED WHEN THE 'IOSGEN' CALL IS CODED * 36010020
*              BY TSO. WHERE VARIABLES ARE SET ACCORDING TO THE       * 36020020
*              FORMAT BELOW --                                        * 36030020
*&NAME   IOSGEN &FUNC,AUTH=CSECTNME     ...WHERE...                   * 36040020
*              &NAME - A SYMBOL TO REFER TO FIRST STATEMENT IN CODE,  * 36050020
*                      IT WILL BE CONCATENATED WITH 01-0N TO FORM     * 36060020
*                      LABELS WITHIN THE CODE. LABEL LIMIT IS 6 CHAR. * 36070020
*                      AND WILL BE IECIRS, IF NOT SPECIFIED.          * 36080020
*              &FUNC - RESTORE                                        * 36090020
*              AUTH=CSECTNME... SPECIFIES THE NAME OF THE CSECT THAT  * 36100020
*                               INVOKES THIS MACRO.                   * 36110020
*                                                                     * 36120020
*    OPERATION GET TO FIRST TCB ENTRY IN THE QUIESCE I/O              * 36130020
*              PARAMETER LIST.                                        * 36140020
*                   PUT IOB ADDRESS IN REGISTER 1                     * 36150020
*                   PUT TCB ADDRESS (FROM ENTRY) IN REG.0             * 36160020
*                   ISSUE TCB EXCP MACRO INSTRUCTION (SVC 92)         * 36170020
*                   POST ECB IF NECESSARY                             * 36180020
*                   REPEAT FOR EACH IOB IN CHAIN                      * 36190020
*              GET TO NEXT TCB ENTRY IN THE QPL, AND REPEAT           * 36200020
*              UNTIL THE LAST TCB ENTRY IS PROCESSED.                 * 36210020
*                                                                     * 36220020
*    FUNCTION  THIS ROUTINE RESTORES A CHAIN OF PREVIOUSLY            * 36230020
*              PURGED I/O REQUESTS FOR EACH TCB SPECIFIED.            * 36240020
*              THE LIST OF TCBS AND IOB CHAINS IS PASSED              * 36250020
*              IN THE QUIESCE I/O PARAMETER LIST (QPL).               * 36260020
*                                                                     * 36270020
*    INPUT     ADDRESS OF QUIESCE I/O PARAMETER LIST                  * 36280020
*              REG 13 WILL NOT BE DESTROYED . IT MUST CONTAIN    M1187* 36282020
*            ADDR OF AREA WHERE CALLER HAS SAVED HIS REGS.       M1187* 36284020
.*            (RESTORE CODE GENERATED NOW DOES NOT STOP REFRESH.)M1187* 36286020
*********************************************************************** 36290020
         SPACE 2                                                        36300020
*********************************************************************** 36310020
* QPL EQUATES                                                         * 36320020
*********************************************************************** 36330020
IECIQCNT EQU   0                        COUNT FIELD IN QPL        20001 36340020
IECIQIOB EQU   0                        IOB CHAIN LOCATION ADDR   20001 36350020
IECIQFLG EQU   4                        QPL FLAG OFFSET           20001 36360020
IECIQTCB EQU   4                        TCB ADDRESS               20001 36370020
IECIQBAS EQU   4                        SIZE OF QPL BASE          20001 36380020
IECIQENT EQU   8                        QPL ENTRY SIZE            20001 36390020
IECIQCUR EQU   X'40'                    QPL CURRENT ENTRY FLAG    20001 36400020
IECIQLST EQU   X'80'                    LAST QPL ENTRY            20001 36410020
         SPACE 2                                                        36420020
*********************************************************************** 36430020
* REGISTER ASSIGNMENTS                                                * 36440020
*********************************************************************** 36450020
         SPACE 1                                                        36460020
IECIRG0  EQU   0                        PARA REG 0                20001 36470020
IECIRINP EQU   1                        PARA REG 1                20001 36480020
IECIRIOB EQU   IECIRINP                 IOB REG FOR TCB EXCP      20001 36490020
IECIRWK1 EQU   2                        WORK REG 1                20001 36500020
IECIRWK2 EQU   3                        WORK REG 2                20001 36510020
IECIRWK3 EQU   5                        WORK REG 3                20001 36520020
IECIRBAS EQU   6                        BASE REGISTER             20001 36530020
IECIXQPL EQU   7                        CURRENT ENTRY IN QPL      20001 36540020
IECIRSAV EQU   8                        SAVE REGISTER             20001 36550020
IECICDRG EQU   10                       ECB CODE REGISTER         20001 36560020
IECIECBR EQU   11                       ECB REGISTER              20001 36570020
IECIRPST EQU   12                       TCB REG FOR POST          20001 36580020
*        EQU   13 .       * DO NOT DESTROY(CALLER'S SAVE AREA) * M1187  36585020
IECIRG13 EQU   13                       CALLERS SAVE AREA ADDR   YM2215 36587000
IECIRG14 EQU   14                       RETURN REG FROM POST      20001 36590020
IECIRG15 EQU   15                       POST ADDR REG             20001 36600020
         SPACE 2                                                        36610020
*********************************************************************** 36620020
* EQUATES                                                             * 36630020
*********************************************************************** 36640020
         SPACE 1                                                        36650020
IECIECBI EQU   4                        ECB POINTER IN IOB        20001 36660020
IECIREST EQU   25                       IOB RESTART FIELD         20001 36670020
IECIPOST EQU   152                      POST ADDR OFFSET IN CVT   20001 36680020
IECICOMP EQU   X'7F'                    COMPLETION CODE IN ECB    20001 36690020
IECIECBF EQU   0                        IOB ECB FLAG OFFSET       20001 36700020
IECIOBDC EQU   20 .                     DISPL TO DCB ADDR IN IOB M4419  36701020
IECDCBDE EQU   44 .                     DISPL TO DEB ADDR IN DCB M4419  36702020
IECDEBUP EQU   16 .                     DISPL TO DEBUSRPG        M4419  36703020
IECIOBF1 EQU   0 .                      DISPL TO IOB FLAG1       M4419  36704020
IECIOBUR EQU   X'02' .                  IOBFLAG1---ON=UNRELATD IOM4419  36705020
IECDCBIF EQU   44 .                     DISPL TO DCB IFLGS       M4419  36706020
IECDCBPE EQU   X'C0' .                  DCBIFLG---ON=PERM ERROR  M4419  36707020
IECPRGCC EQU   X'48' .                  PURGE COMPLETION CODE/IOBM4419  36708020
IECCVTPT EQU   16 .                    GET CVT ADDR              M5464  36709020
IECIWAIT EQU   X'80'                    WAIT CODE                 20001 36710020
IECITXCP EQU   92                       TCB EXCP CODE             20001 36720020
         EJECT                                                    20001 36730020
&LBL     DS    0H .                                              M1187  36740020
         BALR  6,0                      SET BASE REGISTER         20001 36750020
         USING *,IECIRBAS                                         20001 36760020
         LR    IECIXQPL,IECIRINP        SAVE ADDR OF QPL          20001 36770020
         LA    IECIXQPL,IECIQBAS(IECIXQPL)   GET FIRST QPL ENTRY  20001 36780020
*  PREPARE TO BUILD NEW RESTORE IOB CHAINS FOR RELATED REQUESTS--M4419  36780420
*  IN PERM ERROR THAT SVC PURGE GOT TO BEFORE IGE0025E COULD     M4419  36780820
         LR    IECIRWK3,IECIXQPL        BEGIN OF QPL ENTRIES     M4419  36781220
&LBL.1A  L     IECIRWK2,IECIQIOB(IECIRWK3)   BEGIN OF IOB CHAIN  M4419  36781620
&LBL.1B  EQU   * .                                               M4419  36782020
         LA    IECIRWK2,0(IECIRWK2)     CLEAR HI-BYTE            M4419  36782420
         C     IECIRWK2,FFWORD          ANY CHAIN/END OF CHAIN   M4419  36782820
         BE    &LBL.1D .                GO GET NXT QPL ENTRY     M4419  36783220
         TM    IECIOBF1(IECIRWK2),IECIOBUR   UNRELATED I/O       M4419  36783620
         BO    &LBL.1C .                GET NEXT IOB             M4419  36784020
         L     IECIRG15,IECIOBDC(IECIRWK2)   DCB ADDR FROM IOB   M4419  36784420
         TM    IECDCBIF(IECIRG15),IECDCBPE   TEST FOR PERM ERROR M4419  36784820
         BNO   &LBL.1C .                GET NEXT IOB             M4419  36785220
         L     IECIRG15,IECDCBDE(IECIRG15)   DEB ADDR FROM DCB   M4419  36785620
         MVC   IECDEBUP+1(3,IECIRG15),FFWORD+1 INIT EACH DEBUSRPGM4419  36786020
&LBL.1C  L     IECIRWK2,IECIREST-1(IECIRWK2) NEXT IOB ADDR       M4419  36786420
         B     &LBL.1B .                                         M4419  36786820
&LBL.1D  TM    IECIQFLG(IECIRWK3),IECIQLST   LAST ENTRY IN QPL   M4419  36787220
         BO    &LBL.1E                  END OF PASS1             M4419  36787620
         LA    IECIRWK3,IECIQENT(IECIRWK3)   NEXT QPL ENTRY      M4419  36788020
         B     &LBL.1A                                           M4419  36788420
&LBL.1E  EQU   * .                      RELATED I/O--END PASS 1  M4419  36788820
&LBL.01  NI    IECIQFLG(IECIXQPL),255-IECIQCUR    CUR ENT FLG OFF 20001 36790020
         L     IECIRWK1,IECIQIOB(IECIXQPL)   GET FIRST IOB ADDR   20001 36800020
         SR    IECIRWK2,IECIRWK2        CLEAR WORK REGISTER       20001 36810020
&LBL.02  SRDL  IECIRWK1,1               SHIFT BIT TO NEXT REG.    20001 36820020
         LTR   IECIRWK2,IECIRWK2        TEST NEXT REG. FOR NEG.   20001 36830020
         BC    4,&LBL.05                YES-BR TO GET NEXT ENTRY  20001 36840020
         SLL   IECIRWK1,1               RESHIFT VALUE IN REG.     20001 36850020
         L     IECIRWK3,IECIREST-1(IECIRWK1) GET NEXT IOB IN CHAIN20001 36860020
         L     IECIECBR,IECIECBI(IECIRWK1)   GET ECB ADDRESS      20001 36870020
         LA    IECIECBR,0(IECIECBR) .CLEAR HI-BYTE                M0100 36870121
         TM    IECIOBF1(IECIRWK1),IECIOBUR . UNRELATED I/O       M4419  36870320
         BO    &LBL.2A .                                         M4419  36870620
         L     IECIRWK2,IECIOBDC(IECIRWK1) . GET DCB ADDR IN IOB M4419  36870920
         TM    IECDCBIF(IECIRWK2),IECDCBPE . TEST FOR PERM ERROR M4419  36871220
         BNO   &LBL.2A                                           M4419  36871520
*  POST IOB ECB AS PURGED (COMPLETION CODE X'48')                M4419  36871820
         LA    IECICDRG,IECPRGCC .      COMPL CODE               M4419  36872120
         SLL   IECICDRG,24 .            SHIFT TO HI-BYTE         M4419  36872420
         L     IECIRPST,IECIQTCB(IECIXQPL) . TCB ADDR FOR POST   M4419  36872720
         L     IECIRG15,IECCVTPT .     CVT ADDR                  M5464  36873020
         L     IECIRG15,IECIPOST(IECIRG15) . POST RTNE ENTRY     M4419  36873320
         LR    IECIRSAV,IECIRG13 .      SAVE CALLER SA REG      YM2215  36873400
         BALR  IECIRG14,IECIRG15                                 M4419  36873620
         LR    IECIRG13,IECIRSAV .      RESTORE CALLER SA REG   YM2215  36873700
*                                                                M4419  36873920
         MVC     IECIREST(3,IECIRWK1),FFWORD+1 MARK IOBRESTR END M4419  36874220
         L     IECIRWK2,IECDCBDE(IECIRWK2) . GET DEB ADDR IN DCB M4419  36874520
         L     IECIRG15,IECDEBUP(IECIRWK2) . GET CONTENTS - USPRGM4419  36874820
         LA    IECIRWK2,IECDEBUP(IECIRWK2) . FIELD TO CHAIN IOB  M4419  36875120
&LBL.2B  EQU   * .                      CONTINUE SEARCH--CHN END M4419  36875420
         LA    IECIRG15,0(IECIRG15)     CLEAR HI-BYTE            M4419  36875720
         C     IECIRG15,FFWORD          ANY CHAIN/END OF CHAIN   M4419  36876020
         BE    &LBL.2C                  GO TO CHAIN RELATED IOB  M4419  36876320
         LA    IECIRWK2,IECIREST-1(IECIRG15) .ADDR OF NXT CHN FLDM4419  36876620
         L     IECIRG15,IECIREST-1(IECIRG15) .ADDR OF NXT IOB    M4419  36876920
         B     &LBL.2B .                GO TO CONTINUE CHN SEARCHM4419  36877220
&LBL.2C  EQU   * .                      CHAIN IOB FOR 2ND RESTOREM4419  36877520
         IC    IECIRG15,0(IECIRWK2)     SAVE HI-BYTE             M4419  36877820
         ST    IECIRWK1,0(IECIRWK2) .   ADD IOB TO 'RELATED' CHN M4419  36878120
         STC   IECIRG15,0(IECIRWK2)     REST HI-BYTE             M4419  36878420
         SR    IECIRWK2,IECIRWK2 .      CLEAR WORK REG           M4419  36878720
         B     &LBL.04 .                GET NEXT IOB - ORIG CHN  M4419  36879020
&LBL.2A  EQU   * .                      RESUME NORMAL RESTORE    M4419  36879320
         L     IECIRSAV,IECIECBF(IECIECBR)   SAVE CONTECTS OF ECB 20001 36880020
         MVC   IECIQCNT(1,IECIXQPL),IECIECBF(IECIECBR)   ECB CODE 20001 36890020
         LR    IECIRIOB,IECIRWK1        GET IOB ADDR IN REG 1     20001 36900020
         L     IECIRG0,IECIQTCB(IECIXQPL) GET ADDR OF TCB         20001 36910020
         SVC   IECITXCP                 SVC TO TCB EXCP           20001 36920020
*                                                                       36930020
         CLI   IECIQCNT(IECIXQPL),IECIWAIT   WAS ECB WAITING      20001 36940020
         BC    7,&LBL.04                NO-BR TO TEST NEXT IOB    20001 36950020
*                                                                       36960020
*  IT WAS WAITING WHEN PURGED - CONTINUE TESTING                        36970020
*                                                                       36980020
         TM    IECIECBF(IECIECBR),IECICOMP   ECB POSTED NOW       20001 36990020
         BC    8,&LBL.03                NO-GO PUT ECB IN WAIT     20001 37000020
*                                                                       37010020
*  IT WAS POSTED - NOW GET POST CODE                                    37020020
*                                                                       37030020
         IC    IECICDRG,IECIECBF(IECIECBR)   GET COMPLETION CODE  20001 37040020
         SLL   IECICDRG,24              SHIFT INTO POSITION       20001 37050020
         L     IECIRPST,IECIQTCB(IECIXQPL)   TCB ADDRESS FOR POST 20001 37060020
         ST    IECIRSAV,IECIECBF(IECIECBR)   RESTORE WAIT TO ECB  20001 37070020
         L     IECIRG15,16              GET CVT POINTER           20001 37080020
         L     IECIRG15,IECIPOST(IECIRG15)   GET POST ADDRESS     20001 37090020
         LR    IECIRSAV,IECIRG13 .      SAVE CALLER SA REG       YM2215 37092000
         BALR  IECIRG14,IECIRG15        BRANCH TO POST            20001 37100020
         LR    IECIRG13,IECIRSAV .      RESTORE CALLER SA REG    YM2215 37102000
         B     &LBL.04                  GET NEXT IOB ADDR         20001 37110020
*                                                                       37120020
&LBL.03  ST    IECIRSAV,IECIECBF(IECIECBR)   RESTORE WAIT         20001 37130020
&LBL.04  LR    IECIRWK1,IECIRWK3        GET NEXT IOB ADDR         20001 37140020
         B     &LBL.02                  GO TEST FOR END OR EXCP   20001 37150020
*                                                                       37160020
&LBL.05  TM    IECIQFLG(IECIXQPL),IECIQLST   LAST ENTRY?          20001 37170020
         BC    7,&LBL.06                YES-THEN BR TO RETURN     20001 37180020
         LA    IECIXQPL,IECIQENT(IECIXQPL)   GET NEXT ENTRY       20001 37190020
         B     &LBL.01                  BR TO PROCESS THAT ENTRY  20001 37200020
*                                                                       37210020
         DS    0F .                     SAVE WORD BOUND.         M4419  37212020
FFWORD   DC    X'00FFFFFF'              END IOB CHAIN            M4419  37214020
*                                                                M4419  37216020
&LBL.06  DS    0H .     *** EXIT POINT FOR 'RESTORE' CODE ***    M1187  37220020
         DROP  IECIRBAS                                           20001 37240020
         MEXIT                          EXIT MACRO                      37250020
.FLGS010 AIF   ('&AUTH' EQ 'IGE0660A').FLGS011 CHECK FOR DDR MODULE USE 37320019
         AIF   ('&AUTH' EQ 'IGC0308E').FLGS011                          37620019
         AIF   ('&AUTH' EQ 'IGFDDR00').FLGS011                          37920019
         AIF   ('&AUTH' EQ 'IGFDDR10').FLGS011                          38220019
         AIF   ('&AUTH' EQ 'IGC0508E').FLGS011                          38520019
         AGO   .FLGS012                 CHECK FOR SCHEDULER MODULE USE  38820019
.FLGS011 ANOP                                                           39120020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 39420020
*                                                                     * 39720020
*    MACRO DEFINITION - UCB FLAG BYTE 1 UTILITY...                    * 40020020
*        THIS MACRO, OWNED AND MAINTAINED BY IOS PERSONNEL, MAY BE    * 40320020
*        USED TO TURN A BIT ON OR OFF IN THE FLAG BYTE 1 FIELD OF     * 40620020
*        THE UCB. (FIELD IS LOCATED AT DISPLACEMENT 6 IN THE UCB)     * 40920020
*        IT CAN ALSO BE USED TO INTERROGATE THE BIT SETTINGS BY TEST- * 41220020
*        ING UNDER MASK AND RETURNING THE APPROPRIATE CONDITION CODE. * 41520020
*                                                                     * 41820020
         AIF  (&EXECF EQ 1).FLGS017     SKIP AROUND UNLES 1ST TIME THRO 42120020
*        THIS CODE IS GENERATED WHEN THE 'IOSGEN' CALL IS CODED WITH  * 42420020
*        THE VARIABLES SET ACCORDING TO THE FOLLOWING FORMAT - - -    * 42720020
*          IOSGEN &FUNC,&PARM,&REG,&VAR,&AUTH=    WHERE;              * 43020020
*          1.  &FUNC = UCBFL1                                         * 43320020
*          2.  &PARM = NUMBER OF A REGISTER POINTING TO THE UCB       * 43620020
*          3.  &REG = 'ON' OR 'OFF' DEPENDING ON DESIRED SETTING,     * 43920020
*                      OR 'TEST', IF THE SETTING OF THE BIT IS TO BE  * 44220020
*                      INTERROGATED BUT NOT CHANGED.                  * 44520020
*          4.  &VAR =  NAME OF ONE OF THE FOLLOWING BITS              * 44820020
*          5.  &AUTH = IS A KEYWORD PARAMETER SPECIFYING THE NAME     * 45120020
*                      OF THE CALLING MODULE.                         * 45420020
*                    * * * * * * * * * * * * * * * * * * * * * *      * 45720020
*                     NAME FOR MACRO CALL  *  DEFINITION              * 46020020
*                    * * * * * * * * * * * * * * * * * * * * * *      * 46320020
.* (NOT PRESNTLY SUPPORTD)   UCBBSY        * DEV BUSY BIT             * 46620020
*                            UCBNRY        * UCB NOT READY BIT        * 46920020
.* (NOT PRESNTLY SUPPORTD)   UCBPST        * POST BIT                 * 47220020
.* (NOT PRESNTLY SUPPORTD)   UCBITF        * INTERCEPT BIT            * 47520020
.* (NOT PRESNTLY SUPPORTD)   UCBCUB        * C.U. BUSY BIT            * 47820020
.* (NOT PRESNTLY SUPPORTD)   UCBDTR        * D.A. DATA XFER BIT       * 48120020
.* (NOT PRESNTLY SUPPORTD)   UCBASK        * D.A. ARM SEEKING BIT     * 48420020
*                            UCBERR        * ERP IN CONTROL BIT       * 48720020
.* (TURNING 'ON' NOT PRESNTLY SUPPORTD IN UCBERR BIT - - - - - - - )  * 49020020
*                    * * * * * * * * * * * * * * * * * * * * * *      * 49320020
*                                                                     * 49620020
.FLGS017 ANOP                                                           49920020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 50220020
         SPACE 1                                                        51120019
IECIU&SUFFIX EQU &PARM                  UCB POINTER REGISTER            51220020
         AIF   (&EXECF EQ 1).FLGS17A    SKIP AFTER FIRST TIME           51320020
&EXECF   SETB  1                        SET FIRST TIME SWITCH           51420020
IECIFLG1 EQU   6                        OFFSET IN UCB FOR UCBFL1        51720019
.FLGS17A AIF   ('&VAR' NE 'UCBNRY').FLGS029 BR IF NOT RDY BIT ISNT 'IT' 52020019
&HEX     SETC  '40'                     TURN ON UCB NOT RDY BIT IN MSK  52320019
         AGO   .FLGS050                 DETERMINE IF WE ARE TURNING ON  52620019
.FLGS029 AIF   ('&VAR' NE 'UCBERR').FLGS031 BR IF ERR BIT ISNT 'IT'     52920019
&HEX     SETC  '01'                     TURN ON ERROR BIT IN MASK       53220019
         AGO   .FLGS050                 DETERMINE IF WE ARE TURNING ON  53520019
.FLGS031 AGO   .IOSNG3                  IF THIS AGO DONE, ERROR EXISTS. 53820020
.FLGS050 AIF   ('&REG' NE 'OFF').FLGS060 SKIP CODE IF 'ON' OR 'TEST'    54120019
IECIF&SUFFIX EQU X'FF'-X'&HEX'          SET PROPER MSK FOR BIT SELECTN  54420019
         SPACE 1                                                        54720019
*              TURN OFF SELECTED BIT                                  * 55020019
         NI    IECIFLG1(IECIU&SUFFIX),IECIF&SUFFIX                      55320020
         AGO   .IOSGEND                 EXIT FROM MACRO                 55620019
.FLGS060 ANOP                                                           55920019
         AIF   ('&REG' NE 'ON').FLGS065 SKIP CODE IF &REG = TEST        56220019
         AIF   ('&VAR' EQ 'UCBERR').IOSNG3  'OR' OF UCBERR NOT SUPPORTD 56520021
IECIF&SUFFIX EQU X'&HEX'                MASK FOR SELECTED BIT           56820020
         SPACE 1                                                        57120019
*              TURN ON SELECTED BIT                                   * 57420019
         OI    IECIFLG1(IECIU&SUFFIX),IECIF&SUFFIX                      57720020
         AGO   .IOSGEND                 EXIT FROM MACRO                 58020019
.FLGS065 AIF   ('&REG' NE 'TEST').IOSNG3 IF THIS DONE,ERROR EXISTS.     58320020
IECIF&SUFFIX EQU X'&HEX'                MASK FOR SELECTED BIT           58620020
         SPACE 1                                                        58920019
*              TEST DESIRED BIT USING TEST UNDER MASK INSTRCTN.       * 59220019
         TM    IECIFLG1(IECIU&SUFFIX),IECIF&SUFFIX                      59520020
         AGO   .IOSGEND                 EXIT FROM MACRO                 59820019
.FLGS012 AIF   ('&AUTH' EQ 'IEE3103D').FLGS013  BR IF SCHDULER IS USING 60120019
         AIF   ('&AUTH' EQ 'IEFXJIMP').FLGS013  BR IF SCHDULER IS USING 60420019
         AGO   .IOSNG1                  UNAUTHORIZED USE MNOTE          60720019
.FLGS013 ANOP                                                           61020019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 61320019
*                                                                     * 61620019
*   MACRO DEFINITION - UCB FLAG BYTE 1 BIT SETTING MANIPULATOR        * 61920019
*                                                                     * 62420020
*        THIS MACRO, OWNED AND MAINTAINED BY IOS PERSONNEL, MAY BE    * 62920020
*        USED TO TURN OFF THE UCBNRY AND UCBITF BITS IN THE FLAGBYTE1 * 63420020
*        FIELD OF THE UCB IF THE DEVICE IS A TAPE DEVICE AND IF BOTH  * 63920020
*        THE 'NOT READY' AND 'INTERCEPT' BITS ARE 'ON'                * 64420020
*                                                                     * 64920020
*        THIS CODE IS GENERATED WHEN THE 'IOSGEN' CALL IS CODED WITH  * 65420020
*        THE VARIABLES SET ACCORDING TO THE FOLLOWING FORMAT - - -    * 65920020
*          IOSGEN &FUNC,&PARM,&AUTH=          WHERE;                  * 66420020
*          1.  &FUNC = UCBFL1                                         * 66920020
*          2.  &PARM = NUMBER OF A REGISTER POINTING TO THE UCB       * 67420020
*          3.  &AUTH = IS A KEYWORD PARAMETER SPECIFYING THE NAME     * 67920020
*                      OF THE CALLING MODULE.                         * 68420020
*                                                                     * 68920020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 69420020
         SPACE 1                                                        69920020
IECIFUCB EQU   &PARM                    UCB POINTER                     70420020
IECIFLG1 EQU   6                        OFFSET IN UCB FOR UCBFL1        70920020
IECIFTYP EQU   18                       DISP IN UCB TO DEVTYP FIELD     71420020
IECIFTAP EQU   X'80'                    MASK FOR MAGNETIC TAPE IN UCB   71920020
IECIFOFF EQU   X'AF'                    MASK TO TURN OFF NRY AND ITF    72420020
IECIFSET EQU   X'50'                    MASK TO TEST NRY & ITF BITS     72920020
         TM    IECIFTYP(IECIFUCB),IECIFTAP IS THIS A MAGNETIC TAPE DEV. 73420020
         BC    8,IECIFEXT               IF NOT, BR TO MACRO END         73920020
         TM    IECIFLG1(IECIFUCB),IECIFSET Q. ARE BOTH BITS ON          74420020
         BC    12,IECIFEXT                 A. NO, BRANCH TO MACROEND    74920020
         NI    IECIFLG1(IECIFUCB),IECIFOFF A. YES, TURN BOTH BITS OFF   75420020
IECIFEXT DS    0H                                                       75920020
         MEXIT                                                          76420020
.DTCT001 AIF   ('&AUTH' EQ 'IEEMPVCH').DTCT002 AUTHORIZATION OK   21063 77420021
         AIF   ('&AUTH' EQ 'IEEMPVCP').DTCT002 AUTHORIZATION OK   21063 77470021
         AIF   ('&AUTH' NE 'IEEUNIT2').IOSNG1  UNAUTHORIZED USE         77520021
.DTCT002 ANOP                                                           77570021
*********************************************************************** 78810019
*                                                                     * 78840019
*    THIS FUNCTION OF THE IOSGEN MACRO, OWNED AND MAINTAINED BY IOS   * 78870019
*    PERSONNEL, MAY BE USED TO DETERMINE WHETHER OR NOT A DEVICE IS   * 78900019
*    A RESERVED SHARED DASD. IF A DEVICE IS NOT ALL 3 OF THE ABOVE,   * 78930019
*    A CONDITION CODE OF ZERO IS RETURNED. IF A DEVICE IS A RESERVED  * 78960019
*    SHARED DIRECT ACCESS DEVICE A NON-ZERO CONDITION CODE IS RETURNED* 78990019
*                                                                     * 79000021
*    IF THE FOURTH POSITIONAL PARAMETER, &VAR, IS SET TO 1, THE       * 79010021
*    DETECTOR FUNCTION WILL INSPECT THE HARDWARE RESERVE COUNT        * 79012021
*    (OFFSET X'29').                                                  * 79014021
*                                                                     * 79020019
*    THIS CODE IS GENERATED WHEN THE 'IOSGEN' CALL IS CODED WITH THE  * 79050019
*    VARIABLES SET ACCORDING TO THE FOLLOWING FORMAT - -              * 79080019
*        IOSGEN &FUNC,&PARM,,&VAR                                     * 79110021
*        WHERE  &FUNC=DETECTOR, &PARM=NO. OF A UCB POINTER REG AND    * 79120021
*               &VAR=1 IF OFFSET X'29' IN UCB TO BE INSPECTED AS      * 79130021
*                      OPPOSED TO NORMAL OFFSET X'28'                 * 79140021
*                                                                     * 79170019
*********************************************************************** 79200020
IECIDUCB EQU   &PARM                    PARAMETER REG POINTING TO UCB   79230020
IECIDSHR EQU   17                       UCB DEV TYPE FIELD + 1          79260020
IECIDDVT EQU   18                       UCB DEV TYPE FIELD + 2          79290020
IECIDSQC EQU   40                       UCB RESERVE MACROS COUNT FIELD  79320020
IECIDHCT EQU   41                     HARDWARE RESERVE CNT OFFSET 21063 79330021
IECIDDAD EQU   X'20'                    D.A.DEV CL FLGS OR SHARD D.A.FL 79350020
IECIDCNT EQU   X'FF'                    COUNT TEST MASK                 79380020
         TM    IECIDDVT(IECIDUCB),IECIDDAD Q. IS THIS A DASD            79410020
         BC    8,IECIDTCT               A. NO, BRANCH OUT               79440020
         TM    IECIDSHR(IECIDUCB),IECIDDAD Q. IS THIS A SHARED FILE     79470020
         BC    8,IECIDTCT               A. NO, BRANCH OUT               79500020
         AIF   (&VAR NE 1).DTCT003      'UNI-PROCESSING'          21063 79530021
         TM    IECIDHCT(IECIDUCB),IECIDCNT IS DEVICE RESERVED     21063 79540021
         AGO   .DTCT004                                                 79550021
.DTCT003 TM    IECIDSQC(IECIDUCB),IECIDCNT ANY RESRVMACS BEEN ISSUED    79552021
.DTCT004 ANOP                                                           79554021
IECIDTCT DS    0H                                                       79560020
         AGO   .IOSGEND                 END OF FUNCTION                 79590020
.FIFONQ  AIF  ('&AUTH' NE 'IGE0660A').IOSNG1   UNAUTHORIZED USE / MNOTE 79620020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 79650020
*                                                                     * 79680020
*   THIS FUNCTION OF IOSGEN WILL ADD A GIVEN REQUEST ELEMENT TO A     * 79710020
*   LOGICAL CHANNEL QUEUE OR A DDR WAIT QUEUE. THE CALLING MODULE     * 79740020
*   MUST SUPPLY TWO REGISTERS FOR USE AS POINTERS AND A 3RD REGISTER  * 79770020
*   FOR USE AS A WORK REGISTER                                        * 79800020
*                                                                     * 79830020
*   FOLLOWING ARE THE PARAMETERS AND THE ORDER IN WHICH THEY MUST BE  * 79860020
*   SPECIFIED IN THE 'IOSGEN' CALL --                                 * 79890020
*        IOSGEN &FUNC,&PARM,&REG        WHERE---                      * 79920020
*          1. &FUNC = ENQUE                                           * 79950020
*          2. &PARM = LOGICAL CHANNEL WORD OR DDR WAIT QUEUE PTR REG  * 79980020
*          3. &REG = TWO REGISTER SUBLIST, FIRST OF WHICH IS A PTR    * 80010020
*                    TO THE NEXT RQE (REQUEST ELEMNT) TO BE ENQUEUED, * 80040020
*                    SECOND OF WHICH IS TO BE USED AS A WORK REGISTER * 80070020
*                                                                     * 80100020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 80130020
*                    REGISTER DEFINITION                              * 80160020
IECIELCH EQU   &PARM                    PTR TO LCH WORD OR DDR QUEUE    80190020
IECIETST EQU   &REG(1)                  PTR TO NXT RQE TO BE ADDED TO Q 80220020
IECIEWK1 EQU   &REG(2)                  G. P. WORK REGISTER             80250020
*               MISCELLANOUS EQUATES                                  * 80280020
IECIELNK EQU   0                        DISP FOR FIRST RQE ADDRESS      80310020
IECIEONE EQU   1                        DISP OF ONE BYTE                80340020
IECIELST EQU   2                        DISP FOR LAST RQE ADDRESS       80370020
IECIEXFF EQU   X'FF'                    LINK FIELD HALF-MASK            80400020
IECIEDUM EQU   X'01'                    EQUIVELANT TO X'FF' MASK        80430020
         SPACE 2                                                        80460020
*   TEST FOR 'FF' IN 1ST RQE ADDR TO SEE IF QUEUE EMPTY               * 80490020
         TM    IECIEONE(IECIELCH),IECIEDUM . IS THE QUEUE EMPTY  A43241 80520021
         BC    1,IECIESOL               IF IT IS EMPTY, BRANCH          80550020
         SPACE 1                                                        80580020
*        QUEUE IS NOT EMPTY, ADD ELEMENT TO EXISTING CHAIN            * 80610020
         LH    IECIEWK1,IECIELST(IECIELCH) LOAD LAST RQE ADDRESS...     80640020
         STH   IECIETST,IECIELNK(IECIEWK1) STORE ADDR INTO LINK FIELD.  80670020
         BC    15,IECIEMUL                                              80672020
************************                                                80674020
         SPACE 1                                                        80676020
*               QUEUE IS EMPTY, ADD FIRST ELEMENT OF CHAIN            * 80678020
IECIESOL STH   IECIETST,IECIELNK(IECIELCH) PUT ADDR IN 1ST REQ SLOT     80680020
IECIEMUL STH   IECIETST,IECIELST(IECIELCH) PUT ADDR IN LAST REQ SLOT    80682020
         MVI   IECIELNK(IECIETST),IECIEXFF INDICATE ON ADDED RQE LINK   80684020
         MVI   IECIEONE(IECIETST),IECIEXFF FIELD THAT IT'S THE LAST ONE 80686020
         MEXIT                                                          80688020
.SIMINT  ANOP                                                           80690020
         AIF   ('&AUTH' EQ 'IEE3103D').SIMINTA    O.K. TO EXPAND        80692020
         AGO   .IOSNG1                  UNAUTHORIZED USE MNOTE          80694020
.SIMINTA ANOP                                                           80696020
         SPACE 5                                                        80698020
*********************************************************************** 80700020
*        MACRO DEFINITION - SIMULATE INTERRUPT FOR SCHEDULER          * 80702020
*                                                                     * 80704020
*        THIS MACRO, OWNED AND MAINTAINED BY IOS PERSONNEL,           * 80706020
*              SIMULATES A DEVICE END OR CHANNEL AVAILABLE ( 0 STATUS)* 80708020
*              INTERRUPT IN ORDER TO FREE UP A DEVICE.                * 80710020
*                                                                     * 80712020
*              FOLLOWING ARE THE PARAMETERS WHICH MUST BE SPECIFIED   * 80714020
*              IN THIS 'IOSGEN' CALL --                               * 80716020
*        IOSGEN &FUNC,&PARM,&REG,&AUTH=CSECTNME         WHERE --      * 80718020
*              1. &FUNC = SIMINT                                      * 80720020
*              2. &PARM = NUMBER OF A REGISTER CONTAINING THE ADDRESS * 80722020
*                         OF THE UCB OF THE DEVICE TO BE TWICHED.     * 80724020
*              3. &REG = THE NUMBER OF A REGISTER THAT MAY BE USED    * 80726020
*                        BY THIS ROUTINE.                             * 80728020
*              4. &AUTH = A KEYWORD PARAMETER SPECIFYING THE CSECT    * 80730020
*                         NAME OF THIS PROGRAM.                       * 80732020
*                                                                     * 80734020
*********************************************************************** 80736020
IECIS010 SSM   IECISDIS                 THIS ROUTINE MUST NOT BE        80738020
*                                       INTERRUPTED - I/O OLD PSW BEING 80740020
*                                       MODIFIED.                       80742020
         SPACE 2                                                        80744020
*********************************************************************** 80746020
*              R E G I S T E R   D E F I N I T I O N S                * 80748020
*********************************************************************** 80750020
IECISUCB EQU   &PARM                    UCB POINTER REG                 80752020
IECISWK  EQU   &REG                     WORK REGISTER                   80754020
IECISZBS EQU   0                        ZERO BASE REGISTER              80756020
         SPACE 2                                                        80758020
*********************************************************************** 80760020
*              U C B    D E F I N I T I O N                           * 80762020
*********************************************************************** 80764020
IECISCHA EQU   4                        UCB CHANNEL ADDRESS FIELD       80766020
IECISFL1 EQU   6                        UCB ACTIVITY FLAG 1 FIELD       80768020
IECISPST EQU   X'20'                    UCB POST BIT IN UCBFL1          80770020
IECISNRY EQU   X'40'                     UCB NOT READY BIT IN UCBFL1    80772020
IECISBSY EQU   X'80'                    UCB BUSY BIT IN UCBFL1          80774020
         SPACE 2                                                        80776020
*********************************************************************** 80778020
*              M I S C .   M A S K S   A N D   E Q U A T E S          * 80780020
*********************************************************************** 80782020
IECISHLF EQU   2                        HALF WORD IN SIZE               80784020
IECISDBL EQU   8                        DOUBLE WORD LENGTH              80786020
         SPACE 1                                                        80788020
IECISBAM EQU   X'0F'                    BYTE ANDING MASK                80790020
IECISDEI EQU   X'04'                    DEVICE END CSW STATUS           80792020
IECISMCB EQU   X'04'                    MACHINE CHECK ENABLE MASK       80794020
         SPACE 1                                                        80796020
IECISIOO EQU   56                        I/O OLD PSW LOCATION           80798020
IECISCSW EQU   64                       CSW LOCATION                    80800020
IECISION EQU   120                      I/O NEW PSW LOCATION            80802020
         SPACE 5                                                        80804020
*    BUILD SYNTHETIC I/O OLD PSW FOR RETURN FROM DUMMY INTERRUPT --   * 80806020
         SPACE 1                                                        80808020
         MVC   IECISIOO+2(IECISHLF,IECISZBS),IECISCHA(IECISUCB) GET DEV 80810020
         NI    IECISIOO+2(IECISZBS),IECISBAM ADDRESS & ZERO 1ST HALFBYT 80812020
         LA    IECISWK,IECISXIT         PICK UP EXIT ADDRESS            80814020
         ST    IECISWK,IECISIOO+4(IECISZBS) STORE INTO I/O OLD PSW.     80816020
         MVI   IECISIOO+1(IECISZBS),IECISMCB ALLOW MACHINE CHECK INT.   80818020
         SPACE 2                                                        80820020
*    BUILD CSW FOR DUMMY INTERRUPT --                                 * 80822020
         SPACE 1                                                        80824020
         XC    IECISCSW(IECISDBL,IECISZBS),IECISCSW(IECISZBS) ZERO CSW  80826020
         TM    IECISFL1(IECISUCB),IECISPST Q.  IS POST FLAG ON.         80828020
         BO    IECISCAI                 A.  YES, CHANNEL AVAILABLE.     80830020
*                                       A.  NO, CONTINUE TESTING.       80832020
         TM    IECISFL1(IECISUCB),IECISBSY+IECISNRY Q.  BUSY OR NOT RDY 80834020
         BZ    IECISCAI                 A.  NO, GIVE CHANNEL AVAILABLE. 80836020
*                                       A.  YES, SET UP DEVICE END ...  80838020
         OI    IECISCSW+4(IECISZBS),IECISDEI MOVE IN DUMMY STATUS.      80840020
IECISCAI LPSW  IECISION(IECISZBS)       GO TO I/O INTERRUPT ROUTINE...  80842020
************************                                                80844020
         SPACE  1                                                       80846020
IECISDIS DC    X'00'                    DISABLE SYSTEM STATUS MASK      80848020
IECISNAB DC    X'FF'                    ENABLED SYSTEM STATUS MASK      80850020
************************                                                80852020
IECISXIT SSM   IECISNAB                 REENABLE AND EXIT MACRO CODE    80854020
         MEXIT                                                          80856020
.SKUPDT  SPACE 1                                                        80857020
.*         THIS FUNCTION WAS ADDED IN SUPPORT OF PTM3046                80858020
******************************************************************20001 80859020
**       MACRO DEFINITION INLINE UPDATE OF UCB SEEK FIELD         20001 80860020
**             THIS MACRO OWNED AND MAINTAINED BY IOS PERSONNEL,  20001 80861020
******************************************************************20001 80862020
**             THIS CODE IS GENERATED WHEN THE 'IOSGEN' CALL IS   20001 80863020
*              CODED BY TSO,WHEN VARIABLES ARE SET ACCORDING TO   20001 80864020
*              THE FORMAT BELOW----------                         20001 80865020
*&NAME   IOSGEN &FUNC,&PARM,&REG,,&AUTH=CSECTNME                  20001 80866020
*               &NAME-LABEL ASSIGNED TO FIRST INSTRUCTION         20001 80867020
*               &FUNC-SKUPDT, UCB SEEK FIELD UPDATE REQUESTED     20001 80868020
*               &PARM-A REG CONTAINING POINTER TO FIELD CONTAINING20001 80869020
*                     NEW SEEK ADDRESS(MBBCCHHR)                  20001 80870020
*               &REG-A REG CONTAINING POINTER TO UCB              20001 80871020
*               &AUTH=CSECTNME,WHERE CSECTNME IS NAME OF MODULE   20001 80872020
*                    AUTHORIZED TO CALL THIS FUNCTION             20001 80873020
*    FUNCTION  THIS ROUTINE WILL UPDATE THE UCB SEEK FIELD PASSED 20001 80874020
*                    BY &REG WITH THE SEEK ADDRESS POINTED TO BY  20001 80875020
*                    &PARM                                        20001 80876020
*** NOTE NOTE NOTE NOTE                                           20001 80877020
*               MULTI CALLS FROM SAME ASSEMBLY MUST USE SAME REGS 20001 80878020
******************************************************************20001 80879020
         AIF   ('&AUTH' EQ 'IKJEAS02').SKUPDT1                    20001 80880020
         AGO   .IOSNG1                  UNAUTHORIZED USE MNOTE    20001 80881020
.SKUPDT1       ANOP                                               20001 80882020
         AIF   ('&PARM' EQ '' OR '&REG' EQ '').IOSNG3 INVALID PARM20001 80883020
         AIF   (&EXECS).SKUPDT2         DO NOT GEN EQU'S TWICE    20001 80884020
&EXECS   SETB  1                        SET MULTI ENTRY SWITCH    20001 80885020
******************************************************************20001 80886020
***            REGISTER DEFINITIONS                            ***20001 80887020
IECUCBPT EQU   &REG                     POINTER TO UCB            20001 80888020
IECNEWSK EQU   &PARM                    POINTER TO NEW SEEK ADDR  20001 80889020
***            OFFSET AND LENGTH DEFINITIONS                      20001 80890020
IECUCBSK EQU   X'30'                    OFFSET TO UCB SEEK ADDRESS20001 80891020
IECUCBSL EQU   X'8'                     LENGTH OF UCB SEEK FIELD  20001 80892020
******************************************************************20001 80893020
.SKUPDT2 ANOP                                                     20001 80894020
&NAME    MVC   IECUCBSK(IECUCBSL,IECUCBPT),0(IECNEWSK)  SET SEEK  20001 80895020
         MEXIT                                                          80896020
.RQE00   AIF   ('&AUTH' NE 'IGG019R5').IOSNG1  UNAUTHORIZED USE/MNOTE   80905821
         AIF   (N'&REG LT 4).IOSNG2     INSUFFICIENT WORK REGS/MNOTE    80925821
*********************************************************************** 80945821
*                                                                     * 80965821
*        FUNCTION DEFINITION - GET AND ENQUEUE A REQUEST ELEMENT      * 80985821
*                                                                     * 81005821
*        THE GETQRQE FUNCTION OF THE IOSGEN MACRO PERFORMS THE        * 81025821
*        FOLLOWING MAJOR OPERATIONS:                                  * 81045821
*                                                                     * 81065821
*             1. CONTROL BLOCK VALIDATION                             * 81085821
*             2. CONTROL BLOCK INITIALIZATION                         * 81105821
*             3. GET REQUEST ELEMENT (RQE)                            * 81125821
*             4. LOCATE LOGICAL CHANNEL WORD                          * 81145821
*             5. ENQUEUE REQUEST ELEMENT                              * 81165821
*                                                                     * 81185821
*        THE GETQRQE FUNCTION IS INVOKED BY CODING ACCORDING TO       * 81205821
*        THE FOLLOWING FORMAT:                                        * 81225821
*                                                                     * 81245821
* &NAME  IOSGEN &FUNC,(&PARM(1),&PARM(2),&PARM(3),&PARM(4)),        + * 81265821
*              (&REG(1),&REG(2),&REG(3),&REG(4)),&AUTH=CSECTNME       * 81285821
*              WHERE -                                                * 81305821
*                                                                     * 81325821
*             1. &NAME    - THE SYMBOL ASSIGNED TO THE FIRST          * 81345821
*                           INSTRUCTION                               * 81365821
*             2. &FUNC    - GETQRQE                                   * 81385821
*             3. &PARM(1) - A REGISTER WHICH POINTS TO THE CVT        * 81405821
*                &PARM(2) - A REGISTER WHICH POINTS TO THE TCB FOR    * 81425821
*                           THE ASYNCHRONOUS ATTENTION ROUTINE        * 81445821
*                &PARM(3) - A REGISTER WHICH POINTS TO THE IOB FOR    * 81465821
*                           THE I/O REQUEST                           * 81485821
*                &PARM(4) - A REGISTER WHICH POINTS TO THE UCB FOR    * 81505821
*                           THE DEVICE FROM WHICH THE ASYNCHRONOUS    * 81525821
*                           ATTENTION INTERRUPT OCCURRED              * 81545821
*             4. &REG     - THE REGISTER SUBLIST WHICH SPECIFIES      * 81565821
*                           FOUR WORK REGISTERS                       * 81585821
*             5. &AUTH=   - THE NAME OF THE CSECT INVOKING THE        * 81605821
*                           FUNCTION                                  * 81625821
*                                                                     * 81645821
*        THE RETURN CODE REGISTER '&REG(1)' WILL CONTAIN ONE OF THE   * 81665821
*        FOLLOWING RETURN CODES TO INDICATE THE EXIT CONDITION FROM   * 81685821
*        THIS FUNCTION:                                               * 81705821
*                                                                     * 81725821
*             0 - SUCCESSFUL COMPLETION                               * 81745821
*             4 - INVALID CONTROL BLOCK OR CONTROL BLOCK BOUNDARY     * 81765821
*             8 - INVALID CONTROL BLOCK KEYS (STORAGE/PROTECT)        * 81785821
*            12 - NO REQUEST ELEMENT (RQE) AVAILABLE                  * 81805821
*                                                                     * 81825821
*        GETQRQE FUNCTION NOTES -                                     * 81845821
*                                                                     * 81865821
*             1. EXPANDED AS IN-LINE CODE                             * 81885821
*             2. DISABLED SERIALLY REUSABLE                           * 81905821
*             3. GENERATES CODE TO HANDLE BOTH MFT AND MVT SYSTEM     * 81925821
*                CONFIGURATIONS                                       * 81945821
*                                                                     * 81965821
*********************************************************************** 81985821
         SPACE 2                                                        82005821
*********************************************************************** 82025821
*        REGISTER DEFINITION                                          * 82045821
*********************************************************************** 82065821
         SPACE 1                                                        82085821
IECIGCVT EQU   &PARM(1)                 CVT POINTER                     82105821
IECIGTCB EQU   &PARM(2)                 TCB REGISTER                    82125821
IECIGIOB EQU   &PARM(3)                 IOB REGISTER                    82145821
IECIGUCB EQU   &PARM(4)                 UCB REGISTER                    82165821
IECIGWK1 EQU   &REG(1)                  WORK REGISTER                   82185821
IECIGWK2 EQU   &REG(2)                  WORK REGISTER                   82205821
IECIGWK3 EQU   &REG(3)                  WORK REGISTER                   82225821
IECIGWK4 EQU   &REG(4)                  WORK REGISTER                   82245821
IECIGDEB EQU   IECIGWK1                 DEB REGISTER                    82265821
IECIGRTN EQU   IECIGWK1                 RETURN CODE REGISTER            82285821
IECIGDCB EQU   IECIGWK2                 DCB REGISTER                    82305821
IECIGTST EQU   IECIGWK2                 RQE POINTER                     82325821
IECIGLCH EQU   IECIGWK3                 LCH WORD POINTER                82345821
         SPACE 1                                                        82365821
*********************************************************************** 82385821
*        MISCELLANEOUS EQUATES                                        * 82405821
*********************************************************************** 82425821
         SPACE 1                                                        82445821
IECIGSC  EQU   116                      OFFSET IN CVT OF SYS CONFIG     82465821
IECIGAVL EQU   124                      OFFSET IN CVT OF NEXT RQE PTR   82485821
IECIGLCT EQU   140                      OFFSET IN CVT OF LCH TAB PTR    82505821
IECIGTSK EQU   28                       OFFSET IN TCB OF STOR KEY       82525821
IECIGTID EQU   112                      OFFSET IN TCB OF ID (MFT)       82545821
IECIGFL1 EQU   0                        OFFSET IN IOB OF FLAG BYTE 1    82565821
IECIGCOD EQU   4                        OFFSET IN IOB OF ECB COMP CODE  82585821
IECIGECB EQU   5                        OFFSET IN IOB OF ECB PTR        82605821
IECIGFL3 EQU   8                        OFFSET IN IOB OF FLAG BYTE 3    82625821
IECIGIDC EQU   21                       OFFSET IN IOB OF DCB PTR        82645821
IECIGECT EQU   30                       OFFSET IN IOB OF ERROR COUNT    82665821
IECIGUID EQU   2                        OFFSET IN UCB OF UCB IDENT      82685821
IECIGLCI EQU   10                       OFFSET IN UCB OF LCH INDEX      82705821
IECIGDPK EQU   24                       OFFSET IN DEB OF PROT KEY       82725821
IECIGDDC EQU   25                       OFFSET IN DEB OF DCB PTR        82745821
IECIGDDE EQU   45                       OFFSET IN DCB OF DEB PTR        82765821
IECIGRLK EQU   0                        OFFSET IN RQE TO LINK PTR       82785821
IECIGRUB EQU   2                        OFFSET IN RQE TO UCB PTR        82805821
IECIGRAS EQU   4                        OFFSET IN RQE TO ASSIGNED BYTE  82825821
IECIGRID EQU   4                        OFFSET IN RQE TO TCB ID (MFT)   82845821
IECIGRIB EQU   5                        OFFSET IN RQE TO IOB PTR        82865821
IECIGRDB EQU   8                        OFFSET IN RQE TO DEB PTR        82885821
IECIGRKY EQU   12                       OFFSET IN RQE OF REQ PROT KEY   82905821
IECIGRTB EQU   13                       OFFSET IN RQE TO TCB PTR        82925821
IECIGFTS EQU   0                        OFFSET IN LCH OF FIRST RQE      82945821
IECIGLTS EQU   2                        OFFSET IN LCH OF LAST RQE       82965821
IECIG0   EQU   0                        ZERO MASK                       82985821
IECIG4   EQU   4                        RETURN CODE 4                   83005821
IECIG8   EQU   8                        RETURN CODE 8                   83025821
IECIG12  EQU   12                       RETURN CODE 12                  83045821
IECIGDUM EQU   X'01'                    MASK FOR LAST RQE TEST          83065821
IECIGSCM EQU   X'10'                    MVT SYSTEM CONFIG MASK          83085821
IECIGNC  EQU   X'7F'                    NORMAL I/O COMPLETION MASK      83105821
IECIGIDV EQU   X'FF'                    UCB IDENTIFICATION              83125821
         SPACE 1                                                        83145821
*********************************************************************** 83165821
*                                                                     * 83185821
*        CONTROL BLOCK VALIDATION                                     * 83205821
*                                                                     * 83225821
*        THIS ROUTINE CHECKS THE VALIDITY OF THE VARIOUS CONTROL      * 83245821
*        BLOCK USED BY THE GETQRQE FUNCTION.  THESE BLOCKS ARE THE    * 83265821
*        IOB, UCB, DEB, DCB, AND ECB.  AN INVALID BOUNDARY, BLOCK     * 83285821
*        ID, BACKLINK POINTER, OR STORAGE/PROTECT KEY CONDITION       * 83305821
*        WILL RESULT IN THE SETTING OF THE PROPER RETURN CODE IN      * 83325821
*        THE RETURN CODE REGISTER.                                    * 83345821
*                                                                     * 83365821
*********************************************************************** 83385821
         SPACE 1                                                        83405821
&NAME    LR    IECIGWK4,IECIGIOB        IOB ADDR TO WORK REG            83425821
         N     IECIGWK4,IECIGWDM        CHECK IOB FOR WORD BOUNDARY     83445821
         BNZ   IECIG070                 BAD IOB BOUNDARY                83465821
         L     IECIGWK4,IECIGIDC-1(IECIGIOB) DCB ADDR TO WORK REG       83485821
         LR    IECIGDCB,IECIGWK4        SAVE DCB ADDR                   83505821
         N     IECIGWK4,IECIGWDM        CHECK DCB FOR WORD BOUNDARY     83525821
         BNZ   IECIG070                 BAD DCB BOUNDARY                83545821
         L     IECIGWK4,IECIGDDE-1(IECIGDCB) DEB ADDR TO WORK REG       83565821
         LR    IECIGDEB,IECIGWK4        SAVE DEB ADDR                   83585821
         N     IECIGWK4,IECIGWDM        CHECK DEB FOR WORD BOUNDARY     83605821
         BNZ   IECIG070                 BAD DEB BOUNDARY                83625821
         CLC   IECIGIDC(3,IECIGIOB),IECIGDDC(IECIGDEB) IS DCB VALID     83645821
         BNE   IECIG070                 NO, INVALID DCB                 83665821
         MVZ   IECIGIDW(1),IECIGDPK(IECIGDEB) SEPARATE PROTECT KEY      83685821
         TM    IECIGSC(IECIGCVT),IECIGSCM IS SYS CONFIG MFT OR MVT      83705821
         BO    IECIG010                 MVT                             83725821
*   MFT - INSURE THAT DEB PROTECTION KEY CORRESPONDS TO TASK'S KEY      83745821
         CLC   IECIGIDW(1),IECIGTSK(IECIGTCB) PROTECT KEYS THE SAME     83765821
         BE    IECIG020                 YES, VALID KEY                  83785821
         B     IECIG075                 NO, INVALID KEY                 83805821
*   MVT - CHECK CONTROL BLOCK VALIDITY (BOUNDARIES AND KEYS)            83825821
IECIG010 LR    IECIGWK3,IECIGIOB        IOB ADDR TO WORK REG            83845821
         IC    IECIGWK3,IECIGWDM        ZERO BITS 24-31                 83865821
         ISK   IECIGWK3,IECIGWK3        INSERT KEY OF IOB               83885821
         EX    IECIGWK3,IECIGPCK        CHECK IOB STORAGE KEY           83905821
         BNE   IECIG075                 INVALID KEY                     83925821
         LR    IECIGWK3,IECIGDCB        DCB ADDR TO WORK REG            83945821
         IC    IECIGWK3,IECIGWDM        ZERO BITS 24-31                 83965821
         ISK   IECIGWK3,IECIGWK3        INSERT KEY OF DCB               83985821
         EX    IECIGWK3,IECIGPCK        CHECK DCB STORAGE KEY           84005821
         BNE   IECIG075                 INVALID KEY                     84025821
         L     IECIGWK3,IECIGECB-1(IECIGIOB) ECB ADDR TO WORK REG       84045821
         N     IECIGWK3,IECIGWDM        CHECK ECB FOR WORD BOUNDARY     84065821
         BNZ   IECIG070                 BAD ECB BOUNDRY                 84085821
         L     IECIGWK3,IECIGECB-1(IECIGIOB) ECB ADDR TO WORK REG       84105821
         IC    IECIGWK3,IECIGWDM        ZERO BITS 24-31                 84125821
         ISK   IECIGWK3,IECIGWK3        INSERT KEY OF ECB               84145821
         EX    IECIGWK3,IECIGPCK        CHECK ECB STORAGE KEY           84165821
         BNE   IECIG075                 INVALID KEY                     84185821
         LR    IECIGWK3,IECIGDEB        DEB ADDR TO WORK REG            84205821
         IC    IECIGWK3,IECIGWDM        ZERO BITS 24-31                 84225821
         SR    IECIGWK4,IECIGWK4        CLEAR WORK REG                  84245821
         ISK   IECIGWK4,IECIGWK3        INSERT KEY OF DEB               84265821
         LTR   IECIGWK4,IECIGWK4        IS KEY ZERO                     84285821
         BNZ   IECIG075                 NO, INVALID KEY                 84305821
IECIG020 TM    IECIGUID(IECIGUCB),IECIGIDV CHECK UCB ID VALUE           84325821
         BNO   IECIG070                 INVALID UCB                     84345821
         SPACE 1                                                        84365821
*********************************************************************** 84385821
*                                                                     * 84405821
*        CONTROL BLOCK INITIALIZATION                                 * 84425821
*                                                                     * 84445821
*********************************************************************** 84465821
         SPACE 1                                                        84485821
         STH   IECIGWK4,IECIGECT(IECIGIOB) CLEAR ERROR COUNTER          84505821
*   CLEAR IOB FLAGS AND CSW AREA                                        84525821
         XC    IECIGFL3(9,IECIGIOB),IECIGFL3(IECIGIOB)                  84545821
         NC    IECIGFL1(4,IECIGIOB),IECIGCFS CLEAR FLAGS AND SENSE      84565821
         MVI   IECIGCOD(IECIGIOB),IECIGNC SET NORMAL COMPLETION FLAG    84585821
         L     IECIGWK3,IECIGECB-1(IECIGIOB) ECB ADDR TO WORK REG       84605821
         ST    IECIGWK4,0(IECIGWK3)     RESET ECB                       84625821
         SPACE 1                                                        84645821
*********************************************************************** 84665821
*                                                                     * 84685821
*        GET REQUEST ELEMENT                                          * 84705821
*                                                                     * 84725821
*        THIS ROUTINE OBTAINS A REQUEST ELEMENT(RQE) FROM A LIST OF   * 84745821
*        AVAILABLE ELEMENTS.  THE UCB, IOB, DEB, AND TCB(MVT)         * 84765821
*        ADDRESSES ARE PLACED IN THE RQE ALONG WITH THE TCB ID        * 84785821
*        BYTE. IF NO RQE IS AVAILABLE THE PROPER RETURN CODE WILL     * 84805821
*        BE SET IN THE RETURN CODE REGISTER.                          * 84825821
*                                                                     * 84845821
*********************************************************************** 84865821
         SPACE 1                                                        84885821
         L     IECIGWK3,IECIGAVL(IECIGCVT) GET ADDR OF FREELIST PTR     84905821
         LH    IECIGTST,0(IECIGWK3)     GET ADDR OF NEXT RQE            84925821
         LTR   IECIGTST,IECIGTST        TEST FOR DUMMY                  84945821
         BM    IECIG080                 YES, LAST RQE IN USE            84965821
         TM    IECIGRLK+1(IECIGTST),IECIGDUM TEST FOR LAST RQE          84985821
         BO    IECIG080                 YES, CAN NOT USE LAST RQE       85005821
         STH   IECIGUCB,IECIGRUB(IECIGTST) STORE UCB ADDR IN RQE        85025821
         ST    IECIGIOB,IECIGRIB-1(IECIGTST) STORE IOB ADDR IN RQE      85045821
         ST    IECIGDEB,IECIGRDB(IECIGTST) STORE DEB ADDR IN RQE        85065821
         TM    IECIGSC(IECIGCVT),IECIGSCM IS SYS CONFIG MFT OR MVT      85085821
         BO    IECIG030                 MVT                             85105821
*   MFT - GET THE ID FROM THE TCB REQUESTING I/O                        85125821
         MVC   IECIGRID(1,IECIGTST),IECIGTID(IECIGTCB) MOVE ID TO RQE   85145821
         B     IECIG040                                                 85165821
*   MVT - STORE TCB ADDRESS AND GET REQUESTORS PROTECT KEY              85185821
IECIG030 ST    IECIGTCB,IECIGRTB-1(IECIGTST) STORE TCB ADDR IN RQE      85205821
         MVI   IECIGRAS(IECIGTST),IECIG0 MARK AS ASSIGNED               85225821
         MVC   IECIGRKY(1,IECIGTST),IECIGTSK(IECIGTCB) REQ KEY TO RQE   85245821
IECIG040 MVC   0(2,IECIGWK3),IECIGRLK(IECIGTST) UPDATE RQE LIST         85265821
         SPACE 1                                                        85285821
*********************************************************************** 85305821
*                                                                     * 85325821
*        LOCATE LOGICAL CHANNEL WORD                                  * 85345821
*                                                                     * 85365821
*********************************************************************** 85385821
         SPACE 1                                                        85405821
         SR    IECIGWK3,IECIGWK3        CLEAR WORK REG                  85425821
         IC    IECIGWK3,IECIGLCI(IECIGUCB) GET LCH INDEX FROM UCB       85445821
         SLL   IECIGWK3,3               MULTIPLY BY 8                   85465821
         L     IECIGWK4,IECIGLCT(IECIGCVT) GET ADDR OF LCH TABLE        85485821
         LA    IECIGLCH,0(IECIGWK3,IECIGWK4) LOGICAL CHANNEL WORD ADDR  85505821
         SPACE 1                                                        85525821
*********************************************************************** 85545821
*                                                                     * 85565821
*        ENQUEUE                                                      * 85585821
*                                                                     * 85605821
*        THIS ROUTINE ADDS A REQUEST ELEMENT TO A LOGICAL CHANNEL     * 85625821
*        QUEUE.                                                       * 85645821
*                                                                     * 85665821
*********************************************************************** 85685821
         SPACE 1                                                        85705821
         TM    IECIGFTS+1(IECIGLCH),IECIGDUM TEST EMPTY QUEUE           85725821
         BZ    IECIG060                 NO, PUT AT END OF CHAIN         85745821
         STH   IECIGTST,IECIGFTS(IECIGLCH) PUT THE RQE FIRST IN QUEUE   85765821
IECIG050 STH   IECIGTST,IECIGLTS(IECIGLCH) PUT THE RQE LAST IN QUEUE    85785821
         MVC   IECIGRLK(2,IECIGTST),IECIGDAD POINT LAST ENTRY TO DUMMY  85805821
         B     IECIG085                 EXIT, SUCCESSFUL COMPLETION     85825821
IECIG060 LH    IECIGWK4,IECIGLTS(IECIGLCH) GET LAST REQUEST IN QUEUE    85845821
         STH   IECIGTST,IECIGRLK(IECIGWK4) LINK ENTRY ON END            85865821
         B     IECIG050                                                 85885821
         SPACE 1                                                        85905821
*********************************************************************** 85925821
*        CONSTANTS                                                    * 85945821
*********************************************************************** 85965821
         SPACE 1                                                        85985821
         DS    0F                                                       86005821
IECIGWDM DC    X'00000003'              FULL WORD BOUNDARY MASK         86025821
*   X'C2'(COMMAND & DATA CHAINING,UNRELATED) X'01'(QSAM) X'0000'(SENSE) 86045821
IECIGCFS DC    X'C2010000'                                              86065821
IECIGPCK CLI   IECIGIDW,IECIG0          PROTECT KEY TEST                86085821
IECIGIDW DC    X'00'                    PROTECT KEY WORK AREA           86105821
IECIGDAD DC    XL2'FFFF'                DUMMY ADDRESS                   86125821
         SPACE 1                                                        86145821
*********************************************************************** 86165821
*                                                                     * 86185821
*        EXIT                                                         * 86205821
*                                                                     * 86225821
*        THE RETURN CODE REGISTER IS SET TO INDICATE THE EXIT         * 86245821
*        CONDITION.                                                   * 86265821
*                                                                     * 86285821
*********************************************************************** 86305821
         SPACE 1                                                        86325821
IECIG070 LA    IECIGRTN,IECIG4          RETURN CODE = 4, INVALID CTRL   86345821
         B     IECIG100                 BLK OR CTRL BLK BOUNDARY        86365821
IECIG075 LA    IECIGRTN,IECIG8          RETURN CODE = 8, INVALID CTRL   86385821
         B     IECIG100                 BLK KEY (STORAGE/PROTECT)       86405821
IECIG080 LA    IECIGRTN,IECIG12         RETURN CODE = 12, NO RQE IS     86425821
         B     IECIG100                 AVAILABLE                       86445821
IECIG085 SR    IECIGRTN,IECIGRTN        RETURN CODE = 0, SUCCESSFUL     86465821
IECIG100 DS    0H                       EXIT FROM FUNCTION              86485821
         MEXIT                                                          86505821
.********************************************************************** 86525821
.*                                                                    * 86545821
.*       ALL IOSGEN MNOTE ERROR MESSAGES ARE PLACED BELOW --         *  86565821
.*             .IOSNG1 - AUTHORIZATION VIOLATION.                     * 86585821
.*                       USED BY ALL FUNCTIONS.                       * 86605821
.*                                                                    * 86625821
.*             .IOSNG2 - INSUFFICIENT NUMBER OF REGISTERS SPECIFIED.  * 86645821
.*                       USED BY 'MAP','VARY','DOM','PTHAVL',         * 86665821
.*                       'SELSSM', AND 'GETQRQE'.                     * 86685821
.*                                                                    * 86705821
.*             .IOSNG3 - UNSUPPORTED FUNCTION SPECIFIED, OR PARAMETER * 86725821
.*                       SPECIFICATION ERROR.                         * 86745821
.*                       USED AT BEGINNING OF MACRO, AND IN 'PTHAVL', * 86765821
.*                       WHEN AN INVOCATION IS ATTEMPTED FOR          * 86785821
.*                       'UNI-PROCESSING' SYSTEM CODE.                * 86805821
.*                       ALSO FOR SPECIFICATION OF UNSUPPORTED BITS   * 86825821
.*                       IN 'UCBFL1'.                                 * 86845821
.*                                                                    * 86865821
.********************************************************************** 86885821
.*                                                                    * 86905821
.IOSNG1  MNOTE 8,'*** ''&AUTH'' MAY NOT INVOKE ''&FUNC'' FUNCTION.'     86925821
         MEXIT                                                          86945821
.*                                                                    * 86965821
.IOSNG2  MNOTE 8,'*** INSUFFICIENT WORK REGISTERS SPECIFIED.'           86985821
         MEXIT                                                          87005821
.*                                                                    * 87025821
.IOSNG3  MNOTE 8,'*** ERROR IN PARAMETER SET UP, OR ''&FUNC'' NOT A SUP+87045821
               PORTED FUNCTION.'                                        87065821
.*                                                                    * 87085821
.IOSGEND MEND                                                           89913319
