F7I  TITLE '***F7 INITIALIZATION AND I/O SUBROUTINES--   ***'           00020000
         ISEQ  73,80                                                    00040000
         MACRO                                                          00060000
&L       CKFLG &DUMMY                                                   00080000
*CHECK TEXT READ COMPLETE ROUTINE CALL                                  00100000
&L       BAL   GR4,TEXTCK                                               00120000
         MEND                                                           00140000
IEUF7I   START                                                          00160000
*          RELEASE 19 DELETIONS                                       * 00166000
*                                                                A28234 00166319
*                                                                A28249 00166619
*          RELEASE 20 DELETIONS                                       * 00167000
* 024200-024600,025000,025600,163800-167200,176240-176320,         I000 00167220
* 178000-182400,192220-192800,209800,241200-241800,                I000 00167420
* 242400-242600,243600-243800                                      I000 00167620
*                                                                200002 00167820
* 199050-199200                                                  A31005 00168420
* 070700                                                         A32193 00169020
* 178000-178200,178500-179600,180700-181200,181800-182100         M3432 00169320
*          RELEASE 21 DELETIONS                                         00169620
* 179200                                                         A33012 00170021
* 176320                                                         A39657 00170121
* 001650-001659,016935,193320,206540                             A52811 00170221
* 169000,169500                                                  A63333 00170621
* 019426                                                         A66044 00170721
*STATUS CHANGE LEVEL 011                                                00171021
*                                                                       00173020
* INCREMENTAL IMPROVEMENTS FOR RELEASE 20                               00175020
* I000 TSO IMPLEMENTATION                                               00177020
         SPACE 1                                                        00180000
*TITLE-  IEUF7I...PHASE F7 INITIALIZATION AND I/O ROUTINES            * 00200000
*FUNCTION/OPERATION-                                                  * 00240000
*   PERFORMS INITIALIZATION FOR F7.                                   * 00260000
*   CONTAINS I/O ROUTINES USED BY PHASE F7                            * 00280000
*ENTRY POINTS-                                                        * 00300000
*   IEUF7.... PERFORMS INITIALIZATION FUNCTIONS FOR PHASE F7          * 00320000
*   IEUF7I...  PROVIDES ACCESS TO THE FOLLOWING SUBROUTINES-          * 00340000
*   ENTRY  NAME   FUNCTION                                            * 00360000
*   GTP  (GETPT) POINT ROUTINE FOR INPUT BUFFER                       * 00380000
*   GTM  (GETXTM) GET TEXT AND MOVE TO INPUT AREA                     * 00400000
*   PTX  (PUTXT)  PUT TEXT TO OUTPUT BUFFER                           * 00420000
*   CLT  (CLSTXT) CLOSE TEXT                                          * 00440000
*   RDE  (CRDESD) READ EXTERNAL SYMBOL DICTIONARY                     * 00460000
*   WTE  (CWRESD) WRITE EXTERNAL SYMBOL DICTIONARY                    * 00480000
*   PUTX (PUTXRF) PUT CROSS REFERENCE                                 * 00500000
*   PUTLB(PUTLBT) PUT LITERAL BASE TABLE                              * 00520000
*   SYSO (SYSOUT) SYSTEM OUTPUT                                       * 00540000
*   PHC  (PHCLS)  PHASE CLOSE, 'XCTL' TO IEUFI                        * 00560000
*CALLING SEQUENCE-                                                    * 00580000
*   IEUF7...                                                          * 00600000
*        LINK  EP=IEUF7,MV=(E,(1))                                    * 00620000
*   IEUF7I ROUTINES...                                                * 00640000
*        L     SRB,CTXTIO(ACT)                                        * 00660000
*        BAL   SRR,NAME(SRB)                                          * 00680000
*              CTXTIO(ACT) CONTAINS THE ADDRESS OF IEUF7I.  'NAME' IS * 00700000
*              EQUATED (IN FDIMEN MACRO) TO THE DISPLACEMENT, FROM    * 00720000
*              IEUF7I, OF AN INSTRUCTION OF THE FORM-                 * 00740000
*                        B    ENTRY                                   * 00760000
*              WHERE 'ENTRY' IS THE ENTRY POINT OF THE SUBROUTINE     * 00780000
*              SELECTED BY THE SELECTION OF A PARTICULAR 'NAME'.      * 00800000
*INPUT/OUTPUT PARAMETERS-  SEE INDIVIDUAL SUBROUTINES                 * 00820000
*EXTERNAL ROUTINES-                                                   * 00840000
*   THE ADDRESSES OF THE FOLLOWING EXTERNAL ROUTINES ARE PLACED IN THE* 00860000
*   ASSEMBLER CONTROL TABLE (ACT) FOR REFERENCE BY OTHER PHASE 7 ROUT-* 00880000
*   INES-                                                             * 00900000
*      (ROUTINE)        (DECK)         (ACT REFERENCE)                * 00920000
*        IEUF7E          IEUF7E         CBRNDA                        * 00940000
*        COM             IEUF7E         CCOM                          * 00960000
*        CSECT           IEUF7E         CCSECT                        * 00980000
*        DSECT           IEUF7E         CDSECT                        * 01000000
*        ENTRY           IEUF7E         CENTRY                        * 01020000
*        ENTRYS          IEUF7E         CENTRS                        * 01040000
*        ESWBKR          IEUF7E         CESWBK                        * 01060000
*        EXTRN           IEUF7E         CEXTRN                        * 01080000
*        EXTRNS          IEUF7E         CEXTRS                        * 01100000
*        ORG             IEUF7E         CORG                          * 01120000
*        QUIT            IEUF7E         CQUIT                         * 01140000
*        START           IEUF7E         CSTART                        * 01160000
*        UPC             IEUF7E         CUPC                          * 01180000
*        IEUF7D          IEUF7D         CDCVAL                        * 01200000
*        IEUF7X          IEUF7X         CTXGET                        * 01220000
*        IEUF7N          IEUF7N         CTESTR                        * 01240000
*        DXD             IEUF7E         CDXD                          * 01260000
*        STGETR          IEUF7S         CSTGET                        * 01280000
*        STPUTR          IEUF7S         CSTPUT                        * 01300000
*        IEUF7V          IEUF7V         CEEVAL                        * 01320000
*        IEUF7L          IEUF(L         CLOGER                        * 01340000
*        IEUF7G          IEUF7G         CDCGET                        * 01360000
*        VCON            IEUF7E         CVCDN                         * 01380000
*        STROOM          IEUF7S         CSTROM                        * 01400000
*   THESE ROUTINES ARE SUBSEQUENTLY REFERENCED VIA THE ACT BY OTHER   * 01420000
*   PHASE F7 ROUTINES                                                 * 01440000
*EXITS-                                                               * 01460000
*    IEUF7..BRANCH TO IEUF7C                                          * 01480000
*    IEUF7I..PHCLS 'XCTL' TO IEUFI; OTHER SUBROUTINES RETURN TO CALL- * 01500000
*            ING PROGRAM.                                             * 01520000
*TABLES/WORK AREAS-                                                   * 01540000
*    ASSEMBLER CONTROL TABLE..(SEE IEURTA)                            * 01560000
*    URTAB,MTTAB,DATAB..TABLES OF STORAGE REQUIREMENTS FOR I/O DEVICES* 01580000
*    F7CT2...FUNCTIONAL ROUTINE BASE/ENTRY ADDRESSES                  * 01600000
*    F7CT3...COMMON SUBROUTINE BASE/ENTRY ADDRESSES                   * 01620000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 01640000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 01660000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 01680000
*                                                                  I000 01683020
* IEUF7L AND IEUF7S MODULES ARE DELETED AS SEPARATE CSECTS.        I000 01686020
* THEY ARE PLACED IN PHASE IEURTA TO GET MORE SUFFICIENT           I000 01689020
* USE OF CORE IN MVT.                                              I000 01692020
*NOTES -                                                         200002 01692320
*   MAINTENANCEAREA FOR THE MFT SYSTEM IS AVAILABLE IN THREE     200002 01692620
*   LOCATIONS FOR PHASE F7:                                      200002 01692920
*   1 PATCHAREA OF 20F AT END OF MODULE IEUF7D                   200002 01693220
*   2 1024 BYTES OBTAINED FROM GETMAINAREA AT LOC MAINT1         A52811 01693521
*   3 PATCHAREA OF 20F AT LOC MAINT2                             200002 01693820
*   BECAUSE OF THE 2K LOADMODULE SYSTEM NO SPECIAL SPACE IS      200002 01694120
*   REQUESTED FOR THE MVT SYSTEM                                 200002 01694420
*                                                                  I000 01695020
         EJECT                                                          01700000
TEXTIO   EQU   IEUF7I                                                   01720000
         PRINT DATA,NOGEN               SEE RTSEGA FOR TABLE LISTING    01740000
         FDIMEN                                                         01760000
         PRINT GEN                                                      01780000
*   REGISTERS EQUATED TO VALUES DEFINED WITHIN FDIMEN                   01800000
GR3      EQU   GRX                      VOLATILE REGISTER               01820000
GR4      EQU   GRY                      VOLATILE REGISTER               01840000
GR5      EQU   GRZ                      VOLATILE REGISTER               01860000
GR12     EQU   GRA                      GRA-GRD ARE USED BY FUNCTIONAL  01880000
GR13     EQU   GRB                      SUBROUTINES...NOT ALTERED BY    01900000
GR14     EQU   GRC                      COMMON SUBROUTINES...           01920000
GR15     EQU   GRD                      FOUR CONTIGUOUS REGISTERS       01940000
*                                                                  I000 01941020
BIT12    EQU   X'60'                    FLAG FOR PCP OR MFT        I000 01942020
BIT2     EQU   X'20'                    FLAG FOR MFT             A31005 01942220
ONEK     EQU   1024                     CORE TO BE FREED         A31005 01942420
THREEH   EQU   352                      CORE TO BE FREED         A66044 01942621
SEVEN    EQU   7                        CORE TO BE FREED         A31005 01942820
TEST4    EQU   X'08'                    FLAG FOR UNIT RECORD       I000 01943020
NOBUF    EQU   0                        FLAG FOR BUFNO             I000 01944020
DEFTBUF  EQU   2                        DEFAULT BUFNO              I000 01945020
L3       EQU   3                        NUMBER OF BYTES TO MOVE    I000 01946020
L4       EQU   4                        NUMBER OF BYTES TO MOVE    I000 01947020
L8       EQU   8                        NUMBER OF BYTES TO MOVE    I000 01948020
SIZEPH8  EQU   X'5418'                  SIZE OF PHASE 8            I000 01952020
SIZEPH7  EQU   X'53EE'                  SIZE OF PHASE 7            I000 01956020
         ENTRY IEUF7                                                    01960000
*        EXTRNS FOR F/7 FUNCTIONAL ROUTINES                             01980000
         EXTRN IEUF7E        ENTRIES IN EXTERNAL SYMBOL DICTIONARY...   02000000
         EXTRN COM                      'COM' STATEMENTS                02020000
         EXTRN CSECT                    'CSECT' STATEMENTS              02040000
         EXTRN DSECT                    'DSECT'                         02060000
         EXTRN ENTRY                    'ENTRY', ASSIGNMENT MODE        02080000
         EXTRN ENTRYS                   'ENTRY', SUBTITUTION MODE       02100000
         EXTRN ESWBKR                   FILLS STATEMENT WRK BUCKET      02120000
         EXTRN EXTRN                    'EXTRN' STATEMENT, ASSIGNMENT   02140000
         EXTRN EXTRNS                   'EXTRN', SUBSTITUTION MODE      02160000
         EXTRN ORG                      'ORG'                           02180000
         EXTRN QUIT                     'QUIT' (GENERATED AFTER 'END')  02200000
         EXTRN START                    'START'                         02220000
         EXTRN UPC                      UNINITIATED PRIVATE CODE        02240000
         EXTRN IEUF7D                   DC EVALUATION                   02260000
         EXTRN IEUF7X                   TEXT GET STATEMENT ROUTINE      02280000
         EXTRN IEUF7N                   TESTRAN ENTRIES                 02300000
         EXTRN DXD                      'DXD' STATEMENT                 02320000
*                                                                       02340000
*                                                                       02360000
*      * EXTRNS FOR F/7 COMMON SUBROUTINES                              02380000
*                                                                       02400000
         EXTRN IEUF7V                   EXPRESSION EVALUATION           02480000
         EXTRN IEUF7G                   GENERATE LITERAL DC RECORDS     02520000
         EXTRN VCON                     'VCON' PROCESSING               02540000
         EXTRN IEUF7C                   PHASE 7 MAIN LINE CONTROL       02580000
         EJECT                                                          02600000
         USING *,SRB                                                    02620000
*   THIS SERIES OF BRANCHES IS USED TO SELECT THE ENTRY POINT OF THE  * 02640000
*   DESIRED I/O SUBROUTINE.                                           * 02660000
*                                                                     * 02680000
         DC    X'FFFF'                  BASE REFERENCE                  02700000
         B     GTP                      GET POINT SUBROUTINE       D2   02720000
         B     GTM                      GET TEXT AND MOVE          D6   02740000
         B     PTX                      PUT TEXT SUBROUTINE        D10  02760000
         B     CLT                      TCLOSE TEXT DATA FILE      D14  02780000
         DS    2H                       PHASE INITIALIZATION       D18  02800000
         B     PHC                      PHASE CLOSE                D22  02820000
         B     WTE                      WRITE ESD                  D26  02840000
         B     RDE                      READ ESD                   D30  02860000
         B     PUTX                     PUTXRF                     D34  02880000
         B     PUTLB                    PUTLBT                     D38  02900000
         DS    2H                       PUTRLD F/8                 D42  02920000
         DS    2H                       GETLAT F/8                 D46  02940000
         DS    2H                       WTERR F/8                  D50  02960000
         DS    2H                       SYSLST F/8                 D54  02980000
         B     SYSO                     SYSOUT                     D58  03000000
         EJECT                                                          03020000
*TITLE-  GETPT...GET POINT ROUTINE FOR F7                             * 03040000
*FUNCTION-  SUBROUTINE POINTS TO NEXT LOGICAL RECORD OF THE TEXT      * 03060000
*    STREAM IN THE INPUT BUFFER.                                      * 03080000
*INPUT-  NONE                                                         * 03100000
*OUTPUT-  SP1 CONTAINS POINTER TO FIRST (OR ONLY) TEXT SEGMENT,       * 03120000
*                  OR 0, IF END OF FILE WAS READ                      * 03140000
*         SP2 CONTAINS POINTER TO SECOND TEXT SEGMENT,                * 03160000
*                  OR 0, IF TEXT RECORD IS UNBROKEN.                  * 03180000
*         CONDITION CODE IS SET TO SP1                                * 03200000
*TABLES/WORK AREAS-                                                   * 03220000
*        ICT...INPUT CONTROL TABLE                                    * 03240000
*        RD1...'NEED NEW DATA' SWITCH                                 * 03260000
*        CS1...'POINTER ADVANCED' SWITCH                              * 03280000
         SPACE 2                                                        03300000
GTP      STM   GR12,GR15,SAVE           SAVE REGS                       03320000
         LM    GR12,GR15,ICT+8          LOAD ICT                        03340000
         CLI   RD1,1                    NEW DATA SWITCH SET TO NO DATA  03360000
         BE    GT5                      IF YES GO TO GT5                03380000
         BH    GTA                      IF SET TO NEED-NEW-DATA  GO GTA 03400000
         LR    GR12,GR14                NEXT PTR TO ICT+8               03420000
         LR    SP1,GR14                                                 03440000
GT1      TM    2(GR12),X'08'            CONTINUATION BIT SET            03460000
         BO    GTB                      IF YES, GO GTB                  03480000
         SR    GR13,GR13                CLEAR SECOND SEG PTR            03500000
         LR    SP2,GR13                                                 03520000
         TM    2(GR12),X'80'            LAST REC BIT SET                03540000
         BZ    GT3                      IF NO, GO GT3                   03560000
         CLI   ICS,0                    ITERATION CONTROL SWITCH SET 0  03580000
         BE    GT4                      IF YES, GO TO GT4               03600000
GT2      L     GR14,ICT+4               ALTERNATE BUFF TO NXPT          03620000
         MVI   RD1,2                    SET FOR NEED-NEW-DATA ON NXT E  03640000
GTX      MVI   CS1,1                    SET ADVANCED PTR SWITCH         03660000
         STM   GR12,GR15,ICT+8          UPDATE ICT                      03680000
         LM    GR12,GR15,SAVE           RESTORE GEN REGS                03700000
         LTR   SP1,SP1                  SET CONDITION CODE OF SP1       03720000
         BR    SRR                      EXIT TO USER                    03740000
GT3      MVC   RLI(2),0(GR12)           MOVE TO HALFWORD BOUNDARY       03760000
         LH    GR14,RLI                                                 03780000
         AR    GR14,GR12                CURRENT PTR+RLI TO NXPT         03800000
         CR    GR14,GR15                HAS NXPT EXCEEDED LWA OF BUFFE  03820000
         BH    GT2                      YES TO GT2                      03840000
         B     GTX                      IF NO, EXIT                     03860000
GT4      MVI   ICS,1                    SET ITER CNT SW TO POST ZERO    03880000
         MVI   RD1,1                    SET ENTR SW TO NO-DATA          03900000
         B     GTX                      EXIT                            03920000
GT5      SR    SP1,SP1                  EOF-NO DATA EXIT                03940000
         B     GTX                      EXIT                            03960000
GTA      CLI   RD1,3                    INITIALIZATION PASS             03980000
         BE    GTC                      YES TO GTC                      04000000
         MVI   RD1,0                    RESET NEED DATA SWITCH          04020000
* READ COMPLETE INTO (ICT+1) CHECK MUST BE INSERTED HERE                04040000
         CKFLG RDECB                                                    04060000
         L     GR4,ICT+4                                                04080000
         CLC   0(4,GR4),EOF             HAS EOF BEEN READ               04100000
         BE    GT10                     IF YES, GO TO GT10              04120000
GT6      L     GR2,ICT                  CURRENT BUFFER                  04140000
         BAL   GR4,TEXTIN               READ DATA FILE                  04160000
         CLI   RD2,1                    ALTERNATE BUFFER EMPTY          04180000
         BE    GT8                      IF YES, GO TO GT8               04200000
         L     GR4,ICT                  ALTERNATE BUFFERS               04220000
         MVC   ICT(4),ICT+4                                             04240000
         ST    GR4,ICT+4                                                04260000
         LR    GR12,GR14                NXPT TO ICT+2                   04280000
         LR    SP1,GR14                                                 04300000
GT7      LH    GR15,RDECB+6             COMPUTE NEW LWA PTR             04320000
         A     GR15,ICT                                                 04340000
         SH    GR15,THREE               LOG LWA IS 3 LT REAL LWA        04360000
         B     GT1                      RETURN FOR NXPT                 04380000
GT8      MVI   RD2,0                    RESET DBLE BUFF SWITCH          04400000
* READ COMPLETE INTO (ICT) CHECK MUST BE INSERTED HERE                  04420000
         CKFLG RDECB                                                    04440000
         L     GR4,ICT                                                  04460000
         CLC   0(4,GR4),EOF             EOF READ                        04480000
         BE    GT10                     IF YES, GO TO GT10              04500000
         L     GR2,ICT+4                READ INTO ALTERNATE BUFF        04520000
         BAL   GR4,TEXTIN               READ DATA FILE                  04540000
         L     GR12,ICT                 CURRENT PTR TO ICT+2            04560000
         LR    SP1,GR12                 POINT TO NEW TEXT               04580000
         B     GT7                      GO COMPUTE LWA PTR              04600000
GT10     SR    SP1,SP1                  SET NO-DATA ENTRANCE SWITCH     04620000
         B     GT4+4                    GO SET 'NO DATA'                04640000
* READ COMPLETE INTO (ICT+1) MUST BE INSERTED HERE AND TAGGED GTB       04660000
GTB      CKFLG RDECB                                                    04680000
GT11     MVI   RD1,2                    SET NEED MORE DATA ENT SW       04700000
         L     GR13,ICT+4               SECOND SEGMENT PTR TO ICT+3     04720000
         LR    SP2,GR13                                                 04740000
         MVC   RLI(2),0(GR13)           MOVE SEC RLI TO HALFWORD BOUND  04760000
         LH    GR14,RLI                                                 04780000
         AR    GR14,GR13                ALT PTR+RLI2 TO NXPT            04800000
         TM    2(GR13),X'80'            SET END-OF-DATA IF              04820000
         BZ    GTX                      LR BIT IS SET IN RECORD         04840000
         B     GT4                      END RECORD SPLIT UP       22158 04870018
GTC      MVI   RD2,1                    INITIALIZATION PASS             04900000
         MVI   RD1,0                    RESET NEED DATA SWITCH          04920000
         B     GT6                      RETURN TO READ DATA             04940000
         EJECT                                                          04960000
*TITLE-  GETXTM...GET TEXT AND MOVE                                   * 04980000
*FUNCTION-  SUBROUTINE TRANSFERS A LOGICAL RECORD FROM THE INPUT TEXT * 05000000
*    STREAM TO AN AREA SPECIFIED BY THE USER.                         * 05020000
*INPUT-  SP1 CONTAINS POINTER TO USER'S WORK AREA                     * 05040000
*OUTPUT: SP1 REMAINS UNCHANGED, (IF A RECORD WAS AVAILABLE            * 05060000
*    OR  SP1 CONTAINS 0, INDICATING END OF FILE HAS BEEN READ         * 05080000
*TABLES/WORK AREAS-                                                   * 05100000
*        ICT...INPUT CONTROL TABLE                                    * 05120000
*        CS1...'POINTER ADVANCED' SWITCH                              * 05140000
*        RD1...'NEED NEW DATA' SWITCH                                 * 05160000
         SPACE 2                                                        05180000
GTM      CLI   CS1,0                    INPUT PTR ADVANCED              05200000
         BE    GTM7                     IF NO, TO GTM7                  05220000
GTM1     STM   GR12,GR15,SAVE           SAVE GEN REGS                   05240000
         LM    GR12,GR15,ICT+8          LOAD ICT                        05260000
         MVI   CS1,0                    RESET GETPT CNTRL SWITCH        05280000
         MVC   RLI(2),0(GR12)           MOVE TO HALFWORD BOUNDARY       05300000
         LH    GR3,RLI                                                  05320000
         LTR   GR13,GR13                SECOND SEGMENT ZERO             05340000
         BE    GTM2                     IF YES, TO GTM2                 05360000
         MVC   RLI2(2),0(GR13)          MOVE SEC RLI TO HALFWORD BOUND  05380000
         LH    GR4,RLI2                                                 05400000
         SH    GR4,THREE                DEC 3 FOR RLI CT                05420000
         STH   GR4,RLI2                                                 05440000
         AR    GR3,GR4                  SUM RLIS                        05460000
GTM2     STH   GR3,RLISUM                                               05480000
         CLI   CS4,1                    DESTINATION OUTPUT BUFFER       05500000
         BE    GTM5                     IF YES, TO GTM5                 05520000
         LR    GR2,SP1                                                  05540000
GTM3     NI    2(GR12),X'77'            RESET CONT AND LAST FLAG        05560000
         LH    GR3,RLI                  FIRST SEG RLI                   05580000
         LR    GR1,GR12                 FIRST SEG PTR                   05600000
         BAL   GR4,MOVE                 MOVE TO (GR2)                   05620000
         LTR   GR13,GR13                SEC SEG ZERO                    05640000
         BZ    GTMX                     IF SO, TO GTMX                  05660000
         LA    GR1,3(GR13)              BYPASS SEC SEG RLI              05680000
         LH    GR3,RLI2                 SEC RLI TO COUNTER              05700000
         BAL   GR4,MOVE                 MOVE SECOND SEGMENT TO (GR2)    05720000
         MVC   0(2,SP1),RLISUM          UPDATE RLI                      05740000
GTMX     STM   GR12,GR15,ICT+8          RESORE ICT                      05760000
         LM    GR12,GR15,SAVE           RESTORE REGS                    05780000
         LTR   SP1,SP1                  SET SP1 CC                      05800000
         BR    SRR                      EXIT                            05820000
GTM5     BAL   GR5,OBM                  LOC ROOM IN OUTPUT BUFFER       05840000
         LR    SP1,GR2                  SET SP1 TO DEST PTR             05860000
         MVI   CS4,0                    RESET PUTEXT SWITCH             05880000
         B     GTM3                     RETURN TO MOVE DATA             05900000
GTM7     ST    SP1,DPT                  SAVE DEST PTR                   05920000
         ST    SRR,RET                  SAVE RETURN POINTER             05940000
         BAL   SRR,GTP                  GET POINTER IN INPUT BUFF       05960000
         L     SRR,RET                                                  05980000
         BCR   8,SRR                    EOF READ RETURN                 06000000
         L     SP1,DPT                  RESTORE DEST PTR                06020000
         B     GTM1                     RETURN TO MOVE                  06040000
         EJECT                                                          06060000
*TITLE-  PUTXT... PUT TEXT                                            * 06080000
*FUNCTION-  SUBROUTINE MOVES A LOGICAL RECORD FROM THE INPUT BUFFERS  * 06100000
*   OR FROM AN AREA SPECIFIED BY THE USER, TO THE OUTPUT BUFFER       * 06120000
*INPUT-  SP1 CONTAINS EITHER A POINTER TO THE USER'S WORK AREA, OR 0, * 06140000
*   INDICATING THE RECORD IS CONTAINED IN AN INPUT BUFFER.            * 06160000
*OUTPUT-  SP1 CONTAINS POINTER TO USER'S WORK AREA (UNCHANGED),       * 06180000
*                  OR POINTER TO RECORD WITHIN OUTPUT BUFFER (IF      * 06200000
*                      ENTRY WAS WITH SP1=0)                          * 06220000
*                  OR 0, IF END OF FILE WAS READ                      * 06240000
*NOTE-                                                                * 06260000
*   USES OBM FOR OUTPUT BUFFER MANAGEMENT                             * 06280000
*   BRANCHES TO GTM IF THE RECORD TO BE MOVED IS CONTAINED IN AN INPUT* 06300000
*        BUFFER.                                                      * 06320000
         SPACE 2                                                        06340000
PTX      LTR   SP1,SP1                  IS RECORD FROM INPUT BUFFER     06360000
         BZ    PT1                      IF YES, TO PT1                  06380000
         MVC   RLI(2),0(SP1)            MOVE RLI TO HALFWORD BOUNDARY   06400000
         LH    GR3,RLI                  BYTE COUNT                      06420000
         BAL   GR5,OBM                  OUTPUT BUFFER MANAGEMENT        06440000
         LR    GR1,SP1                  SOURCE PTR                      06460000
         BAL   GR4,MOVE                 MOVE RECORD                     06480000
         BR    SRR                      EXIT                            06500000
PT1      MVI   CS4,1                    SET PUTXT CONTROL SWITCH        06520000
         B     GTM                      GO TO GTM                       06540000
         EJECT                                                          06560000
*TITLE-  CLSTXT...CLOSE TEXT FILE                                     * 06580000
*FUNCTIONS-                                                           * 06600000
*   'TCLOSE'S INPUT TEXT FILE                                         * 06620000
*   INSERTS END OF FILE SYMBOL INTO OUTPUT TEXT STREAM                * 06640000
*   'TCLOSE'S OUTPUT TEXT FILE                                        * 06660000
*   INTERCHANGES UTILITY FILE DESIGNATORS                             * 06680000
*INPUT-  NONE                                                         * 06700000
*OUTPUT- NONE                                                         * 06720000
*TABLES/WORK AREAS-                                                   * 06740000
*        OCT...OUTPUT CONTROL TABLE                                   * 06760000
*        WDECB...WRITE DATA EVENT CONTROL BLOCK                       * 06780000
*        RDECB...READ  DATA EVENT CONTROL BLOCK                       * 06800000
*NOTE-                                                                * 06820000
*   BRANCHES TO OBM AND TEXTOT                                        * 06840000
         SPACE 2                                                        06860000
CLT      LH    GR3,WDECB+6              BLOCK LENGTH                    06880000
         BAL   GR5,OBM                  OUTPUT BUFFER MANAGEMENT        06900000
         MVC   0(4,GR2),EOF             EMBED AN EOF                    06920000
         L     GR2,OCT                  BUFFER PTR                      06940000
         BAL   GR4,TEXTOT               TEXT OUTPUT SUBROUTINE          06960000
         SPACE 2                                                        06980000
*TCLOSE TEXT FILE---O/S INTERFACE                                       07000000
         SPACE                                                          07020000
TCLOSETX STM   GRZ,GR1,IOSAVE                                           07040000
         LA    GRZ,IOSAVE+20      O/S SAVE AREA                         07060000
         CLI   RDECB+20,X'00'           IS LAST READ CHECKED     A32193 07063020
         BNE   TCL                      YES, THEN BRANCH         A32193 07066020
         MVI   RDECB+20,X'FF'           NO, SET CHECK FLAG       A32193 07069020
         CHECK RDECB                    CHECK                    A32193 07072020
TCL      MVI   WDECB+20,X'FF'           SET CHECK FLAG           A32193 07075020
         CHECK WDECB              CHECK LAST WRITE                      07080000
         LM    0,1,BLKMIN               RELEASE OUTPUT BUFFERS FOR      07120000
      FREEMAIN R,LV=(0),A=(1)           TEMPORARY STORAGE AND F8.       07140000
         MVI   WTBUFSW,X'FF'                                            07160000
         MVC   TCLS+5(3),RDECB+9        PLUG ADDRESS INTO 'CLOSE' CODE  07180000
         MVC   TCLS+9(3),WDECB+9        ALSO PLUG IN OUTPUT DCB ADDR    07200000
TCLS     CLOSE (0,REREAD,0,REREAD),TYPE=T                               07220000
         LM    GRZ,GR1,IOSAVE                                           07240000
         SPACE 2                                                        07260000
         MVI   CS1,0                    SET GLOBAL GETPT SW             07280000
         MVI   RD1,3                    SET NEED-DATA SW                07300000
         L     GR1,WDECB+8              ALTERNATE I/O LOGIC             07320000
         MVC   WDECB+8(4),RDECB+8       CHANGE OUTPUT TO INPUT AND      07340000
         ST    GR1,RDECB+8              INPUT TO OUTPUT                 07360000
         MVC   RDECB+6(2),WDECB+6       UPDATE INPUT BLK LN             07380000
         MVC   OCT+10(2),WDECB+6        RESET BYTE COUNT                07400000
         MVC   OCT+16(4),OCT            NEXT OUTPUT TO FRONT OF BUFFER  07420000
         BR    SRR                      EXIT                            07440000
EOF      DC    4X'7F'                   END OF TEXT FLAG                07460000
IOERR    DS    0H                       SYNAD ROUTINE             18848 07460900
         BALR  FRB,0                                              18848 07461800
         USING *,FRB                                              18848 07462700
         LR    GRB,GR0                  SAVE PARM2 FOR SYNADAF    18848 07463600
         LR    GRA,GR1                  SAVE PARM1 FOR SYNADAF    18848 07464500
         LA    GRC,4                    DENOTE EXIT FROM IEUF7I   18848 07465400
         CLI   RDECB+20,0               TEST 'CHECK' FLAG         18848 07466300
         BNZ   IOERR1                   BR IF CHECKED             18848 07467200
         MVI   RDECB+20,X'FF'           SET SW                    18848 07468100
         CHECK RDECB                    CHECK READ                18848 07469000
IOERR1   CLI   WDECB+20,0               TEST 'CHECK' FLAG         18848 07469900
         BNE   IOERR2                   BR IF CHECKED             18848 07470800
         MVI   WDECB+20,X'FF'           SET SW                    18848 07471700
         CHECK WDECB                    CHECK WRITE               18848 07472600
IOERR2   CLI   WTBUFSW,0                TEST FOR STG RET          18848 07473500
         BNE   IOERR3                   BR IF RETURNED            18848 07474400
         LM    GR0,GR1,BLKMIN           GET SIZE AND ADDRESS      18848 07475300
         FREEMAIN  R,LV=(0),A=(1)       RETURN STG                18848 07476200
IOERR3   XCTL  EP=IEUERR                TRANSFER TO ABORT         18848 07477100
         DROP  FRB                                                18848 07478000
         EJECT                                                          07480000
*TITLE-  OBM...OUTPUT BUFFER MANAGEMENT                               * 07500000
*FUNCTION-  SUBROUTINE OBTAINS OUTPUT BUFFER SPACE THROUGH 'GETMAIN'  * 07520000
*   UPON FIRST  ENTRY FOLLOWING A 'CLOSE' AND DOLES OUT BUFFER SPACE. * 07540000
*   AS ONE BUFFER IS FILLED, IT IS WRITTEN OUT (BY TEXTOT), AND THE   * 07560000
*   BUFFERS ARE ALTERNATED.                                           * 07580000
*INPUT-  GR3 CONTAINS LENGTH OF CURRENT LOGICAL RECORD                * 07600000
*OUTPUT-  GR2 CONTAINS ADDRESS OF NEXT AVAILABLE BUFFER LOCATION      * 07620000
*TABLE USE-  OCT (OUTPUT CONTROL TABLE)                               * 07640000
         SPACE 1                                                        07660000
OBM      STM   GR12,GR14,OBSAVE                                         07680000
         CLI   WTBUFSW,0                IF FIRST ENTRY SINCE CLOSE,     07700000
         BE    OBM3                     OBTAIN OUTPUT BUFFERS BY        07720000
         L     0,BLKMIN                 GETMAIN AND INITIALIZE          07740000
       GETMAIN R,LV=(0)                 THE OUTPUT CONTROL TABLE.       07760000
         ST    1,BLKMIN+4               FOR SUBSEQUENT FREEMAIN         07780000
         ST    1,OCT                    OUTPUT BUFFER 1                 07800000
         ST    1,OCT+16                                                 07820000
         AH    1,WDECB+6                TEXT BLOCKSIZE                  07840000
         ST    1,OCT+4                  OUTPUT BUFFER 2                 07860000
         MVI   WTBUFSW,0                CLEAR FIRST ENTRY SWITCH.       07880000
OBM3     LM    GR12,GR14,OCT+8                                          07900000
         CR    GR3,GR12                 RLI LTE OCT+2                   07920000
         BC    12,OB2                   YES TO OB2                      07940000
         LH    GR12,WDECB+6             BLOCK BYTE COUNT TO GR12        07960000
OB1      OI    2(GR13),X'80'            SET LAST RECORD BIT             07980000
         L     GR2,OCT                  GIVE OUTPUT ADDRESS TO TEXTOT   08000000
         BAL   GR4,TEXTOT               WRITE UTILITY FILE              08020000
         L     GR14,OCT+4               INTERCHANGE BUFFERS             08040000
         MVC   OCT+4(4),OCT                                             08060000
         ST    GR14,OCT                                                 08080000
OB2      SR    GR12,GR3                 DEC BYTE COUNT BY RLI           08100000
         LR    GR13,GR14                NEXT OUTPUT LOCATION            08120000
         AR    GR14,GR3                 ADVANCE NEXT OUT PTR            08140000
         STM   GR12,GR14,OCT+8          PUT AWAY RESULTS                08160000
         LR    GR2,GR13                 CALLER GETS NEXT RECORD POSIT'N 08180000
         LM    GR12,GR14,OBSAVE                                         08200000
         BR    GR5                      EXIT                            08220000
WTBUFSW  DC    X'FF'                    INITIALIZED AT 'FF'             08240000
         EJECT                                                          08260000
* SUBROUTINE TO MOVE ANY SIZE BLOCK FROM (GR1) TO (GR2)                 08280000
MOVE     SH    GR3,MAXCT                NO. OF BYTES GT 256             08300000
         BP    M1                       IF YES, TO M1                   08320000
         LA    GR3,255(GR3)             DESCREASE LITERAL COUNT BY 1    08340000
         EX    GR3,M2                   EXECUTE MVC                     08360000
         LA    GR3,1(GR3)               INC COUNT TO LITERAL COUNT      08380000
         AR    GR1,GR3                  ADVANCE SOURCE POINTER          08400000
         AR    GR2,GR3                  ADVANCE DESTINATION POINTER     08420000
         BR    GR4                      RETURN TO CALLER                08440000
M1       MVC   0(256,GR2),0(GR1)        MOVE 256 BYTES                  08460000
         LA    GR1,256(GR1)             ADVANCE SOURCE PTR BY 256       08480000
         LA    GR2,256(GR2)             ADVANCE DESTINATION PTR BY 256  08500000
         B     MOVE                     RETURN TO MOVE                  08520000
M2       MVC   0(0,GR2),0(GR1)                                          08540000
         EJECT                                                          08560000
*TITLE-  CRDESD...READ EXTERNAL SYMBOL DICTIONARY                     * 08580000
*FUNCTION-  SUBROUTINE 'POINT'S THE OVERFLOW FILE TO THE REQUESTED    * 08600000
*   EXTERNAL SYMBOL DICTIONARY AND READS  THE ESD INTO AN AREA SPEC-  * 08620000
*   IFIED BY THE USER                                                 * 08640000
*INPUT-  SP1 CONTAINS THE 'NOTE'D ADDRESS OF THE REQUESTED ESD        * 08660000
*        SP2 CONTAINS ADDRESS OF USER'S INPUT AREA                    * 08680000
*OUTPUT- NONE                                                         * 08700000
*NOTE-  WRITE POSITIONING SWITCH IS SET TO INDICATE WRITE POSITIONING * 08720000
*       REQUIRED.                                                     * 08740000
*       READING FUNCTION IS PROVIDED BY RDOF SUBROUTINE               * 08760000
         SPACE 1                                                        08780000
RDE      ST    SP1,ESDTAB               BLOCK PTR                       08800000
         ST    SP2,ESDTAB+4             BUFFER PTR                      08820000
         MVI   ESDTAB+13,1              POSITIONING REQUIRED            08840000
         MVI   ESDTAB+14,1              FIRST TIME SW                   08860000
         MVI   ESDTAB+10,1              ENSURE NON-ZERO BLOCK COUNT     08880000
         LA    GR1,ESDTAB               ESD I/O TABLE POINTER           08900000
         BAL   SP2,RDOF                 READ OVERFLOW FILE              08920000
         BR    SRR                      EXIT                            08940000
         SPACE 5                                                        08960000
         EJECT                                                          08980000
*TITLE-  CWRDESD...WRITE EXTERNAL SYMBOL DICTIONARY                   * 09000000
*FUNCTION-  SUBROUTINE WRITES THE EXTERNAL SYMBOL DICTIONARY ONTO THE * 09020000
*   OVERFLOW FILE AND 'NOTE'S IT'S POSITION FOR FUTURE REFERENCE.     * 09040000
*INPUT-  SP1 CONTAINS ADDRESS OF EXTERNAL SYMBOL DICTIONARY.          * 09060000
*OUTPUT-  SP1 CONTAINS THE 'NOTE'ED RECORD POSITION ON THE OVERFLOW   * 09080000
*         FILE                                                        * 09100000
*NOTE-  WRITING FUNCTION IS PROVIDED BY WROF SUBROUTINE               * 09120000
         SPACE 1                                                        09140000
WTE      ST    SP1,ESDTAB+4             ESD BUFFER POINTER              09160000
         LA    GR1,ESDTAB               ESD I/O TABLE                   09180000
         BAL   SP2,WROF                 WRITE OVERFLOW FILE             09200000
         L     SP1,CTONWP(ACT)          BLOCK POINTER                   09220000
         BR    SRR                      EXIT WTE                        09240000
ESDTAB   DC    F'0'                     BLOCK POSITION PTR              09260000
         DC    F'0'                     ESD BUFFER PTR                  09280000
         DC    H'260'                   ESD BLOCK LENGTH                09300000
         DC    H'0'                     BLOCK COUNT                     09320000
         DC    X'03'                    ESD TYPE INDICATOR              09340000
         DC    X'1'                     POSITIONAL SW                   09360000
         DC    X'1'                     FIRST TIME SW                   09380000
*TITLE-  PUTXRF...PUT CROSS-REFERENCE RECORD                          * 09400000
*FUNCTION-  SUBROUTINE PROVIDES AN ADDRESS AT WHICH A CROSS-REFERENCE * 09420000
*   RECORD MAY BE BUILT.  AS THE CROSS-REFERENCE BUFFER IS FILLED,    * 09440000
*   PUTXRF WRITES THE BUFFER ONTO THE OVERFLOW FILE AND 'NOTE'S IT'S  * 09460000
*   POSITION FOR FUTURE REFERENCE.                                    * 09480000
*INPUT-  NONE                                                         * 09500000
*OUTPUT-  SP1 CONTAINS THE ADDRESS AT WHICH THE NEXT RECORD MAY BE    * 09520000
*   BUILT.                                                            * 09540000
         SPACE 1                                                        09560000
PUTX     L     SP1,XRFLRP               NEXT LOGICAL REC POSITION       09580000
         MVI   NULLXRF,0                TURN OFF NULL XRF SWITCH        09600000
         CL    SP1,XRFLBA               PTR EXCEED BUFFER               09620000
         BL    PUTX1                    NO TO PUTX1                     09640000
         LA    GR1,XRFTAB               XRF I/O TABLE PTR               09660000
         BAL   SP2,WROF                 WRITE OVERFLOW FILE             09680000
         L     SP1,XRFTAB+4             BUFFER POINTER                  09700000
         LA    SP1,1(SP1)               FIRST LOGICAL REC               09720000
PUTX1    LR    GR1,SP1                                                  09740000
         LA    GR1,17(GR1)              ADVANCE PTR TO NEXT LOGICAL REC 09760000
         ST    GR1,XRFLRP               SAVE PTR                        09780000
         BR    SRR                      EXIT PUTX                       09800000
XRFTAB   DC    F'0'                     BLOCK POSITION PTR              09820000
         DC    A(XRFBUF)                XRF BUFFER PTR                  09840000
         DC    AL2(L'XRFBUF)            XRF BLOCK SIZE                  09860000
         DC    H'0'                     XRF BLOCK COUNT                 09880000
         DC    X'07'                    XRF TYPE INDICATOR              09900000
         DC    X'0'                     POSITIONING SWITCH              09920000
         DC    X'1'                     FIRST TIME SWITCH               09940000
XRFLRP   DC    A(XRFBUF+1)              XRF LOGICAL RECORD POINTER      09960000
XRFLBA   DC    A(XRFBUF+L'XRFBUF)       XRF LAST BYTE ADDRESS+1         09980000
NULLXRF  DC    X'FF'                    NULL XRF SWITCH                 10000000
*TITLE-  PUTLBT...PUT LITERAL BASE TABLE                              * 10020000
*FUNCTION-  SUBROUTINE PROVIDES AN ADDRESS AT WHICH  LITERAL BASE     * 10040000
*   TABLE RECORD MAY BE BUILT, WRITES THE BUFFER ONTO THE OVERFLOW    * 10060000
*   FILE AS REQUIRED, AND 'NOTE'S THE POSITION OF THE RECORD WRITTEN. * 10080000
*INPUT-  NONE                                                         * 10100000
*OUTPUT-  SP1 CONTAINS ADDRESS OF NEXT AVAILABLE LOCATION IN LITERAL  * 10120000
*   BASE TABLE BUFFER                                                 * 10140000
*NOTE-  WRITING FUNCTION IS PROVIDED BY WROF SUBROUTINE.              * 10160000
PUTLB    L     SP1,LBPTR                NEXT LOGICAL RECORD PTR         10180000
         CL    SP1,LBLWA                PTR EXCEED BUFFER               10200000
         BL    PUTLB1                   NO TO PUTLB1                    10220000
         LA    GR1,LBTAB                LBT I/O TABLE PTR               10240000
         BAL   SP2,WROF                 WRITE OVERFLOW FILE             10260000
         L     SP1,LBTAB+4              BUFFER PTR                      10280000
         LA    SP1,1(SP1)               FIRST LOGICAL REC PTR           10300000
PUTLB1   LR    GR1,SP1                                                  10320000
         LA    GR1,13(GR1)              ADVANCE TO NEXT LOGICAL REC     10340000
         ST    GR1,LBPTR                SAVE PTR                        10360000
         BR    SRR                      EXIT PUTLB                      10380000
LBTAB    DC    F'0'                     BLOCK POSITION PTR              10400000
         DC    F'0'                     LBT BUFFER PTR                  10420000
         DC    H'79'                    LBT BLOCK LENGTH                10440000
         DC    H'0'                     LBT BLOCK COUNT                 10460000
         DC    X'04'                    LBT TYPE INDICATOR              10480000
         DC    X'0'                     POSITIONING SWITCH              10500000
         DC    X'1'                     FIRST TIME SWITCH               10520000
         EJECT                                                          10540000
*TITLE-  SYSO...SYSTEM OUTPUT                                         * 10560000
*FUNCTION-  SUBROUTINE OUTPUTS 80-CHARACTER LOGICAL RECORDS TO SYSGO  * 10580000
*   AND/OR SYSPUNCH DATA SETS.                                          10600000
*INPUT-  SP1 CONTAINS ADDRESS OF 81-BYTE LOGICAL RECORD...THE FIRST   * 10620000
*   BYTE CONTAINS AN INTERNAL CONTROL CHARACTER.                      * 10640000
*   CTPCH1(ACT) CONTAINS PUNCH/LOAD OPTION BITS                       * 10660000
*OUTPUT- NONE                                                         * 10680000
         SPACE 1                                                        10700000
SYSO     LA    SP1,1(SP1)               BYPASS CTL CHAR.                10720000
         LA    13,IOSAVE                PROVIDE SAVE AREA FOR 'PUT'     10740000
         TM    CTPCHI(ACT),X'80'        PUNCH OPTION BIT                10760000
         BZ    PCHI                     SKIP IF NO DECK WANTED          10780000
         L     1,PCHDCB(ACT)            GET SYSPUNCH DCB ADDRESS        10800000
         PUT   (1),(SP1)                OUTPUT TO SYSPUNCH              10820000
PCHI     TM    CTPCHI(ACT),X'40'        GO OPTION BIT                   10840000
         BCR   8,SRR                    RETURN IF NO LOAD               10860000
         L     1,GODCB(ACT)             GET SYSGO DCB ADDRESS           10880000
         PUT   (1),(SP1)                OUTPUT TO SYSGO                 10900000
         BR    SRR                      RETURN TO CALLER                10920000
         EJECT                                                          10940000
*TITLE-  PHCLS...PHASE CLOSE                                          * 10960000
*FUNCTION-  SUBROUTINE CLOSES  SYSUT1 AND SYSUT2 DATA SETS.           * 10980000
*   END OF FILE LABELS ARE INSERTED INTO XREF AND LITERAL BASE TABLE  * 11000000
*   STREAMS AND THE RESPECTIVE BUFFERS ARE WRITTEN ONTO THE OVERFLOW  * 11020000
*   FILE. THE FOLLOWING PARAMETERS ARE INSERTED INTO THE I/O PORTION  * 11040000
*   OF THE ASSEMBLER CONTROL TABLE:                                   * 11060000
*       CTXUIN..DATA SET DESIGNATOR FOR CURRENT INPUT TEXT            * 11080000
*       CTOUT2..DATA SET DESIGNATOR FOR ALTERNATE OVERFLOW FILE       * 11100000
*       CTRLBT..POINTER TO FIRST LITERAL BASE TABLE BLOCK ON SYSUT3   * 11120000
*       CTCLBT..COUNT OF LITERAL BASE TABLE BLOCKS                    * 11140000
*       CTRXRF..POINTER TO FIRST XREF TABLE BLOCK ON SYSUT3           * 11160000
*       CTCXRF..COUNT OF XREF TABLE BLOCKS                            * 11180000
*       CTDNWP..POINTER TO NEXT SEQUENTIAL FILE POSITION ON SYSUT3    * 11200000
*EXIT- 'XCTL' TO IEUFI (INTERLUDE)                                    * 11220000
         SPACE 1                                                        11240000
PHC      BAL   SRR,CLT                  TCLOSE TEXT                     11260000
         CLI   NULLXRF,0                CLOSE XRF FILE UNLESS           11280000
         BNE   PHC11                    NULL.                           11300000
         BAL   SRR,PUTX                 PUT XRF                         11320000
         MVC   0(4,SP1),EOF             EMBED EOF                       11340000
         LA    GR1,XRFTAB               XRF I/O TABLE ADDRESS           11360000
         BAL   SP2,WROF                 WRITE OVERFLOW FILE             11380000
PHC11    MVC   CTXUIN(4,ACT),RDECB+8    UPDATE CURRENT TEXT-IN FILE     11400000
         MVC   CTOUT2(4,ACT),WDECB+8    UPDATE CURRENT ALT OVF DESIG    11420000
         BAL   SRR,PUTLB                PUT LBT                         11440000
         MVC   0(4,SP1),EOF             EMBED EOF                       11460000
         CLI   LBTAB+14,1               LBT BLOCK WRITTEN               11480000
         BE    PHC1                     NO TO PHC1                      11500000
         LA    GR1,LBTAB                LBT I/O TABLE ADDRESS           11520000
         BAL   SP2,WROF                 WRITE OVERFLOW FILE             11540000
PHC1     MVC   CTCLBT(2,ACT),LBTAB+10   LBT BLOCK COUNT                 11560000
         MVC   CTRLBT(4,ACT),LBTAB      1ST LBT BLOCK PTR               11580000
         MVC   CTCXRF(2,ACT),XRFTAB+10  XRF BLOCK COUNT                 11600000
         MVC   CTRXRF(4,ACT),XRFTAB     1ST XRF BLOCK PTR               11620000
         LA    13,IOSAVE                                                11640000
         XCTL  EP=IEUFI                 TRANSFER CTL TO INTERLUDE PHASE 11660000
         EJECT                                                          11680000
*   TEXTCK...CHECK READ COMPLETE AND SET 'CHECKED' FLAG               * 11700000
*   CALLING SEQUENCE IS GENERATED BY 'CKFLG' MACRO                    * 11720000
*        BAL   GR4,TEXTCK                                             * 11740000
*                                                                     * 11760000
*   UTILIZED BY GETPT SUBROUTINE                                      * 11780000
         SPACE 1                                                        11800000
TEXTCK   STM   GRZ,GR1,IOSAVE                                           11820000
         LA    GRZ,IOSAVE+20      REG 13 O/S SAVE AREA                  11840000
         MVI   RDECB+20,X'FF'           SET 'CHECK' FLAG          18848 11850000
         CHECK RDECB                                                    11860000
         LM    GRZ,GR1,IOSAVE                                           11900000
         BR    GR4                RETURN                                11920000
*                                                                       11940000
         EJECT                                                          11960000
*   TEXT I/O INTERFACE WITH OS/360                                    * 11980000
*ENTRY POINTS-                                                        * 12000000
*   TEXTOT...TEXT OUTPUT                                              * 12020000
*   TEXTIN...TEXT INPUT                                               * 12040000
*INPUT-  GR2 CONTAINS ADDRESS OF OUTPUT (OR INPUT) BUFFER             * 12060000
*FUNCTION-  SUBROUTINE 'CHECK'S OUTPUT (OR INPUT) OPERATION IF        * 12080000
*           'CHECK' HAS NOT  BEEN DONE, THEN  WRITES (OR READS) TEXT. * 12100000
*TABLE USAGE-                                                         * 12120000
*   RDECB...'READ' DATA EVENT CONTROL BLOCK                           * 12140000
*   WDECB...'WRITE' DATA EVENT CONTROL BLOCK                          * 12160000
*NOTE-  CONTENTS OF RDECB AND WDECB ARE OUTLINED IN REMARKS.  TEXTIN  * 12180000
*   AND TEXTOT DCB ADDRESSES ARE INSERTED DURING IEUF7 INITIALIZATION,* 12200000
*   VIA CTOUT2(ACT) AND CTXUIN(ACT). THE ADDRESSES MAY BE ALTERNATED  * 12220000
*   BY TCLOSETX (TCLOSE TEXT FILE). PHCLS RETURNS THE ADDRESSES TO    * 12240000
*   COMMON AREA VIA THE ASSEMBLER CONTROL TABLE.                      * 12260000
         SPACE 1                                                        12280000
TEXTOT   LA    GR1,WDECB                SET UP FOR OUTPUT               12300000
         B     TEXTIN+4                 AND JUMP PAST SETTING INPUT     12320000
TEXTIN   LA    GR1,RDECB                SET UP FOR INPUT                12340000
         STM   GRZ,GR1,IOSAVE           KEEP REGS FOR RETURN            12360000
         LA    GRZ,IOSAVE+20            LET OTHERS HAVE REST OF SAVE A. 12380000
         CLI   20(GR1),0          CHECK IF 'CHECKED' FLAG APPENDED      12400000
         BNE   TEXT1              TO DECB NOT SET.                      12420000
         MVI   20(GR1),X'FF'            SET 'CHECK' FLAG          18848 12430000
         CHECK (1)                      CHECK PREVIOUS READ/WRITE       12440000
TEXT1    L     GR1,IOSAVE+16            IO TABLE                        12460000
         MVI   20(GR1),0          RESET 'CHECKED' FLAG                  12480000
         ST    GR2,12(GR1)                                              12500000
         L       14,8(GR1)                                              12520000
         L       15,48(14)              READ/WRITE SUBROUTINE ADDRESS   12540000
         BALR    14,15                  EXIT TO READ/WRITE              12560000
         LM    GRZ,GR1,IOSAVE                                           12580000
         BR    GR4                      EXIT TEXT IO                    12600000
RDECB    DC    F'0'                     READ EVENT CONTROL BLOCK        12620000
         DC    X'0'                     LENGTH INDICATOR                12640000
         DC    X'80'                    IO ACTION INDICATOR             12660000
         DC    H'0'                     BLOCK LENGTH                    12680000
         DC    A(0)                     TEXTIN DCB ADDRESS              12700000
         DC    F'0'                     ADDRESS OF INPUT AREA           12720000
         DC    F'0'                     PTR TO STATUS INDICATORS        12740000
         DC    X'FF'              'CHECKED' FLAG                        12760000
WDECB    DC    F'0'                     WRITE EVENT CONTROL BLOCK       12780000
         DC    X'0'                     LENGTH INDICATOR                12800000
         DC    X'20'                    IO ACTION INDICATOR             12820000
         DC    H'829'                                                   12840000
         DC    A(0)                     TEXTOUT DCB ADDRESS             12860000
         DC    F'0'                     OUTPUT AREA                     12880000
         DC    F'0'                     PTR TO STATUS INDICATORS        12900000
         DC    X'FF'              'CHECKED' FLAG                        12920000
         EJECT                                                          12940000
*TITLE-  WROF...WRITE OVERFLOW FILE                                   * 12960000
*FUNCTION-  SUBROUTINE PERFORMS 'POINT', 'WRITE', 'CHECK' AND 'NOTE'  * 12980000
*   FUNCTIONS REQUIRED BY CWRESD, PUTXRF, PUTLBT AND PHCLS SUBROUTINES* 13000000
*INPUT-  GR1 CONTAINS ADDRESS OF OUTPUT TABLE                         * 13020000
*OUTPUT-  BLOCK COUNT AND BLOCK POSITION POINTER STORED IN OUTPUT     * 13040000
*   TABLE, BLOCK POSITION POINTER AND TRACK BALANCE STORED VIA ACT    * 13060000
         SPACE 1                                                        13080000
WROF     STM   GRZ,GR2,IOSAVE                                           13100000
         LA    GRZ,IOSAVE+24            LET OTHERS USE REST OF SAVE A.  13120000
         CLI   WPSW,0                   POSITIONING REQUIRED            13140000
         BE    WRF2                     NO TO WRF2                      13160000
         MVI   WPSW,0                   CLEAR POSITIONING SW            13180000
         LA    GR1,CTONWP(ACT)          NEXT WRITE PTR ADDRESS          13200000
         L       15,0(GR1)                                              13220000
         AH    15,=H'1'                 INC FOR WRITE                   13240000
         ST      15,0(GR1)                                              13260000
         LR    GR0,GR1                  PTR ADDRESS                     13280000
         L     GR1,OFDECB+8             DCB PTR                         13300000
         POINT (1),(0)                                                  13320000
WRF2     L     GR1,IOSAVE+16            IO TABLE ADDRESS                13340000
         MVC   OFDECB+12(4),4(GR1)      OUTPUT BUFFER PTR TO DECB       13360000
         MVC   OFDECB+6(2),8(GR1)       BUFFER LENGTH TO DECB           13380000
         WRITE OFDECB,SF,MF=E                                           13400000
         CHECK OFDECB                                                   13420000
         L     GR1,OFDECB+8             UT3 DCB                         13440000
         NOTE  (1)                                                      13460000
         L     GR2,IOSAVE+16            IO TABLE PTR                    13480000
         LH      14,10(GR2)             BLOCK COUNT                     13500000
         LA      14,1(14)               INCREMENT FOR LAST WRITE        13520000
         STH     14,10(GR2)             SAVE BLOCK COUNT                13540000
         CLI   14(GR2),0                FIRST TIME SW SET               13560000
         BE    WRF3                     NO TO WRF3                      13580000
         MVI   14(GR2),0                CLEAR FIRST TIME SW             13600000
         ST    GR1,0(GR2)               SAVE BLOCK POSITION PTR         13620000
WRF3     ST    GR1,CTONWP(ACT)          SAVE BLK PTR                    13640000
         STH   GR0,CTONWP+4(ACT)        SAVE TRACK BALANCE              13660000
         LM    GRZ,GR2,IOSAVE                                           13680000
         BR    SP2                      EXIT WROF                       13700000
*                                                                       13720000
*                                                                       13740000
OFDECB   DC    F'0'                     OVERFLOW FILE I/O DECB          13760000
         DC    X'0000'                  OP AND TYPE FIELD               13780000
         DC    H'0'                     LENGTH FIELD                    13800000
         DC    A(0)                     UT1 DCB ADDRESS                 13820000
         DC    F'0'                     BUFFER ADDRESS                  13840000
         DC    F'0'                     STATUS INDICATOR POINTERS       13860000
         EJECT                                                          13880000
*TITLE-  RDOF...READ OVERFLOW FILE                                    * 13900000
*FUNCTION-  SUBROUTINE PROVIDES 'POINT', 'READ', 'CHECK' AND 'NOTE'   * 13920000
*   FUNCTIONS REQUIRED BY CRDESD SUBROUTINE                           * 13940000
*INPUT-  GR1 CONTAINS INPUT TABLE ADDRESS                             * 13960000
*OUTPUT-  UPDATED BLOCK COUNT AND BLOCK POSITION VALUES IN INPUT TABLE* 13980000
*NOTE-  WRITING ONTO THE OVERFLOW FILE IS PROVIDED BY WROF SUBROUTINE * 14000000
         SPACE 2                                                        14020000
RDOF     LH    GR2,10(GR1)              BLOCK COUNT                     14040000
         LTR   GR2,GR2                  ZERO                            14060000
         BCR   8,SP2                    YES EXIT                        14080000
         MVI   WPSW,1                   SET TO 'WRITE POS'NG REQUIRED'  14100000
         STM   GRZ,GR1,IOSAVE                                           14120000
         LA    GRZ,IOSAVE+20            PROTECT FRONT OF SAVE AREA      14140000
         MVC   OFDECB+12(4),4(GR1)      BUFFER ADDRESS TO DECB          14160000
         MVC   OFDECB+6(2),8(GR1)       BUFFER LENGTH TO DECB           14180000
         CLI   13(GR1),0                FILE REQUIRE POSITIONING        14200000
         BE    RDF1                     NO TO RDF1                      14220000
         MVI   13(GR1),0                CLEAR POSITIONING SWITCH        14240000
         LR    GR0,GR1                  BLOCK POSITION FOR 'POINT'      14260000
         L     GR1,OFDECB+8             DCB ADDRESS FOR 'POINT'         14280000
         POINT (1),(0)                                                  14300000
         L     GR1,IOSAVE+16            IO TABLE PTR                    14320000
         CLI   14(GR1),1                FIRST TIME SW SET               14340000
         BE    RDF2                     YES TO RDF2                     14360000
         READ  OFDECB,SF,MF=E           SKIP UT3 BLOCK                  14380000
         CHECK OFDECB                                                   14400000
RDF1     L     GR2,OFDECB+8             DCB ADDRESS                     14420000
         READ  OFDECB,SF,MF=E           READ UT3 BLOCK                  14440000
         CHECK OFDECB                                                   14460000
         L     GR1,OFDECB+12            BUFFER ADDRESS                  14480000
         L       14,IOSAVE+16           IO TABLE ADDRESS                14500000
         CLC   12(1,14),0(GR1)          CORRECT TYPE                    14520000
         BNE   RDF1+4                   NO,READ NEXT BLOCK              14540000
         LH    GR1,10(14)               BLOCK COUNT                     14560000
         BCTR  GR1,0                    DECREMENT COUNT                 14580000
         STH   GR1,10(14)               RESTORE BLOCK COUNT             14600000
         LR    GR1,GR2                  DCB PTR                         14620000
         NOTE  (1)                                                      14640000
         L     GR2,IOSAVE+16            IO TAB ADDRESS                  14660000
         ST    GR1,0(GR2)               STORE BLOCK POSITION            14680000
         LM    GRZ,GR1,IOSAVE                                           14700000
         LTR   GR2,GR1                  SET NORMAL READ FLAG            14720000
         BR    SP2                      EXIT RDOF                       14740000
RDF2     MVI   14(GR1),0                CLEAR FIRST TIME SW             14760000
         B     RDF1                     RETURN TO READ BLOCK            14780000
         SPACE 3                                                        14800000
*        I/O ROUTINE COMMUNICATIONS FLAGS                             * 14820000
ICS      DC    X'00'               GETPT ITERATION CONTROL SWITCH       14840000
*                                  '00'=TEXT INPUT BUFFER NOT PRIMED    14860000
CS1      DC    X'00'               INPUT POINTER ADVANCED SWITCH        14880000
*                                  '00'=TEXT INPUT POINTER NOT READY    14900000
CS4      DC    X'00'               TEXT DESTINATION SWITCH              14920000
*                                  '01'=RECORD GOES TO OUTPUT BUFFER    14940000
RD1      DC    X'01'               NEW DATA SWITCH                      14960000
*                                  '00'=RECORD IN CURRENT BUFFER        14980000
*                                  '01'=END OF DATA                     15000000
*                                  '02'=NEED MORE DATA (USE OTHER BUFF) 15020000
*                                  '03'=INITIALIZATION PASS             15040000
RD2      DC    X'00'               ALTERNATE BUFFER INDICATOR           15060000
*                                  '01'=ALTERNATE BUFFER IS EMPTY       15080000
WPSW     DC    X'1'                '00'=OVERFLOW FILE NOT 'POINTED'     15100000
*                                  '01'=OVERFLOW FILE PROPERLY POSIT'ND 15120000
THREE    DC    H'3'                                                     15140000
RLISUM   DC    H'0'                RECORD LENGTH..SUM, IF 'BROKEN' INPT 15160000
MAXCT    DC    H'256'              MAX COUNT ALLOWED IN AN 'MVC'        15180000
LBPTR    DC    F'0'                     LBT BUFFER POINTER              15200000
LBLWA    DC    F'0'                     LBT LBA PTR                     15220000
         SPACE 10                                                       15240000
*STORAGE ALLOCATION PARAMETERS.                                         15260000
         SPACE                                                          15280000
BLKMIN   DC    A(2*1738),A(0)           MIN BLKSIZE,OUTPUT BUFFERS FBA  15300000
STGREQ   DC    A(2048+233+1000,511*1024) MIN,MAX TABLE SIZES.           15320000
STGOT    DC    2A(0)                    FBA,LENGTH OF ACQUIRED TABLE.   15340000
  SPACE 5                                                               15360000
         LTORG                                                          15380000
         DROP  SRB                                                      15400000
         DS    0D                                                       15420000
         EJECT                                                          15440000
*TITLE-  IEUF7...F7 INITIALIZATION                                    * 15460000
*FUNCTION-                                                            * 15480000
*   OBTAIN AND ALLOCATE MAIN STORAGE FOR TEXT I/O BUFFERS, SYMBOL     * 15500000
*   TABLE, ETC.                                                       * 15520000
*   INITIALIZE AND OPEN SYSPUNCH AND SYSGO                            * 15540000
*   INITIALIZE RDECB, WDECB AND OFDECB TABLES                         * 15560000
*   MODIFY SYSPRINT DCB TO ACCOMODATE OPTIONS PERMITTED BY ASSEMBLER  * 15580000
*   MOVE EXTRN/ADCON POINTERS,DEFINED IN F7CT2 AND F7CT3 TABLES, INTO * 15600000
*   ASSEMBLER CONTROL TABLE                                             15620000
*ENTRY-  TO IEUF7, VIA 'LINK' FROM RTA                                * 15640000
*INPUT-  GEN. REG. ACT CONTAINS ADDRESS OF ASSEMBLER CONTROL TABLE    * 15660000
*OUTPUT-  GEN. REG. 'ACT' UNCHANGED FROM VALUE AT ENTRY               * 15680000
*        GEN. REG. CRB CONTAINS ADDRESS OF IEUF7C (F7 MAIN-LINE CON-  * 15700000
*        TROL)                                                        * 15720000
*EXIT-  BRANCH TO IEUF7C                                              * 15740000
         SPACE 3                                                        15760000
*BUFFERS WHICH OVERLAP VOLATILE INITIALIZATION LOGIC                    15780000
         SPACE                                                          15800000
XRFBUF   DS    XL(1+17*102)             XRF OUTPUT BUFFER               15820000
ICT      DS    6F                       INPUT CONTROL TABLE             15840000
*       ICT...  ADDRESS OF CURRENT INPUT BUFFER                       * 15860000
*       ICT+4...ADDRESS OF ALTERNATE INPUT BUFFER                     * 15880000
*       ICT+8...ADDRESS OF FIRST INPUT TEXT SEGMENT                   * 15900000
*       ICT+16..ADDRESS OF SECOND TEXT SEGMENT, ZERO IF UNBROKEN TEXT * 15920000
*       ICT+20..ADDRESS OF NEXT LOGICAL RECORD                        * 15940000
*       ICT+24..ADDRESS OF END OF CURRENT BUFFER                      * 15960000
         SPACE 1                                                        15980000
OCT      DS    5F                       OUTPUT CONTROL TABLE            16000000
*   OCT...ADDRESS OF OUTPUT BUFFER 1                                  * 16020000
*   OCT+4...ADDRESS OF ALTERNATE OUTPUT BUFFER                        * 16040000
*   OCT+8...COUNT OF BYTES REMAINING IN BUFFER                        * 16060000
*   OCT+12...ADDRESS OF CURRENT LOGICAL RECORD                        * 16080000
*   OCT+16...NEXT AVAILABLE BUFFER ADDRESS                            * 16100000
         SPACE 1                                                        16120000
RLI      DS    1H                  RECORD LENGTH..ALIGNED FOR CALC'LTNS 16140000
RLI2     DS    1H                  RLI FOR SECOND HALF OF 'BROKEN' INPT 16160000
RET      DS    1F                  RETURN REGISTER STORAGE              16180000
DPT      DS    1F                  GETXTM DESTINATION STORAGE           16200000
SAVE     DS    4F                  SUBROUTINE REGISTER SAVE AREA        16220000
*                                  GETPT AND GETXTM SAVE HERE           16240000
OBSAVE   DS    3F                  OBM ROUTINE REG. SAVE AREA           16260000
IOSAVE   DS    25F                 'F' I/O AND O.S. ROUTINES SAVE HERE  16280000
         ORG   XRFBUF             OVERLAP..CODE OK UNTIL BUFFERS FILL   16300000
         DC    X'07'                    XRF TYPE CODE.                  16320000
         SPACE 10                                                       16340000
IEUF7    ST    14,CTMRSRTN(ACT)                                         16360000
         BALR  SRB,0                                                    16740000
         USING *,SRB                                                    16760000
         L     SRB,=A(TEXTIO)                                           16780000
         USING TEXTIO,SRB                                               16800000
         SPACE 3                                                        16820000
*INSERT EXIT LIST ADDRESS INTO PUNCH AND GO DCB'S.                      16840000
         USING IHADCB,1                 POINT ASSEMBLER TO NAMES...     16860000
         L     1,PCHDCB(ACT)            AND REGISTER TO PUNCH DCB       16880000
         MVC   PGDDNAM(8),DCBDDNAM      MOVE IN PUNCH DDNAME      17315 16890000
         MVC   DCBEXLST+1(3),=AL3(PGOEXLST)  ADDR. TO PUNCH DCB         16900000
         MVC   DCBSYNAD+1(3),=AL3(IOERR) PASS SYNAD EXIT ADDR    A63333 16910021
         L     1,GODCB(ACT)             POINT REG. TO GO DCB            16920000
         MVC   DCBEXLST+1(3),=AL3(PGOEXLST)  ADDR  TO GO DCB            16940000
         MVC   PGDDNAM+8(8),DCBDDNAM    MOVE IN GO DDNAME         17315 16950000
         MVC   DCBSYNAD+1(3),=AL3(IOERR) PASS SYNAD EXIT ADDR    A63333 16950421
         L     GR1,CTOUT1(,ACT)         PASS SYNAD EXIT ADDR TO   18848 16951000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)  DCB OF SYSUT3,          18848 16952000
         L     GR1,CTOUT2(,ACT)           DCB OF                  18848 16954000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)    SYSUT1, AND           18848 16955000
         L     GR1,CTXUIN(,ACT)           DCB OF                  18848 16956000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)    SYSUT2.               18848 16958000
         DROP  1                        NO MORE NEED FOR DCB NAMES      16960000
         SPACE 3                                                        16980000
* OPEN SYSPCH AND SYSGO IF EITHER WAS REQUESTED BY EXEC PARAMETERS      17000000
         TM    CTPCHI(ACT),X'C0'        BITS 0 AND 1 OF OPTION BYTE     17020000
         BNO   NOPORGO                  NO BOTH, GO TEST AGAIN          17040000
         MVC   PGOPEN+5(3),PCHDCB+1(ACT) /ALTERS 'OPEN' EXPANSION/      17060000
         MVC   PGOPEN+9(3),GODCB+1(ACT)  PUT GO DCB ADDR. IN PARAM LIST 17080000
PGOPEN   OPEN  (0,(OUTPUT),0,(OUTPUT))  /BARE, FILLED IN ABOVE /        17100000
         B     NOGO                     GO START RETRIEVING POINTERS    17120000
NOPORGO  EQU   *                                                        17140000
         TM    CTPCHI(ACT),X'80'        SEE IF PUNCH OPTION REQUESTED   17160000
         BZ    NOPUNCH                  NO, DONT OPEN PUNCH DCB         17180000
         MVC   POPEN+5(3),PCHDCB+1(ACT) YES, SUPPLY PUNCH DCB ADDRESS   17200000
POPEN    OPEN  (0,(OUTPUT))             /FILLED IN ABOVE/               17220000
NOPUNCH  EQU   *                                                        17240000
         TM    CTPCHI(ACT),X'40'        SEE IF 'GO' OPTION REQUESTED    17260000
         BZ    NOGO                     NO, DONT OPEN GO DCB            17280000
         MVC   GOPEN+5(3),GODCB+1(ACT)  SUPPLY DCB ADDRESS              17300000
GOPEN    OPEN  (0,(OUTPUT))             /ALTERED BY PREVIOUS CODE/      17320000
         USING IHADCB,1                 SET UP DCB USING           9741 17322013
NOGO     NI    CTDDERR(ACT),X'3F'       SET DD S OK                9741 17324013
         TM    CTPCHI(ACT),X'80'        DID WE OPEN THE PUNCH      9741 17326013
         BZ    NOGO1                    NO, DONT CHECK FOR OPEN OK 9741 17328013
         L     1,PCHDCB(0,ACT)          YES, GET DCB ADDRESS       9741 17330013
         TM    DCBOFLGS,X'10'           WAS IT OPENED OK           9741 17332013
         BO    NOGO1                    YES, CONTINUE              9741 17334013
         NI    CTPCHI(ACT),X'7F'        NO, SET OPTION NODECK      9741 17336013
         OI    CTDDERR(ACT),X'40'       SET TO FLAG ERROR 112      9741 17338013
NOGO1    TM    CTPCHI(ACT),X'40'        DID WE OPEN GO             9741 17340013
         BZ    NOGO2                    NO, DONT CHECK FOR OPEN OK 9741 17342013
         L     1,GODCB(0,ACT)           YES, GET DCB ADDRESS       9741 17344013
         TM    DCBOFLGS,X'10'           WAS IT OPENED OK           9741 17346013
         BO    NOGO2                    YES, CONTINUE              9741 17348013
         NI    CTPCHI(ACT),X'BF'        NO, SET OPTION NOLOAD      9741 17350013
         OI    CTDDERR(ACT),X'80'       SET TO FLAG ERROR 111      9741 17352013
         DROP  1                                                   9741 17354013
NOGO2    EQU   *                                                   9741 17356013
         SPACE 3                                                        17360000
         MVC   RDECB+08,CTXUIN(ACT)     RETRIEVE TEXT INPUT DCB PTR     17380000
         MVC   WDECB+08,CTOUT2(ACT)     RETRIEVE TEXT OUTPUT DCB PTR    17400000
         MVC  OFDECB+08,CTOUT1(ACT)     RETRIEVE OVERFLOW FILE DCB PTR  17420000
         EJECT                                                          17440000
*READ JOB FILE CONTROL BLOCK, CONSTRUCTED FROM INFORMATION SUPPLIED     17460000
*FROM DD STATEMENT, AND MODIFY THE SYSPRINT DCB TO ACCOMODATE           17480000
*VARIOUS OPTIONS PERMITTED BY THE ASSEMBLER AND QSAM.                   17500000
         SPACE                                                          17520000
         TM    CTPCHI(ACT),X'10'        SEE IF LIST OPTION IS ON        17540000
         BZ    NOPRINT                  NO, DONT BOTHER...SKIP          17560000
         L     SP1,LSTDCB(ACT)          SP1 POINTS TO SYSPRINT DCB.     17580000
         USING IHADCB,SP1               ADDRESS DCB THROUGH DCBD DSECT. 17600000
         DEVTYPE  DCBDDNAM,PRDEVT       OBTAIN DEVICE CHAR        10836 17606014
         LTR   15,15                    WAS DD NAME FOUND          9741 17612013
         BZ    PRI0                     YES, CONTINUE              9741 17618013
         L     GRA,CVTPTR               POINT TO CVT               I000 17619020
         USING CVTTABLE,GRA                                        I000 17620020
         TM    CVTDCB,BIT12             IS THIS PCP OR MFT         I000 17621020
         DROP  GRA                                                 I000 17622020
         BZ    NOPRINT                  NO, MVT                    I000 17623020
         MVC   WTOPRT+32(L8),DCBDDNAM  MOVE IN DDNAME OF SYSOUT    I000 17626020
WTOPRT   WTO   'IEU997I OPEN FAILED FOR ********, NOLIST OPTION USED', X17629020
               ROUTCDE=(2,11),DESC=7                               I000 17632021
         NI    CTPCHI(ACT),X'EF'        SET NOLIST OPTION ON       9741 17636013
         B     NOPRINT                  DONT BOTHER WITH THE REST  9741 17642013
PRI0     GETMAIN  R,LV=176              OBTAIN JFCB BUFFER         9741 17648013
         LR    SP2,1                    SP2 POINTS TO JFCB.             17660000
         ST    1,JFCBPTR                                                17680000
         MVI   JFCBPTR,X'87'                                            17700000
         MVC   DCBEXLST+1(3),=AL3(JFCBPTR)  SPECIFY BUFFER FOR RDJFCB.  17720000
         MVC   RDJ+5(3),LSTDCB+1(ACT)                                   17740000
RDJ      RDJFCB (0)                     READ SYSPRINT JOB FILE CTL BLK. 17760000
         USING JFCBMOD,SP2              ADDRESS JFCB THROUGH DSECT.     17780000
         MVI   DCBRECFM,FM              RECFM=FM IS DEFAULT       M3432 17785020
         CLI   PRDEVT+2,TEST4           YES,IS UNIT RECORD SPEC    I000 17790020
         BE    LSTX5                    YES,SET BLKSIZE=121       M3432 17798020
         NI    JFCRECFM,BT              CHECK IF B OR T SPECIN DD M3432 17806020
         OC    DCBRECFM,JFCRECFM                                  M3432 17814020
         MVC   DCBBLKSI,JFCBLKSI        BLKSIZE IN DCB            M3432 17822020
         LH    GR2,DCBLRECL                                        I000 17830020
         CH    GR2,JFCBLKSI             RCD LENGTH GT BLOCKSIZE    I000 17840020
         BNH   LSTX1                                              M3432 17850020
         MVC   DCBBLKSI,DCBLRECL        SET BLKSIZE=LRECL (121)   M3432 17860020
LSTX1    TM    DCBRECFM,T               TRACK OVERFLOW SPEC?      M3432 17870020
         BO    LSTX3                                              M3432 17880020
         CLC   DCBBLKSI,PRDEVT+6        IS BLKSIZE GT TRKSIZE?    M3432 17890020
         BNH   LSTX3                    NO,CONTINUE               M3432 17900020
         MVC   DCBBLKSI,PRDEVT+6        YES,CHANGE BLKSIZE        M3432 17910020
LSTX3    CH    GR2,DCBBLKSI             BLKSIZE GT LRECL         A33012 17920021
         BL    LSTX6                    YES,CHECK BLKSIZE        A33012 17922021
         TM    DCBRECFM,B               BLKSIZE SPEC ANYWAY      A33012 17924021
         BO    LSTX6                    YES,CHECK BLKSIZE         M3432 17930020
LSTX5    MVC   DCBBLKSI,DCBLRECL        SET BLKSIZE=LRECL (121)   M3432 17940020
         B     LSTX8                    CHECK BUFNO               M3432 17950020
LSTX6    LH    GRB,DCBBLKSI             FORCE SPEC BLOCKSIZE      M3432 17960020
         LR    GRD,GRB                  TO EVEN MULTIPLE OF 121    I000 17970020
         SR    GRA,GRA                                             I000 17980020
         DR    GRA,GR2                                             I000 17990020
         SR    GRD,GRA                  PLACE CORRECTED            I000 18000020
         STH   GRD,DCBBLKSI             BLKSIZE IN DCB             I000 18010020
         OI    DCBRECFM,B               SET RECFM=B              A33012 18012021
LSTX8    CLI   JFCBUFNO,NOBUF           IS BUFNO SPEC              I000 18020020
         BNE   LSTX9A                   YES, OK                    I000 18030020
         MVI   DCBBUFNO,DEFTBUF         SET DEFAULT BUFNO=2        I000 18040020
LSTX9    MVC   DCBEXLST+1(L3),=AL3(0)   CLEAR EXIT LST ADDR        I000 18050020
         B     PRI2                                                I000 18060020
LSTX9A   MVC   DCBBUFNO,JFCBUFNO        SET DCB BUFFER ADDRESS     I000 18130020
         B     LSTX9                                               I000 18140020
         SPACE 2                                                   I000 18150020
* DCB RECORD FORMATS                                               I000 18160020
         SPACE 1                                                   I000 18170020
BT       EQU   X'30'                    DCB RECORD FORMATS        M3432 18180020
FM       EQU   X'82'                                              M3432 18190020
B        EQU   X'10'                                              M3432 18200020
T        EQU   X'20'                                              M3432 18210020
         SPACE 1                                                   I000 18220020
         SPACE 5                                                        18260000
*COMPUTE ADDITIONAL STORAGE REQUIREMENTS FOR QSAM.                      18280000
*REFERENCE---'STORAGE ESTIMATES'---C28-6551-1.                          18300000
         SPACE 3                                                        18320000
*TEMPORARY REGISTR ASSIGNMENTS.                                         18340000
         SPACE                                                          18360000
STBUF    EQU   GRA                      STORAGE/BUFFER ACCUMULATOR.     18380000
STCON    EQU   GRB                      CONSTANT STORAGE ACCUMULATOR.   18400000
TPTR     EQU   GRC                      TABLE POINTER 1--DEVICE TYPE.   18420000
TPTR2    EQU   GRD                      TABLE POINTER 2--CHAINED SCHED. 18440000
         SPACE 1                                                        18460000
PRI2     LH    STBUF,DCBBLKSI           STORAGE/BUFFER=BLKSIZE+...      18480000
         LA    STCON,144+120            CONSTANT STG.=B1+B4+...         18500000
         SR    TPTR2,TPTR2              GET READY                       18520000
         TM    JFCOPTCD,X'20'           TEST FOR OPTCD=C(CHAINED SCD)   18540000
         BZ    PRI01                    NO, GO CHECK FOR UNIT RECORD    18560000
         LA    TPTR2,4                  SET CHAINED SCHED POINTER       18580000
PRI01    LA    TPTR,URTAB               POINT TO UNIT RECORD TABLE21327 18600018
         CLI   PRDEVT+2,X'08'           LOOK FOR UNIT RECORD(PRTR)21327 18620018
         BE    PR13                     YES, BYPASS DISK & TAPE CK21327 18640018
PRI02    CLI   PRDEVT+2,X'80'           LOOK FOR MAG TAPE               18660000
         BNE   PRI03                    NO, TESD DIRECT ACCESS          18680000
         LA    TPTR,MTTAB               POINT TO MAG TAPE TABLE         18700000
PRI03    CLI   PRDEVT+2,X'20'           DIRECT ACCESS DEVICE            18720000
         BNE   PR13                     NO, SKIP DA TESTS               18740000
         LA    TPTR,DATAB               POINT TO DIRECT ACCESS TABLE    18760000
         TM    JFCRECFM,X'20'           TEST RECFM=T(TRACK OVERFLOW).   18780000
         BZ    PRI05                    NO, GO TEST OPTCD               18800000
         LA    STCON,60(STCON)          +B2(TRACK OVERFLOW FACTOR)+...  18820000
         LH    0,DCBBLKSI                                               18840000
PRI04    LA    STBUF,48(STBUF)          +A2(OPTION A.) +...             18860000
         S     0,PRDEVT+4               (TRACK SIZE)                    18880000
         BH    PRI04                                                    18900000
PRI05    TM    JFCOPTCD,X'80'          TEST OPTCD =W(WRITE VALIDITY CK) 18920000
         BZ    PR13                     NO, DONT INCLUDE A2             18940000
         LA    STBUF,16(STBUF)          +A2(OPTION B.)+...              18960000
PR13     DS    0H                                                       18980000
         AH    STCON,0(TPTR,TPTR2)      A2(CONST)+B2(MAX)+B3(MAX).      19000000
         AH    STBUF,2(TPTR,TPTR2)      A2(PER BUFFER).                 19020000
      FREEMAIN R,LV=176,A=(SP2)         RELEASE JFCB BUFFER.            19040000
         SR    1,1                      TOTAL STORAGE=                  19060000
         IC    1,DCBBUFNO               (STORAGE/BUFFER)*BUFNO          19080000
         MR    0,STBUF                  +CONSTANT STORAGE.              19100000
         AR    1,STCON                                                  19120000
         SPACE 5                                                        19140000
*DETERMINE BY WHAT AMOUNT,IF ANY, PRINT BUFFER REQUIREMENTS EXCEED      19160000
*SPACE NORMALLY AVAILABLE AT F8 TIME.                                   19180000
         SPACE                                                          19200000
         S     1,BLKMIN      OUTPUT BUFFERS,RELEASED AFTER F7.          19220000
         LTR   GR1,GR1                  CHECK IF                   I000 19240020
         BNP   PR13A                    SPACE ENOUGH,NO OVERFLOW   I000 19260020
         ST    1,PRBUFOVF                                               19300000
NOPRINT  EQU   *                                                        19320000
MFTSYST  EQU   X'20'                   FLAG BIT FOR MFT IN CVT   200002 19326020
MFTMAINT EQU   1024                    MFT MAINTENANCEAREA       A52811 19332021
         SPACE 5                                                        19340000
*COMPUTE MAIN STORAGE REQUIREMENTS AND ISSUE GETMAIN.                   19360000
*TEXT BLOCKSIZE IS THE GREATER OF THE TWO VALUES--PASSED FROM MACRO     19380000
*GENERATOR IN CTXLEN(ACT), OR AN INTERNAL MINIMUM(1738).                19400000
*MINIMUM SYMBOL/ESD/LITERAL TABLE SIZE IS 02K(K=1024).                  19420000
         SPACE                                                          19440000
PR13A    LH    GR2,CTXLEN(ACT)          FIND TEXT BLOCK SIZE            19460000
         STH   GR2,RDECB+6              PUT IN DECB                     19480000
         SLL   GR2,1                    DOUBLE BLOCK                    19500000
         L     GR1,BLKMIN               MINIMUM BLOCK FACTOR            19520000
         CR    GR2,GR1                  GT MIN                          19540000
         BC    12,F71                   NO TO F71                       19560000
         ST    GR2,BLKMIN               USE NEW MIN                     19580000
         LR    GR1,GR2                                                  19600000
F71      SLL   GR1,1                    SPACE FOR 4 TEXT BUFFERS.       19620000
         A     GR1,PRBUFOVF             EXTRA STG. FOR PRINT BUFFERS.   19640000
         A     GR1,STGREQ               ADD ADDITIONAL MIN REQ          19660000
         ST    GR1,STGREQ               TOTAL MINIMUM STORAGE REQUIRED  19680000
       GETMAIN VU,LA=STGREQ,A=STGOT     GRAB ALL AVAILABLE STORAGE.     19700000
         SPACE 5                                                        19720000
*RELEASE SPACE FOR OUTPUT BUFFERS, WHICH WILL BE RECLAIMED IN OUTPUT    19740000
*BUFFER MANAGEMENT(OBM)JUST BEFORE NEEDED.  THE OUTPUT BUFFERS ARE      19760000
*RELEASED AT THE END OF EACH F7 PASS TO PROVIDE SPACE FOR TEMPORARY     19780000
*STORAGE(1500 BYTES) USED BY CLOSE TYPE=T, OR FOR THE ESD TABLES        19800000
*GENERATED BY F INTERLUDE,ETC.                                          19820000
         SPACE                                                          19840000
         L     GRC,BLKMIN               OUTPUT BUFFER SPACE.            19860000
         A     GRC,PRBUFOVF             EXTRA STG. FOR PRINT BUFFERS.   19880000
         LA    GRC,1024(GRC)            DONATE 1K TO OS           M2017 19885021
         L     GRA,CVTPTR               POINT TO CVT              M2017 19890018
         USING CVTTABLE,GRA                                       M2017 19895018
         TM    CVTDCB,BIT12             IS THIS PCP OR MFT         I000 19900020
         BNZ   A1                       YES,MFT OR PCP           A31005 19905020
         LA    GRC,ONEK(GRC)            DONATE 1K MORE IF MVT    A31005 19910020
A1       TM    CVTDCB,BIT2              IS THIS MFT              A31005 19915020
         DROP  GRA                                               A31005 19920020
         BZ    A2                                                A31005 19925020
         LA    GRC,THREEH(GRC)          YES DONATE 300 EXTRA     A31005 19930020
A2       LA    GRC,SEVEN(GRC)           ADJUST RELEASE AMOUNT TO A31005 19935020
         N     GRC,=F'-8'               DOUBLE-WORD BOUNDARY.           19940000
         LM    GRA,GRB,STGOT                                            19960000
      FREEMAIN R,LV=(GRC),A=(GRA)                                       19980000
         AR    GRA,GRC                  NEW FBA OF GOTTEN MAIN          20000000
         SR    GRB,GRC                  NEW LENGTH                      20020000
         STM   GRA,GRB,STGOT            BACK INTO TABLE                 20040000
         SPACE 4                                                        20060000
*ALLOCATE BUFFERS COMMON TO F7,FI,F8.(GETMAIN ACQUIRED)                 20080000
*        INSERT POINTERS INTO ASSEMBLER CONTROL TABLE                 * 20100000
         SPACE                                                          20120000
         L     GR1,STGOT                GETMAIN STORAGE PTR             20140000
         L     GR2,BLKMIN               MIN BLK FACTOR                  20160000
         SRL   GR2,1                    HALVE, TO GET ONE BUFF LEN      20180000
         STH   GR2,WDECB+6              OUTPUT BUFFER LENGTH            20200000
         ST    GR2,OCT+8                INITIALIZE BYTES REMNG IN BUFF  20220000
         STH   GR2,CTXLEN(ACT)          TEXT BLOCKSIZE FOR F8.          20240000
         ST    GR1,ICT                  INPUT BUFFER 1                  20260000
         ST    GR1,CTXIO1(ACT)          I-O BUFFER 1 IN ACT             20280000
         AR    GR1,GR2                  STEP PAST ONE BUFFER            20300000
         ST    GR1,ICT+4                INPUT BUFFER 2                  20320000
         ST    GR1,CTXIO2(ACT)          I-O BUFFER 2 IN ACT             20340000
         AR    GR1,GR2                  STEP PAST SECOND BUFFER         20360000
         ST    GR1,CTERRP(ACT)          ERROR BUFFER PTR                20380000
         LA    GR1,55(GR1)              55-BYTE ERROR BUFFER            20400000
         ST    GR1,CTLBTP(ACT)          LBT BUFFER PTR                  20420000
         ST    GR1,LBTAB+4              LBT PTR                         20440000
         MVI   0(GR1),4                 LBT TYPE CODE                   20460000
         LA    GR1,1(GR1)                                               20480000
         ST    GR1,LBPTR                LBT LOGICAL RECORD PTR          20500000
         LA    GR1,78(GR1)                                              20520000
         ST    GR1,LBLWA                LBT LBA                         20540000
         LA    GR1,3(GR1)         FORCE WORD BOUND                      20560000
         N     GR1,=F'-4'                                               20580000
         ST    GR1,CTESRP(ACT)          ESD SEGMENT RESIDENCE TABLE PTR 20600000
         ST    GR1,CTESRB(ACT)          WILL LATER GET ESD SEG RES BASE 20620000
         MVI   0(GR1),X'00'            ZERO THE ESD SEGMENT      A28234 20626019
         MVC   1(95,GR1),0(GR1)        RESIDENCE TABLE           A28234 20632019
         LA    GR1,96(GR1)              ROOM FOR ESD SEG RES TABLE      20640000
         L     GRA,CVTPTR                                        200002 20642020
         USING CVTTABLE,GRA                                      200002 20644020
         TM    CVTDCB,MFTSYST          IS THIS MFT               200002 20646020
         DROP  GRA                                               200002 20648020
         BZ    *+8                                               200002 20650020
* THE FOLLOWING SPACE IS SET ASIDE FOR A MFT MAINTENANCEAREA.    200002 20652020
* THE SYMBOL TABLE IS DIMINISHED BY THESE 1024 BYTES. AREA       A52811 20654021
* FOR MVT IS NOT NEEDED BECAUSE OF THE 2K LOADMODULE SYSTEM.     200002 20656020
MAINT1   LA    GR1,MFTMAINT(GR1)                                 200002 20658020
         ST    GR1,CTSYMP(ACT)          SYMBOL TABLE PTR                20660000
         L     GR1,STGOT                FIND FBA AGAIN                  20680000
         A     GR1,STGOT+4              GO TO END OF 'GOT' SPACE        20700000
         BCTR  GR1,0                    LBA OF ST                       20720000
         ST    GR1,CTESDP(ACT)          ESD BUFFER PTR                  20740000
         ST    GR1,CTESDB(ACT)          ESD BASE ADDRESS                20760000
         ST    GR1,CESIOB(ACT)          ESD I-O AREA BASE ADDRESS       20780000
         L     SP2,CTESRP(ACT)          FIND WHERE TO PUT ESD SEG RES.. 20800000
         ST    GR1,0(SP2)               BASE, AND PUT IT THERE          20820000
         MVI   0(SP2),1                                                 20840000
         MVI   WPSW,0                   RESET WROF POSITIONING SWITCH.  20860000
         MVI   RD1,3                    GTP SWITCH TO ENTRY STATE.      20880000
         SPACE 4                                                        20900000
* MOVE EXTRN/ADCON POINTERS TO CONTROL TABLE                            20920000
*                                                                       20940000
         MVC   CT2(CT2C*4,ACT),F7CT2   FUNCTIONAL ROUTINES              20960000
         MVC   CTXTIO(L4,ACT),F7CT3     COMMON SUBROUTINES         I000 20970020
         MVC   CEEVAL(L4,ACT),F7CT3-CT3+CEEVAL                     I000 20980020
         MVC   CDCGET(L8,ACT),F7CT3-CT3+CDCGET                     I000 20990020
*                                                                       21000000
* SET SYMTAB PRIME DIVISOR AND INITIAL FREE AREA POINTER, CLEAR HASHES  21020000
*                                                                       21040000
         L     GR1,CESIOB(ACT)          END OF SYMTAB                   21060000
         S     GR1,CTSYMP(ACT)          -START OF SYMTAB                21080000
         SH    GR1,CPRIME(ACT)          -(MIN ESD+LIT HASH)             21100000
         SR    GR0,GR0                  CLEAR EVEN REG                  21120000
         LH    GR2,CPRIME+2(ACT)        DIV BY OPTIMUM NO. BYTES/THREAD 21140000
         DR    GR0,GR2                  GIVE PRIME DIVISOR              21160000
         ST    GR1,CPRIME(ACT)          PRIME DIVISOR                   21180000
         MH    GR1,CFREEP(ACT)          *LEN. OF EACH POINTER           21200000
         AH    GR1,CFREEP+2(ACT)        +LIT HASH                       21220000
         ST    GR1,CFREEP(ACT)          FREE AREA POINTER               21240000
*                                                                       21260000
         L     GR2,CTSYMP(ACT)          START OF SYMB TABLE             21280000
         AR    GR1,GR2                  PLUS LENGTH OF HASH TABLE       21300000
         MVI   0(GR2),0                 MAKE A ZERO BYTE                21320000
SET01    MVC   1(256,GR2),0(GR2)        AND MAKE MORE ZEROS             21340000
         LA    GR2,255(GR2)             STEP CLEARING POINTER           21360000
         CLR   GR1,GR2                  SEE IF HASH TABLE CLEARED       21380000
         BH    SET01                    NO, GO CLEAR ANOTHER 256 BYTES  21400000
*                                                                       21420000
         L     CRB,=A(IEUF7C)           PASS CONTROL TO AC7MLC          21440000
         BR    CRB                      AND TEXT PROCESSING WILL BEGIN  21460000
         SPACE 5                                                        21480000
*PUNCH AND GO DCB EXIT ROUTINE                                          21500000
PGOXRTN  EQU   *                                                        21520000
         ST    14,PGXRTN                SAVE EXIT.                      21540000
         LR    SP1,1                    DCB ADDR. WILL BE IN REG 1      21560000
         USING IHADCB,SP1               GIVE DCB PATTERN TO ASSMBLR     21580000
         LA    1,PGDDNAM                SET FOR PUNCH             17315 21586000
         ST    SP1,PGDEVT               SAVE DCB ADDR             17315 21592000
         CLC   PGDEVT+1(3),PCHDCB+1(ACT)     IS IT THE PUNCH DCB  17315 21598000
         BE    PGI0A                    YES, SKIP                 17315 21604000
         LA    1,PGDDNAM+8              NO, SET FOR GO            17315 21610000
PGI0A    DEVTYPE  (1),PGDEVT           RETRIEVE DEVICE CHAR       17315 21616000
         LTR   15,15                    WAS DD CARD FOUND         17315 21622000
         BNE   PGI11                    NO, SKIP SKIP EVERYTHING  17315 21628000
         NI    DCBRECFM,X'30'           KEEP ONLY TRACK O'FLO, BLOCKED  21640000
         OI    DCBRECFM,X'80'           FORCE RECFM = F(BT)       22211 21660018
         CLI   PGDEVT+2,X'08'           LOOK FOR UNIT RECORD DEVICE     21680000
         BNE   PGOX1                    BLOCKING NOT ALLOWED FOR...     21700000
         MVC   DCBBLKSI,DCBLRECL        UNIT RECORD OUTPUT.             21720000
PGOX1    TM    DCBRECFM,X'20'           UNLESS RECFM=7 IS SPECIFIED     21740000
         BO    PGOX2                    BLOCKSIZE MAY NOT EXCEED...     21760000
         CLC   DCBBLKSI,PGDEVT+6        DEVICE TRACK SIZE.              21780000
         BNH   PGOX2                    OK, GO CHECK LOG. REC LEN       21800000
         MVC   DCBBLKSI,PGDEVT+6                                        21820000
PGOX2    CLC   DCBLRECL,DCBBLKSI        LOG REC MUST NOT BE GT BLOCKSIZ 21840000
         BNH   PGOX3                    NOT GT, GO SEE ABOUT LT         21860000
         MVC   DCBBLKSI,DCBLRECL                                        21880000
PGOX3    BNL   PGI1                     IF ONE LOG REC/BLOCK GO CHK BUF 21900000
         LH    1,DCBBLKSI               FORCE SPECIFIED BLOCKSIZE TO    21920000
         LR    GRD,1                    EVEN MULTIPLE OF 80.            21940000
         SR    0,0                                                      21960000
         LA    GR2,80                                                   21980000
         DR    0,GR2                                                    22000000
         SR    GRD,0                                                    22020000
         STH   GRD,DCBBLKSI                                             22040000
         OI    DCBRECFM,X'10'           SET RECFM=B.                    22060000
PGI1     EQU   *                                                        22080000
         CLI   DCBBUFNO,1               IF BUFNO IS NOT SPECIFIED,      22100000
         BNL   PGI11                    IT IS SET TO 3 FOR UNIT         22120000
         MVI   DCBBUFNO,1               RECORD OUTPUT, 1 FOR OTHER      22140000
         CLI   PGDEVT+2,X'08'           DEVICES.                        22160000
         BNE   PGI11                    NOT UNIT RECORD, LEAVE AT 1     22180000
         MVI   DCBBUFNO,3                                               22200000
PGI11    MVC   DCBEXLST+1(3),=AL3(0)    CLEAR EXIT LIST POINTER         22220000
         L     14,PGXRTN                RETRIEVE EXIT                   22240000
         BR    14                       AND GO THERE                    22260000
         SPACE 10                                                       22280000
PGDDNAM  DS    4F                       PUNCH/GO DDNAME           17315 22300000
PGDEVT   DC    0F'0',X'30002001',F'3625' DEVTYPE OUTPUT--2311 SHOWN     22320000
PGXRTN   DC    F'0'                     RETURN ADDRESS FROM DCB EXIT    22340000
SYSPRINT DC    CL8'SYSPRINT'                                            22360000
PGOEXLST DC    0F'0',X'85',AL3(PGOXRTN) EXIT LIST                       22380000
PRBUFOVF DC    F'0'                     EXCESS PRINT BUFFER SPACE.      22400000
PRDEVT   DC    0F'0',X'30002001',F'3625' DEVTYPE OUTPUT--2311 SHOWN     22420000
JFCBPTR  DC    F'0'                     JFCB POINTER(EXIT LIST)         22440000
         LTORG                                                          22460000
         DS    0H                                                       22480000
         EJECT                                                          22500000
*TABLES OF STORAGE REQUIREMENTS FOR VARIOUS POSSIBLE CONFIGURATIONS.    22520000
*REFERENCE---'STORAGE ESTIMATES'---GC28-6551-8.                  A28249 22540019
         SPACE 5                                                        22560000
*        UNIT RECORD(PRINTER)                                           22580000
         SPACE                                                          22600000
URTAB    DC    AL2(96+152+96)     A2+B2+B3 NOT CHAINED CONST STG A28249 22620019
         DC    AL2(56)            A2        NOT CHAINED  PER BUFFER STG 22640000
         DC    AL2(144+216+1428)  A2+B2+B3 CHAINED SCH CONST STG A28249 22660019
         DC    AL2(56)            A2        CHAINED SCH  PER BUFFER STG 22680000
         SPACE 2                                                        22700000
*        MAGNETIC TAPE                                                  22720000
         SPACE 1                                                        22740000
MTTAB    DC    AL2(96+96+0)       A2+B2+B3 NOT CHAINED CONST STG A28249 22760019
         DC    AL2(48)            A2        NOT CHAINED  PER BUFFER STG 22780000
         DC    AL2(144+240+1428)  A2+B2+B3 CHAINED SCH CONST STG A28249 22800019
         DC    AL2(48)            A2        CHAINED SCH  PER BUFFER STG 22820000
         SPACE 2                                                        22840000
*        DIRECT ACCESS                                                  22860000
         SPACE                                                          22880000
DATAB    DC    AL2(112+544+0)     A2+B2+B3 NOT CHAINED CONST STG A28249 22900019
         DC    AL2(88)            A2        NOT CHAINED  PER BUFFER STG 22920000
         DC    AL2(192+680+1428)  A2+B2+B3 CHAINED SCH CONST STG A28249 22940019
         DC    AL2(56)            A2        CHAINED SCH  PER BUFFER STG 22960000
         EJECT                                                          22980000
*... ADCON DEFINITION FOR PHASE F7...THESE CONSTANTS ARE MOVED INTO   * 23000000
*    THE ASSEMBLER CONTROL TABLE DURING INITIALIZATION PORTION OF     * 23020000
*    IEUF7I.                                                          * 23040000
*    CBRNDA, CCOM, CCSECT, ETC. ARE EQUATED (IN FDIMEN DECK, SEE LIST-* 23060000
*    ING IN IEURTA) TO DISPLACEMENT OF ADCONS RELATIVE TO ADDRESS OF  * 23080000
*    ASSEMBLER CONTROL TABLE                                          * 23100000
         SPACE                                                          23120000
******** F7CT2 - FUNCTIONAL ROUTINE BASE/ENTRY ADDRESSES ************** 23140000
*                                                                       23160000
F7CT2    DS    0F                                                       23180000
*                                                                       23200000
         ORG   F7CT2-CT2+CBRNDA    CBRNDA EQU CT2+00 IN FDIMEN          23220000
         DC    A(IEUF7E)                                                23240000
         ORG   F7CT2-CT2+CCOM                                           23260000
         DC    A(COM)                                                   23280000
         ORG   F7CT2-CT2+CCSECT                                         23300000
         DC    A(CSECT)                                                 23320000
         ORG   F7CT2-CT2+CDSECT                                         23340000
         DC    A(DSECT)                                                 23360000
         ORG   F7CT2-CT2+CENTRY                                         23380000
         DC    A(ENTRY)                                                 23400000
         ORG   F7CT2-CT2+CENTRS                                         23420000
         DC    A(ENTRYS)                                                23440000
         ORG   F7CT2-CT2+CESWBK                                         23460000
         DC    A(ESWBKR)                                                23480000
         ORG   F7CT2-CT2+CEXTRN                                         23500000
         DC    A(EXTRN)                                                 23520000
         ORG   F7CT2-CT2+CEXTRS                                         23540000
         DC    A(EXTRNS)                                                23560000
         ORG   F7CT2-CT2+CORG                                           23580000
         DC    A(ORG)                                                   23600000
         ORG   F7CT2-CT2+CQUIT                                          23620000
         DC    A(QUIT)                                                  23640000
         ORG   F7CT2-CT2+CSTART                                         23660000
         DC    A(START)                                                 23680000
         ORG   F7CT2-CT2+CUPC                                           23700000
         DC    A(UPC)                                                   23720000
         ORG   F7CT2-CT2+CDCVAL                                         23740000
         DC    A(IEUF7D)                                                23760000
         ORG   F7CT2-CT2+CLTVAL                                         23780000
         DC    A(0)                                                     23800000
         ORG   F7CT2-CT2+CTXGET                                         23820000
         DC    A(IEUF7X)                                                23840000
         ORG   F7CT2-CT2+CTESTR                                         23860000
         DC    A(IEUF7N)                                                23880000
         ORG   F7CT2-CT2+CDXD                                           23900000
         DC    A(DXD)                                                   23920000
*                                                                       23940000
         ORG   F7CT2+CT2C*4                                             23960000
         EJECT                                                          23980000
******** F7CT3 - COMMON SUBROUTINE BASE/ENTRY ADDRESSES *************** 24000000
*                                                                       24020000
F7CT3    DS    0F                                                       24040000
*                                                                       24060000
         ORG   F7CT3-CT3+CTXTIO                                         24080000
         DC    A(TEXTIO)                                                24100000
         ORG   F7CT3-CT3+CEEVAL                                         24200000
         DC    A(IEUF7V)                                                24220000
         ORG   F7CT3-CT3+CDCGET                                         24280000
         DC    A(IEUF7G)                                                24300000
         ORG   F7CT3-CT3+CVCON                                          24320000
         DC    A(VCON)                                                  24340000
*                                                                       24400000
         ORG   F7CT3+CT3C*4                                             24420000
         ORG   ,                                                        24440000
MAINT2   DS    20F                                               200002 24443020
         ORG   *+SIZEPH8-SIZEPH7+32         MAKE F7 32 BYTES LONGERI000X24446020
                                        THAN PHASE F8              I000 24452020
         SPACE 10                                                       24460000
*DSECTS FOR DCB AND JFCB.                                               24480000
         SPACE                                                          24500000
         PRINT NOGEN                                                    24520000
         DCBD  DSORG=QS                                                 24540000
JFCBMOD  DSECT ,                        JFCB MODEL DSECT                24560000
         ORG   JFCBMOD+88                                               24580000
JFCBUFNO DS    X                                                        24600000
         ORG   JFCBMOD+100                                              24620000
JFCRECFM DS    X                                                        24640000
JFCOPTCD DS    X                                                        24660000
JFCBLKSI DS    H                                                        24680000
*  DSECT FOR CONTROL VECTOR TABLE                                       24685018
CVTTABLE DSECT                                                          24690018
         CVT                                                            24695018
         SPACE                                                          24700000
         END   IEUF7                                                    24720000
