F8M      TITLE 'F8MOP--F8 MACHINE OPERATOR PROCESSOR'                   00020000
         ISEQ  73,80                                                    00040000
IEUF8M   START 0                        MACHINE OP PROCESSOR            00060000
*          RELEASE 19 DELETIONS                                         00065000
* 056200,069600,104290-104320,106090-106120,149800-150400,       A27017 00065119
* 154000-154600,176800,183800-184000,188400-188600,              A27017 00065219
* 192000-192800                                                  A27017 00065319
*                                                                A28239 00065419
* 083600,184600-184800,191000                                    190000 00065519
*          RELEASE 20 DELETIONS                                         00066000
* 020000,051800,062400-062600,075600,081000-081200                 I001 00066320
*                                                                A28590 00066620
* 051800                                                          M0420 00066820
*          RELEASE 21 DELETIONS                                         00067000
* 081200                                                          21016 00067421
* 000640-000646,000680-000700,168200                             A45818 00069421
* 168200                                                         A67494 00069821
*                                                                       00071421
*STATUS CHANGE LEVEL 010                                                00072021
*                                                                       00074020
* INCREMENTAL IMPROVEMENTS FOR RELEASE 20                               00076020
* I001 NEW INSTRUCTIONS FOR SYSTEM 370                                  00078020
*                                                                       00078421
* INCREMENTAL IMPROVEMENTS FOR RELEASE 21                               00078821
* S99246 NEW INSTRUCTIONS FOR SYSTEM 370                                00079221
*                                                                       00079621
F8MOP    EQU   IEUF8M                   OLD NAME FOR MACH OP PROC       00080000
         PRINT NODATA,NOGEN                                             00100000
         FDIMEN                                                         00120000
         PRINT DATA,GEN                                                 00140000
         SPACE 2                                                        00160000
*                                                                     * 00180000
*TITLE 'IEUF8M  ' ...  MACHINE OPERATOR PROCESSOR                     * 00200000
*FUNCTION/OPERATION-                                                  * 00240000
*   IEUF8M PROCESSES THE OPERAND FIELDS OF EACH MACHINE INSTRUCTION.  * 00260000
*   IT SCANS THE OPERAND, CHECKS FOR SYNTAX ERRORS, FINDS THE CORRECT * 00280000
*   BASE, AND BUILDS 'F8INST' FOR PRINTING AND PUNCHING BY IEUF8P. THE* 00300000
*   FOLLOWING ERRORS ARE DETECTED AND FLAGGED-                        * 00320000
*        IMMEDIATE FIELD           INVALID DELIMITER                  * 00340000
*        ALIGNMENT                 INCORRECT REGISTER                 * 00360000
*        LENGTH                    INVALID LITERAL USAGE              * 00380000
*        NON-REENTERANT            RELOCABILITY                       * 00400000
*        INVALID DISPLACEMENT      LOCATION COUNTER                   * 00420000
*        ILLEGAL START CARD        ADDRESSABILITY                     * 00440000
*ENTRY POINTS-                                                        * 00460000
*   IEUF8M     MACHINE OPERAND PROCESSOR. CALLED VIA-                 * 00480000
*        L     FRB,MACHOP(ACT)          LOAD BASE/ENTRY               * 00500000
*        BALR  CRR,ACT                  CALL IEUF8M                   * 00520000
*   F8AREX     RELOCATABLE EXPRESSION EVALUATOR. CALLED VIA-          * 00540000
*        L     FRB,MACHOP(ACT)          LOAD BASE                     * 00560000
*        L     GR1,F8EXPX(ACT)          LOAD ENTRY                    * 00580000
*        BALR  SRR,GR1                  CALL F8AREX                   * 00600000
*   DCCOMP     DE COMPILE. CALLED VIA-                                * 00620000
*        L     FRB,MACHOP(ACT)          LOAD BASE                     * 00640000
*        L     GR1,F8DCMP(ACT)          LOAD ENTRY                    * 00660000
*        BALR  SRR,GR1                  CALL DE COMPILE               * 00680000
*INPUT-                                                               * 00700000
*   SP2 POINTS TO THE OPERAND                                         * 00720000
*   GRA POINTS TO F8WORK(ACT)                                         * 00740000
*   F8WORK(ACT) CONTAINS RECORD TYPES 4, 6, OR 7                      * 00760000
*OUTPUT-                                                              * 00780000
*   F8INST(ACT) IS PRODUCED FOR PRINTING AND/OR PUNCHING BY IEUF8P    * 00800000
*EXTERNAL ROUTINES-                                                   * 00820000
*   NAME            ROUTINE   USE                                     * 00840000
*   CEEVAL(ACT)     IEUF8V    EXPRESSION EVALUATION                   * 00860000
*   CLOGER(ACT)     IEUF8L    LOG ERROR                               * 00880000
*EXITS- NORMAL--                                                      * 00900000
*   IEUF8M RETURNS TO CALLER VIA-                                     * 00920000
*        B     CTRTRN(ACT)              EXIT                          * 00940000
*   F8AREX AND DCCOMP RETURN TO CALLER VIA-                           * 00960000
*        BR    SRR                      EXIT                          * 00980000
*   ERRORS- NONE                                                      * 01000000
*TABLES/WORKAREAS-                                                    * 01020000
*   MOPTBL -   TRANSFER TABLE FOR TYPE OF INSTRUCTION                 * 01040000
*   EXFLGS -   FLAGS SET BY F8AREX. SEE F8AREX FOR MEANING            * 01060000
*   VALUEB -   RESULTS OF F8AREX                                      * 01080000
*   F8AREGS -  SAVE AREA FOR DCCOMP                                   * 01100000
*   USNGPP -   USING TABLE POINTER. 1X16 BYTES, FF=REGISTER USED      * 01120000
*                                               00=REGISTER NOT USED  * 01140000
*   USNGTP -   USING TABLE. 4X16 BYTES, BYTE 1= ESD/ID                * 01160000
*                                       BYTES 2-4 = VALUE             * 01180000
*NOTES-                                                               * 01200000
*   TO GET THE INDEX IN THE BRANCH TABLE 'MOPTBL', A FOUR BIT INDEX IS* 01220000
*   USED. THE FIRST 2 BITS COME FROM BITS 4-5 OF THE TXASC CODE (TYPE * 01240000
*   CLASS WITHIN INSTRUCTION) AND THE LAST 2 BITS COME FROM THE FIRST * 01260000
*   2 BITS OF THE MACHINE CODE (LENGTH).                              * 01280000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 01300000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 01320000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 01340000
*                                                                     * 01360000
*                                                                       01361020
MKJ      EQU   X'B2'                    TWO-BYTE OPCODE MASK       I000 01362020
MKK      EQU   X'9E'                    TWO-BYTE OPCODE MASK       I000 01363020
MKM      EQU   X'9C'                        TWO-BYTE OPCODE MASK  M0420 01363520
MKN      EQU   X'9D'                    TWO BYTE OPCODE MASK     S99246 01363921
L3F      EQU   3                        OFFSET IN AN AREA          I000 01364020
L1B      EQU   1                        NUMBER OF BYTES TO MOVE    I000 01365020
MKL      EQU   X'F0'                    COM RTN MASK               I000 01366020
MKO      EQU   X'36'                    MASK FOR OUTPUT FLAGS      I000 01367020
MKP      EQU   X'0F'                    COM RTN MASK               I000 01368020
L1D      EQU   1                        NUMBER OF BYTES TO MOVE    I000 01369020
MKQ      EQU   X'01'                    MASK FOR EXPRESSION FLAG   I000 01370020
L10      EQU   10                       COMP. FOR DEC DIG TEST     I000 01371020
L1C      EQU   1                        INCREMENT FOR SP1          I000 01372020
MKR      EQU   X'01'                    INSTR FIELD MASK           I000 01373020
MKS      EQU   X'0E'                    MVCL OR CLCL MASK          I000 01374020
MKT      EQU   X'BF'                    MASK FOR EVEN REG IN OPND  I000 01375020
MKU      EQU   X'01'                    MASK FOR EVEN EXPN VALUE   I000 01376020
MKV      EQU   X'00'                    LITERAL MASK               I000 01377020
MCOP     EQU   X'AF'                    MC OPCODE MASK            21016 01379021
PTLB     EQU   X'0D'                    PTLB OPCODE MASK 2-BYTE  S99246 01379821
         EJECT                                                          01380000
         USING *,FRB                                                    01400000
         SR    GRZ,GRZ                                                  01420000
         MVI   RR2SWH(ACT),X'00'        SET TYPE 2 FLAG OFF             01440000
         MVI   ABSRX,X'00'              ZERO ABSOLUTE WITCH             01460000
         MVI   ERRSW,X'00'             TURN OFF STATEMENT ERROR SWITCH  01480000
         MVI   LITRLTWO,X'00'           ZERO MULT. LIT SWITCH           01500000
         LR    SP1,SP2                  OPERAND POINTER TO SP1          01520000
         IC    GRZ,F8WORK+4(ACT)        HEXOP                           01540000
         STC   GRZ,F8INST+3(ACT)        TO INSTRUCTION                  01560000
         SR    GRY,GRY                                                  01580000
         IC    GRY,BITS45               BITS 4 AND 5                    01600000
         MVC   ALIGNT+3(1),5(GRA)                                       01620000
         N     GRY,ALIGNT                                               01640000
         SRL   GRZ,6                    BITS 0 AND 1 TO 6 AND 7         01660000
         CLI   F8INST+3(ACT),X'B1'      IS IT LRA INSTRUCTION    S99246 01680021
         BE    LRA                      YES, SPECIAL CASE        S99246 01686021
BRANCH   OR    GRZ,GRY                 16 WAY BRANCH TO MACH OPC S99246 01692021
         AR    GRZ,GRZ                 DOUBLE FOR TABLE RECOVERY        01700000
         LH    GRZ,MOPTBL(GRZ)         GET RELATIVE ENTRY POIMT         01720000
         B     MOPROC(GRZ)             BRANCH TO PROPER PROCESSOR       01740000
LRA      LA    SRR,3                    SET BIT 6 AND 7 OF GRZ   S99246 01745021
         XR    GRZ,SRR                     FOR RIGHT ADDRESSING  S99246 01750021
         B     BRANCH                         FOR INSTR LRA - RX S99246 01755021
MOPTBL   DS    0H                      START OF DISPLACEMENT TABLE      01760000
         DC    AL2(RR1-MOPROC)          REGISTER - REGISTER      TYPE 1 01780000
         DC    AL2(RX1-MOPROC)          REGISTER - INDEX STORAGE TYPE 1 01800000
         DC    AL2(RS1-MOPROC)          REGISTER - STORAGE       TYPE 1 01820000
         DC    AL2(SS1-MOPROC)          STORAGE - STORAGE        TYPE 1 01840000
         DC    AL2(RR2-MOPROC)          REGISTER - REGISTER      TYPE 2 01860000
         DC    AL2(RX2-MOPROC)          REGISTER - INDEX STORAGE TYPE 2 01880000
         DC    AL2(RS2-MOPROC)          REGISTER - STORAGE       TYPE 2 01900000
         DC    AL2(SS2-MOPROC)          STORAGE - STORAGE        TYPE 2 01920000
         DC    AL2(RR3-MOPROC)          REGISTER - REGISTER      TYPE 3 01940000
         DC    AL2(PROCER-MOPROC)       PROCEDURE ERROR          ****** 01960000
         DC    AL2(SI3-MOPROC)          STORAGE - IMMEDIATE      TYPE 3 01980000
         DC    AL2(SS3-MOPROC)          STORAGE-STORAGE TYPE 3     I001 02000020
         DC    AL2(RR4-MOPROC)          REGISTER - REGISTER      TYPE 4 02020000
         DC    AL2(PROCER-MOPROC)       PROCEDURE ERROR          ****** 02040000
         DC    AL2(SI4-MOPROC)          STORAGE - IMMEDIATE      TYPE 4 02060000
         DC    AL2(PROCER-MOPROC)       PROCEDURE ERROR          ****** 02080000
MOPROC   DS    0H                      RELATIVE ENTRY ZERO              02100000
*********************************************************************** 02120000
***   RR1   ***                                                         02140000
*REGISTER TO REGISTER INSTRUCTION TYPE 1 PROCESSOR                      02160000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF THOSE REGISTER TO         02180000
* REGISTER INSTRUCTIONS WHICH NAME BOTH REGISTERS EXPLICITLY.           02200000
*********************************************************************** 02220000
RR1      MVI   F8INST+15(ACT),X'02'     LENGTH IS 2 BYTES               02240000
         LA    GR0,2                                                    02260000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 02280000
         BAL   SRR,R1PROC               PROCESS R1                      02300000
         BNE   DLMERR                                                   02320000
         LA    SP1,1(SP1)               SET POINTER TO NEXT CHAR        02340000
RR1A     BAL   SRR,R2PROC               PROCESS R2                      02360000
RRXT     CLI   0(SP1),IBLANK            IS NEXT CHAR A BLANK            02380000
         BNE   DLMERR                   NO, LOG ERROR                   02400000
         B     MOPRTN                   RETURN                          02420000
*********************************************************************** 02440000
***   RR2   ***                                                         02460000
*REGISTER TO REGISTER INSTRUCTION TYPE 2 PROCESSOR                      02480000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF THE SPM INSTRUCTION.      02500000
*********************************************************************** 02520000
RR2      MVI   F8INST+15(ACT),X'02'     LENGTH IS 2 BYTES               02540000
         LA    GR0,2                                                    02560000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 02580000
RR2A     BAL   SRR,R1PROC               PROCESS R1                      02600000
         B     RRXT                     GO SEE IF NEXT CHAR A BLANK     02620000
*********************************************************************** 02640000
***   RR3   ***                                                         02660000
*REGISTER TO REGISTER INSTRUCTION TYPE 3 PROCESSOR                      02680000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF THE SVC INSTRUCTION.      02700000
*********************************************************************** 02720000
RR3      MVI   F8INST+15(ACT),X'02'     LENGTH IS 2 BYTES               02740000
         LA    GR0,2                                                    02760000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 02780000
         BAL   SRR,IPROC                REGISTER BRANCH FOR TRAIL ONLY  02800000
*********************************************************************** 02820000
***   RR4   ***                                                         02840000
*REGISTER TO REGISTER INSTRUCTION TYPE 4 PROCESSOR                      02860000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF EXTENDED MNEMONIC         02880000
*REGISTER TO REGISTER INSTRUCTIONS.  R1 IS SET WITH AN IMPLICITLY       02900000
*DEFINED VALUE AND R2 RECEIVES THE EXPLICITLY DEFINED VALUE.            02920000
*********************************************************************** 02940000
RR4      MVI   F8INST+15(ACT),X'02'     LENGTH IS 2 BYTES               02960000
         LA    GR0,2                                                    02980000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 03000000
         MVO   F8INST+4(1,ACT),F8WORK+3(1,ACT)    MOVE IN EXTENDED MNEM 03020000
         B     RR1A                     CONTINUE AS THOUGH RR1          03040000
*********************************************************************** 03060000
***   RX1   ***                                                         03080000
*REGISTER-INDEXABLE STORAGE INSTRUCTION TYPE 1 PROCESSOR                03100000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF REGISTER-INDEXABLE        03120000
* STORAGE INSTRUCTIONS IN WHICH BOTH OPERANDS ARE EXPLICITLY DEFINED.   03140000
*********************************************************************** 03160000
RX1      MVI   F8INST+15(ACT),X'14'     PUT OUT EA2                     03180000
         LA    GR0,4                    LENGTH IS 4 BYTES               03200000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 03220000
         BAL   SRR,R1PROC               PROCESS R1                      03240000
         BNE   DLMERR                   IF ERROR BRANCH                 03260000
         LA    SP1,1(SP1)               UP TO NEXT CHAR                 03280000
RX2A     BAL   SRR,S2D2A                GET DISPLACEMENT                03300000
         BE    MOPRTN                   BRANCH IF END OF FIELD          03320000
         CLI   0(SP1),ILPARN            IS NEXT CHAR A LEFT PARN        03340000
         BNE   DLMERR                   DELIMETER NOT LEFT PAREN        03360000
         LA    SP1,1(SP1)               BUMP OPERAND POINTER            03380000
         CLI   0(SP1),ICOMMA            IS NEXT CHARACTER COMMA         03400000
         BE    RX1B                     YES, SKIP INDEX                 03420000
RX1A     BAL   SRR,X2PROC               PROCESS X2 FIELD                03440000
         BE    RX1B                     IF COMMA, PROCESS B2            03460000
         CLI   0(SP1),IRPARN            IF NOT, IS DELIMETER RIGHT PARN 03480000
         BNE   DLMERR                   IF NOT, DELIMETER ERROR         03500000
         B     RX1C                     CHECK BLANK AND EXIT TO CALLER  03520000
RX1B     LA    SP1,1(SP1)               BUMP OPERAND POINTER            03540000
         BAL   SRR,B2A                  PROCESS B2                      03560000
RX1C     CLI   1(SP1),IBLANK           IS DELIMETER BLANK               03580000
         BE    MOPRTN                   COMMON RETURN                   03600000
         B     DLMERR                   DELIMETER ERROR                 03620000
*********************************************************************** 03640000
***   RX2   ***                                                         03660000
*REGISTER-INDEXABLE STORAGE INSTRUCTION TYPE 2 PROCESSOR                03680000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF REGISTER-INDEXABLE        03700000
* STORAGE INSTRUCTIONS IN WHICH R1 IS SET WITH AN IMPLICITLY DEFINED    03720000
* VALUE AND THE INDEXABLE VALUE IS SPECIFIED.                           03740000
*********************************************************************** 03760000
RX2      MVI   F8INST+15(ACT),X'14'     OUTPUT FLAG TO INSTRUCTION      03780000
         LA    GR0,4                    LENGTH IS 4 BYTES               03800000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 03820000
         MVO   F8INST+4(1,ACT),F8WORK+3(1,ACT) R1 MASK TO INSTRUCTION   03840000
         B     RX2A                     COMMON RX1 AND RX2 PART         03860000
*********************************************************************** 03880000
***   RS1   ***                                                         03900000
*REGISTER-STORAGE INSTRUCTION TYPE 1 PROCESSOR                          03920000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF REGISTER-STORAGE          03940000
* INSTRUCTIONS IN WHICH R1,R3, AND STORAGE ARE SPECIFIED                03960000
*********************************************************************** 03980000
RS1      MVI   F8INST+15(ACT),X'14'     OUTPUT FLAG TO INSTRUCTION      04000000
         LA    GR0,4                    LENGTH IS 4 BYTES               04020000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 04040000
         BAL   SRR,R1PROC               PROCESS R1                      04060000
         BNE   DLMERR                   DELIMETER ERROR IF NOT COMMA    04080000
         LA    SP1,1(SP1)               BUMP OPERAND POINTER            04100000
         BAL   SRR,R3PROC               PROCESS R3                      04120000
         BNE   DLMERR                   DELIMETER ERROR IF NOT COMMA    04140000
RS2A     LA    SP1,1(SP1)               BUMP OPERAND POINTER            04160000
         BAL   SRR,S2D2A                PROCESS S2 OR D2                04180000
         BE    MOPRTN                   EXIT                            04200000
         CLI   0(SP1),ILPARN            IS DELIMETER LEFT PAREN         04220000
         BNE   DLMERR                   NO, DELIMETER ERROR             04240000
         LA    SP1,1(SP1)               BUMP OPERAND POINTER            04260000
         BAL   SRR,B2A                  PROCESS B2A                     04280000
         CLI   1(SP1),IBLANK           IS DELIMETER BLANK               04300000
         BE    MOPRTN                   YES, EXIT                       04320000
         B     DLMERR                   NO, DELIMETER ERROR             04340000
*********************************************************************** 04360000
***   RS2   ***                                                         04380000
*REGISTER-STORAGE INSTRUCTION TYPE 2 PROCESSOR                          04400000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF ALL SHIFT INSTRUCTIONS    04420000
*********************************************************************** 04440000
RS2      MVI   F8INST+15(ACT),X'14'     SET OUTPUT FLAGS IN INSTRUCTION 04460000
         LA    GR0,4                    LENGTH IS 4 BYTES               04480000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 04500000
         BAL   SRR,R1PROC               PROCESS R1                      04520000
         BNE   DLMERR                   IF DELIMETER NOT COMMA, ERROR   04540000
         B     RS2A                     BRANCH TO COMMON RS1 RS2 RTN    04560000
*********************************************************************** 04580000
***   SI3   ***                                                         04600000
*STORAGE-IMMEDIATE INSTRUCTION TYPE 3 PROCESSOR                         04620000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF ALL STORAGE-IMMEDIATE     04640000
* INSTRUCTIONS EXCEPT LPSW,SSM,HIO,SIO,TIO,TCH, AND TS                  04660000
* ALSO  HDV, SCK, STCK, SIOFR, STHID, STPID                        I001 04670020
*********************************************************************** 04680000
SI3      MVI   F8INST+15(ACT),X'24'     SET OUTPUT FLAGS IN INSTRUCTION 04700000
         LA    GR0,4                    LENGTH IS 4 BYTES               04720000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 04740000
         BAL   SRR,S1D1                 PROCESS S1 D1                   04760000
         CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              04780000
         BE    SI3A                     IF COMMA PROCESS I              04800000
         CLI   0(SP1),ILPARN            DELIMETER LEFT PAREN TEST       04820000
         BNE   DLMERR                   DELIMETER ERROR                 04840000
         LA    SP1,1(SP1)               BUMP OPERAND POINTER            04860000
         BAL   SRR,B1                   PROCESS B1                      04880000
         LA    SP1,1(SP1)               BUMP OPERAND POINTER            04900000
         CLI   0(SP1),ICOMMA           IS DELIMETER COMMA               04920000
         BNE   DLMERR                   DELIMETER ERROR                 04940000
SI3A     LA    SP1,1(SP1)              BUMP OPERAND POINTER BY ONE      04960000
         BAL   SRR,IPROC               PROCESS IMMEDIATE FIELD          04980000
*********************************************************************** 05000000
***   SI4   ***                                                         05020000
*STORAGE-IMMEDIATE INSTRUCTION TYPE 4 PROCESSOR                         05040000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF THE STORAGE-IMMEDIATE     05060000
* INSTRUCTIONS LPSW,SSM,HIO,SIO,TIO,TCH, AND TS                         05080000
* ALSO  HDV, SCK, STCK, SIOFR, STHID, STPID                        I001 05090020
* AND RRB,SCKC,STCKC,SPT,STPT AND  PTLB                          S99246 05095021
*********************************************************************** 05100000
SI4      MVI   F8INST+15(ACT),X'24'     SET OUTPUT FLAGS IN INSTRUCTION 05120000
         LA    GR0,4                    LENGTH IS 4 BYTES               05140000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 05160000
         CLI   TXHEX(GRA),MKJ           IS IT TWO-BYTE OPCODE?     I001 05165020
         BE    IOEXT                    YES                        I001 05170020
         CLI   TXHEX(GRA),MKK                                      I001 05175020
         BE    IOEXT                        YES                   M0420 05177020
         CLI   TXHEX(GRA),MKM                                     M0420 05179020
         BE    IOEXT                        YES                  S99246 05179421
         CLI   TXHEX(GRA),MKN                                    S99246 05179821
         BNE   TAS1                         NO                    M0420 05181020
IOEXT    MVN   F8INST+4(L1B,ACT),L3F(GRA)   GET TABLE DISPLACEMENT I001 05185020
         TR    F8INST+4(L1B,ACT),TASTABLE   GET 2ND BYTE OF OPCODE I001 05190020
         CLI   F8INST+4(ACT),PTLB      IS IT PTLB INSTR          S99246 05191021
         BE    MOPRTA                  YES  IGNORE OPERAND       S99246 05192021
TAS1     BAL   SRR,S1D1                 PROCESS S1 OR D1           I001 05195020
         BE    MOPRTN                   IF DELIMETER BLANK, EXIT        05200000
         CLI   0(SP1),ILPARN            IS DELIMETER LEFT PAREN         05220000
         BNE   DLMERR                   NO, DELIMETER ERROR             05240000
         LA    SP1,1(SP1)               BUMP OPERAND POINTER            05260000
         BAL   SRR,B1                   PROCESS B1                      05280000
         CLI   1(SP1),IBLANK            DELIMETER AFTER PAREN BLANK     05300000
         BE    MOPRTN                   YES, EXIT                       05320000
         B     DLMERR                   NO, ERROR                       05340000
         SPACE 1                                                   I001 05345020
*    TABEL  OF  2ND BYTE OF OPCODE                     I001 I002 S99246 05350021
TASTABLE DC    X'050402010300060708090A0B000D13'            I001 S99246 05352021
         SPACE 1                                                   I001 05355020
*********************************************************************** 05360000
***   SS1   ***                                                         05380000
*STORAGE TO STORAGE INSTRUCTION TYPE 1 PROCESSOR                        05400000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF THE STORAGE TO STORAGE    05420000
* INSTRUCTIONS REQUIRING BOTH L1 AND L2 EITHER EXPLICIT OR IMPLICIT     05440000
*********************************************************************** 05460000
SS1      MVI   F8INST+15(ACT),X'36'     SET OUTPUT FLAGS IN INSTRUCTION 05480000
         OI    TASW+1,MKL               MOD BRANCH FOR COM RTN     I001 05490020
         LA    GR0,6                    LENGTH IS 4 BYTES               05500000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 05520000
         BAL   SRR,S1D1                 PROCESS S1 OR D1                05540000
         CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              05560000
         BNE   SS1A                     NO, SKIP IMPLIED LENGTH 1       05580000
         BAL   SRR,IMPLL1               INSERT INPLIED LENGTH 1         05600000
SS12ND   BAL   SRR,DISPCHEK             CHECK DISP OR ADDR ERROR A27017 05610019
         LA    SP1,1(SP1)               SECOND OPERAND ENTRY     A27017 05620019
         BAL   SRR,S2D2B                PROCESS S2 OR D2, IS DELIM BLNK 05640000
         BNE   SS1N                     NO, SKIP IMPMPLIED LENGTH       05660000
         BAL   SRR,IMPLL2               INSERT INPLIED LENGTH 2         05680000
         B     MOPRTN                   MACHINE OP EXIT                 05700000
IMPLL1   CLI   STLONG+1(ACT),15         IF LARGER THAN 15, TOO BIG      05720000
         BH    LENERR                   ERROR EXIT                      05740000
         CLI   STLONG(ACT),0            IF LARGER THAN 15, TOO BIG      05760000
         BH    LENERR                   ERROR EXIT                      05780000
         MVO   F8INST+4(1,ACT),STLONG+1(1,ACT)  IMPLIED LENGTH TO INST  05800000
         BR    SRR                              RETURN TO CALLER        05820000
IMPLL2   CLI   STLONG+1(ACT),15         IF LARGER THAN 15, TOO BIG      05840000
         BH    LENERR                   ERROR EXIT                      05860000
         CLI   STLONG(ACT),0            IF LARGER THAN 15, ERROR        05880000
         BH    LENERR                   ERROR EXIT                      05900000
         MVN   F8INST+4(1,ACT),STLONG+1(ACT)                            05920000
         BR    SRR                              RETURN TO CALLER        05940000
SS1A     CLI   0(SP1),ILPARN            IS DELIMETER LEFT PAREN         05960000
         BNE   DLMERR                   NO, ERROR                       05980000
         LA    SP1,1(SP1)               BUMP OPERAND POINTER            06000000
         CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              06020000
         BNE   SS1B                     IF NO, PROCESS LENGTH           06040000
         BAL   SRR,IMPLL1               IMPLIED LENGTH 1 TO INSTRUCTION 06060000
         B     SS1E                     PROCESS BASE 1                  06080000
SS1B     BAL   SRR,L1PROC               PROCESS L1                      06100000
         MVO   F8INST+4(1,ACT),VALUEB+3(1) L1 VALUE TO INSTRUCTION      06120000
         BNE   SS1D                     IF DELIMETER NOT COMMA, SKIP B1 06140000
SS1E     LA    SP1,1(SP1)               BUMP OPERAND POINTER            06160000
         BAL   SRR,B1                   PROCESS B1                      06180000
SS1C     LA    SP1,1(SP1)               BUMP OPERAND POINTER            06200000
         CLI   0(SP1),ICOMMA            IS DELIMETER AFTER PAREN COMMA  06220000
         BNE   DLMERR                  NO, ERROR                   I001 06230020
         SPACE 1                                                   I001 06240020
TASW     B     SS12ND                  THIS BR MODIFIED BY SS3,    I001 06250020
         B     SS32ND                   RESET BY SS1.              I001 06260020
         SPACE 1                                                   I001 06270020
SS1N     CLI   0(SP1),ILPARN           IS DELIMERT LEFT PAREN           06280000
         BNE   DLMERR                   NO, ERROR                       06300000
         LA    SP1,1(SP1)               BUMP OPERAND POINTER            06320000
         CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              06340000
         BNE   SS1P                     IF NO, PROCESS LENGTH           06360000
         BAL   SRR,IMPLL2               IMPLIED LENGTH 2 TO INSTRUCTION 06380000
         B     SS1S                     PROCESS BASE 2                  06400000
SS1P     BAL   SRR,L2PROC               PROCESS L2                      06420000
         MVN   F8INST+4(1,ACT),VALUEB+3 MOVE L2 VALUE TO INSTRUCTION    06440000
         BNE   SS1R                     IF DELIMETER NOT COMMA, SKIP B2 06460000
SS1S     LA    SP1,1(SP1)               BUMP OPERAND POINTER            06480000
         BAL   SRR,B2B                  PROCESS B2                      06500000
SS1Q     CLI   1(SP1),IBLANK            IS DELIEETER AFTER PAREN BLANK  06520000
         BE    MOPRTN                   IF YES, EXIT MACHINE OP PROCESS 06540000
         B     DLMERR                   IF NO, DELIMETER ERROR          06560000
SS1D     CLI   0(SP1),IRPARN            IS DELIMETER RIGHT PAREN        06580000
         BE    SS1C                     CHECK NEXT DELIMETER            06600000
         B     DLMERR                   IF NO, DELIMETER ERROR          06620000
SS1R     CLI   0(SP1),IRPARN            IS DELIMETER RIGHT PAREN        06640000
         BE    SS1Q                     CHECK NEXT DELIMETER            06660000
         B     DLMERR                   IF NO, DELIMETER ERROR          06680000
*********************************************************************** 06700000
***   SS2   ***                                                         06720000
*STORAGE TO STORAGE INSTRUCTION TYPE 2 PROCESSOR                        06740000
* THIS ROUTINE PROCESSES THE OPERAND FIELD OF THE STORAGE TO STORAGE    06760000
* INSTRUCTIONS REQUIRING ONLY ONE MOVE LENGTH                           06780000
*********************************************************************** 06800000
SS2      MVI   F8INST+15(ACT),X'36'     SET OUTPUT FLAGS IN INSTRUCTION 06820000
         LA    GR0,6                    LENGTH IS 6 BYTES               06840000
         ST    GR0,CTF8LNGT(ACT)        SET LENGTH FOR WRAP AROUND TEST 06860000
         BAL   SRR,S1D1                 PROCESS S1 OR D1                06880000
         CLI   0(SP1),ICOMMA            IS DELIMETER COMMA              06900000
         BNE   SS2A                     NO, SKIP IMPLIED LENGTH         06920000
         BAL   SRR,IMPLL                INSERT IMPLIED LENGTH           06940000
SS22ND   BAL   SRR,DISPCHEK             CHECK DISP OR ADDR ERR   A27017 06950019
         LA    SP1,1(SP1)               SECOND OPERAND ENTRY     A27017 06960019
         BAL   SRR,S2D2B                PROCESS S2 OR D2, IS DELIM BLNK 06980000
         BNE   SS2N                     NO, PROCESS BASE                07000000
         B     MOPRTN                   MACHINE OP EXIT                 07020000
SS2A     CLI   0(SP1),ILPARN            IS DELIMETER LEFT PAREN         07040000
         BNE   DLMERR                   IF NO, DELIMETER ERROR          07060000
         LA    SP1,1(SP1)               BUMP OPERAND POINTER            07080000
         CLI   0(SP1),ICOMMA            IS NEXT DELIMETER COMMA         07100000
         BNE   SS2B                     IF NOT, PROCESS LENGTH          07120000
         BAL   SRR,IMPLL                IF COMMA, IMPLIED LENGTH TO INS 07140000
         B     SS2E                     PROCESS B1                      07160000
SS2B     BAL   SRR,LPROC                PROCESS LENGTH                  07180000
         MVC   F8INST+4(1,ACT),VALUEB+3 LENGTH VALUE TO INSTRUCTION     07200000
         BNE   SS2D                     IF NOT COMMA, TRY RIGHT PAREN   07220000
SS2E     LA    SP1,1(SP1)               IF DELIMETER COMMA, BUMP OPRN   07240000
         BAL   SRR,B1                   PROCESS B1                      07260000
SS2C     LA    SP1,1(SP1)               BUMP OPERAND POINTER            07280000
         CLI   0(SP1),ICOMMA            IS NEXT DELIMETER COMMA         07300000
         BE    SS22ND                   YES, DO 2ND OPERAND             07320000
         B     DLMERR                   NO, DELIMETER ERROR             07340000
IMPLL    CLI   STLONG(ACT),0            IS LENGTH GREATER THAN 255      07360000
         BH    LENERR                   IF HIGH, TOO BIG                07380000
         MVC   F8INST+4(1,ACT),STLONG+1(ACT) IMPLIED LENGTH TO INST     07400000
         BR    SRR                           RETURN TO CALLING RTN      07420000
SS2N     CLI   0(SP1),ILPARN                 IS DELIMETER LEFT PAREN    07440000
         BNE   DLMERR                        NO, DELIMETER ERROR        07460000
         B     SS2S                          PROCESS B2                 07480000
SS2S     EQU   SS1S                                                     07500000
SS2D     CLI   0(SP1),IRPARN                 IS DELIMETER LEFT PAREN    07520000
         BE    SS2C                          IF EQUAL TEST FUTHER       07540000
         B     DLMERR                  IF NOT, DELIMITER ERROR     I001 07540420
*****************************************************************  I001 07540820
***  SS3  ***                                                  **  I001 07541220
*  STORAGE TO STORAGE INSTRUCTION PROCESSOR                    **  I001 07541620
*  THIS ROUTINE PROCESSES THE OPERAND FIELD OF THE INSTRUCTION **  I001 07542020
*  SRP                                                         **  I001 07542420
*****************************************************************  I001 07542820
SS3      MVI   F8INST+15(ACT),MKO       SET OUTPUT FLAGS IN INSTR. I001 07543220
         NI    TASW+1,MKP               MOD BRANCH FOR COM RTN     I001 07543620
         LA    GR0,6                   LENGTH IS 6 BYTES           I001 07544020
         ST    GR0,CTF8LNGT(ACT)       SET LENGTH FOR WRAPAROUND   I001 07544420
         BAL   SRR,S1D1                TEST,PROCESS S1 OR D1       I001 07544820
         CLI   0(SP1),ICOMMA           IS DELIMITER COMMA?         I001 07545220
         BNE   SS1A                    NO, SKIP IMPLIED LENGTH     I001 07545620
         BAL   SRR,IMPLL1              INSERT IMPLIED LENGTH       I001 07546020
SS32ND   LA    SP1,1(SP1)              SECOND OPERAND ENTRY        I001 07546420
         BAL   SRR,S2D2B               PROCESS S2 OR D2            I001 07546820
         CLI   0(SP1),ICOMMA           IS DELIMITER COMMA?         I001 07547220
         BNE   SS3N                    NO                          I001 07547620
SS33RD   LA    SP1,L1C(SP1)             BUMP OPERAND POINTER       I001 07548020
I3PROC   BAL   SRR,F8ARGX                                          I001 07548420
         TM    AEXP1,MKQ                TEST IF GT 15              I001 07548820
         BNZ   I3ERR                       YES                     I001 07549220
         CLI   VALUEB+3,L10             IS VALUE A DECIMAL DIGIT   I001 07549620
         BNL   I3ERR                   NO, ERROR                   I001 07550020
         MVN   F8INST+4(L1B,ACT),VALUEB+3                          I001 07550420
SS3EXIT  CLI   0(SP1),IBLANK           END OF OPERAND?             I001 07550820
         BNE   DLMERR                  NO, ERROR                   I001 07551220
         B     MOPRTN                  RETURN                      I001 07551620
SS3N     CLI   0(SP1),ILPARN           IS IT LEFT PAREN?           I001 07552020
         BNE   DLMERR                  NO, ERROR                   I001 07552420
         LA    SP1,L1C(SP1)             BUMP OPERAND POINTER       I001 07552820
         BAL   SRR,B2B                 PROCESS B2 FIELD            I001 07553220
         LA    SP1,L1C(SP1)             BUMP OPERAND POINTER       I001 07553620
         CLI   0(SP1),ICOMMA           IS IT COMMA?                I001 07554020
         BNE   DLMERR                                              I001 07554420
         B     SS33RD                                              I001 07554820
SS3ERR   BAL   SRR,ERRZRO              FATAL ERROR - ZERO INSTR    I001 07555220
         DC    AL2(ERRLOC)             RELOCATABILITY ERROR        I001 07555620
         B     MOPRTN                                              I001 07556020
I3ERR    BAL   SRR,ERRNO0              NOT TOO BAD-                I001 07556420
         DC    AL2(ERRIMM)               MAYBE HE WANTED IT        I001 07556820
         B     SS3EXIT                                             I001 07557220
*******************************************************************I001 07557620
*                                                                A27017 07560919
*        SUBROUTINE WICH CHECKS IF ANY DISPLACEMENT OR           A27017 07561819
*        ADDRESSABILITY ERROR HAS OCCURED                        A27017 07562719
*                                                                A27017 07563619
DISPCHEK ST    SRR,SAVESRR              SAVE RETURN ADDR         A27017 07564519
         ST    SP1,COLMNPTR             SAVE CURRENT COL PTR     A27017 07565419
         L     SP1,ERRORPTR             GET POINTER TO ERR COL   A27017 07566319
         TM    DISPERR,X'0F'            CHECK FOR ADDR ERR       A27017 07567219
         BZ    DISPA                    BRANCH NOT FOUND         A27017 07568119
         BAL   SRR,ERRZRO               GO TO LOG ADDR ERR       A27017 07569019
         DC    AL2(ERRADR)              ADDRESSABILITY ERROR     A27017 07569919
         B     DISPOUT                  GO TO SCAN 2ND OPRND     A27017 07570819
DISPA    TM    DISPERR,X'F0'            CHECK FOR DISPL ERR      A27017 07571719
         BZ    DISPOUT                  BRANCH NOT FOUND         A27017 07572619
         BAL   SRR,ERRZRO               GO TO LOG DISPL ERR      A27017 07573519
         DC    AL2(ERRDIS)              DISPLACEMENT ERROR       A27017 07574419
DISPOUT  L     SP1,COLMNPTR             RESTORE CURRENT COL PTR  A27017 07575319
         NI    DISPERR,X'00'            SET ERROR FLAGS OFF      A27017 07576219
         L     SRR,SAVESRR              GET RETURN ADDR          A27017 07577119
         BR    SRR                      RETURN TO CALLER         A27017 07578019
*                                                                A27017 07578919
R1PROC   ST    SRR,RRHOLD               R1 PROCESSOR ENTRY, STORE EXIT  07580000
         BAL   SRR,F8ARGX               REGISTER EXPRESSION EVALUATION  07600000
         TM    AEXP1,X'03'              REGISTER REQUIREMENTS AND SIZE  07620000
         BZ    R1PR1                    IF 0, OK                        07640000
         BAL   SRR,REGERR               REGISTER ERROR ROUTINE          07660000
R1PR1    MVO   F8INST+4(1,ACT),VALUEB+3(1) PUT R1 INTO INSTRUCTION      07680000
         CLI   0(SP1),ICOMMA            IS ENDING DELIMETER COMMA       07700000
         L     SRR,RRHOLD               LOAD EXIT                       07720000
         BR    SRR                      EXIT TO CALLER                  07740000
R2PROC   ST    SRR,RRHOLD               R2 PROCESSOR ENTRY,STORE EXIT   07760000
         CLI   TXHEX(GRA),X'25'         CHECK LRDR OP             IEUN4 07765018
         BNE   R2CHEK                   NO                        IEUN4 07770018
         NI    TXASC(GRA),X'BF'         YES, MAKE R2 0-4 REQMENT  IEUN4 07775018
R2CHEK   CLI   TXHEX(GRA),X'27'         CHECK MXDR OP             IEUN4 07780018
         BNE   R2VAL                    NO                        IEUN4 07785018
         OI    TXASC(GRA),X'40'         YES, MAKE R2 EVEN REQMENT IEUN4 07790018
R2VAL    BAL   SRR,F8ARGX               REGISTER EXPRESSION EVAL  IEUN4 07795018
         TM    AEXP1,X'03'              REGISTER & SIZE REQUIREMENT     07800000
         BZ    R2PR1                    IF 0, OK                        07820000
         BAL   SRR,REGERR               REGISTER ERROR ROUTINE          07840000
R2PR1    OC    F8INST+4(1,ACT),VALUEB+3 R2 (OR R3) TO INSTRUCTION       07860000
         CLI   0(SP1),ICOMMA            IS ENDING DELIMETER COMMA       07880000
         L     SRR,RRHOLD               LOAD EXIT                       07900000
         BR    SRR                      EXIT TO CALLER                  07920000
R3PROC   ST    SRR,RRHOLD               R2 PROCESSOR ENTRY, STORE EXIT  07940000
         BAL   SRR,F8ARGX               REGISTER EXPRESSION EVALUATION  07960000
         TM    AEXP1,X'03'              REG REQUIREMENT AND SIZE S99246 07980021
         BZ    R2PR1                    IF 0, OK                        08000000
         BAL   SRR,REGERR               REGISTER ERROR ROUTINE          08020000
         B     R2PR1                    FINISH SCAN ETC                 08040000
IPROC    ST    SRR,RRHOLD               I PROCESSOR ENTRY, STORE EXIT   08060000
         BAL   SRR,F8AREX               EVALUATE IMMEDIATE EXPRESSION   08080000
         TM    AEXP2,MKR                TEST THAT I FIELD LE 255   I001 08100020
         BNZ   IMMERR                                             21016 08120021
         CLI   TXHEX(GRA),MCOP          IS OPCODE MC              21016 08130021
         BNE   IPR1                                               21016 08132021
         TM    AEXP1,MKR                OK IF LE 15               21016 08134021
         BZ    IPR1                                               21016 08136021
IMMERR   BAL   SRR,ERRZRO               IMMEDIATE ERROR                 08140000
         DC    AL2(ERRIMM)              IMMEDIATE FIELD ERROR           08160000
IPR1     MVC   F8INST+4(1,ACT),VALUEB+3 IMMEDIATE VALUE TO INSTRUCTION  08180000
         CLI   0(SP1),IBLANK            IS BLANK TERMINATING DELIMETER  08200000
         BE    MOPRTN                   IF YES, OK EXIT TO MLC          08220000
         B     DLMERR                   IF NOT, DELIMETER ERROR         08240000
X2PROC   ST    SRR,RRHOLD               X2 PROCESSOR ENTRY              08260000
         BAL   SRR,F8AREX               EVALUATE INDEX EXPRESSION       08280000
         TM    AEXP1,X'01'              IS SIZE OK                      08300000
         BZ    X2PR1                    YES                             08320000
         BAL   SRR,REGERR               NO, LOG REGISTER ERROR          08340000
X2PR1    TM    VALUEB+3,X'FF'           TEST IF DEFINED REGISTER 190000 08348019
         BZ    X2PR1A                   IS NON ZERO              190000 08356019
         NI    ALIGNERR,X'FE'           YES DON' GIVE ALIGN ERR. 190000 08364019
X2PR1A   OC    F8INST+4(1,ACT),VALUEB+3 INDEX VALUE TO INSTR.    190000 08372019
         CLI   0(SP1),ICOMMA            IS ENDING DELIMETER COMMA       08380000
         L     SRR,RRHOLD               LOAD EXIT                       08400000
         BR    SRR                      EXIT TO CALLER                  08420000
L1PROC   ST    SRR,RRHOLD               TEMP STORE EXIT                 08440000
         BAL   SRR,F8AREX               EVALUATE L1                     08460000
         TM    AEXP2,X'01'              IS THIS ABSOLUTE EXPRESSION & + 08480000
         BO    LLNERR                   IF 1, LENGTH ERROR              08500000
         L     GRY,VALUEB               EXPRESSION VALUE TO GRY         08520000
         S     GRY,K17                  TEST AGAINST LIMIT OF 16        08540000
L1L2L    BC    11,LLNERR                BRANCH ON ALL BUT NEGATIVE      08560000
         L     GRY,VALUEB               EXPRESSION VALUE TO GRY         08580000
         LTR   GRY,GRY                  TEST FOR ZERO                   08600000
         BZ    L1PR1                    IF ZERO, OK                     08620000
         BCTR  GRY,0                    IF NOT 0, DECREMENT BY 1        08640000
         ST    GRY,VALUEB               PUT BACK IN VALUE B             08660000
L1PR1    L     SRR,RRHOLD               LOAD EXIT                       08680000
         CLI   0(SP1),ICOMMA            IS EXPRESSION DELIMETER COMMA   08700000
         BR    SRR                      EXIT TO CALLER                  08720000
L2PROC   EQU   L1PROC                   L2 PROCESSOR SAME AS L1         08740000
LPROC    ST    SRR,RRHOLD               L PROCESSOR, TEMP STORE EXIT    08760000
         BAL   SRR,F8AREX               EVALUATE L EXPRESSION           08780000
         TM    AEXP3,X'01'              IS THIS ABSOLUTE EXPRESSION & + 08800000
         BO    LLNERR                   IF 1, LENGTH ERROR              08820000
         L     GRY,VALUEB               EXPRESSION VALUE TO GRY         08840000
         S     GRY,K257                 TEST FOR LIMIT OF 256           08860000
         B     L1L2L                    BRANCH TO COMMON PART LENGTH    08880000
S2D2A    ST    SRR,RRHOLD               S1 OR S2 OR D1 OR D2 ENTRY      08900000
         BAL   SRR,F8AREX               EVALUATE S OR D EXPRESSION      08920000
         TM    SREXP,X'01'              IS IT SIMPLY RELOCATABLE        08940000
         BO    S2D2AA                   IF ONE, TRY ABSOLUTE BRANCH     08960000
         BAL   SRR,DECOMP               YES, SIMPLY RELOCATABLE         08980000
         XC    ABSLUT(4),ABSLUT         ZERO ABSOLUTE DISPLACEMET       09000000
         MVI   ABSFLG,X'00'            TURN ABSOLUTE FLAG OFF           09020000
         MVC   F8INST+12(3,ACT),VALUEB+1 SET ABSOLUTE OPERAND 2         09040000
         MVC   F8INST+5(2,ACT),BSTVAL+2  SET BASE AND DISPLACEMENT 2    09060000
         TM    SREXP,X'2D'              ANY ERROR TRAIL LEFT            09080000
         BZ    S2D2XT                   IF 0, NO                        09100000
         BAL   SRR,S2ERR                IF YES, HUNT DOWN ERROR         09120000
S2D2XT   CLI   0(SP1),IBLANK            IS EXPRESSION DELIMETER BLANK   09140000
         ST    SP1,ERRORPTR             SAVE POSSIBLE ERR PTR    A27017 09150019
         L     SRR,RRHOLD               LOAD EXIT                       09160000
         BR    SRR                      EXIT TO CALLER                  09180000
S2D2AA   TM    AEXP3,X'01'               IS THIS ABSOLUTE               09200000
         BO    SSERRTST                HANDLE ERROR                     09220000
         BAL   SRR,DECOMP              DECOMPOSE EXPRESSION VALUE       09240000
         MVC   ABSLUTSV(4),VALUEB       SAVE ABS VALUE            17168 09250016
         MVC   ABSLUT(4),VALUEB         ABSOLUTE VALUE TO SAVED LOCAT   09260000
         MVI   ABSFLG,X'FF'            TURN ABSOLUTE FLAG ON            09280000
         MVC   F8INST+12(3,ACT),VALUEB+1 SET ABSOLUTE OPERAND 2         09300000
         MVC   F8INST+5(2,ACT),BSTVAL+2  SET B2 AND D2 IN INSTRUCTION   09320000
         TM    AEXP3,X'2D'              ANY ERROR TRAIL LEFT            09340000
         BZ    S2D2XT                   NO, SKIP TO COMMON ROUTINE      09360000
         BAL   SRR,D2ERR                YES, HUNT DOWN ERROR            09380000
         B     S2D2XT                   BRANCH TO COMMON ROUTINE        09400000
S1D1     ST    SRR,RRHOLD               TEMP STORE RETURN               09420000
         BAL   SRR,F8AREX               EVALUATE S1 OR D1               09440000
         TM    SREXP,X'01'              IS IT SIMPLY RELOCATABLE        09460000
         BO    S1D1AB                   NO                              09480000
         BAL   SRR,DECOMP               DECOMPOSE EXPRESSION VALUE      09500000
         XC    ABSLUT(4),ABSLUT         ZERO ABSOLUTE DISPLACEMET       09520000
         MVI   ABSFLG,X'00'            TURN ABSOLUTE FLAG OFF           09540000
         MVC   F8INST+9(3,ACT),VALUEB+1 SET ABSOLUTE OPERAND 1          09560000
         MVC   F8INST+5(2,ACT),BSTVAL+2 SET B1 AND D1 IN INSTRUCTION    09580000
         TM    SREXP,X'55'              ANY ERROR TRAIL LEFT            09600000
         BZ    S2D2XT                   NO, SKIP TO COMMON ROUTINE      09620000
         BAL   SRR,S1ERR                YES, HUNT DOWN ERROR            09640000
         B     S2D2XT                   BRANCH TO COMMON ROUTINE        09660000
S1D1AB   TM    AEXP3,X'01'               IS THIS ABSOLUTE               09680000
         BO    SSERRTST                HANDLE ERROR                     09700000
         BAL   SRR,DECOMP              DECOMPOSE EXPRESSION VALUE       09720000
         MVC   ABSLUTSV(4),VALUEB       SAVE ABS VALUE            17168 09730016
         MVC   ABSLUT(4),VALUEB         ABSOLUTE VALUE TO SAVED LOCAT   09740000
         MVI   ABSFLG,X'FF'             ASSLLUTE FLAG                   09760000
         MVC   F8INST+9(3,ACT),VALUEB+1 SET ABSOLUTE OPERAND 1          09780000
         MVC   F8INST+5(2,ACT),BSTVAL+2 SET B1 AND D1 IN INSTRUCTION    09800000
         TM    AEXP3,X'55'              ANY ERROR TRAIL LEFT            09820000
         BZ    S2D2XT                   IF NONE, COMMON EXIT            09840000
SSERRTST BAL   SRR,D1ERR               IF ERROR, HUNT IT DOWN           09860000
         B     S2D2XT                   BRANCH TO COMMON EXIT           09880000
S2D2B    ST    SRR,RRHOLD               TEMP STORE EXIT                 09900000
         BAL   SRR,F8AREX               EVALUATE S2 OR D2               09920000
         TM    SREXP,X'01'              IS THIS EXPRESSION SIMPLY RELOC 09940000
         BO    S2D2AB                   NO, TRY ABSOLUTE                09960000
         BAL   SRR,DECOMP               DECOMPOSE EXPRESSION VALUE      09980000
         XC    ABSLUT(4),ABSLUT         ZERO ABSOLUTE DISPLACEMET       10000000
         MVI   ABSFLG,X'00'             ABSOLUTE FLAG                   10020000
         MVC   F8INST+12(3,ACT),VALUEB+1 SET ABSOLUTE OPERAND 2         10040000
         MVC   F8INST+7(2,ACT),BSTVAL+2 SET B2 AND D2 IN INSTRUCTION    10060000
         TM    SREXP,X'2D'              ANY ERROR TRAIL LEFT            10080000
         BZ    S2D2XT                   NO, EXIT TO COMMON EXIT         10100000
         BAL   SRR,S2ERR                YES, HUNT ERROR                 10120000
         B     S2D2XT                   EXIT TO COMMON EXIT             10140000
S2D2AB   TM    AEXP3,X'01'               IS THIS ABSOLUTE               10160000
         BO    SSERRTST                 IF NOT ABSOLUTE HANDLE ERROR    10180000
         BAL   SRR,DECOMP               DECOMPOSE EXPRESSION VALUE      10200000
         MVC   ABSLUTSV(4),VALUEB       SAVE ABS VALUE            17168 10210016
         MVC   ABSLUT(4),VALUEB         ABSOLUTE VALUE TO SAVED LOCAT   10220000
         MVI   ABSFLG,X'FF'             ABSOLUTE FLAG                   10240000
         MVC   F8INST+12(3,ACT),VALUEB+1 SET ABSOLUTE OPERAND 2         10260000
         MVC   F8INST+7(2,ACT),BSTVAL+2 SET B2 AND D2 IN INSTRUCTION    10280000
         TM    AEXP3,X'2D'              ANY ERROR TRAIL LEFT            10300000
         BZ    S2D2XT                   NO, GO TO COMMON EXIT           10320000
         BAL   SRR,D2ERR                YES, HUNT ERROR                 10340000
         B     S2D2XT                   NOW GO TO COMMON EXIT           10360000
B1       ST    SRR,RRHOLD               SAVE RETURN                     10380000
         BAL   SRR,F8AREX               EVALUATE EXPRESSION             10400000
B1ERR    BAL   SRR,BXTEST               SEE IF LEGAL BASE               10420000
         CLC   ABSLUTSV(4),K4095        IS ABS VALUE GT 4095      17168 10423016
         BNH   NODISPER                 BR IF NOT                       10426016
         TM    ERRSW,X'FF'              EXPRESSION EVALUATION ERR  IEUJ 10427000
         BO    NODISPER                 IF YES, PLOD ON            IEUJ 10428000
         OI    DISPERR,X'F0'            POST DISPLACEMENT ERR    A27017 10431019
NODISPER MVC   F8INST+5(2,ACT),ABSLUTSV+2 FETCH ABS VALUE         17168 10435016
B1A      MVO   F8INST+5(1,ACT),VALUEB+3(1) B1 VALUE TO INSTRUCTION      10440000
BXIT     L     SRR,RRHOLD               RESTORE RETURN ADDRESS          10460000
         CLI   0(SP1),IRPARN            IS NEXT CHAR A RIGHT PARN       10480000
         BNE   DLMERR                   NO, ERROR                       10500000
         BR    SRR                      YES, EXIT                       10520000
B2A      EQU   B1                       B2A AND B1 ARE DONE THE SAME    10540000
B2B      ST    SRR,RRHOLD               SAVE EXIT ADDRESS               10560000
         BAL   SRR,F8AREX               EVALUATE EXPRESSION             10580000
B2B1     BAL   SRR,BXTEST               SEE IF LEGAL BASE               10600000
         CLC   ABSLUTSV(4),K4095        IS ABS VALUE GT 4095      17168 10603016
         BNH   NODISERR                 BR IF NOT                 17168 10606016
         TM    ERRSW,X'FF'              EXPRESSION EVALUATION ERR  IEUJ 10607000
         BO    NODISERR                 IF YES, PLOD ON            IEUJ 10608000
         OI    DISPERR,X'F0'            POST DISPLACEMENT ERR    A27017 10611019
NODISERR MVC   F8INST+7(2,ACT),ABSLUTSV+2 FETCH ABS VALUE         17168 10615016
         MVO   F8INST+7(1,ACT),VALUEB+3(1)   MOVE IN VALUE              10620000
         B     BXIT                     EXIT                            10640000
*********************************************************************** 10660000
***   F8AREX   ***                                                      10680000
*ABSOLUTE AND SIMPLY RELOCATABLE EXPRESSION EVALUATOR AND CHECK         10700000
* THIS ROUTINE CALLS ON THE EXPRESSION EVALUATION SUBROUTINE (EEVAL)    10720000
* TO ACTUALLY EVALUATE THE EXPRESSION.  ONCE THE EXPRESSION IS          10740000
* EVALUATED, CHECKS ARE MADE FOR CERTAIN POTENTIAL ERRORS.  IF A        10760000
* POTENTIAL ERROR EXISTS, THAT BIT OF A TEST FLAG REMAINS ONE. IF       10780000
* A POTENTIAL ERROR IS ELIMINATED, THAT BIT OF A GIVEN TEST FLAG IS     10800000
* SET TO ZERO.                                                          10820000
* TEST FLAGS ARE AS FOLLOWS.                                            10840000
*  AEXP1 REPRESENTS ABSOLUTE EXPRESSION OF VALUE LESS THAN   16         10860000
*  AEXP2 REPRESENTS ABSOLUTE EXPRESSION OF VALUE LESS THAN  256         10880000
*  AEXP3 REPRESENTS ABSOLUTE EXPRESSION OF VALUE LESS THAN 4096         10900000
*  SREXP REPRESENTS SIMPLY RELOCATABLE EXPRESSION                       10920000
* BITS WITHIN FLAGS ARE AS FOLLOWS.                                     10940000
*  BIT7 = 0, VALID VALUE                                                10960000
*  BIT6 = 0, REGISTER REQUIREMENT MET                                   10980000
*  BIT5 = 0, ALIGNMENT CORRECT                                          11000000
*  BIT4 = 0, LITERAL IN SECOND OPERAND REQUIREMENT OK                   11020000
*  BIT3 = 0, LITERAL IN FIRST OPERAND REQUIREMENT OK                    11040000
*  BIT2      SPARE LATER TO BE USED FOR REENTRANT CHECK                 11060000
*  BIT1      SPARE                                                      11080000
*  BIT0      SPARE                                                      11100000
*********************************************************************** 11120000
F8AREX   MVI   EXFLGS,X'7F'             BIT 1 = 0, DONT CHECK REG       11140000
         B     F8RREX                   CHECK REGISTER VALIDITY         11160000
F8ARGX   MVI   EXFLGS,X'FF'             BIT 1 SET TO 1                  11180000
F8RREX   MVC   EXFLGS+1(3),EXFLGS       INITIALIZE ABS AND RELOC FLAGS  11200000
         MVI   CREXPC,X'FF'        INITIALIZE COMPLEX OFF               11220000
         MVI   LTVLSW,X'00'             INITIALIZE LITERAL SWITCH       11240000
         XC    VALUEB(6),VALUEB         ZERO VALUE AND SIGN AND ESD-ID  11260000
         ST    SRR,HLDSRR               SAVE EXIT                       11280000
         CLI   0(SP1),IEQUAL            CHECK FOR LITERAL               11300000
         BE    LTVL                     DO LITERAL EVALUATION           11320000
         SR    SP2,SP2                                                  11340000
         L     SRB,CEEVAL(ACT)          EEVAL TABLE ADDRESS             11360000
         BALR  SRR,SRB                  DO EXPRESSION EVALUATION        11380000
LTVLXT   BC    8,AEXP                   IF ZERO, ABSOLUTE VALUE         11400000
         BC    4,JSREXP                 IF 1, SIMPLY RELOCATABLE EXPR   11420000
         BC    2,CREXP                  IF 2, COMPLEXLY RELOC EXPR      11440000
         BC    1,EREVAL                 IF 3, EXPRESSION ERROR          11460000
AEXP     LTR   GRY,SP2                  CURRENT EXP VALUE TEST NEGATIVE 11480000
         ST    GRY,VALUEB               EXPRESSION VALUE TO VALUEB      11500000
         TM    VALUEB,X'FF'             TEST FOR WRAP AROUND            11520000
         BM    EXWRAP                   IF MIXED, WRAP AROUND OCCURRED  11540000
         MVI   VALUEB,X'00'             ZERO FIRST BYTE OF VALUE        11560000
         SL    GRY,K16                  IF LESS THAN +16, OK            11580000
         BM    SEXP1                                                    11600000
         L     GRY,VALUEB               EXPRESSION VALUE TO GRY         11620000
         SL    GRY,K256                 IS VALUE LESS THAN +256         11640000
         BM    SEXP2                                                    11660000
         B     SEXP3                    ABSOLUTE EXPRESSION             11680000
EXWRAP   BAL   SRR,ERRZRO               ZERO INSTRUCTION AND LOG ERROR  11700000
         DC    AL2(ERRWRP)              WRAP AROUND ERROR CODE          11720000
         XC    VALUEB(4),VALUEB         ZERO VALUE                      11740000
         B     SEXP3                    SET ABSOLUTE                    11760000
JSREXP   NI    SREXP,X'FE'              SHUT OFF SIMPLY RELOC BIT       11780000
         MVC   VALUEB(6),0(SP2)         EXPRESSION VALUE, SIGN & ESD-ID 11800000
         B     PASSRE                   BRANCH PAST ABSOLUTE SETTINGS   11820000
SEXP1    NI    AEXP1,X'FE'              15 OK                           11840000
SEXP2    NI    AEXP2,X'FE'              255 OK                          11860000
SEXP3    NI    AEXP3,X'9E'              VALUE AND REENTRANT BITS OFF    11880000
         NI    SREXP,X'9F'              REENTRANT BITS OFF              11900000
PASSRE   LA    GRA,F8WORK(ACT)          ADDRESS OF FIRST BYTE OF TEXT   11920000
         TM    AEXP1,X'80'              IF BIT 1 IS ZERO,               11940000
         BZ    NONREG                   NO REGISTER TEST REQUIRED       11960000
         TM    TXASC(GRA),X'80'         TEST ASSEMBLER SWITCH CODE      11980000
         BZ    NOTFLT                   IF ZERO, NOT FLOATING POINT     12000000
         TM    TXASC(GRA),X'40'         TEST ASSEMBLER SWITCH CODE      12020000
         BO    TS0246                   IF ZERO, ONLY 0 OR 4 ALLOWED    12040000
         TM    VALUEB+3,X'FB'           TEST VALUE FOR OTHER THAN 4     12060000
         BZ    SET106                   IF ZERO, VALUE IS 0 OR 4        12080000
         B     DNTSET                   IF NOT, DONT SET                12100000
TS0246   L     GRZ,VALUEB               CURRENT EXPRESSION VALUE        12120000
         LTR   GRY,GRZ                  CHECK IF 0                      12140000
         BZ    SET106                   IF 0, OK EXIT                   12160000
         S     GRY,KTWO                 CHECK IF 2                      12180000
         BZ    SET106                   IF 2, OK EXIT                   12200000
         S     GRY,KTWO                 CHECK IF 4                      12220000
         BZ    SET106                   IF 4, OK EXIT                   12240000
         S     GRY,KTWO                 CHECK IF 6                      12260000
         BZ    SET106                   IF 6, OK EXIT                   12280000
         B     DNTSET                   IF NONE OF THESE, DONT SET      12300000
NOTFLT   TM    TXASC(GRA),X'40'        CHECK IF EVEN REGISTER NEEDED    12320000
         BZ    SET106                   IF ZERO, EVEN NOT NECESSARY     12340000
         MVN   SAVEHEX,TXHEX(GRA)       IS IT MVCL                 I001 12350021
         TM    SAVEHEX,MKS               OR CLCL                   I001 12360021
         BO    DNTNI                   IF SO DON'T CHANGE ASC      I001 12370020
         NI    TXASC(GRA),MKT           EVEN REG ONLY IN 1ST OPND  I001 12380020
DNTNI    TM    VALUEB+3,MKU             CHECK IF EXPN VALUE EVEN   I001 12390020
         BO    DNTSET                   IF 1, VALUE IS NOT EVEN         12400000
SET106   NI    AEXP1,X'FD'              SET REGISTER CHECK OK           12420000
DNTSET   L     SRR,HLDSRR               LOAD EXIT ADDRESS               12440000
         BR    SRR                      EXIT                            12460000
NONREG   TM    TXASC(GRA),X'30'        TEST FOR ALIGNMENT NECESSARY     12480000
         BZ    WORDAL                   IF 0, ALIGNMENT UNNECESSARY     12500000
         BO    DWALIN                   BOTH 1, DOUBLE WORD ALIGNMENT   12520000
         TM    TXASC(GRA),X'20'        IF 1, WORD ALIGNMENT NECESSARY   12540000
         BZ    HWALIN                   IF 0, HALF WORD ALIGNMENT NEEDD 12560000
FWALIN   TM    VALUEB+3,X'03'           TEST LOW TWO BITS OF VALUE      12580000
         BZ    WORDAL                   IF ZERO, WORD ALIGNED           12600000
         B     LITTST                   IF NOT ALIGNED, ERROR           12620000
DWALIN   TM    VALUEB+3,X'07'           TEST LOW THREE BITS OF VALUE    12640000
         BZ    WORDAL                   IF ZERO, DOUBLE WORD ALIGNED    12660000
         B     LITTST                   IF NOT ALIGNED, ERROR           12680000
HWALIN   TM    VALUEB+3,X'01'           TEST LOW BIT OF VALUE           12700000
         BZ    WORDAL                   IF ZERO, HALF WORD ALIGNED      12720000
         B     LITTST                   IF NOT ALIGNED, ERROR           12740000
WORDAL   NI    SREXP,X'FB'              ALIGNMENT OK                    12760000
         NI    AEXP3,X'FB'              ALIGNMENT OK                    12780000
LITTST   TM    TXASC(GRA),X'02'        IS LITERAL OK IN 2ND OPND        12800000
         BZ    SAX04                    IF ZERO, LITERAL NOT PERMITTED  12820000
SAX00    NI    SREXP,X'D7'              REENTRANT AND LITERAL OK 2ND    12840000
         NI    AEXP3,X'D7'              REENTRANT AND LITERAL OK 2ND    12860000
SAX01    TM    TXASC(GRA),X'01'        IS LITERAL OK IN 1ST OPND        12880000
         BZ    SAX05                    IF ZERO, LITERAL NOT PERMITTED  12900000
SAX02    NI    SREXP,X'AF'              REENTRANT AND LITERAL OK 1ST    12920000
         NI    AEXP3,X'AF'              REENTRANT AND LITERAL OK 1ST    12940000
         B     DNTSET                   EXIT                            12960000
SAX04    TM    CTCGOI(ACT),X'20'        IS REENTRANT CHECK NEEDED       12980000
         BZ    SAX040                   IF ZERO, NO                     13000000
         CLC   CTNDID+1(1,ACT),VALUEB+5 NEXT DSECT ESD-ID VS THIS ESD   13020000
         BNL   SAX04A                   IF NOT LOWER, CSECT OR COMMON   13040000
SAX040   NI    AEXP3,X'9F'              IF HI, REENTRANT                13060000
         NI    SREXP,X'9F'              IF HI REENTRANT                 13080000
SAX04A   TM    LTVLSW,X'FF'             IS THIS A LITERAL               13100000
         BNE   SAX04B                   IF NOT 0, LITERAL SKIP SETTING  13120000
         NI    SREXP,X'F7'              IF 0, NO LITERAL, TURN OFF ERR  13140000
SAX04B   B     SAX01                    CHECK FOR 1ST OPERAND           13160000
SAX05    TM    CTCGOI(ACT),X'20'        IS REENTRANT CHECK REQUIRED     13180000
         BZ    SAX050                   IF ZERO, NO                     13200000
         CLC   CTNDID+1(1,ACT),VALUEB+5 NEXT DSECT ESD-ID VS THIS ESD-I 13220000
         BNL   SAX05A                  IF NOT LOWER, CSECT OR COOMMON   13240000
SAX050   NI    AEXP3,X'9F'              IF HIGH, REENTRANT              13260000
         NI    SREXP,X'9F'              IF HI, REENTRANT                13280000
SAX05A   TM    LTVLSW,X'FF'             IS THIS A LITERAL               13300000
         BNE   SAX05B                   YES, SKIP SETTING               13320000
         NI    SREXP,X'EF'              NO, TURN ERROR BIT OFF          13340000
SAX05B   B     DNTSET                   EXIT                            13360000
CREXP    SR    GRZ,GRZ                  SET THE                         13380000
         ST    GRZ,VALUEB               VALUE ZERO                      13400000
         ST    GRZ,CREXPC               AND SET COMPLEX ON              13420000
         MVI   AEXP1,1                  JUST RELOCATABILITY ERROR       13440000
         MVI   AEXP2,1                  JUST RELOCATABILITY ERROR       13460000
         MVI   AEXP3,1                  JUST RELOCATABILITY ERROR       13480000
         MVI   SREXP,1                  JUST RELOCATABILITY ERROR       13500000
         B     DNTSET                                                   13520000
         SPACE 1                                                   I001 13525020
SAVEHEX  DC    X'0'                    USED AT NOTFLT              I001 13530020
         SPACE 1                                                   I001 13535020
*********************************************************************** 13540000
***   DCCOMP   ***                                                      13560000
* THIS IS THE ENTRY TO DECOMP ROUTINE WHEN ENTERED FROM OTHER CONTROL   13580000
* SECTIONS                                                              13600000
*********************************************************************** 13620000
DCCOMP   STM   SRB,SRR,F8REGS           STUFF RETURN AND RETURN BASE    13640000
         STC   SP1,AEXP3                STORE ABSOLUTE, RELOCATABLE FLG 13660000
         LR    SP1,GRY                                                  13680000
         TM    AEXP3,X'01'              TEST IT                         13700000
         BNE   DCCM01                   IF ONE RELOCATABLE              13720000
         ST    SP2,VALUEE               PUT ABSOLUTE VALUE              13740000
         LA    SP2,VALUEE               PICK UP ITS ADDRESS             13760000
DCCM01   MVC   VALUEB(6),0(SP2)         EXPRESSION VALUE, SIGN & ESD-ID 13780000
         BAL   SRR,DECOMP               GO TO DECOMPOSE ROUTINE         13800000
         L     SP2,BSTVAL               DECOMPOSED VALUE TO SP2         13820000
         LM    SRB,SRR,F8REGS           RESTORE RETURN AND RETURN BASE  13840000
         BR    SRR                      RETURN TO EXTERNAL PROGRAM      13860000
*********************************************************************** 13880000
***   DECOMP   ***                                                      13900000
* THIS ROUTINE DECOMPOSES BOTH ABSOLUTE AND RELOCATABLE VALUES WHENEVER 13920000
* POSSIBLE.  WHEN NOT POSSIBLE A RELOCATABILITY ERROR IS NOTED.         13940000
*********************************************************************** 13960000
DECOMP   SR    GRZ,GRZ                  ZERO REGISTER                   13980000
         MVI   DCMPSW,X'00'             SET NO REGISTER SWITCH          14000000
         MVC   TEMVAL(4),VALUEB        SAVE VALUE FOR FUTURE USE        14020000
         L     GRC,USNGPP(ACT)         USING TABLE FLAGS POINTER        14040000
         L     GR2,USNGTP(ACT)         USING TABLE POINTER              14060000
         STC   GRZ,BSTREG               ZERO BEST REGISTER              14080000
         TM    AEXP3,X'01'                                              14100000
         BZ    DCMP01                   IF ZERO, ESD-ID IS ZERO         14120000
         IC    GRZ,5(SP2)               IF NOT, FETCH ESD-ID            14140000
         STC   GRZ,VALUEB              ESD-ID TO FIRST BYTE             14160000
         MVC   VALUEE(4),VALUEB         VALUE AND ESD-ID                14180000
         MVC   BSTVAL(4),BYTES3         HIGHST POSSIBLE RELOC VAL       14200000
         B     DCMP0A                   BRANCH AROUND ABSOLUTE SETTING  14220000
DCMP01   L     GRZ,VALUEB              ESD-ID AND VALUE                 14240000
         ST    GRZ,VALUEE                                               14260000
         LR    GRY,GRZ                 ESDID AND VALUE                  14280000
         N     GRY,BYTES3               DROP LEADING BYTE               14300000
         ST    GRY,BSTVAL               FOR INITIAL VALUE               14320000
DCMP0A   LA    GRA,16                   COUNTER                         14340000
         SR    GRB,GRB                  USINGP INDEX                    14360000
         SR    GR1,GR1                                                  14380000
DCMP02   SR    GRD,GRD                  ZERO REGISTER                   14400000
         L     GRC,USNGPP(ACT)          ADDR OF USNG TABLE POINTERS     14420000
         IC    GRD,0(GRB,GRC)           ONE OF 16 USING TABLE INDICATOR 14440000
         LTR   GRD,GRD                  IS THIS REGESTER BEING USED     14460000
         BZ    DCMP03                   IF ZERO, NOT USING              14480000
         IC    GRD,0(GR1,GR2)          INPUT USING ESD-ID               14500000
         SR    GR0,GR0                  ZERO REGISTER ZERO TO LOSE JUNK 14520000
         IC    GR0,VALUEB               ESD-ID THIS VALUE               14540000
         SR    GRD,GR0                  USING ESD VS THIS ESD           14560000
         BNE   DCMP03                  IF NOT EQUAL, SKIP IT            14580000
         L     GRZ,VALUEE                                               14600000
         L     GRC,LITWRK               WITHIN LITERAL POOL             14620000
         L     GR2,USNGTP(ACT)                                          14640000
         SL    GRZ,0(GR1,GR2)           VALUE & ESD-ID IN USING TABLE   14660000
         N     GRZ,BYTES3               DROP LEADING BYTE               14680000
         CL    GRZ,BSTVAL               SEE IF THIS IS THE BEST VALUE   14700000
         BH    DCMP03                   IF HI, NO GOOD                  14720000
         OI    DCMPSW,X'FF'             SET REGISTER POSSIBILITY        14740000
         ST    GRZ,BSTVAL               IF NOT, KEEP BEST VALUE         14760000
         STC   GRB,BSTREG               KEEP AS BEST REGISTER           14780000
DCMP03   BCT   GRA,DCMP06                                               14800000
         TM    DCMPSW,X'FF'             HAS A POSSIBLE REGISTER FOUND   14820000
         BZ    DCMP09                   CHECK FOR ABSOLUTE              14840000
DCMP04   L     GRZ,BSTVAL               TAKE BEST VALUE TO DATE         14860000
         SL    GRZ,FOR096               1 TOO BIG FOR DISPLACEMENT      14880000
         BM    DCMP05                   IF NEGATIVE GO TO ENDOFF        14900000
DCMPER   SR    GRZ,GRZ                  IF NOT, ERROR                   14920000
         ST    GRZ,BSTVAL               ZERO BEST VALUE                 14940000
         STC   GRZ,BSTREG               ZERO BEST REGISTER              14960000
         TM    CTSCON(ACT),X'08'       IS IT SCON-CALL TO DECOMP A39647 15010021
         BZ    DCMPER1                 NO                        A39647 15020021
         OI    CTSCON(ACT),X'04'       YES, INDICATE ADDR ERROR  A39647 15030021
         B     DCMP05                  FOR SCON ROUTINE          A39647 15040021
DCMPER1  OI    DISPERR,X'0F'           INDICATE ADDR ERR  A27017,A39647 15050021
DCMP05   IC    GRZ,BSTREG               REGISTER                        15060000
         SLL   GRZ,4                    POSITION FOR MERGE              15080000
         STC   GRZ,BSTREG                                               15100000
         OC    BSTVAL+2(1),BSTREG       COMBINE BASE AND REGISTER       15120000
         MVC   VALUEB(4),TEMVAL        RESTORE VALUE TO VALUEB          15140000
         BR    SRR                      ERROR EXIT FROM SUBROUTINE      15160000
DCMP06   LA    GRB,1(GRB)              NEXT USINGP                      15180000
         LA    GR1,4(GR1)               NEXT USING VALUE                15200000
         B     DCMP02                   DO NEXT                         15220000
DCMP09  TM    VALUEB,X'FF'             IS VALUE ABSOLUTE                15240000
         BNE   DCMPER                   IF NOT 0, DECOMP ERROR          15260000
         L     GRZ,BSTVAL               BEST VALUE TO REGISTER          15280000
         S     GRZ,FOR096               CHECK SIZE OF ABLOLUTE          15300000
         BM    DCMP05                   IF OK CONTINUE                  15320000
DESPER   SR    GRZ,GRZ                  DELPLACEMENT ERROR              15340000
         ST    GRZ,BSTVAL               ZERO BEST VALUE                 15360000
         STC   GRZ,BSTREG               ZERO BEST REGISTER              15380000
         OI    DISPERR,X'F0'            INDICATE DISPL ERR       A27017 15430019
         B     DCMP05                   FINISH OFF ROUTINE              15480000
*********************************************************************** 15500000
***************LITERAL EVALUATION ROUTINE****************************** 15520000
***** THIS ROUTINE MERELY SCANS FOR NEXT OPERAND.  LEAVING SP1 POINTING 15540000
******AT THE DELIMETER IF ANY.  IT DOES A SYNTACTICAL ERROR SCAN AND    15560000
******FETCHES THE VALUE OF THE LITERAL AND ITS LENGTH.***************** 15580000
*********************************************************************** 15600000
FAKE     B     2(SRR)                   SKIP AROUND LOG ERROR NUMBER    15620000
FAKEIT   DC    A(FAKE,FAKE)             CHANGED SO WE DONT LOG ERROR    15640000
LTVL     MVI   QUOTFLAG,X'00'           SET QUOTE FLAG EVEN             15660000
         TM    LITRLTWO,X'FF'           ANY PREVIOUS LITERAL THIS OPRND 15680000
         BNZ   LTVL13                   IF NOT 0, YES -- ERROR          15700000
         MVI   LITRLTWO,X'FF'           SET LITRL ENCOUNTERED SWITCH ON 15720000
         SR    GRB,GRB                  SET PAREN FLAG BALANCED         15740000
         L     GRC,F8OPRN(ACT)          ADDR OF OPRN                    15760000
         SR    GRD,GRD                  ZERO REGISTER                   15780000
         BCTR  GRC,0                    POINTER TO OPRN LENGTH          15800000
         IC    GRD,0(GRC)               INPUT PPRN LENGTH               15820000
         A     GRD,F8OPRN(ACT)          COMPUTE END OF OPRN             15840000
         LR    GRX,GRD                  TEMP SAVE                       15860000
LTVL01   SR    GRD,SP1                  IS POINTER AT END               15880000
         BM    LTVLERR                  IF NEGATIVE, YES, ERROR         15900000
         CLI   0(SP1),ILPARN            IS THIS CHAR A LEFT PAREN       15920000
         BE    LTVLP2                   IF YES, PROCESS THAT TYPE LITR  15940000
         CLI   0(SP1),IQUOTE            IS THIS CHAR A QUOTE            15960000
         BE    LTVLQ1                   IF COMMA, PROC THAT KIND LITR   15980000
         LA    SP1,1(SP1)               IF NOT POINT AT NEXT CHAR       16000000
         LR    GRD,GRX                  GET END OF OPERAND ADDRESS      16020000
         B     LTVL01                   TRY AGAIN                       16040000
LTVLP2   LA    SP1,1(SP1)               POINT AT CHAR AFTER LEFT PAREN  16060000
         MVC   FAKEIT,CLOGER(ACT)       CHANGE SO LOG ERROR DOESNT      16080000
         MVC   CLOGER(4,ACT),FAKEIT+4     LOG ERROR BUT JUST RETURNS    16100000
         L     SRB,CEEVAL(ACT)          ADDRESS OF EXPRESSION EVAL RTN  16120000
         BALR  SRR,SRB                  EVALUATE EXPRESSION             16140000
         MVC   CLOGER(4,ACT),FAKEIT     RESTORE LOG ERROR EXIT          16160000
         LTR   SP1,SP1                  HAS CATASTROPHIC ERROR OCCURRED 16180000
         BZ    CTRTRN(ACT)              IF ZERO ALL THRU                16200000
         CLI   0(SP1),ICOMMA            DID EXPRESSION END WITH COMMA   16220000
         BE    LTVLP2                   IF SO, DO AGAIN                 16240000
         CLI   0(SP1),IRPARN            DID EXPRESSION END WITH RT PARN 16260000
         BNE   DLMERR                   IF NOT, DELIMETER ERROR         16280000
LTVLCOMN LA    SP1,1(SP1)               COMMON EXIT, BUMP OPERAND PTR   16300000
         CLI   0(SP1),ICOMMA            IS LITERAL DELIMETER COMMA      16320000
         BE    LTVL10                   IF SO, OK TO EXIT               16340000
         CLI   0(SP1),IBLANK            IS LITERAL DELIMETER A BLANE    16360000
         BE    LTVL10                   IF SO, OK TO EXIT               16380000
         B     DLMERR                   IF NOT, DELIMETER ERROR         16400000
LTVLQ1   XI    QUOTFLAG,X'FF'           TURN ON QUOTFLAG                16420000
         B     LTVLQ5                   CHECK NEXT CHARACTER            16440000
LTVLQ2   CLI   1(SP1),IQUOTE            IS DOUBLE QUOTE PRESENT         16460000
         BE    LTVLQ3                   IF SO, UP OPRN POINTER          16480000
         XI    QUOTFLAG,X'FF'           FLIP ODD QUOTE FLAG             16500000
         B     LTVLQ4                   DONT SKIP OVER QUOTE            16520000
LTVLQ3   LA    SP1,1(SP1)               SKIP OVER QUOTE                 16540000
LTVLQ4   TM    QUOTFLAG,X'FF'           IS QUOTE STRING ENDED           16560000
         BZ    LTVLCOMN                 IF ZERO, ENDED                  16580000
LTVLQ5   LA    SP1,1(SP1)               IF NOT BUMP TO NEXT CHARACTER   16600000
         LR    GRD,GRX                  ADDRESS OF END OF OPERAND       16620000
         SR    GRD,SP1                  HAVE WE GONE TOOO FAR           16640000
         BM    LTVLERR                  IF NEGATIVE, YES                16660000
         CLI   0(SP1),IQUOTE            IF POSITIVE, IN NEXT CHAR QUOTE 16680000
         BE    LTVLQ2                   IF SO, CHECK FOR DOUBLES AGAIN  16700000
         B     LTVLQ5                   IF NOT, TRY NEXT CHARACTER      16720000
LTVLERR  SR    SP1,SP1                  ZERO OPERAND POINTER            16740000
         TM    *+1,X'FF'                SET CONDITION CODE FOR ERROR    16760000
         B     LTVLXT                   EXIT TO F8AREX                  16780000
LTVL10   L     GRB,CTXABP(ACT)          PTR TO APPEND FIXED FIELD       16800000
         TM    TXLASI(GRB),X'03'        IS LITERAL IN POOL       A45818 16810021
         BNZ   LTVL11                   YES CONTINUE             A67494 16820021
         L     GRC,CTEXTP(ACT)          NO GET ADDRESS TO TEXT   A67494 16830021
         TM    2(GRC),X'02'             IS EQUAL SIGN IND. ON    A67494 16834021
         BO    LTVLERR                  YES ERROR FOUND EALIER   A67494 16836021
LTVL11   MVC   LITWRK+1(3),TXLDSP(GRB)  GET LITERAL DISPLACEMENT        16840021
         L     GRC,LITWRK               WITHIN LITERAL POOL             16860000
         SR    GRD,GRD                                                  16880000
         IC    GRD,TXLSTG(GRB)          GET LITERAL STRING NO           16900000
         A     GRD,LATP(ACT)                                            16920000
         MVC   LITWRK+1(3),1(GRD)       GET ADJUSTMENT                  16940000
         MVC   LITID(1),0(GRD)          SET ESD                         16960000
         A     GRC,LITWRK               GET ADJUSTED ADDRESS            16980000
         ST    GRC,LITWRK               FOR MAIN LINE                   17000000
         LA    SP2,LITWRK               POINTER TO VALUE FOR MAIN LINE  17020000
         SR    GRC,GRC                                                  17080000
         IC    GRC,TXLLEN(GRB)          GET EENGTH ATTRIBUTE            17100000
         STH   GRC,STLONG(ACT)          SET LENGTH ATTRIBUTE FOR MLC    17120000
LTVL12   LCR   GRC,GRC                  SET CC=4 FOR MAIN LINE          17140000
         MVI   LTVLSW,X'FF'             SET LITERAL SWITCH FOR MLC      17160000
         B     JSREXP                   TAKE SIMPLY RELOCATABLE BRANCH  17180000
LTVL13   BAL   SRR,ERRZRO               LOG AN ERROR                    17240000
         DC    AL2(ERRLIT)              INVALID LITERAL USAGE           17260000
         B     LTVLERR                  EXIT                            17280000
LITWRK   DC    F'0'                     FULL WORD ALIGNED FOR           17300000
         DC    X'0'                        LITERAL WORK AREA            17320000
LITID    DC    X'0'                     LITERAL ESD/ID                  17340000
SETSEC   STC   SP2,WORDBB               CURRENT ESD-ID                  17360000
         CLC   WORDBB(1),0(SP1)         COMP. TO ADJ TABLE ENTRIES      17380000
         BE    SECFND                   FOUND, BRANCH OUT               17400000
         LA    SP1,4(SP1)               NOT FOUND, BUMP BY 4            17420000
         L     GRX,CTLATB(ACT)          END OF TABLE + 1                17440000
         CR    GRX,SP1                  IS TABLE EXHAUSTED              17460000
         BNH   SETSEC                   EXIT WHEN TABLE EXHAUSTED       17480000
         L     SP2,CTZERO(ACT)          ZERO CELL TO SHOW ERROR         17500000
         BR    SRR                      ERR O                           17520000
SECFND   L     SP2,BYTES3               0FFF FOR MASK                   17540000
         N     SP2,0(SP1)               EXTRACT CSECT ORG               17560000
         ST    SP2,F8CADJ(ACT)          STORE                           17580000
         MVC   F8INST(3,ACT),F8CADJ+1(ACT)                              17600000
         BR    SRR                      RETURN                          17620000
DLMERR   BAL   SRR,ERRZRO               LOG ERROR                       17640000
         DC    AL2(ERRDLM)             DELIMETER ERROR                  17660000
MOPRTN   BAL   SRR,DISPCHEK             CHECK DISP OR ADDR ERROR A27017 17665019
         TM    ALIGNERR,X'03'           TEST IF ANY ALIGN. ERR.  190000 17670019
         BNO   MOPRTA                   BRANCH IF NO             190000 17675019
         MVI   ALIGNERR,X'01'           RESET ALIGN SWITCH       190000 17680019
         BAL   SRR,ERRNO0               ALIGNMENT ERROR          190000 17685019
         DC    AL2(ERRLIN)              ALIGNMENT ERROR          190000 17690019
MOPRTA   TM    ERRSW,X'FF'              CHECK FOR ANY ERR FLAGG  190000 17695019
         BZ    DNTZRO                   IF ERRSW NOT ZERO, BYPASS       17700000
         XC    F8INST+3(12,ACT),F8INST+3(ACT) ZERO INST BLDG AREA       17720000
DNTZRO   B     CTRTRN(ACT)              RETURN TO MAIN LINE CONTROL     17740000
ERRZRO   MVI   ERRSW,X'FF'              SET SWITCH TO ZERO INSTRUCTION  17760000
ERRNO0   L     SRB,CLOGER(ACT)          LOGERR BASE AND ENTRY           17780000
         BR    SRB                      ENTER LOGERR                    17800000
PROCER   BAL   SRR,ERRZRO              PROCEDURE ERROR                  17820000
         DC    AL2(ERPROC)             PROCEDURE ERROR                  17840000
         B     MOPRTN                  MACHINE OP PROCESSOR EXIT        17860000
EREVAL   MVI   ERRSW,X'FF'              EXPRESSION EVALUATION ERROR     17880000
         SR    GR0,GR0                  ZERO A REGISTER                 17900000
         ST    GR0,EXFLGS               TURN OTHER ERRORS OFF           17920000
         LTR   SP1,SP1                  IS IT CATASTROPHIC              17940000
         BZ    MOPRTN                  IF ZERO,YES, ABORT               17960000
         B     DNTSET                   IF NO, CONTINUE                 17980000
REGERR   ST    SRR,HOLDER               REGISTER ERROR, STORE RETURN    18000000
         BAL   SRR,ERRZRO               LOG ERROR                       18020000
         DC    AL2(ERRREG)             REGISTER ERROR                   18040000
         L     SRR,HOLDER               RESTORE RETURN ADDRESS          18060000
         BR    SRR                      AND EXIT                        18080000
LLNERR   BAL   SRR,ERRZRO               LENGTH ERROR                    18100000
         DC    AL2(ERRLLN)             LENGTH ERROR                     18120000
         B     L1PR1                    EXIT                            18140000
S2ERR    ST    SRR,HOLDER               ERROR FLAGGED IN S2             18160000
S2LITR   TM    SREXP,X'08'              IS THERE A LITERAL IN 2ND OPERD 18180000
         BZ    S2RENT                   NO, OK                          18200000
         MVI   LITRLTWO,MKV             RST 'ONE LIT ALREADY' SW A28590 18210020
         BAL   SRR,ERRZRO               ERROR                           18220000
         DC    AL2(ERRLIT)             LITERAL ERROR                    18240000
S2RENT   TM    SREXP,X'20'              REENTRANT CHECK                 18260000
         BZ    SXRLOC                   OK, GO ON                       18280000
SXRENT   BAL   SRR,RNTRR                REENTRANT ERROR                 18300000
         DC    AL2(ERRENT)             REENTRANT ERROR                  18320000
SXRLOC   TM    SREXP,X'01'              RELOCATABILITY ERROR            18340000
         BZ    TERORL                   IF ZERO, RELOCATABILITY OK      18360000
         OI    DISPERR,X'F0'            INDICATE DISPL ERR       A27017 18390019
TERORL   TM    AEXP3,X'04'              IS ALIGNMENT OK                 18420000
         BZ    S2ERXT                   YES, GO ON                      18440000
         TM    CTPCHI(ACT),X'08'        CHECK ALGN FLAGGING       IEUN5 18441018
         BO    ERORL                    YES, GO LOG IT            IEUN5 18442018
         LA    SRR,ALBEG                GET ALIGN OP-TABLE START  IEUN5 18443018
         LA    GR1,ALEND-ALBEG          GET TABLE LENGTH          IEUN5 18444018
         LA    GRA,F8WORK(ACT)          RESTORE GRA              A28239 18444519
         IC    GR2,TXHEX(,GRA)          GET HEX OP-CODE           IEUN5 18445018
ALEX     EX    GR2,ALCOMP               DOES OP REQUIRE ALIGNMENT IEUN5 18446018
         BE    ERORL                    YES, GO LOG IT            IEUN5 18447018
         LA    SRR,1(,SRR)              STEP TO NEXT OP           IEUN5 18448018
         BCT   GR1,ALEX                 LOOP UNTIL TABLE SCANNED  IEUN5 18449018
         B     S2ERXT                   EXIT IF NO ALIGN REQUIRED IEUN5 18450018
ALCOMP   CLI   0(SRR),0                 DUMMY COMPARE             IEUN5 18451018
ERORL    MVI   ALIGNERR,X'03'           POSSIBLE ALIGNMENT ERROR 190000 18471019
S2ERXT   L     SRR,HOLDER               S2 ERROR EXIT                   18500000
         BR    SRR                      RETURN                          18520000
S1ERR    ST    SRR,HOLDER               ERROR FLAGGED IN S1             18540000
S1LITR   TM    SREXP,X'10'              IS A LITERAL IN 1ST OPERAND OK  18560000
         BZ    S1RENT                   YES, CONTINUE                   18580000
         MVI   LITRLTWO,MKV             RST 'ONE LIT ALREADY' SW A28590 18590020
         BAL   SRR,ERRZRO               LITERAL ERROR                   18600000
         DC    AL2(ERRLIT)             LITERAL ERROR                    18620000
S1RENT   TM    SREXP,X'40'              REENTRANT CHECK                 18640000
         BZ    SXRLOC                   OK                              18660000
         B     SXRENT                   LOG ERROR                       18680000
D2ERR    ST    SRR,HOLDER               DISPLACEMENT IN 2ND OPERAND CHK 18700000
D2RENT   TM    AEXP3,X'20'              REENTRANT CHECK                 18720000
DXRENT   BZ    D2RLOC                   OK                              18740000
         BAL   SRR,RNTRR                REENTRANT ERROR                 18760000
         DC    AL2(ERRENT)             REENTRANT ERROR                  18780000
D2RLOC   TM    AEXP3,X'01'              ABSOLUTE VALUE CHECK            18800000
         BZ    TERORL                   IF ZERO, ABSOLUTE VALUE OK      18820000
         OI    DISPERR,X'F0'            INDICATE DISPL ERR       A27017 18850019
         TM    CREXPC,X'FF'             IS THIS COMPLEXLY RELOCATABLE   18880000
         BNZ   TERORL                   IF NOT COMPLEXLY RELOC, NOT ERR 18900000
         BAL   SRR,ERRZRO               LOG THE ERROR                   18920000
         DC    AL2(ERRLOC)              RELOCATABILITY ERROR            18940000
         B     TERORL                   TRY NEXT ERROR TEST             18960000
D1ERR    ST    SRR,HOLDER               DISPLACEMENT IN 1ST OPERAND CHK 18980000
         TM    AEXP3,X'40'              REENTRANT CHECK                 19000000
         B     DXRENT                                                   19020000
BXTEST   ST    SRR,HOLDER               BASE TEST ... SAVE RETURN       19040000
         TM    AEXP1,X'01'              IS IT VALID VALUE .LT. 16       19060000
         BO    BXERR2                   IF NOT 0, ERROR                 19080000
         TM    DISPERR,X'0F'            CHECK IF ADDR ERR LOGGED A27017 19086019
         BO    BXEXIT                   YES EXIT                 A27017 19092019
         TM    VALUEB+3,X'FF'           TEST IF DEFINED REGISTER 190000 19097019
         BZ    GOON1                    IS NON ZERO              190000 19102019
         NI    ALIGNERR,X'FE'           YES DON'T GIVE ALIGN ERR 190000 19107019
GOON1    CLI   ABSFLG,X'FF'             IS IT ABSOLUTE           190000 19112019
         BNE   BXERR1                   IF NOT ABSOLUTE, ERROR          19120000
         L     SRR,ABSLUT               GET VALUE                       19140000
         S     SRR,K4096                SEE CC DEPENDING UPON SIZE      19160000
         BNM   BXERR1                   IF ZERO OR PLUS, LOG ERR A27017 19170019
         B     BXEXIT                   SCRAM                           19180000
BXERR1   OI    DISPERR,X'F0'            INDICATE DISPL ERR       A27017 19240019
         B     BXEXIT                   EXIT                            19300000
BXERR2   BAL   SRR,ERRZRO               LOG ERROR                       19320000
         DC    AL2(ERRREG)             REGISTER ERROR                   19340000
BXEXIT   L     SRR,HOLDER               RESTORE EXIT ADDRESS            19360000
         BR    SRR                      AND EXIT                        19380000
LENERR   ST    SRR,HOLDER               SAVE RETURN                     19400000
         BAL   SRR,ERRZRO               LOG ERROR                       19420000
         DC    AL2(ERRLEN)             LENGTH ERROR                     19440000
         L     SRR,HOLDER               RESTORE RETURN ADDRESS          19460000
         BR    SRR                      AND EXIT                        19480000
RNTRR    MVI   CTRENT(ACT),X'FF'        TURN ON REENTRANT CHECK FLAG    19500000
         LA    SRR,2(SRR)               BUMP PAST REENTRANT ERR CODE    19520000
         BR    SRR                      RETURN                          19540000
         ENTRY DCCOMP                   DE COMPILE - EXTERNAL           19560000
         ENTRY DECOMP                   DE COMPILE - INTERNAL           19580000
         ENTRY F8AREX                   EVALUATE EXPRESSION             19600000
KTWO     DC    F'2'                     CONSTANTS - 2                   19620000
K16      DC    F'16'                               16                   19640000
K17      DC    F'17'                    SEVENTEEN FOR LENGTH COMPARE    19660000
K240     DC    F'240'                             240                   19680000
K256     DC    F'256'                   FULL WORD VALUE 256             19700000
K257     DC    F'257'                             257                   19720000
K4095    DC    F'4095'                           4095                   19740000
K4096    DC    F'4096'                 CONSTANT DECIMAL 4096            19760000
BYTES3   DC    X'00FFFFFF'             THREE BYTE MALK                  19780000
F8REGS   DS    16F                      SAVE AREA FOR DCCOMP            19800000
WORDBB   DC    F'0'                     SAVE FOR CURRENT ESD            19820000
HLDSRR   DC    F'0'                     SAVE AREA FOR RETURN            19840000
HOLDER   DC    F'0'                     SAVE AREA FOR ERROR RETURN      19860000
RRHOLD   DC    F'0'                     SAVE AREA FOR RETURN            19880000
ABSLUT   DC    F'0'                     ABSOLUTE DISPLACEMENT           19900000
CREXPC   DC    F'0'                     COMPLEX SWITCH                  19920000
DCMPSW   DC    X'00'                    DECOMPOSABILITY SWITCH          19940000
ALIGNT   DS    F                        TEMP FOR ALIGNMENT              19960000
BSTVAL   DS    F                        BEST VALUE FOR BASE             19980000
VALUEE   DS    F                       TEMPORARY VALUE AND ESD-ID       20000000
VALUEZ   DS    F                                                        20020000
COLMNPTR DC    F'0'                     SAVE FOR COL PTR         A27017 20022019
ERRORPTR DC    F'0'                     SAVE FOR POSS. ERR PTR   A27017 20024019
SAVESRR  DC    F'0'                     SAVE FOR RETURN ADDR     A27017 20026019
ABSLUTSV DS    F                        ABS DISPLACEMENT SAVE AREA17168 20030016
TEMVAL   DC    F'0'                    TEMPORARY STORAGE SLAQUE         20040000
EXFLGS   DS    0F                       FLAGS FOR F8AREX                20060000
AEXP1    DC    X'00'                      SEE F8AREX FOR THE            20080000
AEXP2    DC    X'00'                        MEANING OF THESE FLAGS      20100000
AEXP3    DC    X'00'                          AND THE MEANING OF THE    20120000
SREXP    DC    X'00'                            BITS WITHIN THE FLAGS   20140000
VALUEB   DC    F'0'                    EXPRESSION VALUE                 20160000
EXPESD   DC    X'0000'                  EXPRESSION SIGN AND ESD-ID      20180000
ABSFLG   DC    X'00'                    ABSOLUTE FLAG                   20200000
DISPERR  DC    X'00'                    ADDR VS DISPL ERR FLAGS  A27017 20210019
LTVLSW   DC    X'00'                    LITERAL SWITCH                  20220000
BITS45   DC    X'0C'                    BITS 4 AND 5                    20240000
F8FF     DC    X'FF'                    ONE BYTE OF ONES                20260000
RENTERR  DC    X'00'                    REENTRANT ERROR FLAG            20280000
RENTRANT DC    X'FF'                    REENTRANT FLAG                  20300000
QUOTFLAG DC    X'00'                    QUOTE FLAG 0 = EVEN             20320000
BSTREG   DS    C                        BEST BASE REG FOR LOWEST DISP   20340000
ABSRX    DS    C                        ABSOLUTE SWITCH                 20360000
ERRSW    DC    X'00'                   ERROR SWITCH FOR ZEROING INST    20380000
LITRLTWO DC    X'00'                    MULITPLE LITERAL SWITCH         20400000
ALIGNERR DC    X'01'                    BIT7=1 NO REG SPECIFIED  190000 20400619
*                                       BIT6=1 ALIGN ERROR PEND. 190000 20401219
ALBEG    EQU   *                        START REQUIRED ALGN TABLE IEUN5 20402018
         DC    X'47'                    BC                        IEUN5 20404018
         DC    X'45'                    BAL                       IEUN5 20406018
         DC    X'46'                    BCT                       IEUN5 20408018
         DC    X'44'                    EX                        IEUN5 20410018
         DC    X'86'                    BXH                       IEUN5 20412018
         DC    X'87'                    BXLE                      IEUN5 20414018
         DC    X'82'                    LPSW                      IEUN5 20416018
ALEND    EQU   *                        END REQUIRED ALIGN TABLE  IEUN5 20418018
ERRIMM   EQU   20                      IMMEDIATE FIELD ERROR            20420000
ERRDLM   EQU   39                       INVALID DELIMITER               20440000
ERRLIN  EQU   33                        ALIGNMENT ERROR                 20460000
ERRREG   EQU   10                       INCORRECT REGISTER              20480000
ERRLLN   EQU   3                        LENGTH ERROR                    20500000
ERRLIT  EQU   15                        INVALID LITERAL USAGE           20520000
ERRENT   EQU   110                      REENTER                         20540000
ERRLOC   EQU   25                       RELOCATABILITY                  20560000
ERRDIS  EQU   8                         INVALID DISPLACEMENT            20580000
ERRLEN   EQU   3                        LENGTH                          20600000
ERRWRP   EQU   7                        WRAP AROUND ERROR CODE          20620000
LATP     EQU   CTXWAP                   POINTER TO LITERAL ADDRESS TABL 20640000
USNGPP   EQU   CTXIO3                   I/O BUFFER 3                    20660000
USNGTP   EQU   CTXIO4                   I/O BUFFER 4                    20680000
ERPROC   EQU   80                       ILLEGAL START CARD              20700000
ERRADR   EQU   35                       ADDRESSABILITY                  20720000
SXTEEN   EQU   K16                      CONSTANT OF 16                  20740000
FOR095   EQU   K4095                    CONSTANT OF 4095                20760000
FOR096   EQU   K4096                    CONSTANT OF 4096                20780000
         END   F8MOP                                                    20800000
