         TITLE 'ITAB MANIPULATION IEX20'                                00020000
*STATUS: CHANGE LEVEL 000                                             * 00040000
*                                                                     * 00060000
*FUNCTION/OPERATION: EACH ITAB BLOCK IS SCANNED FOR DUPLICATE         * 00080000
*   IDENTIFIERS.                                                      * 00100000
*   RELATIVE DISPLACEMENTS IN DSA IS ALLOCATED FOR ALL IDENTIFIERS,   * 00120000
*   EXCEPT PROCEDURES, LABELS AND SWITCHES.                           * 00140000
*   THE ITAB BLOCKS ARE WRITTEN IN PROGRAM BLOCK NUMBER ORDER TO      * 00160000
*   SYSUT3.                                                           * 00180000
*   THE ITAB BLOCKS ARE PRINTED ON SYSPRINT IN PROGRAM BLOCK NUMBER   * 00200000
*   ORDER AND WITH THE IDENTIFIERS IN ALPHABETIC FORM WITHIN EACH     * 00220000
*   BLOCK, IF THE OPTION 'SOURCE' IS SPECIFIED.                       * 00240000
*   CREATES PBTAB2                                                    * 00260000
*                                                                     * 00280000
*ENTRY POINT:                                                         * 00300000
*        IEX20000 ITAB MANIPULATION     XCTL EP=IEX20                 * 00320000
*                                                                     * 00340000
*INPUT: THE ITAB BLOCKS ARE READ IN FROM SYSUT3.                      * 00360000
*                                                                     * 00380000
*OUTPUT: THE ITAB BLOCKS ARE WRITTEN TO SYSUT3 AND PRINTED ON SYSPRINT* 00400000
*   IF THE OPTION 'SOURCE' IS SPECIFIED.                              * 00420000
*                                                                     * 00440000
*EXTERNAL ROUTINES: THE PRINT ROUTINE IN IEX00 IS USED.               * 00460000
*                                                                     * 00480000
*EXITS-NORMAL: CONTROL IS GIVEN TO IEX21  XCTL EP=IEX21               * 00500000
*                                                                     * 00520000
*     -ERROR: N/A                                                     * 00540000
*                                                                     * 00560000
*TABLES/WORKAREA:                                                     * 00580000
*   ATAB  FOR ADDRESS IS OF THE ITAB RECORDS IN PROGRAM BLOCK NUMBER  * 00600000
*         ORDER                                                       * 00620000
*   TRTAB FOR TRANSLATION OC INTERNAL CHATACTERS TO EBCDIC CHARACTERS.* 00640000
*   TAB   FOR PRINTING OF HEXADECIMAL DIGITS.                         * 00660000
*   WORK  FOR BUILDING THE PRINT ENTRIES.                             * 00680000
*                                                                     * 00700000
*ATTRIBUTES: NONE.                                                    * 00720000
*                                                                     * 00740000
*NOTES: CHARACTER CODE DEPENDENCE.                                    * 00760000
*   THE OUTPUT ON SYSPRINT:                                           * 00780000
*   THE IDENTIFIER NAME IS TRANSLATED BY MEANS OF TRTAB, WHICH IS     * 00800000
*   A CHARACTER TABLE.                                                * 00820000
*   THE HEXADECIMAL PART IS TRANSLATED BY MEANS OF TAB.               * 00840000
*   THE REMAININ PARTS DEPEND ON THE INTERNAL REPRESENTATION OF THE   * 00860000
*   EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE ONE USED AT     * 00880000
*   ASSEMBLY TIME.                                                    * 00900000
*   THE OPERATION OF THE OTHER PARTS OF THE PHASE DOES NOT DEPEND     * 00920000
*   UPON A PARTICULAT INTERNAL REPRESENTATION OF THE EXTERNAL         * 00940000
*   CHARACTER SET                                                     * 00960000
IEX20000 START                                                          00980000
* RELEASE 19 CHANGES                                                    00985019
* 110600                                                         A28230 00990019
REG0     EQU   0                  CALCULATIONS                          01000000
REGI     EQU   1                  PBN                                   01020000
REGZ     EQU   2                  CALCULATIONS                          01040000
REGD     EQU   3                  PARAMETER FOR CONVERT ROUTINE         01060000
DP       EQU   3                  DOUBLE WORD POINTER                   01080000
WP       EQU   4                  WORD POINTER                          01100000
REGC     EQU   5                  KEEPS TRACK OF WHEN TO PRINT          01120000
HP       EQU   5                  HALF WORD POINTER                     01140000
BP       EQU   6                  BYTE POINTER                          01160000
RAID     EQU   7                  CURRENT IDENTIFIER                    01180000
AIB      EQU   8                  CURRENT BLOCKHEAD                     01200000
RAKOM    EQU   9                  SCANS FOR DUPLICATES                  01220000
REGY     EQU   10                                                       01240000
REGDIM   EQU   10                 ARRAY STORAGE ALLOCATIONS             01260000
REG11    EQU   11                 BASE REGISTER                         01280000
REGB     EQU   12                 RETURN FROM CONVERT, PRINT ROUTINE    01300000
REGP     EQU   14                 PBN DURING PRINTING                   01320000
REG15    EQU   15                                                       01340000
         SPACE 2                                                        01360000
*****   INITIALIZATION  *********************************************** 01380000
*              GETMAIN FOR ITAB AND ATAB                                01400000
*              FIRST ENTRY IN ATAB IS MADE ZERO IF NO PBN 0             01420000
*              PRINTING OF HEADLINES IS INTITLIZED IF SOURCE SPECIFIED  01440000
*              C IS MADE 4 IF SHORT SPECIFIED OTHERWISE IT REMAINS 8    01460000
         SPACE 2                                                        01480000
         BALR  REG11,0                                                  01500000
         USING *,REG11                                                  01520000
         USING WORKAREA,13                                              01540000
         LA    REG15,SLUT2        INTERUPT BEFORE GETMAIN               01560000
         ST    REG15,ERET                                               01580000
         L     REGI,ITAB20S       ITAB                                  01600000
         LA    REGI,1024(0,REGI)      ATAB                              01620000
         LR    REG0,REGI                                                01640000
         GETMAIN R,LV=(0)              GET ITAB ATAB AREAS              01660000
         LA    REG15,SLUT                                               01680000
         ST    REG15,ERET         INTERUPT ADD. AFTER GETMAIN           01700000
         ST    REGI,AREALOC                                             01720000
         ST    REGI,AITAB         ITAB START LOCATION                   01740000
         A     REGI,ITAB20S                                             01760000
         ST    REGI,ATABAD        ATAB START LOCATION                   01780000
         SR    REGZ,REGZ                                                01800000
         ST    REGZ,KOPOOL                                              01820000
         ST    REGZ,SAVEPB                                              01840000
         TM    HCOMPMOD,PROC       Q. IS THERE A PB0                    01860000
         BO    *+12                                                     01880000
         LA    REG15,1             NO- PROGRAM BLOCK 1 IS FIRST BLOCK   01900000
         ST    REG15,SAVEPB                                             01920000
         MVC   0(4,REGI),KOPOOL                                         01940000
         ST    REGZ,SAVE                INITILIZE WITH ZEROS            01960000
         MVC   SAVE1(16),SAVE                                           01980000
         STC   REGZ,BITS1               INITILIZE SWITCHES              02000000
         LA    REGY,PBTAB2                                              02020000
         ST    REGY,APBTAB2              START ADDRESS OF PBTAB2        02040000
         TM    HCOMPMOD+1,NSRCE   Q. SOURCE SPECIFIED                   02060000
         BO    INITIAL            NO                                    02080000
         MVI   LINCNT,X'7F'                                             02100000
         MVI   PAGEHD1,X'02'                                            02120000
         MVI   PAGEHD1+1,X'11'                                          02140000
         MVI   PAGEHEAD+2,X'40'                                         02160000
         MVC   PAGEHEAD+3(81),PAGEHEAD+2                                02180000
         MVC   PAGEHEAD+39(16),HDING1                                   02200000
         MVI   PAGEHD2,X'01'                                            02220000
         MVI   PAGEHD2+1,X'09'                                          02240000
         MVC   PAGEHD2+2(90),HEAD1                                      02260000
         MVI   PAGEHD3,X'01'                                            02280000
         MVI   PAGEHD3+1,X'11'                                          02300000
         MVC   PAGEHD3+2(90),HEAD2                                      02320000
         BAL   REGB,PRINTITB            INITILIZE PRINTING FOR ITAB     02340000
INITIAL  SR    REGI,REGI                                                02360000
         TM    HCOMPMOD,LNG        LONG OR SHORT PRECISION              02380000
         BO    *+8                 LONG                                 02400000
         MVI   C+1,X'04'          SHORT   C=4                           02420000
*****   SCAN FOR DUPLICATES   ***************************************** 02440000
*                   READS IN A NEW BLOCK                                02460000
*                   START ADDRESS IN AIB END ADDRESS IN AITAB           02480000
*                   COMPARES EACH IDENTIFIER WITH ALL IDENTIFIERS       02500000
*                        FOLLOWING IT IN THE BLOCK                      02520000
*                   IF TWO EQUAL FOUND AND IF NOT FIRST ONE IS A        02540000
*                        FORMAL PARAMETER AND SECOND NOT E45 IS         02560000
*                        GENERATED                                      02580000
*                   WHEN ALL IDENTIFIERS IN THE BLOCK HAVE BEEN         02600000
*                        CHECK THE EXIT IS TO ALLOSTUR                  02620000
READBLK  L     REGB,AITAB         START ADD. OF NEW BLOCK               02640000
         L     REGZ,UT3ADD        READ IN NEW BLOCK                     02660000
         READ  ITABC,SF,(REGZ),(REGB),'S'                               02680000
         CHECK ITABC                                                    02700000
         SR    REGZ,REGZ                                                02720000
         IC    REGZ,10(0,REGB)    GET NEW PBN                           02740000
         SLA   REGZ,2                                                   02760000
         L     RAID,ATABAD                                              02780000
         ST    REGB,0(REGZ,RAID)        SAVE ADD. OF BLOCK IN ATAB      02800000
         LR    AIB,REGB                                                 02820000
         MVC   LENCOUNT(2),0(REGB)      GET LENTH OF BLOCK              02840000
         AH    REGB,LENCOUNT                                            02860000
         ST    REGB,AITAB               SAVE END ADDRESS OF BLOCK       02880000
         LR    RAID,AIB                                                 02900000
         TM    8(AIB),X'80'        Q. IS BLOCK TYPE PROC                02920000
         BZ    SCANNXT             NO                                   02940000
         LA    RAID,22(0,AIB)      YES- SKIP  CHECKING AGAINST          02960000
         B     SCANNXT+4           TYPE PROCEDURE NAME                  02980000
SCANNXT  LA    RAID,11(0,RAID)                                          03000000
         C     RAID,AITAB               Q. ALL IDENTIFIERS CHECKED      03020000
         BE    ALLOSTOR                 YES- GO TO ALLOCATE STORAGE     03040000
         CLI   5(RAID),X'2B'       Q. FOR HEAD OR CONT. ENTRY           03060000
         BE    SCANNXT                  YES- SKIP CHECKING              03080000
         CLI   0(RAID),X'00'            Q. INVALID PROCEDURE NAME       03100000
         BE    SCANNXT                  YES- SKIP CHECKING              03120000
         LR    RAKOM,RAID                                               03140000
CHECKNXT LA    RAKOM,11(0,RAKOM)                                        03160000
         C     RAKOM,AITAB              Q. ALL IDENT. CHECKED AGAINST   03180000
         BE    SCANNXT                  THE ONE PROCESSED               03200000
         CLI   5(RAKOM),X'2B'        Q. FOR HEAD OR CONT ENTRY          03220000
         BE    CHECKNXT                                                 03240000
         CLC   0(6,RAKOM),0(RAID)       COMPARE EACH IDENTIFIER AGAINST 03260000
*ALL FOLLOWING INDENTIFIERS IN THE      BLOCK                           03280000
         BNE   CHECKNXT                                                 03300000
         TM    7(RAID),X'30'            TWO EQUAL FOUND Q. PROCESSED    03320000
         BM    *+8                     ONE FORMAL PARAMETER             03340000
         B     E43                     NO                               03360000
         TM    7(RAKOM),X'30'      Q. COMPARED ONE IS FORMAL PARAMETER  03380000
         BM    E43                     YES                              03400000
         B     CHECKNXT                NO                               03420000
         SPACE 2                                                        03440000
*****   ALLOSTOR ****************************************************** 03460000
*                   ALLOCATETS STORAGE FOR THE IDENTIFIERS              03480000
*                   FOR A TYPE PROC BLOCK ALLOCATION STARTS AT 32       03500000
*                        OTHERWISE AT 24                                03520000
*                   NO BLOCK MAY GET MORE THAN 4K ALLOCATED             03540000
*                   IT IS ALSO CHECKED THAT THERE IS NO PROC, STRING    03560000
*                        OR SWITCH CALLED BY VALUE                      03580000
*                        WHEN ALL DECLARATIONS IN THE BLOCK ARE         03600000
*                             PROCESSED DP-C WILL BE PUT IN PBTAB2      03620000
*                        IF THERE ARE MORE BLOCKS TO BE PROCESSED THE   03640000
*                             EXIT IS TO IDENTIFIER SCAN OTHERWISE      03660000
*                             TO WRITE ITAB                             03680000
*                        FOUR POINTERS ARE USED DP DOUBLE WORD POINTER  03700000
*                                               WP WORD                 03720000
*                                               HP HALF WORD            03740000
*                                               BP BOOLEAN              03760000
*                        DP IS INCREASED BY C WHICH IS 8 FOR LONG       03780000
*                                                      4 FOR SHORT      03800000
*                        FOR LONG PRESITION ALL 4 POINTERS ARE USED     03820000
*                        FOR SHORT WP IS NEVER USED, WILL CONTAIN 0     03840000
*                             ALL THE TIME                              03860000
*                        REAL WILL BE ALLOCATED TO DP, 4 OR 8 BYTES     03880000
*                        INTEGER WILL GET DP OR WP. DP ALLWAYS IF SHORT 03900000
*                             WP IF LONG AND WP NOT ZERO                03920000
*                             OTHERWISE DP, IN WHITCH CASE WP WILL      03940000
*                             EQUAL DP+4 FOR THE NEXT INTEGER           03960000
*                        BOOLEAN WILL GET DP, WP, HP OR BP IF LONG      03980000
*                             DP, HP OR BP IF SHORT                     04000000
*                        FIRST BOOLEAN FOUND WILL GET EITHER WP OR DP   04020000
*                                 HP IS THEN INITILIZED TO WP+2 OR DP+2 04040000
*                                 BP                       WP+1    DP+1 04060000
*                        SECOND BOOLEND WILL GET THE VALUE OF BP        04080000
*                             AND BP WILL BE 0                          04100000
*                        THIRD BOOLEAN WILL GET HP AND HP WILL BE 0     04120000
*                                  BP=HP+1                              04140000
*                        FORTH BOOLEAN WILL GET BP AND BP WILL BE 0     04160000
*                        THIS WILL THEN BE REPEATED FOR EVERY FOUR      04180000
*                             BOOLEAN IDENTIFIERS                       04200000
*                        ALL FORMAL PARAMETERS WILL GET THE DP VALUE    04220000
*                             AND DP WILL BE INCREASED BY 8             04240000
*                        ARRAYS WILL GET DP VALUE AND DP WILL BE        04260000
*                             INCREASED BY 4(DIM+6)+X WHERE X IS 4      04280000
*                             WHEN LONG PRECITION AND DIM IS AN UNEVAN  04300000
*                             NUMBER, OTHERWISE X IS 0                  04320000
*                        LABEL, SWITCH , PROCEDURE WILL NOT GET ANYTHIN 04340000
*                        EX. OF STORAGE ALLOCATION                      04360000
*                        LONG           SHORT                           04380000
*                        01234567       01234567  FP   FORMAL PARAMETER 04400000
*                        FP             FP        R    REAL             04420000
*                        FP             FP        INT  INTEGER          04440000
*                        R              R   INT   B    BOOLEAN          04460000
*                        INT INT        INT INT   NU   NOT USED SPACE   04480000
*                        INT BBB        BBB R                           04500000
*                        R              INT R                           04520000
*                        INT NU                                         04540000
*                        R                                              04560000
         SPACE 2                                                        04580000
ALLOSTOR TM    8(AIB),X'80'   Q. IS THE BLOCK A TYPE PROCEDURE          04600000
         BZ    STARTALL-4     NO                                        04620000
         LA    DP,32          YES- SET DOUBLE WORD POINTER              04640000
         NI    8(AIB),X'7F'   CLEAR TYPE PROCEDURE INDICATION           04660000
         B     *+8                                                      04680000
         LA    DP,24          SET DOUBLE WORD POINTER                   04700000
STARTALL LA    WP,0                SET ALL POINTERS TO ZERO             04720000
         LA    HP,0                                                     04740000
         LA    BP,0                                                     04760000
         LR    RAID,AIB            GET FIRST VARIABLE                   04780000
         B     GETNEXT                                                  04800000
STORALLO AH    DP,C           INCREASE ALLOCATION POINTER               04820000
         C     DP,FOURK            Q. HAS FOURK BEEN ALLOCATED ALLREADY 04840000
         BH    E44                                                      04860000
GETNEXT  LA    RAID,11(0,RAID)     GET NEXT VARIABLE                    04880000
         STM   DP,BP,DPC           STORE ALL POINTERS                   04900000
         C     RAID,AITAB          Q. ALL VARIABLES TAKEN CARE OF       04920000
         BE    LASTREC             YES                                  04940000
         CLI   5(RAID),X'2B'       Q. FOR HEADING OR CONTINUATION       04960000
         BE    GETNEXT                                                  04980000
         CLI   6(RAID),X'91'       Q. ALL PURPOS IDENTIFIER             05000000
         BE    GETNEXT                                                  05020000
         TM    7(RAID),X'30'       Q. FORMPARAM, DEK. VARIABL. OR CONST 05040000
         BM    FORMPARM                                                 05060000
         BZ    CONST                                                    05080000
         TM    7(RAID),X'03'       Q. BOOLEAN VARIABLE                  05100000
         BO    BOOLEAN                                                  05120000
         TM    HCOMPMOD,LNG      Q,SHORT PRESISION                      05140000
         BZ    REAL                YES- ALLOCATE SAME FOR REAL AND      05160000
*                                  INTEGER                              05180000
         TM    7(RAID),X'01'       Q. INTEGER OR REAL                   05200000
         BO    INTEGER                                                  05220000
REAL     MVC   9(2,RAID),DPC+2     MOVE IN DISPLACEMENT                 05240000
         B     STORALLO                                                 05260000
INTEGER  LTR   WP,WP               Q. EMTY HOLE LEFT FOR INTEGER        05280000
         BZ    *+18                NO                                   05300000
         MVC   9(2,RAID),WPC+2     YES- FILL THE HOLE AND MAKE          05320000
         LA    WP,0                WORDPOINTER= 0.                      05340000
         B     GETNEXT                                                  05360000
         MVC   9(2,RAID),DPC+2     MOVE IN DOUBLEWORD POINTER AND MAKE  05380000
         LA    WP,4(0,DP)          WORDPOINTER POINT TD EMPTY HOLE NEXT 05400000
         B     STORALLO            TO IT                                05420000
BOOLEAN  LTR   BP,BP               Q SPACE LEFT NEXT TO PREVIOUS BOOL.  05440000
         BZ    *+18                NO                                   05460000
         MVC   9(2,RAID),BPC+2     YES- MOVE IN DISPLACEMENT AND MAKE   05480000
         LA    BP,0                BYTE  POINTER 0                      05500000
         B     GETNEXT                                                  05520000
         LTR   HP,HP               Q.SPACE LEFT NEXT TO 2 PREVIOUS BOOL 05540000
         BZ    TESTWP-8            NO                                   05560000
         MVC   9(2,RAID),HPC+2     YES- MOVE IN DISPLACEMENT AND MAKE   05580000
         LA    BP,1(0,HP)          MAKE BYTEPOINTER POINT TO NEXT       05600000
         LA    HP,0                HALFWORD POINTER 0                   05620000
         B     GETNEXT             FREE BYTE                            05640000
         TM    HCOMPMOD,LNG      Q, SHORT PRECISION                     05660000
         BZ    TAKEDP              YES- DO NOT USE WP POINTER           05680000
TESTWP   LTR   WP,WP               Q. WPPOINTE FREE                     05700000
         BZ    TAKEDP              NO- TAKE DP POINTER INSTEAP          05720000
         MVC   9(2,RAID),WPC+2     YES- USE WP AS DISPLACEMENT          05740000
         LA    BP,1(0,WP)          SET  HP AND BP TO FREE BYTES IN WORD 05760000
         LA    HP,2(0,WP)                                               05780000
         LA    WP,0                SET WP TO ZERO                       05800000
         B     GETNEXT                                                  05820000
TAKEDP   MVC   9(2,RAID),DPC+2     USE DP AS DISPLACEMENT               05840000
         LA    BP,1(0,DP)          SET WP, HP, BP TO FREE BYTES WITHIN  05860000
         LA    HP,2(0,DP)          THE DOUBLE WORD                      05880000
         LA    WP,4(0,DP)                                               05900000
         B     STORALLO                                                 05920000
CONST    TM    7(RAID),X'04'       FOR LABEL, STRING, PROCEDURE DO NOT  05940000
         BZ    GETNEXT                                                  05960000
         TM    7(RAID),X'08'       ALLOCATE ANY STORAGE                 05980000
         BO    GETNEXT                                                  06000000
         SR    REGDIM,REGDIM                                            06020000
         IC    REGDIM,9(RAID)                                           06040000
         SRA   REGDIM,4            FOR  AN ARRAY                        06060000
         LA    REGDIM,6(0,REGDIM)      STORAGE NEEDED IS 4(DIM+6)+X     06080000
         SLA   REGDIM,2                                                 06100000
         OC    9(2,RAID),DPC+2    OR IN THE DISP. TO SAVE DIMENSIONS    06120000
         TM    HCOMPMOD,LNG        X IS 4 IF LONG PRECITION AND DIM IS  06140000
         BZ    *+16                                                     06160000
         TM    9(RAID),X'10'       AN UNEVAN NUMBER                     06180000
         BZ    *+8                 INCREASE IF NEEDED TO GET            06200000
         LA    REGDIM,4(0,REGDIM)       ON DOUBLE WORD BOUNDARY         06220000
         LA    DP,0(REGDIM,DP)                                          06240000
         B     STORALLO+4                                               06260000
FORMPARM TM    7(RAID),X'03'       Q. TYPE PARAMETER                    06280000
         BZ    NOTTYPE             NO                                   06300000
FORMPALL MVC   9(2,RAID),DPC+2     MOVE IN DISPLACEMENT                 06320000
         LA    DP,8(0,DP)                                               06340000
         B     STORALLO+4                                               06360000
NOTTYPE  TM    7(RAID),X'10'       Q. CALL BY NAME                      06380000
         BO    FORMPALL            YES                                  06400000
         TM    7(RAID),X'03'       NO- CHECK IF VALUE CALL CORRECT      06420000
         BZ    *+8                                                      06440000
         B     FORMPALL                                                 06460000
         CLI   7(RAID),X'28'       Q. LABLE CALLED BY VALUE             06480000
         BE    FORMPALL                                                 06500000
         B     E45       PROC SWITCH OR STRING CALLED BY VALUE          06520000
LASTREC  SR    REGZ,REGZ           CONSTRUCT ENTRY OF PBTAB2            06540000
       IC    REGZ,10(0,AIB)       GET PBN                               06560000
         SLA   REGZ,1                                                   06580000
         L     REGP,APBTAB2                                             06600000
         LA    REGP,0(REGZ,REGP)                                        06620000
         SH    DP,C               GET LAST BYTE USED                    06640000
         STH   DP,0(0,REGP)                                             06660000
         L     REGI,SAVEPB                                              06680000
         CH    REGI,PBN       Q.ALL ITAB-REC WRITTEN OUT                06700000
         LA    REGI,1(0,REGI)                                           06720000
         ST    REGI,SAVEPB                                              06740000
         BNE   READBLK            NO                                    06760000
         SPACE 2                                                        06780000
*****   WRITITAB ****************************************************** 06800000
*                   WRITES THE ITABRECORD TO SYSUT3 IN PROGRAM BLOCK    06820000
*                        NUMBER ORDER                                   06840000
*                   THE ADDRESS TO WHERE THE BLOCK IS GOING TO BE       06860000
*                        WRITTEN IS PICKED UP FROM ATAB                 06880000
*                   IN EACH BLOCK THE LENGTH OF THE NEXT BLOCK IS       06900000
*                        INSERTED                                       06920000
         SPACE 2                                                        06940000
WRITITAB L     REGB,ATABAD        START OF ADDRESS TABLE                06960000
         L     REGY,UT3ADD        DCB ADDRESS                           06980000
         CLOSE ((REGY),REREAD),TYPE=T   GET  TO START OF SYSUT3         07000000
         SR    REGZ,REGZ                                                07020000
         TM    HCOMPMOD,PROC       Q. IS THERE A PB0                    07040000
         BZ    ITLP2              NO                                    07060000
ITABLOOP L     REGY,0(0,REGB)     GET ADDRESS OF BLOCK                  07080000
         L     RAID,UT3ADD        DCB ADDRESS                           07100000
         L     REGC,4(0,REGB)     GET ADDRESS OF NEXT BLOCK             07120000
         CH    REGZ,PBN            Q. LAST BLOCK                        07140000
         BE    *+10               YES                                   07160000
         MVC   2(2,REGY),0(REGC)      INSERT LENGTH OF NEXT BLOCK       07180000
         MVC   LENCOUNT(2),0(REGY)    GET LENGTH OF CURRENT BLOCK       07200000
         LH    REG15,LENCOUNT                                           07220000
         WRITE PRCH4,SF,(RAID),(REGY),(REG15)                           07240000
         CHECK PRCH4                                                    07260000
ITLP2    LA    REGB,4(0,REGB)       GET ADDRESS OF NEXT BLOCK           07280000
         CH    REGZ,PBN       Q.ALL ITAB-REC WRITTEN OUT                07300000
         LA    REGZ,1(0,REGZ)                                           07320000
         BNE   ITABLOOP            NO                                   07340000
         B     ITABPRNT           YES                                   07360000
         SPACE 2                                                        07380000
*****   E43      ****************************************************   07400000
*                   GENERATES ERROR MESSAGE 45                          07420000
*                   RETURNS TO SCANNING FOR DUPLICATES                  07440000
         SPACE 2                                                        07460000
E43      BAL   REG15,ERRNAME                                            07480000
         MVI   1(REGY),X'2D'       E45                                  07500000
         B     SCANNXT                                                  07520000
         SPACE 2                                                        07540000
*****   E45      ****************************************************** 07560000
*                   GENERATER ERROR MESSAGE 47                          07580000
*                   RETURNS TO FORMPALL AS IF VAR. WAS CORRECT          07600000
         SPACE 2                                                        07620000
E45      BAL   REG15,ERRNAME                                            07640000
         MVI   1(REGY),X'2F'       E47                                  07660000
         B     FORMPALL                                                 07680000
         SPACE 2                                                        07700000
*****   E44      ****************************************************** 07720000
*                   GENERATES ERROR MESSAGE 214                         07740000
*                   RETURNS TO LASTREC TO TAKE NEXT BLOCK, IF ANY       07760000
*                                                                     * 07780000
*                                                                     * 07800000
E44      L     REGD,SAVEPB                                              07820000
         BAL   REGB,CONVERT        CONVERT PBN                          07840000
         L     REGY,NEXTERR                                             07860000
         LA    REGB,7(0,REGY)        Q. SPACE LEFT IN ERRORPOOL         07880000
         C     REGB,ENDPOOL                                             07900000
         BH    E0                                                       07920000
         ST    REGB,NEXTERR                                             07940000
         MVI   0(REGY),X'87'       MOVE LENGTH AND BLANK SC INDICATOR   07960000
         MVI   1(REGB),X'D6'            E214                            07980000
         MVC   4(3,REGY),SAVE+1          PBN                            08000000
         B     LASTREC                                                  08020000
         SPACE 2                                                        08040000
*****   ERRNAME  *****                                                  08060000
*                   FINDS THE LENGTH OF THE VAR. IN ERROR CHECKS FOR    08080000
*                        ERRPOOL OVERFLOW, MOVES IN THE NAME OF THE     08100000
*                        VAR. AND LENGTH OF MESSAGE                     08120000
*                        RETURNS TO CALLING PROGRAM, E43 OR E44         08140000
         SPACE 2                                                        08160000
ERRNAME  LA    REGB,5                                                   08180000
         STC   REGB,*+7                                                 08200000
         CLI   0(RAID),X'00'      FIND LENGTH OF NAME                   08220000
         BNE   *+8                                                      08240000
         BCT   REGB,ERRNAME+4                                           08260000
         L     RAKOM,NEXTERR                                            08280000
         LA    RAKOM,5(REGB,RAKOM)                                      08300000
         C     RAKOM,ENDPOOL      CHECK SPACE IN ERRORPOOL              08320000
         BH    E0                                                       08340000
         L     REGY,NEXTERR                                             08360000
         ST    RAKOM,NEXTERR                                            08380000
         EX    REGB,MOVE          INSERT NAME IN ERROR PATTERN          08400000
         LA    REGB,5(0,REGB)                                           08420000
         STC   REGB,0(REGY)                                             08440000
         OI    0(REGY),X'80'       BLANK SC INDICATOR                   08460000
         BCR   15,REG15                                                 08480000
         CNOP  0,4                                                      08500000
MOVE     MVC   4(1,REGY),0(RAID)                                        08520000
E0       LA    REGB,NEXTERR                                             08540000
         MVI   0(REGB),X'02'                                            08560000
         MVI   1(REGB),X'D4'            E212                            08580000
         ST    REGB,NEXTERR                                             08600000
         B     SLUT                                                     08620000
         SPACE 2                                                        08640000
         SPACE 2                                                        08660000
*****   ITABPRNT ****************************************************** 08680000
*                   PRINTS ON SYSPRINT, IF SOURCE SPECIFIED, ALL VAR.   08700000
*                   THE BLOCKS IN PBN NUMBER ORDER AND WITH THE VAR     08720000
*                        SORTED WITHIN EACH BLOCK                       08740000
*                   REGC KEEPS TRACK OF WHEN PRINTING IS NEEDED, THE    08760000
*                        INFORMATION ABOUT EACH VAR. IS BUILT UP IN     08780000
*                        WORK AND THEN TRANSFERD TO PRINTAREA. WHEN     08800000
*                        3 VAR. HAVE BEEN PLACED IN THE PRINTAREA THE   08820000
*                        LINES IS PRINTED                               08840000
*                   THE ADDRESS TO THE BLOCK IS TAKEN FROM ATAB         08860000
*                   THE LENGTH IS TAKEN FROM THE FIRST 2 BYTES IN THE   08880000
*                        BLOCK.                                         08900000
*                   THE SURROUNDING PBN FROM PBTAB1                     08920000
*                   THE STARTING SC COUNTER FOR THE BLOCK FROM BYTE 6   08940000
*                        AND 7 IN THE BLOCK                             08960000
*                   IF THE BLOCK DOES NOT CONTAIN ANY VAR. ONLY THE     08980000
*                        PBN AND SURROUNDING PBN ARE PRINTED            09000000
*                   ALL HEADENTRIES, FOR AND CONTLINES ARE SKIPPED      09020000
*                   EACH NEW BLOCK IS PRECEEDED BY A BLANK LINE         09040000
*                   START ADDRESS OF THE BLOCK IS IN AIB                09060000
*                   END ADDRESS OF THE BLOCK IS IN AITAB, THIS ADD.     09080000
*                        WILL BE AIB+11 WHEN ALL VAR. PROCESSED         09100000
         SPACE 2                                                        09120000
ITABPRNT TM    HCOMPMOD+1,NSRCE     Q. SOURCE SPECIFIED                 09140000
         BO    SLUT               NO                                    09160000
         SR    REGP,REGP           CLEAR REGISTER                       09180000
         TM    HCOMPMOD,PROC       IS THERE A PB0                       09200000
         BO    GETPB+4             YES- PROCESS PB0, REGP=0             09220000
GETPB    LA    REGP,1(0,REGP)      INCREASE PBN                         09240000
         LR    REGB,REGP                                                09260000
         SLA   REGB,2                                                   09280000
         L     AIB,ATABAD               GET ADDRESS OF NEW BLOCK        09300000
         L     AIB,0(REGB,AIB)          VIA ATAB+ 4 TIMES PBN           09320000
         MVC   LENCOUNT(2),0(AIB)       GET LENGTH OF THE BLOCK         09340000
         LH    REGB,LENCOUNT                                            09360000
         LA    REGB,0(REGB,AIB)         GET END OF BLOCK                09380000
         ST    REGB,AITAB          STORE END OF IT                      09400000
         BAL   REGB,PRINTITB       PRINT A BLANK LINE                   09420000
         LR    REGD,REGP           CONVERT PBN                          09440000
         BAL   REGB,CONVERT                                             09460000
         MVC   0(3,REGI),SAVE+1    NEW PBN                              09480000
         IC    REGD,PBTAB1(REGP)   CONVERT SURROUNDING PBN              09500000
         BAL   REGB,CONVERT                                             09520000
         MVC   10(3,REGI),SAVE+1   SURROUNDING PBN                      09540000
         MVC   SCSAVE(2),6(AIB)    CONVERT SC COUNTER TO DECIMAL        09560000
         LH    REGB,SCSAVE                                              09580000
         CVD   REGB,DOUBLE    STARTING SC OF BLOCK IS INSERTED          09600000
         UNPK  4(5,REGI),DOUBLE(8)                                      09620000
         MVZ   8(1,REGI),7(REGI)                                        09640000
         CLC   LENCOUNT(2),ELEVEN    Q. EMPTY BLOCK                     09660000
         BNE   *+12               NO                                    09680000
         BAL   REGB,PRINTITB      FOR AN EMPTY BLOCK PRINT              09700000
         B     ENDBLOCK            ONLY THE BLOCK NUMBERS               09720000
         SR    REGC,REGC                                                09740000
         SPACE 2                                                        09760000
*****   GETNVAR  *****                                                  09780000
*                   LOOPS THROUGH BLOCK TO GET THE CURRENT LOWEST       09800000
*                        VAR.                                           09820000
*                   EXITS TO ENDBLOCK WHEN ALL VAR. IN THE BLOCK HAVE   09840000
*                        BEEN PROCESSED, OTHERWISE TO TESTVAR           09860000
         SPACE 2                                                        09880000
GETNVAR  LA    RAID,11(0,AIB)           GET FIRST VAR. AFTER HEADING    09900000
         LR    REGY,RAID                                                09920000
         C     RAID,AITAB               Q. ALL VAR. PROCESSED           09940000
         BE    ENDBLOCK                 YES                             09960000
         CLI   5(RAID),X'2B'            Q. HEAD OR CONTINUATION LINE    09980000
         BE    ENDVAR2                                                  10000000
TESTNXT  LA    REGY,11(0,REGY)          GET NEXT VAR.                   10020000
         C     REGY,AITAB               Q. ALL VAR. COMPARED            10040000
         BE    TESTVAR                                                  10060000
         CLI   5(REGY),X'2B'            Q. HEAD OR CONTINUATION LINE    10080000
         BE    TESTNXT                  YES- SKIP THAT LINE             10100000
         CLC   0(6,RAID),0(REGY)        Q. COMPARE CURRENT LOWEST - NEW 10120000
         BL    TESTNXT                  CURRENT LOWEST STILL LOW        10140000
         LR    RAID,REGY                NO- SHIFT RAID TO NEW           10160000
         B     TESTNXT                                                  10180000
         SPACE 2                                                        10200000
*****   TESTVAR  *****                                                  10220000
*                   CHECKS THE INTERNAL NAME TO FIND TYPE AND MOVES     10240000
*                        CHARACTERISTICS TO WORKAREA                    10260000
         SPACE 2                                                        10280000
TESTVAR  TM    6(RAID),X'91'      Q. ALL PURPOSE IDENTIFIER             10300000
         BO    ENDVAR             YES                                   10320000
         TM    7(RAID),X'03'       Q. TYPE                              10340000
         BO    BOL                 TYPE=BOOLEAN                         10360000
         BZ    BOL+4               NOT TYPE                             10380000
         TM    7(RAID),X'01'      Q.INTEGER OR REAL                     10400000
         BZ    *+12                                                     10420000
         MVI   WORK+7,C'I'         INTEGER                              10440000
         B     BOL+4                                                    10460000
         MVI   WORK+7,C'R'         REAL                                 10480000
         B     BOL+4                                                    10500000
BOL      MVI   WORK+7,C'B'         BOOLEAN                              10520000
         TM    7(RAID),X'0C'                                            10540000
         BZ    TESTPROC                                                 10560000
         BO    SWITCH                                                   10580000
         TM    7(RAID),X'08'       Q. ARRAY OR LABEL                    10600000
         BZ    ARRAY                                                    10620000
         MVI   WORK+8,C'L'         LABEL                                10640000
TESTPROC TM    7(RAID),X'C0'                                            10660000
         BO    PROCEDUR                                                 10680000
         BZ    FORMAL                                                   10700000
         TM    7(RAID),X'40'                                            10720000
         BZ    FORMAL                                                   10740000
         MVI   WORK+11,C'C'        CODE PROCEDURE                       10760000
         B     PROCEDUR                                                 10780000
FORMAL   TM    7(RAID),X'30'       Q. SPECIFIED IDENTIFIER              10800000
         BO    ENDVAR                                                   10820000
         BZ    ENDVAR                                                   10840000
         NI    BITS1,PROCOFF       RESET PROCEDURE BIT                  10860000
         TM    6(RAID),X'01'                                            10880000
         BZ    *+8                                                      10900000
         MVI   WORK+8,C'T'         STRING                               10920000
         TM    7(RAID),X'10'       Q. NAME OR VALUE CALL                10940000
         BZ    *+12                                                     10960000
         MVI   WORK+10,C'N'        NAME                                 10980000
         B     ENDVAR                                                   11000000
         MVI   WORK+10,C'V'        VALUE                                11020000
         B     ENDVAR                                                   11040000
SWITCH   MVI   WORK+8,C'S'             SWITCH                    A28230 11060019
         B     CONVERT2            CONVERT NR. OF COMPONENTS            11080000
PROCEDUR MVI   WORK+9,C'P'         PROCEDURE                            11100000
         OI    BITS1,PROCBIT       SET PROCEDURE BIT                    11120000
         B     CONVERT2            CONVERT NR. OF PARAMETERS            11140000
ARRAY    MVI   WORK+9,C'A'         ARRAY                                11160000
         SPACE 2                                                        11180000
*****   CONVERT2 *****                                                  11200000
*                   ENTERED FOR PROCEDURE, ARRAY AND SWITCH CONVERTS    11220000
*                        THE NUMBER OF PARAMETERS, DIMENSIONS OR        11240000
*                        COMPONENTS TO DECIMAL FORM AND PUTS IT IN      11260000
*                        WORK                                           11280000
*                   FOR ARRAY OR SWITCH THE COUNTER IS FIRST            11300000
*                        INCREASED BY ONE TO GET THE REAL VALUE         11320000
         SPACE 2                                                        11340000
CONVERT2 TM    7(RAID),X'30'                                            11360000
         BM    FORMAL+12                                                11380000
         IC    REGD,9(0,RAID)                                           11400000
         SRA   REGD,4              SWITCH OR PROCEDURE                  11420000
         TM    BITS1,PROCBIT     TEST IF PROC PARAMETERS                11440000
         BO    *+8                 YES                                  11460000
         LA    REGD,1(0,REGD)      NO- INCREASE DIM COUNTER             11480000
         NI    BITS1,PROCOFF       TO GIVE CORRECT VALUE                11500000
         BAL   REGB,CONVERT             CONVERT IT TO DECIMAL           11520000
         MVC   WORK+13(2),SAVE+2   AND MOVE IT OUT                      11540000
         B     FORMAL                                                   11560000
         SPACE 2                                                        11580000
*****   CONVERT  *****                                                  11600000
*                   CONVERTS FROM HEXADECIMAL TO DECIMAL                11620000
*                   USED FOR LN, DISP AND PBN TO BE WRITEN OUT          11640000
         SPACE 2                                                        11660000
CONVERT  CVD   REGD,DOUBLE         CONVERT TO DECIMAL                   11680000
         UNPK  SAVE(4),DOUBLE+5(3)      UNPACK AND                      11700000
         MVZ   SAVE+3(1),SAVE+2         CLEAR SIGN                      11720000
         BCR   15,REGB                  RETURN                          11740000
         SPACE 2                                                        11760000
*****   PRINTITB *****                                                  11780000
*                   PRINTS A LINE, SAVES NEW PRINTAREA ADDRESS, RESETS  11800000
*                        REGC, RETURNS                                  11820000
         SPACE 2                                                        11840000
PRINTITB STM   14,15,SAVE1                                              11860000
         L     15,PRTRTADD         PRINT A RECORD                       11880000
         BALR  14,15                                                    11900000
         ST    REGI,APRNTAR        SAVE ADD. OF NEXT PRINT AREA         11920000
         LM    14,15,SAVE1                                              11940000
         SR    REGC,REGC           RESET REGC                           11960000
         BCR   15,REGB             RETURN                               11980000
         SPACE 2                                                        12000000
*****   ENDVAR   *****                                                  12020000
*                   MOVES EXTERNAL NAME TO WORK, TRANSLATES IT          12040000
*                   CONVERTS LN OR DISP AND MOVES THAT TO WORK          12060000
*                   MOVES WORK TO CURRENT PRINTAREA WITH HELP OF AN     12080000
*                        EXECUTET MOVE                                  12100000
*                   INCREASES REGC AND CHECKS IF ONE LINE HAS BEEN      12120000
*                        FILLED UP. IN THAT CASE - PRINTS THAT LINE     12140000
*                   SHIFTS AWAY THE NOW PROCESSED VAR. AND STORES THE   12160000
*                        NEW ENDING ADDRESS OF THE BLOCK IN AITAB       12180000
*                   RETURNS TO PROCESS NEXT VAR.                        12200000
         SPACE 2                                                        12220000
ENDVAR   MVC   WORK(6),0(RAID)     MOVE EXTERNAL NAME                   12240000
         TR    WORK(6),TRTAB                                            12260000
         MVC   SAVE2+1(1),10(RAID) MOVE                                 12280000
         MVN   SAVE2(1),9(RAID)    AND                                  12300000
         UNPK  SAVE3(5),SAVE2(3)        CONVERT DISP. OR LABELNUMBER    12320000
         TR    SAVE3+1(3),TAB-X'EF'     TO BE WRITTEN OUT               12340000
         MVC   WORK+16(3),SAVE3+1                                       12360000
         EX    REG0,MOVEVAR(REGC)  MOVE OUT WORK TO PRINTAREA           12380000
         MVI   WORK,C' '          CLEAR WORKAREA                        12400000
         MVC   WORK+1(29),WORK                                          12420000
         LA    REGC,8(0,REGC)                                           12440000
         C     REGC,TWOFOUR        Q. TIME TO PRINT                     12460000
         BNE   *+8                 NO                                   12480000
         BAL   REGB,PRINTITB       YES- CALL FOR PRINTROUTINE           12500000
ENDVAR2  L     REGY,AITAB                                               12520000
         LA    REGB,12(0,RAID)          LEN. TO MOVE ITAB UP TO         12540000
         C     REGB,AITAB               Q. NOTHING TO MOVE              12560000
         BNH   *+12                                                     12580000
         ST    RAID,AITAB          STOREADD. OF CURRENT AS END ADD.     12600000
         B     GETNVAR                                                  12620000
         SR    REGY,REGB           CALCULATE NEW END ADDRESS OF THE     12640000
         LA    REGB,1(REGY,RAID)   BLOCKAND STORE IT IN AITAB           12660000
         ST    REGB,AITAB                                               12680000
COMPARE  C     REGY,D256                                                12700000
         BNH   EX1                                                      12720000
         MVC   0(256,RAID),11(RAID)     TRANSFER A 256 BYTE SECTION     12740000
         LA    RAID,256(0,RAID)         OF THE BLOCK AT THE TIME        12760000
         S     REGY,D256                                                12780000
         B     COMPARE                                                  12800000
EX1      EX    REGY,MOVEITAB            MOVE LAST PARTIAL SECTION       12820000
         B     GETNVAR                                                  12840000
         SPACE 2                                                        12860000
*****   ENDBLOCK *****                                                  12880000
*                   PRINTS LAST LINE OF BLOCK, IF NEEDED                12900000
*                   EXITS TO GETPB IF ANY BLOCK LEFT TO BE PROCESSED    12920000
*                   OTHERWISE A FREEMAIN IS DONE AND IEX21 IS LINKED    12940000
*                        TO                                             12960000
         SPACE 2                                                        12980000
ENDBLOCK C     REGC,ZERO           Q VAR LEFT TO BE WRITTEN OUT         13000000
         BE    *+8                                                      13020000
         BAL   REGB,PRINTITB                                            13040000
         LA    REGB,1(0,REGP)                                           13060000
         CH    REGB,PBN            Q ALL BLOCKS PROCESSED               13080000
         BNH   GETPB               NO- TAKE NEXT                        13100000
SLUT     L     REGI,ITAB20S        ITAB AREA                            13120000
         LA    REGI,1024(0,REGI)   AND ATAB AREA ARE MADE               13140000
         LR    REG0,REGI           FREEMAIN FOR                         13160000
         L     REGI,AREALOC                                             13180000
         FREEMAIN R,LV=(0),A=(1)                                        13200000
SLUT2    XCTL  EP=IEX21000                                              13220000
HDING1   DC    C'IDENTIFIER TABLE'                                      13240000
HEAD1    DC    CL90'PBN SC    PBN      NAME   TYPE  DM DSP       NAME  X13260000
                TYPE  DM DSP       NAME   TYPE  DM DSP'                 13280000
HEAD2    DC    CL90'          SURR                  PR LN              X13300000
                      PR LN                     PR LN '                 13320000
SCSAVE   DS    H                  SAVE SEMICOLON COUNTER                13340000
D256     DC    F'256'             USED BY MOVE LOOP                     13360000
SAVE2    DC    C'000'             USED FOR CONVERTION                   13380000
SAVE3    DC    5X'EF'                                                   13400000
DOUBLE   DC    D'0'                                                     13420000
MOVEITAB MVC   0(1,RAID),11(RAID)     USED BY ENDVAR                    13440000
WORK     DC    30C' '        USED TO BUILD PRINT REC.                   13460000
FOURK    DC    F'4095'            STORAGE ALLOCATION MAXIMUM            13480000
MOVEVAR  MVC   19(27,REGI),WORK     USED TO SORT REC. TO BE PRINTED     13500000
         CNOP  0,4                                                      13520000
         MVC   45(27,REGI),WORK                                         13540000
         CNOP  0,4                                                      13560000
         MVC   71(19,REGI),WORK                                         13580000
TWOFOUR  DC    F'24'              USED BY ENDVAR                        13600000
C        DC    H'8'      INCREASE VALUE DURING STORAGE ALLOCATION       13620000
*                            USED TO TRANSLATE FROM INTERNAL            13640000
*                            TO EBCDIC CODE                             13660000
TRTAB    DS    0CL90                                                    13680000
         DC    C' '                                                     13700000
         DC    47C')'                                                   13720000
         DC    C'0123456789'                                            13740000
         DC    6C')'                                                    13760000
         DC    C'ABCDEFGHIJKLMNOPQRSTUVWXYZ'                            13780000
TAB      DC    C' 0123456789ABCDEF'    FOR PRINTABLE HEXADECIMAL        13800000
ELEVEN   DC    X'000B'                                                  13820000
WORKAREA DSECT                                                          13840000
         COPY  WORKAREA                                                 13860000
KOPOOL   DS    F                  ZERO CONSTANT                         13880000
ZERO     EQU   KOPOOL                                                   13900000
SAVE     DS    F                                                        13920000
SAVE1    DS    4F                                                       13940000
APBTAB2  DS    A                  START ADD. OF PBTAB2                  13960000
ATABAD   DS    A                  START ADD. OF ATAB                    13980000
DPC      DS    F                  SAVE AREAS FOR DP, WP, HP AND BP      14000000
WPC      DS    F                                                        14020000
HPC      DS    F                                                        14040000
BPC      DS    F                                                        14060000
AITAB    DS    F                  ITAB ADDRESS                          14080000
APRNTAR  DS    A                  ADDRESS OF CURRENT PRINTAREA          14100000
AREALOC  DS    A                  ADDRESS OF GETMAIN POOL               14120000
SAVEPB   DS    F                  COUNTS NR. OF BLOCKS READ             14140000
LENCOUNT DS    H                  SAVES LENGTH OF BLOCK                 14160000
BITS1    DS    C                                                        14180000
PROCBIT  EQU   X'02'              PROCEDURE IS PROCESSED                14200000
PROCOFF  EQU   X'FD'                                                    14220000
         END   IEX20000                                                 14240000
