FPP      TITLE 'F ASSEMBLER POST PROCESSOR'                             00020000
         ISEQ  73,80                                                    00040000
IEUFPP   START                                                          00060000
*          RELEASE 19 DELETIONS                                         00105000
* 037200,041200-041400                                           A27012 00106019
*                                                                A27015 00107019
*                                                                A27084 00108019
* 078800,103200                                                  A25982 00109019
* 060400-060800                                                  A28222 00110019
*          RELEASE 20 DELETIONS                                         00111019
* 029800-030400,030800,160775-160800,227200,236200-236500,260400   I000 00111320
* 193200-194400                                                  A28233 00111620
*          RELEASE 21 DELETIONS                                         00112019
* 233650-233800                                                   21016 00112421
* 031400-031800,03000-033400,036000-036400,201200,239200-239800, A39654 00112621
* 260980                                                         A39654 00112821
* 001000-001047,001140-001160,063400,110600                      A61436 00113021
*STATUS CHANGE LEVEL 011                                                00116821
*                                                                       00117620
* INCREMENTAL IMPROVEMENTS FOR RELEASE 20                               00118420
* I000 TSO IMPLEMENTATION                                               00119220
         PRINT DATA,NOGEN               SEE RTSEGA FOR TABLE PRINT      00120000
         FDIMEN SP1=1,SP2=6,GRA=6,GRB=7,GRC=8,GRD=9,SRR=3               00140000
         PRINT GEN                                                      00160000
         SPACE 2                                                        00180000
*                                                                     * 00200000
*TITLE 'IEUFPP  ' ... POST PROCESSOR                                  * 00220000
*FUNCTION/OPERATION-                                                  * 00260000
*   IEUFPP SORTS, PRINTS, AND PUNCHES THE RELOCATION DICTIONARY (RLD) * 00280000
*   AND SORTS AND PRINTS THE SYMBOL CROSS-REFERENCE (XRF).            * 00300000
*ENTRY POINT- IEUFPP   CALLED VIA                                     * 00320000
*        XCTL  EP=IEUFPP                CALL POST PROCESSOR           * 00340000
*INPUT- RECORDS TYPE 7 (XRF) AND 8 (RLD)                              * 00360000
*   FORMAT OF THE XRF RECORD TYPE 7 IS-                               * 00380000
*                                                                     * 00400000
*   *******************************************************           * 00420000
*   *        *       *           *        *       *       *           * 00440000
*   * SYMBOL * FLAGA * STATEMENT * LENGTH * VALUE * FLAGBB*           * 00460000
*   *        *       *  NUMBER   * ATTRIB *       *       *           * 00480000
*   *******************************************************           * 00500000
*    BYTES 8     1        2          2        3       1               * 00520000
*   FLAGA- X'F0'  BASE SYMBOL                                         * 00540000
*          X'F1'  REFERENCE TO SYMBOL                                 * 00560000
*          X'F2'  MULTIPLY DEFINED SYMBOL                             * 00580000
*   FLAGB- 0      ABSOLUTE                                            * 00600000
*         1-15    EXTERNAL SYMBOL DICTIONARY ID                       * 00620000
*                                                                     * 00640000
*   FORMAT OF THE RLD RECORD TYPE 8 IS-                               * 00660000
*                                                                     * 00680000
*   **************************************************                * 00700000
*   *       *          *            *      *         *                * 00720000
*   * TABLE * POSITION * RELOCATION * FLAG * SYMBOL  *                * 00740000
*   *  ID   *   ID     *    ID      *      * ADDRESS *                * 00760000
*   **************************************************                * 00780000
*   BYTES 1      1          1           1       3                     * 00800000
*        FLAG- BITS                                                   * 00820000
*               0-1  00                                               * 00840000
*               2-3  00  A,Y, AND Q TYPE ADDRESS CONSTANTS            * 00860000
*                    01  V TYPE ADDRESS CONSTANTS                     * 00880000
*                    11  CXD                                          * 00900000
*               4-5      LENGTH OF ADDRESS CONSTANT MINUS ONE         * 00920000
*                6       ESD SIGN 0=PLUS(+), 1=MINUS(-)               * 00940000
*                7    0  NEXT ENTRY HAS SAME POSITION AND RELOCATION  * 00960000
*                        ID                                           * 00980000
*                     1  NEXT ENTRY HAS DIFFERENT POSITION AND/OR     * 01000000
*                        RELOCATION ID                                * 01020000
         EJECT                                                          01040000
*OUTPUT- THE RELOCATION DICTIONARY AND CROSS REFERENCE IS PRINTED ON  * 01060000
*        SYSPRINT. RLD AND END CARDS ARE PUT ON SYSPUNCH AND/OR SYSGO.* 01080000
*   FORMAT OF RLD CARD-                                               * 01100000
*       COLUMN      CONTENTS                                          * 01120000
*          1        12-2-9 PUNCH                                      * 01140000
*         2-4       'RLD'                                             * 01160000
*         5-10      BLANK                                             * 01180000
*        11-12      NUMBER OF BYTES IN DATA FIELD                     * 01200000
*        13-16      BLANK                                             * 01220000
*        17-72      DATA FIELD                                        * 01240000
*           17-18      POSITION ESD/ID                                * 01260000
*           19-20      RELOCATION ESD/ID                              * 01280000
*            21        FLAG (SAME AS RLD INPUT)                       * 01300000
*           22-24      ABSOLUTE ADDRESS                               * 01320000
*           25-72      REMAINING RLD ENTRIES                          * 01340000
*        73-76      DECK ID                                           * 01360000
*        77-80      CARD SEQUENCE NUMBER                              * 01380000
*   FORMAT OF END CARD-                                               * 01400000
*       COLUMN      CONTENTS                                          * 01420000
*          1        12-2-9 PUNCH                                      * 01440000
*         2-5       'END'                                             * 01460000
*          5        BLANK                                             * 01480000
*         6-8       ENTRY ADDRESS FROM OPERAND OF END CARD            * 01500000
*   REG 0 CONTAINS ACTUAL PAGE LINE COUNT                        A27012 01510019
*EXTERNAL ROUTINES-                                                   * 01520000
*   NAME            DECK      USE                                     * 01540000
*   CTDUMP(ACT)     IEURTA    FOR PATCHES TO FPP AND FD               * 01560000
*   IEUFD           IEUFD     FOR DIAGNOSTIC OUTPUT                   * 01580000
*EXITS- CALLS IEUFD VIA-                                              * 01600000
*        L     GRY,=V(IEUFD)                                          * 01620000
*        BR    GRY                                                    * 01640000
         EJECT                                                          01660000
*TABLES/WORKAREAS-                                                    * 01680000
*   JUMP       BRANCH TABLE OF WHERE TO GO AT END OF ESORT            * 01700000
*   ACTSAV     SAVE AREA FOR ASSEMBLER CONTROL TABLE                  * 01720000
*   XRFPTR     PART OF I/O CONTROL TABLE                              * 01740000
*   XRFTAB          FOR XRF I/O                                       * 01760000
*   RLDPTR     PART OF I/O CONTROL TABLE                              * 01780000
*   TLDTAB          FOR RLD I/O                                       * 01800000
*   OPT        OPTION CODES FOR ASSEMBLER                             * 01820000
*              BIT 0 = DECK, BIT 1 = LOAD, BIT 3 = LIST,              * 01840000
*              BIT 6 = CROSS REFERENCE                                * 01860000
*   IOSAVE     OS SAVE AREA                                           * 01880000
*   SAVE       GENERAL REGISTER SAVE AREA                             * 01900000
*   XRFH1      CROSS REFERENCE HEADING 1                              * 01920000
*   XRFH2      CROSS REFERENCE HEADING 2                              * 01940000
*   RLDH1      RELOCATION DICTIONARY HEADING 2                        * 01960000
*   RLDH2      RELOCATION DICTIONARY HEADING 1                        * 01980000
*   RLDOUT     CARD IMAGE FOR RLD PUNCH                               * 02000000
*   RESBUF     INTERNAL I/O BUFFERS                                   * 02020000
*   ICT        INPUT CONTROL TABLE                                    * 02040000
*   MCT        MERGE CONTROL TABLE                                    * 02060000
*   OCT        OUTPUT CONTROL TABLE                                   * 02080000
*      THE FORMAT OF THE I/O CONTROL TABLES (ICT,MCT,AND OCT) IS-     * 02100000
*       WORD  TABLE+     CONTENTS                                     * 02120000
*         0      0       ADDRESS BUFFER 1                             * 02140000
*         1      4       ADDRESS BUFFER 2                             * 02160000
*         2      8       ADDRESS BUFFER 3 OR CURRENT BUFFER IN USE    * 02180000
*         3     12       BLOCKING FACTOR                              * 02200000
*         4     16       LOGICAL RECORD LENGTH                        * 02220000
*         5     20       BLOCK SIZE                                   * 02240000
*         6     24       RECORD TYPE                                  * 02260000
*         7     28       BLOCK COUNT                                  * 02280000
*         8     32       BLOCKING FACTOR                              * 02300000
*         9     36       ADDRESS OF HOLD AREA                         * 02320000
*NOTES-                                                               * 02340000
*   STORAGE IS OBTAINED BY A GETMAIN AND THEN ENOUGH STORAGE IS FREED * 02360000
*   SO THAT THE CLOSE TYPE=T HAS A WORK AREA. THIS CLOSE WORK AREA IS * 02380000
*   ALSO USED FOR BUFFERS WHEN NOT CLOSING.                           * 02400000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 02420000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 02440000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 02460000
*NOTES -                                                         200002 02466020
*   MAINTENANCEAREA FOR THIS MODULE IS IN LOC MAINT.             200002 02472020
*                                                                     * 02480000
         SPACE 2                                                   I000 02482020
         ENTRY IOERR                                               I000 02484020
         ENTRY ERRBUF                                              I000 02486020
         ENTRY TERLI                                               I000 02488020
         ENTRY ERRCDL                                              I000 02490020
         ENTRY DIAGSAVE                                            I000 02492020
         EJECT                                                          02500000
XRFLN    EQU   17                       XRF LOGICAL RECORD LENGTH       02520000
RLDLN    EQU   6                        RLD LOGICAL RECORD LN           02540000
BLKFC1   EQU   102                      XRF BLOCKING FACTOR             02560000
BLKFC2   EQU   20                       RLD BLOCKING FACTOR             02580000
GR3      EQU   3                        DESTINATION POINTER             02600000
GR4      EQU   4                        TEMPERARY REGISTER              02620000
GRE      EQU   10                       LOGICAL RECORD LENGTH           02640000
GRF      EQU   11                       BLOCK SIZE                      02660000
GRG      EQU   12                       RECORD TYPE                     02680000
GRH      EQU   13                       BLOCK COUNT                     02700000
GRK      EQU   14                       BLOCKING FACTOR                 02720000
GRL      EQU   15                       HOLD AREA                       02740000
GR13     EQU   13                       GENERAL REGISTERS- 13           02760000
GR14     EQU   14                       GENERAL REGISTERS- 14           02780000
GR15     EQU   15                       GENERAL REGISTERS- 15           02800000
MBASE    EQU   6                        MAIN LINE BASE                  02820000
PBASE    EQU   5                        PHASE INITIALIZATION BASE       02840000
RTN      EQU   14                       RETURN ADDRESS FROM PPIN        02860000
BNE      EQU   7                        BRANCH NOT EQUAL           IEUO 02866018
OSDOS    EQU   X'04'                    OS DOS OPTION              IEUO 02872018
*                                                                       02873020
L1D      EQU   1                        NUMBER OF BYTES TO MOVE    I000 02874020
L3G      EQU   3                        NUMBER OF BYTES TO MOVE    I000 02875020
MKZ      EQU   1                        BUFCB MASK                 I000 02876020
L1E      EQU   1                        CHECK SWITCH               I000 02877020
*        ************************************************************** 02880000
         BALR  MBASE,0                  SET UP MAIN BASE                02900000
         USING *,MBASE                  TELL ASSEMBLER                  02920000
         LA    PBASE,PPIN               SET UP ALTERNATE BASE           02940000
         USING PPIN,PBASE               TELL ASSEMBLER                  02960000
         EXTRN IEUFD                                                    03060000
PATCHN   DS    0C                       RETURN HERE FROM PATCH          03100000
         BAL   RTN,PPIN                 INITIALIZE PHASE                03120000
         STM   POINTD,POINTA,BASED     START OF SORT AREA               03140021
*                 ENDLMT               NUMBER OF LOGICAL RECORDS        03160021
*                     POINTA           ADDRESS OF SORT POINTER          03180021
         MVI   ITRSWH,X'08'             SET JUMP TABLE SWITCH           03200000
*        ************************************************************** 03220000
*        START RLD INPUT PASS                                           03240000
*        ************************************************************** 03260000
RLDLOD   LA    SIX,6                    LOAD RECORD LENGRH OF RLD       03280000
         LM    POINTD,POINTA,BASED      LOAD UP START OF RLD IN CORE    03300021
*                 ENDLMT               NUMBER OF LOGICAL RECORDS        03320021
*                    POINTA            ADDRESS OF SORT BLOCK POINTER    03340021
         LA    BYTCNT,5                 LOAD COMPARE LENGTH FOR RLD     03360000
         SR    X1,X1                                                    03380000
         SR    X2,X2                    ZERO INDEX IN SORT BLOCK POINTR 03400000
         MVI   NOSWIT,X'00'             SET SWITCH FOR NO RLD'S         03420000
         LA    X4,READ                  WHERE TO LOOP TO                03440000
         B     READ                     READ IN RLD'S                   03460000
*        ************************************************************** 03480000
*        ************************************************************** 03500000
*        START XRF INPUT PASS                                           03520000
*        ************************************************************** 03540000
XRFLOD   LA    SIX,XRFLN                LOAD XRF LENGTH IN COUNTER      03560000
         LA    BYTCNT,11                LOAD COMPARE LENGRH OF XRF      03580000
         LM    POINTD,POINTA,BASED     START OF XREF IN CORE            03600021
*                 ENDLMT               NUMBER OF LOGICAL RECORDS        03620021
*                    POINTA            ADDRESS OF SORT BLOCK POINTER    03640021
         LA    X4,REAXRF                WHERE TO LOOP TO                03660000
         SR    X1,X1                                                    03680000
         SR    X2,X2                    ZERO INDEX FOR SORT BLOCK POINT 03700000
         TM    NOSWIT,X'00'             ANY RLD'S                A27012 03708019
         BNE   XRFL1                    YES                      A27012 03716019
         MVI   NORLD,X'FF'              SET NO RLD'S             A27012 03724019
XRFL1    MVI   NOSWIT,X'00'             SET NO XRF'S             A27012 03732019
         B     REAXRF                   READ XRF                        03740000
*        READ RLD FROM INPUT TAPE AND STORE                             03760000
*        ************************************************************** 03780000
READ     BAL   SRR,GTOR                 BRANCH TO IO ROUTINE            03800000
         BC    7,READR                  BRANCH IF NO EOF                03820000
         CLI   NOSWIT,X'FF'             WHERE THERE ANY RLD'S           03840000
         BNE   EXTRLD                   NO, SET UP FOR XRF              03860000
         B     EOFRH                    YES, SORT                       03880000
READR    MVI   NOSWIT,X'FF'             SET SWITCH FOR SOME RLD'S       03900000
         MVC   0(2,POINTD),HOLD         MOVE IN RLD- ESD/ID             03920000
         MVC   2(3,POINTD),HOLD+3                    SYMBOL ADDRESS     03940000
         MVC   5(1,POINTD),HOLD+2                    FLAG               03960000
         B     UPPOIN                   CONTINUE BY UP-DATING POINTERS  03980000
*        ************************************************************** 04000000
*        READ XRF FROM INPUT TAPE AND STORE                             04020000
*        ************************************************************** 04040000
REAXRF   BAL   SRR,GTOX                 BRANCH TO IO ROUTINE            04060000
         BC    7,READX                  BRANCH IF NO EOF                04080000
         CLI   NOSWIT,X'FF'             WHERE THERE ANY XRF'S           04100000
         BE    EOFRH                    YES, SORT                A27012 04107019
         TM    NORLD,X'FF'              ARE THERE ANY RLD        A27012 04114019
         BE    READT                    NO                       A27012 04121019
         LH    LICNT,CNTSAV             YES,GET PREVIOUS LICNT   A27012 04128019
         B     ENDJOB                   END OF FPP CALL FD       A27012 04135019
READT    SR    LICNT,LICNT              PASS ZERO TO IEUFD TO    A27012 04142019
         B     ENDJOB                   FORCE EJECT,TERM. FPP    A27012 04149019
READX    MVI   NOSWIT,X'FF'             SET SOME XRF'S                  04160000
         MVC   0(17,POINTD),HOLD        MOVE XRF TO CORE                04180000
*        ************************************************************** 04200000
*        UP ALL POINTERS FOR NEXT PASS                                  04220000
*        ************************************************************** 04240000
UPPOIN   ST    POINTD,0(X2,POINTA)      STORE ADDRESS POINTER           04260000
         LA    X2,4(X2)                 UP COUNTER BY FULL WORD         04280000
         AR    POINTD,SIX               UP DATA POINTER BY RECORD LENGT 04300000
         CR    X2,ENDLMT                CORE FULL                       04320000
         BCR   13,X4                   (BNH) NO,GET NEXT RECORD   21433 04327018
         L     SRR,ICT+8                POINT TO NEXT RECORD      21433 04334018
         CLC   0(4,SRR),EOF             MORE RECORDS,             21433 04341018
*                                      SEE GET ROUTINE                  04348018
         BNE   ESORT                   YES,SORT FULL CORE         21433 04355018
* EOF AND CORE FULL  AT SAME TIME                                       04362018
         BR    X4                      GO BACK TO TAKE EOF EXIT   21433 04369018
*        ************************************************************** 04380000
*        END OF FILE ON INPUT FILE                                      04400000
*        ************************************************************** 04420000
EOFRH    LR    ENDLMT,X2                LOAD UPPER LIMIT OF STRING      04440000
         MVI   LSTLD,X'FF'              SET LAST PASS SWITCH ON         04460000
         SH    ENDLMT,=H'4'             BACK IT UP ONE                  04480000
         B     ESORT                    GO TO SORT                      04500000
*        ************************************************************** 04520000
*        INTERNAL SORT                                                  04540000
*        ************************************************************** 04560000
*        SHELL'S METHOD                                                 04580000
ESORT    LR    CNTRH,ENDLMT             INITIALIZE DELTA AND            04600000
         L     POINTD,BASED               DATA ITEM BASE                04620000
         LA    CNTRH,4(CNTRH)                                           04640000
         CLI   ITRSWH,X'10'             IS THE SORT FOR XREF'S     IEUO 04644018
         BNL   ESORT1                   YES, GO SORT XREF'S        IEUO 04648018
         TM    OPT,OSDOS                IS DOS OUTPUT OPTION ON    IEUO 04652018
         BO    SETOT1                   YES, DON'T SORT RLD'S      IEUO 04656018
ESORT1   SRL   CNTRH,1                  DELTA/2 INITIALIZES NEXT PASS   04660000
         N     CNTRH,=XL4'FFFFFFFC'    FULL WORD ALIGN                  04680000
         BZ    CHKSWH                   END OF SORT WHEN DELTA =0       04700000
         SR    MASK,MASK                INITIAL SUBSEQUENCE BASE INDEX  04720000
ESORT4   LR    POINTH,MASK                                              04740000
ESORT2   LR    POINTL,POINTH            STEP TO NEXT SUBSEQUENCE PAIR   04760000
ESORT3   LA    POINTH,0(CNTRH,POINTL)   UPPER INDEX = LOWER+DELTA       04780000
         CR    POINTH,ENDLMT            BRANCH IF END OF SUBSEQUENCE    04800000
         BH    ESORT6                                                   04820000
         L     BASEL,0(POINTL,POINTA)   POINT TO LOWER DATA ITEM        04840000
         L     BASEH,0(POINTH,POINTA)   POINT TO UPPER DATA ITEM        04860000
         EX    BYTCNT,COMP1             COMPARE                         04880000
         BNH   ESORT2                   IN SEQUENCE                     04900000
ESORT5   ST    BASEL,0(POINTH,POINTA)   LET UPPER ITEM SINK             04920000
         ST    BASEH,0(POINTL,POINTA)                                   04940000
         SR    POINTL,CNTRH                                             04960000
         BNL   ESORT3                     POSSIBLY ALL THE WAY          04980000
         B     ESORT2                       TO THE BOTTOM.....          05000000
ESORT6   AH    MASK,=H'4'               STEP TO NEXT SUBSEQUENCE        05020000
         CR    MASK,CNTRH               TEST FOR END OF PASS            05040000
         BL    ESORT4                   NO -SORT NEXT SUBSEQUENCE       05060000
         B     ESORT1                   YES -INITIALIZE NEW PASS        05080000
COMP1    CLC   0(,BASEL),0(BASEH)       COMP DATA STRINGS               05100000
*        ************************************************************** 05120000
*        SORT EXIT JUMP TABLE                                           05140000
*        ************************************************************** 05160000
CHKSWH   SR    X4,X4                    JUMP TABLE FOR SORT EXIT        05180000
         IC    X4,ITRSWH                GET INDEX TO BRANCH TABLE       05200000
         L     X5,JUMP(X4)              LOAD BRANCH LOC IN X5           05220000
         BR    X5                       GO TO FINISH UP                 05240000
         CNOP  0,4                                                      05260000
JUMP     DC    AL4(SETOT1)              OUTPUT RLD'S                    05280000
         DC    AL4(SETOT2)              OUTPUT XRF'S                    05300000
         DC    AL4(WR1RLD)              WRITE FIRST RLD STRING ON UT1   05320000
         DC    AL4(RD1RLD)              READ UT1, RLD, WRITE UT2        05340000
         DC    AL4(WR1XRF)              WRITE FIRST XRF STRING ON UT1   05360000
         DC    AL4(RD1XRF)              READ UT1, XRF, WRITE UT2        05380000
*        ************************************************************** 05400000
*        RLD OUTPUT ALL DATA FROM CORE                                  05420000
*        ************************************************************** 05440000
SETOT1   SR    POINTL,POINTL            SET ADDRESS POINTER TO ZERO     05460000
         BAL   SRR,RLDHED               PRINT RLD HEADING ON FIRST PAGE 05480000
         LA    RETURN,LODHLD            WHERE TO LOOP TO                05500000
         LA    X4,48                    LOAD UPPER LIMIT OF CARD        05520000
*  INITIALIZE OUTPUT CARD POINTER AND BYTE COUNT                   IEUO 05540018
         LM    X2,X3,X2SAVE                                        IEUO 05560018
         MVI   ENDSWX,X'00'             TURN END SWITCH OFF             05580000
LODHLD   L     BASEL,0(POINTL,POINTA)   LOAD POINTER TO NEXT DATA ELEM  05600000
         LA    POINTL,4(POINTL)         UP POINTER BY FULL WORD         05620000
         CR    POINTL,ENDLMT            LOOK FOR END OF STRING          05640000
         BNH   MOVE1                    BRANCH IF NOT END               05660000
NOMO     MVI   ENDSWX,X'FF'             END OF STRING TURN END SWH ON   05680000
MOVE1    MVC   PESDID,1(X1)                                             05700000
         MVC   RESDID,0(X1)             MOVE FROM WORK AREA TO OUTPUT   05720000
         MVC   ENDRLD,2(X1)                                             05740000
         UNPK  FWORD(15),HLDRLD(8)      UNPACK RLD ENTRY                05760000
         LA    X5,FWORD                 LOAD ADDRESS OF FIRST BYTE      05780000
CONV     OI    0(X5),X'F0'              MASK HIGH END                   05800000
         CLI   0(X5),X'F9'              IS VALUE EQ OR LESS THAN 9      05820000
         BNH   UP1                      YES                             05840000
         SR    MASK,MASK                NO                              05860000
         IC    MASK,0(X5)               LOAD CHR IN REG                 05880000
         SH    MASK,THRNIN              SUBTRACT 39 FROM CHR            05900000
         STC   MASK,0(X5)               STORE EDITED CHR IN WORK AREA   05920000
UP1      LA    X5,1(X5)                 UP REG X5 BY ONE                05940000
         LA    MASK,DWORD               LOAD UPPER LINIT OF WORK AREA   05960000
         CR    X5,MASK                  CHECK FOR END                   05980000
         BE    CONVEX                   END EXIT                        06000000
         B     CONV                     RETURN FOR NEXT CHR             06020000
*                                       MOVE RLD TO OUTPUT LINE  A28222 06040019
CONVEX   MVC  RLDDET+4(2),FWORD+2       POS. ID                  A28222 06060019
         MVC   RLDDET+13(2),FWORD            REL. ID                    06100000
         MVC   RLDDET+21(2),FWORD+10         FLAG                       06120000
         MVC   RLDDET+28(6),FWORD+4          ADDRESS                    06140000
         MVC   RLDHLD+1(1),PESDID       MOVE FOR CARD- POSITION ID      06160000
         MVC   RLDHLD+3(1),RESDID                      RELOCATION ID    06180000
         MVC   RLDHLD+5(3),ENDRLD                      ADDRESS          06200000
         MVC   RLDHLD+4(1),ENDRLD+3                    FLAG             06220000
         STM   GR1,GR3,REGHLD           STORE WORK REGISTERS            06240000
         LA    GR1,RLDDET               LOAD ADDRESS OF OUTPUT          06260000
         BAL   SRR,WRLST                WRITE OUTPUT                    06280000
         MVI   RLDDET,X'00'             RESET SPACING                   06300000
         BCT   LICNT,NORLDH             CHECK FOR END OF PAGE           06320000
         BAL   SRR,RLDHED1              GO TO RLD HEAD. ROUTINE  A61436 06340021
NORLDH   LM    GR1,GR3,REGHLD           RESTORE WORK REGISTERS          06360000
         CLC   COMPID,RLDHLD            IS THIS THE SAME ID             06380000
         BNE   NEWRLD                   NO START NEW                    06400000
DUPRLD   LA    X5,4                     SET MOVE LENGTH- 4 BYTES        06420000
         LA    EIGHT,RLDHLD+4           SET REGISTER FOR MOVE           06440000
         SR    X2,X5                                                    06460000
         OI    0(X2),X'01'              TURN DUP RLD FLAG ON            06480000
         AR    X2,X5                    RESET OUTPUT POINTER            06500000
         LA    X5,3                     SET MOVE LENGTH                 06520000
         B     CRDTST                                                   06540000
NEWRLD   LA    EIGHT,RLDHLD             SET REGISTER FOR MOVE           06560000
         LA    X5,7                     SET MOVE LENGTH- 7 BYTES        06580000
         MVC   TSTPES,1(X1)                                             06600000
         MVC   TSTRES,0(X1)                                             06620000
CRDTST   LA    X4,56                    SET BYTE COUNT LIMIT            06640000
         LA    X3,1(X3,X5)              STEP BYTE COUNT                 06660000
         CR    X3,X4                    IF END OF OUTPUT RECORD         06680000
         BH    WRITE0                   WRITE OUT                       06700000
         EX    X5,MVRLD                 EXECUTE MOVE INSTRUCTION        06720000
         BE    WRITE1                   BRANCH IF CARD FULL             06740000
         LA    X2,1(X2,X5)              STEP OUTPUT POINTER             06760000
         CLI   ENDSWX,X'FF'             IS END SWITCH ON                06780000
         BE    TSTDOS                   YES, GO TEST DOS OPTION    IEUO 06800018
         BR    RETURN                   RETURN AND GET NEXT RECORD      06820000
WRITE0   OI    PKFLG,X'FF'              TURN ON RLD SPLIT FLAG          06840000
         BCTR  X3,0                                                     06860000
         SR    X3,X5                    GET BYTE COUNT                  06880000
WRITE1   STH   X3,REGDMP                STORE BYTE COUNT                06900000
         MVC   BYTOUT(2),REGDMP         MOVE BYTE COUNT TO OUTPUT       06920000
         BAL   X5,PGCNT                 BRANCH TO UP DECK COUNTER BY 1  06940000
DKNO     DC    4X'F0'                  DECK SEQ NO                      06960000
         MVC   VARRLD+60(4),DKNO        PUT IN DECK SEQUENCE NUMBER     06980000
         OC    VARRLD+60(4),CDZERO      ZERO THE BLANKS                 07000000
         MVC   VARRLD+56(4),DKID        MOVE DECK ID TO OUTPUT          07020000
         BAL   SRR,WRPUN                PUNCH THE CARD                  07040000
         XC    COMPID,COMPID            ZERO SO ID'S GO OUT NEXT TIME   07060000
         MVI   RLDOUT+4,X'40'           BLANK OUT CARD                  07080000
         MVC   RLDOUT+5(67),RLDOUT+4    RESET OUTPUT LINE               07100000
         LA    X2,VARRLD                RESET REG FOR NEXT RECORD       07120000
         SR    X3,X3                    START INDEX AT ZERO             07140000
         CLI   PKFLG,X'FF'              IS SPLIT FLAG ON                07160000
         BNE   TSTND                    NO, CONTINUE RLD OUTPUT         07180000
         MVI   PKFLG,X'00'              ZERO SPLIT FLAG                 07200000
         B     NEWRLD                   PUT IN REST OF RLD              07220000
MVRLD    MVC   0(0,X2),0(EIGHT)         EXECUTED MOVE INSTRUCTION       07240000
TSTND    CLI   ENDSWX,X'FF'             IS END SWITCH ON           IEUO 07244018
         BCR   BNE,RETURN               NO, GET NEXT RLD           IEUO 07248018
         XC    X3SAVE,X3SAVE            ZERO BYTE COUNT            IEUO 07252018
         CLI   LSTLD,X'FF'              ALL RLD'S PROCESSED        IEUO 07256018
         BE    EXTRLD                   YES, GO PROCESS XREF'S     IEUO 07260018
         TM    OPT,OSDOS                NO, IS DOS OPTION ON       IEUO 07264018
         BZ    EXTRLD                   NO, GO PROCESS XREF'S      IEUO 07268018
         B     TSTDOS1                  YES, GET MORE RLD'S        IEUO 07272018
TSTDOS   TM    OPT,OSDOS                IS DOS OPTION ON           IEUO 07276018
         BZ    WRITE1                   NO, GO PUNCH LAST RLD      IEUO 07280018
         CLI   LSTLD,X'FF'              YES, ALL RLD'S PROCESSED   IEUO 07284018
         BE    WRITE1                   YES, GO PUNCH LAST CARD    IEUO 07288018
*                                       NO, GO GET SOME MORE RLD'S IEUO 07292018
TSTDOS1  STM   X2,X3,X2SAVE             SAVE OUTPUT PTR & BYTE CNT IEUO 07296018
         B     RLDLOD                   GET MORE RLD'S             IEUO 07300018
X2SAVE   DC    A(VARRLD)                                           IEUO 07304018
X3SAVE   DC    F'0'                                                IEUO 07308018
*        ************************************************************** 07320000
*        XRF OUTPUT ALL DATA FROM CORE                                  07340000
*        ************************************************************** 07360000
SETOT2   SR    POINTL,POINTL                                            07380000
         LA    RETURN,LODXRF                                            07400000
         LA    ELNE,XRFSN1              LOAD ADDRESS OF FIRST ST-NO     07420000
         LA    ELNE,89(ELNE)            LOAD ADDRESS OF LAST ST-NO      07440000
         LA    X2,XRFSN1                SET BASE ADDRESS OF OUTPUT REC  07460000
         LA    X1,XRFHLD                LOAD ADDRESS OF WORK AREA       07480000
         SR    X3,X3                                                    07500000
         MVI   ENDSWX,X'00'             TURN END SWITCH OFF             07520000
         BAL   X4,XRFHED                                                07540000
LODXRF   L     BASEL,0(POINTL,POINTA)   LOAD POINTER TO NEXT DATA ELEM  07560000
         MVC   XRFHLD(17),0(BASEL)      MOVE DATA TO WORK AREA          07580000
         LA    POINTL,4(POINTL)         UP POINTER BY FULL WORD         07600000
         CR    POINTL,ENDLMT            LOOK FOR END OF STRING          07620000
         BH    ENDXRF                   END OF STRING                   07640000
         B     PUTXR                    NOT END OF STRING               07660000
ENDXRF   MVI   ENDSWX,X'FF'             TURN ON END SWITCH              07680000
PUTXR    LH    X3,XRFHLD+9              LOAD PACKED STATEMENT NUMBER    07700000
         N     X3,=XL4'FFFF'      REMOVE PROPAGATED 'SIGN' BITS.        07720000
         CVD   X3,DWORD2                CONVERT STMT NO. TO DECIMAL     07740000
         UNPK  FWORD2(15),DWORD2(8)     UNPACK STMT NO.                 07760000
         OI    FWORD2+14,X'F0'          OR OUT SIGN                     07780000
         CLI   XRFHLD+8,X'F1'           IS THIS AN INITIAL DEFN         07800000
         BNE   NEWXRF                   YES, GO SET UP PRINT LINE       07820000
         CLC   XRFHLD(8),COMP           ARE SYMBOLS THE SAME            07840000
         BNE   UNDSYM                   NO, GO PROCESS UNDEFINED SYMBOL 07860000
PUTXR0   MVI   RFCTSW,X'00'             ZERO NO REF TO PRINT SW. A25982 07870019
PUTXR1   MVC   0(5,X2),FWORD2+10        MOVE STMT NO. AS REFRENCE IEUN3 07890018
         CLI   0(X2),C'0'               CHECK REF FOR LDING ZERO  IEUN3 07900018
         BNE   PUTXR2                   NO, LEAVE IT ALONE        IEUN3 07910018
         MVI   0(X2),C' '               ELSE BLANK IT OUT         IEUN3 07920018
PUTXR2   LA    X2,6(,X2)                BUMP REF POINTER BY SIX   IEUN3 07930018
         BAL   X5,PGCNT                 ADD ONE TO NO OF STATEMENTS     07940000
COUNT1   DC    4X'F0'                   COUNTER FOR STATEMENT NOS       07960000
         CR    X2,ELNE                  CHECK FOR LAST ST-NO ON LINE    07980000
         BH    ENDLIN                   YES GO AND PRINT LINE           08000000
         CLI   ENDSWX,X'FF'              IS END SWITCH ON               08020000
         BE    NEWXR1                    YES, GO LIST LAST ENTRY        08040000
         BR    RETURN                   RETURN AND GET NEXT RECORD      08060000
ENDLIN   MVC   XRFDEF(5),HAST           MOVE DEFINITION TO PRINT  IEUN3 08080018
         LA    GR1,XRFOUT               LOAD ADDRESS OF OUTPUT AREA     08100000
         BAL   SRR,WRLST                                                08120000
         CLI   ENDSWX,X'FF'              IS END SWITCH ON               08140000
         BE    ENDJOB                    YES, TERMINATE                 08160000
         MVI   XRFOUT,X'00'             RESET SPACING                   08180000
         BCT   LICNT,NOFLO1             CHECK OUTPUT LINE COUNT         08200000
         BAL   X4,XRFHED                GO TO PRINT PAGE HEADING        08220000
NOFLO1   MVI   XRFOUT+1,X'40'           RESET PRINT LINE TO BLANK       08240000
         MVC   XRFOUT+2(119),XRFOUT+1                                   08260000
         MVC   HAST(5),XRFSYM           BLANK DEFN FOR MULT-LINES IEUN3 08280018
         LA    X2,XRFSN1                                                08300000
         MVC   COUNT1(4),HZERO          RESET ST-NO COUNTER             08320000
         MVI   RFCTSW,X'FF'             TURN ON NO REF SWITCH           08340000
         BR    RETURN                   RETURN AND GET NEXT RECORD      08360000
NEWXRF   NI    ENDSWX,X'F0'              SET END SWITCH FOR LAST SYMBOL 08380000
         CLI   FRSTSW,X'FF'              IS FIRST PASS SWITCH ON        08400000
         BE    NOFLO                    YES JUMP                        08420000
         CLI   RFCTSW,X'FF'             IS NO REF SWITCH ON             08440000
         BE    NOFLO                     YES, DON'T PRINT               08460000
NEWXR1   MVC   XRFDEF(5),HAST           MOVE DEFN TO PRINT IMAGE  IEUN3 08480018
CNTER    LA    GR1,XRFOUT               LOAD ADDRESS OF OUTPUT AREA     08500000
         BAL   SRR,WRLST                                                08520000
         MVI   XRFOUT,X'00'             RESET SPACING                   08540000
         CLI   ENDSWX,X'FF'             IS END SWITCH ON                08560000
         BE    ENDJOB                                                   08580000
         BCT   LICNT,NOFLO              CHECK OUTPUT LINE COUNT         08600000
         BAL   X4,XRFHED                GO TO PRINT PAGE HEADING        08620000
NOFLO    MVI   XRFOUT+1,X'40'           RESET PRINT LINE TO BLANK       08640000
         MVC   COMP(8),XRFHLD           MOVE SYMBOL FOR LATER COMPARE   08660000
         MVC   HAST(5),FWORD2+10        SAVE STMT NUMBER AS DEFN. IEUN3 08680018
         MVC   XRFOUT+2(119),XRFOUT+1                                   08700000
         MVI   RFCTSW,X'00'             TURN OFF NO REF SWITCH     IEUA 08720000
         MVI   FRSTSW,X'00'             TURN OFF FIRST TIME SWITCH      08740000
         MVC   XRFSYM(8),XRFHLD         LOAD NEXT PRINT LINE            08760000
         LH    X3,XRFHLD+11             LOAD PACKED SYMBOL LENGTH       08780000
         LA    X3,1(X3)           ADD 1 FOR TRUE LENGTH.                08800000
         N     X3,=XL4'FFFF'      REMOVE PROPAGATED 'SIGN' BITS.        08820000
         CVD   X3,DWORD                                                 08840000
         UNPK  FWORD(15),DWORD(8)                                       08860000
         OI    FWORD+14,X'F0'           MASK OUT ZONE                   08880000
         MVC   XRFLEN(5),FWORD+10                                 IEUN3 08900018
         SPACE 5                                                        08920000
*ADJUST RELOCATABLE ADDRESS FROM ADJUSTMENT TABLE                       08940000
         SPACE                                                          08960000
         CLI   XRFHLD+16,0        NO ADJUSTMENT IF ESDID = 0            08980000
         BE    NOADJUST                 NO ADJUSTMENT, BRANCH           09000000
         L     X3,ADJBS           ADJUSTMENT TABLE ADDRESS              09020000
ADJLP    C     X3,ADJBSEND                                              09040000
         BL    *+10                     ADJUSTMENT IS ZERO IF           09060000
         SR    X3,X3                    TABLE ENTRY IS NOT FOUND        09080000
         B     ADJLP1                                                   09100000
         CLC   XRFHLD+16(1),0(X3)       IS THIS THE RIGHT ENTRY         09120000
         BE    ADJLP0                   YES, ADJUST                     09140000
         LA    X3,4(X3)                 NO, LOOK AT NEXT ENTRY          09160000
         B     ADJLP                    AND LOOP                        09180000
ADJLP0   L     X3,0(X3)                 GET ADJUSTMENT                  09200000
ADJLP1   MVC   FWORD+1(3),XRFHLD+13     GET VALUE IN FULL WORD          09220000
         AL    X3,FWORD           ADD ADJUSTMENT TO VALUE               09240000
         ST    X3,FWORD                 KEEP SUM                        09260000
         MVC   XRFHLD+13(3),FWORD+1    REPLACE RESULT                   09280000
NOADJUST DS    0H                                                       09300000
         SPACE 3                                                        09320000
         UNPK  DWORD(7),XRFHLD+13(4)    UNPACK ADDRESS                  09340000
         LA    X3,DWORD                                                 09360000
CONVA    OI    0(X3),X'F0'              MASK HIGH BITS                  09380000
         CLI   0(X3),X'F9'              TEST FOR EQ OR LESS THAN 9      09400000
         BNH   UP1A                     YES                             09420000
         SR    X4,X4                    NO                              09440000
         IC    X4,0(X3)                 LOAD CHR IN WORK REG            09460000
         SH    X4,THRNIN                SUBTRACT 39 FROM CHR            09480000
         STC   X4,0(X3)                 STORE EDITED CHR IN WORK AREA   09500000
UP1A     LA    X3,1(X3)                 UP ADDRESS IN X3 BY ONE         09520000
         LA    X4,DWORD+7               GET END LIMIT                   09540000
         CR    X4,X3                    CHECK FOR END                   09560000
         BE    CONVAX                   YES END                         09580000
         B     CONVA                    NO RETURN FOR NEXT CHR          09600000
CONVAX   MVC   XRFVAL(6),DWORD          MOVE HEX ADDRESS TO OUTPUT      09620000
         LA    X2,XRFSN1                                                09640000
         CLI   XRFHLD+8,X'F2'           FLAG DUPLICATE SYMBOL IN XREF   09660000
         BNE   *+10                                                     09680000
         MVC   XRFSN1(17),=C'****DUPLICATE****'                         09700000
         MVC   COUNT1(4),HZERO          RESET ST-NO COUNTER             09720000
         CLI   ENDSWX,X'F0'              IS END SWITCH ON               09740000
         BCR   7,RETURN                 YES, EXIT                       09760000
         OI    ENDSWX,X'FF'              TURN ON END SWITCH             09780000
         B     NEWXR1                    GO LIST LAST XREF              09800000
         BR    RETURN                   NO, GO AND GET NEXT RECORD      09820000
EXTRLD   MVI   ENDSWX,X'00'                                             09840000
         MVI   LSTLD,X'00'              RESET SWITCHES FOR RLD SORT     09860000
         MVI   ITRSWH,X'10'             SET JUMP TABLE SWOTCH           09880000
         TM    OPT,OSDOS                IS DOS OPTION ON           IEUO 09882018
         BZ    EXTRLD1                  NO, FORGET LAST CARD       IEUO 09884018
         L     X3,X3SAVE                GET BYTE COUNT             IEUO 09886018
         LTR   X3,X3                    IS BYTE COUNT ZERO         IEUO 09888018
         BZ    EXTRLD1                  YES, NO LAST CARD          IEUO 09890018
         BAL   RETURN,WRITE1            GO PUNCH LAST RLD CARD     IEUO 09892018
EXTRLD1  EQU   *                                                   IEUO 09894018
         BAL   SRR,REWIND               REWIND XRF AND RLD TAPE         09900000
         B     XRFLOD                   START XRF PASS                  09920000
UNDSYM   CLI   FRSTSW,X'FF'             IS THIS THE FIRST SYMBOL        09940000
         BE    UND01                    YES, SKIP LISTING LAST SYMBOL   09960000
         CLI   RFCTSW,X'FF'             IS NO REF SWITCH ON             09980000
         BE    UND01                     YES, DON'T PRINT               10000000
         LA    GR1,XRFOUT               LOAD PRINT ADDRESS              10020000
         MVC   XRFDEF(5),HAST           MOVE DEFN TO LIST         IEUN3 10040018
         BAL   SRR,WRLST                GO PRINT LINE                   10060000
         MVI   XRFOUT,X'00'             ZERO CARRIAGE CONTROL           10080000
UND01    MVI   FRSTSW,X'00'             ZERO FIRST PASS SWITCH          10100000
         BCT   LICNT,UND02              REDUCE LINE COUNT               10120000
         BAL   X4,XRFHED                PRINT NEW HEADER IF COUNT ZERO  10140000
UND02    LA    X2,XRFSN1                RESET POINTER                   10160000
         MVI   XRFOUT+1,X'40'           BLANK PRINT IMAGE               10180000
         MVC   XRFOUT+2(119),XRFOUT+1                                   10200000
         MVC   HAST(5),=C'*****'        FLAG UNDEF SYMBOL IN XREF IEUN3 10220018
         MVC   XRFLEN(13),=C'****UNDEFINED'                       IEUN3 10240018
         MVC   XRFSYM(8),XRFHLD         MOVE SYMBOL TO PRINT IMAGE      10260000
         MVC   COMP(8),XRFHLD           SAVE SYMBOL FOR LATER COMPARE   10280000
         MVC   COUNT1(4),HZERO          RESET REFERENCE COUNT           10300000
         B     PUTXR0                   PUT OUT CROSS REFERENCE  A25982 10320019
*        ************************************************************** 10340000
*        OUTPUT RLD DECK, INPUT FROM TAPE                               10360000
*        ************************************************************** 10380000
LSTRL1   LA    X2,VARRLD                LOAD BASE ADDRESS OF OUTPUT REC 10400000
         BAL   SRR,RLDHED               PRINT FIRST PAGE HEADING        10420000
         LA    EIGHT,8                  LENGTH OF MOVE                  10440000
         SR    X3,X3                                                    10460000
         LA    RETURN,REDRL2            SET RETURN REG                  10480000
REDRL2   STM   X2,X3,REGHLD             STORE WORK REG                  10500000
         LA    X1,HOLD                  LOAD ADDRESS OF WORK AREA       10520000
         BAL   SRR,REDRLD               GET RECORD INTO WORKAREA        10540000
         LA    X1,HOLD                  ADDRESS OF WORKAREA             10560000
         LM    X2,X3,REGHLD             RESTORE WORK REG                10580000
         BC    8,ENDRL2                 BRANCH IF EOF                   10600000
         B     MOVE1                    PUT OUT RLD                     10620000
ENDRL2   MVI   ENDSWX,X'FF'             TURN ON END RLD SWITCH          10640000
         B     WRITE1                   AND WRITE OUT                   10660000
*        ************************************************************** 10680000
*        OUTPUT XRF LISTING, INPUT FROM TAPE                            10700000
*        ************************************************************** 10720000
LSTXR1   LA    X2,XRFSN1                                                10740000
         LA    RETURN,REDXR2            SET RETURN REG                  10760000
         LA    ELNE,XRFSN1              LOAD ADDRESS OF FIRST ST-NO     10780000
         LA    ELNE,89(ELNE)            LOAD ADDRESS OF LAST ST-NO      10800000
         BAL   X4,XRFHED                PRINT FIRST HEADING LINE        10820000
REDXR2   ST    X2,REGHLD                STORE WORK REG                  10840000
         LA    X1,XRFHLD                XRF HOLD AREA ADDRESS           10860000
         BAL   SRR,REDXRF               MOVE RECORD INTO HOLD AREA      10880000
         BC    8,ENDXR2                 BRANCH IF EOF                   10900000
         LA    X1,XRFHLD                XRF HOLD AREA ADDRESS           10920000
         L     X2,REGHLD                RESTORE WORK REG                10940000
         B     PUTXR                    PUT OUT XRF                     10960000
ENDXR2   MVI   ENDSWX,X'FF'             TURN ON END XRF SWITCH          10980000
         B     NEWXR1                                                   11000000
*        ************************************************************** 11020000
*        RLD PAGE HEADING ROUTINE                                       11040000
*        ************************************************************** 11060000
RLDHED1  CLI   ENDSWX,X'FF'             TEST IF LAST RLD STRING  A61436 11070021
         BCR   8,SRR                    YES, RETURN TO USER      A61436 11072021
RLDHED   BAL   X5,PGCNT                 UP PAGE COUNTER                 11080000
CNT4     DC    4X'F0'                   PAGE COUNT                      11100000
         MVC   NY14(4),CNT4             MOVE IN PAGE COUNT              11120000
         ST    SRR,REGHLD+12            STORE RETURN ADDRESS            11140000
         LA    GR1,RLDH2                ADDRESS OF HEADING 2            11160000
         BAL   SRR,WRLST                PUT OUT HEAD 2 (HEADING 1)      11180000
         LA    GR1,RLDH1                ADDRESS OF HEADING 1            11200000
         BAL   SRR,WRLST                PUT OUT HEAD 1 (HEADING 2)      11220000
         L     SRR,REGHLD+12            6OAD RETURN ADDRESS             11240000
         MVI   RLDH2,X'FF'              SET ELECT HEAD 2                11260000
         MVI   RLDH1,X'02'                  DOUBLE SPACE HEAD 1         11280000
         MVI   RLDDET,X'01'                 AND LEAVE SPACE AFTER HEAD1 11300000
         LH    LICNT,CNTSAV             RESET LINE COUNTER              11320000
         BR    SRR                      RETURN TO USER                  11340000
*        ************************************************************** 11360000
*        PRINT XRF PAGE HEADINGS                                        11380000
*        ************************************************************** 11400000
XRFHED   BAL   X5,PGCNT                 CALL PAGE COUNT SUB ROUTINE     11420000
COUNT    DC    4X'F0'                   PAGE COUNTER                    11440000
         MVC   XRFPCT(4),COUNT          MOVE PAGE COUNT TO OUTPUT AREA  11460000
         LA    GR1,XRFH1                ADDRESS OF HEADING 1            11480000
         BAL   SRR,WRLST                PUT OUT HEAD 1                  11500000
         LA    GR1,XRFH2                ADDRESS OF HEADING 2            11520000
         BAL   SRR,WRLST                PUT OUT HEAD 2                  11540000
         MVI   XRFH2,X'02'              DOUBLE SPACE HEAD 2             11560000
         MVI   XRFH1,X'FF'              EJECT HEAD 1                    11580000
         MVI   XRFOUT,X'01'             AND SPACE AFTER HEAD 2          11600000
         LH    LICNT,CNTSAV             RESET LINE COUNTER              11620000
         BR    X4                       RETURN TO MAIN LINE             11640000
*        ************************************************************** 11660000
*        PAGE COUNTER SUB ROUTINE                                       11680000
*        ************************************************************** 11700000
PGCNT    PACK  FWORD+8,0(4,X5)          PACK PAGE COUNTER               11720000
         ST    X2,REGHLD+16             STORE WORK REG                  11740000
         CVB   X2,FWORD+8               CONV PAGE COUNTER TO BIN        11760000
         LA    X2,1(X2)                 ADD ONE TO PAGE NO              11780000
         CVD   X2,DWORD                 CONV BIN COUNTER TO DEC         11800000
         UNPK  FWORD(15),DWORD(8)                                       11820000
         OI    FWORD+14,X'F0'           MASK UNITS POS                  11840000
         LA    X2,FWORD+11              SET ADDRESS OF HIGH ORDER       11860000
SUPR     TM    0(X2),X'0F'              LOOK FOR FIRST NON ZERO         11880000
         BM    PGEX                     YES, EXIT                       11900000
         MVI   0(X2),X'40'              MASK LEADING ZERO TO BLANK      11920000
         LA    X2,1(X2)                 UP BYTE POINTER BY ONE          11940000
         B     SUPR                     RETURN TO CHECK NEXT BYTE       11960000
PGEX     MVC   0(4,X5),FWORD+11         MOVE EDITED PAGE NO TO USER     11980000
         L     X2,REGHLD+16             RESET WORK REG                  12000000
         LA    X5,4(X5)                 UP RETURN POINTER BY FULL WORD  12020000
         BR    X5                       RETURN TO USER                  12040000
FWORD    DS    2D                       PACKED AND DECIMAL VALUE        12060000
DWORD    DS    D                        BINARY VALUE                    12080000
FWORD2   DC    2D'0'                    PACKED AND DECIMAL VALUE        12100000
DWORD2   DC    D'0'                     BINARY VALUE                    12120000
*        ************************************************************** 12140000
*        WRITE FIRST RLD STRING ON UT1                                  12160000
*        ************************************************************** 12180000
WR1RLD   SR    POINTL,POINTL                                            12200000
         CLI   LSTLD,X'FF'              CHECK DID SORT FIT IN CORE      12220000
         BE    SETOT1                   YES OUTPUT RLD                  12240000
PAS1RL   BAL   X3,GETPOI                GET DATA POINTER                12260000
         MVC   HOLD(6),0(BASEL)         MOVE CORE TO WORK AREA          12280000
         LA    GR1,HOLD                 LOAD ADDRESS OF TAPE OUTPUT     12300000
         BAL   SRR,WRRLD                                                12320000
         LA    POINTL,4(POINTL)         UP POINTER BY FULL WORD         12340000
         CR    POINTL,ENDLMT            CHECK FOR END OF STRING         12360000
         BH    EP1RLD                   YES EXIT                        12380000
         B     PAS1RL                   RETURN AND GET NEXT RECORD      12400000
EP1RLD   BAL   SRR,REWIND                                               12420000
         MVI   ITRSWH,X'0C'             SET JUMP TABLE SWITCH           12440000
         B     RLDLOD                   GO TO GET NEXT STRING           12460000
*        ************************************************************** 12480000
*        MERGE RLD                                                      12500000
*        ************************************************************** 12520000
RD1RLD   SR    POINTL,POINTL                                            12540000
RD1RL    LA    GR1,TAPEIN               LOAD ADDRESS OF TAPE WORK AREA  12560000
         BAL   SRR,REDRLD                                               12580000
         BC    8,EP2ARL                 BRANCH IF EOF                   12600000
         CLI   NOCOR,X'FF'              CHECK ALL CORE OUT              12620000
         BE    WT2RL                    YES GO TO DUMP TAPE             12640000
RD1ARL   BAL   X3,GETPOI                GET DATA POINTER                12660000
         CLI   NOCOR,X'FE'              CHECK FOR ALL TAPE IN           12680000
         BE    DP1RL                    YES GO TO DUMP CORE             12700000
         CLC   TAPEIN(6),0(BASEL)       COMP TAPE TO CORE               12720000
         BL    WT2RL                    TAPE LOW                        12740000
DP1RL    MVC   HOLD(6),0(BASEL)         MOVE CORE TO WORK AREA          12760000
         LA    GR1,HOLD                 LOAD ADDRESS OF RLD OUTPUT AREA 12780000
         BAL   SRR,WRRLD                                                12800000
         LA    POINTL,4(POINTL)         UP POINTER BY FULL WORD         12820000
         CR    POINTL,ENDLMT            CHECK FOR END OF STRING         12840000
         BH    EP2RL                    YES EXIT                        12860000
         B     RD1ARL                   RETURN AND GET NEXT RECORD      12880000
WT2RL    LA    GR1,TAPEIN               LOAD ADDRESS OF TAPE WORK AREA  12900000
         BAL   SRR,WRRLD                                                12920000
         B     RD1RL                    RETURN TO READ UT1              12940000
EP2RL    CLI   ENDSWX,X'FF'             CHECK FOR END OF PASS           12960000
         BE    EPRL2                    YES EXIT                        12980000
         MVI   ENDSWX,X'FF'             TURN ON END OF PASS SWITCH      13000000
         MVI   NOCOR,X'FF'              TURN ON END OF CORE SWITCH      13020000
         B     WT2RL                    RETURN TO DUMP TAPE             13040000
EP2ARL   CLI   ENDSWX,X'FF'             CHECK FOR END OF PASS           13060000
         BE    EPRL2                    YES EXIT                        13080000
         MVI   ENDSWX,X'FF'             TURN ON END OF PASS SWITCH      13100000
         MVI   NOCOR,X'FE'              TURN ON END OF TAPE SWITCH      13120000
         L     BASEL,0(POINTL,POINTA)                             15054 13130016
         B     DP1RL                    RETURN TO DUMP CORE             13140000
EPRL2    BAL   SRR,REWIND               REWIND                          13160000
         MVI   NOCOR,X'00'              TURN END OF CORE SWITCH OFF     13180000
         MVI   ENDSWX,X'00'             TURN END OF PASS SWITCH OFF     13200000
         CLI   LSTLD,X'FF'              IS SORT COMP                    13220000
         BE    LSTRL1                   YES GO TO OUTPUT ROUTINE        13240000
         MVI   ITRSWH,X'0C'             SET JUMP TABLE SWOTCH           13260000
         B     RLDLOD                   GO TO GET NEXT STRING           13280000
*        ************************************************************** 13300000
*        WRITE FIRST XRF STRING ON UT1                                  13320000
*        ************************************************************** 13340000
WR1XRF   SR    POINTL,POINTL                                            13360000
         CLI   LSTLD,X'FF'              CHECK DID SORT FIT IN CORE      13380000
         BE    SETOT2                   YES OUTPUT XRF                  13400000
PAS1XR   BAL   X3,GETPOI                GET DATA POINTER                13420000
         MVC   XRFHLD(17),0(BASEL)      MOVE CORE TO WORK AREA          13440000
         LA    GR1,XRFHLD               LOAD ADDRESS OF TAPE OUTPUT     13460000
         BAL   SRR,WRXRF                                                13480000
         LA    POINTL,4(POINTL)         UP POINTER BY FULL WORD         13500000
         CR    POINTL,ENDLMT            CHECK FOR END OF STRING         13520000
         BH    EP1XRF                   YES EXIT                        13540000
         B     PAS1XR                   RETURN AND GET NEXT RECORD      13560000
EP1XRF   BAL   SRR,REWIND                                               13580000
         MVI   ITRSWH,X'14'             SET JUMP TABLE SWOTCH           13600000
         B     XRFLOD                   GO TO GET NEXT STRING           13620000
*        ************************************************************** 13640000
*        MERGE XRF                                                      13660000
*        ************************************************************** 13680000
RD1XRF   SR    POINTL,POINTL                                            13700000
RD1XR    LA    GR1,TAPEIN               LOAD ADDRESS OF TAPE WORK AREA  13720000
         BAL   SRR,REDXRF                                               13740000
         BC    8,EP2AXR                 TEST FOR END OF FILE            13760000
         CLI   NOCOR,X'FF'              CHECK ALL CORE OUT              13780000
         BE    WT2XR                    YES GO TO DUMP TAPE             13800000
RD1AXR   L     BASEL,0(POINTL,POINTA)   LOAD ADDRESS POINTER            13820000
         CLI   NOCOR,X'FE'              CHECK FOR ALL TAPE IN           13840000
         BE    DP1XR                    YES GO TO DUMP CORE             13860000
         CLC   TAPEIN(11),0(BASEL)      COMP TAPE TO CORE               13880000
         BL    WT2XR                    TAPE LOW                        13900000
DP1XR    MVC   XRFHLD(17),0(BASEL)      MOVE CORE TO WORK AREA          13920000
         LA    GR1,XRFHLD               LOAD ADDRESS OF XRF OUTPUT AREA 13940000
         BAL   SRR,WRXRF                                                13960000
         LA    POINTL,4(POINTL)         UP POINTER BY FULL WORD         13980000
         CR    POINTL,ENDLMT            CHECK FOR END OF STRING         14000000
         BH    EP2XR                    YES EXIT                        14020000
         B     RD1AXR                   RETURN AND GET NEXT RECORD      14040000
WT2XR    LA    GR1,TAPEIN               LOAD ADDRESS OF TAPE WORK AREA  14060000
         BAL   SRR,WRXRF                                                14080000
         B     RD1XR                    RETURN TO READ UT1              14100000
EP2XR    CLI   ENDSWX,X'FF'             CHECK FOR END OF PASS           14120000
         BE    EP2                      YES GO TO END PASS TWO          14140000
         MVI   ENDSWX,X'FF'             TURN ON END PASS SWITCH         14160000
         MVI   NOCOR,X'FF'              TURN ON END OF CORE SWITCH      14180000
         B     WT2XR                    RETURN TO DUMP TAPE             14200000
EP2AXR   CLI   ENDSWX,X'FF'             CHECK FOR END OF PASS           14220000
         BE    EP2                      YES GO TO END PASS TWO          14240000
         MVI   ENDSWX,X'FF'             TURN ON END PASS SWITCH         14260000
         MVI   NOCOR,X'FE'              TURN ON END OF TAPE SWITCH      14280000
         B     RD1AXR                   RETURN TO DUMP CORE             14300000
EP2      BAL   SRR,REWIND                                               14320000
         MVI   NOCOR,X'00'              TURN END CORE SWITCH OFF        14340000
         MVI   ENDSWX,X'00'             TRUN END PASS SWITCH OFF        14360000
         CLI   LSTLD,X'FF'              IS SORT COMP                    14380000
         BE    LSTXR1                   YES GO TO OUTPUT ROUTINE        14400000
         MVI   ITRSWH,X'14'             SET JUMP TABLE SWOTCH           14420000
         B     XRFLOD                   GO TO GET NEXT STRING           14440000
*        ************************************************************** 14460000
*        GET POINTER TO DATA IN CORE                                    14480000
*        ************************************************************** 14500000
GETPOI   L     BASEL,0(POINTL,POINTA)   LOAD ADDRESS POINTER            14520000
         BR    X3                       RETURN                          14540000
*        ************************************************************** 14560000
*        WRITE RECORDS ON SYSLST                                        14580000
*        ************************************************************** 14600000
WRLST    ST    SRR,RETHLD               STORE RETURN ADDRESS            14620000
         ST    GR4,XYZ1                 SAVE GR4                        14640000
         LR    GR4,GR1                  LOAD GR4 WITH OUTPUT ADDRESS    14660000
         BAL   SRR,SYSL                 WRITE OUT LINE                  14680000
         MVI   RLDDET,X'00'             SINGLE SPACE NEXT LINE          14700000
         L     SRR,RETHLD               LOAD RETURN ADDRESS             14720000
         L     GR4,XYZ1                 RESTORE GR4                     14740000
         BR    SRR                      RETURN TO USER                  14760000
XYZ1     DS    F                        SAVE AREA FOR GR4               14780000
         EJECT                                                          14800000
*        ************************************************************** 14820000
* PHASE INITIALIZATION                                                  14840000
*        ************************************************************** 14860000
         USING IHADCB,GR1                                         18848 14862000
PPIN     L     GR1,CTOUT1(,ACT)         PASS SYNAD EXIT ADDRESS TO18848 14864000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)  DCB OF SYSUT3,          18848 14866000
         L     GR1,CTOUT2(,ACT)           DCB OF                  18848 14870000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)    SYSUT1,               18848 14872000
         L     GR1,CTXUIN(,ACT)           DCB OF                  18848 14874000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)    SYSUT2,               18848 14876000
         L     GR1,LSTDCB(,ACT)           DCB OF                  18848 14878000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)    SYSPRINT,             18848 14880000
         L     GR1,PCHDCB(,ACT)           DCB OF                  18848 14882000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)    SYSPUNCH, AND         18848 14884000
         L     GR1,GODCB(,ACT)            DCB OF                  18848 14886000
         MVC   DCBSYNAD+1(3),=AL3(IOERR)    SYSGO.                18848 14888000
         DROP  GR1                                                18848 14890000
         L     GR1,ACTSPT                                         18848 14892000
         STM   GRX,GRY,SAVE             SAVE REGISTERS                  14900000
         ST    ACT,0(GR1)               SAVE ACT                        14920000
         LA    GR1,CTCXRF(ACT)          XRF BLOCK COUNT                 14940000
         ST    GR1,XRFPTR+4             PUT IN BLOCK COUNT              14960000
         MVC   ADJBS(4),CADJBS(ACT)    ADJUSTMENT TABLE ADDRESS         14980000
         MVC   ADJBSEND,CTLATB(ACT)     LITERAL ADDRESS TABLE BASE      15000000
         MVC   RD12+2(4),CTOUT1(ACT)   UTY DCB ADDRESS                  15020000
         LA    GR1,CTRXRF(ACT)          XRF OVERFLOW BLOCK POSITION     15040000
         ST    GR1,XRFPTR+8             PUT IN OVERFLOW BLOCK           15060000
         LA    GR1,CTCRLD(ACT)          RLD BLOCK COUNT                 15080000
         ST    GR1,RLDPTR+4             PUT IN BLOCK COUNT              15100000
         LA    GR1,CTRRLD(ACT)          RLD OVERFLOW BLOCK POSITION     15120000
         ST    GR1,RLDPTR+8             PUT IN OVERFLOW BLOCK           15140000
         MVC   DKNO(4),CCRDCT(ACT)      CARD COUNT                      15160000
         MVC   CNTSAV+1(1),CTPGLNCT(ACT) GET VARIABLE LINE COUNT        15180000
         L     GR1,DKIDPT               POSITION OF DECK ID             15200000
         MVC   0(4,GR1),CTITLE(ACT)     TITLE                           15220000
         MVC   XRFH1+1(4),CTITLE(ACT)  DECK ID TO PAGE HEADINGS         15240000
         MVC   RLDH2+1(4),CTITLE(ACT)  OF XRF AND RLD.                  15260000
         MVC   XRFH2+113(8),CTDATE(ACT)     DATE TO PAGE HEADINGS       15280000
         MVC   RLDH1+113(8),CTDATE(ACT)                                 15300000
         MVC   OPT(1),CTCGOI(ACT)       OPTION SW                       15320000
         MVC   OPT+1(L1D),CTTRMI(ACT)   OPTION BYTE 1              I000 15330020
         LA    GRZ,IOSAVE               OS SAVE AREA                    15340000
******************                                                      15360000
         GETMAIN  VU,LA=REQ,A=GOT       GET STORAGE                     15380000
         L     GR4,=A(RESBUF)           GET ADDRESS OF BUFFER           15400000
         ST    GR4,ICT                  INPUT BUFFER 1                  15420000
         LA    GR4,XRFSIZ(GR4)          ADD XRFSIZE TO GET NEXT BUFFER  15440000
         ST    GR4,ICT+4                INPUT BUFFER 2                  15460000
         LA    GR4,XRFSIZ(GR4)          AND SO ON FOR ALL INTERNAL BUFS 15480000
         ST    GR4,OCT                  OUTPUT BUFFER 1                 15500000
         ST    GR4,OCT+8                OUTPUT BUFFER 3                 15520000
         LA    GR4,XRFSIZ(GR4)                                          15540000
         ST    GR4,OCT+4                OUTPUT BUFFER 2                 15560000
         LM    GR2,GR3,GOT              RELEASE MERGE BUFFER FOR T CLOS 15580000
         LH    GR4,=AL2(((2*XRFSIZ+784+7)/8)*8)                   12045 15600014
     FREEMAIN  R,LV=(4),A=(2)           SPACE IS RECLAIMED BEFORE USE   15620000
         AR    GR2,GR4                  GET ADDRESS OF AVAILABLE STOR   15640000
         SR    GR3,GR4                  AND LENGTH OF AVAILABLE STORAGE 15660000
         STM   GR2,GR3,GOT              SAVE IT                         15680000
         LR    POINTA,GR2               FBA OF LARGE SORT BLOCK         15700000
         LR    POINTD,GR3               LENGTH OF LARGE SORT BLOCK      15720000
         SR    POINTL,POINTL            CLEAR UPPER HALF OF DIVIDEND    15740000
         LA    GR1,XRFLN+4              NO OF LOG REC AVAIL             15760000
         DR    POINTL,GR1               NO. OF XRF LOG RECORDS          15780000
         SLL   POINTD,2                 MULTIPLY BY FOUR                15800000
         LR    ENDLMT,POINTD            NO. OF LOGICAL RECORDS          15820000
         AR    POINTD,POINTA            START OF SORT AREA              15840000
         SH    ENDLMT,=H'4'                                             15860000
         L     ACT,ACTSAV               RESTORE ACT                     15880000
         MVC   WR2+2(4),CTXUIN(ACT)     UTX DCB ADDRESS                 15900000
         MVC   RD22+2(4),CTOUT2(ACT)    UTY DCB ADDRESS                 15920000
         MVI   FTSW1,1                  FIRST TIME GET ORIGINAL FILE    15940000
         MVI   FTSW2,1                  FIRST TIME GET MERGED FILE      15960000
         MVI   PUTSW,1                  FIRST TIME PUT FILE             15980000
         SR    GR1,GR1                                                  16000000
         STH   GR1,MBLKC                ZERO MERGED BLOCK COUNT         16020000
         LM    GRX,GRY,SAVE             RESTORE SAVED REGISTERS         16040000
         BR    RTN                      EXIT                            16060000
IOERR    DS    0H                       SYNAD ROUTINE             18848 16060700
         BALR  FRB,0                                              18848 16061400
         USING *,FRB                                              18848 16062100
         LR    4,GR1                    SAVE PARM1 FOR SYNADAF    18848 16062800
         LR    5,GR0                    SAVE PARM2 FOR SYNADAF    18848 16063500
         LA    6,16                     DENOTE EXIT FROM IEUFPP   18848 16064200
         CLI   CHSW1,0                  TEST FOR PENDING OP       18848 16064900
         BNE   IOERR1                   BR IF CHECKED             18848 16065600
         MVI   CHSW1,X'FF'              SET SW                    18848 16066300
         CHECK WR1                      ISSUE CHK                 18848 16067000
IOERR1   CLI   CHSW2,0                  TEST FOR PENDING OP       18848 16067700
         BNE   IOERR2                   BR IF CHECKED             18848 16068400
         MVI   CHSW2,X'FF'              SET SW                    18848 16069100
         CHECK RD21                     ISSUE CHK                 18848 16069800
IOERR2   L     GR1,MGBUFAD              TEST FOR STG RET          18848 16070500
         LTR   GR1,GR1                  X                         18848 16071200
         BE    IOERR3                   BR IF RET'D               18848 16071900
         LA    GR0,2*XRFSIZ             SIZE OF STG RET           18848 16072600
         FREEMAIN  R,LV=(0),A=(1)       RET STG                   18848 16073300
IOERR3   L     GR1,GOT                  TEST FOR STG RET          18848 16074000
         LTR   GR1,GR1                  X                         18848 16074700
         BZ    IOERR4                   BR IF RET'D               18848 16075400
         L     GR0,GOT+4                GET AREA SIZE             18848 16076100
         FREEMAIN  R,LV=(0),A=(1)       RET STG                   18848 16076800
         L     ACT,ACTSAV                                         M2043 16077118
IOERR4   TM    OPT+1,TERM              IS TERM OPTION REQ          I000 16078120
         BZ    IOERR6                   NO,EXIT                    I000 16079120
         MVC   IOERR5+5(L3G),VTERM+1    SYSTERM DCB ADDRESS        I000 16080120
IOERR5   CLOSE (0,LEAVE)                CLOSE SYSTERM              I000 16081120
         L     GR1,VTERM                                           I000 16082120
         TM    23(GR1),MKZ              SKIP FOLLOWING FREEPOOL    I000 16083120
         BO    IOERR6                   IF NO BUFCB                I000 16084120
         FREEPOOL (1)                                              I000 16085120
IOERR6   XCTL  EP=IEUERR                TRANSFER TO ABORT          I000 16086120
         DROP  FRB                                                 I000 16087120
         DS    0F                                                  I000 16088120
PPIN4    DC    X'FFFFFFFC'              FULL WORD ALIGNMENT MASK        16100000
REQ      DC    A(2*XRFSIZ+2*BLKFC1*(XRFLN+4)+600,511*1024) MIN,MAX REQ. 16120000
GOT      DC    A(0)                     FBA OF STORAGE RECEIVED         16140000
         DC    A(0)                     LENGTH OF STORAGE RECEIVED      16160000
ACTSPT   DC    A(ACTSAV)                ADDRESS OF ACT SAVE AREA        16180000
DKIDPT   DC    A(DKID)                  POSITION OF DECK ID             16200000
         EJECT                                                          16220000
*        ************************************************************** 16240000
* GET XRF OR RLD FROM ORIGINAL FILE                                     16260000
*        ************************************************************** 16280000
GTOX     STM   GR1,GRL,SAVE             SAVE ALL REGISTERS              16300000
         LM    GR1,GR4,XRFPTR           LOAD MASK,COUNT,POSITION,TABLE  16320000
         B     GTO                      GET ORIGINAL XRF-D2             16340000
GTOR     STM   GR1,GRL,SAVE             SAVE ALL REGISTERS              16360000
         LM    GR1,GR4,RLDPTR           LOAD MASK,COUNT,POSITION,TABLE  16380000
GTO      CLI   FTSW1,1                  FIRST TIME SWITCH SET           16400000
         BE    GT3                      YES TO GT3                      16420000
GT1      LM    GRA,GRL,ICT              INPUT CONTROL TABLE             16440000
         MVI   GETSW2,0                 SET SWITCH- FROM ORIGINAL FILE  16460000
         BAL   SRR,GET                  GET RECORDS INTO HOLD           16480000
         STM   GRA,GRK,ICT              SAVE NEW ICT                    16500000
         BC    7,GT2                    BRANCH NO EOF                   16520000
         MVI   FTSW1,1                  SET FIRST TIME SWITCH           16540000
GT2      LM    GR1,GRL,SAVE             RESTORE GR                      16560000
         BR    SRR                      EXIT                            16580000
GT3      EX    GR1,GT6                  EXECUTE TEST OUTPUT OPTIONS     16600000
         BZ    GT4                      EXIT IF NONE OF TESTED OPTS ON  16620000
         LH    GR1,0(GR2)               BLOCK COUNT                     16640000
         LTR   GR1,GR1                  IS IT ZERO                      16660000
         BNZ   GT5                      NO, TO GT5                      16680000
GT4      LM    GR1,GRL,SAVE             RESTORE GR                      16700000
         SR    SP1,SP1                  SET EOF FLAG                    16720000
         BR    SRR                      EXIT                            16740000
GT5      MVI   FTSW1,0                  CLEAR FIRST TIME SWITCH         16760000
         ST    GR1,ICT+28               SAVE BLOCK COUNT                16780000
         LA    GRH,IOSAVE               PTR TO IO SAVE AREA             16800000
         LR    GR0,GR3                  POINT ADDRESS                   16820000
         L     GR1,RD12+2               DCB PTR                         16840000
         L     GR15,84(GR1)             POINT SUBROUTINE ADDRESS        16860000
         ST    GR4,CSSGF                ADDRESS OF DATA TABLE           16880000
         BAL   GR14,4(GR15)             EXIT TO POINT                   16900000
         L     GR4,CSSGF                GET ADDRESS OF DATA TABLE       16920000
         LM    GRA,GRD,0(GR4)           SET UP ICT- GET DATA TABLE      16940000
         STM   GRA,GRD,ICT+12           PUT DATA TABLE IN               16960000
         ST    GRA,ICT+32               SAVE BLOCKING FACTOR            16980000
         LM    GRA,GRL,ICT              ICT IN GRA THROUGH CRL          17000000
         LR    GR1,GRA                  CURRENT POINTER TO BUFFER       17020000
         BAL   GR4,READ1                READ ORIGINAL DATA SET          17040000
         LA    GRC,1(GRA)               CURRENT LOG REC PTR             17060000
         LR    GR1,GRB                  ALT PTR                         17080000
         BAL   GR4,READ1                READ ORG DATA SET               17100000
         B     GT1+4                    CONTINUE IN GTOX OR GTOR        17120000
GT6      TM    OPT,X'00'                TEST OUTPUT OPTIONS             17140000
*        ************************************************************** 17160000
* GET XRF OR RLD FROM MERGED DATA SET                                   17180000
*        ************************************************************** 17200000
GTM      CLI   FTSW2,1                  FIRST TIME SW SET               17220000
         STM   GR1,GRL,SAVE                                             17240000
         BE    GTM3                     YES TO GTM3                     17260000
GTM1     LM    GRA,GRK,MCT              MERGED CONTROL TABLE            17280000
         LR    GRL,SP1                  DESTINATION PTR                 17300000
         MVI   GETSW2,1                 SET SWITCH- FROM MERGE          17320000
         BAL   SRR,GET                  MOVE IN THE RECORD              17340000
         STM   GRA,GRK,MCT              SAVE MERGED CONTROL TABLE       17360000
         BC    7,GTM2                   EXIT IF NOT EOF                 17380000
         MVI   FTSW2,1                  SET FTSW                        17400000
GTM2     LM    GR1,GRL,SAVE             RESTORE REGS                    17420000
         BR    SRR                      EXIT                            17440000
GTM3     LH    GRA,MBLKC                MERGED BLK COUNT                17460000
         LTR   GRA,GRA                  COUNT ZERO                      17480000
         BNZ   GTM4                     NO, TO GTM4                     17500000
         LM    GR1,GRL,SAVE             RESTORE REGS                    17520000
         SR    SP1,SP1                  SET EOF FLAG                    17540000
         BR    SRR                      EXIT                            17560000
GTM4     MVI   FTSW2,0                  CLEAR FTSW                      17580000
         ST    GRA,MCT+28               BLOCK COUNT                     17600000
         SR    GRA,GRA                                                  17620000
         STH   GRA,MBLKC                SET BLOCK COUNT OF ZERO         17640000
       GETMAIN R,LV=2*XRFSIZ            OBTAIN MERGE INPUT BUFFERS      17660000
         ST    GR1,MGBUFAD              SAVE ADDRESS OF STORAGE         17680000
         ST    GR1,MCT                  BUFFER 1                        17700000
         LA    GR1,XRFSIZ(GR1)          LENGTH OF BUFFER 1              17720000
         ST    GR1,MCT+4                BUFFER 2                        17740000
         L     GR1,SAVE                 RESTORE GR1                     17760000
         LM    GRA,GRB,ICT+16           SET REC LN AND BLOCK SIZE       17780000
         STM   GRA,GRB,MCT+16           PUT IN MERGED CONTROL TABLE     17800000
         L     GRA,ICT+32               GET BLOCKING FACTOR             17820000
         ST    GRA,MCT+12                                               17840000
         ST    GRA,MCT+32               BLOCKING FACTOR                 17860000
         LM    GRA,GRK,MCT              BRING IN MERGE CONTROL TABLE    17880000
         LR    GRL,SP1                  DEST PTR                        17900000
         LR    GR1,GRA                  CURRENT BUFF                    17920000
         BAL   GR4,READ2                READ MERGED FILE                17940000
         LA    GRC,1(GRA)               POINT BEYOND RECORD TYPE        17960000
         LR    GR1,GRB                  NEXT BUFFER                     17980000
         BAL   GR4,READ2                READ MERGED DATA SET            18000000
         B     GTM1+6                   CONTINUE IN GTM                 18020000
*        ************************************************************** 18040000
* GET SUBROUTINE INTERNAL TO I/O                                        18060000
*        ************************************************************** 18080000
GET      CLC   0(4,GRC),EOF             EOF LABEL                       18100000
         BZ    GET3                     YES TO GET3                     18120000
GET2     EX    GRE,GETM                 EXECUTE MOVE-GRE=LRECL          18140000
         AR    GRC,GRE                  UPDATE LOG REC PTR              18160000
         LA    GRC,1(GRC)               GO BEYOND RECORD TYPE           18180000
         BCT   GRD,GET6                 DEC BLK FACTOR                  18200000
         B     GET4                     BLOCK EMPTY                     18220000
GET3     SR    SP1,SP1                  EOF- SET CC=4                   18240000
         BR    SRR                      EXIT                            18260000
GET4     LR    GR1,GRA                  CURRENT BUFFER PTR              18280000
         CLI   GETSW2,1                 ORIGINAL DATA SET               18300000
         BE    GET7                     NO TO GET7                      18320000
         BAL   GR4,READ1                READ ORIGINAL DATA SET          18340000
GET5     LR    GRC,GRB                  ALTERNATE BUFFER PTR            18360000
         LR    GRB,GRA                  CURRENT PTR                     18380000
         LR    GRA,GRC                  ALT PTR                         18400000
         LA    GRC,1(GRC)               LOG REC PTR                     18420000
         LR    GRD,GRK                  BLOCKING FACTOR                 18440000
GET6     LTR   SP1,GRC                  SET SP1 AND CC                  18460000
         BR    SRR                      EXIT                            18480000
GET7     BAL   GR4,READ2                READ MERGED DATA FILE           18500000
         B     GET5                     CONTINUE                        18520000
GETM     MVC   0(0,GRL),0(GRC)          MOVE LOGICAL RECORD             18540000
*        ************************************************************** 18560000
* ROUTINE TO PUT XRF,RLD ONTO MERGE TAPE K                              18580000
*        ************************************************************** 18600000
PUT      STM   GR1,GRL,SAVE             SAVE ALL REGISTERS              18620000
         LM    GRA,GRD,OCT              BRING IN OUTPUT CONTROL TABLE   18640000
         LR    GR3,SP1                  DESTINATION POINTER             18660000
         CLI   PUTSW,1                  FIRST TIME SW SET               18680000
         BE    PUT3                     YES TO PUT3                     18700000
PUT1     L     GRE,ICT+16               LOGICAL RECORD LENGTH           18720000
         EX    GRE,PUTM                 EXECUTE MOVE                    18740000
         AR    GRC,GRE                  UPDATE LOG REC PTR              18760000
         LA    GRC,1(GRC)                                               18780000
         BCT   GRD,PUT2                 DEC BLK FACTOR                  18800000
         LR    GR1,GRA                  CURRENT PTR                     18820000
         BAL   GR4,WRITE                WRITE UTK                       18840000
         LR    GRC,GRB                  ALTERNATE POINTER               18860000
         LR    GRB,GRA                  CURRENT PTR                     18880000
         LR    GRA,GRC                  ALT PTR TO CURRENT PTR          18900000
         LA    GRC,1(GRC)                                               18920000
         L     GRD,ICT+32               BLOCKING FACTOR                 18940000
PUT2     STM   GRA,GRD,OCT              SAVE OUTPUT CONTROL TABLE       18960000
         LM    GR1,GRF,SAVE             RESTORE GR                      18980000
         BR    SRR                      EXIT                            19000000
PUT3     LR    GRC,GRA                  CURRENT PTR                     19020000
         LA    GRC,1(GRC)                                               19040000
         L     GRD,ICT+32               BLOCKING FACTOR                 19060000
         MVI   PUTSW,0                  CLEAR FIRST TIME SW             19080000
         B     PUT1                     CONTINUE IN PUT                 19100000
PUTM     MVC   0(0,GRC),0(GR3)          MOVE LOGICAL RECORD             19120000
*        ************************************************************** 19140000
* TCLOSE                                                                19160000
*        ************************************************************** 19180000
TCLS     STM   GR1,GRL,SAVE             SAVE ALL REGISTERS              19200000
         L     GR1,OCT+8                GET PLACE FOR NEXT RECORD       19220000
         MVC   0(4,GR1),EOF             EOF LABEL                       19240000
         L     GR1,OCT                                                  19260000
         BAL   GR4,WRITE                WRITE MERGE TAPE                19280000
         L     GR1,OCT                  REINITIATE REG.          A27015 19290019
         BAL   GR4,WRITE                WRITE MERGE TAPE                19300000
         MVC   TC+5(3),WR2+3            MOVE IN DCB ADDRESS             19460000
         MVC   TC+9(3),RD22+3           BOTH DCB ADDRESSES              19480000
         LA    13,IOSAVE+12                                        8125 19500000
         CLI   CHSW2,L1E                IS CHECK REQ'D?          A28233 19503020
         BE    NORDCHK                 NO                        A28233 19506020
         MVI   CHSW2,L1E                SET CHECK SWITCH         A28233 19509020
         CHECK RD21                                              A28233 19512020
NORDCHK  EQU   *                                                 A28233 19515020
         CHECK WR1                                                 8125 19520000
         L     GR1,MGBUFAD              RELEASE MERGE INPUT BUFFERS     19522020
         LTR   GR1,GR1                  ARE THERE BUFFERS TO RELEASE    19524020
         BZ    TCX                      NO, DONT RELEASE                19526020
    FREEMAIN   R,LV=2*XRFSIZ,A=(1)      FOR OS TEMP. STORAGE FOR T-CLOS 19528020
         XC    MCT(8),MCT                                               19530020
         XC    MGBUFAD(4),MGBUFAD                                       19532020
TCX      EQU   *                                                        19534020
TC       CLOSE (0,REREAD,0,REREAD),TYPE=T    CLOSE TO REWIND            19540000
         MVI   PUTSW,1                  SET FIRST TIME SW               19560000
         MVI   CHSW1,1                  CHECK SW                        19580000
         MVI   CHSW2,1                  CHECK SW                        19600000
         L     GR1,RD22+2               READ DCB PTR TO WRITE DCB PTR   19620000
         MVC   RD22+2(4),WR2+2          WRITE DCB PTR TO READ DCB PTR   19640000
         ST    GR1,WR2+2                                                19660000
         LM    GR1,GRL,SAVE             RESTORE REGISTERS               19680000
         BR    SRR                      EXIT                            19700000
*        ************************************************************** 19720000
* WRITE MERGE DATA SET                                                  19740000
*        ************************************************************** 19760000
WRITE    STM   GRH,GRL,IOSAVE           SAVE IO REGS                    19780000
         LA    GRH,IOSAVE+12            POINT TO IO SAVE AREA           19800000
         ST    GR1,RD25                 SAVE OUTPUT PTR                 19820000
         CLI   CHSW1,1                  CHECK REQ                       19840000
         BE    WR0                      NO TO WR0                       19860000
         MVI   CHSW1,1                  SET CHK SW                18848 19870000
         CHECK WR1                      YES, CHECK PREVIOUS WRITE       19880000
WR0      MVC   WR3(4),RD25              MOVE IN BUFFER ADDRESS          19900000
         MVC   WR2(2),ICT+22            RETRIEVE BLOCK LENGTH           19920000
         WRITE WR1,SF,0,0,0             WRITE OUT RECORD                19940000
WR2      EQU   WR1+6                    LENGTH AND DCB ADDR             19960000
WR3      EQU   WR1+12                   BUFFER ADDR                     19980000
         MVI   CHSW1,0                  SET TO CHECK NEXT TIME          20000000
         LM    GRH,GRL,IOSAVE           RESTORE IO REGS                 20020000
         LH    GR1,MBLKC                MERGE BLOCK COUNT               20040000
         LA    GR1,1(GR1)               UP IT BY ONE                    20060000
         STH   GR1,MBLKC                                                20080000
         BR    GR4                      EXIT WRITE                      20100000
*        ************************************************************** 20140000
* READ ORIGINAL DATA SET                                                20160000
*        ************************************************************** 20180000
READ1    STM   GRH,GRL,IOSAVE           SAVE IO REGS                    20200000
         LTR   GRH,GRH                  IS BLOCK COUNT ZERO             20220000
         BCR   8,GR4                    YES, EXIT                       20240000
         LA    GRH,IOSAVE+12            POINT TO IO SAVE AREA           20260000
         ST    GR1,RD13                 INPUT BUFFER ADDRESS            20280000
         STH   GRF,RD12                 BLOCK LENGTH                    20300000
RD11     READ  RD15,SF,0,0,0            READ THE RECORD                 20320000
RD12     EQU   RD15+6                   LENGTH AND DCB ADDR             20340000
RD13     EQU   RD15+12                  BUFFER ADDR                     20360000
         CHECK RD15                     WAIT FOR COMPLETION             20380000
         L     GR1,RD13                 BUFFER ADDRESS                  20400000
         CLC   0(1,GR1),ICT+27          CORRECT RECORD TYPE             20420000
         BNE   RD11                     NO, READ NEXT RECORD            20440000
         LM    GRH,GRL,IOSAVE           RESTORE IO REGS                 20460000
         BCTR  GRH,0                    DECREMENT BLOCK COUNT           20480000
         BR    GR4                      EXIT READ1                      20500000
* READ MERGED DATA SET                                                  20520000
READ2    STM   GRH,GRL,IOSAVE           SAVE IO REGS                    20540000
         LTR   GRH,GRH                  IS BLOCK COUNT ZERO             20560000
         BCR   8,GR4                    YES, EXIT                       20580000
         LA    GRH,IOSAVE+12            POINT TO IO SAVE AREA           20600000
         ST    GR1,RD25                 SAVE BUFFER PTR                 20620000
         CLI   CHSW2,1                  CHECK REQ                       20640000
         BE    RD20                     NO TO RD20                      20660000
         MVI   CHSW2,1                  SET CHK SW                18848 20670000
         CHECK RD21                     YES, CHECK                      20680000
RD20     L     GR1,IOSAVE               GET BLOCK COUNT                 20700000
         LTR   GR1,GR1                  IS IT ZERO                      20720000
         BNZ   RD201                    NO, CONTINUE                    20740000
         LM    GRH,GRL,IOSAVE           YES, RESTORE                    20760000
         BR    GR4                      AND EXIT                        20780000
RD201    MVC   RD23(4),RD25             MOVE IN BUFFER                  20800000
         STH   GRF,RD22                 BLOCK SIZE                      20820000
         READ  RD21,SF,0,0,0            READ RECORD                     20840000
RD22     EQU   RD21+6                   LENGTH AND DCB ADDR             20860000
RD23     EQU   RD21+12                  BUFFER ADDR                     20880000
         MVI   CHSW2,0                  SET TO CHECK NEXT TIME          20900000
         LM    GRH,GRL,IOSAVE           RESTORE IO REGS                 20920000
         BCTR  GRH,0                    DECREMENT BLOCK COUNT           20940000
         BR    GR4                      EXIT READ2                      20960000
RD25     DC    A(0)                     BUFFER POINTER                  20980000
*        ************************************************************** 21020000
* SYSTEM LIST SUBROUTINE                                                21040000
*        ************************************************************** 21060000
SYSL     TM    OPT,X'10'                IS LIST SWITCH ON               21080000
         BCR   8,SRR                    NO EXIT                         21100000
         STM   GR1,GRL,SAVE             YES, SAVE ALL REGISTERS         21120000
         L     ACT,ACTSAV               LOAD UP ACT                     21140000
         LA    GRZ,IOSAVE               OS SAVE AREA                    21160000
         LM    GRA,GRB,CTLINECT(ACT)    GRA=LINE COUNT.                 21180000
         CLI   0(GR4),0                 GRB=PREVIOUS LINE LOCATION.     21200000
         BE    SYSLNORM                 NORMAL PRINT FOR CODE 00        21220000
         CLI   0(GR4),55                55 OR GREATER FORCES EJECT.     21240000
         BL    SYSLSPCE                 LESS, JUST SPACE                21260000
SYSLEJCT MVI   0(GRB),EJECTAP           PUT IN EJECT CODE               21280000
         B     SYSLNORM                 AND PRINT NORMAL                21300000
SYSLSPCE SR    GRC,GRC                  01 TO 54 FORCES THAT NUMBER     21320000
         IC    GRC,0(GR4)               OF BLANK LINES(SPACES).         21340000
         CH    GRC,=H'2'                IS IT 2 OR LESS                 21360000
         BH    *+16                     NO SPACE 3 AND LOOP             21380000
         IC    GRC,APTBL-1(GRC)         01 OR 02 FORCES ONLY            21400000
         STC   GRC,0(GRB)               NEW CODE IN PREVIOUS LINE.      21420000
         B     SYSLNORM                 PRINT NORMAL                    21440000
         MVI   0(GRB),SPACE3AP          03-54 GENERATE A MINIMUM        21460000
         SH    GRC,=H'2'                NUMBER OF LINES WITH            21480000
SYSLSPLP L     GR1,LSTDCB(ACT)          SPACE IMMEDIATE CODES           21500000
         PUT   (1)                      PRINT SPACE                     21520000
         LR    GRB,GR1                  GET POSITION TO PUT NEXT OUTPUT 21540000
         LA    GRA,1(GRA)               INCREMENT LINE COUNT            21560000
         MVI   1(GRB),X'40'             INSERT BLANK             A27084 21566019
         MVC   2(119,GRB),1(GRB)                                 A27084 21572019
         CH    GRC,=H'3'                DO WE HAVE MORE THAN 3 LEFT     21580000
         BNH   *+16                     NO, SPACE AND PRINT             21600000
         MVI   0(GRB),SPACE3IM          YES, JUST SPACE 3               21620000
         SH    GRC,=H'3'                REDUCE BY 3                     21640000
         B     SYSLSPLP                 AND LOOP                        21660000
         IC    GRC,IMTAB-1(GRC)         GET NUMBER OF SPACES            21680000
         STC   GRC,0(GRB)               PUT IN                          21700000
SYSLNORM L     GR1,LSTDCB(ACT)          GET DCB                         21720000
         PUT   (1)                      PUT OUT PREVIOUS LINE           21740000
         LR    GRB,GR1                  AND SAVE THIS NEW LINE          21760000
         LA    GRA,1(GRA)               INCREMENT LINE COUNT.           21780000
         MVI   0(GRB),SPACE1AP          SET FOR NORMAL SPACE            21800000
         MVC   1(120,GRB),1(GR4)        TRANSFER LINE TO BUFFER.        21820000
         STM   GRA,GRB,CTLINECT(ACT)    RESTORE LCOUNT AND POINTER.     21840000
         LM    GR1,GRL,SAVE             RESTORE REGISTERS               21860000
         BR    SRR                      AND EXIT                        21880000
APTBL    DC    AL1(SPACE2AP,SPACE3AP)   SPACE AFTER PRINT TABLE         21900000
IMTAB    DC    AL1(SPACE1IM,SPACE2IM,SPACE3IM) SPACE IMMEDIATE TABLE    21920000
*                                                                       21940000
* SYSTEM OUTPUT SUBROUTINE                                              21960000
*        ************************************************************** 21980000
SYSO     TM    OPT,X'80'                IS A DECK WANTED                22000000
         STM   GR1,GRL,SAVE             SAVE ALL REGISTERS              22020000
         LA    GRZ,IOSAVE               OS SAVE AREA                    22040000
         L     ACT,ACTSAV               RESTORE ASSEMBLER CONTROL TABLE 22060000
         BZ    PCH1                     NO DECK, TRY SYSGO              22080000
         L     GR1,PCHDCB(ACT)          GET ADDRESS OF PUNCH DCB        22100000
         PUT   (1),RLDOUT               PUNCH OUT RLD CARD              22120000
PCH1     TM    OPT,X'40'                IS LOAD OPTION ON               22140000
         BZ    PCH11                    NO, EXIT                        22160000
         L     GR1,GODCB(ACT)           YES, GET SYSGO DCB              22180000
         PUT   (1),RLDOUT               PUT CARD IMAGE ON SYSGO         22200000
         SPACE 5                                                        22220000
PCH11    LM    GR1,GRL,SAVE             RESTORE ALL REGISTERS           22240000
         BR    SRR                      EXIT                            22260000
*        ************************************************************** 22280000
XRFPTR   DC    F'2'                     TEST XRF OPTION BIT             22300000
         DC    A(0)                     XRF BLOCK COUNT ADDRESS         22320000
         DC    A(0)                     XRF FIRST BLK PTR ADDRESS       22340000
         DC    A(XRFTAB)                XRF DATA TABLE ADDRESS          22360000
XRFTAB   DC    A(BLKFC1)                XRF BLOCKING FACTOR             22380000
         DC    A(XRFLN-1)               XRF LOGICAL RECORD LENGTH       22400000
         DC    A(XRFLN*BLKFC1+1)        XRF BLK SIZE                    22420000
         DC    F'7'                     XRF TYPE INDICATOR              22440000
RLDPTR   DC    A(X'D0')                 TEST PCH,GO,&LIST OPTION BITS   22460000
         DC    A(0)                     RLD BLOCK COUNT ADDRESS         22480000
         DC    A(0)                     RLD FIRST BLK PTR ADDRESS       22500000
         DC    A(RLDTAB)                RLD DATA TABLE ADDRESS          22520000
RLDTAB   DC    A(BLKFC2)                RLD BLOCKING FACTOR             22540000
         DC    A(RLDLN-1)               RLD LOGICAL RECORD LENGTH       22560000
         DC    A(RLDLN*BLKFC2+1)        RLD BLK SIZE                    22580000
         DC    F'8'                     RLD TYPE INDICATOR              22600000
FTSW1    DC    X'1'                     SOURCE FIRST TIME SWITCH        22620000
FTSW2    DC    X'1'                     MERGE  FIRST TIME SWITCH        22640000
PUTSW    DC    X'1'                     PUT FIRST TIME SWITCH           22660000
CHSW1    DC    X'1'                     CHECK SWITCH 0=CHECK,1=NO CHECK 22666021
CHSW2    DC    X'1'                    CHECK SWITCH 0=CHECK,1=NO CHECK  22672021
GETSW1   DC    X'0'                     FOR FUTURE USE                  22680000
GETSW2   DC    X'0'                     0= ORIGINAL, 1= FROM MERGED     22700000
OPT      DS    H                        OPTION BYTE 0 AND 1        I000 22710020
VTERM    DC    V(SYTERM)                ADDR OF SYSTERM DCB IN FD  I000 22720020
TERM     EQU   X'40'                    TERM OPTION                I000 22730020
MBLKC    DC    H'0'                     MERGED BLOCK COUNT              22740000
EOF      DC    4X'7F'                   EOF INDICATOR                   22760000
IOSAVE   DC    21F'0'                   OS SAVE AREA                    22780000
ICT      DC    A(0)                     INPUT CONTROL TABLE             22800000
         DC    A(0)                                                     22820000
         DC    3F'0',A(120),3F'0'                                       22840000
         DC    A(HOLD)                                                  22860000
MCT      DC    A(0)                     MERGE CONTROL TABLE             22880000
         DC    A(0)                                                     22900000
         DC    7F'0'                                                    22920000
OCT      DC    A(0)                     OUTPUT CONTROL TABLE            22940000
         DC    A(0)                                                     22960000
         DC    A(0)                                                     22980000
         DC    F'0'                                                     23000000
SAVE     DC    15F'0'                   SAVE AREA FOR REGISTERS 1-15    23020000
CSSGF    DC    F'0'                                                     23040000
MGBUFAD  DC    F'0'                     MERGE BUFFERS' ADDRESS          23060000
*        ************************************************************** 23080000
ENDJOB   BAL   SRR,TCLS                 BRANCH TO I/O ROUTINE           23100000
         MVI   RLDOUT+1,X'40'           BLANK CARD OUTPUT AREA          23120000
         MVC   RLDOUT+2(79),RLDOUT+1                                    23140000
         MVC   COUNTR(4),DKNO           GET CARD COUNT                  23160000
         OC    DKNO(4),=C'0000'         SET BLANKS TO ZERO              23180000
         CLC   DKNO(4),=C'0000'         WERE ANY CARDS PUT OUT          23200000
         BE    YPN                      NO, SKIP                        23220000
         BAL   X5,PGCNT                 GO STEP AND FORMAT NUMBER FOR   23240000
COUNTR   DC    4X'40'                   OUTPUT                          23260000
         MVC   RLDOUT+76(4),COUNTR      MOVE NUMBER TO OUTPUT ARRY      23280000
         OC    RLDOUT+76(4),CDZERO                                      23300000
         MVC   RLDOUT+1(3),ENDCR        MOVE CHARACTERS -END- TO CARD   23320000
         MVC   RLDOUT+72(4),DKID        GET DECK ID                     23340000
         L     ACT,ACTSAV               RESTORE ASSEMBLED CONTROL TABLE 23360000
         TM    CTPCHI(ACT),X'04'        DOS OPTION IN EFFECT      21016 23365021
         BO    NOIDR                    YES, SKIP IDR             21016 23367021
         MVC   RLDOUT+33(10),PID        MOVE PID TO END CARD      21016 23369021
         MVC   RLDOUT+43(4),VERMOD      MOVE VER MOD TO END CARD  21016 23369421
         L     SP1,CTRTBP(ACT)          COPUTE ADDR OF JDATE      21016 23369821
         SH    SP1,H8                   IN RTA                    21016 23369921
         MVC   RLDOUT+47(5),0(SP1)      MOVE JULIAN DATE TO END   21016 23370021
         CLI   CTIDR(ACT),C'2'          A 2ND IDR PRESENT?        21016 23372021
         BNE   ONEIDR                                             21016 23374021
         MVC   RLDOUT+52(19),CT2IDR(ACT)  MOVE 2ND TO CARD        21016 23374421
ONEIDR   MVC   RLDOUT+32(1),CTIDR(ACT)     INSERT FLAG            21016 23374821
NOIDR    L     SP1,ENDSWH(ACT)          GET ENTRY ADDRESS         21016 23374921
         LTR   SP1,SP1                  IS THERE AN ENTRY ADDRESS       23400000
         BZ    XYZ                      NO                              23420000
         MVC   RLDOUT+5(3),ENDSWH+1(ACT)     YES, PUT IN THE ADDRESS    23440000
         MVC   RLDOUT+15(1),ENDSWH(ACT)                                 23460000
         MVI   RLDOUT+14,X'00'                                          23480000
XYZ      BAL   SRR,WRPUN                GO PUNCH CARD                   23500000
YPN      L     ACT,ACTSAV               RESTORE ASSEMBLER CONTROL TABLE 23520000
         LR    GR2,LICNT                LATEST PAGE LICNT FOR FD A27012 23530019
         LA    GRZ,IOSAVE               OS SAVE AREA                    23540000
         L     GR0,GOT+4                RELEASE LARGE MAIN STOR. BLOCK  23560000
         L     GR1,GOT                                                  23580000
         XC    GOT,GOT                  DENOTE STG RET'D          18848 23590000
     FREEMAIN  R,LV=(0),A=(1)           FREE IT                         23600000
         LR    GR0,GR2                  PASS LICNT AS PARM TO FD A27012 23655019
         L     GRY,=V(IEUFD)            LOAD ADDRESS OF IEUFD           23660000
         BR    GRY                      CALL DIAGNOSTIC ROUTINE         23680000
ACTSAV   DC    A(0)                     SAVE AREA FOR ACT               23700000
CDZERO   DC    X'F0F0F0F0'              MASK FOR ZEROING BLANKS         23720000
*        ************************************************************** 23740000
XRFSIZ   EQU   XRFLN*BLKFC1+1           SIZE OF XRF BUFFER              23760000
MASK     EQU   0                        INITIAL SEQUENCE BASE ADDRESS   23780000
X1       EQU   1                        GENERAL REGISTER 1              23800000
X2       EQU   2                        INDEX IN SORT TABLE POINTER     23820000
X3       EQU   ACT                      GENERAL REGISTER 3              23840000
X4       EQU   4                        LOOP ASSRESS FOR RLDLOD, XRFLOD 23860000
X5       EQU   15                       GENERAL REGISTER 15             23880000
SIX      EQU   7                        LENGTH OF RECORD                23900000
POINTL   EQU   8                       LOWER LIMIT FOR SORT             23920021
POINTD   EQU   9                       ADDRESS OF RECORD IN CORE        23940021
ENDLMT   EQU   10                      END OF AVAILABLE CORE FOR SORT   23960021
POINTA   EQU   11                      ADDRESS OF SORT POINTER          23980021
BYTCNT   EQU   12                       LENGTH FOR COMPARE              24000000
CNTRH    EQU   13                       DELTA IN SORT                   24020000
POINTH   EQU   14                       HIGHER LIMIT IN SORT            24040000
BASEL    EQU   X1                       LOWER DATA ITEM                 24060000
BASEH    EQU   X3                       HIGHER DATA ITEM                24080000
VARB     EQU   SIX                      LENGTH OF RECORD                24100000
EIGHT    EQU   SIX                      LENGTH OF RECORD                24120000
ELNE     EQU   SIX                      LENGTH OF RECORD                24140000
RETURN   EQU   BYTCNT                   RETURN ADDRESS FOR RLD OUTPUT   24160000
LICNT    EQU   CNTRH                    LINE COUNTER                    24180000
REWIND   EQU   TCLS                     TO REWIND USE CLOSE TYPE=T      24200000
REDRLD   EQU   GTM                      READ RLD IS GET MERGE           24220000
WRRLD    EQU   PUT                      WRITE XRF IS PUT                24240000
REDXRF   EQU   GTM                      READ XRF IS GET MERGE           24260000
WRXRF    EQU   PUT                      WRITE XRF IS PUT                24280000
WRGO     EQU   SYSO                     WRITE GO AND PUNCH              24300000
WRPUN    EQU   SYSO                        IS WRITE SYSOUT              24320000
PKFLG    DC    X'00'                    RLD SPLIT FLAG FF=SPLIT,00=NOT  24340000
HAST     DC    C'*****'                 STATEMENT NO. WORK AREA   IEUN3 24360018
FRSTSW   DC    X'FF'                    FIRST PASS FLAG FF=FIRST,00=NOT 24380000
ITRSWH   DC    X'00'                    JUMP TABLE INDEX (SEE JUMP)     24400000
HZERO    DC    4X'F0'                   ZERO TO RESET REF. COUNT        24420000
ZERO     DC    F'0'                     FULL WORD OF BINARY ZERO        24440000
RETHLD   DS    F                        RETURN ADDRESS FOR WRLST        24460000
REGHLD   DS    5F                       SAVE AREA FOR WORK REGISTERS    24480000
ADJBS    DS    F                  ADJUSTMENT ADDRESS FROM CONTROL TBL   24500000
ADJBSEND DS    F                        ADJ TABLE FINAL ENTRY +4        24520000
VERMOD   DC    C'2100'                  VERSION MOD LEVEL OF F    21016 24530021
PID      DC    C'360SAS037 '            PID ORDER NUMBER FOR F    21016 24532021
H8       DC    H'8'                                               21016 24534021
DKID     DC    4X'40'                   DECK ID                         24540000
ENDSWX   DC    X'00'                    END SWITCH  FF=ON, 00=OFF       24560000
NOSWIT   DC    X'00'                    RLD OR XRF FLAG 00=NONE,FF=SOME 24580000
CNTSAV   DC    H'0'                     LINE COUNTER SAVE AREA          24600000
RFCTSW   DC    X'00'                    REF. TO PRINT 00=SOME,FF=NONE   24620000
NOCOR    DC    C'0'                     CORE EMPTY SWITCH  FF=EMPTY     24640000
LSTLD    DC    C'0'                     LAST PASS SWITCH  FF=LAST       24660000
LSTRL    DC    C'0'                                                     24680000
THRNIN   DC    H'57'                    THIRTY-NINE HEX                 24700000
REGDMP   DS    H                        TEMP FOR BYTE COUNT             24720000
HOLD     DS    CL18                     RLD HOLD AREA                   24740000
         DS    H                                                        24760000
         DC    X'40'                                                    24780000
XRFHLD   DS    CL18                     XRF HOLD AREA                   24800000
TAPEIN   DS    CL18                     TAPE HOLD AREA                  24820000
COMPID   DS    0CL4                     COMPARE FOR SAME ID             24840000
         DC    X'00'                                                    24860000
TSTPES   DS    C                        POS. ID                         24880000
         DC    X'00'                                                    24900000
TSTRES   DS    C                        REL. ID                         24920000
RLDHLD   DC    8X'0'                    RLD FOR CARD OUTPUT             24940000
HLDRLD   DS    0CL8                     TO UNPACK RLD FOR CARD          24960000
PESDID   DS    C                        POS. ESD/ID                     24980000
RESDID   DS    C                        REL. ESD/ID                     25000000
ENDRLD   DS    CL6                      RLD FOR OUTPUT                  25020000
NORLD    DC    X'00'                    RLD=00, NORLD=FF         A27012 25030019
XRFH2    DS    0CL121                   CROSS REFERENCE HEAD 2          25040000
         DC    X'02'                    DOUBLE SPACE                    25060000
         DC    C'SYMBOL    LEN  VALUE  DEFN     REFERENCES'             25080000
         DC    100C' '                                                  25100000
XRFH1    DS    0CL121                   CROSS REFERENCE HEAD 1          25120000
         DC    X'FF'                    EJECT                           25140000
         DC    45C' '                                                   25160000
         DC    C'CROSS-REFERENCE'                                       25180000
         DC    51C' '                                                   25200000
         DC    C'PAGE '                                                 25220000
XRFPCT   DS    CL4                      XRF PAGE NO.                    25240000
XRFOUT   DS    0CL121                   XRF OUTPUT LINE                 25260000
         DC    X'00'                    SINGLE SPACE                    25280000
XRFSYM   DC    CL8' '                   SYMBOL                    IEUN3 25300018
         DC    C' '                                               IEUN3 25320018
XRFLEN   DC    CL5' '                   LENGTH                    IEUN3 25340018
         DC    C' '                                               IEUN3 25360018
XRFVAL   DC    CL6' '                   VALUE                     IEUN3 25380018
         DC    C' '                                               IEUN3 25400018
XRFDEF   DC    CL5' '                   WHERE DEFINED             IEUN3 25420018
         DC    2C' '                                              IEUN3 25440018
XRFSN1   DC    92C' '                   WHERE REFERENCED          IEUN3 25460018
RLDH1    DS    0CL121                   RLD HEAD 1 (HEADING 2)          25480000
         DC    X'02'                    DOUBLE SPACE                    25500000
         DC    C' POS.ID   REL.ID   FLAGS   ADDRESS'                    25520000
         DC    86X'40'                                                  25540000
RLDH2    DS    0CL121                   RLD HEAD 2 (HEADING 1)          25560000
         DC    X'FF'                    EJECT                           25580000
         DC    49C' '                                                   25600000
         DC    C'RELOCATION DICTIONARY'                                 25620000
         DC    42C' '                                                   25640000
         DC    C'PAGE'                                                  25660000
NY14     DC    4C' '                    RLD PAGE NUMBER                 25680000
RLDDET   DS    0CL121                   RLD DETAIL RECORD               25700000
         DC    X'00'                                                    25720000
         DC    120X'40'                                                 25740000
COMP     DC    2F'0'                    FOR DUPLICATE SYMBOL COMPARE    25760000
BGNLOC   DC    F'0'                                                     25780000
ENDCR    DC    C'END'                   FOR END CARD                    25800000
RLDOUT   DC    X'02'                    CARD IMAGE FOR RLD OUTPUT       25820000
         DC    C'RLD'                                                   25840000
         DC    6C' '                                                    25860000
BYTOUT   DS    2C                       NUMBER OF BYTES                 25880000
         DC    4C' '                                                    25900000
VARRLD   DC    56C' '                   RLD OUTPUT                      25920000
         DC    8C' '                                                    25940000
BASED    DC    A(0)                     START OF SORT AREA              25980000
RECCT    DC    A(0)                     NO. OF LOGICAL RECORDS          26000000
BASE     DC    A(0)                     ADDRESS OF SORT BLOCK           26010021
NYP      DC    4X'40'                   FULL WORD OF BLANKS             26020000
         LTORG                                                          26060000
RESBUF   DS    0D,XL(4*XRFSIZ)          INTERNAL I/O BUFFERS            26080000
ERRBUF   EQU   RESBUF+1                 MUST BE AN ODD ADDRESS     I000 26084020
TERLI    EQU   ERRBUF+1                 HALFWORD BOUNDARY NEC      I000 26088020
ERRCDL   EQU   ERRBUF+519                                          I000 26092020
DIAGSAVE EQU   ERRBUF+558                                          I000 26096020
*   MAINTENANCEAREA FOR THIS MODULE                              200002 26097020
MAINT    DS    110C                      MAINTANACE AREA                26098021
ENDFPP   DS    0D                                                       26100000
         DCBD  DSORG=PS                                           18848 26110000
         END   IEUFPP                                                   26120000
