F8P      TITLE 'F8PRNT -- ASSEMBLER F, PHASE 8   OUTPUT FORMATTING SR'  00020000
         ISEQ  73,80                                                    00040000
IEUF8P   START 0                                                        00060000
*          RELEASE 19 DELETIONS                                       * 00078000
* 113800-114400,118600,119200                                    A28241 00079019
* 159400                                                         190003 00080019
*          RELEASE 20 DELETIONS                                       * 00081000
* 039800,057600,171000                                             I000 00082020
* 036000,036400                                                  A28587 00083020
* 159400                                                          M0423 00083220
*          RELEASE 21 DELETIONS                                       * 00084000
*                                                                 21016 00086021
* 159400                                                          M0351 00086421
* 000750-000777,031400,044000-044200,044600,045400,046400,       A52832 00086521
* 052280,075000,077800,143440,147240-147320                      A52832 00086621
* 000870,159400                                                  A52832 00087021
*STATUS CHANGE LEVEL 014                                                00089021
*                                                                       00091020
* INCREMENTAL IMPROVEMENTS FOR RELEASE 20                               00093020
* I000 TSO IMPLEMENTATION                                               00095020
         USING RECORD,GRA                                               00100000
         USING MAINLN,FRB               FRB IS PRIMARY BASE REGISTER    00120000
         PRINT NODATA,NOGEN                                             00140000
         FDIMEN                                                         00160000
         PRINT DATA,GEN                                                 00180000
*                                                                     * 00200000
*TITLE 'IEUF8P  ' ...  PRINT                                          * 00220000
*FUNCTION/OPERATION-                                                  * 00260000
*   IEUF8P IS TO PRODUCE THE LISTING AND THE OBJECT DECK. TO DO THIS  * 00280000
*   IEUF8P HAS FOUR ENTRY POINTS-                                     * 00300000
*        PRNT-      PROCESS EDITED TEXT RECORD (LEFT HALF)  TYPE 100  * 00320000
*        BLDIMG     BUILDS SOURCE IMAGE (RIGHT HALF)        TYPE 110  * 00340000
*                                                                111  * 00360000
*        COMMENT    MOVES IN SOURCE IMAGE (RIGHT HALF)      TYPE 000  * 00380000
*                                                                010  * 00400000
*                                                                011  * 00420000
*                   PUTS OUT ERROR LINE                          001  * 00440000
*        LOADRA     PRINTS ERROR LINE                       TYPE 001  * 00460000
*ENTRY POINTS- SEE INDIVIDUAL ROUTINE                                 * 00480000
*INPUT- SEE INDIVIDUAL ROUTINE                                        * 00500000
*OUTPUT- SEE INDIVIDUAL ROUTINE                                       * 00520000
*EXTERNAL ROUTINES-                                                   * 00540000
*        NAME            ROUTINE   USE                                * 00560000
*        SYSP(SRB)       IEUF8I    PUNCH ON SYSGO AND/OR SYSPUNCH     * 00580000
*        WTERR(SRB)      IEUF8I    WRITE ERROR RECORD                 * 00600000
*        SYSL(SRB)       IEUF8I    PRINT ON SYSPRINT                  * 00620000
*             BEFORE THE ABOVE ROUTINES ARE CALLED, SRB IS LOADED     * 00640000
*             FROM CTXTIO(ACT).                                       * 00660000
*EXITS- ALL ROUTINE EXIT VIA-  BR  SRR                                * 00680000
*TABLES/WORKAREAS-                                                    * 00700000
*   LIST-     PUSH-DOWN POP-UP SAVE AREA                              * 00720000
*   H1-       HEADING ONE                                             * 00740000
*   H2-       HEADING TWO                                             * 00760000
*   DETAIL-   PRINT OUTPUT BUFFER                                     * 00780000
*   DUMOUT-   PRINT DUMMY OUTPUT BUFFER                               * 00800000
*   TXTOUT-   PUNCH OUTPUT BUFFER                                     * 00820000
*   LFTHLF-   LEFT HALF OF DETAIL RECORD                              * 00840000
*   SOURCE-   RIGHT HALF OF DETAIL RECORD                             * 00860000
*   IEUF8R-   INPUT BUFFER FOR PHASE 8                                * 00880000
*   INPUT-    INPUT SOURCE RECORD                                     * 00900000
*   ERREC     INPUT/OUTPUT ERROR RECORD                               * 00920000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 00940000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 00960000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 00980000
*                                                                     * 01000000
*                                                                       01005020
MKY      EQU   X'00'                    PRINT SWITCH MASK          I000 01010020
MKX      EQU   X'FF'                    PRINT SWITCH MASK          I000 01015020
         EJECT                                                          01020000
*                                                                     * 01040000
*TITLE 'PRNT' ... PROCESS EDITED TEXT RECORDS (LOAD LEFT HALF AND     * 01060000
*                 PRINT)                                              * 01080000
*ENTRY POINT-  PRNT(ACT)   CALLED VIA-                                * 01100000
*        L     SRB,PRNT(ACT)            LOAD BASE/ENTRY               * 01120000
*        BALR  SRR,SRB                  CALL PRNT                     * 01140000
*INPUT-  F8WORK(ACT)   INPUT RECORD                                   * 01160000
*        F8INST(ACT)   LEFT HALF TO BE PRINTED                        * 01180000
*OUTPUT- DETAIL        PRINT IMAGE FOR SYSL(SRB)                      * 01200000
*        TXTOUT        PUNCH IMAGE FOR SYSP(SRB)                      * 01220000
*                                                                     * 01240000
         SPACE 2                                                        01260000
MAINLN   EQU   *                                                        01280000
* ENTRY FOR LEFT HAND SIDE                                              01300000
PRNT00   BAL   GRX,CALLCF               SAVE REGISTERS                  01320000
         L     GRA,RECADDR              LOAD ADDRESS OF INPUT RECORD    01340000
         TM    REPSW(ACT),X'0F'         IS IT PUNCH,REPRO, MNOTE OR TTL 01360000
         BZ    PRNT01                   NO, SKIP                        01380000
*        ************************************************************** 01400000
TSTAOP   MVC   RLI(2),F8WORK+6(ACT)    POINTER                          01420000
         LH    GRX,RLI      TO 2ND                                      01440000
         LA    GR2,F8WORK(GRX,ACT)        OPERAND FIELD                 01460000
         MVC   RLIF+1(1),0(GR2)   MOVE 2ND OPND LENGTH TO ALIGNED CELL  01480000
         LH    GR1,RLIF                                                 01500000
         LTR   GR1,GR1                  IS 2ND OPRN LENGTH 0            01520000
         BNE   TSTAOP1                 NO                               01540000
         TM    REPSW(ACT),X'06'         IS THIS A REPRO                 01560000
         BC    11,RETNCF               NO                               01580000
REPROF7  NI    REPSW(ACT),X'FE'        TURN SWITCH TO 2 FOR F7 REPRO    01600000
         LA    GR1,80                  LENGTH OF REPRO                  01620000
TSTAOP1  BCTR  GR1,0                   REDUCE FOR MOVE                  01640000
         LA    GR2,1(GR2)               IF NOT BUMP BY 1                01660000
         LR    SP2,GR2                                                  01680000
         TM    REPSW(ACT),X'0C'         TEST MNOTE AND TITLE BITS       01700000
         BO    MNOTE00                 IF ONES, MNOTE                   01720000
         BM    TITLE00                 IF MIXED, TITLE                  01740000
         TM    REPSW(ACT),X'02'                                         01760000
         BO    REPRO00                IF 3, REPRO                       01780000
         B     PUNCH00                  IF 1, PUNCH                     01800000
MNOTE00  LA    GR1,1(GR1)               2ND OPRN LENGTH                 01820000
MNOTE01  LA    GRZ,SOURCE+C             SET PRINT LINE PTR TO CONT. COL 01840000
         MVI   LOC,XBLANK               BLANK OUT ENTIRE LINE     11992 01850014
         MVC   LOC+1(119),LOC           INCLUDING CONTINUE COLUMN 11992 01860014
         LA    GRB,E+1-C                MAX NO. OF BYTES PER LINE       01880000
         CR    GR1,GRB                                                  01900000
         BNH   NOCONT                   NO CONT. LINES NEEDED           01920000
* MORE BYTES REMAINING THAN WILL FIT ON ONE LINE                        01940000
         MVI   SOURCE+E+1,X'E7'         SET CONT. MARK ON               01960000
         SR    GR1,GRB                  DETERMINE OVERHANG              01980000
         STH   GR1,K                    SAVE FOR NEXT LINE              02000000
         LR    GR1,GRB                  MOVE MAX NO. OF BYTES           02020000
NOCONT   BCTR  GR1,0                    REDUCE FOR MOVE                 02040000
         EX    GR1,MOVES                MOVE                            02060000
         STM   GR1,GR2,SRRGRY          SAVE ADDR. OF 2ND OPRN           02080000
         BAL   SRR,MNOTE02              PUT OUT MNOTE                   02100000
*                                                                       02120000
         TM    SOURCE+E+1,XNOTBL        ARE BYTES REMAINING             02140000
         BZ    RETNCF                   NO,EXIT TO USER                 02160000
* CONTINUATIONS FOR MNOTE                                               02180000
         MVI   PUNSWH,X'FF'             TURN OFF PUNCH                  02200000
         BAL   SRR,CHKSWJ               PRINT MNOTE LINE                02220000
         LM    GR1,GR2,SRRGRY          RESTORE PTR TO 2ND OPRN          02240000
         LA    GR2,1(GR2,GR1)           ADJUST TEXT RECORD PTR          02260000
         LH    GR1,K                    PICK UP REMAINING BYTE COUNT    02280000
         OI    FLAGA,X'02'              SET CONTINUATION 'ON'           02300000
         B     MNOTE01                  RETURN FOR ANOTHER LINE         02320000
*                                                                       02340000
MNOTE02  BAL   GRX,CALLCF               SAVE REGISTERS                  02360000
         B     LOADRK                   LOAD RIGHT HALF                 02380000
TITLE00  MVI   HEADNG,XBLANK            EXTERNAL BLANK TO HEADING       02400000
         MVC   HEADNG+1(99),HEADNG      BLANK MOST OF HEADING           02420000
         LA    GRZ,HEADNG              ADDR. FOR MOVE                   02440000
         EX    GR1,MOVES                MOVE                            02460000
         L     GRA,RECADDR              LOAD ADDRESS OF INPUT RECORD    02480000
         B     INLCPL                                                   02500000
REPRO00  ST    GR2,SRRGRY             SAVE ADDR OF 2ND OPERAND          02520000
         MVI   PUNSWH,X'FF'               TURN OFF PUNCH                02540000
         MVC   DWORD(1),SOURCE-1        SAVE PRINT POSITION 40    11826 02544014
         CLI   SOURCE-1,XBLANK          WAS THIS STATEMENT GENERAT11826 02548014
         BE    REPRO01                  NO, PRINT IT              11826 02552014
         CLI   F8PGEN(ACT),X'FF'        DO WE PRINT GEN STATEMENT 11826 02556014
         BNE   REPRO01                  YES, PRINT IT             11826 02560014
         MVI   PRNTSW,X'FF'             SET NOT TO PRINT          11826 02564014
REPRO01  BAL   SRR,CHKSWH               GO PRINT 'REPRO'          11826 02568014
         MVC   SOURCE-1(1),DWORD        RESTORE PRINT POSITION 40 11826 02572014
         L     GR2,SRRGRY             RESTORE PTR TO 2ND OPND           02580000
         LA    GRZ,SOURCE                                               02600000
         EX    GR1,MOVES                                                02620000
         LA    GRX,CTSEQ8+2(ACT)       UPDATE STATEMENT NO.             02640000
         BAL   SRR,CNVRT                    AND                         02660000
         MVC   DSTMNT,DWORD             MOVE TO PRINT LINE              02680000
         BAL   SRR,CHKSWH               PRINT REPRO LINE          11826 02700014
         MVI   LSTRCD,X'40'            RESET LAST RECORD TYPE           02720000
         TM    REPSW(ACT),X'03'        IS THIS F8 REPRO                 02740000
         BM    RETNCF                  NO                               02760000
PUNCH00  BAL   GRB,DUMP           DUMP PUNCH BUFFER IF NEEDED           02780000
         LA    GRZ,DUMOUT+1       ADDR FOR MOVE                         02800000
         EX    GR1,MOVES                                                02820000
         LA    SP1,DUMOUT         ADDR FOR PUNCH                        02840000
         L     SRB,CTXTIO(ACT)          TEXT I/O BASE                   02860000
         BAL   SRR,SYSP(SRB)            ENTRY POINT TO PUNCH RTN        02880000
         MVI   DUMOUT+1,XBLANK    BLANK ENTIRE DUMOUT                   02900000
         MVC   DUMOUT+2(119),DUMOUT+1                                   02920000
         B     RETNCF                                                   02940000
MOVES    MVC   0(0,GRZ),0(GR2)          MOVE                            02960000
*        ************************************************************** 02980000
PRNT01   MVC   LFTHLF(4),CONSR             MOVE IN FLI AND FLAG         03000000
         MVC   XESDID(1),CESDID(ACT)    MOVE IN CURRENT ESD-ID          03020000
         MVC   LOCCTR(16),F8INST(ACT)   MOVE IN LEFT HAND SIDE          03040000
         MVC   FLAGA(1),F8WORK+2(ACT)                                   03060000
INLCPL   TM    SPACSW(ACT),X'FF'        IS SPACE SWITCH ON              03080000
         BZ    PRINT1                   NO, SKIP                        03100000
         BM    SPACERR                  SPACE ERROR                     03120000
         STH   SP2,BLKBLK               SPACE ON AND OK          A52832 03140021
         B     PRINT6                   NORMAL SPACE ROUTINE            03160000
SPACERR  MVI   SPACSW(ACT),X'00'       TURN SPACE SWITCH OFF            03180000
         B     INLCPL                                                   03200000
PRINT1   CLI   EJCTSW(ACT),X'FF'        IS EJECT SWITCH ON              03220000
         BE    PRINT7                   YES, EJECT                      03240000
* ANTICIPATE NEEDING LOCAL PRINT SWITCH ON AND LOCAL PUNCH SWITCH OFF   03260000
         MVI   PRNTSW,X'00'             NO, SET SWITCHES                03280000
         MVI   PUNSWH,X'FF'                                             03300000
         MVI   ALGSWH,X'FF'             SET ALIGNMENT SWITCH OFF        03320000
*                                                                       03340000
         TM    FLAGA,X'40'              LEFT HAND SIDE                  03360000
         BO    PRINT3                     YES                           03380000
         TM    FLAGA,X'20'                NO -- IS THIS AN ERROR REC    03400000
         BO    PRINT2                       NO -- CONTINUE              03420000
         TM    FLAGA,X'10'                  MAYBE -- LOOK AGAIN         03440000
         BO    PRINT4                         YES -- ERROR RECORD       03460000
* RECORD TYPE 000, 010 OR 011                                           03480000
PRINT2   TM    LSTRCD,X'40'        IS THERE A LINE TO BE PRINTED        03500000
         BO    PRNT2B                   NO -- CONTINUE                  03520000
         TM    LSTRCD,X'10'             MAYBE -- GEN SWITCH INVOLVED    03540000
         BZ    PRNT2A                   NO, GO AHEAD AND PRINT          03560000
         CLI   F8PGEN(ACT),X'FF'          YES - IS GEN SWITCH OFF       03580000
         BNE   PRNT2A                   ON -- PRINT              A28587 03590020
         MVI   PRNTSW,MKX               OFF - - BLANK LINE       A28587 03600020
PRNT2A   BAL   SRR,CHKSWH               PRINT LINE                      03620000
         MVI   PRNTSW,MKY               TURN PRINT SW ON         A28587 03640020
PRNT2B   B     LOADRERR               NOW LOAD THIS RIGHT HALF          03660000
* RECORD TYPE 100,110 OR 111                                            03680000
PRINT3   MVI   PUNSWH,0                 TURN PUNCH SWITCH ON            03700000
         MVN   LLTH+1(1),FLAG           SEPARATE BYTE COUNTS FROM IND'S 03720000
         TM    FLAGA,X'10'              SHOULD GEN. SWITCH BE CHECKED   03740000
         BZ    PRNT3A                    NO                             03760000
         CLI   F8PGEN(ACT),X'FF'        YES, IS GEN SWITCH OFF          03780000
         BE    PRNT3B                       YES -- TURN PRINT SW OFF    03800000
PRNT3A   TM    LSTRCD,X'40'             WAS LAST RECORD LEFT HLF SIDE   03820000
         BZ    PRNT3C                     NO                            03840000
         CLI   F8PDAT(ACT),X'00'        DO WE PRINT DATA                03860000
         BE    PRNT3C                       YES -- LOAD LEFT HALF       03880000
PRNT3B   MVI   PRNTSW,X'FF'                 NO -- TURN PRINT SW OFF     03900000
*                                                                       03920000
PRNT3C   BAL   SRR,LOADLH               NOW LOAD LEFT HALF              03940000
         CLI   ALGSWH,X'FF'        WAS ALIGNMENT DATA JUST PROCESSED    03960000
         BE    EXIT1                    NO                         I000 03980020
         B     EXIT2                 YES                                04000000
* ERROR RECORD                                                          04020000
PRINT4   MVC   PRNTER,CTEMERR(ACT)     SET LOCAL ERR SWITCH             04040000
         MVC   ERREC(4),F8WORK(ACT)    MOVE ERLI,EFLAG,NERR TO INPUT    04060000
         MVC   ESTMNT(2),CTSEQ8+2(ACT) INSERT STATEMENT NO.             04080000
         LH    GRX,ERLI                UP REC LENGTH BY 2               04100000
         LA    GRX,2(GRX)                                               04120000
         STH   GRX,ERLI                                                 04140000
         LA    GR1,7                                                    04160000
         SR    GRX,GR1                 NO. REMAINING BYTES MINUS ONE    04180000
         BM    PRNT4A                   IF MINUS DONT MOVE              04200000
         EX    GRX,MVERCD              MOVE REMAINDER OF ERR REC        04220000
PRNT4A   LA    SP1,ERREC                LOAD ADDR. OF REFORMATTED REC   04240000
         L     SRB,CTXTIO(ACT)          LOAD BASE                       04260000
         BAL   SRR,WTERR(SRB)          PUR ERR REC IN TEXT STREAM       04280000
         B     RETNCF                  AND RETURN                       04300000
MVERCD   MVC   ERR1(0),F8WORK+4(ACT)    EXECUTED MOVE                   04320000
* SPACE RECORD                                                          04340000
*                                                                       04360000
PRINT6   MVI   SPACSW(ACT),X'00'        TURN OFF SPACE SWITCH           04380000
         LH    GRY,BLKCNT              ACCUMULATE BLANK LINE CNT A52832 04400021
         LH    GR1,BLKBLK              FOR SUCCESSIVE 'SPACE'OPS A52832 04420021
         AR    GRY,GR1                    (CALLCF HAS JUST USED GRY AND 04440000
         STH   GRY,BLKCNT               BLANK LINE COUNTER       A52832 04460021
         B     PRNT7B                   CONTINUE                        04480000
* EJECT RECORD                                                          04500000
*                                                                       04520000
PRINT7   CLC   BLKCNT,LCNT              IS THERE A LARGE SPACE   A52832 04540021
         BNH   PRNT7A                    WAITING  - NO                  04560021
         BAL   SRR,PGEHED                 YES -- EJECT FOR BIG SPACE    04580000
PRNT7A   BAL   SRR,PGEHED              EJECT TO A NEW PAGE              04600000
         MVI   EJCTSW(ACT),X'00'        TURN EJECT SWITCH OFF           04620000
         MVC   BLKCNT,HONE            SET BLNK LINE CNT FOR 1ST  A52832 04640021
PRNT7B   MVI   DETAIL+1,XBLANK          BLANK OUT ENTIRE                04660000
         MVC   DETAIL+2(119),DETAIL+1     DETAIL LINE                   04680000
         MVI   LSTRCD,X'40'             SET LAST RECORD LEFT HALF       04700000
         B     RETNCF                   RETURN TO CALLER                04720000
         EJECT                                                          04740000
*                                                                     * 04760000
*TITLE 'LOADRA'  ... PRINT ERROR RECORD IF AT END                     * 04780000
*ENTRY POINTS- LODRA  CALLED VIA-                                     * 04800000
*        EXTERN  LOADRA                                               * 04820000
*        L     FRB,PRTN(ACT)            LOAD BASE                     * 04840000
*        L     GRX,=A(LOADRA)           LOAD ENTRY                    * 04860000
*        BALR  SRR,GRX                  CALL LOADRA                   * 04880000
*NOTES- LOADRA IN THE MIDDLE OF LOADING THE RIGHT HALF AND THIS ENTRY * 04900000
*       IS USED IF THERE WAS AN ERROR ON THE LAST CARD.               * 04920000
*        ************************************************************** 04940000
*        LOAD RIGHT HALF OF OUTPUT PAGE                                 04960000
*        ************************************************************** 04980000
* CHECK FOR POSSIBLE ERROR MESSAGE ASSOCIATED WITH LAST STATEMENT       05000000
*                                                                       05020000
LOADRA   MVI   PUNSWH,X'FF'            TURN OFF PUNCH                   05040000
         BAL   GRX,CALLCF               PRINT LINE IF ERROR IN END      05060000
         L     GRA,RECADDR             LOAD ADDR.. OF INPUT REC.        05080000
LOADRERR CLI   PRNTER,X'FF'         IS PRINT ERR. MESSAGE SWITCH ON     05100000
         BNE   LOADRI                NO -- CONTINUE WITH LOAD RGT HLF   05120000
         TM    LSTRCD,X'10'          YES - PRINT LAST STMNT FCN GEN SW  05140000
         BZ    LOADRB                  NO -- PRINT ERROR MESSAGE        05160000
         CLI   F8PGEN(ACT),X'FF'       YES - CHECK GEN SWITCH           05180000
         BE    LOADRH                    NOGEN IS OPTION -- SKIP MSG    05200000
* PRINT ERROR MESSAGE                                                   05220000
LOADRB   CLC   CTSEQ8+2(2,ACT),HZERO    IS ERROR BEFORE FIRST    A52832 05228021
*                                       STMT                      M3203 05236018
         BE    LOADRH                   YES,DO NOT PRINT *ERROR*  M3203 05244018
         MVC   DUMOUT+10(13),ERRMSG     USE DUMOUT AREA           M3203 05252018
         LA    GRB,DUMOUT                 FOR PRINT BUFFER              05260000
         CLI   LCNT+1,X'00'             ENOUGH ROOM ON THIS PAGE        05280000
         BH    LOADRF                     YES                           05300000
         MVI   LCNT+1,X'01'               NO -- WELL, MAKE ROOM         05320000
LOADRF   BAL   SRR,DMPLIN               PRINT THE LINE OUT              05340000
LOADRH   MVI   PRNTER,X'00'             RESET PRINT ERR MSG SWITCH      05360000
LOADRI   TM    REPSW(ACT),X'0F'    IS THIS MNOTE                        05380000
         BO    TSTAOP            YES                                    05400000
         SR    GRB,GRB                  MOVE 1, 2, ... 80 BYTE          05420000
         IC    GRB,1(GRA)                 SOURCE IMAGE                  05440000
         LA     GRB,252(GRB)            DECREASE LOW BYTE OF GRB BY 4   05460000
         EX     GRB,MOVCRD                BY ADDING COMPLEMENT OF 4     05480000
         L     GRC,CTRTBP(ACT)         ADDRESS OF TRANSLATE TABLE       05500000
         EX    GRB,TRANS                   MOVE AND TRANSLATE           05520000
         MVI   CTEMERR(ACT),X'FF'       TURN ON MNOTE                   05540000
LOADRK   TM    FLAGA,X'10'              WAS THIS SOURCE REC GENERATED   05560000
         BZ    LOADRJ                     NO                            05580000
          MVI  SOURCE-1,C'+'              YES - PLACE A '+' IN LISTING  05600000
LOADRJ   TM    FLAGA,X'02'             CONTINUATION BIT ON              05620000
         BO    EXIT                    YES - LEAVE STMNT. NO. BLANK     05640000
         TM    FLAGA,X'30'                NO -- TYPE 110, NON-LITR      05660000
         BM    EXIT                    YES - SKIP STMNT. NO.            05680000
         LA    GRX,CTSEQ8+2(ACT)       PICK UP STATEMENT NO., INCREASE  05700000
         BAL   SRR,CNVRT                  BY 1, CONVERT TO EXTERNAL     05720000
         MVC   DSTMNT,DWORD                 AND MOVE TO DETAIL LINE     05740000
EXIT     LH    SP2,FLAGA                PASS FLAGA TO PUTER        I000 05746020
         LA    SP1,DSTMNT               SOURCE IN TERM BUFFER      I000 05752020
         L     SRB,CTXTIO(ACT)          LOAD BASE                  I000 05758020
         BAL   SRR,PUTXT(SRB)           SOURCE IN BUFFER FOR UT3   I000 05764020
EXIT1    MVC   LSTRCD,FLAGA             CURRENT TYPE TO LAST RCD   I000 05770020
EXIT2    MVI   FLAG,X'00'               RESET F8PRNT WORKAREA FLAG      05780000
         B     RETNCF                       AND EXIT                    05800000
MOVCRD   MVC   SOURCE(0),CARD           EXECUTED MOVE                   05820000
TRANS    TR    SOURCE(0),0(GRC)         EXECUTED TRANSLATE              05840000
*        ************************************************************** 05860000
*        LOAD LEFT HALF OF OUTPUT PAGE                                  05880000
*        ************************************************************** 05900000
LOADLH   UNPK  WORK(15),LOCCTR(8)       1ST 14 HEX DIGITS + 1 HEX JUNK  05920000
         UNPK  WORK+14(15),SSB2D2(8)    15TH THROUGH 29TH               05940000
         MVC   WORK+29(1),EA2+2         30TH                            05960000
         LA    1,8                      LOOP 8 TIMES THROUGH WORK       05980000
         LA    2,WORK                   LOAD ADDRESS OF MACHINE INST    06000000
LOOPLH   NC    0(4,2),MASK              MASK FOR TRANSLATE              06020000
         LA    2,4(2)                   UP TO NEXT WORD                 06040000
         BCT   1,LOOPLH                 TEST FOR END OF WORK            06060000
         L     GRB,CTRTBP(ACT)         ADDRESS OF TRANSLATE TABLE       06080000
         TR    WORK(30),0(GRB)          TRANSLATE ALL 30 EXPANDED BYTES 06100000
         CLI   LLTH+1,X'0F'             SHOULD LOCCTR COLUMN BE BLANK   06120000
         BNE   LOADLX                     NO                            06140000
         MVI   LLTH+1,X'00'               YES -- RESET BYTE COUNT       06160000
         B     CHKSWH                       AND CHECK PRINT/NO PRINT    06180000
LOADLX   MVC   LOC(6),WORK              MOVE LOCATION COUNTER           06200000
         TM    FLAG,X'F0'              IS THIS A DS STATEMENT           06220000
         BO    CHKSWH                   YES -- JUMP TO PRINT ROUTINE    06240000
         TM    FLAG,X'80'               NO --- IS THIS ALIGNMENT DATA   06260000
         BO    ALIGN                     YES -- GO TO ALIGNMENT ROUTINE 06280000
         TM    FLAG,X'40'                NO --- TEST FOR DC             06300000
         BO    DCLH                       YES -- GO TO DC/DS SECTION    06320000
         LA    GRX,CHKSWH                 NO --- TREAT AS MACH INSTR    06340000
         CLI   FLAG,X'00'               FIRST -- CHECK IF BYTE COUNT 0  06360000
         BCR   8,GRX                      YES -- JUMP TO CHKSWH         06380000
         TM    FLAG,X'30'                 NO --- DETERMINE SYLLABLE CNT 06400000
         BZ    BYTE2                        CNT = 2 -- SKIP LAST 2 SYLL 06420000
         BM    BYTE4                        CNT = 4 -- SKIP LAST SYLL   06440000
BYTE6    MVC   LOC+17(4),WORK+14            CNT = 6 -- MOVE ALL 3 SYLL  06460000
BYTE4    MVC   LOC+12(4),WORK+10         MOVE 2ND SYLLABLE              06480000
BYTE2    MVC   LOC+7(4),WORK+6           MOVE 1ST SYLLABLE              06500000
* CHECK FOR PRESENCE OF EFFECTIVE ADDRESS 1                             06520000
CHKEA1   TM    FLAG,X'20'              EFFECTIVE ADDRESS 1 PRESENT      06540000
         BZ    CHKEA2                    NO --- GO CHECK FOR EA2        06560000
         MVC   LOC+21(6),WORK+18         YES -- MOVE IT                 06580000
         CLI   LOC+21,X'F0'             DOES EA1 HAVE LEADING ZERO      06600000
         BNE   CHKEA2                    NO --- LEAVE IT AS IS          06620000
         MVI   LOC+21,XBLANK              YES -- REPLACE BY BBLANK      06640000
* CHECK FOR PRESENCE OF EFFECTIVE ADDRESS 2                             06660000
CHKEA2   TM    FLAG,X'10'              EFFECTIVE ADDRESS 2 PRESENT      06680000
         BCR   8,GRX                     NO --- SKIP TO CHKSWH          06700000
         MVC   LOC+27(6),WORK+24         YES -- MOVE IT                 06720000
         CLI   LOC+27,X'F0'             DOES EA2 HAVE LEADING ZERO      06740000
         BCR   7,GRX                     NO                             06760000
         MVI   LOC+27,XBLANK              YES -- REPLACE BY BLANK       06780000
         BCR   15,GRX                   TO CKSWH                        06800000
*                                                                       06820000
ALIGN    MVI   ALGSWH,X'00'             TURN ALIGNMENT DATA SWITCH ON   06840000
         MVI   PUNSWH,X'00'               TURN PUNCH SWITCH ON          06860000
         MVC   DUMOUT+1(6),WORK         MOVE LOCATION COUNTER           06880000
         LA    GRB,DUMOUT               LOAD ADDRESS OF DUMMY LINE      06900000
         LH    GRX,LLTH                 PICK UP BYTE COUNT,             06920000
         AR    GRX,GRX                    DOUBLE IT,                    06940000
         BZ    CHKSWH                     (SKIP MOVE IF 0 ALIGN BYTES)  06960000
         BCTR  GRX,0                        REDUCE BY 1 AND             06980000
         EX    GRX,MOVALG                     MOVE ALIGNMENT DATA       07000000
         B     CHKSWHX                  PRINT ALIGNMENT IF PRINT SW ON  07020000
*                                                                       07040000
MOVALG   MVC   DUMOUT+8(1),WORK+6       MOVE ALIGNMENT BYTES            07060000
MOVDC    MVC   LOC+7(1),WORK+6          MOVE DC BYTES                   07080000
*                                                                       07100000
DCLH     LH    1,LLTH                   GET DC LENGTH                   07120000
         AR    1,1                      DOUBLE DC LENGTH                07140000
         BZ    CHKSWH                   SKIP MOVE IF NO DC BYTES        07160000
         BCTR  1,0                      REDUCE BY ONE FOR EXECUTED MOVE 07180000
         EX    1,MOVDC                  GO MOVE DC TO OUTPUT            07200000
*        ************************************************************** 07220000
*        PRINT ROUTINE                                                  07240000
*        ************************************************************** 07260000
CHKSWH   LA    GRB,DETAIL               PICK UP POINTER TO DETAIL LINE  07280000
CHKSWHX  CLI   PRNTSW,X'FF'             IS PRINT SWITCH ON              07300000
         BE    CLEAR                      NO -- CLEAR LINE              07320000
         B     DMPLIN                     YES, PRINT LINE               07340000
*                                                                       07360000
CHKSWJ   LA    GRB,DETAIL                LOAD ADDRESS OF DETAIL LINE    07380000
*                                                                       07400000
DMPLIN   CLI   F8PON(ACT),X'FF'         PRINTS = X'00' IF PRINT ASSEM   07420000
         BE    CLEAR                      OP IS ON, = X'FF' IF OFF      07440000
         SR    GRD,GRD                  ZERO SO CAN INSERT CHAR         07460000
         ST    SRR,REGHLD               STORE RETURN REGISTER           07480000
         LH    GRD,BLKCNT               PICK UP BLANK LINE COUNT A52832 07500021
         CH    GRD,LCNT                 TEST IF THERE IS ENOUGH ROOM    07520000
         BL    DMPLNB                     YES -- CONTINUE TO DMPLNB     07540000
         BAL   SRR,PGEHED                 NO --- PRINT HEADING          07560000
         LA    GRD,1                        AND SET BLANK LINE COUNT 1  07580000
DMPLNB   STC   GRD,0(GRB)               ONE BLANK LINE AFTER HEADING    07600000
         LR    SP1,GRB                  PICK UP LOCATION OF LINE        07620000
         L     SRB,CTXTIO(ACT)          LOAD BASE                       07640000
         BAL   SRR,SYSL(SRB)            CALL SYSLIST                    07660000
         LH    GRX,LCNT                 ADJUST                          07680000
         SR    GRX,GRD                    LCNT                          07700000
         BCTR  GRX,0                        FOR LINE                    07720000
         STH   GRX,LCNT                       JUST PRINTED              07740000
         L     SRR,REGHLD               RESTORE SRR NOW                 07760000
         MVC   BLKCNT,HZERO             RESET BLANK LINE COUNT   A52832 07780021
* CLEAR DETAIL OR DUMMY LINE NOW WHETHER PRINTING TOOK PLACE OR NOT     07800000
CLEAR    MVI   1(GRB),XBLANK            CLEAR FIRST POSITION TO BLANK   07820000
         MVC   2(119,GRB),1(GRB)          CLEAR NEXT 119                07840000
*                                                                       07860000
ENDPRN   CLI   PUNSWH,X'00'             TEST LOCAL PUNCH SWITCH         07880000
         BE    GOTXT                      ON --- GO TO PUNCH ROUTINE    07900000
         BR    SRR                        OFF -- RETURN TO USER NOW     07920000
*        ************************************************************** 07940000
*        PAGE HEADING ROUTINE                                           07960000
*        ************************************************************** 07980000
PGEHED   CLI   F8PON(ACT),X'FF'         PRINTS = X'00' IF PRINT ASSEM   08000000
         BCR   8,SRR                      OP IS 'ON', = X'FF' IF 'OFF'  08020000
         ST    SRR,REGHLD+4             STORE RETURN REG                08040000
         LA    GRX,PGNO                 UPDATE PAGE NUMBER              08060000
         BAL   SRR,CNVRT                  AND STORE                     08080000
         MVC   PCNT,DWORD                   IN PRIMARY HEADER LINE      08100000
         MVC   DECKNM(4),CTITLE(ACT)   MOVE DECK ID TO OUTPUT LINE      08120000
         LA    SP1,H1                    NOW EJECT AND PRINT            08140000
         MVI   H1SPC,X'60'                    PRIMARY HEADING LINE      08160000
         L     SRB,CTXTIO(ACT)          LOAD BASE                       08180000
         BAL   SRR,SYSL(SRB)            CALL SYSLIST                    08200000
PGEHDD   IC    GRX,CTPGLNCT(ACT)        GET PAGE LINE COUNT             08220000
         LA    GRX,1(GRX)              RESTORE DETAIL LINE COUNT        08240000
         STC   GRX,LCNT+1              PLUS 1                           08260000
         MVC   DATE(8),CTDATE(ACT)      CURRENT DATE TO HEADING LINE    08280000
         MVC   CTLITB(9,ACT),LEVEL      SAVE REL.DATE FOR END CD  IEUN6 08286018
* CTLITB IS SCRATCH AFTER F7.  REUSED FOR END CARD STUFF.         IEUN6 08292018
         LA    SP1,H2                   LOAD ADDRESS OF HEADING LINE 2  08300000
         MVI   H2SPC,X'02'              DOUBLE SPACE                    08320000
         BAL   SRR,SYSL(SRB)           PRINT SECONDARY HEADING          08340000
         L     SRR,REGHLD+4             GET RETURN ADDRESS              08360000
         BR    SRR                      RETURN TO USER                  08380000
*        ************************************************************** 08400000
*        UPDATE STATEMENT, PAGE AND CARD SEQUENCE NUMBERS               08420000
*        ************************************************************** 08440000
CNVRT    LH    GRZ,0(GRX)                                               08460000
         LA    GRZ,1(GRZ)               INCREASE NUMBER AND             08480000
         N     GRZ,=X'0000FFFF'         REMOVE PROPOGATED SIGN    IEUN3 08490018
         STH   GRZ,0(GRX)                 SAVE IT IN BINARY             08500000
CNVRTX   CVD   GRZ,DWORD                CONVERT TO DECIMAL              08520000
         UNPK  DWORD(5),DWORD+5(3)      UNPACK                    IEUN3 08530018
         OI    DWORD+4,X'F0'            AND GET RID OF SIGN       IEUN3 08540018
         MVC   SAVSEQ,DWORD+1      SAVE DEC. NO. WTH LDING ZEROS  IEUN3 08550018
         SPACE 1                                                  IEUN3 08560018
* REPLACE LEADING ZEROS OF 4 BYTE WORD AT DWORD WITH BLANKS             08600000
*   BUT FIRST MOVE RAW NUMBER (LEADING ZEROS AND ALL) TO LOCATION SEQ   08620000
         LA    GRY,DWORD                GET ADDRESS OF DWORD            08640000
SUPR     TM    0(GRY),X'0F'             IS CHAR A ZERO                  08660000
         BCR   4,SRR                    NO, EXIT                        08680000
         MVI   0(GRY),X'40'             YES, REPLACE WITH BLANK         08700000
         LA    GRY,1(GRY)               UP TO NEXT CHAR                 08720000
         B     SUPR                     LOOP FOR ALL LEADING ZEROES     08740000
*        ************************************************************** 08760000
*        PUNCH ROUTINE                                                  08780000
*        ************************************************************** 08800000
GOTXT    BAL   GRX,CALLCF               SAVE REGISTERS 4-9.             08820000
         TM    FLAG,X'F0'               IS THIS A DS STATEMENT          08840000
         BC    12,JUMP1                 NO                              08860000
         BAL   GRB,DUMP                 YES, DUMP PUNCH BUFFER          08880000
         B     RETNCF                   AND EXIT.                       08900000
JUMP1    CLI   LLTH+1,0                 IS THERE ANY DATA TO MOVE       08920000
         BC    8,RETNCF                 NO, EXIT.                       08940000
         CLC   ESDIDX,CESDID(ACT)       IS THIS A NEW ESD/ID            08960000
         BE    JUMP2                    YES                             08980000
         BAL   GRB,DUMP                 NO, DUMP PUNCH BUFFER.          09000000
JUMP2    TM    CESDIDPS(ACT),X'FF'      IS THIS DSECT OR COMMON         09020000
         BC    8,RETNCF                 EXIT.                           09040000
         CLI   BYTCNT+1,0               IS BYTE COUNT = 0               09060000
         BNE   NFRST                    NO, CONTINUE FILLING SAME CARD. 09080000
         MVC   ADDR,LOCCTR              YES, START NEW CARD. MOVE       09100000
         MVC   ESDIDX,CESDID(ACT)       CHANGE TO CURRENT ESD/ID        09120000
         LA    GRX,CCRDCT(ACT)         UPDATE DACK SEQ NO.              09140000
         BAL   SRR,CNVRT                CONVERT IT TO DECIMAL           09160000
         MVC   SEQ,SAVSEQ               MOVE IN WITH LEADING ZEROES     09180000
         MVC   IDRH(4),CTITLE(ACT)      MOVE IN DECK NAME               09200000
         LA    GRX,TXTOUT-1       SAVE ADDR. OF CARD IMAGE              09220000
         ST    GRX,CTLDCP(ACT)                   IN ACT TABLE           09240000
         LA    GRA,INS                  O/P AND SET O/P PTR TO COL. 17  09260000
         B     NFRSTB                   SKIP                            09280000
NFRST    L     GRA,OUTPOI               PICK UP DYNAMIC O/P PTR.        09300000
NFRSTB   LA    GRC,OPCODE               LOAD PTR TO 1ST BYTE TO PUNCH   09320000
         LH    GRD,LLTH                 LOAD NUMBER OF BYTES TO PUNCH.  09340000
         LH    SRB,BYTCNT               LOAD DYNAMIC BYTE COUNT.        09360000
LOOPA    MVC   0(1,GRA),0(GRC)          MOVE ONE BYTE TO PUNCH BUFFER.  09380000
         LA    GRC,1(GRC)               KICK SENDING POINTER.           09400000
         LA    GRA,1(GRA)               KICK RECEIVING POINTER.         09420000
         LA    SRB,1(SRB)               KICK BYTE COUNT                 09440000
         LA    GR1,56                   FOR COMPARE                     09460000
         CR    SRB,GR1                  DOES BYTE COUNT = 56            09480000
         BNE   MORTXT                   NO, BRANCH TO LOOP CONTROL.     09500000
         STH   SRB,BYTCNT               YES, STORE BYTE COUNT IN O/P.   09520000
         BAL   GRB,DUMP                 DUMP PUNCH BUFFER.              09540000
         LA    GR1,1                    FOR COMPARE                     09560000
         CR    GRD,GR1            MORE LLTH BYTES TO MOVE?              09580000
         BE    NOMORE                  NO                               09600000
         LA    GRX,CCRDCT(ACT)         UPDATE DECK SEQ. NO.             09620000
         BAL   SRR,CNVRT                CONVERT TO DECIMAL              09640000
         MVC   SEQ,SAVSEQ               MOVE IN NUMBER                  09660000
         LA    GRX,TXTOUT-1        SAVE ADDR. OF CARD IMAGE             09680000
         ST    GRX,CTLDCP(ACT)         IN ACT TABLE                     09700000
NOMORE   LA    GR1,56                  KICK LOADING ADDRESS IN          09720000
         A     GR1,TXTOUT+4             PUNCH BUFFER BY 56.             09740000
         ST    GR1,TXTOUT+4                                             09760000
         LA    GRA,INS                  RESET O/P POINTER TO COL. 17    09780000
         SR    SRB,SRB                  SET REGISTER BYTE COUNT = 0.    09800000
MORTXT   BCT   GRD,LOOPA                LOOP UNTIL LLTH BYTES MOVED.    09820000
         STH   SRB,BYTCNT               STORE DYNAMIC BYTE COUNT        09840000
         ST    GRA,OUTPOI               STORE DYNAMIC O/P POINTER.      09860000
         B     RETNCF                   EXIT PUNCH ROUTINE.             09880000
* DUMP PUNCH BUFFER                                                     09900000
DUMP     CLI   BYTCNT+1,0               DOES BYTE COUNT = 0.            09920000
         BCR   8,GRB                    YES, RETURN TO LOCAL USER.      09940000
         ST    GRB,REGHLD              SAVE REGS                        09960000
         STM   GR1,GR2,REGHLD+4         ALL OF THEM                     09980000
         LA    SP1,TXTOUT-1             PICK UP ADDR OF CARD IMAGE AND  10000000
         L     SRB,CTXTIO(ACT)          LOAD BASE                       10020000
         BAL   SRR,SYSP(SRB)            CALL SYSPUNCH                   10040000
         L     GRB,REGHLD                                               10060000
         LM    GR1,GR2,REGHLD+4        RESTORE REGS                     10080000
         SR    GRX,GRX              SET TO ZERO WHEN                    10100000
         ST    GRX,CTLDCP(ACT)                  PUNCH BUFFER EMPTY      10120000
         MVI   INS,X'40'                  CLEAR CARD AREA               10140000
         MVC   INS+1(55),INS                  AND                       10160000
         MVI   BYTCNT+1,0               RESET DYNAMIC BYTE COUNT TO 0.  10180000
         BR    GRB                              RETURN TO LOCAL USER    10200000
         EJECT                                                          10220000
*                                                                     * 10240000
*TITLE- 'BLDIMG' ...  BUILD RIGHT HALF                                * 10260000
*ENTRY- BLDIMG  CALLED VIA-                                           * 10280000
*        EXTERN  BLDIMG                                               * 10300000
*        L     FRB,PRNT(ACT)            LOAD BASE                     * 10320000
*        L     GRX,=A(BLDIMG)           LOAD ENTRY                    * 10340000
*        BALR  SRR,GRX                  CALL BLDIMG                   * 10360000
*INPUT-  F8WORK(ACT)     INPUT RECORD                                 * 10380000
*OUTPUT- SOURCE          BUILT CARD IMAGE                             * 10400000
*NOTES-                                                               * 10420000
*   BLDIMG BUILDS THE RIGHT HALF OF THE OUTPUT LINE (DETAIL) FROM THE * 10440000
*   EDITED TEXT RECORD FOR RECORD TYPES 6 (LITERALS, CONDITIONAL      * 10460000
*   ASSEMBLY) AND 7 (TEXT AND MNOTE GENERATED BY MACRO EXPANSION).    * 10480000
*                                                                     * 10500000
         SPACE 2                                                        10520000
BLDIMG   BAL   GRX,CALLCF               SAVE REGISTERS                  10540000
         L     GRA,RECADDR              LOAD ADDRESS OF INPUT RECORD    10560000
         TM    F8WORK+3(ACT),X'80'     IS THIS AN ASSEMBLER OP          10580000
         BZ    BLDIMG0                 IF ZERO,NOT ASSEMBLRT OP         10600000
         CLI   F8WORK+4(ACT),MNOTEX     IS RECORD MNOTE                 10620000
         BNE   BLDIMG0                 IF NOT EQUAL BUILD IMAGE         10640000
         MVC   RLI(2),F8WORK+6(ACT)    POINT TO                         10660000
         LH    GRX,RLI                      1ST CHARACTER               10680000
         LA    GR2,F8WORK(GRX,ACT)               IN 2ND COMMENT FIELD   10700000
         LA    GR2,1(GR2)               LOOK AT NEXT CHAR               10720000
         CLI   0(GR2),X'5C'            IS THIS *                        10740000
         BE    MNOTERR                 YES                              10760000
MNOTEOP  MVI   CTEMERR(ACT),X'00'        SET MNOTE ERROR 37 FLAG        10780000
MNOTERR  MVI   FLAGA,X'00'        MAKE STMNT LOOK LIKE SOURCE           10800000
         MVI   REPSW(ACT),X'0F'            SET MNOTE                    10820000
         B     INLCPL                   PROCESS MNOTE                   10840000
BLDIMG0  MVC   FLAGX(1),F8WORK+2(ACT)   PICK UP EDITED REC FLAG         10860000
BLDIMG2  MVC   RLIX(2),RLIC             INITIALIZE 1ST 2 BYTES OF REC   10880000
         NI    FLAGX,X'34'              IF EDITED RECORD TYPE IS '111', 10900000
         TM    F8WORK+2(ACT),X'70'           MAKE GENERATED RECORD TYPE 10920000
         BO    BLDXX       '011'.  IF GENERATED REC                     10940000
         TM    F8WORK+3(ACT),X'40'           TYPE IS '110',MAKE GENERA- 10960000
         BO    BLDXX                        TED TYPE '010' UNLESS ED    10980000
         CLI   F8WORK+4(ACT),KLITR            REC IS LITR--IF SO,       11000000
         BNE   BLDXX                          MAKE GENERATED REC TYPE   11020000
         NI    FLAGX,X'DF'                     '000'                    11040000
*  START WITH NAME FIELD AND WORK FORWARD                               11060000
BLDXX    SR    GRB,GRB                  ZERO SO CAN INSERT CHARACTER    11080000
         BAL   SRR,CLEARA               CLEAR 80 BYTE AREA              11100000
         LA    GRD,CARD+B               SET RGT HAND PTR = BEGIN COLUMN 11120000
         IC    GRB,F8WORK+8(ACT)        PICK UP LENGTH OF NAME FIELD    11140000
         LA    GRC,F8WORK+9(ACT)          AND POINTER TO THE NAME       11160000
         SR    GRX,GRX                  ZERO SO CAN INSERT CHARACTER    11180000
         IC    GRX,F8WORK+7(ACT)        NOW COMPUTE TOTAL ALLOWABLE     11200000
         LA    GRY,12                     LENGTH FOR NAME, OPCODE,      11220000
         SR    GRX,GRY                      OPERAND AND COMMENT AND     11240000
         LR    GRZ,GRX                        SAVE IN GRZ               11260000
         LA    GRX,9                    CALL C(GRA) = DELTA             11280000
         BAL   SRR,CHECK                CHECK NAME FOR WORKABLE LENGTH  11300000
NAME     BAL   SRR,TRSLMV                 LENGTH = MINUMUM(LN, DELTA,   11320000
         BAL   SRR,RESTORE                  9) -- STEP ON TO OPCODE     11340000
         LA    GRD,CARD+9                     AFTER REDUCING DELTA      11360000
         BAL   SRR,CHECK               LENGTH=MIN(LOP,DELTA,9)   A28241 11370019
         BAL   SRR,TRSLMV                                        A28241 11380019
         LA    GRD,CARD+C              GRD->OPERAND/CONTINUE COL A28241 11390019
         CH    GRB,=H'4'               GRB =(MIN(LOP,DELTA,9)-1) A28241 11400019
         BNH   COL16OK                 LOP LT 5 SO COL 16 OK     A28241 11410019
         LA    GRD,3(GRD)              LOP GT 5 SO USE COL 19    A28241 11420019
COL16OK  BAL   SRR,RESTORE                                       A28241 11430019
* COMBINE OPERAND AND COMMENTS INTO ONE GIANT FIELD                     11460000
OPRND    LA    GRX,0(GRB,GRC)           LOCATE LCMNT = LGTH OF COMMENT  11480000
         SR    GRY,GRY                  ZERO FOR CHARACTER INSERTION    11500000
         IC    GRY,0(GRX)               LOAD GRY WITH VALUE OF LCMNT    11520000
         STM   GRX,GRY,SVCMNT             AND SAVE PTR, VALUE           11540000
         EX    GRY,MVCMNT               MOVE COMMENT NEXT TO OPERAND    11560000
         LA    GRB,0(GRY,GRB)           GRB = LGTH OPND + LGTH COMMENT  11580000
         LA    GRX,1000                 ALLOWABLE LENGTH FOR COMBINED   11600000
         BAL   SRR,CHECK                  OPERAND AND COMMENT IS        11620000
         LTR   GRB,GRB                      MINIMUM(INFINITY, LOPN+     11640000
         BZ    BCD                            LCMNT, DELTA)             11660000
OPRNDA   LA    GRX,0(GRC,GRB)           IF C(GRB) NON-ZERO, CHECK END   11680000
         BCTR  GRX,0                      OF COMBINED STRING FOR BLANKS 11700000
OPRNDB   CLI   0(GRX),BLNK                  DECR GRB TO ELIMINATE       11720000
         BNE   OPRNDD                         TRAILING BLANKS           11740000
         BCTR  GRX,0                                                    11760000
         BCT   GRB,OPRNDB               WRITE OUT NAME AND OPCODE IF    11780000
         B     BCD                        OPERAND + COMMENT IS ALL BLNK 11800000
MVCMNT   MVC   0(0,GRX),1(GRX)          EXECUTED MOVE                   11820000
*                                                                       11840000
OPRNDD   EQU   *                                                 A28241 11860019
*                                                                       11880000
BB       MVI   CARD+E+1,KBLANK          SET CONTINUE SWITCH OFF         11900000
         LA    GRP,CARD+E+1            SET GRP=E+1-C, OR E+1-C-3 A28241 11910019
         SR    GRP,GRD                 IF OPD STARTS IN COL 19   A28241 11920019
         CR    GRB,GRP                  ARE THERE TOO MANY BYTES        11940000
         BNH   BC                       NO                              11960000
* MORE BYTES REMAINING THAN WILL FIT IN CURRENT 80 BYTE BUFFER          11980000
         MVI   CARD+E+1,KX              TURN CONTINUE SWITCH ON         12000000
         SR    GRB,GRP                  DETERMINE OVERHANG              12020000
         STH   GRB,K                    SAVE FOR NEXT LINE              12040000
         LR    GRB,GRP                  SET RHPTR = MAXIMUM REMAINING   12060000
*                                                                       12080000
BC       BAL   SRR,TRSLMV               MOVE IN BYTES                   12100000
BCD      L     GRA,RECADDR              LOAD ADDRESS OF INPUT RECORD    12120000
         BAL   SRR,OUT                  PUT OUT                         12140000
*                                                                       12160000
         TM    CARD+E+1,XNOTBL                                          12180000
         BZ    RETNCF                   EXIT AFTER OUTPUTTING LAST LINE 12200000
*                                                                       12220000
         LA    GRC,1(GRC,GRB)           ADJUST RECORD POINTER           12240000
         LA    GRD,CARD+C               SET RHPTR = CONTINUE COLUMN     12260000
         LH    GRB,K                    PICK UP REMAINING BYTE COUNT    12280000
         BAL   SRR,CLEARA               CLEAR CARD                      12300000
         OI    FLAGX,X'02'              SET CONTINUATION 'ON'           12320000
         B     BB                       RETURN FOR ANOTHER LINE         12340000
         EJECT                                                          12360000
* LOAD RT HLF IN PRINT BUFFER                                           12380000
OUT      BAL   GRX,CALLCF               SAVE REGISTERS                  12400000
         BAL   SRR,INLCPL               GO TO LOAD RT HALF              12420000
*                                                                       12440000
* MOVE SUBROUTINE                                                       12460000
*   GRB = NUMBER OF BYTES TO BE MOVED                                   12480000
*   GRC = RECORD POINTER = ABSOLUTE 'FROM' ADDRESS                      12500000
*   GRD = RIGHT HAND POINTER = ABSOLUTE 'TO' ADDRESS                    12520000
*                                                                       12540000
TRSLMV   BCTR  GRB,0                    REDUCE BYTE COUNT BY 1          12560000
         LTR   GRB,GRB                  IS COUNT ZERO                   12580000
         BCR   4,SRR                    SKIP MOVE IF COUNT WAS ZERO     12600000
         EX    GRB,MVEIMG               MOVE TO OUTPUT AREA,            12620000
TREXIT   BR    SRR                          AND RETURN                  12640000
MVEIMG   MVC   0(1,GRD),0(GRC)          EXECUTED MOVE                   12660000
*                                                                       12680000
*                                                                       12700000
*  RESTORE LENGTH OF FIELD -- MOVE ON TO NEXT FIELD                     12720000
*                                                                       12740000
RESTORE  L     GRB,TEMP                 REDUCE DELTA BY 'TRUE' LENGTH   12760000
         SR    GRZ,GRB                    OF FIELD JUST PROCESSED       12780000
         BC    11,BUMPTR                IF DELTA BECOMES NEGATIVE,      12800000
         SR    GRZ,GRZ                    SET DELTA TO ZERO             12820000
BUMPTR   LA    GRC,0(GRB,GRC)           GRC POINTS TO NEXT FIELD LGTH   12840000
         IC    GRB,0(GRC)               SET GRB = NEXT FIELD COUNT      12860000
         LA    GRC,1(GRC)               SET REC PTR = START NXT FIELD   12880000
         BR    SRR                      EXIT                            12900000
*                                                                       12920000
* CLEAR 80 BYTE AREA                                                    12940000
*                                                                       12960000
CLEARA   MVI   CARD,IBLANK              PUT BLANK IN FIRST COLUMN       12980000
         MVC   CARD+1(79),CARD          AND PROPAGATE DOWN CARD         13000000
         BR    SRR                      EXIT                            13020000
*                                                                       13040000
*  CHOOSE WORKING LENGTH OF FIELD EQUAL TO MINIMUM OF 3 VALUES          13060000
*                                                                       13080000
CHECK    ST    GRB,TEMP                 SAVE TRUE LENGTH OF FIELD       13100000
         CR    GRB,GRX                  IS GRB LESS THAN, EQUAL TO GRX  13120000
         BNH   CHECKD                     YES                           13140000
         LR    GRB,GRX                    NO -- REPLACE GRB BY GRX      13160000
CHECKD   CR    GRB,GRZ                  IS GRB LESS THAN, EQUAL TO GRZ  13180000
         BCR   13,SRR                     YES                           13200000
         LR    GRB,GRZ                    NO--REPLACE BRB BY GRZ        13220000
         BR    SRR                      EXIT                            13240000
         TITLE 'F8PRINT COMMENTS PROCESSOR V -II'                       13260000
*                                                                     * 13280000
*TITLE 'COMMENT' ...  MOVE IN RIGHT HALF                              * 13300000
*ENTRY- COMMENT  CALLED VIA-                                          * 13320000
*        L     FRB,PRNT(ACT)            LOAD BASE                     * 13340000
*        L     GRX,CTCOMT(ACT)          LOAD ENTRY                    * 13360000
*        BALR  SRR,GRX                  CALL COMMENT                  * 13380000
*INPUT-  F8WORK(ACT)     INPUT IMAGE                                  * 13400000
*OUTPUT- SOURCE          PART OF PRINT IMAGE                          * 13420000
*                                                                     * 13440000
         SPACE 2                                                        13460000
COMMENT  BAL   GRX,CALLCF               SAVE REGISTERS                  13480000
         LA    SP1,F8WORK(ACT)          ADDRESS OF INPUT AREA           13500000
         L     GRA,RECADDR              LOAD ADDRESS OF INPUT RECORD    13520000
         MVC   RLI,0(SP1)               RECORD LENGTH INDICATOR         13600000
         LH    GRX,RLI                  PUT IT IN A REGISTER FOR MOVE   13620000
         TM    2(SP1),X'30'             TEST FOR TYPE 011         25196 13630018
         BO    OUTPUT2                  BRANCH IF YES             25196 13640018
OUTPUT1  EX    GRX,MOVOUT               MOVE RECORD FOR OUTPUT    25196 13650018
         BAL   SRR,INLCPL              GO TO PRINT ROUTINE              13660000
         B     RETNCF                   RETURN AND RESTORE REGISTERS    13680000
OUTPUT2  CH    GRX,H74                  IS CONTINUATION NEEDED    25196 13680718
         BNH   OUTPUT1                  IF NO GO BACK             25196 13681418
         LA    GRX,E+5                  LENGTH OF RECORD          25196 13682118
         EX    GRX,MOVOUT               MOVE RECORD               25196 13682818
         STH   GRX,0(GRA)               STORE LENGTH IN MOVED REC 25196 13683518
         MVI   74(GRA),IX               MOVE IN CONTINUATION BYTE 25196 13684218
         BAL   SRR,OUTPUT3              TO PRINT RTNE VIA OUTPUT3 25196 13684918
         LA    SP1,F8WORK(ACT)          ADDRESS OF INPUTAREA      25196 13685618
         OI    2(SP1),X'02'             SET CONTINUATION BIT      25196 13686318
         MVI   3(SP1),IBLANK            BLANK OUT COLUMN          25196 13687018
         MVC   4(14,SP1),3(SP1)         1 TO 15                   25196 13687718
         LH    GRX,RLI                  LOAD RECORD LENGTH        25196 13688418
         SH    GRX,H74                  CALCULATE LENGTH OF PART  25196 13689118
         EX    GRX,MOV                  TO OVERLAY OLD PART       25196 13689818
         LH    GRX,RLI                  LOAD RECORD LENGTH        25196 13690518
         SH    GRX,H56                  CALCULATE NEW RECORD      25196 13691218
*                                       LNGTH                     25196 13691918
         STH   GRX,RLI                  STORE IN RLI              25196 13692618
         STH   GRX,0(SP1)               AND IN INPUT AREA         25196 13693318
         B     OUTPUT2                                            25196 13694018
OUTPUT3  BAL   GRX,CALLCF               SAVE REGISTERS            25196 13694718
         BAL   SRR,INLCPL               GO TO PRINT ROUTINE       25196 13695418
         B     RETNCF                   RETURN AND RESTORE REGS   25196 13696118
H74      DC    H'74'                                              25196 13696818
H56      DC    H'56'                                              25196 13697518
MOV      MVC   18(0,SP1),74(SP1)        EXECUTED                  25196 13698218
MOVREC   MVC   0(0,GRA),0(GR2)          MOVE RECORD                     13700000
MOVOUT   MVC   0(0,GRA),0(SP1)          MOVE RECORD                     13720000
*                                                                       13740000
***                                                                     13760000
         ENTRY BLDIMG                   BUILD EMAGE ENTRY               13780000
         ENTRY COMMENT                  PRINT COMMENT ENTRY             13800000
         ENTRY LOADRA                   PRINT END ERROR ENTRY           13820000
         TITLE 'PUSH DOWN, POP UP ROUTINE -- SAVES GRA, GRB, ... SRR'   13840000
         USING LIST,GRY                 FOR PUSH-DOWN POP-UP LIST       13860000
CALLCF   L     GRY,PUSHDN               GET PRIOR LEVEL POINTER         13880000
         LA    GRY,24(GRY)              OBTAIN POINTER TO NEW LEVEL     13900000
         ST    GRY,PUSHDN               SAVE POINTER TO LATEST LEVEL    13920000
         STM   GRA,SRR,LIST             SAVE GRA, GRB, GRC, GRD, SRB    13940000
         BR    GRX                        AND SRR AND RETURN TO CALLER  13960000
*                                                                       13980000
RETNCF   LM    GRY,GR1,PUSHDN           PICK UP CURRENT LEVEL POINTER   14000000
         BXLE  GRY,GR0,*+4                POP UP TO PRIOR LEVEL         14020000
         ST    GRY,PUSHDN                 PUSHDOWNS                     14040000
         LM    GRA,SRR,LIST+24          RESTORE REGISTERS SAVED         14060000
         BR    SRR                      EXIT                            14080000
         DROP  GRY                      NO LONGER USE LIST              14100000
*                                                                       14120000
PUSHDN   DC    A(LIST-24)               POSITION IN LIST                14140000
POPUP    DC    F'-24'                   POP UP CPUNTER                  14160000
LIST     DC    30F'0'                   5 LEVEL PUSH DOWN STORAGE       14180000
*                                                                       14200000
         TITLE 'F8PRINT CONSTANTS FOR V - II'                           14220000
***                                                                     14240000
***                                                                     14260000
* FULL WORD DC'S, DS'S AND ADCON'S, FORCED FULL WORD ALIGNMENTS, ETC    14280000
***                                                                     14300000
         DS    0F                       FULL WORD ALIGN                 14320000
RLIC     DC    FL2'83'                  LOGICAL RECORD LENGTH           14340000
HZERO    DC    H'0'                     ZERO CONSTANT            A52832 14344021
RECADDR  DC    A(RECORD)                ADDRESS OF INPUT RECORD         14360000
R1       DS    F                        RESULT 1 -- (X, B, D)           14380000
R2       DS    F                        RESULT 2 -- S VALUE             14400000
SVMNTE   DS    2F                       BYTES FOR NEXT LINE             14420000
SVCMNT   DS    2F                       SAVE AREA FOR PTR AND VALUE     14440000
SRRGRY   DS    2F                      TWO REGISTERS SAVED              14460000
TEMP     DS    F                        TRUE LENGTH OF FIELD            14480000
OUTPOI   DS    F                        DYNAMIC O/P PTR                 14500000
WORK     DS    8F                       WORK AREA FOR UNPACK            14520000
REGHLD   DS    4F                       WORK REG HOLD AREA              14540000
***                                                                     14560000
* HALF WORD CONSTANTS AND DS'S                                          14580000
***                                                                     14600000
RLI      DS    1H                       POINTER TO SECOND OPERAND       14620000
RLIF     DC    H'0'                     RECORD LENGTH INDICATOR         14640000
LLTH     DC    H'0'                     LEFT HAND SIDE BYTE COUNT       14660000
LCNT     DC    H'0'                     LINE COUNT                      14680000
BCNT     DC    H'0'                     PUNCH AREA BYTE COUNT           14700000
PGNO     DC    H'0'                     PAGE NUMBER                     14720000
BLKCNT   DC    H'0'                    BLANK LINE COUNT          A52832 14724021
BLKBLK   DC    H'0'                   NO OF SPACES IN SPACE STMT A52832 14728021
HONE     DC    H'1'                     ONE CONSTANT             A52832 14732021
***                                                                     14740000
* HEX CONSTANTS                                                         14760000
***                                                                     14780000
FRST     DC    X'00'                    FIRST PASS SWITCH               14800000
MASK     DC    X'0F0F0F0F'              MASK FOR TRANSLATE              14860000
MASK1    DC    X'0000000F'              MASK FOR TRANSLATE              14880000
PRNTSW   DC    X'00'                    LOCAL PRINT SWITCH              14900000
PUNSWH   DC    X'FF'                    LOCAL PUNCH SWITCH              14920000
LSTRCD   DC    X'40'                    LAST RECORD IN INDICATOR        14940000
PRNTER   DC    X'00'                    PRINT ERROR LINE SWITCH         14960000
ALGSWH   DC    X'FF'                    ALIGNMENT DATA PROCESSED SWITCH 14980000
RECTYP   DC    X'40'                    SUBSTITUTED TYPE FOR X'57' REC  15000000
CONSR    DC    X'00144700'             CONSTANT PART OF RECORD          15020000
***                                                                     15040000
* CHARACTER CONSTANTS                                                   15060000
***                                                                     15080000
SAVSEQ   DC    C'0000'             SAVE AREA FOR DECK SEQ. NO.          15100000
ERRMSG   DC    C'*** ERROR ***'                                         15120000
*                                                                       15140000
DWORD    DS    D                        RESULTS OF CNVRT                15160000
*        ************************************************************** 15180000
* NORMAL CARD FORMAT PARAMETERS                                         15200000
B        EQU   0                        BEGIN -1                        15220000
E        EQU   70                       END -1                          15240000
C        EQU   15                       CONTINUE - 1                    15260000
***                                                                     15280000
SYSL     EQU   SYSLST                   SYSLIST                         15300000
SYSP     EQU   SYSOUT                   SYSPUNCH                        15320000
SYSG     EQU   SYSOUT                   SYSGO                           15340000
K        EQU   SVMNTE                   BYTES LEFT                      15360000
GRP      EQU   GR1                      POINTER                         15380000
*                                                                       15400000
XNOTBL   EQU   X'01'                    LOGICAL INT X AND NOT INT BLNK  15420000
BLNK     EQU   X'32'                    INTERNAL BLANK                  15440000
KBLANK   EQU   BLNK                     INTERNAL BLANK                  15460000
KLITR    EQU   X'25'                    LITERAL RECORD                  15480000
KX       EQU   X'21'                    CONTINUE SWITCH. INTERNAL 'X'   15500000
XBLANK   EQU   X'40'                    EXTERNAL BLANK                  15520000
TITLEX   EQU   X'18'                    TITLE RECORD                    15540000
REPROX   EQU   X'17'                    REPRODUCE RECORD                15560000
PUNCHX   EQU   X'16'                    PUNCH RECORD                    15580000
MNOTEX   EQU   X'0E'                    MNOTE RECORD                    15600000
         EJECT                                                          15620000
* HEADING DATA                                                          15640000
H1       DS    0CL121                   HEADING CODE                    15660000
H1SPC    DC    X'60'                   FORCES PAGE EJECT                15680000
DECKNM   DC    C'WXYZ'                  DECK IDENTIFICATION             15700000
         DC    C'   '                   3 BLANKS                        15720000
HEADNG   DC    CL100' '                 PROGRMER HDING FROM TITLE IEUN3 15740018
         DC    C'    PAGE'              4 BLANKS, 'PAGE'          IEUN3 15760018
PCNT     DC    CL5' '                   PAGE NUMBER               IEUN3 15780018
         SPACE 1                                                  IEUN3 15800018
* 121 BYTE SECONDARY HEADER LINE                                        15840000
H2       DS    0CL121                   HEADING TWO                     15860000
H2SPC    DC    X'02'                                                    15880000
         DC    C'  LOC  OBJECT CODE    ADDR1 ADDR2  STMT   SOURCE STAT' 15900000
         DC    C'EMENT                                            '     15920000
LEVEL    EQU   *                        FOR ASS'Y RELEASE DATE    IEUN6 15930018
         DC    C'F04MAR74  '                                     A52832 15940021
DATE     DC    C'10/07/65'                                              15960000
* 121 BYTE WORKAREA FOR RUN-OF-THE-MILL DETAIL LINE                     15980000
DETAIL   DS    0CL121                   DETAIL LINE                     16000000
DETSPC   DC    X'00'                    SPACES                          16020000
LOC      DS    0CL40                    LEFT HALF                       16040000
         DC    34C' '                   34 BLANKS                 IEUN3 16060018
DSTMNT   DC    CL5' '                   DETAIL LINE STMT NUMBER   IEUN3 16080018
         DC    X'40'                                                    16100000
SOURCE   DS    CL80                     RIGHT HALF                      16120000
* 121 BYTE DUMMY LINE -- FOR ALIGNMENT, ERROR LINE, PUNCH, REPRO        16140000
DUMOUT   DC    X'00'                                                    16160000
         DC    C'                        '                              16180000
         DC    C'                        '                              16200000
         DC    C'                        '                              16220000
         DC    C'                        '                              16240000
         DC    C'                        '                              16260000
         DC    X'00'                                                    16280000
         DS    0F                                                       16300000
***                                                                     16320000
* PUNCH BUFFER                                                          16340000
***                                                                     16360000
TXTOUT   DS    0CL80                                                    16380000
         DC    X'02'                    CARD COL 1                      16400000
         DC    C'TXT '                  COLS 2 - 5                      16420000
ADDR     DC    C'000'                   COLS 6 - 8                      16440000
         DC    C'  '                    COLS 9, 10                      16460000
BYTCNT   DC    X'0000'                  COLS 11, 12                     16480000
         DC    X'404000'                COLS 13 - 15                    16500000
ESDIDX   DC    X'01'                    COL 16                          16520000
INS      DS    0CL56                    COLS 17 - 72                    16540000
         DC    C'        '                                              16560000
         DC    C'        '                                              16580000
         DC    C'        '                                              16600000
         DC    C'        '                                              16620000
         DC    C'        '                                              16640000
         DC    C'        '                                              16660000
         DC    C'        '                                              16680000
IDRH     DC    C'ABCD'                  COLS 73 - 76                    16700000
SEQ      DC    C'0000'                  COLS 77 - 80                    16720000
         EJECT                                                          16740000
* RECORDS OF VARIOUS SORTS                                              16760000
*                                                                       16780000
         DS    0F                                                       16800000
         DC    X'00'                                                    16820000
LFTHLF   DS    0CL20                    LEFT HALF IMAGE                 16840000
RLIB     DC    FL2'20'                  LENGTH                          16860000
FLAGB    DC    X'57'                    FLAG FOR LEFT HALF WORKAREA     16880000
XESDID   DC    X'01'                    CURRENT ESDID                   16900000
LOCCTR   DS    CL3                      LOCATION COUNTER                16920000
OPCODE   DS    CL1                      OP CODE                         16940000
RRR1     DS    CL1                      REGISTER SPECIFICATION          16960000
RXB2D2   DS    CL2                      2ND INSTRUCTION BYTE            16980000
SSB2D2   DS    CL2                      3RD INSTRUCTION BYTE            17000000
EA1      DS    CL3                      EFFECTIVE ADDRESS 1             17020000
EA2      DS    CL3                      EFFECTIVE ADDRESS 2             17040000
FLAG     DS    CL1                      BYTE COUNT                      17060000
*                                                                       17080000
         EJECT                                                          17120000
* F8PRINT INPUT ARES                                                    17140000
IEUF8R   CSECT                                                          17160000
RECORD   EQU   IEUF8R                   INTERNAL NAME                   17180000
         DS    0F                       WORD ALIGNED                    17200000
INPUT    DS    CL400                    400 BYTES FOR RECORD            17220000
* FORMAT OF SOURCE RECORD                                               17240000
RLIA     EQU   INPUT                    LENGTH                          17260000
FLAGA    EQU   INPUT+2                  FLAG                            17280000
CARD     EQU   INPUT+3                  CARD IMAGE                      17300000
* FORMAT OF ERROR RECORD                                                17320000
ERREC    EQU   INPUT                    INTERNAL NAME                   17340000
ERLI     EQU   INPUT                   LGHT VARIES FROM 8 TO 38 BYTES   17360000
EFLAG    EQU   INPUT+2                  FLAG FOR ERROR RECORDS          17380000
NERR     EQU   INPUT+3                 NUMBER OF ERRORAS                17400000
ESTMNT   EQU   INPUT+4                  STATEMENT NUMBER                17420000
ERR1     EQU   INPUT+6                 1-16 ERR CODES AND PTRS          17440000
RGTHLF   EQU   INPUT                    RIGHT HALF                      17460000
RLIX     EQU   RLIA                     LENGTH                          17480000
FLAGX    EQU   FLAGA                    FLAG                            17500000
         END                                                            17520000
