F7N      TITLE 'TSTRAN - F/7 TESTRAN ROUTINE '                          00020000
         ISEQ  73,80                                                    00040000
IEUF7N   START                                                          00060000
*          RELEASE  19  DELETIONS                                       00062019
*                                                                190001 00064019
*          RELEASE  20  DELETIONS                                       00066019
* 124500                                                         200004 00067020
*          RELEASE  21  DELETIONS                                       00068019
* C 124500                                                      A39577  00068421
*          RELEASE  22  DELETIONS                                       00070019
*          RELEASE  23  DELETIONS                                       00072019
*          RELEASE  24  DELETIONS                                       00074019
*          RELEASE  25  DELETIONS                                       00076019
TSTRAN   EQU   IEUF7N                                                   00080000
         SPACE                                                          00100000
         PRINT DATA,NOGEN                                               00120000
         FDIMEN                                                         00140000
         SPACE 2                                                        00160000
*TITLE 'IEUF7N  ',    TESTRAN                                         * 00180000
*STATUS CHANGE LEVEL 002                                                00200019
*FUNCTION/OPERATION-                                                  * 00220000
*   WHEN THE TESTRAN OPTION IS USED, IEUF7C TRANSFERS CONTROL HERE.   * 00240000
*   THIS ROUTINE PRODUCES CARD ON SYSPUNCH AND/OR SYSGO DATA SETS.    * 00260000
*   THESE CARDS ARE TO BE USED IN SUBSEQUENT EXECUTION OF THE OBJECT  * 00280000
*   DECK WHEN EXECUTED IN THE TESTRAN. THIS DECK IS ESSENTIALLY AS    * 00300000
*   STORAGE MRP OF THE PROGRAM.                                       * 00320000
*ENTRY POINT- IEUF7N                                                  * 00340000
*   CALLED BY IEUF7C VIA                                              * 00360000
*        L     FRB,CTESTR(ACT)          GET ENTRY POINT               * 00380000
*        BALR  CRR,ACT                  CALL IEUF7N                   * 00400000
*INPUT- NONE                                                          * 00420000
*OUTPUT-                                                              * 00440000
*   TESTRAN 'SYM' CARDS ARE PUT OUT ON SYSPUNCH AND/OR SYSGO. THE     * 00460000
*   FORMAT OF THE TESTRAN 'SYM' CARD IS-                              * 00480000
*       COLUMN      CONTENTS                                          * 00500000
*         1         T29 PUNCH                                         * 00520000
*         2-4       'SYM'                                             * 00540000
*         5-10      BLANK                                             * 00560000
*        11-12      NUMBER OF BYTES OF TEXT                           * 00580000
*        13-16      BLANK                                             * 00600000
*        17-72      VARIABLE FIELD                                    * 00620000
*        73-80      BLANK                                             * 00640000
*   THE GENERAL FORMAT IN ORDER OF AN INDIVIDUAL ITEM IS-             * 00660000
*      LENGTH(BYTES)  CONTENTS                                        * 00680000
*         1    ORGINIZATIONAL BYTE                                    * 00700000
*         3    ADDRESS-DISP FROM BASE OF CONTROL SECTION              * 00720000
*        0-8   SYMBOLIC NAME                                          * 00740000
*         1    DATA TYPE                                              * 00760000
*         1    LENGTH                                                 * 00780000
*         3    MULTIPLICITY                                           * 00800000
*         2    SCALE                                                  * 00820000
*EXTERNAL ROUTINES-                                                   * 00840000
*   SYSOUT- USED TO PUT OUT THE TESTRAN 'SYM' CARD. THIS ROUTINE IS IN* 00860000
*           IEUF7I AND IS CALLED AS FOLLOWS-                          * 00880000
*                        LA   SP1,TEBFR      LOAD ADDRESS OF CRD IMAGE* 00900000
*                        L    SRB,CTXTIO(ACT)  BASE OF I/O ROUTINE    * 00920000
*                        BAL  SRR,SYSOUT(SRB)  CALL SYSOUT            * 00940000
*EXITS- NORMAL                                                        * 00960000
*   RETURNS TO CALLING ROUTINE VIA                                    * 00980000
*        BR    CRR                      RETURN                        * 01000000
*     - ERROR-- NONE                                                  * 01020000
*TABLES/WORKAREAS-                                                    * 01040000
*        NAME       FUNCTION                                          * 01060000
*        SAVMWD     SAVE AREA                                         * 01080000
*        TTN        OUTPUT CARD IMAGE BUFFER                          * 01100000
*        TBLHEX     DECIMAL TO HEX TRANSLATE TABLE                    * 01120000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 01140000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 01160000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 01180000
         SPACE 3                                                        01200000
GR8      EQU   SRB                                                      01220000
GR9      EQU   SRR                                                      01240000
         SPACE                                                          01260000
         USING *,FRB                                                    01280000
         EJECT                                                          01300000
TESYM    STM   GRA,GRD,SAVMWD           SAVE REGISTERS                  01320000
         TM    CTPH7C(ACT),X'02'        IS PHASE COMPLETE               01340000
         BO    WRILST                   YES                             01360000
         LA    PTR,WKAREA               INITIALIZE WORK AREA POINTER    01380000
         MVI   FOPN,X'00'                                               01400000
TSTALN   L     GRA,CTEXTP(ACT)          SET POINTER TO TEXT RECORD      01420000
         L     GRB,CTXABP(ACT)          SET POINTER TO WORK BUCKETS     01440000
         MVC   LOCCTR+1(3),TXLOC(GRB)                                   01460000
         XC    REMSV(4),REMSV           CLEAR REMAINDER SAVE AREA       01480000
         MVI   BLDATA,0                                                 01500000
         MVI   STPFLG,0                                                 01520000
         TM    TXTO(GRA),X'40'          TEST FOR MACHINE OP ENTRY       01540000
         BO    OPALN                    BRANCH IF BITS ON               01560000
         CLI   TXHEX(GRA),X'26'         CHECK INSTRUCTION TYPE FOR A DC 01580000
         BE    CALNDC                   BRANCH IF EQUAL TO CHECK ALIGN  01600000
         CLI   TXHEX(GRA),X'27'         CHECK INSTRUCTION TYPE FOR A DS 01620000
         BE    CALNDC                   BRANCH IF EQUAL TO CHECK ALIGN- 01640000
*                                       MENT AS DC-DS.                  01660000
         CLI   TXHEX(GRA),X'22'         IS TEXT A LTORG                 01680000
         BE    OPALN                    YES                             01700000
         CLI   TXHEX(GRA),X'25'         IS TEXT A LITERAL               01720000
         BNE   ALRTN                    NO                              01740000
         MVC   LOCCTR(4),CTLOC(ACT)     YES, GET LOCATION COUNTER FOR   01760000
*                                       LITERALS                        01780000
         LA    GRB,5(GRB)                                               01800000
         MVC   SAVWD+1(3),TXDLEN(GRB)                                   01820000
         L     GR8,LOCCTR                                               01840000
         MVI   SAVWD,0                                                  01860000
         MVI   ORBYT,X'08'             INITIALIZE OR BYTE               01880000
         S     GR8,SAVWD                                                01900000
         ST    GR8,LOCCTR                                               01920000
         B     TEDC                                                     01940000
OPALN    TM    TXALIN(GRB),X'07'        TEST FOR ALIGNMENT BITS ON -OP- 01960000
         BZ    ALRTN                    BRANCH TO PROCESS ENTRY IF ZERO 01980000
         IC    GRY,TXALIN(GRB)          GET ALIGNMENT BITS              02000000
         B     TEALEN                   BRANCH TO MAKE ALIGNMENT ENTRY  02020000
*                                                                       02040000
CALNDC   TM    FOPN,X'FF'               CHECK WORK AREA POINTER SWITCH  02060000
         BO    TEDUDP                   IF ON, BRANCH                   02080000
         LA    GRB,5(GRB)                                               02100000
TEDUDP   TM    TXDALN(GRB),X'0E'        TEST FOR ALIGNMENT BITS ON -DC- 02120000
         BZ    ALRTN                    BRANCH TO PROCESS ENTRY IF ZERO 02140000
         IC    GRY,TXDALN(GRB)          GET ALIGNMENT BITS              02160000
         SRL   GRY,1                    ADJUST BITS TO REGISTER BOUNDRY 02180000
         TM    FOPN,X'FF'               IS THIS THE FIRST OPERAND       02200000
         BZ    TEALEN                   YES                             02220000
         LA    GR8,7                    NO, LOAD MASK                   02240000
         NR    GR8,GRY                  MASK ALIGNMENT BITS             02260000
         A     GR8,LOCCTR               ADD LOCATION COUNTER            02280000
         ST    GR8,LOCCTR               STORE AS NEW LOCATION           02300000
TEALEN   MVI   ORBYT,X'08'              INITIALIZE OR BYTE TO SPACE     02320000
         LA    GR8,7                    SET MASK TO CLEAR UNWANTED BITS 02340000
         NR    GRY,GR8                  CLEAR UNWANTED BITS             02360000
         L     GR8,LOCCTR               LOAD LOCATION COUNTER           02380000
         SR    GR8,GRY                  REDUCE ADDRESS BY BYTES SKIPPED 02400000
         ST    GR8,SAVWD                MOVE ADDRESS OF SPACE TO WORK   02420000
         MVC   ADDRES(3),SAVWD+1        AREA                            02440000
         STC   GRY,0(PTR)               STORE NO. BYTES SKIPPED AS LENG 02460000
         LA    PTR,1(PTR)               STEP POINTER TO WORK AREA       02480000
         BAL   GRY,STEN                 BRANCH TO STORE ENTRY           02500000
ALRTN    MVI   ORBYT,X'00'              INITIALIZE OR BYTE              02520000
         TM    FOPN,X'FF'               TEST THIS FOR FIRST OPERAND     02540000
         BO    NONAM                    BRANCH IF FLAG ON TO NO NAME.   02560000
         TM    TXNAML(GRA),X'FF'        CHECK NAME LENGTH INDICATOR     02580000
         BZ    NONAM                    BRANCH ON LENGTH ZERO TO NONAM  02600000
         SR    GRY,GRY                                                  02620000
         IC    GRY,TXNAML(GRA)          GET NAME LENGTH                 02640000
         AR    PTR,GRY                  STEP WORK AREA POINTER          02660000
         BCTR  GRY,0                                                    02680000
         L     SP2,CTRTBP(ACT)          LOAD TRANSLATE TABLE LOCATION   02700000
         EX    GRY,MVNAM                MOVE TRANSLATED NAME TO WORK    02720000
*                                       AREA                            02740000
         EX    GRY,TRANS                TRANSLATE NAME FOR SYMBOL TABLE 02760000
         EX    GRY,ORBOR                OR NAME LENGTH INTO OR BYTE     02780000
         B     NMRTN                                                    02800000
NONAM    MVI   ORBYT,X'08'              INDICATE NO NAME PRESENT        02820000
***********************************************                         02840000
*  TEST FOR MACHINE OP OR ASSEMBLER OP ENTRY  *                         02860000
***********************************************                         02880000
NMRTN    TM    TXTO(GRA),X'80'          TEST FOR DC-DS ENTRY            02900000
         BO    TEDCCT                   YES, BRANCH                     02920000
         TM    TXTO(GRA),X'40'          TEST FOR ASSEMBLER OP ENTRY     02940000
         BO    TEOPS                    YES, BRANCH                     02960000
         B     RETURN                   NO, RETURN TO MAINLINE          02980000
*********************************************************************** 03000000
*  THE FOLLOWING IS A TEST FOR TYPE OF ENTRY. DC AND DS ENTRIES HAVE  * 03020000
*  THE HEX CODES 26 AND 27. ANYTHING ELSE WITH A HEX CODE OF 28 OR    * 03040000
*  LESS IS A CONTROL SECTION ENTRY.                                   * 03060000
*********************************************************************** 03080000
TEDCCT   CLI   TXHEX(GRA),X'26'         TEST FOR DESIRED ENTRY          03100000
         BE    TEDC                     YES, BRANCH                     03120000
         CLI   TXHEX(GRA),X'27'                                         03140000
         BNE   TECTLS                   NOT DC-DS ENTRY, BRANCH         03160000
*                                                                       03180000
TEDC     CLI   TXDTYP(GRB),X'03'        IS ENTRY TYPE P                 03200000
         BE    PZCOD                    BRANCH IF CODE IS P             03220000
         CLI   TXDTYP(GRB),X'04'        CHECK FOR Z CODE                03240000
         BNE   LMPRS                    BRANCH IF CODE NOT Z            03260000
*                                                                       03280000
PZCOD    MVI   PZSWH,X'00'              ZERO P-Z SWITCH                 03300000
         TM    TXDLMP(GRB),X'10'        TEST FOR LENGTH MODIFIER PRES.  03320000
         BC    5,LMPRS                  YES, BRANCH                     03340000
         CLI   TXDCON(GRB),X'01'                                        03360000
         BE    LMPRS                    YES, BRANCH                     03380000
*                                                                       03400000
NOLNM    MVI   PZSWH,X'FF'              SET P-Z SWITCH ON               03420000
*                                                                       03440000
LMPRS    OI    ORBYT,X'80'              INDICATE DATA ENTRY IN OR BYTE  03460000
         MVC   ADDRES(3),LOCCTR+1       MOVE ADDRESS TO WORK AREA       03480000
*                                                                       03500000
         MVC   0(1,PTR),TXDTYP(GRB)     MOVE HEX TYPE TO WORK AREA      03520000
         TR    0(1,PTR),TBLHEX          TRANSLATE TO PROPER CODE        03540000
         LA    PTR,1(PTR)               STEP POINTER TO WORK AREA       03560000
         MVI   BCXIND,0                                                 03580000
*                                                                       03600000
CFBC     CLI   TXDTYP(GRB),X'02'        CHECK FOR B CODE                03620000
         BH    BLNTST                   BRANCH IF CODE HIGH             03640000
*                                                                       03660000
SFBCX    MVI   BCXIND,X'FF'             SET B, C OR X CODE FLAG ON      03680000
BLNTST   TM    TXDLMD(GRB),X'01'        TEST FOR BIT LENGTH CONSTANTS   03700000
         BO    BITLGN                   YES, BRANCH                     03720000
*                                                                       03740000
         TM    BCXIND,X'FF'             TEST B, C OR X FLAG             03760000
         BO    BCORX                    BRANCH IF ON TO MOVE BCX LENGTH 03780000
         TM    PZSWH,X'FF'              TEST P-Z FLAG                   03800000
         BO    PZCLR                    BRANCH IF ON TO MOVE P-Z LENGTH 03820000
*                                                                       03840000
         SR    GRX,GRX                  PUT CONSTANT LENGTH             03860000
         IC    GRX,TXDLNM+1(GRB)                                        03880000
         BCTR  GRX,0                                                    03900000
         STC   GRX,0(PTR)                                               03920000
         LA    PTR,1(PTR)               STEP POINTER TO WORK AREA       03940000
         B     DUPTST                   BRANCH TO TEST DUPLICATION      03960000
*                                                                       03980000
BCORX    MVC   CTWORK(2,ACT),TXDLNM(GRB) MOVE LENGTH MODIFIER TO ARRY   04000000
         LH    GRX,CTWORK(ACT)                                          04020000
         BCTR  GRX,0                                                    04040000
         STH   GRX,CTWORK(ACT)                                          04060000
         MVC   0(2,PTR),CTWORK(ACT)                                     04080000
         LA    PTR,2(PTR)               STEP POINTER TO WORK ARRY       04100000
*                                                                       04120000
DUPTST   MVC   SAVWD+1(3),TXDUPL(GRB)   ALIGN DUPLICATION FACTOR IN     04140000
         L     GRY,SAVWD                FULL WORD AND LOAD IN REGISTER  04160000
         LA    GRY,0(GRY)                                               04180000
         C     GRY,ONE                  IS DUPLICATION GREATER THAN ONE 04200000
         BNE   CKNOP                    YES, BRANCH                     04220000
*                                                                       04240000
         TM    TXDCON(GRB),X'FE'        IS NO. OF CONSTANTS GREATER     04260000
         BE    CKXOB                    THAN ONE.  NO, BRANCH           04280000
*                                                                       04300000
         SR    GRY,GRY                                                  04320000
         IC    GRY,TXDCON(GRB)          GET NO. OF CONSTANTS            04340000
         ST    GRY,SAVWD                BRANCH TO STORE AS MULTIPLICITY 04360000
         B     MVMLT                                                    04380000
*                                                                       04400000
CKNOP    TM    TXDCON(GRB),X'FF'        TEST NO. CONSTANTS.             04420000
         BZ    NOZRO                    NONE, BRANCH                    04440000
*                                                                       04460000
         SR    GR9,GR9                  GET NO CONSTANTS AND ZERO HIGH  04480000
         IC    GR9,TXDCON(GRB)          ORDER BYTES OF REGISTER.        04500000
         MR    GR8,GRY                  NO. CONSTANTS X DUPLICATION     04520000
         ST    GR9,SAVWD                                                04540000
MVMLT    MVC   0(3,PTR),SAVWD+1         STORE AS MULTIPLICITY FACTOR    04560000
         LA    PTR,3(PTR)               STEP POINTER TO WORK AREA       04580000
*                                                                       04600000
         OI    ORBYT,X'40'              INDICATE MULT. IN OR BYTE       04620000
         B     CKXOB                                                    04640000
*                                                                       04660000
NOZRO    ST    GRY,SAVWD                STORE DUP. FACTOR AS MULT. NO.  04680000
         B     MVMLT                    OF CONSTANTS IS ZERO.           04700000
*                                                                       04720000
CKXOB    TM    BCXIND,X'FF'             CHECK B, C OR X INDICATOR.      04740000
         BO    STDCEN                   ON, BRANCH                      04760000
*                                                                       04780000
         MVC   SAVWD+2(2),TXDSCM(GRB)   GET SCALE MODIFIER AND ALIGN IT 04800000
         LH    GR8,SAVWD+2              IN A REGISTER.                  04820000
         MVC   SAVWD+2(2),TXDSCM(GRB)                                   04840000
         LH    GR8,SAVWD+2                                              04860000
         SRA   GR8,5                                                    04880000
         LTR   GR8,GR8                  TEST FOR MODIFIER               04900000
         BZ    STDCEN                   IF NONE, BRANCH                 04920000
*DELETE                                                                 04940000
*DELETE                                                                 04960000
*DELETE                                                                 04980000
NOSOSM   ST    GR8,SAVWD                PUT SCALE MODIFIER              05000000
         MVC   0(2,PTR),SAVWD+2                                         05020000
*                                                                       05040000
         OI    ORBYT,X'10'              UPDATE ORBYT TO INDICATE SCALE  05060000
*                                       MODIFIER PRESENT                05080000
         LA    PTR,2(PTR)                                               05100000
*                                                                       05120000
STDCEN   BAL   GRY,STEN                 BRANCH TO STORE ENTRY           05140000
TSTNBK   MVC   SAVWD+1(3),TXDLEN(GRB)   GET OPERAND LENGTH              05160000
*DELETE                                                                 05180000
*DELETE                                                                 05200000
*DELETE                                                                 05220000
         TM    TXDLAS(GRB),X'08'        IS THIS THE LAST WORK BUCKET    05240000
         BO    RETURN                   YES, RETURN                     05260000
         LA    GRB,15(GRB)                                              05280000
         TM    TXWTYP(GRB),X'40'        TEST FOR ANOTHER OPERAND WORK   05300000
*                                       BUCKET                          05320000
         BZ    RETURN                   RETURN IF NOT FOUND             05340000
         TM    BLDATA,X'FF'                                             05360000
         BZ    STPLC1                   BRANCH IF SWITCH OFF            05380000
         TM    TXDLMD(GRB),X'01'        TEST FOR BIT LENGTH CONSTANTS   05400000
         BZ    STPLC1                   NO, BRANCH                      05420000
         L     GR1,STEPER                                               05440000
         B     STPLC2                                                   05460000
STPLC1   L     GR1,SAVWD                                                05480000
STPLC2   A     GR1,LOCCTR                                               05500000
         ST    GR1,LOCCTR                                               05520000
         MVI   FOPN,X'FF'               SET SWITCH THIS NOT FIRST OPND  05540000
         B     CALNDC                   BRANCH TO PROCESS NEXT OPERAND  05560000
*                                                                       05580000
*                                                                       05600000
BITLGN   SR    GR9,GR9                                                  05620000
         OI    BLDATA,X'FF'                                             05640000
         MVC   SAVWD+2(2),TXDLNM(GRB)   GET LENGTH MODIFIER             05660000
         LH    GR8,SAVWD+2                                              05680000
         N     GR8,=A(X'FFFF')                                          05700000
         A     GR8,REMSV                ADD REMAINING BITS FM LAST OPND 05720000
         SRDL  GR8,3                    DIVID BY 8 FOR NO. OF WORDS     05740000
         LTR   GR8,GR8                  TEST FOR BIT LENGTH LESS THAN 8 05760000
         BZ    BOTCD                    YES, BRANCH                     05780000
*                                                                       05800000
         LTR   GR9,GR9                  TEST FOR REMAINDER              05820000
         BC    6,BOTCD                  YES, BRANCH                     05840000
*                                                                       05860000
         BCTR  GR8,0                    DECREASE LENGTH INDICATOR BY 1  05880000
*                                                                       05900000
BOTCD    TM    BCXIND,X'FF'             TEST B-C-X TYPE CODE FLAG       05920000
         BO    MLTB                     FLAG OFF, BRANCH                05940000
         STC   GR8,0(PTR)               STORE LENGTH-1 IN WORK AREA     05960000
         LA    PTR,1(PTR)               STEP POINTER TO WORK AREA BY 1  05980000
*                                                                       06000000
SETSTP   XC    SAVWD(2),SAVWD           ZERO FIRST 2 BYTES              06020000
         MVC   SAVWD+2(2),TXDLEN(GRB)   GET CONSTANT LEN                06040000
         L     GR9,SAVWD                                                06060000
         MVC   SAVWD+1(3),TXDUPL(GRB)   GET DUP FACTOR                  06080000
         M     GR8,SAVWD                LEN X DFP FACTOR                06100000
         IC    GR8,TXDCON(GR8)          GET NO. CONSTANTS IN OPND       06120000
         MR    GR8,GR8                  LEN X DUP X NO. CONSTANTS       06140000
         LR    GR8,GR9                                                  06160000
         A     GR8,REMSV                                                06180000
         SRDL  GR8,3                                                    06200000
         ST    GR8,STEPER                                               06220000
         SR    GR8,GR8                                                  06240000
         SLDL  GR8,3                                                    06260000
         ST    GR8,REMSV                                                06280000
         B     DUPTST                                                   06300000
*                                                                       06320000
MLTB     STH   GR8,SAVWD+2              STORE LENGTH MODIFIER AS 2 BYTE 06340000
         MVC   0(2,PTR),SAVWD+2                                         06360000
         LA    PTR,2(PTR)               STEP POINTER TO WORK AREA BY 2  06380000
         B     SETSTP                                                   06400000
*                                                                       06420000
*                                                                       06440000
STEN     ST    GRY,STSAV                SAVE RETURN ADD-ESS             06460000
         LA    GR9,56                   LOAD NO. BYTE OF VARIABLE INFO. 06480000
         LA    GR8,ORBYT                GET ENTRY LOCATION              06500000
         SR    PTR,GR8                  FIND THE NO. OF BYTES IN ENTRY  06520000
         S     GR9,NOLEFT               GET NO. OF BYTES USED IN BUFFER 06540000
         LA    GRX,TEBFR+17(GR9)        GET PTR TO NEXT BYTE            06560000
         C     PTR,NOLEFT               COMPARE NO. LEFT TO NO.IN ENTRY 06580000
         BP    CHAREB                   BRANCH IF ANY LEFT              06600000
MCLN     BCTR  PTR,0                    REDUCE NO. OF CHARS. FOR MOVE   06620000
         EX    PTR,MOVEN                EXECUTE MOVE                    06640000
         LA    PTR,1(PTR)               STEP NO. OF CHARS. BY 1         06660000
         L     GR9,NOLEFT               GET NO. BYTE LEFT IN BUFFER.    06680000
         SR    GR9,PTR                  REDUCE BY NO. CHARS. MOVED      06700000
         BZ    RESET                    IF NO. LEFT = 0 BRANCH TO RESET 06720000
*                                                                       06740000
         ST    GR9,NOLEFT               STORE NO. LEFT FOR NEXT ENTRY   06760000
STRTN    LA    PTR,WKAREA               RESET POINTER TO WORK AREA      06780000
         L     GRY,STSAV                RESTORE RETURN ADDRESS          06800000
         BR    GRY                      RETURN                          06820000
*                                                                       06840000
CHAREB   L     GR9,NOLEFT               GET NO. LEFT                    06860000
         BCTR  GR9,0                                                    06880000
         EX    GR9,MOVEN                MOVE NO. CHARS. LEFT TO BUFFER. 06900000
*DELETE                                                                 06920000
         MVI   NLF,X'FF'                SET CHARS. LEFT FLAG            06940000
*                                                                       06960000
OUTSYM   TM    FPSWH,X'FF'              TEST FIRST PASS SWITCH          06980000
         BO    PUNOUT                   BRANCH IF ON                    07000000
         MVI   FPSWH,X'FF'              TURN ON FIRST PASS SWITCH       07020000
         MVC   TTLSEQ(4),CTITLE(ACT)    MOVE TITLE TO BE PUNCHED IN     07040000
*                                       OUTPUT CARDS                    07060000
         SR    GR2,GR2                                                  07080000
         ST    GR2,CCRDCT(ACT)          INITIALIZE CARD COUNT           07100000
PUNOUT   L     GR1,CCRDCT(ACT)          GET CARD SEQUENCE NUMBER        07120000
         LA    GR1,1(GR1)               ADD 1                           07140000
         ST    GR1,CCRDCT(ACT)          STORE                           07160000
         CVD   GR1,DBLWD                CONVERT SEQUENCE NO. TO DECIMAL 07180000
         UNPK  TTLSEQ+4(4),DBLWD+5(3)   UNPACK LOW ORDER 4 DIGITS       07200000
         OI    TTLSEQ+7,X'F0'           MASK SIGN                       07220000
         STM   SRB,SRR,DBLWD            SAVE REGISTERS                  07240000
         STM   0,15,CTWORK(ACT)         ********TEMP FIX*************** 07260000
         LA    SP1,TEBFR                LOAD I/O OUTPUT PARAMETER       07280000
         L     SRB,CTXTIO(ACT)          LOAD I/O ROUTINE ADDRESS        07300000
         BAL   SRR,SYSOUT(SRB)          BRANCH TO OUTPUT SYMBOL CARD    07320000
         LM    SRB,SRR,DBLWD            RESTORE REGISTERS               07340000
         LM    0,15,CTWORK(ACT)         ********TEMP FIX*************** 07360000
*                                                                       07380000
*DELETE                                                                 07400000
*DELETE                                                                 07420000
*DELETE                                                                 07440000
         MVC   TEBFR+17(56),TEBFR+16    BLANK OUTPUT BUFFER             07460000
         LA    GRX,TEBFR+17             RESET BUFFER POINTER            07480000
         LA    GRY,56                   RESET NO. LEFT INDICATOR        07500000
         ST    GRY,NOLEFT                                               07520000
         TM    NLF,X'FF'                TEST IF ANY CHARS LEFT TO ENTER 07540000
         BZ    STRTN                    BRANCH IF NONE.                 07560000
         LA    GR9,1(GR9)                                               07580000
*                                                                       07600000
         SR    PTR,GR9                  SET POINTERS TO MOVE REMAINING  07620000
         AR    GR8,GR9                  CHARSACTERS.                    07640000
         MVI   NLF,X'00'                RESET ADDITIONAL CHARACTERS     07660000
*                                       FLAG                            07680000
         B     MCLN                                                     07700000
*                                                                       07720000
RESET    LA    GR9,56                   RESET NOLEFT                    07740000
         B     OUTSYM                                                   07760000
*                                                                       07780000
TEOPS    TM    8(GRA),X'FF'             CHECK FOR NAME PRESENT          07800000
         BZ    RETURN                   RETURN TO MAIN LINE IF NO NAME  07820000
*                                                                       07840000
         OI    ORBYT,X'40'              UPDATE OR BYTE                  07860000
         MVC   ADDRES(3),LOCCTR+1       MOVE INSTR. LOC. TO WORK AREA   07880000
*                                                                       07900000
         BAL   GRY,STEN                 BRANCH TO STORE ENTRY           07920000
         B     RETURN                   RETURN TO MAIN LINE             07940000
*                                                                       07960000
*   START, CSECT, DSECT, CCW OR COM CODE ENTRY                          07980000
*                                                                       08000000
TECTLS   CLI   TXHEX(GRA),X'1B'         CHECK FOR TYPE OF CODE          08020000
         BE    CSECT                    CSECT CODE, BRANCH              08040000
         BL    RETURN                   RETURN IF LOW                   08060000
         CLI   TXHEX(GRA),X'1D'         CHECK CODE FOR DSECT            08080000
         BL    CSECT                    IF IT IS A CSECT, BRANCH        08100000
         BE    DSECT                    BRANCH ON EQUAL TO DSECT        08120000
*                                                                       08140000
         CLI   TXHEX(GRA),X'1E'         CHECK FOR COM CODE              08160000
         BE    COM                      YES, BRANCH                     08180000
*                                                                       08200000
         CLI   TXHEX(GRA),X'28'         CHECK FOR CCW CODE              08220000
         BNE   RETURN                   RETURN IF NOT ONE OF THE ABOVE  08240000
*                                       CODES.                          08260000
         OI    ORBYT,X'50'              RESET OR BYTE TO INDICATE CCW   08280000
MDSO     MVC   ADDRES(3),LOCCTR+1       MOVE LOCATION CTR AS ADDRESS    08300000
*                                                                       08320000
         BAL   GRY,STEN                 BRANCH TO STORE ENTRY.          08340000
         B     RETURN                   RETURN TO MAIN LINE             08360000
*                                                                       08380000
CSECT    OI    ORBYT,X'10'              RESET OR BYTE TO INDICATE CSECT 08400000
         B     MDSO                                                     08420000
*                                                                       08440000
DSECT    OI    ORBYT,X'20'              RESET OR BYTE TO INDICATE DSECT 08460000
         B     MDSO                                                     08480000
*                                                                       08500000
COM      OI    ORBYT,X'38'              RESET OR BYTE TO INDICATE COM   08520000
         LA    PTR,WKAREA                                               08540000
         B     MDSO                                                     08560000
*                                                                       08580000
*                                                                       08600000
* PUT LAST TESTRAN SYMBOL CARD                                          08620000
*                                                                       08640000
*                                                                       08660000
WRILST   LA    GR8,56                   GET MAX. NO. BYTES IN VAR. TEXT 08680000
         C     GR8,NOLEFT               COMPARE WITH NO. LEFT           08700000
         BE    RETURN                   RETURN IF EQUAL                 08720000
         S     GR8,NOLEFT               DETERMINE THE NO. OF BYTES IN   08740000
*                                       THE LAST CARD                   08760000
         STH   GR8,SAVWD                MOVE NO. OF BYTES IN LAST CARD  08780000
         MVC   NCL(2),SAVWD                                             08800000
*                                                                       08820000
         LA    GRY,RETURN               SET RETURN ADDRESS              08840000
         ST    GRY,STSAV                SAVE RETURN ADDRESS             08860000
         B     OUTSYM                                                   08880000
*                                                                       08900000
RETURN   LM    GRA,GRD,SAVMWD           RESTORE REGISTERS               08920000
         BR    CRR                      RETURN                          08940000
*********************************************************************** 08960000
*  CLUSTER ENTRIES FOR P-Z TYPE CODE                                    08980000
*********************************************************************** 09000000
*                                                                       09020000
*                                                                       09040000
PZCLR    MVC   PZLOC(4),LOCCTR          SAVE LOCATION COUNTER           09060000
         MVI   SCFCN,IZERO              ZERO FIRST CONSTANT FLAG        09080000
         SR    GR8,GR8                  SAVE CLUSTER FIELD ENTRY        09100000
         IC    GR8,TXDLEN+2(GRB)                                        09120000
         BCTR  GR8,0                                                    09140000
         STC   GR8,0(PTR)                                               09160000
         MVC   1(3,PTR),TXDUPL(GRB)                                     09180000
         LA    PTR,4(PTR)                                               09200000
         OI    ORBYT,X'60'                                              09220000
         BAL   GRY,STEN                                                 09240000
*                                                                       09260000
SCANPZ   SR    GR8,GR8                  ZERO COUNTERS                   09280000
         STH   GR8,SCTTL                                                09300000
         STH   GR8,SCWHOL                                               09320000
         TM    SCFCN,X'FF'              TEST FIRST CONSTANT FLAG        09340000
         BO    SC12                     BRANCH IF ON                    09360000
*                                                                       09380000
         STH   GR8,PLENG                ZERO OPERAND LENGTH INDICATOR   09400000
*                                       OPERAND                         09420000
         SR    GRD,GRD                                                  09440000
         IC    GRD,TXDPTR(GRB)          GET POINTER TO OPERAND          09460000
         L     GR9,CTXOFP(ACT)                                          09480000
         LA    GRD,1(GRD,GR9)           ADD POINTER TO BEGIN OF OPERAND 09500000
SC10     CLI   0(GRD),IQUOTE            IS CHAR A QUOTE                 09520000
         BE    SC12                     YES, GO SCAN CONSTANT           09540000
         CLI   0(GRD),IBLANK            IS CHAR A BLANK                 09560000
         BE    TSTNBK                   YES GET OUT                     09580000
         LA    GRD,1(GRD)               STEP PTR TO NEXT CHAR           09600000
         B     SC10                     TEST NEXT CHAR                  09620000
SC12     LA    GRD,1(GRD)               STEP POINTER BY 1               09640000
*                                                                       09660000
         CLI   0(GRD),IMINUS            IS CHARACTER A MINUS SIGN       09680000
         BE    SC14                     YES                             09700000
         CLI   0(GRD),IPLUS             NO, IS CHARACTER A PLUS SIGN    09720000
         BE    SC14                     YES                             09740000
*                                                                       09760000
SC13     CLI   0(GRD),I9                NO, IS CHARACTER NUMERIC        09780000
         BH    SC15                     NO                              09800000
         LA    GR8,1(GR8)               YES, STEP COUNTER BY 1          09820000
SC14     LA    GRD,1(GRD)               STEP POINTER BY 1               09840000
         B     SC13                     LOOP BACK TO CHECK NEXT CHAR-   09860000
*                                       ACTER.                          09880000
SC15     CLI   0(GRD),IPRIOD            IS CHARACTER A PERIOD           09900000
         BNE   SC16                     NO                              09920000
         LA    GR8,1(GRB)                                               09940000
         STH   GR8,SCWHOL               YES, SAVE COUNT IN WHOLE        09960000
         SR    GR8,GR8                  ZERO COUNTER                    09980000
         B     SC14                     LOOP BACK TO CHECK NEXT CHAR-   10000000
*                                       ACTER.                          10020000
SC16     LH    GR9,SCWHOL               LOAD NO. CHARS. BEFORE PERIOD   10040000
         LTR   GR9,GR9                  CHECK FOR NONE                  10060000
         BZ    SC161                    IF NONE, BRANCH                 10080000
         BCTR  GR9,0                    DECREMENT                       10100000
SC161    AR    GR9,GR8                  ADD COUNT                       10120000
         CLI   TXDTYP(GRB),X'04'        IS ENTRY Z TYPE DC-DS           10140000
         BE    SC18                     YES                             10160000
*                                                                       10180000
*                                                                       10200000
SC17     SRL   GR9,1                    DIVIDE TOTAL BY 2               10220000
         LA    GR9,1(GR9)               NO, ADD 1 TO TOTAL              10240000
SC18     STH   GR9,SCTTL                STORE TOTAL                     10260000
         LA    GR9,16                                                   10280000
         CR    GR8,GR9                  IS COUNT GREATER THAN 16        10300000
         BH    SC19                     YES                             10320000
         CLI   SCTTL,X'10'              NO, IS TOTAL GREATER THAN 16    10340000
         BH    SC20                     YES                             10360000
*                                                                       10380000
         B     PZ10                     NO, BRANCH TO OUTPUT CONSTANT   10400000
*                                       DATA                            10420000
SC19     SR    GR8,GR8                  ZERO COUNT                      10440000
SC20     MVI   SCTTL+1,X'10'            RESET TOTAL TO 16               10460000
*                                                                       10480000
PZ10     MVI   ORBYT,X'A8'              INITIALIZE OR BYTE              10500000
         MVC   ADDRES(3),PZLOC+1        MOVE ENTRY ADDRESS TO WORK AREA 10520000
         L     GR9,PZLOC                LOAD LOCATION COUNTER           10540000
         AH    GR9,SCTTL                ADD LENGTH OF CURRENT CONSTANT  10560000
         ST    GR9,PZLOC                STORE AS NEXT ENTRY ADDRESS     10580000
*                                                                       10600000
         LH    GR9,PLENG                GET OPERAND LENGTH COUNTER      10620000
         AH    GR9,SCTTL                ADD LENGTH OF CURRENT CONSTANT  10640000
         STH   GR9,PLENG                STORE NEW LENGTH                10660000
         MVI   WKAREA,X'30'             MOVE DATA TYPE TO WORK AREA     10680000
         CLI   TXDTYP(GRB),X'03'        IS ENTRY TYPE P                 10700000
         BE    PZ11                     YES                             10720000
*                                                                       10740000
         OI    WKAREA,X'04'             NO, UPDATE DATA TYPE            10760000
PZ11     LA    PTR,WKAREA+2             SET POINTER TO WORK AREA        10780000
         LH    GR9,SCTTL                GET CONSTANT LENGTH             10800000
         BCTR  GR9,0                    REDUCE BY 1                     10820000
         STC   GR9,WKAREA+1             STORE LENGTH-1 IN WORK AREA     10840000
*                                                                       10860000
         LTR   GR8,GR8                  IS COUNT ZERO                   10880000
         BZ    PZ12                     YES                             10900000
         CLI   SCWHOL+1,X'00'           NO, IS WHOLE ZERO               10920000
         BE    PZ12                     YES                             10940000
*                                                                       10960000
         STH   GR8,SCWHOL               STORE IN ALIGNED WORD           10980000
         MVC   WKAREA+2(2),SCWHOL       MOVE TO WORK AREA AS SCALING    11000000
         LA    PTR,2(PTR)               STEP WORK AREA POINTER BY 2     11020000
         OI    ORBYT,X'10'              UPDATE OR BYTE TO INDICATE      11040000
*                                       SCALING                         11060000
*                                                                       11080000
PZ12     BAL   GRY,STEN                 BRANCH TO STORE ENTRY           11100000
         MVI   SCFCN,X'FF'              SET FIRST CONSTANT FLAG ON      11120000
         CLI   0(GRD),ICOMMA            TEST FOR LAST CONSTANT IN       11140000
*                                       THE OPERAND                     11160000
         BE    SCANPZ                   BRANCH IF EQUAL                 11180000
         MVI   PZSWH,0                  TURN OFF P-Z SWITCH             11200000
         B     TSTNBK                   BRANCH TO NEXT OPERAND          11220000
*                                                                       11240000
TRANS    TR    WKAREA(0),0(SP2)         TRANSLATE INSTRUCTION TO TRANS- 11260000
*                                       LATE NAME FOR SYMBOL TABLE      11280000
*                                       SYMBOL MOVE.                    11300000
MVNAM    MVC   WKAREA(0),TXNAME(GRA)    MOVE INSTRUCTION EXECUTED ABOVE 11320000
*                                       TO MOVE NAME TO WORK AREA       11340000
ORBOR    OI    ORBYT,X'00'              OR INSTR TO OR LENGTH SYMBOL    11360000
*                                       LENGTH INTO OR BYTE             11380000
*                                                                       11400000
MOVEN    MVC   0(0,GRX),0(GR8)          MOVE INSTR. EXECUTED ELSE WHERE 11420000
DBLWD    DC    D'0'                     TEMPORARY STORAGE AREA          11440000
STSAV    DC    F'0'                     RETURN ADDRESS SAVE AREA        11460000
PZLOC    DC    F'0'                     LOCATION COUNTER SAVE AREA      11480000
SVOBN    DC    12F'0'                                                   11500000
SAVMWD   DC    4F'0'                    SAVE AREA FOR GRA THROUGH GRD   11520000
REMSV    DC    F'0'                     STORE REMNDER FROM LAST OPERAND 11540000
STEPER   DC    F'0'                                                     11560000
ONE      DC    F'1'                     CONSTANT OF 'ONE'               11580000
NOLEFT   DC    F'56'                    NUMBER OF TEXT BYTES LEFT       11600000
SAVWD    DC    F'0'                     WORK AREA                       11620000
LNGCTR   DC    F'0'                                                     11640000
BITREM   DC    F'0'                                                     11660000
LOCCTR   DC    F'0'                     LOCATION COUNTER                11680000
SCTTL    DC    H'0'                     SCAN COUNTER                    11700000
SCWHOL   DC    H'0'                     WHOLE ZERO COUNTER              11720000
PLENG    DC    H'0'                     OPERAND LENGTH COUNTER          11740000
BLDATA   DC    X'0'                     SWITCH                          11760000
STPFLG   DC    X'0'                     SWITCH                          11780000
TTN      DC    X'00'                    OUTPUT BUFFER AREA              11800000
         DC    X'02'                                                    11820000
         DC    C'SYM'                                                   11840000
         DC    6C' '                                                    11860000
NCL      DC    X'0038'                                                  11880000
         DC    4C' '                                                    11900000
         DC    56C' '                                                   11920000
TTLSEQ   DC    8C' '                    OUTPUT BUFFER TITLE AREA        11940000
ORBYT    DC    X'00'                    OP CODE INDICATOR BYTE          11960000
ADDRES   DC    3X'00'                   WORK AREA--ADDRESS STORAGE      11980000
WKAREA   DC    16C' '                   WORK AREA FOR TRANSLATE         12000000
FPSWH    DC    X'00'                    FIRST PASS SWITCH               12020000
FOPN     DC    X'00'                    WORK AREA POINTER SWITCH        12040000
PZSWH    DC    X'00'                    P-Z SWITCH                      12060000
BCXIND   DC    X'00'                    BCX CODE FLAG                   12080000
PZLEN    DC    X'00'                                                    12100000
NLF      DC    X'00'                    CHARACTERS LEFT FLAG            12120000
BLANK    DC    X'40'                                                    12140000
SCFCN    DC    X'00'                    FIRST CONSTANT FLAG             12160000
TBLHEX   DC    X'00'                    TRANSLATE TABLE                 12180000
         DC    X'04'                                                    12200000
         DC    X'08'                                                    12220000
         DC    X'30'                                                    12240000
         DC    X'34'                                                    12260000
         DC    X'1C'                                                    12280000
         DC    X'18'                                                    12300000
         DC    X'10'                                                    12320000
         DC    X'14'                                                    12340000
         DC    X'20'                                                    12360000
         DC    X'24'                                                    12380000
         DC    X'2C'                                                    12400000
         DC    X'28'                                                    12420000
         DC    X'20'                                                    12440000
         DC    X'38'                    GARB BYTE FOR L'CONS    A39577  12450021
TEBFR    EQU   TTN                                                      12460000
PTR      EQU   GRZ                                                      12480000
         END   TSTRAN                                                   12500000
