F3E      TITLE 'ASSEMBLER F - PHASE IEUF3E'                             00020000
IEUF3E   START                                                          00040000
*TITLE 'IEUF3E' ... MACRO GENERATION ABORT PHASE                      * 00100000
*          RELEASE 19 DELETIONS                                       * 00106018
*          RELEASE 20 DELETIONS                                       * 00108018
*                                                                200002 00109020
*          RELEASE 21 DELETIONS                                       * 00110018
* 001020-001040,001120-001200,032200-032800                      A45817 00120021
*                                                                     * 00122018
*STATUS CHANGE LEVEL 005                                                00124020
*                                                                     * 00126018
*FUNCTION/OPERATION-                                                  * 00140000
*   IEUF3E COPIES THE SOURCE STATEMENT AND ERROR RECORDS FROM SYSUT1  * 00160000
*   TO SYSUT2.  THIS CAUSES THE ASSEMBLER PHASES JUST TO LIST THE     * 00180000
*   PROGRAM AND ERRORS.  THIS ROUTINE IS CALLED BY IEUF2 ONLY WHEN THE* 00200000
*   ABORT CASE ARISE.  ABORT CONDITIONS CAN BE CAUSED BY THE FOLLOWING* 00220000
*                                                                     * 00240000
*        GLOBAL DICTIONARY FILLS UP.                                  * 00260000
*        LOCAL DICTIONARY EXCEEDS 64K BYTES ON THE OVERFLOW FILE      * 00280000
*             OR IN CORE.                                             * 00300000
*        THE SUBSETTING AREA IS TOO SMALL.                            * 00320000
*ENTRY POINT- IEUF3E                                                  * 00340000
*   CALLED VIA-                                                       * 00360000
*        XCTL  EP=IEUF3E                                              * 00380000
*INPUT-                                                               * 00400000
*   SYSUT1- EDITED TEXT AND ASSEMBLY STATEMENTS.                      * 00420000
*   REGISTER 13- POINTS TO THE COMMON AREA THAT CONTAINS POINTERS     * 00440000
*                  TO NECESSARY TO PERFORM I/O FUNCTIONS.             * 00460000
*OUTPUT-                                                              * 00480000
*   SYSUT2- CONTAINS SOURCE RECORDS (TYPE 08), ERROR RECORDS (TYPE 13)* 00500000
*                  AND A GENERATED END RECORD (TYPE 10).              * 00520000
*   REGISTER 2- IS SET TO THE BLOCKSIZE OF THE OUTPUT FILE            * 00540000
*EXTERNAL ROUTINES-                                                   * 00560000
*   MACGEN- USED TO PERFORM ALL I/O FUNCTIONS.                        * 00580000
*EXIT- RETURN TO MACGEN VIA-                                          * 00600000
*        L     R14,RETURN                                             * 00620000
*        BR    R14                                                    * 00640000
*TABLES/WORKAREAS-                                                    * 00660000
*   STTYPE- BRNACH TABLE FOR TYPE OF RECORD                           * 00680000
*   WRBUF1 AND WRBUF2- OUTPUT BUFFERS                                 * 00700000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 00720000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 00740000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 00760000
*NOTES -                                                         200002 00766020
*   MAINTENANCEAREA IS SET ASIDE IN LOC MAINT FOR THIS MODULE.   200002 00772020
         SPACE 3                                                        00780000
*                        REGISTER USAGE                                 00800000
R0       EQU   0                        REGISTER - 0                    00820000
R1       EQU   1                                 - 1                    00840000
BASE1    EQU   3                        FIRST BASE REGISTER             00860000
BASE2    EQU   4                        SECOND BASE REGISTER            00880000
COM      EQU   13                       COMMON BASE REGISTER            00900000
GR2      EQU   2                        GENERAL REGISTER - 2            00920000
GR6      EQU   6                                         - 6            00940000
GR7      EQU   7                                         - 7            00960000
GR11     EQU   11                                        - 11           00980000
GR12     EQU   12                                        - 12           01000000
PTCH     EQU   8                        ADDRESS OF PATCH ROUTINE        01020000
WRLENG   EQU   5                        RECORD LENGTH                   01040000
LOBYTE   EQU   5                        LOW BYTE REGISTER               01060000
INDEX    EQU   8                        WORK REG. - MUST BE EVEN        01080000
WORK     EQU   9                        WORK REG. - MUST BE ODD         01100000
RTN      EQU   9                        RETURN LINKAGE - INTERNAL SUBR. 01120000
INPPTR   EQU   10                       INPUT AREA POINTER              01140000
ENTPTR   EQU   11                       POINTER TO END OF RECORD        01160000
ENTRY    EQU   14                       ENTRY ADDRESS TO I/O ROUTINES   01180000
EXIT     EQU   15                       EXIT ADDRESS OF I/O ROUTINES    01200000
*                        I/O REGISTER USAGE                             01220000
AVPOS    EQU   6                        OUTPUT BUFFER SIZE              01240000
BUFPTR   EQU   7                        CURRENT BUFFER                  01260000
RLADR    EQU   8                        RELATIVE ADDRESS IN CURRENT BUF 01280000
TRANZ    EQU   10                       RETURN REGISTER                 01300000
         EJECT                                                          01320000
ZACINA   BALR  BASE1,0                  SET UP FIRST BASE REGISTER      01340000
         USING *,BASE1,BASE2            BASE REGISTERS                  01360000
         USING COMMON,COM               COMMON BASE REGISTER            01380000
         LA    BASE2,*+4095             SET BASE 1 AND BASE 2           01400000
         LA    BASE2,1(BASE2)           4062 APART                      01420000
*                                                                       01520000
*    INITIALIZATION FOR OUTPUT BUFFERS                                  01540000
         L     GR2,OBSIZ                OUTPUT BUFFER SIZE              01560000
         ST    GR2,WRREG                STORE OUTPUT BUFFER SIZE        01580000
         STH   GR2,NEXBF2+4                                             01600000
         LA    GR7,WRBUF1               OUTPUT 1 ADDRESS                01620000
         AR    GR7,GR2                  GET TO END OF OUTPUT 1          01640000
         SH    GR7,TWOH                 GET TO THE LAST TWO BYTES       01660000
         MVC   0(2,GR7),LOW2            MOVE 'FFFF' TO END OF BUFFER    01680000
         L     GR6,NEXBF1               ADDR. OF OUTPUT BUFFER 2        01700000
         AR    GR6,GR2                  GET TO END OF OUTPUT 2          01720000
         SH    GR6,TWOH                 GET TO THE LAST TWO BYTES       01740000
         MVC   0(2,GR6),LOW2            MOVE 'FFFF4 TO END OF BUFFER    01760000
*                                                                       01780000
*    INITIALIZATION FOR INPUT BUFFERS                                   01800000
         L     GR2,INPADR               GET THE ADDRESS OF THE INPUT BF 01820000
         MVI   0(GR2),X'FE'             INITIALIZE INPUT BUFFER         01840000
         L     GR6,INPLEN               GET LENGTH OF INPUT BUFFER      01860000
         LR    GR7,GR2                                                  01880000
         AR    GR7,GR6                  ADD INPUT LENGTH                01900000
         ST    GR7,INPUT3               ALTERNATE INPUT AREA ADDR..     01920000
         ST    GR2,INPCON               INPUT ADDRESS                   01940000
         STH   GR6,INPCON+4              SIZE OF INPUT                  01960000
         LA    GR2,BLKHDR(0,GR2)        GO BEYOND THE HEADER            01980000
         ST    GR2,INPBLK               INPUT ADDR. + BLKHDR            02000000
         L     INPPTR,INPADR            INITIALIZE INPPTR               02020000
*                                                                       02040000
START6   BAL   RTN,READIN               READ IN RECORD                  02060000
BYREAD   SR    LOBYTE,LOBYTE            START LOW BYTES AT THE BEGIN    02080000
         STC   LOBYTE,MISWIT             INITIALIZE                     02100000
*                                                                       02120000
*    COMPUTED GO TO ON STATEMENT TYPE                                   02140000
*                                                                       02160000
         MVC   SAVRL(2),1(INPPTR)       SAVE R/L                        02180000
         ST    INPPTR,BEGADR            SAVE BEG. ADDR. OF RECORD       02200000
         LA    ENTPTR,1(0,INPPTR)       SET UP INPUT POINTER            02220000
         IC    LOBYTE,0(0,INPPTR)       FETCH STATEMENT TYPE            02240000
         STC   LOBYTE,STATYP            STORE STATEMENT FLAG            02260000
         LA    INPPTR,FLGLEN(0,INPPTR)  GET BY FLAG                     02280000
         AR    LOBYTE,LOBYTE            DOUBLE TYPE FOR STTYPE TABLE    02300000
         LH    WORK,STTYPE(LOBYTE)      GET THE ADDRESS                 02320000
         STH   WORK,GOTO+2              STORE T IN THE BRANCH           02340000
         EX    0,GOTO                   EXECUTE THE BRANCH              02360000
*                                                                       02380000
*   BRANCH TABLE FOR TYPE OF RECORD                                     02400000
*                                                                       02420000
STTYPE   DC    S(PARAM)                 00 MACHINE INSTR.               02440000
         DC    S(PARAM)                 01 CSECT, DSECT, ETC            02460000
         DC    S(PARAM)                 02 AGO STATEMENT                02480000
         DC    S(PARAM)                 03 AIF STATEMENT                02500000
         DC    S(PARAM)                 04 SET STATEMENT                02520000
         DC    S(PARAM)                 05 MACRO INSTR.                 02540000
         DS    H                        06 PROTOTYPE STATEMENT          02560000
         DC    S(PARAM)                 07 MEND OR MEXIT                02580000
         DC    S(SOURCE)                08 SOURCE                       02600000
         DC    S(PARAM)                 09 BYPASS STATEMENT             02620000
         DC    S(ENDST)                 10 END OF ASSEM. STATMENT       02640000
         DC    S(PARAM)                 11 PARAMETER RECORD             02660000
         DC    S(PARAM)                 12 END OF M-I RECORD            02680000
         DC    S(SOURCE)                13 ERROR STATEMENT              02700000
*                                                                       02720000
*  PROCESS END CARD                                                     02740000
*                                                                       02760000
ENDST    LA    WRLENG,16                LENGTH OF GENERATED 'END'       02780000
         LA    ENTPTR,GENEND            ADDRESS OF GENERATED END        02800000
         BAL   INDEX,WRTRL              WRITE OUT GENERATED END         02820000
         BAL   INDEX,WREND              DUMP OUTPUT BUFFERS             02840000
         L     GR6,RETURN               RETURN ADDRESS TO MAC           02860000
*                                                                       02880000
*        LOAD REGISTER 2 WITH TEXT BLOCKSIZE TO BE PASSED TO THE        02900000
*         ASSEMBLER PHASE 'RTSEGA'                                      02920000
*                                                                       02940000
         L     GR2,OBSIZ                LOAD RECORD SIZE                02960000
         LR    GR11,EXIT                STORE USING REG.                02980000
         LR    GR12,ENTRY               STORE USING REG.                03000000
*                                                                       03020000
*    SETUP DCB ADDRESSES FOR TCLOSE                                     03040000
*                                                                       03060000
         MVC   TC+5(3),ADCBU1+1         ADDRESS OF UT1                  03080000
         MVC   TC+9(3),ADCBU2+1                   UT2                   03100000
         MVC   TC+13(3),ADCBU3+1                  UT3                   03120000
*                                                                       03140000
*                                                                       03160000
*        RELEASE CORE OBTAINED FOR G.D., COMMON, BUFFERS                03180000
*                                                                       03200000
         L     R1,INPUT3                CALCULATE AMOUNT         A45817 03220021
         A     R1,INPLEN                        OF CORE          A45817 03260021
         LA    R0,8(R1)                 TO FREE ALL CORE         A45817 03270021
         SR    R0,COM                   AMOUNT OF CORE TO BE FREED      03280000
         LR    R1,COM                   BEG. ADDR TO BE FREED    A45817 03290021
         LA    COM,WRBUF1               WORK AREA IN CORE NOT FREED     03300000
         FREEMAIN  R,LV=(0),A=(1)       FREE STORAGE FOR CLOSE          03320000
*                                                                       03340000
*        REWIND UTILITY FILES                                           03360000
*                                                                       03380000
         LR    EXIT,GR11                RESTORE USING REG.              03400000
         LR    ENTRY,GR12               RESTORE USING REG.              03420000
TC       CLOSE (0,REREAD,0,REREAD,0,REREAD),TYPE=T                      03440000
*                                                                       03460000
*        RETURN TO 'MACGEN'                                             03480000
*                                                                       03500000
         SR    EXIT,EXIT                ZERO EXIT CODE                  03520000
         LR    ENTRY,GR6                LOAD UP EXIT ADDRESS            03540000
         RETURN                                                         03560000
*                                                                       03580000
*  SOURCE CARD OR ERROR STATEMENT -- WRITE IT OUT                       03600000
*                                                                       03620000
SOURCE   BAL   RTN,OUTP                 WRITE SOURCE RECORD             03640000
*                                                                       03660000
*   OTHER THAN SOURCE OR ERROR STATEMENT -- DONT WRITE OUT              03680000
*                                                                       03700000
PARAM    L     INPPTR,BEGADR            GET BY STATEMENT                03720000
         AH    INPPTR,SAVRL                                             03740000
         B     START6                   GO TO NEXT RECORD               03760000
*                                                                       03780000
*  OUTPUT ROUTINE                                                       03800000
*                                                                       03820000
OUTP     LH    WRLENG,SAVRL                                             03840000
         BCTR  WRLENG,0                 GET ACTUAL LENGTH               03860000
         BAL   INDEX,WRTRL              WRITE OUT LOGICAL RECORD        03880000
         BR    RTN                      RETURN                          03900000
*                                                                       03920000
*   ****  READIN  ****                                                  03940000
*                                                                       03960000
READIN   CLI   0(INPPTR),EOB            ARE WE AT END OF BLOCK          03980000
         BCR   7,RTN                    NO, RETURN.  CONTINUE IN THIS 1 04000000
         LA    R0,INPCON                YES, GET ADDRESS IN INPUT AREA  04020000
         LH    R1,FILE                  FETCH FILE NO.                  04040000
         L     ENTRY,MREAD              GET ADDRESS OF READ ROUTINE     04060000
         BALR  EXIT,ENTRY               CALL READ                       04080000
         L     ENTRY,MCHECK             LOAD ADDRESS OF CHECK ROUTINE   04100000
         BALR  EXIT,ENTRY               CHECK RECORD JUST READ          04120000
         L     INPPTR,INPBLK            SET UP POINTER TO BEGINNING     04140000
         BR    RTN                      EXIT                            04160000
*                                                                       04180000
*   CHECK ERROR BITS ROUTINE                                            04200000
*                                                                       04220000
*                                                                       04240000
FITST    CR    AVPOS,WRLENG        WILL TEXT FIT.                       04260000
         BC    10,WILFIT                BRANCH IF YES                   04280000
         LR    WORK,AVPOS                                               04300000
         BAL   TRANZ,TXTMUV        GO MOVE IN TEXT THAT WILL FIT.       04320000
         SR    WRLENG,AVPOS        LENGTH REMAINING.                    04340000
         AR    ENTPTR,AVPOS        ADDRESS OF REMAINDER.                04360000
SBB      OI    2(RLADR),8          TURN ON BREAK BIT.                   04380000
         BAL   TRANZ,RYTO               WRITE                           04400000
         LA    WORK,3                                                   04420000
         STH   WORK,RLCNT          REC LENGTH.                          04440000
         L     AVPOS,OBSIZ         GET BUFFER SIZE                      04460000
         SR    AVPOS,WORK          SET CORRECT NBR OF AVAIL POS LEFT    04480000
         MVI   2(BUFPTR),0         ZERO 3RD BYTE.                       04500000
         LR    RLADR,BUFPTR        GET NEW RL ADD.                      04520000
         LA    BUFPTR,3(0,BUFPTR)       AVAIL POS IN BUFFER.            04540000
         B     FITST                                                    04560000
WILFIT   LR    WORK,WRLENG                                              04580000
         BAL   TRANZ,TXTMUV        MOVE IN TEXT.                        04600000
MOSDUN   SR    AVPOS,WRLENG        AVAIL POS LEFT.                      04620000
         AR    BUFPTR,WRLENG       NEXT AVAIL POS.                      04640000
         TM    MISWIT,X'01'        SEE IF OVER MAX                      04660000
         BZ    GOBAK               BRANCH IF NOT                        04680000
         NI    MISWIT,X'FE'        RESET SWITCH                         04700000
         BCTR  BUFPTR,0            GET LAST POS OF REC                  04720000
         MVI   0(BUFPTR),X'32'     PUT BLANK AS LAST CHARACTER          04740000
         LA    BUFPTR,1(0,BUFPTR)  RESET POINTER                        04760000
*                                                                       04780000
*   EXIT FROM I/O ROUTINE                                               04800000
*                                                                       04820000
GOBAK    STM AVPOS,RLADR,WRREG          SAVE I/O REGISTERS              04840000
         LM    WRLENG,TRANZ,REGIST      RESTORE WORK REGISTERS          04860000
         BR    INDEX               RETURN TO CALLING ROUTINE.           04880000
*                                                                       04900000
*   MOVE TEXT INTO OUTPUT AREA                                          04920000
*                                                                       04940000
TXTMUV   BCTR  WORK,0              REDUCE COUNT FOR MOVE.               04960000
         EX    WORK,EXMOVE         MOVE IN TEXT THAT WILL FIT.          04980000
         LA    WORK,1(0,WORK)                                           05000000
         AH    WORK,RLCNT          UPDATE REC LENGTH COUNT.             05020000
         STH   WORK,RLCNT               SAVE RECORD LENGTH COUNT        05040000
         MVC   0(2,RLADR),RLCNT    PUT RL INTO REC.                     05060000
         BR    TRANZ                    EXIT                            05080000
*                                                                       05100000
*  ENTRY POINT FOR START OF RECORD.                                     05120000
*                                                                       05140000
WRTRL    STM   WRLENG,TRANZ,REGIST      SAVE WORK REGISTERS             05160000
         LM    AVPOS,RLADR,WRREG        LOAD I/O R%GISTERS              05180000
         SR    WORK,WORK           CLEAR REG                            05200000
         STH   WORK,CURSIZ         ZERO OUT COUNT FOR NEW REC           05220000
         BAL   TRANZ,SIZET         GO CHECK MAX SIZE OF OUTPUT REC      05240000
         CH    AVPOS,THREEH        IF 3 POS AVAIL,                      05260000
         BC    10,RUMAV             GO USE.                             05280000
*                                                                       05300000
* OUTPUT                                                                05320000
*                                                                       05340000
         BAL   TRANZ,RYTO               GO WRITE OUT                    05360000
*                                                                       05380000
RUMAV    SR    WORK,WORK           CLEAR REG                            05400000
         STH   WORK,RLCNT          SET RL COUNT TO 0.                   05420000
         LR    RLADR,BUFPTR        SET NEW RL ADD.                      05440000
         B     FITST                    CHECK ERROR BITS                05460000
*                                                                       05480000
*   CHECK LAST WRITE, WRITE THIS BUFFER, AND SWITCH BUFFERS             05500000
*                                                                       05520000
RYTO     LA    R1,4                     SYSUT2                          05540000
         L     ENTRY,MCHECK             GET ADDRESS OF CHECK ROUTINE    05560000
         BALR  EXIT,ENTRY               CHECK LPREVIOUSLY WRITTEN       05580000
         LA    R0,NEXBF2                                                05600000
         L     ENTRY,MWRITE             GET ADDRESS OF WRITE ROUTINE    05620000
         BALR  EXIT,ENTRY               WRITE OUT RECORD                05640000
         L     BUFPTR,NEXBF1            SWITCH BUFFERS                  05660000
         L     WORK,NEXBF2                                              05680000
         ST    WORK,NEXBF1                                              05700000
         ST    BUFPTR,NEXBF2                                            05720000
         L     AVPOS,OBSIZ         GET BUFFER SIZE                      05740000
         LA    WORK,0(AVPOS,BUFPTR)  TO END OF BUFFER                   05760000
         BCTR  WORK,0              BACK 2                               05780000
         BCTR  WORK,0              BACK 2                               05800000
         MVC   0(2,WORK),PADKAR         MOVE IN PADDING CHARACTERS      05820000
         BR    TRANZ                    EXIT                            05840000
*                                                                       05860000
*   ENTRY POINT FOR END OF FILE                                         05880000
*                                                                       05900000
WREND    STM   WRLENG,TRANZ,REGIST  SAVE REGISTERS                      05920000
         LM    AVPOS,RLADR,WRREG   LOAD ROUTINE VALUES                  05940000
         OI    2(RLADR),X'80'           SET LAST RECORD FLAG            05960000
         BAL   TRANZ,RYTO          OUTPUT CURRENT BUFFER                05980000
* ***                                                                   06000000
* THE NEXT FEW CARDS WILL EVENTUALLY BE REMOVED                         06020000
* ***                                                                   06040000
         MVI   0(BUFPTR),X'FF'                                          06060000
         BAL   TRANZ,RYTO          WRITE OUT EXTRA BUFFER               06080000
*                                                                       06100000
         LA    R1,4                     SYSUT2                          06120000
         L     ENTRY,MCHECK             GET ADDRESS OF CHECK ROUTINE    06140000
         BALR  EXIT,ENTRY          WAIT FOR LAST BUFFER TO BE WRITTEN   06160000
         LM    WRLENG,TRANZ,REGIST                                      06180000
         BR    INDEX               RETURN                               06200000
*                                                                       06220000
* *** CHECK MAXIMUM SIZE OF OUTPUT RECORD TO ASSEMBLER.                 06240000
*     IF OVER MAX, CHOP OFF AND FORGET EXTRA.                           06260000
*     SET RECORD LENGTH FOR MAXIMUM SIZE PLUS ONE BLANK,                06280000
*     WHICH IS ADDED.                                                   06300000
*                                                                       06320000
SIZET    CLC   CURSIZ(2),MAXSIZ    COMPARE CURRENT REC SIZE TO MAX      06340000
         BH    GOBAK               RETURN IMMED IF ALREADY OVER         06360000
         LR    WORK,WRLENG                                              06380000
         AH    WORK,CURSIZ         ADD OLD PARTIAL SUM TO NEW LENGTH    06400000
         STH   WORK,CURSIZ                                              06420000
         CH    WORK,MAXSIZ         CHECK AGAINST MAX                    06440000
         BCR   13,TRANZ            RETURN IF NOT OVER MAX               06460000
         SH    WORK,MAXSIZ                                              06480000
         SR    WRLENG,WORK         REDUCE OUTPUT COUNT                  06500000
         LA    WRLENG,1(0,WRLENG)  SET FOR 1 OVER MAX                   06520000
         LH    WORK,MAXSIZ         GET MAX SIZE                         06540000
         LA    WORK,1(0,WORK)                                           06560000
         STH   WORK,CURSIZ         SET CURRENT SIZE OVER MAX            06580000
         OI    MISWIT,X'01'        SET IND FOR OVER MAX                 06600000
         BR    TRANZ               RETURN                               06620000
*                                                                       06640000
EXMOVE   MVC   0(0,BUFPTR),0(ENTPTR)                                    06660000
*                                                                       06680000
EOB      EQU   X'FE'                    END OF BLOCK                    06700000
FLGLEN   EQU   10                       LENGTH OF FLAG                  06720000
BLKHDR   EQU   5                        TOTAL BLOCK HEADER              06740000
LOW2     DC    X'FFFFFFFC'              END OF BUFFER SIGNAL            06760000
TWOH     DC    H'2'                     HALF WORD BINARY 2              06780000
THREEH   DC    H'3'                                      3              06800000
PADKAR   DC    X'FFFFFFFC'              PADDING FOR END OF BUFFER       06820000
GENEND   DC    X'001040802100000000030E170D013200'                      06840000
*                                                                       06860000
         EJECT                                                          06880000
*                                                                       06900000
GOTO     B     0                        COMPUTED GO TO                  06920000
WRREG    DS    F                   OUTPUT BUFFER SIZE                   06940000
         DC    A(WRBUF1)           ADDRESS OF WRBUF1                    06960000
         DC    A(WRBUF1)           ADDRESS OF WRBUF1 AGAIN              06980000
NEXBF1   DC    A(WRBUF2)           ADDRESS OF WRBUF2                    07000000
NEXBF2   DC    A(WRBUF1)           ADDRESS OF WRBUF1                    07020000
         DS    H                   OUTPUT BUF SIZE - MUST FOLLOW NEXBF2 07040000
RLCNT    DC    H'0'                WORK AREA - HAS CURRENT REC LENGTH   07060000
MAXSIZ   DC    H'248'             MAX. SIZE  FOR ASSEMBLER REC          07080000
FILE     DC    H'0'                     INITIALIZE WITH SYSUT1          07100000
INPCON   DC    F'0'                     ADDRESS OF INPUT AREA           07120000
         DC    H'0'                     LENGTH OF INPUT AREA            07140000
DBLWRD   DS    3D                       SAVE AREA FOR WORK REGISTERS    07160000
REGIST   EQU   DBLWRD                   SAVE AREA FOR WORK REGISTERS    07180000
BEGADR   DS    F                        BEGINNING ADDRESS OF RECORD     07200000
INPBLK   DS    F                        WHERE RECORD STARTS             07220000
SAVRL    DS    H                        RECORD LENGTH                   07240000
STATYP   DS    C                        STATEMENT TYPE                  07260000
MISWIT   DS    C                        SWITCH USING BIT 7              07280000
*                                          0 = NOT OVER LENGTH,         07300000
*                                          1 = OVER MAXIMUM LENGTH      07320000
CURSIZ   DC    H'0'                CURRENT SIZE OF ASSEMBLER REC        07340000
PATCHH   DS    30F                      PATCH AREA                      07360000
WRBUF1   DS    4000C                    OUTPUT BUFFER 1                 07380000
WRBUF2   DS    4000C                    OUTPUT BUFFER 1                 07400000
*   THIS IS THE MAINTANANCEAREA FOR THIS MODULE                  200002 07406020
MAINT    DS    450C                                              200002 07412020
COMMON   DSECT                                                          07420000
*                                                                       07440000
*                                                                       07460000
         DS    26F                      O/S SAVE AREA                   07480000
GDP      DC    A(0)                     BEGINNING OF DICTIONARY         07500000
DEND     DC    A(0)                     END OF DICTIONARY               07520000
SEG      DC    A(2000)                  SIZE OD DICTIONARY SEGMENT      07540000
*                                                                       07560000
*                                                                       07580000
*        MACGEN RETURN ADDRESS - RETURN FROM PHASE F3                   07600000
RETURN   DC    F'0'                                                     07620000
*        I/O ENTRY POINT LIST                                           07640000
ENTPTS   EQU   *                                                        07660000
MREAD    DC    A(0)                     READ                            07680000
MWRITE   DC    A(0)                     WRITE                           07700000
MCHECK   DC    A(0)                     CHECK                           07720000
MNOTE    DC    A(0)                     NOTE                            07740000
MPNTR    DC    A(0)                     READ POINT                      07760000
MPNTW    DC    A(0)                     WRITE POINT                     07780000
MFIND    DC    A(0)                     FIND                            07800000
DCBTB    EQU   *                        DCB ADDRESS TABLE               07820000
ADCBU1   DC    A(0)                     SYSUT1                          07840000
ADCBU2   DC    A(0)                     SYSUT2                          07860000
ADCBU3   DC    A(0)                     SYSUT3                          07880000
ADCBIN   DC    A(0)                     SYSIN                           07900000
ADCBLB   DC    A(0)                     MACRO LIBRARY                   07920000
*        ADDRESS OF 'RESDNT' ENTRY POINT LIST - PASSED TO ASSEMBLER     07940000
INPADR   DS    F                        ADDR. OF INPUT AREA             07980000
INPUT3   DS    F                        ADDR. OF ALT. INPUT AREA        08000000
INPLEN   DS    F                        SIZE OF INPUT AREA              08020000
OBSIZ    DS    F                        SIZE OF OUTPUT 1 AREA           08040000
SAVUSE   DS    2F                                                       08060000
RESDNT   EQU   ENTPTS                                                   08080000
*                                                                       08100000
*    F3 I/O BUFFER INFORMATION                                          08120000
*                                                                       08140000
GDSTART  EQU   *                                                        08160000
         END   ZACINA                                                   08180000
