F8C      TITLE 'F8MLC--F8 MAIN LINE CONTROL--CSS/NO INITIALIZATION'     00020000
         ISEQ  73,80                                                    00040000
IEUF8C   START 0                        MAIN LINE CONTROL PHASE 8       00060000
*          RELEASE 17 DELETIONS                                         00061000
*1471041200,041600                                                20587 00062000
*          RELEASE 18 DELETIONS                                         00063000
*          RELEASE 19 DELETIONS                                         00064000
*          RELEASE 20 DELETIONS                                         00065000
* 012400-014400                                                  200003 00065500
*          RELEASE 21 DELETIONS                                         00066000
*          RELEASE 22 DELETIONS                                         00067000
*          RELEASE 23 DELETIONS                                         00068000
*          RELEASE 24 DELETIONS                                         00069000
*          RELEASE 25 DELETIONS                                         00070000
F8MLC   EQU   IEUF8C                   OLD NAME OF MAIN LINE CONTROL    00080000
         PRINT NODATA,NOGEN                                             00100000
         FDIMEN                                                         00120000
         PRINT DATA,GEN                                                 00140000
*                                                                     * 00160000
*TITLE 'IEUF8C  ' ...  PHASE 8,MAIN LINE CONTROL                      * 00180000
*STATUS- CHANGE LEVEL  005                                            * 00200000
*FUNCTION/OPERATION-                                                  * 00220000
*   PROCESS EDITED TEXT RECORDS FROM IEUF7. CONTROL THE CALLING OF    * 00240000
*   IEUF8 ROUTINES FOR THE FINAL PROCESSING OF THE ASSEMBLY.          * 00260000
*ENTRY POINTS-                                                        * 00280000
*   IEUF8C- MAIN LINE CONTROL                                         * 00300000
*     INVOKED BY IEUF8I BY                                            * 00320000
*        B     CTRTRN(ACT)              CALL MAIN LINE CONTROL        * 00340000
*   SRLINE- ALIGNMENT ROUTINE                                         * 00360000
*     CALLED INTERNALLY BY                                            * 00380000
*        BAL   SRR,SRLIGN               ALIGN                         * 00400000
*INPUT- NONE                                                          * 00420000
*OUTPUT- NONE                                                         * 00440000
*EXTERNAL ROUTINES-                                                   * 00460000
*        NAME     ROUTINE     FUNCTION                                * 00480000
*                                                                     * 00500000
*        ASOPRO   IEUF8A      PROCESS ASSEMBLER INSTRUCTIONS          * 00520000
*        GETXTM   IEUF8I      GET TEXT AND MOVE                       * 00540000
*        PHCLS    IEUF8I      PHASE 8 CLOSE                           * 00560000
*        CLOGER   IEUF8L      LOG ERROR                               * 00580000
*        MACHOP   IEUF8M      PROCESS MACHINE OPERATIONS              * 00600000
*        BLDIMG   IEUF8P      BUILD SOURCE IMAGE                      * 00620000
*        PRNT     IEUF8P      PRINT ROUTINE                           * 00640000
*EXITS- NORMAL--                                                      * 00660000
*   AT END OF PROCESSING, CONTROL IS RETURN TO IEUF8I VAI             * 00680000
*        L     SRB,CTXTIO(ACT)          SET UP BASE                   * 00700000
*        BAL   SRR,PHCLS(SRB)           CLOSE PHASE 8                 * 00720000
*     - ERROR-- NONE                                                  * 00740000
*TABLES/WORKAREAS-                                                    * 00760000
*   F8REGS- SAVE AREA FOR ALL REGISTERS                               * 00780000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 00800000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 00820000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 00840000
*                                                                     * 00860000
         EJECT                                                          00880000
         USING *,CRB                    CONTROL ROUTINE BASE            00900000
F8NTRY   MVI   CTEMERR(ACT),X'FF'     SET MNOTE ERR FLAG OFF            00920000
F8NTRY1  XC    F8INST(16,ACT),F8INST(ACT)  ZERO INST. BLDG. AREA        00940000
         MVI   REPSW(ACT),X'00'         TURN OFF TITLE,REPRO,PUNCH,MNOT 00960000
         CLI   ERSWH(ACT),X'FF'                                         00980000
         BE    ERLOD8                   IF ERROR, SKIP                  01000000
         LA    SP1,F8WORK(ACT)          MOVE RECORD TO WORK AREA        01020000
         L     SRB,CTXTIO(ACT)          I/O BASE ADDRESS                01040000
         BAL   SRR,GETXTM(SRB)          GET TEXT AND MOVE               01060000
         BZ    ENDOFF                                                   01080000
F8OPND   LA    SP1,F8WORK(ACT)          RELOAD SP1 FOR TESTS            01100000
         TM    TXRT(SP1),PCGREC         PROCESS & CONSTRUCT IF GEN 7    01120000
         BO    PC001                                                    01140000
         TM    TXRT(SP1),PCREC          PROCESS & CONSTRUCT 6           01160000
         BO    PC001                                                    01180000
         TM    TXRT(SP1),PROCREC        PROCESS ONLY 4                  01200000
         BO    SETWBP                                                   01220000
         B     PRINTE                   PRINT RECORD AS IT IS    200003 01300000
PC001    ST    ACT,ACTREG               SAVE ACT REGISTER        200003 01380000
         L     FRB,PRNT(ACT)            PRINT ROUTINE BALE              01460000
         L     GRX,ADBLDMG             F8PRINT BLDIMG                   01480000
         BALR  SRR,GRX                  BRANCH TO BUILD IMMAGE          01500000
         L     ACT,ACTREG              LOAD ACT REGISTER                01520000
* SETWBP - SET CTXWBP(ACT) PT TO FIRST SYMBOL WORK BUCKET               01540000
*                                IN CURRENT TEXT RECORD                 01560000
*          ENTER WITH GRA PT TO TXRL, USE GRY, GRZ                      01580000
*                                                                       01600000
SETWBP   LA    GRA,F8WORK(ACT)          RECORD WORK AREA ADDRESS        01620000
         LR    GRY,GRA                  SET GRY PT TO 1ST BYTE FOLLOWNG 01640000
         AH    GRY,TXABP(GRA)                      APPENDED FIXED FIELD 01660000
         LA    GRY,TXFAFL(GRY)                                          01680000
         LR    GRZ,GRA                  SET GRZ PT TO BYTE FOLLOWING    01700000
         AH    GRZ,TXRL(GRA)                       LAST BYTE OF TEST    01720000
SETWB1   CLR   GRY,GRZ                  END OF REC                      01740000
         BC    10,SETWB3                CLEAR CTXWBP                    01760000
         TM    TXWTYP(GRY),X'80'        W.B. TYPE EQ SYMBOL             01780000
         BO    SETWB4                   SET CTXWBP PT TO 1ST SYMBOL WB  01800000
         TM    TXWLEN(GRY),X'40'        W.B. LEN                        01820000
         BZ    SETWB2                        EQ 6                       01840000
         LA    GRY,9(GRY)                    EQ 15                      01860000
SETWB2   LA    GRY,6(GRY)               STEP W.B. PTR                   01880000
         B     SETWB1                   THEN CHECK NEXT W.B.            01900000
SETWB3   SR    GRY,GRY                  NO XYMBOL W.B. SET CTXWBP EQ 0  01920000
SETWB4   ST    GRY,CTXWBP(ACT)          SET CTXWBP PT TO 1ST SYMBOL W.B 01940000
         SR    SP2,SP2                                                  01960000
         SR    GRZ,GRZ                  ZERO REGISTER                   01980000
         LA    SP2,8(SP2)               BUMP 8                          02000000
         IC    GRZ,F8WORK(SP2,ACT)      INPUT NAME LENGTH               02020000
         AR    SP2,GRZ                  ADD TO 8                        02040000
         LA    SP2,1(SP2)               BUMP BY 1                       02060000
         IC    GRZ,F8WORK(SP2,ACT)      INPUT OPERATOR LENGTH           02080000
         AR    SP2,GRZ                  SUM                             02100000
         LA    SP2,2(SP2)               BUMP BY 2                       02120000
         LA    SP2,F8WORK(SP2,ACT)      OPERAND POINTER                 02140000
         ST    SP2,F8OPRN(ACT)          SAVE OPERAND POINTER            02160000
F8WBPC   MVC   ALIGNT(2),6(GRA)         APPENDED FIXED FIELD POINTER    02180000
         LH    SP1,ALIGNT               LOAD POINTER                    02200000
         LA    GRX,F8WORK(SP1,ACT)      TXLOC POINTER                   02220000
         ST    GRX,CTXABP(ACT)          APPENDED FIXED FIELD POINTER    02240000
         LA    SP1,F8WORK+5(SP1,ACT)                                    02260000
         ST    SP1,WKBKPT(ACT)                                          02280000
         MVC   ALIGNT+1(3),0(GRX)       ALIGN RELATIVE LOCATION         02300000
         L     GRZ,BYTES3               ZERO IN FIRST BYTE              02320000
         N     GRZ,ALIGNT               THREE BYTE LOC                  02340000
       A     GRZ,F8CADJ(ACT)          CURRENT ESD-ID ADJUSTMENT VALUE   02360000
         ST    GRZ,CTWRAPX(ACT)         STORE ADJUSTED LOCATION CTR     02380000
         ST    GRZ,ALIGNT               PUT FOR MOVE TO UNALIGNED       02400000
         MVC   0(3,GRB),ALIGNT+1        CURRENT ADJUSTED LOCATION       02420000
MOPALN   TM    TXTO(GRA),X'C0'          IS STATEMENT VALID STMNT        02440000
         BZ    PPRNT                    IF ZERO, NOT VALID              02460000
         L     GRX,CTXABP(ACT)          POINTER TO APPENDED FIXED FIELD 02480000
         TM    4(GRX),X'07'                                             02500000
         BZ    MOPTST                   IF ZERO, ALIGNMENT              02520000
         TM    F8WORK+3(ACT),X'40'      IS THIS A MACHINE OPERATION     02540000
         BO    MLC01                    IF 1, IT IS A MACINE OP         02560000
         CLI   F8WORK+4(ACT),LITRHEX    NO HXOP BELO LITRL NEED ALIGNMN 02580000
         BL    MOPTST                                                   02600000
MLC01    NC    4(1,GRX),F8SEVN          JUST KEEP ALIGNMENT BITS        02620000
         SR    GRY,GRY                                                  02640000
         IC    GRY,4(GRX)               BYTES TO ALIGN                  02660000
         SR    GRZ,GRY                                                  02680000
         ST    GRZ,ALIGNT               ZERO THE BYTES TO ALIGN         02700000
         MVC   ALIGNM(7),F8INST(ACT)    ADDRESS AND HEXOP               02720000
         STM   GRA,GRD,CTSAVE(ACT)      SAVE MLC REGISTERS              02740000
         CLI   F8WORK+4(ACT),X'29'      HEX FOR CNOP                    02760000
         BE    CNOPRE                   EF EQUAL SPECIAL ALIGNMENT      02780000
         BAL   SRR,SRLIGN                                               02800000
         MVC   F8INST(7,ACT),ALIGNM     ALIGNED LOC AND HEXOP           02820000
MOPTST   TM    F8WORK+3(ACT),X'80'                                      02840000
         L     SP1,F8OPRN(ACT)          ADDRESS OF OPERAND FIELD        02860000
         BZ    MOPROC                   IF ZERO, PROCESS MACHINE OPS    02880000
         L     FRB,ASOPRO(ACT)          ASSEMBLY INSTRUCTION PROCESSOR  02900000
         MVI   EJCTSW(ACT),X'57'       SET LEFT HALF RECORD FLAG ON     02920000
         BALR  CRR,ACT                                                  02940000
         CLI   F8WORK+4(ACT),X'0E'      IS THIS A MNOTE                 02960000
         BE    MPRNT       YES, DONT PRINT                              02980000
         CLI   F8WORK+4(ACT),X'13'     IS THIS A PRINT STATEMENT        03000000
         BE    PPRNT                   IF SO, DONT PRINT                03020000
         CLI   F8WORK+4(ACT),X'25'                                      03040000
         BL    PRINT              IS LESS THAN 25 PRINT                 03060000
         CLI   F8WORK+4(ACT),X'28'     IF LITR(25), DC(26),             03080000
         BL    PPRNT              DS(27) SKIP PRINTING                  03100000
         CLI   F8WORK+4(ACT),X'29'      IF ABOVE CNOP, DONT GO TO PRINT 03120000
         BH    PPRNT                    IF HI, CHECK WRAP AROUND        03140000
PRINT    L     FRB,PRNT(ACT)            PRINT ROUTINE USES FRB          03160000
         ST    ACT,ACTREG              SAVE ACT REGISTER                03180000
         BALR  SRR,FRB                                                  03200000
         L     ACT,ACTREG              LOAD ACT REGISTER                03220000
         B     PPRNT                    CHECK WRAP AROUND               03240000
PRINTE   L     FRB,PRNT(ACT)            PRINT ROUTINE BASE              03260000
         L     GRX,CTCOMT(ACT)         F8PRINT SOURCE AND COMMENT ENTRY 03280000
         ST    ACT,ACTREG               SAVE ACT TABLE POINTER          03300000
         BALR  SRR,GRX                                                  03320000
         L     ACT,ACTREG               LOAD ACT TABLE POINTER          03340000
        B     PPRNT                                                     03360000
CNOPRE   TM    4(GRX),X'01'             IF NOT 1, NO ALIGNMENT          03380000
         BZ    MOPTST                   BYPASS ALIGNMENT FOR CNOP       03400000
         LA    GRY,1                    ALIGN ONLY ONE BYTE             03420000
         XI    4(GRX),X'01'             DROP LOW BIT                    03440000
         BAL   SRR,SRLIGN               PUT OUT ALIGNMENT BYTE          03460000
         MVC   F8INST(7,ACT),ALIGNM     KEEP OLD LOCATION               03480000
         B     MOPTST                   RETURN POST ALIGNMENT           03500000
ENDOFF   L     FRB,PRNT(ACT)           BASE FOR PRINT ROUTINE           03520000
         MVI   F8PGEN(ACT),X'00'       SET TO PRINT ANY ERRORS          03540000
         L     GRX,ENDEND              ENTRY TO CHECK FOR LAST ERROR    03560000
         BALR  SRR,GRX                 EXECUTE PRINT ROUTINE            03580000
         L     SRB,CTXTIO(ACT)         I/O BASE ADDRESS                 03600000
         BAL   SRR,PHCLS(SRB)           CLASE PHASE 8                   03620000
MOPROC   TM    F8WORK+3(ACT),X'40'                                      03640000
         BO    MOPOK                   OK TO CONTINUE IF 1              03660000
        B     PPRNT                     PRINT RECORD                    03680000
MOPOK    L     FRB,MACHOP(ACT)                                          03700000
         MVI   EJCTSW(ACT),X'57'       SET LEFT HALF RECORD FLAG ON     03720000
         BALR  CRR,ACT                                                  03740000
         B     PRINT                    GO TO COMMON EXIT THRU PRNT     03760000
ERLOD8   L     SP2,CTERRP(ACT)          ERROR WORK AREA ADDRESS         03780000
         MVC   F8WORK(36,ACT),0(SP2)    MOVE 36 ERROR REC CHARACTERS    03800000
         MVI   ERSWH(ACT),X'00'         TURN OFF ERROR WITCH            03820000
         B     F8OPND                   BYPASS TAPE INPUT               03840000
SRLIGN   LM    GRA,GRD,CTSAVE(ACT)                                      03860000
         STM   GRB,GRA,F8REGS                                           03880000
         STC   GRY,F8INST+15(ACT)                                       03900000
         OI    F8INST+15(ACT),X'C0'     ALIGNMENT AND DC FORMAT BITS    03920000
         MVC   F8INST(3,ACT),ALIGNT+1   UNALIGNED ADDRESS               03940000
         XC    F8INST+3(12,ACT),F8INST+3(ACT) XERO FOR ALIGNMENT        03960000
         L     FRB,PRNT(ACT)                                            03980000
         BALR  SRR,FRB                                                  04000000
         LM    GRB,GRA,F8REGS                                           04020000
         BR    SRR                                                      04040000
PPRNT    TM    WRAPT,X'FF'              WAS THERE WRAP AROUND           04060000
         BM    MLC10                    IF MIXED, WRAP AROUND OCCURRED  04080000
         TM    CTWRAPX(ACT),X'FF'       CHECK FOR WRAPAROUND            04100000
         BM    MLC10                    WRAPAROUND - GO LOG ERROR 20587 04120000
        CLC   CTWRAP7(4,ACT),CTSEQ8(ACT)  DID THIS WRAP IN F7           04140000
         BNE   MLC11                    NO, CONTINUE TESTING      20587 04148000
         L     GR0,CTSEQ8(ACT)          IF THIS STATEMENT # IS 00 20587 04156000
         LTR   GR0,GR0                    DO NOT LOG INVALID      20587 04164000
         BZ    MLC11                        WRAPAROUND ERROR      20587 04172000
MLC10   L     SRB,CLOGER(ACT)          IF SO, LOG AN ERROR              04180000
         LA    SP1,0                                                    04200000
        BALR  SRR,SRB                  BRANCH TO LOGERROR               04220000
        DC    AL2(ERRWRP)              WRAP AROUND ERROR                04240000
        MVC   PPRNT(4),WRAPBLOT        DONT TEST ANY MORE WRAP AROUND   04260000
WRAPBLOT B    F8NTRY                   TRY NEXT RECORD                  04280000
MLC11    L     GR0,CTWRAPX(ACT)         CURRENT LOCATION COUNTER        04300000
         LTR   GR0,GR0                  TEST CTWRAPX FOR ZERO           04320000
         BZ    F8NTRY                   IF CTWRAPX ZERO, OK             04340000
         BCTR  GR0,0                    DID IT WRAP THIS TIME           04360000
         A     GR0,CTF8LNGT(ACT)        CURRENT INSTRUCTION LENGTH      04380000
         ST    GR0,CTWRAPX(ACT)         STORE FOR WRAP AROUND TEST      04400000
         TM    CTWRAPX(ACT),X'FF'       TEST HI ORDER BYTE              04420000
        BM    MLC10                    IF MIXED, WRAP AROUND ERROR      04440000
         LA    GR0,1(GR0)               WILL IT WRAP NEXT TIME          04460000
         ST    GR0,WRAPT                STORE TO TEST ON NEXT RECORD    04480000
        XC    CTF8LNGT(4,ACT),CTF8LNGT(ACT) ZERO INSTRUCTION LENGTH     04500000
        B     F8NTRY                   PROCESS NEXT RECORD              04520000
WRAPT    DC    F'0'                     LOCAL WRAP AROUND HOLDER        04540000
WRAPVALU DC   F'0'                                                      04560000
ENDEND   DC    A(LOADRA)               ADDRESS OF PRINT ENDOFF RTN      04580000
ACTREG   DC    F'0'                    SAVE HOLE FOR ACT REGISTER       04600000
ALIGNT   DC    F'0'                     FOR ALLIGNMENT                  04620000
SECORG   DC    F'0'                     ORIGIN OF SECTION               04640000
WORDBB   DC    F'0'                                                     04660000
BYTES3   DC    X'00FFFFFF'             THREE BYTE MALK                  04680000
F8SEVN   DC    X'07'                    LOW THREE BITS OR SEVEN         04700000
F8REGS   DS    16F                      SAVE AREA FOR ALL 16 REGISTERS  04720000
ALIGNM   DS    2F                       TWO FULL WDS FOR LIGNMENT       04740000
         EXTRN LOADRA                  ENTRY IN PRINT ROUTINE           04760000
         ENTRY SRLINE                   ALIGNMENT ROUTINE               04780000
WKBKPT   EQU   CTXOFP                   PHASE 8 WORK BUCKET POINTER     04800000
SRLINE   EQU   SRLIGN             EQUATE INTERNAL/EXTERNAL NAMES        04820000
MPRNT    EQU   F8NTRY1                                                  04840000
ERRREC   EQU   X'10'                   ERROR RECORD TYPE 1              04860000
COMREC   EQU   X'20'                   COMMENT RECORD TYPE 2            04880000
COMGREC  EQU   X'30'                   GENERATED COMMENT RECORD TYPE 3  04900000
PROCREC  EQU   X'40'                   PROCESS ONLY RECORD TYPE 4       04920000
PCREC    EQU   X'60'                    TYPE 2 AND 4 RECORDS            04940000
PCGREC   EQU   X'70'                    TYPE 1,2,AND 3 RECORDS          04960000
SOURCE   EQU   X'70'                    SOURCE RECORDS                  04980000
LITRHEX  EQU   X'25'                    HEX OP FOR LITRAL               05000000
ERRWRP  EQU   7                         LOCATION COUNTER ERROR          05020000
PATCHMLC DC    40F'0'                  40 FULL WORDS PATCH AREA         05040000
ADBLDMG  DC    V(BLDIMG)               ADDR OF BUILD IMAGE IN F8PRINT   05060000
         END   F8MLC                                                    05080000
