F8D      TITLE 'F8 DCEVAL -- 1966 VERSION --'                           00020000
         ISEQ  73,80                                                    00040000
IEUF8D   START 0                        START OF DCEVAL FOR F8          00060000
*          RELEASE 13 DELETIONS                                         00061018
*151800,164400,200000-203000                                       9145 00062013
*          RELEASE 14 DELETIONS                                         00063018
*          RELEASE 15 DELETIONS                                         00064018
*          RELEASE 16 DELETIONS                                         00065018
*          RELEASE 17 DELETIONS                                         00066018
*          RELEASE 18 DELETIONS                                         00067018
*3505150400-151000,181400-181600                                   IEUK 00068018
*3505176000-176200                                                IEUN2 00069018
*          RELEASE 19 DELETIONS                                         00070018
*          RELEASE 20 DELETIONS                                         00071018
*                                                                A31016 00071520
*          RELEASE 21 DELETIONS                                         00072018
*          RELEASE 22 DELETIONS                                         00073018
*          RELEASE 23 DELETIONS                                         00074018
*          RELEASE 24 DELETIONS                                         00075018
*          RELEASE 25 DELETIONS                                         00076018
*          RELEASE 26 DELETIONS                                         00077018
DCEVAL   EQU   IEUF8D                   OLD NAME OF DC EVALUATION RTN   00080000
         PRINT DATA,NOGEN                                               00100000
         FDIMEN                                                         00120000
         PRINT GEN                                                      00140000
*                                                                     * 00160000
*TITLE 'IEUF8D  ' ...  DC AND DS EVALUATION                           * 00180000
*STATUS- CHANGE LEVEL  006                                            * 00200020
*FUNCTION/OPERATION-                                                  * 00220000
*   IEUF8D PROCESSES DC'S, DS'S, CXD'S, AND LITERAL DC'S. IT PROCESSES* 00240000
*   THE ENTIRE STATEMENT AND CALLS IEUF8P TO PUT OUT THE RESULTS AS   * 00260000
*   MANY TIMES AS NECESSARY. IEUF8D PROCESSES MULTIPLE CONSTANTS FOR  * 00280000
*   ALL OPERANDS EXCEPT 'C', 'H', AND 'B'. RELOCATION DICTIONARY (RLD)* 00300000
*   ENTRIES ARE MADE FOR 'A', 'Y', 'V', AND 'Q' TYPE RELOCATABLE      * 00320000
*   CONSTANTS. THE FOLLOWING ERRORS ARE FOUND AND LOGGED-             * 00340000
*              INVALID DISPLACEMENT          INVALID REGISTER         * 00360000
*              DATA ITEM TOO LARGE           RELOCATABILITY           * 00380000
*              INVALID DELIMITER                                      * 00400000
*ENTRY POINTS-                                                        * 00420000
*   IEUF8D- DC EVALUATION. CALLED VIA-                                * 00440000
*        L     SRB,CDCVAL(ACT)                                        * 00460000
*        BALR  SRR,SRB                                                * 00480000
*   RLDRTN- ENTER INTO RLD DICTIONARY. CALLED VIA-                    * 00500000
*        L     SRB,CDCVAL(ACT)                                        * 00520000
*        L     GR1,=V(RLDRTN)                                         * 00540000
*        BALR  SRR,GR1                                                * 00560000
*   STLOC- CONTAINS THE LOCATION COUNTER WHEN RLDRTN IS CALLED        * 00580000
*INPUT-                                                               * 00600000
*   FOR IEUF8D, THE RIGHTMOST BYTE OF REGISTER GRZ IS SET AS FOLLOWS- * 00620000
*           00 = DS ---- FF = DC ---- MIXED = LITERAL DC              * 00640000
*           BYTES 0,1, AND 2 OF THE 16 WORD OUTPUT BUFFER, F8INST(ACT)* 00660000
*           CONTAINS THE CURRENT ALIGNED LOCATION COUNTER.            * 00680000
*   FOR RLDRTN- SEE THE RLD ROUTINE.                                  * 00700000
*OUTPUT- DONE BY IEUF8P (PRNT) AND IEUF8I (PUTRLD).                   * 00720000
*EXTERNAL ROUTINES-                                                   * 00740000
*   NAME         ROUTINE      USE                                     * 00760000
*   CEEVAL(ACT)  IEUF8V       EXPRESSION EVALUATION                   * 00780000
*   CTRRTN(ACT)  IEURTA       RETURN                                  * 00800000
*   PRNT(ACT)    IEUF8P       PRINT AND/OR PUNCH                      * 00820000
*   F8DCMP(ACT)  IEUF8M       DE-COMPILE ROUTINE                      * 00840000
*   CCONV(ACT)   IEUF8N       FIXED-FLOATING POINT CONVERSION         * 00860000
*   PUTRLD(ACT)  IEUF8I       PUT OUT RELOCATION DICTIONARY           * 00880000
*   CLOGER(ACT)  IEUF8L       LOG ERROR                               * 00900000
*EXITS- NORMAL                                                        * 00920000
*   FROM IEUF8D VIA  B  CTRTRN(ACT)                                   * 00940000
*   FROM RLDRTN VIA  BR SRR                                           * 00960000
*   -ERROR-- NONE                                                     * 00980000
*TABLES/WORKAREAS-                                                    * 01000000
*   DCBRANCH   BRANCH TABLE TO PROCESS THE TYPE DC                    * 01020000
*   TEMP       RLD TABLE                                              * 01040000
*NOTES-                                                               * 01060000
*   IN THE GENERAL FLOW, IEUF8D IS CALLED BY IEUF8M AND RETURNS TO    * 01080000
*   IEUF8C.                                                           * 01100000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 01120000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 01140000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 01160000
*                                                                       01180000
* DCEVAL WILL PROCESS AN ENTIRE DC STATEMENT EACH PASS. THE PRINT       01200000
* ROUTINE, F8PRNT WILL BE CALLED BY DCEVAL AS MANY TIMES AS NECESSARY.  01220000
* THERE WILL BE ONE DC WORKBUCKET PER OPERAND IN THE STATEMENT AND EACH 01240000
* OPERAND MAY CONTAIN ONE OR MORE CONSTANTS. EXCEPTIONS ARE C,X, AND B  01260000
* TYPE DC'S WHICH MAY CONTAIN ONLY ONE CONSTANT PER OPERAND.            01280000
*                                                                       01300000
* RLD ENTRIES ARE REQUIRED FOR A,Y, AND V TYPE RELOCATABLE CONSTANTS.   01320000
* HOWEVER, NO RLD ENTRIES ARE MADE FOR ADCONS WITHIN A DSECT OR COMMON  01340000
* OR FOR ADCONS WHOSE OPERAND ADDRESS IS WITHIN A DSECT. RLD ENTRIES    01360000
* ARE NOT MADE FOR A AND V TYPE CONSTANTS WITH A LENGTH MODIFIER        01380000
* LESS THAN 3 BYTES, NOR FOR Y TYPE CONSTANTS WITH A LENGTH MODIFIER    01400000
* LESS THAN 2 BYTES. BIT LENGTHS ARE NOT ALLOWED WITH RELOCATABLE       01420000
* ADCONS.                                                               01440000
*                                                                       01460000
         EJECT                                                          01480000
         USING ENTER,SRB                                                01500000
         SPACE 2                                                        01520000
         ENTRY RLDRTN                   TO ALLOW FOR CCW ENTRIES        01540000
         ENTRY STLOC                       TO ALLOW FOR CCW ENTRIES     01560000
         SPACE 2                                                        01580000
R0       EQU   0                        REGISTER EQUATES                01600000
R1       EQU   1                        THE REGISTER RXX IS EQUATED     01620000
R2       EQU   2                        TO THE ACTUAL REGISTER XX       01640000
R3       EQU   ACT                      SOME ARE FOR FUTURE USE         01660000
R4       EQU   GRA                                                      01680000
R5       EQU   GRB                                                      01700000
R6       EQU   GRC                                                      01720000
R7       EQU   GRD                                                      01740000
R8       EQU   SRB                                                      01760000
R9       EQU   SRR                                                      01780000
R10      EQU   SP1                                                      01800000
R11      EQU   SP2                                                      01820000
R12      EQU   FRB                                                      01840000
R13      EQU   GRZ                                                      01860000
R14      EQU   GRX                                                      01880000
R15      EQU   GRY                                                      01900000
INVDPERR EQU   8                        INVALID DISPLACEMENT ERROR      01920000
INVRGERR EQU   10                       INVALID REGISTER SPECIFICATION  01940000
TOOBIGER EQU   17                       DATA ITEM TOO LARGE.            01960000
RELOCERR EQU   25                       RELOCATABILITY ERROR            01980000
INVDELIM EQU   39                       INVALID DELIMITER ERROR         02000000
ADDRERR  EQU   35                                                       02010021
         EJECT                                                          02020000
ENTER    XC    BIT(5),BIT               SET BIT,BYTE,SW TO ZERO.        02040000
         MVI   RR+1,7                   SET BIT REMAINDER = 7           02060000
         LA    GRC,F8INST(ACT)          SET O/P PTR TO LOC CTR          02080000
         MVC   STLOC+1(3),0(GRC)        MOVE LOC CTR TO WORK AREA       02100000
         LA    GRC,3(GRC)               SET O/P PTR TO DATA BUFFER      02120000
         L     R1,CTEXTP(ACT)            GET PTR TO CURRENT TEXT RECORD 02140000
         CLI   4(R1),X'2C'               IS THIS A CXD INSTRUCTION      02160000
         BNE   NOCXD                     NO-BRANCH TO PROC. DC,DS OR LT 02180000
         LA    SP2,X'3C'                 SET RLD FLAG FOR CXD.          02200000
         XC    TEMP(36),TEMP             SET UP 4-BYTE VALUE AND 16     02220000
         MVI   TEMP+4,1                  2-BYTE PAIRS FOR RLD ROUTINE.  02240000
         MVI   TEMP+5,1                                                 02260000
         L     SP1,ADTEMP               LOAD POINTER TO VALUE           02280000
         BAL   SRR,RLDRTN                MAKE RLD ENTRY                 02300000
         LTR   R1,R1                     WAS RLD ENTRY MADE             02320000
         BZ    *+8                       NO, BRANCH                     02340000
         MVI   1(R1),0                   YES, SET REL-ID = 0            02360000
         MVI   LMV+3,32                  SET LMV = 32 BITS.             02380000
         BAL   FRB,KZERO                 MOVE LMV BITS TO O/P BUFF      02400000
         B     ZWEI25                    BRANCH TO DO O/P AND EXIT.     02420000
NOCXD    L     SP1,CTXOFP(ACT)           LOAD PTR TO 1ST DC BUCKET      02440000
         TM    0(SP1),4                  DOES 1ST OPND CONTAIN AN ERROR 02460000
         BO    CTRTRN(ACT)               YES, EXIT.                     02480000
         STC   GRZ,BYTEX                 00=DS FF=DC MIXED=LITERAL      02500000
         OI    F8YDC+1(ACT),1           SET EEVAL ADCON SWITCH.         02520000
         BAL   GRA,HSKP                 ALIGN DATA FROM DC BUCKET.      02540000
         TM    BYTEX,X'FF'                                              02560000
         BZ    DSCHECK                  BRANCH IF DS STATEMENT          02580000
         IC    R1,12(SP1)                GET ALIGN. FROM DC BUCKET      02600000
         SRL   R1,1                      POSITION ALIGNMENT BITS.       02620000
         N     R1,MASK3                  MASK ALIGNMENT BITS.           02640000
         LTR   R1,R1                                                    02660000
         BZ    EIN8                     BRANCH IF NO ALIGNMENT          02680000
         L     R2,STLOC                 SUBTRACT ALIGNMENT FROM         02700000
         SR    R2,R1                     LOCATION COUNTER AND STORE     02720000
         ST    R2,STLOC                   RESULT.                       02740000
         LA    GRC,F8INST(ACT)          RESET O/P POINTER.              02760000
AL2      MVC   0(3,GRC),STLOC+1         ALIGNMENT LOC CTR TO O/P BUFFER 02780000
         XC    3(7,GRC),3(GRC)          SET BYTES 4-10 OF O/P TO ZERO   02800000
         STC   R1,15(GRC)               NO. ALIGN. BYTES TO O/P BUFFER  02820000
         OI    15(GRC),X'80'            SET ALIGNMENT FLAG              02840000
         AR    R2,R1                    RESTORE ALIGNED                 02860000
         ST    R2,STLOC                  LOCATION COUNTER               02880000
         BAL   SRR,TSBPRT               PRINT ALIGNMENT LINE            02900000
         EX    R0,AL2                   ALIGNED LOC CTR TO O/P BUFFER   02920000
         LA    GRC,3(GRC)               SET O/P PTR TO DATA AREA.       02940000
EIN8     TM    12(SP1),1                TEST LENGTH MODIFIER TYPE       02960000
         BO    EIN19                    BRANCH IF BIT LENGTH            02980000
         TM    SW,1                     TEST 1ST OPERAND SWITCH         03000000
         BZ    EIN15                    BRANCH IF 1ST OPERAND           03020000
         CLI   RR+1,7                                                   03040000
         BE    EIN15                    BRANCH IF R = 7                 03060000
         BAL   R13,SUB1                 FILL O/P BYTE                   03080000
         MVI   RR+1,7                   SET R=7                         03100000
EIN15    L     R0,LMV                   CONVERT BYTE LENGTH TO BIT      03120000
         SLL   R0,3                     LENGTH                          03140000
         ST    R0,LMV                                                   03160000
         ST    R0,LMV+4                                                 03180000
EIN19    MVC   SAVWBP(4),CTXWBP(ACT)   UPDATE SYMBOL BKT PTR            03200000
         CLC   DUP(3),DUP+1            IS DUP. FACTOR INITIALLY ZERO    03220000
         BNE   EIN20                    NO                              03240000
         OI    SW,X'10'                 YES, SET ZERO DUP FAC SWITCH    03260000
         B     DSCHECK                  BRANCH TO DS ERROR CK. ROUTINE  03280000
EIN20    L     R1,LMV                                                   03300000
         M     R0,NN                    COMPUTE NEW R = (DNL+R)/8       03320000
         M     R0,DUP                    AND STORE RESULT.              03340000
         AH    R1,RR                                                    03360000
         LA    R2,7                                                     03380000
         NR    R1,R2                                                    03400000
         STC   R1,RR+1                                                  03420000
GETLMV   MVC   LMV(4),LMV+4             RESTORE LENGTH MODIFIER.        03440000
         SR    GRB,GRB                                                  03460000
         IC    GRB,9(SP1)               RELATIVE POINTER TO GRB         03480000
         A     GRB,F8OPRN(ACT)          ADD OPERAND POINTER             03500000
         L     R1,CTXWBP(ACT)           FETCH SYMBOL BUCKET POINTER.    03520000
         LTR   R1,R1                    ARE THERE ANY SYMBOL BUCKETS    03540000
         BZ    PTROK1                   NO, BRANCH.                     03560000
         SPACE 1                                                        03580000
* THIS ROUTINE USES EXPRESSION EVALUATION TO ADVANCE THE SYMBOL BUCKET  03600000
* POINTER PAST ALL MODIFIER SYMBOL BUCKETS IF THERE ARE ANY.            03620000
         SPACE 1                                                        03640000
         STM   SRB,SP1,SRBGRY           SAVE DCEVAL BASE & DCBKT PTR.   03660000
         L     SP1,F8OPRN(ACT)          FETCH OPERAND POINTER.          03680000
         NI    DURHAM1+1,X'0F'          SET LOOK FOR QUOTE=YES     9476 03690013
RALEIGH  CR    SP1,GRB                  COMPARE OPND. PTR. TO ADJ. PTR. 03700000
         BE    PTROK                    BRANCH IF EQUAL.                03720000
         CLI   0(SP1),IQUOTE            IS IT A QUOTE              9476 03730013
         BE    DURHAM3                  YES REVERSE LOOK FOR QUOTE 9476 03740013
DURHAM1  BC    0,DURHAM4                IF LOOK FOR QUOTE=NO,BRANCH9476 03750013
         CLI   0(SP1),ILPARN            IS IT A LEFT PARN          9476 03760013
         BNE   DURHAM4                  NO, CONTINUE SCAN          9476 03770013
DURHAM2  LA    SP1,1(0,SP1)             SKIP OVER DELIMITER        9476 03780013
         ST    GRX,SAV14                                         A31016 03785020
         L     SRB,CEEVAL(0,ACT)        LOAD EVAL BASE             9476 03790013
         BALR  SRR,SRB                  CALL EVAL                  9476 03800013
         USING *,SRR                    SET UP A TEMP BASE         9476 03810013
         L     SRB,SRBGRY               RESTORE OUR BASE           9476 03820013
         DROP  SRR                      NO LONGER NEED SRR AS BASE 9476 03830013
         L     GRX,SAV14                                         A31016 03835020
         CLI   0(SP1),IRPARN            IS IT A RIGHT PARN         9476 03840013
         BNE   DURHAM2                  NO, CALL EVAL AGAIN        9476 03850013
         B     RALEIGH                  YES, CONTINUE SCAN         9476 03860013
DURHAM3  XI    DURHAM1+1,X'F0'          REVERSE LOOK FOR QUOTE     9476 03870013
DURHAM4  LA    SP1,1(0,SP1)             STEP OPERAND POINTER       9476 03880013
         B     RALEIGH                  CONTINUE SCAN              9476 03890013
         SPACE 1                                                        03960000
PTROK    L     SP1,SRBGRY+8             RESTORE DCBKT POINTER.          03980000
PTROK1   LA    GRB,1(GRB)               STEP PAST LEFT DELIMITER.       04000000
         ST    GRB,POINT                STORE INCREMENTED POINTER       04020000
         NI    1(SP1),X'0F'             MASK 2ND BYTE OF DC BUCKET      04040000
         SR    R1,R1                                                    04060000
         IC    R1,1(SP1)                CODED DC TYPE TO R1             04080000
         AR    R1,R1                    MULTIPLY BY 2                   04100000
         LH    FRB,DCBRANCH(R1)         LOAD OFFSET RELATIVE TO CT      04120000
         BAL   SRR,CT(FRB)              BRANCH TO PROCESS DC BY TYPE    04140000
         OI    SW,1                     SET 1ST OPERAND SWITCH.         04160000
         TM    BYTEX,X'FF'                                              04180000
         BZ    ZWEI3                    BRANCH IF DS.                   04200000
         L     R1,DUP                                                   04220000
         BCTR  R1,0                     DECREMENT DUP FACTOR            04240000
         ST    R1,DUP                                                   04260000
         LTR   R1,R1                    ITER ATE UNTIL DUP FACTOR = 0   04280000
         MVC   CTXWBP(4,ACT),SAVWBP     RESTORE SYMBOL BUCKET POINTER.  04300000
         BNZ   GETLMV                  BRANCH IF DUP FACTOR NOT ZERO    04320000
ZWEI3    TM    0(SP1),X'48'             ANOTHER OPERAND TO FOLLOW       04340000
         BO    ZWEI4                    NO                              04360000
         LA    SP1,15(SP1)              YES, GET POINTER TO NEXT BUCKET 04380000
         TM    0(SP1),4                 DOES NEXT OPND HAVE AN ERROR    04400000
         BO    ZWEI4                    YES, PREPARE TO EXIT            04420000
         BAL   GRA,HSKP                 ALIGN DATA FROM DC BUCKET       04440000
         TM    BYTEX,X'FF'              IF DS STATEMENT, BRANCH TO DO   04460000
         BZ    DSCHECK                  DS PROCESSING. OTHERWISE,       04480000
         NI    SW,X'FD'                 ENABLE PRINT SWITCH.            04500000
         TM    12(SP1),X'0E'            TEST ALIGNMENT                  04520000
         BZ    EIN8                     BRANCH IF ZERO                  04540000
         CLI   RR+1,7                   FILL NEEDED                     04560000
         BE    ZWEI19                   NO, BRANCH                      04580000
         BAL   R13,SUB1                 YES, FILL O/P BYTE              04600000
         MVI   RR+1,7                   SET R=7                         04620000
ZWEI19   IC    GRY,12(SP1)              FETCH ALIGNMENT FROM DC BUCKET  04640000
         SRL   GRY,1                    RIGHT JUSTIFY                   04660000
         N     GRY,MASK3                MASK                            04680000
         SR    R14,R14                  SET WORKING BYTE TO ZERO        04700000
ZWEI20   BAL   R13,SUB2                 ONE ALIGNMENT BYTE TO O/P.      04720000
         BCT   GRY,ZWEI20               CONTINUE UNTIL DONE             04740000
         B     EIN15                    PROCESS NEXT OPERAND            04760000
ZWEI4    TM    BYTEX,X'FF'              IS THIS A DS STATEMENT          04780000
         BZ    DSPROC                   YES                             04800000
         TM    SW,X'10'                 WAS DUP FACTOR INITIALLY ZERO   04820000
         BO    DUPZERO                  YES, BRANCH.                    04840000
         CLI   RR+1,7                   DOES LAST BYTE NEED FILL        04860000
         BE    ZWEI25                   NO                              04880000
         BAL   R13,SUB1                 FILL LAST BYTE                  04900000
ZWEI25   LA    GRC,F8INST(ACT)          RESET O/P POINTER               04920000
         MVC   15(1,GRC),BYTE+1         MOVE BYTE COUNT TO O/P BUFFER   04940000
         L     R1,CTEXTP(ACT)           FETCH PTR TO CURRENT TEXT REC.  04960000
         CLI   4(R1),X'2B'              IS THIS A DXD INSTRUCTION.      04980000
         BNE   NODXD                    NO-BRANCH                       05000000
         MVI   15(GRC),X'0F'            YES-DONT PRINT LOCATION CTR.    05020000
NODXD    BAL   SRR,TSBPRT               PRINT O/P BUFFER.               05040000
         NI    F8YDC+1(ACT),X'FE'     RESET EEVAL ADCON SWITCH.         05060000
         MVC   CTLOC(4,ACT),STLOC       UPDATE CTLOC TO CURRENT VALUE   05080000
         B     CTRTRN(ACT)              EXIT FROM DCEVAL.               05100000
HSKP     MVC   DUP+1(3),5(SP1)          MOVE DUP FACTOR,NUMBER OF       05120000
         MVC   NN+3(1),8(SP1)            CONSTANTS, AND LENGTH MODIFIER 05140000
         MVC   LMV+2(2),13(SP1)           VALUE FROM DC WORK BUCKET TO  05160000
         MVC   LMV+6(2),13(SP1)            ALIGNED LOCATIONS AND        05180000
         BR    GRA                          RETURN TO USER.             05200000
         EJECT                                                          05220000
* THIS ROUTINE PROCESSES ALL OPERANDS IN A DS STATEMENT AND IN DC       05240000
* STATEMENTS WITH INITIAL DUP. FACTOR EQUAL ZERO. ERROR CHECKING IS     05260000
* DONE ONLY ON F,H,E,D,A,Y, AND S TYPE OPERANDS WHICH CONTAIN TEXT.     05280000
* ALL OTHER NECESSARY ERROR CHECKING HAS BEEN DONE IN PRIOR PHASES.     05300000
         SPACE 1                                                        05320000
DSCHECK  OI    SW,2                     SET SWITCH TO DISABLE PRINT     05340000
         TM    SW,1                     IS THIS 1ST OPERAND             05360000
         BO    DSCHECK1                 NO, BRANCH                      05380000
         MVC   HOLDLCTR(3),F8INST(ACT)  SAVE ALIGNED LOCATION COUNTER   05400000
DSCHECK1 TM    0(SP1),2                 DOES DS CONTAIN TEXT            05420000
         BZ    ZWEI3                    NO, LOOK FOR NEXT OPERAND.      05440000
         CLI   1(SP1),5                 IS THIS F,H,E,D,A,Y,V,OR S      05460000
         BL    ZWEI3                    NO, LOOK FOR NEXT OPERAND       05480000
         CLI   1(SP1),11                IS THIS A V-CON                 05500000
         BE    ZWEI3                    YES, LOOK FOR NEXT OPERAND      05520000
         TM    SW,X'10'                 IS THIS DC WITH DUP FAC = 0     05540000
         BZ    EIN8                     NO, BRANCH TO ERROR CHECK DS.   05560000
         MVI   DUP+3,1                  SET DUP FACTOR = 1              05580000
         B     GETLMV                   BRANCH TO CHECK DC, DUP FAC = 0 05600000
DSPROC   MVI   BYTE+1,X'F0'              SET DS FLAG FOR PRINT ROUTINE  05620000
         MVC   F8INST(3,ACT),HOLDLCTR   RESTORE ALIGNED LOCATION CTR.   05640000
DUPZERO  NI    SW,X'FD'                  ENABLE PRINT SWITCH            05660000
         B     ZWEI25                   BRANCH TO TERMINATE DS PROC.    05680000
         EJECT                                                          05700000
* PRINT ONE LINE AND RETURN ONLY IF THE PRINT SWITCH IS ENABLED.        05720000
         SPACE 1                                                        05740000
TSBPRT   TM    SW,2                     IS PRINT SWITCH ENABLED         05760000
         BCR   1,SRR                    NO, RETURN IMMEDIATELY.         05780000
         STM   SRB,GRY,SRBGRY           SAVE REGISTERS 8 THRU 15        05800000
         OI    15(GRC),X'40'            THIS IS A DC STATEMENT          05820000
         L     FRB,PRNT(ACT)            PRINT ROUTINE USES BASE FRB     05840000
         BALR  SRR,FRB                  AND RETURNS VIA SRR.            05860000
         USING *,SRR                    USE SRR AS BASE UNTIL           05880000
         LM    SRB,GRY,SRBGRY           WE CAN RESTORE OUR BASE         05900000
         DROP  SRR                      NO LONGER NEED SRR AS BASE      05920000
         BR    SRR                      EXIT                            05940000
         EJECT                                                          05960000
* THIS SUBROUTINE MOVES ONE WORK BYTE TO THE OUTPUT BUFFER. IF THE      05980000
* OUTPUT BUFFER IS ALREADY FULL, IT IS PRINTED FIRST, AND THE SUBJECT   06000000
* BYTE STARTS TO FILL THE OUTPUT BUFFER AGAIN. SUB1 IS SELF-EXPLANATORY 06020000
*                                                                       06040000
SUB1     LA    R1,7                7 TO R1                              06060000
         SH    R1,RR                    7-R                             06080000
         SLL   R14,0(R1)           PAD WORK BYTE WITH (7-R) ZERO BITS   06100000
SUB2     ST    SRR,TSBSRR               TO KEEP FROM GETTING LOST.      06120000
         CLI   BYTE+1,8                 IS OUTPUT BUFFER FULL           06140000
         BE    ZWEI8               YES - BRANCH                         06160000
ZWEI11   STC   R14,0(GRC)          WORK BYTE TO OUTPUT BUFFER           06180000
         LA    GRC,1(GRC)          INCREMENT OUTPUT POINTER             06200000
         IC    R2,BYTE+1                INCREMENT BYTE COUNT            06220000
         LA    R2,1(R2)                                                 06240000
         STC   R2,BYTE+1                SAVE BYTES IN F8INST            06260000
         L     R2,STLOC                 ADD 1 TO INTERNAL LOC. COUNTER  06280000
         LA    R2,1(R2)                                                 06300000
         ST    R2,STLOC                 SAVE INTERNAL LOCATION COUNTER  06320000
         L     SRR,TSBSRR               RESTORE SRR                     06340000
DIXON    MVI   BIT+1,0                  SET BIT COUNT = 0               06360000
         SR    R14,R14                  SET WORKING BYTE = 0            06380000
         BR    R13                      VAMOOSE *********************** 06400000
ZWEI8    LA    GRC,F8INST(ACT)          RESET OUTPUT POINTER            06420000
         MVI   15(GRC),8           8 TO OUTPUT COUNT                    06440000
         BAL   SRR,TSBPRT               PRINT OUTPUT BUFFER             06460000
         EX    R0,AL2                   LOC. CTR. TO O/P BUFFER         06480000
         LA    GRC,3(GRC)          ADD 3 TO OUTPUT COUNT                06500000
         MVI   BYTE+1,0                 SET BYTE COUNT=0                06520000
         B     ZWEI11                   CONTINUE PUTTING IN BYTE        06540000
         EJECT                                                          06560000
* THE KZERO SUBROUTINE CREATES OUTPUT FROM THE REVISED EDITED TEXT      06580000
* TRUNCATION HAS ALREADY BEEN DONE.                                     06600000
*                                                                       06620000
KZERO    TM    SW,2                     TEST PRINT SWITCH               06640000
         BCR   1,FRB                    BRANCH IF ON.                   06660000
KKZERO   LA    GRB,TEMP                 FETCH POINTER TO TEMP BUFFER.   06680000
SVN02    MVC   FULL(4),0(GRB)           ALIGN NEXT FOUR WORDS OF OPND   06700000
         L     R15,FULL                 FULL WORD TO ODD REGISTER       06720000
         XC    TSHIFT(2),TSHIFT         SET TOTAL SHIFT = 0             06740000
SVN03    LA    GRB,4(GRB)               ADD 4 TO TEMP POINTER.          06760000
SVN04    LA    R11,8               IS (8-BIT- GREATER THAN              06780000
         SH    R11,BIT              OR EQUAL TO LMV                     06800000
         L     R1,LMV                                                   06820000
         CR    R11,R1                                                   06840000
         BL    SVN10                    NO,BRANCH                       06860000
SVN05    SLDL  R14,0(R1)           YES, SHIFT LMV BITS TO WORK BYTE     06880000
         AH    R1,BIT                   LMV+BIT                         06900000
         STH   R1,BIT                   STORE NEW BIT COUNT             06920000
         CLI   BIT+1,8                  DOES BIT COUNT=8                06940000
         BNE   SVN09                    NO,BRANCH                       06960000
         BAL   R13,SUB2                 PUT IN BYTE                     06980000
SVN09    BR    FRB                      EXIT FROM OUTPUT ALGORITHM***** 07000000
SVN10    SLDL  R14,0(R11)          SHIFT (8-BIT) BITS TO WORK BYTE      07020000
         SR    R1,R11              LMV-(8-BIT)                          07040000
         ST    R1,LMV                   STORE NEW LMV                   07060000
         AH    R11,TSHIFT          TSHIFT+(8-BIT)                       07080000
         STH   R11,TSHIFT          STORE NEW TOTAL SHIFT                07100000
         BAL   R13,SUB2                 PUT IN BYTE                     07120000
         LA    R2,32                    (32-TSHIFT) GREATER THAN OR     07140000
         SH    R2,TSHIFT                 EQUAL TO 8                     07160000
         LA    R1,8                                                     07180000
         CR    R2,R1                                                    07200000
         BNL   SVN04                    YES,BRANCH                      07220000
         L     R1,LMV                   NO,(32-TSHIFT) GREATER THAN OR  07240000
         CR    R2,R1                     EQUAL TO LMV                   07260000
         BNL   SVN05                    YES,BRANCH                      07280000
         SLDL  R14,0(R2)           NO,SHIFT (32-TSHIFT) BITS            07300000
         SR    R1,R2                    LMV-(32-TSHIFT)                 07320000
         ST    R1,LMV                   STORE NEW LMV                   07340000
         AH    R2,BIT                   (32-TSHIFT)+BIT                 07360000
         STH   R2,BIT                   STORE NEW BIT COUNT             07380000
         B     SVN02                    AND CONTINUE PROCESSING         07400000
         EJECT                                                          07420000
* THE KNEG SUBROUTINE TRUNCATES THE REVISED EDITED TEXT **ON THE LEFT** 07440000
* IF NEEDED AND BRANCHES TO KZERO.                                      07460000
*                                                                       07480000
KNEG     TM    SW,2                     TEST PRINT SWITCH.              07500000
         BCR   1,FRB                    BRANCH IF ON.                   07520000
         STM   R6,R7,SAV2               SAVE                            07540000
         LH    R6,KX               KX TO EVEN REGISTER                  07560000
         LPR   R6,R6               SET KX POSITIVE                      07580000
         SRDL  R6,3                DIVIDE BY 8, REMAINDER TO R7         07600000
         LA    GRB,TEMP                 SET OPERAND POINTER             07620000
         AR    GRB,R6                   TRUNCATE OPERAND KX/8 BYTES     07640000
         SR    R6,R6                    CLEAR KX/8                      07660000
         SLDL  R6,3                     SHIFT IN REMAINDER              07680000
         EX    R0,SVN02                 FULL WORD TO ODD REGISTER       07700000
         L     R15,FULL                 FULL WORD TO ODD REGISTER       07720000
         SLL   R15,0(R6)           TRUNCATE BY KX/8 REMAINDER           07740000
         STC   R6,TSHIFT+1              TSHIFT=NO. OF TRUNC. BITS       07760000
         LM    R6,R7,SAV2               RESTORE                         07780000
         MVI   TSHIFT,0                 FIX FOR THE PHANTOM BULLDOGGER  07800000
         B     SVN03                    BRANCH TO CONTINUE PROCESSING.  07820000
         SPACE 3                                                        07840000
* THE KPOS SUBROUTINE PADS THE REVISED EDITED TEXT **ON THE LEFT**      07860000
* IF NEEDED AND BRANCHES TO KZERO.                                      07880000
*                                                                       07900000
KPOS     TM    SW,2                     TEST PRINT SWITCH               07920000
         BCR   1,FRB                    BRANCH IF ON.                   07940000
         LH    GRA,KX                   LOAD NUMBER OF BITS TO PAD.     07960000
         LA    R1,8                                                     07980000
         SH    R1,BIT                                                   08000000
         CR    R1,GRA                   IS KX LESS THAN (8-BIT)         08020000
         BNL   NINE04                   YES, BRANCH                     08040000
         SLL   R14,0(R1)                SHIFT WORK BYTE LEFT (8-BIT)    08060000
         SR    GRA,R1                   SUBTRACT AMT OF SHIFT FROM KX   08080000
         STH   GRA,KX                   STORE DECREMENTED KX            08100000
         L     R2,LMV                   SUBTRACT AMT OF SHIFT FROM LMV  08120000
         SR    R2,R1                                                    08140000
         ST    R2,LMV                   STORE DECREMENTED LMV           08160000
         BAL   R13,SUB2                 WORK BYTE TO TEMP BUFFER        08180000
         B     KPOS                     BRANCH TO CONTINUE PADDING      08200000
NINE04   SLL   R14,0(GRA)               SHIFT WORK BYTE LEFT KX BITS    08220000
         L     R2,LMV                   SUBTRACT AMT OF SHIFT FROM LMV  08240000
         SR    R2,GRA                                                   08260000
         ST    R2,LMV                   STORE DECREMENTED LMV           08280000
         AH    GRA,BIT                  ADD AMT OF SHIFT TO BIT COUNT   08300000
         STH   GRA,BIT                  STORE INCREMENTED BIT COUNT     08320000
         CLI   BIT+1,8                  DOES BIT COUNT = 8              08340000
         BNE   KKZERO                   NO,LEFT SIDE PADDING COMPLETE   08360000
         BAL   R13,SUB2                 YES, WORK BYTE TO TEMP BUFFER   08380000
         B     KKZERO                   BRANCH TO CONTINUE PROCESSING.  08400000
         EJECT                                                          08420000
* THIS SUBROUTINE PROCESSES CHARACTER TYPE DC STATEMENTS*************** 08440000
*                                                                       08460000
CT       LA    GRA,HEXBIN               COLLAPSE, TRANSLATE CHAR STRING 08480000
CLPSE    LA    GRD,TEMP                 LOAD PTR. TO TEMP BUFFER        08500000
TEN02    CLI   0(GRB),IQUOTE            IS 1ST CHAR. QUOTE              08520000
         BNE   AMP                      NO                              08540000
         CLI   1(GRB),IQUOTE            YES,IS 2ND CHAR. QUOTE          08560000
         BNE   LVN00                    NO, END OF CHARACTER STRING.    08580000
STOCH    MVC   0(1,GRD),0(GRB)          MOVE OPND. CHAR. TO TEMP BUFFER 08600000
         LA    GRB,2(GRB)               ADD 2 TO OPND. PTR.             08620000
TEN05    LA    GRD,1(GRD)               ADD 1 TO TEMP BUFFER PTR.       08640000
         B     TEN02                    LOOK AT NEXT CHAR. OF OPND.     08660000
AMP      CLI   0(GRB),IAMPSD            IS 1ST CHAR. AMPERSAND          08680000
         BE    STOCH                    YES, ASSUME 2ND AND CONTINUE.   08700000
NOAMP    EX    R0,STOCH                 STORE CHAR. NOT AMP. OR QUOTE   08720000
         LA    GRB,1(GRB)               ADD 1 TO OPND. PTR.             08740000
         B     TEN05                    BRANCH TO LOOK AT NEXT CHAR.    08760000
LVN00    ST    GRD,TPOINT               SAVE TEMP POINTER               08780000
         S     GRD,ADTEMP               GET TOTAL LENGTH                08800000
         LR    R1,GRD                   SAVE TOTAL LENGTH               08820000
         SLL   GRD,3                    MULTIPLY BY 8                   08840000
         L     R11,LMV             COMPUTE LMV-8(TOTAL LENGTH) = KX     08860000
         SR    R11,GRD                                                  08880000
         STH   R11,KX                   KEEP KX                         08900000
         BP    LVN05               BRANCH TO PAD                        08920000
TRNSLT   BCTR  R1,0                     DECR. TOTAL LENGTH TO TRANSLATE 08940000
         L     R2,CTRTBP(ACT)           LOAD POINTER TO TRANSLATE TABLE 08960000
         EX    R1,INTEXT                TRANSLATE TEMP BUFFER           08980000
         BR    GRA                      EXIT CLPSE SUBROUTINE********** 09000000
LVN05    LA    R11,7(R11)               ADD 7 TO KX                     09020000
         SRL   R11,3                    DIVIDE BY 8                     09040000
         L     GRD,TPOINT               LOAD TEMP POINTER               09060000
LOOPC    MVI   0(GRD),IBLANK            PAD TEMP BUFFER ON RIGHT SIDE   09080000
         LA    GRD,1(GRD)               WITH BLANKS                     09100000
         BCT   R11,LOOPC                LOOP TO COMPLETE PAD            09120000
         S     GRD,ADTEMP               GET TOTAL LENGTH                09140000
         LR    R1,GRD                   PADDED LENGTH TO REG. 1         09160000
         B     TRNSLT                   BRANCH TO TRANSLATE             09180000
INTEXT   TR    TEMP(0),0(R2)            INTERNAL TO EXTERNAL EBCDIC     09200000
         EJECT                                                          09220000
* THIS SUBROUTINE PROCESSES HEXADECIMAL TYPE DC STATEMENTS ************ 09240000
*                                                                       09260000
XT       LA    GRD,TEMP                 LOAD PTR. TO TEMP BUFFER        09280000
SIX00    CLI   0(GRB),IQUOTE            END QUOTE                       09300000
         BE    SVN00                    YES, BRANCH                     09320000
         SR    R0,R0                    CLEAR R0                        09340000
         IC    R0,0(GRB)                SOURCE CHAR. TO R0              09360000
         SLL   R0,4                     SHIFT LEFT 4                    09380000
         CLI   1(GRB),IQUOTE            NEXT CHAR. END QUOTE            09400000
         BE    SIX10                    YES, BRANCH                     09420000
         IC    R1,1(GRB)                LOGICAL OR                      09440000
         OR    R0,R1                     WITH PREVIOUS CHARACTER        09460000
         STC   R0,0(GRD)                STORE 2 HEX CHARS.              09480000
         LA    GRB,2(GRB)               ADD 2 TO SOURCE POINTER         09500000
         LA    GRD,1(GRD)               ADD 1 TO EDITED HEX. POINTER    09520000
         B     SIX00                    LOOP UNTIL OPERAND EXHAUSTED    09540000
SIX10    STC   R0,0(GRD)                STORE 1 HEX CHAR.               09560000
         LA    GRB,1(GRB)               ADD 1 TO SOURCE POINTER         09580000
SVN00    S     GRB,POINT                COMPUTE SOURCE LENGTH           09600000
         SLL   GRB,2                    MULTIPLY BY 4                   09620000
COMPKX   L     R11,LMV                   COMPUTE KX                     09640000
         SR    R11,GRB                                                  09660000
         STH   R11,KX                                                   09680000
         BP    NINE00                   KX IS PLUS, PAD                 09700000
         BM    SVN18                    KX IS MINUS, TRUNCATE           09720000
HEXBIN   BAL   FRB,KZERO                 NO PADDING OR TRUNCATION       09740000
         BR    SRR                      EXIT HEXADECIMAL SUBROUTINE**** 09760000
SVN18    BAL   FRB,KNEG                 NEGATIVE, TRUNCATE              09780000
         BR    SRR                      EXIT*************************** 09800000
NINE00   BAL   FRB,KPOS                 POSITIVE, PAD                   09820000
         BR    SRR                      EXIT*************************** 09840000
         EJECT                                                          09860000
* THIS SUBROUTINE PROCESSES BINARY TYPE DC STATEMENTS                   09880000
*                                                                       09900000
BT       LA    GRD,TEMP                 LOAD PTR. TO TEMP BUFFER        09920000
         SR    GRA,GRA                  SET BIT COUNTER = 0             09940000
SEARCH   CLI   0(GRB),IQUOTE            SEARCH OPERAND FOR END QUOTE    09960000
         BE    FOUND                    BRANCH WHEN FOUND               09980000
         CH    GRA,=H'8'                DOES BIT COUNT = 8              10000000
         BNE   FVE05                    NO                              10020000
         STC   R0,0(GRD)                YES, STORE WKBYTE IN TEMP BUFF. 10040000
         LA    GRD,1(GRD)               INCREMENT TEMP BUFFER PTR.      10060000
         SR    R0,R0                    SET WORKING BYTE = 0            10080000
         SR    GRA,GRA                  SET BIT COUNTER = 0             10100000
FVE05    SLL   R0,1                     SHIFT WKBYTE LEFT 1             10120000
         IC    R1,0(GRB)                LOGICAL OR OPERAND CHARACTER    10140000
         OR    R0,R1                    TO WORKING BYTE                 10160000
         LA    GRB,1(GRB)               INCREMENT OPERAND PTR.          10180000
         LA    GRA,1(GRA)               INCREMENT BIT COUNTER           10200000
         B     SEARCH                   GET NEXT CHARACTER              10220000
FOUND    LCR   GRA,GRA                  LEFT JUSTIFY WORKING BYTE       10240000
         SLL   R0,8(GRA)                                                10260000
         STC   R0,0(GRD)                STORE LAST BYTE IN TEMP         10280000
         S     GRB,POINT                COMPUTE LENGTH OF OPERAND       10300000
         B     COMPKX                   REST OF BINARY ROUTINE          10320000
*                                       SAME AS HEX ROUTINE             10340000
         EJECT                                                          10360000
* THIS SUBROUTINE PROCESSES PACKED AND ZONED TYPE DC STATEMENTS         10380000
*                                                                       10400000
PZ       NI    SW,X'F7'                 SET LAST CONSTANT SWITCH = 0    10420000
TWV00    L     GRD,=A(TEMP+20)          LOAD POINTER                    10440000
         MVI   CHTEMP+1,0               RESET PACKING SWITCH            10460000
         CLI   0(GRB),IPLUS             IS CHAR. +                      10480000
         BE    TWV04                    YES                             10500000
         CLI   0(GRB),IMINUS            NO, IS CHAR. -                  10520000
         BE    TWV04                    YES                             10540000
         B     TWV03                    NO                              10560000
TWV04    LA    GRB,1(GRB)               INCREMENT OPERAND PTR.          10580000
TWV03    CLI   0(GRB),IPRIOD            IS CHAR. DECIMAL POINT          10600000
         BNE   TWV06                    NO                              10620000
         LA    GRB,1(GRB)               YES, IGNORE IT                  10640000
TWV06    CLI   0(GRB),IQUOTE            IS CHAR. QUOTE                  10660000
         BE    TWV09                    YES                             10680000
         CLI   0(GRB),ICOMMA            NO, IS CHAR. COMMA              10700000
         BE    TWV10                    YES                             10720000
         MVC   0(1,GRD),0(GRB)          NO, MOVE CHAR. TO TEMP BUFFER   10740000
         LA    GRD,1(GRD)               INCREMENT TEMP BUFFER PTR.      10760000
         B     TWV04                    LOOP TO END OF CONSTANT.        10780000
TWV09    OI    SW,8                     SET LAST CONSTANT SWITCH = 1    10800000
TWV10    LA    GRB,1(GRB)               SET OP.PTR. TO START NEXT CONST 10820000
         L     GRA,POINT                LOAD PRESENT OPERAND PTR.       10840000
         ST    GRB,POINT                SAVE NEXT PTR.                  10860000
         CLI   1(SP1),I3                IS THIS DC PACKED OR ZONED      10880000
         BNE   ZONED                    BRANCH IF ZONED                 10900000
         SPACE 2                                                        10920000
* PROCESS PACKED DC. COLLAPSED TEXT STARTS AT TEMP+20                   10940000
* AND GETS PACKED INTO TEMP THRU TEMP+15.                               10960000
         SPACE 2                                                        10980000
         BCTR  GRD,0                    DECR. TEMP PTR. TO STORE SIGN   11000000
         BAL   FRB,TWV12                SET PROPER SIGN                 11020000
         S     GRD,=A(TEMP+20)          UNPACKED LENGTH - 1             11040000
         LA    GRD,1(GRD)               ADD 1                           11060000
         LA    GRA,15                   IS UNPACKED LENGTH > 15?        11080000
         CR    GRD,GRA                                                  11100000
         BNH   WEEP                     NO, BRANCH.                     11120000
         STC   GRD,CHTEMP+2             YES, SAVE TOTAL LENGTH,         11140000
         SR    GRD,GRA                  COMPUTE TL - 15,                11160000
         STC   GRD,CHTEMP+1             AND STORE.                      11180000
WEEP     LR    GRA,GRD                  SAVE LENGTH TO BE PACKED FIRST  11200000
         LA    GRD,2(GRD)               PACKED LENGTH =                 11220000
         SRL   GRD,1                    (UNPACKED LENGTH+2)/2           11240000
         STC   GRD,CHTEMP               SAVE PACKED LENGTH              11260000
         BCTR  GRD,0                    PACKED LENGTH-1                 11280000
         BCTR  GRA,0                    UNPACKED LENGTH-1               11300000
         SLL   GRD,4                    POSITION PACKED LENGTH          11320000
         OR    GRA,GRD                  LOGICAL OR TWO LENGTHS          11340000
         LA    GRD,TEMP                 PTR. TO TEMP BUFFER             11360000
         CLI   CHTEMP+1,0               IS SOURCE LENGTH > 15?          11380000
         BNE   BIGPACK                  YES, BRANCH TO PACK IT.         11400000
         EX    GRA,PACK                 NO, PACK FROM TEMP+20 TO TEMP.  11420000
         B     THTN00                                                   11440000
BIGPACK  MVI   TEMP,0                   SET TEMP = 0                    11460000
         EX    GRA,PACKA                PACK FROM TEMP+20 TO TEMP+1     11480000
         IC    GRA,CHTEMP               FETCH LENGTH ALREADY PACKED     11500000
         LR    GRD,GRA                  SET UP LENGTHS FOR EXECUTING    11520000
         SLL   GRD,4                    MVO INSTRUCTION.                11540000
         OR    GRA,GRD                                                  11560000
         EX    GRA,OFFSET               MOVE WITH OFFSET TEMP TO TEMP+1 11580000
         SR    GRA,GRA                  ZERO BOTH REGISTERS SO          11600000
         SR    GRD,GRD                    CHARACTER CAN BE INSERTED     11620000
         IC    GRD,CHTEMP               GET READY TO PACK REMAINING     11640000
         A     GRD,ADTEMP               15 SOURCE BYTES                 11660000
         IC    GRA,CHTEMP+1                                             11680000
         A     GRA,=A(TEMP+20)                                          11700000
         PACK  1(8,GRD),0(15,GRA)       PACK REMAINING 15 BYTES         11720000
         SR    R2,R2                                                    11740000
         IC    R2,CHTEMP+2              COMPUTE TOTAL PACKED LENGTH     11760000
         LA    R2,2(R2)                  AND STORE FOR FUTURE           11780000
         SRL   R2,1                     REFERENCE BY                    11800000
         STC   R2,CHTEMP                PACKING ROUTINE.                11820000
MOVAGAIN MVC   TEMP(17),TEMP+1          IF LENGTH OF 1ST PACK IS ODD,   11840000
         TM    CHTEMP+1,1               MOVE O/P DATA FROM TEMP+1 TO    11860000
         BO    THTN00                   TEMP. IF EVEN, MOVE O/P DATA    11880000
         EX    R0,MOVAGAIN              FROM TEMP+2 TO TEMP.            11900000
THTN00   TM    0(SP1),X'10'             DOES TEXT CONTAIN LMV           11920000
         BZ    THTN03                   NO                              11940000
         SR    R2,R2                    YES, COMPUTE KX,LMV-8(TL)       11960000
         IC    R2,CHTEMP                                                11980000
         SLL   R2,3                                                     12000000
         L     R1,LMV                                                   12020000
         SR    R1,R2                    R1 NOW = KX                     12040000
         STH   R1,KX                                                    12060000
         BM    THTN05                   BRANCH TO TRUNCATE ON LEFT      12080000
         BP    THTN06                   BRANCH TO PAD ON LEFT           12100000
THTN04   BAL   FRB,KZERO                NO PADDING OR TRUNCATION        12120000
THTN07   TM    SW,8                     IS DELIMITER QUOTE              12140000
         BCR   1,SRR                    YES, EXIT PZ ROUTINE*********** 12160000
         L     GRB,POINT                NO,LOAD PTR. TO NEXT CONSTANT   12180000
         EX    R0,GETLMV                RESTORE LENGTH MODIFIER.        12200000
         B     TWV00                    BRANCH TO PROCESS NEXT CONSTANT 12220000
THTN03   SR    GRD,GRD                                                  12240000
         IC    GRD,CHTEMP               SET LMV = TOTAL LENGTH IN BITS  12260000
         SLL   GRD,3                              FOR PACKED DC         12280000
         ST    GRD,LMV                  KEEP LENGTH OF MOVE             12300000
         B     THTN04                   BRANCH TO OUTPUT PACKED DC.     12320000
THTN05   BAL   FRB,KNEG                 GO TO LEFT TRUNCATION ROUTINE   12340000
         B     THTN07                   GO BACK TO MAIN FLOW            12360000
THTN06   BAL   FRB,KPOS                 GO TO LEFT PADDING ROUTINE      12380000
         B     THTN07                   GO BACK TO MAIN FLOW            12400000
TWV12    CLI   0(GRA),IMINUS            IS SIGN MINUS                   12420000
         BE    TWV14                    YES                             12440000
         OI    0(GRD),X'C0'             NO, SET SIGN PLUS               12460000
         BR    FRB                      RETURN                          12480000
TWV14    OI    0(GRD),X'D0'             SET SIGN MINUS                  12500000
         BR    FRB                      RETURN                          12520000
PACK     PACK  0(0,GRD),20(0,GRD)       VARIABLE LENGTH PACK            12540000
PACKA    PACK  1(0,GRD),20(0,GRD)       VARIABLE LENGTH PACK            12560000
OFFSET   MVO   TEMP+1(0),TEMP(0)      VARIABLE LENGTH MOVE WITH OFFSET  12580000
         SPACE 2                                                        12600000
* PROCESS ZONED DC. COLLAPSED TEXT STARTS AT TEMP+20.                   12620000
         SPACE 2                                                        12640000
ZONED    XC    TEMP(16),TEMP            SET 1ST 16 BYTES OF TEMP = 0    12660000
         S     GRD,=A(TEMP+20)          COMPUTE AND STORE TOTAL         12680000
         ST    GRD,LAST                 LENGTH FOR ZONED DC.            12700000
         LCR   R2,GRD                                                   12720000
          LA   R2,TEMP+16(R2)            RIGHT JUSTIFY ZONED DATA IN    12740000
         BCTR  GRD,0                    1ST 16 BYTES OF TEMP BUFFER.    12760000
         EX    GRD,MOVEX                                                12780000
         L     GRD,CTRTBP(ACT)          POINTER TO TRANSLATE TABLE      12800000
         TR    TEMP(16),0(GRD)          TRANSLATE 1ST 16 BYTES OF TEMP  12820000
         LA    GRD,TEMP+15                                              12840000
         NI    0(GRD),X'0F'             SET PROPER SIGN FOR ZONED DC.   12860000
         BAL   FRB,TWV12                PUT IN SIGN                     12880000
         TM    0(SP1),X'10'             DOES TEXT CONTAIN LMV           12900000
         BO    THTN08                   YES,BRANCH                      12920000
         L     GRD,LAST                 NO,SET LMV = TOTAL LENGTH IN    12940000
         SLL   GRD,3                    BITS FOR ZONED DC.              12960000
         ST    GRD,LMV                                                  12980000
THTN08   LA    R1,128                   TRUNCATE LMV-128 BITS OF 1ST    13000000
         L     GRD,LMV                  16 BYTES OF TEMP BUFFER AND     13020000
         SR    GRD,R1                   OUTPUT REMAINDER.               13040000
         STH   GRD,KX                                                   13060000
         BZ    THTN04                   NO PADDING OR TRUNCATION        13080000
         B     THTN05                   TRUNCATE                        13100000
MOVEX    MVC   0(0,R2),TEMP+20          VARIABLE LENGTH MOVE            13120000
         EJECT                                                          13140000
*        THIS SUBROUTINE PROCESSES A AND Y TYPE ADDRESS CONSTANTS       13160000
*                                                                       13180000
*                         -SPECIFICATIONS-                              13200000
*                                                                       13220000
*                                             A               Y         13240000
*                                                                       13260000
* IMPLIED LENGTH (BYTES)                4               2               13280000
* ALIGNMENT                             WORD            HALF WORD       13300000
* LENGTH MODIFIER RANGE (RELOCATABLE)   3-4             2-4             13320000
* LENGTH MODIFIER RANGE (ABSOLUTE)      .1-4            .1-4            13340000
* SPECIFIED BY                          ANY EXPRESSION  ANY EXPRESSION  13360000
* NUMBER OF CONSTANTS PER OPERAND       MULTIPLE        MULTIPLE        13380000
* TRUNCATION SIDE (NO PADDING ALLOWED)  LEFT            LEFT            13400000
*                                                                       13420000
AY       STM   SRR,SP1,SAVSRR           SAVE REGISTERS 9 AND 10.        13440000
         LR    SP1,GRB                  SET SP1 = PTR. TO 1ST CHAR.     13460000
AYE2     ST    SP1,ERRORPTR             SAVE PTR TO CONSTANT            13480000
         BAL   GRY,EXPRES               EVALUATE EXPRESSION.            13500000
         TM    ACONPT,X'30'             TEST CONDITION CODE FROM EEVAL  13520000
         BC    1,AYK1                   BRANCH IF CC=3 (EEVAL ERROR)    13540000
         BC    8,AYC3                   BRANCH IF CC=0 (ABS. EXP.)      13560000
         TM    ACONPT,X'20'            BRANCH IF EXPRESSION IS          13580000
         BC    1,AYE3                   COMPLEXLY RELOCATABLE           13600000
          XC   6(30,SP2),6(SP2)         SIMP.RELOC.,ZERO 2-16 RLD LIST  13620000
AYE3     L     SP1,SAVSP1               FETCH POINTER TO DC BUCKET.     13640000
         TM    12(SP1),1                EXPRESSION IS RELOCATABLE       13660000
         BO    AYA5                     BRANCH TO ERROR IF BIT LENGTH   13680000
AYD4     CLI   1(SP1),I9                IS THIS AN A-TYPE CONSTANT.     13700000
         BNE   AYC4                     NO, BRANCH TO Y-TYPE LOGIC.     13720000
         CLI   14(SP1),I3                YES, LOG ERROR IF LENGTH       13740000
         BL    AYC5                     MODIFIER LESS THAN 3 BYTES.     13760000
AYD5     SR    SP2,SP2                  PREPARE ARGUMENTS FOR RLD ENTRY 13780000
         IC    SP2,14(SP1)              GET LENGTH                      13800000
         BCTR  SP2,0                      MINUS ONE                     13820000
         SLL   SP2,2                      AND SHIFT OVER 2 BITS FOR RLD 13840000
         L     SP1,SPEVAL+4             POINTER TO PARAMETER TABLE      13860000
         BAL   SRR,RLDRTN               MAKE RLD ENTRY                  13880000
AYD6     LM    SP1,SP2,SPEVAL           RESTORE INFO FROM EEVAL         13900000
         L     SP2,0(SP2)               RELOC. VALUE TO SP2             13920000
AYC3     ST    SP2,TEMP                 ABS. OR RELOC. VALUE TO TEMP    13940000
         L     R2,SAVSP1                FETCH POINTER TO DC BUCKET.     13960000
         CLI   1(R2),I9                 IF THIS IS AN A-CON, DON'T      13980000
         BE    AYC2                      DARE FLAG IT. FLAG Y-CONS ONLY 14000000
         SLA   SP2,16                     IF LARGER THAN + OR -         14020000
         BC    14,AYC2                     HEX 7FFF.                    14040000
         MVI   XY+1,TOOBIGER            GOD HELP THE MAN WHO ACCIDENT-  14060000
         BAL   SRR,ERRLOG                LY GETS AN A-CON TRUNCATED.    14080000
AYC2     L     R2,LMV                   COMPUTE KX=LMV-32               14100000
         SH    R2,XXXII                                                 14120000
         STH   R2,KX                    STORE KX                        14140000
         BM    AYE4                     PADDING NOT POSSIBLE FOR ADCONS 14160000
         BAL   FRB,KZERO                NO TRUNCATION                   14180000
         B     AYK2                     BRANCH TO NEXT CONSTANT OR EXIT 14200000
AYE4     BAL   FRB,KNEG                 TRUNCATE                        14220000
         B     AYK2                     BRANCH TO NEXT CONSTANT OR EXIT 14240000
AYK1     SR    R1,R1                    PLACE LMV ZERO BITS IN          14260000
         ST    R1,TEMP                   OUTPUT STREAM.                 14280000
         BAL   FRB,KZERO                                                14300000
AYK2     CLI   0(SP1),ICOMMA            IS DELIMITER A COMMA       9145 14320013
         CLI   0(SP1),ICOMMA            IS DELIMITER A COMMA            14340000
         BNE   AYK3                     NO, BRANCH TO EXIT              14360000
         LA    SP1,1(SP1)               YES, ADD 1 TO OPND PTR          14380000
         EX    R0,GETLMV                RESTORE LMV.                    14400000
         B     AYE2                     GO TO PROCESS NEXT CONSTANT.    14420000
AYA5     MVI   XY+1,RELOCERR            RELOCATABLE ADCON SPECIFIED BY  14440000
         BAL   SRR,ERRLOG               BIT LENGTH, LOG RELOC. ERROR    14460000
         B     AYK1                     ZERO BITS TO OUTPUT.            14480000
AYC5     MVI   XY+1,RELOCERR            LMV TOO SMALL FOR RELOCATABLE   14500000
         BAL   SRR,ERRLOG               ADCON, LOG RELOC. ERROR AND     14520000
         B     AYD6                     SKIP RLD ENTRY.                 14540000
AYC4     MVI   F8YDC(ACT),X'FF'         SET RELOCATABLE Y-CON IND.      14560000
         CLI   14(SP1),I2               PROCESS Y-TYPE RELOC. DC.       14580000
         BL    AYC5                      LOG AN ERROR MESSAGE AND SKIP  14600000
         B     AYD5                     RLD ENTRY IIF LMV LESS THAN 2.  14620000
AYK3     LM    SRR,SP1,SAVSRR           RESTORE REGISTERS 9 AND 10.     14640000
         BR    SRR                      EXIT AY ROUTINE**************** 14660000
         EJECT                                                          14680000
* THIS SUBROUTINE PROCESSES V AND Q TYPE ADDRESS CONSTANTS              14700000
*                                                                       14720000
VT       STM   SRR,SP1,SAVSRR           SAVE REGISTERS 9 AND 10         14740000
         LR    SP1,GRB                  SET SP1 = PTR. TO 1ST. CHAR.    14760000
VT1      ST    SP1,ERRORPTR             SAVE PTR TO NEXT CONSTANT       14780000
         BAL   GRY,EXPRES               EVALUATE EXPRESSION             14800000
         TM    ACONPT,X'30'             TEST CONDITION CODE FROM EEVAL  14820000
         BC    8,VT2                    TO PREVENT RLD FOR INVALID QCON 14840000
         SPACE 1                                                        14860000
* PREPARE ARGUMENTS FOR RLD ENTRY                                       14880000
         SPACE 1                                                        14900000
         L     R2,SAVSP1                RESTORE PTR. TO DC BUCKET       14920000
         LR    SP1,SP2                  PTR TO VALUE TO SP1             14940000
         SR    SP2,SP2                                                  14960000
         IC    SP2,14(R2)               GET LENGTH FROM DC BKT.         14980000
         BCTR  SP2,0                    SUBTRACT 1                      15000000
         CLI   1(R2),13                 TEST FOR QCON.                  15020000
         LA    R1,4                     SET FLAG = 1 = VCON        IEUK 15030018
         BNE   VCONRLD                  VCON, SO EXIT              IEUK 15040018
         LA    R1,8                     SET FLAG = 2 = QCON        IEUK 15050018
VCONRLD  OR    SP2,R1                   COMBINE TYPE & LENGTH      IEUK 15060018
         SLL   SP2,2                    POSITION RLD FLAG          IEUK 15070018
         BAL   SRR,RLDRTN               MAKE RLD ENTRY                  15120000
VT2      XC    TEMP(4),TEMP             SET 1ST 4 BYTES OF TEMP = 0     15140000
         BAL   FRB,KZERO                OUTPUT LMV ZERO BITS            15160000
         L     SP1,SPEVAL               RESTORE DELIMITER POINTER       15200000
         CLI   0(SP1),ICOMMA            IS DELIMITER A COMMA            15220000
         BNE   VT4                      NO, PREPARE TO EXIT             15240000
         LA    SP1,1(SP1)               YES, STEP OVER COMMA            15260000
         EX    R0,GETLMV                RESTORE LENGTH MODIFIER.        15280000
         B     VT1                       AND PROCESS NEXT CONSTANT.     15300000
VT4      LM    SRR,SP1,SAVSRR                                           15320000
         BR    SRR                      EXIT VT ROUTINE**************** 15340000
         EJECT                                                          15360000
*              THIS SUBROUTINE PROCESSES S TYPE ADDRESS CONSTANTS       15380000
*                                                                       15400000
*                               -SPECIFICATIONS-                        15420000
*                                                                       15440000
*                   IMPLIED LENGTH (BYTES)     2                        15460000
*                   ALIGNMENT              HALF WORD                    15480000
*                   LENGTH MODIFIER RANGE  2 ONLY                       15500000
*                   SPECIFIED BY           ONE ABSOLUTE OR RELOCATABLE  15520000
*                                          EXPRESSION, OR TWO ABSOLUTE  15540000
*                                          EXPRESSIONS                  15560000
*                   # CONSTANTS PER OPND   MULTIPLE                     15580000
*                   PADDING AND TRUNCATION NOT ALLOWED                  15600000
*                                                                       15620000
ST       STM   SRR,SP1,SAVSRR           SAVE REGISTERS 9 AND 10.        15640000
         LR    SP1,GRB                  SET SP1 = PTR TO 1ST EXPRESSION 15660000
STD2     ST    SP1,ERRORPTR             SAVE EXPRESSION POINTER         15680000
         BAL   GRY,EXPRES               EVALUATE EXPRESSION             15700000
         TM    ACONPT,X'30'             TEST CONDITION CODE FROM EEVAL  15720000
         BC    9,STA5                   BRANCH IF ABSOLUTE OR ERROR     15740000
         TM    ACONPT,X'20'                                             15760000
         BC    8,STA3                   BRANCH IF SIMPLY RELOCATABLE    15780000
         MVI   XY+1,RELOCERR            LOG RELOCATABILITY ERROR        15800000
         BAL   SRR,ERRLOG                                               15820000
         XC    TEMP(2),TEMP             SET 1ST 2 BYTES OF TEMP = 0.    15840000
         CLI   0(SP1),ILPARN            IS DELIMETER A LEFT PAREN       15860000
         BNE   STC4                     NO, ZERO TWO O/P BYTES NOW.     15880000
         SR    SP2,SP2                  YES, SET DISP=0, AND BRANCH TO  15900000
         B     STJ2                     PROCESS BASE-DISP. S-CON.       15920000
         SPACE 2                                                        15940000
* PROCESS ABSOLUTE S-CON.                                               15960000
         SPACE 2                                                        15980000
STA5     CLI   0(SP1),ILPARN            IF LEFT PAREN DELIMETER, ABS.   16000000
         BE    STJ2                     S-CON IS IN BASE-DISP FORM.     16020000
         SR    SP1,SP1                  IF NOT, ABS. S-CON MUST BE      16040000
         B     STB3                     DECOMPOSED.                     16060000
         SPACE 2                                                        16080000
* PROCESS SIMPLY RELOCATABLE S-CON.                                     16100000
         SPACE 2                                                        16120000
STA3     CLI   0(SP1),ILPARN            IF RELOC. S-CON DELIMITED BY    16140000
         BE    STJ3                      LEFT PAREN, BRANCH.            16160000
         LA    SP1,1                    SP1=1,RELOC---SP1=0,ABSOLUTE    16180000
STB3     STM   GRC,R14,TEMP             SAVE REGISTERS                  16200000
         OI    CTSCON(ACT),X'08'       INDICATE SCON-CALL TO DECOMP     16210021
         L     GRY,ERRORPTR             FETCH COLUMN PTR FOR DCMPSE.    16220000
         L     FRB,MACHOP(ACT)          PREPARE TO ENTER DECOMPOSITION  16240000
         L     SRB,F8DCMP(ACT)          ROUTINE.                        16260000
         BALR  SRR,SRB                  DECOMPOSE EXPRESSION            16280000
         USING *,SRR                                                    16300000
         LR    R1,SP2                   SAVE DECOMPOSED VALUE           16320000
         LM    GRC,R14,TEMP             RESTORE REGISTERS               16340000
         DROP  SRR                                                      16360000
         LR    SP2,R1                   DECOMPOSED VALUE TO SP2         16380000
         TM    CTSCON(ACT),X'04'       IS ADDR ERROR INDIC       A39647 16382021
         BZ    STC2                    NO                        A39647 16384021
         SR    SP2,SP2                 ZERO OUT DECOMP. VALUE    A39647 16386021
         MVI   XY+1,ADDRERR                                      A39647 16388021
         BAL   SRR,ERRLOG              ADDRESSABILITY ERROR      A39647 16390021
STC2     NI    CTSCON(ACT),X'F3'       RESET SCON SWITCH         A39647 16392021
STC3     STH   SP2,TEMP                 STORE IN TEMP BUFFER            16400000
STC4     BAL   FRB,KZERO                TEMP BUFFER TO O/P.             16420000
         L     SP1,SPEVAL               LOAD TEXT PTR. FROM EEVAL       16460000
STD3     CLI   0(SP1),ICOMMA            IS DELIMETER A COMMA            16480000
         BNE   STE4                     NO, PREPARE TO EXIT             16500000
         LA    SP1,1(SP1)               YES, STEP OVER COMMA, RESTORE   16520000
         EX    R0,GETLMV                 LMV AND BRANCH TO PROCESS      16540000
         B     STD2                       NEXT CONSTANT.                16560000
STE4     LM    SRR,SP1,SAVSRR           RESTORE REGISTERS 9 AND 10 AND  16580000
         BR    SRR                       EXIT S-CON ROUTINE************ 16600000
         SPACE 2                                                        16620000
* PROCESS S-CON WITH BASE-DISPLACEMENT SOURCE FORMAT.                   16640000
         SPACE 2                                                        16660000
STJ2     CL    SP2,=F'4095'             COMPARE DISPLACEMENT WITH MAX.  16680000
         BNH   STF2                     BRANCH IF OK.                   16700000
STJ3     MVI   XY+1,INVDPERR            OTHERWISE, LOG INVALID DIS-     16720000
         BAL   SRR,ERRLOG                PLACEMENT ERROR AND SET        16740000
         SR    SP2,SP2                    DISPLACEMENT=0.               16760000
STF2     ST    SP2,TEMP+100             SAVE DISPLACEMENT               16780000
         L     SP1,SPEVAL               LOAD TEXT POINTER FROM EEVAL.   16800000
         LA    SP1,1(SP1)               STEP OVER LEFT PAREN DELIMETER  16820000
         ST    SP1,ERRORPTR             SAVE TEXT POINTER.              16840000
         BAL   GRY,EXPRES               EVALUATE BASE REG. EXPRESSION   16860000
         TM    ACONPT,X'30'             TEST CONDITION CODE FROM EEVAL  16880000
         BC    8,STF1                   BRANCH IF BASE REG. ABSOLUTE.   16900000
         MVI   XY+1,INVRGERR            OTHERWISE LOG INVALID REGISTER  16920000
         BAL   SRR,ERRLOG                SPECIFICATION ERROR AND SET    16940000
         XC    SPEVAL+4(4),SPEVAL+4       REGISTER = 0.                 16960000
STF1     L     SP1,SPEVAL               LOAD TEXT POINTER FROM EEVAL.   16980000
         LA    SP1,1(SP1)               STEP OVER RIGHT PAREN.          17000000
         ST    SP1,SPEVAL               STORE TEXT POINTER              17020000
         L     SP2,SPEVAL+4             LOAD EVALUATED BASE REG. VALUE  17040000
         CL    SP2,=F'15'               COMPARE WITH MAXIMUM            17060000
         BNH   STB5                     BRANCH IF OK.                   17080000
         MVI   XY+1,INVRGERR            OTHERWISE LOG INVALID REGISTER  17100000
         BAL   SRR,ERRLOG                SPECIFICATION ERROR            17120000
         SR    SP2,SP2                    AND SET BASE = 0.             17140000
STB5     SLL   SP2,12                   POSITION BASE AND               17160000
         O     SP2,TEMP+100             LOGICAL OR WITH DISPLACEMENT    17180000
         B     STC3                     BRANCH TO O/P VALUE.            17200000
         EJECT                                                          17220000
* THIS SUBROUTINE PROCESSES ALL FIXED AND FLOATING POINT CONSTANTS      17240000
*                                                                       17260000
FHED     STM   SRR,SP1,SAVSRR           SAVE REGISTERS 9 AND 10         17280000
         LR    R1,GRB                   SET R1 = PTR TO 1ST CHARACTER   17300000
FHED01   ST    R1,ERRORPTR              SAVE TEXT POINTER               17320000
         STM   GRC,SRB,SRBGRY           SAVE BASE                       17340000
         L     SRB,CCONV(ACT)           LOAD CONVERSION RTN. BASE REG.  17360000
         BALR  SRR,SRB                  BRANCH TO CONVERSION ROUTINE    17380000
         USING *,SRR                    USE SRR AS BASE UNTIL           17400000
         LM    GRC,SRB,SRBGRY             SRB CAN BE RESTORED           17420000
         DROP  SRR                      SRB NOW RESTORED, DROP SRR BASE 17440000
         ST    R1,ACONPT                SAVE TEXT POINTER               17460000
         TM    0(GRZ),X'FF'             ERROR FLAG SET                  17480000
         BZ    FHED02                   NO                              17500000
         MVC   XY+1(1),0(GRZ)           YES, MOVE ERROR FLAG, SAVE PTR. 17520000
         ST    SP2,TEMP                 TO CONVERTED VALUE, AND BRANCH  17540000
         BAL   SRR,ERRLOG               TO ERROR ROUTINE.               17560000
         L     SP2,TEMP                 RESTORE PTR. TO CONVERTED VALUE 17580000
FHED02   MVC   TEMP(16),0(SP2)          MOVE CVT'D VALUE TO TEMP  IEUN2 17600018
         LA    R2,128                   SET KX TO TRUNCATE CVT'D  IEUN2 17620018
         S     R2,LMV                   VALUE ON THE LEFT.              17640000
         LCR   R2,R2                                                    17660000
         STH   R2,KX                                                    17680000
         BAL   FRB,KNEG                 TRUNCATE AND OUTPUT VALUE.      17700000
         L     R1,ACONPT                RESTORE TEXT POINTER            17720000
         CLI   0(R1),ICOMMA             IS DELIMETER A COMMA            17740000
         BNE   FHED03                   NO, PREPARE TO EXIT.            17760000
         LA    R1,1(R1)                 YES, STEP OVER COMMA.           17780000
         EX    R0,GETLMV                RESTORE LMV.                    17800000
         L     SP1,SAVSP1               RESTORE PTR TO DC BUCKET        17820000
         B     FHED01                   PROCESS NEXT CONSTANT.          17840000
FHED03   LM    SRR,SP1,SAVSRR           RESTORE REGISTERS 9 AND 10.     17860000
         BR    SRR                      EXIT FHED ROUTINE************** 17880000
         EJECT                                                          17900000
*                                                                     * 17920000
***                   RLD ROUTINE                                   *** 17940000
*                                                                     * 17960000
* SP1 = POINTER TO PARAMETER TABLE CREATED BY EXPRESSION EVALUATION   * 17980000
**      WHICH CONTAINS 16 2-BYTE ENTRIES AS FOLLOWS,                 ** 18000000
***         BYTES 0-3   ABSOLUTE VALUE OF RELOCATABLE EXPRESSION,   *** 18020000
****                    FULL WORD ALIGNED SIGNED INTEGER, FOLLOWED **** 18040000
*****                   BY ONE 2-BYTE ENTRY FOR EACH RELOCATABLE  ***** 18060000
****                    VALUE, CONTAINING                          **** 18080000
***                         BYTE 0 = SIGN                           *** 18100000
**                          BYTE 1 = ESD ID                          ** 18120000
* SP2 = 00XXLL00 WHERE XX = 00 FOR A & Y TYPE DC'S & CCW'S         IEUK 18130018
*                         = 01 FOR V TYPE DC'S                     IEUK 18140018
**                        = 10 FOR Q TYPE DC'S                     IEUK 18150018
***                       = 11 FOR CXD'S                            *** 18180000
**                 AND LL = LENGTH OF CONSTANT MINUS ONE (IN BYTES)  ** 18200000
*                                                                     * 18220000
RLDRTN   CLC   CESDID(1,ACT),CTNDID+1(ACT)   IS DATA IN A DSECT         18240000
         BCR   2,SRR                          YES, RETURN NOW.          18260000
         CLC   CTCMSW(1,ACT),CESDID(ACT)    IS DATA IN COMMON           18280000
         BCR   8,SRR                          YES, RETURN NOW.          18300000
         TM    SW,2                     IS PRINT SWITCH ENABLED         18320000
         BCR   1,SRR                    NO, RETURN NOW.                 18340000
         STM   GRA,SP2,TEMP+100         SAVE REGISTERS 4 THRU 11        18360000
         LA    GRA,4(SP1)   ADJ PTR TO 16 PAIRS OF VALUES,MOVE TO GRA   18380000
         LA    GRB,16                   SET COUNT FOR LOOP              18400000
RLOOP    SR    GRC,GRC                                                  18420000
         CLI   1(GRA),0                 IS THIS ITEM TO BE IGNORED      18440000
         BE    RLOOPS                     YES                           18460000
         CLC   1(1,GRA),CTNDID+1(ACT)   IS ESD-ID IN A DSECT            18480000
         BH    RLDGOOF                       YES, LOG ERROR AND EXIT.   18500000
         L     SRB,CTXTIO(ACT)                                          18520000
         BAL   SRR,PUTRLD(SRB)          CALL PUTRLD FOR RLDPTR          18540000
         USING *,SRR                                                    18560000
         L     SRB,TEMP+116             RESTORE DCEVAL BASE REGISTER    18580000
         DROP  SRR                                                      18600000
ESDOK    MVC   0(1,SP1),CESDID(ACT)     SET POS.ID = CURRENT ID         18620000
ESDAOK   MVC   3(3,SP1),STLOC+1         SET RLD ADDR. = CURRENT LOC.CTR 18640000
         MVC   2(1,SP1),TEMP+131        SET FLAG IN RLD ENTRY           18660000
         CLI   0(GRA),1                  IS SIGN PLUS                   18680000
         BE    SKIP2                     YES                            18700000
         OI    2(SP1),2                 NO - SET MINUS INDICATOR        18720000
SKIP2    MVC   1(1,SP1),1(GRA)          SET REL ID(RLD) = REL ID(PAR)   18740000
RLOOPS   LA    GRA,2(GRA)               SET PAR PTR TO NEXT PAIR VALUES 18760000
         BCT   GRB,RLOOP                BRANCH TO PROCESS NEXT PAIR     18780000
         LR    R1,SP1                    RLD POINTER TO REG 1.          18800000
RLDEXIT  LM    GRA,SP2,TEMP+100         RESTORE REGISTERS 4 THRU 11     18820000
         BR    SRR                      EXIT RLD ROUTINE*************** 18840000
RLDGOOF   MVI   XY+1,RELOCERR            LOG RELOCATABILITY ERROR, SET  18860000
         BAL   SRR,ERRLOG                 R1 TO ZERO, AND EXIT.         18880000
         LA    R1,0                      R1=0 MEANS NO RLD ENTRY.       18900000
         B     RLDEXIT                                                  18920000
         EJECT                                                          18940000
* THIS IS A COMMON LINKAGE TO THE ERROR ROUTINE, LOGERR.                18960000
         SPACE 2                                                        18980000
ERRLOG   STM   SRB,SP1,SDW                                              19000000
         L     SP1,ERRORPTR             LOAD POINTER TO ERROR           19020000
         L     SRB,CLOGER(ACT)          LOAD LOGERR BASE REGISTER       19040000
         BALR  SRR,SRB                                                  19060000
XY       DC    AL2(0)                   ARGUMENT CONTAINING ERROR NO.   19080000
         USING XY,SRR                                                   19100000
         LM    SRB,SP1,SDW                                              19120000
         DROP  SRR                                                      19140000
         BR    SRR                      RETURN TO LOGERR USER.          19160000
         SPACE 2                                                        19180000
* THIS IS A COMMON LINKAGE TO THE EXPRESSION EVALUATION ROUTINE, EEVAL. 19200000
* CURRENT ESD-ID AND LITERAL ADJUSTMENT VALUE ARE ADJUSTED FOR LITERAL  19220000
* DC'S CONTAINING REFERENCE TO THE LOCATION COUNTER.                    19240000
         SPACE 2                                                        19260000
EXPRES   ST    SRB,SRBGRY               SAVE REGISTERS                  19280000
         STM   GRX,GRY,TEMP                                             19300000
         TM    BYTEX,X'FF'              WHAT TYPE OPERATOR         9145 19306013
         BZ    NOLITDC                  DS STATEMENT               9145 19312013
         L     GRD,CTXABP(0,ACT)        GET POINTER TO APPENDED FLD9145 19318013
         BM    LITDC                    LITERAL DC                 9145 19324013
*        A DC STATEMENT...  CHANGE TXLOC SO EXPRESSION EVALUATION  9145 19330013
*        WILL USE CORRECT VALUE FOR REFERENCES TO THE LOCATION     9145 19336013
*        COUNTER WHEN EVALUATING ADCONS.                           9145 19342013
         L     GRD,STLOC                GET ADJUSTED VALUE OF *    9145 19348013
         S     GRD,F8CADJ(0,ACT)        REDUCE SO IT IS NOT ADJUST 9145 19354013
         ST    GRD,ASTERISK             SAVE IT SO CAN MOVE IN     9145 19360013
         L     GRD,CTXABP(0,ACT)        GET POINTER TO TXLOC       9145 19366013
         MVC   0(3,GRD),ASTERISK+1      PUT IN CORRECT TXLOC       9145 19372013
         B     NOLITDC                  CONTINUE                   9145 19378013
*                                                                  9145 19384013
LITDC    CLI   3(GRD),0                 DOES LIT HAVE AN *         9145 19390013
         BE    NOLITDC                  NO, BRANCH.                     19400000
         MVC   CADJSAV(4),F8CADJ(ACT)     SAVE CUR. LIT. ADJ. VAL.      19420000
         MVC   F8CADJ(4,ACT),CTZERO(ACT)  SET IT TO ZERO.               19440000
         MVC   ESDIDSAV(1),CESDID(ACT)    SAVE CURRENT ESD-ID.          19460000
         MVC   CESDID(1,ACT),3(GRD)     SET CESDID = ESDID OF LITERAL   19480000
         L     R2,CADJBS(ACT)           SET CURRENT ADJUSTMENT VALUE    19500000
MCKAY    C     R2,CTLATB(ACT)            EQUAL ADJUSTMENT VALUE FOR     19520000
         BNL   NOLITDC                    ASTERISK'S ESD.               19540000
         CLC   0(1,R2),CESDID(ACT)      IS THIS THE RIGHT ESD           19560000
         BE    MCKAYY                   YES, CONTINUE                   19580000
         LA    R2,4(R2)                 NO, LOOK AT NEXT ONE            19600000
         B     MCKAY                    BY LOOPING                      19620000
MCKAYY   MVC   F8CADJ+1(3,ACT),1(R2)    MOVE IN ESD BASE                19640000
NOLITDC  L     SRB,CEEVAL(ACT)          LOAD EEVAL BASE REGISTER AND    19660000
         BALR  SRR,SRB                  BRANCH TO EVALUATE EXPRESSION.  19680000
         USING *,SRR                    USE AS TEMP. BASE               19700000
         STM   SP1,SP2,SPEVAL           SAVE INFO FROM EEVAL.           19720000
         L     SRB,SRBGRY               RESTORE BASE                    19740000
         LM    GRX,GRY,TEMP             RESTORE REGISTER                19760000
         DROP  SRR                      DROP TEMP. BASE, SRB RESTORED   19780000
         BALR  R1,R0                    SAVE CONDITION CODE FROM        19800000
         ST    R1,ACONPT                 EEVAL.                         19820000
         TM    BYTEX,X'FF'              IS THIS A LITERAL DC.           19840000
         BCR   11,GRY                   NO, RETURN NOW.                 19860000
         CLI   3(GRD),0                 YES,DOES LIT. HAVE AN ASTERISK  19880000
         BCR   8,GRY                    NO, RETURN NOW.                 19900000
         MVC   CESDID(1,ACT),ESDIDSAV   YES, RESTORE CURRENT ESD-ID     19920000
         MVC   F8CADJ(4,ACT),CADJSAV    AND ADJUSTMENT VALUE.           19940000
         BR    GRY                      RETURN TO USER.                 19960000
         EJECT                                                          19980000
DCBRANCH DC    AL2(CT-CT)               CHARACTER DC.                   20320000
         DC    AL2(XT-CT)               HEXADECIMAL DC.                 20340000
         DC    AL2(BT-CT)                BINARY DC.                     20360000
         DC    AL2(PZ-CT)                PACKED DC.                     20380000
         DC    AL2(PZ-CT)               ZONED DC.                       20400000
         DC    AL2(FHED-CT)             DBL. PRECISION FLT. PT.         20420000
         DC    AL2(FHED-CT)             SNG. PRECISION FLT. PT.         20440000
         DC    AL2(FHED-CT)             FULL WORD DC.                   20460000
         DC    AL2(FHED-CT)             HALF WORD DC.                   20480000
         DC    AL2(AY-CT)               A-CON DC.                       20500000
         DC    AL2(AY-CT)               Y-CON DC.                       20520000
         DC    AL2(VT-CT)               V-CON DC.                       20540000
         DC    AL2(ST-CT)               S-CON DC.                       20560000
         DC    AL2(VT-CT)               Q-CON DC.                       20580000
         DC    AL2(FHED-CT)             EXTENDED FLT.PT L-CON     IEUN2 20590018
DUP      DC    F'0'           DUPLICATION FACTOR                        20600000
NN       DC    F'0'                     NUMBER OF CONSTANTS             20620000
LMV      DC    2F'0'                    LENGTH IN BITS                  20640000
ACONPT   DC    F'0'                     CONDITION CODE RETURNED - EVAL  20660000
STLOC    DC    F'0'                     LOCATION COUNTER FOR CCW RLD    20680000
POINT    DS    F                        PRESENT PNTER TO START OF OPRND 20700000
TPOINT   DC    F'0'                     TEMPARY POINTER SAVE AREA       20720000
ERRORPTR DC    F'0'                     POINTER TO ERRONEOUS EXPRESS.   20740000
ASTERISK DC    F'0'                     USED FOR INCREMENTING TXLOC.    20760000
CADJSAV  DS    F                        SAVE AREA FOR F8CADJ(ACT)       20780000
TEMP     DS    256C                     TEMPARY AREA - RLD TABLE        20800000
ADTEMP   DC    A(TEMP)                  ADDRESS OF TEMPARY AREA         20820000
MASK3    DC    F'7'                     MASK WITH 3 LOW ORDER BITS ON   20840000
TSBSRR   DS    F                        SUB1 AND SUB2 SAVE AREA FOR SRR 20860000
SDW      DS    2F                       SAVE AREA FOR ERROR LOG         20880000
FULL     DS    F                        FOR FULL WORD ALIGNMENT         20900000
SAV2     DS    2F                       RNEG REGISTER SAVE AREA         20920000
SRBGRY   DS    8F                       SAVE AREA FOR SRB THROUGH GRY   20940000
SAVSRR   DS    F                        SAVE AREA FOR RETURN            20960000
SAVSP1   DS    F                        SAVE AREA FOR POINTER           20980000
SAV14    DS    F                                                 A31016 20990020
LAST     DC    F'0'                     LENGTH FOR ZONED DC             21000000
SPEVAL   DS    2F                       RESULTS FROM EVAL               21020000
SAVWBP   DS    F                        SYMBOL BUCKET PTR. SAVE AREA    21040000
KX       DS    H                        LENGTH - 8 TIMES TOTAL LENGTH   21060000
TSHIFT   DC    H'0'                     NO. OF POSITIONS TO SHIFT       21080000
XXXII    DC    H'32'                    CONSTANT OF 32                  21100000
EIGHT    DC    H'8'                     CONSTANT OF 8                   21120000
RR       DC    H'0'                     BIT POSITION FOR NEXT BITS      21140000
BIT      DS    H                        BIT POSITION COUNTER            21160000
BYTE     DS    H                        BYTE POSITION COUNTER           21180000
SW       DC    X'00'                    GENERAL SWITCH                  21200000
*                                            01=FIRST OPERAND           21220000
*                                            02=DONT PRINT              21240000
*                                            08=NOT LAST CONSTANT       21260000
*                                            10=ZERO DUP FACTOR         21280000
CHTEMP   DS    CL3                      PACKING SWITCH                  21300000
HOLDLCTR DS    CL3                      ALIGNED LOCATION COUNTER        21320000
BYTEX    DS    C                        00=DS, FF= DC, MIXED= LITERAL   21340000
ESDIDSAV DS    C                        SAVE AREA FOR CESDID(ACT)       21360000
         END   DCEVAL                                                   21380000
