F8V      TITLE 'PHASE 8 EVALUATION ROUTINE'                             00020000
IEUF8V   START 0                                                        00040000
*          RELEASE 14 DELETIONS                                       * 00043015
*          RELEASE 15 DELETIONS                                       * 00046015
*1472                                                             13455 00047015
*          RELEASE 16 DELETIONS                                       * 00049015
*          RELEASE 17 DELETIONS                                       * 00052015
*          RELEASE 18 DELETIONS                                       * 00055015
*          RELEASE 19 DELETIONS                                       * 00058015
*          RELEASE 20 DELETIONS                                       * 00061015
*          RELEASE 21 DELETIONS                                       * 00064015
*          RELEASE 22 DELETIONS                                       * 00067015
*STATUS- CHANGE LEVEL 004                                               00073015
EEVAL    EQU   IEUF8V                                                   00080000
         PRINT NODATA,NOGEN                                             00100000
         FDIMEN                                                         00120000
         PRINT DATA,GEN                                                 00140000
*                                                                     * 00160000
*TITLE 'IEUF8V  ' ...  EXPRESSION EVALUATION                          * 00180000
*FUNCTION/OPERATION-                                                  * 00220000
*   IEUF8V EVALUATES EXPRESSIONS AND CONVERTS SELF-DEFINED TERMS TO   * 00240000
*   THEIR PROPER VALUES. THE FOLLOWING ERRORS ARE DETECTED AND LOGGED-* 00260000
*              RELOCATABILITY      SELF DEFINING VALUE TOO LARGE      * 00280000
*              ARITHMETIC OVERFLOW TWO CONSECUTIVE TERMS              * 00300000
*              UNDEFINED SYMBOL    TWO CONSECUTIVE OPERATORS          * 00320000
*              ILLEGAL CHARACTER   TWO OPERATORS ILLEGALLY COMBINED   * 00340000
*              TOO MANY TERMS      TOO MANY LEVELS OF PARENTHESES     * 00360000
*              INVALID SYMBOL      PREMATURE END OF EXPRESSION        * 00380000
*              EXPRESSION VALUE TOO LARGE                             * 00400000
*ENTRY POINT-  IEUF8V                                                 * 00420000
*   CALLING SEQUENCE                                                  * 00440000
*        L     SRB,CEEVAL(ACT)     PICK UP IEUF8V ADDRESS FROM ACT    * 00460000
*        BALR  SRR,SRB                                                * 00480000
*        CEEVAL(ACT) IS LOADED BY IEUF8I WITH ADDRESS OF IEUF8V       * 00500000
*INPUT-                                                               * 00520000
*   REGISTERS-                                                        * 00540000
*        SP1 CONTAINS ADDRESS OF FIRST CHARACTER OF THE EXPRESSION TO * 00560000
*        BE EVALUATED                                                 * 00580000
*   PARAMETERS-                                                       * 00600000
*        CTSDVI(ACT)- HIGH-ORDER BIT (BIT 0)                          * 00620000
*            0=NO EFFECT UPON IEUF7V                                  * 00640000
*            1=IF THE FIRST (OR ONLY) TERM OF THE EXPRESSION IS A     * 00660000
*              SELF-DEFINING TERM, THEN-                              * 00680000
*                  THE BIT IS RESET TO 0                              * 00700000
*                  THE VALUE OF THE S.D.T. IS PLACED IN REG. SP1      * 00720000
*                  CONDITION CODE IS SET TO 0                         * 00740000
*                  IEUF7V EXITS TO CALLING ROUTINE                    * 00760000
*        CTSDVI(ACT)- BIT 2                                           * 00780000
*            1='PREVIOUSLY DEFINED SYMBOL' ERROR                      * 00800000
*        F8YDC+1(ACT)                                                 * 00820000
*            X'01'=RESULT IS AN ADCON, MAY BE FOUR BYTES LONG         * 00840000
*OUTPUT-                                                              * 00860000
*   REGISTERS-                                                        * 00880000
*        SP1 CONTAINS ADDRESS OF THE CHARACTER FOLLOWING THE CHARACTER* 00900000
*                     WHICH TERMINATED THE EXPRESSION                 * 00920000
*                  OR ZERO, IF A SYNTACTICAL ERROR WAS DISCOVERED IN  * 00940000
*                     THE EXPRESSION   (FATAL ERROR)                  * 00960000
*        SP2 CONTAINS THE VALUE OF THE EXPRESSION, IF THE EXPRESSION  * 00980000
*                     WAS ABSOLUTE                                      01000000
*                  OR A POINTER TO AN OUTPUT PARAMETER LIST (RLIST),  * 01020000
*                     IF THE EXPRESSION WAS RELOCATABLE.              * 01040000
*   CONDITION CODE-                                                   * 01060000
*        CC=0   ABSOLUTE EXPRESSION                                   * 01080000
*        CC=1   SIMPLY RELOCATABLE EXPRESSION                         * 01100000
*        CC=2   COMPLEXLY RELOCATABLE EXPRESSION                      * 01120000
*        CC=3   EVALUATION IMPOSSIBLE (ERROR)                         * 01140000
*   PARAMETERS-                                                       * 01160000
*        LIST POINTED TO BY SP1-                                      * 01180000
*             ONE FULL WORD CONTAINING THE VALUE OF THE EXPRESSION    * 01200000
*             16 HALF-WORDS, ONE FOR EACH POSSIBLE TERM IN EXPR.      * 01220000
*                  ABSOLUTE TERM ENTRIES...BOTH BYTES 0               * 01240000
*                  PAIRED RELOCATABLE TERM ENTRIES...BOTH BYTES 0     * 01260000
*                  RELOCATABLE TERM ENTRIES...FIRST BYTE=SIGN         * 01280000
*                       (1=+,2=-),SECOND BYTE=ESD-ID                  * 01300000
*             A SIMPLY RELOCATABLE EXPRESSION WILL HAVE A TERM ENTRY  * 01320000
*             IN ONLY THE FIRST HALF-WORD.  THE REMAINING 15 HALF     * 01340000
*             WORDS WILL CONTAIN ZEROES.  A COMPLEXLY RELOCATABLE     * 01360000
*             EXPRESSION WILL HAVE A NON-ZERO ENTRY FOR EACH UNPAIRED * 01380000
*             RELOCATABLE TERM. THESE ENTRIES MAY BE SCATTERED THROUGH* 01400000
*             THE PARAMETER LIST.                                     * 01420000
*        CTLRCI(ACT), BIT 1                                           * 01440000
*            0= NO REFERENCE TO LOCATION COUNTER (*) IN EXPRESSION    * 01460000
*            1=REFERENCE TO LOC. CNTR WAS MADE IN EXPRESSION          * 01480000
*        STLONG(ACT) CONTAINS LENGTH ATTRIBUTE OF FIRST TERM IN EXPR. * 01500000
*EXTERNAL ROUTINES-                                                   * 01520000
*        NAME            ROUTINE   USE                                * 01540000
*        CSTGET(ACT)     IEUF8S    FIND SYMBOL IN SYMBOL TABLE        * 01560000
*        CLOGER(ACT)     IEUF8L    LOG ERROR                          * 01580000
*EXITS- NORMAL-                                                       * 01600000
*        RETURN TO CALLING PROGRAM VIA-                               * 01620000
*        BR    SRR                                                    * 01640000
*       ERRORS-                                                       * 01660000
*          PROCESSING OF EXPRESSION IS COMPLETED AND NORMAL EXIT      * 01680000
*          OCCURS IF THESE ERRORS ARE ENCOUNTERED-  (NON-FATAL ERRORS)* 01700000
*             EXPRESSION VALUE TOO LARGE                              * 01720000
*             SYMBOL NOT PREVIOUSLY DEFINED                           * 01740000
*             ARITHMETIC ERROR                                        * 01760000
*             RELOCATABILITY ERROR                                    * 01780000
*             SELF-DEFINING TERM VALUE TOO LARGE                      * 01800000
*                  OR ZERO, IF AN ERROR WAS DISCOVERED IN THE EXPRES'N* 01820000
*             THE CONDITION CODE WILL NOT BE 3 FOR 'EXPR. VALUE ECEEDS* 01840000
*             RANGE'                                                  * 01860000
*          EXPRESSION PROCESSING IS DISCONTINUED, SP1 AND SP2 ARE SET * 01880000
*          TO ZERO, AND IEUF7V RETURNS TO THE CALLING ROUTINE, IF THE * 01900000
*          FOLLOWING SYNTACTICAL ERRORS ARE ENCOUNTERED. (FATAL ERR'S)* 01920000
*             TWO TERMS NOT SEPARATED                                 * 01940000
*             ILLEGAL CHARACTER                                       * 01960000
*             TOO MANY TERMS                                          * 01980000
*             TWO OPERATORS ILLEGALLY COMBINED                        * 02000000
*             TOO MANY LEVELS OF PARENTHESES                          * 02020000
*             EXPRESSION END PREMATURE                                * 02040000
*             INVALID SYMBOL                                          * 02060000
*          IN ALL CASES, THE ERRORS ARE LOGGED.                       * 02080000
*TABLES/WORK AREAS-                                                   * 02100000
*   TERMS- (16F) AN ENTRY IS MADE FOR EACH TERM IN EXPRESSION...AT END* 02120000
*          OF EVALUATION, FIRST ENTRY CONTAINS RESULT VALUE           * 02140000
*   RLIST- (16H) TERM ENTRY PORTION OF OUTPUT PARAMETER LIST.         * 02160000
*   NTRMS- (16C) AT END OF EVAL., FIRST BYTE CONTAINS 2*NUMBER OF     * 02180000
*          TERMS.                                                     * 02200000
*   OPRNS  (20C) AN ENTRY IS MADE FOR EACH OPERATOR IN EXPR'N         * 02220000
*NOTE-  SEARCH FOR SYMBOLS BEGINS WITH WORK BUCKETS. IF SYMBOL IS NOT * 02240000
*       FOUND, SEARCH CONTINUES IN THE SYMBOL TABLE                   * 02260000
*   THE TERMINATING CHARACTER WILL ALWAYS BE A LEFT OR RIGHT PARN. OR * 02280000
*   A BLANK OR A COMMA, UNLESS THERE WAS A SYNTACTICAL ERROR.         * 02300000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 02320000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 02340000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 02360000
*                                                                     * 02380000
*  GRX USED FOR POINTER TO TERMS LIST                                   02400000
*  GRY USED FOR POINTER TO OPRNS LIST                                   02420000
*  GRZ USED FOR POINTER TO NTRMS LIST                                   02440000
*  GR2 USED FOR POINTER TO RLIST LIST                                   02460000
* GR0,GR1,GRA, AND GRB USED AS WORK REGISTERS                           02480000
         EJECT                                                          02500000
         USING *,SRB                    USING SRB                       02520000
*                                                                       02540000
*  INITIALIZE                                                           02560000
*                                                                       02580000
         SR    GR0,GR0                                                  02600000
         ST    GR0,TERMS                ZERO TO TERMS                   02620000
         MVC   TERMS+1(139),TERMS       ZERO THE REST OF THE WORK AREA  02640000
         STH   GR0,STLONG(ACT)          ZERO TO STLONG(ACT)             02660000
         STM   GRA,GRB,REGSAV                                           02680000
         NI    CTLCRI(ACT),X'BF'        SET BIT FOR LOC. CNTR. REF. OFF 02700000
         LM    GRZ,GRY,NPTR             INITIALIZE GRX,GRY,GRZ,         02720000
         LA    GR2,RLIST                          AND GR2.              02740000
         ST    SP1,FTXPPT              SAV PT TO FIRST BYTE OF EXP      02760000
*                                                                       02780000
*  SCAN OF THE EXPRESSION FOR TERMS OR OPERATORS                        02800000
*                                                                       02820000
LOOK     CLI   0(SP1),IALPHA            IS CHAR. ALPHANUMERIC           02840000
         BH    NOTAM                    NO, GO LOOK FOR SPECIAL CHAR    02860000
         ST    SP1,ERRPT               SAV PT TO FIRST BYTE OF TERM     02880000
         STM   GRZ,GRY,SAVE             SAVE 3 WORK REGISTERS           02900000
         CLI   0(SP1),IA                IS CHAR. A NUMBER               02920000
         BL    DEC                      YES, GO TREAT AS DECIMAL S.D.T. 02940000
         CLI   1(SP1),IQUOTE            IS NEXT CHAR. A QUOTE           02960000
         BE    NEXTQ                    YES, GO LOOK AT FOLLOWIN CHAR   02980000
*                                                                       03000000
*  SYMBOL IN THE EXPRESSION                                             03020000
*                                                                       03040000
SYM      CLI   COND,2                   IS COND GR THAN 2               03060000
         BH    ERR10                    BAD SHOW, TWO CONSECUTIVE TERMS 03080000
         SR    GR0,GR0                  FORM A ZERO AND                 03100000
         ST    GR0,0(GRX)               ZERO TO TERMS LIST              03120000
         CLI   LREF,0                  IS L'SYMBOL                      03140000
         BE    TRYSWB                  NO                               03160000
         CLI   0(SP1),IMULT            IS L'*                           03180000
         BNE   TRYSWB                  NO                               03200000
         MVI   3(GRX),1                1 TO TERMS LIST                  03220000
         MVI   LREF,0                  CLEAR LREF                       03240000
         MVN   LREF(1),F8INST+15(ACT)  MOVE IN LENGTH ATTRIBUTE         03260000
         CLI   LREF,2                   IS IT A ZERO OR A ONE           03280000
         BL    ATTR1                   0YES, GIVE VALUE OF ONE          03300000
         CLI   LREF,8                   IS IT .GT. 8                    03320000
         BH    ATTR1                   GYES, SET VALUE OF ONE           03340000
         MVC   3(1,GRX),LREF           PUT L'* VALUE IN TERMS LIST      03360000
ATTR1    LA    SP1,1(SP1)              POSITION SP1 TO CHAR. AFTER *    03380000
         B     LSTAR                                                    03400000
*                                                                       03420000
*  LOOK FOR SYMBOL VALUE IN WORK BUCKET                                 03440000
*                                                                       03460000
*                                                                       03480000
* CTXWBP(ACT), FULL WORD ALIGNED, POINTS TO 'NEXT' SYMBOL WORK BUCKET.  03500000
* WHEN ZERO, THERE IS NO 'NEXT' SYMBOL WORK BUCKET.                     03520000
*                                                                       03540000
TRYSWB   L     SP2,CTXWBP(ACT)         POINTER TO NEXT SYM. WK-BUCKET   03560000
         LTR   SP2,SP2                  IS THERE A NEXT SYM. WK-BUCKET  03580000
         BZ    TRYST                                                    03600000
         LR    GR1,SP2                  YES, LOAD WORK BUCKET POINTER   03620000
         LA    GR1,6(GR1)               BUMP POINTER TO SYM. WK-BUCKET  03640000
         ST    GR1,CTXWBP(ACT)                    BY 6                  03660000
         TM    TXSUBS(SP2),X'10'        IS VALUE IN WORK-BUCKET         03680000
         BO    WBFNDX                   YES, DONT SEARCH SYMBOL TABLE   03700000
*                                                                       03720000
*  LOOK FOR SYMBOL VALUE IN SYMBOL TABLE                                03740000
*                                                                       03760000
TRYST    STM   SRB,GR2,NCOMP            SAVE OUR BASE                   03780000
         SR    SP2,SP2                  SET LENGTH UNKNOWN              03800000
         L     SRB,CSTGET(ACT)          LOAD BASE/ENTRY                 03820000
         BALR  SRR,SRB                  TO STGET ROUTINE                03840000
         DROP  SRB                      SRB DESTROYED BY STGET, SO      03860000
         USING *,SRR                    USE TEMP. BASE OF SRR           03880000
         LTR   GR1,SP1                  POINTER TO GR1 AND TEST         03900000
         LR    GR0,SP2                  LENGTH OF SYMBOL TO GR0         03920000
         LM    SRB,GRY,NCOMP            RESTORE OUR BASE                03940000
         DROP  SRR                      BASE SRB RESTORED, DROP TEMP.   03960000
         USING EEVAL,SRB                SRR AND START USING OUR BASE    03980000
         L     GR2,NCOMP+40             RESTORE ALL BUT GR0, GR1 NOW    04000000
         BC    7,FOUND                  HAS SYMBOL BEEN FOUND           04020000
*                                                                       04040000
*  SYMBOL NOT FOUND IN EITHER A WORK BUCKET OR THE SYMBOL TABLE         04060000
*                                                                       04080000
         MVI   TERMS,0                                                  04100000
         MVC   TERMS+1(96),TERMS        ZERO TERMS, RLIST AND RCNTR     04120000
         C     GR0,=F'7'                IF SYMBOL LEN GR 8              04140000
         BH    ERR3                     LOG ERROR /INVALID SYMBOL/      04160000
         B     ERR15                    SYMBOL NOT FOUND                04180000
SCANE    LA    SP1,1(SP1)               SCAN TO END OF SYMBOL           04200000
COND3    EQU   SCANE                                                    04220000
         CLI   0(SP1),IPLUS             SEE IF AT END OF SYMBOL         04240000
         BL    SCANE                    NO, LOOP FOR NEXT CHAR          04260000
         B     COMPT4                   YES, START AGAIN                04280000
*                                                                       04300000
*  SYMBOL VALUE FOUND IN SYMBOL TABLE                                   04320000
*                                                                       04340000
FOUND    AR    SP1,GR0                  ADD SYMBOL LENGTH TO PTR        04360000
         LA    SP1,1(SP1)               UP TO NEXT CHAR                 04380000
         CLI   LREF,0                   IS L'SYMBOL                     04400000
         BH    LSYM                     YES, PROCESS                    04420000
         TM    1(GR1),3                 IS THIS A NAME                  04440000
         BC    14,ESDMV                NO                               04460000
         CLI   SYMBL,0                  IS THIS THE FIRST TERM          04480000
         BH    MOVE                     NO, BRANCH                      04500000
         MVC   STLONG(2,ACT),6(GR1)     LENGTH TO STLONG                04520000
MOVE     MVC   1(3,GRX),3(GR1)          VALUE TO TERMS LIST             04540000
         CLI   2(GR1),0                 IS ABSOLUTE TERM                04560000
         BE    COMPT4                   YES, BRANCH                     04580000
ESDMV    MVC   1(1,GR2),2(GR1)          ESD-ID TO RLIST                 04600000
         TM    1(GR1),X'04'             IS DSECT-COM BIT ON (BIT5)      04620000
         BC    7,OUT                                                    04640000
         TM    1(GR1),X'03'            IS EXTRN(01) OR DSECT(10)        04660000
         BM    OUT              YES                                     04680000
*                                                                       04700000
*  LOOK FOR ADJUSTMENT VALUE FOR RELOCATABLE SYMBOL                     04720000
*                                                                       04740000
SUCH     CLC   1(1,GR2),CESDID(ACT)     IS THIS THE CURRENT ESD-ID      04760000
         BE    OUTL                     YES, GET OUT OF LOOP            04780000
         L     SP2,CTLATB(ACT)          ADDRESS OF END OF ADJ TABLE     04800000
         L     GR1,CADJBS(ACT)          ADDRESS OF START OF ADJ TABLE   04820000
FINDA    CLC   1(1,GR2),0(GR1)          IS THIS THE ESD-ID              04840000
         BE    ADDV                     YES, GET OUT                    04860000
         LA    GR1,4(GR1)               BUMP GR1 BY 4 (FOR ADJ TABLE)   04880000
         CLR   GR1,SP2                  HAVE REACHED END OF ADJ TABLE   04900000
         BL    FINDA                    NO, LOOP                        04920000
         B     OUT                      YES, QUIT                       04940000
ADDV     MVC   NCOMP+1(3),1(GR1)        ADJ VALUE TO NCOMP              04960000
         MVI   NCOMP,0                                                  04980000
         L     GR1,NCOMP                ADJ VALUE TO GR1                05000000
ADDADJ   A     GR1,0(GRX)               ADD ADJ VALUE TO S. T. VALUE    05020000
         ST    GR1,0(GRX)                                               05040000
         MVI   0(GRX),X'00'            ZERO 1ST BYTE                    05060000
OUT      MVI   COND,4                  SET COND=4                       05080000
         MVI   0(GR2),1                 CODE FOR + SIGN = 1 TO RLIST    05100000
         IC    GR1,RCNTR                BUMP RCNTR BY 1 (RELOCATABLE)   05120000
         LA    GR1,1(GR1)                                               05140000
         STC   GR1,RCNTR                                                05160000
         B     COMPT                    CONTINUE                        05180000
*                                                                       05200000
*  SYMBOL VALUE FOUND IN WORK BUCKET                                    05220000
*                                                                       05240000
WBFNDX   LA    SP1,1(SP1)               SCAN TO END OF SYMBOL           05260000
         CLI   0(SP1),IPLUS             IS IT STILL PART OF SYMBOL      05280000
         BL    WBFNDX                   YES, CONTINUE SCAN              05300000
         CLI   LREF,0                   IS L'SYMBOL                     05320000
         BH    LSYMWB                   YES, PROCESS                    05340000
         TM    TXSTPC(SP2),X'03'       IS THIS A NAME                   05360000
         BC    14,WBESDMV              NO                               05380000
         CLI   SYMBL,0                  IS THIS THE FIRST TERM          05400000
         BH    WBFNDY                   NO, SKIP FIRST TERM PROCESSING  05420000
         MVC   STLONG+1(1,ACT),TXSLEN(SP2)                              05440000
         TM    TXSEXI(SP2),X'04'        IS LENGTH GR THAN 256           05460000
         BZ    WBFNDY                   NO, LEAVE AS IS                 05480000
         MVI   STLONG(ACT),255          SET FIRST BYTE OF STLONG =255   05500000
WBFNDY   MVC   1(3,GRX),TXSVAL(SP2)     VALUE TO TERMS LIST             05520000
         CLI   TXSESD(SP2),0           IS ABSOLUTE TERM                 05540000
         BE    COMPT4                   YES                             05560000
WBESDMV  MVC   1(1,GR2),TXSESD(SP2)    ESD-ID TO RLIST                  05580000
         TM    TXSDOC(SP2),X'20'        IS DSECT-COM BIT ON (BIT 2)     05600000
         BC    7,OUT                    YES                             05620000
         TM    TXSTPC(SP2),X'03'       IS EXTRN(01) OR DSECT(10)        05640000
         BM    OUT              YES                                     05660000
         B     SUCH                     NO, LOOK FOR ADJUSTMENT VALUE   05680000
*                                                                       05700000
*  L'SYMBOL VALUE FOUND IN SYMBOL TABLE                                 05720000
*                                                                       05740000
LSYM     TM    1(GR1),3                 IS THIS A NAME                  05760000
         BC    14,UPLSYM                NO                              05780000
MOVEL    MVC   2(2,GRX),6(GR1)          LENGTH TO TERMS LIST            05800000
         B     UPLSYM                   CONTINUE                        05820000
*                                                                       05840000
*  L'SYMBOL VALUE FOUND IN WORK BUCKET                                  05860000
*                                                                       05880000
LSYMWB   MVC   1(3,GRX),TXSVAL(SP2)    LENGTH TO TERMS LIST        6822 05900000
UPLSYM   L     GR1,0(GRX)                                               05920000
         LA    GR1,1(GR1)                                               05940000
         ST    GR1,0(GRX)               BUMP VALUE OF L'SYMBOL BY 1     05960000
LSTAR    MVI   LREF,0                  SET LREF TO ZERO                 05980000
         B     COMPT4                   GO ON                           06000000
*                                                                       06020000
*  DECIMAL SELF-DEFINING VALUE IN THE EXPRESSION                        06040000
*                                                                       06060000
DEC      LA    SHFR,3                   DEC. TYPE INDICATOR TO SHFR     06080000
         BAL   RETR,SDVCF               TO SELF-DEFINING VALUE ROUTINE  06100000
         LA    GR0,8                    MAX. NO. OF CHAR. TO GR0        06120000
         LM    GRZ,GRY,SAVE             RE-LOAD SAVED REGISTERS         06140000
         ST    VALR,0(GRX)              VALUE TO TERMS LIST             06160000
         CLI   0(GRX),0                 IS FIRST BYTE ZERO              06180000
         BH    ERR0                     NO, ERROR - TOO LARGE           06200000
         B     ABSD                     GO ON                           06220000
*                                                                       06240000
*  1ST CHARACTER IS ALPHABETIC AND 2ND IS A QUOTE                       06260000
*                                                                       06280000
NEXTQ    CLI   0(SP1),IB                IS BINARY SELF-DEF. VALUE       06300000
         BE    BINRY                    YES, BINARY CONVERT             06320000
         CLI   0(SP1),IC                IS CHARACTER SELF-DEF. VALUE    06340000
         BE    CHARS                    YES, CHARACTER CONVERT          06360000
         CLI   0(SP1),IX                IS HEXADECIMAL SELF-DEF. VALUE  06380000
         BE    HEX                      YES, HEXADECIMAL CONVERT        06400000
         CLI   0(SP1),IL                IS L'SYMBOL                     06420000
         BNE   ERR9                     NO, ERROR - ILLEGAL CHAR        06440000
*                                                                       06460000
*  L'SYMBOL IN THE EXPRESSION                                           06480000
*                                                                       06500000
         LA    SP1,2(SP1)               POINT SP1 TO 1ST CHAR. OF SYM.  06520000
         MVI   LREF,X'FF'               SET L'SYMBOL FLAG NON-ZERO      06540000
         CLI   0(SP1),IALPHA           IS CHAR. ALPHANUMERIC            06560000
         BNH   ALPHA                   YES                              06580000
MAYLCNTR CLI   0(SP1),IMULT            IS CHAR. *                       06600000
         BNE   ERR9                    NO                               06620000
ALPHA    CLI   0(SP1),IA               IS CHAR. ALPHABETIC              06640000
         BL    ERR9                    NO                               06660000
*                                                                       06680000
* IN WORK BUCKET, VALUE = LENGTH.                                       06700000
* IN SYMBOL TABLE, PICK UP LENGTH ATTRIBUTE PART OF SYMBOL.             06720000
*                                                                       06740000
         B     SYM                      SYMBOL IN EXPRESSION            06760000
*                                                                       06780000
*  BINARY SELF-DEFINING VALUE IN THE EXPRESSION                         06800000
*                                                                       06820000
BINRY    LA    SHFR,1                   BINARY TYPE INDICATOR TO SHFR   06840000
         LA    SP1,2(SP1)               POSITION SP1 TO FIRST CHAR.     06860000
         BAL   RETR,SDVCF               TO SELF-DEFINING VALUE ROUTINE  06880000
         LA    GR0,24                   MAX. NO. OF CHAR. TO GR0        06900000
         B     LM                       CONTINUE                        06920000
*                                                                       06940000
*  CHARACTER SELF-DEFINING VALUE IN THE EXPRESSION                      06960000
*                                                                       06980000
CHARS    LA    SP1,2(SP1)               POSITION SP1 TO FIRST CHAR.     07000000
         LA    SHFR,8                   CHAR. TYPE INDICATOR TO SHFR    07020000
         BAL   RETR,SDVCF               TO SELF-DEFINING VALUE ROUTINE  07040000
         LA    GR0,3                    MAX. NO. OF CHAR. TO GR0        07060000
         LM    GRZ,GRY,SAVE             RE-LOAD SAVED REGISTERS         07080000
         ST    VALR,0(GRX)              VALUE TO TERMS LIST             07100000
         L     SP2,CTRTBP(ACT)          POINTER TO TRANSLATE TABLE      07120000
         TR    0(4,GRX),0(SP2)          TRANSLATE CHAR. VALUE           07140000
         B     CKQ                      CONTINUE                        07160000
*                                                                       07180000
*  HEXADECIMAL SELF-DEFINING VALUE IN THE EXPRESSION                    07200000
*                                                                       07220000
HEX      LA    SHFR,4                   HEX TYPE INDICATOR TO SHFR      07240000
         LA    SP1,2(SP1)               POSITION SP1 TO FIRST CHAR.     07260000
         BAL   RETR,SDVCF               TO SELF-DEFINING VALUE ROUTINE  07280000
         LA    GR0,6                    MAX. NO. OF CHAR. TO GR0        07300000
LM       LM    GRZ,GRY,SAVE             RE-LOAD SAVED REGISTERS         07320000
         ST    VALR,0(GRX)              VALUE TO TERMS LIST             07340000
CKQ      CLI   0(SP1),IQUOTE            IS ENDING CHAR. A QUOTE         07360000
         BNE   ERR9                     NO, ERROR - ILLEGAL CHAR        07380000
         LA    SP1,1(SP1)               POSITION SP1 TO CHAR. AFTER '   07400000
         LTR   CNTR,CNTR                IS CNTR ZERO                    07420000
         BZ    ERR9                     YES, ERROR - ILLEGAL CHAR       07440000
ABSD     CLR   CNTR,GR0                 IS CNTR GR THAN MAX.            07460000
         BH    ERR0                     YES, ERROR - TOO MUCH           07480000
         CLI   COND,0                   IS COND ZERO                    07500000
         BH    ABSCK                    NO, TEST FOR .GT. 2             07520000
         TM    CTSDVI(ACT),X'80'        IS BIT FOR SELF-DEF. VALUE ON   07540000
         BZ    ABSCK+8                  NO                              07560000
         NI    CTSDVI(ACT),X'7F'        SET THE BIT OFF                 07580000
         B     FINIS                                                    07600000
ABSCK    CLI   COND,2                   IS COND GR THAN 2               07620000
         BH    ERR10                    YES, ERROR - TWO CONSECUTIVE TR 07640000
COMPT4   MVI   COND,3                  SET COND=3                       07660000
COMPT    CL    GR2,COMP1                ARE THERE TOO MANY TERMS        07680000
         LA     GRB,MNYERR              TOO MANY TERMS                  07700000
         BH    FATLER1                                                  07720000
         OI    SYMBL,1                  OR SYMBL WITH 1                 07740000
         MVI   0(GRZ),2                 2 TO NTRMS LIST                 07760000
         LA    GRZ,1(GRZ)               BUMP GRZ BY 1 (FOR NTRMS)       07780000
         LA    GRX,4(GRX)               BUMP GRX BY 4 (FOR TERMS)       07800000
         LA    GR2,2(GR2)               BUMP GR2 BY 2 (FOR RLIST)       07820000
         B     LOOK                     GO ON IN STRING                 07840000
*                                                                       07860000
*  1ST CHARACTER IS NOT ALPHANUMERIC                                    07880000
*                                                                       07900000
NOTAM    CLI   0(SP1),ICOMMA            IS CHAR. A COMMA                07920000
         BL    LTCOM                    NO, IS A +,-,*, OR /            07940000
         BE    BLCOM                    YES, GO TO BLANK OR COMMA       07960000
         CLI   0(SP1),ILPARN            IS CHAR. A LEFT PAREN.          07980000
         BE    LPAR                     YES                             08000000
         BL    ERR9                     NO, ERROR - ILLEGAL CHAR        08020000
         CLI   0(SP1),IQUOTE            IS CHAR A ' OR ) OR BLANK       08040000
         BL    RPAR                     RIGHT PARN                      08060000
         BH    BLCOM                    BLANK                           08080000
         B     ERR9               ' IS ILLEGAL FIRST CHAR.              08100000
*                                                                       08120000
*  RIGHT PARENTHESIS IN THE EXPRESSION                                  08140000
*                                                                       08160000
RPAR     CLI   COND,3                   IS COND =3 (FOR RIGHT PAREN)    08180000
         BL    ERR12                    NO, ERROR - TWO CONSECUTIVE OPS 08200000
         MVI   COND,3                   SET COND=3                      08220000
         CLI   PCNTR,0                  IS PCNTR =0                     08240000
         BH    NOEND                    NO                              08260000
         B     ENDNG                    YES                             08280000
*                                                                       08300000
*  1ST CHARACTER IS EITHER +,-,*, OR /.                                 08320000
*                                                                       08340000
LTCOM    CLI   0(SP1),IASTER            IS CHAR. AN ASTERISK            08360000
         BE    STAR                     YES                             08380000
         BH    SLASH                    BRANCH IF /                     08400000
*                                                                       08420000
*  + OR - IN THE EXPRESSION                                             08440000
*                                                                       08460000
PLMIN    CLI   COND,3                   IS COND GT 2                    08480000
         BL    ERR12                    NO, ERROR - 2 CONSECUTIVE OPS   08500000
         MVI   COND,1                   SET COND=1                      08520000
SET      LA    GR0,IALPHA               LAST ALPHABETIC CHAR            08540000
         IC    GR1,0(SP1)               GET THIS CHAR                   08560000
         SR    GR1,GR0                                                  08580000
         STC   GR1,NEWOP                HIERARCHY CODE TO NEWOP         08600000
*                                                                       08620000
*  MAIN LOOP TO PERFORM ARITHMETIC                                      08640000
*                                                                       08660000
LOOP     CL    GRY,OPTR                 ARE THERE PREVIOUS OPERATORS    08680000
         BH    ONZ                      YES                             08700000
         CLI   ENDOE,0                  IS ENDOE=0                      08720000
         BH    FINIS                    NO                              08740000
PUT      MVC   0(1,GRY),NEWOP           NEWOP TO OPRNS LIST             08760000
BUMPY    LA    GRY,1(GRY)               BUMP GRY BY 1 (FOR OPRNS)       08780000
BUMPR    LA    SP1,1(SP1)               BUMP SP1 BY 1 (FOR NON-ALFNUM)  08800000
         B     LOOK                     CONTINUE IN STRING              08820000
ONZ      BCTR  GRY,0                    POINT GRY TO PREVIOUS OPERATOR  08840000
         CLC   0(1,GRY),NEWOP           IS NEW HIERARCHY LT-EQ PREVIOUS 08860000
         BNL   LE                       YES                             08880000
         CLI   NEWOP,4                  TEST NEW OP /                   08900000
         BNE   STEPUP                   NO                              08920000
         CLI   0(GRY),3                 TEST PREV OP *                  08940000
         BE    WORK                     YES, DO * FIRST                 08960000
STEPUP   LA    GRY,1(GRY)               ADD 1 BACK TO GRY               08980000
         B     PUT                                                      09000000
LE       CLI   0(GRY),0                 IS OLD HIERARCHY =0             09020000
         BH    WORK                     NO                              09040000
         IC    GR1,PCNTR                SUBTRACT 1 FROM PCNTR           09060000
         BCTR  GR1,0                                                    09080000
         STC   GR1,PCNTR                                                09100000
         B     BUMPR                    CONTINUE LOOP                   09120000
*                                                                       09140000
*  LEFT PARENTHESIS IN THE EXPRESSION                                   09160000
*                                                                       09180000
LPAR     CLI   COND,X'02'               POSS. END OF EXP. IF COND GT 2  09200000
         BH    LPEND                    YES, PROCESS END                09220000
         MVI   COND,X'01'               SET COND=1                      09240000
         CLI   PCNTR,X'04'              ARE THERE TOO MANY LEFT PARENS  09260000
         LA    GRB,PARERR              TOO MANY LEVLS OF PARENS         09280000
         BH    FATLER2                  YES, ERROR                      09300000
         IC    GR1,PCNTR                BUMP PCNTR BY 1                 09320000
         LA    GR1,1(GR1)                                               09340000
         STC   GR1,PCNTR                                                09360000
         MVI   0(GRY),0                 ZERO TO OPRNS LIST              09380000
         B     BUMPY                    RETURN TO PERFORM ARITHMETIC    09400000
*                                                                       09420000
*  ASTERISK IN THE EXPRESSION                                           09440000
*                                                                       09460000
STAR     CLI   COND,2                   IS COND LT 2 (FOR *)            09480000
         BE    ERR12                    NO, ERROR - 2 CONSECUTIVE OPS   09500000
         BL    LCNTR                    BRANCH IF LOC CNTR REFERENCE    09520000
*                                                                       09540000
*  ASTERISK IS MULTIPLICATION OPERATOR                                  09560000
*                                                                       09580000
FORD1    MVI   COND,2                   SET COND = 2                    09600000
         B     SET                      GO TO MAIN LOOP FOR ARITH       09620000
*                                                                       09640000
*  SLASH IN THE EXPRESSION                                              09660000
*                                                                       09680000
SLASH    CLI   COND,3                   IS COND =3 (FOR /)              09700000
         BL    ERR12                    NO, ERROR                       09720000
         B     FORD1                    CONTINUE AS THOUGH MULTIPLICATN 09740000
*                                                                       09760000
*  BLANK OR COMMA IN THE EXPRESSION                                     09780000
*                                                                       09800000
BLCOM    CLI   COND,3                   IS COND LT 3 (FOR BLANK OR ,)   09820000
         BL    ERR17                    YES, ERROR                      09840000
*                                                                       09860000
*  LEFT PARENTHESIS END CONDITION                                       09880000
*                                                                       09900000
LPEND    CLI   PCNTR,0                  IS PCNTR =0                     09920000
         BH    ERR17                    NO, ERROR                       09940000
ENDNG    MVI   ENDOE,15                 SET ENDOE NON-ZERO              09960000
NOEND    MVI   NEWOP,0                  SET NEWOP ZERO                  09980000
         B     LOOP                     MAIN ARITH LOOP                 10000000
*                                                                       10020000
*  ASTERISK IS LOCATION COUNTER                                         10040000
*                                                                       10060000
LCNTR    OI    CTLCRI(ACT),X'40'        SET BIT FOR LOC. CNTR. REF. ON  10080000
         LA    SP1,1(SP1)               POSITION SP1 TO NEXT CHAR.      10100000
         L     SP2,CTXABP(ACT)          POINTER TO LOC. CNTR.           10120000
         MVC   1(3,GRX),TXLOC(SP2)      LOC. CNTR VALUE TO TERMS LIST   10140000
         MVI   0(GRX),0                                                 10160000
         CLI   SYMBL,0                 IS THIS THE FIRST TERM           10180000
         BH    LCNTR2                  NO                               10200000
         MVN   LREF(1),F8INST+15(ACT)  MOVE IMPLIED EXPRESSION LENGTH   10220000
         CLI   LREF,0                  DONT DECREMENT LREF IF ZERO      10240000
         BE    LCNTR1                   ZERO, SO DONT                   10260000
         IC    GR1,LREF                TO TEMP LOC                      10280000
         BCTR  GR1,0                   DECREMENT BY 1                   10300000
         STC   GR1,LREF                AND MOVE                         10320000
LCNTR1   MVC   STLONG+1(1,ACT),LREF         TO STLONG                   10340000
         MVI   LREF,0                  SET LREF TO ZERO                 10360000
LCNTR2   MVC   1(1,GR2),CESDID(ACT)    CURRENT ESD-ID TO RLIST          10380000
OUTL     L     GR1,F8CADJ(ACT)          CURRENT ADJ VALUE TO GR1        10400000
         B     ADDADJ                   PROCESS END OF ADJUSTMENT       10420000
*                                                                       10440000
*  PERFORM ARITHMETIC AND RELOCATABILITY WORK                           10460000
*                                                                       10480000
WORK     ST    GR2,NCOMP                STORE GR2 IN NCOMP              10500000
         LA    GR0,8                    POINT GRX TO 1ST OF THE 2       10520000
         SR    GRX,GR0                       TERMS ENTRIES              10540000
         LA    GR0,2                    POINT GRZ TO 1ST OF THE 2       10560000
         SR    GRZ,GR0                       NTRMS ENTRIES              10580000
         IC    GR0,1(GRZ)               2ND NTRMS  ENTRY TO GR0         10600000
         SR    GR2,GR0                  SUBT. 2ND NTERMS ENTRY FRM GR2  10620000
         CLI   0(GRY),2                 FIND OUT WHAT OPERATOR IT IS    10640000
         BL    OPPLS                    BRANCH IF THIS OPERATOR +       10660000
         BH    MULDV                    BRANCH IF THIS OPERATOR * OR /  10680000
*                                                                       10700000
*  OPERATOR IS SUBTRACTION.  COMPLEMENT 2ND VALUE AND CHANGE THE        10720000
*  RELOCATION SIGN BYTE OF THE TERMS IN THE 2ND VALUE.                  10740000
*                                                                       10760000
         L     GR1,4(GRX)                                               10780000
         LCR   GR1,GR1                  COMPLEMENT 2ND TERMS LIST ENTRY 10800000
         ST    GR1,4(GRX)                                               10820000
CHG      CLI   0(GR2),1                 TEST SIGN BYTE IN 2ND RLIST     10840000
         BL    NOCHG                    BRANCH IF ABS. VALUE            10860000
         BE    PLCHG                    BRANCH IF SIGN +                10880000
         MVI   0(GR2),1                 CHANGE SIGN TO +                10900000
         B     NOCHG                                                    10920000
PLCHG    MVI   0(GR2),2                 CHANGE SIGN TO -                10940000
NOCHG    LA    GR2,2(GR2)               POINT GR2 TO NEXT ENTRY         10960000
         CL    GR2,NCOMP                ARE THERE MORE ENTRIES          10980000
         BL    CHG                      BRANCH BACK IF MORE ENTRIES     11000000
         SR    GR2,GR0                  SUBT. 2ND NTERMS ENTRY FRM GR2  11020000
*                                                                       11040000
*  OPERATION IS ADDITION OR SUBTRACTION.  SCRATCH ENTRIES IN THE        11060000
*  RELOCATION LIST WHERE POSSIBLE.                                      11080000
*                                                                       11100000
OPPLS    IC    GR0,0(GRZ)               1ST NTRMS  ENTRY TO GR0         11120000
         LR    GR1,GR2                  POINT GR1 TO 2ND NTRMS LIST     11140000
         SR    GR2,GR0                  POINT GR2 TO 1ST NTRMS LIST     11160000
         LR    SP2,GR1                  SAVE GR1 IN SP2                 11180000
BCOMP    CLI   0(GR2),1                 IS FIRST SIGN + (CODE =1)       11200000
         BL    NSCR                     BRANCH IF ABS. VALUE (CODE =0)  11220000
         BH    F2                       BRANCH IF SIGN - (CODE =2)      11240000
         CLI   0(GR1),2                 IS SECOND SIGN -                11260000
         BL    NSCR                     BRANCH IF SIGN NOT -            11280000
OPP      CLC   1(1,GR2),1(GR1)          COMPARE FIRST TO SECOND ESD-ID  11300000
         BNE   NSCR                     BRANCH IF NOT THE SAME          11320000
         MVI   0(GR2),0                 ZERO TO FIRST SIGN              11340000
         MVI   1(GR2),0                 ZERO TO FIRST ESD-ID            11360000
         MVC   0(2,GR1),0(GR2)          ZERO TO 2ND SIGN AND ESD-ID     11380000
         IC    GR0,RCNTR                SUBTRACT 2 FROM RCNTR           11400000
         BCTR  GR0,0                    MINUS 1                         11420000
         BCTR  GR0,0                      MINUS 1 MORE                  11440000
         STC   GR0,RCNTR                     SAVE                       11460000
         B     NSCR                                                     11480000
F2       CLI   0(GR1),1                 IS SECOND SIGN +                11500000
         BE    OPP                      YES                             11520000
NSCR     LA    GR1,2(GR1)               POINT GR1 TO NEXT IN 2ND RLIST  11540000
         CL    GR1,NCOMP                                                11560000
         BL    BCOMP                    BRANCH BACK IF MORE IN 2ND LIST 11580000
         LA    GR2,2(GR2)               POINT GR2 TO NEXT IN 1ST LIST   11600000
         LR    GR1,SP2                  START OF 2ND LIST BACK TO GR1   11620000
         CLR   GR1,GR2                                                  11640000
         BH    BCOMP                    BRANCH BACK IF MORE IN 1ST LIST 11660000
         L     GR2,NCOMP                NCOMP BACK TO GR2               11680000
         LCR   GR1,GR1                  COMPLEMENT GR1                  11700000
         AR    GR1,GR2                  2ND NTRMS ENTRY TO GR1          11720000
         IC    GR0,0(GRZ)               1ST NTRMS ENTRY TO GR0          11740000
         AR    GR1,GR0                  ADD THE 2 NTRMS ENTRIES         11760000
         STC   GR1,0(GRZ)               SUM TO POSITION OF THE 1ST      11780000
*                                                                       11800000
*  PERFORM ADDITION                                                     11820000
*                                                                       11840000
         L     GR1,0(GRX)               1ST TERMS LIST ENTRY TO GR1     11860000
         A     GR1,4(GRX)               ADD 2ND ENTRY                   11880000
         BO    ERR13             -DUMMY-APPROP. OVERFLOW ROUTINE TO SYS 11900000
STORE    ST    GR1,0(GRX)               RESULT TO 1ST TERMS LIST ENTRY  11920000
         LA    GRX,4(GRX)               BUMP GRX BY 4 (FOR TERMS LIST)  11940000
         LA    GRZ,1(GRZ)               BUMP GRZ BY 1 (FOR NTRMS LIST)  11960000
         B     LOOP                     CONTINUE IN ARITH LOOP          11980000
*                                                                       12000000
*  OPERATOR IS MULTIPLICATION OR DIVISION.  CHECK THAT NO RELOCATABLE   12020000
*  TERMS REMAIN IN THE 2 VALUES.                                        12040000
*                                                                       12060000
MULDV    SR    GR1,GR1                  CLEAR GR1                       12080000
         IC    GR1,0(GRZ)               1ST NTERMS ENTRY TO GR1         12100000
         AR    GR0,GR1                  ADD THE 2 NTRMS ENTRIES         12120000
         STC   GR0,0(GRZ)               SUM TO 1ST ENTRY LOCATION       12140000
         SR    GR2,GR1                  SUBT. 1ST NTRMS ENTRY FROM GR2  12160000
         LA    GR0,2                    2 TO GR0                        12180000
         L     GR1,NCOMP                                                12200000
         SR    GR1,GR0                  C(NCOMP)-2 TO GR1               12220000
MORE     CLI   0(GR2),0                 IS IT A RELOCATABLE VALUE       12240000
         BH    ERR11                    YES, ERROR                      12260000
MORE1    BXLE  GR2,GR0,MORE                                             12280000
         SR    GR1,GR1                  ZERO GR1                        12300000
         C     GR1,4(GRX)                                               12320000
         BE    STORE                    BRANCH IF 2ND TERMS ENTRY =0    12340000
         L     GR0,0(GRX)               1ST TERMS ENTRY TO GR0          12360000
         SRDA  GR0,32                   PROPAGATE SIGN BIT              12380000
         CLI   0(GRY),3                 IS OPERATOR * OR /              12400000
         BH    DIV                      BRANCH IF /                     12420000
*                                                                       12440000
*  PERFORM MULTIPLICATION                                               12460000
*                                                                       12480000
         M     GR0,4(GRX)               MULTIPLY BY 2ND TERMS ENTRY     12500000
         LTR   GR1,GR1                                                  12520000
         BNL   CHK0                     BRANCH IF LOW-ORDER NON-NEG     12540000
         LCR   GR0,GR0                  COMPLEMENT HIGH-ORDER           12560000
         BCTR  GR0,0                    SUBTRACT 1 FROM THE COMPLEMENT  12580000
CHK0     LTR   GR0,GR0                  SEE IF ZERO                     12600000
         BNZ   ERR13                    ERROR IF HIGH-ORDER NOW NOT=0   12620000
         B     STORE                    SAVE RESULT                     12640000
*                                                                       12660000
*  PERFORM DIVISION                                                     12680000
*                                                                       12700000
DIV      D     GR0,4(GRX)               DIVIDE 1ST BY 2ND TERMS ENTRY   12720000
         B     STORE                    SAVE RESULT                     12740000
*                                                                       12760000
*  END OF EXPRESSION FOUND                                              12780000
*                                                                       12800000
FINIS    TM    F8YDC+1(ACT),X'01'       IS THIS ADCON                   12820000
         BO    NOTST                    YES,ADCON MAY BE 4 BYTES        12840000
         BAL   GRZ,DATATST              RESULT MUST NOT EXCEED 3 BYTES  12860000
NOTST    L     SP2,TERMS                MOVE RESULT TO SP2              12880000
         ST    SP2,RLIST-4              RESULT TO HEAD RLIST            12900000
         LM    GRA,GRB,REGSAV                                           12920000
         CLI   ERROR,0                  WERE THERE ERRORS               12940000
         BH    SETE                     YES                             12960000
         CLI   RCNTR,0                  IS IT RELOCATABLE               12980000
         BCR   8,SRR                    RETURN WITH CC=0 (ABSOLUTE EXP) 13000000
         LA    SP2,RLIST-4              POINTER TO RESULT TO SP2        13020000
         CLI   RCNTR,1                  IS IT COMPLEX RELOCATABLE       13040000
         BCR   2,SRR                    RETURN WITH CC=2 (COMPLX REL.)  13060000
         LA    GR1,RLIST-2              FIND FIRST AND ONLY RLIST ENTRY 13080000
FIND     LA    GR1,2(GR1)                    WHERE SIGN BYTE NON-ZERO   13100000
         CLI   0(GR1),1                 IS THIS IT                      13120000
         BL    FIND                     NO, KEEP LOOKING                13140000
         BCR   2,SRR                    RETURN WITH CC=2 (COMPLX REL.)  13160000
         MVC   RLIST(2),0(GR1)          MOVE ENTRY TO TOP OF LIST       13180000
         XC    RLIST+2(30),RLIST+2      ZERO REST OF LIST         13455 13190015
         CLI   0(GR1),2                 SET CC = 1                      13200000
         BR    SRR                      RETURN WITH CC=1 (SIMPLY REL.)  13220000
*                                                                       13240000
DATATST  TM    TERMS,X'FF'              VALUE EXCEEDS 3 BYTES           13260000
         BC    11,DATAOK                NO                              13280000
         STM   SRB,GR2,NCOMP                                            13300000
         L     SP1,FTXPPT               SET COL PTR TO 1ST BYTE         13320000
         L     SRB,CLOGER(ACT)          TO LOGERR                       13340000
         BALR  SRR,SRB                                                  13360000
         DROP  SRB                      SAME THING CONCERNING OUR BASE  13380000
         USING *,SRR                    SO USE TEMP. UNTIL RESTORED     13400000
         DC    AL2(VALTOLG)             ERROR CODE                      13420000
         LM    SRB,GR2,NCOMP            RESTORE                         13440000
         DROP  SRR                      DROP TEMP.                      13460000
         USING EEVAL,SRB                AND USE OURS                    13480000
DATAOK   MVI   TERMS,0                  ZERO 1ST BYTE OF RESULT         13500000
         BR    GRZ                                                      13520000
         EJECT                                                          13540000
*                                                                       13560000
*                                                                       13580000
*  ERROR FOUND                                                          13600000
*                                                                       13620000
* TABLE OF ERROR CODES USED IN EEVAL                                    13640000
INVALID  EQU   18                       INVALID SYMBOL                  13660000
RELERR   EQU   25                  RELOCATABILITY ERROR                 13680000
SELFDEF  EQU   91                  SELF-DEF. VALUE TOO LARGE            13700000
ARITHER  EQU   56                  ARITHMETIC ERROR-OVERFLOW            13720000
UDSERR   EQU   24                  UNDEFINED SYMBOL                     13740000
ILORDER  EQU   85                  TWO TERMS NOT SEPARATE               13760000
ILLCHAR  EQU   85                  ILLEGAL CHARACTER                    13780000
MNYERR   EQU   27                  EXP. CONTAINS MORE THAN 16 TERMS     13800000
OPERR    EQU   85                  TWO OPERATORS ILLEGALLY COUPLED      13820000
PARERR   EQU   26                  TOO MANY LEVELS OF PARENS            13840000
ENDERR   EQU   39                  EXP. END PREMATURE-UNPAIRED PAREN    13860000
VALTOLG  EQU   110              VALUE EXCEEDS RANGE                     13880000
* NON-FATAL ERROR FOUND                                                 13900000
* LOG ERROR, CONTINUE NORMAL PROCESSING                                 13920000
*                                                                       13940000
*  ERROR IS RELOCATABLE TERM INVOLVED IN A MULT. OR DIV. OPERATION      13960000
*                                                                       13980000
ERR11    LA    GRA,MORE1                RETURN ADDRESS                  14000000
         LA    GRB,RELERR          RELOCATABILITY ERROR                 14020000
         B     NFATLER1                                                 14040000
*                                                                       14060000
*  ERROR IS SELF-DEFINING VALUE TOO LARGE                               14080000
*                                                                       14100000
ERR0     LA    GRA,ABSD+6               RETURN ADDRESS                  14120000
         LA    GRB,SELFDEF         SELF-DEF. VALUE TOO LARGE            14140000
         B     NFATLER2                                                 14160000
*                                                                       14180000
* ERROR IS SYMBOL LENGTH                                                14200000
*                                                                       14220000
ERR3     LA    GRA,SCANE                RETURN ADDRESS                  14240000
         LA    GRB,INVALID              SYMBOL TOO LONG                 14260000
         B     ERRXXX                                                   14280000
*                                                                       14300000
*                                                                       14320000
*  ERROR IS ARITHMETIC                                                  14340000
*                                                                       14360000
ERR13    LA    GRA,STORE                RETURN ADDRESS                  14380000
         LA    GRB,ARITHER         ARITHMETIC ERROR                     14400000
         B     NFATLER1                                                 14420000
*                                                                       14440000
* ERROR IS SYMBOL NOT FOUND OR SYMBOL MUST BE PREVIOUSLY DEFINED        14460000
*                                                                       14480000
ERR15    LA    GRA,SCANE                RETURN ADDRESS                  14500000
ERR15B   LA    GRB,UDSERR          UNDEFINED SYMBOL                     14520000
         B     ERRXXX                                                   14540000
*                                                                       14560000
NFATLER1 MVC   ERRPT(4),FTXPPT         SET COL PTR TO 1ST BYTE          14580000
NFATLER2 STM   SRB,GR2,NCOMP            SAVE                            14600000
         L     SP1,ERRPT                ERROR POSITION                  14620000
         B     ERRXX                                                    14640000
*                                                                       14660000
* FATAL ERROR FOUND                                                     14680000
* LOG ERROR, EXIT FROM EEVAL WITH SP1 AND SP2 EQUAL 0                   14700000
*                                                                       14720000
*                                                                       14740000
*ERROR IS ILLEGAL CHARACTER                                             14760000
*                                                                       14780000
ERR9     LA    GRB,ILLCHAR         ILLEGAL CHARACTER                    14800000
         B     FATLER2                                                  14820000
*                                                                       14840000
* ERROR IS TWO CONSECUTIVE OPERATORS                                    14860000
*                                                                       14880000
ERR12    LA    GRB,OPERR           ILLEGAL ORDER OF OPERATORS           14900000
         B     FATLER2                                                  14920000
*                                                                       14940000
*ERROR IS ILLEGAL END OF EXPRESSION OR UNPAIRED PARENS                  14960000
*                                                                       14980000
ERR17    LA    GRB,ENDERR          EXPRESSION END PREMATURE             15000000
         B     FATLER2                                                  15020000
*                                                                       15040000
* ERROR IS TWO CONSECUTIVE TERMS                                        15060000
*                                                                       15080000
ERR10    LA    GRB,ILORDER         ILLEGAL ORDER OF TERMS               15100000
*                                                                       15120000
FATLER1  STM   SRB,GR2,NCOMP            SAVE                            15140000
         L     SP1,ERRPT               PT TO 1ST OF TERM OR EXP.        15160000
         LA    GRA,EXERR                FATAL ERROR EXIT                15180000
         B     ERRXX                                                    15200000
FATLER2   LA   GRA,EXERR                FATAL ERROR EXIT                15220000
*                                                                       15240000
*                                                                       15260000
ERRXXX   STM   SRB,GR2,NCOMP            SAVE                            15280000
ERRXX    STH   GRB,ERCODE               PUT IN ERROR CODE               15300000
         MVI   ERROR,X'FF'         TURN ON ERROR SWITCH                 15320000
ERRLOG   L     SRB,CLOGER(ACT)          LOAD BASE/ENTRY                 15340000
         BALR  SRR,SRB             TO LOGERR                            15360000
         DROP  SRB                      THE SAME BIT ABOUT              15380000
         USING *,SRR                    BASE REGISTER TROUBLE           15400000
ERCODE   DS    AL2                 ERROR CODE                           15420000
         LM    SRB,GR2,NCOMP            RESTORE BASE                    15440000
         DROP  SRR                      SET UP AS WAS BEFORE            15460000
         USING EEVAL,SRB                BASE REGISTER SWITCHING         15480000
         BR    GRA                 NO,CONTINUE PROCESSING EXPRESSION    15500000
EXERR    SR    SP1,SP1               SET SP1 TO ZERO                    15520000
SETE     SR    SP2,SP2             SET SP2 TO ZERO                      15540000
         LM    GRA,GRB,REGSAV           RESTORE REGISTERS               15560000
         TM    ERROR,X'FF'         SET CC=3 FOR ERROR CONDITION         15580000
         BR    SRR                      EXIT                            15600000
         EJECT                                                          15620000
* CONVERT SELF-DEFINING VALUES                                          15640000
* ENTER WITH REGISTER COLR POINTING TO 1ST CHARACTER OF CONSTANT.       15660000
* LOAD REGISTER SHFR WITH CONSTANT TYPE INDICATOR-                      15680000
*        1 = BINARY                                                     15700000
*        3 = DECIMAL                                                    15720000
*        4 = HEX                                                        15740000
*        8 = CHARACTER                                                  15760000
* BRANCH WITH RETURN REGISTER RTNR.                                     15780000
* RETURNS WITH CONVERTED VALUE IN REGISTER VALR, RIGHT JUSTIFIED,       15800000
* SIGNIFICANT CHARACTER COUNT IN REGISTER CNTR, COLR AT 1ST             15820000
* NON-CONSTANT CHARACTER.                                               15840000
* REGISTERS SAVR AND CHAR ARE SCRATCHED.                                15860000
* SINGLE + CAUSES IMMEDIATE RETURN WITH CNTR = 0 AND COLR AT +.         15880000
* LEADING BITS MAY BE LOST IF VALUE TOO LARGE.                          15900000
RETR     EQU    GRZ                     RETURN ADDRESS                  15920000
COLR     EQU    SP1                     POINTER TO CHAR                 15940000
SHFR     EQU   GRX                      SHIFT COUNTER                   15960000
VALR     EQU   SP2                      VALUE                           15980000
SAVR     EQU    GRY                     SAVE FOR VALUE                  16000000
CHAR     EQU    GR0                     CHARACTER                       16020000
CNTR     EQU    GR1                     COUNTER                         16040000
SDVCF    SR    VALR,VALR                CLEAR VALUE                     16060000
         LR    CHAR,VALR                CLEAR CHAR                      16080000
         LR    CNTR,VALR                CLEAR COUNT                     16100000
         STC   SHFR,SDV08+1             STORE SHIFT                     16120000
         CLI   SDV08+1,8                TEST FOR C-CONSTANT             16140000
         BNE   SDV01                    NO                              16160000
         L     VALR,SDV09               YES, LOAD EXTERNAL ZEROES       16180000
SDV01    LA    SAVR,SDV08-1(SHFR)       TEST CHAR RANGE                 16200000
         CLC   0(1,COLR),0(SAVR)                                        16220000
         BH    SDV07                    EXIT ON TOO HIGH                16240000
         IC    CHAR,0(COLR)                                             16260000
         LR    SAVR,VALR                SAVE CUMULATIVE VALUE           16280000
         CLI   SDV08+1,8                TEST FOR C-CONSTANT             16300000
         BNE   SDV04                    NO, TO SHIFT                    16320000
         CLI   0(COLR),IQUOTE           TEST '                          16340000
         BNE   SDV02                    NO                              16360000
         CLI   1(COLR),IQUOTE           TEST ''                         16380000
         BE    SDV03                    YES, TO SKIP                    16400000
         B     SDV07                    NO, EXIT                        16420000
SDV02    CLI   0(COLR),IAMPSD           TEST +                          16440000
         BNE   SDV04                    NO, TO SHIFT                    16460000
         CLI   1(COLR),IAMPSD           TEST ++                         16480000
         BNE   SDV06                    NO, ERROR                       16500000
SDV03    LA    COLR,1(COLR)             SKIP ' OR +                     16520000
SDV04    SLL   VALR,0(SHFR)             SHIFT VALUE                     16540000
         CLI   SDV08+1,3                TEST FOR DEC CONSTANT           16560000
         BNE   SDV05                    NO                              16580000
         ALR   VALR,SAVR                YES, ADJUST VALUE               16600000
         ALR   VALR,SAVR                                                16620000
SDV05    ALR   VALR,CHAR                CHAR TO VALUE                   16640000
         LA    CNTR,1(CNTR)             STEP COUNT                      16660000
         LA    COLR,1(COLR)             STEP COLUMN POINTER             16680000
         B     SDV01                    TO NEXT CHAR                    16700000
SDV06    SR    CNTR,CNTR                CLEAR COUNT FOR ERROR           16720000
SDV07    BR    RETR                     EXIT                            16740000
*                                                                       16760000
*                                                                       16780000
SDV08    DC    X'0100090F000000FF'      LIMITS                          16800000
         DS    0F                                                       16820000
SDV09    DC    X'F0F0F0F0'              EBCDIC ZEROES                   16840000
REGSAV   DS    2F                 WORK REGS FOR ERROR HANDLING          16860000
REGSAV1   DS   F                                                        16880000
ERRPT    DS    F                       SAV AREA FOR COL PTR             16900000
FTXPPT   DS    F                       SAV AREA FOR PTR TO 1ST BYTE     16920000
OTHERR   DC    X'00'                   SWITH FOR ERR PATH,0-OFF,1-ON    16940000
FATAL    DC    X'00'               FATAL ERR SWH (0=NON-FATAL,1=FATAL)  16960000
TERMS    DS    16F                      LIST OF VALUES                  16980000
RLIST    DS    16H                      RELOCATABILITY LIST             17000000
RCNTR    DS    C                        COUNTER OF RELOCATABLE TERMS    17020000
ERROR    DS    C                        ON(1), OFF(0)                   17040000
PCNTR    DS    C                        COUNTER OF = OF (               17060000
SYMBL    DS    C         0=SYM 1ST TERM,1=NOT 1ST TERM,255=SYM NOT FND  17080000
NTRMS    DS    16C                      NUMBER OF TERMS PER TERMS ENTRY 17100000
OPRNS    DS    20C                      LIST OF OPERATIONS              17120000
COND     DS    C                        VALIDITY INDICATOR              17140000
ENDOE    DS    C                        END EXPRESSION FLAG             17160000
NEWOP    DS    C                        LATEST OPERATION FOUND          17180000
LREF     DS    C                        L'SYM REF  ON(1) OFF(0)         17200000
NCOMP    DS    11F                      GENERAL SAVE AREA               17220000
SAVE     EQU   NCOMP                                                    17240000
NPTR     DC    A(NTRMS)                 ADDRESS OF NTRMS                17260000
TPTR     DC    A(TERMS)                 ADDRESS OF TERMS                17280000
OPTR     DC    A(OPRNS)                 ADDRESS OF OPRNS                17300000
COMP1    DC    A(RLIST+30)              CONST TO CHECK NO. OF TERMS     17320000
         END                                                            17340000
