F7C      TITLE 'AC7MLC - F/7 MAIN LINE CONTROL '                        00020000
         ISEQ  73,80                                                    00040000
IEUF7C   START                                                          00060000
*          RELEASE 19 DELETIONS                                         00066000
*                                                                A27005 00066619
* 175800,189800                                                  A27018 00067219
*          RELEASE 20 DELETIONS                                         00068000
* 021600-022200,023200,207800                                      I000 00068520
* 158600,159400-159600                                             I004 00069020
* 029600-029800                                                  A31000 00069520
* 048400                                                         A32954 00069720
*          RELEASE 21 DELETIONS                                         00070000
* 139120                                                         A32990 00070421
* 000640-000650,000720-000780,048280-048440,117400               A45780 00072421
* 049600,050400                                                  A67476 00074421
AC7MLC   EQU   IEUF7C                                                   00080000
         SPACE                                                          00100000
         PRINT DATA,NOGEN                                               00120000
         FDIMEN                                                         00140000
         SPACE 2                                                        00160000
*TITLE   'IEUF7C'  F/7 MAIN LINE CONTROL                              * 00180000
*STATUS CHANGE LEVEL 009                                                00186021
*                                                                       00192020
* INCREMENTAL IMPROVEMENTS FOR RELEASE 20                               00198020
* I000 TSO IMPLEMENTATION                                               00204020
* I004 IMPLEMENTATION OF WXTRN                                          00210020
*FUNCTION/OPERATION-                                                  * 00220000
*   PROCESS 'EDITED TEXT RECORDS' WRITTEN BY IEUF3                    * 00240000
*   ADD APPENDED FIXED FIELD AND WORK BUCKETS (IF REQUIRED) TO EDITED * 00260000
*    TEXT RECORDS                                                     * 00280000
*   BUILD SYMBOL TABLE AND LITERAL TABLE                              * 00300000
*   BUILD EXTERNAL SYMBOL DICTIONARY (ESD)                            * 00320000
*   GENERATE CROSS-REFERENCE RECORDS                                  * 00340000
*   PROCESS LITERALS AND SELF-DEFINING TERMS IN EXPRESSIONS INVOLVING * 00360000
*    THE LOCATION COUNTER                                             * 00380000
*   MAINTAIN LOCATION COUNTER AND ASSIGN STORAGE LOCATIONS            * 00400000
*   DETECT AND LOG ERROR CONDITIONS                                   * 00420000
*   WRITE TEXT RECORDS FOR PROCESSING BY F8.                          * 00440000
*INPUT-                                                               * 00460000
*   REGISTER CRB- ADDRESS OF IEUF7C                                   * 00480000
*   REGISTER ACT- ADDRESS OF ASSEMBLER CONTROL TABLE                  * 00500000
*ENTRY POINT-                                                         * 00520000
*   IEUF7C                                                            * 00540000
*        CALLING SEQUENCE.                                            * 00560000
*        L     CRB,=A(IEUF7C)                                         * 00580000
*        BR    CRB                                                    * 00600000
*OUTPUT_ NONE                                                         * 00620000
*EXTERNAL ROUTINES-                                                   * 00640000
*     NAME     ACT NAME  FUNCTION                                     * 00660000
*   IEUF7N     CTESTR    GENERATE TESTRAN RECORD                      * 00680000
*   IEUF7D     CDCVAL    EVALUATE LITERALS                            * 00700000
*   IEUF7E     CEEVAL    EVALUATE EXPRESSIONS                         * 00720000
*   IEUF7L     CLOGER    ERROR LOGGING                                * 00740000
*   IEUF7I     CTXTIO    PROVIDE ACCESS TO SYSOUT, PUTLBT, AND PHCLS  * 00760000
*                        COMMON SUBROUTINES                           * 00780000
*   IEUF7S               MAINTAIN AND EXAMINE SYMBOL TABLE            * 00800000
*   IEUF7E               GENERATE ESD ENTRIES                         * 00820000
*EXIT_   BRANCH TO PHCLS (PHASE CLOSE) ROUTINE WITHIN IEUF7I.  PHCLS  * 00840000
*         TRANSFERS CONTROL TO IEUFI (INTERLUDE)                      * 00860000
*TABLES_ AOPGO2...COMPUTED GO-TO VALUES FOR ASSEMBLER OP-CODES, DURING* 00880000
*         ASSIGNMENT MODE                                             * 00900000
*        AOPGO3...COMPUTED GO-TO VALUES FOR ASSEMBLER OP-CODES, DURING* 00920000
*         SUBSTITUTION MODE                                           * 00940000
*        AOPGO2 AND AOPGO3 ARE INTERCHANGED WHEN THE ASSEMBLER MODE IS* 00960000
*         CHANGED.                                                    * 00980000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 01000000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 01020000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 01040000
         SPACE   2                                                      01060000
* BIT MASKS                                                             01080000
         SPACE                                                          01100000
BIT0     EQU   X'80'                    MASKS WHICH...                  01120000
BIT1     EQU   X'40'                    ARE...                          01140000
BIT2     EQU   X'20'                    USED TO...                      01160000
BIT3     EQU   X'10'                    ACCESS...                       01180000
BIT4     EQU   X'08'                    BITS WITHIN...                  01200000
BIT5     EQU   X'04'                    A BYTE...                       01220000
BIT6     EQU   X'02'                    BY A MEANINGFUL...              01240000
BIT7     EQU   X'01'                    NAME...                         01260000
SETWX    EQU   X'02'                    INDICATES WXTRN            I004 01266020
SETEXT   EQU   X'FD'                    PATTERN TO TURN OFF SETWX  I004 01272020
         EJECT                                                          01280000
*        ERRORS DETECTED BY F/7 MAIN-LINE CONTROL                       01300000
         SPACE 2                                                        01320000
ACER00   EQU   23                       MULTIPLY DEFINED NAME           01340000
ACER01   EQU   07                       LOCATION COUNTER WRAP-AROUND    01360000
ACER02   EQU   117                      OPSYN TABLE OVERFLOW      IEUN1 01370018
         SPACE                                                          01380000
*                                       CNOP                            01400000
ACER10   EQU   39                       ILLEGAL DELIMITER               01420000
ACER11   EQU   30                       ILLEGAL VALUE                   01440000
ACER12   EQU   25                       RELOCATABLE VALUE               01460000
         SPACE                                                          01480000
*                                       EQU                             01500000
ACER20   EQU   39                       ILLEGAL DELIMITER               01520000
ACER21   EQU   25                       COMPLEX RELOCATABLE VALUE       01540000
         SPACE                                                          01560000
*                                       EXTRN, ENTRY                    01580000
ACER30   EQU   39                       ILLEGAL DELIMITER               01600000
ACER31   EQU   18                       INVALID SYMBOL IN OPERAND       01620000
         SPACE                                                          01640000
*                                       TITLE                           01660000
ACER40   EQU   73                       NAME ON TITLE CARD AFTER FIRST  01680000
ACER41   EQU   16                       NAME FIELD EXCEEDS 4 CHARACTERS 01700000
ACER42   EQU   17                       OPERAND EXCEEDS 100 CHARACTERS  01720000
         SPACE                                                          01740000
*                                       PUNCH, TITLE, MNOTE             01760000
ACER50   EQU   84                       OPERAND NOT ENCLOSED IN QUOTES  01780000
ACER51   EQU   87                       UNPAIRED QUOTE OR AMPERSAND     01800000
         SPACE                                                          01820000
*                                       PUNCH                           01840000
ACER60   EQU   17                       OPERAND EXCEEDS 80 CHARACTERS   01860000
         SPACE                                                          01880000
*                                       MNOTE                           01900000
ACER70   EQU   37                       MNOTE STATEMENT                 01920000
ACER71   EQU   91                       SEVERITY CODE GR 255            01940000
ACER72   EQU   39                       ILLEGAL DELIMITER               01960000
ACER73   EQU   17                       OPERAND EXCEEDS 100 CHARACTERS  01980000
         SPACE                                                          02000000
*                                       LTORG                           02020000
ACER80   EQU   58                       DEFINED IN CSECT OR COM         02040000
         EJECT                                                          02060000
* AC0 -                                                                 02080000
         SPACE 2                                                        02100000
         USING AC7MLC,CRB                                               02120000
         SPACE                                                          02140000
         SPACE                                                          02240000
AC0      MVC   ACSYWB,CTZERO(ACT)       CLEAR SYMBOL W.B. POINTER       02260000
         MVC   ACFREE(4),CFREEP(ACT)    SAVE INITIAL FREE AREA POINTER  02280000
         SPACE                                                          02300000
         TM    CTTSTI(ACT),BIT0         CHECK TESTRAN OPTION       I000 02320020
         BO    AC01                     ON, LEAVE TESTRAN GATE OPEN     02340000
         OI    AC1+1,X'F0'              OFF, MODIFY PROGRAM TO BYPASS   02360000
         OI    QUIT0+1,X'F0'            TESTRAN ROUTINE                 02380000
         SPACE                                                          02400000
AC01     TM    CTXRFI(ACT),BIT6         CHECK X-REF OPTION              02420000
         BO    AC02                     ON, LEAVE X-REF GATE OPEN       02440000
         OI    MOP2+1,X'F0'             OFF, MODIFY PROGRAM TO BYPASS   02460000
         OI    AOP30+1,X'F0'                 TYPE 2 X-REF ROUTINE       02480000
         MVI   MOP1D+1,X'00'            MODIFY INSTRUCTION MOP1D  23749 02486018
*                                       NOT TO TURN ON XREF BIT   23749 02492018
         SPACE                                                          02500000
AC02     B     AC2                      BYPASS TESTRAN FIRST TIME       02520000
         SPACE 2                                                        02540000
*                                                                       02560000
         SPACE                                                          02580000
         ORG   AC0                                                      02600000
ACSYWB   DS    F                        SYMBOL W.B. PTR (SET BY EXT)    02620000
ACFREE   DS    F                        CFREEP (SAVED BY AC0)           02640000
ACLOC    DS    3C                       LOCATION COUNTER                02660000
ACSEQN   DS    3C                       SEQUENCE NUMBER                 02680000
ACTEMP0  DS    F                                                        02700000
ACTEMP1  DS    F                                                        02720000
ACTEMP2  DS    F                                                        02740000
ACTEMP3  DS    F                                                        02760000
ACTEMP4  DS    F                                                        02780000
ACTEMP5  DS    F                                                        02800000
ACTEMP6  DS    F                                                        02820000
ACTEMP7  DS    F                                                        02840000
         ORG                                                            02860000
         EJECT                                                          02880000
*                                                                       02900000
         SPACE 2                                                        02920000
AC1      BC    0,ACWRAP                 /MOD BY AC0/ BYPASS TESTRAN     02940000
         L     FRB,CTESTR(ACT)          GET IEUF7N ADDRESS, AND...      03000000
         BALR  CRR,ACT                  BRANCH TO GENERATE TESTRAN REC. 03020000
         SPACE                                                          03040000
ACWRAP   BC    0,AC2                    BYPASS WRAP-AROUND TEST IN SUBS 03060000
         CLI   CTLOC+0(ACT),0           TEST FOR LOCATION COUNTER       03080000
         BE    AC2                                       WRAP-AROUND    03100000
         MVC   ACTEMP0,CTLOC(ACT)                                       03120000
         MVC   CTLOC(4,ACT),=X'00FFFFFF'     CALL ORG ROUTINE TO SET    03140000
         LA    GR1,=AL2(X'0100'+IBLANK)      HIGH LOC FOR THIS CSECT    03160000
         ST    GR1,CTXOFP(ACT)               EQ X'FFFFFF'               03180000
         L     GRX,CORG(ACT)                 IF CTLOC GQ X'1000000'     03200000
         BAL   CRR,CTLNK2(ACT)          BRANCH TO A.C.T. LINKAGE ALG'RM 03220000
         MVC   CTLOC(4,ACT),ACTEMP0          SET SEQ NO. IN CTWRAP7     03240000
         CLC   CTLOC+1(3,ACT),CTZERO(ACT)    IF CTLOC GR X'1000000'     03260000
         BE    AC2                      DON'T, IF EQ X'1000000'         03280000
         MVI   CTLOC+0(ACT),0           ZERO 1ST LOC COUNTER BYTE       03300000
         CLC   CTWRAP7(4,ACT),CTZERO(ACT)    IF NOT FIRST TIME HERE,    03320000
         BNE   AC2                      SKIP TO TXGET CALL              03340000
         MVC   CTWRAP7(4,ACT),CTSEQN(ACT)    ELSE, INSERT SEQ. NUMBER   03360000
         SPACE                                                          03380000
AC2      L     FRB,CTXGET(ACT)          CALL TXGET TO GET NEXT STATEMNT 03400000
         NI    CTEXENSW(ACT),X'FB'      RESET ACT-SWITCH FOR SAF A32954 03410020
         BALR  CRR,ACT                  TXGET=IEUF7X                    03420000
         SPACE                                                          03440000
AC3      BC    0,ACS0                   /MOD BY SMODE/ XFER TO SUBS CTL 03460000
         SPACE                                                          03480000
         TM    TXTO(GRA),BIT0                                           03500000
         BO    AOP                      TXTO EQ ASSEMBLER OP            03520000
*        B     MOP                      TXTO EQ MACHINE OP              03540000
         EJECT                                                          03560000
*                                                                       03580000
         SPACE 2                                                        03600000
MOP      BC    0,MOP1                   /UPC/ BYPASS P.C. TEST          03620000
         BAL   CRR,UPC                  TEST UNINITIATED PRIVATE CODE   03640000
         SPACE                                                          03660000
MOP1     BAL   CRR,SYMF                 TEST POSSIBLE S.T. OVERFLOW     03680000
         SPACE                                                          03700000
         SR    SP1,SP1                  ALIGN LOC COUNTER TO HALF WORD  03720000
         LA    SP2,2                    AND SET CTLOC, TXLOC, TXALIN    03740000
         BAL   CRR,ALIGN                                                03760000
         SPACE                                                          03780000
         TM    TXESI(GRA),BIT6          TEST FOR LIT IN OPERAND         03800000
         BZ    MOP2                     NONE. SKIP LITERAL EVAL.        03820000
MOP1A    BC    15,MOP1B                 IF ALREADY XREF NO BRANCH 23749 03828018
         OI    MOP1A+1,X'F0'            SET TO MAKE XREF AGAIN    23749 03836018
         NI    CTXRFI(ACT),X'FD'        TURN OFF XREF BIT         23749 03844018
MOP1B    BAL   CRR,XREF                 MAKE TYPE 2 XREF          23749 03852018
         L     FRB,CDCVAL(ACT)          CALL DCEVAL TO EVALUATE LITERAL 03860000
         BALR  CRR,ACT                  FUNCT. ROUT. LINKAGE TO IEUF7D  03880000
MOP1D    OI    CTXRFI(ACT),BIT6         RESET XREF BIT            23749 03890018
         TM    CTSYMF(ACT),BIT7         ROOM IN S.T. FOR LITERAL        03900000
         BZ    MOP1C                    YES, SEE IF XREF NEEDED    9538 03903013
         MVC   CTXWBP(4,ACT),ACTEMP1    RESTORE WORKBUCKET POINTER 9210 03906013
         NI    MOP1A+1,X'0F'            NOT TO MAKE XREF AGAIN    23749 03909018
         B     SMODE                    PUT IN SUBSTITUTION MODE   9210 03912013
MOP1C    CLI   0(SP1),IBLANK            ARE WE AT END OF FIELD     9538 03915013
         BE    MOP3                     YES, DONT XREF             9538 03918013
*                                                                  9538 03921013
*        SET UP TO GO INTO MIDDLE OF XREF ROUTINE                  9538 03924013
*                                                                  9538 03927013
         L     CRR,CTXOFP(0,ACT)        GET THE LAST BYTE OF       9538 03930013
         SR    FRB,FRB                    OPERAND INTO REGISTER    9538 03933013
         IC    FRB,TXOPNL(0,CRR)            FRB FOR XREF           9538 03936013
         AR    FRB,CRR                                             9538 03939013
         BAL   CRR,XREF0                XREF TYPE TWO              9538 03942013
         B     MOP3                     CONTINUE ON                9538 03945013
         SPACE                                                          03960000
MOP2     BC    0,MOP3                   /AC0/ BYPASS X-REF              03980000
         BAL   CRR,XREF                 GENERATE TYPE 2 X-REF RECORDS   04000000
         SPACE                                                          04020000
MOP3     LA    GRX,2                    TEST HEX CODE FOR OP LENGTH     04040000
         TM    TXHEX(GRA),BIT0+BIT1     LOOK AT FIRST TWO BITS          04060000
         BZ    AC5                      NO BITS, LEAVE OP. LENGTH TWO   04080000
         LR    GR1,GRX                  USE GR1 TO INCREMENT OP  LENGTH 04100000
         BM    MOP4                     ONLY ONE BIT, SKIP TO LAST INC. 04120000
         AR    GRX,GR1                  DO THIS ONLY FOR BOTH BITS ON   04140000
MOP4     AR    GRX,GR1                  GRX NOW HAS FOUR OR SIX         04160000
         SPACE                                                          04180000
*        GO TO AC5 WITH OP LENGTH IN GRX                                04200000
         EJECT                                                          04220000
*                                                                       04240000
         SPACE                                                          04260000
AC5      LR    GR0,GRX                  STEPLLOCATION COUNTER           04280000
         A     GR0,CTLOC(ACT)           WITH OP LENGTH CONTAINED IN GRX 04300000
         ST    GR0,CTLOC(ACT)                                           04320000
         SPACE                                                          04340000
AC6      CLI   TXNAML(GRA),0            TEST NAME FOR S.T. ENTRY        04360000
         BE    AC1                      NONE, GO FINISH STATEMENT       04380000
         SPACE                                                          04400000
         LTR   GRX,GRX                  SET LEGNTH ATTRIBUTE            04420000
         BZ    AC61                     FROM OP LENGTH CONTAINED IN GRX 04440000
         BCTR  GRX,0                    LEN ATTR. EQ LEN-1 IF LEN GR 0  04460000
AC61     STH   GRX,STLONG(ACT)                                          04480000
         SPACE                                                          04500000
         MVC   ESDID(1,ACT),CESDID(ACT) SET ESDID EQ CURRENT ESD        04520000
         SPACE                                                          04540000
         MVI   ADJCOD(ACT),7            SET ADJECTIVE CODE              04560000
         CLI   CTYPE(ACT),7                 EQ 7 IF CTYPE EQ 5 OR 7     04580000
         BE    AC7                          EQ 3 IF CTYPE NQ 5 OR 7     04600000
         CLI   CTYPE(ACT),5                                             04620000
         BE    AC7                                                      04640000
         MVI   ADJCOD(ACT),3                                            04660000
         SPACE                                                          04680000
AC7      MVC   STVALU+1(3,ACT),TXLOC(GRB)  SET VALUE ATTR. FROM TXLOC   04700000
         SPACE                                                          04720000
AC8      L     SRB,CSTPUT(ACT)          SET SRB FOR S.T. ENTRY          04740000
         SPACE 2                                                        04760000
AC9      TM    TXMDN(GRA),BIT3          IF MULT. DEFINED NAME FLAG SET, 04780000
         BO    AC1                      BYPASS S.T. ENTRY/CHECK         04800000
         SPACE                                                          04820000
AC91     SR    SP2,SP2                  SET STPUT/STGET ENTR PAR A32954 04852020
         IC    SP2,TXNAML(GRA)          SP2 EQ NAME FIELD LENGTH        04860000
         LA    SP1,TXNAME(GRA)          SP1 PT TO NAME IN NAME FIELD    04880000
         BALR  SRR,SRB                  CALL STPUT OR STGET             04900000
         NOP   0                        ABNORMAL EXIT /NOT USED BY MLC/ 04920000
         LTR   SP1,SP1                  IF NAME NOT PREVIOUSLY DEFINED, 04940000
         BZ    AC1                      SP1 WILL BE SET TO ZERO         04960000
         SPACE                                                          04980000
         TM    TXMDN(GRA),BIT3          IS MULT. DEF. BIT ON     A67476 04990021
         BO    AC1                      BACK TO FINISHING POINT  A67476 04992021
         OI    TXMDN(GRA),BIT3          MULTIPLY DEFINED, SET TXMDN,    05000000
         BAL   SRR,ERROR0               AND LOG ERROR                   05020000
         DC    AL2(ACER00)                                              05040000
         TM    CTMODE(ACT),BIT1+BIT2    IF MODE SUBST BEFORE REW.A67476 05050021
         BNM   AC1                      NO,BACK TO FINISH. POINT A67476 05060021
         L     SRB,CSTPUT(ACT)          YES,SET FOR S.T.ENTRY TO A67476 05072021
         B     AC91                     DO XREF FOR DUPL. NAMES  A67476 05074021
         EJECT                                                          05080000
*                                                                       05100000
         SPACE 2                                                        05120000
AOP      TM    TXASC(GRA),BIT0          TEST ASC FOR UPC CHECK          05140000
AOP0     BC    8,AOP1                   /MOD BY UPC/ BYPASS UPC CHECK   05160000
         BAL   CRR,UPC                                                  05180000
         SPACE                                                          05200000
AOP1     TM    TXASC(GRA),BIT1          TEST ASC FOR POSSIBLE S.T. ENT. 05220000
         BZ    AOP2                                                     05240000
         BAL   CRR,SYMF                 TEST POSSIBLE S.T. OVERFLOW     05260000
         SPACE                                                          05280000
AOP2     TM    TXASC(GRA),BIT2          TEST ASC FOR LOC COUNTER REF.   05300000
         BZ    AOP3                                                     05320000
         MVC   TXLOC(3,GRB),CTLOC+1(ACT)  MOVE CURRENT LOC CTR TO TXLOC 05340000
         SPACE                                                          05360000
AOP3     TM    TXASC(GRA),BIT3          TEST ASC                        05380000
AOP30    BC    8,AOPGO                  /MOD BY AC0/ BYPASS X-REF       05400000
         BAL   CRR,XREF                 GENERATE TYPE 2 X-REF           05420000
         SPACE 2                                                        05440000
*                                                                       05460000
         SPACE                                                          05480000
AOPGO    SR    GR1,GR1                  USE HEX CODE TO CALC. DISPLCMNT 05500000
         IC    GR1,TXHEX(GRA)           OF POINTER TO ASSEMBLER OP RTN. 05520000
         SH    GR1,AOPGO2               HEX CODE LT X'OE', THEN...      05540000
         BM    AC2                      GO GET A NEW STATEMENT          05560000
         SLL   GR1,1                    MULT REMNANT BY 2               05580000
         LH    GR1,AOPGO2+2(GR1)        GET ADDRESS FROM TABLE          05600000
         B     AC0(GR1)                 BRANCH TO PROCESS OPERATION     05620000
         EJECT                                                          05640000
* ASSEMBLER OP COMPUTED GO-TO DISPLACEMENT VALUES (ASSIGNMENT MODE)     05660000
         SPACE 2                                                        05680000
AOPGO2   DC    X'000E'                  ASSIGNMENT MODE LOWER LIMIT     05700000
         SPACE                                                          05720000
         DC    AL2(MNOTE-AC0)           HEX 0E    MNOTE                 05740000
         DC    AL2(AC1-AC0)                 0F                          05760000
         DC    AL2(AC1-AC0)                 10                          05780000
         DC    AL2(AC1-AC0)                 11                          05800000
         DC    AL2(AC1-AC0)                 12                          05820000
         DC    AL2(AC1-AC0)                 13                          05840000
         DC    AL2(AC1-AC0)                 14                          05860000
         DC    AL2(AC1-AC0)                 15                          05880000
         DC    AL2(PUNCH-AC0)               16    PUNCH                 05900000
         DC    AL2(REPRO-AC0)               17    REPRO                 05920000
         DC    AL2(TITLE-AC0)               18    TITLE                 05940000
         DC    AL2(ENTRY-AC0)               19    ENTRY                 05960000
         DC    AL2(EXTRN-AC0)               1A    EXTRN                 05980000
         DC    AL2(START-AC0)               1B    START                 06000000
         DC    AL2(CSECT-AC0)               1C    CSECT                 06020000
         DC    AL2(DSECT-AC0)               1D    DSECT                 06040000
         DC    AL2(COM-AC0)                 1E    COM                   06060000
         DC    AL2(EQU-AC0)                 1F    EQU                   06080000
         DC    AL2(ORG-AC0)                 20    ORG                   06100000
         DC    AL2(END-AC0)                 21    END                   06120000
         DC    AL2(LTORG-AC0)               22    LTORG                 06140000
         DC    AL2(AC1-AC0)                 23    USING                 06160000
         DC    AL2(AC1-AC0)                 24    DROP                  06180000
         DC    AL2(DCDS-AC0)                25    LITR                  06200000
         DC    AL2(DCDS-AC0)                26    DC                    06220000
         DC    AL2(DCDS-AC0)                27    DS                    06240000
         DC    AL2(CCW-AC0)                 28    CCW                   06260000
         DC    AL2(CNOP-AC0)                29    CNOP                  06280000
         DC    AL2(QUIT-AC0)                2A    QUIT                  06300000
         DC    AL2(DXD-AC0)                 2B    DXD                   06320000
         DC    AL2(CXD-AC0)                 2C    CXD                   06340000
         DC    AL2(OPSYN-AC0)               2D    OPSYN           IEUN1 06350018
         DC    AL2(WXTRN-AC0)               2E    WXTRN            I004 06355020
         EJECT                                                          06360000
* ASSEMBLER OP COMPUTED GO-TO DISPLACEMENT VALUES (SUBSTITUTION MODE)   06380000
         SPACE 2                                                        06400000
AOPGO3   DC    X'0016'                  SUBSTITUTION MODE LOWER LIMIT   06420000
         SPACE                                                          06440000
         DC    AL2(AC2-AC0)             HEX 16    PUNCH                 06460000
         DC    AL2(AC2-AC0)                 17    REPRO                 06480000
         DC    AL2(AC2-AC0)                 18    TITLE                 06500000
         DC    AL2(ENTRYS-AC0)              19    ENTRY                 06520000
         DC    AL2(EXTRNS-AC0)              1A    EXTRN                 06540000
         DC    AL2(ESDWB-AC0)               1B    START                 06560000
         DC    AL2(ESDWB-AC0)               1C    CSECT                 06580000
         DC    AL2(ESDWB-AC0)              11D    DSECT                 06600000
         DC    AL2(ESDWB-AC0)               1E    COM                   06620000
         DC    AL2(ACS2-AC0)                1F    EQU                   06640000
         DC    AL2(AC2-AC0)                 20    ORG                   06660000
         DC    AL2(END-AC0)                 21    END                   06680000
         DC    AL2(LTORG-AC0)               22    LTORG                 06700000
         DC    AL2(AC2-AC0)                 23    USING                 06720000
         DC    AL2(AC2-AC0)                 24    DROP                  06740000
         DC    AL2(DCDS-AC0)                25    LITR                  06760000
         DC    AL2(DCDS-AC0)                26    DC                    06780000
         DC    AL2(DCDS-AC0)                27    DS                    06800000
         DC    AL2(AC2-AC0)                 28    CCW                   06820000
         DC    AL2(AC2-AC0)                 29    CNOP                  06840000
         DC    AL2(AC2-AC0)                 2A    QUIT                  06860000
         DC    AL2(DXD-AC0)                 2B    DXD                   06880000
         DC    AL2(ACS2-AC0)                2C    CXD                   06900000
         DC    AL2(AC2-AC0)                 2D    OPSYN           IEUN1 06910018
         DC    AL2(WXTRNS-AC0)              2E    WXTRN            I004 06915020
AOPGO4   EQU   *                                                        06920000
         EJECT                                                          06940000
* ACS0 - SUBSTITUTION MODE CONTROL (ENTERED FROM AC3)                   06960000
         SPACE                                                          06980000
ACS0     TM    TXMARK(GRA),BIT7         TEST ITERATION POINT INDICATOR  07000000
         BO    AMODE                    IF SET, CHANGE MODE TO ASSIGNMT 07020000
         SPACE                                                          07040000
ACS1     TM    TXTO(GRA),BIT0           TEST TYPE OF OPERATION          07060000
         BO    ACSAOP                   ASSEMBLER OP, ACSAOP            07080000
         SPACE                                                          07100000
         BAL   CRR,SUBWB                MACHINE OP, SUBSTITUTE IN WKBKT 07120000
         SPACE                                                          07140000
         TM    TXESI(GRA),BIT6          TEST FOR LIT IN OPERAND         07160000
         BZ    ACS2                     NONE                            07180000
         TM    CTLIT1(ACT),BIT4         IF LIT IN OPERAND               07200000
         BO    ACS2                     AND LITORG HAS NOT BEEN PROCESD 07220000
         L     FRB,CDCVAL(ACT)          CALL DCEVAL TO EVALUATE LITERAL 07240000
         BALR  CRR,ACT                  THROUGH ACT LINKAGE, TO IEUF7D  07260000
         SPACE                                                          07280000
ACS2     CLI   TXNAML(GRA),0            TEST FOR NAME IN NAME FIELD     07300000
         BE    AC2                      NONE                            07320000
         TM    CTMODE(ACT),BIT1         IF MODE EQ SUBS AFTER REWIND,   07340000
         BO    AC2                      BYPASS MULTIPLY DEF. NAME TEST  07360000
         L     SRB,CSTGET(ACT)          IF MODE EQ SUBS BEFORE REWIND,  07380000
         B     AC9                      SET SRB FOR STGET AND TEST MDN  07400000
         SPACE                                                          07420000
ACSAOP   TM    TXASC(GRA),BIT4          ASSEMBLER OP, TEST ASC/SUBSWKB/ 07440000
         BZ    AOPGO                    SUBSTITUTION NOT REQUIRED       07460000
         BAL   CRR,SUBWB                SUBSTITUTE IN WORKBUCKETS       07480000
         B     AOPGO                    GO TO ASSEMBLER OP ROUTINE      07500000
         EJECT                                                          07520000
* PROCESS TITLE STATEMENTS (ASSIGNMENT MODE ONLY)                       07540000
         SPACE 2                                                        07560000
TITLE    CLC   CTSEQN(4,ACT),=F'1'      TEST SEQUENCE NUMBER            07580000
         BNE   TITLE0                   IF FIRST CARD IS TITLE CARD,    07600000
         MVI   EJCTSW(ACT),X'00'        CLEAR F/8 EJECT SWITCH          07620000
         SPACE                                                          07640000
TITLE0   CLI   TXNAML(GRA),0            TEST NAME FIELD LENGTH          07660000
         BE    TITLE4                   ZERO                            07680000
         SPACE                                                          07700000
TITLE1   BC    15,TITLE2                NOP /MOD BY TITLE4/ AFTER FIRST 07720000
         BAL   SRR,ERROR0               LOG ERROR IF NAME APPEARS ON    07740000
         DC    AL2(ACER40)              OTHER THAN FIRST TITLE CARD     07760000
         B     TITLE4                   AND DON'T PROCESS NAME          07780000
         SPACE                                                          07800000
TITLE2   IC    GR1,TXNAML(GRA)          SAVE NAME LEN IN GR1            07820000
         CLI   TXNAML(GRA),4            TEST NAME LEN GR 4              07840000
         BNH   TITLE3                   NAME LEN LQ 4, O.K.             07860000
         BAL   SRR,ERROR0               NAME LEN GR 4, LOG ERROR        07880000
         DC    AL2(ACER41)                             AND USE FIRST    07900000
         LA    GR1,4                                   FOUR CHARACTERS  07920000
         SPACE                                                          07940000
TITLE3   BCTR  GR1,0                    LENGTH MINUS ONE FOR MVC AND TR 07960000
         L     GR2,CTRTBP(ACT)          GR2 PTS TO TRANSLATE TABLE      07980000
         EX    GR1,TITLEM               MOVE NAME INTO CONTROL TABLE    08000000
         EX    GR1,TITLET               TRANSLATE TO EXTERNAL CODE      08020000
         SPACE                                                          08040000
TITLE4   NI    TITLE1+1,X'0F'           MODIFY FOR SUBSEQUENT TITLES    08060000
         SPACE                                                          08080000
         BAL   SRR,SQUASH               MOVE TITLE TO 2ND COMM FIELD    08100000
         CLI   0(GRY),100               TEST LENGTH                     08120000
         BNH   AC1                      GO FINISH, IF NOT TOO LONG      08140000
         BAL   SRR,ERROR0               TOOOO BIG, LOG ERROR            08160000
         DC    AL2(ACER42)              'DATA ITEM TOO LARGE'           08180000
         B     ABORT                    WIPE UP THE MESS                08200000
         SPACE                                                          08220000
TITLEM   MVC   CTITLE(0,ACT),TXNAME(GRA)                                08240000
         SPACE                                                          08260000
TITLET   TR    CTITLE(0,ACT),0(GR2)                                     08280000
         EJECT                                                          08300000
* PROCESS PUNCH AND REPRO (ASSIGNMENT MODE ONLY)                        08320000
         SPACE 2                                                        08340000
PUNCH    BAL   SRR,SQUASH               ENTRY FOR PUNCH - CALL SQUASH   08360000
         B     PUNCH0                    SR TO MOVE AND COMPRESS OPND   08380000
         SPACE                                                          08400000
REPRO    L     GRY,CTXABP(ACT)          ENTRY FOR REPRO - CALL SQUASH   08420000
         SR    GRX,GRX                   WITH POINTER TO 2ND COM IN GRY 08440000
         IC    GRX,0(GRY)                      LENGTH OF 2ND COM IN GRX 08460000
         BAL   SRR,SQUASH8               TO TRANSLATE TO EXTERNAL       08480000
         SPACE                                                          08500000
         SPACE                                                          08520000
         TM    TXERI(GRA),BIT5          TEST FOR PREV. LOGGED ERRORS    08540000
         BO    ABORT                    IF SO, ABORT PROCESSING         08560000
         L     GR1,CTSEQN(ACT)                                          08580000
         LA    GR1,1(GR1)                                               08600000
         ST    GR1,CTSEQN(ACT)          UPDATE THE SEQUENCE NUMBER      08620000
PUNCH0   CLI   0(GRY),80    TEST 2ND COM LENGTH                         08640000
         BH    PUNCHERR     ERROR IF GR 80                              08660000
         SPACE                                                          08680000
         CLI   CESDID(ACT),0            TEST FOR F/7 PROCESSING         08700000
         BNE   AC1                      BYPASS IF CODE HAS BEEN GENERTD 08720000
         SPACE                                                          08740000
         MVI   CTWORK+0(ACT),X'00'      MOVE CONTROL CHAR               08760000
         MVI   CTWORK+2(ACT),C' '       AND CARD IMAGE TO CTWORK        08780000
         MVC   CTWORK+3(78,ACT),CTWORK+2(ACT)                           08800000
         EX    GRX,PUNCHMVC                                             08820000
         SPACE                                                          08840000
         L     SRB,CTXTIO(ACT)          PUNCH CARD                      08860000
         LA    SP1,CTWORK(ACT)                                          08880000
         BAL   SRR,SYSOUT(SRB)          COMMON SUBR. LINKAGE TO IEUF7I  08900000
         SPACE                                                          08920000
         B     TRUNCATE                 REMOVE 2ND COM FIELD            08940000
         SPACE                                                          08960000
PUNCHMVC MVC   CTWORK+1(0,ACT),1(GRY)                                   08980000
         SPACE                                                          09000000
PUNCHERR BAL   SRR,ERROR0               OPERAND EXCEEDS 80 CHAR         09020000
         DC    AL2(ACER60)              LOG ERROR                       09040000
         B     ABORT                    AND ABORT PROCESSING            09060000
         EJECT                                                          09080000
*  PROCESS MNOTE...COMPRESS OPERAND AND MOVE TO SPECIAL WORK BUCKET     09100000
    SPACE                                                               09120000
MNOTE    L     SP1,CTXOFP(ACT)          FIND OPERAND LENGTH FIELD       09140000
         IC    GR1,TXOPNL(SP1)          PICK UP OP'ND LENGTH BYTE       09160000
         STC   GR1,MNOTEMV1+1           INSERT INTO 'MVC'               09180000
         NI    MNOTESC+1,X'0F'          OPEN GATE TO MNOTE LOGGING      09200000
         SR    SP2,SP2                  SEVERITY CODE STARTS AT ZERO    09220000
MNOTEMV1 MVC   0(0,GRB),0(SP1)          MOVE OPERAND TO SPECIAL W.B.    09240000
         MVI   CTWORK(ACT),IQUOTE       WORK AREA STARTS WITH QUOTE     09260000
         MVC   CTWORK+1(33,ACT),1(SP1)  PUT OPERAND IN BEHIND THAT      09280000
         CLI   1(SP1),IASTER            IF STARTS WITH *, COMMENT ONLY  09300000
         BNE   MNOTE1                   NO, GO CHECK FOR QUOTE          09320000
         LA    SP1,2(SP1)               STEP POINTER UP TO THE COMMA    09340000
         OI    MNOTESC+1,X'F0'          CLOSE ERROR LOGGING GATE        09360000
         B     MNOTE2                   GO TEST REST OF OPERAND         09380000
         SPACE                                                          09400000
MNOTE1   CLI   1(SP1),IQUOTE            NOT *, MAYBE IT'S A QUOTE       09420000
         BE    MNOTE3                   YES, SEV. CODE OMITTED          09440000
         LA    SP1,1(SP1)               NO, STEP POINTER FORWARD        09460000
         LA    SP2,1                    SEV. CODE 1                     09480000
         CLI   0(SP1),9                 FIRST BYTE MIGHT BE NUMBER      09500000
         BH    MNOTE2                   NO, GO CHECK FOR COMMA          09520000
         L     SRB,CEEVAL(ACT)          YES, EVALUATE SEV. CODE         09540000
         OI    CTSDVI(ACT),BIT0         SET SELF-DEFINING ERM IND.      09560000
         BALR  SRR,SRB                  TO IEUF7V THROUGH ACT LINKAGE   09580000
         BNZ   ABORT                    IEUF7V LEAVES CC=0 IF ABS. TERM 09600000
MNOTE2   CLI   0(SP1),ICOMMA            WE LIKE COMMA AT END OF OP'ND   09620000
         BNE   MNOTERR                  AND OBJECT, IF WE NO GET 'EM    09640000
         CLI   1(SP1),IQUOTE            ALSO WANT QUOTE TO COME NEXT    09660000
         BNE   MNOTERR                  GO REGISTER OBJECTION           09680000
         S     SP1,CTXOFP(ACT)          FIND HOW MANY BYTES IN FIRST OP 09700000
         EX    SP1,MNOTEMV2             FIRST OP'ND TO SPEC.WRK BUCKET  09720000
MNOTE3   ST    SP2,ACTEMP0             PUT DOWN SEV. CODE               09740000
         CLC   ACTEMP0(3),CTZERO(ACT)   CHECK LESS THAN 256             09760000
         BE    MNOTE4                   OK, DON'T COMPLAIN              09780000
         BAL   SRR,ERROR0               BAD SHOW, LOG ERROR             09800000
         DC    AL2(ACER71)              'INVALID SELF-DEFINING TERM'    09820000
         B     ABORT                    DISGUSTING, GIVE UP             09840000
MNOTE4   ST    GRB,CTXOFP(ACT)          SET TO POINT TO NEW W.B.        09860000
         BAL   SRR,SQUASH               SQUEEZE THE WORK BUCKET         09880000
MNOTESC  BC    0,MNOTE6                 LOGGING GATE SET UP ABOVE       09900000
         CLC   ACTEMP0+3,CTSEVCOD(ACT)  LOOK FOR HIGHEST SEV. CODE      09920000
         BNH   MNOTE5                   NOT THIS ONE, SO SKIP           09940000
         MVC   CTSEVCOD(1,ACT),ACTEMP0+3  FOUND A HIGHER ONE, KEEP IT   09960000
MNOTE5   BAL   SRR,ERROR0               LOG ERROR RECORD                09980000
         DC    AL2(ACER70)              'MNOTE STATEMENT'               10000000
         NI    TXERI(GRA),X'FF'-BIT5    TURN OFF 'ERROR RECORD FOLLOWS' 10020000
MNOTE6   NI    TXRT(GRA),X'FF'-BIT3     SET TO PRINT, 'GEN' OR 'NOGEN'  10040000
         B     AC2                      GO BACK FOR NEXT STATEMENT      10060000
         SPACE                                                          10080000
MNOTERR  BAL   SRR,ERROR                LOG ERROR                       10100000
         DC    AL2(ACER72)              'INVALID DELIMITER'             10120000
         B     ABORT                    GIVE UP ON THIS STATEMENT       10140000
         SPACE                                                          10160000
MNOTEMV2 MVC   1(0,GRB),CTWORK(ACT)     EXECUTED                        10180000
         EJECT                                                          10200000
*        SQUASH...ROUTINE TO REMOVE DOUBLE QUOTES AND AMPERSANDS        10220000
         SPACE                                                          10240000
SQUASH   L     SP1,CTXOFP(ACT)          ADDRESS OF OPERAND-1            10260000
         SR    SP2,SP2                  MAKE ZERO                       10280000
         IC    SP2,0(SP1)               LENGTH OF OPERAND               10300000
         AR    SP2,SP1                  END OF OPERAND, +1              10320000
SQUASH0  L     GRX,CTXABP(ACT)          ADDRESS OF SECOND COM FIELD     10340000
         LR    GRY,GRX                  ALSO IN GRY                     10360000
         BCTR  SP2,0                    ADDRESS LAST OPERAND BYTE       10380000
         LA    SP1,1(SP1)               ADDRESS FIRST OPERAND BYTE      10400000
         CLI   0(SP1),IQUOTE            FIRST BYTE SHOULD BE QUOTE      10420000
         BNE   SQUASHE1                 NO, LOG ERROR                   10440000
SQUASH01 CR    SP2,SP1                  OPND END SHOULD BE PAST START   10460000
         BNH   SQUASHE1                 NO, LOG ERROR                   10480000
         CLI   0(SP2),IQUOTE            LAST BYTE MAY BE QUOTE          10500000
         BE    SQUASH2                  YES,START PROCESSING            10520000
         BCT   SP2,SQUASH01             NO, MOVE END POINTER AND REPEAT 10540000
         SPACE                                                          10560000
SQUASHE1 BAL   SRR,ERROR                OPERAND NOT ENCLOSED IN QUOTES  10580000
         DC    AL2(ACER50)              LOG ERROR                       10600000
         B     ABORT                    AND ABORT PROCESSING            10620000
         SPACE                                                          10640000
SQUASH1  MVC   0(1,GRX),0(SP1)          MOVE BYTE FROM OPND TO 2ND COM  10660000
SQUASH2  LA    SP1,1(SP1)               STEP START POINTER              10680000
         CR    SP1,SP2                  MAY BE AT OPND END              10700000
         BNL   SQUASH4                  YES, GO SET LENGTH INDICATOR    10720000
         LA    GRX,1(GRX)               NO, POINT TO NEXT 2ND COM POS'N 10740000
         CLI   0(SP1),IQUOTE           MAY BE A QUOTE                   10760000
         BE    SQUASH3                 YES, GO SEE IF NEXT ONE IS TOO   10780000
         CLI   0(SP1),IAMPSD            MAY BE AN AMPERSAND             10800000
         BNE   SQUASH1                  NO, GO MOVE THE BYTE            10820000
SQUASH3  CLC   0(1,SP1),1(SP1)          NEXT BYTE MAY BE THE SAME       10840000
         BNE   SQUASHE2                 NO, UNPAIRED SOMETHING          10860000
         LA    SP1,1(SP1)               YES, SKIP THAT BYTE             10880000
         CR    SP1,SP2                  CAREFUL ABOUT OPERAND END       10900000
         BL    SQUASH1                  OK, NOW MOVE ANOTHER BYTE       10920000
         SPACE                                                          10940000
SQUASHE2 BCTR  SP1,0                    UNPAIRED QUOTE OR AMPSND        10960000
         BAL   SRR,ERROR                LOG ERROR                       10980000
         DC    AL2(ACER51)              AND ABORT                       11000000
         B     ABORT                                                    11020000
         SPACE                                                          11040000
SQUASH4  SR    GRX,GRY                  SET 2ND COM FIELD LENGTH        11060000
         BZ    SQUASHE2                 AND INC TXRL                    11080000
         STC   GRX,0(GRY)                                               11100000
         LA    GR1,1(GRX,GRY)                                           11120000
         SR    GR1,GRA                                                  11140000
         STH   GR1,TXRL(GRA)                                            11160000
         SPACE                                                          11180000
SQUASH8  L     GR1,CTRTBP(ACT)          ENTRY FOR REPRO                 11200000
         BCTR  GRX,0                    TRANSLATE 2ND COM FIELD         11220000
         EX    GRX,SQUASHTR             TO EXTERNAL CODE                11240000
         BR    SRR                                                      11260000
         SPACE                                                          11280000
SQUASHTR TR    1(0,GRY),0(GR1)                                          11300000
         EJECT                                                          11320000
* PROCESS EQU STATEMENTS (ASSIGNMENT MODE)                              11340000
         SPACE 2                                                        11360000
EQU      L     SRB,CEEVAL(ACT)          CALL EXPRESSION EVAL SUBROUTINE 11380000
         L     SP1,CTXOFP(ACT)          WITH POINTER TO FIRST BYTE      11400000
         LA    SP1,1(SP1)               OF OPERAND IN SP1               11420000
         OI    CTPDSI(ACT),BIT2         SET PREVIOUSLY DEF SYMB REQ IND 11440000
         BALR  SRR,SRB                  TO IEUF7V THROUGH ACT LINKAGE   11460000
         SPACE                                                          11480000
         BC    8,EQUABS                 RETURN WITH CC EQ ABS           11500000
         BC    4,EQUREL                                   SIMPLY RELOC  11520000
         BC    1,EQUABORT                                 ERROR         11540000
         BAL   SRR,ERROR0               LOG ERROR         COMPLEX RELOC 11560000
         DC    AL2(ACER21)                                              11580000
         B     EQUABORT                 ABORT PROCESSING                11600000
         SPACE                                                          11620000
EQUREL   MVC   ESDID(1,ACT),5(SP2)      SIMPLY RELOC, SET ESDID         11640000
         L     SP2,0(SP2)               SET VALUE IN SP2                11660000
         CLC   ESDID(1,ACT),CTNDID+1(ACT) SET ADJ CODE EQ 7             11680000
         BH    EQUDSC                     IF DEFINED IN DSECT OR COM    11700000
         CLC   ESDID(1,ACT),CTCMSW(ACT)                                 11720000
         BE    EQUDSC                                            A45780 11740021
         TM    CTEXENSW(ACT),X'04'      IS SWITCH SET            A45780 11752021
         BNO   EQUNDC                   NO                       A45780 11754021
         NI    CTEXENSW(ACT),X'FB'      RESET SWITCH             A45780 11756021
EQUDSC   LA    GR1,7                                                    11760000
         B     EQUSET                   OTHERWISE, ADJ CODE EQ 3        11780000
         SPACE                                                          11800000
EQUABS   MVI   ESDID(ACT),0             ABSOLUTE, SET ESDID EQ 0        11820000
         SPACE                                                          11840000
EQUNDC   LA    GR1,3                    ADJCOD EQ 3 IF ABS OR NOT DSCCM 11860000
         SPACE                                                          11880000
EQUSET   STC   GR1,ADJCOD(ACT)          SET ADJCODE FOR S.T. ENTRY      11900000
         ST    SP2,STVALU(ACT)          SET VALUE FOR S.T. ENTRY        11920000
*        MVC   TXLOC(3,GRB),STVALU+1(ACT) MOVCE VALUE TO TEXT           11940000
*        MVC   TXALIN(1,GRB),ESDID(ACT) MOVE ESDID TO TEXT              11960000
         SPACE                                                          11980000
         CLI   0(SP1),IBLANK            TEST TERM CHAR EQ BLANK         12000000
         BE    AC8                      PUT IN SYMBOL TABLE             12020000
         SPACE                                                          12040000
         BAL   SRR,ERROR                LOG ERROR                       12060000
         DC    AL2(ACER20)              INVALID TERM DELIM              12080000
         B     EQUABORT                 ABORT PROCESSING                12100000
EQUABORT B     ABORT                                                    12120000
         SPACE                                                          12140000
         EJECT                                                          12160000
* PROCESS CNOP STATEMENTS (ASSIGNMENT MODE ONLY)                        12180000
         SPACE 2                                                        12200000
CNOP     L     SP1,CTXOFP(ACT)                                          12220000
         BAL   CRR,CNOPEVAL             EVALUATE B                      12240000
         CLI   0(SP1),ICOMMA            TEST FIRST DELIMITER            12260000
         BNE   CNOPERR1                 NQ COMMA                        12280000
         LR    FRB,SP2                  SAVE B VALUE IN FRB             12300000
         BAL   CRR,CNOPEVAL             EVALUATE W                      12320000
         CLI   0(SP1),IBLANK            TEST SECOND DELIMITER           12340000
         BE    CNOPGOGO                 EQ BLANK                        12360000
         SPACE                                                          12380000
CNOPERR1 BAL   SRR,ERROR                LOG ERROR,                      12400000
         DC    AL2(ACER10)              FIRST OR SECOND DELIMITER ERROR 12420000
         B     CNOPNOGO                 GO RESET AND GIVE UP            12440000
         SPACE                                                          12460000
CNOPGOGO BC    0,CNOPNOGO               /ALTERED BY CNOPERRX/           12480000
         LA    CRR,AC1                  NOT COMING BACK..SET RETURN REG 12500000
         LR    SP1,FRB                  SAVE B VALUE                    12520000
         N     FRB,=F'1'                FRB MODULO 2                    12540000
         BNZ   CNOPERR2                 GO LOG ERROR...B MUST BE EVEN   12560000
         CLR   SP1,SP2                  B SHOULD BE LT W VALUE          12580000
         BNL   CNOPERR2                 OR ELSE, LOG ERROR              12600000
         LA    GR1,4                    GR1 GETS FULL-WORD VALUE        12620000
         CR    SP2,GR1                  IF IT LOOKS LIKE W VALUE...     12640000
         BE    ALIGN                    ALIGN CTLOC, TXLOC, TXALIN      12660000
         AR    GR1,GR1                                                  12680000
         CR    SP2,GR1                                                  12700000
         BE    ALIGN                                                    12720000
         SPACE                                                          12740000
CNOPERR2 BAL   SRR,ERROR0               LOG ERROR,                      12760000
         DC    AL2(ACER11)              ILLEGAL VALUE FOR B OR W        12780000
         B     ABORT                    ABORT PROCESSING THIS STATEMENT 12800000
         SPACE                                                          12820000
CNOPEVAL LA    SP1,1(SP1)               STEP TO NEXT BYTE               12840000
         ST    SP1,ACTEMP0              STORE ADDRESS FOR A WHILE       12860000
         OI    CTPDSI(ACT),BIT2         SET 'DEFINED SYMBOLS REQUIRED'  12880000
         L     SRB,CEEVAL(ACT)          READY TO GO TO IEUF7V           12900000
         BALR  SRR,SRB                  AND GO, THROUGH ACT             12920000
         BCR   8,CRR                    ABSOLUTE VALUE, OK TO RETURN    12940000
         LR    SP2,SP1                  DELIMITER POINTER TO SP2        12960000
         BC    1,CNOPERRX               EVAL FOUND SYNTAX ERROR..LOG IT 12980000
         L     SP1,ACTEMP0              RESTORE EVAL START POINTER      13000000
         BAL   SRR,ERROR                LOG ERROR,                      13020000
         DC    AL2(ACER12)              RELOCATABLE VALUE FOR B OR W    13040000
         SPACE                                                          13060000
CNOPERRX OI    CNOPGOGO+1,X'F0'         SET SWITCH TO ABORT PROCESSING  13080000
         LTR   SP1,SP2                                                  13100000
         BCR   7,CRR                    DELAYED ABORT                   13120000
         SPACE                                                          13140000
CNOPNOGO NI    CNOPGOGO+1,X'0F'         RESET SWITCH                    13160000
         B     ABORT                    WITHOUT DELAY                   13180000
         EJECT                                                          13200000
* PROCESS DC,DS,LDC (ASSIGNMENT MODE) - PROCESS DC,DS (SUBSTITUTION)    13220000
         SPACE 2                                                        13240000
DCDS     MVC   ACTEMP2(4),CTXWBP(ACT)                                   13260000
         SPACE                                                          13280000
DCDS0    L     FRB,CDCVAL(ACT)          CALL DCEVAL                     13300000
         BALR  CRR,ACT                  IEUF7D THROUGH ACT              13320000
         SPACE                                                          13340000
         B     DCDS1                    NORMAL RETURN                   13360000
         SPACE                                                          13380000
         BAL   CRR,SUBWB                ABNORMAL RETURN FOR VCON        13400000
         B     DCDS                     SUBSTITUTE IN ASSIGNMENT        13420000
         SPACE                                                          13440000
DCDS1    TM    CTMODE(ACT),BIT2         TEST MODE                       13460000
         BO    DCDS2                    SUBSTITUTION                    13480000
         SPACE                                                          13500000
         L     GRX,CTLEN(ACT)           ASSIGNMENT, SAVE LEN IN GRX     13520000
         B     AC6                      AND MAKE S.T. ENTRY             13540000
         SPACE                                                          13560000
DCDS2    MVC   CTXWBP(4,ACT),ACTEMP2                                    13580000
         BAL   CRR,SUBWB                SUBST. IN WORK BUCKET           13600000
         B     ACS2                     BACK TO SUBSTITUTION CONTROL    13620000
         EJECT                                                          13640000
* PROCESS CCW STATEMENTS (ASSIGNMENT MODE ONLY)                         13660000
         SPACE 2                                                        13680000
CCW      SR    SP1,SP1                  SET B EQ 0                      13700000
         LA    SP2,8                    AND W EQ 8 FOR ALIGNMENT SUBR   13720000
         LR    GRX,SP2                  SAVE LENGTH IN GRX FOR INC.     13740000
         SPACE                                                          13760000
         BAL   CRR,ALIGN                ALIGN LOC COUNTER TO DOUBLE WD. 13780000
         SPACE                                                          13800000
         B     AC5                      MAKE S.T. ENTRY, INC CTLOC      13820000
         EJECT                                                          13840000
* PROCESS LTORG STATEMENTS                                              13860000
         SPACE 2                                                        13880000
LTORG    MVC   CTWORK(32,ACT),TXFAFL(GRB)   MOVE WORK BKTS TO WORK AREA 13900000
         NI    CTLIT3(ACT),X'FE' CLEAR 'NO LITS TO BE GEN'D      A27005 13906019
         CLI   TXURS(GRB),0             HAS THIS CARD BEEN PROCESSED    13920000
         BNE   LTORG1                   YES                             13940000
         OI    TXURS(GRB),X'FF'         NO,                             13960000
         LH    GR1,TXRL(GRA)            ADD 2 16 BYTE WORK BUCKETS      13980000
         LA    GR1,32(GR1)              TO TEXT AND INC REC LENGTH      14000000
         STH   GR1,TXRL(GRA)                                            14020000
         MVI   CTWORK(ACT),0            INITIALIZE WORK BUCKETS TO ZERO 14040000
         MVC   CTWORK+1(31,ACT),CTWORK(ACT)                             14060000
         SPACE                                                          14080000
LTORG1   SR    FRB,FRB                  USE FRB FOR TOTAL POOL LENGTH   14100000
         LA    GR1,12                   GR1 PTS TO LITA,LITB,WBKT ENTRY 14120000
         LA    GR0,4                    GR0 CONTAINS LOOP DEC, COMPARE  14140000
         SPACE                                                          14160000
LTORG2   L     GR2,CTLITA(ACT,GR1)      CURRENT LENGTH OF LITPOOL STRNG 14180000
         ST    GR2,CTWORK(ACT,GR1)      PUT IT IN WORK BUCKET           14220000
         AR    FRB,GR2                  UPDATE TOTAL LENGTH, IN FRB     14240000
         L     GR2,CTWORK+16(ACT,GR1)   WRK BKT 2. POOL STRING COUNT    14260000
         ST    GR2,CTLITA(ACT,GR1)      TO 'LENGTHS' AREA               14280000
         A     GR2,CTLITB(ACT,GR1)      ADD CURRENT 1. POOL STRING CNT  14300000
         ST    GR2,CTWORK+16(ACT,GR1)   TO WRK BKT 'COUNTS' AREA        14320000
         SPACE                                                          14340000
         CL    GR2,CTLITA(ACT,GR1)      ANY LITS IN THIS STRING?        14360000
         BE    LTORG3                   NO                              14380000
         OI    TXESI(GRA),BIT6          YES, SET TXESI FOR F/8          14400000
         MVI   CTLIT2(ACT),1            SET LIT2 IND EQ GEN LDC         14420000
LTORG3   SR    GR1,GR0                  ALL FOUR STRINGS CHECKED?       14440000
         BNL   LTORG2                   NO                              14460000
         CLI   CTLIT2(ACT),1                 IF LIT GEN SWITCH    17835 14464000
         BE    LTORGA                          NOT ON,            17835 14468000
         XC    CTLITA(32,ACT),CTLITA(ACT)      ZERO CTLITA        17835 14472000
         OI    CTLIT3(ACT),X'01' SET 'NO LITS TO BE GEN'D SWITCH A32990 14474021
LTORGA   EQU   *                                                  17835 14476000
         SPACE                                                          14480000
         MVC   TXFAFL(32,GRB),CTWORK(ACT)  MOVE WORK BKTS TO TEXT       14500000
         TM    CTMODE(ACT),BIT2         IF IN SUBST. MODE...            14520000
         BO    LTORG5                   GO SET LIT COMPLETED IN SUBST   14540000
         SPACE                                                          14560000
         SR    SP1,SP1                  ASSIGNMENT MODE...              14580000
         LA    SP2,8                    SET FOR DOUBLE-WORD ALIGNMENT   14600000
         BAL   CRR,ALIGN                AND ALIGN LOC CNTR FOR LIT POOL 14620000
LTORG31  TM    TXESI(GRA),BIT6          LOOK FOR LITERAL IN OPERAND     14640000
         BZ    LTORG4                   NO, GO CLEAN UP                 14660000
         L     SRB,CTXTIO(ACT)          YES, READY TO PUT LIT BASE TABL 14680000
         BAL   SRR,PUTLBT(SRB)          PUTLBT IS IN IEUF7I             14700000
         MVC   0(1,SP1),CESDID(ACT)     ESDID TO LIT BASE TABLE BUFFER  14720000
         MVC   1(3,SP1),CTLOC+1(ACT)    RELATIVE ADDRESS OF 'LTORG'     14740000
         MVC   4(3,SP1),CTWORK+1(ACT)   LENGTH OF 8-BYTE STRING         14760000
         MVC   7(3,SP1),CTWORK+5(ACT)             4-BYTE STRING         14780000
         MVC  10(3,SP1),CTWORK+9(ACT)             2-BYTE STRING         14800000
         SPACE                                                          14820000
LTORG4   SR    GRX,GRX                  CLEAR GRX...                    14840000
         B     AC6                      GO TEST FOR S.T. ENTRY          14880000
         SPACE                                                          14900000
LTORG5   OI    CTLIT1(ACT),BIT4         SET 'LIT POOL COMPL. DURNG SUB' 14920000
         B     ACS2                     GO TEST NAME FIELD              14940000
         DC    X'0'                     USE TO ZERO SAVELITA            14960000
LITASAVE DC    4F'0'                    STRING COUNT SAVE AREA     9210 14990013
         EJECT                                                          15000000
* PROCESS ORG STATEMENTS (ASSIGNMENT MODE ONLY)                         15020000
         SPACE 2                                                        15040000
ORG      L     GRX,CORG(ACT)            CALL ORG/ESD/ ROUTINE           15060000
         BAL   CRR,CTLNK2(ACT)          IEUF7E VIA FUNC. ROUT. LINKAGE  15080000
         SPACE                                                          15100000
         MVC   TXLOC(3,GRB),CTLOC+1(ACT)  MOVE NEW LOC COUNTER TO TEXT  15120000
         SPACE                                                          15140000
ORGEXIT  B     AC1                      FINISH THIS STATEMENT           15160000
         EJECT                                                          15180000
* PROCESS START, CSECT, DSECT, COM STATEMENTS                           15200000
         SPACE                                                          15220000
*********************************************************************** 15240000
START    L     GRX,CSTART(ACT)          START (ASSIGNMENT MODE)         15260000
         B     ESDWB0                   GRX IS READY FOR JUMP AT ESDWB2 15280000
CSECT    L     GRX,CCSECT(ACT)          CSECT (ASSIGNMENT MODE)         15300000
         B     ESDWB0                                                   15320000
DSECT    L     GRX,CDSECT(ACT)          DSECT (ASSIGNMENT MODE)         15340000
         B     ESDWB0                                                   15360000
COM      L     GRX,CCOM(ACT)            COM   (ASSIGNMENT MODE)         15380000
         B     ESDWB0                                                   15400000
ESDWB    L     GRX,CESWBK(ACT)          (SUBSTITUTION MODE)             15420000
*        B     ESDWB0                                                   15440000
*********************************************************************** 15460000
         SPACE                                                          15480000
ESDWB0   LA    GR1,TXFAFL(GRB)          LOOK PAST APPENDED FIXED FIELD  15500000
         C     GR1,CTXWBP(ACT)          IF 1ST SYMB. WRK BKT IS THERE.. 15520000
         BE    ESDWB1                   GO SET DSECT-COM INDICATOR      15540000
         ST    GR1,CTXWBP(ACT)          SET 1ST SYMB WRK BKT POINTER    15560000
         MVI   TXWTYP(GR1),BIT0+BIT4    SET W.B. TYPE 2                 15580000
         MVC   1(5,GR1),CTZERO(ACT)     ZERO REST OF W.B.               15600000
         SR    GR1,GRA                  DISPLACEMENT OF WRK BKT...      15620000
         LA    GR1,6(GR1)               PLUS WRK BUCKET LENGTH...       15640000
         STH   GR1,TXRL(GRA)            IS TEXT RECORD LENGTH           15660000
         SPACE                                                          15680000
ESDWB1   NI    CTDORCI(ACT),X'FF'-BIT3  SET CURRENTLY IN DSECT OR COM   15700000
         CLI   TXHEX(GRA),X'1D'         INDICATOR                       15720000
         BL    ESDWB2                   OFF, IF CSECT OR START          15740000
         OI    CTDORCI(ACT),BIT3        ON, IF DSECT OR COM             15760000
         SPACE                                                          15780000
ESDWB2   BAL   CRR,CTLNK2(ACT)          IEUF7E VIA FUNC. ROUT. LINKAGE  15800000
         B     AC1                      GO FINISH STATEMENT             15820000
         EJECT                                                          15840000
* PROCESS EXTRN, WXTRN AND ENTRY STATEMENTS                        I004 15860020
         SPACE                                                          15880000
*********************************************************************** 15900000
EXTRN    L     CRR,CEXTRN(ACT)          EXTRN (ASSIGNMENT MODE)         15920000
         NI    CTSWXT(ACT),SETEXT       SET SWITCH TO NOT WXTRN    I004 15926020
         B     EXT                      GO TO COMMON CODE          I004 15932020
WXTRNS   EQU   *                        WXTRN (SUBSTITUTION MODE)  I004 15938020
EXTRNS   L     CRR,CEXTRS(ACT)          EXTRN (SUBSTITUTION MODE)  I004 15944020
         B     EXT                      GO TO COMMON CODE          I004 15950020
WXTRN    L     CRR,CEXTRN(ACT)          WXTRN (ASSIGNMENT MODE)    I004 15956020
         OI    CTSWXT(ACT),SETWX        SET SWITCH TO WXTRN        I004 15962020
EXT      L     FRB,CTXWBP(ACT)          PTR TO 1ST SYMB.WRK BKT.   I004 15968020
         L     FRB,CTXWBP(ACT)          POINTER TO FIRST SYMBOL WRK BKT 15980000
         LTR   FRB,FRB                  LOOK AT IT CLOSELY              16000000
         BNZ   EXTGO                    IF OK, SKIP SYMB. WRK BKT BUILD 16020000
         B     EXT0                     NOT YET, SO BUILD SWB           16040000
ENTRY    L     CRR,CENTRY(ACT)          ENTRY (ASSIGNMENT MODE)         16060000
         B     EXT0                                                     16080000
ENTRYS   L     CRR,CENTRS(ACT)          ENTRY (SUBSTITUTION MODE)       16100000
*        B     EXT0                                                     16120000
*********************************************************************** 16140000
         SPACE                                                          16160000
EXT0     LA    FRB,TXFAFL(GRB)                                          16180000
         ST    FRB,CTXWBP(ACT)                                          16200000
         SPACE                                                          16220000
         TM    CTCLSI(ACT),BIT3                                         16240000
         BO    EXTGO                                                    16260000
         MVC   CTWORK(IALPHA+1,ACT),CTWORK-1(ACT)  SET CTWORK FOR TRT   16280000
         MVI   CTWORK+IALPHA+1(ACT),X'FF'          ON NON A/N CHARACTER 16300000
         MVC   CTWORK+IALPHA+2(254-IALPHA,ACT),CTWORK+IALPHA+1(ACT)     16320000
         L     SP2,CTXOFP(ACT)          ADDRESS OF OPERAND-1            16340000
EXT1     MVC   1(5,FRB),CTZERO(ACT)     ZERO SYMB WRK BKT               16360000
         MVI   TXWTYP(FRB),BIT0         MAKE SWB TYPE 2                 16380000
         LA    SP1,1(SP2)               ADDRESS OPERAND FIELD           16400000
         TRT   0(256,SP1),CTWORK(ACT)   TEST OPERAND                    16420000
         LR    SP2,GR1                  GET ADDRESS OF DELIMITER        16440000
         SR    GR1,SP1                  RELATIVE TO OPND START          16460000
         BNH   EXTERR2                  FIRST NOT ALPHAMERIC, LOG ERROR 16480000
         STC   GR1,TXSBLN(FRB)          INSERT SYMBOL BYTE LENGTH       16500000
         CLI   TXSBLN(FRB),8            BEST BE LESS THAN 9             16520000
         BH    EXTERR1                  NO, LOG ERROR                   16540000
         CLI   0(SP1),IA                YES, FIRST BYTE SHOULD BE ALPHA 16560000
         BC    10,EXT2                  OK, CONTINUE                    16580000
EXTERR1  BAL   SRR,ERROR                BAD, LOG ERROR                  16600000
         DC    AL2(ACER31)              'INVALID SYMBOL'                16620000
         B     EXT3                     GO LOOK FOR COMMA AT END        16640000
EXT2     S     SP1,CTXOFP(ACT)          FROM CTXOFP TO SP1...           16660000
         BCTR  SP1,0                    -1, = RELATIVE POS'N OF SYMBOL  16680000
         STC   SP1,TXSPTR(FRB)          SET POINTER TO SYMBOL IN OPND   16700000
         LA    FRB,6(FRB)               NEXT SYMB WK BKT ADDRESS...     16720000
         LR    GR1,FRB                  TO GR1, THEN...                 16740000
         SR    GR1,GRA                  POS'N RELATIVE TO TEXT FBA...   16760000
         STH   GR1,TXRL(GRA)            BECOMES CURRENT TEXT REC. LNGTH 16780000
EXT3     CLI   0(SP2),ICOMMA            OPND MAY END WITH COMMA         16800000
         BE    EXT1                     YES, GO BACK, START ANOTHER SWB 16820000
         CLI   0(SP2),IBLANK            NO, LOOK FOR BLANK              16840000
         BE    EXT4                     BLANK, END OF OPND FIELD        16860000
         S     FRB,=F'6'                NOT BLANK OR COMMA, BACK UP FRB 16880000
         LH    GR1,TXRL(GRA)            ERASE LAST SYMB WK BKT...       16900000
         S     GR1,=F'6'                SHORTEN TEXT LENGTH...          16920000
         STH   GR1,TXRL(GRA)            AND RESTORE TO ACT              16940000
         LR    SP1,SP2                  POINT TO BAD CHARACTER WITH SP1 16960000
EXTERR2  BAL   SRR,ERROR                LOG ERROR                       16980000
         DC    AL2(ACER30)              ILLEGAL DELIMITER               17000000
EXT4     LA    GR1,6                    MAKE A 6...                     17020000
         SR    FRB,GR1                  SUBTRACT IT FROM SWB ADDRESS    17040000
         CR    FRB,GRB                  SEE IF ALL W.B.'S WERE ERASED   17060000
         BNH   AC2                      YES, GO PROCESS ANOTHER STATMNT 17080000
         OI    TXESI(GRA),BIT6          SET FLAG TO CALL IEUF7E         17100000
         OI    TXSESL(FRB),BIT0         SET LAST ENTRY IN OPERAND       17120000
         SPACE                                                          17140000
EXTGO    TM    TXESI(GRA),BIT6          LOOK AT IEUF7E FLAG             17160000
         BZ    AC2                      OFF, RETURN TO GET NEXT STATMNT 17180000
         LR    GRX,CRR                  SET ROUTINE SELECTED BY ENTRY.. 17200000
         BAL   CRR,CTLNK2(ACT)          TO IEUF7E VIA FUNC. ROUT. LINK  17220000
         B     AC1                      RETURN TO FINISH STATEMENT      17240000
         MVC   ACSYWB(4),CTXWBP(ACT)    ABNORMAL RETURN..SET SWB PNTR   17260000
         B     SMODE                    CHANGE MODE TO SUBSTITUTION     17280000
         EJECT                                                          17300000
* PROCESS END STATEMENT                                                 17320000
         SPACE 2                                                        17340000
END      L     GR1,CTLITB+00(ACT)       CHECK LITERAL POOL              17360000
         A     GR1,CTLITB+04(ACT)       FOR ACTIVE ENTRIES              17380000
         A     GR1,CTLITB+08(ACT)                                       17400000
         A     GR1,CTLITB+12(ACT)                                       17420000
         BZ    AC1                      NONE, GO FINISH UP              17440000
         SPACE                                                          17460000
         TM    TXESI(GRA),BIT6          HAS LTORG BEEN GENERATED        17480000
         BO    AC1                      YES, GO FINISH STATEMENT        17500000
         SPACE                                                          17520000
         MVI   CTLIT2(ACT),4            NO, SET FLAG TO GENERATE LTORG  17540000
         OI    TXESI(GRA),BIT6          FLAG TO INDICATE LTORG GEN'D    17560000
         CLC   CTESRN(2,ACT),CTZERO(ACT) DO WE HAVE A CSECT      A27018 17568019
         BNE   END1                     YES                      A27018 17576019
         BAL   CRR,UPC1                 NO, WELL INITIATE ONE    A27018 17584019
END1     B     AC1                      GO FINISH STATEMENT      A27018 17592019
         EJECT                                                          17600000
* PHASE 7 WRAP-UP (QUIT STATEMENT GENERATED BY EOF IN ASSIGNMENT MODE)  17620000
         SPACE 2                                                        17640000
QUIT     OI    CTPH7C(ACT),BIT6         SET F/7 COMPLETE INDICATOR      17660000
         SPACE                                                          17680000
         L     GRX,CQUIT(ACT)           CALL ESD WRAP-UP ROUTINE        17700000
         BAL   CRR,CTLNK2(ACT)          IEUF7E VIA FUNC. ROUT. LINKAGE  17720000
         SPACE                                                          17740000
QUIT0    BC    0,QUIT1                  /MOD BY AC0/                    17760000
         L     FRB,CTESTR(ACT)          TO CALL TESTRAN ROUTINE         17780000
         BALR  CRR,ACT                  IF TESTRAN OPTION BIT IS ON     17800000
         SPACE                                                          17820000
QUIT1    L     SRB,CTXTIO(ACT)          TRANSFER CONTROL TO NEXT PHASE  17840000
         B     PHCLS(SRB)               VIA PHASE CLOSE ROUTINE         17860000
         EJECT                                                          17880000
* PROCESS DXD, CXD                                                      17900000
         SPACE 2                                                        17920000
DXD      MVC   ACTEMP0(4),CTLOC(ACT)    SAVE LOC'N COUNTER              17940000
         MVC   CTLOC(4,ACT),=F'1'       AND PUT BACK 1                  17960000
         MVC   TXLOC(3,GRB),CTLOC+1(ACT) PUT THE 1 INTO TEXT RECORD TOO 17980000
         SPACE                                                          18000000
DXDS     L     FRB,CDCVAL(ACT)         CALL IEUF7D VIA FUNCTIONAL ROU-  18020000
         BALR  CRR,ACT                  TINE LINKAGE IN ACT             18040000
         B     DXDS1                    NORMAL RETURN, CONTINUE PROC'NG 18060000
         BAL   CRR,SUBWB                ABNORMAL, ATTACH SYMB WK BKT... 18080000
         B     DXDS                     AND TRY AGAIN                   18100000
DXDS1    TM    CTMODE(ACT),BIT1+BIT2    LOOK FOR SUBS MODE OR ITERATION 18120000
         BZ    DXD1                     NO, GO TOWARD IEUF7E CALL       18140000
         BAL   CRR,SUBWB                ATTACH SYMBOL WK BKT            18160000
         B     ACS2                     BACK TO CHECK NAME FIELD        18180000
         SPACE                                                          18200000
DXD1     L     GRX,CDXD(ACT)            CALL IEUF7E VIA...              18220000
         BAL   CRR,CTLNK2(ACT)          FUNC. ROUT. LINKAGE             18240000
         MVC   CTLOC(4,ACT),ACTEMP0     RESTORE LOC COUNTER             18260000
         B     AC1                      FINISH STATEMENT                18280000
         SPACE 2                                                        18300000
CXD      SR    SP1,SP1                  SET PARAM REGS...SP1=0          18320000
         LA    SP2,4                    SP2=4                           18340000
         LR    GRX,SP2                  GRX=4  FOR 0,4 ALIGNMENT        18360000
         BAL   CRR,ALIGN                ALIGN LOC CNTR                  18380000
         B     AC5                      RETURN TO STEP LOC COUNTERIEUN1 18380718
         EJECT                                                    IEUN1 18381418
* PROCESS OPSYN                                                   IEUN1 18382118
         SPACE 2                                                  IEUN1 18382818
         EXTRN OPC04                    OP-TABLE ACCESS, F7X      IEUN1 18383518
         SPACE ,                                                  IEUN1 18384218
OPSYN    TM    CTCLSI(ACT),BIT3         CHECK 1ST PASS            IEUN1 18384918
         BO    AC2                      NO, IGNORE OPSYN          IEUN1 18385618
         L     SP1,CTXOFP(,ACT)         POINT TO OPND LENG FIELD  IEUN1 18386318
         SR    SP2,SP2                                            IEUN1 18387018
         IC    SP2,0(,SP1)              ADJUST LENGTH FOR BLANK   IEUN1 18387718
         BCTR  SP2,0                                              IEUN1 18388418
         SR    GRZ,GRZ                  PRE-SET TO ZERO           IEUN1 18389118
         CLI   TXOPN(SP1),IBLANK        CHECK OMITTED OPND        IEUN1 18389818
         BE    OPS02                    YES, BYPASS LOOKUP        IEUN1 18390518
         BAL   SRR,OPSLUP               NO, LOOK IT UP            IEUN1 18391218
         B     AC2                      NOT FOUND, OVERFLOWED     IEUN1 18391918
         LR    GRZ,SP2                  SAVE ATTRIBUTES PNTR      IEUN1 18392618
OPS02    LA    SP1,TXNAML(,GRA)         POINT TO NAME LENG FIELD  IEUN1 18393318
         SR    SP2,SP2                                            IEUN1 18394018
         IC    SP2,0(,SP1)              GET LENGTH                IEUN1 18394718
         BAL   SRR,OPSLUP               LOOK IT UP                IEUN1 18395418
         B     OPS06                    NOT FOUND                 IEUN1 18396118
         LTR   GRZ,GRZ                  CHECK DELETE              IEUN1 18396818
         BNZ   OPS04                    NO                        IEUN1 18397518
         MVI   0(SP1),0                 DELETE IT                 IEUN1 18398218
         B     AC2                      EXIT                      IEUN1 18398918
OPS04    MVC   0(3,SP2),0(GRZ)          CHANGE ATTRIBUTES         IEUN1 18399618
         B     AC2                                                IEUN1 18400318
OPS06    LTR   GRZ,GRZ                  CHECK DELETE              IEUN1 18401018
         BZ    AC2                      YES, OVERFLOWED           IEUN1 18401718
         EX    0,OPS04                  SET ATTRIBUTES            IEUN1 18402418
         SR    SP1,SP1                                            IEUN1 18403118
         IC    SP1,CTWORK(,ACT)         GET LENGTH                IEUN1 18403818
         LA    FRB,3(,SP1)              SAVE ITEM LENGTH - 1      IEUN1 18404518
         LA    SP1,7(,SP1)              FORM TOTAL NEEDED         IEUN1 18405218
         L     SRB,CSTROM(,ACT)         GO CHECK FOR ROOM         IEUN1 18405918
         BALR  SRR,SRB                                            IEUN1 18406618
         B     OPS08                    NO ROOM                   IEUN1 18407318
         L     GR1,CTSYMP(,ACT)         SYMBOL TABLE PNTR         IEUN1 18408018
         L     GR2,CFREEP(,ACT)         REL FREE PNTR             IEUN1 18408718
         LA    GRX,OPCPTR(,GR1)         OPSYN CHAIN PNTR          IEUN1 18409418
         ALR   GR1,GR2                  FULL FREE PNTR            IEUN1 18410118
         MVC   0(3,GR1),0(GRX)          BACK CHAIN NEW ITEM       IEUN1 18410818
         MVC   0(3,GRX),CFREEP+1(ACT)   NEW OPSYN CHAIN PNTR      IEUN1 18411518
         EX    FRB,OPMOVE               MOVE IN NEW ITEM          IEUN1 18412218
         LA    GR2,4(FRB,GR2)           UPDATE FREE PNTR          IEUN1 18412918
         ST    GR2,CFREEP(,ACT)                                   IEUN1 18413618
         B     AC2                      EXIT                      IEUN1 18414318
OPS08    CLI   OPCAD,0                  IF ALREADY FLAGGED        IEUN1 18415018
         BNE   AC2                      EXIT                      IEUN1 18415718
         MVI   OPCAD,8                  OTHERWISE SET FLAG        IEUN1 18416418
         BAL   SRR,ERROR0               AND LOG ERROR             IEUN1 18417118
         DC    AL2(ACER02)                                        IEUN1 18417818
         B     AC2                      EXIT                      IEUN1 18418518
OPMOVE   MVC   3(0,GR1),CTWORK(ACT)     DUMMY MOVE                IEUN1 18419218
         EJECT                                                    IEUN1 18419918
* OP-CODE LOOKUP FOR OPSYN                                        IEUN1 18420618
* ENTRY-  SP1 POINTS TO LENGTH FIELD IN TEXT                      IEUN1 18421318
*         SP2 CONTAINS TRUE SYMBOL LENGTH                         IEUN1 18422018
* EXIT -  SP1 POINTS TO SYMBOL IN TABLE IF FOUND                  IEUN1 18422718
*         SP2 POINTS 1 PAST SYMBOL IN TABLE OR IN WORK AREA       IEUN1 18423418
*        BR    SRR     - NOT FOUND RETURN                         IEUN1 18424118
*        B     4(SRR)  - FOUND RETURN                             IEUN1 18424818
         SPACE 2                                                  IEUN1 18425518
OPSLUP   STC   SP2,CTWORK(,ACT)         SET UP LENGTH             IEUN1 18426218
         MVC   CTWORK+1(8,ACT),1(SP1)   AND SYMBOL                IEUN1 18426918
         LA    GR1,5                                              IEUN1 18427618
         CLR   SP2,GR1                  IF LONGER THAN 5          IEUN1 18428318
         BH    OPSL07                   SKIP OP TABLE SEARCH      IEUN1 18429018
         LR    GRY,SP2                                            IEUN1 18429718
         BCTR  GRY,0                    FORM L - 1                IEUN1 18430418
         STC   GRY,OPSL02+1             SET COMPARE               IEUN1 18431118
         SLL   GRY,2                    4(L-1)                    IEUN1 18431818
         L     GR1,OPCAD                ACCESS 7X OPTABL POINTERS IEUN1 18432518
         L     SP1,0(GRY,GR1)           SET START                 IEUN1 18433218
         L     GRY,4(GRY,GR1)           SET LIMIT                 IEUN1 18433918
         LA    GRX,3(,SP2)              SET INCREMENT             IEUN1 18434618
OPSL02   CLC   CTWORK+1(0,ACT),0(SP1)   COMPARE SYMBOL            IEUN1 18435318
         BH    OPSL06                   KEEP SEARCHING            IEUN1 18436018
         BL    OPSL07                   FAR ENOUGH, TRY OPSYN TAB IEUN1 18436718
OPSL04   LA    SP2,0(SP2,SP1)           STEP OVER SYMBOL          IEUN1 18437418
         B     4(,SRR)                  FOUND RETURN              IEUN1 18438118
OPSL06   BXLE  SP1,GRX,OPSL02           CHECK NEXT IF ANY         IEUN1 18438818
OPSL07   MVI   CTWORK+16(ACT),0         SET UP CHAIN-LOADER       IEUN1 18439518
         L     GR1,CTSYMP(,ACT)         GET SYMBOL TABLE BASE     IEUN1 18440218
         LA    SP1,OPCPTR(,GR1)         ACCESS OPSYN CHAIN        IEUN1 18440918
         STC   SP2,OPSL09+1             SET COMPARE               IEUN1 18441618
OPSL08   MVC   CTWORK+17(3,ACT),0(SP1)  GET CHAIN POINTER         IEUN1 18442318
         L     SP1,CTWORK+16(,ACT)                                IEUN1 18443018
         LTR   SP1,SP1                  IS THIS END OF CHAIN      IEUN1 18443718
         BZ    OPSL12                   YES, GIVE UP              IEUN1 18444418
         ALR   SP1,GR1                  FORM FULL POINTER         IEUN1 18445118
OPSL09   CLC   CTWORK(0,ACT),3(SP1)     COMPARE L AND SYMBOL      IEUN1 18445818
         BNE   OPSL08                   NO MATCH                  IEUN1 18446518
         LA    SP1,4(,SP1)              STEP OVER POINTER AND L   IEUN1 18447218
         B     OPSL04                   TO FOUND EXIT             IEUN1 18447918
OPSL12   LA    SP2,CTWORK+1(SP2,ACT)    POINT PAST WORK SYMBOL    IEUN1 18448618
         BR    SRR                      NOT FOUND RETURN          IEUN1 18449318
OPCAD    DC    A(OPC04)                 OP TABLE POINTERS,FLAG    IEUN1 18450018
OPCPTR   EQU   28                       OPSYN CHAIN DISPLACEMENT  IEUN1 18450718
         EJECT                                                    IEUN1 18451418
* ALIGN - SUBROUTINE TO ALIGN LOC COUNTER FOR MOP, CNOP, CCW AND LTORG  18452118
*         ENTER WITH SP1 EQ B, SP2 EQ W, CRR EQ RETURN ADDR             18460000
*         SET CTLOC, TXLOC AND TXALIN                                   18480000
         SPACE 2                                                        18500000
ALIGN    LR    GR1,SP2                  W EQ 2,4 OR 8                   18520000
         BCTR  GR1,0                    SET MASK Q  1,3 OR 7            18540000
         N     GR1,CTLOC(ACT)           MASK LOW 1,2 OR 3 BITS OF CTLOC 18560000
         CLR   GR1,SP1                  COMPARE WITH B                  18580000
         BE    ALIGN3                   NO ALIGNMENT REQUIRED           18600000
         BL    ALIGN1                   B GR MASKED BITS                18620000
         LA    SP1,0(SP1,SP2)           B LS MASKED BITS, ADD W         18640000
ALIGN1   SR    SP1,GR1                  B MINUS MASKED BITS             18660000
         STC   SP1,ALIGN2+1             STORE NUMBER OF ALIGN BYTES     18680000
         A     SP1,CTLOC(ACT)           INC LOC COUNTER                 18700000
         ST    SP1,CTLOC(ACT)                                           18720000
ALIGN2   OI    TXALIN(GRB),0            SET NUMBER OF ALIGN BYTES       18740000
ALIGN3   MVC   TXLOC(3,GRB),CTLOC+1(ACT)  MOVE ALIGNED LOC CTR TO TEXT  18760000
         BR    CRR                      RETURN                          18780000
         EJECT                                                          18800000
* UPC - UNINITIATED PRIVATE CODE TEST (CALLED ONCE FROM MOP AND AOP0)   18820000
         SPACE 2                                                        18840000
UPC      OI    MOP+1,X'F0'              MODIFY MLC TO BYPASS UPC        18860000
         OI    AOP0+1,X'F0'                                             18880000
         SPACE                                                          18900000
         CLI   CESDID(ACT),0            TEST CURRENT ESD ID             18920000
         BCR   7,CRR                    IF NOT ZERO, BYPASS UPC         18940000
         SPACE                                                          18960000
UPC1     L     GRX,CUPC(ACT)            IF ESDID EQ ZERO,        A27018 18980019
         B     CTLNK2(ACT)              CALL UNINITIATE P.C. ROUTINE    19000000
         EJECT                                                          19020000
         SPACE 2                                                        19040000
ERROR0   SR    SP1,SP1                  NO ERROR POINTER TO IEUF7L      19060000
ERROR    L     SRB,CLOGER(ACT)          GET ADDRESS OF ERROR LOGGER...  19080000
         BR    SRB                      AND GO THERE                    19100000
         SPACE 2                                                        19120000
ABORT    NI    TXTO(GRA),X'3F'          SET OP TYPE 'UNCHECKED'         19140000
         SPACE                                                          19160000
TRUNCATE L     GR1,CTXABP(ACT)          APPENDED FIXED FIELD POINTER    19180000
         MVI   0(GR1),0                 ZERO FIRST BYTE---              19200000
         SR    GR1,GRA                  CALCULATE DISTANCE TO           19220000
         LA    GR1,1(GR1)               LAST RECORD BYTE                19240000
*        STH   GR1,TXRL(GRA)            INSERT INTO TEXT RECORD LENGTH  19260000
         B     AC2                      GO GET NEXT STATEMENT           19280000
         EJECT                                                          19300000
* XREF - SUBROUTINE CALLED BY ACMOP  AND  ACAOP                         19320000
*        TO GENERATE TYPE 2 X-REF RECORDS                               19340000
*        FOR STATEMENTS WHICH ARE NOT EVALUATED BY PHASE 7              19360000
         SPACE 2                                                        19380000
XREF     L     SP1,CTXOFP(0,ACT)        SP1 POINTS TO OPERAND-1    9538 19386013
         SR    FRB,FRB                                             9538 19392013
         IC    FRB,TXOPNL(0,SP1)        FRB POINTS TO LAST BYTE    9538 19398013
         AR    FRB,SP1                    OF OPERAND               9538 19404013
XREF0    MVC   ACTEMP0(4),CLOGER(ACT)   DISABLE EVAL ERROR LOGGING 9538 19410013
         MVC   ACTEMP1(4),CTXWBP(ACT)   KEEP POINTER TO 1ST SYMB WK BKT 19420000
         LA    GR1,XREFX                GET ERROR HANDLING ADDRESS...   19440000
         ST    GR1,CLOGER(ACT)          AND INSERT IN ACT               19460000
         SPACE                                                          19480000
         L     SRB,CEEVAL(ACT)          SRB PTS TO EEVAL                19500000
         SPACE                                                          19600000
XREF1    LA    SP1,1(SP1)               SP1 PTS TO NEXT EXPRESSION      19620000
         CLR   SP1,FRB                                                  19640000
         BC    11,XREFEXIT              EXIT IF END OF OPERAND          19660000
         CLI   0(SP1),IALPHA            IF NEXT EXPRESSION STARTS ALPHA 19680000
         BNH   XREF2                    OK, MAKE XREF                   19700000
         CLI   0(SP1),IEQUAL            NO, LOOK FOR EQUAL              19720000
         BE    XREFEXAT                 YES, TO RESET ERROR RETURN      19740000
         B     XREF1                    NO, TRY AGAIN                   19760000
         SPACE                                                          19780000
XREF2    BALR  SRR,SRB                  SCAN NEXT EXPRESSION            19800000
         BC    14,XREF1                 NO ERROR, CHECK NEXT EXPRESSION 19820000
         SPACE                                                          19840000
         LTR   SP1,SP1                  ERROR,                          19860000
         BNE   XREF1                    CONTINUE SCAN IF POSSIBLE       19880000
         SPACE                                                          19900000
XREFEXIT MVC   CTXWBP(4,ACT),ACTEMP1                                    19920000
XREFEXAT MVC   CLOGER(4,ACT),ACTEMP0    RESTORE IEUF7L ADDRESS          19940000
         BR    CRR                      RETURN                          19960000
         SPACE                                                          19980000
XREFX    B     2(SRR)                   SUBSTITUTED IEUF7V ERROR RETURN 20000000
         EJECT                                                          20020000
* SYMF -                                                                20040000
         SPACE                                                          20060000
SYMF     CLI   TXNAML(GRA),0            TEST NAME IN NAME FIELD         20080000
         BCR   8,CRR                    NONE, RETURN                    20100000
         SPACE                                                          20120000
         TM    CTSYMF(ACT),BIT7         TEST S.T. FULL INDICATOR        20140000
         BCR   8,CRR                    NOT FULL, RETURN                20160000
         TM    TXMDN(GRA),BIT3          TEST MULT DEF. NAME FLAG        20180000
         BCR   1,CRR                    IF SET, RETURN                  20200000
         SPACE                                                          20220000
*        B     SMODE                    S.T. OVERFLOW, CHANGE MODE      20240000
         SPACE 3                                                        20260000
* SMODE - CHANGE MODE FROM ASIIGNMENT TO SUBSTITUTION                   20280000
         SPACE                                                          20300000
SMODE    OI    CTMODE(ACT),BIT2         SET MODE 'SUBSTITUTION'         20320000
         OI    AC1+1,X'F0'              SET TESTRAN GATE                20340000
         OI    TXMARK(GRA),BIT7         SET ITERATION POINT INDICATOR   20360000
         SPACE                                                          20380000
         MVC   ACLOC(3),CTLOC+1(ACT)    SAVE CURRENT LOC COUNTER        20400000
         MVC   ACSEQN(3),CTSEQN+1(ACT)  SAVE CURRENT SEQUENCE NUMBER    20420000
         MVC   LITASAVE(16),CTLITA(ACT) SAVE CTLITA                9210 20430013
         SPACE                                                          20440000
         LA    CRR,ACS1                 READY TO GO TEST OP TYPE        20460000
         SPACE                                                          20480000
SMODEX   XI    AC3+1,X'F0'              SET SUBS MODE SWITCH            20500000
         MVC   CTWORK(AOPGO4-AOPGO3,ACT),AOPGO2                         20520000
         MVC   AOPGO2(AOPGO4-AOPGO3),AOPGO3                             20540000
         MVC   AOPGO3(AOPGO4-AOPGO3),CTWORK(ACT)  RESET GO TO ADDR'S    20560000
         BR    CRR                      GO BACK TO TEST OP TYPE         20580000
         EJECT                                                          20600000
* AMODE - CHANGE MODE FROM SUBSTITUTION TO ASSIGNMENT                   20620000
         SPACE 2                                                        20640000
AMODE    NI    CTMODE(ACT),X'FF'-(BIT1+BIT2)  SET MODE EQ 00            20660000
         XI    TXMARK(GRA),BIT7         RESET ITERATION POINT INDICATOR 20680000
         XI    CTSYMF(ACT),BIT7         RESET SYM TABLE FULL INDICATOR  20700000
         NI    CTLIT1(ACT),X'FF'-BIT4   CLEAR LTORG PROCESSED INDIC.    20720000
         OI    CTITSW(ACT),BIT0         SET ITERATION SWITCH            20740000
         SPACE                                                          20760000
         TM    CTTSTI(ACT),BIT0         CHECK TESTRAN OPTION       I000 20780020
         BZ    AMODE1                   MODIFY PROGRAM TO               20800000
         NI    AC1+1,X'0F'              CALL TESTRAN ROUTINE            20820000
         SPACE                                                          20840000
AMODE1   MVC   CTLOC+1(3,ACT),ACLOC     RESTORE LOCATION COUNTER        20860000
         MVC   CTSEQN+1(3,ACT),ACSEQN           SEQUENCE NUMBER         20880000
         MVC   CTLITA(16,ACT),LITASAVE  RESTORE CTLITA             9210 20900013
         SPACE                                                          20920000
         L     GR2,ACFREE               REINITIALIZE                    20940000
         ST    GR2,CFREEP(ACT)                                          20960000
         SPACE                                                          20980000
         L     GR1,CTSYMP(ACT)          CLEAR SYM TABLE HASH POINTERS   21000000
         AR    GR2,GR1                  UP TO FREE AREA, AT LEAST       21020000
         MVI   0(GR1),0                 START WITH A ZERO               21040000
ACS2A2   MVC   1(256,GR1),0(GR1)        ZERO 256 BYTES                  21060000
         LA    GR1,256(GR1)             READY TO DO MORE                21080000
         CLR   GR1,GR2                  SEE IF WE HAVE CLEARED ENOUGH   21100000
         BL    ACS2A2                   NO, GO DO MORE                  21120000
         BAL   CRR,SMODEX               YES, GO RESET COMP. GO TO'S     21140000
         SPACE                                                          21160000
         L     GR1,ACSYWB               RESTORE WORK BUCKET POINTER     21180000
         LTR   GR1,GR1                  IF OVERFLOW OCURRED ON EXTRN    21200000
         BZ    AC3                      ELSE, BACK TO TEST OF OP TYPE   21220000
         ST    GR1,CTXWBP(ACT)          RESTORE                         21240000
         MVC   ACSYWB(4),CTZERO(ACT)    CLEAR TEMPORARY SWB POINTER     21260000
         B     AC3                      GO TEST OPERATION TYPE          21280000
         EJECT                                                          21300000
* SUBWB - S/R TO ATTACH AND FILL SYMBOL WORK BUCKETS                    21320000
         SPACE 2                                                        21340000
SUBWB    L     FRB,CTXWBP(ACT)          BYPASS SCAN IF WORK BUCKETS     21360000
         LTR   GRZ,FRB                  PREVIOUSLY ATTACHED             21380000
         BNZ   SUBWBA                   HAVE BUCKETS, WILL SKIP         21400000
         SPACE                                                          21420000
         MVC   CTWORK(256,ACT),CTWORK-1(ACT)  INITIALIZE TRT TABLE      21440000
         MVI   CTWORK+IQUOTE(ACT),X'FF'                                 21460000
         LA    GRY,2                    GRY CONTAINS LPARN COUNT (=2)   21480000
         L     GR1,CTXOFP(ACT)          GR1 PTS TO NEXT OPND BYTE-1     21500000
         IC    GRZ,0(GR1)                                               21520000
         AR    GRZ,GR1                                                  21540000
         SR    GRZ,GRY                  GRZ PTS TO FINAL OPND BYTE-2    21560000
         LH    FRB,TXRL(GRA)                                            21580000
         AR    FRB,GRA                  FRB PTS TO FIRST WORK BUCKET    21600000
         LR    GRX,FRB                  GRX PTS TO NEXT  WORK BUCKET    21620000
         SPACE                                                          21640000
         LA    SRR,SUBWB2               READY THE RETURN REG            21660000
         TM    TXTO(GRA),BIT0           INSPECT OPERATION TYPE          21680000
         BO    SUBWB0                   ASSEMBLER OP, SKIP              21700000
         MVI   CTWORK+IEQUAL(ACT),X'FF' PUT CHECK FOR = INTO TABLE      21720000
         B     SUBWB2                   GO RESET ALPHA CHECK            21740000
SUBWB0   TM    TXASC(GRA),BIT4          CHECK FOR SUBSITUTION REQUIRED  21760000
         BCR   1,SRR                    YES, TO 'RETURN'                21780000
         LA    SRR,SUBWB1               NO, RESET 'RETURN' POINT        21800000
         SR    GRY,GRY                  MAKE A ZERO                     21820000
         SPACE                                                          21840000
SUBWB1   XI    CTWORK+ILPARN(ACT),X'FF' SET TRT TABLE FOR COMPARE       21860000
         XI    CTWORK+IRPARN(ACT),X'FF' ON PARENS (IF DC,DS,LDC OR DXD) 21880000
SUBWB2   XI    CTWORK+IA(ACT),X'FF'     AND ALPHA CHARACTERS            21900000
         MVC   CTWORK+IB(28,ACT),CTWORK+IA(ACT)                         21920000
         SPACE                                                          21940000
SUBWB3   LR    GR2,GRZ                  CALC NUMBER OF BYTES TO SCAN    21960000
         SR    GR2,GR1                                                  21980000
         BM    SUBWB9                   NONE                            22000000
         EX    GR2,SUBWBT               EXECUTE TRT FOR ALPHA OR DELIMS 22020000
         BZ    SUBWB9                   NONE                            22040000
         SPACE                                                          22060000
         CLI   0(GR1),IALPHA            IF ALPHA, TEST FOR SYMBOL       22080000
         BNH   SUBWB4                                                   22100000
         CLI   0(GR1),IQUOTE            IF QUOTE, CHANGE TRT TABLE      22120000
         BCR   8,SRR                              AND RESUME SCAN       22140000
         CLI   0(GR1),IEQUAL            NOW TEST FOR EQUAL SIGN         22160000
         BNE   SUBWB300                 NO, GO LOOK FOR PAREN           22180000
         CLI   CTWORK+IA(ACT),0         YES, LOOK AT ALPHAS IN TRT TABL 22200000
         BE    SUBWB300                 NOT TESTED, GO LOOK FOR PAREN   22220000
SUBWB30  LA    GR1,1(GR1)               NEXT OPERAND BYTE               22240000
         CLI   1(GR1),IALPHA            TEST BYTE FOLLOWING FOR ALPHA   22260000
         BH    SUBWB3                   ALPHA, GO CALCULATE SCAN        22280000
         B     SUBWB30                  NUMERIC, TRY AGAIN              22300000
         SPACE                                                          22320000
SUBWB300 CLI   0(GR1),ILPARN            IF PAREN, SET PAREN COUNTER     22340000
         BNE   SUBWB31                            AND RESUME SCAN       22360000
         A     GRY,=F'1'                                                22380000
         B     SUBWB3                                                   22400000
SUBWB31  S     GRY,=F'1'                RIGHT PAREN--REDUCE PAREN CNT   22420000
         B     SUBWB3                   RESUME SCAN                     22440000
         SPACE                                                          22460000
SUBWBT   TRT   1(0,GR1),CTWORK(ACT)     TRT USED BY SUBWB3              22480000
         EJECT                                                          22500000
SUBWB4   LR    GR2,GR1                  ALPHA CHAR FOUND OUTSIDE QUOTES 22520000
SUBWB41  LA    GR1,1(GR1)               SCAN FOR NON A/N DELIMETER      22540000
         CLI   0(GR1),IALPHA                                            22560000
         BNH   SUBWB41                                                  22580000
         CLI   0(GR1),IQUOTE                                            22600000
         BNE   SUBWB5                   DELIMITED BY NON-QUOTE, SYMBOL. 22620000
         CLI   0(GR2),IL                DELIMITED BY QUOTE,             22640000
         BCR   7,SRR                    RESET TRT TABLE IF NOT L-QUOTE  22660000
         SPACE                                                          22680000
         LA    GR2,1(GR1)               L-QUOTE                         22700000
SUBWB42  LA    GR1,1(GR1)               SCAN SYMBOL                     22720000
         CLI   0(GR1),IALPHA            LOOK FOR ALPHAMERICS            22740000
         BNH   SUBWB42                  A-N, CONTINUE SCAN              22760000
         CR    GR1,GR2                  NOT ALPHA...IF FIRST BYTE...    22780000
         BE    SUBWB9                   SYNTAX ERROR...GO TO.SCAN COMPL 22800000
         MVC   0(6,GRX),CTZERO(ACT)     CLEAR WORK BUCKET               22820000
         MVI   TXSESD(GRX),X'FF'        SET ESDID                       22840000
         B     SUBWB50                  GO ATTACH BUCKET                22860000
         SPACE                                                          22880000
SUBWB5   LTR   GRY,GRY                  SYMBOL FOUND IF NOT IN DC       22900000
         BNP   SUBWB51                  OUTSIDE OF PARENS               22920000
         MVC   0(6,GRX),CTZERO(ACT)     ATTACH SYMBOL WORK BUCKET       22940000
SUBWB50  MVI   TXWTYP(GRX),BIT0         SET WK BKT TYPE 2               22960000
         LR    GR0,GR1                  SYMBOL END...                   22980000
         SR    GR0,GR2                  - SYMBOL START...               23000000
         STC   GR0,TXSBLN(GRX)          BECOMES SYMBOL BYTE LENGTH      23020000
         S     GR2,CTXOFP(ACT)          SYMBOL START-OPND START...      23040000
         BCTR  GR2,0                    LESS ONE...                     23060000
         STC   GR2,TXSPTR(GRX)          BECOMES POINTER TO SYMB IN OPND 23080000
         LA    GRX,6(GRX)               ADVANCE POINTER TO NEXT W.B.    23100000
SUBWB51  BCT   GR1,SUBWB3                                               23120000
         SPACE                                                          23140000
SUBWB9   CR    GRX,FRB                  SCAN COMPLETE, TEST IF ANY WBS  23160000
         BCR   8,CRR                    NONE, EXIT                      23180000
         LA    GR1,6                    DECREMENT BY 6                  23200000
         SR    GRX,GR1                  ADDRESS LAST WORK BUCKET        23220000
         OI    TXSLAS(GRX),BIT4         SET 'LAST SYMBOL IN OPERAND'    23240000
         ST    FRB,CTXWBP(ACT)          SET SYMBOL W.B. POINTER IN ACT  23260000
         SR    GRX,GRA                                                  23280000
         LA    GRX,6(GRX)                                               23300000
         STH   GRX,TXRL(GRA)            INC REC LENGTH                  23320000
*        B     SUBWBA                   SUBSTITUTE VALUES IN WORK BKTS  23340000
         EJECT                                                          23360000
SUBWBA   TM    TXSUBS(FRB),X'10'        TEST PREVIOUSLY SUBSTITUTED     23380000
         BO    SUBWBX                   YES, TEST END OF W.B.S          23400000
*                                                                       23420000
         SR    SP1,SP1                  NO, CALL STGET                  23440000
         IC    SP1,TXSPTR(FRB)              WITH SP1 PT TO SYMB IN OPND 23460000
         A     SP1,CTXOFP(ACT)                                          23480000
         LA    SP1,1(SP1)                                               23500000
         SR    SP2,SP2                           SP2 EQ SYMB BYTE LEN   23520000
*        IC    SP2,TXSBLN(FRB)          FIND SYMBOL BYTE LENGTH         23540000
         L     SRB,CSTGET(ACT)          CALL S.T. GET ROUTINE IN IEUF7S 23560000
         BALR  SRR,SRB                  THROUGH COMMON SUBROUT. LINKAGE 23580000
*                                                                       23600000
         LTR   SP1,SP1                  RETURN WITH SP1 PT TO ST ENTRY  23620000
         BZ    SUBWBX                   OR ZERO INDICATES NOT IN ST     23640000
         CLI   TXSESD(FRB),0            LOOK FOR ESDID ZERO             23660000
         BE    SUBWBB                   FOUND, GO MOVE VALUE TO W.B.    23680000
         XI    TXSESD(FRB),0                                            23700000
         MVC   TXSVAL+1(2,FRB),6(SP1)   LENGTH, FROM S.T. TO W.B.       23720000
         B     SUBWBD                   GO MOVE ESDID TO W.B.           23740000
SUBWBB   NOP   0                                                        23760000
*                                                                       23780000
         MVC   TXSVAL(3,FRB),3(SP1)     MOVE VALUE TO W.B.              23800000
         CLI   6(SP1),0                 SET TXSEXI IF LEN GR 256        23820000
         BE    SUBWBC                   NO, GO MOVE LENGTH TO W.B.      23840000
         OI    TXSEXI(FRB),X'04'        SET 'IMPL'D LENGTH OVER 256'    23860000
         B     SUBWBD                   GO MOVE ESDID                   23880000
SUBWBC   MVC   TXSLEN(1,FRB),7(SP1)     MOVE LEN (LE 256) TO W.B.       23900000
SUBWBD   MVC   TXSESD(1,FRB),2(SP1)     MOVE ESD ID TO W.B.             23920000
         MVC   CTWORK(1,ACT),1(SP1)     SET TYPE FROM ADJ CODE          23940000
         NI    CTWORK(ACT),X'03'                                        23960000
         OC    TXSTPC(1,FRB),CTWORK(ACT)                                23980000
         TM    1(SP1),X'04'             SET DSECT/COM IND. FROM ADJCOD  24000000
         BZ    SUBWBE                   GO SET VALUE SUBSTITUTED        24020000
         OI    TXSDOC(FRB),X'20'        SYMBOL DEFINED IN DSECT OR COM  24040000
*                                                                       24060000
SUBWBE   OI    TXSUBS(FRB),X'10'        SET VALUE SUBSTITUTED INDICATOR 24080000
*                                                                       24100000
SUBWBX   TM    TXSLAS(FRB),X'08'        TEST FOR LAST SYMBOL W.B.       24120000
         BCR   7,CRR                    RETURN TO CALLING ROUTINE       24140000
         LA    FRB,6(FRB)               INC POINTER TO NEXT SYMB W.B.   24160000
         B     SUBWBA                   PROCESS NEXT SYMB W.B.          24180000
         EJECT                                                          24200000
         SPACE                                                          24540000
         END   AC7MLC                                                   24560000
