F8S      TITLE '                        IEUF8S, SYMBOL TABLE GET'       00020000
         ISEQ  73,80                                                    00040000
IEUF8S   CSECT                                                          00060000
*          RELEASE 18 DELETIONS                                         00061018
*1472009200                                                       IEUN1 00062018
*          RELEASE 19 DELETIONS                                         00063018
*          RELEASE 20 DELETIONS                                         00064018
*          RELEASE 21 DELETIONS                                         00065018
*          RELEASE 22 DELETIONS                                         00066018
*          RELEASE 23 DELETIONS                                         00067018
*          RELEASE 24 DELETIONS                                         00068018
*          RELEASE 25 DELETIONS                                         00069018
*          RELEASE 26 DELETIONS                                         00070018
 SPACE                                                                  00080000
         PRINT NODATA,NOGEN                                             00100000
         FDIMEN                                                         00120000
*                                                                     * 00140000
*TITLE 'IEUF8S  ' ... SYMBOL TABLE GET                                * 00160000
*STATUS CHANGE LEVEL 004                                                00180018
*FUNCTION/OPERATION-                                                  * 00200000
*   IEUF8S LOOKS UP THE SYMBOL IN THE SYMBOL TABLE AND RETURNS        * 00220000
*   WITH EITHER THE VALUE OR A NOT FOUND INDICATOR                    * 00240000
*ENTRY POINT- STGETR                                                  * 00260000
*   CALLING SEQUENCE                                                  * 00280000
*        LA    SP1,SYMBOL               POINT TO SYMBOL               * 00300000
*        L     SRB,CSTGET(ACT)          GET BASE/ENTRY                * 00320000
*        BALR  SRR,SRB                  CALL IEUF8S                   * 00340000
*INPUT-  SP1   POINTS TO SYMBOL                                       * 00360000
*        SP2   CONTAINS LENGTH OF SYMBOL OR ZERO                      * 00380000
*OUTPUT- SP1   POINTS TO ATTRIBUTES IF FOUND                          * 00400000
*              IS ZERO IF NOT FOUND                                   * 00420000
*EXTERNAL ROUTINES- NONE                                              * 00440000
*EXITS- NORMAL                                                        * 00460000
*   RETURNS VIA                                                       * 00480000
*        BR    SRR                      EXIT                          * 00500000
*     - ERROR -- NONE                                                 * 00520000
*NOTES- SEE NOTES FOR IEUF7S                                          * 00540000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 00560000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 00580000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 00600000
         EJECT                                                          00620000
         ENTRY STGETR                                                   00640000
 SPACE                                                                  00660000
RW1      EQU   GRZ                      WORK REGISTER                   00680000
REVEN    EQU   GRX                      EVEN                            00700000
RODD     EQU   GRY                        ODD PAIR FOR NAME             00720000
RW2      EQU   2                        WORK REGISTER                   00740000
RFS      EQU   1                        FREE STORAGE POINTER            00760000
RPT      EQU   RODD                     POINTER INTO TABLE              00780000
RSTB     EQU   REVEN                    POINTS TO BASE OF SYMBOL TABLE  00800000
*        *     SYMBOLIC DISPLACEMENTS                                   00820000
*                                                                       00840000
EOS      EQU   32                       END OF STRING                   00860000
NAMES    EQU   3                        MASK FOR NAME ITEM              00880000
ILENG    EQU   0                                   X+0                  00900000
LASH     EQU   31                       LENGTH OF LITERAL AND     IEUN1 00910018
*                                       OPSYN HASH TABLES         IEUN1 00920018
ISYM     EQU   1                                   X+1                  00940000
ADJ      EQU   1                                   Y+1                  00960000
INAME    EQU   5                        AMOUNT TO SKIP IF NAME          00980000
IOTHER   EQU   3                        AMOUNT TO SKIP FOR OTHERS       01000000
 SPACE                                                                  01020000
ACC      EQU   GRX                      ACCUMULATOR                     01040000
TEMPR    EQU   GRZ                      TEMPERARY                       01060000
 EJECT                                                                  01080000
         USING *,SRB                                                    01100000
STGETR   LTR   SP2,SP2                  IF PARAMETER SP2 WAS GIVEN,     01120000
         BP    KNOWN LENGTH SYMBOL.     LENGTH IS KNOWN, BRANCH         01140000
         CLI   0(SP1),IALPHA            IS FIRST CHAR PART OF SYMBOL    01160000
         BH    GETOUT                   NO, RETURN NOT FOUND            01180000
 SPACE                                                                  01200000
         LR    SP2,SP1                  SP2= BEGINNING OF NAME          01220000
SCAN     LA    SP2,1(SP2)               SET AT NEXT CHAR                01240000
         CLI   0(SP2),IALPHA            IS THIS CHAR PART OF SYMBOL     01260000
         BNH   SCAN                     YES, LOOP                       01280000
 SPACE                                                                  01300000
         SR    SP2,SP1                  =LENGTH OF SYMBOL OR 256        01320000
KNOWN    LA    1,8                                                      01340000
         CR    1,SP2                    IF SYMBOL IS GREATER THAN 8,    01360000
         BCTR  SP2,0                    REDUCE BY ONE FOR COMPARE       01380000
         BC    4,GETOUT                 SET 'NOT FOUND' AND EXIT.       01400000
 SPACE                                                                  01420000
NOXREF   SR    RW1,RW1                  CLEAR REGISTER                  01440000
         ST    RW1,BENCH                AND WORKBENCH.                  01460000
         ST    RW1,BENCH+4              CLEAR BENCH.                    01480000
         EX    SP2,MOVE1                SYMBOL TO BOUNDARY.             01500000
         LM    REVEN,RODD,BENCH         LOAD SYMBOL LEFT JUSTIFIED.     01520000
         XR    RODD,REVEN               FOLD SYMBOL INTO FULLWORD.      01540000
         SR    REVEN,REVEN              CLEAR 4 BYTES OF DIVIDEND.      01560000
         D     REVEN,CPRIME(ACT)        PRIME IS HASH DIMENSION.        01580000
         LA    RODD,0(REVEN,REVEN)      MULTIPLY BY                     01600000
         AR    RODD,REVEN               THREE BYTES/POINTER.            01620000
         L     RSTB,CTSYMP(ACT)         FIND SYMBOL TABLE BASE          01640000
         LA    RODD,LASH(RODD,RSTB)     LASH IS LENGTH OF LITERAL HASH. 01660000
         ST    RW1,BENCH                CLEAR BENCH                     01680000
 SPACE                                                                  01700000
FOLLOW   MVC   BENCH+1(3),0(RPT)        POINTER TO BOUNDARY             01720000
         L     RPT,BENCH                POINTER TO REGISTER             01740000
         LTR   RPT,RPT                  IF POINTER IS ZERO,NO SYNONYMS. 01760000
         BZ    GETOUT                   NO SYNONYMS, NOT FOUND          01780000
 SPACE                                                                  01800000
         AR    RPT,RSTB                 GET ADDRESS OF ENTRY IN TABLE   01820000
         EX    SP2,ACLI                 IF UNEQUAL LENGTHS, SEE IF AT   01840000
         BNE   BITTER END OF THREAD YET.                                01860000
         EX    SP2,ACLC                 COMPARE SYMBOLS.                01880000
 SPACE                                                                  01900000
BITTER   IC    RW1,ILENG(RPT)           GET LENGTH                      01920000
         LA    RPT,2(RPT,RW1)           POINT TO FIXED LENGTH INFO.     01940000
         BE    FOUND                    SYMBOL FOUND, EXIT              01960000
 SPACE                                                                  01980000
         TM    ADJ(RPT),EOS             IS THIS END OF STRING           02000000
         BZ    GETOUT                   YES, NOT FOUND                  02020000
 SPACE                                                                  02040000
         TM    ADJ(RPT),NAMES           IS THIS A NAME                  02060000
         LA    RPT,IOTHER(RPT)          OTHERS.                         02080000
         BC    12,FOLLOW                BRANCH NOT NAME                 02100000
 SPACE                                                                  02120000
         LA    RPT,INAME(RPT)           NAME ITEMS ARE LONGER THAN      02140000
         B     FOLLOW THE THREAD        OTHERS                          02160000
 SPACE 2                                                                02180000
GETOUT   SR    RPT,RPT                 SET PARAM 'NOT FOUND'.           02200000
FOUND    LR    SP1,RPT                  SET SP1 TO POINT TO ATTRIBUTE   02220000
         BCR   15,SRR                  EXIT.                            02240000
 SPACE 4                                                                02260000
ACLI     CLI   ILENG(RPT),0             EXECUTED                        02280000
ACLC     CLC   0(0,SP1),ISYM(RPT)       EXECUTED                        02300000
MOVE1    MVC   BENCH(0),0(SP1)          EXECUTED                        02320000
 SPACE 2                                                                02340000
BENCH    DC    D'0'                     WORK BENCH                      02360000
 SPACE                                                                  02380000
         END   STGETR                                                   02400000
