         MACRO                                                          00100020
         MSTARTMH &X                                                    00200020
.******************* MICROFICHE FLAGS *********************** SUPT CODE 00200122
.*A419000,430000,443000,447000,747000-XXXXXX,748000-XXXXXX       S99528 00201022
.*A807000-XXXXXX                                                 S99528 00201122
.*C694000                                                        S99528 00201222
.*D687400-687460,708000-708300,710000-710500,714000-721000       S99528 00201322
.*D753000-754000                                                 S99528 00201422
.*A533500,897020-XXXXXX                                          S22029 00201522
.*C427000,510000-510500,511000-511500,528000,618360,813000       S22029 00201622
.*C824100,824500                                                 S22029 00201722
.*D508000,531000,618030-618330,618390,816000,831000-860000       S22029 00201822
.*A689000                                                        A44861 00201922
.*C483000                                                        A44861 00202022
.*A824000                                                         M6673 00202122
.*A862000                                                        S21101 00202222
.*C483000                                                         M6673 00202322
.*C483000,839000                                                 A44907 00202422
.*D841000                                                        A44907 00202522
.*A858100                                                        A44907 00202622
.*A441000,590070,618333,618400,630300,632000,687100,862980,      S22025 00202722
.*A872200,926200                                                 S22025 00202822
.*C556000,569000,610000,617000,632000,636000-644000,687000,      S22025 00202922
.*C690000-691500,694000,697000-700000,706000,709000-710500,      S22025 00203022
.*C714000-717000,721000,769000-775000                            S22025 00203122
.*D578000-583000,662800-665000,718000-719000,725000-743000,      S22025 00203222
.*D760000-766000,786000-787000,788000-805000,862500-862960,892000S22025 00203322
.*A467000,680000,822000                                         SA52512 00203422
.*C630600,872000                                                SA52512 00203522
.*A872000                                                       SA56222 00203622
.*C822000                                                       SA56222 00203722
.*A868000,906000                                                SA54959 00203822
.*C630600                                                       SA54959 00203922
.*A565000,932000                                                SA52971 00204305
.*C538000-541000                                                SA52971 00204405
.*D543000-554000,562000-563000                                  SA52971 00204505
.*C882000,887000-888000,895000,897520,902000                     A59509 00204605
.*D886000,897580,897740                                          A59509 00204705
.*A897940-897960                                                 A59509 00204805
.*D862982,862994                                                SA59169 00204905
.*A464000,642000,861000,863000,897200,936000                     S22024 00205005
.*A467700-467900,758100-758800,807040-807880                     S22024 00205105
.*C211000,710400,871000                                          S22024 00205205
.*C824700                                                       SA61771 00205305
.*A618354                                                       SA62383 00205405
.*A467600,566000                                                SA60343 00205505
.*747800,747880                                                 SA63640 00205605
.*D747200,747240                                                SA63640 00205705
.*D537000-555000                                                SA66605 00235753
*A807000                                                        SA68025 00242756
*C807090                                                        SA68025 00249756
*D807780-809000                                                 SA68025 00256756
.*A606000                                                       SA66605 00265753
*********************************************************************** 00299222
         AIF   ('&X' NE 'TSO').A1                                       00300020
AYR1     TITLE '''IEDAYR'' -- STARTMH SUBTASK, TCAM-TSO MIXED'          00400020
IEDAYR   CSECT                                                          00500020
*********************************************************************** 00600020
*TITLE  'IEDAYR'  TSO STARTMH SUBTASK                                 * 00700020
*                                                                     * 00800020
*  MODULE NAME = IEDAYR                                               * 00900022
*                                                                     * 00910022
*  DESCRIPTIVE NAME= TSO/MIXED STARTMH ROUTINE                        * 00920022
*                                                                     * 00930022
*  COPYRIGHT = 'NONE'                                                 * 00940022
*                                                                     * 00950022
*  STATUS = CHANGE LEVEL 5                                            * 00960053
*                                                                     * 01000020
*FUNCTION -- THE TSO STARTMH SUBTASK PERFORMS INITIALIZATION FUNC-    * 01100020
*   TIONS FOR A BUFFER BEFORE SENDING IT THROUGH A TCAM OR TSO MES-   * 01200020
*   SAGE HANDLER.  THE EXACT FUNCTIONS VARY, DEPENDING UPON WHETHER   * 01300020
*   THE BUFFER IS A HEADER OR A TEXT BUFFER, AND WHETHER IT IS TO BE  * 01400020
*   PROCESSED BY THE INCOMING OR OUTGOING SIDE OF THE MH.             * 01500020
*      THIS ROUTINE FIRST CHECKS FOR A RECALLED BUFFER.  IF IT IS RE- * 01600020
*   CALLED, NO INITIALIZATION FUNCTIONS ARE PERFORMED, AND ONLY THE   * 01700020
*   CHECK FOR TRANSLATION IS MADE.  IF THE BUFFER IS OUTGOING, AND    * 01800020
*   THE DESTINATION TERMINAL IS IN LOCK MODE, THE LCB COUNT OF OUT-   * 01900020
*   STANDING LOCK RESPONSES IS INCREMENTED, AND THE PREFIX LOCK BIT   * 02000020
*   IS SET OFF.  IF THE BUFFER, INCOMING OR OUTGOING, IS A TSO BUFFER,* 02100020
*   THE LCB RESERVE COUNT IS INITIALIZED TO ZERO.  THEN THIS ROUTINE  * 02200020
*   CHECKS TO SEE IF THE BUFFER IS HEADER OR TEXT.  FOR ALL HEADER    * 02300020
*   BUFFERS, THE SCB MULTIPLE BUFFER HEADER ENTRY IS SET TO ZERO.     * 02400020
*   NEXT, THIS ROUTINE CHECKS TO SEE IF THE BUFFER IS TO BE PROCESSED * 02500020
*   BY AN INCOMING OR OUTGOING MH.  PROCESSING IS THEN TAILORED FOR   * 02600020
*   EACH OF THE FOUR SITUATIONS.                                      * 02700020
*      FOR AN INCOMING HEADER BUFFER, THE PREFIX SOURCE FIELD IS      * 02800020
*   INITIALIZED FROM THE CURRENT TERMINAL INDEX IN THE LCB, AND THE   * 02900020
*   SCB PRIORITY AND CUTOFF COUNT ARE SET TO ZERO.  IF IT IS A TSO    * 03000020
*   BUFFER, THIS ROUTINE BRANCHES TO THE EXIT ROUTINE.  IF NOT, THE   * 03100020
*   PREFIX SCAN POINTER IS SET TO POINT TO THE LAST BYTE OF THE PRE-  * 03200020
*   FIX, OR TO THE LAST RESERVE CHARACTER, IF SPECIFIED.  IF THE      * 03300020
*   MESSAGE SOURCE WAS AN APPLICATION PROGRAM, THIS ROUTINE NOW       * 03400020
*   BRANCHES TO THE EXIT ROUTINE.  OTHERWISE, IT CHECKS TO SEE IF AN  * 03500020
*   EOA SEQUENCE WAS DEFINED IN THE SPECIAL CHARACTERS TABLE.  IF IT  * 03600020
*   WAS, IT LINKS TO THE SKIP FORWARD AND SCAN ROUTINE TO SEE IF THE  * 03700020
*   EOA SEQUENCE IS IN THE BUFFER.  IF IT IS, THE SCAN POINTER IS SET * 03800020
*   TO POINT BEYOND IT.  FOR 1030'S AND REMOTE 2260'S, THE SCAN       * 03900020
*   POINTER IS ALSO MOVED BEYOND THE ADDRESSING CHARACTER, WHICH FOL- * 04000020
*   LOWS THE EOA SEQUENCE FOR THESE DEVICES.  AT THIS POINT, IF THE   * 04100020
*   TERMINAL IS IN LOCK MODE, THIS ROUTINE BRANCHES TO THE EXIT ROU-  * 04200020
*   TINE.  OTHERWISE, THIS ROUTINE CHECKS TO SEE IF THE BUFFER CON-   * 04300020
*   TAINS AN ON-LINE TEST MESSAGE.  FOR BINARY SYNCHRONOUS LINES, A   * 04400020
*   BIT IN THE LCB IS CHECKED; FOR START/STOP LINES, THIS ROUTINE     * 04500020
*   LINKS TO THE SKIP FORWARD AND SCAN ROUTINE TO SEE IF AN ON-LINE   * 04600020
*   TEST SEQUENCE IS IN THE BUFFER.  IF THE BUFFER CONTAINS AN ON-    * 04700020
*   LINE TEST MESSAGE, BUT ON-LINE TEST IS NOT IN THE SYSTEM, THIS    * 04800020
*   ROUTINE SETS A BIT IN THE ERROR WORD AND BRANCHES TO THE EXIT     * 04900020
*   ROUTINE.  IF ON-LINE TEST IS IN THE SYSTEM, THIS ROUTINE SETS ON- * 05000020
*   LINE TEST PRIORITY IN THE BUFFER PREFIX AND EXITS TO THE DIS-     * 05100020
*   PATCHER POST FUNCTION TO POST THE BUFFER TO THE ON-LINE TEST QCB. * 05200020
*   IF THE BUFFER DOES NOT CONTAIN AN ON-LINE TEST MESSAGE, THIS      * 05300020
*   ROUTINE BRANCHES TO THE EXIT ROUTINE.                             * 05400020
*      FOR AN INCOMING TEXT BUFFER, THE PREFIX SOURCE FIELD IS INI-   * 05500020
*   TIALIZED AS FOR AN INCOMING HEADER BUFFER.  IF THE MH TO RECEIVE  * 05600020
*   THE BUFFER IS A TSO MH, THIS ROUTINE CHECKS TO SEE IF THE DES-    * 05700020
*   TINATION IS THE TSINPUT QCB.  IF IT IS, THIS ROUTINE BRANCHES     * 05800020
*   TO THE ROUTINE TO CHECK FOR TRANSLATION.  IF IT IS NOT, THIS      * 05900020
*   ROUTINE CHECKS FOR A LOGON EXIT.  IF A LOGON EXIT IS NOT PRESENT, * 06000020
*   IT ALSO BRANCHES TO THE TRANSLATION CHECK.  IF A LOGON EXIT IS    * 06100020
*   PRESENT, A NEW QCB AND MH ARE ESTABLISHED, AND THIS ROUTINE       * 06200020
*   BRANCHES TO THE NEW MH.  IF THE MH TO RECEIVE THE BUFFER IS NOT A * 06300020
*   TSO MH, THE LCB RESERVE COUNT IS INITIALIZED FROM THE COUNT       * 06400020
*   SPECIFIED IN THE DCB, AND THE SCAN POINTER IS SET TO POINT TO THE * 06500020
*   LAST BYTE OF THE TEXT PREFIX, OR TO THE LAST RESERVE CHARACTER,   * 06600020
*   IF SPECIFIED.  THEN THIS ROUTINE BRANCHES TO THE TRANSLATION      * 06700020
*   CHECK.                                                            * 06800020
*      FOR AN OUTGOING HEADER BUFFER, AN IMMEDIATE BRANCH TO THE EXIT * 06900020
*   ROUTINE IS TAKEN IF IT IS A TSO BUFFER.  OTHERWISE, A CHECK IS    * 07000020
*   MADE FOR A LOGON EXIT.  IF ONE IS PRESENT, THIS ROUTINE SETS UP   * 07100020
*   AND BRANCHES TO THE NEW MH, AS DESCRIBED ABOVE.  IF NO LOGON EXIT * 07200020
*   IS PRESENT, THIS ROUTINE PERFORMS FEFO UPDATING.  NORMALLY, THE   * 07300020
*   FEFO POINTER IN THE DESTINATION (PRIORITY) QCB IS UPDATED FROM    * 07400020
*   THE SCB FEFO POINTER, AND THE 'CURRENTLY SENDING' FLAG IN THE     * 07500020
*   MASTER QCB IS SET OFF.  HOWEVER, THERE ARE THREE SITUATIONS IN    * 07600020
*   WHICH THIS IS NOT DONE: (1) IF THE DESTINATION TERMINAL IS IN     * 07700020
*   LOCK MODE WITH AN APPLICATION PROGRAM, NO FEFO UPDATING CAN TAKE  * 07800020
*   PLACE UNTIL IT IS UNLOCKED.  (2) IF THE LINE IS IN INITIATE MODE, * 07900020
*   NO FEFO UPDATING CAN TAKE PLACE UNTIL THE LAST BUFFER OF THE INI- * 08000020
*   TIATE MESSAGE HAS BEEN PROCESSED THROUGH THE MH.  (3) IF A TEXT   * 08100020
*   TRANSFER ERROR GENERATED A ZERO LENGTH BUFFER, NO FEFO UPDATING   * 08200020
*   TAKES PLACE BECAUSE THE BUFFER WILL NOT BE SENT TO THE DESTINA-   * 08300020
*   TION.  IF THE DESTINATION TERMINAL IS IN BOTH LOCK AND EXTENDED   * 08400020
*   LOCK MODE, BOTH LOCK BITS IN THE SCB ARE SET OFF.                 * 08500020
*      AFTER ANY FEFO UPDATING IS COMPLETE, THE LCB RESERVE COUNT IS  * 08600020
*   SET TO ZERO FOR ZERO LENGTH BUFFERS, OR TO THE VALUE IN THE SCAN  * 08700020
*   POINTER FOR NON-ZERO LENGTH BUFFERS.  THE SCAN POINTER IS THEN    * 08800020
*   SET TO POINT TO THE LAST BYTE OF THE HEADER PREFIX, OR TO THE     * 08900020
*   LAST RESERVE CHARACTER, IF SPECIFIED.  IN ADDITION, FOR NON-ZERO  * 09000020
*   LENGTH BUFFERS, THIS ROUTINE LINKS TO THE TERMNAME TABLE CODE TO  * 09100020
*   GET THE TERMINAL ENTRY, SAVES THE CURRENT OUTPUT SEQUENCE NUMBER  * 09200020
*   IN THE SCB, AND INCREMENTS THE OUTPUT SEQUENCE NUMBER IN THE      * 09300020
*   TERMINAL ENTRY.  IF THE MAXIMUM OUTPUT SEQUENCE NUMBER IS EX-     * 09400020
*   CEEDED, IT IS RESET TO ONE.  FINALLY, THIS ROUTINE BRANCHES TO    * 09500020
*   THE EXIT ROUTINE.                                                 * 09600020
*      FOR AN OUTGOING TEXT BUFFER, AN IMMEDIATE BRANCH TO THE TRANS- * 09700020
*   LATION CHECK IS TAKEN IF IT IS A TSO BUFFER.  OTHERWISE A CHECK   * 09800020
*   IS MADE FOR A LOGON EXIT.  IF ONE IS PRESENT, THIS ROUTINE SETS   * 09900020
*   UP AND BRANCHES TO THE NEW MH, AS DESCRIBED ABOVE.  IF NO LOGON   * 10000020
*   EXIT IS PRESENT, THIS ROUTINE INITIALIZES THE LCB RESERVE COUNT   * 10100020
*   TO ZERO, SETS THE SCAN POINTER TO POINT TO THE LAST BYTE OF THE   * 10200020
*   TEXT PREFIX, AND BRANCHES TO THE TRANSLATION CHECK, WHICH IS DE-  * 10300020
*   SCRIBED NEXT.                                                     * 10400020
*      THE TSO STARTMH SUBTASK HANDLES BUFFER TRANSLATION FOR THE     * 10500020
*   FOLLOWING TYPES OF BUFFERS: (1) INCOMING TEXT BUFFERS DIRECTED TO * 10600020
*   A NON-TSO MH, (2) INCOMING TEXT BUFFERS DIRECTED TO A TSO MH WITH-* 10700020
*   OUT A LOGON EXIT, (3) OUTGOING TCAM (NON-TSO) HEADER BUFFERS, AND * 10800020
*   (4) ALL RECALLED BUFFERS.  THE TRANSLATION CHECK FIRST CHECKS FOR * 10900020
*   A ZERO LENGTH BUFFER.  A ZERO LENGTH BUFFER IS NOT TRANSLATED.    * 11000020
*   NEXT IT CHECKS THE SCB TO SEE IF TRANSLATION WAS REQUESTED.  IF   * 11100020
*   NOT, THE BUFFER IS NOT TRANSLATED.  IF IT WAS, THIS ROUTINE LINKS * 11200020
*   TO THE TRANSLATE BUFFER ROUTINE, VIA THE USER INTERFACE, TO TRANS-* 11300020
*   LATE THE BUFFER.  IF THE SCB MULTIPLE BUFFER HEADER ENTRY IS ZERO,* 11400020
*   THIS ROUTINE BRANCHES TO THE EXIT ROUTINE.  IF NOT, THE PRESENCE  * 11500020
*   OF A MULTIPLE BUFFER HEADER IS INDICATED BY SETTING A NEGATIVE    * 11600020
*   VALUE IN REGISTER 0, AND THE ADDRESS OF THE USER INTERFACE IS     * 11700020
*   LOADED INTO REGISTER 15, BEFORE BRANCHING TO THE EXIT ROUTINE.    * 11800020
*      THE EXIT ROUTINE OF THIS SUBTASK GETS THE ADDRESS OF THE FIRST * 11900020
*   INSTRUCTION IN THE MH AND SETS AN INCREMENT OF 4096 IN REGISTER 2 * 12000020
*   FOR MULTIPLE BASE REGISTER SUPPORT.  IF A MULTIPLE BUFFER HEADER  * 12100020
*   IS PRESENT, A CONDITION CODE OF 4 IS SET IN THE PSW.  OTHERWISE,  * 12200020
*   A CONDITION CODE OF EITHER 1 OR 8 IS SET IN THE PSW, DEPENDING ON * 12300020
*   WHETHER THE LINE IS SENDING OR RECEIVING, RESPECTIVELY.  THESE    * 12400020
*   CONDITION CODES WILL BE TESTED BY THE CODE GENERATED BY THE       * 12500020
*   STARTMH MACRO INSTRUCTION.  FINALLY, THIS ROUTINE EXITS TO THE    * 12600020
*   FIRST EXECUTABLE INSTRUCTION OF THE MH.                           * 12700020
*                                                                     * 12800020
*ENTRY POINT -- IEDQAA01 - TO PERFORM INITIALIZATION FOR A BUFFER     * 12900020
*   BEFORE SENDING IT THROUGH A TCAM OR TSO MESSAGE HANDLER           * 13000020
*   CALLING SEQUENCE          L    R15,STCBLINK-1                     * 13100020
*                             BR   R15                                * 13200020
*                                                                     * 13300020
*INPUT -- IEDAYR IS CALLED BY THE DISPATCHER WHEN, IN A MIXED         * 13400020
*   TSO/TCAM ENVIRONMENT, A BUFFER IS POSTED TO THE STARTMH QCB.      * 13500020
*   AT ENTRY, THE FOLLOWING REGISTERS ARE SET.                        * 13600020
*   R1 HAS THE BUFFER ADDRESS, WHICH THIS ROUTINE SAVES IN THE AVT    * 13700020
*   R7 HAS THE ADDRESS OF THE STARTMH QCB                             * 13800020
*   R11 HAS THE DISPATCHER ADDRESS                                    * 13900020
*   R13 HAS THE ADDRESS OF AVTSAVE2                                   * 14000020
*   R15 HAS THE ENTRY POINT ADDRESS                                   * 14100020
*                                                                     * 14200020
*OUTPUT -- ON LINKING TO THE SKIP FORWARD AND SCAN ROUTINE (IEDQAI),  * 14300020
*   VIA THE USER INTERFACE, THE FOLLOWING REGISTERS ARE SET.          * 14400020
*   R1 HAS THE ADDRESS OF THE PARAMETER LIST, WHICH INCLUDES THE OFF- * 14500020
*   SET OF THE EOA SEQUENCE OR ON-LINE TEST SEQUENCE IN THE SPECIAL   * 14600020
*   CHARACTERS TABLE.                                                 * 14700020
*   R8 HAS THE ADDRESS OF THE SPECIAL CHARACTERS TABLE                * 14800020
*   R14 HAS THE RETURN ADDRESS IN IEDAYR                              * 14900020
*   R15 HAS THE ENTRY POINT ADDRESS IN IEDQUI                         * 15000020
*                                                                     * 15100020
*   ON LINKING TO THE TRANSLATE BUFFER ROUTINE (IEDQAW), VIA THE USER * 15200020
*   INTERFACE, THE FOLLOWING REGISTERS ARE SET.                       * 15300020
*   R1 HAS THE ADDRESS OF THE TRANSLATE PARAMETER LIST FROM THE SCB   * 15400020
*   R14 HAS THE RETURN ADDRESS IN IEDAYR                              * 15500020
*   R15 HAS THE ENTRY POINT ADDRESS IN IEDQUI                         * 15600020
*                                                                     * 15700020
*   ON EXIT TO THE DISPATCHER POST FUNCTION, THE ELEMENT KEY IN THE   * 15800020
*   PREFIX IS SET TO INDICATE EITHER A BISYNC OR A START/STOP LINE,   * 15900020
*   THE DESTINATION QCB FIELD IN THE SCB CONTAINS THE ADDRESS OF THE  * 16000020
*   ON-LINE TEST QCB, THE LINE STATUS IS SET TO STOPPED, AND REGISTER * 16100020
*   1 CONTAINS THE ADDRESS OF THE BUFFER TO BE POSTED.                * 16200020
*                                                                     * 16300020
*   ON EXIT TO AN MH SPECIFIED AS A LOGON EXIT, THE FOLLOWING REGIS-  * 16400020
*   TERS ARE SET.                                                     * 16500020
*   R3 HAS THE SCB ADDRESS                                            * 16600020
*   R4 HAS THE LCB ADDRESS                                            * 16700020
*   R6 HAS THE BUFFER ADDRESS                                         * 16800020
*   R7 HAS THE ADDRESS OF THE NEW QCB                                 * 16900020
*   R15 HAS THE ENTRY POINT ADDRESS IN THE NEW MH                     * 17000020
*                                                                     * 17100020
*   ON EXIT TO THE MH TO PROCESS THE BUFFER, A CONDITION CODE OF 1,   * 17200020
*   4, OR 8 IS SET IN THE PSW, AND THE FOLLOWING REGISTERS ARE SET.   * 17300020
*   R0 HAS A NEGATIVE VALUE, IF A MULTIPLE BUFFER HEADER IS PRESENT,  * 17400020
*   OR ZERO                                                           * 17500020
*   R2 HAS AN INCREMENT OF 4096                                       * 17600020
*   R3 HAS THE SCB ADDRESS                                            * 17700020
*   R4 HAS THE LCB ADDRESS                                            * 17800020
*   R6 HAS THE BUFFER ADDRESS                                         * 17900020
*   R12 HAS THE ENTRY POINT ADDRESS IN THE MH                         * 18000020
*                                                                     * 18100020
*EXTERNAL ROUTINES -- IEDQAI - TO SCAN FOR AN EOA SEQUENCE OR ON-LINE * 18200020
*   TEST SEQUENCE IN THE BUFFER                                       * 18300020
*   IEDQTNT - TO GET THE TERMINAL ENTRY FOR THE DESTINATION OF AN     * 18400020
*   OUTGOING HEADER BUFFER                                            * 18500020
*   IEDQAW - TO TRANSLATE THE BUFFER                                  * 18600020
*                                                                     * 18700020
*EXITS-NORMAL -- TO THE MH SPECIFIED IN THE STARTMH QCB               * 18800020
*   TO THE MH SPECIFIED AS THE LOGON EXIT IN THE STARTMH QCB          * 18900020
*   TO THE DISPATCHER POST FUNCTION                                   * 19000020
*                                                                     * 19100020
*EXITS-ERROR -- NONE                                                  * 19200020
*                                                                     * 19300020
*TABLES/WORKAREAS -- AVT, LCB, SCB, DCB, DEB, UCB, QCB, BUFFER PREFIX,* 19400020
*   TERMINAL ENTRY, SPECIAL CHARACTERS TABLE, TPRIOR ERB.             * 19500020
*                                                                     * 19600020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 19700020
*   PROBLEM PROGRAM MODE.                                             * 19800020
*                                                                     * 19900020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A         * 20000020
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET. * 20100020
*                                                                     * 20200020
*********************************************************************** 20300020
         AGO   .A2                                                      20400020
.A1      ANOP                                                           20500020
AA01     TITLE '''IEDQAA'' - STARTMH ROUTINE'                           20600020
IEDQAA   CSECT                                                          20700020
         SPACE                                                          20800020
*********************************************************************** 20900020
*                                                                     * 21000020
*  TITLE 'IEDQAA'  STARTMH ROUTINE                                    * 21100022
*                                                                     * 21110022
*  DESCRIPTIVE NAME= STARTMH ROUTINE                                  * 21120022
*                                                                     * 21130022
*  COPYRIGHT = 'NONE'                                                 * 21140022
*                                                                     * 21150022
*  STATUS: CHANGE LEVEL 4                                             * 21160022
*                                                                     * 21200020
*FUNCTION -- PERFORMS INITIALIZATION FUNCTIONS FOR THE PROCESSING     * 21300020
*   OF A MESSAGE BY THE MESSAGE HANDLER.                              * 21400020
*                                                                     * 21500020
*   ON ENTRY,  THE ADDRESS OF THE BUFFER POSTED IS SET IN THE AVT.    * 21600020
*   IF THE CANCEL FLAG IS SET IN THE PREFIX STATUS BYTE (PRFCNCLN     * 21700020
*   IN PRFSTAT1),  CONTROL PASSES IMMEDIATELY TO THE TEXT-PROCESS-    * 21800020
*   ING-INPUT SUBROUTINE TO TEST FOR A ZERO-LENGTH BUFFER.            * 21900020
*                                                                     * 22000020
*   IF ENTRY IS TO THE SEND SIDE OF THE MH,  AND IF THE TERMINAL IS   * 22100020
*   IN LOCK MODE,  THE PREFIX LOCK BIT IS TURNED OFF.  THE COUNT OF   * 22200020
*   OUTSTANDING LOCK REQUESTS IN THE LCB IS INCREMENTED BY ONE.       * 22300020
*   THE SUBTASK THEN DETERMINES IF THE                                * 22400020
*   BUFFER IS A HEADER OR TEXT BUFFER AND IF IT HAS BEEN RECEIVED     * 22500020
*   OR IS TO BE SENT AND PASSES CONTROL TO THE PROPER SUBROUTINE.     * 22600020
*                                                                     * 22700020
*   HEADER PROCESSING,  INPUT --                                      * 22800020
*                                                                     * 23900020
*     THE FOLLOWING FIELDS ARE INITIALIZED-                           * 24000022
*         PRFSRCE  --  ORIGIN FROM LCBTTCIN                           * 24100022
*         PRFSEQIN --  SEQUENCE IN NUMBER - ZEROED                    * 24200022
*         SCBPRI   --  SCB PRIORITY - ZEROED                          * 24300022
*         SCBBKFCT --  SCB CUTOFF COUNT - ZEROED                      * 24400022
*         PRFSCAN  --  SCAN POINTER OFFSET TO FIRST DATA BYTE-1       * 24500022
*                                                                     * 24700020
*     IF THE TERMINAL IS IN LOCK MODE (X'20' IN SCBSTATE)             * 24800022
*         PRFSTAT1 --  PRFLOCK SET (X'04')                            * 24900022
*         PRFDEST  --  DESTINATION OFFSET FROM LCBINSRC               * 25000022
*         SCBDESTQ --  DESTINATION QCB ADDR FROM TERM ENTRY           * 25100022
*         LCBINSRC+2-  POST PENDING SET (X'D0')                       * 25200022
*                                                                     * 25700020
*   IF THE TERMINAL IS NOT IN LOCK MODE,  THE SUBROUTINE DETERMINES   * 25800020
*   IF THE MESSAGE IS AN ON-LINE TEST REQUEST MESSAGE.  BEFORE        * 25900020
*   DOING SO,  THE LCB IS EXAMINED FOR A STOPLINE REQUEST CURRENTLY   * 26000020
*   PENDING ON THIS LINE.  IF SO,  THE ON-LINE TEST REQUEST DETER--   * 26100020
*   MINATION IS BYPASSED AND CONTROL PASSES TO THE EXIT SUBROUTINE.   * 26200020
*                                                                     * 26300020
*     IF THE MESSAGE IS A VALID ON-LINE TEST REQUEST, THE BUFFER IS   * 26400022
*     POSTED TO THE ON-LINE TEST QCB VIA A BRANCH TO THE DISPATCHER   * 26700022
*     (DSPPOST).  IF THE TEST REQUEST CANNOT BE HONORED, AN ERROR IS  * 27000022
*     SET IN THE SCB AND CONTROL PASSED TO THE EXIT SUBROUTINE.       * 27300022
*                                                                     * 27700020
*   TEXT PROCESSING,  INPUT --                                        * 27800020
*     THE FOLLOWING FIELDS ARE INITIALIZED-                           * 27900022
*         PRFSRCE  --  ORIGIN FROM LCBTTCIN                           * 28200022
*         LCBISZE --  NUMBER OF RESERVES FROM DCBRESER+1              * 28500022
*         PRFSCAN  --  SCAN POINTER OFFSET TO FIRST DATA BYTE-1       * 28800022
*     CONTROL PASSES TO THE EXIT SUBROUTINE                           * 29100022
*                                                                     * 29500020
*   HEADER PROCESSING,  OUTPUT --                                     * 29600020
*   NORMALLY THE FEFO POINTER IN THE DESTINATION QCB (QCBFFEFO) IS    * 29700020
*   UPDATED FROM THE FEFO POINTER IN THE SCB (SCBFEFO)  AND THE       * 29800020
*   'CURRENTLY SENDING' FLAG IN THE QCB IS TURNED OFF.  THIS IS NOT   * 29900020
*   DONE (1) IF THE DESTINATION IS IN LOCK MODE,  (2) IF THE LCB IS   * 30000020
*   IN INITIATE MODE,  OR (3) IF THE BUFFER IS A ZERO-LENGTH BUFFER   * 30100020
*   AND THE SEND ERROR IS A TEXT TRANSFER ERROR.                      * 30200020
*                                                                     * 30300020
*   IF THE DESTINATION IS IN LOCK MODE,  THE SUBROUTINE TESTS IF      * 30400020
*   BOTH THE LOCK AND EXTENDED LOCK BITS IN THE SCB ARE ON AND,  IF   * 30500020
*   SO,  TURNS THEM BOTH OFF.                                         * 30600020
*                                                                     * 30700020
*   THE NUMBER OF RESERVE CHARACTERS IN THE BUFFER IS ACCESSED FROM   * 30800020
*   THE PREFIX SCAN POINTER FIELD (PRFSCAN) AND SET IN THE LCB        * 30900020
*   (LCBISZE).  IF THIS IS A ZERO-LENGTH BUFFER,  LCBISZE IS SET TO   * 31000020
*   ZERO.                                                             * 31100020
*                                                                     * 31200020
*   THE SCAN POINTER IS INITIALIZED TO POINT TO THE LAST BYTE OF      * 31300020
*   THE PREFIX OR,  IF RESERVE CHARACTERS ARE PRESENT,  TO THE LAST   * 31400020
*   RESERVE CHARACTER.                                                * 31500020
*                                                                     * 31600020
*   IF THIS IS A ZERO-LENGTH BUFFER,  CONTROL PASSES TO THE NORMAL    * 31700020
*   EXIT SUBROUTINE.  OTHERWISE THE ADDRESS OF THE TERMINAL TABLE     * 31800020
*   ENTRY FOR THE DESTINATION IS ACCESSED VIA A LINK TO THE TNT       * 31900020
*   CODE (AVTRNMPT) AND THE OUTPUT SEQUENCE NUMBER IS INCREMENTED     * 32000020
*   BY ONE.  CONTROL THEN PASSES TO THE NORMAL EXIT SUBROUTINE.       * 32100020
*                                                                     * 32200020
*   TEXT PROCESSING,  OUTPUT --                                       * 32300020
*   THE RESERVE CHARACTERS COUNT IN THE LCB IS SET TO ZERO.  THE      * 32400020
*   SCAN POINTER IS INITIALIZED TO POINT TO THE LAST BYTE IN THE      * 32500020
*   PREFIX.  CONTROL PASSES TO THE TEXT-PROCESSING-INPUT SUBROUTINE   * 32600020
*   TO TEST FOR A ZERO-LENGTH BUFFER.                                 * 32700020
*                                                                     * 32800020
*   EXIT SUBROUTINE --                                                * 32900020
*   ON NORMAL ENTRY,  REGISTER 0 IS SET TO ZERO.  ON AN MBH ENTRY,    * 33000020
*   REGISTER 0 HAS ALREADY BEEN SET TO A NEGATIVE VALUE AND IS NOT    * 33100020
*   CHANGED.                                                          * 33200020
*                                                                     * 33300020
*   A VALUE OF X'1000' (4096 DECIMAL) IS SET IN REGISTER 2.  THE      * 33400020
*   ENTRY ADDRESS OF THE MESSAGE HANDLER IS COMPUTED.  REGISTER 0     * 33500020
*   IS THEN TESTED AND,  IF IT IS NEGATIVE,  ENTRY IS MADE TO THE     * 33600020
*   MESSAGE HANDLER WITH THE NEGATIVE CONDITION CODE (I.E.,  CONDI-   * 33700020
*   CODE OF 4).  OTHERWISE THE LCB IS TESTED TO DETERMINE IF THE      * 33800020
*   LINE IS SENDING OR RECEIVING AND THE RESULTING CONDITION CODE     * 33900020
*   IS PASSED TO THE MESSAGE HANDLER (SEND BIT ON = CONDITION CODE    * 34000020
*   OF 1,  SEND BIT OFF = 8).                                         * 34100020
*                                                                     * 34200020
*ENTRY POINTS --                                                      * 34300020
*       'IEDQAA01' TO INITIALIZE FOR PROCESSING A BUFFER THROUGH      * 34400020
*   THE MESSAGE HANDLER.  ENTRY IS FROM THE DISPATCHER VIA A POST     * 34500020
*   OF A BUFFER TO THE STARTMH QCB.                                   * 34600020
*                                                                     * 34700020
*INPUT --                                                             * 34800020
*   REGISTER 1 -- THE ADDRESS OF THE BUFFER TO BE PROCESSED           * 34900020
*                                                                     * 35000020
*   REGISTER 7 - THE ADDRESS OF THE STARTMH QCB                       * 35100020
*                                                                     * 35200020
*   REGISTER 13 - THE ADDRESS OF THE SAVE AREA FOR THE SUBTASK,       * 35300020
*   USED AS A BASE FOR AVT ADDRESSABILITY.                            * 35400020
*                                                                     * 35500020
*   REGISTER 15 - ENTRY POINT ADDRESS INTO THE STARTMH SUBTASK        * 35600020
*                                                                     * 35700020
*OUTPUT --                                                            * 35800020
*   REGISTER 2 - INCREMENT VALUE OF X'1000' USED FOR MULTIPLE         * 35900020
*   BASE REGISTER SUPPORT                                             * 36000020
*                                                                     * 36100020
*   REGISTER 12 - BASE REGISTER FOR THE MESSAGE HANDLER               * 36200020
*                                                                     * 36300020
*   CONDITION CODE - SET TO 4 FOR MULTIPLE-BUFFER HEADER RE-ENTRY,    * 36400020
*   1 FOR NORMAL RECEIVE PROCESSING,  OR 8 FOR NORMAL SEND            * 36500020
*   PROCESSING                                                        * 36600020
*                                                                     * 36700020
*EXTERNAL REFERENCES -                                                * 36800020
*   'IEDQAI' - SCAN ROUTINE                                           * 36900020
*                                                                     * 37000020
*   'IEDQAW' - TRANSLATE ROUTINE.                                     * 37100020
*                                                                     * 37200020
*   AVTRNMPT - TNT CODE                                               * 37300020
*                                                                     * 37400020
*   AVT - ADDRESS VECTOR TABLE.                                       * 37500020
*                                                                     * 37600020
*   BUFFER CURRENTLY BEING PROCESSED.                                 * 37700020
*                                                                     * 37800020
*   SCB - THE STATION CONTROL BLOCK FOR THE CURRENT STATION.          * 37900020
*                                                                     * 38000020
*   TERMINAL TABLE ENTRY                                              * 38100020
*                                                                     * 38200020
*   LCB - THE LINE CONTROL BLOCK.                                     * 38300020
*                                                                     * 38400020
*   MESSAGE HANDLER VCON TABLE (AVTMSGS).                             * 38500020
*                                                                     * 38600020
*   DCB - THE DATA CONTROL BLOCK.                                     * 38700020
*   SCT - SPECIAL CHARACTERS TABLE.                                   * 38800020
*                                                                     * 38900020
*                                                                     * 39000020
*EXITS,  NORMAL -- ENTRY IS MADE TO THE MESSAGE HANDLER.                39100020
*                                                                     * 39200020
*EXITS,  ERROR -- N/A.                                                * 39300020
*                                                                     * 39400020
*TABLES/WORK AREAS -- N/A.                                            * 39500020
*                                                                     * 39600020
*ATTRIBUTES -- SERIALLY REUSABLE,  REFRESHABLE,  ENABLED,             * 39700020
*   RESIDENT,  PROBLEM PROGRAM MODE.                                  * 39800020
*                                                                     * 39900020
*                                                                     * 40000020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN        * 40100020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 40200020
*                                                                     * 40300020
*********************************************************************** 40400020
.A2      ANOP                                                           40500020
         EJECT                                                          40600020
********* REGISTER EQUATES *********                                    40700020
         SPACE                                                          40800020
R0       EQU   0                        WORK REGISTER                   40900020
         SPACE                                                          41000020
R1       EQU   1                        PARAMETER LIST                  41100020
         SPACE                                                          41200020
RWORK2   EQU   2                        WORK REGISTER                   41300020
         SPACE                                                          41400020
RSCB     EQU   3                        SCB ADDRESS                     41500020
         SPACE                                                          41600020
RLCB     EQU   4                        LCB ADDRESS                     41700020
         SPACE                                                          41800020
RUCB5    EQU   5                        ADDRESS OF UCB                  41900020
RWORK5   EQU   5                        WORK REGISTER            S99528 41950022
         SPACE                                                          42000020
RPREFIX  EQU   6                        BUFFER ADDRESS                  42100020
         SPACE                                                          42200020
RQCB7    EQU   7                        ADDRESS OF STARTMH QCB          42300020
         SPACE                                                          42400020
RSCT8    EQU   8                        SPECIAL CHARS TABLE ADDRESS     42500020
         SPACE                                                          42600020
R9       EQU   9                        WORK REGISTER               TSO 42700020
RTQCB    EQU   9                        ADDR. OF TERMINAL'S QCB. S22029 42750022
         SPACE                                                          42800020
RRET10   EQU   10                       F.E. RETURN REGISTER            42900020
RDCB     EQU   10                       DCB ADDRESS                     43000020
RERB     EQU   10                       ERB ADDRESS              S99528 43050022
         SPACE                                                          43100020
RDISP    EQU   11                       DISPATCHER ADDRESS              43200020
         SPACE                                                          43300020
RBASE    EQU   12                       BASE OF ROUTINE                 43400020
         SPACE                                                          43500020
R13      EQU   13                       SAVE AREA                       43600020
         SPACE                                                          43700020
R14      EQU   14                       RETURN ADDRESS                  43800020
         SPACE                                                          43900020
R15      EQU   15                       ENTRY POINT                     44000020
         SPACE                                                          44100020
RAVT     EQU   9                                                 S22025 44150022
********* OTHER EQUATES *********                                       44200020
         SPACE                                                          44300020
ZERO     EQU   0                        CONSTANT DISPLACEMENT    S99528 44350022
ONE      EQU   1                        BYTE OFFSET                     44400020
TWO      EQU   2                        MOVE LENGTH FOR AN OFFSET       44500020
THREE    EQU   3                        MOVE LENGTH FOR AN ADDRESS      44600020
FOUR     EQU   4                        WORK OFFSET                     44700020
FIVE     EQU   5                        CONSTANT DISPLACEMENT    S99528 44720022
CVTOFF   EQU   16                       OFFSET TO CVT            S22025 44750022
         SPACE                                                          44800020
SCTEOA   EQU   1                        OFFSET TO EOA OFFSET            44900020
SCTOLT   EQU   13                       OFFSET TO OLT OFFSET            45000020
SCTCANCL EQU   27                       OFFSET TO OLT CANCEL OFFSET     45100020
         SPACE                                                          45200020
SSOLTLEN EQU   6                        LNG OF START/STOP OLT    S22025 45300022
BSOLTLEN EQU   2                        LNG OF BISYNC OLT STRING        45350020
SSTOTLEN EQU   14                                                       45360020
CANLEN   EQU   7                        LNG OF OLT CANCEL STRING        45370020
         SPACE                                                          45400020
POSTPEND EQU   X'D0'                    POST PENDING FLAGS              45500020
         SPACE                                                          45600020
PARMLEN  EQU   8                        LENGTH OF STARTMH PARM LIST     45700020
         SPACE                                                          45800020
NOSTARTL EQU   X'F1'                    LCB SETTING TO PREVENT          45900020
*                                         ISSUANCE OF STARTLINE         46000020
         SPACE                                                          46100020
TPDEVICE EQU   X'40'                    DEVICE CLASS = TP               46200020
IBM1030  EQU   X'21'                    DEVICE TYPE = IBM 1030          46300020
IBM2260R EQU   X'81'                    DEVICE TYPE = IBM 2260R         46400020
LGB      EQU   X'80'                    LINE GROUP BLOCK - 3705  S22024 46450022
         SPACE                                                          46500020
LMDSTCB  EQU   X'0A'                    LMD FLAG                 S22025 46530022
         SPACE                                                          46560022
MINUS    EQU   4                        CONDITION CODE: NEGATIVE        46600020
NOTON    EQU   14                       CONDITION CODE: NOT ON          46700020
SEVEN    EQU   7                        CONDITION CODE          SA52512 46730022
SCTEOT   EQU   20                       EOT INDEX OFFSET IN SCT SA52512 46760022
LASTNOFF EQU   X'04'                    FLAG SET BY RP WHEN     SA60343 46763005
*                                       SETTING A ZARO FEFO PRT SA60343 46766005
RNKEY    EQU   X'14'                    PRFKEY SETTING FOR TOTE  S22024 46770022
*                                         INDICATING MULTIPLE    S22024 46780022
*                                         BUFFER FROM 3705       S22024 46790022
         EJECT                                                          46800020
         DC    AL1(DSPMCPL2)            STCB                            46900020
         DC    AL1(0)                                                   47000020
         SPACE                                                          47100020
         USING IEDQAA01,R15                                             47200020
         USING AVTSAVE2,R13                                             47300020
         SPACE                                                          47400020
IEDQAA01 EQU   *                                                        47500020
         AIF   ('&X' NE 'TSO').A8                                       47700020
IEDAYR   IEDHJN STARTMH .               MODULE ID AND DATE       S22025 47800022
         AGO   .A9                                                      47900020
.A8      ANOP                                                           48000020
IEDQAA   IEDHJN STARTMH .               MODULE ID AND DATE       S22025 48100022
.A9      ANOP                                                           48200020
         TM    AVTAFE30,AVTEFF          IS DUMP REQUESTED               48700020
         BZ    SETBASE                  NO, GO SET NEW BASE             48800020
         SPACE                                                          48900020
         L     RWORK2,AVTAFE30          YES, GET ROUTINE ADDRESS        49000020
         BALR  RRET10,RWORK2            LINK TO IT                      49100020
         SPACE                                                          49200020
SETBASE  EQU   *                                                        49300020
         DROP  R15                                                      49400020
         LR    RBASE,R15                                                49500020
         USING IEDQAA01,RBASE                                           49600020
         ST    R1,AVTADBUF              SET BUFFER ADDRESS              49700020
         LR    RPREFIX,R1               SAVE BUFFER ADDRESS             49800020
         USING IEDQPRF,RPREFIX                                          49900020
         L     RLCB,PRFLCB-1            LCB ADDRESS                     50100020
         USING IEDQLCB,RLCB             ESTABLISH ADDRESSABILITY        50200020
         L     RSCB,LCBSCBA-1           SCB ADDRESS                     50300020
         USING IEDQSCB,RSCB             ESTABLISH ADDRESSABILITY        50400020
         L     RDCB,LCBDCBPT            GET DCB ADDRESS FROM LCB        50500020
         USING IHADCB,RDCB                                              50600020
         SPACE                                                          50700020
PFXSELEC EQU   *                                                        50800020
         AIF   ('&X' NE 'TSO').A3                                       50900020
         TM    LCBSTATE,LCBSENDN        SEND OPERATION           S22029 50910022
         BZ    TSCHK                    NO BRANCH                S22029 50920022
         L     R15,SCBDESTQ-1           GET DEST QCB ADDRESS     S22029 50930022
         TM    QCBFLAG-IEDQQCB(R15),QCBPROC IS THIS A PROCESS ENTS22029 50940022
         BO    TSO1                     YES, BRANCH              S22029 50950022
TSCHK    EQU   *                                                 S22029 50960022
         SR    R15,R15                  CLEAR REGISTER           S22029 50970022
         TM    LCBTSOB,LCBTSBUF         IS A TIME-SHARING        S22029 51000022
*                                       TERMINAL ON THIS LINE    S22029 51050022
         BZ    TSO1                     NO. CONTINUE MH FLOW     S22029 51100022
         OI    PRFSTAT1,PRFTSMSG        FLAG TIME-SHARING MSG    S22029 51150022
         SPACE                                                          51200020
         STC   R15,LCBISZE              ZERO OUT IDLES COUNT        TSO 51300020
         SPACE                                                          51400020
TSO1     EQU   *                                                    TSO 51500020
.A3      ANOP                                                           51600020
         SR    R15,R15                  CLEAR REGISTER           S22029 51650022
         TM    PRFSTAT1,PRFNHDRN        TEST IF HEADER OR TEXT          51700020
         BO    TEXT                     TEXT,  GO PROCESS               51800020
*                                       HEADER,  FALL THROUGH           51900020
         SPACE                                                          52000020
HEADER   EQU   *                                                        52100020
         TM    LCBSTATE,LCBSENDN        TEST IF SEND OR RECEIVE         52200020
         BNO   HDRRCV                   RECEIVE, GO PROCESS             52300020
*                                       SEND, FALL THROUGH              52400020
         EJECT                                                          52500020
HDRSEND  EQU   *                                                        52600020
         AIF   ('&X' NE 'TSO').A4                                       52700020
         TM    PRFSTAT1,PRFTSMSG .      IS IT A TS MESSAGE       S22029 52800022
         BO    EXIT                     BRANCH ON YES TO EXIT       TSO 52900020
         SPACE                                                          53000020
         SPACE                                                          53200020
.A4      ANOP                                                           53300020
         TM    PRFSTAT1,PRFCNCLN        IS THIS A RECALLED BUFFER       53400020
         BO    COMPIDLS                 YES, DON'T UPDATE FEFO          53500020
         SPACE                                                          53600020
         SR    R0,R0 .                  CLEAR FOR INSERT         S22025 55600022
         IC    R0,SCBPRI                GET INDEX TO PRIORITY QCB       55700020
         LA    R1,QCBPSIZE              GET SIZE OF PRIORITY QCB        55800020
         MR    R0,R0                    MULTIPLY TO GET OFFSET          55900020
         L     RWORK2,SCBDESTQ-1        GET ADDRESS OF MASTER QCB       56000020
         USING IEDQQCB,RWORK2                                           56100020
         LA    R1,QCBMSIZE(RWORK2,R1)   GET ADDR OF PRIORITY QCB        56400020
         USING IEDQPQCB,R1                                              56500020
         LA    RWORK2,SCBSCHDR          ASSUME FEFO ADDR IN SCB SA52971 56506022
         TM    SCBSCHDR+L'SCBSCHDR-1,CPBQTYPE CORE COPY OF DISK SA52971 56512022
*                                         BACKUP                SA52971 56518022
         BNZ   MOVEFEFO                 NO, GOT IT              SA52971 56524022
         L     RWORK2,SCBSCHDR-1        POINT TO QUEUED HEADER  SA52971 56530022
         LA    RWORK2,PRFCRCD-IEDQPRF(,RWORK2) POINT TO DISK ADRSA52971 56536022
MOVEFEFO EQU   *                                                SA52971 56542022
         CLC   AVTEZERO(3,RWORK2),QCBFFEFO IS IT TOP ON QUEUE   SA52971 56548022
         BNE   COMPIDLS                 NO, DON'T RESET         SA52971 56554022
         NC    QCBINTFF(3),QCBINTFF     IS QUEUE HELD           SA52971 56560022
         BNZ   JUSTPVF                  YES, DON'T UPDATE PFEFO SA52971 56566022
         MVC   QCBPFEFO(3),QCBPREVF     SHUFFLE TO LAST SRVCD   SA52971 56572022
*                                         MESSAGE               SA52971 56578022
         MVC   QCBPREVF(3),QCBFFEFO     KEEP POINTER TO THIS MSGSA52971 56584022
JUSTPVF  EQU   *                                                SA52971 56590022
         MVC   QCBFFEFO(THREE),SCBFEFO  UPDATE FEFO POINTER             56600020
         TM    QCBFFEFO+L'QCBFFEFO-1,CPBQTYPE                   SA60343 56607005
*              ARE THE FLAGS FOR DISK QUEUEING ON               SA60343 56614005
         BNZ   COMPIDLS                 BR IS NOT SET           SA60343 56621005
         NI    QCBFFEFO+L'QCBFFEFO-1,X'FF'-LASTNOFF             SA60343 56628005
*              RESET THE 'DO NOT UPDATE' FLAG SET BY RP FOR     SA60343 56635005
*              FA WHEN REMOVING THE LAST FEFO MESSAGE           SA60343 56642005
         DROP  RWORK2                                            S22029 56650022
         SPACE                                                          56700020
COMPIDLS EQU   *                                                        56800020
         SR    RWORK2,RWORK2 .           SET IDLES CNT TO ZERO   S22025 56900022
         CH    RWORK2,PRFSIZE           ZERO-LENGTH BUFFER              57000020
         BE    STORIDLS                 YES, LEAVE IDLES CT ZERO        57100020
         SPACE                                                          57200020
         IC    RWORK2,PRFSCAN+1   NO, GET IDLES CT FROM BFR             57300020
         SPACE                                                          57400020
STORIDLS EQU   *                                                        57500020
         STC   RWORK2,LCBISZE           INITIALIZE LCB RESERVE CT       57600020
         LA    RWORK2,AVTHDRSZ(,RWORK2) ADD SIZE OF HEADER PREFIX       57700020
         SPACE                                                          58400020
         LH    R1,PRFDEST               GET DESTINATION KEY             58500020
         N     R1,AVTCLRHI                                              58600020
         L     R15,AVTRNMPT             GET ADDRESS OF TNT CODE         58700020
         BALR  R14,R15                  LINK TO GET ETRM ENTRY ADDR     58800020
         SPACE                                                          58900020
         USING IEDQTRM,R1                                               59000020
         SR    R9,R9                    CLEAR REG                S22025 59007022
         IC    R9,TRMSTATE              GET STATUS BYTE          S22025 59014022
         SRL   R9,FOUR                  SHIFT OUT OPTIONS        S22025 59021022
         CH    R9,AVTHA3                PROCESS SPEC DATE=YES    S22025 59028022
         BNE   NODATE                   NO, SCAN OK              S22025 59035022
         LA    RWORK2,PARMLEN(RWORK2)   BUMP SCAN FOR DATE/TIME  S22025 59042022
NODATE   EQU   *                                                 S22025 59049022
         STH   RWORK2,PRFSCAN           INITIALIZE SCAN          S22025 59056022
         TM    PRFSTAT1,PRFCNCLN        RECALLED                 S22025 59063022
         BO    EXIT                     YES, DON'T UPDATE SEQ OUTS22025 59070022
         NC    SCBOSEQ(2),SCBOSEQ       HAS SEQ OUT BEEN  UPDATE S22025 59077022
         BNZ   EXIT                     BRANCH IF YES            S22025 59084022
         LH    RWORK2,TRMOUTSQ          GET OUTPUT SEQUENCE NUMBER      59100020
         STH   RWORK2,SCBOSEQ           PASS IN SCB                     59200020
         LA    RWORK2,ONE(,RWORK2)      INCREMENT BY ONE                59300020
         CH    RWORK2,CONMAX            IS MAXIMUM COUNT EXCEEDED       59400020
         BNH   UPCOUNT                  NO, PUT BACK UPDATED COUNT      59500020
         SPACE                                                          59600020
         LA    RWORK2,ONE               NO, RESET COUNT TO ONE          59700020
         SPACE                                                          59800020
UPCOUNT  EQU   *                                                        59900020
         STH   RWORK2,TRMOUTSQ          STORE IT BACK                   60000020
         B     EXIT                     RETURN TO MH                    60100020
         EJECT                                                          60200020
HDRRCV   EQU   *                                                        60300020
         TM    PRFSTAT1,PRFCNCLN        IS THIS A RECALLED BUFFER       60400020
         BO    TESTRAN                  YES, GO TRANSLATE & EXIT        60500020
         SPACE                                                          60600020
         SPACE                                                          60650053
         LH    RWORK2,LCBTTCIN          INITIALIZE ORIGIN FIELD         60700020
         STH   RWORK2,PRFSRCE             IN PREFIX FROM LCB            60800020
         SR    RWORK2,RWORK2 .          CLEAR FOR INSERT         S22025 61700022
         IC    RWORK2,LCBISZE           PICK UP RESERVE CT FROM LCB     61800020
         TM    SCBQTYPE,SCBBFMM .       IS THIS MID-OF-MSG       S22025 61833322
         BNO   NOTLMD .                 NO, CONTINUE AS HEADER   S22025 61833622
         MVC   SCBDEOB+1(3),AVTADBUF+1  SET DEOB FOR THE CASE OF S22025 61833722
*                                         A DE-BLOCKED HEADER    S22025 61833822
         NI    SCBQTYPE,X'FF'-SCBBFMM . TURN OFF MID-OF-MSG      S22025 61833922
         OI    PRFSTAT1,PRFNHDRN .      SET AS TEXT BUFFER       S22025 61834222
         OI    PRFTIC,PRFBFMM .         SET AS HDR CHGD TO TEXT  S22025 61834322
         LA    RWORK2,AVTHDRSZ-AVTTXTSZ(,RWORK2)   ADD TO ISIZE  S22025 61834522
         B     REALTEXT .               BRANCH TO TREAT AS TEXT  S22025 61834822
         SPACE 1                                                 S22025 61835122
NOTLMD   EQU   *                                                 S22025 61835422
         TM    PRFTIC,PRFEOMSG          TEMPORARY END OF MSG    SA62383 61835505
         BNO   SKIPMM                   BR YES                  SA62383 61835605
         OI    SCBQTYPE,SCBBFMM         SET MIDDLE OF MESSAGE   SA62383 61835705
SKIPMM   EQU   *                                                SA62383 61835805
         LA    RWORK2,AVTHDRSZ(,RWORK2) ADD LNG OF HDR PREFIX           61836020
         ST    R15,SCBPRI .             CLEAR SCB PRIORITY       S22025 61840022
         CH    RWORK2,PRFSIZE           IS THERE DATA IN BUFFER?        61842020
         BNE   SETSCPTR                 YES, GO SET SCAN PTR            61845020
         SPACE                                                          61848020
         STH   R15,PRFSIZE              NO, SET SIZE TO ZERO            61851020
         SPACE                                                          61854020
SETSCPTR EQU   *                                                        61857020
         AIF   ('&X' NE 'TSO').A3A                                      61860020
         TM    PRFSTAT1,PRFTSMSG .     IS IT A TS MESSAGE        S22029 61863022
         BO    EXIT                     BRANCH ON YES TO EXIT           61866020
         SPACE                                                          61869020
.A3A     ANOP                                                           61872020
         STH   RWORK2,PRFSCAN           INITIALIZE PREFIX SCAN PTR      61875020
         STH   R15,PRFISEQ              INITIALIZE SEQ IN TO ZERO       61878020
         L     RSCT8,DCBSCTAD-1         GET SPEC CHARS TABLE ADDR       62600020
         LA    RSCT8,0(RSCT8)                                           62700020
         LTR   RSCT8,RSCT8              IS THERE NO SPEC CHARS TBL      62800020
         BZ    EXIT                     NO, SOURCE IS APPLICATION       62900020
*                                         PROGRAM,  RETURN TO MH        63000020
         CH    R15,PRFSIZE .             IS THIS A ZERO BUFFER   S22025 63030022
         BE    EOTCODE .                BRANCH IF YES           SA54959 63060021
EOTCODE1 EQU   *                                                SA54959 63080021
         SPACE                                                          63100020
         L     R1,LCBSTCBA-1 .          LOAD ADDRESS OF STCB     S22025 63120022
         CLI   0(R1),LMDSTCB .          IS IT LMD STCB           S22025 63140022
         BE    EXIT .                   YES, RETURN              S22025 63160022
         SPACE                                                          63180022
         LR     R1,RWORK2 .             SET PARAMETER FOR SCAN   S22025 63200022
         L     RAVT,CVTOFF              GET ADDRESS OF CVT       S22025 63220022
         L     RAVT,AVTCVTPT(,RAVT)     FIND POINTER TO AVT      S22025 63240022
         L     RAVT,AVTEZERO(,RAVT)     GET ADDRESS OF AVT       S22025 63260022
         CLI   SCTEOA(RSCT8),AVTEZERO   IS AN EOA SEQ DEFINED           63300020
         BE    TESTLOCK                 NO, PROCEED                     63400020
         SPACE                                                          63450020
         TM    LCBTSOB,LCB2741N         IS SOURCE AN IBM 2741           63460020
         BO    TESTLOCK                 YES, NO EOA, BRANCH             63470020
         SPACE                                                          63500020
         LA     R15,SCTEOA .            GET EOA SEQUENCE OFFSET  S22025 63600022
         BAL   R14,LINKAL .             SCAN FOR EOA CHARACTER   S22025 63700022
         SPACE 1                                                 S22025 63800022
*   ON RETURN -- PRFDATOF WILL BE INCREMENTED IF EOA SEQUENCE    S22025 63900022
*            IS IN BUFFER                                        S22025 64000022
         SPACE 1                                                 S22025 64100022
         LR    R1,R0 .                  GET UPDATED SCAN OFFSET  S22025 64200022
         TM    DCBDSORG,LGB             IS BLOCK A DCB OR LGB    S22024 64300022
         BO    TESTLOCK                 BRANCH IF LGB            S22024 64400022
         L     RUCB5,DCBDEBAD           GET ADDRESS OF DEB FROM DCB     64500020
         USING DEBNMSUB,RUCB5                                           64600020
         L     RUCB5,DEBUCBAD           GET ADDRESS OF UCB FROM DEB     64700020
         USING UCBOB,RUCB5                                              64800020
         CLI   UCBTBYT3,TPDEVICE        IS THIS A TP DEVICE             64900020
         BNE   TESTLOCK                 NO, GO TEST FOR LOCK            65000020
         SPACE                                                          65100020
         IC    R15,UCBTBYT1             PICK UP MODEL BYTE              65200020
         STC   R15,AVTDOUBL             SET IT IN AVT WORK AREA         65300020
         MVZ   AVTDOUBL(ONE),UCBTBYT4   OVERLAY IT WITH ADAP BYTE       65400020
         CLI   AVTDOUBL,IBM1030         IS DEVICE AN IBM 1030           65500020
         BE    BUMPXTRA                 YES, BUMP SCAN ONE MORE         65600020
         SPACE                                                          65700020
         CLI   AVTDOUBL,IBM2260R        IS DEVICE IBM 2260 REMOTE       65800020
         BNE   TESTLOCK                 NO, GO TEST FOR LOCK            65900020
         SPACE                                                          66000020
BUMPXTRA EQU   *                                                        66100020
         LA    R1,ONE(,R1) .            UPDATE SCAN OFFSET       S22025 66200022
TESTLOCK EQU   *                                                        66600020
         TM    SCBSTATE,SCBLCK1N        TERMINAL IN LOCK MODE           66700020
         BNO   NOLOCK                  NO, BRANCH                       66800020
         SPACE                                                          66900020
         NI    LCBMSGFM,AVTEFF-LCBOLT   MAKE SURE OLT BIT IS OFF        67000020
         OI    PRFSTAT1,PRFLOCK         SET PREFIX LOCK BIT             67100020
         MVC   PRFDEST,LCBINSRC         GET INDEX IN TERMNAME TABLE     67200020
         MVI   LCBINSRC+2,POSTPEND      SET POST PENDING FLAGS          67300020
         LH    R1,PRFDEST                                               67400020
         N     R1,AVTCLRHI             SET UP FOR LINK TO TNT           67500020
         L     R15,AVTRNMPT                                             67600020
         BALR  R14,R15                 LINK TO GET TERM ENTRY ADDRESS   67700020
         SPACE                                                          67800020
         MVC   SCBDESTQ,TRMDESTQ        SET DEST QCB ADDRESS            67900020
         B     EXIT                     EXIT TO MH              S22025  68000022
         SPACE                                                          68005022
LOCKTEST EQU   *                                                SA52512 68010022
         TM    SCBSTATE,SCBLCK1N .      LOCK MODE               SA52512 68015022
         BNO   EXIT .                   NO, BRANCH              SA52512 68020022
         MVI   PRFSIZE+ONE,PRFSHDR+ONE-PRFSUNIT SET PRFSIZE     SA52512 68025022
         BAL   R14,EOTADDR              COMPUTE EOT ADDRESS     SA52512 68030022
         MVC   PRFSHDR(ONE),ONE(R1)     INSERT EOT IN BUFFER    SA52512 68035022
         MVI   LCBISZE,AVTEZERO .       CLEAR IDLES COUNT       SA52512 68040022
         B     TESTLOCK .               FINISH INQUIRY HANDLING SA52512 68045022
EOTADDR  EQU   *                                                SA52512 68050022
         L     RSCT8,DCBSCTAD-1         SPEC CHAR TABLE         SA52512 68055022
         SR    R1,R1                    CLEAR INDEX REGISTER    SA52512 68060022
         IC    R1,SCTEOT(RSCT8)         GET EOT INDEX           SA52512 68065022
         LA    R1,AVTEZERO(R1,RSCT8)    EOT ENTRY ADDRESS       SA52512 68070022
         CLI   AVTEZERO(R1),TWO         ETX/EOT                 SA52512 68075022
         BCR   SEVEN,R14                NO, RETURN              SA52512 68080022
         LA    R1,ONE(,R1)              BUMP PAST ETX           SA52512 68085022
         BR    R14                      RETURN                  SA52512 68090022
         SPACE                                                          68100020
NOLOCK   EQU   *                                                        68200020
         TM    LCBSTAT1,LCBOCNI         TEST FOR STOPLINE REQUEST       68300020
         BO    EXIT                     YES, EXIT TO MH NOW     S22025  68400022
         SPACE                                                          68500020
         TM    LCBSTAT2,LCBSYNC         IS THIS BISYNC LINE             68600020
         BNO   TOTESS .                 NO, CHECK FOR TOTE STRINGS22025 68700022
         TM    LCBMSGFM,LCBOLT .        YES, IS THIS OLT MESSAGE S22025 68710022
         BNO   EXIT .                   NO, EXIT TO MH           S22025 68720022
         LA    R1,BSOLTLEN(,R1) .       UPDATE SCAN PARAMETER    S22025 68730022
         B     LINKERST .               CHECK FOR ERRORS         S22025 68747022
         SPACE 1                                                 S22025 68750022
         SPACE                                                          68800020
TOTESS   EQU   *                                                        68900020
         CLI   SCTOLT(RSCT8),AVTEZERO   OLT SEQ SPECIFIED        A44861 68930021
         BE    EXIT                     BRANCH IF NO             S22025 68960022
         LA    R15,SCTOLT .             GET OLT SEQUENCE OFFSET  S22025 69000022
         BAL   R14,LINKAL .             LINK TO SCAN             S22025 69050022
         SPACE 1                                                 S22025 69100022
         LR     R1,R0 .                 GET OFFSET RETURNED      S22025 69150022
         SPACE                                                          69200020
         LTR   R15,R15                  TEST RETURN CODE                69300020
         BNZ   LINKERST                 PRESENT, TEST FOR ERRORS S99528 69400022
         SPACE                                                          69500020
         TM    LCBTSOB,LCB2741N         IS IT IBM 2741                  69600020
         BNO   EXIT .                   NO, NOT OLT, EXIT TO MH  S22025 69700022
         SPACE 1                                                 S22025 69800022
         LA    RWORK2,SSTOTLEN(,RWORK2) POINT TO 2D OLT STRING   S22025 69900022
         BAL   R14,LINKAL2 .            SCAN FOR 2D TOTE STRING  S22025 70000022
         SPACE                                                          70400020
         LR    R1,R0 .                  SAVE OFFSET RETURNED     S22025 70450022
         LTR   R15,R15                  TEST RETURN CODE                70500020
         BZ    EXIT .                                            S22025 70600022
         SPACE                                                          70700020
LINKERST EQU   *                                                 S22025 70860022
         CLI   AVTOLTST,AVTEZERO .      IS ON-LINE TEST IN SYSTEMS22025 70900022
         BE    OLTERROR .               NO, SET ERROR BIT        S22025 70950022
         TM    PRFSTAT1,PRFNLSTN  IS MESSAGE CONTAINED IN ONE    S99528 70980022
*                                   BUFFER?                      S99528 71010022
         BO    OLTPRFER                 NO GO SEE IF 3705 BUFFER S22024 71040022
         TM    AVTBIT3,AVTOLTBN         OLT MAXIMUM LOAD REACHED        71100020
         BO    OLTERROR                 YES, SET ERROR BIT              71200022
         SPACE                                                          71300020
         SPACE                                                          72200020
SSFLAG   EQU   *                                                        72300020
         LA    R15,AVTECD8              NO ERROR, SET BYTE FOR PFX      72400020
         TM    LCBSTAT2,LCBSYNC .       IS THIS A BISYNC LINE    S22025 72500022
         BNO   SETOTT .                 NO, FLAG IS SET CORRECTLYS22025 73400022
         LA    R15,AVTECD4              NO ERROR, SET BYTE FOR PREFIX   74400020
         NI    LCBMSGFM,AVTEFF-LCBOLT   TURN OFF ON-LINE TEST FLAG      74500020
         SPACE                                                          74600020
SETOTT   EQU   *                                                        74700020
         LA    RERB,LCBERB                     ERB ADDRESS       S99528 74704022
         TM    LCBERBST,LCBDLNKN        IS DLINK SWITCH SET      S99528 74708022
         BO    ERBFRE                   BRANCH NOT IN CHAIN      S99528 74712022
         LA    R1,AVTBFRTB-FOUR         BUFFER RETURN QCB        S99528 74716022
NEXT     EQU   *                                                 S99528 74728022
         LR    RWORK2,R1               SET TO NEXT ELEMENT       S99528 74732022
         L     R1,FOUR(ZERO,RWORK2)     FIRST/NEXT ELEMENT IN    S99528 74736022
*                                       CHAIN                    S99528 74740022
         LA    R1,ZERO(ZERO,R1)         CLEAR HIGH ORDER BYTE    S99528 74744022
         CLR   R1,RERB                  IS THIS THE ERB?         S99528 74748022
         BE    REMOVERB                 BR IF ERB FOUND          S99528 74752022
         C     R1,AVTDELAD              IS THIS THE DUMMY END    S99528 74756022
*                                       ELEMENT. IF YES,THIS     S99528 74760022
*                                       IS END OF THIS CHAIN     S99528 74764022
         BNE   NEXT                     BR NOT END OF CHAIN      S99528 74768022
         LA    R1,AVTREADY-FOUR         ADDRESS OF READY QUEUE   S99528 74772022
*                                        FOR LOOP                S99528 74776022
         B     NEXT                     SEARCH READY QUEUE      SA63640 74780005
REMOVERB EQU   *                                                 S99528 74784022
         MVC   FIVE(THREE,RWORK2),LCBERBLK REMOVE ERB           SA63640 74788005
         OI    LCBERBST,LCBDLNKN        SET ERB POSTABLE         S99528 74792022
ERBFRE   EQU   *                                                 S99528 74796022
         LA    RWORK2,AVTOLTQB          GET ADDRESS OF OLT QCB          74800020
*                               QUEUE POINTER                    S99528 74860022
         MVI   PRFPRI,PRIONLT           SET ON-LINE TEST PRIORITY       74900020
         ST    RWORK2,PRFRCB            SET IT IN THE BUFFER'S RECB     75000020
         STC   R15,PRFKEY               SET SOURCE BYTE IN PREFIX       75100020
         LR    R1,RPREFIX               PASS BUFFER ADDRESS             75200020
         MVI   LCBTSTSW,AVTEFF         SET NO SOURCE                    75500020
         OI    LCBSTAT2,LCBNEGRP       INDICATE NEG. RESP.              75600020
         USING IEDQDISP,RDISP                                           75700020
         B     DSPPOST                  EXIT TO POST BUFFER TO QCB      75800020
OLTPRFER EQU   *                                                 S22024 75810022
         CLI   LCBFLAG1,AVTEZERO        IS THIS A PLCB?          S22024 75820022
         BNE   OLTERROR                 NO, BYPASS 3705 CODE     S22024 75830022
         OI    LCBMSGFM,LCBOLT          SET ONLINE TEST BIT      S22024 75840022
         LA    R15,RNKEY                SET PRFKEY TO 3705       S22024 75850022
*                                         MULTIPLE BUFFER        S22024 75860022
         MVI   PRFSTAT1,AVTEZERO        SET BUFFER STATUS TO     S22024 75870022
*                                         HEADER-LAST            S22024 75880022
         B     SETOTT                   GO POST BUFFER TO TOTE   S22024 75890022
         SPACE                                                          75900020
OLTERROR EQU   *                                                        76700020
         OI    SCBERR2,SCBOLTR          SET OLT ERROR BIT IN SCB        76800020
         B     EXIT .                   EXIT TO MH               S22025 76900022
         SPACE 2                                                 S22025 77000022
LINKAL   EQU   *                                                 S22025 77100022
         SR    RWORK2,RWORK2 .          CLEAR FOR INSERT         S22025 77200022
         IC    RWORK2,AVTEZERO(R15,RSCT8)  PICK UP SEQ OFFSET    S22025 77300022
         LA    RWORK2,0(RWORK2,RSCT8) . GET ADDR OF STRING       S22025 77400022
LINKAL2  EQU   *                                                 S22025 77500022
         LR    R0,RWORK2 .              SET FOR SCAN ROUTING     S22025 77600022
         L     R15,AVTAL                LOAD SCAN ROUTINE ADDR   S22025 77700022
         BR    R15 .                                             S22025 77800022
         EJECT                                                          80600020
TEXT     EQU   *                                                        80700020
         TM    LCBSTATE,LCBSENDN       SEND OR RECEIVE          SA68025 80701056
         BO    TXTSEND                  SEND, NOT TOTE REQUEST  SA68025 80702056
         TM    LCBMSGFM,LCBOLT          IS THIS AN ONLINE TEST   S22024 80703022
*                                         TEXT BUFFER            S22024 80706022
         BNO   TXTRCV                   NO, NOT A TOTE BUFFER   SA68025 80709056
         LA    RWORK2,AVTBFRTB          GET ADDRESS OF BUFFER    S22024 80712022
*                                         RETURN QCB             S22024 80715022
         IC    RWORK5,SCBDESTQ-ONE      SAVE FLAG BYTE           S22024 80718022
         ST    RWORK2,SCBDESTQ-ONE      PUT QCB ADDRESS IN SCB   S22024 80721022
         STC   RWORK5,SCBDESTQ-ONE      RESTORE FLAG BYTE        S22024 80724022
         MVI   PRFPRI,PRIBFRTB          PUT IN PRIORITY          S22024 80727022
         TM    PRFSTAT1,PRFNLSTN        IS THIS THE LAST BUFFER? S22024 80730022
         BO    BUFRET                   NO, GO POST BUFFER TO    S22024 80733022
*                                         BUFFER RETURN          S22024 80736022
         NI    LCBMSGFM,AVTEFF-LCBOLT   TURN OFF ONLINE TEST BIT S22024 80739022
         LA    RWORK2,AVTINOUT          GET ADDR OF DUMMY IN/OUT S22024 80742022
         IC    RWORK5,SCBMACR-ONE       SAVE HIGH ORDER BYTE     S22024 80745022
         ST    RWORK2,SCBMACR-ONE       PLACE ADDRESS IN SCB     S22024 80748022
         STC   RWORK5,SCBMACR-ONE       RESTORE HIGH ORDER BYTE  S22024 80751022
         L     RWORK2,AVTMSGS-ONE       GET VCON TABLE ADDRESS   S22024 80754022
         L     RWORK2,AVTEZERO(RWORK2)  GET ADDRESS OF BD'S QCB  S22024 80757022
         MVI   PRFPRI,PRIDSPLB          SET LOW PRIORITY         S22024 80760022
BUFRET   EQU   *                                                 S22024 80763022
         ST    RWORK2,PRFQCBA-ONE       PUT QCB ADDR IN BUFFER   S22024 80766022
         LR    R1,RPREFIX               PUT ADDR OF BUFFER IN R1 S22024 80769022
         B     DSPPOST                  EXIT TO POST BUFFER TO   S22024 80772022
*                                         QCB                    S22024 80775022
         SPACE                                                          81000020
TXTSEND  EQU   *                                                        81100020
         AIF   ('&X' NE 'TSO').A6                                       81200020
         TM    PRFSTAT1,PRFTSMSG .      IS IT A TS MESSAGE       S22029 81300022
         BO    TESTRAN                  YES, GO TRANS AND EXIT      TSO 81400020
         SPACE                                                          81500020
         SPACE                                                          81700020
.A6      ANOP                                                           81800020
         MVI   LCBISZE,AVTEZERO         SET IDLES COUNT TO ZERO         81900020
         LA    RWORK2,AVTTXTSZ          GET SIZE OF TEXT PREFIX         82000020
         STH   RWORK2,PRFSCAN           INITIALIZE SCAN POINTER         82100020
         CH    R15,PRFSIZE              IS THIS A ZERO BFR      SA56222 82200000
         BE    EXIT                     IF 0 EXIT               SA56222 82203000
         B     TESTRAN1                 IF NOT 0 CONTINUE       SA56222 82206000
         SPACE                                                          82210022
CHKLOCK  EQU   *                                                SA52512 82220022
         TM    SCBSTATE,SCBLCK1N .      LOCK MODE               SA52512 82230022
         BNO   EXIT .                   NO, BRANCH              SA52512 82240022
         MVI   PRFSIZE+ONE,PRFSTXT+ONE-PRFSUNIT SET PRFSIZE     SA52512 82250022
         BAL   R14,EOTADDR              COMPUTE EOT ADDRESS     SA52512 82260022
         MVC   PRFSTXT(ONE),ONE(R1)     INSERT EOT IN BUFFER    SA52512 82270022
         MVI   LCBISZE,AVTEZERO .       CLEAR IDLES COUNT       SA52512 82280022
         B     EXIT .                   END TEXT PROCESSING     SA52512 82290022
         SPACE                                                          82300020
TXTRCV   EQU   *                                                        82400020
         LH    R0,LCBTTCIN              INITIALIZE ORIGIN FIELD SA61771 82401022
         STH   R0,PRFSRCE                 IN PREFIX FROM LCB    SA61771 82402022
         AIF   ('&X' NE 'TSO').A65                                M6673 82405020
         TM    PRFSTAT1,PRFTSMSG .      IS IT A TS MESSAGE       S22029 82410022
         BNO   TSTEXIT                  NO, GO CHECK LOGON EXIT   M6673 82420020
         SR    RWORK2,RWORK2            CLEAR WORK REGISTER       M6673 82430020
         IC    RWORK2,LCBISZE           GET NUMBER OF IDLES       M6673 82440020
         LA    RWORK2,AVTTXTSZ(,RWORK2) ADD TEST PREFIX LENGTH   S22029 82450022
         CH    RWORK2,PRFSIZE           CHECK BUFFER DATA LENGTH  M6673 82460020
         BNE   TESTRAN                  BR IF NOT EMPTY         SA61771 82470022
         STH   R15,PRFSIZE              ZERO PREFIX SIZE          M6673 82480020
TSTEXIT  EQU   *                                                  M6673 82490020
.A65     ANOP                                                     M6673 82495020
         SPACE                                                          82700020
         TM    PRFSTAT1,PRFCNCLN        IS THIS A RECALLED BUFFER       82800020
         BO    TESTRAN                  YES, DON'T CHANGE SCAN          82900020
         SPACE                                                          83000020
         SR    RWORK2,RWORK2            (CLEAR FOR INSERT)              86100020
         IC    RWORK2,DCBRESER+1        PICK UP NO. RESERVE CHARS       86200020
REALTEXT EQU   *                                                 S21101 86298020
         TM    PRFTIC,PRFEOMSG          TEMP END OF MESSAGE      S22025 86298422
         BZ    NOTEOM                   BRANCH NO                S22025 86298622
*                                                                S22025 86298822
         OI    SCBQTYPE,SCBBFMM         INDICATE MIDDLE  OF MSG  S22025 86299022
NOTEOM   EQU   *                                                 S22025 86299222
         STC   RWORK2,LCBISZE           SET COUNT IN LCB                86300020
NOIDLS2  EQU   *                                                 S22024 86350022
         LA    RWORK2,AVTTXTSZ(,RWORK2) ADD SIZE OF TEXT PREFIX         86400020
         STH   RWORK2,PRFSCAN           INITIALIZE SCAN PTR             86500020
         CH    RWORK2,PRFSIZE                                           86600020
         BNE   TESTRAN                                                  86700020
         XC    PRFSIZE(2),PRFSIZE                                       86800020
         B     EOTCODE3 .               HANDLE ZERO LEN BFR     SA54959 86850021
         SPACE                                                          86900020
TESTRAN  EQU   *                                                        87000020
         CLC   AVTFZERO(TWO),PRFSIZE    ZERO LENGTH BUFFER ?     S22024 87100022
         BE    CHKLOCK .                YES, BRANCH             SA52512 87200022
TESTRAN1 EQU   *                                                SA56222 87210000
         TM    LCBSTATE,LCBSENDN .      IS LINE SENDING          S22025 87220022
         BNO   EXIT .                   IF RECEIVING, INHDR      S22025 87240022
*                                         WILL MAKE TESTS        S22025 87260022
         SPACE                                                          87300020
         TM    SCBSTATE,SCBCODE         IS TRANSLATION REQUESTED        87400020
         BNO   TESTMBH                  NO, GO TEST FOR MBH             87500020
         SPACE                                                          87600020
         L     R1,SCBTRANS-1            YES, GET CODE PARM LIST         87700020
         L     R15,AVTUI                GET USER INTERFACE ADDRESS      87800020
         BALR  R14,R15                  LINK TO TRANSLATE BUFFER        87900020
         SPACE                                                          88000020
TESTMBH  EQU   *                                                        88100020
         L     RWORK2,SCBMBHEN-1        GET MBH PARM LIST ADDR   A59509 88200022
         CLC   AVTINOUT,AVTEZERO(RWORK2) DOES IT POINT TO '0100' A59509 88300022
         BE    EXIT                     IT DOES, NO MBH, EXIT           88400020
         SPACE                                                          88500020
         LNR   RWORK5,RWORK2            SET NEG REGISTER AS FLAG A59509 88700022
         BCT   RWORK2,MBHEXIT           DECR TO CLEAR FLAG BIT   A59509 88800022
*                                         AND EXIT TO RE-ENTER RTN      88900020
         EJECT                                                          89000020
         SPACE                                                          89300020
EXIT     EQU   *                                                        89400020
         SR    RWORK5,RWORK5            ZERO FLAG REG - NO MBH   A59509 89500022
         SPACE                                                          89600020
MBHEXIT  EQU   *                                                        89700020
         AIF   ('&X' NE 'TSO').MIX0500                           S22029 89704022
         CLC   ONE(THREE,RQCB7),AVTFZERO ALTMH PRESENT           S22029 89708022
         BE    NOALTMH .                NO CONTINUE              S22029 89712022
         USING IEDQQCB,RTQCB                                     S22029 89716022
         SR    RTQCB,RTQCB                                       S22029 89720022
         CLI   LCBFLAG1,AVTEZERO        IS THIS 3705 PLCB        S22024 89721022
         BE    NOTDIAL                  BRANCH ON YES            S22024 89722022
         TM    LCBSTAT2,LCBDIAL .      IS IT A DIAL LINE         S22029 89724022
         BZ    NOTDIAL .                NO  BRANCH               S22029 89728022
         LH    R1,LCBLNENT .            OFFSET TO LINE ENTRY     S22029 89732022
         B     TERMENT .                TO GET TERM ENTRY        S22029 89736022
NOTDIAL  EQU   * .                                               S22029 89740022
         LH    R1,LCBTTCIN .            INDEX TO CURRENT TERM    S22029 89744022
TERMENT  EQU   * .                                               S22029 89748022
         N     R1,AVTCLRHI              CLEAR HIGH AND TEST      A59509 89752022
         BZ    NOALTMH                  NO.CANNOT LOCATE ALTMH   S22029 89756022
         L     R15,AVTRNMPT .           ADDRESS OF TERMNAME TBL  S22029 89760022
         BALR  R14,R15 .                GET TERMINAL ENTRY       S22029 89764022
         USING IEDQTRM,R1 .                                      S22029 89768022
         L     RTQCB,TRMDESTQ-1         GET DESTINATION ADDRESS  S22029 89772022
         TM    QCBDSFLG,QCBALTMH .      ALTERNATE MH             S22029 89776022
         BZ    NOALTMH .                NO CONTINUE              S22029 89780022
         L     RQCB7,AVTEZERO(,RQCB7)   GET ALTMH                S22029 89784022
NOALTMH  EQU   * .                                               S22029 89788022
.MIX0500 ANOP                                                    S22029 89792022
         LR    R1,RWORK2                SET MBH PARAMETER IN     A59509 89794022
*                                        CORRECT REG FOR EXIT    A59509 89796022
         L     R15,AVTUI                GET USER INTERFACE ADDR  A59509 89798022
         LH    RWORK2,CONBASE           SET INCR VALUE IF MULT BASE     89800020
         SR    RBASE,RBASE              (CLEAR FOR INSERT)              89900020
         IC    RBASE,PARMLEN(,RQCB7)    PICK UP LNG OF PARM LIST        90000020
         LA    RBASE,AVTEZERO(RQCB7,RBASE) GET 1ST INSTRUCTION ADDR     90100020
         LTR   RWORK5,RWORK5            MBH RE-ENTRY NEEDED      A59509 90200022
         BCR   MINUS,RBASE              YES, PASS MINUS TO MH           90300020
         SPACE                                                          90400020
         TM    LCBSTAT1,LCBSENDN        NO, TEST IF SENDING             90500020
         BR    RBASE                    ENTER MH, SELECT IN OR OUT      90600020
         EJECT                                                          90602021
EOTCODE  EQU   *                                                SA54959 90604021
         TM    SCBERR4,SCBTXTTN .       TEXT TRANSFER ERROR     SA54959 90606021
         BNO   LOCKTEST .               BRANCH IF NO            SA54959 90608021
EOTCODE3 EQU   *                                                SA54959 90610021
         STH   R15,PRFSIZE .            SET ZERO LENGTH         SA54959 90612021
         L     R15,DCBSCTAD-1 .         SPECIAL CHAR TABLE      SA54959 90614021
         SR    R1,R1 .                  CLEAR INDEX REGISTER    SA54959 90616021
         MVI   LCBISZE,AVTEZERO .       CLEAR IDLES COUNT       SA54959 90618021
         IC    R1,SCTEOT(R15) .         GET EOT INDEX           SA54959 90620021
         LA    R1,AVTEZERO(R1,R15) .    EOT ENTRY ADDRESS       SA54959 90622021
         CLI   AVTEZERO(R1),TWO .       ETX/EOT                 SA54959 90624021
         BNE   EOTCODE2 .               BRANCH IF NO            SA54959 90626021
         LA    R1,ONE(,R1) .            BUMP PAST ETX           SA54959 90628021
EOTCODE2 EQU   *                                                SA54959 90630021
         SR    R15,R15 .                CLEAR WORK REGISTER     SA54959 90632021
         TM    PRFSTAT1,PRFNHDRN .      HEADER BUFFER           SA54959 90634021
         BNO   EOTCODE4 .               BRANCH IF YES           SA54959 90636021
         MVC   PRFSTXT(ONE),ONE(R1) .   INSERT EOT IN BFR       SA54959 90638021
         MVI   PRFSIZE+ONE,PRFSTXT+ONE-PRFSUNIT SET PRFSIZE     SA54959 90640021
         B     TESTRAN .                CONTINUE PROCESSING     SA54959 90642021
EOTCODE4 EQU   *                                                SA54959 90644021
         TM    SCBSTATE,SCBLCK1N .      LOCK MODE               SA54959 90646021
         BNO   EOTCODE5 .               BRANCH IF NO            SA54959 90648021
         MVC   PRFSHDR(ONE),ONE(R1) .   INSERT EOT IN BFR       SA54959 90650021
         MVI   PRFSIZE+ONE,PRFSHDR+ONE-PRFSUNIT SET PRFSIZE     SA54959 90652021
         B     EOTCODE1 .               CONTINUE PROCESSING     SA54959 90654021
EOTCODE5 EQU   *                                                SA54959 90656021
         XC    SCBMRFSD(4),SCBMRFSD .   CLEAR MULTI ROUTE       SA54959 90658021
         LA    R1,AVTBFRTB .            BUFFER RETURN QUEUE     SA54959 90660021
         ST    R1,AVTDOUBL .            WORKAREA                SA54959 90662021
         MVC   SCBDESTQ(3),AVTDOUBL+1 . SET FOR BFR RETURN      SA54959 90664021
         B     EXIT .                   SCRAM                   SA54959 90666021
         SPACE                                                          90700020
********* CONSTANTS *********                                           90800020
         SPACE                                                          90900020
CONMAX   DC    H'9999'                  MAXIMUM SEQUENCE NUMBER         91000020
CONBASE  DC    H'4096'                  INCREMENT VALUE FOR             91100020
*                                         MULTIPLE BASE REGISTERS       91200020
         EJECT                                                          91300020
********* DSECTS *********                                              91400020
         SPACE                                                          91500020
         TAVTD                                                          91600020
         EJECT                                                          91700020
         DCBD  DSORG=TX                                                 91800020
         EJECT                                                          91900020
         TDEBD                                                          92000020
         EJECT                                                          92100020
         TDISPD                                                         92200020
         EJECT                                                          92300020
         TLCBD                                                          92400020
         EJECT                                                          92500020
         TPRFD                                                          92600020
         EJECT                                                          92700020
         TPRIOR                                                         92800020
         EJECT                                                          92900020
         TQCBD                                                          93000020
         EJECT                                                          93100020
         TSCBD                                                          93200020
CPBQTYPE EQU   X'03'                    RRN QUEUING MEDIA FLAGS SA52971 93250022
         EJECT                                                          93300020
         TTRMD                                                          93400020
         EJECT                                                          93500020
         IEFUCBOB                                                       93600020
         EJECT                                                          93630022
         TLGBD ,                                                 S22024 93660022
         SPACE                                                          93700020
         MEND                                                           93800020
