FI TITLE '                         FI, ESD OUTPUT PHASE  '              00020000
         ISEQ  73,80                                                    00040000
IEUFI    CSECT                                                          00060000
*          RELEASE 18 DELETIONS                                         00075000
*0352099200                                                       IEUN1 00076018
*0352                                                             IEUN6 00077018
*0352180800                                                       M2017 00078018
*          RELEASE 19 DELETIONS                                         00080000
*                                                                A27084 00082019
*          RELEASE 20 DELETIONS                                         00085000
* 009200-010400,100860,100880,101400-101800,10212-,107860-107890   I000 00086020
* 156600                                                           I004 00087020
*                                                                200002 00088020
* 135820-135832,135852-135860,135872-135900,135908-135912         M3432 00089020
*          RELEASE 21 DELETIONS                                         00090000
* 135907                                                         A33012 00092021
* 107890                                                         A39657 00093021
*          RELEASE 22 DELETIONS                                         00095000
*          RELEASE 23 DELETIONS                                         00100000
*          RELEASE 24 DELETIONS                                         00105000
*          RELEASE 25 DELETIONS                                         00110000
*STATUS CHANGE LEVEL 007                                                00111020
*                                                                       00112020
* INCREMENTAL IMPROVEMENTS FOR RELEASE 20                               00113020
* I000 TSO IMPLEMENTATION                                               00114020
* I004 IMPLEMENTATION OF WXTRN                                          00115020
*TITLE 'IEUFI'      F ASSEMBLER INTERLUDE PHASE                       * 00120000
*FUNCTION/OPERATION-                                                  * 00160000
*   TO WRITE THE EXTERNAL SYMBOL DICTIONARY ON SYSPRINT, SYSPUNCH,    * 00180000
*   AND/OR SYSGO DATA SETS. THE EXTERNAL SYMBOL TABLE SEGMENTS AND    * 00200000
*   LITERAL POOL BASES ARE LOCATED EITHER IN CORE OR ON SYSUT1.       * 00220000
*ENTRY POINT- IEUFI                                                   * 00240000
*   CALLING SEQUENCE                                                  * 00260000
*        LA    13,IOSAVE                ADDRESS OF SAVE AREA          * 00280000
*        XCTL  EP=IEUFI                 TRANSFER CONTROL TO IEUFI     * 00300000
*INPUT-                                                               * 00320000
*   REGISTER- ACT CONTAINS CONTROL TABLE POINTER                      * 00340000
*   PARAMETERS- LITERAL BASE TABLE AND EXTERNAL SYMBOL DICTIONARY. IF * 00360000
*               AN OVERFLOW OCCURRED, THEN ON SYSUT3                  * 00380000
*OUTPUT-                                                              * 00400000
*   REGISTER- ACT CONTAINS CONTROL TABLE POINTER                      * 00420000
*   PARAMETERS- ADJUSTMENT TABLE AND LETERAL ADDRESS TABLE. IF AN     * 00440000
*               OVERFLOW OCCURRED, THEN ON SYSUT1                     * 00460000
*EXTERNAL REFERENCES- NONE                                            * 00480000
*EXITS-                                                               * 00500000
*   NORMAL- TRNASFERS CONTROL TO PHASE 8 VIA                          * 00520000
*        XCTL  EP=IEUF8                                               * 00540000
*   ERROR- NONE                                                       * 00560000
*TABLES/WORK AREAS-                                                   * 00580000
*   ADJUSTMENT TABLE- (1092 BYTES) CONTAINS THE EXTERNAL TABLE SEGMENT* 00600000
*                                  AND LETERAL POOL BASES             * 00620000
*   CALNDR- (12 BYTES) NUMBER OF DAYS PER MONTH                       * 00640000
*   CARD- (81 BYTES) PUNCH CARD AREA FOR ESD OUTPUT                   * 00660000
*   ESDSTG- (6240 BYTES) BUFFER FOR ESD ENTRIES                       * 00680000
*   HD1- (121 BYTES) PRINT LINE FOR FIRST LINE OF HEADING             * 00700000
*   HD2- (121 BYTES) PRINT LINE FOR SECOND LINE OF HEADING            * 00720000
*   LNAME- (121 BYTES) PRINT LINE AREA FOR ESD OUTPUT                 * 00740000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 00760000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 00780000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 00800000
*NOTES -                                                         200002 00806020
*   MAINTENANCEAREA FOR THE PHASE FI IS IN LOC MAINT.            200002 00812020
*                                                                     * 00820000
         EJECT                                                          00840000
         PRINT NOGEN                                                    00860000
         FDIMEN                                                         00880000
         PRINT GEN                                                      00900000
SYMTAB   EQU   CTSYMP                   SYMBOL TABLE ADDRESS            01060000
CSR      EQU   CTESRB                   ESD SEGMENT TABLE BASE ADDRESS  01080000
CTESDC   EQU   CTESDB                   ESD BASE ADDRESS                01100000
LATPTR   EQU   CTLATB                   LITERAL ADDRESS TABLE ADDRESS   01120000
CTRTBL   EQU   CTRTBP                   TRANSLATE TABLE                 01140000
*                                                                       01141020
L3B      EQU   3                        NUMBER OF BYTES TO MOVE    I000 01142020
MKE      EQU   X'10'                    MASK FOR LIST OPTION       I000 01143020
L3       EQU   3                        NUMBER OF BYTES TO MOVE    I000 01144020
L8A      EQU   8                        NUMBER OF BYTES TO MOVE    I000 01145020
MKF      EQU   X'10'                    MASK FOR SYSPRINT          I000 01146020
MKG      EQU   X'EF'                    MASK FOR NOLIST OPTION     I000 01147020
TEST4    EQU   X'08'                    FLAG FOR UNIT RECORD       I000 01148020
NOBUF    EQU   0                        FLAG FOR BUFNO             I000 01149020
DEFTBUF  EQU   2                        DEFAULT BUFNO              I000 01150020
SIZEPH8  EQU   X'5418'                  SIZE OF PHASE 8            I000 01155020
LIST     EQU   X'EF'                    LIST DD CARD MISS SW OFF   I000 01156020
NDDLST   EQU   X'10'                    LIST DD CARD MISS SW ON    I000 01157020
GR14     EQU   14                       GENERAL REGISTER 14             01160000
GR15     EQU   15                       GENERAL REGISTER 15             01180000
*                        TYPES OF ESD ENTRIES                           01200000
SDCON    EQU   0                        SECTION DEF NAME (CSECT,START)  01220000
LDCON    EQU   1                        NAME IN ENTRY                   01240000
ERCON    EQU   2                        EXTERNAL REFERENCE              01260000
PCCON    EQU   4                        UNNAMED CONTROL SECTION         01280000
CMCON    EQU   5                        COMMON CONTROL SECTION          01300000
VCCON    EQU   8                        V-TYPE ADDRESS CONSTANT         01320000
DXCON    EQU   6                        DUMMY EXTERNAL SECTION          01340000
WXCONA   EQU   10                       WEAK EXTERNAL REFERENCE    I004 01346020
         EJECT                                                          01360000
         BALR  U1,0                     SET UP BASE REGISTER            01380000
         USING *,U1                                                     01400000
         BAL   SRR,FII                  CALL INTERLUDE INITIATOR        01420000
         SPACE 2                                                        01440000
         TIME  DEC                      GET DATE                        01460000
         ST    GR0,TIMESV               SAVE TIME OF DAY                01480000
         ST    GR1,WORK                 SAVE DATE                       01500000
         L     GRZ,CTRTBP(ACT)          SAVE JULIAN DATE IN RTA         01510021
         SH    GRZ,=H'8'                IN A DUBBLE WORD JUST           01512021
         UNPK  0(5,GRZ),WORK+1(3)       BEFORE TRTABLE                  01514021
         TM    WORK+1,X'01'             TEST YEAR FOR ODD               01520000
         BO    PHSIN2X                  YES,NOT LEAP YEAR               01540000
         TM    WORK+1,X'12'             NO,TEST BIT 3 AND 6             01560000
         BM    PHSIN2X                  IF MIXED NOT LEAP YEAR          01580000
         MVI   FEB,X'1D'                SET NO OF DAYS IN FEB=29        01600000
PHSIN2X  XC    DWORD(8),DWORD           CLEAR WORK AREA                 01620000
         STH   GR1,DWORD+6              CONVERT DAY OF YEAR             01640000
         CVB   GR0,DWORD                TO BINARY                       01660000
         LA    GRZ,1                    MONTH COUNTER = 1               01680000
         LA    GRX,CALNDR               CALENDAR PTR TO JANUARY         01700000
         SR    GRY,GRY                                                  01720000
PHSIN3X  IC    GRY,0(GRX)               SUBTRACT NO OF DAYS IN A MONTH  01740000
         SR    GR0,GRY                  FROM DAY OF YEAR                01760000
         BC    12,PHSIN4X               DONE IF RESULT ZERO OR MINUS    01780000
         LA    GRZ,1(GRZ)               MONTH CTR=MONTH CTR+1           01800000
         LA    GRX,1(GRX)               CALENDAR PTR=NEXT MONTH         01820000
         B     PHSIN3X                                                  01840000
PHSIN4X  AR    GR0,GRY                  ADD LAST  MONTH BACK            01860000
PHSIN5X  BAL   SRR,CNVRTX               CONVERT MONTH                   01880000
         MVC   DATE(2),DWORD+2          AND MOVE IT IN DATE AREA        01900000
         LR    GRZ,GR0                  CONVERT                         01920000
         BAL   SRR,CNVRTX               DAY                             01940000
         MVC   DATE+3(2),SEQ+2          AND MOVE IT IN DATE AREA        01960000
         MVO   WORK+2(2),WORK(2)        PUT SIGN ON YEAR                01980000
         EX    0,PHSIN2X                CLEAR WORK AREA                 02000000
         MVC   DWORD+6(2),WORK+2        MOVE YEAR WITH SIGN TO WORK     02020000
         CVB   GRZ,DWORD                AREA AND                        02040000
         BAL   SRR,CNVRTX               CONVERT                         02060000
         MVC   DATE+6(2),SEQ+2          MOVE YEAR INTO DATE AREA        02080000
         UNPK  DWORD(7),TIMESV(4)       TIME OF DAY CONVERSION          02100000
         MVC   TIME(2),DWORD                                            02120000
         MVC   TIME+3(2),DWORD+2                                        02140000
         MVC   CTDATE(8,ACT),DATE      DATE TO CONTROL TABLE            02160000
         MVC   CTLITB+9(6,ACT),TIME     TIME TO CONTROL TABLE     IEUN6 02166018
* CTLITB IS SCRATCH AFTER F7.  REUSED FOR END CARD STUFF.         IEUN6 02172018
         MVC   HD1+1(4),CTITLE(ACT)    DECK ID TO HEADING LINE          02180000
         MVC   HD2+113(8),CTDATE(ACT)  DATE TO HEADING LINE             02200000
         MVC   HD2+113-L'TIME(L'TIME),TIME   TIME OF DAY TO HEADING     02220000
         EJECT G0KKK &A-AG0J6P-JH&FG\K{C\&AK &B                         02240000
         L     ACC,CCRDCT(ACT)          PASSED FROM F7 (SYMCARDS)       02260000
         CVD   ACC,CRDCNT               CONVERT TO PACKED               02280000
         UNPK  CDCTFD(4),CRDCNT         PUT IN CARD NUMBER              02300000
         L     ADJPTR,CADJBS(ACT)       ADDRESS OF ADJUSTMENT TABLE     02320000
         LH    NOESD,CNOESD(ACT)        SET NUMBER OF ESD ENTRIES       02340000
         LTR   SEGNO,NOESD              SEE IF ANY ESD S                02360000
         BZ    CALLF8                   NO ESD, CALL IEUF8I             02380000
         L     SRPTR,CSR(ACT)           FIND OUT HOW MANY SEGMENTS      02400000
FI2      CLI   SID(SRPTR),1             IS THERE ONLY ONE               02420000
         BE    FI2HD                    YES, GO ON                      02440000
         LA    SEGNO,15(SEGNO)          NO, READ IN REST OF SEGMENTS    02460000
         SRL   SEGNO,4                  NO. SEGMENTS=NOESD+15/16        02480000
         L     ESDPTR,CTESDS(ACT)       GET LAST BYTE OF ESD            02500000
         ST    ESDPTR,CTESDC(ACT)       SAVE                            02520000
         SH    ESDPTR,=H'259'                                           02540000
 SPACE                                                                  02560000
* READ EXTERNAL SYMBOL DICTIONARY PHASE F/I                             02580000
 SPACE                                                                  02600000
LPFI2    L     SP1,0(SRPTR)             GET POINTER                     02620000
         LA    SP1,0(SP1)               STRIP OFF FIRST BYTE            02640000
RDESD    ST    SP1,ESDTAB               ESD POSITIONAL PTR              02660000
         ST    ESDPTR,ESDTAB+4          ESD BUFFER ADDRESS              02680000
         MVI   ESDTAB+13,1              SET REQUIRE-POSITIONING SW      02700000
         MVI   ESDTAB+14,1              SET FIRST-TIME SW               02720000
         LA    GR1,ESDTAB               ESD IO PARAMETER TABLE          02740000
         BAL   SP2,RDOF                 READ OVERFLOW FILE              02760000
         MVI   LBTAB+13,1               SET LBT REQ-POS SW              02780000
         LA    SRPTR,4(SRPTR)               SET FOR NEXT SEGMENT        02800000
         SH    ESDPTR,=H'260'                                           02820000
         BCT   SEGNO,LPFI2              LOOP FOR ALL SEGMENTS           02840000
FI2HD    L     ESDPTR,CTESDC(ACT)       GET LAST BYTE OF ESD            02860000
         SH    ESDPTR,=H'15'            POSITION FIRST ESD ENTRY        02880000
         L     VARFLD,CRD17             POSITION IN ESD FOR ESD TEXT    02900000
         BAL   SRR,PRNTHD               PRINT THE HEADING               02920000
         LA    ACC,1(ACC)               UP LINE COUNT BY ONE            02940000
         STH   ACC,LINECT               STORE                           02960000
         LH    NOESD,CNOESD(ACT)        NUMBER OF ESD ENTRIES           02980000
         EJECT FIP00370G0KKK &A-AG0J6P-JH&FG\K{C\&AK &B                 03000000
*                        BUILD THE ADJUSTMENT TABLE                     03020000
FI3      CLI   TTYPE(ESDPTR),SDCON      IF TYPE = SD OR PC              03040000
         BE    FI30                     YES,BUILD ADJUSTMENT TABLE ENTR 03060000
         CLI   TTYPE(ESDPTR),PCCON                                      03080000
         BNE   FI8A                     NOT, DONT BUILD ADJUSTMENT TABL 03100000
 SPACE                                                                  03120000
FI30     L     ACC,CSTVAL(ACT)          GET RELATIVE LOC FROM START CD  03140000
         ST    ACC,AID(ADJPTR)          PUT IN ADJUSTMENT TABLE         03160000
         MVC   AID(1,ADJPTR),TID(ESDPTR)     MOVE IN ESD/ID             03180000
         MVC   TADDR(3,ESDPTR),ADDR(ADJPTR)     SET LOCATION IN ESD     03200000
         LA    ADJPTR,4(ADJPTR)         SET ADJPTR FOR NEXT ENTRY       03220000
         A     ACC,TLTH-1(ESDPTR)       ADD LENGTH                      03240000
         LA    ACC,7(ACC)               ADJUST START VALUE              03260000
         ST    ACC,CSTVAL(ACT)          TO NEXT DOUBLE WORD             03280000
         NI    CSTVAL+3(ACT),X'F8'                                      03300000
 SPACE                                                                  03320000
FI8A     SH    ESDPTR,=H'16'            POSITION TO NEXT ESD            03340000
         LH    ACC,ITEMCT               NUMBER LEFT IN THIS BLOCK       03360000
         BCT   ACC,STARP2               BRANCH IF MORE LEFT             03380000
 SPACE                                                                  03400000
ENDSG    LA    ACC,16                   POSITION TO NEXT BLOCK          03420000
         SH    ESDPTR,=H'4'                                             03440000
 SPACE                                                                  03460000
STARP2   STH   ACC,ITEMCT               SAVE NO. LEFT IN BLOCK          03480000
         BCT   NOESD,FI3                LOOP FOR ALL ESD ENTRIES        03500000
 EJECT                                                                  03520000
         L     ESDPTR,CTESDC(ACT)       SET ESD POINTER                 03540000
         SH    ESDPTR,=H'15'            TO FIRST ESD                    03560000
         LH    NOESD,CNOESD(ACT)           NUMBER OF ESD ENTRIES        03580000
         MVC   ITEMCT,=H'16'            NUMBER OF ESD S PER BLOCK       03600000
         SPACE 2                                                        03620000
FI4      CLI   TTYPE(ESDPTR),LDCON      SEE IF AN ENTRY                 03640000
         BE    FI4LD                    YES, GO COMPLETE ENTRY          03660000
TABLOOK  SR    GR2,GR2                                                  03680000
         TRT   TTYPE(1,ESDPTR),BTBL     FIND WHERE TO BRANCH TO         03700000
         B     TYPBR(GR2)               COMPUTED BRANCH                 03720000
*                        BRANCH TABLE                                   03740000
BTBL     DC    12AL1(FIONA-TYPBR)       IF NOT DEFINED BELOW,      I004 03750020
*                                       GO TO FIONA                I004 03760020
 SPACE                                                                  03780000
         ORG   BTBL+SDCON               IF START OR CSECT               03800000
         DC    AL1(FI7-TYPBR)           GO TO FI7                       03820000
         ORG   BTBL+ERCON               IF EXTERNAL REFERENCE           03840000
         DC    AL1(FI7-TYPBR)           GO TO FI7                       03860000
         ORG   BTBL+PCCON               IF PRIVATE CODE                 03880000
         DC    AL1(FI7-TYPBR)           GO TO FI7                       03900000
         ORG   BTBL+CMCON               IF COMMON SECTION               03920000
         DC    AL1(FI7CM-TYPBR)         GO TO FI7CM                     03940000
         ORG   BTBL+VCCON               IF V-TYPE CONSTANT              03960000
         DC    AL1(FI7VC-TYPBR)         GO TO FI7VC                     03980000
         ORG   BTBL+DXCON               IF EXTERNAL DUMMY SECTION       04000000
         DC    AL1(DXD-TYPBR)           GO TO DXD                       04020000
         ORG   BTBL+WXCONA              IF WXTRN                   I004 04026020
         DC    AL1(FI7WX-TYPBR)         GO TO FI7WX                I004 04032020
         ORG                                                            04040000
TYPBR    EQU   *-2                                                      04060000
FIONA    B     FI8B                     SKIP AND GO TO NEXT ESD         04080000
 EJECT                                                                  04100000
*                        PROCESS ENTRY                                  04120000
FI4LD    CLI   TID(ESDPTR),1            HAS THIS ENTRY BEEN COMPLETED   04140000
         BE    LDCOM                    YES                             04160000
 SPACE                                                                  04180000
         LA    SP1,TNAME(ESDPTR)        NO, GET ADDRESS OF NAME         04200000
         BAL   SRR,STGET                GO FIND IN SYMBOL TABLE         04220000
         LTR   SP1,SP1                  NOT FOUND - ERROR               04240000
         BZ    FI8B                                                     04260000
 SPACE                                                                  04280000
         CLI   ESDDD(SP1),0             ABSOLUTE - ERROR                04300000
         BZ    FI8B                                                     04320000
 SPACE                                                                  04340000
         TM    ADJCD(SP1),4             DEFINED IN DSECT OR COM - ERROR 04360000
         BO    FI8B                     ERROR                           04380000
 SPACE                                                                  04400000
         TM    ADJCD(SP1),ENTCMBS       IF XD OR LD COMPLETE            04420000
         BNZ   FI8B                     ERROR                           04440000
         OI    ADJCD(SP1),ENTCMBI       SET XD COMPLETE                 04460000
         TM    ADJCD(SP1),SDBIT         IS THIS A CSECT,DSECT OR EXTRN  04480000
         BC    14,FI8B                   YES,IGNORE                     04500000
 SPACE                                                                  04520000
         MVC   TADDR(3,ESDPTR),VALUE(SP1)  SET ADDRESS AND LENGTH IN    04540000
         MVC   TLTH+2(1,ESDPTR),ESDDD(SP1)   ESD FROM ST                04560000
         B     ADJSCH                   CONTINUE                        04580000
 SPACE                                                                  04600000
 SPACE                                                                  04620000
LDCOM    MVI   TID(ESDPTR),0                                            04640000
         SPACE 1                                                        04660000
ADJSCH   L     ACC,CADJBS(ACT)          SET ACC TO ADJUSTMENT TABLE     04680000
ADJLP    CLC   TLTH+2(1,ESDPTR),0(ACC)  IS THIS THE RIGHT CONTROL SECT  04700000
         BE    ADJFND                     YES                           04720000
 SPACE                                                                  04740000
         LA    ACC,4(ACC)               SET FOR NEXT                    04760000
         B     ADJLP                    LOOP                            04780000
 SPACE                                                                  04800000
ADJFND   L     ACC,0(ACC)               SET ACC WITH                    04820000
         LA    ACC,0(ACC)                 ADJUSTMENT VALUE              04840000
         A     ACC,TTYPE(ESDPTR)        ADD DISPLACEMENT VALUE          04860000
         ST    ACC,TTYPE(ESDPTR)        SET TADDR                       04880000
ELLDID   UNPK  TEMPAR(3),TLTH+2(2,ESDPTR)         CONVERT LLDID         04900000
         TR    TEMPAR(2),HEXTBL                   TO HEX                04920000
         MVC   LLDID(2),TEMPAR          PUT IN OUTPUT AREA              04940000
         B     RETLLD                        SET LLDID WHEN TYPE = LD   04960000
 EJECT                                                                  04980000
*                        PROCESS EXTERNAL DUMMY SECTION                 05000000
DXD      MVC   ESDNO,TADDR(ESDPTR)      GET ESD NUMBER                  05020000
         LH    SP1,ESDNO                                                05040000
         LTR   SP1,SP1                  TEST FOR ZERO                   05060000
         BZ    CALN                     ZERO-GENERATE FROM DXD          05080000
PNTESD   LA    SP2,15                   NON-ZERO-GENERATE FROM V-TYPE   05100000
         NR    SP2,SP1                  GET LOW ORDER BYTE              05120000
         XR    SP2,SP1                  SP2 =15 - ESD NUMBER            05140000
         SLL   SP1,4                    FIND THE DSECT IN THE           05160000
         SRL   SP2,2                    ESD TABLE THAT THIS             05180000
         AR    SP2,SP1                  Q-TYPE REFERENCES               05200000
         L     SP1,CTESDC(ACT)                                          05220000
         SR    SP1,SP2                                                  05240000
         MVC   TLTH(3,ESDPTR),TLTH+1(SP1)         MOVE IN DSECT LENGTH  05260000
CALN     MVC   CALIGN(1,VARFLD),TALIGN(ESDPTR)    PUT IN ALIGNMENT      05280000
FI7CM    MVC   TADDR(3,ESDPTR),=XL3'0'   SET COM TO ZERO                05300000
         B     FI7                      CONTINUE                        05320000
*                        V-TYPE CONSTANTS                               05340000
FI7VC    MVI   TTYPE(ESDPTR),ERCON      SET V-TYPE SAME AS EXTERNAL     05360000
         B     FI7                      CONTINUE                   I004 05370020
 SPACE                                                                  05380000
*                        WEAK EXTERNAL REFERENCE                   I004 05385020
FI7WX    MVI   TTYPE(ESDPTR),WXCONA     SET WXTRN SAME AS V-TYPE   I004 05390020
         SPACE 1                                                   I004 05395020
*                        START, CSECT, PRIVATE CODE, OR EXTERNAL        05400000
FI7      UNPK  TEMPAR(3),TID(2,ESDPTR)  CONVERT TID TO HEX              05420000
         TR    TEMPAR(2),HEXTBL                                         05440000
         MVC   LID(2),TEMPAR                 SET LID                    05460000
         CLI   COL15,C' '               SEE IF COLUMN 15 HAS BEEN SET   05480000
         BNE   ISITER                   YES, DONT SET AGAIN             05500000
 SPACE                                                                  05520000
STCL15   MVC   COL15+1(1),TID(ESDPTR)        SET COL15 = TID            05540000
         MVI   COL15,X'0'                                               05560000
ISITER   CLI   TTYPE(ESDPTR),ERCON      SEE IF EXTERNAL TYPE            05580000
         BE    EER                      YES, BRANCH                     05600000
         CLI   TTYPE(ESDPTR),WXCONA     SEE IF WEAK EXTERNAL TYPE  I004 05606020
         BE    EER                      BRANCH IF YES              I004 05612020
 SPACE                                                                  05620000
ELLTH    UNPK  TEMPAR(7),TLTH(4,ESDPTR) CONVERT LENGTH                  05640000
         TR    TEMPAR(6),HEXTBL         TO HEX FOR OUTPUT               05660000
         MVC   LLTH(6),TEMPAR                                           05680000
 SPACE                                                                  05700000
RETLLD   MVC   CLTH(3,VARFLD),TLTH(ESDPTR)   SET CLTH                   05720000
         UNPK  TEMPAR(7),TADDR(4,ESDPTR)     CONVERT LADDR TO HEX       05740000
         TR    TEMPAR(6),HEXTBL                                         05760000
         MVC   LADDR(6),TEMPAR               SET LADDR                  05780000
         OC    LALIGN(1),CALIGN(VARFLD) SET ALIGNMENT                   05800000
         B     RETEER                   ALREADY SET CLTH SO SKIP NEXT   05820000
 SPACE                                                                  05840000
EER      MVC   CLTH(3,VARFLD),CLTH-1(VARFLD)                            05860000
RETEER   L     ACC,CTRTBL(ACT)          ADDRESS OF TRT TABLE            05880000
         TR    TNAME(8,ESDPTR),0(ACC)        CAUTION - CHANGES ESD      05900000
         MVC   CNAME(8,VARFLD),TNAME(ESDPTR) SET CNAME                  05920000
         MVC   LNAME(8),TNAME(ESDPTR)          AND LNAME                05940000
         MVC   CTYPP(4,VARFLD),TTYPE(ESDPTR) SET CTYPE AND CADDR        05960000
         SR    ACC,ACC                                                  05980000
         IC    ACC,TTYPE(ESDPTR)        GET TYPE                        06000000
         AR    ACC,ACC                  DOUBLE                          06020000
         LH    ACC,TYPTBL(ACC)          GET TYPE NAME FROM TABLE        06040000
         STH   ACC,LTYPE                PUT IN PRINT LINE               06060000
 SPACE                                                                  06080000
         AH    VARFLD,=H'16'                   VARFLD VARFLD + 16       06100000
         C     VARFLD,CRDTOP            SEE IF CARD IMAGE IS FULL       06120000
         BNE   OUTLNE                   NO, DONT PUT OUT CARD           06140000
 SPACE                                                                  06160000
NOROUT   MVI   CBYTE+1,X'30'            PUT IN NO. BYTES IN CARD        06180000
         BAL   INTSUB,SUB               OUTPUT ESD CARD IMAGE           06200000
OUTLNE   LH    ACC,LINECT               GET LINE COUNT                  06220000
         BCT   ACC,LINEOK               REDUCE BY ONE                   06240000
         BAL   SRR,PRNTHD               IF ZERO, START BY HEADED NEW PG 06260000
LINEOK   STH   ACC,LINECT               SAVE LINE COUNT                 06280000
         LA    SP1,LNAME-1              ADDRESS OF WHERE TO PRINT FROM  06300000
         BAL   SRR,SYSL                 PRINT ON SYSPRINT               06320000
         MVI   LNAME-1,0                SET SINGLE SPACE FOR NEXT PRINT 06340000
         MVI   LNAME,C' '               BLANK OUT PRINT OUTPUT AREA     06360000
         MVC   LNAME+1(34),LNAME                                        06380000
 SPACE                                                                  06400000
FI8B     SH    ESDPTR,=H'16'            POSITION TO NEXT ESD            06420000
         LH    ACC,ITEMCT               NUMBER LEFT IN THIS BLOCK       06440000
         BCT   ACC,FI9                  BRANCH IF MORE LEFT             06460000
 SPACE                                                                  06480000
ENDSG2   LA    ACC,16                   POSITION TO NEXT BLOCK          06500000
         SH    ESDPTR,=H'4'                                             06520000
FI9      STH   ACC,ITEMCT               SAVE NUMBER LEFT IN BLOCK       06540000
         BCT   NOESD,FI4                LOOP FOR ALL ESD ENTRIES        06560000
 SPACE                                                                  06580000
FI10     S     VARFLD,CRD17             GET NUMBER OF FIELDS IN CARD    06600000
         BZ    FI5                      NONE, CONTINUE ON               06620000
 SPACE                                                                  06640000
         SH    VARFLD,=H'16'            SEE IF ONE OR TWO FIELDS LEFT   06660000
         LA    INTSUB,FI5               RETURN FOR OUTPUT CARD ROUTINE  06680000
         BZ    ONEFLD                   ONE FIELD LEFT - PUT IT OUT     06700000
 SPACE                                                                  06720000
         MVI   CBYTE+1,X'20'            TWO FIELDS LEFT                 06740000
         B     SUB                      PUT IT OUT                      06760000
 EJECT                                                                  06780000
*                        BUILD THE LITERAL ADDRESS TABLES (LAT)         06800000
FI5      ST    ADJPTR,LATPTR(ACT)       SET POSITION TO BUILD LAT       06820000
         MVI   3(ADJPTR),LATIOT         SET LAT IO TYPE                 06840000
         LA    ADJPTR,3(ADJPTR)         SET UP BUFFER AREA              06860000
         ST    ADJPTR,LADECB+12         FOR OVERFLOW LAT                06880000
         LA    ADJPTR,1(ADJPTR)                                         06900000
         ST    ADJPTR,LABPTR            SET LAT BUFFER PTR              06920000
         S     ADJPTR,CADJBS(ACT)       ADJPTR IS LENGTH OF ESD ADJ TAB 06940000
         LCR   ADJPTR,ADJPTR                                            06960000
         A     ADJPTR,ATLEN             ADJPTR IS LENGTH OF LAT + X     06980000
         N     ADJPTR,=F'-16'             GET RID OF X                  07000000
         STH   ADJPTR,CTLALN(ACT)       SET                             07020000
         A     ADJPTR,LABPTR              CTLALN AND                    07040000
         ST    ADJPTR,CTLATL(ACT)           CTLATL                      07060000
         LH    ACC,CTLALN(ACT)          GET LENGTH OF LAT               07080000
         LA    ACC,1(ACC)               INCREASE BY ONE                 07100000
         STH   ACC,CTLALN(ACT)          SET IT BACK                     07120000
         STH   ACC,LADECB+6                                             07140000
FI11P    BAL   SRR,GETLBT               GET LITERAL BASE TABLE          07160000
         BZ    FICLS                    NO MORE LBT S, CLOSE FILE       07180000
 SPACE                                                                  07200000
         LR    LBTPTR,SP1               SET LBT POINTER                 07220000
         BAL   SRR,PUTLAT               PUT OUT LAT                     07240000
         LR    LADJP,SP1                                                07260000
FI13     L     ADJCT,CADJBS(ACT)        SET PTR TO ADJ BASE FOR SEARCH  07280000
         IC    ACC,LBTID(LBTPTR)                                        07300000
         SLL   ACC,24                   SET UP LBT/ID                   07320000
LOOPSR   CLC   LBTID(1,LBTPTR),AID(ADJCT) SEARCH ESD ADJ TAB WITH LBTID 07340000
         BE    RELFND                       FOUND                       07360000
         LA    ADJCT,4(ADJCT)              IF NOT, INCREMENT ESD ADJPTR 07380000
         CL    ADJCT,LATPTR(ACT)          ARE WE AT TOP                 07400000
         BL    LOOPSR                   NO, TRY AGAIN                   07420000
         B     ATOP                     YES                             07440000
 EJECT                                                                  07460000
RELFND   MVC   TEMPF+1(3),ADDR(ADJCT)   SET LITERAL ADJ TABLE           07480000
         A     ACC,TEMPF                WHERE IT WAS FOUND              07500000
ATOP     MVC   TEMPF+1(3),LITAD(LBTPTR)                                 07520000
         A     ACC,TEMPF                1ST ITEM = ID, ADDR, + LITAD    07540000
         ST    ACC,AID(LADJP)                                           07560000
         MVC   TEMPF+1(3),D8(LBTPTR)                                    07580000
         A     ACC,TEMPF                2ND ITEM = 1ST + D8             07600000
         ST    ACC,AID+4(LADJP)                                         07620000
         MVC   TEMPF+1(3),D4(LBTPTR)                                    07640000
         A     ACC,TEMPF                3RD ITEM = 2ND + D4             07660000
         ST    ACC,AID+8(LADJP)                                         07680000
         MVC   TEMPF+1(3),D2(LBTPTR)                                    07700000
         A     ACC,TEMPF                4TH ITEM = 3RD + D2             07720000
         ST    ACC,AID+12(LADJP)                                        07740000
         MVC   AID+00(1,LADJP),LBTID(LBTPTR) ***RESTORE ESDID           07760000
         MVC   AID+04(1,LADJP),LBTID(LBTPTR) **JUST IN CASE             07780000
         MVC   AID+08(1,LADJP),LBTID(LBTPTR) ***THERE WAS WRAP AROUND   07800000
         MVC   AID+12(1,LADJP),LBTID(LBTPTR) ***IN THE LITERAL POOL     07820000
FI14     B     FI11P                                                    07840000
 SPACE                                                                  07860000
*                        PUNCH OUTPUT CARD                              07880000
ONEFLD   MVI   CBYTE+1,X'10'            NUMBER BYTES FOR ONE FIELD      07900000
SUB      MVI   CBYTE,X'0'                    INTERNAL SUBROUTINE FOR    07920000
         MVC   CRDNME(4),CTITLE(ACT)    OUTPUTTING CARD IMAGE           07940000
         CVB   ACC,CRDCNT               PUT IN CARD SEQUENCE            07960000
         LA    ACC,1(ACC)               ADD ONE                         07980000
         CVD   ACC,CRDCNT                                               08000000
         UNPK  CDCTFD(4),CRDCNT         PUT IN COUNT FIELD              08020000
         OI    CDCTFD+3,X'F0'           SET ZONE                        08040000
         LA    SP1,CARD-1               WHERE TO START OUTPUTTING       08060000
         BAL   SRR,SYSO                 PUT OUT CARD                    08080000
         L     VARFLD,CRD17             RESTORE WHERE TO PUT ESD ON CD  08100000
         MVC   CARD+5(67),CARD+4        BLANK OUT CARD                  08120000
         BR    INTSUB                   RETURN                          08140000
 SPACE                                                                  08160000
*                        PRINT HEADING                                  08180000
PRNTHD   ST    SRR,SAVEF                SAVE RETURN                     08200000
         CVB   ACC,PGCNT                                                08220000
         LA    ACC,1(ACC)               INCREMENT PAGE COUNT            08240000
         CVD   ACC,PGCNT                KEEP PAGE COUNT IN PACKED       08260000
         UNPK  CNTFLD(4),PGCNT          SET IN FIELD                    08280000
         LA    R1,CNTFLD+3                                              08300000
         TRT   CNTFLD(3),DECTBL-240     FIRST NON ZERO                  08320000
         S     R1,ACNTFLD               BLANK OUT ALL LEADING ZEROS     08340000
         EX    R1,MVBLNK                                                08360000
         OI    CNTFLD+3,X'F0'           REMOVE SIGN FROM LAST DIGIT     08380000
         LA    SP1,HD1                  PRINTS HEADING ONE              08400000
         BAL   SRR,SYSL                 CALL SYSLIST                    08420000
         LA    SP1,HD2                  PRINTS HEADING TWO              08440000
         BAL   SRR,SYSL                 CALL SYSLIST                    08460000
         MVC   HD2+113-L'TIME(L'TIME),=CL6' '  TOD ON PAGE ONE ONLY     08480000
         MVI   LNAME-1,2                RESET PRINT BUFFER              08500000
         SR    ACC,ACC                                                  08520000
         IC    ACC,CTPGLNCT(ACT)        SET LINE COUNT                  08540000
         L     SRR,SAVEF                RESTORE RETURN ADDRESS          08560000
         BR    SRR                      RETURN                          08580000
MVBLNK   MVC   CNTFLD(0),=CL6' '                                        08600000
 EJECT                                                                  08620000
*                        FIND SYMBOL IN SYMBOL TABLE                    08640000
STGET    LA    1,8(SP1)                 SET AT END OF NAME              08660000
         TRT   0(8,SP1),TRTABLE         SCAN TO END OF NAME             08680000
         LR    SP2,1                                                    08700000
         SR    SP2,SP1                  =LENGTH OF SYMBOL OR 256        08720000
         BZ    GETOUT                   IF LE ZERO. NGTH IS             08740000
 SPACE                                                                  08760000
KNOWN    LA    1,8                                                      08780000
         CR    1,SP2                    IF SYMBOL IS GREATER THAN 8,    08800000
         BCTR  SP2,0                                                    08820000
         BC    4,GETOUT                 SET 'NOT FOUND' AND EXIT.       08840000
 SPACE                                                                  08860000
         SR    RW1,RW1                  CLEAR REGISTER                  08880000
         ST    RW1,BENCH                AND WORKBENCH.                  08900000
         ST    RW1,BENCH+4              CLEAR BENCH.                    08920000
         EX    SP2,MOVE1                SYMBOL TO BOUNDARY.             08940000
         LM    REVEN,RODD,BENCH         LOAD SYMBOL LEFT JUSTIFIED.     08960000
         XR    RODD,REVEN               FOLD SYMBOL INTO FULLWORD.      08980000
         SR    REVEN,REVEN              CLEAR 4 BYTES OF DIVIDEND.      09000000
         D     REVEN,CPRIME(ACT)        PRIME IS HASH DIMENSION.        09020000
         LA    RODD,0(REVEN,REVEN)      MULTIPLY BY                     09040000
         AR    RODD,REVEN               THREE BYTES/POINTER.            09060000
         L     RSTB,SYMTAB(ACT)         FIND SYMBOL TABLE BASE          09080000
         LA    RODD,LASH(RODD,RSTB)     LASH IS LENGTH OF LITERAL HASH. 09100000
         ST    RW1,BENCH                CLEAR BENCH                     09120000
FOLLOW   MVC   BENCH+1(3),0(RPT)        POINTER TO BOUNDARY             09140000
         L     RPT,BENCH                POINTER TO REGISTER             09160000
         LTR   RPT,RPT                  IF POINTER IS ZERO,NO SYNONYMS. 09180000
         BZ    GETOUT                   (INITIALIZED BEFORE EACH FILL). 09200000
 SPACE                                                                  09220000
         AR    RPT,RSTB                                                 09240000
         EX    SP2,ACLI                 IF UNEQUAL LENGTHS, SEE IF AT   09260000
         BNE   BITTER END OF THREAD YET.                                09280000
         EX    SP2,ACLC                 COMPARE SYMBOLS.                09300000
 SPACE                                                                  09320000
BITTER   IC    RW1,ILENG(RPT)           GET LENGTH OF SYMBOL            09340000
         LA    RPT,2(RPT,RW1)           POINT TO FIXED LENGTH INFO.     09360000
         BE    FOUND                    IF SYMBOLS ARE EQUAL.           09380000
 SPACE                                                                  09400000
         TM    ADJ(RPT),EOS                                             09420000
         BZ    GETOUT                   IF END OF STRING                09440000
 SPACE                                                                  09460000
         TM    ADJ(RPT),NAMES                                           09480000
         LA    RPT,IOTHER(RPT)          OTHERS.                         09500000
         BC    12,FOLLOW                BRANCH NOT NAME                 09520000
 SPACE                                                                  09540000
         LA    RPT,INAME(RPT)           NAME ITEMS ARE LONGER THAN      09560000
         B     FOLLOW THE THREAD                                        09580000
 SPACE 2                                                                09600000
FOUND    LR    SP1,RPT                  LOAD ADDRESS OF FIXE LENGTH INF 09620000
         BR    SRR                      RETURN                          09640000
 SPACE                                                                  09660000
GETOUT   SR    SP1,SP1                  SET PARAM 'NOT FOUND'.          09680000
         BR    SRR                      RETURN                          09700000
 SPACE 4                                                                09720000
ACLI     CLI   ILENG(RPT),0             EXECUTED                        09740000
ACLC     CLC   0(0,SP1),ISYM(RPT)       EXECUTED                        09760000
MOVE1    MVC   BENCH(0),0(SP1)          EXECUTED                        09780000
 SPACE 2                                                                09800000
*        *     SYMBOLIC DISPLACEMENTS                                   09820000
 SPACE                                                                  09840000
EOS      EQU   32                       END OF STRING INDICATOR         09860000
NAMES    EQU   3                        EXTERNAL DICTIONARY SYMBOL TYPE 09880000
ILENG    EQU   0                                   X+0                  09900000
LASH     EQU   31                       LENGTH OF LITERAL AND     IEUN1 09910018
*                                       OPSYN HASH TABLES               09920018
ISYM     EQU   1                                   X+1                  09940000
ADJ      EQU   1                                   Y+1                  09960000
INAME    EQU   5                        CHAIN POINTER  Y+8              09980000
IOTHER   EQU   3                        ESD/ID  Y+3                     10000000
 EJECT                                                                  10020000
* F/INTERLUDE INITIALIZATION                                            10040000
         SPACE 1                                                        10060000
FII      MVC   PHSIN+5(3),LSTDCB+1(ACT) SYSLIST DCB ADDRESS             10080000
         USING IHADCB,GR1                                         18848 10081000
         L     GR1,CTOUT1(,ACT)           DCB OF                  18848 10083000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)  DCB OF SYSUT3,          18848 10084000
         L     GR1,CTOUT2(,ACT)           DCB OF                  18848 10085000
         MVC   DCBSYNAD+1(L3B),=AL3(IOERR)   SYSUT1 OR SYSUT2      I000 10086020
         L     GR1,LSTDCB(,ACT)           DCB OF                  18848 10087000
         MVC   DCBSYNAD+1(L3B),=AL3(IOERR)   SYSLST                I000 10088020
         L     GR1,PCHDCB(,ACT)           DCB OF                  18848 10089000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)    SYSPUNCH, AND         18848 10090000
         L     GR1,GODCB(,ACT)            DCB OF                  18848 10091000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)    SYSGO.                18848 10092000
         DROP  GR1                                                18848 10093000
         SPACE 1                                                        10100000
         LA    GRZ,IOSAVE               SAVE AREA                       10120000
         TM    CTLSTI(ACT),MKE          IS LIST OPTION REQ         I000 10160020
         BZ    NOPRINT                  NO, DONT LIST EITHER            10200000
         L     SP1,LSTDCB(ACT)          DCB OF SYSPRINT            I000 10202020
         USING IHADCB,SP1                                          I000 10204020
         CLC   DCBEXLST+1(L3),=AL3(0)   WAS DDCARD FOR SYSPRINT    I000 10206020
         BE    PHSIN                    FOUND,YES                  I000 10208020
         MVC   DCBEXLST+1(L3),LSTXLST+1 NO,MAY BE A TERMINAL       I000 10210020
         MVC   WTOPRT+32(L8A),DCBDDNAM DDNAME OF SYSPRINT          I000 10215020
         NI    CTDDERR(ACT),LIST        RST LIST DD CARD MISS SW   I000 10217020
PHSIN    OPEN  (0,(OUTPUT))             YES, OPEN OUTPUT LISTING        10220000
         TM    DCBOFLGS,MKF             IS SYSPRINT OPENED OK      I000 10225020
         BZ    NOPEN                    NO,THEN CONSOLE MESSAGE    I000 10230020
         DROP  SP1                                                 I000 10235020
         L     1,LSTDCB(ACT)            COMPLETE OPEN BY SETTING        10240000
         PUT   (1)                      UP FIRST LINE,                  10260000
         ST    1,CTPBUFPT(ACT)          SAVE OUTPUT ADDRESS             10280000
         MVI   1(1),C' '                BLANK OUT OUTPUT LINE           10300000
         MVC   2(119,1),1(1)                                            10320000
         MVI   0(1),EJECTAP             AND SET TO EJECT                10340000
         MVI   CTLINECT+3(ACT),1        AND RESETTING LINE COUNT.       10360000
NOPRINT  MVC   OFDECB+8(4),CTOUT1(ACT)  OBTAIN OVERFLOW FILE DCB PTR    10380000
         MVC   LADECB+8(4),CTOUT2(ACT)  OBTAIN ALT OVERFLOW DCB PTR     10400000
         LH    SP1,CTCLBT(ACT)          LBT RECORD ON OVERFLOW FILE     10420000
         LTR   SP1,SP1                                                  10440000
         BZ    PHSIN1                   NO TO PHSIN1                    10460000
         MVC   LBTAB+4(4),CTLBTP(ACT)   LBT BUFFER PTR                  10480000
         MVC   LBTAB+10(2),CTCLBT(ACT)  LBT RECORD COUNT                10500000
         MVC   LBTAB(4),CTRLBT(ACT)     LBT 1ST RECORD PTR              10520000
         LA    GR1,LBTAB                LBT IO PARAMETER TABLE          10540000
         BAL   SP2,RDOF                 READ OVERFLOW FILE              10560000
PHSIN1   L     SP1,CTLBTP(ACT)          LBT BUFFER                      10580000
         LA    SP1,1(SP1)               LBT 1ST LOGICAL RECORD PTR      10600000
         ST    SP1,LBPTR                LOG REC PTR                     10620000
         LA    SP1,78(SP1)              UP TO 6 LBT S                   10640000
         ST    SP1,LBLWA                LBA OF LBT BUFFER               10660000
         L     GR1,CTESRB(ACT)          ESR BUFFER PTR                  10680000
         CLI   0(GR1),2                 TABLE OVERFLOW                  10700000
         BCR   7,SRR                    NO EXIT                         10720000
         L     SP1,LESDFBA        USE LARGE RESIDENT BUFFER FOR ESD'S   10740000
         ST    SP1,CTESDS(ACT)          FBA OF ESD BUFFER               10760000
         BR    SRR                      EXIT                            10780000
NOPEN    EQU   *                                                   I000 10783020
WTOPRT   WTO   'IEU997I OPEN FAILED FOR ********, NOLIST OPTION USED', X10786020
               ROUTCDE=(2,11),DESC=7                               I000 10789021
         NI    CTPCHI(ACT),MKG          SET NOLIST OPTION          I000 10792020
         OI    CTDDERR(ACT),NDDLST      SET LIST DD CARD MISS SW0  I000 10793020
         B     NOPRINT                                             I000 10795020
LESDFBA  DC    A(ESDFBA)                                                10800000
 EJECT                                                                  10820000
* F/INTERLUDE PHASE CLOSE                                               10840000
FICLS    BAL   SRR,PUTLAT               RETRIEVE NEXT LAT POSITION      10860000
         MVC   0(4,SP1),EOF             EMBED AN EOF                    10880000
         LH    SP1,CTCLAT(ACT)          PREVIOUS BLOCKS BEEN WRITTEN    10900000
         LTR   SP1,SP1                                                  10920000
         BZ    CALLF8                   NO                              10940000
         BAL   SP2,WRLAT                YES, WRITE LAT                  10960000
******************                                                      10980000
 SPACE                                                                  11000000
CALLF8   MVC   CCRDCT(4,ACT),CDCTFD     MOVE IN CARD COUNT              11020000
         LA    GRZ,IOSAVE               SAVE AREA FOR OS/360            11040000
*        TCLOSE  (SYSUX,REREAD)         CLOSE FILE                      11060000
FCL1     MVC   FCL2(3),CTOUT2+1(ACT)    ALT OVERFLOW FILE DCB PTR       11080000
         CNOP  0,4                                                      11100000
         BAL   1,FCL2+3                                                 11120000
         DC    X'90'                    REREAD OPTION                   11140000
FCL2     DC    AL3(0)                   DCB ADDRESS                     11160000
         SVC   23                       EXIT TO TCLOSE                  11180000
******************                                                      11200000
         XCTL  EP=IEUF8                 CALL IN PHASE IEUF8  IN IEUF8I  11220000
         EJECT                                                          11240000
* GET LITERAL BASE TABLE PHASE F/I                                      11260000
GETLBT   L     SP1,LBPTR                NEXT LOGICAL RECORD POINTER     11280000
         CLC   0(4,SP1),EOF             EOF LABEL                       11300000
         BNE   GETLB2                   NO TO GETLB2                    11320000
         SR    SP1,SP1                  SET EOF FLAG                    11340000
         BR    SRR                      EXIT                            11360000
GETLB2   CL    SP1,LBLWA                EXCEED BUFFER                   11380000
         BL    GETLB1                   NO TO GETLB1                    11400000
         LA    GR1,LBTAB                LBT IO PARAMETER TABLE          11420000
         BAL   SP2,RDOF                 READ OVERFLOW FILE              11440000
         BCR   8,SRR                    BLOCK COUNT ZERO                11460000
         L     SP1,LBTAB+4                                              11480000
         LA    SP1,1(SP1)               1ST LOGICAL REC PTR             11500000
GETLB1   LR    GR1,SP1                                                  11520000
         LA    GR1,13(GR1)              ADVANCE TO NEXT LOGICAL RECORD  11540000
         ST    GR1,LBPTR                                                11560000
         BR    SRR                      EXIT                            11580000
LBTAB    DC    F'0'                     FILE POSITION PTR               11600000
         DC    F'0'                     LBT BUFFER PTR                  11620000
         DC    H'79'                    LBT BLOCK LENGTH                11640000
         DC    H'0'                     LBT BLOCK COUNT                 11660000
         DC    X'04'                    LBT TYPE INDICATOR              11680000
         DC    X'1'                     LBT POSITIONAL SW               11700000
         DC    X'1'                     FIRST TIME SW                   11720000
 EJECT                                                                  11740000
* PUT LITERAL ADJUSTMENT TABLE PHASE F/I                                11760000
PUTLAT   L     SP1,LABPTR               LAT LOGICAL RECORD POINTER      11780000
         CL    SP1,CTLATL(ACT)          PTR EXCEED BUFFER               11800000
         BL    PUTLA1                   NO TO PUTLA1                    11820000
         BAL   SP2,WRLAT                YES, WRITE OUT LAT              11840000
PUTLA1   LR    GR1,SP1                                                  11860000
         LA    GR1,16(GR1)              ADVANCE PTR TO NEXT LOGICAL REC 11880000
         ST    GR1,LABPTR                                               11900000
         BR    SRR                      EXIT TO USER                    11920000
WRLAT    STM   GRZ,GR15,IOSAVE          WRITE LITERAL ADJUSTMENT TABLE  11940000
         LA    GRZ,IOSAVE+12            SET UP SAVE AREA                11960000
         LA    GR1,LADECB               LAT DECB                        11980000
         L     GR2,LADECB+8             DCB ADDRESS                     12000000
         L     GR15,48(GR2)             WRITE SUBROUTINE ADDRESS        12020000
         BALR  GR14,GR15                EXIT TO WRITE                   12040000
         LA    GR1,LADECB                                               12060000
         L     GR15,52(GR2)             CHECK SUBROUTINE ADDRESS        12080000
         BALR  GR14,GR15                EXIT TO CHECK                   12100000
         LH    GR1,CTCLAT(ACT)          LAT BLOCK COUNT                 12120000
         LA    GR1,1(GR1)               UP LAT BLOCK COUNT BY ONE       12140000
         STH   GR1,CTCLAT(ACT)                                          12160000
         LM    GRZ,GR15,IOSAVE          RESTORE REGISTERS               12180000
         L     SP1,CTLATB(ACT)          LAT BUFFER POINTER              12200000
         LA    SP1,4(SP1)               FBA OF LAT LOGICAL RECORD       12220000
         BR    SP2                      EXIT WRLAT                      12240000
LADECB   DC    F'0'                     ALTERNATE OVERFLOW FILE DECB    12260000
         DC    X'0020'                  OP AND TYPE FIELD               12280000
         DC    H'0'                     LENGTH FIELD                    12300000
         DC    A(0)                     ALTERNATE OVERFLOW FILE DCB     12320000
         DC    F'0'                     BUFFER ADDRESS                  12340000
         DC    F'0'                     STATUS INDICATORS               12360000
* SYSTEM OUTPUT SUBROUTINE F ASSEMBLER                                  12380000
SYSO     LA    SP1,1(SP1)               BYPASS CTL CHAR.                12400000
         STM   13,1,IOSAVE              SAVE                            12420000
         LA    13,IOSAVE+20             AND SET UP SAVE AREA            12440000
         TM    CTPCHI(ACT),X'80'        PUNCH OPTION BIT                12460000
         BZ    PCHI                     NO, DONT PUNCH CARD             12480000
         L     1,PCHDCB(ACT)            YES, GET PUNCH DCB              12500000
         PUT   (1),(SP1)                OUTPUT TO SYSPUNCH              12520000
PCHI     TM    CTPCHI(ACT),X'40'        GO OPTION BIT                   12540000
         BZ    PCHX                     NO, DONT PUT ON SYSGO           12560000
         L     1,GODCB(ACT)             YES, GET SYSGO DCB              12580000
         PUT   (1),(SP1)                OUTPUT TO SYSGO                 12600000
PCHX     LM    13,1,IOSAVE              RESTORE REGISTERS               12620000
         BR    SRR                      RETURN                          12640000
 EJECT                                                                  12660000
* SYSTEM LIST SUBROUTINE F ASSEMBLER                                    12680000
SYSL     TM    CTPCHI(ACT),X'10'        BYPASS IF NO PRINT.             12700000
         BCR   8,SRR                    NO PRINT, RETURN                12720000
         STM   GRA,GRC,PRSAV            SAVE GRA-C.                     12740000
         STM   13,1,IOSAVE              SAVE 13-01                      12760000
         LA    13,IOSAVE+20             O/S SAVE AREA.                  12780000
         LM    GRA,GRB,CTLINECT(ACT)    GRA=LINE COUNT.                 12800000
         CLI   0(SP1),0                 GRB=PREVIOUS LINE LOCATION.     12820000
         BE    SYSLNORM                 NORMAL PRINT FOR CODE 00        12840000
         CLI   0(SP1),55                55 OR GREATER FORCES EJECT.     12860000
         BL    SYSLSPCE                 JUST SPACE, NO EJECT            12880000
SYSLEJCT MVI   0(GRB),EJECTAP           PUT IN EJECT CODE               12900000
         B     SYSLNORM                 CONTINUE AS NORMAL              12920000
SYSLSPCE SR    GRC,GRC                  01 TO 54 FORCES THAT NUMBER     12940000
         IC    GRC,0(SP1)               OF BLANK LINES(SPACES).         12960000
         CH    GRC,=H'2'                SEE IF LESS THAN 2 SPACES       12980000
         BH    *+16                     IS NOT, SO SPACE 3 AT A TIME    13000000
         IC    GRC,APTBL-1(GRC)         01 OR 02 FORCES ONLY            13020000
         STC   GRC,0(GRB)               NEW CODE IN PREVIOUS LINE.      13040000
         B     SYSLNORM                                                 13060000
         MVI   0(GRB),SPACE3AP          03-54 GENERATE A MINIMUM        13080000
         SH    GRC,=H'2'                NUMBER OF LINES WITH            13100000
SYSLSPLP L     1,LSTDCB(ACT)            SPACE IMMEDIATE CODES.          13120000
         PUT   (1)                      PUT OUT LAST LINE AND GET ONE   13140000
         LR    GRB,1                    SAVE WHERE NEXT LINE IS         13160000
         LA    GRA,1(GRA)               INCREMENT LINE COUNT            13180000
         MVI   1(GRB),X'40'             INSERT BLANK             A27084 13186019
         MVC   2(119,GRB),1(GRB)                                 A27084 13192019
         CH    GRC,=H'3'                SEE IF MORE THAN 3              13200000
         BNH   *+16                     NOT SO, DONT LOOP               13220000
         MVI   0(GRB),SPACE3IM          PUT IN TRIPLE SPACE             13240000
         SH    GRC,=H'3'                REDUCE NO. SPACES BY 3          13260000
         B     SYSLSPLP                 LOOP                            13280000
         IC    GRC,IMTAB-1(GRC)         GET CONTROL FOR SPACES LEFT     13300000
         STC   GRC,0(GRB)                                               13320000
SYSLNORM L     1,LSTDCB(ACT)            GET SYSPRINT DCB                13340000
         PUT   (1)                      PUT OUT RECORD                  13360000
         LR    GRB,1                    SAVE NEXT LINE POINTER          13380000
         LA    GRA,1(GRA)               INCREMENT LINE COUNT.           13400000
         MVI   0(GRB),SPACE1AP          PUT IN NORMAL SPACING           13420000
         MVC   1(120,GRB),1(SP1)        TRANSFER LINE TO BUFFER.        13440000
         STM   GRA,GRB,CTLINECT(ACT)    RESTORE LCOUNT AND POINTER.     13460000
         LM    GRA,GRC,PRSAV            RESTORE GRA-C.                  13480000
         LM    13,1,IOSAVE              RESTORE 13-01                   13500000
         BR    SRR                      RETURN.                         13520000
PRSAV    DC    3F'0'                    REGISTR SAVE AREA.              13540000
APTBL    DC    AL1(SPACE2AP,SPACE3AP)   SPACE AFTER PRINT TABLE         13560000
IMTAB    DC    AL1(SPACE1IM,SPACE2IM,SPACE3IM) SPACE IMMEDIATE TABLE    13580000
*                                                                  I000 13580420
*       SYSPRINT DCB EXIT ROUTINE                                  I000 13580820
*                                                                  I000 13581220
* REGISTERS USED IN THIS RTN ARE GR0,GR1,GR2,GRA,GRB,GRD,GR14      I000 13581620
BT       EQU   X'30'                    DCB RECORD FORMATS        M3432 13582020
FM       EQU   X'82'                                              M3432 13582420
B        EQU   X'10'                                              M3432 13582820
T        EQU   X'20'                                              M3432 13583220
         SPACE 1                                                   I000 13583620
LSTXRTN  ST    GR14,PSAVE               RETURN ADDRESS             I000 13584020
         USING IHADCB,GR1                                          I000 13584420
         NI    DCBRECFM,BT              RECFM=BT IF SPEC IN DD    M3432 13584520
         OI    DCBRECFM,FM              RECFM=FM IS DEFAULT       M3432 13584620
         CLI   PRDEVT+2,TEST4           YES,IS UNIT RECORD SPEC    I000 13584820
         BE    LSTX5                    YES,SET BLKSIZE=121       M3432 13585620
         LH    GR2,DCBLRECL                                        I000 13586420
         CH    GR2,DCBBLKSI             RCD LENGTH GT BLOCKSIZE    I000 13586820
         BNH   LSTX1                    NO                        M3432 13587520
         MVC   DCBBLKSI,DCBLRECL        SET BLKSIZE=LRECL (121)   M3432 13588220
LSTX1    TM    DCBRECFM,T               TRACK OVERFLOW SPEC?      M3432 13588920
         BO    LSTX3                    YES                       M3432 13589621
LSTX4    CLC   DCBBLKSI,PRDEVT+6        IS BLKSIZE GT TRKSIZE      I000 13589821
         BNH   LSTX3                    NO,CONTINUE               M3432 13590021
         MVC   DCBBLKSI,PRDEVT+6        YES,CHANGE BLKSIZE        M3432 13590221
LSTX3    CH    GR2,DCBBLKSI             BLKSIZE GT LRECL         A33012 13590321
         BL    LSTX6                    YES,CHECK BLKSIZE        A33012 13590421
         TM    DCBRECFM,B               BLKSIZE SPEC ANYWAY      A33012 13590521
         BO    LSTX6                    YES,THEN CHECK BLKSIZE    M3432 13590820
LSTX5    MVC   DCBBLKSI,DCBLRECL        SET BLKSIZE=LRECL (121)   M3432 13590920
         B     LSTX8                    CHECK BUFNO               M3432 13591020
LSTX6    LH    GRB,DCBBLKSI             FORCE SPEC BLOCKSIZE       I000 13591620
         LR    GRD,GRB                  TO EVEN MULTIPLE OF 121    I000 13592020
         SR    GRA,GRA                                             I000 13592420
         DR    GRA,GR2                                             I000 13592820
         SR    GRD,GRA                  PLACE CORRECTED            I000 13593220
         STH   GRD,DCBBLKSI             BLKSIZE IN DCB             I000 13593620
         OI    DCBRECFM,B               SET RECFM=B              A33012 13593721
LSTX8    CLI   DCBBUFNO,NOBUF           IS BUFNO SPEC              I000 13594020
         BNE   LSTX9                    YES, OK                    I000 13594420
         MVI   DCBBUFNO,DEFTBUF         SET DEFAULT BUFNO=2        I000 13594820
LSTX9    MVC   DCBEXLST+1(L3),=AL3(0)   CLEAR EXIT LST ADDRESS     I000 13595220
         DROP  GR1                                                 I000 13595620
         L     GR14,PSAVE               RETURN TO OPEN             I000 13596020
         BR    GR14                     RETURN TO OPEN MACRO       I000 13596420
PSAVE    DS    F                                                   I000 13596820
PRDEVT   DC    0F'0',X'30002001',F'3625' DEVTYPE OUTPUT-2311       I000 13597220
LSTXLST  DC    0F'0',X'85',AL3(LSTXRTN)  EXIT LIST FOR SYSPRINT    I000 13597620
         EJECT                                                     I000 13598020
 EJECT                                                                  13600000
* READ OVERFLOW FILE INTERFACE WITH OS/360                              13620000
*        INCLUDES POINT,READ,CHECK AND NOTE LOGIC                       13640000
*        ENTER WITH I/O TABLE ADDRESS IN GR1                            13660000
RDOF     LH    GR2,10(GR1)              BLOCK COUNT                     13680000
         LTR   GR2,GR2                  ZERO                            13700000
         BCR   8,SP2                    YES EXIT                        13720000
         STM   GRZ,GR1,IOSAVE                                           13740000
         LA    GRZ,IOSAVE+20                                            13760000
         MVC   OFDECB+12(4),4(GR1)      BUFFER ADDRESS TO DECB          13780000
         MVC   OFDECB+6(2),8(GR1)       BUFFER LENGTH TO DECB           13800000
         MVI   OFDECB+5,X'80'           READ TYPE CODE TO DECB          13820000
         CLI   13(GR1),0                FILE REQUIRE POSITIONING        13840000
         BE    RDF1                     NO TO RDF1                      13860000
         MVI   13(GR1),0                CLEAR POSITIONING SWITCH        13880000
         LR    GR0,GR1                                                  13900000
         L     GR2,OFDECB+8             DCB ADDRESS                     13920000
         LR    GR1,GR2                  DCB PTR TO GR1                  13940000
         L     GR15,84(GR2)             POINT SUBROUTINE ADDRESS        13960000
         BAL   GR14,4(GR15)             EXIT TO POINT                   13980000
         L     GR1,IOSAVE+16            IO TABLE PTR                    14000000
         CLI   14(GR1),1                FIRST TIME SW SET               14020000
         BE    RDF2                     YES TO RDF2                     14040000
         LA    GR1,OFDECB               DECB PTR                        14060000
         L     GR15,48(GR2)             READ SUBROUTINE ADDRESS         14080000
         BALR  GR14,GR15                SKIP BLOCK ON FILE              14100000
         LA    GR1,OFDECB                                               14120000
         L     GR15,52(GR2)             CHECK SUBROUTINE ADDRESS        14140000
         BALR  GR14,GR15                CHECK SKIP ACTION               14160000
RDF1     L     GR2,OFDECB+8             DCB ADDRESS                     14180000
         LA    GR1,OFDECB               DECB ADDRESS                    14200000
         L     GR15,48(GR2)             READ SUBROUTINE ADDRESS         14220000
         BALR  GR14,GR15                EXIT TO READ UT1                14240000
         LA    GR1,OFDECB                                               14260000
         L     GR15,52(GR2)             CHECK SUBROUTINE ADDRESS        14280000
         BALR  GR14,GR15                EXIT TO CHECK READ UT1          14300000
         L     GR1,OFDECB+12            BUFFER ADDRESS                  14320000
         L     GR14,IOSAVE+16           IO TABLE ADDRESS                14340000
         CLC   12(1,GR14),0(GR1)        CORRECT TYPE                    14360000
         BNE   RDF1+4                   NO,READ NEXT BLOCK              14380000
         LH    GR1,10(GR14)             BLOCK COUNT                     14400000
         BCTR  GR1,0                    DECREMENT COUNT                 14420000
         STH   GR1,10(GR14)             RESTORE BLOCK COUNT             14440000
         LR    GR1,GR2                  DCB PTR                         14460000
         L     GR15,84(GR2)             NOTE SUBROUTINE ADDRESS         14480000
         BALR  GR14,GR15                EXIT TO NOTE LAST READ ACTION   14500000
         L     GR2,IOSAVE+16            IO TAB ADDRESS                  14520000
         ST    GR1,0(GR2)               STORE BLOCK POSITION            14540000
         LM    GRZ,GR1,IOSAVE                                           14560000
         LTR   GR2,GR1                  SET NORMAL READ FLAG            14580000
         BR    SP2                      EXIT RDOF                       14600000
RDF2     MVI   14(GR1),0                CLEAR FIRST TIME SW             14620000
         B     RDF1                     RETURN TO READ BLOCK            14640000
 EJECT                                                                  14660000
*                                                                       14680000
*                                                                       14700000
OFDECB   DC    F'0'                     OVERFLOW FILE I/O DECB          14720000
         DC    X'0000'                  OP AND TYPE FIELD               14740000
         DC    H'0'                     LENGTH FIELD                    14760000
         DC    A(0)                     UT1 DCB ADDRESS                 14780000
         DC    F'0'                     BUFFER ADDRESS                  14800000
         DC    F'0'                     STATUS INDICATOR POINTERS       14820000
IOSAVE   DS    23F                      IO REGISTER SAVE AREA           14840000
 SPACE                                                                  14860000
CALNDR   DC    X'1F'                    NUMBER OF DAYS IN JANUARY       14880000
FEB      DC    X'1C'                    NUMBER OF DAYS IN FEB           14900000
         DC    X'1F'                    NUMBER OF DAYS IN MARCH         14920000
         DC    X'1E'                    NUMBER OF DAYS IN APRIL         14940000
         DC    X'1F'                    NUMBER OF DAYS IN MAY           14960000
         DC    X'1E'                    NUMBER OF DAYS IN JUNE          14980000
         DC    X'1F'                    NUMBER OF DAYS IN JULY          15000000
         DC    X'1F'                    NUMBER OF DAYS IN AUG           15020000
         DC    X'1E'                    NUMBER OF DAYS IN SEPT          15040000
         DC    X'1F'                    NUMBER OF DAYS IN OCT           15060000
         DC    X'1E'                    NUMBER OF DAYS IN NOV           15080000
         DC    X'1F'                    NUMBER OF DAYS IN DEC           15100000
WORK     DC    F'0'                                                     15120000
TIMESV   DC    F'0'                     TIME OF DAY SAVE                15140000
DATE     DC    C'00/00/00'              DATE BASE                       15160000
TIME     DC    C'00.00 '                TIME OF DAY BASE                15180000
*                        CONVERT BINARY TO EBCDIC                       15200000
CNVRTX   CVD   GRZ,DWORD                CONVERT BINARY WORD             15220000
         UNPK  DWORD(4),DWORD+5(3)      IN REGISTER GRZ TO              15240000
         OI    DWORD+3,X'F0'            UNPACKED FORM IN WORD SEQ       15260000
         MVC   SEQ,DWORD                                                15280000
*RETURN NO. WITH LEADING ZEROES IN SEQ, ZERO SUPPRESSED IN DWORD        15300000
         LA    GRY,DWORD                                                15320000
SUPRESS  TM    0(GRY),X'0F'             IS THIS A ZERO                  15340000
         BCR   4,SRR                    NO, RETURN                      15360000
         MVI   0(GRY),X'40'             YES, REPLACE WITH BLANK         15380000
         LA    GRY,1(GRY)                                               15400000
         B     SUPRESS                  LOOP                            15420000
IOERR    DS    0H                       SYNAD ROUTINE             18848 15422000
         BALR  FRB,0                                              18848 15424000
         USING *,FRB                                              18848 15426000
         LR    GRA,GR1                  SAVE PARM1 FOR SYNADAF    18848 15428000
         LR    GRB,GR0                  SAVE PARM2 FOR SYNADAF    18848 15430000
         LA    GRC,8                    DENOTE EXIT FROM IEUFI    18848 15432000
         XCTL  EP=IEUERR                TRANSFER TO ABORT         18848 15434000
         DROP  FRB                                                18848 15436000
SEQ      DS    F                        NUMBER WITH LEADING ZEROS       15440000
DWORD    DS    D                        NUMBER WITH ZERO SUPPRESSED     15460000
 EJECT                                                                  15480000
*                        INDEX IN ESD TABLE                             15500000
TTYPE    EQU   0                        TYPE                            15520000
TADDR    EQU   1                        ADDRESS                         15540000
TALIGN   EQU   3                        ALIGNMENT                       15560000
TID      EQU   4                        ESD/ID                          15580000
TLTH     EQU   5                        LENGTH                          15600000
TNAME    EQU   8                        NAME                            15620000
 SPACE                                                                  15640000
TYPTBL   DC    C'SDLDER  PCCMXD      WX'  ESD TYPE IN EBCDIC       I004 15660020
HXTBL    DC    C'0123456789ABCDEF'      TABLE TO CONVERT TO HEX         15680000
HEXTBL   EQU   HXTBL-240                                                15700000
DECTBL   DC    X'0'                     TABLE FOR LEADING ZERO          15720000
         DC    9X'1'                                                    15740000
         SPACE 2                                                        15760000
ITEMCT   DC    H'16'                    COUNT PER ESD BLOCK             15780000
LINECT   DC    H'53'                    LINES PER PAGE                  15800000
ACNTFLD  DC    A(CNTFLD+1)              ADDRESS OF PAGE NUMBER          15820000
         DS    0D                       CARD COUNT                      15840000
CRDCNT   DC    PL8'0'                   PAGE COUNT                      15860000
PGCNT    DC    PL8'0'                                                   15880000
 SPACE                                                                  15900000
         LTORG                                                          15920000
 SPACE                                                                  15940000
ESDNO    DC    H'0'                     NUMBER OF ESD                   15960000
 SPACE                                                                  15980000
ESDTAB   DC    F'0'                     BLOCK POSITION PTR              16000000
         DC    F'0'                     BUFFER PTR                      16020000
         DC    H'260'                   BUFFER LENGTH                   16040000
         DC    X'FFFF'                  BLOCK COUNT                     16060000
         DC    X'03'                    ESD TYPE INDICATOR              16080000
         DC    X'1'                     REQUIRE-POSITIONING SW          16100000
         DC    X'1'                     FIRST-TIME SW                   16120000
 EJECT                                                                  16140000
         DC    X'0'                          LINE IMAGE                 16160000
         DS    0H                                                       16180000
LNAME    DC    10C' '                   NAME                            16200000
LTYPE    DC    4C' '                    TYPE                            16220000
LID      DC    3C' '                    ESD/ID                          16240000
LADDR    DC    7C' '                    ADDRESS                         16260000
LALIGN   EQU   LADDR+5                  ALIGNMENT                       16280000
LLTH     DC    8C' '                    LENGTH                          16300000
LLDID    DC    87C' '                   LD ID                           16320000
         DC    C' '                                                     16340000
 SPACE                                                                  16360000
HD1      DC    X'70'                    FIRST LINE OF HEADING           16380000
         DC    CL46' '                                                  16400000
         DC    CL65'EXTERNAL SYMBOL DICTIONARY'                         16420000
         DC    C'PAGE '                                                 16440000
CNTFLD   DC    CL4' '                   PAGE NUMBER                     16460000
 SPACE                                                                  16480000
HD2      DC    X'00'                    SECOND LINE OF HEADING          16500000
         DC    C'SYMBOL   TYPE ID  ADDR  LENGTH LD ID'                  16520000
         DC    CL84' '                                                  16540000
 SPACE                                                                  16560000
         DC    X'0'                     CARD CONTROL CHARACTER          16580000
CARD     DC    X'02C5E2C4404040404040'  CARD IMAGE   (ESD)              16600000
         DC    70C' '                                                   16620000
CBYTE    EQU   CARD+10                  NUMBER OF BYTES ON CARD         16640000
COL15    EQU   CARD+14                  COLUMN 15                       16660000
CRDNME   EQU   CARD+72                  CARD NAME                       16680000
CNAME    EQU   0                        NAME RELATIVE TO VARFLD         16700000
CTYPP    EQU   8                        TYPE                            16720000
CALIGN   EQU   12                       ALIGNMENT                       16740000
CLTH     EQU   13                       LENGTH                          16760000
         ORG   CARD+76                                                  16780000
CDCTFD   DC    ZL4'0'                   CARD NUMBER                     16800000
         ORG                                                            16820000
CRD17    DC    A(CARD+16)               BEGINNING OF VARFLD             16840000
CRDTOP   DC    A(CARD+64)               END OF VARFLD                   16860000
 SPACE                                                                  16880000
TEMPF    DS    0F                       CONTIGUOUS                      16900000
         DC    X'0'                     WORKSPACE                       16920000
TEMPAR   DC    XL3'0'                    AND                            16940000
SAVEF    DC    F'0'                      SAVE AREA                      16960000
 SPACE                                                                  16980000
ATLEN    DC    F'1088'                  LENGTH OF BUFFER FOR LAT        17000000
LBPTR    DC    A(EOF)                   POINTER IN LBT                  17020000
LBLWA    DC    F'0'                     LBT BUFFER LWA                  17040000
LABPTR   DC    F'0'                     LAT LOGICAL RECORD PTR          17060000
EOF      DC    4X'7F'                   EOF FOR LAT                     17080000
 SPACE 2                                                                17100000
BENCH    DC    2F'0'                    WORK BENCH FOR SYMBOL           17120000
TRTABLE  DC    (IALPHA+1)X'0',(255-IALPHA)X'1'                          17140000
 EJECT                                                                  17160000
         DS    0F                       ALIGN ON WORD BOUNDARY          17180000
ESDSTG   DS    XL(24*260)         COLLECTED ESD TABLE BUFFER            17200000
ESDFBA   EQU   *-1                      END OF ESD TABLE BUFFER         17220000
 EJECT                                                                  17240000
AID      EQU   0                        ID IN ADJUSTMENT                17260000
ADDR     EQU   1                        ADDRESS IN ADJUSTMENT TABLE     17280000
ENTCMBS  EQU   X'18'                    MASK FOR COMPLETION OF XD OR LD 17300000
SDBIT    EQU   3                        MASK FOR CSECT,DSECT,OR EXTERN  17320000
ENTCMBI  EQU   X'10'                    MASK FOR COMPLETE CD            17340000
LBTID    EQU   0                        LITERAL BASE TABLE ID           17360000
LITAD    EQU   1                        LBT  ADDRESS                    17380000
D8       EQU   4                        LENGTH OF 8 BYTE STRINGS        17400000
D4       EQU   7                                  4                     17420000
D2       EQU   10                                 2                     17440000
SID      EQU   0                        SEGMENT ID                      17460000
ADJCD    EQU   1                        ADJECTIVE CODE IN SYMBOL TABLE  17480000
ESDDD    EQU   2                        ESD ID                          17500000
VALUE    EQU   3                        VALUE OF SYMBOL                 17520000
LATIOT   EQU   6                        TYPE OF I/O RECORD - LAT T YPE  17540000
 SPACE                                                                  17560000
**                            REGISTER USAGE                         ** 17580000
R1       EQU   1                                                        17600000
U1       EQU   FRB            BASE REGISTERS                            17620000
ESDPTR   EQU   GRA            POINT TO ESD TABLE                        17640000
VARFLD   EQU   GRB            POINTS TO FIELD ON CARD                   17660000
SEGNO    EQU   GRB                      NO OF SEGMENTS TO FETCH         17680000
LBTPTR   EQU   GRB            POINTS TO LITERAL BASE TABLE              17700000
NOESD    EQU   GRC            COUNTS THROUGH ESD                        17720000
SRPTR    EQU   GRC                                                      17740000
ADJPTR   EQU   GRD            POINTS TO ESD ADJUSTMENT TABLE            17760000
LADJP    EQU   GRD            POINTS TO LITERAL ADJUSTMENT TABLE        17780000
ACC      EQU   GRX           ACCUMLATOR                                 17800000
DSPTR    EQU   GRY                                                      17820000
INTSUB   EQU   GRY            REGISTER FOR SUBROUTINE SUB               17840000
ADJCT    EQU   GRY            USED TO SEARCH ADJ TABLE FOR A LIT POOL   17860000
RW1      EQU   SRB            STGET                                     17880000
REVEN    EQU   GRX                      EVEN                            17900000
RODD     EQU   GRY                       ODD PAIR                       17920000
RSTB     EQU   REVEN                                                    17940000
RPT      EQU   RODD                                                     17960000
*   MAINTENANCEAREA FOR THIS PHASE                               200002 17966020
MAINT    DS    730C                                              200002 17972020
 SPACE                                                                  17980000
*F INTERLUDE MUST BE AT LEAST AS LONG AS F8 TO AVOID FRAGMENTATION      18000000
*OF MAIN STORAGE AT SOME LEVELS OF O/S DUE TO INITIAL LOADING OF        18020000
*QSAM ROUTINES AT FI TIME.                                              18040000
 SPACE                                                                  18060000
         ORG   IEUFI+SIZEPH8+16         MAKE FI 16 BYTES LONGER    I000X18068020
                                        THAN PHASE F8              I000 18076020
         PRINT NOGEN                                              18848 18086000
         DCBD  DSORG=PS                                           18848 18092000
         END   IEUFI                                                    18100000
