F7V      TITLE 'PHASE 7 EVALUATION ROUTINE'                             00020000
         ISEQ  73,80                                                    00040000
IEUF7V   START  0                                                       00060000
*                                                                       00062000
*          RELEASE  20  DELETIONS                                A32954 00063020
* 000640,049000                                                  A32954 00064020
* 058000                                                         A28596 00065020
*           RELEASE 21 DELETIONS                                 A39650 00066000
* 028800,145200-145400,149200,151400,174600                      A39650 00068000
* 047400,048880-049120,054000,056000                             A45780 00068821
*                                                                       00070000
*                                                                       00072000
*                                                                       00074000
*                                                                       00076000
*                                                                       00078000
EEVAL    EQU   IEUF7V                                                   00100000
         PRINT OFF                                                      00120000
         FDIMEN                                                         00140000
         PRINT ON                                                       00160000
         SPACE 2                                                        00180000
*TITLE 'IEUF7V'  PHASE F7 EXPRESSION EVALUATION ROUTINE               * 00200000
*                                                                     * 00220000
*STATUS- CHANGE LEVEL   03                                            * 00240021
*FUNCTION/OPERATION-                                                  * 00260000
*   EVALUATE EXPRESSIONS                                              * 00280000
*   LOG TYPE 2 CROSS-REFERENCES FOR EACH SYMBOL                       * 00300000
*   CONVERT SELF-DEFINING TERMS TO THEIR PROPER VALUES                * 00320000
*   DETECT THE FOLLOWING ERRORS-                                      * 00340000
*        RELOCATABILITY ERROR                                         * 00360000
*        SELF-DEFINING VALUE TOO LARGE                                * 00380000
*        ARITHMETIC OVERFLOW                                          * 00400000
*        SYMBOL NOT FOUND                                             * 00420000
*        SYMBOL NOT PREVIOUSLY DEFINED                                * 00440000
*        TWO TERMS NOT SEPARATED BY OPERATOR                          * 00460000
*        ILLEGAL CHARACTER                                            * 00480000
*        TOO MANY TERMS                                               * 00500000
*        TWO OPERATORS ILLEGALLY COMBINED                             * 00520000
*        TOO MANY LEVELS OF PARENTHESES                               * 00540000
*        PREMATURE END OF EXPRESSION                                  * 00560000
*        INVALID SYMBOL                                               * 00580000
*        EXPRESSION VALUE TOO LARGE                                   * 00600000
*ENTRY POINT-  IEUF7V                                                 * 00620000
*   CALLING SEQUENCE                                                  * 00640000
*        L     SRB,CEEVAL(ACT)     PICK UP IEUF7V ADDRESS FROM ACT    * 00660000
*        BALR  SRR,SRB                                                * 00680000
*        CEEVAL(ACT) IS LOADED BY IEUF7I WITH ADDRESS OF IEUF7V       * 00700000
*INPUT-                                                               * 00720000
*   REGISTERS-                                                        * 00740000
*        SP1 CONTAINS ADDRESS OF FIRST CHARACTER OF THE EXPRESSION TO * 00760000
*        BE EVALUATED                                                 * 00780000
*   PARAMETERS-                                                       * 00800000
*        CTSDVI(ACT)- HIGH-ORDER BIT (BIT 0)                          * 00820000
*            0=NO EFFECT UPON IEUF7V                                  * 00840000
*            1=IF THE FIRST (OR ONLY) TERM OF THE EXPRESSION IS A     * 00860000
*              SELF-DEFINING TERM, THEN-                              * 00880000
*                  THE BIT IS RESET TO 0                              * 00900000
*                  THE VALUE OF THE S.D.T. IS PLACED IN REG. SP1      * 00920000
*                  CONDITION CODE IS SET TO 0                         * 00940000
*                  IEUF7V EXITS TO CALLING ROUTINE                    * 00960000
*        CTSDVI(ACT)- BIT 2                                           * 00980000
*            1='PREVIOUSLY DEFINED SYMBOL' ERROR                      * 01000000
*        F8YDC+1(ACT)                                                 * 01020000
*            X'01'=RESULT IS AN ADCON, MAY BE FOUR BYTES LONG         * 01040000
*OUTPUT-                                                              * 01060000
*   REGISTERS-                                                        * 01080000
*        SP1 CONTAINS ADDRESS OF THE CHARACTER FOLLOWING THE CHARACTER* 01100000
*                     WHICH TERMINATED THE EXPRESSION                 * 01120000
*                  OR ZERO, IF A SYNTACTICAL ERROR WAS DISCOVERED IN  * 01140000
*                     THE EXPRESSION   (FATAL ERROR)                  * 01160000
*        SP2 CONTAINS THE VALUE OF THE EXPRESSION, IF THE EXPRESSION  * 01180000
*                     WAS ABSOLUTE                                      01200000
*                  OR A POINTER TO AN OUTPUT PARAMETER LIST (RLIST),  * 01220000
*                     IF THE EXPRESSION WAS RELOCATABLE.              * 01240000
*   CONDITION CODE-                                                   * 01260000
*        CC=0   ABSOLUTE EXPRESSION                                   * 01280000
*        CC=1   SIMPLY RELOCATABLE EXPRESSION                         * 01300000
*        CC=2   COMPLEXLY RELOCATABLE EXPRESSION                      * 01320000
*        CC=3   EVALUATION IMPOSSIBLE (ERROR)                         * 01340000
*   PARAMETERS-                                                       * 01360000
*        LIST POINTED TO BY SP1-                                      * 01380000
*             ONE FULL WORD CONTAINING THE VALUE OF THE EXPRESSION    * 01400000
*             16 HALF-WORDS, ONE FOR EACH POSSIBLE TERM IN EXPR.      * 01420000
*                  ABSOLUTE TERM ENTRIES...BOTH BYTES 0               * 01440000
*                  PAIRED RELOCATABLE TERM ENTRIES...BOTH BYTES 0     * 01460000
*                  RELOCATABLE TERM ENTRIES...FIRST BYTE=SIGN         * 01480000
*                       (1=+,2=-),SECOND BYTE=ESD-ID                  * 01500000
*             A SIMPLY RELOCATABLE EXPRESSION WILL HAVE A TERM ENTRY  * 01520000
*             IN ONLY THE FIRST HALF-WORD.  THE REMAINING 15 HALF     * 01540000
*             WORDS WILL CONTAIN ZEROES.  A COMPLEXLY RELOCATABLE     * 01560000
*             EXPRESSION WILL HAVE A NON-ZERO ENTRY FOR EACH UNPAIRED * 01580000
*             RELOCATABLE TERM. THESE ENTRIES MAY BE SCATTERED THROUGH* 01600000
*             THE PARAMETER LIST.                                     * 01620000
*        CTLRCI(ACT), BIT 1                                           * 01640000
*            0= NO REFERENCE TO LOCATION COUNTER (*) IN EXPRESSION    * 01660000
*            1=REFERENCE TO LOC. CNTR WAS MADE IN EXPRESSION          * 01680000
*        STLONG(ACT) CONTAINS LENGTH ATTRIBUTE OF FIRST TERM IN EXPR. * 01700000
*EXTERNAL REFERENCE-                                                  * 01720000
*   STGETR (IN IEUF7S) IS ENTERED (VIA ACT) TO SEARCH SYMBOL TABLE.   * 01740000
*EXITS- NORMAL-                                                       * 01760000
*        RETURN TO CALLING PROGRAM VIA-                               * 01780000
*        BR    SRR                                                    * 01800000
*       ERRORS-                                                       * 01820000
*          PROCESSING OF EXPRESSION IS COMPLETED AND NORMAL EXIT      * 01840000
*          OCCURS IF THESE ERRORS ARE ENCOUNTERED-  (NON-FATAL ERRORS)* 01860000
*             EXPRESSION VALUE TOO LARGE                              * 01880000
*             SYMBOL NOT PREVIOUSLY DEFINED                           * 01900000
*             ARITHMETIC ERROR                                        * 01920000
*             RELOCATABILITY ERROR                                    * 01940000
*             SELF-DEFINING TERM VALUE TOO LARGE                      * 01960000
*                  OR ZERO, IF AN ERROR WAS DISCOVERED IN THE EXPRES'N* 01980000
*             THE CONDITION CODE WILL NOT BE 3 FOR 'EXPR. VALUE ECEEDS* 02000000
*             RANGE'                                                  * 02020000
*          EXPRESSION PROCESSING IS DISCONTINUED, SP1 AND SP2 ARE SET * 02040000
*          TO ZERO, AND IEUF7V RETURNS TO THE CALLING ROUTINE, IF THE * 02060000
*          FOLLOWING SYNTACTICAL ERRORS ARE ENCOUNTERED. (FATAL ERR'S)* 02080000
*             TWO TERMS NOT SEPARATED                                 * 02100000
*             ILLEGAL CHARACTER                                       * 02120000
*             TOO MANY TERMS                                          * 02140000
*             TWO OPERATORS ILLEGALLY COMBINED                        * 02160000
*             TOO MANY LEVELS OF PARENTHESES                          * 02180000
*             EXPRESSION END PREMATURE                                * 02200000
*             INVALID SYMBOL                                          * 02220000
*          IN ALL CASES, THE ERRORS ARE LOGGED.                       * 02240000
*TABLES/WORK AREAS-                                                   * 02260000
*   TERMS- (16F) AN ENTRY IS MADE FOR EACH TERM IN EXPRESSION...AT END* 02280000
*          OF EVALUATION, FIRST ENTRY CONTAINS RESULT VALUE           * 02300000
*   RLIST- (16H) TERM ENTRY PORTION OF OUTPUT PARAMETER LIST.         * 02320000
*   NTRMS- (16C) AT END OF EVAL., FIRST BYTE CONTAINS 2*NUMBER OF     * 02340000
*          TERMS.                                                     * 02360000
*   OPRNS  (20C) AN ENTRY IS MADE FOR EACH OPERATOR IN EXPR'N         * 02380000
*NOTE-  SEARCH FOR SYMBOLS BEGINS WITH WORK BUCKETS. IF SYMBOL IS NOT * 02400000
*       FOUND, SEARCH CONTINUES IN THE SYMBOL TABLE                   * 02420000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 02440000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 02460000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 02480000
*                                                                     * 02500000
*  GRX USED FOR POINTER TO TERMS LIST                                   02520000
*  GRY USED FOR POINTER TO OPRNS LIST                                   02540000
*  GRZ USED FOR POINTER TO NTRMS LIST                                   02560000
*  GR2 USED FOR POINTER TO RLIST LIST                                   02580000
* GR0,GR1,GRA, AND GRB USED AS WORK REGISTERS                           02600000
         EJECT                                                          02620000
         USING *,SRB                    USING SRB                       02640000
*                                                                       02660000
*  INITIALIZE                                                           02680000
*                                                                       02700000
         SR    GR0,GR0                                                  02720000
         ST    GR0,TERMS                ZERO TO TERMS                   02740000
         MVC   TERMS+1(139),TERMS       ZERO ON THROUGH LREF            02760000
         STH   GR0,STLONG(ACT)          ZERO TO STLONG(ACT)             02780000
         STM   GRA,GRB,REGSAV                                           02800000
         NI    CTLCRI(ACT),X'BF'        SET BIT FOR LOC. CNTR. REF. OFF 02820000
         LM    GRZ,GRY,NPTR             INITIALIZE GRX,GRY,GRZ,         02840000
         LA    GR2,RLIST                          AND GR2.              02860000
         ST    SP1,FTXPPT              SAV PT TO FIRST BYTE OF EXP      02880000
         XC    OTHERR(1),OTHERR         CLEAR SWITCH             A39650 02890000
*                                                                       02900000
*  SCAN OF THE EXPRESSION FOR TERMS OR OPERATORS                        02920000
*                                                                       02940000
LOOK     CLI   0(SP1),IALPHA            IS CHAR. ALPHANUMERIC           02960000
         BH    NOTAM                    NO, GO LOOK FOR SPECIAL CHAR'S  02980000
         ST    SP1,ERRPT               SAV PT TO FIRST BYTE OF TERM     03000000
         STM   GRZ,GRY,SAVE             SAVE 3 WORK REGISTERS           03020000
         CLI   0(SP1),IA                IS CHAR. A NUMBER               03040000
         BL    DEC                      YES, GO TREAT DECIMAL S.D.T.    03060000
         CLI   1(SP1),IQUOTE            IS NEXT CHAR. A QUOTE           03080000
         BE    NEXTQ                    YES, GO LOOK AT FOLLOWING CHAR. 03100000
*                                                                       03120000
*  SYMBOL IN THE EXPRESSION                                             03140000
*                                                                       03160000
SYM      CLI   COND,2                   IS COND GR THAN 2               03180000
         BH    ERR10                    BAD SHOW, TWO CONSEC. TERMS     03200000
         SR    GR0,GR0                  FORM A ZERO, AND                03220000
         ST    GR0,0(GRX)               ZERO TO TERMS LIST              03240000
         CLI   LREF,0                  IS L'SYMBOL                      03260000
         BE    TRYSWB                   NO..GO LOOK IN SYMBOL WK-BUCKET 03280000
         CLI   0(SP1),IMULT            IS L'*                           03300000
         BNE   TRYSWB                  NO                               03320000
         MVI   3(GRX),1                1 TO TERMS LIST                  03340000
         MVI   LREF,0                  CLEAR LREF                       03360000
         MVN   LREF(1),F8INST+15(ACT)  MOVE IN LENGTH ATTRIBUTE         03380000
         CLI   LREF,2                   IS IT ZERO OR ONE               03400000
         BL    ATTR1                    YES, GIVE VALUE OF 1            03420000
         CLI   LREF,8                   IS IT GREATER THAN 8            03440000
         BH    ATTR1                    YES, SET VALUE OF 8             03460000
         MVC   3(1,GRX),LREF           PUT L'* VALUE IN TERMS LIST      03480000
ATTR1    LA    SP1,1(SP1)              POSITION SP1 TO CHAR. AFTER *    03500000
         B     LSTAR                                                    03520000
*                                                                       03540000
*  LOOK FOR SYMBOL VALUE IN WORK BUCKET                                 03560000
*                                                                       03580000
*                                                                       03600000
* CTXWBP(ACT), FULL WORD ALIGNED, POINTS TO 'NEXT' SYMBOL WORK BUCKET.  03620000
* WHEN ZERO, THERE IS NO 'NEXT' SYMBOL WORK BUCKET.                     03640000
*                                                                       03660000
TRYSWB   L     SP2,CTXWBP(ACT)         POINTER TO NEXT SYM. WK-BUCKET   03680000
         LTR   SP2,SP2                  IS THERE A NEXT SYM. WK-BUCKET  03700000
         BZ    TRYST                    NO, TRY IN SYMBOL TABLE         03720000
         LR    GR1,SP2                  YES, LOAD WORK-BUCKET POINTER   03740000
         LA    GR1,6(GR1)               BUMP POINTER TO SYM. WK-BUCKET  03760000
         ST    GR1,CTXWBP(ACT)                    BY 6                  03780000
         TM    TXSUBS(SP2),X'10'        IS VALUE IN WORK-BUCKET         03800000
         BO    WBFND                    YES, DONT SEARCH SYMBOL TABLE   03820000
*                                                                       03840000
*  LOOK FOR SYMBOL VALUE IN SYMBOL TABLE                                03860000
*                                                                       03880000
TRYST    STM   SRB,GR2,NCOMP                                            03900000
         SR    SP2,SP2                  SET LENGTH UNKNOWN              03920000
         L     SRB,CSTGET(ACT)          FIND ADDRESS OF STGETR          03940000
         BALR  SRR,SRB                  AND SEARCH SYMBOL TABLE         03960000
         DROP  SRB                 THAT STGETR CALL BUGGERED SRB        03980000
         USING *,SRR               BUT SRR IS UNDER CONTROL...USE IT    04000000
         LTR   GR1,SP1                  ENTRY ADDRESS, OR ZERO IN SP1   04020000
         LR    GR0,SP2                  SYMBOL LENGTH IN SP2            04040000
         LM    SRB,GRY,NCOMP            RESTORE REGS..SRB IS OK REG NOW 04060000
         DROP  SRR                      SO LET'S DON'T USE SRR          04080000
         USING EEVAL,SRB                WELL, WE MUST USE SOME REG      04100000
         L     GR2,NCOMP+40             RESTORED ALL BUT GR0,GR1 NOW    04120000
         BC    7,FOUND                  BRANCH IF SYMBOL HAS BEEN FOUND 04140000
*                                                                       04160000
*  SYMBOL NOT FOUND IN EITHER A WORK BUCKET OR THE SYMBOL TABLE         04180000
*                                                                       04200000
         MVI   TERMS,0                                                  04220000
         MVC   TERMS+1(96),TERMS        ZERO TERMS, RLIST AND RCNTR     04240000
         LA    GR1,X'08'                                                04260000
         CLR   GR0,GR1                  TEST SYMBOL LENGTH              04280000
         BNL   ERR3                     MORE THAN 8 CHARACTERS          04300000
         STM   SRB,GR2,NCOMP            1-8 CHARACTERS IN SYM, SAVE REC 04320000
         LR    FRB,GR0                                                  04340000
         BAL   GR2,XREF                 LOG CROSS-REF                   04360000
         LM    FRB,GR2,NCOMP+16        RESTORE REGS                     04380000
         B     ERR15                    SYMBOL NOT FOUND                04400000
SCANE    LA    SP1,1(SP1)               SCAN TO END OF SYMBOL           04420000
COND3    EQU   SCANE                                                    04440000
         CLI   0(SP1),IPLUS             SEE IF AT END OF SYMBOL         04460000
         BL    SCANE                    NO, TRY AGAIN                   04480000
         B     COMPT4                   YES, START AGAIN                04500000
*                                                                       04520000
*  SYMBOL VALUE FOUND IN SYMBOL TABLE                                   04540000
*                                                                       04560000
FOUND    STM   SRB,GR2,NCOMP            SAVE REGS                       04580000
         LR    FRB,GR0                                                  04600000
         BAL   GR2,XREF                 LOG CROSS-REF.                  04620000
         LM    FRB,GR2,NCOMP+16        RESTORE REGS                     04640000
         AR    SP1,GR0                  ADD SYMBOL LENGTH TO POINTER    04660000
         LA    SP1,1(SP1)                                               04680000
         CLI   LREF,0                   IS L'SYMBOL                     04700000
         BH    LSYM                     YES, BRANCH                     04720000
         TM    1(GR1),3                 IS THIS A NAME                  04740000
         BM    SETSW                     DSECT OR COMMON         A45780 04750021
         BC    14,ESDMV                NO                               04760000
         CLI   SYMBL,0                  IS THIS THE FIRST TERM          04780000
         BH    MOVE                     NO, BRANCH                      04800000
         MVC   STLONG(2,ACT),6(GR1)     LENGTH TO STLONG                04820000
MOVE     MVC   1(3,GRX),3(GR1)          VALUE TO TERMS LIST             04840000
         CLI   2(GR1),0                 IS ABSOLUTE TERM                04860000
         BE    COMPT4                   YES, BRANCH                     04880000
         TM    1(GR1),X'04'             IS SYMBOL DEF AS EXTRN   A45780 04888021
         BZ    ESDMV                    BRANCH IF NOT            A45780 04896021
SETSW    XI    CTEXENSW(ACT),X'04'      SET SWITCH TO TELL ENTRY A45780 04904021
ESDMV    MVC   1(1,GR2),2(GR1)          ESD-ID TO RLIST          A45780 04912021
*                                                                       04920000
OUT      MVI   COND,4                  SET COND=4                       04940000
         MVI   0(GR2),1                 CODE FOR + SIGN = 1 TO RLIST    04960000
         IC    GR1,RCNTR                BUMP RCNTR BY 1 (RELOCATABLE)   04980000
         LA    GR1,1(GR1)                                               05000000
         STC   GR1,RCNTR                SAVE RCNTR                      05020000
         B     COMPT                    FIX UP TO GO ON                 05040000
*                                                                       05060000
*  SYMBOL VALUE FOUND IN WORK BUCKET                                    05080000
*                                                                       05100000
WBFND    SR    GRA,GRA                                                  05120000
         STM   SRB,GR2,NCOMP           SAVE REGS                        05140000
WBFNDX   LA    SP1,1(SP1)               SCAN TO END OF SYMBOL           05160000
         LA    GRA,1(GRA)              CNTR FOR LENGTH OF SYM MINUS 1   05180000
         CLI   0(SP1),IPLUS             IS IT STILL PART OF SYMBOL      05200000
         BL    WBFNDX                   YES, CONTINUE SCAN              05220000
         BCTR    GRA,0                 DECREMENT SYMBOL LENGTH BY 1     05240000
         ST    SP1,REGSAV1             SAVE PTR TO END OF SYMBOL        05260000
         LR    FRB,GRA                                                  05280000
         BAL   GR2,XREF                 LOG CROSS-REF                   05300000
         L     SP1,REGSAV1             RESTORE PTR TO END OF SYMBOL     05320000
         LM    FRB,GR2,NCOMP+16        RESTORE REGS                     05340000
         CLI   LREF,0                   IS L'SYMBOL                     05360000
         BH    LSYMWB                   YES, PROCESS L'                 05380000
         TM    TXSTPC(SP2),X'03'       IS THIS A NAME                   05400000
         BM    WBSETSW                  DSECT, COMMON OR EXTRN   A45780 05410021
         BC    14,WBESDMV              NO                               05420000
         CLI   SYMBL,0                  IS THIS THE FIRST TERM          05440000
         BH    WBFNDY                   NO, SKIP FIRST TERM PROCESSING  05460000
         MVC   STLONG+1(1,ACT),TXSLEN(SP2)                              05480000
         TM    TXSEXI(SP2),X'04'        IS LENGTH GR THAN 256           05500000
         BZ    WBFNDY                   NO, LEAVE AS IS                 05520000
         MVI   STLONG(ACT),255          SET FIRST BYTE OF STLONG =255   05540000
WBFNDY   MVC   1(3,GRX),TXSVAL(SP2)     VALUE TO TERMS LIST             05560000
         CLI   TXSESD(SP2),0           IS ABSOLUTE TERM                 05580000
         BE    COMPT4                                                   05600000
         TM    TXSDOC(SP2),X'20'        DEF AS EXTRN             A45780 05610021
         BZ    WBESDMV                  NO,BRANCH                A45780 05612021
WBSETSW  XI    CTEXENSW(ACT),X'04'      SET SWITCH               A45780 05614021
WBESDMV  MVC   1(1,GR2),TXSESD(SP2)    ESD-ID TO RLIST                  05620000
         B     OUT                                                      05640000
*                                                                       05660000
* BUILD TYPE 2  CROSS-REFERENCE RECORD                                  05680000
*                                                                       05700000
XREF     TM    CTXRFI(ACT),X'02'       X-REF OPTION?                    05720000
         BZ    NOXREF                  OFF                              05740000
         TM    F8YDC+1(ACT),X'03'       IS THIS LITERAL ADCON    A28596 05746020
         BO    XREFA                    IF YES, MAKE XREF        A28596 05752020
         TM    CTMODE(ACT),X'60'        YES, ASSIGNMENT MODE?           05760000
         BNE   NOXREF                   NO                              05780000
XREFA    L     SRB,CTXTIO(ACT)          YES                      A28596 05800020
         BAL   SRR,PUTXRF(SRB)          TO PUT-CROSS-REFERENCE          05820000
         DROP  SRB                      PUT CROSS REF DISTROYS OUR BASE 05840000
         USING *,SRR                    SO SET UP TEMPARY BASE,         05860000
         LR    GR1,SP1                  GR1 POINTS TO CROSS-REF. RECORD 05880000
         LM    SRB,SP2,NCOMP                                            05900000
*                                               GRX,GRY,GR0             05920000
         DROP  SRR                      HAVE RESTORED OUR BASE          05940000
         USING EEVAL,SRB                SO GO BACK TO USING IT          05960000
         MVI   1(GR1),IBLANK            BLANKS TO SYMBOL FIELD IN       05980000
         MVC   2(6,GR1),1(GR1)            XREF RECORD                   06000000
         EX    FRB,MVSYM               MOVE SYMBOL                      06020000
         L     FRB,CTRTBP(ACT)                                          06040000
         TR    0(8,GR1),0(FRB)         TRANSLATE SYM. TO EXTERNAL CODE  06060000
         MVI   8(GR1),X'F1'      SET XREF RECORD TYPE                   06080000
         MVC   9(2,GR1),CTSEQN+2(ACT)  MOVE CURRENT STMNT. NO. TO XREF  06100000
NOXREF   LM    SRB,SP2,NCOMP                                            06120000
         BR    GR2                      RETURN                          06140000
*                                                                       06160000
MVSYM    MVC   0(0,GR1),0(SP1)          EXECUTED MOVE                   06180000
*                                                                       06200000
*  L'SYMBOL VALUE FOUND IN SYMBOL TABLE                                 06220000
*                                                                       06240000
LSYM     TM    1(GR1),3                 IS THIS A NAME                  06260000
         BC    14,UPLSYM                NO                              06280000
MOVEL    MVC   2(2,GRX),6(GR1)          LENGTH TO TERMS LIST            06300000
         B     UPLSYM                                                   06320000
*                                                                       06340000
*  L'SYMBOL VALUE FOUND IN WORK BUCKET                                  06360000
*                                                                       06380000
LSYMWB   MVC   1(3,GRX),TXSVAL(SP2)    LENGTH TO TERMS LIST        6822 06400000
UPLSYM   L     GR1,0(GRX)                                               06420000
         LA    GR1,1(GR1)                                               06440000
         ST    GR1,0(GRX)               BUMP VALUE OF L'SYMBOL BY 1     06460000
LSTAR    MVI   LREF,0                  SET LREF TO ZERO                 06480000
         B     COMPT4                   GO ON                           06500000
*                                                                       06520000
*  DECIMAL SELF-DEFINING VALUE IN THE EXPRESSION                        06540000
*                                                                       06560000
DEC      LA    SHFR,3                   DEC. TYPE INDICATOR TO SHFR     06580000
         BAL   RETR,SDVCF               TO SELF-DEFINING VALUE ROUTINE  06600000
         LA    GR0,8                    MAX. NO. OF CHAR. TO GR0        06620000
         LM    GRZ,GRY,SAVE             RE-LOAD SAVED REGISTERS         06640000
         ST    VALR,0(GRX)              VALUE TO TERMS LIST             06660000
         CLI   0(GRX),0                 IS FIRST BYTE ZERO              06680000
         BH    ERR0                     NO, ERROR - TOO LARGE           06700000
         B     ABSD                                                     06720000
*                                                                       06740000
*  1ST CHARACTER IS ALPHABETIC AND 2ND IS A QUOTE                       06760000
*                                                                       06780000
NEXTQ    CLI   0(SP1),IB                IS BINARY SELF-DEF. VALUE       06800000
         BE    BINRY                    YES, CONVERT FROM BINARY        06820000
         CLI   0(SP1),IC                IS CHARACTER SELF-DEF. VALUE    06840000
         BE    CHARS                    YES, CONVERT FROM CHARACTER     06860000
         CLI   0(SP1),IX                IS HEXADECIMAL SELF-DEF. VALUE  06880000
         BE    HEX                      YES, CONVERT FROM HEX           06900000
         CLI   0(SP1),IL                IS L'SYMBOL                     06920000
         BNE   ERR9                     NO, ERROR - ILLEGAL CHAR        06940000
*                                                                       06960000
*  L'SYMBOL IN THE EXPRESSION                                           06980000
*                                                                       07000000
         LA    SP1,2(SP1)               POINT SP1 TO 1ST CHAR. OF SYM.  07020000
         MVI   LREF,X'FF'               SET L'SYMBOL FLAG NON-ZERO      07040000
         CLI   0(SP1),IALPHA           IS CHAR. ALPHANUMERIC            07060000
         BNH   ALPHA                   YES                              07080000
MAYLCNTR CLI   0(SP1),IMULT            IS CHAR. *                       07100000
         BNE   ERR9                    NO,  ERROR - ILLEGAL CHAR        07120000
ALPHA    CLI   0(SP1),IA               IS CHAR. ALPHABETIC              07140000
         BL    ERR9                    NO,  ERROR - ILLEGAL CHAR        07160000
*                                                                       07180000
* IN WORK BUCKET, VALUE = LENGTH.                                       07200000
* IN SYMBOL TABLE, PICK UP LENGTH ATTRIBUTE PART OF SYMBOL.             07220000
*                                                                       07240000
         B     SYM                                                      07260000
*                                                                       07280000
*  BINARY SELF-DEFINING VALUE IN THE EXPRESSION                         07300000
*                                                                       07320000
BINRY    LA    SHFR,1                   BINARY TYPE INDICATOR TO SHFR   07340000
         LA    SP1,2(SP1)               POSITION SP1 TO FIRST CHAR.     07360000
         BAL   RETR,SDVCF               TO SELF-DEFINING VALUE ROUTINE  07380000
         LA    GR0,24                   MAX. NO. OF CHAR. TO GR0        07400000
         B     LM                                                       07420000
*                                                                       07440000
*  CHARACTER SELF-DEFINING VALUE IN THE EXPRESSION                      07460000
*                                                                       07480000
CHARS    LA    SP1,2(SP1)               POSITION SP1 TO FIRST CHAR.     07500000
         LA    SHFR,8                   CHAR. TYPE INDICATOR TO SHFR    07520000
         BAL   RETR,SDVCF               TO SELF-DEFINING VALUE ROUTINE  07540000
         LA    GR0,3                    MAX. NO. OF CHAR. TO GR0        07560000
         LM    GRZ,GRY,SAVE             RE-LOAD SAVED REGISTERS         07580000
         ST    VALR,0(GRX)              VALUE TO TERMS LIST             07600000
         L     SP2,CTRTBP(ACT)          POINTER TO TRANSLATE TABLE      07620000
         TR    0(4,GRX),0(SP2)          TRANSLATE CHAR. VALUE           07640000
         B     CKQ                                                      07660000
*                                                                       07680000
*  HEXADECIMAL SELF-DEFINING VALUE IN THE EXPRESSION                    07700000
*                                                                       07720000
HEX      LA    SHFR,4                   HEX TYPE INDICATOR TO SHFR      07740000
         LA    SP1,2(SP1)               POSITION SP1 TO FIRST CHAR.     07760000
         BAL   RETR,SDVCF               TO SELF-DEFINING VALUE ROUTINE  07780000
         LA    GR0,6                    MAX. NO. OF CHAR. TO GR0        07800000
LM       LM    GRZ,GRY,SAVE             RE-LOAD SAVED REGISTERS         07820000
         ST    VALR,0(GRX)              VALUE TO TERMS LIST             07840000
CKQ      CLI   0(SP1),IQUOTE            IS ENDING CHAR. A QUOTE         07860000
         BNE   ERR9                     NO, ERROR - ILLEGAL CHAR        07880000
         LA    SP1,1(SP1)               POSITION SP1 TO CHAR. AFTER '   07900000
         LTR   CNTR,CNTR                IS CNTR ZERO                    07920000
         BZ    ERR9                     YES, ERROR - ILLEGAL CHAR       07940000
ABSD     CLR   CNTR,GR0                 IS CNTR GR THAN MAX.            07960000
         BH    ERR0                     YES, ERROR - TOO MUCH           07980000
         CLI   COND,0                   IS COND ZERO                    08000000
         BH    ABSCK                    NO, TEST FOR GT 2               08020000
         TM    CTSDVI(ACT),X'80'        IS BIT FOR SELF-DEF. VALUE ON   08040000
         BZ    ABSCK+8                                                  08060000
         NI    CTSDVI(ACT),X'7F'        SET THE BIT OFF                 08080000
         B     FINIS                                                    08100000
ABSCK    CLI   COND,2                   IS COND GR THAN 2               08120000
         BH    ERR10                    YES, ERROR - TWO CONSECUTIVE TR 08140000
COMPT4   MVI   COND,3                  SET COND=3                       08160000
COMPT    CL    GR2,COMP1                ARE THERE TOO MANY TERMS        08180000
         LA     GRB,MNYERR              TOO MANY TERMS                  08200000
         BH    FATLER1                                                  08220000
         OI    SYMBL,1                  OR SYMBL WITH 1                 08240000
         MVI   0(GRZ),2                 2 TO NTRMS LIST                 08260000
         LA    GRZ,1(GRZ)               BUMP GRZ BY 1 (FOR NTRMS)       08280000
         LA    GRX,4(GRX)               BUMP GRX BY 4 (FOR TERMS)       08300000
         LA    GR2,2(GR2)               BUMP GR2 BY 2 (FOR RLIST)       08320000
         B     LOOK                     GO ON IN CARD                   08340000
*                                                                       08360000
*  1ST CHARACTER IS NOT ALPHANUMERIC                                    08380000
*                                                                       08400000
NOTAM    CLI   0(SP1),ICOMMA            IS CHAR. A COMMA                08420000
         BL    LTCOM                    NO, IS A +,-,*, OR /            08440000
         BE    BLCOM                    YES, GO TO BLANK OR COMMA       08460000
         CLI   0(SP1),ILPARN            IS CHAR. A LEFT PAREN.          08480000
         BE    LPAR                     YES                             08500000
         BL    ERR9                     ERROR - ILLEGAL CHAR            08520000
         CLI   0(SP1),IQUOTE            IS CHAR. A ' OR ) OR BLANK      08540000
         BL    RPAR                     RIGHT PARN                      08560000
         BH    BLCOM                    BLANK                           08580000
         B     ERR9               ' IS ILLEGAL FIRST CHAR.              08600000
*                                                                       08620000
*  RIGHT PARENTHESIS IN THE EXPRESSION                                  08640000
*                                                                       08660000
RPAR     CLI   COND,3                   IS COND =3 (FOR RIGHT PAREN)    08680000
         BL    ERR12                    NO, ERROR - TWO CONSECUTIVE OPS 08700000
         MVI   COND,3                   SET COND=3                      08720000
         CLI   PCNTR,0                  IS PCNTR =0                     08740000
         BH    NOEND                    NO                              08760000
         B     ENDNG                    YES                             08780000
*                                                                       08800000
*  1ST CHARACTER IS EITHER +,-,*, OR /.                                 08820000
*                                                                       08840000
LTCOM    CLI   0(SP1),IASTER            IS CHAR. AN ASTERISK            08860000
         BE    STAR                     YES                             08880000
         BH    SLASH                    BRANCH IF /                     08900000
*                                                                       08920000
*  + OR - IN THE EXPRESSION                                             08940000
*                                                                       08960000
PLMIN    CLI   COND,3                   IS COND GT 2                    08980000
         BL    ERR12                    NO, ERROR - TWO CONSECUTIVE OPS 09000000
         MVI   COND,1                   SET COND=1                      09020000
SET      LA    GR0,IALPHA                                               09040000
         IC    GR1,0(SP1)                                               09060000
         SR    GR1,GR0                                                  09080000
         STC   GR1,NEWOP                HIERARCHY CODE TO NEWOP         09100000
*                                                                       09120000
*  MAIN LOOP TO PERFORM ARITHMETIC                                      09140000
*                                                                       09160000
LOOP     CL    GRY,OPTR                 ARE THERE PREVIOUS OPERATORS    09180000
         BH    ONZ                      YES                             09200000
         CLI   ENDOE,0                  IS ENDOE=0                      09220000
         BH    FINIS                    NO                              09240000
PUT      MVC   0(1,GRY),NEWOP           NEWOP TO OPRNS LIST             09260000
BUMPY    LA    GRY,1(GRY)               BUMP GRY BY 1 (FOR OPRNS)       09280000
BUMPR    LA    SP1,1(SP1)               BUMP SP1 BY 1 (FOR NON-ALFNUM)  09300000
         B     LOOK                                                     09320000
ONZ      BCTR  GRY,0                    POINT GRY TO PREVIOUS OPERATOR  09340000
         CLC   0(1,GRY),NEWOP           IS NEW HIERARCHY LT-EQ PREVIOUS 09360000
         BNL   LE                       YES                             09380000
         CLI   NEWOP,4                  TEST NEW OP /                   09400000
         BNE   STEPUP                   NO                              09420000
         CLI   0(GRY),3                 TEST PREV OP *                  09440000
         BE    WORK                     YES, DO * FIRST                 09460000
STEPUP   LA    GRY,1(GRY)               ADD 1 BACK TO GRY               09480000
         B     PUT                                                      09500000
LE       CLI   0(GRY),0                 IS OLD HIERARCHY =0             09520000
         BH    WORK                     NO                              09540000
         IC    GR1,PCNTR                SUBTRACT 1 FROM PCNTR           09560000
         BCTR  GR1,0                                                    09580000
         STC   GR1,PCNTR                                                09600000
         B     BUMPR                                                    09620000
*                                                                       09640000
*  LEFT PARENTHESIS IN THE EXPRESSION                                   09660000
*                                                                       09680000
LPAR     CLI   COND,X'02'               POSS. END OF EXP. IF COND GT 2  09700000
         BH    LPEND                    YES, PROCESS END                09720000
         MVI   COND,X'01'               SET COND=1                      09740000
         CLI   PCNTR,X'04'              ARE THERE TOO MANY LEFT PARENS  09760000
         LA    GRB,PARERR              TOO MANY LEVLS OF PARENS         09780000
         BH    FATLER2                  YES, ERROR                      09800000
         IC    GR1,PCNTR                BUMP PCNTR BY 1                 09820000
         LA    GR1,1(GR1)                                               09840000
         STC   GR1,PCNTR                                                09860000
         MVI   0(GRY),0                 ZERO TO OPRNS LIST              09880000
         B     BUMPY                                                    09900000
*                                                                       09920000
*  ASTERISK IN THE EXPRESSION                                           09940000
*                                                                       09960000
STAR     CLI   COND,2                   IS COND LT 2 (FOR *)            09980000
         BE    ERR12                    NO, ERROR - TWO CONSECUTIVE OPS 10000000
         BL    LCNTR                    BRANCH IF LOC CNTR REFERENCE    10020000
*                                                                       10040000
*  ASTERISK IS MULTIPLICATION OPERATOR                                  10060000
*                                                                       10080000
FORD1    MVI   COND,2                   SET COND = 2                    10100000
         B     SET                                                      10120000
*                                                                       10140000
*  SLASH IN THE EXPRESSION                                              10160000
*                                                                       10180000
SLASH    CLI   COND,3                   IS COND =3 (FOR /)              10200000
         BL    ERR12                    NO, ERROR                       10220000
         B     FORD1                                                    10240000
*                                                                       10260000
*  BLANK OR COMMA IN THE EXPRESSION                                     10280000
*                                                                       10300000
BLCOM    CLI   COND,3                   IS COND LT 3 (FOR BLANK OR ,)   10320000
         BL    ERR17                    YES, ERROR                      10340000
*                                                                       10360000
*  LEFT PARENTHESIS END CONDITION                                       10380000
*                                                                       10400000
LPEND    CLI   PCNTR,0                  IS PCNTR =0                     10420000
         BH    ERR17                                                    10440000
ENDNG    MVI   ENDOE,15                 SET ENDOE NON-ZERO              10460000
NOEND    MVI   NEWOP,0                  SET NEWOP ZERO                  10480000
         B     LOOP                                                     10500000
*                                                                       10520000
*  ASTERISK IS LOCATION COUNTER                                         10540000
*                                                                       10560000
LCNTR    OI    CTLCRI(ACT),X'40'        SET BIT FOR LOC. CNTR. REF. ON  10580000
         LA    SP1,1(SP1)               POSITION SP1 TO NEXT CHAR.      10600000
         L     SP2,CTXABP(ACT)          POINTER TO LOC. CNTR.           10620000
         MVC   1(3,GRX),TXLOC(SP2)      LOC. CNTR VALUE TO TERMS LIST   10640000
         MVI   0(GRX),0                                                 10660000
         CLI   SYMBL,0                 IS THIS THE FIRST TERM           10680000
         BH    LCNTR2                  NO                               10700000
         MVN   LREF(1),F8INST+15(ACT)  MOVE IMPLIED EXPRESSION LENGTH   10720000
         CLI   LREF,0                  DONT DECREMENT LREF IF ZERO      10740000
         BZ    LCNTR1                   ZERO, SO DONT                   10760000
         IC    GR1,LREF                TO TEMP LOC                      10780000
         BCTR  GR1,0                   DECREMENT BY 1                   10800000
         STC   GR1,LREF                AND MOVE                         10820000
LCNTR1   MVC   STLONG+1(1,ACT),LREF         TO STLONG                   10840000
         MVI   LREF,0                  SET LREF TO ZERO                 10860000
LCNTR2   MVC   1(1,GR2),CESDID(ACT)    CURRENT ESD-ID TO RLIST          10880000
         B     OUT                                                      10900000
*                                                                       10920000
*  PERFORM ARITHMETIC AND RELOCATABILITY WORK                           10940000
*                                                                       10960000
WORK     ST    GR2,NCOMP                STORE GR2 IN NCOMP              10980000
         LA    GR0,8                    POINT GRX TO 1ST OF THE 2       11000000
         SR    GRX,GR0                       TERMS ENTRIES              11020000
         LA    GR0,2                    POINT GRZ TO 1ST OF THE 2       11040000
         SR    GRZ,GR0                       NTRMS ENTRIES              11060000
         IC    GR0,1(GRZ)               2ND NTRMS  ENTRY TO GR0         11080000
         SR    GR2,GR0                  SUBT. 2ND NTERMS ENTRY FRM GR2  11100000
         CLI   0(GRY),2                 FIND OUT WHAT THE OPERATOR IS   11120000
         BL    OPPLS                    BRANCH IF THIS OPERATOR +       11140000
         BH    MULDV                    BRANCH IF THIS OPERATOR * OR /  11160000
*                                                                       11180000
*  OPERATOR IS SUBTRACTION.  COMPLEMENT 2ND VALUE AND CHANGE THE        11200000
*  RELOCATION SIGN BYTE OF THE TERMS IN THE 2ND VALUE.                  11220000
*                                                                       11240000
         L     GR1,4(GRX)                                               11260000
         LCR   GR1,GR1                  COMPLEMENT 2ND TERMS LIST ENTRY 11280000
         ST    GR1,4(GRX)                                               11300000
CHG      CLI   0(GR2),1                 TEST SIGN BYTE IN 2ND RLIST     11320000
         BL    NOCHG                    BRANCH IF ABS. VALUE            11340000
         BE    PLCHG                    BRANCH IF SIGN +                11360000
         MVI   0(GR2),1                 CHANGE SIGN TO +                11380000
         B     NOCHG                                                    11400000
PLCHG    MVI   0(GR2),2                 CHANGE SIGN TO -                11420000
NOCHG    LA    GR2,2(GR2)               POINT GR2 TO NEXT ENTRY         11440000
         CL    GR2,NCOMP                ARE THERE MORE ENTRIES          11460000
         BL    CHG                      BRANCH BACK IF MORE ENTRIES     11480000
         SR    GR2,GR0                  SUBT. 2ND NTERMS ENTRY FRM GR2  11500000
*                                                                       11520000
*  OPERATION IS ADDITION OR SUBTRACTION.  SCRATCH ENTRIES IN THE        11540000
*  RELOCATION LIST WHERE POSSIBLE.                                      11560000
*                                                                       11580000
OPPLS    IC    GR0,0(GRZ)               1ST NTRMS  ENTRY TO GR0         11600000
         LR    GR1,GR2                  POINT GR1 TO 2ND NTRMS LIST     11620000
         SR    GR2,GR0                  POINT GR2 TO 1ST NTRMS LIST     11640000
         LR    SP2,GR1                  SAVE GR1 IN SP2                 11660000
BCOMP    CLI   0(GR2),1                 IS FIRST SIGN + (CODE =1)       11680000
         BL    NSCR                     BRANCH IF ABS. VALUE (CODE =0)  11700000
         BH    F2                       BRANCH IF SIGN - (CODE =2)      11720000
         CLI   0(GR1),2                 IS SECOND SIGN -                11740000
         BL    NSCR                     BRANCH IF SIGN NOT -            11760000
OPP      CLC   1(1,GR2),1(GR1)          COMPARE FIRST TO SECOND ESD-ID  11780000
         BNE   NSCR                     BRANCH IF NOT THE SAME          11800000
         MVI   0(GR2),0                 ZERO TO FIRST SIGN              11820000
         MVI   1(GR2),0                 ZERO TO FIRST ESD-ID            11840000
         MVC   0(2,GR1),0(GR2)          ZERO TO 2ND SIGN AND ESD-ID     11860000
         IC    GR0,RCNTR                SUBTRACT 2 FROM RCNTR           11880000
         BCTR  GR0,0                                                    11900000
         BCTR  GR0,0                                                    11920000
         STC   GR0,RCNTR                                                11940000
         B     NSCR                                                     11960000
F2       CLI   0(GR1),1                 IS SECOND SIGN +                11980000
         BE    OPP                      YES                             12000000
NSCR     LA    GR1,2(GR1)               POINT GR1 TO NEXT IN 2ND RLIST  12020000
         CL    GR1,NCOMP                                                12040000
         BL    BCOMP                    BRANCH BACK IF MORE IN 2ND LIST 12060000
         LA    GR2,2(GR2)               POINT GR2 TO NEXT IN 1ST LIST   12080000
         LR    GR1,SP2                  START OF 2ND LIST BACK TO GR1   12100000
         CLR   GR1,GR2                                                  12120000
         BH    BCOMP                    BRANCH BACK IF MORE IN 1ST LIST 12140000
         L     GR2,NCOMP                NCOMP BACK TO GR2               12160000
         LCR   GR1,GR1                  COMPLEMENT GR1                  12180000
         AR    GR1,GR2                  2ND NTRMS ENTRY TO GR1          12200000
         IC    GR0,0(GRZ)               1ST NTRMS ENTRY TO GR0          12220000
         AR    GR1,GR0                  ADD THE 2 NTRMS ENTRIES         12240000
         STC   GR1,0(GRZ)               SUM TO POSITION OF THE 1ST      12260000
*                                                                       12280000
*  PERFORM ADDITION                                                     12300000
*                                                                       12320000
         L     GR1,0(GRX)               1ST TERMS LIST ENTRY TO GR1     12340000
         A     GR1,4(GRX)               ADD 2ND ENTRY                   12360000
         BO    ERR13             -DUMMY-APPROP. OVERFLOW ROUTINE TO SYS 12380000
STORE    ST    GR1,0(GRX)               RESULT TO 1ST TERMS LIST ENTRY  12400000
         LA    GRX,4(GRX)               BUMP GRX BY 4 (FOR TERMS LIST)  12420000
         LA    GRZ,1(GRZ)               BUMP GRZ BY 1 (FOR NTRMS LIST)  12440000
         B     LOOP                                                     12460000
*                                                                       12480000
*  OPERATOR IS MULTIPLICATION OR DIVISION.  CHECK THAT NO RELOCATABLE   12500000
*  TERMS REMAIN IN THE 2 VALUES.                                        12520000
*                                                                       12540000
MULDV    SR    GR1,GR1                  CLEAR GR1                       12560000
         IC    GR1,0(GRZ)               1ST NTERMS ENTRY TO GR1         12580000
         AR    GR0,GR1                  ADD THE 2 NTRMS ENTRIES         12600000
         STC   GR0,0(GRZ)               SUM TO 1ST ENTRY LOCATION       12620000
         SR    GR2,GR1                  SUBT. 1ST NTRMS ENTRY FROM GR2  12640000
         LA    GR0,2                    2 TO GR0                        12660000
         L     GR1,NCOMP                                                12680000
         SR    GR1,GR0                  C(NCOMP)-2 TO GR1               12700000
MORE     CLI   0(GR2),0                 IS IT A RELOCATABLE VALUE       12720000
         BH    ERR11                    YES, LOG ERROR                  12740000
MORE1    BXLE  GR2,GR0,MORE                                             12760000
         SR    GR1,GR1                  ZERO GR1                        12780000
         C     GR1,4(GRX)                                               12800000
         BE    STORE                    BRANCH IF 2ND TERMS ENTRY =0    12820000
         L     GR0,0(GRX)               1ST TERMS ENTRY TO GR0          12840000
         SRDA  GR0,32                   PROPAGATE SIGN BIT              12860000
         CLI   0(GRY),3                 IS OPERATOR * OR /              12880000
         BH    DIV                      BRANCH IF /                     12900000
*                                                                       12920000
*  PERFORM MULTIPLICATION                                               12940000
*                                                                       12960000
         M     GR0,4(GRX)               MULTIPLY BY 2ND TERMS ENTRY     12980000
         LTR   GR1,GR1                                                  13000000
         BNL   CHK0                     BRANCH IF LOW-ORDER NON-NEG     13020000
         LCR   GR0,GR0                  COMPLEMENT HIGH-ORDER           13040000
         BCTR  GR0,0                    SUBTRACT 1 FROM THE COMPLEMENT  13060000
CHK0     LTR   GR0,GR0                  SEE IF ZERO                     13080000
         BC    7,ERR13                  ERROR  IF HIGH-ORDER NOW NOT=0  13100000
         B     STORE                                                    13120000
*                                                                       13140000
*  PERFORM DIVISION                                                     13160000
*                                                                       13180000
DIV      D     GR0,4(GRX)               DIVIDE 1ST BY 2ND TERMS ENTRY   13200000
         B     STORE                                                    13220000
*                                                                       13240000
*  END OF EXPRESSION FOUND                                              13260000
*                                                                       13280000
FINIS    TM    F8YDC+1(ACT),X'01'       IS THIS ADCON                   13300000
         BO    NOTST                    YES,ADCON MAY BE 4 BYTES        13320000
         BAL   GRZ,DATATST              RESULT MUST NOT EXCEED 3 BYTES  13340000
NOTST    L     SP2,TERMS                MOVE RESULT TO SP2              13360000
         ST    SP2,RLIST-4              RESULT TO HEAD RLIST            13380000
         LM    GRA,GRB,REGSAV                                           13400000
         NI    CTPDSI(ACT),X'DF'        TURN OFF                        13420000
         CLI   ERROR,0                  WAS THERE AN ERROR              13440000
         BH    SETE                     YES, SET ERROR CODE             13460000
         CLI   RCNTR,0                  DOES IT CONTAIN RELOCAT TERM    13480000
         BCR   8,SRR                    RETURN WITH CC=0 (ABSOLUTE EXP) 13500000
         LA    SP2,RLIST-4              POINTER TO RESULT TO SP2        13520000
         CLI   RCNTR,1                  IS IT COMPLEX RELOCATABLE       13540000
         BCR   2,SRR                    RETURN WITH CC=2 (COMPLX REL.)  13560000
         LA    GR1,RLIST-2              FIND FIRST AND ONLY RLIST ENTRY 13580000
FIND     LA    GR1,2(GR1)                    WHERE SIGN BYTE NON-ZERO   13600000
         CLI   0(GR1),1                 IS THIS IT                      13620000
         BL    FIND                     NO, KEEP LOOKING                13640000
         BCR   2,SRR                    RETURN WITH CC=2 (COMPLX REL.)  13660000
         MVC   RLIST(2),0(GR1)          MOVE ENTRY TO TOP OF LIST       13680000
         CLI   0(GR1),2                 SET CC =1                       13700000
         BR    SRR                      RETURN WITH CC=1 (SIMPLY REL.)  13720000
*                                                                       13740000
DATATST  TM    TERMS,X'FF'              VALUE EXCEEDS 3 BYTES           13760000
         BC    11,DATAOK                NO                              13780021
         STM   SRB,GR2,NCOMP                                            13800000
         L     SP1,FTXPPT               SET COL PTR TO 1ST BYTE         13820000
         L     SRB,CLOGER(ACT)          TO LOGERR                       13840000
         BALR  SRR,SRB                                                  13860000
         DROP  SRB                                                      13880000
         USING *,SRR                                                    13900000
         DC    AL2(VALTOLG)             ERROR CODE                      13920000
         LM    SRB,GR2,NCOMP                                            13940000
         DROP  SRR                                                      13960000
         USING EEVAL,SRB                                                13980000
DATAOK   MVI   TERMS,0                  ZERO 1ST BYTE OF RESULT         14000000
         BR    GRZ                                                      14020000
*                                                                       14040000
*                                                                       14060000
*  ERROR FOUND                                                          14080000
*                                                                       14100000
* TABLE OF ERROR CODES USED IN EEVAL                                    14120000
INVALID  EQU   18                       INVALID SYMBOL                  14140000
RELERR   EQU   25                  RELOCATABILITY ERROR                 14160000
SELFDEF  EQU   91                  SELF-DEF. VALUE TOO LARGE            14180000
ARITHER  EQU   56                  ARITHMETIC ERROR-OVERFLOW            14200000
PDSERR   EQU   21                  SYMBOL MUST BE PREVIOUSLY DEFINED    14220000
ILORDER  EQU   85                  TWO TERMS NOT SEPARATE               14240000
ILLCHAR  EQU   85                  ILLEGAL CHARACTER                    14260000
MNYERR   EQU   27                  EXP. CONTAINS MORE THAN 16 TERMS     14280000
OPERR    EQU   85                  TWO OPERATORS ILLEGALLY COUPLED      14300000
PARERR   EQU   26                  TOO MANY LEVELS OF PARENS            14320000
ENDERR   EQU   39                  EXP. END PREMATURE-UNPAIRED PAREN    14340000
VALTOLG  EQU   110              VALUE EXCEEDS RANGE                     14360000
* NON-FATAL ERROR FOUND                                                 14380000
* LOG ERROR, CONTINUE NORMAL PROCESSING                                 14400000
*                                                                       14420000
*  ERROR IS RELOCATABLE TERM INVOLVED IN A MULT. OR DIV. OPERATION      14440000
*                                                                       14460000
ERR11    LA    GRA,MORE1                                                14480000
         TM    CTPDSI(ACT),X'20'       PREV.DEF. SYM. SWITCH ON         14500000
         BCR   14,GRA                  NO, DONT LOG  ERROR       A39650 14540000
         CLI   OTHERR,NOTFOUND          ANY SYMBOL NOT FOUND     A39650 14546000
         BCR   8,GRA                    YES, DONT LOG ERROR      A39650 14552000
ERR11A   LA    GRB,RELERR              RELOCATABILILTY ERROR            14560000
         B     NFATLER1                                                 14580000
*                                                                       14600000
*  ERROR IS SELF-DEFINING VALUE TOO LARGE                               14620000
*                                                                       14640000
ERR0     LA    GRA,ABSD+6                                               14660000
         LA    GRB,SELFDEF         SELF-DEF. VALUE TOO LARGE            14680000
         B     NFATLER2                                                 14700000
*                                                                       14720000
* ERROR IS SYMBOL LENGTH                                                14740000
*                                                                       14760000
ERR3     LA    GRA,SCANE                                                14780000
         LA    GRB,INVALID              SYMBOL TOO LONG                 14800000
         B     ERRXXX                                                   14820000
*                                                                       14840000
*                                                                       14860000
*  ERROR IS ARITHMETIC                                                  14880000
*                                                                       14900000
ERR13    LA    GRA,STORE                                                14920000
         CLI   OTHERR,NOTFOUND          SHOULD IT BE FLAGGED     A39650 14926000
         BCR   8,GRA                    NO CONTINUE              A39650 14932000
         LA    GRB,ARITHER         ARITHMETIC ERROR                     14940000
         B     NFATLER1                                                 14960000
*                                                                       14980000
* ERROR IS SYMBOL NOT FOUND OR SYMBOL MUST BE PREVIOUSLY DEFINED        15000000
*                                                                       15020000
ERR15    LA    GRA,SCANE                                                15040000
         TM    CTMODE(ACT),X'60'   PHASE 7, ASSIGNMENT MODE?            15060000
         BNE   ERR15A              NOT ZERO, DONT LOG ERROR             15080000
         TM    CTPDSI(ACT),X'20'        YES,PREV.-DEF. SYM. SWITCH ON ? 15100000
         BO    ERR15C                  YES                              15120000
ERR15A   OI OTHERR,NOTFOUND         NO SET NOT FOUND SW          A39650 15130000
         BR    GRA                 NO,DONT LOG ERROR             A39650 15140000
ERR15C   LA    GRB,PDSERR          SYMBOL MUST BE PREVIOUSLY DEFINED    15160000
         B     ERRXXX                                                   15180000
*                                                                       15200000
*                                                                       15220000
NFATLER1 MVC   ERRPT(4),FTXPPT         SET COL PTR TO 1ST BYTE          15240000
NFATLER2 STM   SRB,GR2,NCOMP                                            15260000
         L     SP1,ERRPT                                                15280000
         B     ERRXX                                                    15300000
*                                                                       15320000
* FATAL ERROR FOUND                                                     15340000
* LOG ERROR, EXIT FROM EEVAL WITH SP1 AND SP2 EQUAL 0                   15360000
*                                                                       15380000
*                                                                       15400000
*ERROR IS ILLEGAL CHARACTER                                             15420000
*                                                                       15440000
ERR9     LA    GRB,ILLCHAR         ILLEGAL CHARACTER                    15460000
         B     FATLER2                                                  15480000
*                                                                       15500000
* ERROR IS TWO CONSECUTIVE OPERATORS                                    15520000
*                                                                       15540000
ERR12    LA    GRB,OPERR           ILLEGAL ORDER OF OPERATORS           15560000
         B     FATLER2                                                  15580000
*                                                                       15600000
*ERROR IS ILLEGAL END OF EXPRESSION OR UNPAIRED PARENS                  15620000
*                                                                       15640000
ERR17    LA    GRB,ENDERR          EXPRESSION END PREMATURE             15660000
         B     FATLER2                                                  15680000
*                                                                       15700000
* ERROR IS TWO CONSECUTIVE TERMS                                        15720000
*                                                                       15740000
ERR10    LA    GRB,ILORDER         ILLEGAL ORDER OF TERMS               15760000
*                                                                       15780000
FATLER1  STM   SRB,GR2,NCOMP                                            15800000
         L     SP1,ERRPT               PT TO 1ST OF TERM OR EXP.        15820000
         LA    GRA,EXERR                                                15840000
         B     ERRXX                                                    15860000
FATLER2   LA   GRA,EXERR                                                15880000
*                                                                       15900000
*                                                                       15920000
ERRXXX   STM   SRB,GR2,NCOMP                                            15940000
ERRXX    STH   GRB,ERCODE                                               15960000
         MVI   ERROR,X'FF'         TURN ON ERROR SWITCH                 15980000
ERRLOG   L     SRB,CLOGER(ACT)                                          16000000
         BALR  SRR,SRB             TO LOGERR                            16020000
         DROP  SRB                                                      16040000
         USING *,SRR                                                    16060000
ERCODE   DS    AL2                 ERROR CODE                           16080000
         LM    SRB,GR2,NCOMP                                            16100000
         DROP  SRR                                                      16120000
         USING EEVAL,SRB                                                16140000
         BR    GRA                 NO,CONTINUE PROCESSING EXPRESSION    16160000
EXERR    SR    SP1,SP1               SET SP1 TO ZERO                    16180000
SETE     SR    SP2,SP2             SET SP2 TO ZERO                      16200000
         NI    CTPDSI(ACT),X'DF'        TURN OFF                        16220000
         LM    GRA,GRB,REGSAV                                           16240000
         TM    ERROR,X'FF'         SET CC=3 FOR ERROR CONDITION         16260000
         BR    SRR                                                      16280000
*                                                                       16300000
* CONVERT SELF-DEFINING VALUES - FENDALL                                16320000
* ENTER WITH REGISTER COLR POINTING TO 1ST CHARACTER OF CONSTANT.       16340000
* LOAD REGISTER SHFR WITH CONSTANT TYPE INDICATOR-                      16360000
*        1 = BINARY                                                     16380000
*        3 = DECIMAL                                                    16400000
*        4 = HEX                                                        16420000
*        8 = CHARACTER                                                  16440000
* BRANCH WITH RETURN REGISTER RTNR.                                     16460000
* RETURNS WITH CONVERTED VALUE IN REGISTER VALR, RIGHT JUSTIFIED,       16480000
* SIGNIFICANT CHARACTER COUNT IN REGISTER CNTR, COLR AT 1ST             16500000
* NON-CONSTANT CHARACTER.                                               16520000
* REGISTERS SAVR AND CHAR ARE SCRATCHED.                                16540000
* SINGLE + CAUSES IMMEDIATE RETURN WITH CNTR = 0 AND COLR AT +.         16560000
* LEADING BITS MAY BE LOST IF VALUE TOO LARGE.                          16580000
RETR     EQU    GRZ                                                     16600000
COLR     EQU    SP1                                                     16620000
SHFR     EQU   GRX                                                      16640000
VALR     EQU   SP2                                                      16660000
SAVR     EQU    GRY                                                     16680000
CHAR     EQU    GR0                                                     16700000
CNTR     EQU    GR1                                                     16720000
SDVCF    SR    VALR,VALR                CLEAR VALUE                     16740000
         LR    CHAR,VALR                CLEAR CHAR                      16760000
         LR    CNTR,VALR                CLEAR COUNT                     16780000
         STC   SHFR,SDV08+1             STORE SHIFT                     16800000
         CLI   SDV08+1,8                TEST FOR C-CONSTANT             16820000
         BNE   SDV01                    NO                              16840000
         L     VALR,SDV09               YES, LOAD EXTERNAL ZEROES       16860000
SDV01    LA    SAVR,SDV08-1(SHFR)       TEST CHAR RANGE                 16880000
         CLC   0(1,COLR),0(SAVR)                                        16900000
         BH    SDV07                    EXIT ON TOO HIGH                16920000
         IC    CHAR,0(COLR)                                             16940000
         LR    SAVR,VALR                SAVE CUMULATIVE VALUE           16960000
         CLI   SDV08+1,8                TEST FOR C-CONSTANT             16980000
         BNE   SDV04                    NO, TO SHIFT                    17000000
         CLI   0(COLR),IQUOTE           TEST '                          17020000
         BNE   SDV02                    NO                              17040000
         CLI   1(COLR),IQUOTE           TEST ''                         17060000
         BE    SDV03                    YES, TO SKIP                    17080000
         B     SDV07                    NO, EXIT                        17100000
SDV02    CLI   0(COLR),IAMPSD           TEST +                          17120000
         BNE   SDV04                    NO, TO SHIFT                    17140000
         CLI   1(COLR),IAMPSD           TEST ++                         17160000
         BNE   SDV06                    NO, ERROR                       17180000
SDV03    LA    COLR,1(COLR)             SKIP ' OR +                     17200000
SDV04    SLL   VALR,0(SHFR)             SHIFT VALUE                     17220000
         CLI   SDV08+1,3                TEST FOR DEC CONSTANT           17240000
         BNE   SDV05                    NO                              17260000
         ALR   VALR,SAVR                YES, ADJUST VALUE               17280000
         ALR   VALR,SAVR                                                17300000
SDV05    ALR   VALR,CHAR                CHAR TO VALUE                   17320000
         LA    CNTR,1(CNTR)             STEP COUNT                      17340000
         LA    COLR,1(COLR)             STEP COLUMN POINTER             17360000
         B     SDV01                    TO NEXT CHAR                    17380000
SDV06    SR    CNTR,CNTR                CLEAR COUNT FOR ERROR           17400000
SDV07    BR    RETR                     EXIT                            17420000
*                                                                       17440000
*                                                                       17460000
NOTFOUND EQU   1                        F7 SW                    A39650 17470000
SDV08    DC    X'0100090F000000FF'      LIMITS                          17480000
         DS    0F                                                       17500000
SDV09    DC    X'F0F0F0F0'              EBCDIC ZEROES                   17520000
REGSAV   DS    2F                 WORK REGS FOR ERROR HANDLING          17540000
REGSAV1   DS   F                                                        17560000
ERRPT    DS    F                       SAV AREA FOR COL PTR             17580000
FTXPPT   DS    F                       SAV AREA FOR PTR TO 1ST BYTE     17600000
OTHERR   DC    X'00'                   SWITH FOR ERR PATH,0-OFF,1-ON    17620000
FATAL    DC    X'00'               FATAL ERR SWH (0=NON-FATAL,1=FATAL)  17640000
TERMS    DS    16F                      LIST OF VALUES                  17660000
RLIST    DS    16H                      RELOCATABILITY LIST             17680000
RCNTR    DS    C                        COUNTER OF RELOCATABLE TERMS    17700000
ERROR    DS    C                        ON(1), OFF(0)                   17720000
PCNTR    DS    C                        COUNTER OF = OF (               17740000
SYMBL    DS    C         0=SYM 1ST TERM,1=NOT 1ST TERM,255=SYM NOT FND  17760000
NTRMS    DS    16C                      NUMBER OF TERMS PER TERMS ENTRY 17780000
OPRNS    DS    20C                      LIST OF OPERATIONS              17800000
COND     DS    C                        VALIDITY INDICATOR              17820000
ENDOE    DS    C                        END EXPRESSION FLAG             17840000
NEWOP    DS    C                        LATEST OPERATION FOUND          17860000
LREF     DS    C                        L'SYM REF  ON(1) OFF(0)         17880000
NCOMP    DS    11F                                                      17900000
SAVE     EQU   NCOMP                                                    17920000
NPTR     DC    A(NTRMS)                 ADDRESS OF NTRMS                17940000
TPTR     DC    A(TERMS)                 ADDRESS OF TERMS                17960000
OPTR     DC    A(OPRNS)                 ADDRESS OF OPRNS                17980000
COMP1    DC    A(RLIST+30)              CONST TO CHECK NO. OF TERMS     18000000
         END                                                            18020000
