         MACRO                                                          00600020
&NAME    STAEPARM  &FLAG=,                                             X01200020
               &PSEUDO=,                                               X01800020
               &LIST=,                                                 X02400020
               &ADDR=,                                                 X03000020
               &MF=                                                     03600020
.*                                                                      04200020
.*       THIS MACRO BUILDS THE CONTROL BLOCK THAT IS PASSED TO THE      04800020
.*       IKJEHSIR EXIT ROUTINE VIA THE PARAM= PARAMETER OF THE STAE     05400020
.*       MACRO.                                                         06000020
.*                                                                      06600020
.*       &FLAG  IS THE FLAG TO SET IN THE BLOCK, CAN BE ONE OF TWO      07200020
.*             SETTINGS:  CP OR TMP.                                    07800020
.*             IF IT IS CP, THE DEFAULT, IT SAYS THE CP WANTS TO HANDLE 08400000
.*             SOME ABENDS.  IF IT IS TMP, IT SAYS THAT THE CP WANTS    09000020
.*             THE TMP TO HANDLE ALL ABENDS.                            09600020
.*       &PSEUDO  THE ADDRESS OF THE PSEUDO RETRY ROUTINE BUILT WITH    10200000
.*             THE PSEUDO MACRO.  FOR THE FULL EXPLAINATION OF THE      11400000
.*             PSEUDO RETRY ROUTINE, SEE THE PSEUDO MACRO.              12000020
.*       &LIST  THIS IS THE ADDRESS OF THE RETRY CODE TABLE BUILD       12600020
.*             WITH THE STABUILD MACRO. FOR A FULLER EXPLAINATION,      13200020
.*             OF THE RETRY CODE TABLE SEE THE STABUILD MACRO.          13800000
.*       &ADDR  THIS IS THE ADDRESS OF THE MF=L FORM OF THIS MACRO.     14400020
.*             IT IS USED BY THE MF=E MACRO TO FILL IT IN, OR IT IS     15000000
.*             USED BY THE MF=L FORM AS A NAME IF NO NAME IS PROVIDED   15600000
.*                                                                      16200020
         LCLA  &FNUM                                                    16800020
         LCLB  &F(8)                                                    17400020
.*                                                                      18000020
.*       IF NO FLAG IS GIVEN, DEFAULT TO CP                             18600020
.*                                                                      19200020
         AIF   (T'&FLAG EQ 'O').SET1                                    19800020
.*                                                                      20400020
.*       LOOP THRU THE FLAG POSSIBILITIES AND SET SOME BITS             21000020
.*                                                                      21600020
&FNUM    SETA  N'&FLAG   NUMBER OF FLAG SETTINGS                        22200000
.LOOP1   AIF   ('&FLAG(&FNUM)' NE 'CP').LOOP2                           22800020
&F(8)    SETB  1                                                        23400020
.LOOP2   AIF   ('&FLAG(&FNUM)' NE 'TMP').LOOP3                          24000020
&F(7)    SETB  1                                                        24600020
.LOOP3   ANOP                                                           25200020
&FNUM    SETA  &FNUM-1                                                  25800020
         AIF   (&FNUM NE 0).LOOP1                                       26400020
         AIF   (&F(8) EQ 1 AND &F(7) EQ 1).BADFLAG  CANT BE BOTH        26450000
&FNUM    SETA  &F(7)*2+&F(8)                                            27000020
         AGO   .SET                                                     27600020
.SET1    ANOP                                                           28200020
&FNUM    SETA  1        DEFAULT TO CP                                   28800000
.SET     ANOP                                                           29400020
.*                                                                      30000020
.*             IF ITS LIST FORM, GO CHECK ITS REQUIREMENTS              30600020
.*                                                                      31200020
         AIF   ('&MF' EQ 'L').MFL                                       31800020
.*                                                                      31850000
.*   EXECUTE FORM OF MACRO                                              31900000
.*                                                                      31950000
         AIF   (T'&PSEUDO EQ 'O').NOPS   NEED PSEUDO PARM               33000020
         AIF (&F(7) EQ 1).ADDR  DONT NEED LIST IF TMP SPECIFIED         33050020
         AIF   (T'&LIST EQ 'O').NOLST    NEED A LIST                    33600020
.ADDR    AIF   (T'&ADDR EQ 'O').NOADDR  NEED AN ADDRESS                 34200000
         SPACE 1                                                        34800020
.*                                                                      35400020
.*             CHECK FOR THINGS BEING IN REGISTERS                      36000000
.*                                                                      36600020
         AIF   ('&ADDR'(1,1) EQ '(').REGAD                              37200020
         AIF   (T'&LIST EQ 'O').NLIST  MAY NOT HAVE A LIST              38400020
            AIF ('&LIST'(1,1) EQ '(').RLIST                             38450020
&NAME    LA    15,&LIST            LIST OF CODES OR POINTERS            39000020
         AGO   .NLIST1             BYPASS                               39600000
.NLIST   ANOP                                                           40200020
&NAME    LA    15,0                LIST OMITTED                         40800020
.NLIST1  ST    15,&ADDR            STORE LIST POINTER                   41400020
         AGO   .RLIST1                                                  42000020
.RLIST   ANOP                                                           42600020
&NAME    ST    &LIST(1),&ADDR      LIST OF CODES                        43200020
.RLIST1  MVI   &ADDR,&FNUM         STORE FLAG                           43800020
         AIF   (T'&PSEUDO EQ 'O').NPSE  MAY NOT NEED IT                 45000020
           AIF ('&PSEUDO'(1,1) EQ '(').RPS                              45050020
         LA    15,&PSEUDO          PSEUDO RETRY ROUTINE                 45600020
         AGO   .NPSE1              VYPASS                               46200020
.NPSE    LA    15,0                PSEUDO POINTER OMITTED               46800020
.NPSE1   ST    15,&ADDR+4          STORE PSEUDO POINTER                 47400020
         AGO   .END                                                     48000020
.RPS     ST    &PSEUDO(1),&ADDR+4  STORE PSEUDO RETRY ROUTINE           48600020
.END     SPACE 1                                                        49200020
         MEXIT                                                          49800020
.REGAD   AIF   (T'&LIST EQ 'O').NLIST2  NEED NOT HAVE IT                51000020
&NAME    LA    15,&LIST            LIST OF CODES OR POINTERS            51600020
         AGO   .NLIST3                                                  52200020
.NLIST2  ANOP                                                           52800020
&NAME    LA    15,0                LIST OMITTED                         53400020
.NLIST3  ST    15,0(&ADDR(1))      STORE LIST POINTER                   54000020
         AGO   .REGAD2                                                  54600020
.REGAD1  ANOP                                                           55200020
&NAME    ST    &LIST(1),0(&ADDR(1))  LIST OF CODES                      55800020
.REGAD2  MVI   0(&ADDR(1)),&FNUM   STORE FLAG BYTE                      56400020
         AIF   (T'&PSEUDO EQ 'O').PSE2                                  57600020
          AIF ('&PSEUDO'(1,1) EQ '(').REGAD3                            57650000
         LA    15,&PSEUDO          PSEUDO RETRY ROUTINE                 58200020
         AGO   .PSE3                                                    58800020
.PSE2    LA    15,0                PSEUDO POINTER OMITTED               59400020
.PSE3    ST    15,4(&ADDR(1))      STORE PSEUDO POINTER                 60000020
         AGO   .END                                                     60600020
.REGAD3  ST    &PSEUDO(1),4(&ADDR(1))  STORE PSEUDO RETRY ROUTINE       61200020
         AGO   .END                                                     61800020
.*                                                                      62400020
.*                            LIST FORM                                 63000000
.*                                                                      63600020
.*       NEED EITHER A NAME OR AN ADDR FOR MAKING A NAME FOR THIS       64200020
.*                                                                      64800020
.MFL     AIF   (T'&NAME EQ 'O' AND T'&ADDR EQ 'O').BOTH                 65400020
.*                                                                      66000020
.*             THE NAME WILL OVER-RIDE THE ADDR PARAMETER               66600020
.*                                                                      67200020
         AIF   (T'&ADDR EQ 'O').NAME                                    67800020
         AIF   (T'&NAME NE 'O').NAME                                    68400020
.*                                                                      69000020
.*             IF ADDR IS REG-FORM, NO GOOG                             69600020
.*                                                                      70200020
         AIF   ('&ADDR'(1,1) EQ '(').BADADR                             70800020
&ADDR    DS    0F                  FULLWORD ALIGNMENT                   71400020
         AGO   .DCNUM                                                   72000020
.NAME    ANOP                                                           72600020
&NAME    DS    0F                  FULLWORD ALIGNMENT                   73200020
.DCNUM   AIF   (T'&FLAG EQ 'O').DCNUM1     NEED NOT AHVE A FLAG         73250000
         DC    AL1(&FNUM)          FLAG BYTE                            73800020
         AGO   .DCNUM2      BYPASS                                      73850000
.DCNUM1  DC    AL1(0)               FLAG BYTE                           73900000
.DCNUM2  AIF   (T'&LIST EQ 'O').MFL1                                    74400000
         DC    AL3(&LIST)          POINTER TO CODES                     75000020
         AGO   .MFL2                                                    75600020
.MFL1    DC    AL3(0)              POINTER TO CODES                     76200020
.MFL2    AIF   (T'&PSEUDO EQ 'O').MFL3                                  76800020
         DC    A(&PSEUDO)          PSEUDO RETRY ROUTINE                 77400020
         AGO   .END                                                     78000020
.MFL3    DC    A(0)                PSEUDO RETYR ROUTINE                 78600020
         AGO   .END                                                     79200020
.NOPS    MNOTE 8,'PSEUDO PARAMETER OMITTED'                             79800020
         SPACE 1                                                        80400020
         MEXIT                                                          81000020
.BADFLAG  MNOTE  8,'CANT HAVE BOTH FLAG=CP AND TMP'                     81050000
         SPACE 1                                                        81100000
         MEXIT                                                          81150000
.NOLST   MNOTE 8,'LIST PARAMETER OMITTED'                               81600020
         SPACE 1                                                        82200020
         MEXIT                                                          82800020
.NOADDR  MNOTE 8,'ADDR PARAMETER OMITTED'                               83400020
         SPACE 1                                                        84000020
         MEXIT                                                          84600020
.BOTH    MNOTE 8,'BOTH ADDR AND NAME PARAMETERS OMITTED'                85200020
         SPACE 1                                                        85800020
         MEXIT                                                          86400020
.BADADR  MNOTE 8,'CANNOT NAME STAEPARM WITH A REGISTER'                 87000020
         SPACE 1                                                        87600020
         MEXIT                                                          88200020
         MEND                                                           88800020
