F8N      TITLE 'ASSM F - FLOATING-FIXED POINT CONVERSION--- '           00020000
         ISEQ  73,80                                                    00040000
IEUF8N   START 0                        DECIMAL CONVERSION ROUTINE      00060000
*          RELEASE 18 DELETIONS                                         00061018
*1472008800-098800                                                IEUN2 00062018
*1472270600-271600,286600-287600,290600-291600,293600,295600-     IEUN2 00062318
*1472297600                                                       IEUN2 00062618
*          RELEASE 19 DELETIONS                                         00063018
*          RELEASE 20 DELETIONS                                         00064018
*          RELEASE 21 DELETIONS                                         00065018
*          RELEASE 22 DELETIONS                                         00066018
*          RELEASE 23 DELETIONS                                         00067018
*          RELEASE 24 DELETIONS                                         00068018
*          RELEASE 25 DELETIONS                                         00069018
*          RELEASE 26 DELETIONS                                         00070018
DCNVRT   EQU   IEUF8N                   OLD NAME FOR DECIMAL CNVRT RTN  00080000
         PRINT DATA,NOGEN                                               00100000
         FDIMEN                                                         00120000
         PRINT GEN                                                      00140000
*                                                                     * 00160000
*TITLE 'IEUF8N  ' ...  FIXED-FLOATING POINT CONVERSION                * 00180000
*STATUS CHANGE LEVEL 004                                                00200018
*FUNCTION/OPERATION-                                                  * 00220000
*   TO DO ALL FIXED OR FLOATING POINT CONVERSION FOR DC STATEMENTS. IT* 00240000
*   IS CALLED BY IEUF8D ONCE FOR EACH CONSTANT TO BE CONVERTED.       * 00260000
*ENTRY POINT- IEUF8N                                                  * 00280000
*   IEUF8N IS CALLED VIA                                              * 00300000
*        L     SRB,CCONV(ACT)           GET BASE/ENTRY                * 00320000
*        BALR  SRR,SRB                  CALL IEUF8N                   * 00340000
*INPUT- TWO REGISTERS ARE USE FOR INPUT                               * 00360000
*   (1)  ZWRB  POINTS TO FIRST CHAR OF STRING TO BE CONVERTED         * 00380000
*   (A)  SP1   POINTS TO DC WORKBUCKET                                * 00400000
*OUTPUT- THREE REGISTERS ARE USED FOR OUTPUT                          * 00420000
*   (1)  ZWRB  POINTS TO CHAR TERMINATING FIELD                       * 00440000
*   (B)  SP2   POINTS TO BINARY CONVERTED VALUE                       * 00460000
*   (D)  GRZ   POINTS TO BYTE CONTAINING ERROR NUMBER                 * 00480000
*                  0 - NO ERROR                                       * 00500000
*                 11 - SCALE MODIFIER                                 * 00520000
*                 13 - EXPONENT MODIFIER                              * 00540000
*                 17 - TRUNCATION                                     * 00560000
*                 39 - INVALID DELIMITER                              * 00580000
*                 70 - FLOATING POINT CHARACTERISTIC OUT OF RANGE     * 00600000
*                109 - PRECISION LOST                                 * 00620000
*EXTERNAL ROUTINES- NONE                                              * 00640000
*EXITS- NORMAL AND ERROR                                              * 00660000
*    RETURN VIA                                                       * 00680000
*        BR    SRR                      EXIT                          * 00700000
*TABLES/WORKAREA                                                      * 00720000
*   ZWSVRG- SAVE AREA FOR REGISTERS B THROUGH E                       * 00740000
*   DCVW-   CONTAINS RESULTS OF CONVERSION                            * 00760000
*   HOLD-   CONTAINS PACKED NUMBER TO BE CONVERTED                    * 00780000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 00800000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 00820000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 00840000
         EJECT                                                          00860000
         USING *,SRB                                                    00960018
*                                                                       01060018
*    INITIALIZATION                                                     01160018
*                                                                       01260018
DCNVRT1  MVI   DCSW,0                   ZERO SWITCHES                   01360018
         MVI   DCXPON,X'00'             SET SIGN POSITIVE               01460018
         MVC   DCXPON+1(5),TXDEXP(SP1)  GET EXP AND SCL MODF            01560018
         LH    GR2,DCSCAL               GET SCALE MODIFIER              01660018
CNV1     SRL   GR2,5                    SHIFT EXTRANEOUS BITS           01760018
         STH   GR2,DCSCAL               SAVE IN SCALE MODIFIER          01860018
         TM    TXDEXP(SP1),X'80'        TEST SIGN OF EXPONENT MODIFIER  01960018
         BZ    CNV2                     BRANCH IF PLUS                  02060018
         MVI   DCXPON,X'FF'             SET SIGN NEGATIVE               02160018
CNV2     LH    GR2,DCVW                 GET LENGTH MODIFIER             02260018
         TM    TXDLMD(SP1),X'01'        IS LENGTH MODIFIER BITS         02360018
         BO    CNV3                     YES                             02460018
         SLL   GR2,3                    NO,BYTES, SO SHIFT FOR BITS     02560018
CNV3     BCTR  GR2,0                    DECREMENT BY ONE                02660018
         STH   GR2,DCLNG+2              SAVE LENGTH MODIFIER            02760018
         CLI   TXDTYP(SP1),X'07'        TEST IF FIXED OR FLOATING       02860018
         BL    ZWFLCV                   BRANCH IF FLOATING              02960018
         CLI   TXDTYP(SP1),X'0E'        IS THIS L-CON                   03060018
         BNE   ZWFXCV                     NO.  FIXED.                   03160018
         MVI   ZWSW,X'09'                 YES. SET INDICATOR            03260018
         B     ZWA2                     GO INITIALIZE                   03360018
*A                                                                      03460018
*A MOVE SCALE FACTOR AND EXPO MOD TO WORK AREA.CHECK RANGE OF FORMER    03560018
*A SAVE REGISTERS 11,13,14.INIT CONTROL SWITCHES(ZWSW) AND ACCUMULATOR  03660018
*A                                                                      03760018
ZWFLCV   MVI   ZWSW,X'01'          SET SWITCH FOR FLOATING POINT        03860018
ZWA2     SR    ZWRD,ZWRD           LOWER LIMIT SCALE FACTOR             03960018
         LA    ZWRE,30             UPPER LIMIT SCALE FACTOR             04060018
         B     ZWA1                     SKIP FIXED POINT SET UP         04160018
ZWFXCV   MVI   ZWSW,0              SET SWITCH FOR FIXED POINT           04260018
         LA    ZWRD,187            LOWER                                04360018
         LCR   ZWRD,ZWRD             LIMIT SCALE FACTOR                 04460018
         LA    ZWRE,346            UPPER LIMIT SF                       04560018
ZWA1     LH    ZWRA,DCSCAL         SCALE FACTOR                         04660018
         LH    ZWRH,DCXPON         EXPONENT MODIFIER                    04760018
         STM   ZWRI,ZWRB,ZWSVRG    SAVE ABOVE,REGS 11-13,AND RETURN ADD 04860018
         XC    ZWACC,ZWACC         CLEAR ACCUMULATOR                    04960018
         SR    ZWRL,ZWRL           PREPARE TO MARK DECIMAL POINT        05060018
         LR    ZWRF,ZWRB           SET UP FOR NO EXP DIGITS TEST        05160018
         LR    ZWRI,ZWRH           SAVE EXPONENT MODIFIER               05260018
*B                                                                      05360018
*B SCAN TEXT MARKING DECIMAL,END OF VALUE,FIRST TERMINATOR.             05460018
*B CONVERT EXPONENT IF ANY AND MODIFY.                                  05560018
*B                                                                      05660018
ZWB1     LR    ZWRJ,ZWRB           MARK END OF VALUE FIELD              05760018
         CLI   0(ZWRB),IE               BRANCH                          05860018
         BNE   ZWB3                     IF CHARACTER NOT E              05960018
         LA    ZWRB,1(ZWRB)             STEP OVER E                     06060018
         BAL   ZWRG,ZWS1           STEP OVER SIGN IF PRESENT            06160018
         BAL   ZWRG,DECON          CONVERT EXPONENT                     06260018
         CLI   1(ZWRJ),IMINUS      BRANCH                               06360018
         BNE   ZWB2                     UNLESS EXP NEGATIVE             06460018
         LCR   ZWRH,ZWRH           COMPLEMENT EXPONENT                  06560018
ZWB2     AR    ZWRI,ZWRH           ADD TO EXP MODIFIER                  06660018
         ST    ZWRI,ZWDE           STORE MODIFIED EXP                   06760018
ZWB3     CLI   0(ZWRB),ICOMMA           BRANCH OUT                      06860018
         BE    ZWC1                     IF CHAR COMMA                   06960018
         CLI   0(ZWRB),IQUOTE           BRANCH OUT                      07060018
         BE    ZWC1                     IF CHAR QUOTE                   07160018
         CLI   0(ZWRB),IPRIOD           BRANCH                          07260018
         BNE   ZWB4                     UNLESS CHAR DECIMAL POINT       07360018
         LR    ZWRL,ZWRB           MARK DECIMAL POINT                   07460018
ZWB4     LA    ZWRB,1(ZWRB)             ADVANCE TEXT POINTER            07560018
         B     ZWB1                     CONTINUE LOOP                   07660018
*C                                                                      07760018
*C SAVE POINTER TO TERMINATOR.CHECK EXPONENT AND SCALE FACTOR RANGE AND 07860018
*C CHECK FOR NO EXPONENT DIGITS. SET UP TO SCAN VALUE.                  07960018
*C                                                                      08060018
ZWC1     ST    ZWRB,ZWAUXT              SAVE PTR TO TERMINATING CHAR    08160018
         LA    ZWRH,ZRCD13              SET NO. FOR EXP RANGE ERROR     08260018
         AH    ZWRI,=H'5'          MAKE RANGE SYMMETRIC                 08360018
         LPR   ZWRI,ZWRI           TAKE MAGNITUDE                       08460018
         CH    ZWRI,=H'80'         BRANCH                               08560018
         BH    ZWZ3                     IF EXPONENT OUTSIDE RANGE       08660018
         LA    ZWRH,ZRCD11              SET NO. FOR SCL FAC RANGE ERROR 08760018
         CR    ZWRA,ZWRD           BRANCH                               08860018
         BL    ZWZ3                     IF SF TOO SMALL                 08960018
         CR    ZWRA,ZWRE           BRANCH                               09060018
         BH    ZWZ3                     IF SF TOO LARGE                 09160018
         CR    ZWRB,ZWRF           BRANCH TO ERROR ROUTINE              09260018
         BE    ZWZ4                     IF NO EXP DIGIT OR TEXT         09360018
         L     ZWRB,ZWTXPT         RESET TEXT POINT TO BEGINNING VALUE  09460018
         BAL   ZWRG,ZWS1           STEP OVER VALUE SIGN IF PRESENT      09560018
         LTR   ZWRL,ZWRL           IF NO DECIMAL                        09660018
         BNZ   ZWD1                  SET MARK TO                        09760018
         LR    ZWRL,ZWRJ             END OF VALUE                       09860018
*D                                                                      09960018
*D STEP OVER DECIMAL POINT. CHECK FOR END OF VALUE.                     10060018
*D                                                                      10160018
ZWD1     CR    ZWRB,ZWRL           IF NEXT CHAR                         10260018
         BNE   ZWD2                     DECIMAL POINT                   10360018
         LA    ZWRB,1(ZWRB)             ADVANCE VALUE POINTER           10460018
         LR    ZWRL,ZWRB             AND DECIMAL MARKER                 10560018
ZWD2     CR    ZWRB,ZWRJ           IF END OF VALUE                      10660018
         BNL   ZWM1                  BRANCH                             10760018
         EJECT                                                          10860018
*E                                                                      10960018
*E CONVERT PIECE OF VALUE.CHECK FOR ZERO.COMPUTE ADJUSTED EXP FOR PIECE 11060018
*E                                                                      11160018
ZWE1     BAL   ZWRG,DECON          CONVERT PIECE OF VALUE               11260018
         TM    VASCTL,X'C0'        IF ONE OR MORE DIGITS CONVERTED      11360018
         BZ    ZWE2                     AND NON-DIGIT REACHED, BRANCH   11460018
         TM    VASCTL,X'80'        IF NO DIGITS FOUND                   11560018
         BO    ZWZ4                     BRANCH TO INVALID TERM. MESSAGE 11660018
         LA    ZWRB,9(ZWRF)        CORRECT VALUE POINTER                11760018
ZWE2     OI    ZWSW,X'02'          SET VALUE FOUND SWITCH               11860018
         LTR   ZWRD,ZWRH           COPY AND TEST VALUE                  11960018
         BZ    ZWD1                     BRANCH IF ZERO                  12060018
         LR    ZWRG,ZWRL           LOCATION DECIMAL                     12160018
         SR    ZWRG,ZWRB             MINUS LOCATION CHAR AFTER FLD CNVT 12260018
         A     ZWRG,ZWDE             PLUS EXP GIVES ADJ EXP FOR THIS    12360018
*                                    PIECE OF VALUE                     12460018
         TM    ZWSW,X'05'          BRANCH UNLESS FIRST NON-ZERO         12560018
         BNM   ZWG1                  PIECE FLOATING VALUE               12660018
*F                                                                      12760018
*F IF FLOATING PT COMPUTE WORKING SCALE FACTOR.                         12860018
*F                                                                      12960018
         LCR   ZWRC,ZWRG           COMPLEMENT ADJ EXP                   13060018
         MH    ZWRC,=HS13'3.322'   MULT BY LOG 10 BASE 2 (3.527 HEX)    13160018
         SRA   ZWRC,13             SCALE PRODUCT                        13260018
ZWF1     BCTR  ZWRC,0              COUNT NUMBER BITS                    13360018
         SRA   ZWRD,1                AND SUBTRACT                       13460018
         BP    ZWF1                     FROM PRODUCT                    13560018
         SRA   ZWRC,2              ROUND DOWN TO MULTIPLE OF 4          13660018
         SLA   ZWRC,2                                                   13760018
         AH    ZWRC,=H'124'          AND ADD 124                        13860018
         ST    ZWRC,ZWSF           STORE WORKING SCALE FACTOR           13960018
         OI    ZWSW,X'04'          SET FL PT INIT SWITCH                14060018
         LPR   ZWRF,ZWRC           IF WORKING SCALE FACTOR WILL         14160018
         CH    ZWRF,=H'400'          PRODUCE INVALID CHARACTERISTIC     14260018
         BH    ZWQ7                     BRANCH TO INVALID EXP MSG       14360018
*G                                                                      14460018
*G COMPUTE AMT OF BINARY SHIFT. SPLIT INTO WORD INDEX AND BIT SHIFT.    14560018
*G RESET WORKING AREA. TEST SIGN OF ADJ EXPONENT.                       14660018
*G                                                                      14760018
ZWG1     LA    ZWRC,32             32                                   14860018
         AR    ZWRC,ZWRG             PLUS ADJ EXP                       14960018
         A     ZWRC,ZWSF           PLUS SCALE FACTOR GIVES BIN SHIFT    15060018
* NOTE - ZWSF HAS S-MODIFIER VALUE IF F-, H-CON,                        15160018
*             OR THE WORKING SCALE FACTOR IF L-, D-, OR E-CON.          15260018
         SRDA  ZWRC,5              SEPARATE INTO BIT AND WORD SHIFTS    15360018
         SRL   ZWRD,27             POSITION BIT SHIFT                   15460018
         SLL   ZWRC,2              POSITION WORD SHIFT                  15560018
         XC    ZWW1,ZWW1           CLEAR WORK AREA                      15660018
         LTR   ZWRG,ZWRG           TEST ADJ EXP                         15760018
         BNP   ZWI1                BRANCH IF ZERO OR NEG                15860018
         EJECT                                                          15960018
*H                                                                      16060018
*H ADJ EXP IS PLUS.  MULTIPLY VALUE BY 5 TO THE GIVEN POWER.            16160018
*H                                                                      16260018
         ST    ZWRH,ZWW2           STORE VALUE                          16360018
         LR    ZWRA,ZWRC           WORD SHIFT IN BYTES                  16460018
         SH    ZWRA,=H'16'           LESS 16 = LEFT LIMIT OF WORK AREA  16560018
         BP    ZWJ8                     BRANCH IF LIMIT DEFINES NO WORK 16660018
ZWH1     SR    ZWRI,ZWRI           RESET WORK AREA POINTER              16760018
         SR    ZWRH,ZWRH           CLEAR CARRY REG                      16860018
ZWH2     L     ZWRF,ZWW2(ZWRI)     LOAD PART OF VALUE                   16960018
         M     ZWRE,=F'5'          TIMES 5                              17060018
         ALR   ZWRF,ZWRH           ADD CARRY                            17160018
         BC    12,ZWH3             PROPAGATE                            17260018
         AH    ZWRE,=H'1'            CARRY                              17360018
ZWH3     LTR   ZWRH,ZWRE           SAVE CARRY AND TEST SIGN             17460018
         BNM   ZWH4                  IF NEGATIVE                        17560018
         AH    ZWRH,=H'5'            CORRECT                            17660018
ZWH4     ST    ZWRF,ZWW2(ZWRI)     STORE PARTIAL PRODUCT                17760018
         SH    ZWRI,=H'4'          STEP AREA POINTER LEFT               17860018
         CR    ZWRI,ZWRA           IF LEFT LIMIT NOT REACHED            17960018
         BNL   ZWH2                  BRANCH                             18060018
         LTR   ZWRH,ZWRH           TEST FINAL CARRY                     18160018
         BZ    ZWH5                     IF NOT ZERO                     18260018
         OI    DCSW,DCTRUN           SET TRUNCATION INDICATOR           18360018
ZWH5     BCT   ZWRG,ZWH1           DECREMENT ADJ EXP AND CLOSE LOOP     18460018
         B     ZWJ1                     SHIFT VALUE                     18560018
*I                                                                      18660018
*I ADJ EXP IS NOT PLUS. SHIFT VALUE AS INDICATED BY THE WORD INDEX AND  18760018
*I DIVIDE BY 5 TO THE MAGNITUDE OF THE GIVEN POWER. RESET WORD INDEX    18860018
*I                                                                      18960018
ZWI1     LCR   ZWRC,ZWRC           COMPLEMENT WORD SHIFT GIVES LEFT     19060018
*                                    LIMIT WORK AREA                    19160018
         BP    ZWD1                     BRANCH IF LIMIT DEFINES NO WORK 19260018
         ST    ZWRH,ZWW2(ZWRC)     STORE VALUE IN WORK AREA SHIFTED     19360018
         LCR   ZWRG,ZWRG           COMPLEMENT AND TEST ADJ EXP GIVES    19460018
*                                    COUNT FOR NUMBER TIMES TO DIVIDE   19560018
         BZ    ZWI5                     BRANCH IF ZERO                  19660018
ZWI2     LR    ZWRI,ZWRC           SET WORKING POINTER TO LEFT LIMIT    19760018
         SR    ZWRE,ZWRE           CLEAR UPPER DIVIDEND REG             19860018
ZWI3     L     ZWRF,ZWW2(ZWRI)     LOAD PART OF DIVIDEND                19960018
         D     ZWRE,=F'10'         DIVIDE                               20060018
         SLL   ZWRF,1                BY 5                               20160018
         CH    ZWRE,=H'5'          IF REMAINDER                         20260018
         BL    ZWI4                     TOO LARGE                       20360018
         SH    ZWRE,=H'5'            CORRECT REMAINDER                  20460018
         AH    ZWRF,=H'1'            AND DIVIDEND                       20560018
ZWI4     ST    ZWRF,ZWW2(ZWRI)     STORE PARTIAL QUOTIENT               20660018
         AH    ZWRI,=H'4'          STEP WORKING POINTER RIGHT           20760018
         BNP   ZWI3                REPEAT UNTIL RIGHT LIMIT REACHED     20860018
         BCT   ZWRG,ZWI2           REDUCE COUNT AND CLOSE LOOP          20960018
ZWI5     SR    ZWRC,ZWRC           CLEAR WORD SHIFT                     21060018
         OC    ZWW1(L'ZWW1-L'ZWACC),ZWW1  TEST HI PART OF WORK AREA     21160018
         BE    ZWJ1                     IF NOT ZERO                     21260018
         OI    DCSW,DCTRUN           SET TRUNCATION INDICATOR           21360018
*J                                                                      21460018
*J SHIFT VALUE PER WORD SHIFT AND BIT SHIFT. TRUNCATE TO 160            21560018
*J BITS AND ADD TO ACCUMULATOR.                                         21660018
*J                                                                      21760018
ZWJ1     SR    ZWRG,ZWRG           RESET CARRY REG                      21860018
         LA    ZWRH,16             INIT ACCUMULATOR POINTER             21960018
ZWJ2     SR    ZWRE,ZWRE           RESET WORKING REGISTERS              22060018
         SR    ZWRF,ZWRF                                                22160018
         LTR   ZWRC,ZWRC           TEST WORD INDEX                      22260018
         BP    ZWJ4                     IF PLUS LEAVE WORK AREA CLEAR   22360018
         BZ    ZWJ3                     IF ZERO FETCH ONE WORD OF RESLT 22460018
         L     ZWRF,ZWW2+4(ZWRC)   FETCH LO WORD OF RESULT              22560018
ZWJ3     L     ZWRE,ZWW2(ZWRC)     FETCH HI WORD OF RESULT              22660018
ZWJ4     SLDL  ZWRE,0(ZWRD)        BIT SHIFT                            22760018
         ALR   ZWRE,ZWRG           ADD IN CARRY                         22860018
         BC    3,ZWJ5              BRANCH IF CARRY LEAVING ONE IN ZWRG  22960018
         SR    ZWRG,ZWRG           RESET CARRY                          23060018
ZWJ5     LTR   ZWRH,ZWRH           END OF ACCU                          23160018
         BM    ZWJ7                     YES, BRANCH                     23260018
         AL    ZWRE,ZWACC(ZWRH)    ADD IN PIECE FROM ACCUMULATOR        23360018
         BC    12,ZWJ6             BRANCH IF NO CARRY                   23460018
         LA    ZWRG,1              SET CARRY                            23560018
ZWJ6     ST    ZWRE,ZWACC(ZWRH)    STEP WORKAREA PT                     23660018
         SH    ZWRC,=H'4'          STEP ACCU PT                         23760018
         SH    ZWRH,=H'4'          REPEAT FOR EACH WORD OF ACCU         23860018
         B     ZWJ2                     LOOP                            23960018
ZWJ7     LTR   ZWRE,ZWRE           TEST CARRY                           24060018
         BZ    ZWD1                     IF ON                           24160018
ZWJ8     OI    DCSW,DCTRUN           SET TRUNCATION INDICATOR           24260018
         B     ZWD1                     STEP OVER DECIMAL POINT         24360018
*M                                                                      24460018
*M SET UP TO FORMAT RESULT. BRANCH TO APPROPRIATE ROUTINE.              24560018
*M                                                                      24660018
ZWM1     LM    ZWRL,ZWRJ,ZWSF      GET SCALE FACTOR AND TEXT POINTER,   24760018
         L     ZWRC,DCLNG               GET BIT LENGTH                  24860018
         LCR   ZWRC,ZWRC             AND COMPLEMENT                     24960018
         TM    ZWSW,X'06'          WHAT FORMAT REQUIRED                 25060018
         BZ    ZWZ4                     BRANCH IF TEXT TRIVIAL          25160018
         BO    ZWP1                     BRANCH IF FLOAT PT AND NON-ZERO 25260018
         EJECT                                                          25360018
*N                                                                      25460018
*N FORMAT FIXED POINT RESULT.                                           25560018
*N                                                                      25660018
ZWN1     TM    ZWACC+L'ZWACC-4,X'80'    TEST DROPPED BIT                25760018
         BZ    ZWN2                       NO ROUND NEEDED               25860018
         LA    ZWRI,L'ZWACC-4           LOAD INDEX REG                  25960018
ZWN3     LA    ZWRA,1                   LOAD ROUND/CARRY BIT            26060018
         AL    ZWRA,ZWACC-4(ZWRI)       ADD IN PIECE OF VALUE           26160018
         ST    ZWRA,ZWACC-4(ZWRI)                                       26260018
         BC    12,ZWN2                  IF NO CARRY, GO QUIT            26360018
         SH    ZWRI,=H'4'                 ELSE PROPAGATE CARRY          26460018
         BP    ZWN3                         THRU ALL OF ZWACC           26560018
         OI    DCSW,DCTRUN              IF CARRY OUT SET TRUNC.INDIC.   26660018
ZWN2     CLI   0(ZWRJ),IMINUS           IF VALUE SIGN IS NEGATIVE       26760018
         BE    ZWN4                       GO DO NEG. OUTPUT             26860018
* VALUE IS POSITIVE.  MOVE INTACT TO OUTPUT.                            26960018
         LM    ZWRG,ZWRB,ZWACC                                    IEUN2 26980018
         STM   ZWRG,ZWRB,DCVW           STORE IN OUTPUT AREA      IEUN2 27000018
* TEST FOR TRUNCATION OF HIGH-ORDER BITS (POSITIVE DATA)                27020018
         CH    ZWRC,=H'-63'             IS LENGTH OVER 2 WORDS    IEUN2 27040018
         BL    ZWN6                       YES.  GO DO HI 2 WORDS  IEUN2 27060018
         OR    ZWRG,ZWRH                TEST HI 2 WORDS FIRST     IEUN2 27080018
         BNZ   ZWN8                     SHOULD BE ZERO            IEUN2 27100018
         SLDA  ZWRA,63(ZWRC)            TEST TRUN. IN BITS OF LO  IEUN2 27120018
*                                       2 WDS                     IEUN2 27140018
         B     ZWN6+L'ZWN6                THEN GO TEST                  27160018
ZWN6     SLDA  ZWRG,127(ZWRC)           TEST TRUN. IN BITS OF HI  IEUN2 27180018
*                                       2 WDS                     IEUN2 27200018
         BC    10,ZWZ5                  IF OKAY GO PUT IT OUT     IEUN2 27220018
         B     ZWN8                     ELSE GO LOG ERROR         IEUN2 27240018
* VALUE IS NEGATIVE.  COMPLIMENT IT AND PUT IN OUTPUT.                  27260018
ZWN4     LA    ZWRI,L'ZWACC-4           LOAD UP INDEX                   27360018
         SR    ZWRA,ZWRA                CLEAR REDUCTION BIT             27460018
ZWN5     L     ZWRB,ZWACC-4(ZWRI)       PICK UP A WORD                  27560018
         LCR   ZWRB,ZWRB                COMPLIMENT IT, 2'S COMP         27660018
         SLR   ZWRB,ZWRA                REDUCE TO 1'S COMP IF ABOVE    X27760018
                                            FIRST NON-ZERO WORD         27860018
         BC    2,ZWN0                   BRANCH IF VALUE IS STILL ZERO   27960018
* BRANCH GOES WRONG IF ZERO IS DEVELOPED ABOVE 1ST NON-ZERO. BUT THAT'S 28060018
*  OKAY, AS, ONCE ZWRA IS = 1, RELOADING IT DOESN'T MATTER ANYWAY.      28160018
         LA    ZWRA,1                   BEGIN 1'S COMPLIMENT NEXT WORD  28260018
ZWN0     ST    ZWRB,DCVW-4(ZWRI)        STORE IN OUTPUT AREA            28360018
         SH    ZWRI,=H'4'               NEXT                            28460018
         BP    ZWN5                       WORD                          28560018
* TEST FOR TRUNCATION OF HIGH-ORDER BITS (NEGATIVE DATA)                28660018
         LM    ZWRG,ZWRB,DCVW           PICK UP COMP. VALUE       IEUN2 28760018
         CH    ZWRC,=H'-63'             IS LENGTH OVER 2 WORDS          28860018
         BL    ZWN7                       YES.  GO DO HI 2 WORDS        28960018
         SLDA  ZWRG,63                  TEST HI 2 WORDS FIRST     IEUN2 29060018
         BC    3,ZWN8                   SHOULD BE MAX NEG OR ZERO IEUN2 29160018
         SLDA  ZWRA,63(ZWRC)            TEST TRUN. IN BITS OF LO 2 WDS  29260018
         B     ZWN7+L'ZWN7                THEN GO TEST                  29360018
ZWN7     SLDA  ZWRG,127(ZWRC)           TEST TRUN. IN BITS OF HI 2 WDS  29460018
         BC    12,ZWZ5                  IF OKAY GO PUT IT OUT     IEUN2 29560018
* SET TRUNCATION INDICATOR AND GO PUT OUT VALUE                         29660018
ZWN8     OI    DCSW,DCTRUN                ELSE SET TRUNCATION SW,       29860018
         B     ZWZ5                         THEN GO PUT IT OUT.         29960018
         EJECT                                                          30060018
*P                                                                      30160018
*P NORMALIZE FLOATING POINT RESULT                                      30260018
*P                                                                      30360018
ZWP1     LH    ZWRD,DCSCAL              GET S-MODIFIER                  30460018
         CLI   ZWACC,X'10'              IS HIGH HEX DIGIT GT 0          30560018
         BNL   ZWP2                     -YES.                           30660018
* VALUE NEEDS NORMALIZATION.            -NO.                            30760018
         MVC   ZWW1(L'ZWACC),ZWACC      PUT IN TEMP STORAGE             30860018
         MVO   ZWACC+10(10),ZWW1+10(10) SHIFT VALUE LEFT 4 BITS         30960018
         MVO   ZWACC+00(11),ZWW1+00(11)                                 31060018
         AH    ZWRL,=H'4'               ADJUST WORKING SCALE FACTOR     31160018
         B     ZWP1                     RETEST NORMALIZATION            31260018
* ROUND VALUE TO LENGTH                                                 31360018
*   CALCULATE LEFT SHIFT FOR ROUNDING-BIT                               31460018
ZWP2     LR    ZWRE,ZWRD                GRAB S-MOD (HEX BYTES)          31560018
         SLA   ZWRE,2                     MAKE INTO BITS                31660018
         TM    ZWSW,X'08'               IS THIS AN L-CON                31760018
         BZ    ZWP3                       NO. GO TO  D-,E- FORMULA      31860018
         CH    ZWRC,=H'-63'               YES. IS LENGTH .GT. 64 BITS   31960018
         BNL   ZWP3                         NO. USE D,E-CON FORMULA     32060018
         CH    ZWRC,=H'-71'                 YES. IS LENGTH .GT. 72      32160018
         BL    ZWP4                           YES. USE LONG L FORMULA   32260018
         SH    ZWRE,=H'-71'                   NO. SPECIAL L FORMULA,    32360018
         B     ZWP5                             GO SHIFT                32460018
ZWP4     AH    ZWRE,=H'8'               LONG L-CON FORM.                32560018
ZWP3     AH    ZWRE,=H'134'             SHORT L-CON, D-E-CON.           32660018
         AR    ZWRE,ZWRC                SUBTRACT LENGTH-1               32760018
*                                                                       32860018
ZWP5     CH    ZWRE,=H'127'             WILL ANY OF VALUE BE RETAINED   32960018
         BH    ZWQ1                       NO.  SKIP ROUNDING.           33060018
         SRDL  ZWRE,5                   SPLIT SHIFT INTO                33160018
         SRL   ZWRF,32-5                  BITS AND                      33260018
         SLL   ZWRE,2                     WORDS  (IN BYTE TERMS).       33360018
         LCR   ZWRE,ZWRE                                                33460018
         LA    ZWRI,L'ZWACC-4(,ZWRE)    INIT INDEX WORD-SHIFT ADJUSTED  33560018
         LA    ZWRA,1                   LOAD ROUND BIT                  33660018
         SLL   ZWRA,0(ZWRF)             POSITION IT                     33760018
ZWP6     AL    ZWRA,ZWACC-4(ZWRI)       ADD IN PIECE OF VALUE           33860018
         ST    ZWRA,ZWACC-4(ZWRI)                                       33960018
         BC    12,ZWQ1                  IF NO CARRY, GO QUIT            34060018
         LA    ZWRA,1                     ELSE LOAD CARRY REGISTER,     34160018
         SH    ZWRI,=H'4'                                               34260018
         BP    ZWP6                       GO PROPAGATE CARRY            34360018
*OVERFLOW ON ROUNDING. NUTS.                                            34460018
         MVI   ZWACC,X'10'              PUT CORRECTED VALUE             34560018
         SH    ZWRL,=H'4'  (ART'S FIX)  ADJUST WORKING SCALE FACTOR     34660018
         EJECT                                                          34760018
*Q                                                                      34860018
*Q SHIFT RIGHT PER SCALE MOD., PLACE EXPONENT(S), POSITION FOR OUTPUT   34960018
*Q                                                                      35060018
ZWQ1     LR    ZWRB,ZWRD                GET S-MOD                       35160018
         AH    ZWRB,=H'1'               BUMP TO MOVE EXTRA BYTE IF     X35260018
                                          S-MOD IS ODD                  35360018
         SRA   ZWRB,1                   MAKE INTO BYTES                 35460018
         XC    ZWW1(L'ZWACC-3),ZWW1     CLEAR NEW HIGH BYTES            35560018
         LA    ZWRI,ZWW1+1(ZWRB)        INDEX MOVE. ADD 1 FOR EXP.      35660018
         MVC   0(L'ZWACC-5,ZWRI),ZWACC  MOVE AND SHIFT BY BYTES         35760018
         TM    DCSCAL+1,X'1'            WAS S-MOD ODD                   35860018
         BZ    ZWQ2                       NO. LET IT SIT                35960018
         MVO   ZWW1+1(16),ZWW1+1(16)    SHIFT BACK 1 HEX DIGIT          36060018
ZWQ2     MVC   ZWACC(L'ZWACC-3),ZWW1    BRING IT HOME                   36160018
*VALUE IN ZWW1 USED LATER IN LOST PRECISION TEST                        36260018
*                                                                       36360018
*CALCULATE EXPONENT BYTE AND INSERT IT IN VALUE                         36460018
         LA    ZWRB,384                 FORM                            36560018
         SR    ZWRB,ZWRL                  CHARACTERISTIC                36660018
         SRA   ZWRB,2                                                   36760018
         AR    ZWRB,ZWRD                ADJUST FOR S-MODIFIER           36860018
         LR    ZWRA,ZWRB                                                36960018
         SRA   ZWRA,7                   TEST FOR                        37060018
ZWQ7     LA    ZWRH,ZRCD70              CHARACTERISTIC                  37160018
         BNZ   ZWZ3                       OUT OF BOUNDS                 37260018
         CLI   0(ZWRJ),IMINUS           IF VALUE IS NEGATIVE            37360018
         BNE   *+8                        NOT NEG                       37460018
         LA    ZWRB,X'80'(,ZWRB)          PUT - SIGN                    37560018
         STC   ZWRB,ZWACC               PLUG IN EXPONENT                37660018
         TM    ZWSW,X'08'               IS THIS A L-CON                 37760018
         BZ    ZWQ3                       NO.  GO DO FINALS.            37860018
*THIS IS AN L-CON, PROCESS LOWER EXPONENT                               37960018
         LM    ZWRE,ZWRF,ZWACC+8        PICK LOW 2 WORDS                38060018
         SRDL  ZWRE,8                   MAKE ROOM FOR EXPONENT          38160018
         STM   ZWRE,ZWRF,ZWACC+8                                        38260018
         STM   ZWRE,ZWRF,ZWW1+8         SAVE FOR LATER TEST             38360018
         SH    ZWRB,=H'14'              LOWER EXPONENT IS 14 LESS       38460018
         STC   ZWRB,ZWACC+8             PLUG IT IN                      38560018
* IF LOW EXPONENT UNDERFLOWED, THE SIGN BIT WILL BE WRONG.              38660018
*  CORRECT FOR THAT POSSIBILITY.                                        38760018
         NI    ZWACC+8,B'01111111'      KILL WHATEVER SIGN BIT          38860018
         CLI   0(ZWRJ),IMINUS           IS VALUE NEGATIVE               38960018
         BNE   *+8                      BIF NO                          39060018
         OI    ZWACC+8,B'10000000'      YES, PUT - SIGN                 39160018
* CLODDY LOOP TO SHIFT VALUE FROM ZWACC TO DCVW, AND ALSO MOVE          39260018
* TEST VALUE FROM ZWW1 TO LOW ZWW1.                                     39360018
ZWQ3     AH    ZWRC,=H'127'             COMPUTE SHIFT                   39460018
         SRDL  ZWRC,5                                                   39560018
         SRL   ZWRD,32-5                BIT SHIFT                       39660018
         SLL   ZWRC,2                   WORD SHIFT IN BYTES             39760018
         XC    DCVW(12),DCVW            CLEAR RECEIVING AREA            39860018
         XC    ZWW1+16(12),ZWW1+16      CLEAR RECIEVING AREA            39960018
         SR    ZWRI,ZWRI                CLEAR LOOP INDEX                40060018
         SR    ZWRG,ZWRG                CLEAR CARRY REG                 40160018
         SR    ZWRH,ZWRH                CLEAR CARRY REG                 40260018
ZWQ4     L     ZWRE,ZWACC(ZWRI)         PICK UP WORD                    40360018
         L     ZWRL,ZWW1(ZWRI)          PICK UP WORD                    40460018
         SR    ZWRF,ZWRF                CLEAR RH WORD                   40560018
         SR    ZWRJ,ZWRJ                CLEAR RH WORD                   40660018
         SRDL  ZWRE,0(ZWRD)             SHIFT PER BIT SHIFT             40760018
         SRDL  ZWRL,0(ZWRD)             SHIFT PER BIT SHIFT             40860018
         OR    ZWRE,ZWRG                PUT IN BIT FROM PREVIOUS WORD   40960018
         OR    ZWRL,ZWRH                PUT IN BIT FROM PREVIOUS WORD   41060018
         LR    ZWRG,ZWRF                SAVE OUTSHIFT FOR NEXT WORD     41160018
         LR    ZWRH,ZWRJ                SAVE OUTSHIFT FOR NEXT WORD     41260018
         LA    ZWRB,0(ZWRI,ZWRC)        ADD 2 INDEX REGS TOGETHER       41360018
         ST    ZWRE,DCVW(ZWRB)          PUT WORD OFFSET PER WD SHIFT    41460018
         ST    ZWRL,ZWW1+16(ZWRB)       PUT WORD OFFSET PER WD SHIFT    41560018
         AH    ZWRI,=H'4'               BUMP INDEX                      41660018
         CH    ZWRB,=H'12'              TEST WHERE LATEST WD STORED     41760018
         BL    ZWQ4                       BR IF NOT LAST WORD           41860018
* TEST THE VALUE AT ZWW1+4 FOR LOST PRECISION                           41960018
         OC    ZWW1+16(16),ZWW1+16      ZERO IF SHIFTED OUT ALL BITS    42060018
         BNZ   ZWZ5                       IF BIT, GO OUTPUT             42160018
         LA    ZWRH,ZRCD109                                             42260018
         BAL   ZWRG,MERROR              POST ERROR MESSAGE, THEN        42360018
         B     ZWZ5                       GO OUTPUT                     42460018
         EJECT                                                          42560018
*S1                                                                     42660018
*S1 STEP OVER SIGN.                                                     42760018
*S1                                                                     42860018
ZWS1     CLI   0(ZWRB),IPLUS            IF CHAR IS +                    42960018
         BE    ZWS11                    BRANCH                          43060018
         CLI   0(ZWRB),IMINUS           IF CHAR                         43160018
         BCR   7,ZWRG                IS - RETURN                        43260018
ZWS11    LA    ZWRB,1(ZWRB)        STEP TEXT POINTER                    43360018
         BR    ZWRG                     RETURN                          43460018
*Z                                                                      43560018
*Z ERROR ROUTINE  AND RETURN ROUTINE.                                   43660018
*Z                                                                      43760018
ZWZ4     LA    ZWRH,ZRCD39              LOAD ERROR NUMBER               43860018
ZWZ3     BAL   ZWRG,MERROR         STORE ERROR MESSAGE                  43960018
         XC    DCVW,DCVW           CLEAR OUTPUT AREA                    44060018
ZWZ5     LM    ZWRI,ZWRG,ZWSVRG    RESTORE REG 11, 13, AND LINK ADDRESS 44160018
         L     ZWRB,ZWAUXT              RESTORE TEXT POINTER            44260018
         LA    SP2,DCVW                                                 44360018
         LA    GRZ,DCSW                                                 44460018
         BR    SRR                      RETURN                          44560018
*                                                                       44660018
MERROR   STC   ZWRH,DCSW                SET ERROR                       44760018
         BR    ZWRG                     AND RETURN                      44860018
         SPACE 2                                                        44960018
*DECON- CONVERT A PIECE OF THE VALUE                                    45060018
*       INPUT- CONDEX POINTS TO FIRST CHAR                              45160018
*       OUTPUT-BINVAL CONTAINS CONVERTED VALUE                          45260018
*              CONDEX TO TERMINATING CHAR                               45360018
*              ZWRF POINTS TO FIRST CHAR OF FIELD                       45460018
*              DECSW CONTAINS 1 IF TERMINATING CHAR COMMA               45560018
*                             2 IF TERMINATING CHAR QUOTE               45660018
*              VASCTL CONTAINS X'00'  NO ERRORS                         45760018
*                              X'40'  TOO LONG                          45860018
*                              X'80'  NO CHAR TO CONVERT                45960018
         SPACE 2                                                        46060018
DECON    BCTR  CONDEX,0                 SEE IT BACK ONE                 46160018
GETMOD   MVI   SIGN,X'0C'               SET SIGN PLUS                   46260018
         SR    CNT,CNT                  ZERO COUNTER                    46360018
         NI    VASCTL,X'00'             AND FLAG                        46460018
         ST    CONDEX,AFIRST            SAVE POINTER TO BEGINNING-1     46560018
ADDIT    LA    CONDEX,1(CONDEX)         UP TO NEXT CHAR                 46660018
         CLI   0(CONDEX),I9             IS CHAR NUMERIC                 46760018
         BH    SETUP                    NO, BRANCH                      46860018
         LA    CNT,1(CNT)               YES, UP COUNTER                 46960018
         B     ADDIT                    LOOP, LOOKING FOR NON-NUMERIC   47060018
SETUP    ST    CONDEX,SAVEAD            SAVE END POINTER                47160018
         CLI   0(CONDEX),IQUOTE         IS IT A QUOTE                   47260018
         BNE   COM                      NO                              47360018
         OI    DECSW,2                  YES, SET AS QUOTE AND CONTINUE  47460018
         B      BACK                                                    47560018
COM      CLI   0(CONDEX),ICOMMA         IS IT A COMMA                   47660018
         BNE   BACK                     NO, CONTINUE                    47760018
         ST     CONDEX,COMADD           YES, SAVE POINTER TO COMMA      47860018
         OI    DECSW,1                  SET AS COMMA                    47960018
BACK     L     CONDEX,AFIRST            BEGIN AT BEGINNING              48060018
         LA    CONDEX,1(CONDEX)                                         48160018
SET1     LTR   CNT,CNT                  ARE THERE CHAR TO CONVERT       48260018
         BZ    ZNONE                    NO, RETURN                      48360018
         CH    CNT,=H'10'               YES, IS IT GREATER THAN MAX     48460018
         BH    GTTEN                    YES, TRY TO GET DOWN TO NINE    48560018
         BL    GOTOIT                   NO, OK                          48660018
         CLC   0(10,CONDEX),=X'02010407040803060407'  =10 CHARS, IS IT X48760018
                                                        .GT. 2**31-1    48860018
         BNH   GOTOIT                   NO, CONVERT                     48960018
ZLONG    OI    VASCTL,X'40'             YES, SET FLAG                   49060018
         LA    CNT,9                    AND CONVERT 9                   49160018
GOTOIT   BCTR  CNT,0                    DECREMENT FOR MOVE              49260018
         EX    CNT,PACKIT               PACK VALUE INTO HOLD            49360018
         OC    HOLD+7(1),SIGN           SET POSITIVE SIGN               49460018
         CVB   BINVAL,HOLD              CONVERT HOLD TO BINARY          49560018
LEAVE    LR    ZWRF,CONDEX              SET TO FIRST CHAR               49660018
         L     CONDEX,SAVEAD            SET TO TERMINATOR               49760018
         BR    REG                      RETURN                          49860018
ZNONE    OI    VASCTL,X'80'             SET CODE, NONE TO CONVERT       49960018
         B     LEAVE                    AND EXIT                        50060018
GTTEN    CLI   0(CONDEX),IZERO          IS FIRST CHAR A ZERO            50160018
         BNE   ZLONG                    NO, TOO LONG                    50260018
         LA    CONDEX,1(CONDEX)         YES, IGNORE ZERO                50360018
         BCTR  CNT,0                    AND SEE IF IT IS                50460018
         B     SET1                     NOW SHORT ENOUGH                50560018
PACKIT   PACK  HOLD(8),0(00,CONDEX)     EXECUTED PACK TO PACK HOLD      50660018
         EJECT                                                          50760018
* ZWSVRG THRU ZWACC ARE STORED AND LOADED BY MULTIPLE OPS               50860018
* AND MUST BE IN GIVEN SEQUENCE.                                        50960018
ZWSVRG   DS    4F                  SAVE R11, R13, AND RETURN ADDR.      51060018
ZWDE     DS    F                   DECIMAL EXPONENT                     51160018
ZWSF     DS    F                   FIXED PT SCALE AND FLOATING PT EXPON 51260018
ZWTXPT   DS    F                   SAVE TEXT POINTER                    51360018
         DS    0F                  ENSURE WORD ALIGNMENT OF ZWACC       51460018
ZWACC    DS    XL20                ACCUMULATOR                          51560018
ZWAUXT   DS    F                        PTR TO CHAR TERMINATING FIELD   51660018
ZWSW     DS    C                   CONTROL SWITCHES AND VALUE SIGN      51760018
*                             BIT 7 X'01' = FLOATING POINT  (ELSE FIXD) 51860018
*                                 6    2  = VALUE FOUND (MAYBE ZERO)    51960018
*                                 5    4  = FLT.PT IS INITIALIZED (WSF) 52060018
*                                 4    8  = FLT.PT IS L-CON             52160018
*                                                                       52260018
         DS    0F                  SET PROPER ALIGNMENT FOR ZWW1        52360018
ZWW1     DS    XL56                WORK AREA                            52460018
ZWW2     EQU   ZWW1+L'ZWW1-4       LOW WORD OF WORK AREA                52560018
*                                                                       52660018
DCLNG    DC    F'0'                     LENGTH MODIFIER                 52760018
* DCXPON THRU DCVW ARE LOADED SERIALLY BY MVC AND MUST BE TOGETHER      52860018
         DC    0F'0'               ENSURE ALIGNMENT OF DCVW             52960018
DCXPON   DC    H'00'                    EXPONENT                        53060018
DCSCAL   DC    H'00'                    SCALE                           53160018
DCVW     DC    XL16'0'             OUTPUT AREA  (WORD ALIGNED)          53260018
HOLD     DC    D'0'                     DOUBLE WORD FOR CVB INST        53360018
AFIRST   DC    F'0'                     SAVE AREA FOR BEGINNING POINTER 53460018
SAVEAD   DC    F'0'                     SAVE AREA FOR ENDING POINTER    53560018
COMADD   DC    F'0'                     HOLD                            53660018
VASCTL   DC    X'00'                    DECON FLAG                      53760018
DCSW     DC    X'00'                    ERROR FLAG                      53860018
SIGN     DC    X'0'                     SIGN FOR PACKED                 53960018
DECSW    DC    X'0'                     FLAG - 1=COMMA, 2=QUOTE         54060018
         LTORG                                                          54160018
*                                                                       54260018
ZWRA     EQU   0                        REGISTERS- SCALE FACTOR         54360018
ZWRB     EQU   1                                   POINTER TO SCAN CHAR 54460018
ZWRC     EQU   GRC                                 WORKING SCALE FACTOR 54560018
ZWRD     EQU   GRD                                 LOWER LIMIT SCALE    54660018
ZWRE     EQU   4                                   UPPER LIMIT SCALE    54760018
ZWRF     EQU   5                                   LOW WORD OF RESULT   54860018
ZWRG     EQU   14                                  ADJECTIVE EXPONENT   54960018
ZWRH     EQU   15                                  BINARY RESULT        55060018
ZWRI     EQU   11                                  EXPONENT MODIFIER    55160018
ZWRJ     EQU   13                                  END POINTER          55260018
ZWRL     EQU   12                                  POSITION OF DEC PONT 55360018
CONDEX   EQU   ZWRB                     POINTER TO SCAN CHAR            55460018
CNT      EQU   ZWRF                     COUNTER FOR CHAR TO CONVERT     55560018
BINVAL   EQU   ZWRH                     BINARY VALUE-DECON              55660018
REG      EQU   ZWRG                     RETURN REGISTER-DECON           55760018
ZRCD11   EQU   11                       SCALE MODIFIER ERROR            55860018
ZRCD13   EQU   13                       EXPONENT MODIFIER ERROR         55960018
DCTRUN   EQU   17                       TRUNCATION ERROR                56060018
ZRCD39   EQU   39                       INVALID DELIMITER               56160018
ZRCD70   EQU   70           FLOATING POINT CHARACTERISTIC OUT OF RANGE  56260018
ZRCD109  EQU   109                      PRECISION LOST                  56360018
         END   DCNVRT1                                                  56460018
