         MACRO                                                          00100000
&LABEL   XCTLTABL &ID=,&TAG=,&SVC=019,&LENGTH=1024,&PATCH=              00200000
.*                                                                      00300000
.*  THIS MACRO IS USED MAINLY BY OPEN/CLOSE/EOV TRANSIENT SVC           00400000
.*  MODULES TO BUILD AN XCTL IDTTRL TABLE.                              00500000
.*  THE TTRL IS FILLED IN BY THE SYSTEM UTILITY PROGRAM IEHIOSUP.       00600000
.*  A VALID NULL ENTRY IS REPRESENTED BY A '#' IN THE ID FIELD   XM5707 00650001
.*                                                                      00700000
         LCLA  &C1,&C2                  INDEXES TO ID                   00800000
         LCLA  &L20,&L40,&L41           LENGTHS FOR EQUATE CALCS        00900000
         LCLC  &NAME,&PATCHLY,&PATCHLZ  NAMES FOR ASSEMBLED STATEMENTS  01000000
         LCLC  &PATCHL0,&PATCHL1        NAMES FOR ASSEMBLED STATEMENTS  01100000
         LCLC  &IGG,&I                  FIRST 3 CHAR OF MODULE NAME     01200000
         AIF   ('&LABEL' EQ '').A1      IF LABEL OMITTED                01300000
&NAME    SETC  '&LABEL'                 USE SPECIFIED LABEL NAME        01400000
         AGO   .A2                                                      01500000
.A1      ANOP                                                           01600000
&NAME    SETC  'IHB&SYSNDX.X'           DEFAULT NAME TO IHBNNNNX        01700000
.A2      ANOP                                                           01800000
&NAME    DC    0D'0'                    ALIGN TO DOUBLE WORD BOUNDARY   01900000
.*                                                                      02000000
         AIF   ('&SYSECT' LT '        ').A4  IF NOT 8 CHAR CSECT NAME   02100000
&IGG     SETC  '&SYSECT'(1,3)           FIRST 3 CHARS OF CSECT NAME     02200000
         AIF   ('&IGG' EQ 'IFG').A5     IFG MODULE REFERS TO IFG        02300000
         AIF   ('&IGG' EQ 'IGG').A5     IGG MODULE REFERS TO IGG        02400000
         AIF   ('&IGG' NE 'IGC').A4     IF NOT RECOGNIZABLE CSECT NAME  02500000
         AIF   ('&SVC' EQ '019').A3     IGC019 REFERS TO IFG019         02600000
         AIF   ('&SVC' EQ '020').A3     IGC020 REFERS TO IFG020         02700000
         AIF   ('&SVC' EQ '023').A3     IGC023 REFERS TO IFG023         02800000
         AIF   ('&SVC' EQ '055').A3     IGC055 REFERS TO IFG055         02900000
.*       NOTE THAT IGC0002B REFERS TO IFG019ID.                         03000000
&IGG     SETC  'IGG'                    ALL OTHER IGC REFER TO IGG      03100000
         AGO   .A5                                                      03200000
.A3      ANOP                                                           03300000
&IGG     SETC  'IFG'                    IGC019-055 REFERS TO IFG        03400000
         AGO   .A5                                                      03500000
.A4      ANOP                                                           03600000
&IGG     SETC  ''                       CAN NOT DETERMINE MODULE NAME   03700000
.*                                                                      03800000
.A5      ANOP                           START OF ID PARAMETER LOOP      03900000
&C1      SETA  &C2+1                    INCR C1 BY 2, START AT 1        04000000
&C2      SETA  &C1+1                    INCR C2 BY 2, START AT 2        04100000
         AIF   (&C1 GT N'&ID).A9        IF END OF ID PARAMETERS         04200000
         AIF   ('&ID(&C2)' EQ 'FFFF').A11  IF IFG/IGG DELIMITER         04250021
         AIF   ('&ID(&C2)' EQ '#').A5   NULL ENTRY LOOP          XM5707 04260001
         AIF   (K'&ID(&C2) NE 2).A8     ERROR IF MODULE ID NOT 2 CHAR   04300000
&I       SETC  '&ID(&C2)'               GET MODULE ID FROM LIST         04400000
         AIF   ('&IGG' NE '').A6        IF MODULE NAME KNOWN            04500000
&ID(&C1) DC    C'&I'                    ID OF MODULE                    04600000
         AGO   .A7                                                      04700000
.A6      ANOP  C'ID',0C'                ID OF MODULE IGG019ID'          04800000
&ID(&C1) DC    C'&I',0C'                ID OF MODULE &IGG&SVC&I'        04900000
.A7      DC    X'00000000'              TTRL                            05000000
         AGO   .A5                      LOOP ON ID PARAMETERS           05100000
.*                                                                      05110021
.A11     DC    X'FFFF'                  END OF IFG, START OF IGG        05120021
         AIF   ('&IGG' EQ '').A5        LOOP ON ID PARAMETERS           05130021
&IGG     SETC  'IGG'                    CHANGE FROM IFG TO IGG          05140021
         AGO   .A5                      LOOP ON ID PARAMETERS           05150021
.*                                                                      05200000
.A8      MNOTE 12,'** ID PARAMETER ''&ID(&C2)'' MUST HAVE 2 CHARS **'   05300000
.A9      DC    X'0000'                  END OF XCTL TABLE               05400000
*                                                                       05500000
         AIF   ('&PATCH' EQ '0').A20    IF MINIMUM LENGTH MODULE        05600000
&L20     SETA  &LENGTH-4                USUALLY 1020                    05700000
&L40     SETA  2*&L20                   USUALLY 2040                    05800000
&L41     SETA  &L40+1                   USUALLY 2041                    05900000
&PATCHLY SETC  'IHB&SYSNDX.Y'           SET NAME TO IBHNNNNY            06000000
&PATCHLZ SETC  'IHB&SYSNDX.Z'           SET NAME TO IBHNNNNZ            06100000
.*  IHBNNNNZ WILL NEVER BE NEGATIVE (OR LARGE POSITIVE).                06200000
.*  THIS DEVIOUS EQUATE PREVENTS A LONG LOOP IN ASSEMBLER F IF          06300000
.*  THE PATCH AREA LENGTH WOULD HAVE BEEN NEGATIVE.                     06400000
&PATCHLY EQU   *-&SYSECT                LENGTH BEFORE PATCH AREA        06500000
         AIF   ('&PATCH' NE '').A10     IF VARIABLE LENGTH WITH PATCH   06600000
&PATCHLZ EQU   (&L41-2*&PATCHLY)/(&L40-2*&PATCHLY)*(&L20-&PATCHLY)      06700000
         DC    (&PATCHLZ)X'00'          ZEROED PATCH AREA               06800000
*                                                                       06900000
         AGO   .A21                                                     07000000
.A10     ANOP                                                           07100000
&PATCHL0 SETC  'IHB&SYSNDX.0'           SET NAME TO IBHNNNN0            07200000
&PATCHL1 SETC  'IHB&SYSNDX.1'           SET NAME TO IBHNNNN1            07300000
&PATCHL0 EQU   (&L41-2*&PATCHLY)/(&L40-2*&PATCHLY)*(&L20-&PATCHLY)      07400000
&L20     SETA  &L20-&PATCH              USUALLY  970                    07500000
&L40     SETA  2*&L20                   USUALLY 1940                    07600000
&L41     SETA  &L40+1                   USUALLY 1941                    07700000
&PATCHL1 EQU   (&L41-2*&PATCHLY)/(&L40-2*&PATCHLY)*(&L20-&PATCHLY)      07800000
&PATCHLZ EQU   &PATCHL0-&PATCHL1        LENGTH OF PATCH AREA            07900000
         DC    (&PATCHLZ)X'00'          ZEROED PATCH AREA               08000000
*                                                                       08100000
.A20     CNOP  4,8                      ALIGN TO END MODULE ON DW       08200000
.A21     AIF   ('&SVC' EQ '019').A22    IF OPEN SVC CODE                08300000
         AIF   ('&SVC' EQ '020').A23    IF CLOSE SVC CODE               08400000
         AIF   ('&SVC' EQ '023').A24    IF TCLOSE SVC CODE              08500000
         AIF   ('&SVC' EQ '055').A25    IF EOV SVC CODE                 08600000
&TAG     DC    C'&SVC'                  SVC CODE                        08700000
         AGO   .A26                                                     08800000
.A22     ANOP                                                           08900000
&TAG     DC    C'019'                   OPEN SVC CODE                   09000000
         AGO   .A26                                                     09100000
.A23     ANOP                                                           09200000
&TAG     DC    C'020'                   CLOSE SVC CODE                  09300000
         AGO   .A26                                                     09400000
.A24     ANOP                                                           09500000
&TAG     DC    C'023'                   TCLOSE SVC CODE                 09600000
         AGO   .A26                                                     09700000
.A25     ANOP                                                           09800000
&TAG     DC    C'055'                   EOV SVC CODE                    09900000
.*                                                                      10000000
.A26     DC    AL1((&NAME-&SYSECT)/8)     DOUBLE WORDS TO XCTL TABLE    10100000
         ORG   &SYSECT+&LENGTH-*+&SYSECT ASM ERROR IF MODULE TOO LONG   10200000
         MEND                                                           10300000
