         MACRO                                                          00400020
&NAME    STABUILD &FLAG=,                                              X00800020
               &LIST=,                                                 X01200020
               &LISTNUM=,                                              X01600020
               &ADDR=,                                                 X02000020
               &CODE=,                                                 X02400020
               &RTN=,                                                  X02800020
               &NUM=,                                                  X03200020
               &TYPE=A,                                                X03250020
               &MF=                                                     03600020
         GBLA  &$PSEUDO(5)                                              04000020
         LCLA  &FNUM                                                    04400020
         LCLA  &FNUM1,&INCR                                             04800020
         LCLB  &F(8)                                                    05200020
.*                                                                      05210020
.* THIS MACRO BUILDS THE CONTROL BLOCK THAT IKJEHSIR WILL EXAMINE       05250020
.* TO DETERMINE WHAT SPECIFIC ABENDS AND/OR WHAT TYPES OF ABENDS        05300020
.* A CP WANTS TO HANDLE.                                                05350020
.*                                                                      05400020
.*  &FLAG IS THE FLAG(S) TO SET IN THE BLOCK, CAN BE ONE OR MORE        05450020
.*     OF THE FOLLOWING:                                                05550020
.*        ONE  SAYS ONLY ONE ABEND CODE TO BE HANDLED BY &RTN           05560020
.*        MUL  SAYS MULTIPLE ABENDS TO BE HANDLED BY &RTN, ALSO         05570020
.*             IMPLIES THAT &LIST EXISTS                                05580020
.*        ALL  SAYS THAT &RTN WILL HANDLE ALL ABEND CODES NOT           05590020
.*             SPECIFICALLY CALLED OUT BY A ONE OR MUL ENTRY            05592020
.*        NMSG TELLS IKJEHSIR THAT THE CP WANTS TO PUT OUT ITS          05594020
.*             OWN MESSAGE, AND THAT IKJEHSIR SHOULD NOT PUT            05594420
.*             OUT THE STANDARD MESSAGE.                                05594820
.*        USER SAYS THAT THE CODES ARE USER ABENDS                      05598020
.*        END  THIS SIGNIFIES THE END OF A TYPE OF CODE ENTRY,          05598420
.*             EITHER USER OR SYSTEM ABEND CODES                        05598820
.*  &LIST THIS IS THE ADDRESS OF THE AREA FOR A LIST OF CODES TO        05599220
.*        BE STORED IN BY THIS MACRO ON AN MF=E.  THE CODES (FROM       05599620
.*        &CODE) WILL BE STORED IN THE ORDER THAT THEY APPEAR IN        05599720
.*        THE &CODE=( ) PARAMETER                                       05599820
.*  &LISTNUM  ONLY VALID FOR AN MF=L FORM.  THIS IS THE NUMBER OF       05599920
.*        CODES THAT AN MF=E FORM WILL FILL-IN IN AN &LIST              05649920
.*  &ADDR  THIS IS THE ADDRESS OF THE MF=L TO BE FILLED IN BY THE       05659920
.*        MF=E FORM OF THE MACRO.                                       05669920
.*  &CODE  THIS IS THE CODE OR CODES THAT &RTN WILL HANDLE              05679920
.*        CANNOT BE IN A REGISTER.                                      05681921
.*  &RTN  THIS IS THE ADDRESS OF THE ROUTINE THAT WILL HANDLE THE       05689920
.*        CODE OR LIST OF CODES GIVEN IN THE &CODE= PARAMETER           05691920
.*  &NUM  IS VALID ONLY FOR MF=L.  THIS IS USED BY THE 1ST              05693920
.*        STABUILD MF=L TO DETERMINE THE NUMBER OF STABUILDS            05695920
.*        THAT WILL BE USED IN THIS ASSEMBLY.  IT SETS UP AN            05697920
.*        ADDRESS REFERENCE POINT FOR THE &LIST PARAMETERS OF           05698320
.*        OTHER STABUILD MACROS.                                        05698720
.*  &TYPE  TYPE OF MACRO EXPANSION FOR MF=E                             05698820
.*        A SAYS THAT NEW BLOCK IS BEING BUILT                          05698920
.*        C SAYS THAT OLD BLOCK IS BEING CHANGED                        05699020
.*                                                                      05699120
         AIF   (T'&NUM NE 'O').NUMIT                                    05699920
         AIF   ('&MF' EQ 'L').LISTFRM                                   06400020
.*                                                                      06450020
.*   EXECUTE FORM OF MACRO                                              06500020
.*                                                                      06550020
.TRYERS  AIF   ('&TYPE' EQ 'C').TYPEC  CHANGING A BLOCK                 06600020
         AIF   (T'&FLAG EQ 'O').NOFLAG                                  06800020
         AIF   (T'&ADDR EQ 'O').NOADDR                                  07200020
         AIF   (T'&RTN EQ 'O').NORTN                                    07600020
         AIF   (N'&CODE GE 2 AND T'&LIST EQ 'O').BAD                    08000020
.LOOP0   ANOP                                                           08400020
&FNUM    SETA  0                                                        08800020
&FNUM1   SETA  N'&FLAG                                                  09200020
.LOOP1   ANOP                                                           09600020
&FNUM    SETA  &FNUM+1                                                  10000020
         AIF   ('&FLAG(&FNUM)' NE 'ONE').LOOP2                          10400020
&F(8)    SETB  1                                                        10800020
.LOOP2   AIF   ('&FLAG(&FNUM)' NE 'MUL').LOOP3                          11200020
&F(7)    SETB  1                                                        11600020
.LOOP3   AIF   ('&FLAG(&FNUM)' NE 'ALL').LOOP4                          12000020
&F(6)    SETB  1                                                        12400020
.LOOP4   AIF   ('&FLAG(&FNUM)' NE 'USER').LOOP5                         12800020
&F(5)    SETB  1                                                        13200020
.LOOP5   AIF   ('&FLAG(&FNUM)' NE 'NMSG').LOOP6                         13250020
&F(4)    SETB 1                                                         13300020
.LOOP6   ANOP                                                           13350020
.LOOP7   ANOP                                                           13400020
.LOOP8   AIF   ('&FLAG(&FNUM)' NE 'END').LOOP9                          13600020
&F(1)    SETB  1                                                        14000020
.LOOP9   ANOP                                                           14400020
&FNUM1   SETA  &FNUM1-1                                                 14800020
         AIF   (&FNUM1 NE 0).LOOP1                                      15200020
         AIF   ('&MF' EQ 'L').MFL001 BYPASS ON MF=L                     15250020
         AIF   (&F(8)+&F(7)+&F(6) EQ 0).NONE                            15600020
         AIF   (&F(8)+&F(7)+&F(6) NE 1).EXC                             16000020
         AIF   ('&TYPE' EQ 'C').MFL001  BYPASS ON TYPE=C                16050020
         AIF   (&F(7) EQ 1 AND T'&LIST EQ 'O').BAD2                     16400020
         AIF   (&F(6) NE 1 AND T'&CODE EQ 'O').NOCODE                   16800020
.MFL001  SPACE 1                                                        17200020
&FNUM SETA &F(1)*128+&F(2)*64+&F(3)*32+&F(4)*16+&F(5)*8+&F(6)*4+&F(7)*2+17600020
               +&F(8)                                                   18000020
.*                                                                      18050020
.*  SEE IF WE HAVE TO GO ON WITH MF=L PROCESSING                        18100020
.*                                                                      18150020
         AIF   ('&MF' EQ 'L').MFL                                       18400020
         AIF   ('&TYPE' EQ 'C').TYPEC1  GO ON WITH TYPE=C               18450020
         AIF   (N'&CODE GE 2).LISTER                                    18800020
         AIF   ('&ADDR'(1,1) EQ '(').REGAD                              19200020
&NAME    MVI   &ADDR,&FNUM         STORE FLAG BYTE                      19600020
         AIF   (T'&CODE EQ 'O').ZERO                                    20400020
         AIF   ('&CODE'(1,1) EQ '(').REG1                               20450020
         LA    15,X'&CODE'         ABEND CODE                           20800020
         AGO   .STH15                                                   21200020
.ZERO    LA    15,0                CODE OMITTED                         21600020
.STH15   STH   15,&ADDR+2          STORE IT                             22000020
         AGO   .REG2                                                    22400020
.REG1    STH   &CODE(1),&ADDR+2    STORE ABEND CODE                     22800020
.REG2    AIF   ('&RTN'(1,1) EQ '(').REG3                                23200020
         LA    14,&RTN             RETRY ROUTINE ADDRESS                23600020
         ST    14,&ADDR+4          STORE IT                             24000020
         AGO   .END                                                     24400020
.REG3    ST    &RTN(1),&ADDR+4     STORE ROUTINE ADDRESS                24800020
.END     SPACE 1                                                        25200020
         MEXIT                                                          25600020
.REGAD   ANOP                                                           26000020
&NAME    MVI   0(&ADDR(1)),&FNUM   STORE FLAG BYTE                      26400020
         AIF   (T'&CODE EQ 'O').ZERO1                                   27200020
         AIF   ('&CODE'(1,1) EQ '(').REGAD1                             27250020
         LA    15,X'&CODE'         ABEND CODE                           27600020
         AGO   .STH15A                                                  28000020
.ZERO1   LA    15,0                CODE OMITTED                         28400020
.STH15A  STH   15,2(&ADDR(1))      STORE IT                             28800020
         AGO   .REGAD2                                                  29200020
.REGAD1  STH   &CODE(1),2(&ADDR(1))  STORE ABEND CODE                   29600020
.REGAD2  AIF   ('&RTN'(1,1) EQ '(').REGAD3                              30000020
         LA    14,&RTN             RETRY ROUTINE ADDRESS                30400020
         ST    14,4(&ADDR(1))      STORE IT                             30800020
         AGO   .END                                                     31200020
.REGAD3  ST    &RTN(1),4(&ADDR(1))  STORE ROUTINE ADDRESS               31600020
         AGO   .END                                                     32000020
.LISTER  ANOP                                                           32400020
         AIF   ('&ADDR'(1,1) EQ '(').LADR                               32800020
         AIF   ('&LIST'(1,1) EQ '(').LLIST                              33200020
&NAME    LA    14,&LIST            LIST OF CODES                        33600020
.ST14A   ST    14,&ADDR            STORE IT                             34000020
         MVI   &ADDR,&FNUM         STORE FLAG BYTE                      34400020
         AIF   ('&RTN'(1,1) EQ '(').LRTN                                34800020
         LA    15,&RTN             RETRY ROUTINE ADDRESS                35200020
         ST    15,&ADDR+4          STORE IT                             35600020
         AGO   .CODES                                                   36000020
.LADR    AIF   ('&LIST'(1,1) EQ '(').ALIST                              36400020
&NAME    LA    14,&LIST            LIST OF CODES                        36800020
.ST14    ST    14,0(&ADDR(1))      STORE IT                             37200020
         MVI   0(&ADDR(1)),&FNUM   STORE FLAG BYTE                      37600020
         AIF   ('&RTN'(1,1) EQ '(').ARTN                                38000020
         LA    15,&RTN             RETRY ROUTINE ADDRESS                38400020
         ST    15,4(&ADDR(1))      STORE IT                             38800020
         AGO   .CODES                                                   39200020
.LRTN    ST    &RTN(1),&ADDR+4     STORE ROUTINE ADDRESS                39600020
         AGO   .CODES                                                   40000020
.ALIST   ANOP                                                           40400020
&NAME    LR    14,&LIST(1)         LIST OF CODES                        40800020
         AGO   .ST14                                                    41200020
.ARTN    ST    &RTN(1),4(&ADDR(1))  STORE ROUTINE ADDRESS               41600020
         AGO   .CODES                                                   42000020
.LLIST   ANOP                                                           42400020
&NAME    LR    14,&LIST(1)         LIST OF CODES                        42800020
         AGO   .ST14A                                                   43200020
.*                                                                      43250020
.*      LOOP TO SET UP THE CODES                                        43300020
.*                                                                      43350020
.CODES   SPACE 1                                                        43600020
&FNUM    SETA  0        CLEAR COUNTER                                   43650020
&INCR    SETA  0           CLEAR INCREMENT                              43700020
&FNUM1   SETA  N'&CODE      GET NUMBER OF CODES                         44000020
.LOOPS   ANOP               ANY LABEL                                   44050020
&FNUM    SETA  &FNUM+1     UP POINTER BY ONE                            44100020
         LA    15,X'&CODE(&FNUM)'  ABEND CODE                           44400020
         STH   15,&INCR.(14)    STORE IN LIST                           44800020
&FNUM1   SETA  &FNUM1-1 BACK UP ONE                                     44850020
         AIF   (&FNUM1 NE 0).LOOPS1                                     45600020
         OI    &INCR.(14),X'80'         END OF LIST                     46000020
         AGO   .END                                                     46400020
.LOOPS1  ANOP                                                           46800020
&INCR    SETA  &INCR+2            UP POINTER                            46850020
         AGO   .LOOPS                                                   47200020
.*                                                                      47210020
.*       THIS IS THE TYPE=C PROCESSING                                  47250020
.*                                                                      47300020
.TYPEC   AIF   (T'&ADDR EQ 'O').NOADDR NEED AN ADDRESS                  47350020
         AIF   (N'&CODE GE 2 AND T'&LIST EQ 'O').BAD NEED A LIST        47400020
         AIF   (T'&FLAG NE 'O').LOOP0  CHECK FLAG SETTING               47450020
.TYPEC1  AIF   ('&ADDR'(1,1) EQ '(').REGTC  ADDR IN REG                 47500020
         AIF   (N'&CODE GE 2).TYPECL                                    47550020
         AIF   (T'&FLAG NE 'O' AND T'&CODE EQ 'O').TYPECF  FLAG ONLY    47600020
         AIF   (T'&CODE NE 'O' AND T'&FLAG EQ 'O').TYPECC CODE ONLY     47650020
         AIF   (T'&CODE EQ 'O' AND T'&FLAG EQ 'O').TYPECR  BOTH OMITTED 47700020
&NAME    MVI   &ADDR,&FNUM         STORE FLAG BYTE                      47750020
         LA    15,X'&CODE'         ABEND CODE                           47800020
         STH   15,&ADDR+2          STORE IT                             47850020
         AGO   .TYPECR1            CHECK ROUTINE                        47900020
.TYPECF  ANOP                                                           47950020
&NAME    MVI   &ADDR,&FNUM         STORE NEW FLAG                       48000020
         AGO   .TYPECR1                                                 48010020
.TYPECC  ANOP                                                           48020020
&NAME    LA    15,X'&CODE'         NEW ABEND CODE                       48030020
         STH   15,&ADDR+2          STORE IT                             48040020
         AGO   .TYPECR1                                                 48042020
.TYPECR  AIF   (T'&RTN EQ 'O').TYPCLST  SEE IF THER IS A LIST           48044021
         AIF   ('&RTN'(1,1) EQ '(').TYPECRR  IN A REG                   48046020
&NAME    LA    15,&RTN             NEW ROUTINE                          48048020
         ST    15,&ADDR+4          STORE IT                             48048420
         AGO   .END                                                     48048820
.TYPECRR ANOP                                                           48049220
&NAME    ST    &RTN(1),&ADDR+4     STORE NEW ROUTINE                    48049620
         AGO   .END                                                     48049720
.TYPECR1 AIF   (T'&RTN EQ 'O').END                                      48049820
         AIF   ('&RTN'(1,1) EQ '(').TYPECR2                             48049920
         LA    15,&RTN             NEW ROUTINE                          48066620
         ST    15,&ADDR+4          STORE IT                             48076620
         AGO   .END                                                     48078620
.TYPECR2 ST    &RTN(1),&ADDR+4     STORE NEW ROUTINE                    48080620
         AGO   .END                                                     48082620
.REGTC   AIF   (N'&CODE GE 2).TYPECLR                                   48083020
         AIF   (T'&FLAG NE 'O' AND T'&CODE EQ 'O').TYPCRF               48083120
         AIF   (T'&CODE NE 'O' AND T'&FLAG EQ 'O').TYPCRC               48083220
         AIF   (T'&CODE EQ 'O' AND T'&FLAG EQ 'O').TYPCRR               48088820
&NAME    MVI   0(&ADDR(1)),&FNUM   STORE FLAG BYTE                      48090820
         LA    15,X'&CODE'         NEW ABEND CODE                       48092820
         STH   15,2(&ADDR(1))      STORE IT                             48093220
         AGO   .TYPCR1                                                  48093620
.TYPCRF  ANOP                                                           48094020
&NAME    MVI   0(&ADDR(1)),&FNUM   STORE NEW FLAG BYTE                  48094120
         AGO   .TYPCR1                                                  48094220
.TYPCRC  ANOP                                                           48094320
&NAME    LA    15,X'&CODE'         NEW ABEND CODE                       48108220
         STH   15,2(&ADDR(1))      STORE IT                             48118220
         AGO   .TYPCR1                                                  48120220
.TYPCRR  AIF   (T'&RTN EQ 'O').WHY                                      48120620
         AIF   ('&RTN'(1,1) EQ '(').TYPCRRR                             48121420
&NAME    LA    15,&RTN             NEW ROUTINE                          48121820
         ST    15,4(&ADDR(1))      STORE IT                             48121920
         AGO   .END                                                     48122020
.TYPCRRR ANOP                                                           48122120
&NAME    ST    &RTN(1),4(&ADDR(1)) STORE NEW ROUTINE                    48126720
         AGO   .END                                                     48128720
.TYPCR1  AIF   (T'&RTN EQ 'O').END                                      48130720
         AIF   ('&RTN'(1,1) EQ '(').TYPCRR2                             48131120
         LA    15,&RTN             NEW ROUTINE                          48131220
         ST    15,4(&ADDR(1))      STORE IT                             48131320
         AGO   .END                                                     48131420
.TYPCRR2 ST    &RTN(1),4(&ADDR(1)) STORE NEW ROUTINE                    48136020
         AGO   .END                                                     48136120
.TYPECL  AIF   ('&LIST'(1,1) EQ '(').TYPECL1                            48138120
         AIF   (T'&FLAG EQ 'O').TYPCL2                                  48140120
&NAME    LA    14,&LIST            LIST OF CODES                        48140520
.TYPCS14 ST    14,&ADDR            STORE IT                             48140620
         MVI   &ADDR,&FNUM         STORE FLAG BYTE                      48140720
         AIF   (T'&CODE EQ 'O').END   OUT IF NO CODE                    48150721
         AGO   .CODES                                                   48152520
.TYPECL1 AIF   (T'&FLAG EQ 'O').TYPCL3                                  48162520
&NAME    LR    14,&LIST(1)         LIST OF CODES                        48164520
         AGO   .TYPCS14                                                 48168420
.TYPCL2  ANOP                                                           48170420
&NAME    LA    14,&LIST            LIST OF CODES                        48172420
.TYPCI15 IC    15,&ADDR            SAVE FLAG BYTE                       48176320
         ST    14,&ADDR            STORE LIST ADDRESS                   48176420
         STC   15,&ADDR            RESTORE FLAG BYTE                    48178420
         AIF   (T'&CODE EQ 'O').END  OUT IF NO CODE                     48178521
         AGO   .CODES                                                   48178820
.TYPCL3  ANOP                                                           48179220
&NAME    LR    14,&LIST(1)         LIST ADDRESS                         48179620
         AGO   .TYPCI15                                                 48180020
.TYPECLR AIF   ('&LIST'(1,1) EQ '(').TYPRCL                             48180120
         AIF   (T'&FLAG EQ 'O').TYPRCL1                                 48180220
&NAME    LA    14,&LIST            LIST OF CODES                        48180320
.TYPRS14 ST    14,0(&ADDR(1))      STORE IT                             48184220
         MVI   0(&ADDR(1)),&FNUM   STORE FLAG BYTE                      48184320
         AIF   (T'&CODE EQ 'O').END  OUT IF NO CODE                     48184721
         AGO   .CODES                                                   48186320
.TYPRCL  AIF   (T'&FLAG EQ 'O').TYPRCL3                                 48186720
&NAME    LR    14,&LIST(1)         LIST OF CODES                        48187120
         AGO   .TYPRS14                                                 48187520
.TYPRCL1 ANOP                                                           48187920
&NAME    LA    14,&LIST            LIST OF CODES                        48188020
.TYPRI15 IC    15,0(&ADDR(1))      SAVE FLAG BYTE                       48188120
         ST    14,0(&ADDR(1))      STORE CODE ADDRESS                   48188220
         STC   15,0(&ADDR(1))      RESTORE FLAG BYTE                    48198520
         AIF   (T'&CODE EQ 'O').END  OUT IF NO CODE                     48198621
         AGO   .CODES                                                   48198920
.TYPRCL3 ANOP                                                           48199320
&NAME    LR    14,&LIST(1)         ADDRESS OF CODES                     48199720
         AGO   .TYPRI15                                                 48199820
.TYPCLST AIF   (T'&LIST EQ 'O').WHY  NOTHING SPECIFIED                  48202021
         AGO   .TYPECL             ONWARD                               48204021
.*                                                                      48208820
.*          LIST FORM OF MACRO                                          48219120
.*                                                                      48229420
.* FIRST CHECK TO SEE IF THERE ARE ANY FLAGS                            48239720
.*                                                                      48250020
.LISTFRM AIF   (T'&FLAG NE 'O').LOOP0                                   48400020
&FNUM    SETA  0                                                        48800020
         AIF   (T'&NAME EQ 'O' AND T'&ADDR EQ 'O').BOTH                 49200020
         SPACE 1                                                        49600020
.MFL     AIF   (T'&LIST EQ 'O' AND N'&CODE GE 2).BAD                    50000020
         AIF   (T'&LISTNUM NE 'O' AND T'&LIST EQ 'O').NOLIST1           50400020
         AIF   (T'&CODE EQ 'O' AND T'&LIST NE 'O' AND T'&LISTNUM EQ 'O')50800020
               ).NOLIST2                                                51200020
         AIF   (T'&NAME EQ 'O' AND T'&ADDR EQ 'O').BOTH                 51600020
         AIF   (T'&NAME NE 'O').NOADRS  BYPASS                          51602020
         AIF   (T'&ADDR EQ 'O').NOADRS     IS THERE AN ADDRESS          51610020
         AIF   ('&ADDR'(1,1) EQ '(').BADADR     CAN'T DO THAT           51620020
.NOADRS  AIF   (T'&LIST EQ 'O').NOLIST     IS THERE A LIST              51630020
         AIF   ('&LIST'(1,1) EQ '(').BADLIST     CAN'T DO THAT EITHER   51640020
.NOLIST  ANOP                                                           51642020
         AIF   (&$PSEUDO(2) EQ 0).FIRST1   FIRST TIME                   51650020
         ORG   $STAELST+&$PSEUDO(2)*8  ORG AT NEXT SLOT                 52000020
         AGO   .FIRST2                                                  52050020
.FIRST1  ORG   $STAELST          ORG AT FIRST SLOT                      52100020
.FIRST2  ANOP                                                           52150020
&$PSEUDO(2) SETA &$PSEUDO(2)+1                                          52400020
         SPACE 1                                                        52800020
.*                                                                      52850020
.*        THE NAME PARAMETER OVERRIDES THE ADDR PARAMETER               52900020
.*                                                                      52950020
         AIF   (T'&ADDR EQ 'O').NAME                                    53200020
         AIF   (T'&NAME NE 'O').NAME                                    53600020
&ADDR    DS    0F                  NAME THIS SECTION                    54400020
         AGO   .DCNUM                                                   54800020
.NAME    ANOP                                                           55200020
&NAME    DS    0F                  NAME THIS SECTION                    55600020
.DCNUM   DC    AL1(&FNUM)          FLAG BYTE                            56000020
         AIF   (N'&CODE GE 2).LISTMFL                                   56400020
         AIF   (T'&LIST NE 'O').LISTMFL                                 56800020
         AIF   (T'&CODE EQ 'O').CODE0S                                  57200020
         DC    AL3(X'&CODE')       ABEND CODE                           57600020
         AGO   .RTN0S                                                   58000020
.CODE0S  DC    AL3(0)             ABEND CODE                            58400020
.RTN0S   AIF   (T'&RTN EQ 'O').RTN1S                                    58800020
         DC    A(&RTN)             RETRY ROUTINE ADDRESS                59200020
         AGO  .LSTEND                                                   59600020
.RTN1S   DC    A(0)               RETRY ROUTINE ADDRESS                 60000020
         AGO   .LSTEND                                                  60400020
.NUMIT   SPACE 1                                                        60800020
         AIF   ('&MF' NE 'L').TRYERS                                    61200020
         AIF   (&$PSEUDO(4) EQ 1).NUMITE                                61600020
&$PSEUDO(4) SETA 1                                                      62000020
$STAELST DS    0F                  NAME THE POINTER ENTRIES             62400020
         SPACE 1                                                        62800020
         ORG   $STAELST+&NUM*8     ORG TO END OF ENTRIES                63200020
         SPACE 1                                                        63600020
$STAEEND DS    0F                 NAME THE END OF ENTRIES               64000020
.NUMITE  ANOP                                                           64400020
         AIF   (T'&FLAG NE 'O' OR T'&LIST NE 'O' OR T'&ADDR NE 'O' OR T'64800020
               '&CODE NE 'O' OR T'&RTN NE 'O' OR T'&LISTNUM NE 'O').LIST65200020
               TFRM                                                     65250020
         AGO   .LSTEND                                                  65600020
.LISTMFL DC    AL3(&LIST)          ADDRESS OF LIST                      66000020
         AIF   (T'&RTN EQ 'O').RTN2S                                    66400020
         DC    A(&RTN)             ADDRESS OF RETRY ROUTINE             66800020
         AGO   .RTN3S                                                   67200020
.RTN2S   DC    A(0)               RETRY ROUTINE ADDRESS                 67600020
.RTN3S   AIF   (&$PSEUDO(3) NE 0).BYPAS1                                68000020
         SPACE 1                                                        68400020
.MLORG   ORG   $STAEEND            ORG AT BOTTOM OF ENTRIES             68800020
         SPACE 1                                                        69200020
$STAECOD DS    0F                  NAME LIST OF CODES                   69600020
         AGO   .BYPAS2                                                  70000020
.BYPAS1  SPACE 1                                                        70400020
         ORG   $STAECOD+&$PSEUDO(3)*2  ORG AT NEXT SLOT                 70800020
.BYPAS2  SPACE 1                                                        71200020
&LIST    DS    0H                  NAME THIS LIST OF CODES              71600020
         AIF   (N'&CODE EQ 0).CODE1S                                    72000020
&FNUM    SETA  0         ZERO THE COUNTER                               72050020
&FNUM1   SETA  N'&CODE  GET THE NUMBER OF CODES                         72400020
.LISTLOP ANOP A LABEL                                                   72450020
&FNUM    SETA &FNUM+1 UP POINTER BY ONE                                 72500020
         DC    AL2(X'&CODE(&FNUM)')  CODE ENTRY                         72800020
&$PSEUDO(3) SETA &$PSEUDO(3)+1                                          73200020
&FNUM1   SETA  &FNUM1-1                                                 73600020
         AIF   (&FNUM1 NE 0).LISTLOP                                    74000020
.LSTEND  SPACE 1                                                        74400020
         ORG                                                            74450020
         SPACE 1                                                        74500020
         MEXIT                                                          74800020
.CODE1S  DC    (&LISTNUM)AL2(0)   SPACE FOR ABEND CODES                 75200020
&$PSEUDO(3) SETA &$PSEUDO(3)+&LISTNUM                                   75600020
         AGO   .LSTEND                                                  76000020
.NONE    MNOTE 8,'NO FLAG PARAMETER CODES'                              76400020
         SPACE 1                                                        76800020
         MEXIT                                                          77200020
.EXC     MNOTE 8,'MUTUALLY EXCLUSIVE PARAMETERS IN FLAG CODES'          77600020
         SPACE 1                                                        78000020
         MEXIT                                                          78400020
.NOFLAG  MNOTE 8,'FLAG PARAMETER OMITTED'                               78800020
         SPACE 1                                                        79200020
         MEXIT                                                          79600020
.NOCODE  MNOTE 8,'CODE PARAMETER OMITTED'                               80000020
         SPACE 1                                                        80400020
         MEXIT                                                          80800020
.NOADDR  MNOTE 8,'ADDR PARAMETER OMITTED'                               81200020
         SPACE 1                                                        81600020
         MEXIT                                                          82000020
.NORTN   MNOTE 8,'RTN PARAMETER OMITTED'                                82400020
         SPACE 1                                                        82800020
         MEXIT                                                          83200020
.BAD     MNOTE 8,'MORE THAN ONE ABEND CODE AND NO LIST PARAMETER'       83600020
         SPACE 1                                                        84000020
         MEXIT                                                          84400020
.BAD2    MNOTE 8,'FLAG=MUL AND NO LIST PARAMETER'                       84800020
         SPACE 1                                                        85200020
         MEXIT                                                          85600020
.NOLIST1 MNOTE 8,'LIST PARAMETER OMITTED WITH LISTNUM PARAMETER'        86000020
         SPACE 1                                                        86400020
         MEXIT                                                          86800020
.NOLIST2 MNOTE 8,'LISTNUM PARAMETER OMITTED WITH LIST PARAMETER AND NO C87200020
               CODE PARAMETER'                                          87600020
         SPACE 1                                                        88000020
         MEXIT                                                          88400020
.BOTH    MNOTE 8,'BOTH NAME AND ADDR PARAMETERS OMITTED'                88800020
         SPACE 1                                                        89200020
         MEXIT                                                          89600020
.BADADR  MNOTE 8,'CANNOT NAME THE SECTION WITH A REGISTER'              90000020
         SPACE 1                                                        90400020
         MEXIT                                                          90800020
.BADLIST MNOTE 8,'CANNOT NAME THE LIST WITH A REGISTER'                 90850020
         SPACE 1                                                        90900020
         MEXIT                                                          90950020
.WHY     MNOTE 8,'NO OPERANDS ON TYPE=C'                                91000020
         SPACE 1                                                        91050020
         MEXIT                                                          91100020
         MEND                                                           91200020
