F7D      TITLE 'DC EVALUATION - PHASE 7 --- '                           00020000
IEUF7D   START                                                          00040000
*          RELEASE 19 DELETIONS                                         00052000
* 162600                                                         A28269 00054019
*          RELEASE 20 DELETIONS                                         00056000
* 114400,214800,217000,219200                                    A28596 00058020
*          RELEASE 21 DELETIONS                                         00060000
* 000440-000512,000640-000760,154500,178600-178800               A52831 00070021
DCEVAL   EQU   IEUF7D                                                   00080000
         ISEQ  73,80                                                    00100000
         PRINT DATA,NOGEN                                               00120000
         FDIMEN                                                         00140000
         USING *,FRB                                                    00160000
*                                                                     * 00180000
*TITLE 'IEUF7D  ' ...  DC EVALUATION                                  * 00200000
*STATUS- CHANGE LEVEL  010                                            * 00220021
*FUNCTION/OPERATION-                                                  * 00240000
*   IEUF7D PROCESSES DC'S, DS'S, DXD'S, LITERALS, AND LITERAL DC'S, A * 00260000
*   COMPLETE SYNTAX CHECK IS DONE FOR ALL DC'S AND DS'S. A 15 BYTE    * 00280000
*   WORKBUCKET IS ATTACHED TO THE APPENDED FIXED FIELD FOR USE BY     * 00300000
*   IEUF8D IN THE EVALUATION OF THE OPERAND. AN EXTERNAL SYMBOL ENTRY * 00320000
*   IS MADE FOR ALL VALID V-TYPE AND Q-TYPE DC'S.                     * 00340000
*ENTRY POINT- IEUF7D                                                  * 00360000
*   ENTRY IS MADE VIA                                                 * 00380000
*        L     FRB,CDCVAL(ACT)          GET BASE/ENTRY ADDRESS        * 00400000
*        BALR  FRR,ACT                  CALL IEUF8D                   * 00420000
*INPUT- NONE                                                          * 00440000
*OUTPUT- NONE                                                         * 00460000
*EXTERNAL ROUTINES-                                                   * 00480000
*   CVCON(ACT)      ESD PROCESSING OF V AND Q TYPE CONSTANTS          * 00500000
*   CLOGER(ACT)     LOG ERROR ROUTINE                                 * 00520000
*EXITS- NORMAL                                                        * 00540000
*   RETURNS TO CALLER VIA                                             * 00560000
*        B     CTRTRN(ACT)              RETURN                        * 00580000
*     - ERROR-- SAME AS NORMAL RETURN                                 * 00600000
*TABLES/WORKAREAS-                                                    * 00620000
*   ZRC01      ERROR ASSIGNMENT TABLE                                 * 00640000
*   TRTTAB     TYPE OF MODIFIERS FOR IEUF7D TO PROCESS                * 00660000
*   TYTABL     BRANCH TABLE FOR DC/DS MODIFIERS (SEE TEXT)            * 00680000
*   WFLAG      15 BYTE DC WORKBUCKET AREA                             * 00700000
*NOTES-                                                               * 00720000
*   THE FORMAT OF THE DC WORKBUCKET IS-                               * 00740000
*   LABEL  BYTE  BIT    CONTENTS                                      * 00760000
*                                                                     * 00780000
*   WFLAG    0    0     0 - TYPE 3 WORKBUCKET                         * 00800000
*            0    1     1 - WKBKT LENGTH = 15 BYTES                   * 00820000
*            0    2     DC PREVIOUSLY PROCESSED INDICATOR             * 00840000
*            0    3     LENGTH MODIFIER PRESENT INDICATOR             * 00860000
*            0    4     LAST OPERAND INDICATOR                        * 00880000
*   WTYP     1          TYPE (SEE TRTABL) 'FF' = ERROR                * 00900000
*   WTOTL   2-4         TOTAL LENGTH                                  * 00920000
*   WDUP    5-7         DUPLICATION FACTOR                            * 00940000
*   WCONS    8          NUMBER OF CONSTANTS                           * 00960000
*   WPTR1    9          RELATIVE POINTER FIRST BYTE OPERAND           * 00980000
*   WEXP    10          EXPONENT                                      * 01000000
*   WSCL    11   0-7    SCALE MODIFIER (11 BITS TOTAL)                * 01020000
*           12   0-2    PART OF ABOVE SCALE MODIFIER                  * 01040000
*           12    3     SYMBOL WORKBUCKET FLAG                        * 01060000
*           12   4-6    ALIGNMENT (BYTES)                             * 01080000
*           12    7     LENGTH MODIFIER TYPE (0=BYTE, 1= BIT)         * 01100000
*   WLMOD  13-14        LENGTH MODIFIER VALUE                         * 01120000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 01140000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 01160000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 01180000
         EJECT                                                          01200000
DCEVL    MVI   OPCOD,0                   RESET INTERNAL OP CODE         01220000
         MVI   DCBKT,0                  RESET DC WORKBUCKET COUNTER     01240000
         MVC   SAVWBP,CTXWBP(ACT)       SAVE SYMBOL BUCKET POINTER      01260000
         TM    TXESI(GRA),2             TEST IF LIT. ENTRY (MACH OP)    01280000
         BO    LITVAL                   YES,GO TO LITERAL ROUTINE       01300000
         L     GR1,CTXABP(ACT)          PTR TO APPENDED FIXED FIELD     01320000
         MVC   OPCOD(1),TXHEX(GRA)      GET HEX OPERATION CODE          01340000
         CLI   VSCNSW,X'FF'             IF V-CON SWITCH IS ON,          01360000
         BE    INTOT                    BRANCH.                         01380000
         CLI   OPCOD,X'25'              TRST IF LITERAL DC              01400000
         BE    INTOT                    YES,DON'T BULLDOG TXLOC         01420000
         TM    CTMODE(ACT),X'60'   TEST IF ASSIGN. OR SUBSTITUTION MODE 01440000
         BNE   INTOT+6                  BRANCH IF SUBSTITUTION MODE.    01460000
         MVC   TXLOC(3,GR1),CTLOC+1(ACT) SET LOC. CTR. IN TEXT RECORD   01480000
INTOT    MVC   TOTAL(4),CTLOC(ACT)      MOVE LOC. CTR. TO WORK AREA.    01500000
         LA    GRB,TXFAFL(GR1)          SAVE DC WORK BUCKET POINTER.    01520000
         L     GR1,CTXOFP(ACT)          GET OPERAND LENGTH POINTER.     01540000
         LA    GRA,1(GR1)               GET OPERAND FIELD POINTER.      01560000
         SR    GR2,GR2                                                  01580000
         IC    GR2,0(GR1)               GET OPERAND FIELD LENGTH        01600000
         AR    GR2,GRA                                                  01620000
         ST    GR2,FINADR               STORE PTR TO END OF OPND FIELD  01640000
LITENT   ST    GRA,SAVPTR               STORE PTR TO START OF OPND.     01660000
         XC    ERSW(FCONS+1-ERSW),ERSW                                  01680000
         MVI   BITREM+1,7               SET BIT REMAINDER = 7           01700000
         CLI   OPCOD,37                 STEP PAST                       01720000
         BNE   INIT                     = SIGN IF                       01740000
         LA    GRA,1(GRA)               A LITERAL DC                    01760000
INIT     LA    GR1,1                    INITIALIZE DUPFAC AND           01780000
         ST    GR1,DUPFAC                NOCONS TO 1.                   01800000
         STC   GR1,NOCONS                                               01820000
         XC    PZLNAT(FHEDSW-PZLNAT),PZLNAT                             01840000
         SR    GRC,GRC                  ZERO SWITCHES AND GRC           01860000
         LA    GRD,1                                                    01880000
         SPACE 2                                                        01900000
* CHECK DUPLICATION FACTOR                                              01920000
         SPACE 1                                                        01940000
         CLI   0(GRA),IA                TEST FOR NUMERIC.               01960000
         BL    DCEV1                    YES-EVALUATE DUPLICATION FACTOR 01980000
         CLI   0(GRA),ILPARN            CHECK FOR LEFT PAREN.           02000000
         BNE   NODUP                    NO,THEN NO DUP FACTOR PRESENT.  02020000
         CLI   LITSW,X'FF'              TEST FOR LITERAL.               02040000
         BE    ZRC01                    YES-DUP. FACTOR ERROR.          02060000
DCEV1    BAL   SRR,XPREV                TO EXPRESSION EVALUATION        02080000
         CL    SP2,=XL4'FFFFFF'         TEST FOR VALID BOUNDS     18695 02082021
         BNH   DCEV1X                   BRANCH IF OK              18695 02084021
         L     SRB,CLOGER(ACT)          ELSE GO AND-              18695 02086021
         BALR  SRR,SRB                       LOG THE-             18695 02088000
STUPID   EQU   1                                  STUPID-         18695 02090000
         DC    AL2(STUPID)                             ERROR      18695 02092000
         SR    SP2,SP2                  ZERO DUPLICATION FACTOR   18695 02094000
DCEV1X   EQU   *                                                  18695 02096000
         ST    SP2,DUPFAC               STORE DUPLICATION FACTOR        02100000
         TM    CTMODE(ACT),X'60'   TEST IF ASSIGN. OR SUBSTITUTION MODE 02120000
         BNE   NODUP                    BRANCH IF SUBSTITUTION MODE.    02140000
         TM    RSLT,X'30'                                               02160000
         BO    ZRC01                    DUPLICATION FACTOR ERROR        02180000
         BM    ZRC02                    RELOCATABLE DUPLICATION FACTOR  02200000
         TM    CTLCRI(ACT),X'40'        WAS AN * IN THE EXPRESSION      02220000
         BO    ZRC01                    YES - DUP FACTOR ERROR          02240000
         CLI   LITSW,X'FF'              TEST FOR LITERAL.               02260000
         BNE   NODUP                    NO, EVERYTHING OK.              02280000
         SR    GR1,GR1                  YES, DUP FACTOR ERROR           02300000
         CR    SP2,GR1                   IF DUP FACTOR = 0              02320000
         BE    ZRC01                                                    02340000
         SPACE 2                                                        02360000
* CHECK DC TYPE                                                         02380000
         SPACE 1                                                        02400000
NODUP    ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           02420000
         CLI   0(GRA),I9                TEST TYPE FOR NUMERIC           02440000
         BC    12,ZRC31                 UNKNOWN TYPE                    02460000
         CLI   0(GRA),IZ                TEST FOR ALPHABETIC             02480000
         BH    ZRC31                    UNKNOWN TYPE                    02500000
         MVC   DCTYP,0(GRA)             FETCH DC TYPE FROM TEXT RECORD  02520000
         TR    DCTYP,TRTABL-10          TRANSLATE TYPE                  02540000
         CLI   DCTYP,X'FF'              TEST FOR VALID TYPE             02560000
         BE    ZRC31                    UNKNOWN TYPE                    02580000
         IC    WR1,DCTYP                BUILD                           02600000
         SLL   WR1,2                    POINTER                         02620000
         AH    WR1,DCTYP1                                               02640000
         AH    WR1,DCTYP1                                               02660000
         IC    WR2,TYTABL(WR1)          TO TYPE                         02680000
         SRL   WR2,4                    TABLE                           02700000
         IC    WR2,ILTABLE(WR2)         LENGTH CODE INTO LENGTH   IEUN2 02710018
         LA    GRA,1(GRA)               KICK TEXT POINTER               02720000
         SPACE 2                                                        02740000
* CHECK LENGTH MODIFIER                                                 02760000
         SPACE 1                                                        02780000
LMSCAN   CLI   0(GRA),IL                TEST FOR LENGTH MODIFIER        02800000
         BE    LMS1                                                     02820000
         ST    WR2,LLNG                 IMPLIED LENGTH TO L-MOD         02840000
         MVI   BITREM+1,X'07'           SET REMAINDER=7                 02860000
         B     SMSCAN    TO SCALE MODIF SCAN                            02880000
LMS1     MVI   LMSW,X'FF'      SET L-MOD SWITCH                         02900000
         OI    WFLAG,X'10'              SET L-7OD PRESENT INDICATOR     02920000
         LA    GRA,1(GRA)               KICK TEXT POINTER               02940000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           02960000
         CLI   0(GRA),IPRIOD            TEST FOR BIT LENGTH             02980000
         BE    LMS2                                                     03000000
         MVI   BITREM+1,X'07'           SET REMAINDER=7                 03020000
         B     LMS3                                                     03040000
LMS2     LA    SAVE,TYTABL(WR1)                                         03060000
         TM    0(SAVE),X'04'            TEST IF BIT SPECS LEGAL         03080000
         BZ    ZRC03                    LENGTH ERROR.                   03100000
         MVI   BITSW,X'01'              SET BIT SWITCH                  03120000
         LA    GRA,1(GRA)               KICK TEXT POINTER               03140000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           03160000
LMS3     CLI   0(GRA),I9                TEST FOR NUMERIC                03180000
         BC    12,LMS4                                                  03200000
         CLI   LITSW,X'FF'              LENGTH ERROR IF LIT. LENGTH     03220000
         BE    ZRC03                    MOD. NOT DEC. SELF-DEF. TERM.   03240000
         CLI   0(GRA),ILPARN            TEST FOR LEFT PAREN.            03260000
         BNE   ZRC03                    LENGTH ERROR.                   03280000
LMS4     BAL   SRR,XPREV                TO EXPRESSION EVALUATION        03300000
         ST    SP2,LLNG                 STORE LENGTH MODIFIER           03320000
         TM    CTMODE(ACT),X'60'   TEST IF ASSIGN. OR SUBSTITUTION MODE 03340000
         BNE   SMSCAN                   BRANCH IF SUBST. MODE     17835 03360000
         TM    RSLT,X'30'                                               03380000
         BO    ZRC03                    LENGTH ERROR                    03400000
         BM    ZRC04                    RELOCATABLE LENGTH              03420000
         TM    CTLCRI(ACT),X'40'        WAS AN * IN THE EXPRESSION      03440000
         BO    ZRC03                    YES - LENGTH MODIFIER ERROR     03460000
SUBS2    L     SAVE,LLNG                                                03480000
         CLI   BITSW,X'01'                                              03500000
         BNE   LMS5                                                     03520000
         LA    SAVE,7(SAVE)                                             03540000
         SRL   SAVE,3                                                   03560000
LMS5     IC    WR2,TYTABL+1(WR1)       TEST MIN L-MOD VALUE             03580000
         CR    SAVE,WR2                                                 03600000
         BL    ZRC03                    LENGTH ERROR.                   03620000
         IC    WR2,TYTABL+2(WR1)       TEST MAX L-MOD VALUE             03640000
         LA    WR2,1(WR2)               GET UPPER LIMIT                 03660000
         CR    SAVE,WR2                                                 03680000
         BH    LMS6                                                     03700000
         B     SMSCAN                                                   03720000
LMS6     CLI   OPCOD,DS                                                 03740000
         BL    ZRC03                    LENGTH ERROR.                   03760000
         CLI   DCTYP,1                  LENGTH ERROR IF NOT CHARACTER   03780000
         BH    ZRC03                     OR HEXADECIMAL DS.             03800000
LMS7     CL    SAVE,DSMAX              TEST MAX L-MOD VALUE FOR DS      03820000
         BH    ZRC03                    LENGTH ERROR.                   03840000
         SPACE 2                                                        03860000
* CHECK SCALE MODIFIER                                                  03880000
         SPACE 1                                                        03900000
SMSCAN   MVI   SIGN,X'00'               INITIALIZE SIGN TO PLUS         03920000
         CLI   0(GRA),IS                TEST FOR SCALE MODIFIER         03940000
         BNE   EMSCAN                   TO EXPONENT MODIFIER SCAN       03960000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           03980000
         LA    SAVE,TYTABL(WR1)                                         04000000
         TM    0(SAVE),X'02'            IS SCALE MODIFIER LEGAL         04020000
         BZ    ZRC11                    SCALE MODIFIER ERROR.           04040000
         LA    GRA,1(GRA)               KICK TEXT POINTER               04060000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           04080000
         CLI   0(GRA),IPLUS             TEST FOR PLUS SIGN              04100000
         BE    SMS1                                                     04120000
         CLI   0(GRA),IMINUS            TEST FOR MINUS SIGN             04140000
         BNE   SMS2                                                     04160000
         CLI   DCTYP,X'07'              IF - TEST FOR D AND E TYPE      04180000
         BL    ZRC11                    SCALE MODIFIER ERROR.           04200000
         CLI   DCTYP,X'0E'              TEST FOR L-TYPE           IEUN2 04206018
         BE    ZRC11                    DIE IF L CON              IEUN2 04212018
         XI    SIGN,X'01'               SET SIGN MINUS                  04220000
SMS1     LA    GRA,1(GRA)               KICK TEXT POINTER               04240000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           04260000
SMS2     CLI   0(GRA),IA                TEST FOR NUMERIC.               04280000
         BL    SMS3                     YES-EVALUATE SCALE MODIFIER.    04300000
         CLI   LITSW,X'FF'              IF LITERAL, SCALE MOD. MUST BE  04320000
         BE    ZRC11                    DECIMAL SELF DEFINING TERM.     04340000
         CLI   0(GRA),ILPARN            TEST FOR LEFT PAREN.            04360000
         BNE   ZRC11                    NO-SCALE MODIFIER ERROR.        04380000
SMS3     BAL   SRR,XPREV                TO EXPRESSION EVALUATION        04400000
         LA    SAVE,0(SP2)              USE 3 BYTES ONLY                04420000
         TM    CTMODE(ACT),X'60'   TEST IF ASSIGN. OR SUBSTITUTION MODE 04440000
         BNE   SUBS3                    BRANCH IF SUBSTITUTION MODE.    04460000
         TM    RSLT,X'30'               TEST CC FROM EEVAL              04480000
         BO    ZRC11                    CC=11, SCALE MODIFIER ERROR     04500000
         BM    ZRC12                    CC=10 OR 01, RELOC. SCALE MOD.  04520000
         TM    CTLCRI(ACT),X'40'        WAS AN * IN THE EXPRESSION      04540000
         BO    ZRC11                    YES - SCALE MODIFIER ERROR      04560000
SUBS3    CLI   SIGN,1                   TEST SIGN                       04580000
         BE    SMS4                     BRANCH IF MINUS                 04600000
         CH    SAVE,=H'346'             CHECK SCALE MOD. AGAINST MAX.   04620000
         BH    ZRC11                    SCALE MODIFIER TOO LARGE        04640000
         B     SMS5                                                     04660000
SMS4     LCR   SAVE,SAVE                COMPLEMENT SCALE MODIFIER       04680000
         CH    SAVE,=H'-187'            CHECK SCALE MOD. AGAINST MIN.   04700000
         BL    ZRC11                    SCALE MODIFIER TOO SMALL        04720000
SMS5     CLI   DCTYP,X'07'                                        IEUN2 04730018
         BE    SMS8                     BR IF F CON               IEUN2 04740018
         CLI   DCTYP,X'08'                                        IEUN2 04750018
         BE    SMS8                     BR IF H CON               IEUN2 04760018
         CH    SAVE,=H'30'              FLOATING--CHECK MAX SCALE IEUN2 04770018
         BH    ZRC11                    FLOATING PT. SCALE TOO LARGE    04800000
SMS8     SLL   SAVE,5                   POSITION SCALE MODIFIER         04820000
         STH   SAVE,SCMODF              STORE AS HALF WORD              04840000
         SPACE 2                                                        04860000
* CHECK EXTERNAL EXPONENT MODIFIER                                      04880000
         SPACE 1                                                        04900000
EMSCAN   CLI   0(GRA),IE                TEST FOR EXT. EXP. MODIFIER     04920000
         BNE   CONSCN                   NO,GO TO SCAN CONSTANT          04940000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           04960000
         MVI   SIGN,X'00'               SET SIGN PLUS                   04980000
         LA    SAVE,TYTABL(WR1)                                         05000000
         TM    0(SAVE),X'01'            IS EXPONENT MODIFIER LEGAL      05020000
         BZ    ZRC13                    EXOPNENT MODIFIER ERROR         05040000
         LA    GRA,1(GRA)               KICK TEXT POINTER               05060000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           05080000
         CLI   0(GRA),IPLUS             TEST FOR PLUS SIGN              05100000
         BE    EMS1                                                     05120000
         CLI   0(GRA),IMINUS            TEST FOR MINUS SIGN             05140000
         BNE   EMS2                                                     05160000
         XI    SIGN,1                   SET SIGN SWITCH MINUS.          05180000
EMS1     LA    GRA,1(GRA)               KICK TEXT POINTER               05200000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           05220000
EMS2     CLI   0(GRA),IA                TEST FOR NUMERIC.               05240000
         BL    EMS3                     YES-EVALUATE EXPONENT MODIFIER  05260000
         CLI   LITSW,X'FF'              IF LITERAL, EXP.MOD. MUST BE    05280000
         BE    ZRC13                    DECIMAL SELF DEFINING TERM.     05300000
         CLI   0(GRA),ILPARN            TEST FOR LEFT PAREN.            05320000
         BNE   ZRC13                    NO-EXPONENT MODIFIER ERROR.     05340000
EMS3     BAL   SRR,XPREV                TO EXPRESSION EVALUATION        05360000
         LA    SAVE,0(SP2)              USE 3 BYTES ONLY                05380000
         TM    CTMODE(ACT),X'60'   TEST IF ASSIGN. OR SUBSTITUTION MODE 05400000
         BNE   SUBS4                    BRANCH IF SUBSTITUTION MODE.    05420000
         TM    RSLT,X'30'                                               05440000
         BO    ZRC13                    EXPONENT MODIFIER ERROR         05460000
         BM    ZRC14                    RELOCATABLE EXPONENT MODIFIER   05480000
         TM    CTLCRI(ACT),X'40'        WAS AN * IN THE EXPRESSION      05500000
         BO    ZRC13                    YES - EXPONENT MODIFIER ERROR   05520000
SUBS4    CLI   SIGN,1                    TEST SIGN                      05540000
         BE    EMS4                     BRANCH IF MINUS                 05560000
         CH    SAVE,=H'75'              CHECK EXP. AGAINST MAX.         05580000
         BH    ZRC13                    EXPONENT TOO LARGE              05600000
         B     EMS5                                                     05620000
EMS4     LCR   SAVE,SAVE                COMPLEMENT EXP. MODIFIER        05640000
         CH    SAVE,=H'-85'             CHECK EXP. AGAINST MIN.         05660000
         BL    ZRC13                    EXPONENT TOO SMALL              05680000
EMS5     STC   SAVE,EXMODF              EXPONENT JUST RIGHT             05700000
         SPACE 2                                                        05720000
* CHECK VALIDITY OF LEFT DELIMETER, CALCULATE ALIGNMENT IF NECESSARY,   05740000
* AND EXECUTE A VARIABLE BRANCH BY TYPE FOR SYNTAX CHECKING.            05760000
         SPACE 1                                                        05780000
CONSCN   LA    GRC,TYTABL+3(GRC)                                        05800000
         MVC   ALWRD+1(3),0(GRC)        GET ADDR OF VARIABLE BRANCH     05820000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           05840000
         MVI   FHEDSW,0                 INITIALIZE SWITCHES             05860000
         L     ODDR,ALWRD               SET VARIABLE BRANCH             05880000
         CLI   0(GRA),IQUOTE            TEST FOR QUOTE                  05900000
         BE    CONS1                                                    05920000
         CLI   0(GRA),ILPARN            TEST FOR LEFT PAREN.            05940000
         BE    CONS2                                                    05960000
         CLI   0(GRA),ICOMMA            TEST FOR COMMA                  05980000
         BE    CONSDS                   YES-CHECK FOR DS                06000000
         CLI   0(GRA),IBLANK            TEST FOR BLANK                  06020000
         BNE   ZRC107                   INVALID OPERAND                 06040000
CONSDS   CLI   OPCOD,DS                 TEST FOR DS OPCODE              06060000
         BL    ZRC107                   NO-INVALID OPERAND              06080000
         BCTR  GRA,0                    ADJUST OPERAND POINTER          06100000
         CLI   LMSW,X'FF'               TEST IF LGTH MODIFIER PRESENT   06120000
         BE    ENOPND                   YES-END OF OPERAND, EXIT.       06140000
         BAL   SRR,ALIGN                NO-ALIGN PRIOR TO EXIT.         06160000
         B     ENOPND                   EXIT.                           06180000
CONS1    CLI   DCTYP,I9                 IF QUOTE, TEST FOR VALID TYPES  06200000
         BL    CONS3                                                    06220000
         CLI   DCTYP,X'0E'              IS THIS L CON             IEUN2 06226018
         BE    CONS3                    YES.  QUOTE IS JUST FINE. IEUN2 06232018
         B     ZRC107                   INVALID OPER AND.               06240000
CONS2    CLI   DCTYP,I8     IF LEFT PAREN TEST VALID TYPES              06260000
         BNH   ZRC107                   INVALID OPERAND           IEUN2 06270018
         CLI   DCTYP,X'0E'              IS THIS L CON             IEUN2 06280018
         BE    ZRC107                   INVALID OPERAND           IEUN2 06290018
CONS3    S     GRA,SAVPTR               GET REL. PTR. TO 1ST BYTE OF    06300000
         STC   GRA,WPTR1                OPERAND AND PUT IT IN DC BKT.   06320000
         A     GRA,SAVPTR               RESTORE TEXT POINTER            06340000
         OI    WFLAG,2                  SET TEXT BIT                    06360000
         CLI   LMSW,X'FF'               TEST FOR LENG MODIFIER          06380000
         BE    ZROSAV                   SKIP ALIGNMENT IF YES           06400000
         CLI   LITSW,X'FF'              TEST IF LITERAL SCAN            06420000
         BE    ZROSAV                   SKIP ALIGNMENT IF YES           06440000
         CLI   OPCOD,X'25'              TEST FOR LITERAL DC             06460000
         BE    ZROSAV                   YES, ALREADY ALIGNED            06480000
         CLI   VSCNSW,X'FF'             TEST FOR 2ND V-TYPE SCAN        06500000
         BE    ZROSAV                   YES, ALIGNMENT ALREADY DONE     06520000
         TM    CTMODE(ACT),X'60'        SKIP ALIGNMENT                  06540000
         BC    7,ZROSAV                 IF SUBSTITUTION MODE.           06560000
         BAL   SRR,ALIGN                ALIGN LOCATION COUNTER          06580000
ZROSAV   SR    SAVE,SAVE                                                06600000
CONBR    BR    ODDR                                                     06620000
         SPACE 2                                                        06640000
* END OF OPERAND PROCESSING --- COMPUTE TOTAL LENGTH OF OPERAND IN      06660000
* BYTES, FORM 15 BYTE DC WORK-BUCKET AND MOVE IT INTO TEXT RECORD. EXIT 06680000
* IF NO MORE OPERANDS TO FOLLOW, OTHERWISE BRANCH TO PROCESS NEXT       06700000
* OPERAND.                                                              06720000
         SPACE 1                                                        06740000
ENOPND   L     GRY,LLNG                 COMPUTE LENGTH TIMES NUMBER     06760000
         MH    GRY,NOCON1                OF CONSTANTS.                  06780000
         TM    FHEDSW,X'20'             TEST FOR P OR Z WITH NO LMV.    06800000
         BZ    ENOP1                    NO-BRANCH.                      06820000
         L     GRY,PZLNAT               YES-LOAD ACCUMULATED LENGTH.    06840000
ENOP1    M     GRX,DUPFAC               MULTIPLY BY DUP FACTOR.         06860000
         L     GRC,LLNG                 FETCH LMV.                      06880000
         CLI   BITSW,1                  TEST FOR BIT LENGTH.            06900000
         BNE   ENOP2                    NO-BRANCH.                      06920000
         LA    GRC,7(GRC)               CONVERT LMV TO BIT LENGTH.      06940000
         SRL   GRC,3                    ---                             06960000
         AH    GRY,BITREM               ADD BIT REMAINDER TO TOTAL LGTH 06980000
         LR    GRX,GRY                  SAVE RESULT.                    07000000
         LA    GRZ,7                    COMPUTE NEW BIT REMAINDER.      07020000
         NR    GRX,GRZ                  ---                             07040000
         STH   GRX,BITREM               ---                             07060000
         SRL   GRY,3                    COMPUTE NO.OF ADDITIONAL BYTES  07080000
ENOP2    ST    GRY,OPRNLN               AND STORE IN TOTAL OPND.LGTH.   07100000
         LA    GRA,1(GRA)               KICK TEXT POINTER               07120000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           07140000
         CLI   VSCNSW,X'FF'             TEST IF 1ST V-TYPE SCAN         07160000
         BE    PUTWB1                   NO,WBS WERE PUT IN 1ST SCAN     07180000
         A     ODDR,TOTAL                                               07200000
         ST    ODDR,TOTAL                                               07220000
         CLI   FOPND,0                  IS THIS 1ST OPERAND             07240000
         BNE   PUTWB                                                    07260000
         ST    WR1,CTLEN(ACT)           SET LENGTH ATTRIBUTE FOR MLC    07280000
         MVI   FOPND,X'FF'              SET 1ST OPND. SWITCH.           07300000
         CLI   ERSW,X'FF'                                               07320000
         BE    EXIT1                                                    07340000
PUTWB    CLI   DCBKT,32                 HAVE 32 OPNDS BEEN PROCESSED    07360000
         BE    ZRC100      YES - STATEMENT COMPLEXITY EXCEEDED ERROR    07380000
         OI    WFLAG,X'40'              SET DC WORKBUCKET INDICATOR     07400000
         MVC   WTYP,DCTYP               SET TRANSLATED TYPE             07420000
         MVC   WTOTL(3),OPRNLN+1        SET TOTAL OPERAND LENGTH        07440000
         MVC   WDUP(3),DUPFAC+1         SET DUP FACTOR                  07460000
         MVC   WNCONS(1),NOCONS         SET NUMBER OF CONSTANTS         07480000
         MVC   WEXP(1),EXMODF           SET EXP MODF                    07500000
         MVC   WSCL(2),SCMODF           SET SCL MODF                    07520000
         OC    WSCL+1(1),ALBYS          SET ALIGNMENT                   07540000
         OC    WSCL+1(1),BITSW          SET BIT-BYTE                    07560000
         MVC   WLMOD(2),LLNG+2          EET LENGTH MODIFIER VALUE       07580000
         CLI   LITSW,X'FF'                                              07600000
         BE    LTVL1                                                    07620000
         TM    CTMODE(ACT),X'60'        ARE WE IN SUBSTUTUTION     7000 07640000
         BC    7,PUTWB0                 YES, DONT PUT IT IN        7000 07660000
         MVC   TXWTYP(15,WBPTR),WFLAG   MOVE WB INTO TEXT RECORD        07680000
PUTWB0   NI    TXWTYP(WBPTR),X'7F'      SET AS A DC WORKBUCKET     9956 07690013
         OI    TXWTYP(WBPTR),X'40'                                 9956 07700013
         IC    GR1,DCBKT                INCREMENT DC WKBT COUNTER  9956 07710013
         LA    GR1,1(GR1)               A MAXIMUM OF 32 IS ALLOWED PER  07720000
         STC   GR1,DCBKT                 DC/DS STATEMENT.               07740000
         CLI   OPCOD,X'25'              TEST FOR LITERAL DC.            07760000
         BE    PUTWB1                   YES-DONT INCREMENT REC.LGTH.    07780000
         TM    CTCLSI(ACT),X'10'        TEST FIRST PASS INDICATOR       07800000
         BO    PUTWB1                   IF ON-DONT INCREMENT REC.LGTH.  07820000
         L     GRC,CTEXTP(ACT)          FETCH POINTER TO TEXT RECORD.   07840000
         LH    GR1,TXRL(GRC)            FETCH RECORD LENGTH.            07860000
         LA    GR1,15(GR1)              ADD 15 AND                      07880000
         STH   GR1,TXRL(GRC)            PLACE BACK IN TEXT RECORD.      07900000
         MVI   RLSW,X'FF'               SET REC LENG UPDATE SWITCH      07920000
PUTWB1   CLI   0(GRA),IBLANK            TEST FOR BLANK                  07940000
         BE    DONE                                                     07960000
         C     GRA,FINADR               TEST FOR END OF OPERAND         07980000
         BE    DONE                                                     08000000
         CLI   0(GRA),ICOMMA            TEST FOR COMMA                  08020000
         BNE   ZRC39                    INVALID DELIMITER               08040000
         LA    WBPTR,15(WBPTR)          UPDATE POINTER FOR NEXT WB      08060000
         LA    GRA,1(GRA)               KICK TEXT POINTER               08080000
         MVI   FCONS,0                  RESET FIRST CONSTANT SWITCH     08100000
         B     INIT                                                     08120000
         SPACE 2                                                        08140000
* CHECK CHARACTER TYPE DC'S.                                            08160000
         SPACE 1                                                        08180000
CTYP     LA    GRA,1(GRA)               KICK TEXT POINTER               08200000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           08220000
         CL    GRA,FINADR               TEST FOR NO ENDING QUOTE  23218 08222018
         BH    ZRC87                    BRANCH IF OPERAND DONE,   23218 08224018
*                                       NO '                      23218 08226018
         CH    SAVE,=H'256'             TEST IF MAX CHARACTERS    23218 08228018
*                                       HIT                       23218 08230018
         BH    ZRC107                   BRANCH IF MORE THAN 256   23218 08232018
         CLI   0(GRA),IQUOTE            TEST FOR QUOTE                  08240000
         BE    CTYP4                    IF FOUND TEST IF NEXT CHAR QUOT 08260000
         CLI   0(GRA),IAMPSD            TEST FOR AMPERSAND              08280000
         BNE   CTYP3                                                    08300000
         LA    GRA,1(GRA)               KICK TEXT POINTER               08320000
         CLI   0(GRA),IAMPSD            TEST FOR PAIRED AMPERSAND       08340000
         BNE   ZRC107                   INVALID OPERAND                 08360000
CTYP3    LA    SAVE,1(SAVE)             ADD 1 TO COUNT OF CHARACTERS    08380000
         B     CTYP                     CONTINUE SCAN                   08400000
CTYP4    LA    GRA,1(GRA)               KICK TEXT POINTER               08420000
         CLI   0(GRA),IQUOTE            TEST FOR QUOTE                  08440000
         BE    CTYP3                    2 QUOTES MEAN 1 QUOTE IN CONST  08460000
         BCTR  GRA,0                    SUB. 1 FROM TEST POINTER        08480000
         B     XTYP4                                                    08500000
CTYP5    CLI   LMSW,X'FF'               TEST IF LENGTH SPECIFIED  23218 08540018
         BC    8,ENOPND                                                 08580000
         ST    SAVE,LLNG                STORE LENGTH OF CONSTANT        08600000
CEXIT    B     ENOPND                   TO END OPERAND                  08620000
         SPACE 2                                                        08640000
* CHECK HEXADECIMAL TYPE DC'S.                                          08660000
         SPACE 1                                                        08680000
XTYPE    LA    GRA,1(GRA)               KICK TEXT POINTER               08700000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           08720000
         CLI   0(GRA),X'0F'             TEST FOR VALID HEX DIGIT        08740000
         BH    XTYP3                    GO TO TEST FOR QUOTE IF NOT     08760000
         LA    SAVE,1(SAVE)             ADD 1 TO COUNT OF HEX DIGITS    08780000
         B     XTYPE                    CONTINUE SCAN                   08800000
XTYP3    CLI   0(GRA),IQUOTE            TEST FOR QUOTE                  08820000
         BNE   ZRC107                   INVALID OPERAND                 08840000
         LA    SAVE,1(SAVE)             ADD 1 TO COUNT                  08860000
         SRL   SAVE,1                   DIVIDE COUNT BY 2               08880000
XTYP4    LTR   SAVE,SAVE                TEST IF COUNT IS ZERO           08900000
         BZ    ZRC107                   INVALID OPERAND                 08920000
         CH    SAVE,=H'256'             TEST IF BYTE LIMIT        23218 08925018
*                                       EXCEEDED                  23218 08930018
         BH    ZRC107                   BRANCH IF MORE THAN 256   23218 08935018
         B     CTYP5                    TEST LENGTH AND RETURN DC MAIN  08940000
         SPACE 2                                                        08960000
* CHECK BINARY TYPE DC'S.                                               08980000
         SPACE 1                                                        09000000
BTYPE    LA    GRA,1(GRA)               KICK TEXT POINTER               09020000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           09040000
         CLI   0(GRA),1                 TEST FOR VALID BINARY DIGIT     09060000
         BH    BTYP3                    NO,TEST FOR QUOTE               09080000
         LA    SAVE,1(SAVE)             ADD 1 TO COUNT                  09100000
         B     BTYPE                    CONTINUE SCAN                   09120000
BTYP3    CLI   0(GRA),IQUOTE            TEST FOR QUOTE                  09140000
         BNE   ZRC39                    INVALID DELIMITER               09160000
         LA    SAVE,7(SAVE)             ADD 7 TO COUNT                  09180000
         SRL   SAVE,3                   DIVIDE COUNT BY 8               09200000
         B     XTYP4                    TEST EXPLICIT LENG AND EXIT     09220000
         SPACE 2                                                        09240000
* CHECK FIXED AND FLOATING POINT DC'S.                                  09260000
         SPACE 1                                                        09280000
FHEDSCAN MVI   FHEDSW,0                 SET SIGN,EXP.,DOT SWITCHES = 0  09300000
FA       LA    GRA,1(GRA)               BUMP TEXT POINTER               09320000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           09340000
         CLI   0(GRA),IPLUS             IS 1ST CHAR. PLUS               09360000
         BE    FD                       YES                             09380000
         CLI   0(GRA),IMINUS            IS 1ST CHAR. MINUS              09400000
         BE    FD                       YES                             09420000
         CLI   0(GRA),IPRIOD            IS 1ST CHAR. DECIMAL POINT      09440000
         BE    FB                       YES                             09460000
         CLI   0(GRA),I9                IS 1ST CHAR. NUMERIC            09480000
         BH    ZRC107                   NO, LOG INVALID OPERAND ERROR   09500000
FC       LA    GRA,1(GRA)               YES, BUMP TEXT POINTER          09520000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           09540000
         CLI   0(GRA),I9                IS NEXT CHAR NUMERIC            09560000
         BNH   FC                       YES, CONTINUE SCAN              09580000
         CLI   0(GRA),IPRIOD            IS NEXT CHAR. DECIMAL POINT     09600000
         BE    FB                       YES                             09620000
         CLI   0(GRA),IE                CHECK FOR EXPONENT.             09640000
         BE    FE                       YES                             09660000
         CLI   0(GRA),ICOMMA            IS NEXT CHAR. COMMA             09680000
         BE    FF                       YES, END OF CONSTANT            09700000
         CLI   0(GRA),IQUOTE            IS NEXT CHAR. QUOTE             09720000
         BE    ENOPND                   YES, END OF OPERAND---EXIT.     09740000
         B     ZRC107                   NO, LOG INVALID OPERAND ERROR.  09760000
FB       TM    FHEDSW,1                 IS DOT SWITCH ON                09780000
         BO    ZRC107                   YES, TOO MANY DECIMAL POINTS.   09800000
         OI    FHEDSW,1                 TURN ON DOT SWITCH              09820000
         B     FC                       CONTINUE SCAN                   09840000
FD       TM    FHEDSW,4                 IS SIGN SWITCH ON               09860000
         BO    ZRC107                   YES, TOO MANY ALGEBRAIC SIGNS.  09880000
         OI    FHEDSW,4                 TURN ON SIGN SWITCH             09900000
         B     FA                       CONTINUE SCAN                   09920000
FE       TM    FHEDSW,2                 IS EXP. SWITCH ON               09940000
         BO    ZRC107                   YES, TOO MANY EXPONENTS.        09960000
         OI    FHEDSW,3                 TURN ON EXP. AND DOT SWITCHES   09980000
         NI    FHEDSW,X'FB'             TURN OFF SIGN SWITCH            10000000
         B     FA                       DO EXPONENT SCAN.               10020000
FF       IC    GR14,NOCONS              ADD 1 TO NUMBER OF CONSTANTS    10040000
         LA    GR14,1(GR14)                                             10060000
         STC   GR14,NOCONS                                              10080000
         B     FHEDSCAN                 BEGIN SCANNING NEXT CONSTANT.   10100000
         SPACE 2                                                        10120000
* CHECK PACKED AND ZONED DC'S.                                          10140000
         SPACE 1                                                        10160000
PTYPE    LA    GRA,1(GRA)               STEP OPERAND POINTER.           10180000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           10200000
         CLI   0(GRA),IPLUS             TEST FOR PLUS SIGN.             10220000
         BE    PTYP3                    YES-BRANCH                      10240000
         CLI   0(GRA),IMINUS            TEST FOR MINUS SIGN.            10260000
         BE    PTYP3                    YES-BRANCH                      10280000
PTYP2    CLI   0(GRA),I9                TEST FOR NUMERIC.               10300000
         BH    PTYP4                    NO-BRANCH.                      10320000
         LA    GRX,1(GRX)               ADD 1 TO LENGTH.                10340000
PTYP3    LA    GRA,1(GRA)               STEP OPERAND POINTER.           10360000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           10380000
         B     PTYP2                    BRANCH TO CONTINUE SCAN.        10400000
PTYP4    CLI   0(GRA),IPRIOD            TEST FOR DOT.                   10420000
         BNE   PTYP5                    NO-BRANCH.                      10440000
         TM    FHEDSW,8                 TEST DOT SWITCH.                10460000
         BO    ZRC107                   ON-TOO MANY DOTS IN CONSTANT.   10480000
         OI    FHEDSW,8                 OFF-TURN DOT SWITCH ON.         10500000
         B     PTYP3                    BRANCH TO CONTINUE SCAN.        10520000
PTYP5    CLI   0(GRA),IQUOTE            TEST FOR QUOTE.                 10540000
         BE    PTYP6                    YES-BRANCH                      10560000
         CLI   0(GRA),ICOMMA            TEST FOR COMMA.                 10580000
         BNE   ZRC39                    NO-INVALID DELIMITER.           10600000
         IC    GRZ,NOCONS               ADD 1 TO NUMBER OF CONSTANTS.   10620000
         LA    GRZ,1(GRZ)               ---                             10640000
         STC   GRZ,NOCONS               ---                             10660000
PTYP6    LTR   GRX,GRX                  TEST FOR ZERO LENGTH.           10680000
         BZ    ZRC39                    YES-INVALID DELIMITER.          10700000
         CLI   DCTYP,4                  CHECK DC TYPE.                  10720000
         BE    ZONED                    ZONED-BRANCH.                   10740000
         LA    GRX,2(GRX)               PACKED-COMPUTE PACKED LENGTH.   10760000
         SRL   GRX,1                    ---                             10780000
ZONED    CH    GRX,CON16                COMPARE LENGTH WITH MAXIMUM.    10800000
         BH    ZRC17                    DATA ITEM TOO LARGE-BRANCH.     10820000
         CLI   LMSW,X'FF'               TEST FOR LENGTH MODIFIER.       10840000
         BE    PTYP7                    YES-BRANCH.                     10860000
         CLI   FCONS,0                  TEST FOR 1ST CONSTANT IN OPND.  10880000
         BNE   PTYP8                    NO-BRANCH.                      10900000
         MVI   FCONS,X'FF'              SET 1ST CONSTANT SWITCH.        10920000
         OI    FHEDSW,X'20'             SET PZ, NO LMV SWITCH.          10940000
         ST    GRX,LLNG                 USE 1ST CONSTANT LGTH.FOR LMV.  10960000
PTYP8    A     GRX,PZLNAT               ACCUMULATE TOTAL LENGTH.        10980000
         ST    GRX,PZLNAT               ---                             11000000
PTYP7    CLI   0(GRA),IQUOTE            TEST FOR QUOTE.                 11020000
         BE    ENOPND                   YES-BRANCH.                     11040000
         SR    GRX,GRX                  NO-SET LENGTH COUNTER TO ZERO.  11060000
         NI    FHEDSW,X'F7'             RESET DOT SWITCH.               11080000
         B     PTYPE                    BRANCH TO PROCESS NEXT CONSTANT 11100000
         SPACE 2                                                        11120000
* CHECK A AND Y TYPE ADDRESS CONSTANTS.                                 11140000
         SPACE 1                                                        11160000
ATYPE    LA    GRA,1(GRA)               KICK TEXT POINTER               11180000
         BAL   SRR,XPREVA               TO EXPRESSION EVALUATION        11200000
         CLI   LITSW,X'FF'              CHECK FOR LITERAL               11220000
         BNE   ATYP1                    NO, BRANCH                      11240000
         TM    CTLCRI(ACT),X'40'        CHECK FOR LOC. CTR. REF.        11260000
         BZ    ATYP1                    NO, BRANCH                      11280000
         MVI   LOCSW,X'FF'              YES, SET SWITCH                 11300000
ATYP1    CLI   0(GRA),ICOMMA            TEST FOR COMMA                  11320000
         BNE   ATYP3                    NO,GO TO TEST FOR RIGHT PAREN   11340000
         IC    SAVE,NOCONS                                              11360000
         LA    SAVE,1(SAVE)             ADD 1 TO NO OF CONSTANTS        11380000
         STC   SAVE,NOCONS                                              11400000
         B     ATYPE                                                    11420000
ATYP3    CLI   LITSW,X'FF'              CHECK IF LITERAL         A28596 11428020
         BNE   ATYP4                    NO, BRANCH               A28596 11436020
         OI    TXLXRI(GRB),4            SET XREF MADE SWITCH     A28596 11444020
ATYP4    CLI   0(GRA),IRPARN            TEST FOR RIGHT PAREN     A28596 11452020
         BNE   ZRC39                    INVALID DELIMITER               11460000
         B     ENOPND                   TO END OPERAND                  11480000
         SPACE 2                                                        11500000
* CHECK S TYPE ADDRESS CONSTANTS.                                       11520000
         SPACE 1                                                        11540000
STYPE    CLI   LITSW,X'FF'                                              11560000
         BE    ZRC05                    ERROR-LITERAL IN S-CON.         11580000
STYP1    LA    GRA,1(GRA)               KICK TEXT POINTER               11600000
         BAL   SRR,XPREVA               TO EXPRESSION EVALUATION        11620000
         CLI   0(GRA),ILPARN            TEST FOR LEFT PAREN.            11640000
         BNE   STYP3                    NO, BRANCH                      11660000
         TM    FHEDSW,X'10'             LEFT PAREN SWITCH ON            11680000
         BO    ZRC107                    YES, TOO MANY LEFT PARENS      11700000
         OI    FHEDSW,X'10'             TURN ON LEFT PAREN SWITCH       11720000
         B     STYP1                    CHECK BASE REG. EXPRESSION.     11740000
STYP3    TM    FHEDSW,X'10'             TEST FOR BASE-DISP S-CON.       11760000
         BZ    STYP4                    NO-BRANCH                       11780000
         CLI   0(GRA),IRPARN            YES-TEST FOR RT. PAREN DELIM.   11800000
         BNE   ZRC39                    NO-INVALID DELIMITER            11820000
         LA    GRA,1(GRA)               YES-STEP OVER RIGHT PAREN.      11840000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           11860000
STYP4    CLI   0(GRA),IRPARN            TEST FOR RT. PAREN. DELIM.      11880000
         BE    ENOPND                   TO END OF OPERAND               11900000
         CLI   0(GRA),ICOMMA            TEST FOR COMMA                  11920000
         BNE   ZRC39                    INVALID DELIMITER               11940000
         IC    SAVE,NOCONS              ADD                             11960000
         LA    SAVE,1(SAVE)             1                               11980000
         STC   SAVE,NOCONS              TO NUMBER OF CONSTANTS          12000000
         NI    FHEDSW,X'EF'             TURN OFF LEFT PAREN SWITCH      12020000
         B     STYP1                    CONTINUE SCAN                   12040000
         SPACE 2                                                        12060000
* CHECK Q AND V TYPE ADDRESS CONSTANTS, AND MAKE ESD ENTRY FOR EACH.    12080000
         SPACE 1                                                        12100000
QTYPE    CLI   LITSW,X'FF'                                              12120000
         BE    ZRC15                    ERROR - QCON IN LITERAL.        12140000
         MVI   QFLAG,1                  SET QCON FLAG FOR ESD ROUTINE   12160000
         B     VQCOM                                                    12180000
VTYPE    MVI   QFLAG,0                  SET VCON FLAG FOR ESD ROUTINE   12200000
VQCOM    CLI   LITSW,X'FF'              TEST IF LITERAL VCON OR QCON    12220000
         BE    SCAN1                                                    12240000
VSCN1    CLI   VSCNSW,X'FF'             TEST IF 1ST SCAN                12260000
         BE    SCAN2                    NO,TO SCAN FOR ESD PROCESSING   12280000
         MVI   EXITSW,X'FF'             OTHERWISE,SET 1ST SCAN          12300000
SCAN1    LA    GRA,1(GRA)               KICK TEXT POINTER               12320000
         ST    GRA,ERRORPTR             USED ONLY FOR ERRORS.           12340000
         SR    GR2,GR2                  RESET SYMBOL CHAR. COUNTER      12360000
         CLI   0(GRA),I9                TEST FOR NUMERIC                12380000
         BC    12,ZRC107                INVALID OPERAND.                12400000
SCAN1A   CLI   0(GRA),ICOMMA            TEST FOR COMMA                  12420000
         BE    SCAN1B                                                   12440000
         CLI   0(GRA),IRPARN            TEST FOR RIGHT PAREN.           12460000
         BE    SCAN3                    YES,CHECK VALIDITY LAST SYMBOL  12480000
         CLI   0(GRA),IAT                                               12500000
         BH    ZRC107                   INVALID OPERAND.                12520000
         LA    GR2,1(GR2)               KICK SYMBOL CHAR. COUNTER       12540000
         LA    GRA,1(GRA)               KICK TEXT POINTER               12560000
         B     SCAN1A                   CONTINUE SCAN                   12580000
SCAN1B   IC    SAVE,NOCONS                                              12600000
         LA    SAVE,1(SAVE)                                             12620000
         STC   SAVE,NOCONS                                              12640000
SCAN3    CH    GR2,=H'8'                SYMBOL ERROR IF ANY V-CON IS    12660000
         BH    ZRC18                    MORE THAN 8 CHARACTERS LONG.    12680000
         LTR   GR2,GR2                  INVALID OPERAND IF ANY V-CON    12700000
         BZ    ZRC107                   IS MISSING - I.E. DC V()        12720000
         L     GR2,CTXWBP(ACT)          LOAD SYMBOL BUCKET POINTER      12740000
         LTR   GR2,GR2                  TEST FOR ZERO                   12760000
         BZ    VW                       YES, BRANCH                     12780000
         LA    GR2,6(GR2)               STEP SYMBOL BUCKET POINTER      12800000
         ST    GR2,CTXWBP(ACT)          STORE INCREMENTED BKT PTR.      12820000
VW       CLI   0(GRA),ICOMMA            IS DELIMITER A COMMA            12840000
         BE    SCAN1                    YES, CONTINUE SCAN              12860000
         B     ENOPND                   NO, END OF OPERAND.             12880000
SCAN2    TM    TXWTYP(WBPTR),4          TEST FOR ERROR                  12900000
         BO    DONE2                    BRANCH IF YES                   12920000
SCAN2AA  LA    SP1,1(GRA)               PTR TO 1ST BYTE OF CONSTANT     12940000
SCAN2A   LA    GRA,1(GRA)               KICK TEXT POINTER               12960000
         CLI   0(GRA),ICOMMA            TEST FOR COMMA                  12980000
         BE    SCAN2B                                                   13000000
         CLI   0(GRA),IRPARN            TEST FOR RIGHT PAREN.           13020000
         BNE   SCAN2A                   CONTINUE TO SCAN CONST          13040000
SCAN2B   TM    WFLAG,2                  DOES DS CONTAIN TEXT            13060000
         BZ    ENOPND                   NO,SKIP ESD PROCESSING          13080000
         LR    SP2,GRA                  MAKE                            13100000
         SR    SP2,SP1                  ESD                             13120000
         BCTR  SP2,0                    ENTRY                           13140000
         STM   GRA,GRY,REGSAV                                           13160000
         CLI   OPCOD,X'26'              SET COND. CODE FOR ESD PROCESS  13180000
         L     GR1,CVCON(ACT)           BRANCH TO DO ESD PROCESSING     13200000
         L     FRB,CBRNDA(ACT)           AND CROSS-REFERENCE.           13220000
         BALR  SRR,GR1                                                  13240000
         USING *,SRR                                                    13260000
QFLAG    DC    AL2(0)                   ESD ROUTINE FLAG -- 0=V --- 1=Q 13280000
         LM    4,15,REGSAV              RESTORE REGISTERS               13300000
         DROP  SRR                                                      13320000
NOESD    L     GR1,CTXWBP(ACT)          INCREMENT                       13340000
         LA    GR1,6(GR1)               SYMBOL WORK BUCKET              13360000
         ST    GR1,CTXWBP(ACT)          POINTER BY 6                    13380000
         CLI   0(GRA),ICOMMA            TEST FOR COMMA                  13400000
         BE    SCAN2AA                  YES, BRANCH.                    13420000
         B     ENOPND                                                   13440000
         SPACE 2                                                        13460000
*        ROUTINE TO ALIGN LOCATION COUNTER TO CORRECT BOUNDARY          13480000
*        R1 IS WORK REGISTER,LNKR IS LINK REGIATER                      13500000
         SPACE 1                                                        13520000
ALIGN    L     R1,TOTAL                 GET LOCATION COUNTER            13540000
         SR    SAVE,SAVE                SET SAVE = ALL ONES             13560000
         BCTR  SAVE,0                                                   13580000
         BCTR  WR2,0                    WR2 = ALIGNMENT                 13600000
         N     WR2,=XL4'7'                MAXIMUM OF DBLWD        IEUN2 13610018
         AR    R1,WR2                        1=BYTE, 2=HALF WORD        13620000
         XR    WR2,SAVE                      4=FULL WORD, 8=DOUBLE WRD  13640000
         NR    R1,WR2                   R1 IS LOC CNT ALIGNED           13660000
         S     R1,TOTAL                 FIND NUMBER BYTES OF ALIGNMENT  13680000
         SLL   R1,1                     SHIFT                           13700000
         STC   R1,ALBYS                 AND PUT IN                      13720000
         SRL   R1,1                                                     13740000
         A     R1,TOTAL                 SET THE NEW ALIGNED             13760000
         ST    R1,TOTAL                 LOCATION COUNTER                13780000
         CLI   FOPND,0                  IS THIS 1ST OPND.               13800000
         BCR   7,SRR                    NO, BRANCH                      13820000
         CLI   VSCNSW,X'FF'                                             13840000
         BCR   8,SRR                    BRANCH IF 2ND V-TYPE SCAN.      13860000
         TM    CTMODE(ACT),X'60'   TEST IF ASSIGN. OR SUBSTITUTION MODE 13880000
         BCR   7,SRR                    BRANCH IF SUBSTITUTION MODE.    13900000
         L     R1,CTXABP(ACT)           GET POINTER TO TEXT RECORD      13920000
         MVC   TXLOC(3,R1),TOTAL+1      SET ALIGNED LOC CTR IN TEXT     13940000
ALIGN1   BR    SRR                      RETURN FROM WHENCE THOU CAME    13960000
DONE     OI    TXWTYP(WBPTR),X'08'      SET LAST DC WB INDICATOR        13980000
DONE1    TM    CTMODE(ACT),X'60'   TEST IF ASSIGN. OR SUBSTITUTION MODE 14000000
         BNE   DONE2                    BRANCH IF SUBSTITUTION MODE.    14020000
         MVC   CTLOC(4,ACT),TOTAL  SET NEW LOC CTR IN CENTRAL TABLE     14040000
DONE2    CLI   EXITSW,X'FF'             TEST IF ABNORMAL RETURN TO MLC  14060000
         BE    ABNEXT                   YES,BRANCH                      14080000
         MVI   VSCNSW,X'00'             NO,SET 1ST V-TYPE SCAN          14100000
         B     CTRTRN(ACT)              NORMAL RETURN TO MLC            14120000
ABNEXT   MVI   EXITSW,X'00'             SET NORMAL RETURN TO MLC        14140000
         MVI   VSCNSW,X'FF'             SET 2ND V-TYPE SCAN             14160000
         MVC   CTXWBP(4,ACT),SAVWBP     RESTORE SYMBOL BUCKET POINTER   14180000
         L     WR1,CTSAVE+12(ACT)       ABNORMAL                        14200000
         LA    WR1,4(WR1)               RETURN                          14220000
         ST    WR1,CTSAVE+12(ACT)       TO                              14240000
         B     CTRTRN(ACT)              MLC                             14260000
         SPACE 2                                                        14280000
* ERROR EXIT ROUTINE. LOG ASSIGNED ERROR MESSAGE AND VAMOOSE.           14300000
         SPACE 1                                                        14320000
EXIT     L     SP1,ERRORPTR             LOAD COLUMN POINTER FOR LOGERR  14340000
         CLI   LITSW,X'FF'              IS THIS A LITERAL               14360000
         BE    LOGERR                   YES, BRANCH.                    14380000
         MVI   TXWTYP(GRB),X'4C'        SET ERROR INDICATOR IN DC BKT.  14400000
         CLI   RLSW,X'FF'               TESTREC LENG UPDATE SWITCH      14420000
         BNE   UPRECL                   BRANCH IF OFF                   14440000
         L     WR1,TOTAL                SUBTRACT LENGTH                 14460000
         S     WR1,OPRNLN               OF ERRONEOUS OPERAND FROM       14480000
         ST    WR1,TOTAL                TOTAL LENGTH OF STATEMENT       14500000
         B     LOGERR                                                   14520000
UPRECL   L     WR1,CTEXTP(ACT)          POINTER TO TEXT RECORD          14540000
         LH    WR2,TXRL(WR1)            INCREMENT                       14560000
         LA    WR2,15(WR2)              RECORD LENGTH                   14580000
         STH   WR2,TXRL(WR1)            BY LENGTH OF WORK BUCKET        14600000
LOGERR   L     SRB,CLOGER(ACT)                                          14620000
         BALR  SRR,SRB                                                  14640000
KAPUT    DC    AL2(0)                   DIAGNOSTIC NUMBER STORED HERE   14660000
         CLI   LITSW,X'FF'              IS THIS A LITERAL               14680000
         BE    LTVL3                    YES, BRANCH.                    14700000
         CLI   FOPND,0                  IS THIS 1ST OPND.               14720000
         BNE   DONE1                                                    14740000
         CLI   NOCONS,X'01'                                             14760000
         BNE   STERSW                                                   14780000
EXIT1    TM    CTMODE(ACT),X'60'   TEST IF ASSIGN. OR SUBSTITUTION MODE 14800000
         BNE   SUBS1                    BRANCH IF SUBSTITUTION MODE.    14820000
         L     GR1,CTXABP(ACT)     FETCH PTR TO APPENDED FIXED FIELD    14840000
         MVC   TOTAL+1(3),TXLOC(GR1)    GET LOC CNT                     14860000
         L     GR2,TOTAL                IN GR2                          14880000
         SR    WR1,WR1                                                  14900000
         IC    WR1,ALBYS                GET NUMBER OF BYTES             14920000
         SRL   WR1,1                    TO ALIGN                        14940000
         SR    GR2,WR1                  GET ORIGINAL LOC CNT            14960000
         ST    GR2,TOTAL                AND PUT BACK                    14980000
         MVC   TXLOC(3,GR1),TOTAL+1       (IF ERROR, DONT ALIGN)        15000000
SUBS1    CLI   ERSW,X'FF'                                               15020000
         BE    DONE1                                                    15040000
         LA    GR1,1                                                    15060000
         ST    GR1,CTLEN(ACT)                                           15080000
         B     DONE1                                                    15100000
STERSW   MVI   ERSW,X'FF'                                               15120000
         B     ENOPND                                                   15140000
         SPACE 2                                                        15160000
* LITERAL EVALUATION AND PROCESSING ROUTINE.                            15180000
         SPACE 1                                                        15200000
LITVAL   L     1,CTXOFP(ACT)            GET OPRND LENGTH POINTER        15220000
         SR    GR2,GR2                  CLEAR WORK REGISTER       23218 15221018
         IC    GR2,0(GR1)               GET OPERAND LENGTH        23218 15222018
         AR    GR2,GR1                  GET END OF OPERAND        23218 15223018
*                                       POINTER                   23218 15224018
         ST    GR2,FINADR                    AND  SAVE            23218 15225018
         LA    2,=X'32'                 SET AS A BLANK             9538 15226013
         ST    2,GRASAVE                  IN CASE OF AN ERROR      9538 15232013
         L     2,CTXABP(ACT)            GET PTR TO APPENDED FIXED FIELD 15240000
         SR    WR1,WR1                                                  15260000
         IC    WR1,TXLSTG(2)            GET RELATIVE PTR TO = SIGN      15280000
         STH   GRC,RELEQL                AND SAVE IT.                   15300000
         LA    GRA,2(GR1,GRC)           GET ABSOLUTE PTR. TO = SIGN+1   15320000
         MVI   LITSW,X'FF'              SET LITERAL SWITCH              15340000
         LR    WBPTR,2                  SAVE PTR TO WORK BUCKET         15360000
         TM    TXLEVI(GRB),2            LITERAL PREVIOUSLY EVALUATED    15380000
         BO    LTVL3A                   YES, BRANCH                     15400000
         B     LITENT                   OTHERWISE GO TO EVALUATE        15420000
LTVL1    OI    TXLEVI(GRB),2            SET LITERAL EVALUATED INDICATOR 15440000
         ST    GRA,GRASAVE              SAVE POINTER               9538 15450013
         TM    TXLASI(GRB),1            WAS LIT ASSIGNED PREV    A52831 15452021
         BO    LTVL3                    YES, DONT TRY AGAIN      A52831 15454021
         SR    SAVE,SAVE                                                15460000
         TM    OPRNLN+3,X'07'           TEST LENGTH FOR MULTIPLE OF 8   15480000
         BZ    LTVL2                                                    15500000
         LA    SAVE,4(SAVE)                                             15520000
         TM    OPRNLN+3,X'03'           TEST LENGTH FOR MULTIPLE OF 4   15540000
         BZ    LTVL2                                                    15560000
         LA    SAVE,4(SAVE)                                             15580000
         TM    OPRNLN+3,X'01'           TEST LENGTH FOR MULTIPLE OF 2   15600000
         BZ    LTVL2                                                    15620000
         LA    SAVE,4(SAVE)             OTHERWISE 7ULTIPLE OF 1         15640000
LTVL2    SR    SP1,SP1                                                  15660000
         S     GRA,SAVPTR               GET DEFINITION LENGTH,          15680000
         BCTR  GRA,0                    SUBTRACT 1                      15700000
         STC   GRA,DEFLEN               AND STORE.                      15720000
         MVC   WLNAT(1),CTLEN+3(ACT)    SET LENGTH ATTRIBUTE            15740000
         SPACE 2                                                        15760000
*  THE FOLLOWING IS SYMBOL TABLE LOOK-UP FOR LITERALS.ENTERS LITERALS   15780000
*  IN TABLE,IF NO DUPLICATES FOUND AND IF ROOM IN TABLE.                15800000
         SPACE 1                                                        15820000
PUTLIT   IC    SP1,DEFLEN               GET DEFINITION LENGTH-1         15840000
         L     GRA,SAVPTR               GET PPINTER TO TEXT.            15860000
         L     WR1,CTSYMP(ACT)                                          15880000
         L     WR2,LITPTR(SAVE)         GET DISPLACEMENT OF POINTER     15900000
         AR    WR2,WR1                                                  15920000
NEXENT   ST    WR2,PREPTR               FOR FORWARD THREADING           15940000
         MVC   ALWRD+1(3),0(WR2)                                        15960000
         L     WR2,ALWRD                GET NEXT POINTER                15980000
         LTR   WR2,WR2                  ZERO POINTER MEANS              16000000
         BZ    NOSAME                   END OF THREAD                   16020000
         AR    WR2,WR1                  =ADDRESS OF ENTRY               16040000
         CLI   LOCSW,X'FF'              CHECK LITERAL-ASTERISK SWITCH   16060000
         BE    NEXENT                   BRANCH IF ON                    16080000
         CLC   DEFLEN,3(WR2)            IF DEFINITION LENGTHS UNEQUAL   16100000
         BNE   NEXENT                   TRY NEXT ENTRY                  16120000
         EX    SP1,LCOMP                EXECUTE COMPR WITH DEF LNG-1    16140000
         BNE   NEXENT                                                   16160000
         AR    WR2,SP1                  DUPLICATE FOUND                 16180000
         MVC   WTOTL(3),8(WR2)          GET DISPLACEMENT FROM TABLE     16200000
         MVC   TXLDSP(3,WBPTR),8(WR2)   MOVE DISPLACEMENT IN WB         16220000
         B     SETWB1                                                   16240000
NOSAME   LA    SP1,21(SP1)              DEF LENGTH+ FIXED INFO   A28269 16260019
         CLI   LOCSW,X'FF'              CHECK LITERAL-ASTERISK SWITCH   16280000
         BNE   PEG                      BRANCH IF OFF, OTHERWISE        16300000
         LA    SP1,4(SP1)               ALLOW FOR TXLOC AND CESDID      16320000
PEG      XC    SAVLEN(4),SAVLEN         SET SAVLEN = 0                  16340000
         L     GR1,CTXWBP(ACT)          FETCH SYMBOL BUCKET POINTER     16360000
         LTR   GR1,GR1                  TEST FOR ZERO                   16380000
         BZ    NOSYMBKT                 YES, NO SYMBOL BUCKETS TO MOVE. 16400000
         CLI   DCTYP,I9                 IS THIS AN ADCON LITERAL        16420000
         BL    NOSYMBKT                 NO, THEN DONT MOVE SYMBOL BKTS. 16440000
         L     GR2,CTEXTP(ACT)          FETCH PTR TO CURR. TEXT REC.    16460000
         AH    GR2,TXRL(GR2)            ADD RECORD LENGTH.              16480000
         SR    GR2,GR1                  COMPUTE LGTH OF ALL SYM. BKTS.  16500000
         BZ    NOSYMBKT                 IF 0, THEN THERE ARE NONE.      16520000
         LA    SP1,0(SP1,GR2)           ADD LENGTH OF SYMBOL BKTS.      16540000
         ST    GR2,SAVLEN               SAVE LENGTH OF SYMBOL BUCKETS.  16560000
         OI    WTYP,X'40'               SET SWITCH FOR DCGETR ROUTINE.  16580000
NOSYMBKT ST    SAVE,REGSAV                                              16600000
         TM    CTSYMF(ACT),X'01'        IS SYM TABLE FULL IND. ON 19884 16606000
         BO    LTVL3                    YES, SKIP ENTRY TEST      19884 16612000
         L     SRB,CSTROM(ACT)          TEST IF ROOM                    16620000
         BALR  SRR,SRB                  IN SYMBOL TABLE                 16640000
         B     LTVL3                    RETURN HERE IF NO ROOM          16660000
         L     SAVE,REGSAV                                              16680000
         L     WR2,PREPTR               RETURN HERE IF ROOM             16700000
         MVC   0(3,WR2),CFREEP+1(ACT)   THREAD NEW ENTRY                16720000
         L     WR2,CFREEP(ACT)                                          16740000
         AR    WR2,WR1                  = ADDRESS OF FREE STORAGE       16760000
         SR    WR1,WR1                                                  16780000
         XC    0(3,WR2),0(WR2)          ZERO AS POINTER                 16800000
         MVC   3(1,WR2),DEFLEN          MOVE IN DEFINITION LENGTH-1     16820000
         IC    WR1,DEFLEN               GET DEFINITION LENGTH-1         16840000
         EX    WR1,MOVTEX               FOR EXECUTED MOVE INSTRUCTION   16860000
         LA    WR2,5(WR1,WR2)           POINT PAST TEXT FORM            16880000
         LA    WR1,CTLITA(SAVE,ACT)                                     16900000
         MVC   WTOTL(3),1(WR1)                                          16920000
         MVC   0(16,WR2),WLNAT          MOVE FIXED INFO INTO TABLE      16940000
         CLI   LOCSW,X'FF'              CHECK LITERAL-ASTERISK SWITCH   16960000
         BNE   UPFREE                   BRANCH IF OFF                   16980000
         MVI   LOCSW,0                  RESET LITERAL-ASTERISK SWITCH   17000000
         OI    2(WR2),X'80'              SET MOVE INDICATOR IN DC BKT.  17020000
         MVC   16(3,WR2),TXLOC(GRB)     MOVE TXLOC.                     17040000
         MVC   19(1,WR2),CESDID(ACT)    MOVE CURRENT ESD-ID             17060000
         LA    WR2,4(WR2)               BUMP RECORD POINTER             17080000
         SPACE 2                                                        17100000
* AT THIS POINT TEST IF WORK BUCKETS ATTATCHED. IF YES MOVE THEM IN.    17120000
         SPACE 1                                                        17140000
UPFREE   LA    WR2,16(WR2)                                              17160000
         L     GR2,SAVLEN               FETCH TOTAL SYM.BKT. LENGTH     17180000
         LTR   GR2,GR2                  IF ZERO, THEN NO SYM.BKTS.      17200000
         BZ    IPA                       TO MOVE.                       17220000
         L     GR1,CTXWBP(ACT)          FETCH SYMBOL BUCKET PTR.        17240000
         BCTR  GR2,0                    DECREMENT LENGTH AND EXECUTE    17260000
         EX    GR2,MVSYMBKT             A MOVE OF SYMBOL BUCKETS.       17280000
ALVISO   TM    0(GRD),X'10'             TEST VALUE SUBSTITUTED SWITCH   17300000
         BO    MILPITAS                 BRANCH IF ON                    17320000
         SR    GRZ,GRZ                                                  17340000
         IC    GRZ,TXSPTR(GRD)          COMPUTE RELATIVE PTR TO         17360000
         SH    GRZ,RELEQL               SYMBOL IN OPERAND FIELD.        17380000
         STC   GRZ,TXSPTR(GRD)                                          17400000
MILPITAS TM    0(GRD),8                 TEST LAST SYMBOL INDICATOR      17420000
         BO    SANJOSE                  BRANCH IF  LAST SYMBOL.         17440000
         LA    GRD,6(GRD)               KICK PTR TO NEXT SYMBOL BKT.    17460000
         B     ALVISO                   AND CONTINUE.                   17480000
SANJOSE  LA    GRD,6(GRD)               KICK PTR PAST LAST SYM. BKT.    17500000
IPA      S     GRD,CTSYMP(ACT)          REDUCE POINTER TO               17520000
         ST    WR2,CFREEP(ACT)          A DISPLACEMENT AND STORE        17540000
         MVC   TXLDSP(3,WBPTR),1(WR1)   SET DISPLACEMENT IN WB          17560000
         L     WR2,0(WR1)                                               17580000
         A     WR2,OPRNLN               ADD CURRENT LENGTH TO           17600000
         ST    WR2,0(WR1)               APPROPRIATE STRING LENGTH       17620000
         L     WR2,CTLITB(SAVE,ACT)     ADD 1 TO LITERAL COUNT          17640000
         LA    WR2,1(WR2)               IN                              17660000
         ST    WR2,CTLITB(SAVE,ACT)     APPROPRIATE STRING              17680000
SETWB1   OI    TXLASI(WBPTR),X'01'      SET LITERAL ASSIGNED INDICATOR  17700000
         STC   SAVE,TXLSTG(WBPTR)       SET LITERAL STRING NUMBER       17720000
         IC    SP1,CTLEN+3(ACT)                                         17740000
         BCTR  SP1,0                                                    17760000
         STC   SP1,TXLLEN(WBPTR)                                        17780000
LTVL3    MVI   LITSW,X'00'              RESET LITERAL SWITCH            17800000
         L     SP1,GRASAVE              RESTORE POINTER TO LAST CHR9538 17810013
         B     CTRTRN(ACT)              BACK TO MAIN LINE               17820000
LTVL3A   TM    TXLASI(GRB),1                                            17840000
         BZ    LITENT                   LIT NOT ASSIGNED PREV    A52831 17880021
         TM    TXLSOP(GRB),X'08'        LIT IN SECOND OPERAND    A52831 17882021
         BO    LTVL3                    YES, OK                  A52831 17884021
         LA    GRA,2(GR1)               LOAD ADDR TO = SIGN+1    A52831 17890021
         B     LITENT                   AND EVALUATE             A52831 17892021
LCOMP    CLC   0(0,GRA),4(GRD)          EXECUTED COMPARE-SOURCE LITS.   17900000
MOVTEX   MVC   4(0,GRD),0(GRA)          EXECUTED MOVE-SOURCE LITS.      17920000
MVSYMBKT MVC   0(0,GRD),0(GR1)          EXEC. MOVE - SYMBOL BKTS.       17940000
         SPACE 2                                                        17960000
* TABLES, CONSTANTS, AND SWITCHES, AND TEMPORARY STORAGE.               17980000
         SPACE 1                                                        18000000
REGSAV   DC    12F'0'                   REGISTER SAVE AREA              18020000
LITPTR   DC    F'0'                     DISP FOR LITERAL POINTER        18040000
         DC    F'3'                                                     18060000
         DC    F'6'                                                     18080000
         DC    F'9'                                                     18100000
PREPTR   DC    F'0'                     SAVE AREA FOR WR2               18120000
SAVPTR   DS    F                        POINTER TO BEGINNING OF FIELD   18140000
FINADR   DS    F                                   END OF FIELD         18160000
OPRNLN   DC    F'0'                     OPERAND LENGTH                  18180000
DSMAX    DC    X'0000FFFF'              MAX LENGTH FOR DS               18200000
LOCSW    DC    X'00'                    SWITCH FOR LOCATION CNT REF     18220000
DUPFAC   DS    F                        DUPLICATION FACTOR              18240000
RSLT     DS    F                        SWITCH FOR ERRORS               18260000
LLNG     DS    F                        LENGTH                          18280000
ERRORPTR DS    F                        COLUMN NUMBER OF ERROR          18300000
TOTAL    DS    F                        LOCATION COUNTER                18320000
SAVWBP   DS    F                        TEMP STORAGE FOR CTXWBP         18340000
GRASAVE  DS    F                        SAVE AREA FOR POINTER      9538 18350013
DEFLEN   DC    X'00'                    DEFINITION LENGTH               18360000
SIGN     DC    X'00'                    SIGN OF CONSTANT                18380000
ALWRD    DC    F'0'                     NO. BYTES OF ALIGNMENT          18400000
CON16    DC    H'16'                    MAX LENGTH FOR ZONED            18420000
BITREM   DC    H'00'                    BIT REMAINDER                   18440000
NOCON1   DC    X'00'                    NO. OF CONSTANTS - HALF WORD    18460000
NOCONS   DC    X'00'                                     - BYTE         18480000
LITSW    DC    X'00'                    SWITCH IF A LITERAL             18500000
OPCOD    DC    X'00'                    OPERATION                       18520000
DCBKT    DS    C                        DC WORKBUCKET COUNTER           18540000
         SPACE 2                                                        18560000
* ERROR ASSIGNMENT TABLE                                                18580000
         SPACE 1                                                        18600000
ZRC01    MVI   KAPUT+1,1                DUPLICATION FACTOR ERROR.       18620000
         B     EXIT                                                     18640000
ZRC02    MVI   KAPUT+1,2                RELOCATABLE DUPLICATION FACTOR  18660000
         B     EXIT                                                     18680000
ZRC03    MVI   KAPUT+1,3                LENGTH ERROR                    18700000
         B     EXIT                                                     18720000
ZRC04    MVI   KAPUT+1,4                RELOCATABLE LENGTH              18740000
         B     EXIT                                                     18760000
ZRC05    MVI   KAPUT+1,5                S-TYPE CONSTANT IN LITERAL      18780000
         B     EXIT                                                     18800000
ZRC11    MVI   KAPUT+1,11               SCALE MODIFIER ERROR            18820000
         B     EXIT                                                     18840000
ZRC12    MVI   KAPUT+1,12               RELOCATABLE SCALE MODIFIER      18860000
         B     EXIT                                                     18880000
ZRC13    MVI   KAPUT+1,13               EXPONENT MODIFIER ERROR         18900000
         B     EXIT                                                     18920000
ZRC14    MVI   KAPUT+1,14               RELOCATABLE EXPONENT MODIFIER   18940000
         B     EXIT                                                     18960000
ZRC15    MVI   KAPUT+1,15               INVALID LITERAL USAGE.          18980000
         B     EXIT                                                     19000000
ZRC17    MVI   KAPUT+1,17               DATA ITEM TOO LARGE             19020000
         B     EXIT                                                     19040000
ZRC18    MVI   KAPUT+1,18               SYMBOL ERROR                    19060000
         B     EXIT                                                     19080000
ZRC31    MVI   KAPUT+1,31               UNKNOWN TYPE                    19100000
         B     EXIT                                                     19120000
ZRC39    MVI   KAPUT+1,39               INVALID DELIMITER               19140000
         B     EXIT                                                     19160000
ZRC87    MVI   KAPUT+1,87               NO ENDING APOSTROPHE      23218 19166018
         B     EXIT                                               23218 19172018
ZRC100   MVI   KAPUT+1,100              STATEMENT COMPLEXITY EXCEEDED   19180000
         B     EXIT                                                     19200000
ZRC107   MVI   KAPUT+1,107              INVALID OPERAND                 19220000
         B     EXIT                                                     19240000
         DS    0F                                                       19260000
TRTABL   DC    X'09'                    A                               19280000
         DC    X'02'                    B                               19300000
         DC    X'00'                    C                               19320000
         DC    X'05'                                                    19340000
         DC    X'06'                    E                               19360000
         DC    X'07'                    F                               19380000
         DC    X'FF'                    G                               19400000
         DC    X'08'                    H                               19420000
         DC    X'FF'                    I                               19440000
         DC    X'FF'                    J                               19460000
         DC    X'FF'                    K                               19480000
         ENTRY LCNPTR                                              IEUO 19490018
LCNPTR   DC    X'0E'                    L                         IEUN2 19500018
         DC    X'FF'                    M                               19520000
         DC    X'FF'                    N                               19540000
         DC    X'FF'                    O                               19560000
         DC    X'03'                    P                               19580000
         ENTRY QCNPTR                                              IEUO 19590018
QCNPTR   DC    X'0D'                    Q                          IEUO 19600018
         DC    X'FF'                    R                               19620000
         DC    X'0C'                    S                               19640000
         DC    X'FF'                    T                               19660000
         DC    X'FF'                    U                               19680000
         DC    X'0B'                    V                               19700000
         DC    X'FF'                    W                               19720000
         DC    X'01'                    X                               19740000
         DC    X'0A'                    Y                               19760000
         DC    X'04'                    Z                               19780000
         SPACE 2                                                        19800000
* TYTABL CONTAINS ONE SIX-BYTE ENTRY FOR EACH DC/DS TYPE AS FOLLOWS---  19820000
*        BYTE 1 --- 0-3  IMPLIED LENGTH CODE - SEE ILTABLE        IEUN2 19840018
*                   4    SOMETHING TO DO WITH ADCONS              IEUN2 19860018
*                   5    BIT LENGTH LEGAL=1                             19880000
*                   6    SCALE MODIFIER LEGAL=1                         19900000
*                   7    EXPONENT MODIFIER LEGAL=1                      19920000
*        BYTE 2 --- 0-7  MINIMUM LENGTH MODIFIER VALUE                  19940000
*        BYTE 3 --- 0-7  MAXIMUM LENGTH MODIFIER VALUE MINUS ONE        19960000
*        BYTES 4-6       BRANCH ADDRESS FOR SCAN ROUTINE                19980000
         SPACE 1                                                        20000000
TYTABL   DC    0X'123456'               DUMMY TO START TABLE      IEUN2 20010018
         DC    X'0401FF'                CHARACTER                 IEUN2 20020018
         DC    AL3(CTYP)                                                20040000
         DC    X'0401FF'                HEXADECIMAL               IEUN2 20060018
         DC    AL3(XTYPE)                                               20080000
         DC    X'0401FF'                BINARY                    IEUN2 20100018
         DC    AL3(BTYPE)                                               20120000
         DC    X'04010F'                PACKED                    IEUN2 20140018
         DC    AL3(PTYPE)                                               20160000
         DC    X'04010F'                ZONED                     IEUN2 20180018
         DC    AL3(PTYPE)                                               20200000
         DC    X'370107'                DBL FLOATING POINT        IEUN2 20220018
         DC    AL3(FHEDSCAN)                                            20240000
         DC    X'270107'                SGL FLOATING POINT        IEUN2 20260018
         DC    AL3(FHEDSCAN)                                            20280000
         DC    X'270107'                FULLWORD FIXED POINT      IEUN2 20300018
         DC    AL3(FHEDSCAN)                                            20320000
         DC    X'170107'                HALFWORD FIXED POINT      IEUN2 20340018
         DC    AL3(FHEDSCAN)                                            20360000
         DC    X'2C0103'                A-CON                     IEUN2 20380018
         DC    AL3(ATYPE)                                               20400000
         DC    X'1C0101'                Y-CON                     IEUN2 20420018
         DC    AL3(YTYPE)                                               20440000
         DC    X'280303'                V-CON                     IEUN2 20460018
         DC    AL3(VTYPE)                                               20480000
         DC    X'180201'                S-CON                     IEUN2 20500018
         DC    AL3(STYPE)                                               20520000
         DC    X'280103'                Q-CON                     IEUN2 20540018
         DC    AL3(QTYPE)                                               20560000
         DC    X'47010F'                L-CON                     IEUN2 20562018
         DC    AL3(FHEDSCAN)                                      IEUN2 20564018
         SPACE 2                                                  IEUN2 20566018
* ILTABLE CONTAINS A ONE-BYTE ENTRY FOR EACH DIFFERENT IMPLIED    IEUN2 20568018
*        LENGTH CODE FROM BYTE 1, BITS 0-3, OF TYTABL.  ITS       IEUN2 20570018
*        PURPOSE IS CONSERVE BITS IN TYTABLE.  THIS TABLE YIELDS  IEUN2 20572018
*        ACTUAL VALUE OF THE IMPLIED LENGTH.                      IEUN2 20574018
ILTABLE  DC    X'0102040810'            CODES 0 - 4               IEUN2 20576018
         SPACE 2                                                  IEUN2 20578018
LNKSAV   DS    F                        DCEVAL BASE REGISTER            20580000
SAVLEN   DS    F                        LENGTH OF SYMBOL BUCKETS        20600000
RELEQL   DC    H'0'                     RELATIVE POINTER TO OPERAND     20620000
ADCSW    DC    X'00'                    ADDRESS CONSTANT SWITCH         20640000
VSCNSW   DC    X'00'                    V-TYPE CONSTANT SWITCH          20660000
EXITSW   DC    X'00'                    EXIT SWITCH FOR WHICH SCAN      20680000
XPRESW   DC    X'00'                    PREVENT XREF SWITCH      A28596 20690020
ERSW     DS    X                        ERSW THRU FCONS INITIALIZED     20700000
FOPND    DS    X                         WITH ONE XC. DO NOT DISTURB.   20720000
FCONS    DS    X                                                        20740000
PZLNAT   DS    F                        PZLNAT THRU WLMOD INITIALIZED   20760000
SCMODF   DS    H                         WITH ONE XC. DO NOT DISTURB    20780000
DCTYP1   DC    X'00'                    DC TYPE - HALF WORD             20800000
DCTYP    DS    X                                - BYTE                  20820000
ALBYS    DS    X                        NO. BYTES FOR ALIGNMENT         20840000
RLSW     DS    X                        SWITCH TO UP-DATE RECORD LENGTH 20860000
LMSW     DS    X                        LENGTH MODIFIER PRESENT SWITCH  20880000
BITSW    DS    X                        BIT SWITCH                      20900000
EXMODF   DS    X                        EXPONENT RIGHT ADJUSTED         20920000
WLNAT    DS    X                        WKBKT LENGTH ATTRIBUTE          20940000
WFLAG    DS    X                              FLAG                      20960000
WTYP     DS    X                              TYPE                      20980000
WTOTL    DS    XL3                            OPERAND LENGTH            21000000
WDUP     DS    XL3                            DUP FACTOR                21020000
WNCONS   DS    X                              NUMBER OF CONSTANTS       21040000
WPTR1    DS    X                              POINTER FIRST BYTE OPERND 21060000
WEXP     DS    X                              EXPONENT                  21080000
WSCL     DS    XL2                            SCALE FACTOR              21100000
WLMOD    DS    XL2                            LENGTH MODIFIER           21120000
FHEDSW   DS    C                        SIGN, EXPONENT, POT SWITCH      21140000
         SPACE 2                                                        21160000
* THIS IS A CONNECTOR TO THE EXPRESSION EVALUATION SUBROUTINE.          21180000
         SPACE 1                                                        21200000
XPREVA   MVI   ADCSW,X'FF'              SET ADR CON SWITCH              21220000
         OI    F8YDC+1(ACT),1           SET EEVAL ADCON SWITCH          21240000
         B     XPREV2                                                   21260000
XPREV    OI    CTPDSI(ACT),X'20'        SET PREV. DEF. SYMBOL SWITCH    21280000
         CLI   0(GRA),ILPARN            TEST FOR LEFT PAREN.            21300000
         BE    XPREV1                                                   21320000
         CLI   0(GRA),I9                TEST FOR NUMERIC                21340000
         BH    XPREV2                                                   21360000
         OI    CTSDVI(ACT),X'80'        SET SELF DEFINING VALUE SWITCH  21380000
         B     XPREV2                                                   21400000
XPREV1   LA    GRA,1(GRA)               KICK TEXT POINTER               21420000
XPREV2   LR    SP1,GRA                  TEXT POINTER TO SP1 FOR EEVAL.  21440000
         ST    SP1,ERRORPTR             STORE COLUMN POINTER FOR LOGERR 21460000
         MVC   XPRESW,VSCNSW            IF SEC VCON SCAN PREV XRFA28596 21463020
         CLI   ADCSW,X'FF'              IS THIS AN ADCON .Q      A28596 21466020
         BNE   XPREV2B                  NO, BRANCH               A28596 21469020
         CLI   LITSW,X'FF'              TEST IF LITERAL          A28596 21472020
         BNE   XPREV2B                  NO, BRANCH               A28596 21475020
         OI    F8YDC+1(ACT),X'02'       SET EEVAL LITERAL SWITCH A28596 21478020
         TM    TXLXRI(GRB),4            XREF PREVIOUSLY MADE .Q  A28596 21481020
         BZ    XPREV2B                  NO, BRANCH               A28596 21484020
         MVI   XPRESW,X'FF'             PREVENT DUBBLE XREF      A28596 21487020
XPREV2B  CLI   XPRESW,X'FF'             TEST FOR SECOND SCAN     A28596 21490020
         BNE   FRSTSCN                  BRANCH IF FIRST SCAN.           21500000
         MVI   XREF+1,2                 SAVEXREF BIT FROM CENTRAL       21520000
         NC    XREF+1(1),CTXRFI(ACT)     TABLE AND THEN TURN IT OFF TO  21540000
         NI    CTXRFI(ACT),X'FD'         PREVENT DOUBLE XREF BY EEVAL.  21560000
FRSTSCN  ST    SRR,LNKSAV               SAVE DCEVAL BASE REGISTER.      21580000
         L     SRB,CEEVAL(ACT)                                          21600000
         BALR  SRR,SRB                                                  21620000
         LR    GRA,SP1                  TEXT PTR FROM EEVAL TO GRA.     21640000
         BALR  GR1,0                    SAVE RIGHTMOST 32 BITS          21660000
         ST    GR1,RSLT                  OF PSW IN RSLT.                21680000
         NI    F8YDC+1(ACT),X'FC'       RESET EEVAL ADCON AND LITA28596 21700020
         CLI   0(GRA),IRPARN            TEST FOR RIGHT PAREN.           21720000
         BNE   XPREV3                                                   21740000
         CLI   ADCSW,X'FF'              TEST ADDR CON SWITCH            21760000
         BE    XPREV3                                                   21780000
         LA    GRA,1(GRA)               KICK TEXT POINTER               21800000
XPREV3   L     SRR,LNKSAV               LOAD RETURN REGISTER            21820000
         MVI   ADCSW,X'00'                                              21840000
         CLI   LITSW,X'FF'              TEST FOR LITERAL                21860000
         BNE   XPREV3A                  NO,BRANCH                       21880000
         MVC   CTXWBP(4,ACT),SAVWBP     YES, RESTORE SYMBOL BKT PTR.    21900000
XPREV3A  CLI   XPRESW,X'FF'             TEST IF XREF PREVENTED   A28596 21920020
         BCR   7,SRR                    RETURN NOW IF FIRST SCAN        21940000
XREF     OI    CTXRFI(ACT),0            RESTORE XREF BIT IN CENT. TBL.  21960000
         BR    SRR                      RETURN FROM WHENCE THOU CAME    21980000
WR1      EQU   GRC                      6                               22000000
WR2      EQU   GRD                      7                               22020000
EVENR    EQU   GRX                      14                              22040000
ODDR     EQU   GRY                      15                              22060000
R1       EQU   WR1                                                      22080000
SAVE     EQU   GRX                      14                              22100000
WBPTR    EQU   GRB                      5                               22120000
DS       EQU   X'27'                    DS OP-CODE                      22140000
GR14     EQU   14                                                       22160000
YTYPE    EQU   ATYPE                                                    22180000
         DS    20F                      PATCH AREA                      22200000
         LTORG                                                          22220000
         END   DCEVL                                                    22240000
