         TITLE 'SCAN I/II  IEX11000'                                    00020000
*STATUS: CHANGE LEVEL 000                                             * 00040000
*                                                                     * 00060000
*FUNCTION/OPERATION: TO TRANSFORM THE SOURCE PROGRAM TO               * 00080000
*   MODIFICATION LEVEL 1, WHICH INCLUDES A ONE FOR ONE TRANSLATION OF * 00100000
*   ALL CHARACTERS, THE REPLACEMENT OF ALL ALGOL DELIMITERS BY ONE    * 00120000
*   BYTE OPERATORS AND THE REMOVAL OR MODIFICATION OF ALL             * 00140000
*   DECLARATIONS.                                                     * 00160000
*   TO TABULATE AND CLASSIFY ALL VALID IDENTIFIERS.                   * 00180000
*   TO ASSIGN A SERIAL PROGRAM BLOCK NUMBER TO ALL BLOCKS AND         * 00200000
*   PROCEDURES AND A SERIAL GROUP NUMBER TO ALL BLOCKS, PROCEDURES    * 00220000
*   AND FOR STATEMENTS.                                               * 00240000
*   TO RECOGNIZE SYNTACTICAL ERRORS IN THE SOURCE PROGRAM AND TO      * 00260000
*   GENERATE APPROPRIATE ERROR PATTERNS.                              * 00280000
*   TO PRINT A LISTING ON SYSPRINT OF THE SOURCE PROGRAM IF OPTION    * 00300000
*   'SOURCE' IS SPECIFIED.                                            * 00320000
*   TO PREPARE TABLES TO BE USED BY THE SUCCEEDING PHASES. THE TABLES * 00340000
*   ARE PBTAB1, GROUPTABLE, AND SCOPETABLE.                           * 00360000
*                                                                     * 00380000
*ENTRY POINTS:                                                        * 00400000
*        IEX11000   SCAN I/II    XCTL EP=IEX11000                     * 00420000
*                                                                     * 00440000
*INPUT: THE SOURCE PROGRAM IS READ IN FROM SYSIN.                     * 00460000
*                                                                     * 00480000
*OUTPUT: THE SOURCE PROGRAM, MODIFICATION LEVEL 1, IS WRITTEN ON      * 00500000
*   SYSUT1.                                                           * 00520000
*   AN ITAB RECORD IS WRITTEN FOR EACH BLOCK ON SYSUT3.               * 00540000
*   ESD CARD FOR THE OBJECT MODULE AND TXT CARDS FOR THE CONSTANTS 0  * 00560000
*   THROUGH 15 AND THE STRINGS IN THE CONSTANT POOL ARE WRITTEN ON    * 00580000
*   SYSLIN AND OR SYSPUNCH IF THE OPTIONS 'LOAD' AND OR 'DECK' IS     * 00600000
*   SPECIFIED.                                                        * 00620000
*   THE SOURCE PROGRAM IS LISTED ON SYSPRINT IF OPTION 'SOURCE' IS    * 00640000
*   SPECIFIED.                                                        * 00660000
*                                                                     * 00680000
*EXITS-NORMAL: CONTROL IS GIVEN TO ITAB MANIPULATION, XCTL EP=IEX20000* 00700000
*   IF NO TERMINATING ERROR HAS BEEN DETECTED.                        * 00720000
*                                                                     * 00740000
*EXITS-ERROR: IF A TERMINATING ERROR HAS BEEN DETECTED CONTROL IS     * 00760000
*   GIVEN TO THE ERROR MESSAGE HANDLING PHASE        XCTL  EP=IEX21000* 00780000
*                                                                     * 00800000
*EXTERNAL ROUTINES: THE PRINT ROUTINE IN IEX00 IS USED.               * 00820000
*                                                                     * 00840000
*TABLES/WORKAREAS:                                                    * 00860000
*   BPRTAB    BRANCH ADDRESS TABLE                                    * 00880000
*   TESTTABL  FOR MAINLOOP SCANNING                                   * 00900000
*   RETRANS   FOR TRANSLATION FROM INTERNAL TO EBCDIC CHARACTER SET   * 00920000
*   COMTABLE  USED BY COMMENT PROGRAM                                 * 00940000
*   STRTABLE  USED BY STRING PROGRAM                                  * 00960000
*   BTABLE    USED BY BLANK PROGRAM                                   * 00980000
*   KEYTAB    USED BY TRANSOP                                         * 01000000
*   PTTABLE   USED BY POINT AND POINT IN LIST PROGRAMS                * 01020000
*   TRLTABLE  FOR TRANSLATION FROM EBCDIC TO INTERNAL CHARACTER SET   * 01040000
*   KOPOOL    CONTAIN THE CONSTANTS 0 THROUGH 15                      * 01060000
*   ATABLE    USED BY APOSTROF                                        * 01080000
*   SCTAB     USED TO SAVE THE STARTING SC COUNTER FOR THE BLOCKS     * 01100000
*   WITAB     USED FOR THE ALGOL DELIMITERS                           * 01120000
*   LITAB     FOR DISPLACEMENTS TO WITAB                              * 01140000
*   DELPRGTB  BRANCH ADDRESS TABLE AFTER A DELIMITER HAS BEEN FOUND   * 01160000
*   ARTABLE   USED BY LIST PROGRAM                                    * 01180000
*   WA        80 BYTE WORKAREA WITH 17 PRECEEDING CHARACTERS, USED FOR* 01200000
*             INPUT RECORDS. THE 17 EXTRA BYTES USED TO OVERLAP       * 01220000
*             BETWEEN ONE RECORD AND THE NEXT ONE.                    * 01240000
*   STACK     USED FOR THE SCOPE STRUCTURE HANDLING                   * 01260000
*   ITAB      USED TO TABULATE ALL VALID IDENTIFIERS                  * 01280000
*   SAVEPRT   DUMMY PRINTAREA. USED TO PICK UP STRINGS FROM IN EBCDIC * 01300000
*             FORM IF THE OPTION 'NOSOURCE IS SPECIFIED.              * 01320000
*                                                                     * 01340000
*ATTRIBUTES: NONE                                                     * 01360000
*                                                                     * 01380000
*NOTES: CHARACTER CODE DEPENDENCE                                     * 01400000
*   IF THE SOURCE PROGRAM IS IN ISO CODE A SCAN IS MADE IN THE        * 01420000
*   PROGRAM CIB TO EXCHANGE THE CHARACTERS   4C, 7B, 7C, 6C, 50,      * 01440000
*   WITH THE EBCDIC CHARACTERS               5D, 7E, 7D, 4D, 4E.      * 01460000
*   THEN WHEN THE SOURCE PROGRAM IN WA IS IN EBCDIC FORM IT IS        * 01480000
*   TRANSFERRED TO THE PRINTBUFFER, POSSIBLY THE DUMMY PRINTAREA.     * 01500000
*   THE SOURCE PROGRAM IN WA IS THEN TRANSLATED TO INTERNAL CODE BY   * 01520000
*   MEANS OF THE HEXADECIMAL TABLE TRLTABLE.                          * 01540000
*   THE INVERS TABLE, TRANSLATING FROM INTERNAL TO EBCDIC CODE IS     * 01560000
*   CALLED RETRANS AND IS IN CHARACTER FROM.                          * 01580000
*   THE TRANSFER OF PRECOMPILED AND CODE PROCEDURE NAMES, THE         * 01600000
*   TRANSFER OF STRINGS AND CONSTANTS TO THE CONSTANT POOL AND THE    * 01620000
*   OPERATION OF THE ROUTINE GENERATE DEPENDS ON AN INTERNAL          * 01640000
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 01660000
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.                        01680000
*   THE OPERATION OF THE OTHER PARTS DOES NOT DEPEND UPON A           * 01700000
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET. * 01720000
*                                                                     * 01740000
*   THIS MODULE IS ONLY INTENDED TO BE EXECUTED IN CONNECTION         * 01760000
*   WITH THE OTHER MODULES OF THE ALGOL COMPILER. IN PARTICULAR IT    * 01780000
*   REQUIRES THE COMMON WORKAREA.                                     * 01800000
*                                                                     * 01820000
*                                                                     * 01840000
*                                                                     * 01860000
         SPACE 2                                                        01880000
         SPACE 2                                                        01900000
         SPACE 2                                                        01920000
*   CONTROL SECTION 1 CONTAINS:                                         01940000
*                               INITIALIZATION                          01960000
*                               MAINLOOP AND ITS SUBPROGRAMS            01980000
*                                       BLANK                           02000000
*                                       TRANSOP (*,/,(,>,<,NOT,)        02020000
*                                       RIGHTPAR                        02040000
*                                       POINT                           02060000
*                                       COLON                           02080000
*                                            LABEL                      02100000
*                                            LETDEL                     02120000
*                                            ASSIGN                     02140000
*                                       APOSTROPHE                      02160000
*                                            SCALE                      02180000
*                                            BLKAPOS                    02200000
*                                            ZETAAPOS                   02220000
*                                            NPAFAPO (NOT PERMITTED)    02240000
*                               SOME GENERAL ROUTINES                   02260000
*                                       STATE  (STATEMENT PROGRAM)      02280000
*                                       ERROR ROUTINES                  02300000
*                                       ITABCLEA                        02320000
*                                       IDCHCK1                         02340000
*                                       FINDSEMCO                       02360000
*                             AND TABLES AND CONSTANTS OUTSIDE CWA      02380000
*   CONTROL SECTION 2 CONTAINS:                                         02400000
*                               COB (CHANGE OUTPUT BUFFER)              02420000
*                               CIB (CHANGE INPUT BUFFER)               02440000
*                               DELIMITER                               02460000
*                                       EROUT (DELIMITER ERROR ROUTINE) 02480000
*                             NORMAL (/ OR AND NOT STEP LESS            02500000
*                                     IMPL UNTIL WHILE POWER EQUIU      02520000
*                                     NOTLESS GREATER NOTEQUAL          02540000
*                                     NOT GREATER)                      02560000
*                                       BOLCON ('TRUE', 'FALSE')        02580000
*                                       GIF (GOTO, IF)                  02600000
*                                       TED (THEN, ELSE, DO)            02620000
*                                       BEGIN                           02640000
*                                       BEGI (BLOCKHEAD)                02660000
*                                       END                             02680000
*                                            FOREND                     02700000
*                                            PBLCKEND                   02720000
*                                       COM (COMMENT)                   02740000
*                                       FOR                             02760000
*                                       TYPE ( REAL, INTEGER, BOOLEAN)  02780000
*                                  IER (IDENT. ERROR ROUTINE)           02800000
*                                       CODE                            02820000
*   CONTROL SECTION 3 CONTAINS:                                         02840000
*                               IDCHECK (SPECIFIED IDENTIFIERS)         02860000
*                               VALUE                                   02880000
*                               TYPEARRAY                               02900000
*                                       ARRAY                           02920000
*                               TRATE (ARRAY AND SWITCH LIST)           02940000
*                                       PONTLST                         02960000
*                                       SEMCLST                         02980000
*                                       LEFTPARL                        03000000
*                                       RIGHTPARL                       03020000
*                                       SLASHLST                        03040000
*                                       COMMALST                        03060000
*                                       COLONLST                        03080000
*                               SWITCH                                  03100000
*                               STRING                                  03120000
*                               TYPPROC                                 03140000
*                               PROCEDURE                               03160000
*                                     PROCEDEL (PROC. LETTERSTRING)     03180000
*                               ENDMISSIN (UNBALLANCED BEGIN END COUNT) 03200000
*   CONTROL SECTION 4 CONTAINS:                                         03220000
*                               TERMINATION                             03240000
*                                                                       03260000
*                                                                       03280000
*                                                                       03300000
IEX11000 START                                                          03320000
* RELEASE 19 CHANGES                                                    03325019
* 777400                                                         A22571 03330019
*                                                                A28230 03335019
*                                                                A28251 03337019
* RELEASE 20 CHANGES                                                    03337300
* 112800,348000                                                  A32949 03337600
REG0     EQU   0                                                        03340000
REGI     EQU   1                  INPUT POINTER                         03360000
K        EQU   2                                                        03380000
REGZ     EQU   2                                                        03400000
EAP      EQU   3                  OUTPUT POINTER                        03420000
REGM     EQU   4                  POINTS TO FIRST APOSTROPHE            03440000
KEY      EQU   4                  TRANSOP REGISTER                      03460000
REGE     EQU   4              LINKREGISTER FOR PRGBLOCKEND              03480000
REGF     EQU   4              LINKREGISTER FOR FDREND                   03500000
REGB     EQU   6                  RETURN REG. FROM ERROR ROUTINES       03520000
IN       EQU   7                  ITAB POINTER                          03540000
REGN     EQU   7                                                        03560000
REG7     EQU   7                                                        03580000
REG8     EQU   8                  BASE REGISTER                         03600000
REGX     EQU   9                  RETURN REGISTER FROM BEGI             03620000
REG9     EQU   9                                                        03640000
REGIX    EQU   9                  RETURN REG. FROM CIB                  03660000
REGA     EQU   9                                                        03680000
RET      EQU   10                 TESTLOOP AND LIST MAIN RETURN REG.    03700000
REG11    EQU   11                 BASE REGISTER                         03720000
REGPS    EQU   12                 SPECIFICATION HANDLING                03740000
REG12    EQU   12                                                       03760000
REGOX    EQU   12                 RETURN REG. FROM COB                  03780000
PIN      EQU   14                 LABEL POINTER                         03800000
REGL     EQU   14                                                       03820000
REGY     EQU   15                                                       03840000
REGH     EQU   15                                                       03860000
         SPACE 2                                                        03880000
*****   INITIALIZATION   ********************************************** 03900000
*                   GETMAIN FOR KOPOOL                                  03920000
*                                STACK                                  03940000
*                                ITABBUF                                03960000
*                                OUTPUTAREA2                            03980000
*                                ITAB                                   04000000
*                   ALPHA  00 IS PUT IN STACK AND SP (STACK POINTER)    04020000
*                        IS MADE TO POINT TO NEXT BYTE                * 04040000
*                   ADDRESS OF THE FIRST O/P AREA IS TAKEN FROM CWA     04060000
*                        AND PUT IN ADDARI. THE ADDRESS OF SECOND       04080000
*                        O/P AREA (FROM GETMAIN) IS PUT IN ADDARI+4     04100000
*                   AITAB, LIGP, LPBP, AITAB AND ELI ARE INITILIZED IN* 04120000
*                        ITAB. HEADLINE FOR PB0 IS CREATED.           * 04140000
*                   AITAB, LPBP, LIGP WILL POINT TO PB0 HEAD            04160000
*                   AITL TO NEXT FREE ENTRY                             04180000
*                   ELI TO LAST POSITION+1 OF ITAB                    * 04200000
*                   APE WILL POINT TO LAST POSSITION IN FIRST           04220000
*                        OUTPUT BUFFER                                  04240000
*                   WADDARI (CURRENT OUTPUT BUFFER) WILL POINT TO       04260000
*                        FIRST OUTPUT BUFFER                            04280000
*                   EAP (REGISTR 3) WILL POINT TO FIRST O/P BUFFER      04300000
*                   PRINTING OF HEADLINES IS INITILIZED IF SOURCE       04320000
*                        WAS SPECIFIED                                  04340000
*                   SWITCHES ARE SET TO ZERO                            04360000
*                   FIRST ENTRIES IN TABLES ARE SET TO ZERO             04380000
         SPACE 2                                                        04400000
         USING IEX11001,8                                               04420000
         USING IEX11002,11                                              04440000
         BALR  5,0                      GET BASE REGISTERS              04460000
         USING *,5                                                      04480000
         USING WORKAREA,13                                              04500000
         L     REG8,VIEX1                                               04520000
         L     REG11,VIEX2                                              04540000
         LA    REGOX,SLUT2                                              04560000
         ST    REGOX,ERET               INTERUPT BEFORE GETMAIN         04580000
         LH    REGI,FOURKA              KOPOOL                          04600000
         LA    REGI,1000(0,REGI)        STACK                           04620000
         A     REGI,SRCE1S              O/P BUFFER 1                    04640000
         A     REGI,ITAB10S             ITAB                            04660000
         LA    REGI,2000(0,REGI)        ITAB BUF                        04680000
         ST    REGI,POOLLEN             STORE TOTAL LENGTH              04700000
         LR    REG0,REGI                                                04720000
         GETMAIN R,LV=(0)               GET AREAS NEEDED                04740000
         ST    REGI,POOLLOC             SAVE LOCATION                   04760000
         LA    REGOX,ENDMISS       END OF DATA ADDRESS                  04780000
         ST    REGOX,EODIN                                              04800000
         LA    REGOX,EODADIN                                            04820000
         ST    REGOX,ERET               INTERUPT ADDRESS AFTER GETMAIN  04840000
         ST    REGI,AKOPOOL             ADDRESS OF KOPOOL               04860000
         LA    REGI,4095(0,REGI)                                        04880000
         MVC   1(4,REGI),KOPOOL         INITILIZE STACK                 04900000
         LA    REGI,2(0,REGI)                                           04920000
         ST    REGI,SP                  ADDRESS OF SECOND BYTE IN STACK 04940000
         LA    REGI,999(0,REGI)                                         04960000
         ST    REGI,AITABBUF            INITILIZE ITAB BUFFER           04980000
         LA    REGI,2000(0,REGI)                                        05000000
         ST    REGI,ADDARI+4                      OUTPUTAREA 2          05020000
         A     REGI,SRCE1S                                              05040000
         ST    REGI,AITAB                         ITAB                  05060000
         ST    REGI,LIGP                SURROUNDING GROUP ADDRESS       05080000
         ST    REGI,LPBP                            BLOCK ADDRESS       05100000
         MVI   0(REGI),X'00'       CLEAR FIRST TWO ITABENTRIES          05120000
         MVC   1(21,REGI),0(REGI)                                       05140000
         MVI   3(REGI),X'FF'       CONSTRUCT CONTINUATION               05160000
         MVI   5(REGI),X'2B'       LINE FOR PB0                         05180000
         LA    REGOX,11(0,REGI)                                         05200000
         ST    REGOX,AITL               ADDRESS OF FIRST FREE ENTRY     05220000
         A     REGI,ITAB10S                                             05240000
         ST    REGI,ELI            END OF ITAB                          05260000
         L     EAP,SRCE1ADD        ADD OF FIRST OUTPUT BUFFER           05280000
         A     EAP,SRCE1S                                               05300000
         BCTR  EAP,0                                                    05320000
         ST    EAP,APE                  END OF FIRST O/P BUFFER         05340000
         L     EAP,SRCE1ADD             OUTPUTAREAS' CONSTANTS          05360000
         MVC   ADDARI(4),SRCE1ADD                                       05380000
         MVC   WADDARI(4),ADDARI        CURRENT O/P AREA ADDRESS        05400000
         LA    REGOX,SAVEPRNT           APRNTAR IS INITILIZED WITH      05420000
         ST    REGOX,APRNTAR            DUMMY PRINTAREA ADDRESS         05440000
         MVI   PAGEHEAD+2,X'40'         CREATE HEADLINES                05460000
         MVC   PAGEHEAD+3(81),PAGEHEAD+2                                05480000
         MVC   PAGEHEAD+39(14),HDING1                                   05500000
         MVI   PAGEHEAD+92,X'02'                                        05520000
         MVI   PAGEHEAD+93,X'11'                                        05540000
         MVI   PAGEHEAD+94,X'40'                                        05560000
         MVC   PAGEHEAD+95(81),PAGEHEAD+94                              05580000
         MVC   PAGEHEAD+94(24),HDING2                                   05600000
         MVI   PAGEHEAD+186,X'FF'                                       05620000
         MVI   LINCNT,X'7F'                                             05640000
         BAL   REGIX,CIB                GET FIRST RECORD AND ADDRESS    05660000
*                                       OF FIRST PRINTAREA              05680000
         SR    REGZ,REGZ                                                05700000
         STC   REGZ,ONC                 USE REGZ TO ZERO COUNTERS       05720000
         STC   REGZ,DISP                AND SWITCHES                    05740000
         LA    REGOX,64            INITIAL VALUE FOR KOPOOL ASSAIGNMENT 05760000
         ST    REGOX,SPCLT                                              05780000
         STH   REGZ,IGC            ITABGROUPCOUNTER AND                 05800000
         ST    REGZ,MGESITL                                             05820000
         STC   REGZ,PBC            INITIAL VALUE OF PROGRAMBLOCKCOUNTER 05840000
         STC   REGZ,ONC           OUTPUTRECORDCOUNTER                   05860000
         STC   REGZ,BITS1          INITIAL VALUE OF SWITCHBITS          05880000
         STC   REGZ,BITS2                                               05900000
         STC   REGZ,BITS3                                               05920000
         STH   REGZ,SC                  INITIAL VALUE OF SC COUNTER     05940000
         STC   REGZ,FSN          INITIAL VALUE OF FSN                   05960000
         STC   REGZ,PBTAB1       INITIAL VALUE OF PB0                   05980000
         ST    REGZ,GPTAB+3             INITILIZE GROUP AND SCOUP TABLE 06000000
         STC   REGZ,SPTAB                                               06020000
         STC   REGZ,0(0,EAP)      FIRST BYTE IN FIRST OUTPUTRECORD      06040000
         ST    EAP,OPIN                                                 06060000
         ST    EAP,LAPIN                SET LABEL POINTERS              06080000
         STC   REGZ,OPIN+4                                              06100000
         LA    REGOX,GPTAB                                              06120000
         ST    REGOX,AGT                ADDRESS TO GROUPTABLE           06140000
         LA    REGOX,0                 MAKE                      A28251 06146019
         ST    REGOX,BRACKET                BRACKETCOUNTER ZERO  A28251 06152019
         L     REGOX,AITABBUF                                           06160000
         BCTR  REGOX,0                                                  06180000
         ST    REGOX,ATOPSTAK           HIGHEST BYTE IN STACK TO USE    06200000
         B     TESTLOOP                 GO TO START PROCESSING          06220000
         DS    0H                                                       06240000
MOVE     MVC   0(1,EAP),0(REGM)                                         06260000
         SPACE 3                                                        06280000
SAVE1    DS    7F                                                       06300000
SAVEPRNT DS    CL88                                                     06320000
         SPACE 2                                                        06340000
*****   BPRTAB   ****************************************************** 06360000
*                   CONTAINS ADDRESSCONSTANTS OF PROGRAMS UTILIZED BY   06380000
*                        TEST                                           06400000
*                        LIST                                           06420000
*                        POINT                                          06440000
*                        APOSTROF                                       06460000
*                        POINTLST                                       06480000
*                   THE ADDRESSES ARE PICKED UP WITH DISPLACEMENTS FROM 06500000
*                        TESTTABL                                       06520000
*                        ARTABLE                                        06540000
*                        PTTABLE                                        06560000
*                        ATABLE                                         06580000
*                        PTTABLE FOR POINTLST 56 IS ADDED TO DISP GIVEN 06600000
         SPACE 2                                                        06620000
         DS    0F                                                       06640000
BPRTAB   DS    0CL140                                                   06660000
         DC    4X'00'                                                   06680000
         DC    A(TRANSOP)                                               06700000
         DC    A(TRANSOP)                                               06720000
         DC    A(TRANSOP)                                               06740000
         DC    A(TRANSOP)                                               06760000
         DC    A(TRANSOP)                                               06780000
         DC    A(TRANSOP)                                               06800000
         DC    A(COLON)                COLON                            06820000
         DC    A(SEMCO)                SEMICOLON                        06840000
         DC    A(RIGHTPAR)                                              06860000
         DC    A(BLANK)                                                 06880000
         DC    A(ERR1)                                                  06900000
         DC    A(POINT)                                                 06920000
         DC    A(APOSTROF)                                              06940000
         DC    A(CIB)                                                   06960000
         DC    A(ASSIGN)                                                06980000
         DC    A(DECPOINT)                                              07000000
         DC    A(ERR5)             ERROR AFTER POINT                    07020000
         DC    A(BLKAPOS)              BLANK AFTER APOSTROPHE           07040000
         DC    A(NPAFTAPO)             NOT PERMITTED AFTER APOSTR       07060000
         DC    A(SCALE)                DIGIT OR SIGN AFTER APOSTROPHE   07080000
         DC    A(COLONLST)             COLON IN LIST                    07100000
         DC    A(SEMCLST)              SEMICOLON IN LIST                07120000
         DC    A(DELIMIT)              DELIMITER PROGRAM                07140000
         DC    A(ZETAAPO)              ZETA AFTER APOSTROPHE            07160000
         DC    A(EROUT)                ERROR (FROM W1,W2OR W3 TAB)      07180000
         DC    A(LEFTPARL)             LEFT PARENTHESIS IN LIST         07200000
         DC    A(RIGTPARL)             RIGHT PARENTHESIS IN LIST        07220000
         DC    A(PZETA)                ZETA AFTER POINT IN LIST         07240000
         DC    A(ASSIGN)               ASSIGNMENT POINT IN LIST         07260000
         DC    A(DECPOINT)             DECPOINT IN LIST                 07280000
         DC    A(ERR5A)            POINT ERROR IN LIST                  07300000
         DC    A(COMMALST)             COMMA IN LIST                    07320000
         DC    A(PONTLST)              POINT IN LIST                    07340000
         DC    A(SLASHLST)             SLASH IN LIST                    07360000
         DC    A(QUOTE)                QUOTE                            07380000
         DC    A(SEMC60)                                                07400000
         SPACE 2                                                        07420000
*****   TESTTABL ****************************************************** 07440000
*                   USED BY TEST - GIVES DISPLACEMENTS TO BPRTAB        07460000
         SPACE 2                                                        07480000
TESTTABL DS    0CL90                                                    07500000
         DC    2X'00'                                                   07520000
         DC    X'0408'                                                  07540000
         DC    2X'00'                                                   07560000
         DC    X'0C1C'                                                  07580000
         DC    3X'00'                                                   07600000
         DC    X'90'                                                    07620000
         DC    4X'00'                                                   07640000
         DC    X'001014'                                                07660000
         DC    13X'00'                                                  07680000
         DC    X'18'                                                    07700000
         DC    5X'00'                                                   07720000
         DC    X'24'                                                    07740000
         DC    4X'00'                                                   07760000
         DC    X'282C303438'                                            07780000
         DC    42X'00'                                                  07800000
         SPACE 2                                                        07820000
*****   RETRANS  ****************************************************** 07840000
*                   CONVERT TABLE FOR INTERNAL CODE TO EBCDIC           07860000
*                   USED BY CODE TO TRANSLATE PROCEDURE NAME            07880000
*                           PROCEDURE TO TRANSLATE PROCEDURE NAME FOR   07900000
*                                     ESD CARD IF PRECOMPILED SPECIFIED 07920000
         SPACE 2                                                        07940000
RETRANS  DS    0CL90                                                    07960000
         DC    C' '                                                     07980000
         DC    47C'"'                                                   08000000
         DC    C'0123456789'                                            08020000
         DC    6C'"'                                                    08040000
         DC    C'ABCDEFGHIJKLMNOPQRSTUVWXYZ'                            08060000
         SPACE 2                                                        08080000
*****   COMTABLE ****************************************************** 08100000
*                   USED BY COMMENT PROGRAM                             08120000
*                   TESTS FOR POINT, SEMICOLON, ZETA AND APOSTROPHE     08140000
*                   GIVES DISPLACEMENT TO PROGRAMS FROM COMCEE2+2       08160000
COMTABLE DS    0CL90                                                    08180000
         DC    11X'00'                                                  08200000
         DC    X'2A'                                                    08220000
         DC    33X'00'                                                  08240000
         DC    X'220E1E'                                                08260000
         DC    42X'00'                                                  08280000
         SPACE 2                                                        08300000
*****   STRTABLE ****************************************************** 08320000
*                   USED BY STRING PROGRAM. SCANS FOR APOSTROPHE OR   * 08340000
*                        ZETA                                           08360000
*                   GIVES DISPLACEMENTS TO BPRTAB                       08380000
         SPACE 2                                                        08400000
STRTABLE DS    0CL90         TRT-TABLE USED BY STRING-PROGRAM           08420000
         DC    46X'00'                                                  08440000
         DC    X'8C38'                                                  08460000
         DC    42X'00'                                                  08480000
         SPACE 2                                                        08500000
*****   BTABLE   ****************************************************** 08520000
*                   BLANK TABLES - SCANNES FOR FIRST NONBLANK CHARACTER 08540000
*                   USED BY BLANK                                       08560000
*                           BLKAPOS  BLANK AFTER APOSTROPHE             08580000
*                           READROUT IN TERMINATION                     08600000
         SPACE 2                                                        08620000
BTABLE   DS    0CL90                                                    08640000
         DC    4X'FF'                                                   08660000
         DC    2X'00'                                                   08680000
         DC    2X'FF'                                                   08700000
         DC    3X'00'                                                   08720000
         DC    X'FF'                                                    08740000
         DC    4X'00'                                                   08760000
         DC    3X'FF'                                                   08780000
         DC    13X'00'                                                  08800000
         DC    X'FF'                                                    08820000
         DC    X'00'                                                    08840000
         DC    2X'FF'                                                   08860000
         DC    X'00'                                                    08880000
         DC    2X'FF'                                                   08900000
         DC    5X'00'                                                   08920000
         DC    14X'FF'                                                  08940000
         DC    6X'00'                                                   08960000
         DC    26X'FF'                                                  08980000
         DS    0F                                                       09000000
         SPACE 2                                                        09020000
*****   KEYTAB   ****************************************************** 09040000
*                   USED BY TRANSOP                                     09060000
*                   BYTE 3 IS EXCPECTED BYTE, IF THAT ONE MATCHES CHAR. 09080000
*                        IN INPUT BYTE 1 IS PUT OUT OTHERWISE BYTE 2    09100000
*                   THE DISPLACEMENT FROM TESTTABL OR ATABLE IS USED  * 09120000
*                        TO GET THE APPROPRIATE ENTRY IN KEYTAB         09140000
*                   USED WHEN  *  FOUND      EXCPECTED  *               09160000
*                              /                        )               09180000
*                              (                        /               09200000
*                              <  LESS THAN             = EQUAL         09220000
*                              >  GREATER THAN          =               09240000
*                                NOT                   =               09260000
         SPACE 2                                                        09280000
KEYTAB   DS    0CL28                                                    09300000
         DS    CL4                                                      09320000
         DC    X'00050202'                                              09340000
         DC    X'00280326'                                              09360000
         DC    X'00080603'                                              09380000
         DC    X'00141110'                                              09400000
         DC    X'00151210'                                              09420000
         DC    X'00132010'                                              09440000
         SPACE 2                                                        09460000
*****   PTTABLE  ****************************************************** 09480000
*                   USED BY POINT                                       09500000
*                            PONTLST                                    09520000
*                   GIVES DISPLACEMENTS TO BPRTAB                       09540000
*                   WHEN USED BY PONTLST 56 IS ADDED TO ORIGINAL DISP.  09560000
         SPACE 2                                                        09580000
PTTABLE  DS    0CL90                                                    09600000
         DC    4X'44'                                                   09620000
         DC    2X'00'                                                   09640000
         DC    2X'44'                                                   09660000
         DC    3X'00'                                                   09680000
         DC    X'44'                                                    09700000
         DC    4X'00'                                                   09720000
         DC    X'3C'                                                    09740000
         DC    2X'44'                                                   09760000
         DC    13X'00'                                                  09780000
         DC    X'44'                                                    09800000
         DC    X'00'                                                    09820000
         DC    2X'44'                                                   09840000
         DC    X'00'                                                    09860000
         DC    X'2044'                                                  09880000
         DC    5X'00'                                                   09900000
         DC    X'441C4438'                                              09920000
         DC    10X'40'                                                  09940000
         DC    6X'00'                                                   09960000
         DC    26X'44'                                                  09980000
         SPACE 2                                                        10000000
*****   TRLTABLE ****************************************************** 10020000
*                   USED IN CIB TO TRANSLAT FROM EBCDIC TO INTERNAL     10040000
*                        CODE                                           10060000
         SPACE 2                                                        10080000
TRLTABLE DS    0CL256                                                   10100000
         DC    64X'2C'                                                  10120000
         DC    X'2B'                                                    10140000
         DC    10X'2C'                                                  10160000
         DC    X'2D1106002223'                                          10180000
         DC    11X'2C'                                                  10200000
         DC    X'02260B200103'                                          10220000
         DC    9X'2C'                                                   10240000
         DC    X'25'                                                    10260000
         DC    2X'2C'                                                   10280000
         DC    X'12'                                                    10300000
         DC    11X'2C'                                                  10320000
         DC    X'07'                                                    10340000
         DC    2X'2C'                                                   10360000
         DC    X'2E10'                                                  10380000
         DC    66X'2C'                                                  10400000
         DC    X'404142434445464748'                                    10420000
         DC    7X'2C'                                                   10440000
         DC    X'494A4B4C4D4E4F5051'                                    10460000
         DC    8X'2C'                                                   10480000
         DC    X'5253545556575859'                                      10500000
         DC    6X'2C'                                                   10520000
         DC    X'30313233343536373839'                                  10540000
         DC    6X'2C'                                                   10560000
         SPACE 2                                                        10580000
*****   KOPOOL   ****************************************************** 10600000
*                   KEEPS THE CONSTANTS 0 THROUGH 15                    10620000
*                   THE CONSTANS ARE USED WITHIN SCAN 1/2 FOR           10640000
*                        CALCULATION AND ARE THEN INSERTED AS           10660000
*                        THE FIRST 64 BYTES OF THE CONSTANT POOL        10680000
         SPACE 2                                                        10700000
KOPOOL   DC    F'0'                                                     10720000
         DC    F'1'                                                     10740000
         DC    F'2'                                                     10760000
         DC    F'3'                                                     10780000
         DC    F'4'                                                     10800000
         DC    F'5'                                                     10820000
         DC    F'6'                                                     10840000
         DC    F'7'                                                     10860000
         DC    F'8'                                                     10880000
         DC    F'9'                                                     10900000
         DC    F'10'                                                    10920000
         DC    F'11'                                                    10940000
         DC    F'12'                                                    10960000
         DC    F'13'                                                    10980000
         DC    F'14'                                                    11000000
         DC    F'15'                                                    11020000
         SPACE 2                                                        11040000
*****   ATABLE   ****************************************************** 11060000
*                   USED BY THE APOSTROPHE PROGRAM                      11080000
*                   GIVES DISPLACEMENTS TO BPRTAB                       11100000
         SPACE 2                                                        11120000
ATABLE   DS    0CL90                                                    11140000
         DC    2X'50'                                                   11160000
         DC    X'64'                                                    11180000
         DC    X'00'                                                    11200000
         DC    2X'00'                                                   11220000
         DC    X'0064'                                                  11240000
         DC    3X'00'                                                   11260000
         DC    X'64'                   SEMICOLON                 A32949 11280000
         DC    4X'00'                                                   11300000
         DC    3X'64'                                                   11320000
         DC    13X'00'                                                  11340000
         DC    X'64'                                                    11360000
         DC    X'00'                                                    11380000
         DC    2X'64'                                                   11400000
         DC    X'00'                                                    11420000
         DC    2X'64'                                                   11440000
         DC    4X'00'                                                   11460000
         DC    X'484C645C60'                                            11480000
         DC    10X'50'                                                  11500000
         DC    32X'00'                                                  11520000
         SPACE 2                                                        11540000
*****   CONSTANTS  **************************************************** 11560000
TWOFIVEK DC    F'25000'                                                 11580000
TWOK     DC    F'2000'                                                  11600000
FOURK    DC    F'4095'                                                  11620000
FOURKA   DC    H'4096'                                                  11640000
DOUBLE   DC    D'0'                                                     11660000
D256     DC    F'256'                                                   11680000
INT      DC    X'2EC8030000'           COMMON PART OF THE INTERNAL      11700000
*                                  NAMES OF BOOLEAN CONSTANTS           11720000
ENDCOUNT DC    H'0'                                                     11740000
ERRSAVE  DS    4F                                                       11760000
SAVAR    EQU   ERRSAVE                                                  11780000
VIEX1    DC    A(IEX11001)                                              11800000
VIEX2    DC    A(IEX11002)                                              11820000
VIEX14   DC    V(IEX11003)                                              11840000
ESDPARAM DC    8C' '                                                    11860000
HDING1   DC    C'SOURCE PROGRAM'                                        11880000
HDING2   DC    C' SC     SOURCE STATEMENT'                              11900000
OPINCHAR DC    C'0'                                                     11920000
BRACKET  DS    F                       BRACKET COUNTER           A28251 11930019
         SPACE 2                                                        11940000
         SPACE 2                                                        11960000
*****   MAINLOOP ****************************************************** 11980000
*                                                                       12000000
*              SCANS  THE INPUT STREAM                                  12020000
*              EVERYTHING PRECEDING THE FIRST REAL ALGOL WORD WILL BE   12040000
*              SKIPED WITH THE HELP OF BITS2,X'20'                      12060000
         SPACE 2                                                        12080000
TESTLOOP BALR  RET,0                                                    12100000
         LR    REGIX,RET          RETURNADDRESS FOR CIBPROGRAM          12120000
         LR    REGM,REGI                                                12140000
         SR    REGZ,REGZ                                                12160000
         TRT   0(73,REGI),TESTTABL                                      12180000
         TM    BITS2,X'20'              Q. FIRST BEGIN FOUND            12200000
         BZ    FIRSTSTR                 NO                              12220000
CONT     LR    REGH,REGI                FIND LENGTH OF SCANNED BYTES    12240000
         SR    REGH,REGM                                                12260000
         BZ    SUBROUT                                                  12280000
         BAL   REGOX,COB                                                12300000
         LA    REG0,0(REGH,EAP)                                         12320000
         C     REG0,APE                 Q. SPACE LEFT IN O/P BUFFER     12340000
         BH    MSBLOOP                                                  12360000
         BCTR  REGH,0                                                   12380000
         EX    REGH,MOVE                MOVE SCANNED BYTES              12400000
         LR    EAP,REG0           INCREASE OUTPUTPOINTER                12420000
SUBROUT  L     REGB,BPRTAB(REGZ)                                        12440000
         BCR   15,REGB                  BRANCH TO PROGRAM               12460000
*                             MSBLOOP-  USED WHEN SCANNED BYTES HAS     12480000
*                                       TO BE PLACED IN TWO O/P AREAS   12500000
MSBLOOP  L     REGB,APE                                                 12520000
         SR    REGB,EAP                                                 12540000
         BCTR  REGB,0                                                   12560000
         EX    REGB,MOVE          MOVE TO FIRST O/P AREA                12580000
         LA    EAP,1(REGB,EAP)                                          12600000
         BAL   REGOX,COB+8        CHANGE O/P BUFFER                     12620000
         LA    REGOX,1(REGB,REGM)                                       12640000
         SR    REGH,REGB                                                12660000
         BCTR  REGH,0                                                   12680000
         BCTR  REGH,0                                                   12700000
         EX    REGH,MOVERST       MOVE TO 2ND O/P BUFFER                12720000
         LA    EAP,1(REGH,EAP)                                          12740000
         B     SUBROUT            RETURN                                12760000
         CNOP  0,4                                                      12780000
MOVERST  MVC   0(1,EAP),0(REGOX)                                        12800000
FIRSTSTR CLI   0(REGI),X'2E'       Q APOSTROPHY                         12820000
         BE    APOSTROF                                                 12840000
         CLI   0(REGI),X'2F'         Q. ZETA                            12860000
         BE    CIB                                                      12880000
         LA    REGI,1(0,REGI)           IF NEITHER- CONTINUE SCANNING   12900000
         B     TESTLOOP                                                 12920000
         SPACE 2                                                        12940000
*****   BLANK    ****************************************************** 12960000
*              SCANS   TO THE NEXT NONBLANK CHARACTER                   12980000
*              ALL BLANK CHARACTER WILL BE SKIPPED                      13000000
*              USED BY MAIN LOOP AND ARRAYLIST                          13020000
         SPACE 2                                                        13040000
BLANK    LA    REGI,1(0,REGI)           INCREASE INPUTPOINTER           13060000
         CLI   0(REGI),X'2B'            COMPARE BLANK                   13080000
         BCR   7,RET                    IF NO , RETURN                  13100000
         LA    REGI,1(0,REGI)           IF YES, INCREASE INPUTPOINTER   13120000
         SR    REGZ,REGZ                                                13140000
         TRT   0(73,REGI),BTABLE        SCAN INPUT TO NEXT DELIMITER    13160000
         BCR   15,RET                   RETURN                          13180000
         SPACE 2                                                        13200000
*****   TRANSOP  ****************************************************** 13220000
*                                                                       13240000
*              CHECKS THE NEXT BYTE IN THE INPUT INPUTAREA AGAINS A KEY 13260000
*              I.E. IF ( FOUND, NEXT BYTE WILL BE CHECKED FOR /, IF A   13280000
*              SLASH IS FOUND A LEFT SQUARE BRACKET WILL BE TRANSFERED  13300000
*              OTHERWISE A (                                            13320000
*              USED BY MAIN LOOP AND ARRAYLIST                          13340000
         SPACE 2                                                        13360000
TRANSOP  LA    KEY,KEYTAB(REGZ)         GET CORRECT ENTRY IN TABLE      13380000
         CNOP  0,4                                                      13400000
INCR     LA    REGI,1(0,REGI)                                           13420000
         CLC   0(1,REGI),3(KEY)      Q. INPUT EQUAL EXPECTED ONE        13440000
         BE    TROE                     YES TAKE SUBSTITUTE CHAR.       13460000
         CLI   0(REGI),X'2B'      Q. BLANK                              13480000
         BE    INCR                                                     13500000
         CLI   0(REGI),X'2F'      Q. ZETA                               13520000
         BNE   TRONE              IF NEITHER TAKE CHAR. IN I/P          13540000
         LA    REGIX,INCR+4                                             13560000
         BC    15,CIB                                                   13580000
TRONE    BAL   REGOX,COB           CHECK IF O/P AREA FILLED             13600000
         MVC   0(1,EAP),2(KEY)          TAKE CHAR FOUND IN INPUT        13620000
         LA    EAP,1(0,EAP)                                             13640000
         BCR   15,RET             RETURN                                13660000
TROE     BAL   REGOX,COB           CHECK IF O/P AREA FILLED             13680000
         MVC   0(1,EAP),1(KEY)          TAKE SUBSTITUE CHAR FROM TABLE  13700000
         L     REGOX,BRACKET                                     A28251 13702019
         TM    0(EAP),X'28'            IS IT RIGHT BRACKET       A28251 13704019
         BC    14,TSTMORE              NO                        A28251 13706019
         BCTR  REGOX,0                 YES  SUBTRACT 1 FROM CTR  A28251 13708019
         BC    15,NOUPDAT                                        A28251 13710019
TSTMORE  TM    0(EAP),X'08'            IS IT LEFT BRACKET        A28251 13712019
         BC    14,NOUPDAT              NO                        A28251 13714019
         LA    REGOX,1(REGOX)          YES  ADD 1 TO CTR         A28251 13716019
NOUPDAT  ST    REGOX,BRACKET                                     A28251 13718019
         LA    EAP,1(0,EAP)                                             13720000
         LA    REGI,1(0,REGI)                                           13740000
         BCR   15,RET             RETURN                                13760000
         SPACE 2                                                        13780000
*****   RIGHTPAR ****************************************************** 13800000
*              INSERTS A ) IN O/P, SETS THE LABEL POINTERS              13820000
         SPACE 2                                                        13840000
RIGHTPAR BAL   REGOX,COB           CHECK IF O/P AREA FILLED             13860000
         MVI   0(EAP),X'26'        TRANSFER ) TO OUTPUTBUFFER           13880000
         ST    EAP,OPIN            NOTE ITS POSITION                    13900000
         MVI   OPINCHAR,X'26'                                           13920000
         MVC   OPIN+4(1),ONC       AND THE OUTPUTRECORDNUMBER           13940000
         LA    EAP,1(0,EAP)                                             13960000
         ST    EAP,LAPIN           NOTE POSITION WHERE LETTERSTRING     13980000
         LA    REGI,1(0,REGI)      MAY START                            14000000
         B     TESTLOOP                                                 14020000
         SPACE 2                                                        14040000
*****   POINT    ****************************************************** 14060000
*              SCANS FOR : DECPOINT                                     14080000
*                          ERROR                                        14100000
*                          COLON                                        14120000
*                          SEMICOLON                                    14140000
*                          ASSIGN                                       14160000
*              USED BY MAIN LOOP AND ARRAYLIST                          14180000
         SPACE 2                                                        14200000
POINT    LA    REGI,1(0,REGI)           SCAN SOURCESTRING               14220000
         CNOP  0,4                                                      14240000
         LA    REGIX,*            RETURNADDRESS FOR CIBPROGRAM          14260000
         SR    REGZ,REGZ                                                14280000
         TRT   0(73,REGI),PTTABLE       TO NEXT DELIMITER               14300000
         L     REGB,BPRTAB(REGZ)        BRANCH TO SUITABLE              14320000
         BCR   15,REGB                  SUBROUTINE                      14340000
         SPACE 2                                                        14360000
*****   DECPOINT ****************************************************** 14380000
*              TRANSFERS A DECIMAL POINT                                14400000
         SPACE 2                                                        14420000
DECPOINT BAL   REGOX,COB           CHECK IF O/P AREA FILLED             14440000
         MVI   0(EAP),X'3E'             TRANSFER DECIMALPOINT           14460000
         LA    EAP,1(0,EAP)                                             14480000
         BCR   15,RET                                                   14500000
         SPACE 2                                                        14520000
*****   ASSIGN   ****************************************************** 14540000
*              TRANSFERS A ASSIGN CHAR TO O/P. RETURNS VIA STATEMENT    14560000
         SPACE 2                                                        14580000
ASSIGN   BAL   REGOX,COB           CHECK IF O/P AREA FILLED             14600000
         MVI   0(EAP),X'16'        TRANSFER .= TO OUTPUTBUFFER          14620000
         LA    REGI,1(0,REGI)      INCREASE INPUT- AND                  14640000
         LA    EAP,1(0,EAP)        OUTPUTPOINTER                        14660000
         BC    15,STATE            BRANCH TO STATEMENT PROGRAM          14680000
         SPACE 2                                                        14700000
*****   STATE    ****************************************************** 14720000
*                                                                       14740000
*                   CHECKS WITH PROBIT IF FIRST LABEL, FOR, IF, GOTO    14760000
*                   OR ASSIGN STATMENT AFTER A PROCEDURE                14780000
*                   CHECKS THAT ALL PARAMETERS HAVE BEEN SPECIFIED      14800000
*                   TURNS OFF THE PROBIT                                14820000
*                   AND THE BEGBIT, POSSIBLE PROCEEDING BEGIN WILL BE   14840000
*                   COMPOOND BEGIN                                      14860000
         SPACE 2                                                        14880000
STATE    NI    BITS1,X'7F'              BEGBIT = 0                      14900000
         L     REGY,SP                                                  14920000
         CLI   0(REGY),X'0C'            Q. PROC IN STACK                14940000
         BCR   7,RET               IF NO.RETURN                         14960000
         MVI   0(REGY),X'14'                                            14980000
         NI    BITS1,X'BF'         PROBIT.=0                            15000000
         CLI   PZ,X'00'                 Q. ALL PARAMETERS SPECIFIED     15020000
         BCR   8,RET                    YES RETURN                      15040000
         BAL   REGOX,ERROR10            NO- GENERATE E10                15060000
         BCR   15,RET             RETURN                                15080000
         SPACE 2                                                        15100000
*****   APOSTROF ****************************************************** 15120000
*              SCANS FOR : SCALE                                        15140000
*                                 BLANK                                 15160000
*                               ZETA                                    15180000
*                               NOT PERMITTED                           15200000
*                               ONE MORE APOSTROPHE (DELIMITER)         15220000
*                   REGM WILL POINT TO THE APOSTROPHE                   15240000
*                   USED BY TESTLOOP AND LIST                           15260000
         SPACE 2                                                        15280000
APOSTROF MVI   FBYTE,X'00'              ZEROSET FBYTE                   15300000
ENTRAPR  LR    REGM,REGI          REGM WILL POINT TO FIRST APOSTROPHE   15320000
         LA    REGI,1(0,REGI)                                           15340000
         BALR  REGIX,0                                                  15360000
         SR    REGZ,REGZ                                                15380000
         TRT   0(73,REGI),ATABLE   SOURCESTRING IS SCANNED TO THE NEXT  15400000
         L     REGB,BPRTAB(REGZ)   SIGNIFICANT DELIMITER AND THE        15420000
         BCR   15,REGB             SUITABLE SUBROUTINE SELECTED         15440000
         SPACE 2                                                        15460000
*****   SCALE    ****************************************************** 15480000
*                CORRECT ONLY DIRECT AFTER TESTLOOP OR LIST             15500000
*                CHECK THAT THE APOSTROPHE IS ONLY ONE CHAR. IN FRONT   15520000
*                    OF DIGIT                                           15540000
         SPACE 2                                                        15560000
SCALE    TM    FBYTE,X'FF'                                              15580000
         BO    COMCEE2            COMMENT UNDER PROCESS                 15600000
         BM    TYPESPEC           DECLARATION UNDER PROCESS             15620000
SCALEOK  LR    REGB,REGI                                                15640000
         TM    BITS2,X'20'        Q. PROGRAM STARTED YET                15660000
         BZ    TESTLOOP           NO - RETURN                           15680000
         BCTR  REGB,0                                                   15700000
         CLI   0(REGB),X'2E'  Q  APOSTOF ONE BYTE BEFORE SIGN OR DIGIT  15720000
         BNE   EROUT               IF NO,BRANCH TO ERROR-ROUTINE        15740000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             15760000
MOVETEN  MVI   0(EAP),X'3F'        MOVE SCALEFACTOR TO OUTPUT RECORD    15780000
         LA    EAP,1(0,EAP)        INCREASE OUTPUT- AND                 15800000
         BCR   15,RET              RETURN                               15820000
         SPACE 2                                                        15840000
*****   BLKAPOS  ****************************************************** 15860000
*                   SHIFT THE BLANK OR BLANKS AWAY AND MOVES THE        15880000
*                   APOSTROPHE AND VALID CHARACTERS UP TO THE RIGHT     15900000
*                   SETS REGM TO POINT NEW LOCATION OF THE              15920000
*                   APOSTROPHE                                          15940000
*                   USED BY MAINLOOP AND INDIRECT BY THE ARRYLIST       15960000
*                          AND THE NPAFTAPO                             15980000
         SPACE 2                                                        16000000
BLKAPOS  LR    REGH,REGI           NOTE POSITION OF FIRST BLANK.        16020000
         TRT   0(73,REGI),BTABLE                                        16040000
         LR    REGB,REGI           COMPUTE  NUMBER OF BLANKS .          16060000
         SR    REGB,REGH           NUMBER OF BLANKS IN REGB .           16080000
         LR    REGL,REGH                                                16100000
         SR    REGL,REGM                                                16120000
         C     REGL,KOPOOL+44      Q BYTES EXEED THE LIMIT ALLREADY     16140000
         BH    EROUT                                                    16160000
         BCTR  REGL,0         NUMBER OF BYTES TO BE SHIFTED             16180000
         LA    REGH,0(REGB,REGM)   COMPUTE NEW POSITION OF APOSTPOPHE,  16200000
         EX    REGL,MAPOS     MOVE APOSTROPHE AND SCANNED CHARACTERS    16220000
         EX    REGL,MAPOS2                                              16240000
         LR    REGM,REGH           NOTE NEW POSITION OF APOSTROPHE .    16260000
         BCR   15,REGIX           RETURN                                16280000
         CNOP  0,4                                                      16300000
MAPOS    MVC   BUCKET(1),0(REGM)                                        16320000
         CNOP  0,4                                                      16340000
MAPOS2   MVC   0(1,REGH),BUCKET                                         16360000
BUCKET   DC    11X'00'                                                  16380000
         SPACE 2                                                        16400000
*****   ZETAAPO  ****************************************************** 16420000
*                   MOVES SCANED BYTES AND APOSTROPHE IN FRONT OF WA    16440000
*                   AND PUTS REGM TO NEW START LOCATION                 16460000
*                   OF POSSIBLE DELIMITER                               16480000
*                   USED BY MAINLOOP AND ARRAYLIST                      16500000
         SPACE 2                                                        16520000
ZETAAPO  LR    REGY,REGM               COMPUTE                          16540000
         LR    REGL,REGI               NR OF SCANNED                    16560000
         SR    REGL,REGM               BYTES                            16580000
         C     REGL,KOPOOL+44      Q EXEED LIMIT                        16600000
         BH    EROUT                    YES                             16620000
         LA    REGM,WA                  NO- CALCULATE WHERE TO MOVE     16640000
         SR    REGM,REGL                CHAR. STRING                    16660000
         BCTR  REGL,0                                                   16680000
         EX    REGL,MOVBEFWA            MOVE CHAR IN FRONT OF WA        16700000
         B     CIB                CHANGE INPUT BUFFER                   16720000
         CNOP  0,4                                                      16740000
MOVBEFWA MVC   0(1,REGM),0(REGY)                                        16760000
         SPACE 2                                                        16780000
*****   NPAFAPO  ****************************************************** 16800000
*                   GIVES ERROR MESSAGE AND UTILIZES BLANKAPO TO SHIFT  16820000
*                   THE INVALID CHARACTER AWAY                          16840000
*                   USED BY MAINLOOP AND ARRAYLIST                      16860000
         SPACE 2                                                        16880000
NPAFTAPO TM    FBYTE,X'FF'                                              16900000
         BM    TYPESPEC            INVALID IDENTIFIER                   16920000
         BO    COMCED2            COMMENT UNDER PROCESS                 16940000
         TM    BITS2,X'20'         Q. PROGRAM STARTED YET               16960000
         BZ    *+10                NO                                   16980000
         BAL   REGB,ERR7                                                17000000
         DC    X'0401'             E1                                   17020000
         LR    REGH,REGI                                                17040000
         LA    REGI,1(0,REGI)           GO TO BLKAPOS TO SHIFT AWAY     17060000
         B     BLKAPOS+2                INVALID CHARACTER               17080000
         SPACE 2                                                        17100000
*****   COLON    ****************************************************** 17120000
*                   ENTERD FROM MAINLOOP OR POINT                       17140000
*                   CHECKS FOR   :=  ASSIGN                             17160000
*                                :(  DELIMITER                          17180000
*                                    LABEL                              17200000
         SPACE 2                                                        17220000
COLON    LR    REGB,REGI           STORE PRECEEDING 6 CHARACTERS        17240000
         S     REGB,KOPOOL+24      TO BE USED ONLY IF INCORRECT         17260000
         MVC   BUCKET(6),0(REGB)   USE OF COLON E3                      17280000
COLON2   LA    REGI,1(0,REGI)                                           17300000
EQUAL    CLI   0(REGI),X'10'       IF COLON IS FOLLOWED BY EQUALSIGN    17320000
         BE    ASSIGN              BRANCH TO ASSIGN-PROGRAM             17340000
         CLI   0(REGI),X'06'       IF COLON IS FOLLOWED BY LEFT PAREN-  17360000
         BE    LETDEL              THESIS,BRANCH TO DELIMITERPROCESSING 17380000
         CLI   0(REGI),X'2B'       IF COLON IS FOLLOWED BY BLANK        17400000
         BE    COLON2              REPEAT SEARCH                        17420000
         CLI   0(REGI),X'2F'       IF COLON IS FOLLOWED BY ZETA         17440000
         BNE   *+12                                                     17460000
         LA    REGIX,EQUAL         PROVIDE RETURNADDRESS AND            17480000
         BC    15,CIB              CHANGE INPUTBUFFER                   17500000
         SPACE 2                                                        17520000
*****   LABEL    ****************************************************** 17540000
*                   OPIN POINTS TO LAST OPERATOR WHICH MIGHT BE       * 17560000
*                        FOLLOWED BY A LABEL.                         * 17580000
*                   PIN IS THE POINTER, STEPPING UP BETWEEN LAPIN AND   17600000
*                        THE COLON WHICH EAP POINTS TO                  17620000
*                   OPIN+4 CONTAINS THE O/P REC. NUMBER WHEN OPIN       17640000
*                        WAS SET                                        17660000
*                   LABEL IS CHECKED FOR VALIDITY. THE FIRST 6 CHAR.    17680000
*                        ARE MOVED TO OUTPUT AND ITAB.                * 17700000
*                   CHECKS IF THE LABEL IS SPLIT OVER MORE THAN         17720000
*                        ONE  O/P BUFFER                                17740000
*                   IF THE LABEL IS SPLIT BY ONE O/P BUFFER END THE     17760000
*                        HANDLING IS THE SAME AS IF NOT EXEPT THAT WHEN 17780000
*                        ZETA- RECORD END - IS FOUND PIN IS UPDATED TO  17800000
*                        THE FIRST CHARACTER OF THE CURRENT O/P REC.  * 17820000
*                   E3 IF THERE IS NO LABEL                             17840000
*                   E6 IF LABEL LONGER THAN 1024 BYTES                  17860000
*                   E7 IF LABEL CONTAINS INVALID CHARACTER              17880000
*                   E8 IF LABEL STARTS WITH INVALID CHAR.               17900000
         SPACE 2                                                        17920000
         CLC   ONC(1),OPIN+4         Q. LABEL EXCEEDS ONE O/P REC.      17940000
         BE    LABEL                    NO                              17960000
         SR    REGM,REGM                                                17980000
         IC    REGM,OPIN+4                                              18000000
         LA    REGM,1(0,REGM)                                           18020000
         IC    REGZ,ONC                                                 18040000
         CR    REGZ,REGM                Q. LABEL EXCEEDS 2 O/P REC.     18060000
         BE    *+10                     NO                              18080000
         BAL   REGB,ERR4                                                18100000
         DC    X'0406'        E6   TERMINATING ERROR                    18120000
LABEL    L     PIN,LAPIN                                                18140000
         CR    EAP,PIN             IS THERE ANY IDENTIFIER              18160000
         BE    ERROR3              E3 COLON DELETED                     18180000
         CLI   OPINCHAR,X'26'      Q LABEL PROCEEDED BY RIGHT           18200000
         BE    ERROR3              PARENTHESIS IF YES E3 IS GIVEN       18220000
LABNAME  CLI   0(PIN),X'40'     Q. FIRST CHAR. IS LETTER                18240000
         BL    LABNAMER                                                 18260000
         L     IN,AITL                                                  18280000
         MVC   0(1,IN),0(PIN)           MOVE CONTENTS OF PIN TO ITAB    18300000
         LA    IN,1(0,IN)                INCREABE IN                    18320000
         LA    K,1                      INITILIZE K WITH 1              18340000
LABID    LA    PIN,1(0,PIN)        GET NEXT CHAR.                       18360000
         CR    PIN,EAP                   Q(PIN=EAP                      18380000
         BE    LABEND                                                   18400000
LABCHECK CLI   0(PIN),X'2F'        Q. LETTER, DIGIT                     18420000
*                                         OR ZETA                       18440000
         BNE   *+12                                                     18460000
         L     PIN,WADDARI              GET START OF CURRENT O/P AREA   18480000
         B     LABCHECK                                                 18500000
         BL    ERROR7                                                   18520000
         C     K,KOPOOL+24              Q. K=6                          18540000
         BE    LABID                    YES- DON'T MOVE MORE CHAR. TO   18560000
*                                       ITAB                            18580000
         MVC   0(1,IN),0(PIN)            MOVE CONTENT OF PINTOIN        18600000
         LA    IN,1(0,IN)                INCREASE  IN ANO PIN           18620000
         LA    K,1(0,K)                 AND K                           18640000
         B     LABID                                                    18660000
LABNAMER CLI   0(PIN),X'2F'        Q. ZETA  OR DIGIT                    18680000
         BNE   *+12                                                     18700000
         L     PIN,WADDARI         UPDATE PIN TO CURRENT O/P BUFFER     18720000
         B     LABNAME                                                  18740000
         CLI   0(PIN),X'2B'        Q. BLANK                             18760000
         BE    LABNAME                                                  18780000
         BAL   REGB,ERR7                                                18800000
         DC    X'0408'        E8                                        18820000
         B     ERROR7+6                                                 18840000
ERROR7   BAL   REGB,ERR2                                                18860000
         DC    X'0007'             E7 INCORRECT LABEL                   18880000
         L     REGY,AITL                                                18900000
         BAL   REGOX,ITABCLEA+8         CLEAR  THE ITAB ENTRY           18920000
         BCR   15,RET                                                   18940000
         SPACE 2                                                        18960000
********LABEND   ****************************************************** 18980000
*                   IF  (LABEL:LABELX) THE LN (LABEL NUMBER)            19000000
*                   WILL ONLY BE INCREASE ONCE                          19020000
*                   INTERNAL NAME IS CREATED AND LN INSERTED            19040000
*                   X'27' IS MOVED TO THE O/P TO INDICATE LABEL         19060000
*                   OPIN, OPIN+4 AND LAPIN ARE UPDATED                  19080000
*                   ITABCLEA IS ACTIVATED TO PREPARE NEXT ITABENTRY     19100000
         SPACE 2                                                        19120000
LABEND   CLI   OPINCHAR,X'27'           +. LABEL PRECEEDED BY LABEL     19140000
         BE    LABLAHEI                 YES- DO NOT UPDATE LN           19160000
         LH    REGY,LN             LN=LN+4                              19180000
         LA    REGY,4(0,REGY)                                           19200000
LABCREAT CLC   LN(2),FOURKA      Q. LN= 2**12                           19220000
         BL    *+14                                                     19240000
         BAL   REGB,ERR7                                                19260000
         DC    X'04D8'                  E216                            19280000
         LA    REGY,LATBEG         RESET LN                             19300000
         STH   REGY,LN                                                  19320000
LABLAHEI L     REGY,AITL                                                19340000
         MVI   6(REGY),X'CC'            CREATE INTERNAL NAME            19360000
         MVI   7(REGY),X'08'                                            19380000
         L     REGL,LPBP                                                19400000
         MVC   8(1,REGY),10(REGL)      PROGRAMMBLOCKNR   AITL + 7       19420000
         MVC   9(2,REGY),LN             LN IN AITL+9                    19440000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             19460000
         MVI   0(EAP),X'27'             MOVE LABEL IND. TO O/P          19480000
         ST    EAP,OPIN                 SET LABEL POINTERS              19500000
         MVI   OPINCHAR,X'27'                                           19520000
         MVC   OPIN+4(1),ONC                                            19540000
         LA    EAP,1(0,EAP)                                             19560000
         ST    EAP,LAPIN                                                19580000
         BAL   REG12,ITABCLEA           CHECK AND CLEAR NEXT ITABENTRY  19600000
         B     STATE                    RETURN VIA STATEMENT PCM        19620000
         SPACE 2                                                        19640000
*****   LETDEL   ****************************************************** 19660000
*                   :( HAS BEEN FOUND IN THE I/P                        19680000
*                  IF OPIN POINTS TO A RIGHT PARENTHESIS IT SHOULD BE   19700000
*                   LETTER DELIMITER, WHITCH SHOULD BE REMOVED AND      19720000
*                   REPLACED BY A COMMA                                 19740000
*                   IT IS CHECKED THAT ALL CHARACTERS ARE LETTERS       19760000
*                        OTHERWISE E3 IS GIVEN                          19780000
         SPACE 2                                                        19800000
LETDEL   CLI   OPINCHAR,X'26'           Q. OPIN POINTS TO A RIGHT PAREN 19820000
         BNE   ERROR3                   NO- E3- COLON DELETED           19840000
         CLC   ONC(1),OPIN+4           Q LETDEL EXCEEDS ONE O/P REC     19860000
         BNE   LETDELB2                YES                              19880000
         L     PIN,OPIN                                                 19900000
         LA    REGB,1(0,PIN)                                            19920000
         CR    REGB,EAP                 Q. AT LEAST ONE CHAR.           19940000
         BE    ERROR3                   NO- E3 DELETE COLON             19960000
LETDELE1 LA    PIN,1(0,PIN)            OTHER CHAR. THAN                 19980000
         CLI   0(PIN),X'39'            LETTERS                          20000000
         BNH   ERROR3                                                   20020000
         LA    REGB,1(0,PIN)                                            20040000
         CR    REGB,EAP                 Q. ALL CHAR. CHECKED            20060000
         BNE   LETDELE1                 NO- CHECK NEXT                  20080000
         L     EAP,OPIN            SET O/P POINTER TO BEGINING OF       20100000
         MVI   0(EAP),X'25'            THE STRING,MOVE IN A COMMA       20120000
         LA    EAP,1(0,EAP)                                             20140000
         LA    REGI,1(0,REGI)          GET NEXT CHAR.                   20160000
         BCR   15,RET                                                   20180000
*  DELIMITER EXCEEDS  ONE O/P RECORD                                    20200000
LETDELB2 SR    REGB,REGB           Q. DOES THE STRING                   20220000
         IC    REGB,OPIN+4           Q. EXCEED 2 O/P RECORDS            20240000
         LA    REGB,1(0,REGB)                                           20260000
         IC    REGZ,ONC                                                 20280000
         CR    REGB,REGZ                                                20300000
         BE    *+10                     NO                              20320000
         BAL   REGB,ERR4                                                20340000
         DC    X'0404'             E4  GOES TO COMPFIN                  20360000
         L     PIN,OPIN                MAKE PIN POINT TO LETTER DEL.    20380000
LETDELB3 LA    PIN,1(0,PIN)                                             20400000
         CLI   0(PIN),X'40'            Q LETTER                         20420000
         BNL   *-8                     YES                              20440000
         CLI   0(PIN),X'2F'            NO-Q ZETA                        20460000
         BNE   ERROR3                                                   20480000
         L     PIN,WADDARI         CHANGE BACK SO PIN POINT TO CURR.O/P 20500000
LETDELF4 CLI   0(PIN),X'40'            Q LETTER                         20520000
         BL    ERROR3                   E3 DELETE COLON                 20540000
         LA    PIN,1(0,PIN)            SKIP ALL LETTERS                 20560000
         CR    PIN,EAP            UNTIL END OF DELIMITERS               20580000
         BNE   LETDELF4                                                 20600000
         L     EAP,WADDARI         LOAD ADD. OF CURRENT  O/P REC        20620000
         MVI   0(EAP),X'3D'            MOVE IN $ RHO                    20640000
         LA    EAP,1(0,EAP)                                             20660000
         LA    REGI,1(0,REGI)          GET NEXT CHAR                    20680000
         BCR   15,RET                                                   20700000
         SPACE 2                                                        20720000
*****   SEMCO    ****************************************************** 20740000
*                   IF THE DELTA BIT IS ON, THE DELTA AND SEMICOLON     20760000
*                   COUNTER (SC) IS MOVED TO THE OUTPUT                 20780000
*                   IF THE DELTABIT IS OFF THE STACK IS INSPECTED       20800000
*                   BEGIN, BETA OR PROC* - A SEMICOLON AND THE SC       20820000
*                             IS MOVED TO THE O/P AND PROCESSING IS     20840000
*                             CONTINUES VIA TEST                        20860000
*                   FOR - THE FORSTATMENT IS COMPLETE, THE FOREND       20880000
*                             PROGRAM IS ACTIUATED                      20900000
*                             THE RETURN IS TO STACKTST TO SEE IF ONE   20920000
*                             MORE FOR STATEMENT OR A PROC** HAS ENDED  20940000
*                             AT THE SAME TIME                          20960000
*                   PROC - A PROCEDURE CONSISTING OF ONLY ONE           20980000
*                             STATMENT OR A DOMMY STATMENT HAS ENDED    21000000
*                             IT IS CHECKED THAT ALL PARAMETERS HAVE    21020000
*                             BEEN SPECIFIED, AND THE PROC** PGM IS     21040000
*                             JOINED                                    21060000
*                   PROC** - A PROCEDURE CONSISTING OF ONE LABELED      21080000
*                             STATEMENT OR ONE FOR, IF, GOTO OR ASSIGN  21100000
*                             STATEMENT HAS ENDED                       21120000
*                             THE PROGRAM BLOCKEND PROGRAM IS ACTIVATED 21140000
*                             AND A DELTA AND THE SC IS MOVED OUT       21160000
*                   THE FINAL EXIT IS IN ALL CASES TO TEST              21180000
         SPACE 2                                                        21200000
SEMC60   OI    HCOMPMOD+2,SET60         SET SWITCH FOR 60 CHAR. SET     21220000
SEMCO    LH    REGM,SC                                                  21240000
         C     REGM,SCOVFL         TEST SC OVERFLOW                     21260000
         BL    SEMCO01                                                  21280000
         BAL   REGB,ERR7                                                21300000
         DC    X'0411'             E17                                  21320000
         MVC   SC(2),KOPOOL        RESET SC COUNTER TO ZERO             21340000
SEMCO01  LA    REGM,1(0,REGM)      INCREASE SC                          21360000
         STH   REGM,SC                                                  21380000
         LA    REG0,3(0,EAP)       PROVIDE 3 BYTES IN OUTPUTBUFFER      21400000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         21420000
         NI    BITS3,FMOFF                                              21440000
         TM    BITS1,X'20'         TEST DELTABIT                        21460000
         BO    DELTA               IF  1  BRANCH TO DELTATRANSFER       21480000
         LA    REGE,STACKTST       RETURN REGISTER ( FOREND, PBLCKEND ) 21500000
         L     REGY,SP             SELECT                               21520000
         IC    REGZ,0(0,REGY)      BRANCH                               21540000
         L     REGB,PROG2(REGZ)    ADDRESS                              21560000
         BCR   15,REGB             DEPENDING ON WHAT IS IN STACK        21580000
         DS    0F                                                       21600000
PROG2    DC    A(ERR8)             SHOULD NOT OCCUR, TOPBYTE IS ALPHA   21620000
         DC    A(SCTRANS)                                      BETA     21640000
         DC    A(SCTRANS)                                      BEGIN    21660000
         DC    A(SEMPROC)                                      PROC     21680000
         DC    A(SCTRANS)                                      PROC*    21700000
         DC    A(SEMPROC2)                                     PROC**   21720000
         DC    A(FOREND)                                       FOR      21740000
DELTA    NI    BITS1,X'DF'         DELTA BIT= 0                         21760000
         MVI   0(EAP),X'29'        TRANSFER DELTA                       21780000
         BC    15,SCTRANS+4                                             21800000
SCTRANS  MVI   0(EAP),X'0B'        TRANSFER SEMICOLON                   21820000
         MVI   OPINCHAR,X'0B'                                           21840000
         ST    EAP,OPIN            NOTE POSITION OF SEMICOLON IN OPIN   21860000
         MVC   OPIN+4(1),ONC       AND O/P NO                           21880000
         MVC   1(2,EAP),SC         TRANSFER SEMICOLONCOUNTER            21900000
         LA    EAP,3(0,EAP)        INCREASE OUTPUTPOINTER               21920000
         ST    EAP,LAPIN                                                21940000
         NI    BITS1,X'7F'         BEGBIT.=0                            21960000
         LA    REGI,1(0,REGI)      INCREASE INPUTPOINTER                21980000
         B     TESTLOOP                                                 22000000
SCOVFL   DC    F'65535'           (2**16)-1                             22020000
SEMPROC  NI    BITS1,X'BF'         PROBIT.=0                            22040000
         CLI   PZ,X'00'            ALL PARAMETERS SPECIFIED             22060000
         BE    *+8                                                      22080000
         BAL   REGOX,ERROR10                                            22100000
SEMPROC2 BAL   REGE,PBLCKEND                                            22120000
         LA    REG0,3(0,EAP)       PROVIDE 3 BYTES IN OUTPUTBUFFER      22140000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         22160000
         MVI   0(EAP),X'29'        TRANSFER DELTA                       22180000
         BC    15,SCTRANS+4                                             22200000
STACKTST CLI   0(REGY),X'14'                                            22220000
         BE    SEMPROC2            PROC**                               22240000
         BH    FOREND              FOR                                  22260000
         LA    REG0,3(0,EAP)                                            22280000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         22300000
         B     SCTRANS                                                  22320000
         SPACE 2                                                        22340000
         SPACE 2                                                        22360000
*****   ERROR ROUTINE  ************************************************ 22380000
*                   GENERATES ERROR PATTERNS                            22400000
*                   MAINLY CLOSED SUBROUTINES, ENTERED WITH BAL REGB    22420000
*                        FOLLOWED BY TWO BYTES. FIRST BYTE SPECIFIES    22440000
*                        THE LENGTH, IF KNOW AND SECOND BYTE ERROR      22460000
*                        NUMBER                                         22480000
*                   USES ERROR1 TO CHECK FOR ERRORPOL OVERFLOW AND      22500000
*                        TO INSERT NUMBER, LENGTH AND SC                22520000
         SPACE 2                                                        22540000
*****   ERR0     ****************************************************** 22560000
*                   GENERATES E212 PATTERN                              22580000
*                   EXITS TO COMFIN                                     22600000
         SPACE 2                                                        22620000
ERR0     MVI   0(REGY),X'02'                                            22640000
         MVI   1(REGY),X'D4'       E212                                 22660000
         LA    REGY,2(0,REGY)                                           22680000
         ST    REGY,NEXTERR                                             22700000
         B     COMPFIN                                                  22720000
         SPACE 2                                                        22740000
*****   ERR1     ****************************************************** 22760000
*                   E1                                                  22780000
*                   ACTIVATES ERR7, SKIPPS INVALID CHARACTER AND        22800000
*                        RETURNS TO EITHER TESTLOOP OR LIST             22820000
*                        ENTERED VIA BPRTAB WHEN USED BY TESTLOOP OR    22840000
*                             LIST                                      22860000
*                        INVALID CHARACTER FOLLOWING AN APOSTROPHE IS   22880000
*                             TREATED SPECIALLY IN NPAFTAPO             22900000
         SPACE 2                                                        22920000
ERR1     BAL   REGB,ERR7     NOT PERMITTED CHARACTER                    22940000
         DC    X'0401'        E1                                        22960000
         LA    REGI,1(0,REGI)                                           22980000
         BCR   15,RET              RETURN TO TEST OR TRATE              23000000
         SPACE 2                                                        23020000
*****   ERR2     ****************************************************** 23040000
*                   ERR2      7, 16, 31, 32, 33, 34                     23060000
*                        ENTERED   ERROR7, IER, ARRAYERR, SWITCHERR     23080000
*                                  SLASHERR, SEMCLST, SEMCLER, ARRYSLSH 23100000
*                                  SLASHLST, PNAMERR                    23120000
*                        NAME TAKE FROM AITL                            23140000
*                   ERR2B          10, 36, 37                           23160000
*                                  ERROR10, PROCFIN, ERROP37            23180000
*                        NAME TAKEN FROM LPBP-11                        23200000
*                   ERR2C     14                                        23220000
*                                  EROUT                                23240000
*                        DELIMITER TAKEN FROM BUCKET                    23260000
*                   ERR2E     16, 26, 27, 30                            23280000
*                                  IDVALCHK, VALDLB2, IDSELSE, NOTFOUND 23300000
*                        NAME TAKEN FROM IDBUCKET                       23320000
*                   ERR2D UTILISES ERROR2 TO FIND LENGTH                23340000
*                                  ERROR1 TO CREATE MESSAGE             23360000
*                                  MOVES IN INFORMATION                 23380000
*                                  RETURNS TO CALLING SEQUENCE          23400000
         SPACE 2                                                        23420000
ERR2     L     IN,AITL                  NAME FROM AITL                  23440000
         B     ERR2D                                                    23460000
ERR2B    L     IN,LPBP                  NAME FRM LPBP-11                23480000
         S     IN,KOPOOL+44                                             23500000
         B     ERR2D                                                    23520000
ERR2C    MVC   BUCKET(6),1(REGM)        DELIMITER FROM BUCKET           23540000
         LA    IN,BUCKET                                                23560000
         B     ERR2D                                                    23580000
ERR2E    LA    IN,IDBUCKET     E26      NAME FROM IDBUCKET              23600000
ERR2D    STM   12,15,ERRSAVE                                            23620000
         BAL   REG12,ERROR2             GET NAME AND LENGTHS            23640000
         BAL   REG12,ERROR1             CREATE ENTRY IN ERRPOOL         23660000
         EX    K,ERRMOVE                MOVE THE NAME                   23680000
         LM    12,15,ERRSAVE                                            23700000
         BC    15,2(0,REGB)                                             23720000
         SPACE 2                                                        23740000
*****   ERROR3   ****************************************************** 23760000
*                   GENERATES PATTERN FOR E3                            23780000
*                   ENTERED FROM LABEL, COLONLST                        23800000
*                   TAKES INFORMATION FROM BUCKET                       23820000
         SPACE 2                                                        23840000
ERROR3   STM   12,15,ERRSAVE            GET PARAMETER FIELD             23860000
         LA    REGB,PARAM3                                              23880000
         BAL   REG12,ERROR1             CREATE PATTERN                  23900000
         MVC   4(6,REGY),BUCKET         MOVE IN INFORMATION             23920000
         LM    12,15,ERRSAVE                                            23940000
         BCR   15,RET                                                   23960000
PARAM3   DC    X'0A03'                                                  23980000
         SPACE 2                                                        24000000
*****   ERR4     ****************************************************** 24020000
*                   TAKES CARE OF ALL TERMINATING ERRORS THAT ARE       24040000
*                        4 BYTETS LONG                                  24060000
*                   THAT IS   4, 6, 20, 22, 38, 41, 44, 213, 215, 216   24080000
*                   ENTERED FROM   LABEL, ITABCLEA, COB, BEGIN, BEG1,   24100000
*                                  PBLCKEND, FOR, PROCEDUR, ENDMISS     24120000
*                   EXITS TO COMPFIN                                    24140000
         SPACE 2                                                        24160000
ERR4     BAL   REG12,ERROR1                                             24180000
         SPACE 2                                                        24200000
*****   COMPFIN  ****************************************************** 24220000
*                   TERMINATING ERROR HAS BEEN FOUND                    24240000
*                   SETS TERMBIT IN HCOMPMOD                            24260000
*                   EXITS TO KOPOOLRL IN TERMINATION                    24280000
*                                                                       24300000
COMPFIN  OI    HCOMPMOD,X'08'      SET TERMINATING ERROR BIT            24320000
         L     REG11,VIEX14                                             24340000
         USING IEX11003,11                                              24360000
         B     KOPOOLRL                 EXIT TO ERMINATION              24380000
         USING IEX11002,11                                              24400000
         SPACE 2                                                        24420000
*****   ERR5     ****************************************************** 24440000
*                   ERR5A     E35  FROM BPRTAB, DISP IN TESTTABL        24460000
*                   ERR5      E2   FROM BPRTAB, DISP IN ARTABLE         24480000
*                   GENERATES ERROR PATTERN RETURNS TO TESTLOOP OR LIST 24500000
*                                                                       24520000
         SPACE 2                                                        24540000
ERR5A    LA    REGB,PPARLST             GET PARAMETER FIELD             24560000
         B     *+8                                                      24580000
ERR5     LA    REGB,PONTPAR             GET PARAMETER FIELD             24600000
         STM   12,15,ERRSAVE                                            24620000
         BAL   REGOX,ERROR1             GENERATE PATTERN                24640000
         LM    12,15,ERRSAVE                                            24660000
         BCR   15,RET                   RETURN TO TESTLOOP OR LIST      24680000
PPARLST  DC    X'0423'                                                  24700000
PONTPAR  DC    X'0402'             E2                                   24720000
         SPACE 2                                                        24740000
*****   ERR6     ****************************************************** 24760000
*                   GENERATES PATTERN FOR E6                            24780000
*                   TESTS IF PROGRAM STARTED IF NOT, NO ERROR MESSAGE   24800000
*                   TEST IF IN COMMENT OR IDENTIFIER PROGRAM            24820000
*                   TAKES THE 6 CHARACTERS PRECEEDING THE FIRST         24840000
*                        APOSTROPHE                                     24860000
*                   RETURNS TO APOSTROPHE PROGRAM TO TEST ON SECOND     24880000
*                        APOSTROPHE                                     24900000
         SPACE 2                                                        24920000
ERR6     TM    BITS2,X'20'              Q. FIRST BEGIN FOUND YET        24940000
         BZ    TESTLOOP                 NO                              24960000
         TM    FBYTE,X'FF'                                              24980000
         BO    ENTRAPR             INVALID IDENTIFIER                   25000000
         BZ    *+12                COMMENT                              25020000
         LA    REGI,1(0,REGI)                                           25040000
         B     TPSPECER                                                 25060000
         BCTR  REGI,0                                                   25080000
         STM   12,15,ERRSAVE                                            25100000
         BAL   REG12,ERROR1                                             25120000
         S     REGI,KOPOOL+24      SUBTRACT 6                           25140000
         MVC   4(6,REGY),0(REGI)        MOVE OUT INFORMATION TO POOL    25160000
         LA    REGI,7(0,REGI)                                           25180000
          LM    12,15,ERRSAVE                                           25200000
         B     ENTRAPR             RETURN TO TEST SECOND APOSTROPHE     25220000
         SPACE 2                                                        25240000
*****   ERR7     ****************************************************** 25260000
*                   TAKES CARE OF ALL SERIOUS AND WARNING MESSAGES THAT 25280000
*                        ARE 4 BYTES LONG                               25300000
*                   ENTERED FROM ERR1, IERSPEC, ARNAMSE, SWITCHNSE      25320000
*                                 PNAMESE, LABNAMER, CODE, SEMCO, ERR18 25340000
*                                 ERR23, CODE, SPEC, VALUE, VALDLB2,    25360000
*                                  FIRSTBEG, ERR9, LABEL, PROCEDURE,    25380000
*                                 SWITCH, COM                           25400000
*                   1, 5, 8, 15, 17, 18, 23, 24, 25, 28, 29, 42, 43,216 25420000
*                   RETURNS TO CALLING SEQUENCE                         25440000
         SPACE 2                                                        25460000
ERR7     STM   12,15,ERRSAVE                                            25480000
         BAL   REG12,ERROR1             CREATE ENTRY                    25500000
         LM    12,15,ERRSAVE                                            25520000
         BC    15,2(0,REGB)                                             25540000
         SPACE 2                                                        25560000
*****   ERR8     ****************************************************** 25580000
*                   GENERATES ERROR PATTERN E11 ONCE                    25600000
*                   IF FOUND DELIMITER IS COMMENT E18 IS GIVEN          25620000
*                        INSTEAD                                        25640000
*                   ENTERED FROM   TYPESPEC                             25660000
*                                  STARTDEL                             25680000
*                   EXITS TO TESTLOOP                                   25700000
         SPACE 2                                                        25720000
ERR8     TM    BITS3,E11BIT             Q. MESSAGE ALLREADY GIVEN ONCE  25740000
         LA    REGI,1(0,REGI)      GET NEXT CARACTER                    25760000
         BO    TESTLOOP                 YES- RETURN                     25780000
         CLI   BCHAR,X'38'              Q COMMENT FOUND                 25800000
         BE    E18                YES GENERATE E18 INSTEAD              25820000
         OI    BITS3,E11BIT             SET E11BIT                      25840000
         BAL   REGB,ERR7                GENERATE E11 PATTERN            25860000
         DC    X'040B'                                                  25880000
         B     *+10                                                     25900000
E18      BAL   REGB,ERR7                                                25920000
         DC    X'0412'                                                  25940000
         BCR   15,RET              RETURN                               25960000
         SPACE 2                                                        25980000
*****   ERR9    ******************************************************* 26000000
*                   GENERATE  E9 PATTERN                                26020000
*                   ENTERED FROM TED                                    26040000
*                                 END                                   26060000
*                                 READROUT                              26080000
*                   EXITS TO EODADIN                                    26100000
         SPACE 2                                                        26120000
ERR9     BAL   REGB,ERR7           PROGRAM CONTINIUED AFTER LAST END    26140000
         DC    X'042B'                                                  26160000
         B     EODADIN                                                  26180000
         SPACE 2                                                        26200000
*****   ERROR10  ****************************************************** 26220000
*                   GENERATES E10 PATTERN                               26240000
*                   INSERTS IN THE NOT SPECIFID PARAMETERS A            26260000
*                        ALLPURPOS IDENTIFIER                           26280000
*                   RETURNS TO CALLING PROGRAM                          26300000
         SPACE 2                                                        26320000
ERROR10  BAL   REGB,ERR2B                                               26340000
         DC    X'000A'             E10                                  26360000
         L     REGB,LPBP                                                26380000
FINDEMTY LA    REGB,11(0,REGB)     GET FIRST PARAMETER                  26400000
         C     REGB,AITL                Q. ALL PARAMETERS CHECKED       26420000
         BCR   8,REGOX             WHEN ALL CHECKED RETURN              26440000
         CLI   6(REGB),X'00'       INSERT ALL PURPOSE IDENTIFIER        26460000
         BNE   FINDEMTY            IN EMPTY INTERNAL NAMES              26480000
         MVC   6(5,REGB),ALLPUPOS                                       26500000
         B     FINDEMTY                                                 26520000
ALLPUPOS DC    X'91FF010000'                                            26540000
         SPACE 2                                                        26560000
*****   ERR13    ****************************************************** 26580000
*                   GENERATES E13 PATTERN                               26600000
*                   PICKS UP THE DELIMITER FROM W1TAB                   26620000
         SPACE 2                                                        26640000
ERR13    STM   12,15,ERRSAVE                                            26660000
         LA    REGOX,5(0,REGL)     INCREASE TO GET WHOLE LENGTH         26680000
         STC   REGOX,0(REGB)                                            26700000
         BAL   REGOX,ERROR1                                             26720000
         L     REGL,ERRSAVE+8      GET LENGTH OF DELIMITER              26740000
         LA    IN,1(0,REGM)        GET START ADDRESS OF DELIMITER       26760000
         EX    REGL,ERRMOVE        MOVE DELIMITER TO ERROR PATTER       26780000
         LM    12,15,ERRSAVE                                            26800000
         BC    15,2(0,REGB)        RETURN                               26820000
         SPACE 2                                                        26840000
*****   ERROR21  ****************************************************** 26860000
*                   GENERATES E21 PATTERN                               26880000
*                   PICKS UP DELIMITER FROM DELIMITER TABLE             26900000
*                   EXITS TO PROGRAM WHICH CALLED FOR BEG1              26920000
         SPACE 2                                                        26940000
ERROR21  STM   12,15,ERRSAVE                                            26960000
         LA    REGB,5(0,REGL)           INCREASE L TO GET WHOLE LENGTH  26980000
         STC   REGB,E21PAR                                              27000000
         LA    REGB,E21PAR                                              27020000
         BAL   REG12,ERROR1                                             27040000
         L     IN,SAVE1                 GET DEK. FROM DELIMITER TABEL   27060000
         L     REGL,ERRSAVE+8                LENGTH FROM SAVEAREA       27080000
         EX    REGL,ERRMOVE             MOVE IN DEK. IN ERROR MESSAGE   27100000
         LA    EAP,1(0,EAP)             SUBSTITUTE BEG1 DECREASION      27120000
         LM    12,15,ERRSAVE            BEGIN WILL REMAIN COMPOUND      27140000
         BCR   15,REGX                  RETURN                          27160000
E21PAR   DC    X'0015'                  E21                             27180000
         SPACE 2                                                        27200000
         SPACE 2                                                        27220000
*****   ERROR1   ****************************************************** 27240000
*                   CHECKS IF SPACE LEFT IN ERRORPOOL                   27260000
*                   INSERTS LENGTH, SC, ERROR NUMBER                    27280000
*                   RETURNS TO CALLIN ERROR PUTINE                      27300000
         SPACE 2                                                        27320000
ERROR1   MVC   ERRMOD1+3(1),0(REGB)     MOVES IN THE LENGTH AND         27340000
         MVC   ERRMOD2+1(1),0(REGB)     ERRORNUMBER IN THE FOLLOWING    27360000
         MVC   ERRMOD3+1(1),1(REGB)     INSTRUCTIONS                    27380000
         L     REGY,NEXTERR                                             27400000
ERRMOD1  LA    REGL,0(0,REGY)                                           27420000
         C     REGL,ENDPOOL        Q. ROOM LEFT IN ERRORPOOL            27440000
         BNH   *+8                 FOR THIS MESSAGE                     27460000
         B     ERR0                     NO- GENERATE E212               27480000
         L     REGY,NEXTERR                                             27500000
         ST    REGL,NEXTERR             CORRECT NEXTERR POINTER         27520000
ERRMOD2  MVI   0(REGY),X'00'            MOVE IN LENGTH                  27540000
ERRMOD3  MVI   1(REGY),X'00'                    ERRORNUMBER             27560000
         MVC   2(2,REGY),SC                     SC COUNTER              27580000
         LR    REGL,REGI                MAKE REGL POINT TO SIX CHAR     27600000
         SH    REGL,SEVEN               BEFORE CURRENT INPUT POINTER    27620000
         BCR   15,REG12                                                 27640000
         SPACE 2                                                        27660000
*****   ERROR2   ****************************************************** 27680000
*                   FINDS FIRST NONZERO CHAR. IN BUCKET, ITAB,          27700000
*                   IDBUCKET OR BUCKET                                  27720000
         SPACE 2                                                        27740000
ERROR2   LA    K,5                      INITILIZE K FOR THE LOOP        27760000
         STC   K,ERRKCAL+3                                              27780000
ERRKCAL  CLI   0(IN),X'00'              LOOP TO FIND THE FIRST 0 CHAR   27800000
         BNE   *+8                      OR END OF EXTERNALNAME          27820000
         BCT   K,ERRKCAL-4                                              27840000
         LA    REGY,5(0,K)    INCREASE TO GET THE WHOLE                 27860000
         STC   REGY,0(0,REGB)      ERROR MESSAGE LENGTH                 27880000
         BCR   15,REG12                                                 27900000
         CNOP  0,4                                                      27920000
ERRMOVE  MVC   4(1,REGY),0(IN)                                          27940000
SEVEN    DC    X'0007'                                                  27960000
         SPACE 2                                                        27980000
*****   IDCHECK1 ****************************************************** 28000000
*                   CHECKS IDENTIFIER NAMES FOR ARRAY, PROCEDURE AND    28020000
*                   SWITCH                                              28040000
*                   MOVES THE FIRST 6 CHARATERS OF THE NAME TO ITAB     28060000
*                   AND THE OUTPUT                                      28080000
*                   RETURNS VIA REGB WHEN A CHARACTER IS FOUND THAT     28100000
*                   IS NOT LETTER, DIGIT, BLANK OR ZETA                 28120000
         SPACE 2                                                        28140000
IDCHECK1 BAL   REGOX,COB           CHECK IF O/P AREA FILLED             28160000
         MVC   0(1,EAP),0(REGI)    MOVE OUT FIRST CHAR.                 28180000
         LA    EAP,1(0,EAP)                                             28200000
         L     IN,AITL             GET ITAB POINTER                     28220000
         MVC   0(1,IN),0(REGI)     MOVE IN FIRST CHAR. TO ITAB          28240000
         LA    IN,1(0,IN)                                               28260000
         LA    K,1                 INITILIZE K                          28280000
         LA    REGIX,*+8                                                28300000
IDCHECK2 LA    REGI,1(0,REGI)      GET NEXT CHAR.                       28320000
         CLI   0(REGI),X'2F'       Q.WHAT IS CHAR.                      28340000
         BCR   4,REGB              NOT LETTER OR ZETA                   28360000
         BE    CIB                 ZETA                                 28380000
         C     K,KOPOOL+24         LETTER Q. 6 CHAR. MOVED ALLREADY     28400000
         BE    IDCHECK2            YES SKIP ADDITIONAL CHAR             28420000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             28440000
         MVC   0(1,EAP),0(REGI)    MOVE CHAR TO OUTPUT                  28460000
         LA    EAP,1(0,EAP)                                             28480000
         MVC   0(1,IN),0(REGI)               TO ITAB                    28500000
         LA    IN,1(0,IN)          INCREASE                             28520000
         LA    K,1(0,K)            POINTERS                             28540000
         B     IDCHECK2            GO AND CHECK NEXT CHAR.              28560000
         SPACE 2                                                        28580000
*****   FINDSEMC ****************************************************** 28600000
*                   CHECKS FOR SEMICOLON OR POINT- COMMA                28620000
*                   BLANKS AND I/P BUFFER CHANGE IS HANDLED             28640000
*                   IF SEMICOLON IS FOUND THE RETURN IS VIA REG12       28660000
*                   IF NOT THE RETURN IS VIA REGB                       28680000
         SPACE 2                                                        28700000
         LA    REGI,1(0,REGI)                                           28720000
FINDSEMC LA    REGIX,*                                                  28740000
         CLI   0(REGI),X'0B'       Q. SEMICOLON                         28760000
         BC    8,0(0,REG12)        EQUAL- SEMICOLON FOUND               28780000
         CLI   0(REGI),X'2D'       Q POINT                              28800000
         BE    FINDCOMA                 YES- LOOK FOR COMMA             28820000
         CLI   0(REGI),X'2B'       Q BLANK                              28840000
         BE    FINDSEMC-4                                               28860000
         CLI   0(REGI),X'2F'                                            28880000
         BE    CIB                                                      28900000
         BCR   15,REGB             ERROR- NO SEMICOLON                  28920000
FINDCOMA LA    REGIX,*+8                                                28940000
         LA    REGI,1(0,REGI)                                           28960000
         CLI   0(REGI),X'25'       Q COMMA                              28980000
         BC    8,0(0,REG12)        EQUAL- SEMICOLON FOUND               29000000
         CLI   0(REGI),X'2B'       Q BLANK                              29020000
         BE    FINDCOMA+4                                               29040000
         CLI   0(REGI),X'2F'                                            29060000
         BE    CIB                                                      29080000
         BCR   15,REGB             ERROR NO SEMICOLON                   29100000
         SPACE 2                                                        29120000
*****   ITABCLEA ***                                                    29140000
*                   CHECKS FOR ITABOVERFLOW AND CLEARS THE NEXT ENTRY   29160000
         SPACE 2                                                        29180000
ITABCLEA L     REGY,AITL                                                29200000
         LA    REGY,11(0,REGY)                                          29220000
         C     REGY,ELI            Q ROOM FOR ONE MORE ITAB ENTRY       29240000
         BL    *+10                                                     29260000
         BAL   REGB,ERR4                                                29280000
         DC    X'04D5'             E213                                 29300000
         LR    IN,REGY             INCREASE ITAB POINTERS               29320000
         ST    REGY,AITL                                                29340000
         MVI   0(REGY),X'00'       CLEAR NEXT                           29360000
         MVC   1(10,REGY),0(REGY)  ITAB ENTRY                           29380000
         BCR   15,REG12            RETURN                               29400000
IEX11001 CSECT                                                          29420000
         SPACE 2                                                        29440000
*****   COB      ****************************************************** 29460000
*                   CHECKS IF NEW O/P BUFFER IS NEEDED                  29480000
*                   ENTRY IS TO COBSPEC IF TWO OR MORE CONTINIOUS       29500000
*                        BYTES ARE NEEDED                               29520000
*                   THE CHANGE OF ADDRESS BETWEEN THE TWO BUFFERS IS    29540000
*                        DONE WITH DISP. DISP IS EITHER 0 OR 4          29560000
*                        SO ADDARI+DISP WILL PICK UP EITHER ADDARI OR   29580000
*                        THE ADDRESS OF THE ALTERNATE O/P BUFFER        29600000
*                   WADDARI POINTS TO THE FIRST BYTE OF THE CURRENT     29620000
*                        O/P BUFFER                                     29640000
*                   EAP IS THE CURRENT O/P POINTER                      29660000
*                   APE POINTS TO THE LAST BYTE OF THE CORRENT BUFFER   29680000
*                   ONC CONTAINS THE CURRENT O/P RECORD NUMBER          29700000
*                   ZETA IS THE BUFFER END INDICATION                   29720000
         SPACE 2                                                        29740000
COBSPEC  C     REG0,APE                 Q. SPACE LEFT FOR X MORE BYTES  29760000
         BC    4,0(0,REGOX)             YES- RETURN                     29780000
         B     *+12                NO CHANGE OUTPUT BUFFER FIRST        29800000
COB      C     EAP,APE                  Q. SPACE LEFT FOR ONE MORE BYTE 29820000
         BC    4,0(0,REGOX)             YES- RETURN                     29840000
         MVI   0(EAP),X'2F'             MOVE ZETA TO O/P BUFFER         29860000
         STM   14,2,SAVE1          SAVE REGISTERS                       29880000
         ST    REGB,SAVE1+24                                            29900000
         CLI   ONC,X'FF'           Q ALREADY 256 OUTPUTRECORDS          29920000
         BL    *+10                                                     29940000
         BAL   REGB,ERR4           IF YES TERMINATE COMPILATION         29960000
         DC    X'04D7'             E215                                 29980000
         L     EAP,WADDARI         LOAD ADD. OF CURRENT  O/P REC        30000000
         LA    REGB,DCBUT1         DCBADDRESS                           30020000
         CLI   ONC,X'00'           Q FIRST OUTPUTRECORD                 30040000
         BE    WRITEOB             IF YES SKIP CHECK                    30060000
         CHECK ODECB               CHECK IF BEFORELAST RECORD IS        30080000
*                                  WRITTEN                              30100000
WRITEOB  WRITE ODECB,SF,(REGB),(EAP)                                    30120000
         XI    DISP,X'04'          CHANGE ADDRESSDISPLACEMENT           30140000
         IC    REGZ,DISP                                                30160000
         L     EAP,ADDARI(REGZ)         COMPUTE VALID O/P BUFFERADD     30180000
         ST    EAP,WADDARI              STORE IT IN WADDARI             30200000
         LR    REGL,EAP            COMPUTE ADDRESS OF LAST BYTE IN      30220000
         A     REGL,SRCE1S         THE NEW OUTPUT AREA                  30240000
         BCTR  REGL,0              AND SAVE IT                          30260000
         ST    REGL,APE            IN APE                               30280000
         IC    REGZ,ONC            INCREASE OUTPUTRECORDCOUNTER         30300000
         LA    REGZ,1(0,REGZ)                                           30320000
         STC   REGZ,ONC                                                 30340000
         L     REGB,SAVE1+24                                            30360000
         LM    14,2,SAVE1                                               30380000
         BCR   15,REGOX                 RETURN TO CALLING SEQUENCE      30400000
         SPACE 2                                                        30420000
*****   CIB      ****************************************************** 30440000
*                   GET NEXT RECORD AND PRINTS IT WITH THE SC           30460000
*                   IF ISO CODE IS SPECIFIED A TRANSLATION IS FIRST     30480000
*                        MADE TO EBCDIC                                 30500000
*                   THE RECORD IS TRANSLATE AND THE RECORD END          30520000
*                        INDICATION - ZETA- IS INSERTED                 30540000
         SPACE 2                                                        30560000
CIB      STM   14,2,SAVE1          SAVE REGISTERS                       30580000
         SH    REGI,SEVEN          MOVE SEVEN CHAR INFRONT              30600000
         MVC   WABEFOR(7),0(REGI)  OF WORKAREA                          30620000
         TM    HCOMPMOD+1,NSRCE         Q. NOSOURCE SPECIFIED           30640000
         BO    GETREC                   YES SKIP PRINTING               30660000
         L     15,PRTRTADD              PRINT                           30680000
         BALR  14,15                                                    30700000
         ST    REGI,APRNTAR             SAVE NEW PRINT BUFFER ADDRESS   30720000
GETREC   L     REGI,INADD               DCBADDRESS                      30740000
         GET   (1),WA              GET NEXT RECORD                      30760000
TESTISO  TM    HCOMPMOD+1,ISO      TEST IF ISO INPUT                    30780000
         BO    ISOTRANS                 YES TRANSLATE ISO TO EBCDIC     30800000
         L     REGI,APRNTAR                                             30820000
         TM    HCOMPMOD+1,NSRCE         Q. NOSOURCE SPECIFIED           30840000
         BO    NOPRINT                  YES- MOVE TO DUMMY PRINTAREA    30860000
         LH    REGY,SC        CONVERT  SEMICOLON  COUNTER               30880000
         CVD   REGY,DOUBLE                                              30900000
         UNPK  0(5,REGI),DOUBLE(8)                                      30920000
         MVZ   4(1,REGI),3(REGI)        MOVE OUT SC COUNTER             30940000
         MVC   8(80,REGI),WA       MOVE RECORD TO PRINTAREA             30960000
         B     *+10                                                     30980000
NOPRINT  MVC   SAVEPRNT+8(72),WA   IF NSRCE MOVE RECORD TO DUMMY PRINT  31000000
         LM    14,2,SAVE1                                               31020000
         LA    REGI,WA             SET INPUT POINTER                    31040000
         TR    WA(72),TRLTABLE     TRANSLATE RECORD                     31060000
         MVI   72(REGI),X'2F'      MOVE RECORD END IDENTIFIER           31080000
         BCR   15,REGIX            RETURN                               31100000
ISOTRANS ST    REGB,SAVE1+24                                            31120000
         LA    REGB,WA                  GET START OF WA                 31140000
         LA    REGY,79(0,REGB)          GET END OF WA                   31160000
LOOP     CLI   0(REGB),X'4C'       )                                    31180000
         BE    IRPAR                                                    31200000
         CLI   0(REGB),X'7B'       =                                    31220000
         BE    IEQUAL                                                   31240000
         CLI   0(REGB),X'7C'       '                                    31260000
         BE    IAPOST                                                   31280000
         CLI   0(REGB),X'6C'       (                                    31300000
         BE    ILPAR                                                    31320000
         CLI   0(REGB),X'50'       +                                    31340000
         BNE   LOOPEND                                                  31360000
         MVI   0(REGB),X'4E'       +                                    31380000
         B     LOOPEND                                                  31400000
IRPAR    MVI   0(REGB),X'5D'       )                                    31420000
         B     LOOPEND                                                  31440000
IEQUAL   MVI   0(REGB),X'7E'       =                                    31460000
         B     LOOPEND                                                  31480000
IAPOST   MVI   0(REGB),X'7D'       '                                    31500000
         B     LOOPEND                                                  31520000
ILPAR    MVI   0(REGB),X'4D'       (                                    31540000
LOOPEND  LA    REGB,1(0,REGB)                                           31560000
         CR    REGB,REGY                Q. ALL CHAR. CHECKE IN WA       31580000
         BNH   LOOP                     NO- CHECK NEXT                  31600000
         L     REGB,SAVE1+24            YES RETURN                      31620000
          B     TESTISO+8                                               31640000
         SPACE 2                                                        31660000
*****   WITAB    ****************************************************** 31680000
*                   CONTAINS ALL DELIMITERS, EACH FOLLOWED BY           31700000
*                        3 BYTES OF INFORMATION, 2 CHARACTERISTICS      31720000
*                   AND A DISPLACEMENT TO DELPRGTB                      31740000
         SPACE 2                                                        31760000
W1TAB    DS    0CL256                                                   31780000
B1       DC    X'020304000006000004'                                    31800000
*                  SLASH    STRING                                      31820000
B2       DC    X'03434E1C000848451D000C4E51220000'                      31840000
*                   DO        IF        OR                              31860000
B3       DC    X'04444D43000010454E51000014404D432300004D4E53200000'    31880000
*                   END                     AND         NOT             31900000
B4       DC    X'095144404BC212185253444F1900005347444D1E0008444B52441F$31920000
               0008464E534E17000C5351544407001C4B445252110000424E4344'  31940000
*                   REAL          STEP          THEN         ELSE       31960000
*                   GOTO          TRUE          LESS         CODE       31980000
         DC    X'000020484C4F4B210000'                                  32000000
*                       IMPL                                            32020000
*                       IMPL                                            32040000
B5       DC    X'0A414446484D000024544D53484B1A00004051514058CA16285540$32060000
               4B544400002C4B4041444BCA18305647484B441B000045404B5244'  32080000
*                   BEGIN           UNTIL          ARRAY            VA  32100000
*              LUE          LABEL           WHILE           FALSE       32120000
         DC    X'00001C4F4E564451050000445054404B10000044'              32140000
*                       POWER           EQUAL                           32160000
         DC    X'50544855240000'                                        32180000
*                   EQUIV                                               32200000
B6       DC    X'02525648534247CA1C34525351484D46CB1030'                32220000
*                   SWITCH            STRING                            32240000
B7       DC    X'05484D5344464451C21118414E4E4B44404DC21318424E4C4C444D$32260000
               530000384D4E534B44525215000046514440534451120000'        32280000
*                   INTEGER             BOOLEAN              COMMENT    32300000
*                       NOTLESS             GREATER                     32320000
B8       DC    X'014D4E53445054404B130000'                              32340000
*                   NOTEQUAL                                            32360000
B9       DC    X'014F514E424443545144CAD03C'                            32380000
*                   PROCEDURE                                           32400000
B10      DC    X'014D4E5346514440534451140000'                          32420000
*                   NOTGREATER                                          32440000
         DS    0F                                                       32460000
         SPACE 2                                                        32480000
*****   LITAB    ****************************************************** 32500000
*                   USED TO SET REFERENCE IN W1TAB TO STRING            32520000
*                        DELIMITERS WITH A PATICULARY LENGTH            32540000
         SPACE 2                                                        32560000
L1TAB    DC    A(B1)                                                    32580000
         DC    A(B2)                                                    32600000
         DC    A(B3)                                                    32620000
         DC    A(B4)                                                    32640000
         DC    A(B5)                                                    32660000
         DC    A(B6)                                                    32680000
         DC    A(B7)                                                    32700000
         DC    A(B8)                                                    32720000
         DC    A(B9)                                                    32740000
         DC    A(B10)                                                   32760000
         SPACE 2                                                        32780000
*****   DELPRGTB ****************************************************** 32800000
*                   BRANCH ADDRESS TABLE USED AFTER A DELIMITER         32820000
*                        HAS BEEN FOUND                                 32840000
         SPACE 2                                                        32860000
DELPRGTB DS    0CL68                                                    32880000
         DC    A(NORMAL)                                                32900000
         DC    A(STRING)                                                32920000
         DC    A(TED)                                                   32940000
         DC    A(GIF)                                                   32960000
         DC    A(END)                                                   32980000
         DC    A(FOR)                                                   33000000
         DC    A(TYPE)                                                  33020000
         DC    A(BOLCON)                                                33040000
         DC    A(CODE)                                                  33060000
         DC    A(BEGIN)                                                 33080000
         DC    A(ARRAY)                                                 33100000
         DC    A(VALUE)                                                 33120000
         DC    A(SPEC)                                                  33140000
         DC    A(SWITCH)                                                33160000
         DC    A(COM)                                                   33180000
         DC    A(PROCEDUR)                                              33200000
         DC    A(TYPEARRY)                                              33220000
         DC    A(TYPPROC)                                               33240000
         SPACE 2                                                        33260000
*****   DELTMIT  ****************************************************** 33280000
*                   TWO APOSTROPHES HAVE BEEN FOUND                     33300000
*                   IT IS CHECKED THAT THE LENGTH IS NOT ZERO OR EXCEED 33320000
*                        THE LIMIT FOR A DELIMITER (10 CHARACTERS)      33340000
*                   REGM POINTS TO THE FIRST AND REGI TO THE LAST       33360000
*                        APOSTROPHE                                     33380000
*                   THE LENGTH IS USED TO GET A DISPLACEMENT FROM THE   33400000
*                        LITAB FOR A SECTION IN THE WITAB               33420000
*                   A    SECTION IN THE WITAR CONTAINS ALL DELIMITERS   33440000
*                        OF THE SAME LENGTH                             33460000
*                   THE FIRST BYTE IN EACH SECTION SAYS HOW MANY        33480000
*                        ENTRIES THERE ARE IN THE SECTION               33500000
*                        THEREAFTER A DELIMITER PLUS 3 BYTES OF         33520000
*                        INTERNAL CODE MAKES A SUBSECTION               33540000
*                        THE FIRST 2 BYTES OF THE INTERNAL CODE IS      33560000
*                        CHARECTERISTCS FOR THE DELIMITER               33580000
*                        THE THIRD BYTE IS A DISPLACEMENT TO THE        33600000
*                        DELPRGTB, WHERE THE ADDRESS IS PICKED UP       33620000
*                        TO THE PROGRAM TO HANDLE THE DELIMITER         33640000
*                   A CHECK IS MADE WHEN A DILIMITER IS FOUND IF IF IS  33660000
*                        THE FIRST FOUND IN THE PROGRAM - THE EXIT IS   33680000
*                        THEN TO STARTDEL. THE TEST IS ON BITS2 X'20'   33700000
*                   IF NO DELIMITER IS FOUND THE EXIT IS TO THE EROUT   33720000
*                        PROGRAM                                        33740000
*                   FBYTE- SWITCH                                       33760000
*                        THE FBYTE IS FF IF AN APOSTROPHE IS FOUND IN   33780000
*                        THE COMMENT PROGRAM                            33800000
*                        THE FBYTE IS F0 IF AN APOSTROPHE IS FOUND IN   33820000
*                        THE TYPE PROGRAM INSTEAD OF THE FIRST          33840000
*                        CHARACTER OF THE NAME                          33860000
*                        OTHERWISE IT IS 00                             33880000
         SPACE 2                                                        33900000
DELIMIT  SR    REGY,REGY                                                33920000
         SR    REGL,REGL                                                33940000
         LR    REGL,REGI                                                33960000
         BCTR  REGL,0                                                   33980000
         SR    REGL,REGM           COMPUTE LENGTH L                     34000000
         BP    *+10                     Q. GREATER THAN ZERO            34020000
         BAL   REGB,ERR6                                                34040000
         DC    X'0A0C'        E12 DELETE FIRST APOSTROPHE               34060000
         C     REGL,KOPOOL+44      Q. LIMIT EXEEDED ALLREADY            34080000
         BH    EROUT               BRANCH TO ERRORROUTINE               34100000
         BCTR  REGL,0                                                   34120000
         LA    REGX,L1TAB                                               34140000
         TM    FBYTE,X'FF'              TEST FBYTE                      34160000
         BO    COMSPEC                                                  34180000
         BM    TYPESPEC                                                 34200000
         SLA   REGL,2(0)               START OF LOOKUP STRING           34220000
         L     REGX,0(REGL,REGX)                                        34240000
         IC    REGY,0(0,REGX)      NUMBER OF ENTRIES IN THIS SECTION    34260000
         LA    REGX,1(0,REGX)      AND ADDRESS OF FIRST WORDENTRY       34280000
         SRA   REGL,2(0)                                                34300000
CLC      EX    REGL,COMPARE             Q. DELIMITER FOUND              34320000
         BNE   NOTEQUAL                    NO- TRY NEXT IN SAME SECTION 34340000
         IC    REGZ,3(REGL,REGX)                                        34360000
         TM    BITS2,X'20'              Q. PROGRAM STARTED YET          34380000
         BO    *+8                      YES                             34400000
         B     STARTDEL                 NO- CHECK FOR CORRECT START     34420000
         L     REGB,DELPRGTB(REGZ)      BRANCH TO APPROPRIATE SUBPGM    34440000
         BCR   15,REGB                  DEPENDING ON DISP IN WITAB      34460000
NOTEQUAL LA    REGX,4(REGL,REGX)   GET  NEXT DELIMITER                  34480000
         BCT   REGY,CLC                 Q. AMY DELIMITERS LEFT TO CHECK 34500000
         BC    15,EROUT            BRANCH TO ERRORROUTINE               34520000
         CNOP  0,4                                                      34540000
COMPARE  CLC   1(1,REGM),0(REGX)                                        34560000
         SPACE 2                                                        34580000
*****   EROUT    ****************************************************** 34600000
*                   CHECKS ALL SECTIONS OF THE WITAB FOR AN EQUAL       34620000
*                   DELIMITER TO THE ONE IN I/P, DISREGARDING LENGTH    34640000
*                   IF NO EQUAL FOUND E14 IS GENERATED AND THE FIRST    34660000
*                   APOSTROPHE IS DELETED. EXIT IS THEN TO TEST         34680000
*                   IF AN EQUAL IS FOUND E13 IS FENERATED AND AN BRANCH 34700000
*                   IS TAKEN TO THE APPROPRIATE SUBPROGRAM              34720000
         SPACE 2                                                        34740000
EROUT    TM    FBYTE,X'FF'                                              34760000
         BM    TYPESPEC                 INVALID IDENTIFIER              34780000
         BO    COMCEE2                 COMMENT                   A32949 34800000
EROUTOK  LA    REGZ,10       GO THROUGH ALL POSSIBILITIES               34820000
         SR    REGY,REGY                                                34840000
         LA    REGL,0                   INITILIZE REGL= 0               34860000
EROUT2   SLA   REGL,2(0)                                                34880000
         LA    REGX,L1TAB                                               34900000
         L     REGX,0(REGL,REGX)        GET SECTION IN WITAB            34920000
         IC    REGY,0(0,REGX)          NUMBER OF ENTRIES IN STRING      34940000
         LA    REGX,1(0,REGX)          FIRST ENTRY                      34960000
         SRA   REGL,2(0)                                                34980000
CLCERR   EX    REGL,COMPARE             Q. DELIMITER FOUND              35000000
         BNE   EROUT3                   NO                              35020000
         TM    BITS2,STARTBIT           Q. PROGRAM STARTED YET          35040000
         BZ    STARTDEL                 NO- CHECK FOR A CORRECT START   35060000
         BAL   REGB,ERR13                                               35080000
         DC    X'000D'             E13                                  35100000
         LA    REGI,1(REGL,REGM)  SET REGI TO ONE BEYOND DELIMITER      35120000
         IC    REGZ,3(REGL,REGX)       GET DISPLACEMENT OF PROGRAM      35140000
         L     REGB,DELPRGTB(REGZ)     IN DELPRGTB                      35160000
         BCR   15,REGB                 BRANCH TO PROGRAM                35180000
EROUT3   LA    REGX,4(REGL,REGX)   NO GET NEXT DELIMITER                35200000
         BCT   REGY,CLCERR             Q ALL DEL IN STRING CHECKED      35220000
         LA    REGL,1(0,REGL)          YES-GET NEXT STRING              35240000
         BCT   REGZ,EROUT2                                              35260000
         TM    BITS2,X'20'         Q. PROGRAM STARTED YET               35280000
         BZ    TESTLOOP            NO RETURN TO MAINLOOP SCANNING       35300000
         BAL   REGB,ERR2C                                               35320000
         DC    X'0A0E'        E14                                       35340000
         LA    REGI,1(0,REGM)          GET NEXT CHAR                    35360000
         BCR   15,RET                  RETURN                           35380000
         SPACE 2                                                        35400000
*****   TYPESPEC ****************************************************** 35420000
*                   'REAL'' OR 'INTEGER'' OR 'BOOLEAN'' HAS BEEN FOUND  35440000
*                   THE ONLY VALID DELIMITERS ARE AT THIS POINT         35460000
*                   ARRAY OR PROCEDURE                                  35480000
         SPACE 2                                                        35500000
TYPESPEC CLC   1(9,REGM),B9+1      Q. TYPE PROCEDURE                    35520000
         BE    TYPPROC                  YES                             35540000
         TM    BITS2,X'20'              Q. PROGRAM STARTED YET          35560000
         BZ    ERR8                     NO- GENERATE E11                35580000
         CLC   1(5,REGM),B5+17     Q. TYPE ARRAY                        35600000
         BE    TYPEARRY                 YES                             35620000
*                                       INVALID IDENTIFIER HAS BEEN     35640000
*                                       FOUND GO TO IER SPEC            35660000
TPSPECER TM    BITS1,X'40'              Q. SPECIFICATION                35680000
         BO    *+12                                                     35700000
         LA    REGH,TYPEDAFI            NO- SET RETURN TO TYPE PGM.     35720000
         B     IERSPEC                                                  35740000
         LA    REGH,IDCHECK             YES- SET RETURN TO IDCHECK      35760000
         B     IERSPEC                                                  35780000
         SPACE 2                                                        35800000
*****   COMSPEC  ******                                                 35820000
*                   TWO APOSTROPHES HAVE BEEN FOUND IN A COMMENT        35840000
*                   VALID DELIMITERS TO END A COMMENT ARE               35860000
*                   END OR ELSE                                         35880000
         SPACE 2                                                        35900000
COMSPEC  LA    REGX,B4+22      Q.COMMENT ENDING WITH ELSE               35920000
         CLC   1(4,REGM),B4+22                                          35940000
         BNE   *+16                     NO                              35960000
         C     REGL,KOPOOL+12      CHECK CORRECT LENGTH                 35980000
         BE    TED                                                      36000000
         B     ENTRAPR         RETURN TO FIND ANOTHER APOSTROPHE   4762 36020016
         CLC   1(3,REGM),B3+1           Q. COMMENT ENDED WITH END       36040000
         BNE   ENTRAPR         RETURN TO FIND ANOTHER APOSTROPHE   4762 36060016
         C     REGL,KOPOOL+8       CHECK CORRECT LENGTH                 36080000
         BE    END                 END                                  36100000
         B     ENTRAPR         RETURN TO FIND ANOTHER APOSTROPHE   4762 36120016
         SPACE 2                                                        36140000
*****   STARTDEL ****************************************************** 36160000
*                   THE ONLY VALID DELIMITERS TO START A PROGRAM IS     36180000
*                   BEGIN OR IF PRECOMPILED PROCEDURE IS SPECIFIED      36200000
*                   PROCEDURE OR TYPE PROCEDURE                         36220000
         SPACE 2                                                        36240000
STARTDEL STC   REGZ,BCHAR               GET DELIMITERS CHARACTERISTIC   36260000
*                                       FROM WITAB                      36280000
         CLI   BCHAR,X'24'              Q. BEGIN FOUND                  36300000
         BE    FIRSTBEG                 YES                             36320000
         TM    HCOMPMOD,PROC       Q. PRECOMPIELED SPECIFIED            36340000
         BZ    ERR8                     NO- GENERATE E11                36360000
         CLI   BCHAR,X'3C'         Q. FOUND WORD IS PROCEDURE           36380000
         BNE   TYPEPREC-8          NO                                   36400000
         B     PROCEDUR                 YES                             36420000
         CLI   BCHAR,X'18'         Q. TYPE FOUND                        36440000
         BNE   ERR8                NO                                   36460000
TYPEPREC LA    REGI,1(0,REGI)           LOOK FOR APOSTROPHE- TYPE PROC  36480000
         CLI   0(REGI),X'2E'            Q. APOSTROPHE FOUND             36500000
         BNE   *+10                                                     36520000
         BCTR  REGI,0                   YES- DECREASE TO LET TYPE PGM   36540000
         B     TYPE                     FIND THE APOSTROPHE AGAIN       36560000
         CLI   0(REGI),X'2B'            Q. BLANK                        36580000
         BE    TYPEPREC                                                 36600000
         CLI   0(REGI),X'2F'            Q. ZETA                         36620000
         BNE   ERR8                     NEITHER- GENERATE E11           36640000
         ST    REGX,SAVE1+20            CHANGE I/P AND LOOK AGAIN       36660000
         BAL   REGIX,CIB                                                36680000
         L     REGX,SAVE1+20                                            36700000
         B     TYPEPREC+4                                               36720000
         SPACE 2                                                        36740000
         SPACE 2                                                        36760000
*****   NORMAL   ****************************************************** 36780000
*                   INSERTS IN THE O/P THE INTERNAL CODE FROM WITAB     36800000
         SPACE 2                                                        36820000
NORMAL   BAL   REGOX,COB           CHECK IF O/P AREA FILLED             36840000
         LA    REGX,1(REGL,REGX)   COMPUTE ADDRESS OF CODE              36860000
         MVC   0(1,EAP),0(REGX)    MOVE CODE TO OUTPUTBUFFER            36880000
         LA    EAP,1(0,EAP)        INCREASE OUTPUT- AND                 36900000
         LA    REGI,1(0,REGI)      INPUTPOINTERS                        36920000
         BCR   15,RET                                                   36940000
         SPACE 2                                                        36960000
*****   BOLCON   ****************************************************** 36980000
*                   MOVES OUT SIX BYTES OF INTERNAL CODE FOR            37000000
*                   FALSE OR TRUE                                       37020000
         SPACE 2                                                        37040000
BOLCON   LA    REG0,6(0,EAP)                                            37060000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         37080000
         MVC   0(5,EAP),INT        TRANSFER FIRST PART OF INTERNAL NAME 37100000
         LA    REGN,1(REGL,REGX)   AND                                  37120000
         MVC   5(1,EAP),0(REGN)    LAST PART                            37140000
         LA    EAP,6(0,EAP)        INCREASE OUTPUT-                     37160000
         LA    REGI,1(0,REGI)      AND INPUTPOINTERS                    37180000
         BCR   15,RET                                                   37200000
         SPACE 2                                                        37220000
*****   GIF      ****************************************************** 37240000
*                   TRANSFERS INTERNAL CODEBYTE AND EXITS               37260000
*                   TO THE STATEMENT PROGRAM TO CHECK IF A PROCEDURE    37280000
*                   BOBY HAS STARTED                                    37300000
         SPACE 2                                                        37320000
GIF      BAL   REGOX,COB           CHECK IF O/P AREA FILLED             37340000
         LA    REGN,1(REGL,REGX)   TRANSFER INTERNAL CODE               37360000
         MVC   0(1,EAP),0(REGN)                                         37380000
         LA    EAP,1(0,EAP)        INCREASE OUTPUT-                     37400000
         LA    REGI,1(0,REGI)      AND INPUTPOINTER                     37420000
         BC    15,STATE            BRANCH TO STATEMENTPROGRAM           37440000
         SPACE 2                                                        37460000
*****   TED      ****************************************************** 37480000
*                   TRANSFERS INTERNAL CODE                             37500000
*                   SETS POSSIBLE LABEL POINTERS                        37520000
         SPACE 2                                                        37540000
TED      TM    BITS2,ENDBIT      Q. ELSE ENDED FINAL END COMMENT        37560000
         BO    ERR9              YES                                    37580000
         BAL   REGOX,COB                                                37600000
         LA    REGX,1(REGL,REGX)                                        37620000
         MVC   0(1,EAP),0(REGX)         TRANSFER INTERNAL CODE          37640000
         ST    EAP,OPIN                 SET LABEL POINTERS              37660000
         MVC   OPIN+4(1),ONC                                            37680000
         MVC   OPINCHAR(1),0(REGX)                                      37700000
         LA    EAP,1(0,EAP)                                             37720000
         ST    EAP,LAPIN                                                37740000
         LA    REGI,1(0,REGI)                                           37760000
         NI    BITS2,X'FE'         SET ENDELSE BIT TO ZERO              37780000
         BCR   15,RET                                                   37800000
         SPACE 2                                                        37820000
*****   BEGIN    ****************************************************** 37840000
*                   TEST IF PROC IN STACK                               37860000
*                   TRANSFERS 'BEGIN' TO OUTPUT AND STACK               37880000
*                   SETS OPIN, OPIN+4, LAPIN, BEGBIT                    37900000
*                   BEGBIT IS USED TO DISTINGUISH BETWEEN COMPOUND      37920000
*                        BEGIN AND BLOCK BEGIN. IF A DECLARATION IS     37940000
*                        FOUND WHEN THE BEGBIT IS ON IT'S A BLOCK BEGIN 37960000
*                        THE BEGBIT IS TURNED OF BY THE STATEMENT       37980000
*                        PROGRAM AND THE BEG1 PROGRAM                   38000000
         SPACE 2                                                        38020000
BEGIN    L     REGY,SP                                                  38040000
         CLI   0(REGY),X'0C'            Q. PROC IN STACK                38060000
         BE    BEGPROC             IF YES BRANCH TO PROC PROCESSING     38080000
         LA    REG0,4(0,EAP)                                            38100000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         38120000
         MVI   0(EAP),X'0C'   TRANSFER BEGIN TO O/P                     38140000
         MVI   OPINCHAR,X'0C'           SET LABELSAVE                   38160000
         ST    EAP,OPIN            NOTE ITS POSITION IN OPIN AND        38180000
         MVC   OPIN+4(1),ONC       THE NUMBER OF THE OUTPUTBUFFER       38200000
         LA    EAP,1(0,EAP)        INCREASE OUTPUTPOINTER               38220000
         ST    EAP,LAPIN           NOTE WHERE LABEL MAY START           38240000
         OI    BITS1,X'80'         BEGBIT.= 1                           38260000
         LA    REGY,1(0,REGY)     INCREASE STACKPOINTER                 38280000
         C     REGY,ATOPSTAK                                            38300000
         BL    *+10                                                     38320000
         BAL   REGB,ERR4           STACK OVERFLOW                       38340000
         DC    X'0414'             E20                                  38360000
         MVI   0(REGY),X'08'            PUT BEGIN IN STACK              38380000
         ST    REGY,SP                                                  38400000
         LA    REGI,1(0,REGI)                                           38420000
         B     TESTLOOP                                                 38440000
         SPACE 2                                                        38460000
*****   BEGPROC  ****************************************************** 38480000
*                   PROCEDURE- SPECIFICATIONS- BEGIN HAS BEEN FOUND     38500000
*                   PROC BOBY IS TO COME. PROC IS CHANGED TO PROC*      38520000
*                   ITS CHECKED THAT ALL PARAMETERS HAVE BEEN           38540000
*                        SPECIFIED                                      38560000
*                   THE RETURN IS TO TEST VIA THE BEGIN PROGRAM         38580000
         SPACE 2                                                        38600000
BEGPROC  MVI   0(REGY),X'10'       CONVERT PROC INTO PROC*              38620000
         NI    BITS1,X'BF'         PROBIT=0                             38640000
         CLI   PZ,X'00'            TEST IF ALL PARAMETERS SPECIFIED     38660000
         BE    BEGPROC-8                YES                             38680000
         BAL   REGOX,ERROR10            NO- GENERATE E11                38700000
         B     BEGPROC-8                                                38720000
         SPACE 2                                                        38740000
*****   FIRSTBEG ****************************************************** 38760000
*                   THE FIRST BEGIN IS CONSIDERED AS A BLOCK BEGIN      38780000
*                   THE START BIT IS TURNED OFF                         38800000
*                   THE BEG1 PROGRAM IS JOINED                          38820000
*                   IF PRECOMPILED PROCEDURE HAS BEEN SPECIFID E42 IS   38840000
*                        GIVEN AS A WARNING AND THE BEGIN IS            38860000
*                        DISREGARDED                                    38880000
         SPACE 2                                                        38900000
FIRSTBEG TM    HCOMPMOD,PROC       Q. PRECOMPIELED PROCEDURE            38920000
         BZ    *+18                                                     38940000
         BAL   REGB,ERR7           YES  GIVE WARNING MESSAGE            38960000
         DC    X'042A'                                                  38980000
         LA    REGI,1(0,REGI)      DISREGARD THE BEGIN                  39000000
         B     TESTLOOP                                                 39020000
         OI    BITS2,X'20'         NO  TURN STARTBIT OFF                39040000
         LA    REGX,TESTLOOP            MAKE RETURN FROM BEGI BE TEST   39060000
         LA    REGI,1(0,REGI)                                           39080000
         B     BEG1FRST       FIRST BEGIN =BLOCK BEGIN                  39100000
         SPACE 2                                                        39120000
*****   BEGI     ****************************************************** 39140000
*                   BLOCKBEGIN PROGRAM                                  39160000
*                   CHANGES BEGIN TO BETA IN STACK AND OUTPUT           39180000
*                   INCREASES ITAB GROUP NR. AND PROGRAM BLOCK NR.      39200000
*                   ENTRIES ARE MADE IN.                                39220000
*                        GROUPTABEL                                     39240000
*                             SORROUNDING BLOCKS IG. NR                 39260000
*                        PBTAB1                                         39280000
*                             SURROUNDING PBN                           39300000
*                        SCTAB - CURRENTSC COUNTER                      39320000
*                        ITAB                                           39340000
*                             ADDRESSES OF SORROUNDIN BLOCK AND         39360000
*                             IG HEADENTRIES, NEW PBN AND IGN.          39380000
*                   LPBP (ADDRESS OF CURRENT PROGRAM BLOCK HEAD ENTRY)  39400000
*                        AND                                            39420000
*                   LIGP (ADDRESS OF CURRENT ITAB GROUP HEAD ENTRY)     39440000
*                        ARE UPDATED                                    39460000
*                   PUTS BETA + NEW PBN AND IGN TO OUTPUT REC.          39480000
         SPACE 2                                                        39500000
BEG1     BCTR  EAP,0                                                    39520000
         NI    BITS1,BEGOFF        BEGBIT 0                             39540000
         CLI   0(EAP),X'0C'          Q. BEGIN IN O/P                    39560000
         BNE   ERROR21                  NO- DECLARATION INCORRECT PLACE 39580000
BEG1FRST MVI   0(EAP),X'0D'             MOVE BETA TO O/P                39600000
         L     REGY,SP             AND                                  39620000
         MVI   0(REGY),X'04'       STACK                                39640000
         SR    REGB,REGB                                                39660000
         LH    REGB,IGC                                                 39680000
         LA    REGB,1(0,REGB)           INCREASE ITABGROUPNUMBER        39700000
         STH   REGB,IGC                                                 39720000
         AR    REGB,REGB                ENTRY IS TO GO INTO             39740000
         AH    REGB,IGC                 A(GT)+3*(IGC)                   39760000
         A     REGB,AGT                                                 39780000
         L     REG7,LIGP                                                39800000
         MVC   0(2,REGB),8(REG7)        ENTRY INTO GROUPTABLE           39820000
         MVI   2(REGB),X'00'                                            39840000
         NI    0(REGB),X'7F'            CLEAR POSSIBLE PHI IND.         39860000
         CLI   PBC,X'FF'                Q. MORE THAN 255 BLOCKS         39880000
         BNE   *+10                                                     39900000
         BAL   REGB,ERR4                                                39920000
         DC    X'0416'             E22                                  39940000
         IC    REGZ,PBC                 INCREASE                        39960000
         LA    REGZ,1(0,REGZ)      PROGRAMBLOCKNUMBER                   39980000
         STC   REGZ,PBC                                                 40000000
         L     REG7,LPBP                                                40020000
         LA    REGB,PBTAB1                                              40040000
         AR    REGB,REGZ                                                40060000
         MVC   0(1,REGB),10(REG7)       ENTRY INTO PROGRAMBLOCKTABLE    40080000
         STC   REGZ,1(0,EAP)            TRANSFER PBN TO O/P             40100000
         AR    REGZ,REGZ           MAKE ENTRY OF CURRENT                40120000
         LA    REGB,SCTAB(REGZ)    SC COUNTER IN SCTAB                  40140000
         MVC   0(2,REGB),SC                                             40160000
         MVC   2(2,EAP),IGC        IGN IN OUTPUT BUFFER                 40180000
         LA    EAP,4(0,EAP)                                             40200000
         ST    EAP,LAPIN                SET LABEL POINTERS              40220000
         L     REGY,AITL                MAKE BLOCK HEAD IN ITAB         40240000
         MVC   0(4,REGY),LIGP                                           40260000
         MVC   4(4,REGY),LPBP                                           40280000
         MVC   8(2,REGY),IGC                                            40300000
         MVC   10(1,REGY),PBC                                           40320000
         ST    REGY,LPBP                UPDATE LIGP AND LPBP            40340000
         ST    REGY,LIGP                                                40360000
         BAL   REG12,ITABCLEA           CHECK AND CLEAR NEXT ITABENTRY  40380000
         BCR   15,REGX                                                  40400000
         SPACE 2                                                        40420000
*****   END      ****************************************************** 40440000
*                   ACTION DEPENDS ON WHAT IS IN THE STACK              40460000
*                   TURNS IN ALL CASES OFF THE DELTABIT AND THE         40480000
*                        END ELSE BIT                                   40500000
*                   GENERAL RETURN POINT IS CSPEND IF RETURN            40520000
*                        ADDRESS - IN REGE- IS NOT CHANGED              40540000
*                   FINAL RETURN IS TO TEST VIA SEMCO OR COMMENT        40560000
*                        PROGRAM                                        40580000
*                   PROC** IN STACK ACTIVATES PBLOCKEND AND RETURNS     40600000
*                        TO END TO INSPECT THE STACK AGAIN              40620000
         SPACE 2                                                        40640000
END      NI    BITS1,X'DF'         DELTABIT.=0                          40660000
         TM    BITS2,ENDBIT      Q. END FINISHED FINAL END COMMENT      40680000
         BO    ERR9              YES                                    40700000
         NI    BITS2,X'FE'         SET ENDELSE BIT TO ZERO              40720000
CSPEND   LA    REGE,*             RETURN FOR PBLCKEND, FOREND           40740000
         L     REGY,SP                                                  40760000
         IC    REGZ,0(0,REGY)      BRANCH                               40780000
         L     REGB,PROG1(REGZ)    DEPENDING ON TOPBYTE                 40800000
         BCR   15,REGB             OF THE STACK                         40820000
         CNOP  0,4                                                      40840000
PROG1    DC    A(ERR8)                  E11 IF ALPHA                    40860000
         DC    A(BLOCKEND)                     BETA                     40880000
         DC    A(COMPDEND)                     BEGIN                    40900000
         DC    A(PREND)                        PROC                     40920000
         DC    A(STAREND)                    PROC*                      40940000
         DC    A(PBLCKEND)                                              40960000
         DC    A(FOREND)                FOR                             40980000
         SPACE 2                                                        41000000
*****   STAREND  ****************************************************** 41020000
*                   PROC* HAS ENDED                                     41040000
*                        ACTIVATES THE PBLOCKEND PROGRAM AND RETURNS    41060000
*                        AFTERWARDS TO TEST VIA COMMENT PROGRAM         41080000
         SPACE 2                                                        41100000
STAREND  OI    BITS1,X'20'         DELTABIT= 1                          41120000
         LA    REGE,COMMEND        LOAD ADDRESS OF ENDENTRY INTO COM-   41140000
*                                  MENTPROGRAM                          41160000
         BC    15,PBLCKEND                                              41180000
         SPACE 2                                                        41200000
*****   PREND    ****************************************************** 41220000
*                   PROC  HAS ENDED                                     41240000
*                        CHECKS IF ALL PARAMETERS SPECIFIED             41260000
*                        TURNS OFF THE PROBIT                           41280000
*                   A PROC THAT ENDS WITH 'END' IS NOT CORRECTED,       41300000
*                        THEREFOR THE STACK IS AGAIN INSPECTED AFTER    41320000
*                        THE PBLOCKEND PROGRAM HAS BEEN ACTIVATED       41340000
         SPACE 2                                                        41360000
PREND    NI    BITS1,X'BF'         PROBIT.=0                            41380000
         CLI   PZ,X'00'            ALL PARAMETERS SPECIFIED             41400000
         BE    PBLCKEND                 YES- ACTIVATE PBLCKEND          41420000
         BAL   REGOX,ERROR10            NO- GENERATE E10 FIRST          41440000
         B     PBLCKEND                                                 41460000
         SPACE 2                                                        41480000
*****   COMPDEND ****************************************************** 41500000
*                   A COMPOUND STATMENT HAS ENDED                       41520000
*                        TRANSFERS END '2C' TO OUTPUT AND RELEASES      41540000
*                        BEGIN IN STACK                                 41560000
*                   THEN- IT CHECKS IF THE END OF THIS COMPOUND         41580000
*                        STATEMENT INDICATETS THE END OF ANY            41600000
*                        FORSTATMENT(S) OR PROC**.                      41620000
*                        THIS IS DONE WITH BITS2 X'01' AND THE          41640000
*                        COMMENT PROGRAM                                41660000
*                        IF THE END IS FOLLOWED BY A ., OR 'END' THE    41680000
*                        STACK IS INSPECTED AGAIN                       41700000
*                        IF THE END IS FOLLOWED BY AN 'ELSE' THE        41720000
*                        COUMPOUND STATMENT ITSELF IS ALL THAT HAS      41740000
*                        ENDED AT THIS POINT                            41760000
         SPACE 2                                                        41780000
COMPDEND BAL   REGOX,COB           CHECK IF O/P AREA FILLED             41800000
         MVI   0(EAP),X'2C'        TRANSFER END TO OUTPUTBUFFER         41820000
         LA    EAP,1(0,EAP)        INCREASE OUTPUTPOINTER               41840000
         L     REGY,SP             RELEASE BEGIN IN                     41860000
         BCTR  REGY,0              STACK                                41880000
         ST    REGY,SP                                                  41900000
COMPENDI CLI   0(REGY),X'00'       Q. ALPHA IN STACK                    41920000
         BE    PGMEND                   YES- LOGICAL PROGRAM END        41940000
         CLI   0(REGY),X'14'       Q. PROC**                            41960000
         BL    COMMEND             BRANCH TO COM-PROGRAM,END-ENTRY      41980000
*                                  FOR BEGIN OR BETA OR PROC* IN STACK  42000000
         OI    BITS2,X'01'         SET END-ELSE BIT                     42020000
         B     COMMEND                  CHECK HOW ENDCOMMENT ENDS       42040000
*                                  ENDCOMMENT ENDED WITH A SEMICOLON    42060000
COMPEND2 NI    BITS2,X'FE'         RESET END ELSE BIT                   42080000
         L     REGY,SP                  INSPECT STACK AGAIN             42100000
         CLI   0(REGY),X'14'            Q. PROC** OR FOR IN STACK       42120000
         BE    *+12                     PROC**                          42140000
         LA    REGE,COMPEND4            FOR  GOTO FORENS AND THEN       42160000
         B     FOREND                   TEST AGAIN - COMPEND4           42180000
COMPEND3 OI    BITS1,X'20'              PROC**- SET DELTABIT            42200000
         LA    REGE,SEMCO               RETURN FROM PBLCKEND            42220000
         B     PBLCKEND                 BLOCKEND FOR PROC**             42240000
COMPEND4 CLI   0(REGY),X'14'            Q. PROC**,FOR OR S.E.           42260000
         BE    COMPEND3                 PROC**                          42280000
         BH    FOREND                   FOR                             42300000
         B     SEMCO                    SOMETHING ELSE                  42320000
         SPACE 2                                                        42340000
*****   BLOCKEND ****************************************************** 42360000
*                   A BETA BLOCK HAS ENDED                              42380000
*                        THE RETURN AFTER THE PBLOCKEND PROGRAM IS      42400000
*                        TO THE COMPENDI TO CHECK IF SOME MORE          42420000
*                        ITAB GROUP SHOULD END AT THIS POINT            42440000
         SPACE 2                                                        42460000
BLOCKEND BAL   REGE,PBLCKEND       EXECUTE PROGRAMBLOCKEND-PROGRAM      42480000
         B     COMPENDI                                                 42500000
         SPACE 2                                                        42520000
*****   FOREND   ****************************************************** 42540000
*                   CORRECTS THE LIGP POINTER                           42560000
*                   INSERTS A CONTINUATION LINE IN ITAB IF THE          42580000
*                        FORSTATMENT CONTAINED ANY LABEL                42600000
*                   IF THE FORSTATMENT DID NOT CONTAIN ANY DEKLARATIONS 42620000
*                        THE PREVIOUSC CREATED FOR HEADENTRY IS         42640000
*                        ERASED                                         42660000
*                   IF ONE CONTINUATION LINE IS CREATED, FOLLOWING      42680000
*                        ENCLOSING FORSTATEMENTS WILL OVERLAY THE       42700000
*                        FIRST CONTINUATION LINE, IF LABELS OR NOT      42720000
*                   ETA AND SURROVNDING ITABGROUPS IG NR. IS MOVED      42740000
*                        TO THE OUTPUT                                  42760000
*                   FOR IS RELEASED IN THE STACK                        42780000
*                   ENTERED FROM SEMCO                                  42800000
*                                END                                    42820000
*                   EXITS TO     END                                    42840000
*                                COMPEND4                               42860000
*                                STACKTST (IN SEMCO)                    42880000
         SPACE 2                                                        42900000
FOREND   L     REGB,LIGP                                                42920000
         MVC   LIGP(4),0(REGB)     GET PREVIOUS LIGP HEAD               42940000
         L     REGY,AITL           CURRENT ENTRY                        42960000
         S     REGY,KOPOOL+44           MINUS ELEVEN                    42980000
         TM    6(REGY),X'FF'       Q. IS CONTINUATION LINE NEEDED       43000000
         BZ    EMPTYFOR            NO                                   43020000
         BO    *+8                 OVERLAY PREVIOUS CONT. LINE          43040000
         LA    REGY,11(0,REGY)     CREATE NEW CONT. LINE                43060000
         L     REGB,LIGP                                                43080000
         MVC   8(2,REGY),8(REGB)        COPY IG NUMBER                  43100000
         MVI   6(REGY),X'FF'       CONTINUATION LINE INDICATOR          43120000
         NI    8(REGY),X'7F'            CLEAR POSSIBLE PHI INDICATOR    43140000
         MVI   5(REGY),X'2B'                                            43160000
         BAL   REG12,ITABCLEA+4    CLEA NEXT ENTRY                      43180000
         B     *+8                                                      43200000
EMPTYFOR BAL   REG12,ITABCLEA+8    CLEAR FORHEAD FOR EMPTY FORGROUP     43220000
         LA    REG0,3(0,EAP)                                            43240000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         43260000
         MVI   0(EAP),X'2B'        INSERT ETA                           43280000
         L     REGB,LIGP                                                43300000
         MVC   1(2,EAP),8(REGB)    AND CURRENT  IGN  IN OUTPUTBUFFER    43320000
         NI    1(EAP),X'7F'        CLEAR EVENTUALLY PHI                 43340000
         LA    EAP,3(0,EAP)                                             43360000
         L     REGY,SP             RELEASE FOR IN STACK                 43380000
         BCTR  REGY,0                                                   43400000
         ST    REGY,SP                                                  43420000
         BCR   15,REGF             RETURN                               43440000
         SPACE 2                                                        43460000
*****   PBLCKEND ****************************************************** 43480000
*                   ERASES EMPTY CONTINUATION LINES                     43500000
*                   WRITES OUT THE PROGRAMBLOCK TO SYSUT 3              43520000
*                        LENGTH IS CALCULATED AND SAVED IN ITABLEN      43540000
*                        AND STORED IN THE FIRST TWO BYTES OF THE       43560000
*                        ITAB RECORD                                    43580000
*                   THE SC IS PICKED UP FROM SCTAB AND ENTERED IN BYTES 43600000
*                        6 AND 7                                        43620000
*                        THE BLOCK IS MOVED TO THE ITABBUFFER WHERE     43640000
*                        FROM IT IS WRITTEN OUT.                        43660000
*                   THE SURROUNDING BLOCKS NEW DECLARATIONS WILL        43680000
*                   BE OVERLAYING THE OUTWRITTEN RECORD                 43700000
*                   AITL WILL POINT TO THE HEADENTRY'S PLACE OF THE     43720000
*                       BLOCK WHICH NOW WAS WRITTEN OUT                 43740000
*                   LPBP TO THE SURROUNDING BLOCKS HEADENTRY            43760000
*                   LIGP TO THE SURROUNDING ITABGROUPS HEADENTRY        43780000
*                   AITL, LPBP AND LIGP WILL BE MODIFIED ACCORDINLY     43800000
*                   EPSILON, THE SURROUNDING BLOCKS PBN AND IGN WILL    43820000
*                        BE PUT TO THE OUTPUT                           43840000
*                   THE BLOCK INDICATOR IN THE STACK WILL BE RELEASED   43860000
*                   IF STACK NOW IS EMPTY - ALPHA IN STACK - PGMEND     43880000
*                        WILL SET THE END BIT AND CHANGE END OF DATA    43900000
*                        EXIT TO EODADIN. THIS WILL CAUSE THE COMMENT   43920000
*                        PROGRAM TO CHECK FOR AN CORRECT ENDCOMMENT     43940000
*                        BUT NOTHING MORE IS TO BE PROCESSED            43960000
*                   FOR PROGRAM BLOCK 0, IF ANY, THE BLOCK WILL ONLY    43980000
*                        BE WRITTEN OUT AND NO FURTHER ACTIONS TAKEN    44000000
*                   ENTERED FROM END (BETA, PROC* )                     44020000
*                                SEMCO (PROC, PROC**)                   44040000
*                   EXITS  TO    COMMEND  (NORMAL)                      44060000
*                                COMPEND4 ( PROC OR PROC** FOLLOWED BY  44080000
*                                          END)                         44100000
*                                TERMINATION (NOPBN0)                   44120000
         SPACE 2                                                        44140000
PBLCKEND L     REGY,AITL                                                44160000
         S     REGY,KOPOOL+44           SUBTRACT 11 TO EARSE            44180000
         CLI   6(REGY),X'00'       EMPTY                                44200000
         BE    *-8                      CONTINUATION                    44220000
         LA    REGY,11(0,REGY)                                          44240000
WRTITAB  S     REGY,LPBP            COMPUTE LENGTH OFITABSECTION        44260000
         ST    REGY,ITABLEN                                             44280000
         C     REGY,TWOK                Q. ITAB SECTION TOO LONG        44300000
         BL    *+10                                                     44320000
         BAL   REGB,ERR4                                                44340000
         DC    X'0426'        E38  MORE THAN 184 IDENTIFIERS            44360000
         MVC   AITL(4),LPBP             UPDATE AITL                     44380000
         L     REGB,LPBP                                                44400000
         MVC   LIGP(4),0(REGB)          UPDATE LIGP                     44420000
         MVC   LPBP(4),4(REGB)         UPDATE LPBP                      44440000
         MVC   0(2,REGB),ITABLEN+2      INSERT LENGTH IN HEADENTRY      44460000
         MVI   5(REGB),X'2B'                                            44480000
         STM   14,3,SAVE1          SAVE REGISTERS                       44500000
         SR    REGZ,REGZ                                                44520000
         IC    REGZ,10(0,REGB)          GET CORRENT PBN                 44540000
         AR    REGZ,REGZ           INSERT SC AT BLOCKSTART              44560000
         LA    REG7,SCTAB(REGZ)    IN HEADING                           44580000
         MVC   6(2,REGB),0(REG7)                                        44600000
         TM    BITS2,X'08'             IS IT PB0                 A28230 44604019
         BC    8,*+12                  NO                        A28230 44608019
         MVI   6(REGB),X'00'           CORRECT SC                A28230 44612019
         MVI   7(REGB),X'00'                FOR PB0              A28230 44616019
         TM    BITS3,FRSITB             Q. FIRST BLOCK TO BE WRITEN     44620000
         BZ    WRT1                     YES- DO NOT CHECK               44640000
         STM   14,15,ERRSAVE            CHECK PREVIOUS WRITE            44660000
         CHECK ITABC                                                    44680000
         LM    14,15,ERRSAVE                                            44700000
WRT      L     REG7,AITABBUF       ADDRESS OF BUFFER                    44720000
COMPARE1 C     REGY,D256                Q. MORE THAN 256 BYTES TO MOVE  44740000
         BL    EX1                      NO MOVE ALL AT ONCE             44760000
         MVC   0(256,REG7),0(REGB)      YES- MOVE A SECTION OF 256      44780000
         LA    REGB,256(0,REGB)         BYTES AT A TIME                 44800000
         LA    REG7,256(0,REG7)                                         44820000
         S     REGY,D256                                                44840000
         C     REGY,D256                Q. STILL MORE THAN 256 LEFT     44860000
         BH    COMPARE1+8               YES MOVE NEXT SECTION           44880000
EX1      EX    REGY,MOVE4               MOVE A SECTION OF LESS THAN 256 44900000
         LA    EAP,0(REGY,REG7)                                         44920000
         L     REG7,AITABBUF          LOAD ADD. OF ITABBUFFER           44940000
         L     REGY,UT3ADD                        DCB                   44960000
         L     REGL,ITABLEN                       LENGTH                44980000
        WRITE ITABC,SF,(REGY),(REG7),(REGL)                             45000000
         LM    14,3,SAVE1                                               45020000
         TM    BITS2,X'08'              Q. PB0 WAS WRITTEN              45040000
         BCR   1,REGE              BRANCH BACK IF TERBIT ON             45060000
         L     REGB,AITL                CLEAR                           45080000
         MVI   0(REGB),X'00'            NEXT                            45100000
         MVC   1(10,REGB),0(REGB)       ITABENTRY                       45120000
         LA    REG0,4(0,EAP)                                            45140000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         45160000
         MVI   0(EAP),X'2A'             INSERT EPSILON                  45180000
         L     REGB,LPBP                                                45200000
         MVC   1(1,EAP),10(REGB)                         PBN            45220000
         L     REGB,LIGP                                                45240000
         MVC   2(2,EAP),8(REGB)                          IGN            45260000
         NI    2(EAP),X'7F'        CLEAR FIRST BIT OF IGN (PHI IND)     45280000
         LA    EAP,4(0,EAP)                                             45300000
         L     REGY,SP       RELEASE                                    45320000
         BCTR  REGY,0        TOPBYTE                                    45340000
         ST    REGY,SP       IN STACK                                   45360000
         TM    BITS1,X'01'        Q. TERMINATION BIT ON                 45380000
         BCR   1,REGE                   YES- RETURN TO ENDMISS PGM.     45400000
         CLI   0(REGY),X'00'         Q.  STACK EMPTY                    45420000
         BE    PGMEND                   YES- LOGICAL PROGRAM ENP        45440000
         BCR   15,REGE                  RETURN                          45460000
PGMEND   OI    BITS2,ENDBIT      SET ENDBIT                             45480000
         LA    REGOX,EODADIN            NEW.EOD ADDRESS                 45500000
         ST    REGOX,EODIN                                              45520000
         B     COMMEND                                                  45540000
WRT1     OI    BITS3,FRSITB        DON'T CHECK FIRST TIME               45560000
         B     WRT                                                      45580000
         CNOP  0,4                                                      45600000
MOVE4    MVC   0(1,REG7),0(REGB)        PBLCKEND MOVE FOR ITAB          45620000
SCTAB    DS    CL510                                                    45640000
         SPACE 2                                                        45660000
*****   COMMENT  ****************************************************** 45680000
*                   THREE ENTRIES                                       45700000
*                       1 COM  FOR THE ALGOL WORD COMMENT               45720000
*                             SETS CODIT=1, CHECKS THAT COMMENT IS IN   45740000
*                             A LEGAL POSSITION                         45760000
*                       2 COMERR FOR ERRORS IN DECLARATIONS ALL CHAR    45780000
*                             TO NEXT SEMICOLON WILL BE SKIPPED         45800000
*                             SET COBIT AND DELTABIT=1                  45820000
*                       3 COMMEND  ENTERED AFTER AN END IS FOUND.       45840000
*                             SKIPPS ALL CHARACTERS TO NEXT ., OR END   45860000
*                             OR ELSE                                   45880000
*                             SETS THE COBIT =0                         45900000
         SPACE 2                                                        45920000
COMERR   OI    BITS2,X'40'         SET COBIT AND                        45940000
         OI    BITS1,X'20'             DELTABIT ON                      45960000
         B     COMCEE2                                                  45980000
COMMEND  NI    BITS2,X'BF'           SET  COBIT TO 0                    46000000
         BC    15,COMCED2                                               46020000
COM      OI    BITS2,X'40'           SET  COBIT  TO  I                  46040000
         LR    REGM,EAP                                                 46060000
         BCTR  REGM,0                                                   46080000
         CLI   0(REGM),X'0C'            Q. BEGIN IN O/P                 46100000
         BE    COMCED2                                                  46120000
         BCTR  REGM,0                                                   46140000
         BCTR  REGM,0                                                   46160000
         CLI   0(REGM),X'0B'            Q. BETA IN O/P                  46180000
         BE    COMCED2                                                  46200000
         CLI   0(REGM),X'29'            Q. DELTA IN O/P                 46220000
         BE    COMCED2                                                  46240000
         BCTR  REGM,0                                                   46260000
         CLI   0(REGM),X'0D'            SEMICOLON IN O/P                46280000
         BE    COMCED2                                                  46300000
         BAL   REGB,ERR7                E18                             46320000
         DC    X'0412'                                                  46340000
COMCED2  LA    REGI,1(0,REGI)        INCREASE  REGI BY I                46360000
COMCEE2  BALR  REGIX,0                                                  46380000
         SR    REGZ,REGZ                                                46400000
         TRT   0(73,REGI),COMTABLE      SCAN THE COMMENT                46420000
         LA    REGM,0(REGZ,REGIX)       BRANCH WITH HELP OF DISP.       46440000
         BCR   15,REGM                  TO APPROPRIATE SUB. PGM.        46460000
         SPACE 2                                                        46480000
*****   COMAPOST *****                                                  46500000
*                   IF AN END COMMENT IS PROCESSED, COBIT= 0, CHECK IF  46520000
*                        APOSTROPHE IS THE START OF END OR ELSE         46540000
*                   OTHERWISE RETURN TO SCAN THE COMMENT AGAIN          46560000
         SPACE 2                                                        46580000
COMAPOST TM    BITS2,X'40'              Q. COBIT ON                     46600000
         BO    COMCED2                  YES- RETURN TO SCANNING AGAIN   46620000
         MVI   FBYTE,X'FF'              SET FBYTE                       46640000
         BC    15,ENTRAPR                 RETUN TO APOSTROFPROGRAM      46660000
COMZETA  B     CIB                 ZETA - RETURN TO COMERR              46680000
         SPACE 2                                                        46700000
*****   COMPOINT *****                                                  46720000
*                   CHECK FOR SEMICOLON ., IF NOT RETURN                46740000
         SPACE 2                                                        46760000
COMPOINT LA    REGB,COMCEE2             RETURN IF NOT SEMCOLON          46780000
         BAL   REG12,FINDSEMC                                           46800000
         SPACE 2                                                        46820000
*****   COMSEMCO *****                                                  46840000
*                   ENDELSE BIT ON- END COMMENT AFTER BEGIN OR BETA     46860000
*                        ENDED WITH A ., MEANS THAT THE END MIGHT ALSO  46880000
*                        CLOSE AN FORSTATEMENT OR A PROCEDURE           46900000
*                   ENDBIT ON- FINAL END HAS BEEN REACHED NOTHING IS TO 46920000
*                        FOLLOW THIS COMMENT IN THE CORRECT CASE        46940000
*                   AN SEMICOLON AFTER AN COMMENT IS NOT TO BE COUNTED  46960000
*                        THAT IS COBIT= 1 AND DELTABIT=0 RETURN TO      46980000
*                        TEST OTHERWISE RETURN VIA SEMICOLON PROGRAM    47000000
         SPACE 2                                                        47020000
COMSEMCO TM    BITS2,X'01'         END ELSE BIT                         47040000
         BO    COMPEND2            YES                                  47060000
         TM    BITS2,ENDBIT      Q.FINAL END COMMENT HAS ENDED          47080000
         BO    READROUT            YES OK                               47100000
         TM    BITS2,X'40'              Q. COMMENT                      47120000
         BZ    SEMCO                    NO                              47140000
         TM    BITS1,X'20'              Q. DELIMITER ERROR              47160000
         BO    SEMCO                    YES                             47180000
         LA    REGI,1(0,REGI)           FOR A COMMENT SKIP SEMICOLON    47200000
         B     TESTLOOP                                                 47220000
         SPACE 2                                                        47240000
*****   FOR      ****************************************************** 47260000
*                   INCREASES IG AND FSN NUMBER                         47280000
*                   MAKES ENTRIES IN SCOPE AND GROUPTABEL               47300000
*                   MOVES FOR (18) TO OUTPUT FOLLOWED BY NEW IG NUMBER  47320000
*                   CHECKS IF PROC IN STACK, IF YES PROC IS CHANGED TO  47340000
*                        PROC**                                         47360000
*                   PUTS FOR IN STACK                                   47380000
*                   AN FORHEAD ENTRY IS MADE IN ITAB                    47400000
*                   THE RETURN IS TO TEST                               47420000
         SPACE 2                                                        47440000
FOR      LA    REG0,3(0,EAP)                                            47460000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         47480000
         LH    REGY,IGC            INCREASE ITABGROUPNUMBER             47500000
         LA    REGY,1(0,REGY)                                           47520000
         MVI   0(EAP),X'18'        MOVE 'FOR'                           47540000
         STH   REGY,IGC            AND  IGN                             47560000
         MVC   1(2,EAP),IGC                                             47580000
         LA    EAP,3(0,EAP)        TO OUTPUTBUFFER                      47600000
         CLI   FSN,X'FF'           Q. MORE THAN 255 FOR STATEMENTS      47620000
         BNE   *+10                                                     47640000
         BAL   REGB,ERR4                                                47660000
         DC    X'0429'             E41                                  47680000
         IC    REGZ,FSN            INCREASE FSN                         47700000
         LA    REGZ,1(0,REGZ)                                           47720000
         STC   REGZ,FSN                                                 47740000
         LA    REG12,SPTAB-1                                            47760000
         AR    REG12,REGZ                                               47780000
         L     REGY,LPBP                                                47800000
         MVC   0(1,REG12),10(REGY) MAKE ENTRY IN SCOUPTABLE             47820000
         NI    BITS1,X'7F'              BEGBIT= 0                       47840000
         L     REG12,SP                                                 47860000
         C     REG12,ATOPSTAK           Q. STACK OVERFLOW               47880000
         BL    *+10                                                     47900000
         BAL   REGB,ERR4                                                47920000
         DC    X'0414'             E20                                  47940000
         CLI   0(REG12),X'0C'           Q. PROC IN STACK                47960000
         BNE   NOPROCBY                 NO                              47980000
         MVI   0(REG12),X'14'           MAKE PROC BE PROC**             48000000
         NI    BITS1,X'BF'        PROBIT=0                              48020000
         CLI   PZ,X'00'            Q.ALLPARAMETERS SPECIFIED            48040000
         BE    *+8                 YES                                  48060000
         BAL   REGOX,ERROR10       NO- GENERATE E10                     48080000
NOPROCBY L     REG12,SP                                                 48100000
         LA    REG12,1(0,REG12)    INCREASE STACKPOINTER                48120000
         MVI   0(REG12),X'18'      PUT FOR INTO STACK                   48140000
         ST    REG12,SP                                                 48160000
         LH    REG12,IGC                                                48180000
         AR    REG12,REG12                                              48200000
         AH    REG12,IGC                                                48220000
         A     REG12,AGT                                                48240000
         L     REGY,LIGP                                                48260000
         MVC   0(2,REG12),8(REGY)  ENTRY INTO GROUPTABLE                48280000
         STC   REGZ,2(REG12)                                            48300000
         NI    0(REGOX),X'7F'      CLEAR POSSIBLE PHI IND.              48320000
         L     REGY,AITL                                                48340000
         MVC   0(4,REGY),LIGP      CONSTRUCT FOR HEADENTRY IN ITAB      48360000
         MVI   5(REGY),X'2B'                                            48380000
         MVC   8(2,REGY),IGC                                            48400000
         ST    REGY,LIGP           UPDATE LIGP                          48420000
         BAL   REG12,ITABCLEA           CHECK AND CLEAR NEXT ITABENTRY  48440000
         LA    REGI,1(0,REGI)                                           48460000
         B     TESTLOOP                                                 48480000
         SPACE 2                                                        48500000
*****   TYPE     ****************************************************** 48520000
*                   ENTRED FOR INTEGER, REAL AND BOOLEAN                48540000
*                   TESTS FOR NEWBLOCK, BEGBIT, AND IF IDENTIFIER IS    48560000
*                        SPECIFIED, PROBIT                              48580000
*                   MOVES INTERNAL NAME CHARACTERISTICS AND PBN TO ITAB 48600000
*                   CHECKS THE IDENTIFIER FOR VALIDITY AND MOVES UP TO  48620000
*                        6 CHARACTERS TO ITAB EXTERNAL NAME             48640000
*                   IF THE FIRST CHARACTER FOUND IS AN OPOSTROPHE THE   48660000
*                        CHECK IS VIA APOSTROF, DELIMITER AND TYPESPEC  48680000
*                        FOR ARRAY OR PROCEDURE (FBYTE=F0)              48700000
         SPACE 2                                                        48720000
TYPE     TM    BITS1,X'40'               Q PROBIT = 1                   48740000
         BO    SPECENT                   YES                            48760000
         TM    BITS1,X'80'               Q BEGBIT = 1                   48780000
         BZ    *+16                                                     48800000
         ST    REGX,SAVE1               IF YES GO TO BEGI PGM           48820000
         BAL   REGX,BEG1                                                48840000
         L     REGX,SAVE1                                               48860000
         L     REGY,AITL                MOVE CHARACTERISTICS TO ITAB    48880000
         MVI   6(REGY),X'C0'             TO  THE  7TH  AND  8TH         48900000
         MVI   7(REGY),X'30'            BYTE OF THE ENTRY               48920000
         LA    REGB,2(REGL,REGX)        MODIFIY THE LAST 4 BITS WITH    48940000
         MVN   7(1,REGY),0(REGB)        INFORMATION FROM THE WITAB      48960000
         L     REGB,LPBP                                                48980000
         MVC   8(1,REGY),10(REGB)  MOVE IN PROGRAMBLOCK NUMBER          49000000
TYPEDAFI LA    REGI,1(0,REGI)            GET NEXT CHARACTER             49020000
         CLI   0(REGI),X'40'       Q IS CHAR A LETTER                   49040000
         BNL   TYPENAME                  YES                            49060000
         CLI   0(REGI),X'2B'               Q IS IT BLANK                49080000
         BE    TYPEDAFI                                                 49100000
         CLI   0(REGI),X'2F'     Q. IS IT ZETA                          49120000
         BNE   *+12                                                     49140000
         LA    REGIX,TYPEDAFI+4    CHANGE INPUT                         49160000
         BC    15,CIB                       BUFFER                      49180000
         CLI   0(REGI),X'2E'               Q  IS  IT  APOSTROPHE        49200000
         BE    *+12                                                     49220000
         LA    REGH,TYPEDAFI               STORE RETURN ADDR            49240000
         B     IERSPEC             GO TO ERRORROUTINE                   49260000
         MVI   FBYTE,X'F0'                 MOVE F0 TO FBYTE             49280000
         BC    15,ENTRAPR               CHECK FOR TYPE ARRAY OR PROC    49300000
TYPENAME L     IN,AITL             GET ITAB POINTER                     49320000
         MVC   0(1,IN),0(REGI)     MOVE FIRST CHAR. TO ITAB             49340000
         LA    IN,1(0,IN)          INCREASE POINTER                     49360000
         LA    K,1                 INITILIZE COUNTER                    49380000
         LA    REGIX,*+8           RETURN IF CHANGE OF I/P BUF. NEEDED  49400000
TYPENM02 LA    REGI,1(0,REGI)      GET NEXT CHAR.                       49420000
         CLI   0(REGI),X'2F'       Q. LETTER, ZETA OR SOMETHING ELSE    49440000
         BE    CIB                 CHANGE I/P BUFFER                    49460000
         BL    TLISTSE             CHECK FURTHER                        49480000
         C     K,KOPOOL+24         Q. 6 CHAR. ALLREADY MOVED IN         49500000
         BE    TYPENM02            YES                                  49520000
         MVC   0(1,IN),0(REGI)     NO- MOVE IN NEXT CHAR                49540000
         LA    IN,1(0,IN)          INCREASE                             49560000
         LA    K,1(0,K)            POINTERS                             49580000
         B     TYPENM02            TAKE NEXT CHAR.                      49600000
TLISTSE  CLI   0(REGI),X'2B'  Q. BLANK                                  49620000
         BE    TYPENM02                                                 49640000
         CLI   0(REGI),X'25'       Q. COMMA                             49660000
         BE    TYPECOMA                                                 49680000
         LA    REGH,TYPEDAFI            RETURN ADDRESS FOR IER          49700000
         LA    REGB,IER                 RETURN ADDRESS IF NO SEMICOLON  49720000
         BAL   REG12,FINDSEMC           LOOK FOR SEMICOLON              49740000
         SPACE 2                                                        49760000
*****   TYPESEMC ******                                                 49780000
*                   SEMICOLON FOUND                                     49800000
*                   END OF THIS DECLARATION                             49820000
*                   DELTABIT IS TURNED ON AND THE RETURN TO TEST IS     49840000
*                        VIA SEMCO                                      49860000
         SPACE 2                                                        49880000
TYPESEMC BAL   REG12,ITABCLEA           CLEAR NEXT ITAB ENTRY           49900000
         OI    BITS1,X'20'              SET DELTABIT TO ONE             49920000
         B     SEMCO                    GO TO SEMICOLON PROGRAM         49940000
         SPACE 2                                                        49960000
*****   TYPECOMA ******                                                 49980000
*                   AN COMMA ENDED THE IDENTIFIER                       50000000
*                   THE INTERNAL NAME IS COPIED AND TYPEPROGRAM         50020000
*                        UTILIZED AGAIN                                 50040000
         SPACE 2                                                        50060000
TYPECOMA L     REGA,AITL                                                50080000
         BAL   REG12,ITABCLEA           CHECK AND CLEAR NEXT ITABENTRY  50100000
         MVC   6(3,REGY),6(REGA)        COPY ID AND PBN FIELDS          50120000
         B     TYPEDAFI                 RETURN TO CHECK NEXT IDENTIFIER 50140000
         SPACE 2                                                        50160000
*****   IER      ****************************************************** 50180000
*                   IDENTIFIER ERROR ROUTINE                            50200000
*                   HAS 2 ENTRIES                                       50220000
*                       1. IERSPEC IF FIRST CHARACTER IS IN ERROR, E5   50240000
*                       2. IER ANY OTHER CHARACTER, E16                 50260000
*                   THE RETURN                                          50280000
*                       1. VIA REGH IF AN COMMA IS FOUND AFTER THE      50300000
*                             IDENTIFIER IN ERROR                       50320000
*                       2. TO TEST VIA SEMCO IF AN SEMICOLON IS FOUND   50340000
*                       3. TO PROCFIN IF AN RIGHT PARENTHESIS IS FOUND  50360000
*                             AND THE FMBIT IS ON WHITCH INDICATES      50380000
*                             THAT THE FORMAL PARAMETER LIST OF A       50400000
*                             PROCEDURE IS UNDER PROCESS                50420000
*                   REGH MIGHT LEAD TO TYPEDAFI                         50440000
*                                       IDCHECK                         50460000
*                                       PROCID                          50480000
         SPACE 2                                                        50500000
IERSPEC  BAL   REGB,ERR7                                                50520000
         DC    X'0405'             E5                                   50540000
         B     *+10                                                     50560000
IER      BAL   REGB,ERR2                                                50580000
         DC    X'0010'             E16                                  50600000
         L     IN,AITL                      RESET IN TO START           50620000
         MVI   0(IN),X'00'              CLEAR EXTERNAL NAME PART        50640000
         MVC   1(5,IN),0(IN)                                            50660000
IERCOMMA LA    REGI,1(0,REGI)                                           50680000
         LA    REGB,IERSELSE       RETURN IF NO SEMICOLON FOUND         50700000
         BAL   REG12,FINDSEMC      LOOK FOR SEMICOLON                   50720000
IERSEMCO L     REGY,AITL           SEMICOLON FOUND - END OF DECLARATION 50740000
         BAL   REG12,ITABCLEA+8    CLEAR ITAB ENTRY                     50760000
         TM    BITS3,FMBIT         Q. FORMAL PARAMETER LIST PROCESSED   50780000
         BO    SCYES3-8            YES RETURN TO PROCEDURE END          50800000
         OI    BITS1,X'20'         DELTABIT = 1                         50820000
         NI    BITS2,X'EF'              VALBIT=0                        50840000
         MVC   KB(2),KOPOOL        CKB = 00                             50860000
         B     SEMCO               RETURN TO TEST VIA SEMCO             50880000
IERSELSE CLI   0(REGI),X'25'       Q COMMA                              50900000
         BCR   8,REGH              RETURN IF COMMA FOUND                50920000
         TM    BITS3,FMBIT         Q. FORMAL PARAMETER LIST PROCESSED   50940000
         BZ    IERCOMMA            NO                                   50960000
         CLI   0(REGI),X'26'       Q CHAR IS RIGHT PARENTHESIS          50980000
         BE    PROCFIN        YES GO TO PROCEDURE END HANDLING          51000000
         B     IERCOMMA            CONTINUE CHECKING NEXT CHAR          51020000
         SPACE 2                                                        51040000
*****   CODE     ****************************************************** 51060000
*                   SETS THE PROBIT TO ZERO                             51080000
*                   CHECKS THAT CODE IS IN THE CORRECT PLACE AND IS     51100000
*                        FOLLOWED BY A SEMICOLON                        51120000
*                   CORRECTS THE INTERNAL NAME OF THE PROCEDURE         51140000
*                   TRANSFER THE NAME IN EXTERNAL FORM TO OUTPUT        51160000
*                   RETURNS VIA PROGRAM BLOCK END TO TEST               51180000
         SPACE 2                                                        51200000
CODE     NI    BITS1,X'BF'         PROBIT=0                             51220000
         CLI   PZ,X'00'            Q. ALL PARAMETERS SPECIFIED          51240000
         BZ    *+8                 YES                                  51260000
         BAL   REGOX,ERROR10       NO- GENERATE E10                     51280000
         L     REGY,SP                                                  51300000
         CLI   0(REGY),X'0C'       PROC IN STACK                        51320000
         BNE   CODERR              IF NO BRANCH TO ERROR                51340000
         LR    REGL,EAP                                                 51360000
         S     REGL,KOPOOL+12                                           51380000
         CLI   0(REGL),X'29'       Q. DELTA IN O/P                      51400000
         BNE   CODERR              IF NO  BRANCH TO ERROR               51420000
         L     REGY,LPBP                                                51440000
         S     REGY,KOPOOL+44      GET PROCEDURE NAME                   51460000
         XI    7(REGY),X'80'       INTERNAL NAME IS CORRECTED           51480000
         TM    19(REGY),X'80'      Q. TYPE PROCEDURE                    51500000
         BZ    *+8                                                      51520000
         XI    29(REGY),X'80'      YES- CORRECT SECOND NAME ENTRY       51540000
         LA    REG0,9(0,EAP)                                            51560000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         51580000
         MVI   0(EAP),X'3C'        TRANSFER GAMMA                       51600000
         MVC   1(6,EAP),0(REGY)    TRANSFER NAME AND                    51620000
         TR    1(6,EAP),RETRANS    CONVERT TO EXTERNAL CODE             51640000
         MVC   7(1,EAP),RETRANS    INSERT EXTERNAL BLANKS               51660000
         MVC   8(1,EAP),RETRANS                                         51680000
         LA    EAP,9(0,EAP)                                             51700000
         OI    BITS1,X'20'         DELTABIT.=1                          51720000
SEARCH   LA    REGB,NOSEMC         RETURN IF NO SEMICOLON FOUND         51740000
         LA    REGE,SEMCO          RETURN ADD. FOR PBLCKEND             51760000
         LA    REGI,1(0,REGI)                                           51780000
         BAL   REG12,FINDSEMC      Q. SEMICOLON FOLLOWS                 51800000
         B     PBLCKEND            SEMICOLON FOUND- GO TO PBLCKEND      51820000
NOSEMC   BAL   REGB,ERR7                                                51840000
         DC    X'040F'             E15                                  51860000
         LA    REGB,FINDSEMC       Q WAS A PERIOD FOUND                 51880000
         CR    REGB,REGIX                                               51900000
         BE    PBLCKEND            NO                                   51920000
         BCTR  REGI,0              YES-                                 51940000
         MVI   0(REGI),X'2D'       MOVE IN A PERIOD                     51960000
         BCTR  REGI,0              DECREASE REGI, WILL BE INCREASED     51980000
         B     PBLCKEND            BY SEMCO. RETURN VIA PBLCKEND        52000000
*                                  AND SEMCO TO TEST                    52020000
CODERR   BAL   REGB,ERR7                                                52040000
         DC    X'0418'             E24                                  52060000
         B     COMERR              SKIP TO NEXT SEMICOLON               52080000
         SPACE 2                                                        52100000
IEX11002 CSECT                                                          52120000
         SPACE 2                                                        52140000
*****   SPEC     ****************************************************** 52160000
*                   ENTERED FOR LABEL AND STRING                        52180000
*                   CHECKS THAT THEY ARE IN PROCEDURE HEAD              52200000
         SPACE 2                                                        52220000
SPEC     TM    BITS1,X'40'         Q. PROBIT ON                         52240000
         BO    SPECENT YES PROCESS SPECIFIED LABEL OR STRING            52260000
         BAL   REGB,ERR7                                                52280000
         DC    X'0419'             E25                                  52300000
         B     COMERR              SKIP TO NEXT SEMICOLON               52320000
         SPACE 2                                                        52340000
*****   SPECENT  ****************************************************** 52360000
*                   ENTERED FOR SPECIFICATIONS FROM                     52380000
*                                                 TYPE                  52400000
*                                                 SPEC                  52420000
*                                                ARRAY                  52440000
*                                                SWITCH                 52460000
*                                                PROCEDURE              52480000
*                   SAVES IN KB THE CHARACTERISTICS TAKEN FROM THE      52500000
*                        DELIMITER TABLE                                52520000
         SPACE 2                                                        52540000
SPECENT  LA    REGY,1(REGL,REGX)   MOVE IN IDFIELD                      52560000
         MVC   KB(2),0(REGY)                                            52580000
         SPACE 2                                                        52600000
*****   IDCHECK  ****************************************************** 52620000
*                   ENTERED FROM VALUE                                  52640000
*                                 TYPEARRAY                             52660000
*                                 TYPEPROCEDURE                         52680000
*                                  SPECENT                              52700000
*                   CHECKS THE NAME FOR FORMAL PARAMETERS               52720000
*                   FINDS THE ENTRY IN ITAB AND INSERTS THERE THE       52740000
*                        CHARACTERISTICS AND PROGRAM BLOCK NUMBER       52760000
*                   DECREASES THE PARAMETER COUNT PZ BY ONE FOR EACH    52780000
*                        CORRECT PARAMETER FOUND                        52800000
*                   IF A COMMA ENDS THE IDENTIFIER IDCHECK WILL BE      52820000
*                        ACTIVATED AGIAN                                52840000
*                   IF A SEMICOLON ENDS THE DELIMITER THE RETURN IS TO  52860000
*                        TEST VIA SEMICOLON PROGRAM                     52880000
         SPACE 2                                                        52900000
IDCHECK  LA    REGI,1(0,REGI)               GET NEXT  CHAR              52920000
         CLI   0(REGI),X'39'              Q IS IT A LETTER              52940000
         BNH   IDNOLETR                     NO                          52960000
         MVC   IDBUCKET(6),KOPOOL       CLEAR BUCKET WITH ZEROS         52980000
         LA    IN,IDBUCKET                                              53000000
         LA    REGL,1                                                   53020000
         MVC   0(1,IN),0(REGI)     MOVE FIRST CHAR. TO BOCKET           53040000
         LA    IN,1(0,IN)                                               53060000
         LA    REGIX,*+8           RETURN IF CIB NEEDED                 53080000
IDLOOP   LA    REGI,1(0,REGI)      GET NEXT CHAR.                       53100000
         CLI   0(REGI),X'2F'            Q ZETA                          53120000
         BE    CIB                      YES                             53140000
         BL    IDSEARCH                 SOMETHING ELSE                  53160000
         C     REGL,KOPOOL+24           LETTER OR DIGIT                 53180000
         BE    IDLOOP                   Q 6 CHAR MOVED ALLREADY YES     53200000
         MVC   0(1,IN),0(REGI)          NO MOVE CHAR                    53220000
         LA    IN,1(0,IN)          INCREASE POINTERS                    53240000
         LA    REGL,1(0,REGL)                                           53260000
         B     IDLOOP              TAKE NEXT CHAR.                      53280000
IDNOLETR CLI   0(REGI),X'2B'      FIRST CHAR WAS NOT LETTER. Q. BLANK   53300000
         BE    IDCHECK                       YES . GET NEXT CHAR        53320000
         CLI   0(REGI),X'2F'                Q  IS IT A ZETA             53340000
         BNE   *+12                                                     53360000
         LA    REGIX,IDCHECK+4         YES- CHANGE I/P-BUFFER           53380000
         BC    15,CIB                        BUFFER                     53400000
         CLI   0(REGI),X'2E'                 Q  IS IT A APOSTROPHE      53420000
         BE    *+12                                                     53440000
         LA    REGH,IDCHECK             NO- SET RETURN ADD AND GOTO     53460000
         B     IERSPEC                  IDENTIFIER ERROR ROUTINE        53480000
         MVI   FBYTE,X'F0'              SET FBYTE- LOOK FOR TYPE        53500000
         BC    15,ENTRAPR               ARRAY OR TYPE PROC              53520000
IDSELSE  BAL   REGB,ERR2E                                               53540000
         DC    X'0010'                  E16                             53560000
         LA    REGH,IDCHECK             RETURN ADD FOR IER              53580000
         B     IERCOMMA                 GO TO IDENTIFIER ERROR ROUTINE  53600000
IDBUCKET DC    6X'00'                                                   53620000
IDSEARCH CLI   0(REGI),X'2B'            Q BLANK                         53640000
         BE    IDLOOP                                                   53660000
         CLI   0(REGI),X'25'            Q COMMA                         53680000
         BE    IDCOMMA                                                  53700000
         LA    REGB,IDSELSE             IF NOT SEMICOLON FOUND          53720000
         BAL   REG12,FINDSEMC           LOOK FOR SEMICOLON              53740000
         OI    BITS1,X'20'              SEMICOLON FOUND SET DELTABIT    53760000
IDCOMMA  CLC   PRIMPAR(4),KOPOOL        Q. ARE THERE ANY PARAMETER      53780000
         BE    NOTFOUND                 NO                              53800000
         L     REGPS,PRIMPAR            GET FIRST PARAMETER             53820000
         SPACE 2                                                        53840000
*****   COMPID   ******                                                 53860000
*                   A LOOP TO FIND THE PARAMETER IN ITAB                53880000
         SPACE 2                                                        53900000
COMPID   CLC   IDBUCKET(6),0(REGPS)     CHECK IF IDENTIFIER FOUND       53920000
         BE    IDVALCHK                     FOUND                       53940000
         LA    REGPS,11(0,REGPS)        NOT FOUND  TRY NEXT PARAMETER   53960000
         C     REGPS,AITL                   IF THERE ARE ANY LEFT       53980000
         BNE   COMPID                       YES                         54000000
NOTFOUND BAL   REGB,ERR2E                                               54020000
         DC    X'001B'                  E27                             54040000
         B     IDENDER                                                  54060000
IDVALCHK TM    BITS2,X'10'                   VALUE  CALL                54080000
         BO    VALDLB2                      YES - GO TO VAL ROUTINE     54100000
         TM    6(REGPS),X'06'           Q SPECIAL USE BITS ON           54120000
         BZ    IDCHKEND                 NO                              54140000
         BAL   REGB,ERR2E               YES CREATE                      54160000
         DC    X'001A'                  E26                             54180000
         B     IDENDER        GET NEXT IDENTIFIER                       54200000
         SPACE 2                                                        54220000
*****   IDCHKEND ******                                                 54240000
*                   INSERTS CHARACTERISTICS AND PBN, DECRESES PZ        54260000
*                   IF BOTH VALUE AND NAME BIT ON BYTE 7 EQVALS 30      54280000
*                        A VALUE SPECIFICATION HAS BEEN MADE EARLIER    54300000
*                        SO IT IS CORRECTED TO BE A CALL BY VALUE       54320000
         SPACE 2                                                        54340000
IDCHKEND L     REGB,LPBP                                                54360000
         MVC   8(1,REGPS),10(REGB)      INSERT PBN                      54380000
         OC    6(2,REGPS),KB                                            54400000
         IC    REGB,PZ                 CORRECT IDFIELD IS CREATED       54420000
         BCTR  REGB,0              PZ= PZ-1                             54440000
         STC   REGB,PZ                                                  54460000
         TM    7(REGPS),X'30'           Q. VALUE BIT ON                 54480000
         BM    *+8                                                      54500000
VALCALL  NI    7(REGPS),X'EF'           YES- ZERO NAME BIT              54520000
IDENDER  TM    BITS1,X'20'         Q. DELTABIT ON                       54540000
         BZ    IDCHECK                  NO-GET NEXT  IDENT.             54560000
         MVC   KB(2),KOPOOL        YES CLEAR IDFIELD                    54580000
         NI    BITS2,X'EF'         SET VALBIT TO ZERO                   54600000
         BC    15,SEMCO                  GO TO SEMICOLON PROGRAM.       54620000
         SPACE 2                                                        54640000
*****   VALUE    ******                                                 54660000
*                   CHECKS THAT SPECIFICATION IS IN A PROCEDURE HEAD    54680000
*                   EXITS FIRST TO IDCHECK TO FIND THE PARAMETER        54700000
*                   WILL THEN RETURN TO VALDLB2 FOR FUTHER CHECKS AND   54720000
*                   TO INSERT THE VALUE BIT IN THE INTERNAL NAME        54740000
         SPACE 2                                                        54760000
VALUE    TM    BITS1,X'40'            Q PROCEDDRE  PROCECED             54780000
         BZ    *+12                   NO- ERROR                         54800000
         OI    BITS2,X'10'              YES- SET VALUE BIT TO ONE       54820000
         BC    15,IDCHECK             AND GO TO IDCHEK                  54840000
         BAL   REGB,ERR7                E28  VALVE                      54860000
         DC    X'041C'                   OUTSIDE PROC.                  54880000
         B     COMERR              SKIP TO NEXT SEMICOLON               54900000
VALDLB2  TM    7(REGPS),X'20'      Q. VALUE BIT ON IN IDENTIFIER        54920000
         BZ    *+14                     NO                              54940000
         BAL   REGB,ERR2E                                               54960000
         DC    X'001E'             E30                                  54980000
         B     IDENDER        GET NEXT IDENTIFIER                       55000000
         TM    6(REGPS),X'06'        Q SPECIAL USE BIT ENTERED          55020000
         BZ    *+18                     NO                              55040000
         BAL   REGB,ERR7                                                55060000
         DC    X'041D'             E29                                  55080000
         XI    7(REGPS),X'30'          MOVE IN IDFIELD                  55100000
         B     IDENDER        GET NEXT IDENTIFIER                       55120000
         MVI   7(REGPS),X'30'           CORRECT - MOVE IN IDFIELD       55140000
         B     IDENDER        GET NEXT IDENTIFIER                       55160000
         SPACE 2                                                        55180000
*****   TYPEARRAY ***************************************************** 55200000
*                   ENTERED FROM TYPESPEC                               55220000
*                   TEST FOR PROBIT, BEGBIT                             55240000
*                   INSERTS CHARACTERISTICS IN INTERNAL NAME WITHOUT    55260000
*                        DESTROYING THE TYPE SPECIFICATIONS ENTERED BY  55280000
*                        THE TYPE PROGRAM                               55300000
*                   JOINS ARRAY PROGRAM                                 55320000
*                   FOR A SPECIFIED TYPEARRAY THE EXIT IS TO IDCHECK    55340000
         SPACE 2                                                        55360000
TYPEARRY TM    BITS1,X'40'             Q IS PROBIT ON                   55380000
         BO    TARYDHB3               YES - SPECIFICATION               55400000
         TM    BITS1,X'80'              Q. BEGBIT ON                    55420000
         BZ    *+16                                                     55440000
         ST    REGX,SAVE1               YES                             55460000
         BAL   REGX,BEG1           GO AND PROCESS PROGRAMBLOCK HEAD     55480000
         L     REGX,SAVE1                                               55500000
         L     IN,AITL                                                  55520000
         MVI   6(IN),X'C8'              MOVE IN                         55540000
         XI    7(IN),X'34'              ID FIELD                        55560000
         BC    15,ARRYDME1           GO  TO ARRAY  PROCECING            55580000
TARYDHB3 MVI   KB,X'CA'                 MOVE IN                         55600000
         OI    KB+1,X'04'             TYPE ARRAY SPECIFICATION ID       55620000
         BC    15,IDCHECK                                               55640000
         SPACE 2                                                        55660000
*****   ARRAY    ****************************************************** 55680000
*                   TESTS FOR PRO AND BEGBIT                            55700000
*                   ENTERS CHARACTERISTICS IN INTERNAL NAME             55720000
*                TYPEARRAY JOINS HERE                                   55740000
*                   PBN IS ENTERED IN INTERNAL NAME                     55760000
*                   09 FOR ARRAY IS MOVED TO OUTPUT                     55780000
*                   THE NAME IS CHECKED AND MOVED TO OUTPUT AND ITAB    55800000
*                   SHOULD BE FOLLOWED BY A COMMA OR LEFT PARENTHISIS   55820000
*                SETS N (NUMBER OF ARRAYS WITH SAME DIMENSIONS) TO ONE  55840000
         SPACE 2                                                        55860000
ARRAY    TM    BITS1,X'40'               Q  PROBIT  ON                  55880000
         BO    SPECENT                    YES                           55900000
         TM    BITS1,X'80'               Q  BEGBITI  ON                 55920000
         BZ    *+16                                                     55940000
         ST    REGX,SAVE1     YES- GO TO PROCESS PROGRAMBLOCKHEAD       55960000
         BAL   REGX,BEG1                                                55980000
         L     REGX,SAVE1                                               56000000
         L     IN,AITL                                                  56020000
         MVI   6(IN),X'C8'              MOVE IN                         56040000
         MVI   7(IN),X'06'                IO-FIELD                      56060000
ARRYDME1 L     REGB,LPBP                                                56080000
         MVC   8(1,IN),10(REGB)           MOVE IN PROGRAMBLOCK NR.      56100000
         LA    REGB,9(0,IN)               MOVE  ADD  OF  AITL+9         56120000
         ST    REGB,DIM                   TO  DIM                       56140000
         BAL   REGOX,COB                                                56160000
         MVI   0(EAP),X'09'             MOVE ARRAY ID TO O/P            56180000
         LA    EAP,1(0,EAP)                                             56200000
ARRYNAME LA    REGI,1(0,REGI)           GET FIRST CHAR                  56220000
         CLI   0(REGI),X'39'            Q. LETTER                       56240000
         BNH   ARNAMESE                 NO                              56260000
         TM    BITS1,X'04'              Q. LISTBIT ON                   56280000
         BO    ARRYMULT                 YES                             56300000
         MVC   N(1),KOPOOL+7            SET N=1                         56320000
ARRYID   BAL   REGB,IDCHECK1       CHECK, MOVE IDENT. TO ITAB AND O/P   56340000
ARRYSE   CLI   0(REGI),X'2B'       Q. BLANK                             56360000
         BE    IDCHECK2                                                 56380000
         CLI   0(REGI),X'06'       Q  LEFT PARENTHESIS                  56400000
         BE    ARRYLPAR                                                 56420000
         CLI   0(REGI),X'25'       Q. COMMA                             56440000
         BE    ARCOMMA                                                  56460000
ARRAYERR BAL   REGB,ERR2           SOMETHING ELSE FOUND                 56480000
         DC    X'0010'             E16                                  56500000
         BAL   REGOX,COB                                                56520000
         MVI   0(EAP),X'3D'   MOVE IN RHA                               56540000
         LA    EAP,1(0,EAP)                                             56560000
ARYEXIT  L     REGY,AITL                                                56580000
         BAL   REG12,ITABCLEA+8         CLEAR ITAB-ENTRY                56600000
         NI    BITS1,X'F7'    TURN OFF ARBIT                            56620000
         LA    RET,TESTLOOP        RESET RETURN REGISTER TO MAINLOOP    56640000
         B     COMERR              SKIP TO NEXT SEMICOLON               56660000
ARNAMESE CLI   0(REGI),X'2B'       Q. NAME STARTS WITH BLANK            56680000
         BE    ARRYNAME                                                 56700000
         CLI   0(REGI),X'2F'       Q. ZETA                              56720000
         BNE   *+12                                                     56740000
         LA    REGIX,ARRYNAME+4                                         56760000
         B     CIB                                                      56780000
         BAL   REGB,ERR7                FIRST CHAR. OF NAME IN ERROR    56800000
         DC    X'0405'                                                  56820000
         B     ARYEXIT             DELETE DECLARATION                   56840000
         SPACE 2                                                        56860000
*****   ARRAYPAR ******                                                 56880000
*                   ENTERED WHEN A LEFT PARENTHESIS IS FOUND AFTER THE  56900000
*                        NAME                                           56920000
*                   INITILIZES D DIMENSION COUNTER=0                    56940000
*                   SETS THE ARBIT                                      56960000
*                              C PARENTHESIS COUNT=1                    56980000
*                   SEARCHES FOR A SLASH                                57000000
*                   MOVES OUT SUBSCRIPT BRACKETS TO OUTPUT              57020000
*                   EXITS TO ARRAYLIST                                  57040000
         SPACE 2                                                        57060000
ARRYLPAR OI    BITS1,X'08'              ARBIT = 1                       57080000
         LA    REGOX,1                                                  57100000
         STH   REGOX,C                  C=1                             57120000
         LA    REGOX,0                                                  57140000
         STC   REGOX,D                  D=0                             57160000
         LA    REGI,1(0,REGI)          GET NEXT CHAR                    57180000
ARRYSLSH CLI   0(REGI),X'03'            Q SLASH                         57200000
         BE    ARRYLSQB                 YES- MOVE IN LEFT SQ. BRACKET   57220000
         CLI   0(REGI),X'2B'            Q CHAR IS BLANK                 57240000
         BE    ARRYSLSH-4               YES-GET NEXT CHAR.              57260000
         CLI   0(REGI),X'2F'            Q CHAR IS ZETA                  57280000
         BNE   *+12                     NO-GOTO ERROR ROUTIEN           57300000
         LA    REGIX,ARRYSLSH           YES- CHANGE                     57320000
         BC    15,CIB                  INPUT  BUFFER                    57340000
         BAL   REGB,ERR2                                                57360000
         DC    X'001F'        E31                                       57380000
         BCTR  REGI,0                                                   57400000
ARRYLSQB BAL   REGOX,COB           CHECK IF O/P AREA FILLED             57420000
         MVI   0(EAP),X'08'             MOVE IN LEFT SQUAREBRACKET      57440000
         LA    EAP,1(0,EAP)             INCREASE                        57460000
         LA    REGI,1(0,REGI)      POINTERS                             57480000
         B     LIST                     GO TO PROCESS ARRAY LIST        57500000
         SPACE 2                                                        57520000
*****   ARCOMMA  ******                                                 57540000
*                   COPIES INTERNAL PART OF ITAB ENTRY SETS THE LISBIT  57560000
*                   EXITS TO ARRAYNAME TO CHECK FIRST CHARACTER OF NEXT 57580000
*                        NAME. THE LIST BIT WILL THEN CAUSE ARRAYMULT   57600000
*                        TO BE EXECUTED BEFORE THE REST OF THE NAME     57620000
*                        IS CHECKED                                     57640000
*                   INCREASES N, NUMBER OF ARRAYS WITH THE SAME         57660000
*                        DIMENSIONS, BY ONE                             57680000
         SPACE 2                                                        57700000
ARCOMMA  L     REGA,AITL                SAVE AITL                       57720000
         BAL   REG12,ITABCLEA           CHECK AND CLEAR NEXT ITABENTRY  57740000
         MVC   6(3,REGY),6(REGA)        COPY ID AND PBN FIELDS          57760000
         IC    REGB,N                   INCREASE                        57780000
         LA    REGB,1(0,REGB)      N                                    57800000
         STC   REGB,N                   BY ONE                          57820000
         OI    BITS1,X'04'              SET LISTBIT TO ONE              57840000
         B     ARRYNAME            GET NEXT EXTERNAL NAME               57860000
         SPACE 2                                                        57880000
*****   ARRAYMULT  ******                                               57900000
*                   MOVES OUT THE COMMA PREVIONSLY FOUND                57920000
*                   SETS THE LISTBIT TO ZERO                            57940000
*                   RETURNS TO ARRAYID (AVOIDS RESETING N TO ONE)       57960000
         SPACE 2                                                        57980000
ARRYMULT BAL   REGOX,COB                                                58000000
         MVI   0(EAP),X'25'        MOVE OUT THE COMMA                   58020000
         LA    EAP,1(0,EAP)                                             58040000
         NI    BITS1,X'FB'         SET LISTBIT TO ZERO                  58060000
         B     ARRYID                                                   58080000
         SPACE 2                                                        58100000
*****   ARTABLE  ****************************************************** 58120000
*                  USED BY LIST EQUIVALENT TO THE USE OF TESTTABLE      58140000
*                        BY TESTLOOP. GIVES DISPLACEMENT TO BPRTAB      58160000
         SPACE 2                                                        58180000
ARTABLE  DS    0CL90                                                    58200000
         DC    2X'00'                                                   58220000
         DC    X'0488'                                                  58240000
         DC    2X'00'                                                   58260000
         DC    X'6854'                                                  58280000
         DC    3X'00'                                                   58300000
         DC    X'58'                                                    58320000
         DC    5X'00'                                                   58340000
         DC    X'1014'                                                  58360000
         DC    13X'00'                                                  58380000
         DC    X'18'                                                    58400000
         DC    4X'00'                                                   58420000
         DC    X'806C'                                                  58440000
         DC    4X'00'                                                   58460000
         DC    X'282C843438'                                            58480000
         DC    42X'00'                                                  58500000
         SPACE 2                                                        58520000
*****   LIST     ****************************************************** 58540000
*                   USED FOR ARRAY AND SWITCH LIST PROCESSING           58560000
*                   MAKES THE TRT AGAINST ARTABLE AND UTILIZES MAINLOOP 58580000
*                        TO MOVE SCANNED BYTES AND BRANCH TO THE        58600000
*                        APPROPRIATE PROGRAM, EITHER A LIST PROGRAM     58620000
*                        OR ONE OF THE COMMON PROGRAMS                  58640000
*                        THE RETURN WILL BE TO LIST VIA REGISTER 10,    58660000
*                   RET WILL POINT TO LIST UNTIL CHANGED BY ENDLIST     58680000
*                        TO POINT TO TESTLOOP AGAIN                     58700000
         SPACE 2                                                        58720000
LIST     BALR  RET,0                    SET RETURN REGISTER             58740000
         LR    REGM,REGI                START CHAR IN SCAN              58760000
         LR    REGIX,RET                RETURN FROM CIB                 58780000
         SR    REGZ,REGZ                                                58800000
         TRT   0(73,REGI),ARTABLE       SCAN AGAINST AR TABLE           58820000
         B     CONT                     UTILIZE TESTLOOP                58840000
         SPACE 2                                                        58860000
*****   PONTLST  ******                                                 58880000
*                   USES THE SAME POINTABEL AS MAINLOOP BUT             58900000
*                   ADDS 56 TO THE DISPLACEMENTS                        58920000
         SPACE 2                                                        58940000
PONTLST  LA    REGI,1(0,REGI)                GET NEXT CHAR.             58960000
         SR    REGZ,REGZ                                                58980000
         TRT   0(73,REGI),PTTABLE       SCAN TO NEXT DELIMITER          59000000
         LA    REGB,BPRTAB         IN PTTABLE                           59020000
         L     REGB,56(REGB,REGZ)                                       59040000
         BCR   15,REGB             BRANCH ACCORDING TO 56+ DISP+ BPRTAB 59060000
         SPACE 2                                                        59080000
PZETA    LA    REGIX,PONTLST+4               ZETA IN POINTLIST          59100000
         BC    15,CIB                                                   59120000
         SPACE 2                                                        59140000
*****   RIGTPARL ******  MOVES OUT THE RIGHT PARENTHESIS DECREASES THE  59160000
*                        PARENTHESIS COUNT AND RETURNS TO LIST          59180000
         SPACE 2                                                        59200000
RIGTPARL BAL   REGOX,COB           CHECK IF O/P AREA FILLED             59220000
         MVI   0(EAP),X'26'            MOVE  IN   $   RIGHT  PAREN.     59240000
         LA    EAP,1(0,EAP)                                             59260000
         LA    REGI,1(0,REGI)           GET NEXT  CHAR.                 59280000
         LH    REGB,C                                                   59300000
         BCTR  REGB,0              DECREASE PARENTHESIS COUNT           59320000
         STH   REGB,C                                                   59340000
         BCR   15,RET                                                   59360000
         SPACE 2                                                        59380000
*****   LEFTPARL ******                                                 59400000
*                        INCREASES THE PARENTHESIS COUNT                59420000
*                        CHECKS IF NEXT CHARACTER IS A SLASH, IF IT IS  59440000
*                        MOVES A SUBSCRIPT BRACKET OUTPUT, IF NOT       59460000
*                        MOVES A SIMPLE PARENTHESIS                     59480000
         SPACE 2                                                        59500000
LEFTPARL LH    REGB,C              INCREASE PARENTHESIS COUNT           59520000
         LA    REGB,1(0,REGB)                                           59540000
         STH   REGB,C                                                   59560000
LPARDQC3 LA    REGI,1(0,REGI)           GET  NEXT  CHAR.                59580000
         CLI   0(REGI),X'03'            Q   SLASH                       59600000
         BNE   SIMPLPAR                 NO SIMPLE PARENTHESIS           59620000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             59640000
         MVI   0(EAP),X'08'            YES - MOVE IN SQUARE BRACKET     59660000
LPARDQ63 LA    REGI,1(0,REGI)      INCREASE POINTERS                    59680000
         LA    EAP,1(0,EAP)                                             59700000
         BCR   15,RET              RETURN                               59720000
SIMPLPAR CLI   0(REGI),X'2B'           Q IS NEXT CHAR  BLANK            59740000
         BE    LPARDQC3                YES                              59760000
         CLI   0(REGI),X'2F'           NO -  Q    ZETA                  59780000
         BNE   *+12                                                     59800000
         LA    REGIX,LPARDQC3+4                                    1520 59820018
         BC    15,CIB                                                   59840000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             59860000
         MVI   0(EAP),X'06'              MOVE  IN  LEFT  PARENTHESIS    59880000
         B     LPARDQ63+4                                               59900000
         SPACE 2                                                        59920000
*****   COMMALST ******                                                 59940000
*                   INCREASES THE DIEMSION COUNTER D IF C THE           59960000
*                        PARENTHESIS COUNTER IS 1 FOR ARRAY OR 0 FOR    59980000
*                        SWITCH LIST                                    60000000
         SPACE 2                                                        60020000
COMMALST TM    BITS1,X'08'             Q AR BIT = 0                     60040000
         BZ    COMMAG3                                                  60060000
         CLC   C(2),KOPOOL+6  Q. C=1                                    60080000
         BNE   COMMAJ2                  NO                              60100000
COMMAH2  IC    REGZ,D                  INCREASE D-COUNTER               60120000
         LA    REGZ,1(0,REGZ)                                           60140000
         STC   REGZ,D                                                   60160000
COMMAJ2  BAL   REGOX,COB           CHECK IF O/P AREA FILLED             60180000
         MVI   0(EAP),X'25'            MOVE COMMA TO OUTPUT             60200000
         LA    EAP,1(0,EAP)            INCREASE POINTERS                60220000
         LA    REGI,1(0,REGI)                                           60240000
         BCR   15,RET                                                   60260000
COMMAG3  CLC   C(2),KOPOOL         Q. C=0                               60280000
         BE    COMMAH2                                                  60300000
         BC    15,COMMAJ2                                               60320000
         SPACE 2                                                        60340000
*****   COLONLST ******                                                 60360000
*                   CORRECT ONLY FOR AN ARRAYLIST                       60380000
         SPACE 2                                                        60400000
COLONLST TM    BITS1,X'08'         Q. ARBIT ON                          60420000
         BZ    ERROR3              E3 COLON DELETE D                    60440000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             60460000
         MVI   0(EAP),X'07'            MOVE $ COLON TO O/P              60480000
         LA    EAP,1(0,EAP)                                             60500000
         LA    REGI,1(0,REGI)          GET NEXT CHAR                    60520000
         BCR   15,RET                  AND RETURN                       60540000
         SPACE 2                                                        60560000
*****   SEMCLST  ******                                                 60580000
*                   IS ONLY VALID FOR AN SWITCH IN WHITCH CASE          60600000
*                        INDICATES THE END OF THE SWITCH LIST           60620000
*                   THE NUMBER OF COMPONENTS IS INSERTED IN THE         60640000
*                        INTERNAL NAME                                  60660000
*                   EXIT IS TO ENDLIST                                  60680000
         SPACE 2                                                        60700000
SEMCLST  TM    BITS1,X'08'                   Q ARBIT=1                  60720000
         BO    SEMCLER             YES- ERROR                           60740000
*  END OF SWITCH HANDLING                                               60760000
         CLI   D,X'10'                  Q. MORE THAN 15 COMPONENTS      60780000
         BL    *+14                                                     60800000
         BAL   REGB,ERR2                                                60820000
         DC    X'0021'             E33                                  60840000
         B     COMPFIN                                                  60860000
         L     IN,AITL                  INSERT DIMENSION COUNTER        60880000
         SR    REGB,REGB                                                60900000
         IC    REGB,D                                                   60920000
         SLA   REGB,4(0)                IN LEFTMOST 4 BYTES             60940000
         STC   REGB,D                                                   60960000
         MVZ   9(1,IN),D                IN DECLARATION                  60980000
         B     ENDLIST                  GO TO ENDLIST                   61000000
         SPACE 2                                                        61020000
*****   SEMCLER  ******                                                 61040000
*                   ENTERED IF A SEMICOLON IS FOUND IN AN ARRAY         61060000
*                        LIST                                           61080000
*                   GIVES E32, CLEAR THE ITAB ENTRY SETS THE            61100000
*                        ARBIT OFF, DELTABIT ON AND RETURNS TO          61120000
*                        TEST VIA SEMCO                                 61140000
         SPACE 2                                                        61160000
SEMCLER  BAL   REGB,ERR2                                                61180000
         DC    X'0020'        E32                                       61200000
         L     REGY,AITL                                                61220000
         BAL   REG12,ITABCLEA+8    CLEAR THE ENTRY                      61240000
         OI    BITS1,X'20'         DELTABIT ON                          61260000
         NI    BITS1,X'F7'         ARRAYBIT OFF                         61280000
         B     SEMCO                    RETURN TO SEMCO- WILL RESET RET 61300000
         SPACE 2                                                        61320000
*****   SLASHLST ******                                                 61340000
*                   CHECKS IF NEXT CHARACTER IS A RIGHT PARENTHESIS     61360000
*                        IT IS NOT MOVES OUT A SLASH                    61380000
*                   IF IT IS MOVES OUT A RIGHT SQUARE BRACKET           61400000
*                   DECREASES THE PARENTHESIS COUNT                     61420000
*                   RETURNS TO LIST IF EITHER AN SWITCH LIST IS         61440000
*                        PROCESSED OR THE PARENTHESIS COUNT NOT IS 0    61460000
         SPACE 2                                                        61480000
SLASHLST LA    REGI,1(0,REGI)              GET NEXT CHAR.               61500000
         CLI   0(REGI),X'26'               Q  LEFT  PARENTHWSIS         61520000
         BNE   SLASHSE                  NO SOMETHING ELSE               61540000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             61560000
         MVI   0(EAP),X'28'        TRANSFER A RIGHT SQUARE BRACKET      61580000
         LA    EAP,1(0,EAP)                                             61600000
         LA    REGI,1(0,REGI)                                           61620000
         LH    REGB,C                                                   61640000
         BCTR  REGB,0              DECREASE PARENTHESIS COUNT           61660000
         STH   REGB,C                                                   61680000
         TM    BITS1,X'08'               Q ARBIT = 1                    61700000
         BC    8,0(0,RET)          NO- RETURN                           61720000
         CLC   C(2),KOPOOL         Q. C=0                               61740000
         BC    7,0(0,RET)          NO- RETURN                           61760000
         SPACE 2                                                        61780000
*****   ARRAY END HANDLING                                              61800000
*                   INSERT THE DIMENSION COUNTERS IN THE INTERNAL       61820000
*                        NAME OR NAMES IF MORE THAN ONE ARRAY WITH      61840000
*                        THE SAME DIMENSIONS                            61860000
*                   IF A COMMA FOLLOWS THE CHARACTERISTICS AND THE PBN  61880000
*                        IS COPIED AND THE NEXT ARRAY NAME IS HANDLED   61900000
*                   IF A SEMICOLON FOLLOWS ENDLIST IS ACTIVATED         61920000
         SPACE 2                                                        61940000
         IC    REGZ,D                                                   61960000
         CLI   D,X'10'             Q. MORE THAN 16 DIMENSIONS           61980000
         BL    *+14                                                     62000000
         BAL   REGB,ERR2                                                62020000
         DC    X'0021'             EOO                                  62040000
         B     COMPFIN                                                  62060000
         SLA   REGZ,4                   SHIFT DIMENSION COUNTER         62080000
         STC   REGZ,D                                                   62100000
SLASHREP L     REGB,DIM                                                 62120000
         MVZ   0(1,REGB),D              INSERT DIMENSION COUNTER        62140000
         LA    REGB,11(0,REGB)           INCREASE   DIM POINTER         62160000
         ST    REGB,DIM                                                 62180000
         IC    REGOX,N                   DECREASE                       62200000
         BCTR  REGOX,0                  REP.DECLARATION COUNTER         62220000
         STC   REGOX,N                                                  62240000
         CLC   N(1),KOPOOL              Q. IS IT ZERO                   62260000
         BNE   SLASHREP                 NO INSERT DIM IN NEXT           62280000
         B     SLASHEND+4               ITAB ENTRY                      62300000
SLASHSE  CLI   0(REGI),X'2B'            Q. BLANK                        62320000
         BE    SLASHLST                                                 62340000
         CLI   0(REGI),X'2F'            Q. ZETA                         62360000
         BNE   *+12                                                     62380000
         LA    REGIX,SLASHLST+4                                         62400000
         BC    15,CIB                                                   62420000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             62440000
         MVI   0(EAP),X'03'              MOVE  IN  A  SLASH             62460000
         LA    EAP,1(0,EAP)                                             62480000
         BCR   15,RET                                                   62500000
SLASHEND LA    REGI,1(0,REGI)            GET NEXT  CHAR.                62520000
         CLI   0(REGI),X'25'             Q   COMMA                      62540000
         BNE   SLSHENSE                 NO SOMETHING ELSE               62560000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             62580000
         MVI   0(EAP),X'25'             MOVE IN A COMMA                 62600000
         LA    EAP,1(0,EAP)                                             62620000
         L     REGA,AITL           SAVE AITL                            62640000
         BAL   REG12,ITABCLEA      CHECK AND CLEAR NEXT ITABENTRY       62660000
         MVC   6(3,REGY),6(REGA)   COPY ID AND PBN FIELDS               62680000
         B     ARRYNAME            GET NEXT NAME                        62700000
SLSHENSE CLI   0(REGI),X'2B'            Q BLANK                         62720000
         BE    SLASHEND                                                 62740000
         CLI   0(REGI),X'2F'       Q ZETA                               62760000
         BNE   *+12                                                     62780000
         LA    REGIX,SLASHEND+4                                         62800000
         B     CIB                                                      62820000
         LA    REGB,SLASHERR       RETURN IF NO SEMICOLON FOUND         62840000
         BAL   REG12,FINDSEMC      LOOK FOR SEMICOLON                   62860000
         SPACE 2                                                        62880000
*****   ENDLIST  ******                                                 62900000
*                   SETS DELTABIT TO ONE, ARBIT TO ZERO, CLEARS NEXT    62920000
*                        ITABENTRY                                      62940000
*                   RESETS THE RETUN REGISTER TO TEST                   62960000
*                   RETURNS TO TESTLOOP VIA SEMCO                       62980000
         SPACE 2                                                        63000000
ENDLIST  OI    BITS1,X'20'                 DELTA BIT =1                 63020000
         NI    BITS1,X'F7'         ARBIT= 0                             63040000
         BAL   REG12,ITABCLEA      CHECK AND CLEAR NEXT ITABENTRY       63060000
         LA    RET,TESTLOOP        RESET RETURN REGISTER TO MAINLOOP    63080000
         B     SEMCO               GO TO SEMICOLONPROGRAM               63100000
SLASHERR BAL   REGB,ERR2                                                63120000
         DC    X'0022'             E34                                  63140000
         BAL   REG12,ITABCLEA      CHECK AND CLEA NEXT ITABENTRY        63160000
         B     ARYEXIT+8           CLEAR THE ENTRY IN ITAB AND RETURN   63180000
         SPACE 2                                                        63200000
*****   SWITCH   ****************************************************** 63220000
*                   TESTS ON PROBIT (SPECIFICATION) AND BEGBIT          63240000
*                        (PROGRAM BLOCK HEAD)                           63260000
*                   INSERTS CHARACTERISTICS AND PBN IN INTERNAL NAME    63280000
*                   INCREASES AND INSERTS LABELNUMBER LN                63300000
*                   MOVES 0A SWITCH TO OUTPUT                           63320000
*                   SETS ARBIT TO ZERO                                  63340000
*                   CHECKS THE NAME FOR VALIDITY AND MOVES FIRST 6      63360000
*                        CHARACTERS TO OUTPUT AND ITAB VIA IDCHECK      63380000
*                   SEARCHES FOR ASSIGN TO FOLLOW THE SWITCHNAME        63400000
*                   INITILIZES C PARENTHESIS COUNT AND D DIMENSION      63420000
*                        COUNT WITH ZERO AND N WITH ONE                 63440000
*                   EXITS TO LIST                                       63460000
         SPACE 2                                                        63480000
SWITCH   TM    BITS1,X'40'             Q PROCEDURE HEAD                 63500000
         BO    SPECENT                 YES                              63520000
         TM    BITS1,X'80'             Q BLOCK START                    63540000
         BZ    *+16                                                     63560000
         ST    REGX,SAVE1                                               63580000
         BAL   REGX,BEG1                YES- PROCESS BLOCKBEGIN         63600000
         L     REGX,SAVE1                                               63620000
         L     REGY,AITL                MOVE IN ID FIELDS               63640000
         MVI   6(REGY),X'CC'                                            63660000
         MVI   7(REGY),X'0C'                                            63680000
         L     REGOX,LPBP                                               63700000
         MVC   8(1,REGY),10(REGOX)      AND PBN- NUMBER                 63720000
         LH    REGOX,LN                IN CREASE LABELNUMBER            63740000
         LA    REGOX,4(0,REGOX)                                         63760000
         CLC   LN(2),FOURKA             Q. LN OVERFLOW                  63780000
         BL    *+14                                                     63800000
         BAL   REGB,ERR7                                                63820000
         DC    X'04D8'        E216                                      63840000
         LA    REGOX,LATBEG        RESET LN                             63860000
         STH   REGOX,LN                                                 63880000
         MVC   9(2,REGY),LN             MOVE IN LABEL NUMBER            63900000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             63920000
         MVI   0(EAP),X'0A'            MOVE IN $ SWITCH                 63940000
         LA    EAP,1(0,EAP)                                             63960000
         NI    BITS1,X'F7'         SET ARBIT TO ZERO                    63980000
SWTCHB3  LA    REGI,1(0,REGI)      GET FIRST CHAR.                      64000000
         CLI   0(REGI),X'39'           Q IS IT A LETTER                 64020000
         BL    SWTCHNSE                 NO                              64040000
         BAL   REGB,IDCHECK1  INIILIZ N WITH ONE                        64060000
SWITCHSE CLI   0(REGI),X'2B'           Q IS CHAR A BLANK                64080000
         BE    IDCHECK2                                                 64100000
         CLI   0(REGI),X'07'       Q COLON                              64120000
         BE    SWCOLON                                                  64140000
         CLI   0(REGI),X'2D'       Q. POINT                             64160000
         BNE   SWITCHER                                                 64180000
SWPOINT  LA    REGI,1(0,REGI)      ONE POINT HAS BEEN FOUND             64200000
         CLI   0(REGI),X'2D'       Q. ONE MORE POINT                    64220000
         BE    SWCOLON                                                  64240000
         CLI   0(REGI),X'10'       Q. EQUALSIGN  E.G.  .=               64260000
         BE    EQUALOK                                                  64280000
         CLI   0(REGI),X'2B'       Q. BLANK                             64300000
         BE    SWPOINT                                                  64320000
         CLI   0(REGI),X'2F'       Q.ZETA                               64340000
         BNE   SWITCHER                                                 64360000
         LA    REGIX,SWPOINT+4                                          64380000
         B     CIB                                                      64400000
SWCOLON  LA    REGI,1(0,REGI)      NOW A COLON OR TWO POINTS ARE FOUND  64420000
         CLI   0(REGI),X'10'       Q EQUALSIGN                          64440000
         BE    EQUALOK             IF YES '= OR  .= OR ..= ARE FOUND    64460000
         CLI   0(REGI),X'2B'       Q BLANK                              64480000
         BE    SWCOLON                                                  64500000
         CLI   0(REGI),X'2F'       Q  ZETA                              64520000
         BNE   SWITCHER                                                 64540000
         LA    REGIX,SWCOLON+4                                          64560000
         B     CIB                                                      64580000
EQUALOK  BAL   REGOX,COB           CHECK IF O/P AREA FILLED             64600000
         MVI   0(EAP),X'16'            MOVE IN $ EQUALSIGN              64620000
         LA    EAP,1(0,EAP)            INCREASE O/P POINTER             64640000
         SR    REGB,REGB                                                64660000
         STH   REGB,C                   C=0                        1514 64680018
         MVI   N,X'01'                  N=1                             64700000
         STC   REGB,D                   D=0                             64720000
         LA    REGI,1(0,REGI)          GET NEXT CHAR                    64740000
         B     LIST                     GO TO PROCESS LIST              64760000
SWTCHNSE CLI   0(REGI),X'2B'       Q. BLANK                             64780000
         BE    SWTCHB3                                                  64800000
         CLI   0(REGI),X'2F'       Q. ZETA                              64820000
         BNE   *+12                                                     64840000
         LA    REGIX,SWTCHB3+4                                          64860000
         B     CIB                                                      64880000
         BAL   REGB,ERR7                                                64900000
         DC    X'0405'             E5                                   64920000
         B     SWITCHER+18                                              64940000
SWITCHER BAL   REGB,ERR2                                                64960000
         DC    X'0010'             E16                                  64980000
         BAL   REGOX,COB                                                65000000
         MVI   0(EAP),X'3D'        MOVE IN RHA                          65020000
         LA    EAP,1(0,EAP)                                             65040000
         L     REGB,AITL               CLEAR ITAB-ENTRY                 65060000
         MVI   0(REGB),X'00'                                            65080000
         MVC   1(10,REGB),0(REGB)                                       65100000
         BC    15,COMERR               COM-PRGM ERROR-ENTRY             65120000
         SPACE 2                                                        65140000
*****   STRING   ****************************************************** 65160000
*                   MOVES INTERNAL NAME TO OUTPUT                       65180000
*                   THE STRING IS TAKEN FROM THE PRINTAREA (OR DUMMY)   65200000
*                        AND MOVED TO KOPOOL, START ADDRESS IS IN       65220000
*                        SPCLT                                          65240000
*                   THE STRINGS TWO FIRST BYTES SPECIFIES ITS LENGTH    65260000
*                   THE TRT TESTS ONLY FOR APOSTROPHE AND ZETA          65280000
         SPACE 2                                                        65300000
STRING   LA    REG0,6(0,EAP)       PROVIDE 6 BYTES IN O/P               65320000
         BAL   REGOX,COBSPEC                                            65340000
         MVC   0(4,EAP),SINT       MOVE FIRST 4 BYTES OF INTERNAL NAME  65360000
         MVC   4(2,EAP),SPCLT+2         AND LAST TWO BYTES IN O/P       65380000
         LA    EAP,6(0,EAP)                                             65400000
         L     REGL,SPCLT          GET CURRENT DISP WITHIN KOPOOL       65420000
         LA    REGL,2(0,REGL)      INCREASE FOR LENGTH SPECIFICATION    65440000
         C     REGL,FOURK          Q  STRINGPOOL  OVERFLOW              65460000
         BNH   *+8                                                      65480000
         BAL   REGOX,E23                                                65500000
         LA    REGI,1(0,REGI)                                           65520000
         MVC   SQC(4),KOPOOL+4     STRINQUOTE=1                         65540000
CDE2     LA    REGIX,*             PROVIDE RETURNADDRESS FOR CIB        65560000
         LR    REGM,REGI                                                65580000
         SR    REGZ,REGZ                                                65600000
         TRT   0(73,REGI),STRTABLE SCAN STRING                          65620000
         LR    REGN,REGI           COMPUTE NUMBER OF SCANNED BYTES      65640000
         SR    REGN,REGM                                                65660000
         BZ    SROUT                                                    65680000
         LA    REG0,0(REGN,REGL)   Q. STRINGPOOL OVERFLOW               65700000
         C     REG0,FOURK                                               65720000
         BNH   *+8                                                      65740000
         BAL   REGOX,E23                                                65760000
         BCTR  REGN,0              MOVE SCANNED BYTES TO KOPOOL         65780000
         L     REGB,AKOPOOL                                             65800000
         LA    REGY,0(REGB,REGL)  COMPUTE NEW KOPOOL ADDRESS            65820000
         LA    REG0,WA             COMPUTE ADDRESS                      65840000
         LR    REG12,REGM          OF STRING IN                         65860000
         SR    REG12,REG0          PRINTBUFFER                          65880000
         L     REGB,APRNTAR                                             65900000
         LA    REG12,8(REGB,REG12) GET STRING FROM PRINTBUFFER          65920000
         EX    REGN,MV1                                                 65940000
         LA    REGL,1(REGN,REGL)   INCREASE SPCLT                       65960000
SROUT    L     REG12,BPRTAB(REGZ)  BRANCH TO APPROPRIATE                65980000
         BCR   15,REG12            SUBROUTINE                           66000000
         SPACE 2                                                        66020000
*****   QUOTE   *****                                                   66040000
*                   CHECKS IF THE APOSTROPHE IS THE START OF A QUOTE    66060000
*                        SIGN                                           66080000
*                   USES REPL TO MOVE THE FOUND CHARACTER(S) TO         66100000
*                        KOPOOL. REPL+1 WILL BE A LEFT OR RIGHT         66120000
*                        PARENTHESIS                                    66140000
*                   HOW MUCH OF REPL THAT IS TO BE MOVED TO KOPOOL      66160000
*                        IS KEPT TRACK OF IN REGN                       66180000
*                   IF A COMPLETE LEFT STRING QUOTE IS FOUND THE        66200000
*                        STRING QUOTE COUNTER IS INCREASED AND THE      66220000
*                        REPL MOVED TO KOPOOL                           66240000
*                   IF A COMPLETE RIGHT STRING QUOTE IS FOUND IT IS     66260000
*                        CHECKED IF IT IS THE CLOSING ONE FOR THE       66280000
*                        STRING (SQC=0) IF IT IS ENDSTRING IS ACTIVATED 66300000
*                        IF NOT REPL IS MOVED TO KOPOOL AFTER           66320000
*                        SQC IS DECREASED                               66340000
*                   IF NO COMPLETE QUOTE IS FOUND THE CHARACTER(S)      66360000
*                        FOUND ARE MOVED TO KOPOOL FROM REPL, LENGTH    66380000
*                        SPECIFIED BY REGN AND THE SCANNING OF          66400000
*                        THE STRING IS REASSUMED                        66420000
         SPACE 2                                                        66440000
QUOTE    LA    REGI,1(0,REGI)                                           66460000
         LA    REGIX,*+4                                                66480000
         CLI   0(REGI),X'26'       Q RIGHT PARENTHESIS IN SOURCE        66500000
         BNE   NORIP                                                    66520000
         MVI   REPL+1,C')'         MAKE REPL A RIGHT STRING QUOTE       66540000
         B     TESTAPOS            LOOK FOR APOSTROPHE                  66560000
NORIP    CLI   0(REGI),X'06'       Q. LEFT PARENTHESIS                  66580000
         BNE   TESTZETA            NO                                   66600000
         MVI   REPL+1,C'('         MAKE REPL A LEFT STRING QUOTE        66620000
         B     TESTAPOS            LOOK FOR APOSTROPHE                  66640000
TESTZETA CLI   0(REGI),X'2F'       Q.ZETA                               66660000
         BE    CIB                 YES                                  66680000
         LA    REGN,1              NO MOVE TO STRING ONLY FIRST APOST . 66700000
         B     CID1                MOVE REPL                            66720000
TESTAPOS LA    REGI,1(0,REGI)                                           66740000
         LA    REGIX,*+4           NEW RETURN FOR CIB                   66760000
         CLI   0(REGI),X'2E'       Q. SECOND APOSTROPHE                 66780000
         BE    CID                 YES                                  66800000
         CLI   0(REGI),X'2F'       ZETA                                 66820000
         BE    CIB                 YES                                  66840000
         LA    REGN,2              NO MOVE TO STRING ONLY THE FIRST     66860000
         B     CID1                APOSTROPHE AND THE PARENTHESIS       66880000
CID      LA    REGI,1(0,REGI)                                           66900000
         L     REGOX,SQC                                                66920000
         CLI   REPL+1,X'4D'        Q. LEFT STRING QUOTE                 66940000
         BNE   *+12                NO                                   66960000
         LA    REGOX,1(0,REGOX)    YES- INCREASE STRING QUOTE COUNT     66980000
         B     *+12                                                     67000000
         S     REGOX,KOPOOL+4      RIGHT QUOTE- DECREASE QUOTE COUNT    67020000
         BC    13,ENDSTRIN         BRANCH IF LAST QUOTE                 67040000
         ST    REGOX,SQC                                                67060000
         LA    REGN,3                                                   67080000
CID1     LA    REG0,0(REGN,REGL)                                        67100000
         C     REG0,FOURK          Q STRINGPOOL OVERFLOW                67120000
         BNH   *+8                                                      67140000
         BAL   REGOX,E23                                                67160000
         L     REGB,AKOPOOL                                             67180000
         LA    REGB,0(REGB,REGL)   COMPUTE NEW KOPOOL ADDRESS           67200000
         BCTR  REGN,0                                                   67220000
         EX    REGN,MV2            MOVE CONTENTS OF REPL TO KOPOOL      67240000
         LA    REGL,1(REGN,REGL)   INCREASE SPCLT                       67260000
         BC    15,CDE2                  RESUME SCAN OF STRING           67280000
         SPACE 2                                                        67300000
*****   ENDSTRIN *****                                                  67320000
*                   INCREASES SPCLT                                     67340000
*                   PUTS THE LENGTH OF THE STRING (DIFFERENCE BETWEEN   67360000
*                        NEW AND OLD SPCLT) AS TWO FIRST BYTES IN THE   67380000
*                        STRING                                         67400000
         SPACE 2                                                        67420000
ENDSTRIN L     REG9,SPCLT          COMPUTE LENGTH AND PUT IT            67440000
         STH   REGL,SPCLT+2        AS THE FIRST 2 BYTES IN STRING       67460000
         L     REGB,AKOPOOL        AND                                  67480000
         LA    REGOX,0(REGB,REG9)   STORE NEW DISPLACEMENT              67500000
         SR    REGL,REG9                IN  SPCLT                       67520000
         STH   REGL,LENSTRIG                                            67540000
         MVC   0(2,REGOX),LENSTRIG                                      67560000
         BCR   15,RET              RETURN TO TESTLOOP                   67580000
E23      BC    0,*+10                   NO BRANCH FIRST TIME       0208 67590014
         BAL   REGB,ERR7                RECORD ERROR               0208 67600014
         DC    X'0417'             E23                                  67620000
         OI    E23+1,X'F0'              NO ERROR RECORDING NEXT    0208 67630014
         LA    REGL,64                                                  67640000
         ST    REGL,SPCLT          RESETSPCLT TO 64 AGAIN               67660000
         BCR   15,REGOX            RESUME STRING PROCESSING             67680000
         CNOP  0,4                                                      67700000
MV1      MVC   0(1,REGY),0(REG12)                                       67720000
LENSTRIG DS    H                        MUST NOT BE MOVED               67740000
MV2      MVC   0(1,REGB),REPL                                           67760000
SQC      DC    F'0'                STRINGQOUTECOUNTER  (AFTER MV2       67780000
SINT     DC    X'2EC90000'             STRING INTERNAL NAME             67800000
*                             OF THE CONSTANT POOL NAMED KOPOOL         67820000
REPL     DC    C''' '''                 BUCKET TO BUILD STRING QUOTES   67840000
         SPACE 2                                                        67860000
*****   TYPPROC  ****************************************************** 67880000
*                   TEST PRO AND BEGBIT (FORMAL PARAMETER, BLOCKSTART)  67900000
*                   MOVE PHI TO OUTPUT                                  67920000
*                   INSERT CHARACTERISTICS IN INTERNAL NAME             67940000
*                   JOIN PROCEDURE PROGRAM                              67960000
         SPACE 2                                                        67980000
TYPPROC  TM    BITS1,X'40'           QPROCEDURE PROCEDED                68000000
         BZ    *+16                  NO                                 68020000
         MVI   KB,X'CA'            YES-MOVE IN IDFIELD                  68040000
         OI    KB+1,X'C0'                                               68060000
         BC    15,IDCHECK                                               68080000
         TM    BITS1,X'80'         Q. BEGBIT ON                         68100000
         BZ    *+16                NO                                   68120000
         ST    REGX,SAVE1                                               68140000
         BAL   REGX,BEG1           GO TO PROCESS PROGRAM BLOCK HEAD     68160000
         L     REGX,SAVE1                                               68180000
         LA    REG0,4(0,EAP)      PROVIDE FOUR BYTES IN OUTPUT          68200000
         BAL   REGOX,COBSPEC       CHECK IF ENOUGH SPACE IN O/P         68220000
         MVI   0(EAP),X'0F'        MOVE PHI TO O/P                      68240000
         L     REGY,AITL                                                68260000
         XI    7(REGY),X'F0'            MOVE IN THE IDCODE              68280000
         MVI   6(REGY),X'CA'            TO ITAB                         68300000
         B     PROCEAG1            JOIN THE PROCEDUR PROGRAM            68320000
         SPACE 2                                                        68340000
*****   PROCEDURE ***************************************************** 68360000
*                   TEST PRO AND BEGBIT                                 68380000
*                   MOVE PI TO OUTPUT                                   68400000
*                   INSERT CHARACTERISTICS IN INTERNAL NAME             68420000
*                   TYPEPROCEDURE JOINS PROCEDURE PROGRAM AT THIS POINT 68440000
*                   IF ALPHA IN STACK, PRECOMPILED PROCEDURE,           68460000
*                        THE STARTBIT IS TURNED ON                      68480000
*                   PROC IS PUT IN STACK                                68500000
*                   PROGRAM BLOCK AND ITAB GROUP NUMBER ARE INCREASED   68520000
*                        THE NEW PBN IS INSERTED IN THE INTERNAL NAME   68540000
*                   LABELNUMBER IS INCREASED AND INSERTED IN THE        68560000
*                        INTERNAL NAME                                  68580000
*                   THE SURRONDING BLOCKNUMBET IS ENTERED IN PBTAB1     68600000
*                   THE SURROUNDING ITABGROUP NUMBER IN GROUPTABLE      68620000
*                   THE SC IS ENTERED IN SCTAB                          68640000
*                   PROBIT AND IDBIT ARE SET TO ONE                     68660000
*                   PROBIT WILL STAY AS ONE TILL THE WHOLE PROCEDURE    68680000
*                        HEAD IS PROCESSED. THE IDBIT IS ONLY ONE       68700000
*                        WHILE THE PROCEDURE NAME IS PROCESSED          68720000
*                   THE FM (FORMAL PARAMETER)BIT IS ONE WHEN THE        68740000
*                        FORMAL PARAMETER LIST IS PROCESSED             68760000
*                   THE ITABGROUP NUMBER IS MOVED TO O/P                68780000
         SPACE 2                                                        68800000
PROCEDUR TM    BITS1,X'40'         IF PROBIT IS ONE                     68820000
         BO    SPECENT             GOTO IDCHECK VIA SPECENT             68840000
         TM    BITS1,X'80'         Q. BEGBIT ON                         68860000
         BZ    *+16                NO                                   68880000
         ST    REGX,SAVE1                                               68900000
         BAL   REGX,BEG1      GO TO PROCESS PROGRAMBLOCKHEAD            68920000
         L     REGX,SAVE1                                               68940000
         LA    REG0,4(0,EAP)      PROVIDE FOUR BYTES IN OUTPUT          68960000
         BAL   REGOX,COBSPEC                                            68980000
         MVI   0(EAP),X'0E'        TRANSFER PI IN OUTPUTBUFFER          69000000
         L     REGY,AITL                                                69020000
         MVI   6(REGY),X'CA'       CONSTRUCT FIRST PART                 69040000
         MVI   7(REGY),X'C0'       OF INTERNAL NAME                     69060000
PROCEAG1 L     REGL,SP                                                  69080000
         CLI   0(REGL),X'00'       Q ALPHA IN STACK                     69100000
         BNE   L3                                                       69120000
         OI    BITS2,X'20'         TURN ON THE STARTBIT                 69140000
         OI    BITS3,PROCESD                                            69160000
L3       LA    REGL,1(0,REGL)      INCREASE STACKPOINTER                69180000
         C     REGL,ATOPSTAK       Q STACKOVERFLOW                      69200000
         BL    *+10                                                     69220000
         BAL   REGB,ERR4                                                69240000
         DC    X'0414'             E20                                  69260000
         MVI   0(REGL),X'0C'       PUT PROC IN STACK                    69280000
         ST    REGL,SP                                                  69300000
         CLI   PBC,X'FF'           Q.PBN OVERFLOW                       69320000
         BNE   *+10                NO                                   69340000
         BAL   REGB,ERR4                                                69360000
         DC    X'0416'             E22                                  69380000
         IC    REGZ,PBC                                                 69400000
         LA    REGZ,1(0,REGZ)      INCREASE PROGRAMBLOCKNUMBER          69420000
         STC   REGZ,8(0,REGY)      INSERT PBN IN INTERVAL NAME          69440000
         STC   REGZ,PBC                                                 69460000
         LA    REGL,PBTAB1(REGZ)   CONSTRUCTION                         69480000
         L     REGB,LPBP           PBTAB1-ENTRY                         69500000
         MVC   0(1,REGL),10(REGB)                                       69520000
         AR    REGZ,REGZ                                                69540000
         LA    REGL,SCTAB(REGZ)                                         69560000
         MVC   0(2,REGL),SC        MAKE ENTRY IN SCTAB                  69580000
         LH    REGL,LN             INCREASE                             69600000
         LA    REGL,4(0,REGL)      LABELNUMBER BY 4                     69620000
         CLC   LN(2),FOURKA        Q. LNOVERFLOW                        69640000
         BL    *+14                                                     69660000
         BAL   REGB,ERR7                                                69680000
         DC    X'04D8'        E216                                      69700000
         LA    REGL,LATBEG         RESET LN                             69720000
         STH   REGL,LN                                                  69740000
         L     REGY,AITL                                                69760000
         MVC   9(2,REGY),LN        PUT LN IN INTERNAL NAME              69780000
         LH    REGY,IGC            INCREASE                             69800000
         LA    REGY,1(0,REGY)      ITABGROUPNUMBER                      69820000
         STH   REGY,IGC                                                 69840000
         MVC   1(2,EAP),IGC        INSERT IT IN OUTPUT BUFFER           69860000
         LA    EAP,3(0,EAP)                                             69880000
         AR    REGY,REGY                                                69900000
         AH    REGY,IGC                                                 69920000
         A     REGY,AGT                                                 69940000
         L     REG7,LIGP                                                69960000
         MVC   0(2,REGY),8(REG7)   CONSTRACT ENTRY                      69980000
         MVI   2(REGY),X'00'       IN   GROUPTABEL                      70000000
         NI    0(REGY),X'7F'       CLEAR POSSIBLE PHI IND.              70020000
         MVC   PRIMPAR(4),KOPOOL   CLEARPRIMPAR WITH ZEROS              70040000
         OI    BITS1,X'50'         PROBIT =1,IDBIT =1                   70060000
         MVI   PZ,X'00'       SET PARAMTER COUNT TO ZERO                70080000
         SPACE 2                                                        70100000
*****   PROCID   *****                                                  70120000
*                   PROCESSES PROCEDURE NAME (IDBIT=1)                  70140000
*                        AND THE FORMAL PARAMETER LIST (IDBIT=0)        70160000
*                   CHECKS THE NAMES FOR VALIDITY AND MOVES THEM        70180000
*                        TO ITAB AND OUTPUT                             70200000
*                        THIS IS DONE VIA IDCHECK1                      70220000
         SPACE 2                                                        70240000
PROCID   LA    REGI,1(0,REGI)                                           70260000
         CLI   0(REGI),X'40'            Q IDENTIFIER STARTS WITH LETTER 70280000
         BL    NOLETTER                                                 70300000
         BAL   REGB,IDCHECK1  CHECK AND MOVE IDENTIFIER TO O/P AND ITAB 70320000
         CLI   0(REGI),X'2B'       Q BLANK                              70340000
         BE    IDCHECK2                                                 70360000
         TM    BITS1,X'10'         Q IDBIT ONE                          70380000
         BZ    EDA1                GOTO PROCESS FORMAL PARAMETER NAME   70400000
         SPACE 2                                                        70420000
*****   PROCEDURE NAME  *****                                           70440000
*                   CHECKS IF NAME IS FOLLOWED BY (A FORMAL PARAMETER   70460000
*                        LIST FOLLOWS OR ., NO PARAMETERS               70480000
*                   CHECKS IF PROCEDURE IS TO BE PRECOMPILED, IF YES    70500000
*                       THE NAME IN EXTERNAL FORM AND EXPANDED WITH     70520000
*                        TWO ZEROS IS PUT FOR AN ESDCARD IF SYLIN OR    70540000
*                        DECK HAS BEEN SPECIFIED                        70560000
*                   THE NEW BLOCK ENTRY IS DONE IN ITAB                 70580000
*                        ADD, OF SURROUNDIN BLOCK AND ITAB GROUP, PBN   70600000
*                             AND IGN ARE INSERTED                      70620000
*                       IF TYPEPROCEDURE, BIT 0 IN BYTE 8 IS            70640000
*                        TURNED ON AND A SECOND ENTRY OF THE NAME       70660000
*                        IS DONE AFTER THE HEAD ENTRY                   70680000
*                   IDBIT IS SET TO ZERO, FMBIT TO ONE                  70700000
*                   IF THE NAME WAS FOLLOWED BY A SEMICOLON THE         70720000
*                   SEMCO IS ACTIUATED                                  70740000
*                   IF THE NAME WAS FOLLOWED BY A(PROCID IS             70760000
*                        ACTIVATED TO PROCESS THE NAME IN THE LIST      70780000
         SPACE 2                                                        70800000
         CLI   0(REGI),X'06'       Q IDENTIFIER FOLLOWED BY )           70820000
         BE    EBF4                                                     70840000
         LA    REGB,ERROR16             RETURN IF NOT SEMICOLON         70860000
         BAL   REG12,FINDSEMC           Q SEMICOLON                     70880000
         OI    BITS1,X'20'          YES DELTABIT = 1                    70900000
EBF4     TM    BITS3,PROCESD                                            70920000
         BZ    DEL1                NO                                   70940000
         NI    BITS3,PROCOFF                                            70960000
         TM    HCOMPMOD+1,X'60' Q. DECK AND OR LOAD SPECIFIED           70980000
         BO    DEL1                 NO- NO NEED FOR ESDCARD             71000000
         L     REGY,AITL                                                71020000
         LA    REGB,ESDPARAM                                            71040000
         MVC   0(6,REGB),0(REGY)   MOVE IN AND TRANSLATE EXTERNAL NAME  71060000
         TR    0(6,REGB),RETRANS                                        71080000
DEL1     TM    BITS1,X'20'         Q DELTABIT = 1                       71100000
         BO    ECA3                                                     71120000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             71140000
         MVI   0(EAP),X'06'        INSERT )                             71160000
         LA    EAP,1(0,EAP)                                             71180000
ECA3     BAL   REG12,ITABCLEA                                           71200000
         MVC   0(4,REGY),LIGP      MOVE ADDRESS HEADINGENTRY OF EMBRAC  71220000
         MVC   4(4,REGY),LPBP      ING ITABGROUP AND PBLOCK TO ENTRY    71240000
         MVC   8(2,REGY),IGC            INSERT CURRENT IGN              71260000
         MVC   10(1,REGY),PBC      AND CURRENT PBN                      71280000
         ST    REGY,LIGP           NEW VALUE OF LIGP                    71300000
         ST    REGY,LPBP           AND LPBP                             71320000
         S     REGY,KOPOOL+44      DECREASE REGY BY 11                  71340000
         TM    7(REGY),X'03'       Q TYPEPROCEDURE                      71360000
         BC    5,TPROHEAD                                               71380000
         LA    REGY,22(0,REGY)     IF NO INCREASE ITABPOINTER           71400000
ECJ3     BAL   REG12,ITABCLEA+8                                         71420000
         OI    BITS3,FMBIT         FMBIT                                71440000
         TM    BITS1,X'20'         Q DELTABIT = 1                       71460000
         BO    SEMCO               IF YES BRANCH TO SEMICOLONPROGRAM    71480000
         NI    BITS1,X'EF'         IDBIT'= 0                            71500000
         BC    15,PROCID           CHECK NEXT IDENTIFIER                71520000
*                CONSTRUCT TYPE PROCEDURE ENTRIES                       71540000
TPROHEAD OI    19(REGY),X'80'           FLAGBIT IN IGN IS SET ON        71560000
         LA    REG0,22(0,REGY)     Q ONE MORE ENTRY IN ITAB AVAILABLE   71580000
         C     REG0,ELI                                                 71600000
         BNE   *+10                                                     71620000
         BAL   REGB,ERR4                                                71640000
         DC    X'04D5'             E213                                 71660000
         MVC   22(11,REGY),0(REGY) ENTER PROCEDURE NAME ONCE MORE       71680000
         XI    28(REGY),X'08'      NO-ASSIGNMENTBIT IS SWITCHED OFF     71700000
         LA    REGY,33(0,REGY)     INCREASE ITABPOINTER                 71720000
         BC    15,ECJ3             BRANCH BACK TO MAINPROGRAM           71740000
NOLETTER CLI   0(REGI),X'2B'            Q BLANK INSTEAD OF LETTER       71760000
         BE    PROCID                                                   71780000
         LA    REGIX,PROCID+4                                           71800000
         CLI   0(REGI),X'2F'            Q ZETA                          71820000
         BE    CIB                 CHANGE INPUTBUFFER                   71840000
         TM    BITS1,X'10'                                              71860000
         BO    PNAMERR-10                                               71880000
         LA    REGH,PROCID         LOAD RETURN ADDRESS                  71900000
         B     IERSPEC             BRANCH TO IDENTIFIER ERROR ROUTINE   71920000
ERROR16  BAL   REGOX,COB                                                71940000
         MVI   0(EAP),X'3D'        MOVE IN RHA                          71960000
         LA    EAP,1(0,EAP)                                             71980000
         TM    BITS1,X'10'         Q. PROC NAME UNDER PROCESS           72000000
         BO    PNAMERR             YES                                  72020000
         LA    REGH,PROCID         LOAD RETURN ADDRESS                  72040000
         B     IER                 GO TO IDENTIFIER ERROR ROUTINE       72060000
         BAL   REGB,ERR7                                                72080000
         DC    X'0405'             E5                                   72100000
         B     *+10                                                     72120000
PNAMERR  BAL   REGB,ERR2                                                72140000
         DC    X'0010'             E16                                  72160000
         L     IN,AITL                                                  72180000
         MVI   0(IN),X'00'       CLEAR ERRONEOUS NAME                   72200000
         MVC   1(5,IN),0(IN)                                            72220000
         LA    REGB,PROCIDSE       THE PROCEDURE HEAD SHOULD            72240000
         BAL   REGOX,FINDSEMC                                           72260000
         B     EBF4-4              BE FOLLOWED BY EITHER  ( OR .,       72280000
PROCIDSE CLI   0(REGI),X'06'       KEEP LOOPING UNTIL ONE OF TWO FOUND  72300000
         BE    EBF4                LEFT PARENTHESIS FOUND               72320000
         BAL   REGOX,FINDSEMC-4                                         72340000
         B     EBF4-4              SEMICOLON FOUND                      72360000
         SPACE 2                                                        72380000
*****   FORMAL PARAMETER LIST *****                                     72400000
*                   IF A COMMA TERMINATES THE NAME, THE COMMA IS        72420000
*                        TRANSFERED TO OUTPUT AND THE PARAMETER COUNT   72440000
*                        (PZ) IS INCREASED BY ONE                       72460000
*                        AND PROCID IS ACTIVATED AGAIN TO TAKE NEXT     72480000
*                        NAME                                           72500000
*                   IF A ) FOLLOWED BY A SEMICOLON TERMINATES THE NAME  72520000
*                        PROCFIN IS ACTIVATED                           72540000
*                   IF A ) BUT NO SEMICOLON TERMINATES THE NAME         72560000
*                        PROCDEL IS ACTIVATED                           72580000
*                   IS SOMETHING ELSE IS FOUND RHA IS MOVED TO OUTPUT,  72600000
*                        THE PARAMETER COUNT IS NOT INCREASED AND IER   72620000
*                        ACTIVATED (NOLETTER, ERROR16)                  72640000
         SPACE 2                                                        72660000
EDA1     CLI   0(REGI),X'25'       Q COMMA TERMINATES IDENTIFIER        72680000
         BNE   PAR                                                      72700000
PROCEND  IC    REGZ,PZ             INCREASE                             72720000
         LA    REGZ,1(0,REGZ)      PARAMETER                            72740000
         STC   REGZ,PZ             COUNT BY ONE                         72760000
         BAL   REG12,ITABCLEA      CHECK AND CLEAR NEXT ITABENTRY       72780000
         BAL   REGOX,COB           CHECK IF O/P AREA FILLED             72800000
         CLI   0(REGI),X'25'       Q COMMA                              72820000
         BNE   PROCFIN                                                  72840000
         MVI   0(EAP),X'25'        MOVE COMMA TO OUTPUTBUFFER           72860000
         LA    EAP,1(0,EAP)        INCREASE OUTPUTPOINTER               72880000
         BC    15,PROCID           BRANCK TO CHECK THE NEXT IDENTIFIER  72900000
PAR      CLI   0(REGI),X'26'       Q ( TERMINATES IDENTIFIER            72920000
         BE    PROCEND                                                  72940000
         BAL   REGOX,COB                                                72960000
         MVI   0(EAP),X'3D'        MOVE IN RHA                          72980000
         LA    EAP,1(0,EAP)                                             73000000
         LA    REGH,PROCID              NOTE RETURN ADDRESS AND BRANCH  73020000
         BC    15,IER              TO IER                               73040000
         SPACE 2                                                        73060000
*****   PROCFIN  *****                                                  73080000
*                   THE PARAMERER LIST HAS BEEN COMPLETLY CHECKED       73100000
*                        THE RIGHT PARENTHESIS IS MOVED TO OUTPUT       73120000
*                        DELTABIT IS SET TO ONE                         73140000
*                   THE PARENTHESIS COUNT IS INSERTED IN THE            73160000
*                        PROCEDURE NAME (NAMES IF TYPEPROCEDURE)        73180000
*                   FMBIT IS TURNED OFF                                 73200000
*                   THE RETURN TO TEST IS VIA SEMCO                     73220000
*                   IF SOMETHING ELSE, E5 OR E16 IS GENERATED AND       73240000
*                        EVERYTHING SKIPPED TILL A (OR A., IS           73260000
*                        FOUND (NOLETTER, PNAMERR)                      73280000
         SPACE 2                                                        73300000
PROCFIN  LA    REGI,1(0,REGI)                                           73320000
         LA    REGB,PROCDEL        RETURN IF NO SEMICOLON               73340000
         BAL   REG12,FINDSEMC           Q SEMICOLON                     73360000
         BAL   REGOX,COB                                                73380000
         LA    REGL,SEMCO          EXIT FROM PROCEDUR                   73400000
SCYES3   MVI   0(EAP),X'26'        MOVE RIGHT PARENTHESIS               73420000
         LA    EAP,1(0,EAP)                                             73440000
         OI    BITS1,X'20'         DELTABIT'=1                          73460000
         CLI   PZ,X'10'       Q.MORE THAN 15 PARAMETERS                 73480000
         BL    *+14                                                     73500000
         BAL   REGB,ERR2B                                               73520000
         DC    X'0024'             E36                                  73540000
         B     COMPFIN                                                  73560000
         L     REGY,LPBP                                                73580000
         S     REGY,KOPOOL+44      REGY CONTAINS ADDRESS OF PROC ENTRY  73600000
         SR    REGB,REGB                                                73620000
         IC    REGB,PZ                                                  73640000
         SLA   REGB,4(0)                                                73660000
         STC   REGB,PZ                                                  73680000
         MVZ   9(1,REGY),PZ        INSERT NUMBER OF PARAMETERS INTO     73700000
*                                  INTERNAL NAME OF THE PROCEDURE       73720000
         SRA   REGB,4(0)                                                73740000
         STC   REGB,PZ             NOTE NUMBER OF PARAMETER             73760000
         NI    BITS3,FMOFF         FMBIT=0                              73780000
         TM    19(REGY),X'80'      Q TYPE PROCEDURE                     73800000
         BZ    TESTPAR             NO                                   73820000
         MVZ   31(1,REGY),9(REGY)  INSERT NUMBER OF PARAMETERS INTO     73840000
*                                  SECOND NAME-ENTRY IN ITAB            73860000
         LA    REGY,33(0,REGY)     GET ADDRESS OF FIRST PARAMETER       73880000
         B     *+8                                                      73900000
TESTPAR  LA    REGY,22(0,REGY)                                          73920000
         CLI   PZ,X'00'            Q. IS THERE ANY PARAMETERS           73940000
         BCR   8,REGL              NO BRANCH TO SEMCO OR COMERR         73960000
         ST    REGY,PRIMPAR        YES- SAVE ADDRESS OF FIRST           73980000
         BCR   15,REGL             B TO SEMCO OR COMERR                 74000000
         SPACE 2                                                        74020000
*****   PROCDEL  *****                                                  74040000
*                   A RIGHT PARENTHESIS HAS BEEN FOUND IN THE LIST      74060000
*                        THAT NOT WAS FOLLOWED BY A .,                  74080000
*                   IF A LETTERSTRING IS FOUND, NOTHING BUT LETTERS     74100000
*                        AND BLANKS FOLLOWED BY ..(A COMMA IS MOVED     74120000
*                        TO OUTPUT AND PROCID ACTIVATED TO TAKE         74140000
*                        NEXT NAME                                      74160000
*                   IF ANYTHING ELSE IS FOUND E37 IS GENERATED          74180000
*                        AND COMERR ACTIVATED TO SKIP TO NEXT           74200000
*                        SEMICOLON                                      74220000
*                   ADDRESS OF COMERR IS PUT IN REGL                    74240000
         SPACE 2                                                        74260000
PROCDEL  LA    REGIX,DELCHECK+4                                         74280000
DELCHECK LA    REGI,1(0,REGI)                                           74300000
         CLI   0(REGI),X'40'       Q. LETTER                            74320000
         BNL   DELCHECK                                                 74340000
         CLI   0(REGI),X'2F'       Q. ZETA                              74360000
         BE    CIB                                                      74380000
         CLI   0(REGI),X'07'       Q. COLON                             74400000
         BE    DELCOLON                                                 74420000
         CLI   0(REGI),X'2B'                                            74440000
         BE    DELCHECK                                                 74460000
         CLI   0(REGI),X'2D'       Q. POINT                             74480000
         BNE   ERROR37                                                  74500000
DELPOINT LA    REGI,1(0,REGI)                                           74520000
         CLI   0(REGI),X'2D'       Q. ONE MORE POINT                    74540000
         BE    DELCOLON                                                 74560000
         CLI   0(REGI),X'2B'                                            74580000
         BE    DELPOINT                                                 74600000
         CLI   0(REGI),X'2F'       Q  ZETA                              74620000
         BNE   ERROR37                                                  74640000
         LA    REGIX,DELPOINT+4                                         74660000
         B     CIB                                                      74680000
DELCOLON LA    REGI,1(0,REGI)                                           74700000
         CLI   0(REGI),X'06'       Q LEFT PARENTHESIS                   74720000
         BE    DELPAREN                                                 74740000
         CLI   0(REGI),X'2B'       Q. BLANK                             74760000
         BE    DELCOLON                                                 74780000
         CLI   0(REGI),X'2F'       Q. ZETA                              74800000
         BNE   *+12                                                     74820000
         LA    REGIX,DELCOLON+4                                         74840000
         B     CIB                                                      74860000
         BCTR  REGI,0              NO PARENTHESIS FOLLOWS THE COLON     74880000
         B     ERROR37             RESET REGI AND GO TO ERROR 37        74900000
DELPAREN BAL   REGOX,COB                                                74920000
         MVI   0(EAP),X'25'        MOVE COMMA TO OUTPUT INSTEAD OF      74940000
         LA    EAP,1(0,EAP)        DELIMITER INCREASE  O/P POINTER      74960000
         B     PROCID              RETURN TO  PROCEDURE  CHECKING       74980000
ERROR37  BAL   REGB,ERR2B                                               75000000
         DC    X'0025'             E37                                  75020000
         LA    REGL,COMERR                                              75040000
         B     SCYES3                                                   75060000
         SPACE 2                                                        75080000
*****   ENDMISS  ****************************************************** 75100000
*                   ENTERED VIA OS IF END OF DATA SENSED BEFORE         75120000
*                   LOGICAL PROGRAM END IS FOUND BY SCAN I/II           75140000
*                   CLOSES WHAT REMAINS OPEN IN STACK                   75160000
*                   GENERATES PATTERN FOR ERR. MESS. 39.                75180000
         SPACE 2                                                        75200000
ENDMISS  TM    BITS2,STARTBIT           Q. FIRST BEGIN FOUND            75220000
         BO *+10                        YES                             75240000
         BAL   REGB,ERR4                                                75260000
         DC    X'042C'             E44 NOTHING PROCESSED                75280000
         OI    BITS1,TERBIT                                             75300000
TERMSEAC LA    REGE,TERMSEAC            RETURN FOR PBLCKEND PROG.       75320000
         L     REGY,SP             GET STACKPOINTER                     75340000
         CLI   0(REGY),X'04'            Q.BETA IN STACK                 75360000
         BE    STEPUP                                                   75380000
         CLI   0(REGY),X'08'            Q.BEGIN                         75400000
         BE    STEPUP                                                   75420000
         CLI   0(REGY),X'10'            Q. PROC*                        75440000
         BNE   TERMBRNC                                                 75460000
STEPUP   LH    REGB,ENDCOUNT            INCREASE ENDCOUNT               75480000
         LA    REGB,1(0,REGB)                                           75500000
         STH   REGB,ENDCOUNT                                            75520000
TERMBRNC IC    REGZ,0(0,REGY)                                           75540000
         L     REGB,TERMTAB(REGZ)       BRANCH ACORDING TO STACKBYTE    75560000
         BCR   15,REGB                                                  75580000
         CNOP  0,4                                                      75600000
TERMTAB  DC    A(ERROR39)                                               75620000
         DC    A(PBLCKEND)              BEGIN                           75640000
         DC    A(TERMBGN)               BETA                            75660000
         DC    A(PBLCKEND)              PROC                            75680000
         DC    A(PBLCKEND)              PROC*                           75700000
         DC    A(PBLCKEND)              PROC**                          75720000
         DC    A(FOREND)                FOR                             75740000
TERMBGN  BAL   REGOX,COB                                                75760000
         MVI   0(EAP),X'2C'             MOVE OUT END TO O/P             75780000
         LA    EAP,1(0,EAP)                                             75800000
         L     REGY,SP                                                  75820000
         BCTR  REGY,0                   RELEASE BEGIN IN STACK          75840000
         ST    REGY,SP                                                  75860000
         B     TERMSEAC                                                 75880000
         SPACE 2                                                        75900000
*****   SLUT2    ****************************************************** 75920000
*                   INTERED FROM IEX00 IF INTERUPT OCCURS BEFORE        75940000
*                   GETMAIN                                             75960000
         SPACE 2                                                        75980000
SLUT2    OI    BITS3,NOFREE        INTERUPT OCCURED PRIOR TO GETMAIN    76000000
         L     REG11,VIEX14                                             76020000
         USING IEX11003,11                                              76040000
         B     SCANEND                  GO TO PROCESS TERMINATING PART  76060000
         USING IEX11002,11                                              76080000
         SPACE 2                                                        76100000
*****   READROUT ****************************************************** 76120000
*                   ENTERED AFTER FINAL ENDCOMMENT HAS BEEN CHECKED     76140000
*                   SHOULD EXIT TO EODADIN VIA OS EOD ROUTINE           76160000
         SPACE 2                                                        76180000
READROUT LA    REGI,1(0,REGI)                                           76200000
         LA    REGIX,*+4                                                76220000
         TRT   0(73,REGI),BTABLE        ONLY VALID CHARACTER AFTER      76240000
         CLI   0(REGI),X'2F'            FINAL END COMMENT IS ZETA       76260000
         BE    CIB                                                      76280000
         B     ERR9                     ANYTHING ELSE FOUND             76300000
E39PAR   DC    X'0727'             E39                                  76320000
ERROR39  LA    REGB,E39PAR                                              76340000
         BAL   REG12,ERROR1             CREATE E39 PATTERN              76360000
         LH    REGB,ENDCOUNT                                            76380000
         CVD   REGB,DOUBLE                                              76400000
         UNPK  SAVE1(4),DOUBLE+5(3)                                     76420000
         MVZ   SAVE1+3(1),SAVE1+2       INSERT NUMBER OF ENDS MISSING   76440000
         MVC   4(3,REGY),SAVE1+1        IN ERROR PATTERN                76460000
         SPACE 2                                                        76480000
*****   EODADIN  ****************************************************** 76500000
*                   FALL THROUGH TO TERMINATION SECTION                 76520000
         SPACE 2                                                        76540000
EODADIN  L     REG11,VIEX14                                             76560000
         USING IEX11003,11                                              76580000
         B     TERMOK                                                   76600000
IEX11003 CSECT                                                          76620000
         SPACE 2                                                        76640000
*****   TERMINATION  ************************************************** 76660000
*                   WRITES PB0 ITAB BLOCK FOR A PRECOMPILED PROCEDURE   76680000
*                   WRITES LAST O/P REC IF MORE THAN ONE O/P REC        76700000
*                   CORRECTS SPCLT AND MOVES THE CONSTANTS 0 TROUGH     76720000
*                        15 TO THE CONSTANT POOL                        76740000
*                   IF NO TERMINATION ERROR AND EITHER DECK OR LOAD     76760000
*                        IS SPECIFIED ESD CARD AND TXT CARDS ARE        76780000
*                        GENERATED WITH GENERATE                        76800000
*                   CHECKS LAST ITAB RECORD WRITTEN, IF ANY             76820000
*                   CLOSES SYSIN, SYSUT1, SYSUT3                        76840000
*                   MAKES A FREEMAIN                                    76860000
*                   EXITS TO IEX20 IF NO TERMINATING ERROR              76880000
*                            IEX21 IF TERMINATING ERROR                 76900000
         SPACE 2                                                        76920000
TERMOK   TM    HCOMPMOD,X'08'           Q. TERMINATING ERROR            76940000
         BO    KOPOOLRL                 YES- DO NOT WRITE OUT ANYTHING  76960000
         L     REGI,AITAB          CHECK IF PB0                         76980000
         LA    REGI,11(0,REGI)     CONTAINS  ANYTHING                   77000000
         C     REGI,AITL                                                77020000
         BE    NOPBN0                   NO PB0                          77040000
         L     REGY,AITL                                                77060000
         OI    BITS2,X'08'              SET SWITCH                      77080000
         BAL   REGE,WRTITAB        WRITE OUT PB0                        77100000
NOPBN0   BAL   REGOX,COB                                                77120000
         MVI   0(EAP),X'2D'             MOVE OMEGA TO O/P               77140000
         LA    EAP,1(0,EAP)                                             77160000
         CLI   ONC,X'00'           Q  ONLY ONE O/P RECORD               77180000
         BE    *+12                EQUAL=YES                            77200000
         BAL   REGOX,COB+8         NO- WRITE LAST O/P BUFFER            77220000
         B     KOPOOLRL                                                 77240000
         OI    HCOMPMOD+2,X'40'    YES- LEAVE THE SINGLE BUFFER IN CORE 77260000
KOPOOLRL L     REG7,POOLLOC                                             77280000
         MVC   0(64,REG7),KOPOOL        MOVE THE CONSTANTS 0 TO 15      77300000
         L     REGB,SPCLT                                               77320000
         A     REGB,KOPOOL+28      MAKE SPCLT POINT                     77340000
         ST    REGB,SPCLT          TO THE NEAREST                       77360000
         NI    SPCLT+3,X'F8'            DOUBLE WORD BOUNDARY            77380000
         MVC   PBN+1(1),PBC             SAVE NUMBER OF BLOCKS           77400000
         IC    REGI,FSN                                                 77420000
         BCTR  REGI,0                   CORRECT FSN                     77440000
         STC   REGI,ZFSNMAX             SET FOR SCAN 3                  77460000
         CLC   MGESITL,TWOFIVEK         Q. WILL ITAB OVERFLOW           77480000
         BL    *+10                                                     77500000
         BAL   REGB,ERR7                                                77520000
         DC    X'0413'               E 19                               77540000
         TM    HCOMPMOD+1,X'60'         DECK AND OR LOAD SPECIFIED      77560000
         BO    SCANEND                  NO SKIP ESD CARD GENERATION     77580000
        SR    PRPOINT,PRPOINT                                           77600000
         TM    HCOMPMOD,PROC       Q. PRECOMPILED PROCEDURE             77620000
         BZ    *+10           NO                                        77640000
         MVC   ESDPAR2(8),ESDPARAM      GET NAME OF PROCEDURE           77660000
         BAL   INFORM,GENESD            WRITE ESD                       77680000
ESDPAR2  DC    8X'40'                                                   77700000
         DC    X'00'                                                    77720000
         MVC   29(3,OUTAREA),KOPOOL    CORRECT FIRST ESD CARD    A22571 77740019
SKIPESD  L     INFORM,AKOPOOL                                           77760000
         MVC   *+10(2),SPCLT+2          GET LENGTH OF KOPOOL FOR TXT    77780000
         BAL   LENGTH,GENTXTS           GENERATE TXT CARD               77800000
         DC    H'0'                                                     77820000
SCANEND  TM    BITS3,FRSITB                                             77840000
         BZ    CLSYSUT3                                                 77860000
         CHECK ITABC                                                    77880000
CLSYSUT3 L     REGB,UT3ADD                                              77900000
         CLOSE ((REGB),REREAD),TYPE=T   RESET SYSUT3                    77920000
         L     REGB,INADD          CLOSE SYSIN                          77940000
         CLOSE ((REGB),REREAD)                                          77960000
         L     1,INADD                  FREE QSAM BUFFER POOL           77980000
         FREEPOOL (1)                                                   78000000
         L     REGB,UT1ADD                                              78020000
         TM    HCOMPMOD,X'08'           Q. TERMINATING ERROR            78040000
         BO    CLSPERM             YES- CLOSE SYSUT1 FOR GOOD           78060000
         CLOSE ((REGB),REREAD),TYPE=T   RESET SYSUT1                    78080000
         B     FREE                                                     78100000
CLSPERM  CLOSE ((REGB),REREAD)          CLOSE SYSUT1                    78120000
FREE     TM    BITS3,NOFREE          Q. INTERUPT BEFOR GETMAIN          78140000
         BO    GETERRPH                 YES- DONOT MAKE FREEMAIN        78160000
         L     REG0,POOLLEN                                             78180000
         L     REGI,POOLLOC                                             78200000
         FREEMAIN R,LV=(0),A=(1)                                        78220000
         OI    HCOMPMOD+2,NOSC          SET SWITCH FOR ERROR MESSAGES   78240000
         TM    HCOMPMOD,X'08'           Q. TERMINATING ERROR            78260000
         BO    GETERRPH                 YES- CALL IEX21                 78280000
         L     REGB,BRACKET                                      A28251 78283019
         SR    REGOX,REGOX                                       A28251 78286019
         CR    REGOX,REGB              IS BRACKETCOUNTER ZERO    A28251 78289019
         BC    8,*+8                   YES                       A28251 78292019
         OI    HCOMPMOD,X'90'          NO  SET SYNTAX MODE       A28251 78295019
         XCTL  EP=IEX20000         GO TO ITAB-MANIPULATION              78300000
GETERRPH XCTL  EP=IEX21000         GO TO ERROR MESSAGE HANDLING         78320000
         SPACE 2                                                        78340000
         SPACE 2                                                        78360000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 78380000
*                                                                     * 78400000
*        S U B R O U T I N E   G E N E R A T E                        * 78420000
*                                                                     * 78440000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 78460000
         SPACE 3                                                        78480000
* REGISTER DEFINITIONS                                                  78500000
OUTAREA  EQU   1                        OUTPUT RECORD POINTER           78520000
INFORM   EQU   2                        ADDRESS OF INFORMATION          78540000
TYPER    EQU   3                        TYPE OF RECORD TO BE GENERATED  78560000
RETURN   EQU   4                        RETURN REGISTER                 78580000
PRPOINT  EQU   6                                                        78600000
LENGTH   EQU   14                       LENGTH OF INFORM. FROM CALL     78620000
L        EQU   15                       LENGTH WITHIN RECORD            78640000
         SPACE 3                                                        78660000
* BIT PATTERNS                                                          78680000
SDENTRY  EQU   X'00'                    SD-ENTRY IDENTIFICATION         78700000
LDENTRY  EQU   X'01'                    LD-ENTRY IDENTIFICATION         78720000
RLDFLAG  EQU   B'00001101'              FLAG USED IN RLD-ENTRY          78740000
*ADDRESS DISPLACEMENTS                                                  78760000
RSTART   EQU   0                        START OF RECORD TYPE TABLE      78780000
RTYP     EQU   1                        RECORD IDENTIFICATION           78800000
RLEN     EQU   4                        INITIAL LENGTH 0 OR 4           78820000
RESID    EQU   6                        ESID OR BLANKS                  78840000
RMAX     EQU   12                       MAXIMUM NUMBER OF BYTES IN REC  78860000
RMOV     EQU   14                       START OF MOVE ROUTINE           78880000
INFL     EQU   10                       LENGTH OF INFORM IN A RECORD    78900000
         SPACE 3                                                        78920000
GENESD   LA    LENGTH,16            LENGTH ALLWAYS 16                   78940000
         LA    TYPER,ESDT               INDICATE ESD-CALL               78960000
         MVC   PIDENT(4),0(INFORM)      NAME TO IDENT. PART             78980000
         B     GEN3                     CALLFOR FIRST OUT REC           79000000
*                                                                       79020000
GENTXTS  LA    RETURN,2(0,LENGTH)   COMPUTE RETURN ADDRESS              79040000
         LH    LENGTH,0(0,LENGTH)       LOAD LENGTH GIVEN IN CALL       79060000
GEN2     LA    TYPER,TXTT               INDICATE TXT-CALL               79080000
         SPACE 3                                                        79100000
GEN1     L     OUTAREA,SAVOUTA         LOAD ADDRESS OF OUT RECORD       79120000
         CLC   RTYP(3,OUTAREA),RTYP(TYPER)     RECORD RIGTH TYPE        79140000
         BNE   GEN3                     NO,CALL IOR NEW                 79160000
         CLC   INFL(2,OUTAREA),RMAX(TYPER)     RECORD FILLED            79180000
         BNL   GEN3                     YES,CALL FOR NEW                79200000
GEN6     LA    L,56                                                     79220000
         LH    REG0,INFL(0,OUTAREA)     REG0=LENGTH OF INFORM IN REC    79240000
         SR    L,REG0                   L=EMPTY POS LEFT IN RECORD      79260000
         CR    L,LENGTH                 ENOUTH SPACE LEFT               79280000
         BL    *+6                      NO                              79300000
         LR    L,LENGTH                 YES L=LENGTH FROM CALL          79320000
         AR    L,REG0                                                   79340000
         STH   L,INFL(0,OUTAREA)        INSERT NEW LENGTH INTO RECORD   79360000
*                                                                       79380000
         SR    L,REG0                                                   79400000
         AR    OUTAREA,REG0             START ADDRESS WITHIN RECORD     79420000
         SR    LENGTH,L                 REMAINING LENGTH                79440000
         B     RMOV(TYPER)              TO DIFFERENT MOVE ROUTINES      79460000
*                                                                       79480000
GEN4     LTR   LENGTH,LENGTH            MORE INFORMATION MUST BE MOVED  79500000
         BH    GEN3                     YES                             79520000
         BR    RETURN                                                   79540000
         SPACE 3                                                        79560000
GEN3     EQU   *                        CALL FOR NEW OUTPUT RECORD      79580000
PUNCH    ST  14,SAVAR                                                   79600000
         TM    HCOMPMOD+1,X'60'    Q. BOTH DECK AND LOAD SPECIFIED      79620000
         BZ    BOTH                     YES                             79640000
         TM    HCOMPMOD+1,NDCK         Q. ONLY DECK                     79660000
         L     OUTAREA,PCHADD           IF ONLY DECK                    79680000
         BZ    PUT1                     YES                             79700000
         L     OUTAREA,LINADD           ONLY SYSLIN                     79720000
PUT1     PUT   (OUTAREA)                PUT FOR SYSLIN AND SYSPUNCH IF  79740000
         ST    OUTAREA,SAVOUTA          ONLY SYSPUNCH SPECIFIED         79760000
         L     14,SAVAR                                                 79780000
         B     PUNCHOUT                                                 79800000
BOTH     TM    BITS2,X'02'              Q. FIRST PUT                    79820000
         BZ    FIRSTPUT                 YES                             79840000
         L     LENGTH,OUTAREA2          COPY SYSLIN BUFFER TO SYSPUNCH  79860000
         L     OUTAREA,SAVOUTA                                          79880000
         MVC   0(80,LENGTH),0(OUTAREA)  BUFFER                          79900000
PUT2     L     OUTAREA,PCHADD                                           79920000
         PUT   (OUTAREA)                PUT FOR SYSPUNCH WHEN BOTH HAS  79940000
         ST    OUTAREA,OUTAREA2         BEEN SPECIFIED                  79960000
         B     PUT1-4                   GO TO PUT SYSLIN                79980000
FIRSTPUT OI    BITS2,X'02'                                              80000000
         B     PUT2                                                     80020000
PUNCHOUT EQU   *                                                        80040000
         MVC   0(4,OUTAREA),RSTART(TYPER)     INSERT FIRST 4 BYTES      80060000
         MVI   4(OUTAREA),C' '          INSERT ONE BLANK                80080000
         MVC   5(67,OUTAREA),4(OUTAREA)      BLANK OUTPUT RECORD        80100000
         MVC   72(4,OUTAREA),PIDENT     INSERT PROGRAM IDENT            80120000
         L     L,SEQU                                                   80140000
         LA    L,1(0,L)                                                 80160000
         ST    L,SEQU                                                   80180000
         CVD   L,DOUBLE                                                 80200000
         UNPK  76(4,OUTAREA),DOUBLE+5(3)                                80220000
         MVZ   79(1,OUTAREA),76(OUTAREA)                                80240000
         MVC   10(2,OUTAREA),RLEN(TYPER)     INSERT INITIAL LENGTH      80260000
         MVC   14(6,OUTAREA),RESID(TYPER)     INSERT ESID+R AND P       80280000
         CLC   TXTT+1(3),RTYP(TYPER)    TXT-RECORD PROCESSED            80300000
         BNE   GEN6                     NO                              80320000
         ST    PRPOINT,4(OUTAREA)       YES INSERT PRPOINT              80340000
         MVI   4(OUTAREA),C' '                                          80360000
         B     GEN6                                                     80380000
         SPACE 3                                                        80400000
* TABLES AND MOVE ROUTINES                                              80420000
         SPACE 3                                                        80440000
ESDT     DS    0H                  START OF ESD-RECORD TABLE            80460000
         DC    X'02'                    CARD CODE                       80480000
         DC    C'ESD'                   IDENTIFICATION                  80500000
         DC    H'0'                     INITIAL LENGTH 0                80520000
         DC    C'      '                                                80540000
         DC    H'48'                    MAXIMUM LENTH IN RECORD         80560000
GEN7     EQU   *                   MOVE ESD-INFORMATION TO OUTAREA      80580000
         MVC   16(16,OUTAREA),0(INFORM)     MOVE INFORM TO OUTAREA      80600000
         MVC   25(7,OUTAREA),ESDCON     CHANGE LAST PART OF ENTRY       80620000
         LA    TYPER,1                 ESID NR IS 1                     80640000
         STH   TYPER,14(OUTAREA)        YES INSERT ESID NUMBER          80660000
         B     10(INFORM)               RETURN TO CALLING ROUTINE       80680000
         SPACE 3                                                        80700000
TXTT     DS    0H                  START OF TXT-RECORD  TABLE           80720000
         DC    X'02'                    CARD CODE                       80740000
         DC    C'TXT'                   IDENTIFICATION                  80760000
         DC    H'0'                     INITIAL LENGTH 0                80780000
         DC    H'1'                     ESID                            80800000
         DC    C'    '                                                  80820000
         DC    H'56'                    MAXIMUM LENGTH                  80840000
GEN8     EQU   *                   MOVE TXT-INFORMATION TO OUTAREA      80860000
         BCTR  L,0                      L=L-1                           80880000
         STC   L,*+5                    INSERT PROPER LENGTH TO MOVE    80900000
         MVC   16(0,OUTAREA),0(INFORM)      MOVE INFORM TO OUTAREA      80920000
         LA    PRPOINT,1(L,PRPOINT)     INCREASE PROGRAM POINTER        80940000
         LA    INFORM,1(L,INFORM)       MODIFY DATA ADDRESS             80960000
         B     GEN4                     OUT OF MOVE TXT ROUTINE         80980000
         SPACE 3                                                        81000000
* VARIABLES AND CONSTANTS                                               81020000
DEC1     DC    P'1'                     ADD CONSTANT                    81040000
ESDCON   DC    X'000000'                ESD-                            81060000
         DC    C'    '                  *CONSTANT,7 BYTES               81080000
         SPACE 3                                                        81100000
WORKAREA DSECT                                                          81120000
         COPY  WORKAREA                                                 81140000
C        DS    H                  PARENTHESIS COUNT                     81160000
KB       DS    H                  HOLDS ID FIELD FOR SPECIFICATIONS     81180000
POOLLEN  DS    F                  LENGTH OF AREA GOTTEN FROM GETMAIN    81200000
POOLLOC  DS    F                  START LOC. OF AREA FROM GETMAIN       81220000
AITABBUF DS    F                  ADD. OF ITAB BUFFER                   81240000
ELI      DS    F                  ADD. OF ONE LOC. BEYOND ITAB AREA     81260000
ADDARI   DS    A                  ADDRESS OF FIRST O/P BUFFER           81280000
         DS    A                  ADD. OF SECOND O/P BUFFER             81300000
DISP     DS    C                  DISPLACEMENT TO ADDARI                81320000
D        DS    C                  DIMENSION COUNTER                     81340000
SPCLT    EQU   PRPT                                                     81360000
SP       DS    F                  CURRENT STACK POINTER                 81380000
SC       EQU   SEMCNT                                                   81400000
APE      DS    F                  LAST AVAILABLE BYTE IN CURRENT O/P    81420000
WASAVE   DS    CL12                                                     81440000
WABEFOR  DS    CL7                                                      81460000
WA       DS    CL80               INPUT AREA                            81480000
APRNTAR  DS    A                  ADD. OF CURRENT PRINTAREA             81500000
ATOPSTAK DS    A                  LAST BYTE IN THE STACK                81520000
IGC      DS    H                  ITAB GROUP COUNTER                    81540000
AGT      DS    A                  ADD. OF GROUPE TAB. -3                81560000
AKOPOOL  DS    A                  ADD. OF THE CONSTANT POOL (0)         81580000
LAPIN    DS    A                  ADD. OF LAST POSS. LABEL START        81600000
DIM      DS    A                  ADD. FOR DIMENSION IN ITAB NAME       81620000
PRIMPAR  DS    A                  ADD. OF FIRST SPECIFICATION           81640000
AITAB    DS    A                  START ADD. OF ITAB                    81660000
AITL     DS    A                  CURRENT ITAB ENTRY ADD.               81680000
LIGP     DS    A                  POINTER TO CURRENT IG HEAD ENTRY      81700000
LPBP     DS    A                 POINTER TO CURRENT PBHEADING           81720000
WADDARI  DS    A                  CURRENT O/P BUFFER ADD.               81740000
ITABLEN  DS    F                  ITAB LENGTH                           81760000
MGESITL  DS    F                  ACCUMULATED ITAB LENGTH               81780000
BCHAR    DS    C                  SAVE CHAR.                            81800000
FBYTE    DS    CL1                SWITCH BYTE FOR APOSTROPHE            81820000
FSN      DS    C                 FORSTATEMENR COUNTER                   81840000
ZFSNMAX  DS    C                                                        81860000
PBC      DS    C                  PROGRAM BLOCK COUNTER                 81880000
ONC      DS    C                  O/P REC. COUNTER                      81900000
N        DS    C                  NR. OF ARRAYS WITH SAME DIM.          81920000
OPIN     DS    A                  POINTS TO LAST LABEL OPERATER         81940000
         DS    C                  O/P REC. NR. WHEN OPIN WAS SET        81960000
PZ       DS    C                  COUNTS NR. OF PARMETERS               81980000
BITS1    DS    C                  INTERNAL SWITCHES                     82000000
BEGBIT   EQU   X'80'              BLOCK BEGIN                           82020000
BEGOFF   EQU   X'7F'                                                    82040000
PROBIT   EQU   X'40'              PROCEDURE HEAD PROCESSING             82060000
DELTABIT EQU   X'20'              SEMICOLON FOUND AFTER DECLARATION     82080000
IDBIT    EQU   X'10'              PROCEDURE NAME                        82100000
ARBIT    EQU   X'08'              ARRAY PROCESSED                       82120000
LISTBIT  EQU   X'04'              COMMA FOUND AFTER ARRAY NAME          82140000
TERBIT   EQU   X'01'              RETURN TO TERM. AFTER PBLCKEND        82160000
BITS2    DS    C                                                        82180000
ENDBIT   EQU   X'80'              LOGICAL END HAS BEEN FOUND            82200000
COBIT    EQU   X'40'              COMMENT                               82220000
STARTBIT EQU   X'20'              ZERO UNTIL FIRST BEGIN FOUND          82240000
VALBIT   EQU   X'10'              VALUE                                 82260000
PB0BIT   EQU   X'08'              WRITE PB0 FOR PRE. COMP. PROC.        82280000
FRSTPUT  EQU   X'02'              FIRST PUT IN GENERATE                 82300000
ENDELSE  EQU   X'01'              END MAY CLOSE FOR OR PROC**           82320000
BITS3    DS    C                                                        82340000
E11BIT   EQU   X'80'              E11 HAS BEEN GENERATED ONCE           82360000
FMBIT    EQU   X'40'               FORMAL PARAMETER BIT                 82380000
FMOFF    EQU   X'BF'                                                    82400000
NOFREE   EQU   X'20'              INTERUPT BEFORE GETMAIN               82420000
FRSITB   EQU   X'10'              FIRST ITAB REC. IS WRITTEN            82440000
PROCESD  EQU   X'08'              WRITE SED CARD FOR PRE. COMP. PROC.   82460000
PROCOFF  EQU   X'F7'                                                    82480000
         END   IEX11000                                                 82500000
