RTA  TITLE 'F ASSEMBLER ROOT SEGMENT A AND CONTROL TABLE.*.*.*.*.*.*.*' 00020000
         ISEQ  73,80                                                    00040000
IEURTA   START                                                          00060000
*          RELEASE 19 DELETIONS                                         00064000
*          RELEASE 20 DELETIONS                                         00065000
* 022000-022400,042000,043000,046000-047200,050600,051200,         I000 00065320
* 052000-061400                                                    I000 00065620
*                                                                200002 00065820
* 054260,055940                                                  A32954 00065920
*          RELEASE 21 DELETIONS                                         00066000
* 000633-000636,000670-000700,054260,055933-055942               A45780 00066421
*                                                                A45780 00076421
RTSEGA   EQU   IEURTA                   INTERNAL NAME                   00080000
*                                                                     * 00100000
*TITLE- 'IEURTA  ' ... ROOT SEGMENT ASSEMBLER PHASE                   * 00120000
*STATUS CHANGE LEVEL 007                                                00128021
*                                                                       00136020
* INCREMENTAL IMPROVEMENTS FOR RELEASE 20                               00144020
* I000 TSO IMPLEMENTATION                                               00152020
*FUNCTION/OPERATION-                                                  * 00160000
*   SETS UP PARTS OF THE ASSEMBLER CONTROL TABLE AND SETS UP THE      * 00180000
*   REGISTER ACT FOR ALL OF PHASE 7 AND 8. HAS THE DCB'S FOR SYSLIST, * 00200000
*   SYSPUNCH, SYSGO, AND THE TRANSLATE TABLE. PROCESSES THE PATCH     * 00220000
*   FACILITY OF THE ASSEMBLER.                                        * 00240000
*ENTRY POINTS-                                                        * 00260000
*   IEURTA ... ROOT SEGMENT FOR PHASES 7 AND 8                        * 00280000
*        CALLING SEQUENCE                                             * 00300000
*               XCTL   EP=IEURTA        CALL ASSEMBLER  PHASES        * 00320000
*   CTDUMP ...ASSEMBLER F PATCH SUBROUTINE                            * 00340000
*        CALLING SEQUENCE- SEE TEXT                                   * 00360000
*EXTERNAL ROUTINES-                                                   * 00380000
*   IEURTA LINKS TO ASSEMBLER PHASES. CONTROL IN RTA IS AS SHOWN...   * 00400000
*        IEURTA LINKS   TO IEUF7                                      * 00420000
*        IEUF7  XCTL    TO IEUFI                                      * 00440000
*        IEUFI  XCTL    TO IEUF8                                      * 00460000
*        IEUF8  XCTL    TO IEUFPP                                     * 00480000
*        IEUFPP RETURNS TO IEURTA                                     * 00500000
*EXITS- NORMAL                                                        * 00520000
*   RETURNS TO IEUASM                                                 * 00540000
*     - ERROR                                                         * 00560000
*   ON I/O ERROR, XCTL TO IEUERR                                      * 00580000
*TABLES/WORKAREAS-                                                    * 00600000
*   ACT        ASSEMBLER CONTROL TABLE                                * 00620000
*   TRSLTB     TRANSLATE AND TEST TABLE                               * 00640000
*   ACT1       STORAGE FOR FUNCTION LINKAGE ALGORITHIMS               * 00660000
*   ACT2                   FUNCTION BASE/ENTRY ADDRESSES              * 00680000
*   ACT3                   SUBROUTINE BASE/ENTRY ADDRESSES            * 00700000
*   ACT4                   POINTERS TO COMMON DATA AREAS              * 00720000
*   ACT5                   CENTRAL TABLES AND ITEMS                   * 00740000
*   ACT6                   TEXT RECORD WORK AREA                      * 00760000
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 00780000
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 00800000
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 00820000
*NOTES -                                                         200002 00823020
*   MAINTENANCEAREA FOR THIS MODULE IS INCLUDED IN THE           200002 00826020
*   MAINTENANCEAREAS IN THE DIFFERENT PHASES F7,FI,F8 AND FPP    200002 00829020
*   FOR MFT. BECAUSE OF THE 2K LOADMODULE SYSTEM                 200002 00832020
*   NO EXTRA MAINTENANCEAREA IS REQUESTED FOR THE MVT SYSTEM.    200002 00835020
*                                                                     * 00840000
         EJECT                                                          00860000
         FDIMEN                                                         00880000
*                                       REGISTERS CONTAINING INPUT PARM 00900000
PARAM2   EQU   2                             TEXT BLOCK LENGTH          00920000
PARAM3   EQU   3                             POINTER TO I/O DCB         00940000
PARAM4   EQU   4                             PUNCH OPTION INDICATOR     00960000
PARAM5   EQU   5                             PAGE LINE COUNT            00980000
PARAM6   EQU   6                             RETURN ADDRESS             01000000
BASE1    EQU   7                             INITIAL BASE               01020000
BASE2    EQU   BASE1                         SECOND BASE                01040000
BASE0    EQU   0                             NEVER USED                 01060000
N8       EQU   8                        NUMBER OF BYTES TO MOVE    I000 01066020
D24      EQU   24                       OFFSET IN AN AREA          I000 01072020
         EJECT                                                          01080000
         BALR  BASE2,0                  SET UP BASE                     01100000
         USING *,BASE2                                                  01120000
         ST    13,LIKSAV+4              SET UP OS/360 SAVE AREA         01140000
         LA    13,LIKSAV                AND CONVENTIONS                 01160000
         ST    PARAM6,RETSAV            SAVE RETURN ADDRESS             01180000
         LA    BASE2,ACTABL             LOAD UP ACT                     01200000
         USING ACTABL,BASE2             USE IT AS BASE                  01220000
CTINIT0  BAL   10,CTINIT                CALL CTIN INITIALIZATION        01240000
         USING *,10                     SET UP ANOTHER BASE             01260000
         LINK  EP=IEUF7,MF=(E,(1))      CALL F7  IEUF7 IN IEUF7I        01280000
         BALR  10,0                     SET UP BASE  CAME FROM IEUFPP   01300000
         USING *,10                                                     01320000
         L     13,LIKSAV+4              LOAD SAVE AREA                  01340000
         L     14,RETSAV                AND RETURN ADDRESS              01360000
         BR    14                       RETURN TO MRS                   01380000
         SPACE 3                                                        01400000
IOERR    DS    0H                       SYNAD ROUTINE                   01420000
         SPACE 3                                                        01560000
RETSAV   DC    F'0'                     ADDRESS OF MRS                  01580000
LIKSAV   DS    18F                      SAVE AREA FOR RTA               01600000
JDATE    DS    2F                       JULIAN DATE SAVED FOR END 21016 01610021
*                                       CARD IN FPP               21016 01612021
         DROP  10                       GET RID OF THE BASE REGISTERS   01620000
         DROP  BASE2                                                    01640000
         EJECT                                                          01660000
*                                       ******************************* 01680000
*                                       * TRANSLATE AND TEST TABLE    * 01700000
*                                       ******************************* 01720000
TRSLTB   DC    X'F0F1F2F3F4F5F6F7F8F9C1C2C3C4C5C6'                01-16 01740000
         DC    X'C7C8C9D1D2D3D4D5D6D7D8D9E2E3E4E5'                02-16 01760000
         DC    X'E6E7E8E95B7B7C4E605C616B7E504B4D'                03-16 01780000
         DC    X'5D7D40333435363738393A3B3C3D3E3F'                04-16 01800000
         DC    X'324142434445464748494A2E4C2F274F'                05-16 01820000
         DC    X'2D5152535455565758595A2429305E5F'                06-16 01840000
         DC    X'282A62636465666768696A2B6C6D6E6F'                07-16 01860000
         DC    X'707172737475767778797A2526312C7F'                08-16 01880000
         DC    X'808182838485868788898A8B8C8D8E8F'                09-16 01900000
         DC    X'909192939495969798999A9B9C9D9E9F'                10-16 01920000
         DC    X'A0A1A2A3A4A5A6A7A8A9AAABACADAEAF'                11-16 01940000
         DC    X'B0B1B2B3B4B5B6B7B8B9BABBBCBDBEBF'                12-16 01960000
         DC    X'C00A0B0C0D0E0F101112CACBCCCDCECF'                13-16 01980000
         DC    X'D0131415161718191A1BDADBDCDDDEDF'                14-16 02000000
         DC    X'E0E11C1D1E1F20212223EAEBECEDEEEF'                15-16 02020000
         DC    X'00010203040506070809FAFBFCFDFEFF'                16-16 02040000
         EJECT                                                          02060000
*                                                                       02080000
*        DATA CONTROL BLOCK FOR SYSPRINT                                02100000
*                                                                       02120000
SYLIST   DCB   DSORG=PS,MACRF=(PL),DDNAME=SYSPRINT,SYNAD=IOERR,        X02140000
               BFTEK=S,      FIXED.                                    X02160000
               LRECL=121,    FIXED.                                    X02180000
               BUFNO=0,      DD MAY SPECIFY UP TO 255                  X02200020
               BLKSIZE=0,    DD MAY SPECIFY,ELSE 121                   X02220020
               EXLST=1       DUMMY EXIT ADDRESS                    I000 02240020
*              OPTCD=,       W,C,WC MAY BE SPECIFIED IN DD.             02260000
         SPACE 10                                                       02280000
*        DATA CONTROL BLOCK FOR SYSPUNCH                                02300000
*                                                                       02320000
*                                                                       02340000
SYSPCH   DCB   DDNAME=SYSPUNCH,MACRF=(PM),SYNAD=IOERR,DSORG=PS,        X02360000
               BFTEK=S,LRECL=80                                         02380000
         SPACE 10                                                       02400000
*                                                                       02420000
*        DATA CONTROL BLOCK FOR SYSGO                                   02440000
*                                                                       02460000
SYSGO    DCB   DDNAME=SYSGO,MACRF=(PM),SYNAD=IOERR,DSORG=PS,           X02480000
               BFTEK=S,LRECL=80                                         02500000
         EJECT                                                          02520000
ACTABL   DS    0F                       BEGINNING OF ASSEMBLER CONTROL  02540000
*                                       TABLE                           02560000
******** CT1 - MLC/FUNCTIONAL ROUTINE LINKAGE ALGORITHIMS ************* 02580000
*                                                                       02600000
         USING ACTABL,ACT               SET UP BASE                     02620000
         ORG   ACTABL                   PUT IN CORRECT SPOT             02640000
ACT1     DS    (CT1C)C                                                  02660000
*                                                                       02680000
         ORG   ACT1+0                   CTLNK1                          02700000
         STM   GRA,GRD,SAVER            SAVE                            02720000
         BR    FRB                      GO TO FUNCTION                  02740000
*                                                                       02760000
         ORG   ACT1+CTLNK2              CTLNK2                          02780000
         STM   GRA,GRD,SAVER            SAVE                            02800000
         L     FRB,CBRNDA(ACT)          GET THE BASE                    02820000
         BR    GRX                      GO TO THE FUNCTION              02840000
*                                                                       02860000
         ORG   ACT1+CTRTRN              CTRTRN                          02880000
         LM    GRA,GRD,SAVER            RESTORE THE SAVED REGISTERS     02900000
         BR    CRR                      RETURN                          02920000
*                                                                       02940000
         ORG   ACT1+CTSAVE              CTSAVE                          02960000
SAVER    DS    4F                       SAVE AREA FOR MLC/FUNCTION      02980000
         DROP  ACT                                                      03000000
*                                                                       03020000
*                                                                       03040000
******** CT2 - FUNCTIONAL ROUTINES BASE/ENTRY ADDRESSES *************** 03060000
*                                                                       03080000
         ORG   ACT1+CT2                                                 03100000
ACT2     DS    (CT2C)A                  SET ASIDE AREA FOR FUNCTION ADD 03120000
*                                                                       03140000
*                                                                       03160000
******** CT3 - COMMON SUBROUTINES BASE/ENTRY ADDRESS                    03180000
*                                                                       03200000
         ORG   ACT1+CT3                                                 03220000
ACT3     DS    (CT3C)A                  SET ASIDE AREA FOR SUBROUTINES  03240000
*                                                                       03260000
*                                                                       03280000
******** CT4 - POINTERS TO COMMON DATA AREAS ************************** 03300000
*                                                                       03320000
         ORG   ACT1+CT4                                                 03340000
ACT4     DS    (CT4C)A                  SET ASIDE AREA FOR COMMON DATA  03360000
*                                                                       03380000
*                                                                       03400000
******** CT5 - CENTRAL TABLES AND ITEMS ******************************* 03420000
*                                                                       03440000
         ORG   ACT1+CT5                                                 03460000
ACT5     DC    (CT5C)X'0'               SET ASIDE AREA FOR TABLES       03480000
*                                                                       03500000
*                                                                       03520000
******** CT6 - TEXT RECORD WORK AREA ********************************** 03540000
*                                                                       03560000
         ORG   ACT1+CT6                                                 03580000
ACT6     DS    (CT6C)C                  SET ASIDE AREA FOR WORK AREA    03600000
         EJECT                                                          03620000
******** CT2 INITIAL CONDITIONS *************************************** 03640000
*                                                                       03660000
         SPACE 5                                                        03680000
******** CT3 INITIAL CONDITIONS *************************************** 03700000
*                                                                       03720000
         ORG   ACT1+CSTGET                                         I000 03722020
         DC    A(STGETR)                                           I000 03724020
         ORG   ACT1+CSTPUT                                         I000 03726020
         DC    A(STPUTR)                                           I000 03728020
         ORG   ACT1+CSTROM                                         I000 03730020
         DC    A(STROOM)                                           I000 03732020
         ORG   ACT1+CLOGER                                         I000 03734020
         DC    A(LOGERR)                                           I000 03736020
         SPACE 5                                                        03740000
******** CT4 INITIAL CONDITIONS *************************************** 03760000
*                                                                       03780000
         ORG   ACT1+CADJBS                                         I000 03786020
         DC    A(ADJTAB)                ADJUSTMENT TABLE           I000 03792020
         ORG   ACT1+LSTDCB              PUT IN ADDRESS OF DCB FOR       03800000
         DC    A(SYLIST)                SYSLIST                         03820000
         ORG   ACT1+PCHDCB                                              03840000
         DC    A(SYSPCH)                SYSPUNCH                        03860000
         ORG   ACT1+GODCB                                               03880000
         DC    A(SYSGO)                 SYSGO                           03900000
         ORG   ACT1+CTRTBP                                              03920000
         DC    A(TRSLTB)                AND ADDRESS OF TRT TABLE        03940000
         SPACE 5                                                        03960000
******** CT5 INITIAL CONDITIONS *************************************** 03980000
*                                                                       04000000
         ORG   ACTABL+CTWORK            OVERLAY SCRATCH PAD AREA        04020000
         USING ACTABL,BASE2                                             04040000
******** CTINIT - F/7I8PP INITIALIZATION ROUTINE (ONCE ONLY CODE) ***** 04060000
*                                                                       04080000
*                                                                       04100000
*                                                                       04120000
* SAVE ENTRANCE PARAMETERS (SET BY F/6) IN F/7 CONTROL TABLE            04140000
*                                                                       04160000
CTINIT   STH   PARAM2,CTXLEN(BASE1)     PUT IN TEXT BLOCK LENGTH        04180000
         STC   PARAM4,CTTSTI(BASE1)     PUT IN PARAM FLAG BYTE 1   I000 04190020
         SRL   PARAM4,8                                            I000 04200020
         STC   PARAM4,CTPCHI(BASE1)     PUT IN PARAM FLAG BYTE 0   I000 04210020
         STC   PARAM5,CTPGLNCT(BASE1)   PUT IN PAGE LINE COUNT          04220000
         MVC   CTOUT2(8,BASE1),0(PARAM3)  TEST OUTIN, INOUT       18848 04250000
         MVC   CTOUT1(4,BASE1),8(PARAM3)    OVERFLOW(NP)--------UT3     04280000
         L     PARAM2,ACT1+LSTDCB       INSERT INVOKER DDNAMES,PASSED   04320000
         USING IHADCB,PARAM2            BY MACROGEN,INTO DCB'S.         04340000
         L     PARAM3,12(PARAM3)                                        04360000
         MVC   DCBDDNAM,0(PARAM3)       SYSPRINT                        04380000
         MVC   LISTNAM(N8,BASE1),DCBDDNAM                          I000 04390020
         L     PARAM2,ACT1+PCHDCB                                       04400000
         MVC   DCBDDNAM,8(PARAM3)       SYSPUNCH                        04420000
         L     PARAM2,ACT1+GODCB                                        04440000
         MVC   DCBDDNAM,16(PARAM3)      SYSGO                           04460000
         MVC   TERMNAM(N8,BASE1),D24(PARAM3) SYSTERM               I000 04470020
         DROP  PARAM2                                                   04480000
         LA    2,ACT6                   GET TEXT RECORD WORK AREA       04500000
         ST    2,CTXWAP(BASE1)          PUT IN TEXT WORKAREA POINTER    04520000
         ST    2,CTLDCP(BASE1)          AND LITERAL DC WORK AREA POINTR 04540000
         LR    ACT,BASE1                PUT ADDRESS OF ASSEMBLER CONTRO 04560000
         DROP  BASE2                    TABLE INTO ACT                  04580000
         BR    10                       RETURN TO CALLER                04740000
*********************************************************************** 04760000
         SPACE                                                          04780000
         ORG   ACT1+CLASID              CONTINUE INITIALIZATION IN CT5  04800000
         DC    H'0'                     LAST ID                         04820000
         ORG   ACT1+CTNDID                                              04840000
         DC    H'255'                   NEXT DSECT ID                   04860000
         ORG   ACT1+CTITLE                                              04880000
         DC    C'        '              FIRST TITLE NAME                04900000
         ORG   ACT1+CPRIME                                              04920000
         DC    H'527'                   LIT-OPSYN HASH,ESD RESERV IEUN1 04940018
         DC    H'54'                    OPTIMUM NUMBER OF BYTES/THREAD  04960000
         ORG   ACT1+CFREEP                                              04980000
         DC    H'3'                     LENGTH OF EACH POINTER          05000000
         DC    H'31'                    LIT-OPSYN HASH PTR RESERV IEUN1 05020018
         EJECT                                                          05040000
         USING ACTABL,ACT                                               05140000
         ORG   ACTABL+CTDUMP                                            05160000
         SPACE                                                          05180000
*        ADJUSTMENT TABLE                                          I000 05181020
*                                                                  I000 05182020
*                                                                  I000 05183020
         DS    0D                                                  I000 05184020
ADJTAB   DS    1092X                                               I000 05185020
*                                                                  I000 05185120
* IEUF7L AND IEUF7S MODULES ARE DELETED AS SEPARATE CSECTS.        I000 05185220
* THEY ARE PLACED IN PHASE IEURTA TO GET MORE SUFFICIENT           I000 05185320
* USE OF CORE IN MVT. THE CODE IS OVERLAID IN IEUFI AND IEUF8 BY   I000 05185420
* ADJUSTMENT TABLE.                                                I000 05185520
*                                                                  I000 05185620
         SPACE 2                                                   I000 05186020
         ORG   ACTABL+CTDUMP                                       I000 05187020
IEUF7L   EQU   *                                                        05188020
*                                                                       05189020
*                                                                       05190020
*                                                                       05191020
*                                                                       05192020
*                                                                       05193020
*                                                                       05194020
*                                                                       05195020
*                                                                       05196020
*                                                                       05197020
LOGERR   EQU   IEUF7L                                                   05198020
         SPACE                                                          05199020
*TITLE 'IEUF7L  ' ... LOG ERROR                                       * 05200020
*STATUS- CHANGE LEVEL  01                                             * 05201020
*FUNCTION/OPERATION-                                                  * 05202020
*   IEUF7L ATTACHES THE ERROR MESSAGE TO AN EDITED TEXT RECORD. IF THE* 05203020
*   ERROR RECORD IS ALREADY PRESENT, IEU7L CHECKS FOR DUPLICATION AND * 05204020
*   A MAXIMUM OF 16 ERRORS, IF EITHER OF THESE CONDITIONS IS MET, THE * 05205020
*   ERROR IS NOT LOGGED. IF BOTH OF THE CONDITIONS ARE NOT MET, THE   * 05206020
*   ERROR IS LOGGED. IF THE ERROR RECORD IS NOT PRESENT, THE ERROR IS * 05207020
*   LOGGED AND A BIT IS SET IN TXERI SO THAT AN ERROR RECORD WILL BE  * 05208020
*   CREATED.                                                          * 05209020
*ENTRY POINT- IEUF7L                                                  * 05210020
*     CALLING SEQUENCE--                                              * 05211020
*                                                                     * 05212020
*       L     SRB,CLOGER(ACT)           LOGERR BASE/ENTRY ADDRESS     * 05213020
*       L     SP1,POINTER               ABS POINTER TO ERROR (OR ZERO)* 05214020
*       BALR  SRR,SRB                                                 * 05215020
*       DC    AL2(ERRORCODE)            ERRORCODE EQU ERROR MSSG NUMBR* 05216020
*                                                                     * 05217020
* LOGERR WILL RETURN TO CALLING ROUTINE WITH SP1,SP2 UNCHANGED.       * 05218020
* GR0-GR2, GRX, GRY, AND GRZ ARE VOLATILE.                            * 05219020
*                                                                     * 05220020
*INPUT- NONE                                                          * 05221020
*OUTPUT- NONE                                                         * 05222020
*EXTERNAL ROUTINES-                                                   * 05223020
*   GETXTM- GET TEXT AND MOVE, CALLED IF AN ERROR RECORD IS PRESENT   * 05224020
*EXITS- NORMAL                                                        * 05225020
*   RETURNS TO CALLER VIA                                             * 05226020
*        BR    2(SRR)                   EXIT                          * 05227020
*   --- ERROR- NONE                                                   * 05228020
*TABLES/WORKAREAS-                                                    * 05229020
*   CTERRP(ACT)- POINTS TO THE ERROR RECORD WORK AREA                 * 05230020
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 05231020
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 05232020
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 05233020
*                                                                     * 05234020
         EJECT                                                          05235020
ERRMAX   EQU   16                       MAX NUMBER OF ERRORS/STATEMENT  05236020
         SPACE                                                          05237020
         USING LOGERR,SRB                                               05238020
         SPACE 2                                                        05239020
         STM   SP1,SP2,SAVE2            ENTER LOGERR, SAVE REGS         05240020
         L     SP2,CTERRP(ACT)          POINTER TO ERROR REC WORK AREA  05241020
         TM    CTPH7C(ACT),X'02'        TEST PHASE                      05242020
         BZ    LOGERRF7                 PHASE 7                         05243020
*        BO    LOGERRF8                 PHASE 8                         05244020
         SPACE                                                          05245020
******** PHASE 8 ****************************************************** 05246020
LOGERRF8 LA    SP1,1(SP1)               CALC RELATIVE POINTER         * 05247020
         S     SP1,F8OPRN(ACT)                                        * 05248020
         B     COLPOINT                                               * 05249020
*********************************************************************** 05250020
         SPACE                                                          05251020
******** PHASE 7 ****************************************************** 05252020
LOGERRF7 S     SP1,CTXOFP(ACT)          CALC RELATIVE POINTER         * 05253020
*        B     COLPOINT                                               * 05254020
*********************************************************************** 05255020
         SPACE                                                          05256020
COLPOINT BP    GETERR                   POINTER PRESENT                 05257020
         SR    SP1,SP1                  NOT PRESENT, CLEAR SP1          05258020
*        B     GETERR                                                   05259020
         EJECT                                                          05260020
GETERR   CLI   ERSWH(ACT),X'FF'         TEST ERROR REC IN CORE SWITCH   05261020
         BE    ADDERR                   SET, ADD ERROR MESSAGE TO REC   05262020
         MVI   ERSWH(ACT),X'FF'         NOT SET, SET                    05263020
         MVI   2(SP2),X'10'             INITIALIZE ERR REC IN WORK AREA 05264020
         MVI   3(SP2),X'00'             REC TYPE EQ 001, COUNT EQ ZERO  05265020
         L     GR1,CTEXTP(ACT)                                          05266020
         TM    TXERI(GR1),X'04'         TEST ERROR REC FOLLOWS IND      05267020
         BO    GETREC                   SET, GET ERROR REC FROM TEXT    05268020
         OI    TXERI(GR1),X'04'         NOT SET, SET IT                 05269020
         B     ADDERR                   THEN ADD ERR MESSAGE TO NES REC 05270020
         SPACE                                                          05271020
GETREC   STM   SRB,SP2,SAVE4            SAVE REGISTERS                  05272020
         LR    SP1,SP2                  PUT RECORD IN ERROR WK AREA     05273020
         L     SRB,CTXTIO(ACT)          LOAD BASE                       05274020
         BAL   SRR,GETXTM(SRB)          GET ERROR REC FROM TEXT FILE    05275020
         USING *,SRR                    GETXTM DESTROYED OUR BASE       05276020
         LM    SRB,SP2,SAVE4            SO RESTORE OUR BASE USING SRR   05277020
         DROP  SRR                      NO MORE NEED FOR SRR, SO DROP   05278020
         SPACE                                                          05279020
ADDERR   CLI   3(SP2),ERRMAX            TEST ERROR COUNT                05280020
         BE    RETURN                   EXIT IF MAX                     05281020
         SPACE                                                          05282020
         SR    GR1,GR1                  PUT ERROR COUNT IN GR1          05283020
         IC    GR1,3(SP2)                                               05284020
         LR    GR2,GR1                  POINT GR2 TO CURRENT MESSAGE-1  05285020
         SLL   GR2,1                                                    05286020
         LA    GR2,0(GR2,SP2)                                           05287020
         SPACE                                                          05288020
         STC   SP1,5(GR2)               PUT COL POINTER IN ERR MESSAGE  05289020
         MVC   4(1,GR2),1(SRR)          PUT ERROR CODE  IN ERR MESSAGE  05290020
         LH    SP1,4(GR2)               PUT ERROR MESSAGE IN SP1        05291020
         SPACE                                                          05292020
CHECKERR CLR   GR2,SP2                  COMPARE CURRENT ERROR MESSAGE   05293020
         BE    COUNTERR                 AGAINST PRIOR MESSAGES          05294020
         CH    SP1,2(GR2)                                               05295020
         BE    RETURN                   IGNORE IF PREVIOUSLY LOGGED     05296020
         BCTR  GR2,0                                                    05297020
         BCT   GR2,CHECKERR             LOOP TO COMPARE ALL             05298020
         SPACE                                                          05299020
COUNTERR LA    GR1,1(GR1)               INC ERROR COUNT                 05300020
         STC   GR1,3(SP2)                                               05301020
         LA    GR1,4(GR1,GR1)           INC RECORD LENGTH               05302020
         STH   GR1,TXRL(SP2)                                            05303020
         SPACE                                                          05304020
RETURN   LM    SP1,SP2,SAVE2            RESTORE REGS                    05305020
         B     2(SRR)                   RETURN TO CALLING ROUTINE       05306020
         SPACE 1                                                        05307020
SAVE2    DS    2F                       SP1,SP2 SAVE AREA               05308020
SAVE4    DS    4F                       SRB-SP2 SAVE AREA               05309020
         SPACE 1                                                        05310020
IEUF7S   EQU   *                                                        05311020
*          RELEASE 18 DELETIONS                                         05312020
*1476027800                                                       IEUN1 05313020
*          RELEASE 19 DELETIONS                                         05314020
*          RELEASE 20 DELETIONS                                         05315020
*          RELEASE 21 DELETIONS                                         05316020
*          RELEASE 22 DELETIONS                                         05317020
*          RELEASE 23 DELETIONS                                         05318020
*          RELEASE 24 DELETIONS                                         05319020
*          RELEASE 25 DELETIONS                                         05320020
*          RELEASE 26 DELETIONS                                         05321020
*                                                                     * 05322020
*TITLE 'IEUF7S  ' ...  SYMBOL TABLE PROCESSOR                         * 05323020
*STATUS CHANGE LEVEL 005                                                05324020
*FUNCTION/OPERATION-                                                  * 05325020
*   IEUF7S IS TO MAINTAIN THE SYMBOL TABLE. IT PUTS SYMBOLS INTO THE  * 05326020
*   TABLE, RETRIEVES SYMBOLS FROM THE TABLE, AND TESTS IF ROOM EXISTS * 05327020
*   FOR ANOTHER SYMBOL. BOTH THE SYMBOL TABLE AND EXTERNAL SYMBOL     * 05328020
*   DICTIONARY (ESD) SHARE THE SAME AREA OF STORAGE. THE SYMBOL TABLE * 05329020
*   STARTS IN LOW CORE AND WORKS UP, AND THE ESD STARTS IN HIGH CORE  * 05330020
*   AND WORKS DOWN. CROSS REFERENCES TYPE 1 AND 3 (BASE AND MULTIPLY  * 05331020
*   DEFINED SYMBOLS) ARE MADE. BIT 7 OF CTSYMF(ACT) IS SET ON IF THE  * 05332020
*   SYMBOL TABLE IS FULL.                                             * 05333020
*ENTRY POINTS-                                                        * 05334020
*   NAME   EXT NAME      FUNCTION                                     * 05335020
*   STGETR CSTGET(ACT)   GETS AN ITEM FROM THE SYMBOL TABLE           * 05336020
*   STPUTR CSTOUT(ACT)   PUTS AN ITEM INTO THE SYMBOL TABLE           * 05337020
*                      INPUT PARAMETERS FOR BOTH STGETR AND STPUTR ARE* 05338020
*                             SP1- POINTS TO THE SYMBOL               * 05339020
*                             SP2- CONTAINS ZERO OR LENGTH OF SYMBOL  * 05340020
*                             SRB- CONTAINS BASE/ENTRY                * 05341020
*                             SRR- CONTAINS RETURN ADDRESS            * 05342020
*   STROOM CSTROM(ACT)   SEES IF ROOM LEFT IN SYMBOL TABLE            * 05343020
*                             SP1- NO. OF BYTES WANTED IN SYMBOL TABLE* 05344020
*                             SRB- CONTAINS BASE/ENTRY                * 05345020
*                             SRR- CONTAINS RETURN ADDRESS            * 05346020
*INPUT- NONE                                                          * 05347020
*OUTPUT- NONE                                                         * 05348020
*EXTERNAL ROUTINES-                                                   * 05349020
*   PUTXRF(ACT)     PUTS OUT CROSS REFERENCE                          * 05350020
*   CWRESD(ACT)     WRITES OUT ESD SEGMENT                            * 05351020
*EXITS-                                                               * 05352020
*   STGETR                                                            * 05353020
*        B     0(SRR)    SP1=VALUE      SYMBOL FOUND                  * 05354020
*                        SP1=0          SYMBOL NOT FOUND              * 05355020
*   STPUTR                                                            * 05356020
*        B     0(SRR)    SP1=VALUE      SYMBOL FOUND                  * 05357020
*                        SP1=0          SYMBOL PUT IN BUT SYMBOL TABLE* 05358020
*                                       OVERFLOW                      * 05359020
*        B     4(SRR)    SP1=0          SYMBOL PUT IN                 * 05360020
*   STROOM                                                            * 05361020
*        B     0(SRR)    SP1=0          NOT ENOUGH ROOM               * 05362020
*        B     4(SRR)    SP1=0          ENOUGH ROOM                   * 05363020
*NOTE-  TO BRING THE ASSEMBLER LISTING UP TO STANDARDS, ABSOLUTE      * 05364020
*   REGISTERS HAVE BEEN MADE SYMBOLIC AND COMMENTS HAVE BEEN          * 05365020
*   MODIFIED, WITHOUT CHANGING ORIGIONAL OBJECT CODE.                 * 05366020
         EJECT                                                          05367020
*NOTES-                                                               * 05368020
*   SYMBOL TABLE LAYOUT AND ASSOCIATED POINTERS-                      * 05369020
         SPACE 2                                                        05370020
*   *  HASH     *          *                  NO SYMBOL ENTRIES     * * 05371020
*   *--POINTER--*--SYMBOL--*                  MAY BE MADE PAST      * * 05372020
*   *  TABLES   *  ENTRIES *                  THIS POINT            * * 05373020
*   *           *          *                  *                     * * 05374020
*   *-----------*----------*------//------*---*----------*----------* * 05375020
*   *                      *              *   *          *          * * 05376020
*   *--------CFREEP--------*              *   *---260----* --260 ---* * 05377020
*   *                                     *       BYTES  *   BYTES  * * 05378020
*   CTSYMP                                *              *          * * 05379020
*                                         *              CTESDB     * * 05380020
*        CTSYMP+CFREEP =                  *                         * * 05381020
*          START OF NEXT SYMBOL ENTRY     *--------ESD ENTRIES------* * 05382020
*                                         *                         * * 05383020
*        THE FIRST FOUR ENTRIES IN        CTESBP               CESIOB * 05384020
*        THE HASH TABLE ARE FOR                                       * 05385020
*        DC ENTRIES                                                   * 05386020
*        THE FIFTH ITEM IS FOR OPSYN                              IEUN1 05387020
         EJECT                                                          05388020
*                THE SYMBOL TABLE IS A SERIES OF ITEMS OF THE           05389020
*              FORM DESCRIBED BELOW.  THESE ARE ACCESSED BY MEANS       05390020
*              OF A HASH TABLE OF 3-BYTE ADDRESS POINTERS.  ITEMS       05391020
*              WITH THE SAME HASH VALUE ARE CONNECTED BY BACKWARD       05392020
*              CHAINING.  THUS THE FIRST SYNONYM ENTERED HAS NO         05393020
*              CHAIN POINTER,THE SECOND POINTS TO IT,AND SO ON          05394020
*              UNTIL THE LAST OR MOST RECENT,TO WHICH THE HASH          05395020
*              TABLE ADDRESS POINTS.                                    05396020
 SPACE 3                                                                05397020
*                   SYMBOL TABLE ITEM FORMAT                            05398020
 SPACE                                                                  05399020
*       *************************************************************** 05400020
*       *               .                   .                         * 05401020
*       * SYMBOL LENGTH .       SYMBOL      .  ATTRIBUTES (SEE BELOW) * 05402020
*       *               .                   .                         * 05403020
*       *************************************************************** 05404020
*                                                                       05405020
* LENGTH      1 BYTE          1-8 BYTES          3,6,7 OR 11 BYTES      05406020
 SPACE 2                                                                05407020
*                     ATTRIBUTE FIELD FORMAT                            05408020
 SPACE                                                                  05409020
*       *************************************************************** 05410020
*       *        .                .        .        .        .        * 05411020
*       * ESD NO . ADJECTIVE CODE . ESD ID .  VALUE . LENGTH . CHAIN  * 05412020
*       *        .                .        .        .        .        * 05413020
*       *************************************************************** 05414020
*                                                                       05415020
* LENGTH= 9 BITS .      7 BITS    . 1 BYTE ,3 BYTES ,2 BYTES ,3 BYTES   05416020
 SPACE                                                                  05417020
* ESD NO       USED FOR POINTING TO ESD ITEM                            05418020
* ESD ID       USED TO IDENTIFY CONTROL SECTION                         05419020
* VALUE        ADDRESS RELATIVE TO CONTROL SECTION.                     05420020
* LENGTH       LENGTH ATTRIBUTE OF SYMBOL.MINUS ONE.                    05421020
*                        VALUE AND LENGTH PRESENT ONLY FOR NAME ITEMS   05422020
* CHAIN        POINTER TO PREVIOUS ITEM  WITH GIVEN HASH                05423020
*                        ABSENT FROM FIRST HASH-SYNONYM.                05424020
* ADJECTIVE CODE - BITS.  MASK , MEANING                                05425020
*                   2    X'20'    CHAIN POINTER PRESENT                 05427020
*                   3    X'10'   'ENTRY'ITEM COMPLETED (INTERLUDE)      05428020
*                   4    X'08'   'ENTRY'ITEM COMPLETED (PHASES 7,8)     05429020
*                   5    X'04'    DEFINED IN DSECT,COM OR DXD           05430020
*                  6,7   X'03'   * 00 - CSECT OR START                  05431020
*                                * 01 - EXTRN                           05432020
*                                * 10 - DSECT OR DXD                    05433020
*                                * 11 - NAME ITEM                       05434020
*                                                                       05435020
 EJECT                                                                  05436020
         SPACE 3                                                        05437020
RW1      EQU   GRZ                      WORK REGISTER                   05438020
REVEN    EQU   GRX                      EVEN                            05439020
RODD     EQU   GRY                         ODD REGISTER PAIR FOR SYMBOL 05440020
RW2      EQU   2                        WORK REGISTER                   05441020
RFS      EQU   1                        FREE STORAGE POINTER            05442020
RPT      EQU   RODD                     POINTS TO SYMBOL TABLE ENTRY    05443020
RSTB     EQU   REVEN                    POINTS TO BASE OF SYMBOL TABLE  05444020
*        *     SYMBOLIC DISPLACEMENTS                                   05445020
*                                                                       05446020
FREE     EQU   CFREEP        **DC F' '                                  05447020
EOS      EQU   32                       END OF STRING                   05448020
NAMES    EQU   3                        X=SYMBOL TABLE, Y=ATTRIBUTE FLD 05449020
ILENG    EQU   0                                   X+0                  05450020
LASH     EQU   31                       LENGTH OF LITERAL AND     IEUN1 05451020
*                                       OPSYN HASH TABLES         IEUN1 05452020
ISYM     EQU   1                                   X+1                  05453020
ADJ      EQU   1                                   Y+1                  05454020
IEPTR    EQU   0                                   Y+0                  05455020
IESDID   EQU   2                                  Y+2                   05456020
IVALUE   EQU   3                                  Y+3                   05457020
ILENGT   EQU   6                                  Y+6                   05458020
 EJECT                                                                  05459020
         USING *,SRB                                                    05460020
STGETR   OI    FLAGS,GETSW              SET IN GET MODE                 05461020
         BALR  SRB,0                    SET UP BASE                     05462020
 SPACE                                                                  05463020
         USING *,SRB                                                    05464020
STPUTR   LTR   SP2,SP2                  IF PARAMETER SP2 WAS GIVEN,     05465020
         BP    KNOWN LENGTH SYMBOL.     BRANCH IF LENGTH IS KNOWN       05466020
         CLI   0(SP1),IALPHA            IS FIRST CHAR A SYMBOL          05467020
         BH    GETOUT                   NO, RETURN NOT FOUND            05468020
 SPACE                                                                  05469020
         LR    SP2,SP1                  SP2 = BEGINNING OF SYMBOL       05470020
SCAN     LA    SP2,1(SP2)               SET AT NEXT CHAR                05471020
         CLI   0(SP2),IALPHA            IS THIS CHAR PART OF SYMBOL     05472020
         BNH   SCAN                     YES, LOOP                       05473020
 SPACE                                                                  05474020
         SR    SP2,SP1                  =LENGTH OF SYMBOL OR 256        05475020
KNOWN    LA    1,8                                                      05476020
         CR    1,SP2                    IF SYMBOL IS GREATER THAN 8,    05477020
         BCTR  SP2,0                    REDUCE BY ONE FOR MOVE          05478020
         BC    4,GETOUT                 SET 'NOT FOUND' AND EXIT.       05479020
 SPACE                                                                  05480020
         TM    FLAGS,GETSW              ARE WE IN PUT MODE              05481020
         BC    7,NOXREF                  NO-SKIP OVER XREF ENTRY ROUTIN 05482020
         TM    CTXRFI(ACT),X'02'        YES- IS XREF OPTION BIT ON      05483020
         BC    14,NOXREF                NO- SKIP OVER XREF ROUTINE      05484020
 SPACE                                                                  05485020
         STM   SRB,SP2,SAVESR           SAVE REGISTERS (SRB,SRR,SP1,SP2 05486020
         L     SRB,CTXTIO(ACT)          LOAD XREF BASE                  05487020
         BAL   SRR,PUTXRF(SRB)          GET POINTER TO XREF AREA        05488020
         USING *,SRR                    OUR BASE WAS DESTROYED          05489020
         LM    SRB,SRR,SAVESR           RESTORE BASE (SRB,SRR)          05490020
         DROP  SRR                      AND DROP TEMPERARY BASE         05491020
 SPACE                                                                  05492020
         MVI   1(SP1),IBLANK            PAD NAME PART OF XREF ENTRY     05493020
         MVC   2(6,SP1),1(SP1)           WITH BLANKS                    05494020
         LM    GRX,GRY,SAVESR+8         SET GRX=SP1 AND GRV=SP2         05495020
         EX    GRY,MOVSYM               MOVE SYM NAME INTO XREF ENTRY   05496020
 SPACE                                                                  05497020
         L     GRX,CTRTBP(ACT)          GET ADDRESS OF TRT TABLE        05498020
         TR    0(8,SP1),0(GRX)          TRANSLATE PADDED SYMBOL         05499020
         MVI   8(SP1),X'F0'             SET FLAG BYTE EQUAL ZERO        05500020
         ST    SP1,SAVE3                SAVE PTR IN CASE DUP SYM        05501020
         MVC   9(2,SP1),CTSEQN+2(ACT)   MOVE SEQ NO. INTO XREF ENTRY    05502020
         TM    ADJCOD(ACT),NAMES        IS THIS A NAME ENTRY            05503020
         BC    12,NOTNAME               NO                              05504020
 SPACE                                                                  05505020
         MVC   11(2,SP1),STLONG(ACT)    MOVE STATEMENT LENGTH           05506020
         MVC   13(3,SP1),STVALU+1(ACT)  MOVE SYMBOL VALUE               05507020
         B     LASTBYTE                 SKIP NO ENTRY SEGMENT           05508020
 EJECT                                                                  05509020
NOTNAME  MVC   11(5,SP1),CTZERO(ACT)    SET VALUE & LENGTH = 0          05510020
 SPACE                                                                  05511020
LASTBYTE MVI   16(SP1),0                ZERO LAST BYTE OF XREF ENTRY    05512020
         TM    ADJCOD(ACT),X'03'        IS IT EXTERN OR DSECT           05513020
         BM    RESTRG                   YES, BRANCH                     05514020
         TM    ADJCOD(ACT),X'04'        IS IT DEFINED IN DSECT OF COM   05515020
         BO    RESTRG                   YES, BRANCH                     05516020
         MVC   16(1,SP1),ESDID(ACT)     PUT ESD-ID IN XREF ENTRY        05517020
RESTRG   LM    SP1,SP2,SAVESR+8         RESTORE SP1 AND SP2             05518020
 SPACE                                                                  05519020
NOXREF   SR    RW1,RW1                  CLEAR REGISTER                  05520020
         ST    RW1,BENCH                AND WORKBENCH.                  05521020
         ST    RW1,BENCH+4              CLEAR BENCH.                    05522020
         EX    SP2,MOVE1                SYMBOL TO BOUNDARY.             05523020
         LM    REVEN,RODD,BENCH         LOAD SYMBOL LEFT JUSTIFIED.     05524020
         XR    RODD,REVEN               FOLD SYMBOL INTO FULLWORD.      05525020
         SR    REVEN,REVEN              CLEAR 4 BYTES OF DIVIDEND.      05526020
         D     REVEN,CPRIME(ACT)        PRIME IS HASH DIMENSION.        05527020
         LA    RODD,0(REVEN,REVEN)      MULTIPLY BY                     05528020
         AR    RODD,REVEN               THREE BYTES/POINTER.            05529020
         L     RSTB,CTSYMP(ACT)         FIND SYMBOL TABLE BASE          05530020
         LA    RODD,LASH(RODD,RSTB)     LASH IS LENGTH OF LITERAL HASH. 05531020
         ST    RODD,SAVERS              SAVE HASH TABLE ENTRY           05532020
         ST    RW1,BENCH                CLEAR BENCH                     05533020
 SPACE                                                                  05534020
FOLLOW   MVC   BENCH+1(3),0(RPT)        POINTER TO BOUNDARY             05535020
         L     RPT,BENCH                POINTER TO REGISTER             05536020
         LTR   RPT,RPT                  IF POINTER IS ZERO,NO SYNONYMS. 05537020
         BZ    NOFIND                   (INITIALIZED BEFORE EACH FILL). 05538020
 SPACE                                                                  05539020
         AR    RPT,RSTB                 GET ADDRESS OF ENTRY IN TABLE   05540020
         EX    SP2,ACLI                 IF UNEQUAL LENGTHS, SEE IF AT   05541020
         BNE   BITTER                    END OF THREAD YET              05542020
         EX    SP2,ACLC                 COMPARE SYMBOLS.                05543020
 SPACE                                                                  05544020
BITTER   IC    RW1,ILENG(RPT)           GET LENGTH                      05545020
         LA    RPT,2(RPT,RW1)           POINT TO FIXED LENGTH INFO.     05546020
         BE    DUPCHK                   IF SYMBOLS ARE EQUAL.           05547020
 SPACE                                                                  05548020
         TM    ADJ(RPT),EOS             IS IT END OF STRING             05549020
         BZ    NOFIND                   YES, NOT FOUND                  05550020
 SPACE                                                                  05551020
         TM    ADJ(RPT),NAMES           IS THIS A NAME                  05552020
         LA    RPT,3(RPT)               POINT TO VALUE                  05553020
         BC    12,FOLLOW                NOT NAME                        05554020
         LA    RPT,5(RPT)               POINT TO CHAIN                  05555020
         B     FOLLOW THE THREAD        LOOP                            05556020
 EJECT                                                                  05557020
DUPCHK   TM    FLAGS,GETSW              ARE WE IN GET MODE              05558020
         BC    7,FOUND                  YES, SET FOUND                  05559020
 SPACE                                                                  05560020
         TM    CTXRFI(ACT),X'02'        PUT- IS XREF OPTION BIT ON      05561020
         BC    14,FOUND                 NO- SKIP OVER XREF ROUTINE      05562020
 SPACE                                                                  05563020
         L     SP1,SAVE3                YES                             05564020
         MVI   8(SP1),X'F2'             CHANGE XREF REC. FLAG TO DUP    05565020
         B     FOUND                    SET FOUND                       05566020
 SPACE                                                                  05567020
NOFIND   TM    FLAGS,GETSW                                              05568020
         BC    8,PUTSCH                                                 05569020
 SPACE                                                                  05570020
GETOUT   SR    RPT,RPT                 SET PARAM 'NOT FOUND'.           05571020
FOUND    LR    SP1,RPT                  SET SP1 = VALUE                 05572020
         NI    FLAGS,GETOFF             RESET FLAG                      05573020
         BR    SRR                      RETURN                          05574020
 EJECT                                                                  05575020
PUTSCH   L     RFS,FREE(ACT)            GET FREE STORAGE POINTER.       05576020
         AR    RFS,RSTB                 GET ACTUAL CORE LOCATION        05577020
         STC   SP2,ILENG(RFS)           STORE LENGTH  0-7               05578020
         MVC   1(8,RFS),0(SP1)          MOVE SYMBOLS, EXTRA BYTES       05579020
         LA    RFS,2(RFS,SP2)           OVERLAID WHEN FREE INCREMENTED. 05580020
 SPACE                                                                  05581020
         LH    RW2,CESDNO(ACT)          ESD ITEM POINTER                05582020
         IC    RW1,ADJCOD(ACT)          ADJECTIVE CODE                  05583020
         SLL   RW2,7                                                    05584020
         OR    RW2,RW1                  OVERLAY ADJ CODE                05585020
 SPACE                                                                  05586020
         LA    RW1,EOS                  GET EOS INDICATOR               05587020
         OR    RW2,RW1                  TURN SWITCH ON                  05588020
         LTR   RPT,RPT                  STILL 0 IF NO SYNONYNS.         05589020
         BP    SETADJ                   BRANCH, SYNONYMS                05590020
 SPACE                                                                  05591020
         XR    RW2,RW1                  SET ADJ 'END OF THREAD'.        05592020
SETADJ   ST    RW2,BENCH                ESDITEMPOINTER AND ADJ CODE     05593020
SETADJ1  MVC   IEPTR(2,RFS),BENCH+2     PUT ITEM INTO TABLE      A32954 05594520
         MVC   IESDID(1,RFS),ESDID(ACT) ESD-ID TO TABLE ITEM.           05595020
         TM    ADJCOD(ACT),NAMES        IS IT A NAME                    05596020
         BC    12,SKNAME                NOT NAME, SKIP                  05597020
 SPACE                                                                  05598020
         MVC   IVALUE(3,RFS),STVALU+1(ACT) PRESENT ONLY                 05599020
         MVC   ILENGT(2,RFS),STLONG(ACT) IN NAME ITEMS.                 05600020
         LA    RFS,5(RFS,0)              KICK FREE STORAGE POINTER.     05601020
SKNAME   LA    RFS,3(RFS,0)             SET AT CHAIN                    05602020
         L     RW1,SAVERS               FIND HASH POINTER.              05603020
         MVC   0(3,RFS),0(RW1)           MOVE IT AS ITEM POINTER.       05604020
         LTR   RPT,RPT                  ARE THERE SYNONYMS              05605020
         BZ    MVFREE                   NO                              05606020
 SPACE                                                                  05607020
         LA    RFS,3(RFS)               YES                             05608020
MVFREE   MVC   0(3,RW1),FREE+1(ACT)     MOVE OLD FREE STORAGE TO HASH.  05609020
         SR    RFS,RSTB                 RESET TO A DISPLACEMENT.        05610020
         ST    RFS,FREE(ACT)       UPDATED FREE STORAGE.                05611020
         SR    SP1,SP1                  NO BYTES REQUIRED FOR ROOM      05612020
         BAL   SRB,NOTESD               RESET BASE AND CHECK FOR ROOM   05613020
 EJECT                                                                  05614020
*                STROOM IS CALLED WHEN SYMBOL TABLE SPACE IS            05615020
*              NEEDED.  THE NUMBER OF BYTES REQUIRED IS PUT             05616020
*              IN SP1 BY THE CALLER.  THE EXTERNAL SYMBOL               05617020
*              DICTIONARY OCCUPIES THE HIGH-NUMBERED PORTION            05618020
*              OF SYMBOL TABLE SPACE IF AVAILABLE.  CTESDP              05619020
*              POINTS TO THE BEGINNING OF THE SPACE SO                  05620020
*              OCCUPIED.  IF USE OF THE REQUESTED SPACE WILL            05621020
*              LEAVE INSUFFICIENT SPACE FOR THE LARGEST                 05622020
*              POSSIBLE SYMBOL TABLE ITEM THEN AN ATTEMPT IS            05623020
*              MADE TO MAKE ROOM BY SPELLING ALL BUT THE                05624020
*              LAST SEGMENT OF THE ESD(IF IT IS INCOMPLETE)             05625020
*              AND LEAVING SPACE FOR TWO SEGMENTS (ONE FOR              05626020
*              READING AND UPDATING OLD SEGMENTS,ONE AT                 05627020
*              LEAST FOR INSERTING NEW ITEMS                            05628020
         SPACE 2                                                        05629020
*              ESD SEGMENT RESIDENT TABLE                               05630020
*                   MAXIMUM OF 16 ENTRIES EACH 4 BYTES LONG             05631020
*                   BEGINNING OF TABLE POINTED TO BY CTESRB(ACT)        05632020
*                                                                       05633020
*                   FIRST BYTE          LAST THREE BYTES                05634020
*                   0  SEG NOT USED     NOT USED                        05635020
*                   1  SEG IN  CORE     ADDRESS OF RIGHT HAND OF SEG    05636020
*                   2  SEG ON TAPE      RECORD NO OF SEG (FOR POINT)    05637020
 EJECT                                                                  05638020
* ENTRY POINT FOR ESD AND LITVAL                                        05639020
 SPACE                                                                  05640020
         USING *,SRB                                                    05641020
STROOM   OI    FLAGS,ESDSW              SET ESD SWITCH ON               05642020
         CL    FRB,CBRNDA(ACT)          IF ESD CALLED STROOM            05643020
         BE    STRTOG                   LEAVE ESD ON                    05644020
 SPACE                                                                  05645020
NOTESD   NI    FLAGS,ESDOFF             TURN ESD OFF                    05646020
STRTOG   A     SP1,CTSYMP(ACT)                                          05647020
         A     SP1,CFREEP(ACT)          SET SP1 = LAST OF ST + MAX SYMB 05648020
         AH    SP1,MAXSYM                 + REQUESTED BYTES = NEW POS   05649020
         L     ACC,CESIOB(ACT)          SET ACC TO                      05650020
         SH    ACC,TWOSEG                 ESD TOP                       05651020
         CLR   SP1,ACC                  COMPARE                         05652020
         BNH   STR2R                    BRANCH, ENOUGH ROOM             05653020
 SPACE                                                                  05654020
         TM    FLAGS,ESDSW              IS ESD SWITCH ON                05655020
         BZ    STITER                   NO, SET SYMBOL TABLE FULL       05656020
 SPACE                                                                  05657020
STR2R    CL    SP1,CTESDP(ACT)          COMPARE NEW TO ESD PTR          05658020
         BNH   STNX                     ROOM FOR NEW ESD, RETURN        05659020
 SPACE                                                                  05660020
         TM    FLAGS,ESDSW              IS ESD SWITCH ON                05661020
         BZ    SPILL                    NO, SPILL OVER                  05662020
 SPACE                                                                  05663020
         TM    CTSYMF(ACT),SYMFON       IS SYMBF ON                     05664020
         BC    14,SPILL                   NO - SPILL                    05665020
 SPACE                                                                  05666020
         SH    SP1,MAXSYM               YES - WILL ESD W/O SYMB FIT     05667020
         CL    SP1,CTESDP(ACT)                                          05668020
         BH    SPILL                      NO - SPILL                    05669020
 SPACE                                                                  05670020
STNX     SR    SP1,SP1                  YES                             05671020
         B     4(SRR)                   NORMAL EXIT                     05672020
 SPACE 2                                                                05673020
STITER   OI    CTSYMF(ACT),SYMFON        OTHERWISE SYMB TAB FULL        05674020
         SR    SP1,SP1                                                  05675020
         BR    SRR                      ABNORMAL EXIT                   05676020
         EJECT                                                          05677020
SPILL    L     ESR,CTESRB(ACT)          POINT TO ESD SEG RES TABLE      05678020
         B     SPLP1R                     LOOP                          05679020
 SPACE                                                                  05680020
SPLP1    LA    ESR,4(ESR)               SET FOR NEXT SEGMENT            05681020
SPLP1R   CLI   0(ESR),2                 IS SEGMENT ON TAPE              05682020
         BE    SPLP1                      YES - LOOP                    05683020
 SPACE                                                                  05684020
         STM   SRB,SRR,SAVESR           NO, SAVE SRB,SRR                05685020
         BALR  ACC,0                                                    05686020
         USING *,ACC                    *** NON STANDARD BASE ***       05687020
 SPACE                                                                  05688020
SPLP2    CLI   0(ESR),1                 HAS THIS SEGMENT BEEN USED      05689020
         ST    ACC,SPLINK               SAVE BASE                       05690020
         BNE   LSTSEG                   NO                              05691020
 SPACE                                                                  05692020
         CLI   4(ESR),1                 YES, HAS NEXT SEGMENT BEEN USED 05693020
         BNE   LSTSEG                   NO, BRANCH                      05694020
 SPACE                                                                  05695020
SPLSEG   L     SP1,0(ESR)               YES, SO PREPARE TO WRITE ESD    05696020
         LA    SP1,1(SP1)                                               05697020
         SH    SP1,=H'260'              SET SP1 TO ESD TO WRITE         05698020
         MVI   0(SP1),ESIOID            ESD FILE IDENTIFIER             05699020
         L     SRB,CTXTIO(ACT)          GET I/O BASE                    05700020
         BAL   SRR,CWRESD(SRB)          CALL ESP WRITE                  05701020
 SPACE                                                                  05702020
         DROP  ACC                                                      05703020
         USING *,SRR                    *** NON STANDARD BASE ***       05704020
         L     ACC,SPLINK                                               05705020
         ST    SP1,0(ESR)               UPDATE ESD SEG RES TABLE        05706020
         MVI   0(ESR),2                 SET ESD SEGMENT NOW ON TAPE     05707020
         LA    ESR,4(ESR)               SET ESR FOR NEXT SEGMENT        05708020
         BR    ACC                      LOOP TO SPLP2 OR SEGFIN         05709020
 SPACE                                                                  05710020
         DROP  SRR                                                      05711020
         USING SPLP2,ACC                                                05712020
LSTSEG   L     SRB,SAVESR               RESTORE BASE                    05713020
         DROP  ACC                                                      05714020
 SPACE                                                                  05715020
         USING STROOM,SRB               ***  STANDARD BASE   ***        05716020
         L     GR1,CESIOB(ACT)          GET POSITION OF LAST ESD SEGMNT 05717020
         SH    GR1,=H'260'              SET TO NEW                      05718020
         ST    GR1,CTESDB(ACT)          NEW SEGMENT BASE                05719020
         L     ACC,0(ESR)               IS THIS LAST                    05720020
         LA    ACC,0(ACC)                 SEGMENT FULL                  05721020
         S     ACC,CTESDP(ACT)          POINT TO CURRENT ESD            05722020
         CH    ACC,=H'260'                                              05723020
         BE    SEGFUL                   YES                             05724020
         EJECT                                                          05725020
         SR    GR1,ACC                  NO                              05726020
         L     TEMPR,CTESDP(ACT)        OLD ESD POINTER                 05727020
         ST    GR1,CTESDP(ACT)          NEW ESD POINTER                 05728020
         BCTR  ACC,0                    MACHINE LENGTH                  05729020
         EX    ACC,MVSEG                MOVE SEGMENT                    05730020
         MVC   1(3,ESR),CTESDB+1(ACT)   MOVE IN SEGMENT BASE            05731020
         SR    SP1,SP1                  SET ROOM                        05732020
         L     SRR,SAVESR+4             RESTORE RETURN ADDRESS          05733020
         B     4(SRR)                   NORMAL EXIT                     05734020
 SPACE                                                                  05735020
SEGFUL   L     ACC,SPLINK               SET SPLINK TO SEGFIN            05736020
         MVC   SPLINK,=A(SEGFIN)        FOR LOOP IN BRANCH BEFOR LSTSEG 05737020
         B     SPLSEG                   AND PUT OUT ESD SEGMENT         05738020
 SPACE                                                                  05739020
         USING *,ACC                    *** NON STANDARD BASE ***       05740020
SEGFIN   L     SRR,SAVESR+4             GET RETURN ADDRESS              05741020
         MVC   CTESDP(4,ACT),CTESDB(ACT)  SET CTESDP                    05742020
         SR    SP1,SP1                                                  05743020
         B     4(SRR)                   NORMAL EXIT                     05744020
         DROP   ACC                     DROP NON STANDARD BASE          05745020
         EJECT                                                          05746020
MOVSYM   MVC   0(0,SP1),0(GRX)          EXECUTED                        05747020
ACLI     CLI   ILENG(RPT),0             EXECUTED                        05748020
ACLC     CLC   0(0,SP1),ISYM(RPT)       EXECUTED                        05749020
MVSEG    MVC   1(0,GR1),1(TEMPR)        EXECUTED                        05750020
         USING STPUTR,SRB                                               05751020
MOVE1    MVC   BENCH(0),0(SP1)          EXECUTED                        05752020
 SPACE                                                                  05753020
MAXSYM   DC    H'20'                    MAXIMUM SYMBOL LENGTH           05754020
TWOSEG   DC    H'520'                   LENGTH OF TWO ESD SEGMENTS      05755020
 SPACE                                                                  05756020
SAVESR   DC    4F'0'                    SUBROUTINE REGISTER SAVE AREA   05757020
SAVERS   EQU   SAVESR+8                 SAVE AREA FOR SRR               05758020
SAVE3    DC    F'0'                                                     05759020
SPLINK   EQU   SAVE3                    LOOP CONTROL ADDRESS            05760020
 SPACE                                                                  05761020
BENCH    DC    D'0'                                                     05762020
         LTORG                                                          05763020
FLAGS    DC    X'00'                    FLAG FOR FOLLOWIN INDICATORS    05764020
 SPACE                                                                  05765020
ESDSW    EQU   X'F0'                         ESD                        05766020
ESDOFF   EQU   X'0F'                         MASK OFF ESD               05767020
GETSW    EQU   X'0F'                         GET MODE                   05768020
GETOFF   EQU   X'F0'                         MASK OFF GET MODE          05769020
SYMFON   EQU   X'1'                     SYMBOL TABLE FULL INDICATOR     05770020
ESIOID   EQU   X'03'                    ESD I/O ID                      05771020
ACC      EQU   GRX                      ACCUMULATOR                     05772020
ESR      EQU   GRY                      ESD SEGMENT RESIDENT TABLE PT.  05773020
TEMPR    EQU   GRZ                                                      05774020
         ORG                                                            05775020
         SPACE 2                                                        06160000
*DATA CONTROL BLOCK DSECT.                                              06180000
         SPACE                                                          06200000
         PRINT NOGEN                                                    06220000
         DCBD  DSORG=PS                                                 06240000
         SPACE 3                                                        06260000
         END   RTSEGA                                                   06280000
