F7G      TITLE 'DCGETR - F/7 LITERAL DC GENERATION SUBROUTINE '         00020000
         ISEQ  73,80                                                    00040000
IEUF7G   START                                                          00060000
*        RELEASE 21 DELETIONS                                         * 00062021
* 013200,014000,015200                                           A52850 00064021
*                                                                       00066000
*                                                                       00068000
*                                                                       00070000
*                                                                       00072000
*                                                                       00074000
*                                                                       00076000
*                                                                       00078000
DCGETR   EQU   IEUF7G                                                   00080000
         PRINT DATA,NOGEN                                               00100000
         FDIMEN                                                         00120000
         PRINT GEN                                                      00140000
*                                                                     * 00160000
*TITLE 'IEUF7G  ' ... LITERAL DC GENERATION                           * 00180000
*STATUS- CHANGE LEVEL  02                                             * 00200021
*FUNCTION/OPERATION-                                                  * 00220000
*   IEUF7G BUILDS A LITERAL DC EDITED TEXT RECORD FOR A OUTSTANDING   * 00240000
*   LITERL ENTRY IN THE SYMBOL TABLE                                  * 00260000
*ENTRY POINTS- IEUF7G                                                 * 00280000
*   CALLING SEQUENCE                                                  * 00300000
*        L     SRB,CDCGET(ACT)          SET UP BASE                   * 00320000
*        BALR  SRR,SRB                  CALL IEUF7G                   * 00340000
*INPUT- NONE                                                          * 00360000
*OUTPUT- NONE                                                         * 00380000
*EXTERNAL ROUTINES- NONE                                              * 00400000
*EXITS- NORMAL                                                        * 00420000
*       RETURNS TO CALLER VIA                                         * 00440000
*        BR    SRR                      EXIT                          * 00460000
*     - ERROR-- NONE                                                  * 00480000
*TABLES/WORKAREA-                                                     * 00500000
*   RL- FIXED FIELDS OF TEXT RECORD                                   * 00520000
*NOTES-                                                               * 00540000
*   IEUF7G CREATES THE TEXT RECORD BY BUILDING IT AND/OR MOVING IT    * 00560000
*   FROM THE LITERAL DC RECORD AREA. GRZ POINTS TO THE FIELD IN THE   * 00580000
*   LITERAL DC RECORD AREA AND GRX POINTS TO THE TEXT RECORD.         * 00600000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 00620000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 00640000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 00660000
*                                                                     * 00680000
         EJECT                                                          00700000
         USING *,SRB                                                    00720000
DCGTR    SR    GR1,GR1                  ZERO STRING COUNTER             00740000
         L     GRX,CTLDCP(ACT)          GET PTR TO LITERAL DC REC AREA  00760000
         ST    GRX,SAVPTR               SAVE IT                         00780000
GETLIT   L     GRY,CTSYMP(ACT)          GET PTR TO 1ST BYTE OF SYM TBL  00800000
GTLIT1   MVC   ALWRD+1(3),0(GRY)                                        00820000
         L     GRZ,ALWRD                GET NEXT STRING POINTER         00840000
         LTR   GRZ,GRZ                  TEST IF POINTER IS ZERO         00860000
         BNE   GTLIT2                   NO MEANS MORE LITERALS          00880000
         LA    GR1,1(GR1)               ADD 1 TO STRING COUNTER         00900000
         LA    GRY,3(GRY)               POSITION TO NEXT STRING POINTER 00920000
         CH    GR1,CON4                 TEST IF 4 STRINGS PROCESSED     00940000
         BNE   GTLIT1                   NO,GO TO PROCESS NEXT STRING    00960000
EXIT     BR    SRR                      BACK TO MAIN LINE               00980000
GTLIT2   A     GRZ,CTSYMP(ACT)          GET PTR TO LITERAL ENTRY        01000000
         MVC   0(3,GRY),0(GRZ)          MOVE CHAIN PTR TO STRING PTR    01020000
         IC    GR1,3(GRZ)               GET DEF LENG-1 OF SOURCE LITRL  01040000
         EX    GR1,MVSRCE               MOVE SOURCE INTO TEXT RECORD    01060000
         LA    GRZ,6(GRZ,GR1)           POINT TO WORK BUCKET IN TABLE   01080000
* AT THIS POINT MOVE WBS IN IF PRESENT                                  01100000
         LA    GR1,3(GR1)               GET TRUE LGTH OF OPND. FIELD    01120000
         STC   GR1,OPNL                 STORE IN OPRND FIELD LENGTH     01140000
         LA    GRX,14(GRX,GR1)          POINT PAST OPRND FIELD          01160000
* AT THIS POINT TXLOC SHOULD BE SET PROPERLY IN CASE OF *               01180000
         MVC   0(7,GRX),BLNK            MOVE IN BLANK AND APP FIXED FLD 01200000
         LA    GRX,2(GRX)               POINT TO APPENDED FIXED FIELD   01220000
         S     GRX,SAVPTR               GET PTR TO APPENDED FIXED FIELD 01240000
         STH   GRX,ABP                  STORE IT                        01260000
         A     GRX,SAVPTR                                               01280000
         MVC   5(15,GRX),0(GRZ)         MOVE LDC WB FROM TABLE TO TEXT  01300000
         OI    5(GRX),X'08'             SET LAST OPERAND INDICATOR      01320000
         SR    GR2,GR2                                           A52850 01330021
         TM    6(GRX),X'80'             TEST IF LOC CTR IN TABLE ENTRY  01340000
         BZ    GTLIT3                   NO, BRANCH                      01360000
         MVC   0(4,GRX),15(GRZ)         YES,MOVE IT INTO TEXT RECORD    01380000
         LA    GR2,4                    SET INDEX PAST CTR FLD   A52850 01400021
GTLIT3   NI    6(GRX),X'3F'             SET LOC CTN NOT IN TABLE ENTRY  01420000
         LA    GRX,20(GRX)              SET POINTER BEYOND LDC WKBKT    01440000
         TM    1(GRZ),X'40'             ARE THERE WKBKTS                01460000
         BZ    GETLIT6                  NO, PUT IN TEXT RECORD AS IS    01480000
         ST    GRX,CTXWBP(ACT)          SAVE POINTER TO WKBKT           01500000
         LA    GRZ,9(GRZ,GR2)           SET LITERAL ENTRY PTR..  A52850 01520021
GETLIT4  LA    GRZ,6(GRZ)               UP TO BEGINNING OF WKBKT        01540000
         MVC   0(6,GRX),0(GRZ)          MOVE IN WKBKT                   01560000
         LA    GRX,6(GRX)               UP POINTER PAST WKBKT JUST MOVE 01580000
         TM    TXSLAS(GRZ),X'08'        IS THIS LAST WKBKT              01600000
         BZ    GETLIT4                  NO, GET THE REST                01620000
GETLIT6  S     GRX,SAVPTR                GET RECORD LENGTH.             01640000
         STH   GRX,RL                   STORE IN FIXED BUILD AREA       01660000
         L     GRX,SAVPTR               POINT TO BEGINING OF RECORD     01680000
         MVC   0(16,GRX),RL             MOVE IN FIXED PART OF RECORD    01700000
         B     EXIT                                                     01720000
MVSRCE   MVC   16(0,GRX),4(GRZ)         EXECUTED MOVE OF SOURCE LITERAL 01740000
*FIXED FIELDS OF TEXT RECORD DEFINED INTERNAL TO THIS ROUTINE           01760000
RL       DC    H'0'                     RECORD LENGTH                   01780000
RT       DC    X'60'                    REC TYPE=EDITED GENERATED       01800000
TO       DC    X'80'                    TYPE OF OPERATION=ASSEMBLER     01820000
HEXOP    DC    X'25'                    HEX OPERATION CODE=25(LITR)     01840000
ASC      DC    X'01'                    ASSEMBLER SWITCH CODES          01860000
ABP      DC    2X'00'                   APPENDED FIXED FIELD POINTER    01880000
NAML     DC    X'00'                    NAME FIELD LENGTH=0             01900000
OPL      DC    X'04'                    OPERATION FIELD LENGTH=4        01920000
OP       DC    4AL1(IBLANK)             OPERATION FIELD = BLANK         01940000
OPNL     DC    X'00'                    OPERAND FIELD LENGTH INCLUDING  01960000
*                                       ONE TRAILING BLANK              01980000
         DC    AL1(IEQUAL)              EQUAL SIGN IN OPERAND FIELD     02000000
BLNK     DC    AL1(IBLANK)                                              02020000
COML     DC    X'00'                    COMMENTS FIELD LENGTH=0         02040000
LOC      DC    3X'00'                   LOCATION COUNTER                02060000
URS      DC    X'00'                    UNRESOLVED SYMBOL COUNTER=0     02080000
LES      DC    X'00'                                                    02100000
ALWRD    DC    F'0'                     TEMP FULL WORD                  02120000
SAVPTR   DC    F'0'                     TEMP SAVE AREA FOR GRX          02140000
CON4     DC    H'4'                     NO. OF LIT DC IN SYMBOL TABLE   02160000
         END   DCGTR                                                    02180000
