F8A      TITLE 'F8AOP--F8 ASSEMBLER OPERATOR PROCESSOR'                 00020000
         ISEQ  73,80                                                    00040000
IEUF8A   START 0                       ASSEMBLER OP PROCESSOR           00060000
*          RELEASE 19 DELETIONS                                         00067000
*          RELEASE 20 DELETIONS                                         00068000
*                                                                  I004 00068520
*                                                                A32954 00068720
*          RELEASE 21 DELETIONS                                         00069000
* 088600,092600-092800,093800-094000                              21016 00069421
* 095090-095134,095176                                            M2110 00069821
* 000660-000665,000700,059660-059720                             A45780 00070021
*                                                                       00070421
*STATUS CHANGE LEVEL 010                                                00072021
*                                                                       00074020
* INCREMENTAL IMPROVEMENTS FO RELEASE 20                                00076020
* I004 IMPLEMENTATION OF WXTRN                                          00078020
F8AOP    EQU   IEUF8A                   OLD NOME FOR ASSEM OP PROC      00080000
         PRINT NODATA,NOGEN                                             00100000
         FDIMEN                                                         00120000
         PRINT DATA,GEN                                                 00140000
*                                                                     * 00160000
*TITLE 'IEUF8A  ' ...  ASSEMBLER OPERATION PROCESSOR                  * 00180000
*FUNCTION/OPERATION-                                                  * 00220000
*   IEUF8A PROCESSES THE FOLLOWING ASSEMBLER OPERATIONS- PRINT, SPACE,* 00240000
*   EJECT, MNOTE, PUNCH, REPRO, TITLE, ENTRY, EXTERN, START, CSECT,   * 00260000
*   DSECT, COMMON, EQU, ORG, LITORG, USING, DROP, CNOP, DXD, CXD, CCW,* 00280000
*   LITERAL DC, DC, AND DS. IT IS CALLED BY IEUF8C AND USES DC EVAL   * 00300000
*   TO EVALUATE EXPRESSIONS, AND DCVAL TO EVALUATE DC STATEMENTS. THE * 00320000
*   FOLLOWING ERRORS ARE FOUND AND LOGGED-                            * 00340000
*        LOCATION COUNTER               WRAP AROUND                   * 00360000
*        EXPRESSION TOO LARGE           REGISTER SPECIFICATION        * 00380000
*        UNDEFINED SYMBOL               RELOCATABILITY                * 00400000
*        REGISTER NOT USED              CCW ERRORS                    * 00420000
*        ALIGNMENT                      ENTRY ERRORS                  * 00440000
*        OPERAND TOO COMPLEX            LENGTH                        * 00460000
*        INVALID DELIMITER              PRINT PARAMETER ERRORS        * 00480000
*ENTRY POINTS                                                         * 00500000
*   IEUF8A   ASOPRO(ACT)      PROCESS ASSEMBLER OPERATIONS            * 00520000
*     CALLING SEQUENCE-                                               * 00540000
*        L     FRB,ASOPRO(ACT)          LOAD BASE/ENTRY               * 00560000
*        BALR  CRR,ACT                  CALL IEUF8A                   * 00580000
*   SETSEC                    SETS CURRENT ADJUSTMENT BASE- INTERNAL  * 00600000
*   SECSET   F8STSC(ACT)      SETS CURRENT ADJUSTMENT BASE- EXTERNAL  * 00620000
*     CALLING SEQUENCE                                                * 00640000
*        L     FRB,ASOPRO(ACT)          LOAD BASE                     * 00660000
*        L     GR1,F8STSC(ACT)          LOAD ENTRY                    * 00680000
*        BALR  SRR,GR1                  CALL SET ADJUSTMENT           * 00700000
*INPUT- RECORDS TYPE 4, 6, AND 7                                      * 00720000
*OUTPUT- IEUF8P IS CALLED TO PRINT OUT THE LISTING AND CARDS WHEN     * 00740000
*        NECESSARY                                                    * 00760000
*EXTERNAL ROUTINES-                                                   * 00780000
*   NAME            ROUTINE   USE                                     * 00800000
*   PRNT(ACT)       IEUF8P    TO PRINT AND/OR PUNCH                   * 00820000
*   CEEVAL(ACT)     IEUF8E    EXPRESSION EVALUATION                   * 00840000
*   CSTGER(ACT)     IEUF8C    FIND SYMBOL IN SYMBOL TABLE             * 00860000
*   GETLAT(ACT)     IEUF8I    GET LITERAL ADDRESS TABLE               * 00880000
*   CDCVAL(ACT)     IEUF8D    DC EVALUATION                           * 00900000
*   CLOGER(ACT)     IEUF8L    LOG ERROR                               * 00920000
*   RLDRTN          IEUF8D    RLD PROCESSING                          * 00940000
*   STLOC           IEUF8D    FOR CCW RLD PROCESSING                  * 00960000
*EXITS- NORMAL AND ERROR                                              * 00980000
*   RETURN FROM IEUF8A VIA                                            * 01000000
*        B     CTRTRN(ACT)              EXIT                          * 01020000
*   RETURN FROM SECSET VIA                                            * 01040000
*        BR    SRR                      EXIT                          * 01060000
*TABLES/WORKAREAS                                                     * 01080000
*   ASMOPR- TRANSFER TABLE FOR ASSEMBLER OP-CODES                     * 01100000
*   F8REGS- SAVE AREA FOR REGISTER IN SECSET                          * 01120000
*   ERRREGS- SAVE AREA FOR REGISTER ON ERRORS                         * 01140000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 01160000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 01180000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 01200000
*NOTES                                                                * 01220000
***   F8AOP   ***                                                       01240000
*ASSEMBLER OP PROCESSOR                                                 01260000
* THIS ROUTINE PROCESSES THE ASSEMBLY OPS WHICH HAVE NOT BEEN           01280000
* PREVIOUSLY COMPLETELY PROCESSED.                                      01300000
*                                                                     * 01320000
         EJECT                                                          01340000
         USING *,FRB                                                    01360000
         SR    GRZ,GRZ                                                  01380000
         L     GRX,CTWRAPX(ACT)         LOCATION COUNTER ADJUSTED VALUE 01400000
         ST    GRZ,CTWRAPX(ACT)         ZERO OUT ADJUSTED LOC CTR       01420000
         IC    GRZ,F8WORK+4(ACT)        GET HEX CODE                    01440000
         MVI   F8INST+15(ACT),X'0F'     DONT PRINT LEFT HAND SIDE       01460000
         MVI   ERRSW,X'00'              INITIALIZE ERROR SWITCH         01480000
         S     GRZ,NINEEN               SET DISP OF INST RELATIVE TO 0  01500000
         BM    MNOTST                   MINUS, PROCESS MNOTE            01520000
         OC    PYRSW(1,ACT),F8WORK+5(ACT)  GET ASSEMBLER SWITCH CODE    01540000
         SR    GRY,GRY                  ZERO INDEX                      01560000
         AR    GRZ,GRZ                  FIX FOR HALF WORD GET           01580000
         LH    GRZ,ASMOPR(GRZ)          GET RELATIVE ADDRESS            01600000
         B     AOPTBL(GRZ)             INDEXED BRANCH TO INSTRUCTION    01620000
MNOTST   CLI   F8WORK+4(ACT),KMNOTE     IS THIS RECORD AN MNOTE         01640000
         BNE   CTRTRN(ACT)              IF NOT, EXIT                    01660000
         MVI   REPSW(ACT),X'0F'         SET FOR MNOTE                   01680000
         B     CTRTRN(ACT)              RETURN                          01700000
*********************************************************************** 01720000
***   ASMOPR   ***                                                      01740000
*TABLE OF ASSEMBLER OPS TO BE USED IN COMPUTED GO TO                    01760000
*********************************************************************** 01780000
ASMOPR   DS    0H                                                       01800000
         DC    AL2(PRINTB-AOPTBL)       PRINT DISPLACEMENT              01820000
         DC    AL2(SPACE-AOPTBL)        SPACE DISPLACEMENT              01840000
         DC    AL2(EJECT-AOPTBL)        EJECT DISPLACEMENT              01860000
         DC    AL2(PUNCHB-AOPTBL)       PUNCH DISPLACEMENT              01880000
         DC    AL2(REPRO-AOPTBL)        REPRO DISPLACEMENT              01900000
         DC    AL2(TITLEB-AOPTBL)       TITLE DISPLACEMENT              01920000
         DC    AL2(ENTRYB-AOPTBL)       ENTRY DISPLACEMENT              01940000
         DC    AL2(EXTRNB-AOPTBL)       EXTERN DISPLACEMENT             01960000
         DC    AL2(STARTB-AOPTBL)       START DISPLACEMENT              01980000
         DC    AL2(CSECTB-AOPTBL)       CSECT DISPLACEMENT              02000000
         DC    AL2(DSECTB-AOPTBL)       DSECT DISPLACEMENT              02020000
         DC    AL2(COMB-AOPTBL)         COMMON DISPLACEMENT             02040000
         DC    AL2(EQUB-AOPTBL)         EQUIVALENCE DISPLACE,ENT        02060000
         DC    AL2(ORGB-AOPTBL)         ORIGIN DISPLACEMENT             02080000
         DC    AL2(ENDB-AOPTBL)         END DISPLACEMENT                02100000
         DC    AL2(LTORGB-AOPTBL)       LITORG DISPLACEMENT             02120000
         DC    AL2(USINGB-AOPTBL)       USING DISPLACEMENT              02140000
         DC    AL2(DROPB-AOPTBL)        DROP DISPLACEMENT               02160000
         DC    AL2(LITERB-AOPTBL)       LITERAL DISPLACEMENT            02180000
         DC    AL2(DCB-AOPTBL)          DC DISPLACEMENT                 02200000
         DC    AL2(DSB-AOPTBL)          DS DISPLACEMENT                 02220000
         DC    AL2(CCWB-AOPTBL)         CCW DISPLACEMENT                02240000
         DC    AL2(CNOPB-AOPTBL)        CNOP DISPLACEMENT               02260000
         DC    AL2(ASERRB-AOPTBL)       QUIT EXIT  2A                   02280000
         DC    AL2(DSB-AOPTBL)          DXD  2B                         02300000
         DC    AL2(DCDSLT-AOPTBL)       CXD   2C                        02320000
         DC    AL2(RETURN-AOPTBL)       OPSYN 2D                  IEUN1 02330018
         DC    AL2(EXTRNB-AOPTBL)       WXTRN DISPLACEMENT         I004 02335020
         DC    AL2(ASERRB-AOPTBL)      ASSEMBLY ERROR DISPLACEMENT      02340000
         DC    AL2(RETURN-AOPTBL)       RETURN TO MAIN LINE CONTROL     02360000
AOPTBL   DS    0H                       1ST ASSEMBLER OP LOCATION       02380000
*********************************************************************** 02400000
***   PRINTB   ***                                                      02420000
*THIS ROUTINE SCANS THE OPERAND FIELD OF ALL PRINT STATEMENTS AND SETS  02440000
* SWITCHES TO BE USED BY THE PRINT AND PUNCH PORTION OF F8OP.           02460000
*********************************************************************** 02480000
PRINTB   MVI   F8INST+15(ACT),X'0F'     DONT PRINT LOCATION COUNTER     02500000
         MVC   PNTSAV(12),F8PON(ACT)    SAVE OLD SETTINGS               02520000
         MVI   PRNTFLAG,X'00'           TURN ALL FLAGS OFF              02540000
         ST    ACT,F8TEMP               SAVE ACT REG.                   02560000
         L     FRB,PRNT(ACT)            LOAD F8OP BASE REG.             02580000
         BALR  SRR,FRB                  CALL PRINT                      02600000
         L     FRB,ASOPRO(ACT)     LOAD F8AOP BASE REG.                 02620000
         L     ACT,F8TEMP              RESTORE ACT REG.                 02640000
         LA    GRY,3                   INITIALIZE PARAMETER COUNT       02660000
         SR    GRX,GRX                  ZERO CELL                       02680000
         L     SP1,F8OPRN(ACT)          OPERAND POINTER                 02700000
PRNTB1   CLC   0(2,SP1),ONC                                             02720000
         BE    DON                      IF OPERAND 'ON'                 02740000
         CLC   0(3,SP1),OFFC                                            02760000
         BE    DOFF                     IF OPERAND 'OFF'                02780000
         CLC   0(3,SP1),GENC                                            02800000
         BE    DGEN                     IF OPERAND 'GEN'                02820000
         CLC   0(5,SP1),NOGENC                                          02840000
         BE    DNOGEN                   IF OPERAND 'NOGEN'              02860000
         CLC   0(4,SP1),DATAC                                           02880000
         BE    DDATA                    IF OPERAND 'DATA'               02900000
         CLC   0(6,SP1),NDATAC                                          02920000
         BE    DNDATA                   IF OPERAND 'NODATA'             02940000
         BAL   SRR,ERRZRO               LOG AN ERRORSWITCH SETTINGS     02960000
         DC    AL2(ERRPNT)              UNRECOGNIZABLE PRINT PRAMTR     02980000
         MVC   F8PON(12,ACT),PNTSAV     RESTORE OLD SETTINGS            03000000
RETURN   B     CTRTRN(ACT)              EXIT                            03020000
DON      LA    SP2,F8PON(ACT)           SWITCH LOCATION FOR ON          03040000
         SR    GRX,GRX                  SET ON                          03060000
         LA    SP1,2(SP1)               BUMP OPERAND POINTER BY 2       03080000
         TM    PRNTFLAG,X'02'           OFF                             03100000
         BO    PNTOPNER                 CONFLICTING PRINT OPERANDS      03120000
         OI    PRNTFLAG,X'01'           ON                              03140000
         B     CPRNTB                   BRANCH TO COMMON POINT          03160000
DOFF     LA    SP2,F8PON(ACT)                                           03180000
         LA    GRX,255                  SET OFF                         03200000
         LA    SP1,3(SP1)                                               03220000
         TM    PRNTFLAG,X'01'           ON                              03240000
         BO    PNTOPNER                 CONFLICTING PRINT OPERANDS      03260000
         OI    PRNTFLAG,X'02'           OFF                             03280000
         B     CPRNTB                                                   03300000
DGEN     LA    SP2,F8PGEN(ACT)                                          03320000
         SR    GRX,GRX                  SET ON                          03340000
         LA    SP1,3(SP1)                                               03360000
         TM    PRNTFLAG,X'08'           NOGEN                           03380000
         BO    PNTOPNER                 CONFLICTING PRINT OPERANDS      03400000
         OI    PRNTFLAG,X'04'           GEN                             03420000
         B     CPRNTB                                                   03440000
DNOGEN   LA    SP2,F8PGEN(ACT)         ADDRESS OF GEN SWOTCH            03460000
         LA    GRX,255                  SET OFF                         03480000
         LA    SP1,5(SP1)                                               03500000
         TM    PRNTFLAG,X'04'           GEN                             03520000
         BO    PNTOPNER                 CONFLICTING PRINT OPERANDS      03540000
         OI    PRNTFLAG,X'08'           NOGEN                           03560000
         B     CPRNTB                                                   03580000
DDATA    LA    SP2,F8PDAT(ACT)                                          03600000
         SR    GRX,GRX                  SET ON                          03620000
         LA    SP1,4(SP1)                                               03640000
         TM    PRNTFLAG,X'20'           NODATA                          03660000
         BO    PNTOPNER                 CONFLICTING PRINT OPERANDS      03680000
         OI    PRNTFLAG,X'10'           DATA                            03700000
         B     CPRNTB                                                   03720000
         LA    SP1,1(SP1)               BUMP PAST FIRST QUOTE           03740000
DNDATA   LA    SP2,F8PDAT(ACT)                                          03760000
         LA    GRX,255                  SET OFF                         03780000
         LA    SP1,6(SP1)                                               03800000
         TM    PRNTFLAG,X'10'           DATA                            03820000
         BO    PNTOPNER                 CONFLICTING PRINT OPERANDS      03840000
         OI    PRNTFLAG,X'20'           NODATA                          03860000
         B     CPRNTB                                                   03880000
PNTOPNER BAL   SRR,ERRZRO               LOG ERROR ETC                   03900000
         DC    AL2(ERROPN)              ILLEGAL OPERAND                 03920000
         MVC   F8PON(12,ACT),PNTSAV     RESTORE OLD SETTINGS            03940000
         B     CTRTRN(ACT)              PRINT NOW FOOL (}) PROOF        03960000
CPRNTB   CLI   0(SP1),ICOMMA            IF COMMA, OK                    03980000
         BE    PDELOK                                                   04000000
         CLI   0(SP1),IBLANK            IF BLANK,OK                     04020000
         BNE   DLMERR                   IF NOT, SYNTAX ERROR            04040000
PDELOK   STC   GRX,0(SP2)               SET APPROPRIATE FLAG IN APP LOC 04060000
         CLI   0(SP1),ICOMMA            IF COMMA, MORE                  04080000
         BNE   CTRTRN(ACT)              IF NOT COMMA RETURN TO MLC      04100000
         LA    SP1,1(SP1)               IF COMMA BUMP OPERAND POINTER   04120000
         BCT   GRY,PRNTB1              IF NOT 3, CONTINUE               04140000
         MVC   F8PON(12,ACT),PNTSAV     RESTORE OLD SETTINGS            04160000
         B     DLMERR                  3 IS ERROR                       04180000
*********************************************************************** 04200000
***   SPACE   ***                                                       04220000
*THIS ROUTINE SETS A SWITCH TO BE USED IN THE PRINT PORTION OF F8OP.    04240000
*********************************************************************** 04260000
SPACE    TM    F8PON(ACT),X'FF'         IS PRINT SWITCH ON              04280000
         BNZ   SPAC03                   IF NON ZERO, OFF                04300000
         TM    F8PGEN(ACT),X'FF'        IS GEN SWITCH ON                04320000
         BZ    SPACE00                  YES                             04340000
         TM    F8WORK+2(ACT),X'10'      IS THIS A GENERATED STATEMENT   04360000
         BZ    SPACE00                  NO                              04380000
SPAC03   SR    SP2,SP2                  ZERO REGISTER                   04400000
         B     SPAC02                   SET TO SPACE 0 TIMES            04420000
SPACE00  CLI   0(SP1),ICOMMA            IS OPERAND BLANK                04440000
         BE    SPAC01                   IF COMMA SET TO DO 1 SPACE      04460000
         CLI   0(SP1),IBLANK            IF OPERAND BLANK SET TO DO 1    04480000
         BE    SPAC01                   BRANCH TO DO 1 SPACE            04500000
         CLI   0(SP1),I9                TEST FIRST CHAR FOR DECIMAL     04520000
         BH    OPNERR                   IF NOT DECIMAL ERROR            04540000
         MVI   CTSDVI(ACT),X'80'        TURN SELF DEFINING SWITCH ON    04560000
         L     SRB,CEEVAL(ACT)          BASE FOR EXPRESSION EV ALUATIO  04580000
         BALR  SRR,SRB                  EXIT TO EXPRESSION EVALUATION   04600000
         BC    1,SPACER                 BRANCH IF ERR IN EVAL           04620000
         CLI   0(SP1),IBLANK            IS EXPRESSION DELIMETER BLANK   04640000
         BE    SPAC02                   IF YES, SKIP ERROR ROUTINE      04660000
         MVI   SPACSW(ACT),X'AA'        TURN SPACE SWITCH HALF ON ERR   04680000
         B     DLMERR                   EXIT TO DELIMETER ERROR RTN     04700000
SPAC01   LA    SP2,1                    SER TO SPACE ONCE               04720000
SPAC02   MVI   SPACSW(ACT),X'FF'        TURN SPACE SWITCH ON            04740000
         B     CTRTRN(ACT)              EXIT FROM F8AOP                 04760000
OPNERR   BAL   SRR,ERRZRO               GO TO LOG ERROR                 04780000
         DC    AL2(ERROPN)              OPERAND ERROR CODE              04800000
SPACER   MVI   SPACSW(ACT),X'AA'        SET SPACE SWITCH FOR ERROR      04820000
         XC    F8INST(3,ACT),F8INST(ACT)   ZERO INSTRUCTION COUNTER     04840000
         MVI   F8INST+15(ACT),X'00'     PRINT LEFT HALF                 04860000
         SR    SP2,SP2                  SET TO NOT SPACE                04880000
         B     CTRTRN(ACT)              EXIT FROM F8AOP                 04900000
*********************************************************************** 04920000
***   EJECT   ***                                                       04940000
*THIS ROUTINE SETS A SWITCH TO BE USED IN THE PRINT PORTION OF F8OP.    04960000
*********************************************************************** 04980000
EJECT    TM    F8PGEN(ACT),X'FF'        IS GEN SWITCH ON          11040 05020014
         BZ    EJECT01                  IF ZERO DO EJECT                05060000
         TM    F8WORK+2(ACT),X'10'      IS THIS A GENERATED STATEMENT   05080000
         BNZ   EJECT02                  ITS GENERATED DONT EJECT        05100000
EJECT01  MVI   EJCTSW(ACT),X'FF'        SET TO EJECT                    05120000
EJECT02  B     CTRTRN(ACT)              EXIT TO MAIN LINE CONTROL       05140000
*********************************************************************** 05160000
***   PUNCHB   ***                                                      05180000
*THIS ROUTINE SETS A SWITCH TO BE USED IN F8OP.                         05200000
*********************************************************************** 05220000
PUNCHB   MVI   REPSW(ACT),X'01'         TURN ON PUNCH                   05240000
         B     CTRTRN(ACT)              EXIT                            05260000
*********************************************************************** 05280000
***   REPRO   ***                                                       05300000
*THIS ROUTINE SETS A SWITCH TO BE USED IN F8OP.                         05320000
*********************************************************************** 05340000
REPRO    MVI   REPSW(ACT),X'03'         TURN ON REPRO                   05360000
         B     CTRTRN(ACT)              EXIT                            05380000
*********************************************************************** 05400000
***   TITLEB   ***                                                      05420000
*THIS ROUTINE CHANGES THE TITLE TO BE PRINTED AT THE TOP OF EACH PAGE   05440000
* AND THEN CALLS THE EJECT ROUTINE                                      05460000
*********************************************************************** 05480000
TITLEB   MVI   REPSW(ACT),X'07'         SET TITLE SWITCH                05500000
         TM    F8PGEN(ACT),X'FF'        IS GEN SW ON              18743 05503000
         BZ    EJECT01                  BRANCH IF NOT             18743 05506000
         TM    F8WORK+2(ACT),X'10'      IS THIS A GENERATED RCD   18743 05507000
         BNO   EJECT01                  BRANCH IF NOT             18743 05508000
         LH    SP2,CTSEQ8+2(ACT)        GET STMNT CTR             18743 05509000
         BCTR  SP2,0                    DECR STMNT CNT            18743 05512000
         STH   SP2,CTSEQ8+2(ACT)        ST UPDATED STMNT CNT      18743 05515000
         B     CTRTRN(,ACT)             RETURN                    18743 05525000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 05540000
***      ENTRYB   ***                                                   05560000
*THIS ROUTINE ONLY MAKES A VALIDITY CHECK OF THE OPERAND FIELD OF ALL   05580000
* ENTRY STATEMENTS, OTHER PROCESSING WAS COMPLETED IN INTERLUDE         05600000
*********************************************************************** 05620000
ENTRYB   MVC   WKBKPT(4,ACT),CTXWBP(ACT) SET WORK BUCKET POINTER        05640000
ENTRYC   L     ACC,WKBKPT(ACT)          CURRENT WORK BUCKER POINTER     05660000
         LTR   ACC,ACC                  IS THERE A BUCKET               05680000
         BZ    CTRTRN(ACT)              IF ZERO, NO BUCKET              05700000
         CLI   TXSPTR(ACC),ECMPLT       IS WORKBUCKET COMPLETE          05720000
         BE    ENSEX                    YES - IGNORE                    05740000
         SR    SP1,SP1                  NO, ZERO LENGTH                 05760000
         LR    SP2,SP1                  AND PREPARE FOR ADDRESS OF NAME 05780000
         IC    SP1,TXSPTR(ACC)          GET                             05800000
         A     SP1,F8OPRN(ACT)           NAME POINTER                   05820000
         ST    SP1,ENTSAVE              SAVE POINTER                    05840000
         IC    SP2,TXSESL(ACC)          GET                             05860000
         N     SP2,LENMSK                NAME LENGTH                    05880000
         L     SRB,CSTGET(ACT)          GET SYMBOL ATTRIBUTES           05900000
         BALR  SRR,SRB                  CALL STGETR - IEUF8S            05920000
         LTR   SP1,SP1                  WAS SYMBOL FOUND                05940000
         BZ    ENSER1                   NO, LOG ERROR                   05960000
         CLI   STID(SP1),0              IS SYMBOL ABSOLUTE              05980000
         BE    ENSER2                   YES, LOG ERROR                  06000000
         TM    ADJCD(SP1),DSOCM         DEFINED IN DSECT OR COM         06020000
         BO    ENSER3                   YES, LOB ERROR                  06040000
         TM    ADJCD(SP1),ENTCMB        IS ENTRY COMPLETE               06060000
         BO    ENSER3                   YES, LOG ERROR                  06080000
         OI    ADJCD(SP1),ENTCMB         SET ADJ CODE COMPLETE          06100000
         TM    ADJCD(SP1),SDBIT         IS ADJ CODE = SD                06120000
         BM    ENSER3                   ERROR IF DSECT OR EXTRN         06140000
ENSEX    L     ACC,WKBKPT(ACT)                                          06160000
         TM    EWBKSW(ACC),LASTOP       IS THIS THE LAST OPERAND        06180000
         BO    CTRTRN(ACT)              YES - EXIT                      06200000
         LA    ACC,WBKLEN(ACC)          SET FOR NEXT WKBKT              06220000
         ST    ACC,WKBKPT(ACT)          SAVE POINTER                    06240000
         B     ENTRYC                   TRY FOR NEXT                    06260000
ENSER1   L     SP1,ENTSAVE              LOAD OPERAND POINTER            06280000
         BAL   SRR,ERRNO0               LOG ERROR                       06300000
         DC    AL2(ERRUDF)             UNDEFINED SYMBOL                 06320000
         B     ENSEX                    LOOK FOR OPERANDS               06340000
ENSER2   L     SP1,ENTSAVE              LOAD OPERAND POINTER            06360000
         BAL   SRR,ERRNO0               LOG ERROR                       06380000
         DC    AL2(ERRLOC)              EXTERNAL NAME ERROR             06400000
         B     ENSEX                    LOOK FOR MORE OPERANDS          06420000
ENSER3   L     SP1,ENTSAVE              LOAD OPERAND POINTER            06440000
         BAL   SRR,ERRNO0               LOG ERROR                       06460000
         DC    AL2(ERRNTY)             ENTRY ERROR                      06480000
         B     ENSEX                    LOOK FOR MORE OPERANDS          06500000
ACC      EQU   GRX                      ACCUMULATOR                     06520000
ADJCD    EQU   1                        POSITION OF ADJECTIVE CODE      06540000
DSOCM    EQU   4                        DSECT OR COMMON MASK            06560000
ECMPLT   EQU   X'FF'                    WORKBUCKET COMPLETE FLAG        06580000
ENTCMB   EQU   X'08'                    ENTRY COMPLETE FLAG             06600000
EWBKSW   EQU   TXSESL                   SYMBOL LENGTH POINTER           06620000
LASTOP   EQU   X'80'                    LAST OPERAND MASK               06640000
SDBIT    EQU   3                        CSECT MASK                      06660000
STID     EQU   2                        POSITION OF SYMBOL ID           06680000
WBKLEN   EQU   6                        LENGTH OF WORKBUCKETS           06700000
         DS    0F                                                       06720000
LENMSK   DC    X'0000000F'              MASK FOR MAX LENGTH OF SYMBOL   06740000
*********************************************************************** 06760000
***   EXTRNB   ***                                                      06780000
*THIS ROUTINE RETURNS TO F8MLC, PROCESSING WAS DONE IN INTERLUDE        06800000
*********************************************************************** 06820000
EXTRNB   B     CTRTRN(ACT)              EXIT                            06840000
*********************************************************************** 06860000
***   STARTB   ***                                                      06880000
*THIS ROUTINE SETS CURRENT TYPE, CURRENT ESD-ID, CURRENT ADJUSTMENT     06900000
* BASE (BY CALLING SETSEC)                                              06920000
*********************************************************************** 06940000
STARTB   TM    CTPCSW(ACT),X'FF'                                        06960000
         MVI   F8INST+15(ACT),X'00'     PRINT LOCATION                  06980000
         BNZ   CSECTB                   PROCESS AS CSECT                07000000
         L     SP2,WKBKPT(ACT)          WORK BUCKET POINTER             07020000
START01  MVC   CTYPE(1,ACT),1(SP2)     WK BKT TO CURRENT TYPE CELL      07040000
         SR    GRY,GRY                  ZERO CELL                       07060000
         IC    GRY,2(SP2)               CURRENT ESD-ID FROM WORK BUCKET 07080000
         STC   GRY,CESDID(ACT)          TO TABLE                        07100000
         STC   GRY,CESDIDPS(ACT)        SET ESDID SW ON                 07120000
         L     SP1,CADJBS(ACT)          ADJUSTMENT TABLE BASE           07140000
         LR    SP2,GRY                                                  07160000
         BAL   SRR,SETSEC               CSECT SETTING ROUTINE           07180000
         B     CTRTRN(ACT)              EXIT                            07200000
*********************************************************************** 07220000
***   CSECTB   ***                                                      07240000
*THIS ROUTINE SETS CURRENT TYPE, CURRENT ESD-ID AND CURRENT ADJUSTMENT  07260000
* BASE (VIA SETSEC ROUTINE)                                             07280000
*********************************************************************** 07300000
CSECTB   MVC   TSTYPE(1),F8WORK+2(ACT)  MOVE TYPE OF OP FOR ALTERATION  07320000
         NI    TSTYPE,X'70'             KEEP JUST TYPE OF OPERATION     07340000
         CLI   TSTYPE,X'50'             IS THIS AFTER END CARD          07360000
         BE    CSECT2                   IF EQUAL SET FLAG FF            07380000
         MVI   F8INST+15(ACT),X'00'     JUST EJECT CARD AND PRINT LOC   07400000
CSECT2   OI    F8INST+15(ACT),X'F0'     SET FLAG TO EJECT CARD          07420000
         L     SP2,WKBKPT(ACT)          WORK BUCKET POINTER             07440000
         CLC   2(1,SP2),CESDID(ACT)     WORK BUCKET ESD-ID VS CURRENT   07460000
         BNE   START01                 COMMON CODE FOR START AND CSECT  07480000
         B     CTRTRN(ACT)             IF CSECT SAME NO ACTION NEEDED   07500000
*********************************************************************** 07520000
***   DSECTB   ***                                                      07540000
*THIS ROUTINE SETS CURRENT TYPE, CURRENT ESD-ID AND SETS CURRENT        07560000
* ADJUSTMENT BASE EQUAL TO ZERO.                                        07580000
*********************************************************************** 07600000
DSECTB   L     SP2,WKBKPT(ACT)          WORK BUCKET POINTER             07620000
         MVI   F8INST+15(ACT),X'F0'     START A NEW CARD                07640000
         MVI   CESDIDPS(ACT),X'00'      SET ESDID FLAG OFF        16679 07650016
         CLC   2(1,SP2),CESDID(ACT)     WORK BUCKET ESD-ID VS CURRENT   07660000
         BE    CTRTRN(ACT)              RETURN TO MAIN LINE CONTROL     07680000
         SR    GRY,GRY                  ZERO CELL                       07700000
         IC    GRY,1(SP2)               CURRENT TYPE FROM WORK BUCKET   07720000
         STC   GRY,CTYPE(ACT)           TO CURRENT TYPE CELL            07740000
         IC    GRY,2(SP2)                                               07760000
         STC   GRY,CESDID(ACT)          CURRENT ESD-ID                  07780000
         SR    SP2,SP2                                                  07800000
         ST    SP2,F8CADJ(ACT)                                          07820000
         MVC   F8INST(3,ACT),F8CADJ(ACT)  ZERO TO LOCATION              07840000
         B     CTRTRN(ACT)              EXIT                            07880000
*********************************************************************** 07900000
***   COMB   ***                                                        07920000
*SEE DSECT, THE FUNCTIONS ARE THE SAME                                  07940000
*********************************************************************** 07960000
COMB     EQU   DSECTB                   COMMON IS HANDLED LIKE DSECT    07980000
*********************************************************************** 08000000
***   EQUB   ***                                                        08020000
*THIS ROUTINE PUTS THE EQUATED VALUE FOR PRINTING, IF THE VALUE IS      08040000
* NOT ABSOLUTE, IT IS COMPUTED VIA F8AREX.                              08060000
*********************************************************************** 08080000
EQUB     L     GRZ,CTXABP(ACT)          GET FIRST BYTE OF TEXT APPENDED 08100000
         MVI   F8INST+15(ACT),X'00'     PRINT LOCATION                  08120000
         MVC   F8INST(3,ACT),0(GRZ)     EQUATED VALUE TO ADDR FLD       08140000
*        TM    4(GRZ),X'FF'             IS IT ABSOLUTE                  08160000
*        BZ    CTRTRN(ACT)              YES, RETURN                     08180000
         BAL   SRR,F8AREX               NO, EVALUATE                    08200000
         TM    EVLERF,X'FF'             IS EXPRESSION EVAL ERROR ON     08220000
         BO    EQUERR                   YES, LOG ERROR                  08240000
         MVC   F8INST(3,ACT),VALUEB+1   MOVE IN INSTRUCTION COUNTER     08260000
         MVI   F8INST+3(ACT),X'32'      BLANK OUT REST OF LINE          08280000
         MVC   F8INST+4(11,ACT),F8INST+3(ACT)                           08300000
         B     CTRTRN(ACT)              RETURN TO MAIN LINE             08320000
*********************************************************************** 08340000
***   ORGB   ***                                                        08360000
*THIS ROUTINE SETS A SPECIAL FLAG FOR F8OP ROUTINE.                     08380000
*********************************************************************** 08400000
ORGB     MVC   TSTYPE(1),F8WORK+2(ACT)  MOVE TYPE OF OP FOR ALTERATION  08420000
         ST    GRX,CTWRAPX(ACT)         REPLACE ADJUSTED LOCATION CTR   08440000
         NI    TSTYPE,X'70'             KEEP JUST TYPE OF OPERATION     08460000
         CLI   TSTYPE,X'50'             IS THIS AFTER END CARD          08480000
         BE    ORG1                     YES, DONT PRINT LOC             08500000
         MVI   F8INST+15(ACT),X'00'     JUST EJECT CARD AND PRINT LOC   08520000
ORG1     OI    F8INST+15(ACT),X'F0'     SET FLAG TO EJECT CARD          08540000
         SR    SP1,SP1                  LOG ERROR WITHOUT COL PTR       08560000
         TM    CTWRAPX(ACT),X'FF'       TEST FOR ORG ERROR              08580000
         BC    5,ORGERR                 IF MIXED, ORG ERROR             08600000
         B     CTRTRN(ACT)              EXIT                            08620000
ORGERR   BAL   SRR,ERRZRO               LOG ORG ERROR                   08640000
         DC    AL2(ERRORG)              ORG ERROR CODE                  08660000
         XC    CTWRAPX(4,ACT),CTWRAPX(ACT)  ZERO WORD                   08680000
         LA    GR0,1                                                    08700000
         ST    GR0,CTWRAPX(ACT)         FIX SO DECREMENT WONT HURT      08720000
         B     CTRTRN(ACT)              RETURN TO MAIN LONE CONTROL     08740000
*********************************************************************** 08760000
***   ENDB   ***                                                        08780000
*THIS ROUTINE TURNS ON THE END SWITCH AND PUTS THE ADDRESS IN THE       08800000
* OPERAND FIELD OF THE END CARD                                         08820000
*********************************************************************** 08840000
ENDB     MVI   CTIDR(ACT),C'1'          SET 1 IDR FIELD           21016 08860021
         CLI   0(SP1),IBLANK            IS DELIMITER BLANK        21016 08870021
         BNE   END04                    NO, TRY A COMMA                 08880000
END00    XC    ENDSWH(4,ACT),ENDSWH(ACT)  YES, ZERO TO ESD-ID & COUNT   08900000
         MVI   F8INST+15(ACT),X'0F'     SUPPRESS PRINTIOG OF LOC CTR    08920000
         B     CTRTRN(ACT)              EXIT                            08940000
END01    BAL   SRR,F8AREX               EVALUATE EXPRESSION             08960000
         TM    SREXP,X'01'              IS IT SIMPLY RELOCATABLE        08980000
         BNZ   END02                    IF NOT, ERROR                   09000000
         CLC   CTNDID+1(1,ACT),VALUEB+5 NEXT DSECT ESDID VS THIS ESDID  09020000
         BL    END02                    IF NOT LOWER, CSECT OR COMMON   09040000
END03    CLC   CTCMSW(1,ACT),VALUEB+5   IS THIS COMMON                  09060000
         BE    END02                    IF COMMOM, ERROR                09080000
         MVC   ENDSWH(4,ACT),0(SP2)     IF YES, SET VALUE               09100000
         MVC   ENDSWH(1,ACT),5(SP2)     ESD-ID TO FIRST BYTE            09120000
         MVC   F8INST(3,ACT),1(SP2)     SET CORRECT LOC FOR LISTING     09140000
         TM    F8INST+2(ACT),X'01'      IS END ALIGNED CORRECTLY        09160000
         BZ    END05                    IF ZERO, YES                    09180000
         BAL   SRR,ERRNO0               LOG ALIGNMENT ERROR             09200000
         DC    AL2(ERRLIN)              ALIGNMENT ERROR                 09220000
END05    CLI   0(SP1),IBLANK            IS DELIMETER A BLANK            09240000
         BE    END06                    2ND FIELD OMITTED         21016 09260021
         CLI   0(SP1),ICOMMA            COMMA FOLLOWS?            21016 09270021
         BNE   DLMERR                   NO, ERROR                 21016 09280021
         B     END07                    YES, SCAN 2ND FIELD       21016 09290021
END06    MVI   F8INST+15(ACT),X'00'     ZERO TO PRINT LOC CTR     21016 09292021
         B     AOPRTN                   NORMAL EXIT                     09300000
END04    CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              09320000
         BNE   END01                    IF NOT, EVALUATE EXPRESSION     09340000
         CLI   1(SP1),IBLANK            IS COMMA FOLLOWED BY BLANK      09360000
         MVI   F8INST+15(ACT),X'0F'     SUPPRESS PRINT OF LOC CTR 21016 09380021
         BNE   END075                                             21016 09390021
         B     END00                   TREAT AS BLANK END CARD          09420000
END02    BAL   SRR,ERRNO0               LOG ERROR                       09440000
         DC    AL2(ERRLOC)              RELOCATABILITY ERROR            09460000
         B     AOPRTN                  ZERO LOCATION                    09480000
END07    MVI   F8INST+15(ACT),X'00'     ZERO TO PRINT LCTR        21016 09485021
END075   CLI   1(SP1),ILPARN            LPAREN SHOULD FOLLOW      21016 09490021
         BE    END077                                             21016 09495021
         CLI   1(SP1),IBLANK            OK IF BLANK FOLLOWS       21016 09496021
         BNE   DLMERR                   ANY OTHER CHAR ERROR      21016 09497021
         B     END06                    GO PRINT                  21016 09498021
END077   LA    SP1,2(SP1)               STEP PAST DELIMITERS      21016 09499021
         LA    GRZ,10                   1ST SUBFIELD = 10 BYTES   21016 09499221
         LR    GRY,ACT                  INIT TO MOVE FIELD        21016 09499421
END08    CLI   0(SP1),ICOMMA                                      21016 09499621
         BE    END09                    BRANCH AT END OF FIRST    21016 09499821
         MVC   CT2IDR(1,GRY),0(SP1)     SAVE BYTE FOR END CARD    21016 09499921
         LA    GRY,1(GRY)               UPDATE POINTERS           21016 09504921
         LA    SP1,1(SP1)                                         21016 09505921
         BCT   GRZ,END08                BRANCH IF POSITIVE        21016 09506921
         CLI   0(SP1),ICOMMA            COMMA SHOULD DELIMIT      21016 09507921
         BNE   DLMERR                                             21016 09508921
         LTR   GRZ,GRZ                  WAS IT 10 CHAR.           M2110 09509021
         BZ    END10                    YES                       M2110 09510421
END09    MVI   CT2IDR(GRY),X'32'        NO,  FILL WITH BLANKS     M2110 09513421
         LA    GRY,1(GRY)                                         21016 09514821
         BCT   GRZ,END09                BRANCH IF POSITIVE        21016 09516221
END10    MVC   CT2IDR(4,GRY),1(SP1)     SAVE VLML FOR END CARD    M2110 09517621
         CLI   5(SP1),ICOMMA           SHOULD BE A COMMA          21016 09519021
         BNE   DLMERR                                             21016 09520421
         LA    GRY,4(GRY)               UPDATE POINTERS           21016 09521821
         LA    SP1,6(SP1)                                         21016 09523221
         MVC   CT2IDR(5,GRY),0(SP1)     SAVE DATE FOR END CARD    21016 09524621
         CLI   5(SP1),IRPARN            SHOULD END WITH RPAREN    21016 09526021
         BNE   DLMERR                                             21016 09527421
         MVI   CTIDR(ACT),C'2'          IND 2 IDR'S IN END CARD   21016 09528821
         L     GRZ,CTRTBP(ACT)          LOAD TR TABLE PTR         21016 09530221
         TR    CT2IDR(19,ACT),0(GRZ)    TRANSLATE TO EXTERNAL     21016 09531621
         CLI   F8INST+15(ACT),X'00'     PRINT LCTR ?              21016 09533021
         BNE   END00                                              21016 09534421
         B     AOPRTN                   YES                       21016 09535821
*********************************************************************** 09537221
***   LTORGB   ***                                                      09538621
*THIS ROUTINE TESTS TO SEE IF ANY LITERALS NEED BE OUTPUT. IF LITERALS  09540000
* ARE TO BE OUTPUT, THE ADJUSTED LOCATION OF THE FIRST LITERAL IS       09560000
* PUT FOR OUTPUT IN THE LOCATION FIELD. IF NO LITERALS ARE TO BE OUTPUT 09580000
* CONTROL IS RETURNED TO F-, MAIN LINE CONTROL. LOCATION COUNTER        09600000
* REMAINS CURRENT LOCATION COUNTER.                                     09620000
*********************************************************************** 09640000
LTORGB   MVC   TSTYPE(1),F8WORK+2(ACT)  MOVE TYPE OF OP FOR ALTERATION  09660000
         ST    GRX,CTWRAPX(ACT)         REPLACE ADJUSTED LOCATION CTR   09680000
         NI    TSTYPE,X'70'             KEEP JUST TYPE OF OPERATION     09700000
         CLI   TSTYPE,X'50'             IS THIS AFTER END CARD          09720000
         BE    LTORG0                   YES, DONT PRINT LOC             09740000
         MVI   F8INST+15(ACT),X'00'     JUST EJECT CARD AND PRINT LOC   09760000
LTORG0   OI    F8INST+15(ACT),X'F0'     SET FLAG TO EJECT CARD          09780000
         TM    TXESI(GRA),LITQ          DOES LAT HAVE TO BE READ IN     09800000
         BZ    LTORG1                   NO                              09820000
         L     SRB,CTXTIO(ACT)            YES - GET NEXT LIT ADJ TABLE  09840000
         BAL   SRR,GETLAT(SRB)          CALL LAT GET                    09860000
         ST    SP1,LATP(ACT)            SAVE POINTER                    09880000
LTORG1   L     ACC,CTXABP(ACT)                                          09900000
         MVC   TEMPF+1(3),TXLOC(ACC)    GET LOC CTR FROM TEXT           09920000
         L     ACC,TEMPF                                                09940000
         A     ACC,F8CADJ(ACT)            ADJUST                        09960000
         ST    ACC,CTLOC(ACT)           SET CURRENT LOC CNT             09980000
         B     CTRTRN(ACT)              EXIT                            10000000
LITQ     EQU   2                                                        10020000
TEMPF    DC    F'0'                     FULL WORD FOR ALIGNMENT         10040000
*********************************************************************** 10060000
***   USINGB   ***                                                      10080000
*THIS ROUTINE SETS AN INDICATOR FLAG TO INDICATE A REGISTER MAY BE USED 10100000
* AS A BASE REGISTER.  THE VALUE FOR DECOMPOSITION IS HELD IN THE THREE 10120000
* LOW ORDER BYTES AND THE ESD-ID IS LOGICALLY ADDED INTO THE HIGH ORDER 10140000
* BYTE.                                                                 10160000
*********************************************************************** 10180000
USINGB   MVI   BUSING,X'00'             TURN USING OFF                  10200000
         MVI   USINGR0,X'00'            SET 1ST TIME V REG SWITCH TO 0  10220000
         MVI   F8INST+15(ACT),X'00'     PRINT LOCATION                  10240000
         LA    GRB,16                  PROCESS ONLY 16 REGISTERS        10260000
         SR    GRD,GRD                 ZERO ESD-ID REGISTER             10280000
         L     SRB,CEEVAL(ACT)          EEVAL ENTRY AND BASE            10300000
         BALR  SRR,SRB                  EVALUATE EXPRESSION             10320000
         BC    8,VALUEK                 ABSOLUTE EXPRESSION             10340000
         BC    4,SIMREL                 SIMPLY RELOCATABLE EXPR         10360000
         BC    2,ERRUSG                 COMPLEXLY RELOCATABLE EXPR      10380000
         BC    1,EREVL                  EXPRESSION EVALUATION ERROR     10400000
SIMREL   CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              10420000
         BNE   DLMERR                   IF NOT COMMA, SYNTAX ERROR      10440000
         LR    GRY,SP2                                                  10460000
         IC    GRD,5(SP2)              ESD-ID                           10480000
         L     GRX,0(SP2)              VALUE                            10500000
         B     US01                                                     10520000
VALUEK   LR    GRX,SP2                  ABSOLUTE VALUES                 10540000
         SR    GRD,GRD                  ZERO GRD FOR ESD-ID             10560000
US01     CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              10580000
         BNE   DLMERR                   NO, ERROR                       10600000
         STC   GRD,ESDUSG               TEMP STORE ESD-ID               10620000
         ST    GRX,VALUEB               VALUE TO VALUEB                 10640000
         MVI   BUSING,X'FF'             TURN USING OFF                  10660000
         MVI   USGFLG,X'FF'             FF INDICATES USING, NOT DROP    10680000
         MVC   F8INST(3,ACT),VALUEB+1   VALUE TO F8INST                 10700000
         LA    SP1,1(SP1)               POINT AT NEXT OPRN ARG          10720000
US02     ST    GRX,F8TEMP               STORE LOC FOR USING             10740000
USIROP   BAL   SRR,F8AREX               EXPRESSION SEIVE                10760000
         IC    GRZ,BUSING                                               10780000
         CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              10800000
         BE    DELOKB                   IF COMMA,OK                     10820000
         CLI   0(SP1),IBLANK            IS DELIMETER BLANK              10840000
         BNE   DLMERR                   IF NOT BLANK, OR COMMA, ABORT   10860000
DELOKB   TM    AEXP1,X'01'              SIZE AND ABLOLUTE TEST          10880000
         BZ    QUANOKQ                  IF 0, QUANTITY OK, CHECK REG 0  10900000
         B     ERQNDU                   REGISTER ERROR                  10920000
QUANOKT  TM    USGFLG,X'FF'             IS THIS USING STMNT             10940000
         BZ    QUANOK                   IF ZERO, ITS A DROP             10960000
         CLI   VALUEB+3,X'00'           IS REGISTER ZERO                10980000
         BE    ERQNDU                   IF ZERO REGISTER ERROR          11000000
         B     QUANOK                   BRANCH OK                       11020000
QUANOKQ  OC    USINGR0(1),VALUEB+3      CURRENT REGISTER V 1ST TIME SW  11040000
         TM    USINGR0,X'FF'            IS THIS 1ST TIME & REG 0        11060000
         BNZ   QUANOKT                  IF NON-ZERO TEST REGISTER       11080000
         TM    ESDUSG,X'FF'             IS THIS ABSOLUTE                11100000
         BNZ   QUANOO                   IF NOT, DONT CHECK FURTHER      11120000
         L     GR0,F8TEMP               VALUE FOR USING                 11140000
         LTR   GR0,GR0                  IS IT ABSOLUTE ZERO             11160000
         BNZ   ERQNDU                   IF NOT, ERROR                   11180000
QUANOO   SR    GR0,GR0                  ZERO TO REGISTER 0              11200000
         ST    GR0,F8TEMP               REG 0 VALUE ALWAYS 0            11220000
QUANOK   L     GRY,VALUEB               QUANTITY (REG)                  11240000
         L     GRC,USNGPP(ACT)                                          11260000
         TM    USGFLG,X'FF'             IS THIS USING, OR DROP          11280000
         BO    USGSKP                   IF 1, IT IS USING               11300000
         LA    GR1,0(GRY,GRC)           ADDR OF THIS USING TBL FLAG     11320000
         TM    0(GR1),X'FF'             IS THIS BEING USED              11340000
         BO    USGSKP                   YES                             11360000
         BAL   SRR,ERRZRO               ERROR ROUTINE BRANCH            11380000
         DC    AL2(ERDROP)              REGISTER TO BE DROPED NOT USED  11400000
USGSKP   STC   GRZ,0(GRY,GRC)           STORE FLAG IN USING POINTER     11420000
         SLL   GRY,2                                                    11440000
         L     GRX,F8TEMP               PICK UP SUMMED VALUE AND ESDID  11460000
         L     GR2,USNGTP(ACT)                                          11480000
         ST    GRX,0(GRY,GR2)           VALUE TO USING TABLE            11500000
         IC    GRD,ESDUSG               ESD-ID THIS VALUE               11520000
         STC   GRD,0(GRY,GR2)          ESD-ID TO 1ST BYTE OF VALUE      11540000
TESNDU   CLI   0(SP1),IBLANK            IS IT A BLANK                   11560000
         MVI   USINGR0,X'FF'            SET FIRST TIME SWITCH OFF       11580000
         BE    CTRTRN(ACT)              IF BLANK, EXIT                  11600000
         LA    SP1,1(SP1)               NO                              11620000
         AL    GRX,K4096                BUMP TO NEXT AVAILABEL          11640000
         BCT   GRB,US03                 DO 16 TIMES                     11660000
LNGERR   BAL   SRR,ERRZRO               CALL LOG ERROR                  11680000
         DC    AL2(ERRLNG)             OPERAND LENGTH ERROR             11700000
         MVI   F8INST+15(ACT),X'0F'     DONT PRINT LOCATION COUNTER     11720000
         B     CTRTRN(ACT)              EXIT                            11740000
ERRUSG   BAL   SRR,ERRZRO               ERROR ROUTINE BRANCH            11760000
         DC    AL2(ERRLOC)              RELOCATABILITY ERROR            11780000
         MVI   F8INST+15(ACT),X'0F'     DONT PRINT LOCATION COUNTER     11800000
         B     CTRTRN(ACT)              EXIT                            11820000
US03     ST    GRX,F8TEMP               PUT FOR FUTURE USE              11840000
US04     NI    F8TEMP,X'00'             ZERO TO BYTE                    11860000
         B     USIROP                   DO NEXT REGISTER                11880000
*********************************************************************** 11900000
***   DROPB   ***                                                       11920000
*THIS ROUTINE SETS AN INDICATOR FLAG TO INDICATE A REGISTER MAY NOT BE  11940000
* USED AS A BASE REGISTER.                                              11960000
*********************************************************************** 11980000
DROPB    MVI   USGFLG,X'00'             TURN USING FLAG OFF             12000000
         MVI   BUSING,X'00'             USING POINTER FLAG TO 0         12020000
         LA    GRB,16                  PROCESS ONLY 16 REGISTERS        12040000
         SR    GRD,GRD                 ZERO ESD-ID REGISTER             12060000
         SR    GRX,GRX                 ZERO VALUE                       12080000
         STC   GRD,ESDUSG               ZERO ESD-ID FOR ABSOLUTE        12100000
         B     US02                    COMMON ENTRY FOR USING & DROP    12120000
*********************************************************************** 12140000
***   LITERB   ***                                                      12160000
*THIS ROUTINE PLACES THE ADDRESS OF THE LITERAL FOR OUTPUT AND BRANCHES 12180000
* TO A COMMON EXIT FOR LITERAL, DC, AND DS.                             12200000
*********************************************************************** 12220000
LITERB   MVC   F8INST(3,ACT),CTLOC+1(ACT)  PUT IN LOCATION COUNTER      12240000
         LA    GRZ,10                   MIXED VALUE                     12260000
         B     DCDSLT                   COMMON EXIT                     12280000
*********************************************************************** 12300000
***   DSB   ***                                                         12320000
*THIS ROUTINE SETS GRZ TO ZERO CONTINUES WITH COMMON ROUTINE TO LITERAL 12340000
* DC AND DS.                                                            12360000
*********************************************************************** 12380000
DSB      SR    GRZ,GRZ                 SET DS FLAG                      12400000
DCDSLT   L     SRB,CDCVAL(ACT)          GET BASE/ENTRY OF DC EVAL       12420000
         ST    GRX,CTWRAPX(ACT)         PUT BACK ADUSTED LOC CTR        12440000
         MVI   F8INST+15(ACT),X'00'     PRINT LOCATION COUNTER          12460000
         BALR  SRR,SRB                  CALL DC EVAL  IEUF8D            12480000
         B     CTRTRN(ACT)              EXIT                            12500000
SAVER    EQU   206                                                      12520000
*********************************************************************** 12540000
***   DCB   ***                                                         12560000
*THIS ROUTINE STARTS AT THE COMMON BRANCH FOR LITERAL, DC, AND DS.  GRZ 12580000
* WILL ALWAYS CONTAIN A NON-ZERO VALUE.                                 12600000
*********************************************************************** 12620000
DCB      LA    GRZ,255                  ALL BITS                        12640000
         B     DCDSLT                   GO TO COMMON EXIT               12660000
*********************************************************************** 12680000
***   CCWB   ***                                                        12700000
*THIS ROUTINE PROCESS THE OPERAND FIELD OF A CCW STATEMENT.  DATA IS    12720000
* SET FOR THE F8OP ROUTINE TO OUTPUT.  RLD ENTRIES ARE MADE IF          12740000
* NECESSARY                                                             12760000
*********************************************************************** 12780000
CCWB     ST    GRX,CTWRAPX(ACT)         REPLACE ADJUSTED LOC CTR        12800000
         L     GRX,CTXABP(ACT)          GET APPENDED FIXED FIELD PTR    12820000
         LA    GR0,8                    CCW LENGTH FOR WRAP TEST        12840000
         ST    GR0,CTF8LNGT(ACT)        LENGTH FOR WRAP TEST            12860000
CCWB0A   MVI   F8INST+15(ACT),X'48'     SET DC AND LENGTH OF 8          12880000
         LA    GR0,8                                                    12900000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 12920000
         CLI   0(SP1),IBLANK           IS OPERAND BLANK                 12940000
         BE    DLMERR                   IF SO, DELIMETER ERROR          12960000
         CLI   0(SP1),IEQUAL            IS NEXT CHAR EQUAL              12980000
         BE    DLMERR                   IF SO, DELIMETER ERROR          13000000
         BAL   SRR,F8AREX               PROCESS EXPRESSION              13020000
         CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              13040000
         BNE   DLMERR                   DELIMETER ERROR, ABORT          13060000
         TM    ERRSW,X'FF'               WAS EXPRESSION IN ERROR        13080000
         BO    CCW02                     IF SO SKIP FIRST OPERAND       13100000
         TM    AEXP2,X'01'              IS ABSOLUTE AND SIZE OK         13120000
         BZ    CCW01                    YES, CONTINUE                   13140000
         TM    AEXP3,X'01'              IS THIS RELOCATABILITY ERROR    13160000
         BZ    CCWR01                   IF ZERO, NO                     13180000
         BAL   SRR,ERRZRO               LOG ERROR AND ZERO INSTRUCTION  13200000
         DC    AL2(ERRLOC)              RELOCATABILITY ERROR            13220000
         B     CCW02                    SCAN NEXT OPERAND FIELD         13240000
CCWR01   BAL   SRR,ERRZRO               LOG ERROR                       13260000
         DC    AL2(ERRLAR)              TOO LARGE EXPRESSION            13280000
         B     CCW02                    SCAN NEXT OPERAND FIELD         13300000
CCW01    STC   SP2,F8INST+3(ACT)        MACHINE OP CCW                  13320000
CCW02    LA    SP1,1(SP1)               LOOK AT NEXT CHAR               13340000
         CLI   0(SP1),IEQUAL            IS DELIMETER EQUAL              13360000
         BE    DLMERR                   DELIMETER ERROR                 13380000
         CLI   0(SP1),IBLANK            IS NEXT OPERAND CHARACTER BLANK 13400000
         BE    DLMERR                   IF SO, DELIMETER ERROR          13420000
         BAL   SRR,F8AREX               PROCESS 2ND EXPRESSION          13440000
         CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              13460000
         BNE   DLMERR                   NO, ERROR                       13480000
         TM    AEXP3,X'01'              IS ABSOLUTE AND SIZE OK         13500000
         BZ    CCW03                    YES, OK                         13520000
         TM    SREXP,X'01'              IS IT RELOCATABLE               13540000
         BZ    RLDRTN00                 YES, RELOCATE                   13560000
         TM    CREXP,X'01'              IS IT COMPLEX RELOCATABLE       13580000
         BZ    RLDRTN00                 YES, RELOCATE                   13600000
         TM    VALUEB,X'FF'             SIZE CHECK                      13620000
         BZ    CCW03                    OK, CONTINUE                    13640000
         BAL   SRR,ERRZRO               LOG ERROR                       13660000
         DC    AL2(ERRLAR)              EXPRESSION TOO LARGE            13680000
         B     CCW04                    SKIP RLD ENTRY RTN FOR ABSOLUTE 13700000
CCW03    MVC   F8INST+4(3,ACT),VALUEB+1 DATA ADDRESS FOR CCW            13720000
         B     CCW04                    SKIP RLD ENTRY RTN FOR ABSOLUTE 13740000
*                                                                     * 13760000
***                   RLD ROUTINE                                   *** 13780000
*                                                                     * 13800000
RLDRTN00 MVC   F8INST+4(3,ACT),VALUEB+1 DATA ADDRESS FOR CCW            13820000
         STM   SP2,SP1,F8REGS           OPERAND REGISTERS FOR LATER     13840000
         L     SRB,STLOCADR             ADDRESS OF DC STLOC DATA        13860000
         MVC   1(3,SRB),F8INST(ACT)     MOVE CURRENT LOCATION COUNTER/  13880000
         OI    3(SRB),X'01'             OR IN LOW ORDER BIY FOR RLD     13900000
         LR    SP1,SP2                  POINTER TO VALUE & TABLE OF ESD 13920000
         LA    SP2,X'08'                SET FOR THREE                   13940000
         L     SRB,CDCVAL(ACT)          DCEVAL BASE                     13960000
         L     GR1,RLDRTNAD             RLD ROUTINE ADDRESS             13980000
         BALR  SRR,GR1                  PROCESS RLD                     14000000
         LM    SP2,SP1,F8REGS           GET BACK REGISTERS              14020000
CCW04    LA    SP1,1(SP1)               LOOK AT NEXT CHAR               14040000
         CLI   0(SP1),IBLANK            IS NEXT OPERAND CHARACTER BLANK 14060000
         BE    DLMERR                   IF SO, DELIMETER ERROR          14080000
         CLI   0(SP1),IEQUAL            IS NEXT CHAR EQUAL              14100000
         BE    DLMERR                   IF SO, DELIMETER ERROR          14120000
         BAL   SRR,F8AREX               PROCESS 3RD EXPRESSION          14140000
         CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              14160000
         BNE   DLMERR                   NO, LOG ERROR                   14180000
         TM    AEXP2,X'01'              SIZE AND ABSOLUTE TEST          14200000
          BO   CCW04A                    IF 1, ERROR                    14220000
         TM    VALUEB+3,X'07'           BOTTOM 3 BITS CHECK             14240000
         BZ    CCW06                    OK                              14260000
CCW05    BAL   SRR,ERRNO0               LOG ERROR                       14280000
         DC    AL2(ERRCCW)              CCW ERROR                       14300000
         B     CCW06                    PUT IN FLAGS ANYWAY             14320000
CCW04A   TM    AEXP3,X'01'              IS THIS RELOCATABILITY ERROR    14340000
         BZ    CCWR02                   IF ZERO, NO                     14360000
         BAL   SRR,ERRZRO               LOG ERROR                       14380000
         DC    AL2(ERRLOC)              RELOCATABILITY ERROR            14400000
         B     CCW07                    SCAN NEXT OPERAND FIELD         14420000
CCWR02   BAL   SRR,ERRZRO               LOG ERROR                       14440000
         DC    AL2(ERRLAR)              EXPRESSION TO LARGE             14460000
         B     CCW07                    SCAN NEXT OPERAND FIELD         14480000
CCW06    MVC   F8INST+7(1,ACT),VALUEB+3 FLAGS FOR CCW                   14500000
CCW07    LA    SP1,1(SP1)               LOOK AT NEXT CHAR               14520000
         CLI   0(SP1),IBLANK            IS NEXT OPERAND CHARACTER BLANK 14540000
         BE    DLMERR                   IF SO, DELIMETER ERROR          14560000
         CLI   0(SP1),IEQUAL            IS NEXT CHAR EQUAL              14580000
         BE    DLMERR                   IF SO, DELIMETER ERROR          14600000
         BAL   SRR,F8AREX               PROCESS 4TH EXPRESSION          14620000
         CLI   0(SP1),IBLANK            IS DELIMETER BLANK              14640000
         BNE   DLMERR                   NO, ERROR                       14660000
         TM    AEXP3,X'01'              ABSOLUTE CHECK                  14680000
         BO    CCW08                    NOT, ERROR                      14700000
          CLC  VALUEB(2),KX0000          CHECK IF SIZE IS RIGNT         14720000
         BNE   CCWR03                   ERROR                           14740000
        MVC   F8INST+9(2,ACT),VALUEB+2 COUNT FOR CCW                    14760000
         B     AOPRTN                   EXIT FROM AOP RTN               14780000
CCWR03   BAL   SRR,ERRZRO               LOG ERROR                       14800000
         DC    AL2(ERRLAR)              EXPRESSION TOO LARGE            14820000
         B     AOPRTN                   RETURN TO MAIN LINE             14840000
CCW08    BAL   SRR,ERRZRO               LOG ERROR                       14860000
         DC    AL2(ERRLOC)              RELOCATABILITY ERROR            14880000
         B     AOPRTN                   EXIT FROM AOP RTN               14900000
*********************************************************************** 14920000
***   CNOPB   ***                                                       14940000
*THIS ROUTINE OUTPUTS A VARIABLE NUMBER OF BC 0,0 INSTRUCTIONS.         14960000
*********************************************************************** 14980000
CNOPB    ST    GRX,CTWRAPX(ACT)         REPLACE ADJUSTED LOCATION CTR   15000000
         L     GRX,CTXABP(ACT)          APPENDED FIXED FIELD POINTER    15020000
         MVI   F8INST+15(ACT),X'00'     FIX FOR NO OUTPUT               15040000
         TM    4(GRX),X'06'             IF ZERO, NO BCT OUTPUT          15060000
         BZ    CTRTRN(ACT)              EXIT TO MLC                     15080000
         LA    GRY,6                    MASK TO REGISTER                15100000
         IC    GRZ,4(GRX)               ALIGNMENT TO REGISTER           15120000
         NR    GRY,GRZ                  KEEP JUST EVEN ALIGNMENT        15140000
         STC   GRY,F8INST+15(ACT)       PUT NUMBER OF BYTES FOR OUTPUT  15160000
         OI    F8INST+15(ACT),X'40'     PUT OUT AS DC                   15180000
         MVC   ALIGNT+1(3),F8INST(ACT)  REPLACE LOCATION                15200000
         MVI   ALIGNT,X'00'             ZERO FIRST BYTE                 15220000
         L     GRZ,ALIGNT               GET LOCATION IN REGISTER        15240000
         SR    GRZ,GRY                  BACK UP TO LOCATION             15260000
         ST    GRZ,ALIGNT               REPLACE                         15280000
         MVC   F8INST(3,ACT),ALIGNT+1   PUT FOR OUTPUT                  15300000
         EX    GRY,BCTRMV               BCR TO OUTPUT AREA              15320000
         B     CTRTRN(ACT)              RETURN TO MAIN LINE CONTROL     15340000
BCTRMV   MVC   F8INST+3(0,ACT),BCTROP   INDEXED MOVE, THRU EXECUTE      15360000
*********************************************************************** 15380000
***   SETSEC   ***                                                      15400000
*THIS ROUTINE SETS CURRENT ADJUSTMENT BASE BY USING CURRENT ESD-ID FOR  15420000
* TABLE SEARCH OF ADJUSTMENT TABLE ENTRIES.                             15440000
*********************************************************************** 15460000
SECSET   STM   GRB,GRA,F8REGS           STUFF ALL REGISTERS             15480000
         BAL   SRR,SETSEC               GO TO SET SECTION NUMBER        15500000
         LM    GRB,GRA,F8REGS           RESTORE REGISTERS               15520000
         BR    SRR                      RETURN TO MAIN PROGRAM          15540000
SETSEC   STC   SP2,WORDBB               CURRENT ESD-ID                  15560000
         CLC   WORDBB(1),0(SP1)         COMP. TO ADJ TABLE ENTRIES      15580000
         BE    SECFND                   FOUND, SET FOUND                15600000
         LA    SP1,4(SP1)               NOT FOUND, BUMP BY 4            15620000
         L     GRX,CTLATB(ACT)          END OF TABLE + 1                15640000
         CR    SP1,GRX                  IS TABLE EXHAUSTED              15660000
         BL    SETSEC                   EXIT WHEN TABLE EXHAUSTED       15680000
         L     SP2,CTZERO(ACT)          ZERO CELL TO SHOW ERROR         15700000
         B     SECFNX                    ERR O                          15720000
SECFND   L     SP2,BYTES3               0FFF FOR MASK                   15740000
         N     SP2,0(SP1)               EXTRACT CSECT ORG               15760000
SECFNX   ST    SP2,F8CADJ(ACT)          STORE                           15780000
         MVC   F8INST(3,ACT),F8CADJ+1(ACT)                              15800000
         BR    SRR                      RETURN                          15820000
WORDBB   DC    F'0'                                                     15840000
BYTES3   DC    X'00FFFFFF'             THREE BYTE MALK                  15860000
         IC    SP2,1(SP1)               WORK BUCKET ESD-ID              15880000
         STC   SP2,CESDID(ACT)          TO CESDID(ACT)                  15900000
CSECXT   B     CTRTRN(ACT)              RETURN TO MAIN LINE             15920000
*********************************************************************** 15940000
***   F8AREX   ***                                                      15960000
*THIS ROUTINE IN AOP USES EEVAL FOR GETTING VALUES.  A CHECK IS MADE    15980000
* FOR SIZE.  IF SIZE IS OK BIT 7 IS SET TO ZERO IN PROPER FLAG WORD.    16000000
*********************************************************************** 16020000
F8AREX  L      GRZ,ALBITS                                               16040000
         ST    SRR,HLDSRR               SAVE RETURN ADDRESS             16060000
        ST     GRZ,EXFLGS               SET EXPRESION FLAGS ONES        16080000
         MVI   CREXP,X'FF'              TURN OFF COMPLEXLY RELOCATABLE  16100000
         XC    VALUEB(6),VALUEB         ZERO VALUE AND SIGN AND ESD-ID  16120000
         MVI   EVLERF,X'00'             TURN EVAL ERR FLAG OFF          16140000
        L      SRB,CEEVAL(ACT)          GET BASE/ENTRY OF EVAL          16160000
        BALR   SRR,SRB                  CALL EVAL  IEUF8V               16180000
        BC     8,AEXP                   ABSOLUTE EXPRESSION             16200000
        BC     4,JSREXP                 SIMPLE RELOCATABLE              16220000
         BC    2,JCREXP                 COMPLEXLY RELOCATABLE           16240000
        BC     1,EREVAL                 COULD NOT EVALUATE              16260000
         B     ASERRB                   STATEMENT TOO COMPLEX           16280000
AEXP     LTR   GRY,SP2                  CURRENT EXP VALUE TEST NEGATIVE 16300000
        ST     GRY,VALUEB               SAVE VALUE                      16320000
         TM    VALUEB,X'FF'             TEST FOR WRAP AROUND            16340000
         BM    EXWRAP                   IF MIXED, WRAP AROUND OCCURRED  16360000
         MVI   VALUEB,X'00'             ZERO FIRST BYTE OF VALUE        16380000
         SL    GRY,K16                  IF LESS THAN +16, OK            16400000
        BM     SEXP1                    OK                              16420000
         L     GRY,VALUEB               RESTORE VALUE TO GRY            16440000
         SL    GRY,K256                 IF LESS THAN 256, OK            16460000
        BM     SEXP2                    OK                              16480000
         B     SEXP3                    SET ABSOLUTE OK                 16500000
EXWRAP   BAL   SRR,ERRZRO               ZERO INSTRUCTION AND LOG ERROR  16520000
         DC    AL2(ERRWRP)              WRAP AROUND ERROR CODE          16540000
         XC    VALUEB(4),VALUEB         ZERO VALUE                      16560000
         B     SEXP3                    SET ABSOLUTE                    16580000
JCREXP   MVI   CREXP,X'00'              TURN ON COMPLEXLY RELOCATABLE   16600000
         MVC   VALUEB(4),0(SP2)         VALUE TO VALUEB                 16620000
         B     PASSRE                   EXIT                            16640000
JSREXP   NI    SREXP,X'FE'              SET SIMPLY RELOC SWTCH          16660000
         MVC   VALUEB(6),0(SP2)         EXPRESSION VALUE, SIGN & ESD-ID 16680000
        B      PASSRE                   EXIT                            16700000
SEXP1    NI    AEXP1,X'FE'               ET ABS. < 16 OK                16720000
SEXP2    NI    AEXP2,X'FE'               SET ABS. < 256 OK              16740000
SEXP3    NI    AEXP3,X'FE'               SET ABSOLUTE EXP OK            16760000
PASSRE   L     SRR,HLDSRR               GET SUBROUTINE RETURN           16780000
        BR     SRR                      RETURN                          16800000
EREVAL   SR    GR0,GR0                 ZERO A REGISTER                  16820000
         ST    GR0,EXFLGS               TURN OTHER ERRORS OFF           16840000
         LTR   SP1,SP1                 IF ZERO, ABORT                   16860000
         MVI   ERRSW,X'FF'              TURN ON LOCAL ERROR SWITCH      16880000
         BZ    AOPRTN                  IF ZERO BRANCH                   16900000
         MVI   EVLERF,X'FF'             TURN EVAL ERR FLAG ON           16920000
         L     SRR,HLDSRR               GET SUBROUTINE RETURN           16940000
         BR    SRR                      EXIT F8AREX                     16960000
ASERRB   BAL   SRR,ERRZRO               LOG ERROR                       16980000
         DC    AL2(ERRASM)              STATEMENT COMPLEXITY EXCEEDED   17000000
         B     AOPRTN                   EXIT                            17020000
ERQNDU   BAL   SRR,ERRZRO               LOG ERROR                       17040000
         DC    AL2(ERRREG)              REGISTER ERROR                  17060000
         LM    GR0,GRY,ERRREGS          PICK UP ALL REGISTERS           17080000
         B     TESNDU                   GO BACK FOR MORE                17100000
DLMERR   BAL   SRR,ERRZRO               DELIMETER ERROR                 17120000
         DC    AL2(ERRDLM)              LOG ERROR                       17140000
ZEROINST MVI   ERRSW,X'FF'             TURN ON ERROR SWITCH             17160000
AOPRTN   TM    ERRSW,X'FF'              ASSEMBLER OP PROCESSOR RETURN   17180000
         BZ    DNTZRO                   NO ERROR, SKIP                  17200000
         XC    F8INST+3(12,ACT),F8INST+3(ACT) ZERO INSTRUCTION          17220000
         SR    SP2,SP2                  ZERO SP2 FOR NO SPACING         17240000
DNTZRO   B     CTRTRN(ACT)              DONT ZERO INSTRUCTION           17260000
ERRZRO   MVI   ERRSW,X'FF'              SET ERROR SWITCH ON             17280000
ERRNO0   L     SRB,CLOGER(ACT)          LOAD LOGERR BASE AND ENTRY      17300000
         STM   GR0,GRY,ERRREGS          SAVE ALL REGISTERS              17320000
         BR    SRB                      EXIT TO LOGERR                  17340000
         ENTRY SECSET                   SETS CURRENT ADJUSTMENT BASE SV 17360000
         ENTRY SETSEC                   SAME AS ABOVE BUT DOESNT SAVE   17380000
FWORD    DS    2D                       2 DOUBLE WORDS TEMP             17400000
DWORD    DS    D                        DOUBLE WORD TEMP                17420000
RLDRTNAD DC    V(RLDRTN)                EXTERNAL ADDRESS OF DC RLD RTN  17440000
STLOCADR DC    V(STLOC)                 LOCATION ADDRESSED IN DC RTN    17460000
PNTSAV   DC    3F'0'                    THREE PRINT SWITCH SETTINGS     17480000
FOURB    DC    F'4'                     CONSTANT FOUR                   17500000
ENTSAVE  DC    F'0'                     ENTRY ERROR OPERAND POINTER     17520000
F8TEMP   DS    F                        HOLE FOR TEMP STORAGE           17540000
F8REGS   DS    16F                      SAVE AREA FOR SECSET            17560000
ERRREGS  DS    16F                      SAVE REGISTERS ON ERRORS        17580000
VALUEB   DS    F                        EVALUATED VALUE FROM F8AREX     17600000
EXPESD   DC    X'0000'                  EXPRESSION SIGN AND ESD-ID      17620000
BCTROP   DC    X'070007000700'          THREE BCR COMMANDS              17640000
NDATAC   DC    X'17180D0A1D0A'          NODATA                          17660000
DATAC    DC    X'0D0A1D0A'              DATA                            17680000
NOGENC   DC    X'1718100E17'            NOGEN                           17700000
GENC     DC    X'100E17'                GEN                             17720000
OFFC     DC    X'180F0F'                OFF                             17740000
ONC      DC    X'1817'                  ON                              17760000
RLDFLG   DC    X'08'                    INDICATES 2 WHICH MEANS 3       17780000
EQUAL    DC    X'2C'                    HEX FOR EQU AL SIGN             17800000
NINEEN   DC    F'19'                    CONSTANT OF 19                  17820000
K16     DC     F'16'                    DECIMAL 16                      17840000
K256     DC    F'256'                   DECIMAL 265                     17860000
K4096    DC    F'4096'                  DECIMAL 4096                    17880000
KX0000    DC    X'0000'                  TWO BYTES OF ZERO              17900000
ZEROM    DC    F'0'                     FULL WORD OF ZERO               17920000
ALBITS   DC    X'FFFFFFFF'              FULL WORD OF BITS               17940000
ALIGNM   DC    F'0'                     FOR ALIGNING HALF AND FULL WORD 17960000
ALIGNT   DS    F                        FOR ALIGNMENT HALF AND FULL WRD 17980000
TOOBIG   DC    X'00003000'              *                               18000000
HLDSRR   DS    F                        RETURN ADDRESS FOR F8AREX       18020000
CREXPC   DS    F                        COMPLEXLY RELOCATABLE SWITCH    18040000
EXFLGS   DS    0F                       EXPRESSION FLAGS                18060000
AEXP1    DC    X'00'                    FLAG- ABSOLUTE LT 16            18080000
AEXP2    DC    X'00'                    FLAG- ABSOLUTE LT 256           18100000
AEXP3    DC    X'00'                    FLAG- ABSOLUTE LT 4096          18120000
SREXP    DC    X'00'                    FLAG- SIMPLE RELOCATABLE        18140000
CREXP    DC    X'00'                    COMPLEX RELOCATABLE FLAG        18160000
EVLERF   DC    X'00'                    F8AREX ERROR FLAG               18180000
BUSING   DC    X'00'                    USING SWITCH                    18200000
BIT6     DC    X'02'                    BIT 6                           18220000
BIT7     DC    X'01'                    BIT 7                           18240000
TEN      DC    X'0A'                    10                              18260000
BITS45   DC    X'0C'                    BITS 4 AND 5                    18280000
USINGR0  DC    X'FF'                    SWITCH FOR USING REGISTER 0     18300000
USGFLG   DC    X'00'                   USING FLAG                       18320000
ESDUSG   DC    X'00'                    ESD-ID USED IN USING STATEMENT  18340000
ERRSW    DC    X'00'                   ERROR SWITCH                     18360000
PRNTFLAG DC    X'00'                    FLAG FOR DUPLICATE PRNT SWITCH  18380000
ABSRX    DS    C                        ABSOLUTE FLAG                   18400000
FRSTIM   DS    C                        FIRST TIME SWITCH FOR F8AREX    18420000
TSTYPE   DC    X'00'                    TYPE OF OPERATION SLOT          18440000
USNGPP   EQU   CTXIO3                   I/O BUFFER 3                    18460000
USNGTP   EQU   CTXIO4                   I/O BUFFER 4                    18480000
QUOTE    EQU   X'31'                    TRANSLATED QUOTE                18500000
WKBKPT   EQU   CTXOFP                   PHASE 8 WORK BUCKET POINTER     18520000
LATP     EQU   CTXWAP                   LITERAL ADDRESS TABLE POINTER   18540000
SIGN     EQU   0                        SIGN                            18560000
PID      EQU   0                        POSITION ID                     18580000
RID      EQU   1                        RELOCATION ID (PARAM TABLE)     18600000
VAL      EQU   2                        V OR A, LENGTH INDICATOR        18620000
ADDR     EQU   3                        ADDRESS                         18640000
RELID    EQU   1                        RELOCATION ID (RLD)             18660000
PLSCON   EQU   1                        PLUS CONSTANT                   18680000
PNEXT    EQU   2                                                        18700000
ERRORG   EQU   6                        ERROREOUS ORG STATEMENT FLAG    18720000
ERRWRP   EQU   7                        WRAP AROUND ERROR CODE          18740000
ERRDIS   EQU   8                        EXPRESSION TOO LARGE            18760000
ERRREG   EQU   10                       REGISTER SPECIFICATION ERROR    18780000
ERRLAR   EQU   17                       EXPRESSION TOO LARGE            18800000
ERRUDF   EQU   24                       UNDEFINED SYMBOL                18820000
ERRLOC   EQU   25                       RELOCATABILITY ERRORS           18840000
ERDROP   EQU   28                       REGISTER NOT USED               18860000
ERRCCW   EQU   29                       BITS 37-39 OF CCW NON-ZERO      18880000
ERRLIN   EQU   33                       ERROR CODE FOR ALIGNMENT ERROR  18900000
ERRNTY   EQU   38                       ENTRY ERROR                     18920000
ERRDLM   EQU   39                       INVALID DELIMITER               18940000
ERRLNG   EQU   98                       LENGTH ERROR                    18960000
ERRASM   EQU   100                     OPERAND TOO COMPLES(ASSEMBLER ER 18980000
ERROPN   EQU   107                      OPERAND ERROR                   19000000
ERRPNT   EQU   107                      UNRECOGNIZABLE PRINT PRAMTR     19020000
EREVL    EQU   AOPRTN                   EXPRESSION EVALUATION ERROR     19040000
EQUERR   EQU   ASERRB                   STATEMENT TOO COMPLEX ERROR     19060000
PPTR     EQU   GRA                      PARAMETER TABLE POINTER         19080000
RLDPTR   EQU   SP1                      RLD POINTER                     19100000
COUNT    EQU   GRB                      COUNTER REGISTER                19120000
KMNOTE   EQU   X'0E'                   HEXOP FOR MNOTE                  19140000
PATCHAOP DC    40F'0'                   PATCH AREA FOR AOP RTN          19160000
         END                                                            19180000
