F8L      TITLE 'LOGERR - F/8 LOG ERROR SUBROUTINE '                     00020000
         ISEQ  73,80                                                    00040000
IEUF8L   START                                                          00060000
*                                                                       00062013
*                                                                       00064013
*                                                                       00066013
*                                                                       00068013
*                                                                       00070013
*                                                                       00072013
*                                                                       00074013
*                                                                       00076013
*                                                                       00078013
LOGERR   EQU   IEUF8L                                                   00080000
         SPACE                                                          00100000
         PRINT DATA,NOGEN                                               00120000
         FDIMEN                                                         00140000
         SPACE                                                          00160000
*TITLE 'IEUF8L  ' ... LOG ERROR                                       * 00180000
*STATUS- CHANGE LEVEL  01                                             * 00200000
*FUNCTION/OPERATION-                                                  * 00220000
*   IEUF8L ATTACHES THE ERROR MESSAGE TO AN EDITED TEXT RECORD. IF THE* 00240000
*   ERROR RECORD IS ALREADY PRESENT, IEU8L CHECKS FOR DUPLICATION AND * 00260000
*   A MAXIMUM OF 16 ERRORS, IF EITHER OF THESE CONDITIONS IS MET, THE * 00280000
*   ERROR IS NOT LOGGED. IF BOTH OF THE CONDITIONS ARE NOT MET, THE   * 00300000
*   ERROR IS LOGGED. IF THE ERROR RECORD IS NOT PRESENT, THE ERROR IS * 00320000
*   LOGGED AND A BIT IS SET IN TXERI SO THAT AN ERROR RECORD WILL BE  * 00340000
*   CREATED.                                                          * 00360000
*ENTRY POINT- IEUF8L                                                  * 00380000
*     CALLING SEQUENCE--                                              * 00400000
*                                                                     * 00420000
*       L     SRB,CLOGER(ACT)           LOGERR BASE/ENTRY ADDRESS     * 00440000
*       L     SP1,POINTER               ABS POINTER TO ERROR (OR ZERO)* 00460000
*       BALR  SRR,SRB                                                 * 00480000
*       DC    AL2(ERRORCODE)            ERRORCODE EQU ERROR MSSG NUMBR* 00500000
*                                                                     * 00520000
* LOGERR WILL RETURN TO CALLING ROUTINE WITH SP1,SP2 UNCHANGED.       * 00540000
* GR0-GR2, GRX, GRY, AND GRZ ARE VOLATILE.                            * 00560000
*                                                                     * 00580000
*INPUT- NONE                                                          * 00600000
*OUTPUT- NONE                                                         * 00620000
*EXTERNAL ROUTINES-                                                   * 00640000
*   GETXTM- GET TEXT AND MOVE, CALLED IF AN ERROR RECORD IS PRESENT   * 00660000
*EXITS- NORMAL                                                        * 00680000
*   RETURNS TO CALLER VIA                                             * 00700000
*        BR    2(SRR)                   EXIT                          * 00720000
*   --- ERROR- NONE                                                   * 00740000
*TABLES/WORKAREAS-                                                    * 00760000
*   CTERRP(ACT)- POINTS TO THE ERROR RECORD WORK AREA                 * 00780000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 00800000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 00820000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 00840000
*                                                                     * 00860000
         EJECT                                                          00880000
ERRMAX   EQU   16                       MAX NUMBER OF ERRORS/STATEMENT  00900000
         SPACE                                                          00920000
         USING LOGERR,SRB                                               00940000
         SPACE 2                                                        00960000
         STM   SP1,SP2,SAVE2            ENTER LOGERR, SAVE REGS         00980000
         L     SP2,CTERRP(ACT)          POINTER TO ERROR REC WORK AREA  01000000
         TM    CTPH7C(ACT),X'02'        TEST PHASE                      01020000
         BZ    LOGERRF7                 PHASE 7                         01040000
*        BO    LOGERRF8                 PHASE 8                         01060000
         SPACE                                                          01080000
******** PHASE 8 ****************************************************** 01100000
LOGERRF8 LA    SP1,1(SP1)               CALC RELATIVE POINTER         * 01120000
         S     SP1,F8OPRN(ACT)                                        * 01140000
         B     COLPOINT                                               * 01160000
*********************************************************************** 01180000
         SPACE                                                          01200000
******** PHASE 7 ****************************************************** 01220000
LOGERRF7 S     SP1,CTXOFP(ACT)          CALC RELATIVE POINTER         * 01240000
*        B     COLPOINT                                               * 01260000
*********************************************************************** 01280000
         SPACE                                                          01300000
COLPOINT BP    GETERR                   POINTER PRESENT                 01320000
         SR    SP1,SP1                  NOT PRESENT, CLEAR SP1          01340000
*        B     GETERR                                                   01360000
         EJECT                                                          01380000
GETERR   CLI   ERSWH(ACT),X'FF'         TEST ERROR REC IN CORE SWITCH   01400000
         BE    ADDERR                   SET, ADD ERROR MESSAGE TO REC   01420000
         MVI   ERSWH(ACT),X'FF'         NOT SET, SET                    01440000
         MVI   2(SP2),X'10'             INITIALIZE ERR REC IN WORK AREA 01460000
         MVI   3(SP2),X'00'             REC TYPE EQ 001, COUNT EQ ZERO  01480000
         L     GR1,CTEXTP(ACT)                                          01500000
         TM    TXERI(GR1),X'04'         TEST ERROR REC FOLLOWS IND      01520000
         BO    GETREC                   SET, GET ERROR REC FROM TEXT    01540000
         OI    TXERI(GR1),X'04'         NOT SET, SET IT                 01560000
         B     ADDERR                   THEN ADD ERR MESSAGE TO NES REC 01580000
         SPACE                                                          01600000
GETREC   STM   SRB,SP2,SAVE4            SAVE REGISTERS                  01620000
         LR    SP1,SP2                  PUT RECORD IN ERROR WK AREA     01640000
         L     SRB,CTXTIO(ACT)          LOAD BASE                       01660000
         BAL   SRR,GETXTM(SRB)          GET ERROR REC FROM TEXT FILE    01680000
         USING *,SRR                    GETXTM DESTROYED OUR BASE       01700000
         LM    SRB,SP2,SAVE4            SO RESTORE OUR BASE USING SRR   01720000
         DROP  SRR                      NO MORE NEED FOR SRR, SO DROP   01740000
         SPACE                                                          01760000
ADDERR   CLI   3(SP2),ERRMAX            TEST ERROR COUNT                01780000
         BE    RETURN                   EXIT IF MAX                     01800000
         SPACE                                                          01820000
         SR    GR1,GR1                  PUT ERROR COUNT IN GR1          01840000
         IC    GR1,3(SP2)                                               01860000
         LR    GR2,GR1                  POINT GR2 TO CURRENT MESSAGE-1  01880000
         SLL   GR2,1                                                    01900000
         LA    GR2,0(GR2,SP2)                                           01920000
         SPACE                                                          01940000
         STC   SP1,5(GR2)               PUT COL POINTER IN ERR MESSAGE  01960000
         MVC   4(1,GR2),1(SRR)          PUT ERROR CODE  IN ERR MESSAGE  01980000
         LH    SP1,4(GR2)               PUT ERROR MESSAGE IN SP1        02000000
         SPACE                                                          02020000
CHECKERR CLR   GR2,SP2                  COMPARE CURRENT ERROR MESSAGE   02040000
         BE    COUNTERR                 AGAINST PRIOR MESSAGES          02060000
         CH    SP1,2(GR2)                                               02080000
         BE    RETURN                   IGNORE IF PREVIOUSLY LOGGED     02100000
         BCTR  GR2,0                                                    02120000
         BCT   GR2,CHECKERR             LOOP TO COMPARE ALL             02140000
         SPACE                                                          02160000
COUNTERR LA    GR1,1(GR1)               INC ERROR COUNT                 02180000
         STC   GR1,3(SP2)                                               02200000
         LA    GR1,4(GR1,GR1)           INC RECORD LENGTH               02220000
         STH   GR1,TXRL(SP2)                                            02240000
         SPACE                                                          02260000
RETURN   LM    SP1,SP2,SAVE2            RESTORE REGS                    02280000
         B     2(SRR)                   RETURN TO CALLING ROUTINE       02300000
         SPACE                                                          02320000
SAVE2    DS    2F                       SP1,SP2 SAVE AREA               02340000
SAVE4    DS    4F                       SRB-SP2 SAVE AREA               02360000
         SPACE                                                          02380000
         END   LOGERR                                                   02400000
