F7E      TITLE 'IEUF7E, EXTERNAL SYMBOL DICTIONARY PROCESSOR'           00020000
         ISEQ  73,80                                                    00040000
IEUF7E   CSECT                                                          00060000
*          RELEASE  19  DELETIONS                                       00064019
*                                                                A27016 00068019
*          RELEASE  20  DELETIONS                                       00072019
* 107800,110600-110800                                             I004 00073020
*                                                                A31001 00074020
* 098000                                                         A32954 00075020
*          RELEASE  21  DELETIONS                                       00076019
* 124600,132200,254800                                           A45759 00080000
* 097860-098100                                                  A45780 00082021
* 041600                                                         A52808 00084021
         PRINT DATA,NOGEN                                               00100000
         FDIMEN                                                         00120000
         USING *,FRB                                                    00140000
 SPACE                                                                  00160000
*TITLE-  IEUF7E  EXTERNAL SYMBOL DICTIONARY PROCESSOR                 * 00180000
*STATUS CHANGE LEVEL 004                                                00188021
*                                                                       00196020
* INCREMENTAL IMPROVEMENTS FO RELEASE 20                                00204020
* I004 IMPLEMENTATION OF WXTRN                                          00212020
*FUNCTION/OPERATION-                                                  * 00220000
*   GENERATE EXTERNAL SYMBOL DICTIONARY ENTRIES                       * 00240000
*   UPDATE THE LOCATION COUNTER IN ESD ENTRIES                        * 00260000
*   GENERATE SYMBOL TABLE ENTRIES FOR NAMES IN THE NAME FIELD OF      * 00280000
*    STATEMENTS HANDLED BY IEUF7E                                     * 00300000
*   SET AND MAINTAIN THE FOLLOWING ASSEMBLER CONTROL TABLE SWITCHES-  * 00320000
*        CBDNO...BLANK DSECT ESD NUMBER                               * 00340000
*        CBDSW...BLANK DSECT ID NUMBER                                * 00360000
*        CCMNO...COMMON ESD NUMBER                                    * 00380000
*        CESDID..CURRENT ESD ID NUMBER                                * 00400000
*        CESDNO..CURRENT ESD NUMBER                                   * 00420000
*        CNOESD..NUMBER OF ESD ENTRIES                                * 00440000
*        CPCNO...UNINITIATED PRIVATE CODE ESD NUMBER                  * 00460000
*        CTPCSW..PRIVATE CODE SWITCH                                  * 00480000
*        CSTVAL..VALUE FROM START CARD                                * 00500000
*        CSGCTR..ESD RESIDENT SEGMENT COUNTER                         * 00520000
*        CLASID..LAST ESD ID NUMBER                                   * 00540000
*        CNTDID..NEXT DSECT ID NUMBER                                 * 00560000
*        CTCMSW..COMMON SWITCH                                        * 00580000
*        CTESDP..ESD TABLE POINTER (FIRST BYTE)                       * 00600000
*        CTESRN..FIRST ESD NUMBER                                     * 00620000
*        CTESRP..ESD SEGMENT RESIDENCE TABLE ENTRY POINTER            * 00640000
*        CTFSTN..FIRST CSECT NAME                                     * 00660000
*        CTLOC...CURRENT LOCATION COUNTER                             * 00680000
*        CTYPE...CURRENT CSECT TYPE                                   * 00700000
*   DTECT AND LOG THE FOLLOWING ERRORS                                * 00720000
*        INVALID ORIGIN                                               * 00740000
*        EXTERNAL NAME ERROR                                          * 00760000
*        SYMBOL NOT PREVIOUSLY DEFINED                                * 00780000
*        ESD TABLE OVERFLOW                                           * 00800000
*        RELOCATABILITY ERROR                                         * 00820000
*        ALIGNMENT ERROR                                              * 00840000
*        ENTRY ERROR                                                  * 00860000
*        INVALID DELIMITER                                            * 00880000
*        ILLEGAL START CARD                                           * 00900000
*        ENTRY TABLE OVERFLOW                                         * 00920000
*ENTRY POINTS-                                                        * 00940000
*        UPC...PROCESS UNINITIATED PRIVATE CODE                       * 00960000
*        COM,START,CSECT,DSECT...PROCESS STATEMENTS OF SAME NAMES     * 00980000
*        ESWBKR...FILL ESD WORKBUCKET                                 * 01000000
*        ENTRY,EXTRN,WXTRN,ORG...PROCESS STATEMENTS OF SAME NAME   I004 01020020
*        ENTRYS,EXTRNS,WXTRNS..PROCESS ENTRY,EXTRN,WXTRN SMTS      I004 01040020
*                        WITH SUBSTITUTION                         I004 01060020
*        QUIT...                                                      * 01080000
*        DXD...                                                       * 01100000
*        VCON...PROCESS VCON'S OR QCON'S                              * 01120000
*INPUT-  NONE                                                         * 01140000
*OUTPUT- NONE                                                         * 01160000
*   CALLING SEQUENCE-                                                 * 01180000
*        L     GRX,NAME(ACT)       NAME(ACT) CONTAINS DESIRED ADDRESS * 01200000
*        B     CTLNK2(ACT)         BRANCH TO LINKAGE CODE WITHIN ACT  * 01220000
*     CTLNK2(ACT) CONTAINS-                                           * 01240000
*        L     FRB,CBRNDA(ACT)     CBRNDA(ACT)CONTAINS IEUF7E ADDRESS * 01260000
*        B     GRX                                                    * 01280000
*        STM   GRA,GRD,SAVER                                          * 01300000
*EXTERNAL ROUTINES-                                                   * 01320000
*   IEUF7L (LOGERR)  RECORD ERRORS DETECTED                           * 01340000
*   IEUF7V (EEVAL) OPERAND EVALUATION                                 * 01360000
*   IEUF7I (STPUTR,STGETR,CRDESD,PUTXRF) PERFORM I/O FUNCTIONS        * 01380000
*EXIT-                                                                * 01400000
*   NORMAL-                                                           * 01420000
*        B     CTRTRN(ACT)         BRANCH TO RETURN LINKAGE OF ACT    * 01440000
*     CTRTRN(ACT) CONTAINS                                            * 01460000
*        LM    GRA,GRD,SAVER                                          * 01480000
*        BR    CRR                 RETURN TO CALLING PROGRAM          * 01500000
*   ERRORS-                                                           * 01520000
*        SAME SEQUENCE AS NORMAL RETURN                               * 01540000
*TABLES/WORK AREAS-                                                   * 01560000
*   ESD ENTRY WORK AREA...16 BYTES, STARTING AT LOCATION 'TYPE'       * 01580000
*NOTES-                                                               * 01600000
*                  THE  EXTERNAL SYMBOL DICTIONARY (ESD)  IS            01620000
*              SEGMENTED INTO BLOCKS OF 260 BYTES EACH, FULL            01640000
*              WORD ALIGNED.  THE FIRST BYTE OF EACH SEGMENT            01660000
*              IS SET TO X'03' TO IDENTIFY  THE BLOCK TO THE            01680000
*              I/O ROUTINES. 16 ITEMS,WORD-ALIGNED,OF LENGTH            01700000
*              16 BYTES EACH FILL THE SEGMENT,  BEGINNING AT            01720000
*              THE LAST (HIGHEST NUMBERED) BYTE.                        01740000
  SPACE 2                                                               01760000
*                   THE FORMAT OF EACH ITEM IS AS FOLLOWS               01780000
 SPACE                                                                  01800000
*             ************************************************          01820000
*             *                      *                       *          01840000
*             * ATTRIBUTES (8 BYTES) * NAME (8 BYTES,PADDED) *          01860000
*             *                      *                       *          01880000
*             ************************************************          01900000
 EJECT                                                                  01920000
*              THE ATTRIBUTE FIELD FORMAT IS ONE OF THE FOLLOWING       01940000
 SPACE                                                                  01960000
*                   CONTROL OR DUMMY SECTION (PC,CM,SD OR DS)           01980000
*                                                                       02000000
*       *********************************************************       02020000
*       *      *                    *      *                    *       02040000
*       * TYPE * CURRENT LOC. CTR.  *  ID  * HIGHEST LOC. CTR.  *       02060000
*       *      *                    *      *                    *       02080000
*       *********************************************************       02100000
*                                                                       02120000
*                   THE LOCATION COUNTERS ARE UPDATED BY THE            02140000
*              ROUTINES 'ORG' OR 'ESFIN' WHENEVER A CSECT,              02160000
*              DSECT,COM OR ORG INSTRUCTION IS ENCOUNTERED              02180000
*              IN ASSIGNMENT MODE.                                      02200000
  SPACE                                                                 02220000
*                   EXTERNAL SYMBOL (ER,WX OR VC)                  I004 02240020
*                                                                       02260000
*       *********************************************************       02280000
*       *      *                    *      *                    *       02300000
*       * TYPE *        ZERO        *  ID  *        ZERO        *       02320000
*       *      *                    *      *                    *       02340000
*       *********************************************************       02360000
 SPACE                                                                  02380000
*                   ENTRY LABEL DEFINITION (LD)                         02400000
*                                                                       02420000
*       *********************************************************       02440000
*       *      *                    *      *                    *       02460000
*       * TYPE *      ADDRESS       * FLAG *    ZERO     * LDID *       02480000
*       *      *                    *      *                    *       02500000
*       *********************************************************       02520000
*                                                                       02540000
*                   THE FLAG IS SET TO ONE TO INDICATE THAT             02560000
*              THE ITEM IS COMPLETE. THE ADDRESS AND LDID               02580000
*              IDENTIFY THE RELATIVE LOCATION AND ESDID OF              02600000
*              THE SYMBOL REFERENCED                                    02620000
 SPACE                                                                  02640000
*                   EXTERNAL DUMMY SECTION (XD)                         02660000
*                                                                       02680000
*       *********************************************************       02700000
*       *      *             *      *      *                    *       02720000
*       * TYPE *    ESDNO    *ALIGN *  ID  *       LENGTH       *       02740000
*       *      *             *      *      *                    *       02760000
*       *********************************************************       02780000
*                                                                       02800000
*                   THE ESDNO IS USED TO POINT TO THE  DSECT            02820000
*              REFERENCED BY THE CORRESPONDING Q-CON.  IT IS            02840000
*              ZERO,AND THE LENGTH FIELD SET, WHEN THE ITEM             02860000
*              WAS CREATED BY A DXD INSTRUCTION. ALIGN GIVES            02880000
*              THE ALIGNMENT.                                           02900000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 02920000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 02940000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 02960000
         SPACE 2                                                        02980000
*              PHASE 7 MAIN LINE PASSES CONTROL TO ONE OF THESE       * 03000000
*        ENTRY POINTS ON ANY STATEMENT WHICH AFFECTS THE EXTERNAL     * 03020000
*        SYMBOL DICTIONARY.  ITEMS ARE ENTERED IN THE DICTIONARY,     * 03040000
*        UPDATED WHEN NECESSARY,AND SYMBOL TABLE ENTRIES MADE.        * 03060000
*                                                                     * 03080000
 SPACE                                                                  03100000
         ENTRY UPC,COM,START,CSECT,DSECT,DXD,ESWBKR                     03120000
         ENTRY ENTRY,ENTRYS,EXTRN,EXTRNS,ORG,QUIT,VCON                  03140000
         EJECT                                                          03160000
*********************************************************************** 03180000
***                 UNINITIATED PRIVATE CODE ROUTINE                *** 03200000
*    THE UNINITIATED PRIVATE CODE ROUTINE IS CALLED WHENEVER AN EQU,  * 03220000
*  ORG, LTORG, LITR, DC, DS, CCW, CNOP, OR MACHINE OP IS ENCOUNTERED  * 03240000
*  BEFORE THE FIRST CSECT, START, COMMON, OR DSECT.                   * 03260000
*                                                                     * 03280000
UPC      MVC   NAME(8),IBL2F            BLANK OUT NAME                  03300000
         BAL   LEV3,FSTNR               PROCESS IF FIRST ONE            03320000
         MVI   TYPE,PCCON               SET TYPE = PC                   03340000
         SR    ACC,ACC                                                  03360000
         ST    ACC,CTLOC(ACT)           SET CURRENT LOC CTR = 0         03380000
         BAL   LEV2,SETESD              PUT IN ESD                      03400000
         MVI   CTYPE(ACT),PCCON         SET TYPE = PC                   03420000
         MVC   CTPCSW(1,ACT),CESDID(ACT)    PC SWITCH AND FIRST CONTROL 03440000
         MVC   CPCNO(2,ACT),CESDNO(ACT)                                 03460000
         STM   GRA,CRR,SAVEREG          SAVE REGISTERS           A31001 03462020
         L     GRB,CTEXTP(ACT)          SAVE TEXT REC POINTER    A31001 03464020
         LA    GRA,TEXTREC              POINT TO SIMULATED CSECT A31001 03466020
         ST    GRA,CTEXTP(ACT)                                   A31001 03468020
         L     FRB,CTESTR(ACT)                                   A31001 03470020
         BALR  CRR,FRB                  MAKE TESTRAN ENTRY       A31001 03472020
         ST    GRB,CTEXTP(ACT)          RESTORE TEXT REC POINTER A31001 03474020
         LM    GRA,CRR,SAVEREG          RESTORE REGISTERS        A31001 03476020
         B     CTRTRN(ACT)              EXIT                            03480000
*                                                                     * 03500000
SAVEREG  DC    4F'0'                                             A31001 03506020
TEXTREC  DC    X'000000801B00000000'                             A31001 03512020
*********************************************************************** 03520000
 SPACE 2                                                                03540000
*********************************************************************** 03560000
***                          COM ROUTINE                            *** 03580000
*                                                                     * 03600000
COM      MVI    TYPE,CMCON              SET TYPE = CM                   03620000
         BAL    LEV1,ESFIN              FINISH PREVIOUS SECTION IF ANY  03640000
         MVC   CTLOC(4,ACT),CTZERO(ACT) SET CTLOC = 0                   03660000
         MVC   NAME(8),IBL2F            BLANK NAME                      03680000
         CLI   CTCMSW(ACT),0            HAS COM BEEN PREVIOUSLY STARTED 03700000
         BC    7,CMCONT                   YES                           03720000
 SPACE                                                                  03740000
         BAL   LEV2,SETESD                NO - SET ESD                  03760000
CMCNTR   MVC   CTYPE(1,ACT),TYPE        SET CURR TYPE                   03780000
         MVC   CTCMSW(1,ACT),CESDID(ACT)   COM SWITCH                   03800000
         MVC   CCMNO(2,ACT),CESDNO(ACT)     COM ESD NO                  03820000
         B     SETWBK                   CREATE WORKBUCKET               03840000
 SPACE 2                                                                03860000
CMCONT   LH    SP2,CCMNO(ACT)                                           03880000
         STH   SP2,CESDNO(ACT)          SET CURR ESD NO FOR CM          03900000
         BAL   LEV2,PNTESD              POINT TO PREVIOUS ESD ITEM FOR  03920000
         MVC   ESDID(1,ACT),TID(SP1)      COM                           03940000
         MVC   CESDID(1,ACT),TID(SP1)   SET ESDID -ASSIGNED AND CURRENT 03960000
         MVC   CTLOC+1(3,ACT),TADDR(SP1) SET CURR LOC CTR               03980000
         B     CMCNTR                   CONTINUE WITH ESD SET           04000000
*                                                                     * 04020000
*********************************************************************** 04040000
         EJECT                                                          04060000
*********************************************************************** 04080000
***                            START ROUTINE                        *** 04100000
*                                                                     * 04120000
*                                                                     * 04140000
START    CLC   CTESRN(2,ACT),CTZERO(ACT)  IS THIS THE 1ST CSECT  A52808 04160021
         BE    SRT1ST                   YES, CONTINUE                   04180000
 SPACE                                                                  04200000
SRTERR   BAL   SRR,LOGERR               NO, ERROR - ILLEGAL START CARD  04220000
         DC    AL2(ERR01)                                               04240000
         B     CSECT                    TREAT AS CSECT                  04260000
 SPACE 2                                                                04280000
SRT1ST   L     SP1,CTXOFP(ACT)            YES - IS THE OPERAND PRESENT  04300000
         BAL   LEV3,ISOPF               IS THERE AN OPERAND FIELD       04320000
         BC    8,CSECT                  NO, TREAT AS CSECT              04340000
 SPACE                                                                  04360000
         LA    SP1,1(SP1)                   YES - POINT TO OPERAND      04380000
         ST    SP1,ERRPTR               SAVE OPERAND COLUMN POINTER     04400000
         OI    CTSDVI(ACT),ONSDVI        AND SET SELF-DEFINING VALUE    04420000
         L     SRB,CEEVAL(ACT)            INDICATOR ON                  04440000
         BALR  SRR,SRB                  EVALUATE EXPRESSION             04460000
         TM    CTSDVI(ACT),ONSDVI       WAS SELF-DEFINING VALUE FOUND   04480000
         BZ    SRTABS                   YES, CONTINUE                   04500000
 SPACE                                                                  04520000
         BAL   SRR,ELOGER               NO, ERROR - RELOCATION ERROR    04540000
         DC    AL2(ERR03)                                               04560000
         B     CSECT                    AND TREAT AS CSECT              04580000
 SPACE 2                                                                04600000
SRTABS   CLI   0(SP1),IBLANK            IS NEXT CHARACTER A BLANK       04620000
         BE    SRTSET                   YES, CONTINUE                   04640000
 SPACE                                                                  04660000
         BAL   SRR,LOGERP               NO, ERROR - INVALID DELIMITOR   04680000
         DC    AL2(ERR02)                                               04700000
         B     CSECT                    AND TREAT AS CSECT              04720000
 SPACE                                                                  04740000
SRTSET   ST    SP2,CSTVAL(ACT)            YES - SET START VALUE         04760000
         TM    CSTVAL+3(ACT),MOD8       IS START VALUE = 0 MOD 8        04780000
         BZ    CSECT                      YES - GO TO CSECT             04800000
 SPACE                                                                  04820000
         LA    SP2,7(SP2)                 NO - SET START VALUE TO NEXT  04840000
         N     SP2,=F'-8'                   MULTIPLE OF 8               04860000
         ST    SP2,CSTVAL(ACT)                                          04880000
         BAL   SRR,ELOGER               LOG IT AS ERROR - ALIGNMENT     04900000
         DC    AL2(ERR04)                                               04920000
*        B     CSECT                    AND GO ON                       04940000
*                                                                     * 04960000
*********************************************************************** 04980000
         EJECT                                                 MMM      05000000
*********************************************************************** 05020000
***                          CSECT ROUTINE                          *** 05040000
CSECT    MVI   TYPE,SDCON               SET TYPE = SD                   05060000
         MVI   CTYPE(ACT),SDCON                                         05080000
         BAL   LEV1,ESFIN               FINISH PREVIOUS SECTION IF ANY  05100000
 SPACE                                                                  05120000
         MVC   CTLOC(4,ACT),CTZERO(ACT) SET CURRENT LOC. CTR TO ZERO    05140000
         BAL   LEV3,GETNAME             GET THE NAME                    05160000
         NOP   CSP3                     NAME BLANK                      05180000
 SPACE                                                                  05200000
CSP3     BAL   LEV3,FSTNR               SET FIRST ESDNO IF FIRST TIME   05220000
         L     ACC,CTXABP(ACT)          IS WORKBUCKET FILLED            05240000
         CLI   WBKSW(ACC),FILLED                                        05260000
         BZ    CWBKFL                   YES, SKIP                       05280000
 SPACE                                                                  05300000
         CLC   NAME(8),IBL2F            NO - IS NAME BLANK              05320000
         BZ    CSPC                         YES - PRIVATE CODE          05340000
 SPACE                                                                  05360000
         BAL   LEV3,STGET               GET SYMBOL                      05380000
         LA    LEV2,SETWBK              IF ABSENT,                      05400000
         BZ    SETESD                    SET ESD AND EXIT               05420000
 SPACE                                                                  05440000
FNDST    MVC   TEMPH(2),0(SP1)          SYMBOL FOUND IN ST - CHECK TYPE 05460000
         B     FNDTOG                                                   05480000
 SPACE                                                                  05500000
CWBKFL   MVC   TEMPH(2),WBKNO(ACC)      IF WKBKT IS FULL                05520000
FNDTOG   L     SP2,TEMPF                  FIND ADJ CODE AND             05540000
         SRL   SP2,7                    ESDNO                           05560000
         NI    ADJ,SDMSK                                                05580000
         CLI   ADJ,SDBITS               IS ADJ CODE = SD                05600000
         BNE   FNDERR                   NO, LOG ERROR                   05620000
 SPACE 2                                                                05640000
FNDENT   STH   SP2,CESDNO(ACT)          SET CURR ESD NO                 05660000
         BAL   LEV2,PNTESD                POINT TO ESD                  05680000
         IC    ACC,TID(SP1)             GET ID                          05700000
         STC   ACC,ESDID(ACT)           SET ASSIGNED AND                05720000
         STC   ACC,CESDID(ACT)          CURRENT ESDID                   05740000
         MVC   CTLOC+1(3,ACT),TADDR(SP1)    AND CURR LOC CTR            05760000
         BAL   LEV3,XREF1               REFERENCE                       05780000
         B     SETWBK                   SET WKBKT AND EXIT              05800000
 EJECT                                                                  05820000
FNDERR   BAL   SRR,LOGERR               LOG ERROR - EXTERNAL NAME       05840000
         DC    AL2(ERR05)                                               05860000
         BAL   LEV3,XREF2               CROSS REFERANCE - DUPLICATE     05880000
         MVC   NAME(8),IBL2F            BLANK OUT NAME                  05900000
CSPC     MVI   TYPE,PCCON               SET TYPE = PC                   05920000
         MVI   CTYPE(ACT),PCCON                                         05940000
         LH    SP2,CPCNO(ACT)           IS PC INITIATED                 05960000
         LTR   SP2,SP2                                                  05980000
         BNZ   FNDENT                   YES, GO TO FNDENT               06000000
         BAL   LEV2,SETESD              NO, SET ESD                     06020000
         MVC   CPCNO(2,ACT),CESDNO(ACT)  AND PCNO                       06040000
*                                                                     * 06060000
*                                                                     * 06080000
SETWBK   L     ACC,CTXABP(ACT)          GET PLACE TO PUT WORK BUCKET    06100000
         MVC   WBKTYP(1,ACC),TYPE       SET TYPE IN WKBKT               06120000
         MVC   WBKID(1,ACC),ESDID(ACT)  SET ID IN WKBKT                 06140000
         MVI   WBKSW(ACC),FILLED        SET SWITCH IN WKBKT = FILLED    06160000
         B     CTRTRN(ACT)              EXIT                            06180000
*                                                                     * 06200000
LOGERR   SR    SP1,SP1                  LOG ERROR                       06220000
LOGERP   L     SRB,CLOGER(ACT)                                          06240000
         BR    SRB                      AND QUIT                        06260000
 SPACE                                                                  06280000
*********************************************************************** 06300000
         EJECT                                                          06320000
*********************************************************************** 06340000
***                          DSECT ROUTINE                          *** 06360000
*                                                                     * 06380000
DSECT    MVI   TYPE,DSCON               SET TYPE = DS                   06400000
         MVI   CTYPE(ACT),DSCON                                         06420000
         BAL   LEV1,ESFIN               FINISH PREVIOUS SECTION IF ANY  06440000
         MVC   CTLOC(4,ACT),CTZERO(ACT) SET CURRENT LOCATION CTR = 0    06460000
 SPACE                                                                  06480000
         BAL   LEV3,GETNAME             GET NAME                        06500000
         B     DSBLNK                   NO NAME                         06520000
 SPACE                                                                  06540000
         L     SP1,CTXABP(ACT)                                          06560000
         CLI   WBKSW(SP1),FILLED         IF WORKBUCKET IS FULL          06580000
         BE    DSWBKFL                  YES, GO TO DSWBKFL              06600000
 SPACE                                                                  06620000
         BAL   LEV3,STGET               GET SYMBOL                      06640000
          LA   LEV2,SETWBK              SET ESD  AND EXIT               06660000
          BZ   SETESD                                                   06680000
 SPACE                                                                  06700000
         MVC   TEMPH(2),0(SP1)          SYMBOL WAS FOUND                06720000
         B     DSFNDT                                                   06740000
 SPACE                                                                  06760000
DSWBKFL  MVC   TEMPH(2),WBKNO(SP1)                                      06780000
DSFNDT   L     SP2,TEMPF                  FIND ADJ CODE AND             06800000
         SRA   SP2,7                    ESDNO                           06820000
         TM    ADJ,SDMSK                                                06840000
         BO    DSERR                    ERROR IF NAME TYPE              06860000
         STH   SP2,CESDNO(ACT)             SET CURR ESDNO               06880000
         BAL   LEV2,PNTESD                                              06900000
         CLI   TTYPE(SP1),DSCON                                         06920000
         BNE   DSERR                                                    06940000
 SPACE                                                                  06960000
         MVC   CTLOC+1(3,ACT),TADDR(SP1)  SET CURRENT LOCATION COUNTER  06980000
         IC    ACC,TID(SP1)                                             07000000
         STC   ACC,ESDID(ACT)           SET ASSIGNED AND                07020000
         STC   ACC,CESDID(ACT)          CURRENT ESDID                   07040000
         BAL   LEV3,XREF1               REFERENCE                       07060000
          B    SETWBK                   EXIT                            07080000
 EJECT                                                                  07100000
DSERR    BAL   SRR,LOGERR                                               07120000
         DC    AL2(ERR05)                                               07140000
         BAL   LEV3,XREF2               DUPLICATE                       07160000
         MVC   NAME(8),IBL2F                                            07180000
DSBLNK   CLI   CBDSW(ACT),0             IS BLANK DSECT SWITCH = 0       07200000
         LA    LEV2,BDTYP               YES - SET ESD AND GO TO BDTYP   07220000
         BZ    SETESD                                                   07240000
 SPACE                                                                  07260000
         LH    SP2,CBDNO(ACT)           NO                              07280000
         STH   SP2,CESDNO(ACT)          SET CURRENT ESDNO               07300000
         BAL   LEV2,PNTESD              POINT TO ESD                    07320000
         MVC   CESDID(1,ACT),TID(SP1)     SET CURRENT ESDID             07340000
         MVC   ESDID(1,ACT),TID(SP1)      SET ESDID                     07360000
         MVC   CTLOC+1(3,ACT),TADDR(SP1)  SET CURRENT LOC CTR           07380000
BDTYP    MVC   CBDNO(2,ACT),CESDNO(ACT) SET CBDNO,CBDSW                 07400000
         MVC   CBDSW(1,ACT),CESDID(ACT)                                 07420000
          B    SETWBK                   EXIT                            07440000
*                                                                     * 07460000
*********************************************************************** 07480000
         EJECT                                                          07500000
*********************************************************************** 07520000
*                                                                     * 07540000
DXD      MVI   TYPE,DXCON               SET TYPE = DX                   07560000
         BAL   LEV3,GETNAME             GET THE NAME                    07580000
         B     CTRTRN(ACT)              NO NAME, EXIT                   07600000
 SPACE                                                                  07620000
         BAL   LEV3,STGET               GET SYMBOL                      07640000
         BNZ   DXERR                    MULTIPLE DEFINITION             07660000
 SPACE                                                                  07680000
         L     TXPTR,CTXABP(ACT)        GET ALIGNMENT                   07700000
         SR    ALN,ALN                   FROM TEXT                      07720000
         IC    ALN,ALNBYTE(TXPTR)        WORKBUCKET                     07740000
         N     ALN,=F'15'               AND SET ON                      07760000
         SRL   ALN,1                                                    07780000
         STC   ALN,ALIGN                ON                              07800000
         L     LTH,CTLOC(ACT)                                           07820000
         CLC   CTLOC+1(3,ACT),TXLOC(TXPTR)   IF ZERO LENGTH             07840000
         BE    CTRTRN(ACT)              TREAT AS COMMENT                07860000
 SPACE                                                                  07880000
         SR    LTH,ALN                  COMPUTE LENGTH                  07900000
         BCTR  LTH,0                                                    07920000
         ST    LTH,ALTH-1                                               07940000
         BAL   LEV2,SETESD              SET ESD                         07960000
         B     CTRTRN(ACT)              EXIT                            07980000
 SPACE 2                                                                08000000
DXERR    BAL   LEV3,XREF2               DUPLICATE                       08020000
         BAL   SRR,LOGERR               LOG ERROR                       08040000
         DC    AL2(ERR05)                                               08060000
         B     CTRTRN(ACT)              EXIT                            08080000
 SPACE                                                                  08100000
*********************************************************************** 08120000
 EJECT                                                                  08140000
*********************************************************************** 08160000
***                      ESD WORKBUCKET ROUTINE                     *** 08180000
*                                                                     * 08200000
*    THIS IS A SUBSTITUTION ROUTINE FOR CSECT, DSECT, START. IT FILLS * 08220000
*  THE STATEMENT WORKBUCKET FOR FUTURE USE.                           * 08240000
*                                                                     * 08260000
ESWBKR   BAL   LEV3,GETNAME             GET THE NAME                    08280000
         B     CTRTRN(ACT)              NO NAME, EXIT                   08300000
 SPACE                                                                  08320000
         CLC   NAME(8),IBL2F            IS NAME BLANK                   08340000
         BZ    CTRTRN(ACT)                YES - EXIT                    08360000
 SPACE                                                                  08380000
         BAL   LEV3,STGET               GET SYMBOL                      08400000
         BZ    CTRTRN(ACT)              NOT FOUND - EXIT                08420000
 SPACE                                                                  08440000
         L     ACC,CTXABP(ACT)                                          08460000
         MVC   WBKNO(2,ACC),0(SP1)      SET WBKNO FROM ST               08480000
         MVI   WBKSW(ACC),FILLED        SET WKBKT COMPLETE              08500000
         B     CTRTRN(ACT)              EXIT                            08520000
*                                                                     * 08540000
*********************************************************************** 08560000
         EJECT                                                          08580000
*********************************************************************** 08600000
***                        ENTRY ROUTINE                            *** 08620000
*                                                                     * 08640000
ENTRY    L     WBP,CTXWBP(ACT)          GET ADDRESS OF WKBKT            08660000
         BALR  ELOOPR,0                 LOOP REGISTER                   08680000
         LH    ECT,ECTR                 COUNT DOWN TABLE                08700000
         BCT   ECT,ECTROK               REDUCE BY ONE                   08720000
 SPACE                                                                  08740000
         BAL   LEV3,ENAMGET             SET COLUMN POINTER              08760000
         BAL   SRR,ELOGER               NONE LEFT, LOG ERROR            08780000
         DC    AL2(ERR08)                                               08800000
         B     CTRTRN(ACT)              END PROCESSING STATEMENT        08820000
 SPACE                                                                  08840000
ECTROK   STH   ECT,ECTR                 STORE UDDATED COUNTER           08860000
         TM    EWBCMP(WBP),ECMPLT       IS WKBKT COMPLETE               08880000
         BO    ENTEXX                   YES, EXIT                       08900000
 SPACE                                                                  08920000
         BAL   LEV3,ENAMGET             GET NAME AND SYMBOL TABLE ITEM  08940000
         MVI   TYPE,LDCON               SET TYPE = LD                   08960000
         BC    7,ENTFND                 BRANCH IF FOUND                 08980000
 SPACE                                                                  09000000
         TM   EWBKSW(WBP),FULL          TEST WORKBUCKET SWITCH          09020000
         BO    ENTFUL                   IF ON - USE WORKBUCKET          09040000
 SPACE                                                                  09060000
         BAL   LEV3,ESCRBL               OFF - CREATE BLANK ESD ITEM    09080000
         MVC   EWBKNO(2,WBP),CNOESD(ACT) SET ESDNO IN BUCKET            09100000
         B     ENTEXX                   SEE IF MORE                     09120000
 SPACE 2                                                                09140000
ENTFUL   MVI   AID,1                    SET ID                          09160000
         MVC   ADDR,EWBKVL(WBP)         MOVE IN ADDRESS                 09180000
         MVC   ALTH+2(1),EWBKID(WBP)    AND LENGTH                      09200000
         BAL   LEV3,ESCRBL              CREATE COMPLETE ESD ITEM        09220000
         B     ENTEX                                                    09240000
 SPACE 2                                                                09260000
ENTFND   TM    STADJ(SP1),ENTCMB        IF ENTRY COMPLETE,ER-O-         09280000
         BO    ENTERR                                                   09300000
 SPACE                                                                  09320000
         BAL   LEV3,ENTESTS                                             09340000
         MVC   ADDR,SYMVAL(SP1)                                         09360000
         MVI   AID,1                                                    09380000
         MVC   ALTH+2(1),STID(SP1)                                      09400000
         OI    STADJ(SP1),ENTCMB                                        09420000
         BAL   LEV3,ESCRBL              CREATE COMPLETE ESD ITEM        09440000
         B     ENTEX                    SET WKBKT COMPLETE & SEE IF MOR 09460000
 SPACE 2                                                                09480000
ENTERR   BAL   SRR,ELOGER               LOG ERROR - ENTRY ERROR         09500000
         DC    AL2(ERR06)                                               09520000
         B     ENTEX                    AND SEE IF MORE                 09540000
 EJECT                                                                  09560000
ENTRYS   L     WBP,CTXWBP(ACT)          GET POSITION OF WKBKT           09580000
         BALR  ELOOPR,0                 LOOP REGISTER                   09600000
         TM    EWBCMP(WBP),ECMPLT       IS WKBKT COMPLETE               09620000
         BO    ENTEXX                   YES, SEE IF MORE                09640000
 SPACE                                                                  09660000
         BAL   LEV3,ENAMGET             GET NAME AND SYMBOL TABLE ITEM  09680000
         BZ    ENTEXX                   IF NOT IN TABLE, SKIP           09700000
 SPACE                                                                  09720000
         BAL   LEV3,ENTESTS                                             09740000
         MVC   EWBKVL(3,WBP),SYMVAL(SP1)  SET VALUE AND ID FROM         09760000
         MVC   EWBKID(1,WBP),STID(SP1)      SYMBOL TABLE TO WKBKT       09780000
         B     EFULL                    SET WKBKT FULL AND SEE IF MORE  09792021
*                                                                A45780 09802021
 SPACE                                                                  09820000
ENTESTS  CLI   STID(SP1),0              IS SYMBOL ABSOLUTE              09840000
         BE    ENTABS                   YES, LOG ERROR                  09860000
         TM    STADJ(SP1),DSOCM           NO - WAS IT DEFINED IN DS,CM  09880000
         BO    ENTERR                       YES - ERROR                 09900000
         TM    STADJ(SP1),SDBIT               NO - IS IT SECTION DEF    09920000
         BZ    ENTEX                    YES, ENTER WKBKT AND SEE IF MOR 09940000
         BM    ENTERR                   EXTRN OR DSECT, LOG ERROR       09960000
 SPACE                                                                  09980000
         MVC   TEMPH,EWBKNO(WBP)        GET ESDNO                       10000000
         LH    SP2,TEMPH                                                10020000
         LTR   SP2,SP2                                                  10040000
         BCR   8,LEV3                   RETURN IF ESDNO NOT SET         10060000
 SPACE                                                                  10080000
         LR    GRA,SP1                  FETCH INCOMPLETE ESD ITEM       10100000
         BAL   LEV2,PNTESD              POINT TO ESD                    10120000
         MVC   TADDR(3,SP1),SYMVAL(GRA) COMPLETE IT                     10140000
         MVC   TLTH+2(1,SP1),STID(GRA)                                  10160000
         MVI   TID(SP1),1                                               10180000
         CLI   0(SP2),1                 IS IT IN CORE                   10200000
         BE    ENTEX                    YES, DONT READ IN               10220000
         L     SP1,CESIOB(ACT)          NO, READ IN ESD                 10240000
         BAL   LEV1,WRESD               REPLACE SEGMENT ON FILE         10260000
ENTEX    L     WBP,CTXWBP(ACT)                                          10280000
         OI    EWBCMP(WBP),ECMPLT       SET WORKBUCKET COMPLETE         10300000
EFULL    OI    EWBKSW(WBP),FULL         SET WORKBUCKET SWITCH           10320000
ENTEXX   TM   EWBKSW(WBP),LASTOP                                        10340000
         BO    CTRTRN(ACT)              EXIT IF LAST OPERAND            10360000
 SPACE                                                                  10380000
         LA    WBP,WBKLEN(WBP)          POINT TO NEXT WORKBUCKET        10400000
         ST    WBP,CTXWBP(ACT)                                          10420000
         BR    ELOOPR                   AND LOOP FOR NEXT OPERAND       10440000
 SPACE                                                                  10460000
ENTABS   BAL   SRR,ELOGER               LOG ERROR - RELOCATION          10480000
         DC    AL2(ERR13)                                               10500000
         B     ENTEX                    AND SEE IF MORE                 10520000
*                                                                     * 10540000
*********************************************************************** 10560000
         EJECT                                                          10580000
*********************************************************************** 10600000
***                       EXTRN/WXTRN ROUTINE                      I004 10620020
*                                                                     * 10640000
WXTRN    EQU   *                                                   I004 10650020
EXTRN    L     WBP,CTXWBP(ACT)          SET WORBUCKET POINTER           10660000
         BALR  ELOOPR,0                 LOOP REGISTER                   10680000
         TM    CTSYMF(ACT),X'01'        IS SYMBOL TABLE FULL            10700000
         BO    EXABX                    YES, ABNORMAL EXIT              10720000
 SPACE                                                                  10740000
         MVI   TYPE,ERCON               SET TYPE = ER                   10760000
         TM    CTSWXT(ACT),SETWX        EXTRN OR WXTRN?            I004 10764020
         BZ    EXTRN2                   SKIP IF EXTRN              I004 10768020
         MVI   TYPE,WXCONA              SET TYPE = WX              I004 10772020
EXTRN2   TM    EWBKSW(WBP),FULL         IS WORK BUCKET FULL        I004 10776020
         BO    EFULL                    YES, GO SEE IF MORE             10800000
 SPACE                                                                  10820000
         BAL   LEV3,ENAMGET             GET NAME AND SYMBOL TABLE ITEM  10840000
         BC    7,EXERR                   ERROR IF IN SYBBOL TABLE       10860000
 SPACE                                                                  10880000
         OI    VMATCH,X'F0'                                             10900000
         BAL   LEV2,SCHESD              WAS ESD ITEM FOUND              10920000
         LA    LEV2,EFULL                IF NOT FOUND,                  10940000
         BNZ   SETESD                    GO TO SETESD AND EXEX          10960000
 SPACE                                                                  10980000
EXFND    CLI   TTYPE(BEGIN),VCCON       IS IT A V-TYPE                  11000000
         BNE   EXERR                    NO, LOG ERROR                   11020000
 SPACE                                                                  11040000
         MVI   TTYPE(BEGIN),ERCON       SET TYPE = ER              I004 11050020
         TM    CTSWXT(ACT),SETWX        EXTRN OR WXTRN ?           I004 11060020
         BZ    EXTRN3                   SKIP IF EXTRN              I004 11070020
         MVI   TTYPE(BEGIN),WXCONA      SET TYPE = WX              I004 11080020
EXTRN3   MVC   ESDID(1,ACT),TID(BEGIN)                             I004 11090020
         MVI   ADJCOD(ACT),1                                            11100000
         CLI   RDSW,0                   IS IT IN CORE                   11120000
         BE    EXINC                    YES, DONT READ IN               11140000
 SPACE                                                                  11160000
         L     SP1,CESIOB(ACT)          NO, READ IN ESD                 11180000
         SH    SP2,=H'4'                                                11200000
         BAL   LEV1,WRESD               UPDATED SEGMENT TO FILE         11220000
EXINC    LA    SP1,NAME                                                 11240000
         SR    SP2,SP2                                                  11260000
         L     SRB,STPUT(ACT)           PUT IN NAME IN SYMBOL TABLE     11280000
         BALR  SRR,SRB                                                  11300000
         NOP   0                        IGNORE IF FOUND                 11320000
EXEX     B     EFULL                    GO SEE IF MORE                  11340000
 SPACE                                                                  11360000
EXERR    BAL   SRR,ELOGER               LOG ERROR - EXTERNAL NAME       11380000
         DC    AL2(ERR05)                                               11400000
         B     EXEX                     AND SEE IF MORE                 11420000
 SPACE 2                                                                11440000
EXABX  L     ACC,CTSAVE+12(ACT)         ABNORMAL EXIT                   11460000
         LA    ACC,4(ACC)                                               11480000
         ST    ACC,CTSAVE+12(ACT)                                       11500000
         B     CTRTRN(ACT)              EXIT                            11520000
 EJECT                                                                  11540000
***                       EXTRN/WXTRN SUBSTITUTION ROUTINE         I004 11560020
*                                                                     * 11580000
WXTRNS   EQU   *                                                   I004 11590020
EXTRNS   L     WBP,CTXWBP(ACT)          SET WORBUCKET POINTER           11600000
         BALR  ELOOPR,0                 LOOP REGISTER                   11620000
         TM    EWBKSW(WBP),FULL         IS WKBKT FULL                   11640000
         BO    EFULL                    YES, GO SEE IF MORE             11660000
 SPACE                                                                  11680000
         BAL   LEV3,ENAMGET             GET NAME AND SYMBOL TABLE ITEM  11700000
         BZ    ENTEXX                   FOUND, GO SEE IF MORE           11720000
 SPACE                                                                  11740000
         BAL   SRR,ELOGER               NOT FOUND, LOG ERROR - EXTERNAL 11760000
         DC    AL2(ERR05)                                               11780000
         B     EFULL                    AND SEE IF MORE                 11800000
*                                                                     * 11820000
*********************************************************************** 11840000
 SPACE                                                                  11860000
*********************************************************************** 11880000
*                                       LEVEL 3 - FIND IN SYMBOL TABLE* 11900000
ENAMGET  SR    SP1,SP1                                                  11920000
         LR    SP2,SP1                  CLEAR PARAMETER REGISTERS       11940000
         IC    SP1,TXSPTR(WBP)                                          11960000
         A     SP1,CTXOFP(ACT)                                          11980000
         LA    SP1,1(SP1)               POINTER TO NEXT OPERAND         12000000
         IC    SP2,TXSBLN(WBP)                                          12020000
         N     SP2,=F'15'               NAME LENGTH                     12040000
         MVC   NAME,IBL2F               BLANK NAME                      12060000
         LR    ACC,SP2                                                  12080000
         BCTR  ACC,0                    MACHINE CODE LENGTH             12100000
         EX    ACC,MVNMEV               MOVE IN NAME                    12120000
         ST    SP1,ERRPTR               LOCATION FOR ERROR POINTER      12140000
         L     SRB,CSTGET(ACT)          LOAD BASE                       12160000
         BALR  SRR,SRB                  SYMBOL TABLE GET                12180000
         LTR   SP1,SP1                  SET CONDITION CODE ON RESULT    12200000
         BR    LEV3                     RETURN                          12220000
 SPACE                                                                  12240000
ELOGER   L     SP1,ERRPTR               CALL LOG ERROR                  12260000
         L     SRB,CLOGER(ACT)                                          12280000
         BR    SRB                      EXIT                            12300000
*                                                                     * 12320000
*********************************************************************** 12340000
         EJECT                                                          12360000
*********************************************************************** 12380000
***                           ORG ROUTINE                           *** 12400000
*                                                                     * 12420000
ORG      LH    SP2,CESDNO(ACT)                                          12440000
         BAL   LEV2,PNTESD              POINT ESD                       12460000
         ST    SP1,SVSP1                SAVE ESD ITEM POINTER    A45759 12470000
         CLC   CTLOC+1(3,ACT),TLTH(SP1) IS LOC CTR GTR TLTH             12480000
         BC    NOTHI,ORGEE              NO, GO AROUND                   12500000
 SPACE                                                                  12520000
         MVC   TLTH(3,SP1),CTLOC+1(ACT)   YES - SET TLTH = LOC CTR      12540000
         CLI   0(SP2),1                 IS ESD IN CORE                  12560000
         BE    ORGEE                    YES, DONT BRING IT IN           12580000
 SPACE                                                                  12600000
         L     SP1,CESIOB(ACT)          NO, READ IN ESD                 12620000
         BAL   LEV1,WRESD                                               12640000
 SPACE                                                                  12660000
ORGEE    BAL   LEV3,ISOPF               IS THERE AN OPERAND FIELD       12680000
         BZ    ORGNOP                   NO, SET LOC CTN = TLTH          12700000
 SPACE                                                                  12720000
         OI    CTPDSI(ACT),PDSI         OPERAND MUST BE PREVIOUSLY DEF  12740000
         L     SP1,CTXOFP(ACT)                                          12760000
         LA    SP1,1(SP1)                 YES                           12780000
         L     SRB,CEEVAL(ACT)             EVALUATE OPERAND             12800000
         BALR  SRR,SRB                  WHAT TYPE EXPRESSION            12820000
         BC    4,ORGID                  SIMPLE RELOCATABLE              12840000
         BC    10,ORGERR                COMPLEX OR ABSOLUTE - LOG ERROR 12860000
         L     ACC,CTEXTP(ACT)          EVALUATION IMPOSSIBLE           12880000
         NI    TXTO(ACC),X'3F'          LOG ERROR                       12900000
         B     CTRTRN(ACT)              AND EXIT                        12920000
 SPACE                                                                  12940000
ORGID    CLC   PARID(1,SP2),CESDID(ACT) CHECK CONTROL SECTION           12960000
         BNE   ORGERR                   NOT THE SAME, ERROR             12980000
 SPACE                                                                  13000000
         CLI   0(SP1),IBLANK            IS THERE ONLY ONE OPERAND       13020000
         BE    ORGLOC                   YES, CONTINUE                   13040000
 SPACE                                                                  13060000
         BAL   SRR,LOGERP               NO, LOG ERROR                   13080000
         DC    AL2(ERR02)               ONLY ONE OPERAND ALLOWED        13100000
         B     CTRTRN(ACT)              EXIT                            13120000
 SPACE 2                                                                13140000
ORGLOC   MVC   CTLOC+1(3,ACT),1(SP2)   SET LOCATION COUNTER             13160000
         B     CTRTRN(ACT)                   CTR TO VALUE AND EXIT      13180000
 SPACE 2                                                                13200000
ORGNOP   L     SP1,SVSP1               RESTORE ESD ITEM POINTER  A45759 13220000
         MVC   CTLOC+1(3,ACT),TLTH(SP1) SET LOC CTR = TLTH       A45759 13230000
         B     CTRTRN(ACT)                AND EXIT                      13240000
 SPACE 2                                                                13260000
ORGERR   BAL   SRR,LOGERR               LOG ERROR - INVALID ORIGIN      13280000
         DC    AL2(ERR10)                                               13300000
         B     CTRTRN(ACT)              AND EXIT                        13320000
*                                                                     * 13340000
*********************************************************************** 13360000
         EJECT                                                          13380000
*********************************************************************** 13400000
***                          QUIT ROUTINE                           *** 13420000
*                                                                     * 13440000
QUIT     BAL   LEV1,ESFIN               FINISH PREVIOUS SECTION IF ANY  13460000
         TM    CNOESD+1(ACT),X'0F'      ARE WE BETWEEN BLOCKS           13480000
         BZ    QFUDGE                   YES, ADJUST                     13500000
 SPACE                                                                  13520000
QUR      L     SP2,CTESRB(ACT)                                          13540000
         CLI   0(SP2),2                 ARE SEGMENTS (BLOCKS) ON TAPE   13560000
         BC    7,CTRTRN(ACT)            NO, EXIT                        13580000
 SPACE                                                                  13600000
QLOOP    LA    SP2,4(SP2)               GO TO NEXT SEGMENT              13620000
         CL    SP2,CTESRP(ACT)          IF AFTER LAST SEGMENT ,         13640000
         BH    CTRTRN(ACT)                EXIT                          13660000
 SPACE                                                                  13680000
         CLI   0(SP2),2                 IF ON TAPE,                     13700000
         BE    QLOOP                      LOOP                          13720000
 SPACE                                                                  13740000
         L     SP1,0(SP2)                                               13760000
         LA    SP1,0(SP1)               WRITE                           13780000
         BAL   LEV1,WRESD                                               13800000
         B     QLOOP                    LOOP                            13820000
 SPACE 2                                                                13840000
QFUDGE   L     ACC,CTESRP(ACT)          ADJUST FOR THE FACT             13860000
         MVI   0(ACC),0                 THAT WE ARE BETWEEN             13880000
         SH    ACC,=H'4'                BLOCK                           13900000
         ST    ACC,CTESRP(ACT)          AND CONTINUE                    13920000
         B     QUR                                                      13940000
*                                                                     * 13960000
*********************************************************************** 13980000
         EJECT                                                          14000000
*********************************************************************** 14020000
*        CALLED BY DC EVAL    0(SRR) IS FLAG  1=Q-TYPE, 0=V-TYPE        14040000
*                             2(SRR) IS RETURN ADDRESS                  14060000
*                                                                       14080000
VCON     STM   SRR,SP1,VSAVE            SAVE LINK AND OPERAND POINTER   14100000
         L     WBP,CTXWBP(ACT)          POINT TO WORKBUCKET             14120000
         MVI   ESDID(ACT),0             ZERO ID                         14140000
         MVI   TYPE,VCCON               SET TYPE = VC                   14160000
         MVC   NAME(8),IBL2F            BLANK NAME                      14180000
         EX    SP2,MVNMEV               GET NAME FROM TEXT              14200000
         TM    CTMODE(ACT),X'60'        IF IN SUBSTITUTION MODE,        14220000
         BNZ   2(SRR)                      RETURN                       14240000
 SPACE                                                                  14260000
         TM    0(SRR),1                 IS IT A Q OR V-TYPE             14280000
         BO    QCON                     Q-TYPE                          14300000
 SPACE 2                                                                14320000
         TM    CTDORCI(ACT),BIT3        IS IN DSECT OR COM              14340000
         BO    VSHSET                   YES, EXIT                       14360000
         TM    VSAVE,CCHIGH             IS IN DS OR DXD OPERAND         14380000
         BO    VSHSET                   YES, EXIT                       14400000
 SPACE                                                                  14420000
         NI    VMATCH,X'0F'                                             14440000
         NI    DRTFIX,X'0F'             SET VCON RETURN                 14460000
         BAL   LEV2,SCHESD              FIND ESD                        14480000
         LA    LEV2,VCONDRT             SET ESD RETURN                  14500000
         BC    7,SETESD                 IF NOT FOUND, BUILD ESD         14520000
 SPACE                                                                  14540000
         MVC   ESDID(1,ACT),TID(BEGIN)   ELSE COPY EXISTING ID          14560000
VCONDRT  OI    DRTFIX,X'F0'             UPSET VCON RETURN               14580000
VSHSET   MVC   TXSLEN(5,WBP),CTZERO(ACT)                                14600000
         MVC   TXSESD(1,WBP),ESDID(ACT)                                 14620000
         NI    0(WBP),LASTWB+SDMSK      SET WORKBUCKET                  14640000
         OI    0(WBP),FILLED                                            14660000
         L     SRR,VSAVE                RESTORE                         14680000
         B     2(SRR)                   RETURN                          14700000
 EJECT                                                                  14720000
QCON     BAL   LEV3,XREF1               REFERENCE                       14740000
         TM    TXSUBS(WBP),X'10'        IS PREVIOUSLY DEFINED           14760000
         BZ    QCERRA                   NO, LOG ERROR                   14780000
 SPACE                                                                  14800000
         TM    TXSTPC(WBP),DSBITS       IS A DSECT OR DXD               14820000
         BZ    QCERRB              NOT DNO, LOG ERROR                   14840000
         TM    TXSTPC(WBP),SDMSK        IS A CSECT                      14860000
         BO    QCERRB              NAME YES, LOG ERROR                  14880000
 SPACE                                                                  14900000
         TM    CTDORCI(ACT),BIT3        IS CONSTANT DEFINED IN DSECT    14920000
         BO    VSHSET                   YES                             14940000
         TM    VSAVE,CCHIGH             IS IN DS OR DXD OPERAND         14960000
         BO    VSHSET                   YES, EXIT                       14980000
 SPACE                                                                  15000000
         MVC   ESDID(1,ACT),TXSESD(WBP) SET ESDID                       15020000
         CLC   CTNDID+1(1,ACT),TXSESD(WBP)    COMPARE WITH NEXT DSECT   15040000
         BH    VSHSET              DEF AS DXD                           15060000
 SPACE                                                                  15080000
         OI    VMATCH,X'F0'                                             15100000
         BAL   LEV2,SCHESD              SEARCH ESD FOR ITEM             15120000
         CLI   TTYPE(BEGIN),VCCON       IS IT A V-CON                   15140000
         BE    SESLP                    YES, CONTINUE SEARCH            15160000
         CLI   TTYPE(BEGIN),DSCON       IS IT A DSECT                   15180000
         BE    DXSET                    YES, UP-DATE DSECT              15200000
 SPACE                                                                  15220000
         MVC   ESDID(1,ACT),TID(BEGIN)  USE ID IF XD                    15240000
         B     VSHSET                   EXIT                            15260000
 SPACE 2                                                                15280000
DXSET    MVC   TNAME(8,BEGIN),IBL2F     OBLITERATE DSECT NAME           15300000
         STH   SP1,TEMPH                SAVE ESDNO OF DSECT             15320000
         BAL   LEV2,SETESD              CREATE ESD ITEM                 15340000
         MVC   TADDR(2,SP1),TEMPH       INSERT ESDNO OF DSECT           15360000
         MVI   TTYPE(SP1),DXCON         SET NEW TYPE FLAG IN ESD        15380000
         MVI   TALIGN(SP1),7            SET ALIGNMENT - DOUBLE WORD     15400000
         CLI   RDSW,0                   IF IN MAIN STORAGE,             15420000
         BE    VSHSET                    EXIT                           15440000
         L     SP1,CESIOB(ACT)           ELSE RESTORE UPDATED DSECT     15460000
         L     SP2,PNTSVE+4                                             15480000
         BAL   LEV1,WRESD               WRITE OUT ESD                   15500000
         L     WBP,CTXWBP(ACT)                                          15520000
         B     VSHSET                   EXIT                            15540000
 SPACE 2                                                                15560000
QCERRA   MVI   QERR,ERR11               LOG ERROR - SYMBOL NOT PREVIOUS 15580000
         B     QLGER                    DEFINED                         15600000
QCERRB   MVI   QERR,ERR12               LOG ERROR - NOT DXD OR DSECT    15620000
QLGER    BAL   SRR,ELOGER                                               15640000
         DC    AL1(0)                   CALL LOG ERROR                  15660000
QERR     DC    X'0'                                                     15680000
         B      VSHSET                  EXIT                            15700000
*********************************************************************** 15720000
 EJECT                                                                  15740000
*              THERE ARE THREE LEVELS OF INTERNAL SUBROUTINES.        * 15760000
 SPACE 2                                                                15780000
*                    LEVEL 1                                          * 15800000
 SPACE                                                                  15820000
*   ESFIN   -  UPDATES THE LOCATION COUNTER IN THE PREVIOUS CONTROL   * 15840000
*              SECTION.                                               * 15860000
 SPACE                                                                  15880000
*   WRESD   -  INTERFACES WITH TXTIO WRITE ESD ROUTINE.               * 15900000
  SPACE 2                                                               15920000
*                    LEVEL 2                                          * 15940000
 SPACE                                                                  15960000
*   SETESD  -  ASSIGNS AN ESD ID TO ITEM,AND PUTS SYMBOL TABLE ENTRY. * 15980000
 SPACE                                                                  16000000
*   SCHESD  -  SEARCHES ESD FOR ITEM WITH GIVEN NAME,AND FINDS ESDNO. * 16020000
 SPACE                                                                  16040000
*   PNTESD  -  OBTAINS ESD ITEM WITH GIVEN ESDNO.                     * 16060000
 SPACE   2                                                              16080000
*                    LEVEL 3                                          * 16100000
 SPACE                                                                  16120000
*   RDESD   -  INTERFACES WITH TXTIO READ ESD ROUTINE.                * 16140000
 SPACE                                                                  16160000
*   FSTNR   -  SETS ESDNO AND ADJECTIVE CODE OF FIRST SD OR PC TYPE   * 16180000
*              CONTROL SECTION IN CONTROL TABLE.USED FOR END LITERALS.* 16200000
 SPACE                                                                  16220000
*   STGET   -  INTERFACES WITH SYMBOL TABLE GET ROUTINE.              * 16240000
 SPACE                                                                  16260000
*   GETNAME -  GETS NAME FROM TEXT RECORD.                            * 16280000
 SPACE                                                                  16300000
*   ISOPF   -  SETS CONDITION CODE TO INDICATE PRESENCE OF OPERAND.   * 16320000
 SPACE                                                                  16340000
*   XREF1,2 -  MAKES REFERENCE OR DUPLICATE TYPE CROSS-REFERENCE.     * 16360000
 SPACE                                                                  16380000
*   ESCRBL  -  CREATES ESD ITEM.                                      * 16400000
    EJECT                                                               16420000
*              LEVEL 1 ROUTINES                                         16440000
*        THESE CALL LEVEL 2 ROUTINES AND MODIFY LEV2,LEV3, ETC.         16460000
*        RETURN REGISTER IS LEV1                                        16480000
 SPACE                                                                  16500000
*********************************************************************** 16520000
***                      ESD FINISH ROUTINE                         *** 16540000
 SPACE                                                                  16560000
ESFIN    CLI   CESDID(ACT),0            DOES CURRENT ESDID = 0          16580000
         BCR   8,LEV1                   YES, RETURN NONE TO FINISH      16600000
 SPACE                                                                  16620000
         LH    SP2,CESDNO(ACT)          NO -FINISH ESD FOR PREV SECTION 16640000
         BAL   LEV2,PNTESD              POINT TO THE LAST ESD ITEM      16660000
         MVC   TADDR(3,SP1),CTLOC+1(ACT)  SET TADDR = CURRENT LOC CTR   16680000
         CLC   CTLOC+1(3,ACT),TLTH(SP1)   IS CURR LOC CTR GTR TLTH      16700000
         BNH   TLTHR                    NO, DONT SET TLTH               16720000
 SPACE                                                                  16740000
TLTHS    MVC   TLTH(3,SP1),CTLOC+1(ACT) SET TLTH = CURR LOC CTR AND     16760000
TLTHR    CLI   0(SP2),1                 NO - IS SEG IN CORE             16780000
         BCR   8,LEV1                   YES,EXIT                        16800000
 SPACE                                                                  16820000
         L     SP1,CESIOB(ACT)             NO - POINT (WRITE)         * 16840000
*****                                   ******************************* 16860000
*                            WRITE ESD ROUTINE                        * 16880000
WRESD    SH    SP1,=H'259'                                              16900000
         MVC   TEMPH(1),0(SP1)          SAVE FIRST BYTE OF ESD   A27016 16906019
         LR    TEMPR,SP1                SEGMENT                  A27016 16912019
         MVI   0(SP1),ESIOID            ESD INDICATOR                   16920000
         ST    SP2,SAVESP               SAVE SP2                        16940000
         L     SRB,CTXTIO(ACT)          SET UP I/O BASE                 16960000
         BAL   SRR,CWRESD(SRB)          CALL ESD WRITE                  16980000
         MVC   0(1,TEMPR),TEMPH         RETRIEVE ORIG. INFO.     A27016 16990019
         L     SP2,SAVESP               RESTORE SP2                     17000000
         ST    SP1,0(SP2)               SEGMENT RESIDENCE TABLE ENTRY   17020000
         MVI   0(SP2),2                 ON FILE FLAG                    17040000
         BR    LEV1                     EXIT                            17060000
*                                                                     * 17080000
*********************************************************************** 17100000
 EJECT                                                                  17120000
*              LEVEL 2 ROUTINES                                         17140000
*        THESE CALL LEVEL 3 ROUTINES AND THEREFORE MODIFY LEV3          17160000
*        RETURN REGISTER IS LEV2                                        17180000
*********************************************************************** 17200000
         SPACE 3                                                        17220000
*   SETESD-  ASSIGN ESD IDENTIFICATION                                * 17240000
*FUNCTION-                                                            * 17260000
*   SETS ESD-ID TO EITHER-                                            * 17280000
*        NUMBER OF NEXT ESD, OR                                       * 17300000
*        NUMBER OF NEXT DSECT                                         * 17320000
*   UPDATES COUNT OF ESD'S OR DSECT'S, AS REQUIRED                    * 17340000
*   PUTS SYMBOL TABLE ENTRY, IF REQUIRED                              * 17360000
*                                                                     * 17380000
*INPUT-                                                               * 17400000
*   CLASID(ACT) CONTAINS ID NUMBER OF LAST ESD                        * 17420000
*   CTNDID(ACT) CONTAINS ID NUMBER OF NEXT DSECT                      * 17440000
*OUTPUT-                                                              * 17460000
*   CLASID(ACT) OR CTNDID(ACT) IS UPDATED                             * 17480000
*   ESDID(ACT) CONTAINS CURRENT ESD-ID                                * 17500000
*   ADJCOD(ACT) CONTAINS ADJECTIVE CODE FOR CORRESPONDING SYMBOL TABLE* 17520000
*    ENTRY                                                            * 17540000
*EXTERNAL ROUTINES-                                                   * 17560000
*   STPUTR (IN IEUF7I) IS USED TO PUT ENTRY TO SYMBOL TABLE           * 17580000
*EXITS-                                                               * 17600000
*   NORMAL-    BR   LEV2                                              * 17620000
*   ERROR-                                                            * 17640000
*        EXIT FROM F7E,                                               * 17660000
*        OR RETURN TO VCONDRT (IN VCON SUBROUTINE) IF CALLED FROM VCON* 17680000
*NOTE-  VCON SUBROUTINE ALTERS ERROR RETURN                           * 17700000
*   DISCOVERS AND LOGS 'ESD TABLE OVERFLOW' ERROR IF ESD'S+DSECT'S=   * 17720000
*    MORE THAN 255                                                    * 17740000
         SPACE 2                                                        17760000
SETESD   LH    ACC,CLASID(ACT)          GET LAST ID                     17780000
         CH    ACC,CTNDID(ACT)          IS THIS = NEXT DSECT ID         17800000
         BE    STESDE                   YES, ERROR                      17820000
         SPACE                                                          17840000
         CLI   TYPE,DSCON               IS IT A DSECT                   17860000
         BE    STADJD                   YES, PUT IN                     17880000
 SPACE                                                                  17900000
         LA    ACC,1(ACC)                                               17920000
         STH   ACC,CLASID(ACT)          LAST ID = LAST ID +1            17940000
         STC   ACC,ESDID(ACT)           SET ID(ASSIGNED) = LAST ID      17960000
 SPACE                                                                  17980000
         CLI   TYPE,VCCON               IS IT A V-TYPE                  18000000
         BE    ESIDX                    YES, PROCESS                    18020000
         CLI   TYPE,ERCON               IS IT EXTERNAL                  18040000
         BE    STADJX                   YES, PROCESS                    18060000
         CLI   TYPE,WXCONA              IS IT WEAK EXTERNAL        I004 18066020
         BE    STADJX                   YES, PROCESS               I004 18072020
         CLI   TYPE,DXCON               IS IT DUMMY EXTERNAL            18080000
         BE    STADJDX                  YES, PROCESS                    18100000
 SPACE                                                                  18120000
         STC   ACC,CESDID(ACT)          SET ESD-ID OF CURRENT CONTROL   18140000
STADJSD  MVI   ADJCOD(ACT),SDBITS       IS CSECT, SET SD                18160000
         B     ESIDX                    CONTINUE                        18180000
STADJX   MVI   ADJCOD(ACT),ERBITS       SET  EXTERNAL                   18200000
         B     ESIDX                    CONTINUE                        18220000
STADJDX  MVI   ADJCOD(ACT),DSBITS+DXDFLAG+DSOCM                         18240000
         B     ESIDX                    SET FOR DUMMY EXTERNAL          18260000
 SPACE 2                                                                18280000
STADJD   MVI   ADJCOD(ACT),DSBITS+DSOCM                                 18300000
DSCTID   LH    ACC,CTNDID(ACT)          SET ID(ASSIGNED) = NEXT DSECT   18320000
         STC   ACC,ESDID(ACT)             ID                            18340000
         STC   ACC,CESDID(ACT)          SET ESD-ID OF CURRENT CONTROL   18360000
         BCTR  ACC,0                      SECTION = NEXT DSECT ID       18380000
         STH   ACC,CTNDID(ACT)          NEXT DSECT ID = NEXT DSECT ID-1 18400000
         SPACE 5                                                        18420000
*                  BUILD THE ESD ITEM FORMAT                            18440000
ESIDX    MVC   AID,ESDID(ACT)           GET ID                          18460000
         MVC   SVSDNO,CESDNO(ACT)       SAVE CURRENT ESDNO              18480000
         BAL   LEV3,ESCRBL              BUILD ESD                       18500000
         CLC   NAME(8),IBL2F            IF NAME IS NOT BLANK, PUT       18520000
         BCR   8,LEV2                   BLANK, RETURN                   18540000
 SPACE                                                                  18560000
         LA    SP1,NAME                 NONE BLANK, SO PUT              18580000
         SR    SP2,SP2                  SYMBOL IN SYMBOL TABLE          18600000
         L     SRB,STPUT(ACT)           SYMBOL TABLE PUT                18620000
         BALR  SRR,SRB                                                  18640000
         NOP   0                                                        18660000
         CLI   TYPE,ERCON                                               18680000
         BE    RESDNO                   IF TYPE = DX OR ER              18700000
         CLI   TYPE,WXCONA              OR                         I004 18706020
         BE    RESDNO                   WEAK EXTERNAL              I004 18712020
         CLI   TYPE,DXCON               DONT RETURN YET                 18720000
         BCR   7,LEV2                   OTHER WISE RETURN               18740000
RESDNO   MVC   CESDNO(2,ACT),SVSDNO     RESTORE CURRENT ESDNO           18760000
         BR    LEV2                     NOW RETURN                      18780000
 SPACE 2                                                                18800000
STESDE   BAL   SRR,LOGERR                                               18820000
         DC    AL2(ERR14)               'ESD TABLE OVERFLOW'            18840000
DRTFIX   EQU   *+1                 ** BYTE IS ALTERED BY VCON **        18860000
         B     CTRTRN(ACT)              EXIT FROM THE FUNCTIONAL RTN.   18880000
         B     VCONDRT                  VCON RETURN                     18900000
SVSDNO   DC    H'0'                                                     18920000
*                                                                     * 18940000
*********************************************************************** 18960000
         EJECT                                                          18980000
*********************************************************************** 19000000
 SPACE                                                                  19020000
SCHESD   L     BEGIN,CTESDB(ACT)        SEARCH ESD ROUTINE              19040000
         MVI   RDSW,0                   ZERO READ SWITCH                19060000
         LA    ITEMCT,17                ITEMS PER BLOCK                 19080000
         L     END,CTESDP(ACT)           SET SEGAD AT BEGINNING OF ESRT 19100000
         L     SEGAD,CTESRB(ACT)         SET BEGIN AND END FOR IN CORE  19120000
         SR    SP1,SP1             ESDNO=0                              19140000
 SPACE                                                                  19160000
SESLP    CLR   BEGIN,END                   SEARCH                       19180000
         BE    SES1                     IF BEGIN = ESD, READ IN ESD     19200000
         BCT   ITEMCT,SES2              REDUCE NO. IN BLOCK BY ONE      19220000
         SPACE                                                          19240000
         SH    BEGIN,=H'4'                                              19260000
         LA    ITEMCT,17                SET UP FOR NEXT BLOCK           19280000
         B     SESLP                    AND CONTINUE                    19300000
 SPACE 2                                                                19320000
SES2     SH    BEGIN,=H'16'             SET TO NEXT ESD                 19340000
         LA    SP1,1(SP1)          ESDNO=ESDNO+1                        19360000
         CLC   NAME(8),TNAME(BEGIN)     SEE IF SAME NAME                19380000
         BC    7,SESLP                    NO - LOOP                     19400000
 SPACE                                                                  19420000
VMATCH   EQU   *+1                                                      19440000
         BR    LEV2                     YES, EXIT                       19460000
 SPACE 2                                                                19480000
SESTST   CLI   TTYPE(BEGIN),VCCON       IS TYPE = VCON                  19500000
         BCR   8,LEV2                   YES, RETURN                     19520000
         CLI   TTYPE(BEGIN),ERCON       IS TYPE = ER                    19540000
         BCR   8,LEV2                   YES, RETURN                     19560000
         CLI   TTYPE(BEGIN),WXCONA      IS TYPE = WX               I004 19566020
         BCR   8,LEV2                   YES, RETURN                I004 19572020
         B     SESLP                    KEEP SEARCHING                  19580000
 SPACE 2                                                                19600000
SES1     CLI   0(SEGAD),1               DOES THIS BLOCK EXIST           19620000
         BNH   SESX                     NO, COULD NOT FIND              19640000
 SPACE                                                                  19660000
         BAL   LEV3,RDESD               READ IN NEXT ESD BLOCK          19680000
         L     BEGIN,CESIOB(ACT)        SET BEGIN AND END FOR           19700000
         LR    END,BEGIN                  LOOP                          19720000
         SH    END,=H'256'                                              19740000
         LA    SEGAD,4(SEGAD)           SET SEGAD                       19760000
         MVI   RDSW,1                   SET READ SWITCH                 19780000
         LA    ITEMCT,17                RESET ITEMS PER BLOCK           19800000
         B     SESLP                    CONTINUE LOOP                   19820000
 SPACE 2                                                                19840000
SESX     LTR   ACT,ACT                  SET CC = 2 FOR NOT FOUND        19860000
         BR    LEV2                     AND EXIT                        19880000
 SPACE                                                                  19900000
*********************************************************************** 19920000
         EJECT                                                          19940000
*********************************************************************** 19960000
***                    POINT ESD ROUTINE                            *** 19980000
*    THIS ROUTINE POINTS AT THE ESD ITEM WHOSE NUMBER IS IN SP2,      * 20000000
*  WHETHER THIS ITEM IS IN CORE OR NOT.                               * 20020000
*                                                                     * 20040000
PNTESD   LA    SP1,15                   MASK                            20060000
         NR    SP1,SP2                  FIND OUT WHICH BLOCK            20080000
         SR    SP2,SP1                  ESD NO. IS IN                   20100000
         SRL   SP2,2                                                    20120000
         A     SP2,CTESRB(ACT)            SR TABLE ITEM                 20140000
         LTR   SP1,SP1                  IS IT IN FIRST BLOCK            20160000
         BNZ   PNTR                     YES                             20180000
 SPACE                                                                  20200000
PNTFUD   SH    SP2,=H'4'                ADJUST FOR RECORD               20220000
         LA    SP1,16                   AND TYPE                        20240000
 SPACE                                                                  20260000
PNTR     CLI   0(SP2),1                 IS THIS ESD IN CORE             20280000
         BC    7,PNT1                   NO, READ IT IN                  20300000
 SPACE                                                                  20320000
         SLL   SP1,4                       SET SP1 TO POINT AT ESD ITEM 20340000
         MVC   TEMPZF+1(3),1(SP2)            GET SEG ADDRESS FROM SRT   20360000
         LCR   SP1,SP1                                                  20380000
         A     SP1,TEMPZF                                               20400000
         BR    LEV2                     EXIT                            20420000
 SPACE 2                                                                20440000
PNT1     BAL   LEV3,RDESD               READ IN ESD                     20460000
         SLL   SP1,4                    SET SP1 TO POINT AT             20480000
         LCR   SP1,SP1                  ESD ITEM                        20500000
         A     SP1,CESIOB(ACT)                                          20520000
         BR    LEV2                     EXIT                            20540000
*                                                                     * 20560000
*********************************************************************** 20580000
 EJECT                                                                  20600000
*              LEVEL 3 ROUTINES                                         20620000
*        THESE MAY ONLY MODIFY THE VOLATILE AND PARAMETER REGISTRRS     20640000
*        RETURN REGISTER IS LEV3                                        20660000
 SPACE                                                                  20680000
*********************************************************************** 20700000
 SPACE                                                                  20720000
*   RDESD- READ EXTERNAL SYMBOL DICTIONARY                            * 20740000
*FUNCTION-                                                            * 20760000
*   PROVIDES INTERFACE WITH CRDESD ROUTINE (IN IEUF7I) TO READ THE    * 20780000
*   DESIRED ESD FROM THE OVERFLOW FILE                                * 20800000
*INPUT-                                                               * 20820000
*   REGISTER SP2 CONTAINS ADDRESS AT WHICH THE 'NOTE'D POSITION OF THE* 20840000
*     DESIRED ESD MAY BE FOUND                                        * 20860000
*   CESIOB(ACT) CONTAINS THE BASE ADDRESS OF THE ESD I/O AREA         * 20880000
*OUTPUT-  THE DESIRED ESD IS PLACED IN AN AREA BEGINNING AT           * 20900000
*         CESIOB(ACT)-259                                             * 20920000
*         CES10B(ACT)-259                                             * 20940000
         SPACE 2                                                        20960000
RDESD    STM   SP1,SP2,PNTSVE           DEPOSIT REGISTERS               20980000
         L     SP1,0(SP2)               LOAD 'NOTE'D ESD POSITION       21000000
         LA    SP1,0(SP1)               CONVERT TO 24-BIT ADDRESS       21020000
         L     SP2,CESIOB(ACT)          FIND ESD I/O AREA               21040000
         SH    SP2,=H'259'              START AT FRONT OF I/O AREA      21060000
         L     SRB,CTXTIO(ACT)                                          21080000
         BAL   SRR,CRDESD(SRB)          CALL CRDESD                     21100000
         LM    SP1,SP2,PNTSVE           WITHDRAW DEPOSITED REG'S        21120000
         BR    LEV3                     AND THAT'S ALL                  21140000
 SPACE                                                                  21160000
*********************************************************************** 21180000
 SPACE 2                                                                21200000
*********************************************************************** 21220000
*                                                                     * 21240000
*   FSTNR- SET FIRST ESD NUMBER                                       * 21260000
*FUNCTION-                                                            * 21280000
*   SETS THE FOLLOWING VARIABLES IN THE ACT-                          * 21300000
*        CTFSTNO..SET TO ESD NUMBER AND AJECTIVE CODE OF FIRST        * 21320000
*                 CONTROL SECTION                                     * 21340000
*        CTFSTN...RECEIVES EIGHT-BYTE NAME OF FIRST CONTROL SECTION   * 21360000
*   THESE VALUES ARE USED IN GENERATING SYMBOL TABLE ENTRIES FOR THE  * 21380000
*    LITERALS WHICH FOLLOW THE 'END' STATEMENT.                       * 21400000
         SPACE 2                                                        21420000
FSTNR    CLC   CTFSTNO(2,ACT),CTZERO(ACT) IF ALREADY SET                21440000
         BCR   7,LEV3                    THEN RETURN                    21460000
         LH    ACC,CNOESD(ACT)                                          21480000
         LA    ACC,1(ACC)               SET ESDNO AND ADJ CODE          21500000
         SLL   ACC,7                     OF FIRST CONTROL SECTION       21520000
         STH   ACC,CTFSTNO(ACT)          IN CENTRAL TABLE               21540000
         MVC   CTFSTN(8,ACT),NAME       MOVE FIRST NAME                 21560000
CTFSTNO  EQU   CTESRN                   FIRST ESD NO                    21580000
         BR    LEV3                     RETURN                          21600000
*                                                                     * 21620000
*********************************************************************** 21640000
 SPACE 2                                                                21660000
*********************************************************************** 21680000
*                                                                     * 21700000
*   STGET- SCAN SYMBOL TABLE                                          * 21720000
*FUNCTION-                                                            * 21740000
*   PROVIDES INTERFACE WITH STGETR ROUTINE (IN IEUF7S)                * 21760000
*   FINDS (IF POSSIBLE) A REQUESTED SYMBOL IN THE SYMBOL TABLE        * 21780000
*INPUT-                                                               * 21800000
*   NAME CONTAINS THE DESIRED EIGHT-BYTE SYMBOL                       * 21820000
*OUTPUT-                                                              * 21840000
*   SP1 CONTAINS THE ADDRESS OF THE FIRST BYTE FOLLOWING THE NAME     * 21860000
*                FIELD OF THE DESIRED SYMBOL TABLE ENTRY,             * 21880000
*            OR  ZERO, IF THE SYMBOL CAN NOT BE FOUND                 * 21900000
*   CONDITION CODE.. 0= SYMBOL NOT FOUND                              * 21920000
*                    2= SYMBOL FOUND                                  * 21940000
         SPACE 2                                                        21960000
STGET    LA    SP1,NAME                 POINT SP1 AT SYMBOL SOUGHT      21980000
         SR    SP2,SP2                                                  22000000
         L     SRB,CSTGET(ACT)          USE ACT AND FDIMEN TO           22020000
         BALR  SRR,SRB                  GET TO STGETR IN IEUF7S         22040000
         LTR   SP1,SP1                  SET CC TO SHOW RESULT           22060000
         BR    LEV3                     RETURN                          22080000
*                                                                     * 22100000
*********************************************************************** 22120000
         EJECT                                                          22140000
*********************************************************************** 22160000
*   GETNAME-                                                          * 22180000
*FUNCTION-                                                            * 22200000
*   RETRIEVE NAME FIELD OF CURRENT INPUT TEXT RECORD                  * 22220000
*INPUT-                                                               * 22240000
*   CTEXTP(ACT) CONTAINS ADDRESS OF CURRENT INPUT TEXT RECORD         * 22260000
*OUTPUT-                                                              * 22280000
*   NAME CONTAINS SYMBOL IN THE TEXT NAME FIELD, OR BLANKS IF THE     * 22300000
*   SYMBOL HAS BEEN MULTIPLY-DEFINED                                  * 22320000
*EXITS-                                                               * 22340000
*   NORMAL...  B    4(LEV3)                                           * 22360000
*   IF NAME FIELD BLANK.. B LEV3                                      * 22380000
         SPACE                                                          22400000
 SPACE                                                                  22420000
GETNAME  MVC   NAME(8),IBL2F            BLANK NAME                      22440000
         L     ACC,CTEXTP(ACT)          ACC POINTS TO TEXT RECORD       22460000
         TM    TXMDN(ACC),BIT3                                          22480000
         BCR   1,LEV3                   ERROR IN NAME                   22500000
 SPACE                                                                  22520000
         SR    TEMPR,TEMPR                                              22540000
         IC    TEMPR,TXNAML(ACC)        TEMPR HAS NAME LENGTH           22560000
         LTR   TEMPR,TEMPR              IS THERE AN ERROR IN NAME       22580000
         BCR   8,LEV3                   YES EXIT - NO NAME              22600000
 SPACE                                                                  22620000
         BCTR  TEMPR,0                  REDUCE BY ONE                   22640000
         EX    TEMPR,MVNAME             MOVE NAME FROM TEXT TO BLNK FLD 22660000
         B     4(LEV3)                  NORMAL EXIT                     22680000
         SPACE                                                          22700000
*********************************************************************** 22720000
 SPACE 2                                                                22740000
*********************************************************************** 22760000
*   ISOPF-   IS THERE AN OPERAND                                      * 22780000
*FUNCTION- DETERMINES WHETHER THE CURRENT INPUT TEXT RECORD CONTAINS  * 22800000
*     AN OPERAND.  THERE IS NO OPERAND IF THE FIRST CHARACTER OF THE  * 22820000
*     OPERAND FIELD CONTAINS A BLANK OR COMMA.                        * 22840000
*INPUT-                                                               * 22860000
*   CTXOFP(ACT) CONTAINS ADDRESS OF OPERAND FIELD,-1                  * 22880000
*OUTPUT-                                                              * 22900000
*   CONDITION CODE.. 0= NO OPERAND                                    * 22920000
*                    1= IS OPERAND                                    * 22940000
*                    2= IS OPERAND                                    * 22960000
         SPACE                                                          22980000
ISOPF    L     ACC,CTXOFP(ACT)          FIND OPERAND FIELD              23000000
         CLI   1(ACC),IBLANK            IS IT A BLANK                   23020000
         BCR   8,LEV3                   YES, RETURN                     23040000
         CLI   1(ACC),ICOMMA            IS IT A COMMA                   23060000
         BCR   7,LEV3                   NO, RETURN                      23080000
         CLI   0(ACC),2                 SET CC NE 0                     23100000
         BR    LEV3                     RETURN                          23120000
*********************************************************************** 23140000
 SPACE                                                                  23160000
*********************************************************************** 23180000
 SPACE                                                                  23200000
*   XREF-  FORM CROSS-REFERENCE RECORDS                               * 23220000
*ENTRY POINTS-                                                        * 23240000
*   XREF1...FOR TYPE 2 CROSS-REFERENCE  (REFERENCE TO SYMBOL)         * 23260000
*   XREF2...FOR TYPE 3 CROSS-REFERENCE  (MULTIPLY DEFINED)            * 23280000
*INPUT-                                                               * 23300000
*   CTXRFI(ACT)...BIT 7... 1=CROSS REFERENCE DESIRED                  * 23320000
*   CTSEQN(ACT) CONTAINS CURRENT STATEMENT SEQUENCE NUMBER            * 23340000
*OUTPUT-                                                              * 23360000
*   REGISTER SP1 CONTAINS ADDRESS OF NEW XREF RECORD                  * 23380000
*FUNCTION-  WRITE XREF RECORD (VIA PUTXRF) AND FORM NEW XREF RECORD   * 23400000
*EXTERNAL ROUTINES-  PUTXRF (IN IEUF7I) IS USED TO PERFORM RECORD OUT-* 23420000
*                    PUT AND BUFFER ALLOCATION.                       * 23440000
*NOTE-  STATEMENTS AT 'XREF1' AND 'XREF2' ALTER THE COMMAND AT 'XRTYP'* 23460000
         SPACE                                                          23480000
XREF2    MVI   XRTYP+1,C'2'             X'F2'=TYPE 3                    23500000
         B     XREF                     WORK STARTS AT XREF             23520000
XREF1    MVI   XRTYP+1,C'1'             X'F1'=TYPE 2                    23540000
XREF     TM    CTXRFI(ACT),X'02'        XREF BIT ON   Q.                23560000
         BCR   8,LEV3                   NO, SKIP IT                     23580000
         CLI   NAME,IBLANK              NO XREF FOR BLANK NAMES, SO     23600000
         BCR   8,LEV3                   HERE'S ANOTHER CHANCE TO SKIP   23620000
         SPACE                                                          23640000
         L     ACC,CTEXTP(ACT)         TEXT RECORD ADDRESS TO ACC  6822 23660000
         MVC   XREFWK(1),TXRT(ACC)     PICK OUT RECORD TYPE        6822 23680000
         NI    XREFWK,X'70'            STRIP OFF EXTRA BITS        6822 23700000
         BZ    XREF005                 SKIP, IF TYPE IS ZERO       6822 23720000
         XI    XREFWK,X'50'            SEE ABOUT TYPE 5            6822 23740000
         BCR   8,LEV3                  NO XREF FOR TYPE 5          6822 23760000
XREF005  L     SRB,CTXTIO(ACT)         SELECT IEUF7I               6822 23780000
         BAL   SRR,PUTXRF(SRB)          PUTXRF RETURNS NEW BUFF IN SP1  23800000
         MVC   0(8,SP1),NAME            INSERT NAME FIELD               23820000
         L     ACC,CTRTBP(ACT)          FIND TRANSLATE TABLE            23840000
         TR    0(8,SP1),0(ACC)          TRANSLATE NAME TO EBCDIC        23860000
XRTYP    MVI   8(SP1),C'1'              INSERT 'FLAGA' FIELD            23880000
         MVC   9(2,SP1),CTSEQN+2(ACT)   INSERT STATEMENT SEQ. NUMBER    23900000
         MVC   11(6,SP1),CTZERO(ACT)    CLEAR LENGTH, VALUE, FLAGB FLDS 23920000
         BR    LEV3                     ALL DONE                        23940000
         SPACE                                                     6822 23960000
XREFWK   DS    1C                      TEAR UP RECORD TYPE HERE    6822 23980000
         SPACE                                                     6822 24000000
*********************************************************************** 24020000
         EJECT                                                          24040000
*********************************************************************** 24060000
*                                                                     * 24080000
*   ESCRBL-  FORM ESD ENTRY                                           * 24100000
*                                                                     * 24120000
*FUNCTION-                                                            * 24140000
*   FINDS ROOM TO PLACE ESD ENTRY (VIA STROOM IN IEUF7S)              * 24160000
*   UPDATES POINTERS IN CONTROL TABLE, TO INDICATE ESD ENTRY HAS BEEN * 24180000
*    MADE.                                                            * 24200000
*INPUT/OUTPUT PARAMETERS                                              * 24220000
*   CTDESP(ACT)...POINTER TO START OF ESD TABLE                       * 24240000
*   CSGCTR(ACT)...COUNT OF ESD ENTRIES IN CURRENT SEGMENT             * 24260000
*   CNOESD(ACT)...NUMBER OF ESD'S                                     * 24280000
*   CESDNO(ACT)...CURRENT ESD NUMBER                                  * 24300000
*   CTESRP(ACT)...POINTER TO RESIDENT ESD                             * 24320000
*EXTERNAL ROUTINES-                                                   * 24340000
*   STROOM...(IN IEUF7S) USED TO CHECK SYMBOL-ESD TABLE FOR POSSIBLE  * 24360000
*    OVERFLOW                                                         * 24380000
*EXITS-                                                               * 24400000
*   IF TYPE IS VCON OR QCON,                                          * 24420000
*        BR    LEV2                                                   * 24440000
*   OTHERWISE,                                                        * 24460000
*        BR    LEV3                                                   * 24480000
         SPACE                                                          24500000
ESCRBL   L     SRB,CSTROM(ACT)          GET STROOM ADDRESS              24520000
         LA    SP1,16                   HOW MUCH ROOM NEEDED            24540000
         BALR  SRR,SRB                  GO FIND ROOM                    24560000
         NOP   0                                                        24580000
         L     SP1,CTESDP(ACT)          POINTS TO START OF ESD          24600000
         SH    SP1,=H'16'               CHANGE IT                       24620000
         ST    SP1,CTESDP(ACT)          AND PUT IT BACK                 24640000
         CLI   CSGCTR+1(ACT),SRSGSZ     IS CURRENT SEGMENT FULL-        24660000
         BE    SRUPDT                   YES, START NEW SEGMENT          24680000
         LH    ACC,CSGCTR(ACT)          NO, UPDATE CURRENT SEG. POINTER 24700000
         LA    ACC,1(ACC)                                               24720000
         STH   ACC,CSGCTR(ACT)          NOW UPDATED                     24740000
         SPACE                                                          24760000
SETESP   MVC   TTYPE(16,SP1),TYPE       PUT ENTRY INTO ESD TABLE        24780000
         MVC   ADDR(7),CTZERO(ACT)      CLEAR WORK AREA                 24800000
         LH    ACC,CNOESD(ACT)          UPDATE ESD COUNT                24820000
         LA    ACC,1(ACC)                                               24840000
         STH   ACC,CNOESD(ACT)          NOW UPDATED                     24860000
         CLI   TYPE,LDCON               IF TYPE=LD,                     24880000
         BCR   8,LEV3                   RETURN                          24900000
         CLI   TYPE,VCCON               IF TYPE= VCON OR QCON,          24920000
         BCR   8,LEV2                   RETURN TO VCON CODE             24940000
         STH   ACC,CESDNO(ACT)          OTHERWISE, SET ESD NUMBER       24960000
         BR    LEV3                     AND RETURN                      24980000
         SPACE                                                          25000000
SRUPDT   MVI   CSGCTR+1(ACT),0          COUNTER STARTS=0                25020000
         L     ACC,CTESDP(ACT)          SPACE ESD START DOWN ENOUGH-    25040000
         SH    ACC,=H'4'                FOR BLOCK IDENTIFIER-           25060000
         ST    ACC,CTESDP(ACT)          DONE                            25080000
         L     GRZ,CTESRP(ACT)          POINT TO ESD RESIDENT SEGMENT   25100000
         LA    GRZ,4(GRZ)               SKIP IDENTIFIER                 25120000
         ST    GRZ,CTESRP(ACT)          FRONT OF SEGMENT                25140000
         ST    ACC,0(GRZ)               POINTS TO PREVIOUS SEGMENT      25160000
         MVI   0(GRZ),1                 CLEAR FIRST BYTE                25180000
         B     SETESP                   NOW GO MAKE ENTRY               25200000
*                                                                     * 25220000
*********************************************************************** 25240000
         EJECT                                                          25260000
MVNAME   MVC   NAME(0),TXNAME(ACC)                                      25280000
MVNMEV   MVC   NAME(0),0(SP1)           EXECUTED                        25300000
 SPACE                                                                  25320000
**                            AREAS NEEDED                           ** 25340000
         DS    0F                                                       25360000
TEMPF    DC    H'0'                     TEMPARY FULL WORD               25380000
TEMPH    DC    H'0'                             HALF WORD               25400000
ADJ      EQU   TEMPH+1                  ADJECTIVE CODE                  25420000
ECTR     DC    H'101'                   ENTRY COUNTER                   25440000
RDSW     DC    X'0'                     READ SWITCH                     25460000
VSAVE    DC    F'0'                     V-CON SAVE AREA                 25480000
SVSP1    DC    F'0'                     ESD ITEM PTR TEMP SAVE   A45759 25490000
ERRPTR   DC    F'0'                     ERROR POINTER TO COLUMN         25500000
SAVESP   DC    F'0'                     SAVE FOR ESD WRITE              25520000
PNTSVE   DC    2F'0'                                                    25540000
TEMPZF   DC    F'0'                     FULL WORD ZERO                  25560000
         DS    0F                        ESD ITEM FORMAT                25580000
TYPE     DC    X'0'                     *    TYPE                       25600000
ADDR     DC    XL3'0'                   *    ADDRESS                    25620000
ALIGN    EQU   ADDR+2                   *    ALIGNMENT                  25640000
AID      DC    X'0'                     *    ESD/ID                     25660000
ALTH     DC    XL3'0'                   *    LENGTH                     25680000
NAME     DC    CL8'0'                   *    NAME                       25700000
IBL2F    DC    8AL1(IBLANK)             8 BYTES OF BLANK                25720000
         LTORG                                                          25740000
         EJECT                                                          25760000
EWBKSW   EQU   TXSESL                   LAST OPERAND INDICATOR          25780000
EWBCMP   EQU   TXSPTR                                                   25800000
STPUT    EQU   CSTPUT                   POINTER TO SYMBOL IN OPERAND    25820000
STADJ    EQU   1                        SYMBOL TABLE PUT ROUTINE        25840000
ADJCD    EQU   STADJ                    POSITION OF ADJECTIVE           25860000
ALNBYTE  EQU   17                       POSITION OF ALIGNMENT           25880000
DSOCM    EQU   4                        DS OR COM MASK                  25900000
ESIOID   EQU   3                        ESD INDICATOR                   25920000
ENTCMB   EQU   8                        ENTRY COMPLETE CODE             25940000
EWBKID   EQU   0                        POSITION OF WKBKT ID            25960000
EWBKVL   EQU   1                                         VALUE          25980000
EWBKNO   EQU   EWBKVL+1                 PISITION OF BLOCK NO.           26000000
MOD8     EQU   7                        MASK FOR DOUBLE WORD BOUNDARY   26020000
NOTHI    EQU   13                       NOT HIGH                        26040000
PARID    EQU   5                        PARAMETER TABLE ID              26060000
SRSGSZ   EQU   15                       SEGMENT FULL INDICATOR          26080000
STID     EQU   2                        POSITION OF ID                  26100000
SYMVAL   EQU   3                                    SYMBOL VALUE        26120000
CCHIGH   EQU   X'20'                    MASK FOR DS OR DXD              26140000
ECMPLT   EQU   X'FF'                             WKBKT COMPLETE         26160000
FILLED   EQU   X'90'                    WKBKT COMPLETE INDICATOR        26180000
FULL     EQU   X'40'                    MASK FOR WKBKT FULL             26200000
LASTOP   EQU   X'80'                             LAST OPERAND           26220000
ONSDVI   EQU   X'80'                    INDICATOR FOR SELF DEFINE VALUE 26240000
LASTWB   EQU   X'08'                                  LAST WKBKT        26260000
PDSI     EQU   X'20'                                  PREVIOUSLY DEFINE 26280000
SDBIT    EQU   3                                      CSECT OR START    26300000
SDMSK    EQU   3                                      CSECT OR START    26320000
SDBITS   EQU   X'00'                                  CSECT OR START    26340000
ERBITS   EQU   X'01'                                  EXTERNAL          26360000
DSBITS   EQU   X'02'                                  DSECT             26380000
DXDFLAG  EQU   X'10'                                  DXD               26400000
BIT3     EQU   X'10'                    MASK FOR DSECT OR COMMON        26420000
WBKLEN   EQU   6                        WKBKT LENGTH                    26440000
WBKSW    EQU   TXFAFL                   WKBKT SWITCH                    26460000
WBKTYP   EQU   TXFAFL+1                       TYPE                      26480000
WBKID    EQU   TXFAFL+TXSESD                  ESD/ID                    26500000
WBKNO    EQU   TXFAFL+4                 ESDNO AND ADJ CODE              26520000
SETWX    EQU   X'02'                    INDICATES WXTRN            I004 26530020
         SPACE                                                          26540000
ERR01    EQU   80                       ILLEGAL START                   26560000
ERR02    EQU   39                       INVALID DELIMITER               26580000
ERR03    EQU   25                       RELOCATABILITY                  26600000
ERR04    EQU   33                       ALIGNMENT                       26620000
ERR05    EQU   19                       EXTERNAL NAME                   26640000
ERR06    EQU   38                       EXTRN                           26660000
ERR08    EQU    95                      ENTRY TABLE OVERFLOW            26680000
ERR10    EQU     6                      INVALID ORIGIN                  26700000
ERR11    EQU   21                       SYMBOL NOT PREVIOUSLY DEFINED   26720000
ERR12    EQU   106                      NOT NAME OF DXD OR DSECT        26740000
ERR13    EQU   25                       RELOCATABILITY                  26760000
ERR14    EQU   22                       ESD TABLE OVERFLOW              26780000
         EJECT                                                          26800000
**                       FIELDS IN ESD ITEMS                         ** 26820000
TTYPE    EQU   1                                  TYPE                  26840000
TADDR    EQU   2                                  ADDRESS               26860000
TID      EQU   5                                  ESD/ID                26880000
TLTH     EQU   6                                  LENGTH                26900000
TNAME    EQU   9                                  NAME                  26920000
TALIGN   EQU   TTYPE+3                            ALIGNMENT             26940000
         SPACE                                                          26960000
**                            TYPE CONSTANTS                         ** 26980000
SDCON    EQU   0                                  CSECT OR START        27000000
LDCON    EQU   1                                  ENTRY                 27020000
ERCON    EQU   2                                  EXTERN                27040000
PCCON    EQU   4                                  PRIVATE CODE          27060000
CMCON    EQU   5                                  COMMON                27080000
DXCON    EQU   6                                  DXD                   27100000
DSCON    EQU   7                                  DSECT                 27120000
VCCON    EQU   8                                  V-TYPE CONSTANT       27140000
WXCONA   EQU   10                                 WEAK EXTERN      I004 27150020
         SPACE                                                          27160000
**                           REGISTER USAGE                          ** 27180000
ACC      EQU   GRX                      ACCUMULATOR                     27200000
TEMPR    EQU   GRY                      TEMPERARY                       27220000
ECT      EQU   GRZ                      NUMBER OF ENTRIES               27240000
LTH      EQU   GRZ                      LENGTH                          27260000
ALN      EQU   TEMPR                    ALIGNMENT                       27280000
SEGAD    EQU   SP2                      SEGMENT (BLOCK)                 27300000
BEGIN    EQU   TEMPR                    BEGINNING OF SEGMENT            27320000
END      EQU   ACC                      END OF SEGMENT                  27340000
ITEMCT   EQU   GRD                      ITEMS IN SEGMENT                27360000
TXPTR    EQU   ACC                      POINTER TO TEXT                 27380000
WBP      EQU   GRA                      POINTER TO WKBKT                27400000
LEV1     EQU   GRA                      RETURN LEVEL 1                  27420000
LEV2     EQU   GRB                      RETURN LEVEL 2                  27440000
LEV3     EQU   GRD                      RETURN LEVEL 3                  27460000
ELOOPR   EQU   GRC                      LOOP ADDRESS                    27480000
         SPACE                                                          27500000
         END                                                            27520000
