         MACRO                                                          00500020
         STAES                                                          01000020
         SPACE 1                                                        01500020
STAEPARM DSECT                                                          02000020
         SPACE 1                                                        02500020
*        THIS IS A DSECT OF THE PARAMETERS PASSED TO STAE DURING        03000020
*        EXECUTION OF THE STAE MACRO.   THESE ARE PASSED IN THE         03500020
*        PARAM= PARAMETER OF THE STAE MACRO WHICH IS PASSED AS THE      04000000
*        FIRST WORD OF THE STAEWORK MACRO TO IKJEHSIR.                  04050020
         SPACE 1                                                        04500020
TBLADDR  DS    0A             ADDRESS OF RETRY TABLE                    05000020
         SPACE 1                                                        05500020
STAEFLAG DC    X'00'          FLAG BYTE FOR STAE EXIT                   06000020
         SPACE 1                                                        06500020
*        THE MEANING OF THE FLAG BYTE BITS FOLLOWS:                     07000020
         SPACE 1                                                        07500020
STAEUSER EQU   X'01'          USER WILL HANDLE ABENDS                   08000020
STAETMP  EQU   X'02'          USER WANTS THE TMP TO HANDLE ABENDS       08500020
         SPACE 1                                                        09000020
*        IF NEITHER OF THE BITS IS SET, STAEUSER IS ASSUMED             09500020
         SPACE 1                                                        10000020
*        THE FOLLOWING IS THE POINTER TO THE TABLE OF ABENDS.           10500000
*        THIS IS DESCRIBED IN PARAM DSECT                               11000020
         SPACE 1                                                        11500020
STAETBL  DC    AL3(0)         POINTER TO TABLE                          12000020
         SPACE 1                                                        12500020
*        THE FOLLOWING IS THE POINTER TO THE PSEUDO RETRY ADDRESS       13000020
*        THIS IS DESCRIBED IN THE RETRY DSECT.                          13500020
         SPACE 1                                                        14000020
RETRYER  DC    A(0)           ADDRESS OF LM & SAVEAREA                  14500020
         EJECT                                                          15000020
RETRY    DSECT                                                          15500020
         SPACE 1                                                        16000020
*        THIS IS A DSECT OF THE RETRY ADDRESS PASSED TO IKJEHSIR        16500020
*        DURING THE EXECUTION OF THE STAE MACRO VIA PARAM=.             17000000
         SPACE 1                                                        17500020
*        THE FIRST TWO DC'S ARE USED TO OBTAIN ADDRESSABILITY FOR THE   18000020
*        USER'S RETRY ROUTINE; THIS ELIMINATES THE PROBLEM OF A         18500020
*        PROGRAM THE USER CALLED ABENDING.  WHEN THIS HAPPENS, STAE     19000020
*        RETURNS THE REGISTERS BELONGING TO THE CALLED PROGRAM TO       19500020
*        THE STAE RETRY ROUTINE.                                        20000020
*              NOTE:  DUE TO MEMMAP RESTRICTION, THESE SHOULD BE DC'S   20500020
         SPACE 1                                                        21000020
RETRIER  DC    X'980FF008'    LM    R0,R15,8(R15)   LOAD ALL REGISTERS  21500020
         DC    X'47F0F000'    B     0(R15)    GO TO RETRY ROUTINE       22000020
         SPACE 1                                                        22500020
*        THE FOLLOWING 16 DC'S ARE A STORAGE AREA FOR THE USER'S        23000020
*        REGISTERS.  THE SLOTS FOR R0, R1, R2 & R15 WILL BE SET UP      23500000
*        BY THE IKJEHSIR ROUTINE AS FOLLOWS:                            24000020
*              R0     THE CODE GIVEN TO THE EXIT ROUTINE BY STAE        24500020
*              R1     THE ABEND CODE, RIGHT JUSTIFIED                   25000020
*              R2     THE ENTRY NUMBER IN LIST OF CODES                 25500020
*              R15    THE ADDRESS OF THE USERS RETRY ROUTINE            26000020
         SPACE 1                                                        26500020
RETRYR0  DC    F'0'           STORAGE FOR R0                            27000020
RETRYR1  DC    F'0'           STORAGE FOR R1                            27500020
RETRYR2  DC    F'0'           STORAGE FOR R2                            28000020
RETRYRS  DC    10F'0'         THE REST OF THE REGS                      28500020
RETRYR13 DC    F'0'           STORAGE FOR R13                           29000020
RETRYR14 DC    F'0'           STORAGE FOR R14                           29500020
RETRYR15 DC    F'0'           STORAGE FOR R15                           30000020
         SPACE 1                                                        30500020
*        THE FOLLOWING WORD IS REQUIRED SO THAT THE PUTLINE             31000020
*        SERVICE ROUTINE CAN BE INVOKED BY THE STAE EXIT                31500020
*        ROUTINE.  IT IS REGISTER 1 AS GIVEN TO THE CP BY               32000020
*        THE TMP.  IT IS A POINTER TO FOUR ADDRESSES, SEE               32500020
*        THE TMPPARM DSECT.                                             33000020
         SPACE 1                                                        33500020
TMPREG1  DC    F'0'           REG 1 FROM TMP                            34000020
         EJECT                                                          34500020
PARAM    DSECT                                                          35000020
         SPACE 1                                                        35500020
*        THIS IS A DSECT OF THE PARAMETER TABLE OF ADDRESSES OF THOSE   36000020
*        ROUTINES WHICH WILL HANDLE SPECIFIC ABENDS.  THIS IS BUILD     36500020
*        BY THE USER OF THE STAE EXIT ROUTINE AND PASSED TO THE         37000000
*        IKJEHSIR ROUTINE THRU THE PARAM= PARAMETER OF THE STAE MACRO.  37500020
         SPACE 1                                                        38000020
*        EACH ENTRY IN THE TABLE IS OF THE FOLLOWING FORM, AND MUST     38500020
*        BE TWO WORDS LONG.  THE TABLE MUST BE FULLWORD ALIGNED.        39000020
         SPACE 1                                                        39500020
*  *****************************************************************    40000020
*  *         *                                                     *    40500020
*  *   FLAG  *    ABEND CODE OR ADDRESS OF LIST OF CODES           *    41000020
*  *         *                                                     *    41500020
*  *****************************************************************    42000020
*  *                                                               *    42500020
*  *           ADDRESS OF THE ROUTINE TO HANDLE THE CODE(S)        *    43000020
*  *                                                               *    43500020
*  *****************************************************************    44000020
         SPACE 1                                                        44500020
PARMADDR DS    0A             ADDRESS OF LIST OF CODES                  45000020
         SPACE 1                                                        45500020
PARMFLAG DC    X'00'          FLAG BYTE                                 46000020
         SPACE 1                                                        46500020
*        THE FOLLOWING IS THE MEANING OF THE FLAG BYTE BITS             47000020
         SPACE 1                                                        47500020
FLAGONE  EQU   X'01'          RETRY FOR ONE CODE ONLY--CODE FOLLOWS     48000020
FLAGMUL  EQU   X'02'          RETRY FOR LIST OF CODES--ADDRESS FOLLOWS  48500020
FLAGALL  EQU   X'04'          RETRY ALL OTHER CODES--A ZERO FOLLOWS     49000020
FLAGUSER EQU   X'08'          RETRY FOR USER ABENDS                     49500020
FLAGNMSG EQU   X'10'          DO NOT ISSUE MESSAGE                      50000020
FLAGEND  EQU   X'80'          END OF TABLE                              50500020
         SPACE 1                                                        51000020
*        THE FOLLOWING CAN BE ONE OF THREE THINGS:  THE ACTUAL ABEND    51500020
*        CODE, THE ADDRESS OF A LIST OF CODES, OR A ZERO.               52000020
         SPACE 1                                                        52500020
PARMCODA DC    X'00'          1ST BYTE OF ADDRESS                       53000020
PARMCODE DC    H'0'           ABEND CODE                                53500020
         SPACE 1                                                        54000020
*        THE FOLLOWING IS ALWAYS REQUIRED.  IT IS THE ADDRESS OF THE    54500020
*        ROUTINE WHICH WILL HANDLE ABENDS; IE, THE USER'S RETRY         55000020
*        ROUTINE.                                                       55500020
         SPACE 1                                                        56000020
PARMRTRY DC    A(0)           ADDRESS OF ROUTINE                        56500020
         SPACE 1                                                        57000020
PARMLNTH EQU   *-PARMADDR     LENTH OF EACH ENTRY                       57500020
         EJECT                                                          58000020
PARMLIST DSECT                                                          58500020
         SPACE 1                                                        59000020
*        THE FOLLOWING IS A DSECT OF THE LIST OF CODES PASSED TO THE    59500020
*        IKJEHSIR ROUTINE BY THE USER THRU THE USE OF THE FLAGMUL       60000020
*        BIT OF THE PARMFLAG OF THE PARAM DSECT.  EACH ENTRY IS A       60500020
*        HALFWORD LONG, AND MAY BE EITHER A USER OR A SYSTEM ABEND      61000020
*        CODE.  THE USER ABEND CODES MUST BE FLAGGED BY THE USE         61500020
*        OF THE FLAGUSER IN THE PARMFLAG OF THE PARAM DSECT.  IF THE    62000020
*        FLAGUSER IS ON, ALL CODES IN THAT LIST MUST BE USER ABEND      62500020
*        CODES.                                                         63000020
         SPACE 1                                                        63500020
CODES    DC    H'0'           AN ABEND CODE                             64000020
         SPACE 1                                                        64500020
*        THE HIGH ORDER BIT OF CODES IS USED TO SIGNIFY THE END OF THE  65000020
*        LIST OF CODES.  IF THE BIT IS ON, THAT IS THE END OF THE LIST  65500020
         SPACE 1                                                        66000020
CODESEND EQU   X'80'          END OF LIST                               66500020
         SPACE 1                                                        67000020
CODELNTH EQU   *-CODES        LENGTH OF EACH CODE                       67500020
         EJECT                                                          68000020
TMPPARM  DSECT                                                          68500020
         SPACE 1                                                        69000020
*        THIS IS A DSECT OF THE FOUR WORD AREA PASSED TO THE            69500020
*        CP BY THE TMP.  THE UPT, PSCB, AND ECT ARE DESCRIBED           70000000
*        IN THEIR RESPECTIVE DSECTS (QV).  THE COMMAND BUFFER           70500000
*        IS THE COMMAND AS ENTERED BY THE USER AT THE TERMINAL.         71000000
         SPACE 1                                                        72000020
TMPCMBUF DC    F'0'           POINTER TO COMMAND BUFFER                 72500020
TMPUPT   DC    F'0'           POINTER TO THE UPT                        73000020
TMPPSCB  DC    F'0'           POINTER TO PSCB                           73500020
TMPECT   DC    F'0'           POINTER TO ECT                            74000020
         EJECT                                                          74500020
STAEWORK DSECT                                                          75000020
         SPACE 1                                                        75500020
*        THIS IS A DSECT OF THE WORK AREA PASSED TO THE IKJEHSIR        76000020
*        ROUTINE BY ASIR.  IT IS USED ONLY TO OBTAIN THE PARAMETER      76500000
*        ADDRESS PASSED BY THE USER TO THE STAE SVC.                    77000020
         SPACE 1                                                        77500020
STAEEXIT DC    F'0'           EXIT ROUTINE PARAMETER, PARAM=            78000020
STAECODE DC    F'0'           ABEND COMPLETION CODE                     78500020
STAEPSW  DC    D'0'           PSW AT ABEND TIME                         79000020
STAEPSWP DC    D'0'           LAST P/P PSW                              79500020
STAEREGS DC    16F'0'         REGS AT TIME OF ABEND                     80000020
STAEPGM  DC    CL8' '         NAME OF ABENDING PROGRAM                  80500020
STAEENT  DC    F'0'           ENTRY POINT OF ABENDING PGM               81000020
STAEPAD  DC    F'0'           PADDING                                   81500020
         SPACE 1                                                        82000020
STAELNTH EQU   *-STAEWORK     LENGTH OF THE WORK AREA                   82500020
         MEND                                                           83000020
