 TITLE  'IGC011 - IEA0RT01 TIME SERVICE ROUTINE FOR TOD CLOCK - SVC 11 *00200020
               (MVT - MFT TIME=INTERVAL/JOBSTEP)'                       00400020
IGC011   START 0                                                        00600020
         SPACE 2                                                        00800020
*        ROUTINE NAME -                                                 01000020
*              TIME SVC SERVICE ROUTINE FOR TIME-OF-DAY CLOCK           01200020
         SPACE 2                                                        01400020
*        FUNCTION -                                                     01600020
*              RETURN CURRENT DATE IN REGISTER 1 AND LOCAL TIME         01800020
*              OF DAY IN REGISTER 0 UNLESS THE TIME WAS REQUESTED       02000020
*              IN MICROSECONDS IN WHICH CASE THE VALUE IS STORED        02200020
*              IN THE DESIGNATED DOUBLEWORD.                            02400020
         SPACE 2                                                        02600020
*        ENTRY POINT -                                                  02800020
*              IGC011                                                   03000020
*              IGC011A0                                                 03200020
         SPACE 2                                                        03400020
*        CONTAINED IN MODULE -                                          03600020
*              IEA0RT01                                                 03800020
         SPACE 2                                                        04000020
*        ATTRIBUTES -                                                   04200020
*              TYPE 1 SVC, REENTRANT, DISABLED, RESIDENT, IN            04400020
*              SUPERVISOR STATE AND KEY                                 04600020
         SPACE 2                                                        04800020
*        APPLICABILITY -                                                05000020
*              OPTION 2 AND 4 SYSTEMS (MFT AND MVT)                     05200020
*              ON CPU'S WITH THE TIME-OF-DAY CLOCK                      05400020
         SPACE 2                                                        05600020
*        INPUT -                                                        05800020
*            - REGISTER 0 CONTAINS THE ADDRESS OF A DOUBLEWORD          06000020
*              INTO WHICH THE TIME OF DAY IS STORED IF MIC              06200020
*              WAS SPECIFIED. (TOD IN CLOCK FORMAT-LEFT ADJUSTED)       06400020
*            - REGISTER 1 CONTAINS 0 IF TU  WAS SPECIFIED               06600020
*            - REGISTER 1 CONTAINS 1 IF BIN WAS SPECIFIED               06800020
*            - REGISTER 1 CONTAINS 2 IF DEC WAS SPECIFIED               07000020
*            - REGISTER 1 CONTAINS 3 IF MIC WAS SPECIFIED               07200020
*            - REGISTER 3 CONTAINS THE ADDRESS OF THE CVT               07400020
*            - REGISTER 14 CONTAINS THE RETURN ADDRESS                  07600020
         SPACE 2                                                        07800020
*        OUTPUT -                                                       08000020
*            - REGISTER 0 CONTAINS TIME OF DAY IN REQUESTED FORMAT      08200020
*              IF TU, BIN OR DEC WAS SPECIFIED.                         08400020
*            - REGISTER 0 CONTAINS A 0 IF TIME OF DAY WAS RETURNED      08600020
*              AS A RESULT OF A MIC REQUEST.                            08800020
*            - REGISTER 1 CONTAINS DATE IN PACKED DECIMAL - 00YYDDDF    09000020
*            - ADDRESS SPECIFIED IF TIME REQUESTED IN MIC HAS TIME      09200020
*              OF DAY IN MICROSECONDS IN CLOCK FORMAT - LEFT ADJUSTED.  09400020
*            - REGISTER 15 CONTAINS A 0 IF THE TIME OF DAY WAS          09600020
*              RETURNED AS A RESULT OF A MIC REQUEST. IF THE            09800020
*              ADDRESS SPECIFIED ON A MIC REQUEST WAS INVALID           10000020
*              REGISTER 15 CONTAINS A 4.                                10200020
         SPACE 2                                                        10400020
*            - REGISTER 0 WILL CONTAIN 0 AND REGISTER 1 A HEX 'F'       10600020
*              IF A TIME REQUEST IS MADE PRIOR TO SETTING               10800020
*              THE DATE AND TIME.                                       11000020
         SPACE 2                                                        11200020
*        EXITS -                                                        11400020
*              RETURN ON REGISTER 14                                    11600020
         SPACE 2                                                        11800020
*        TABLES AND CONTROL BLOCKS REFERENCED -                         12000020
*           CVT                                                         12200020
*              CVTTPC  - NOT ALTERED                                    12400020
*              CVTDATE - NOT ALTERED                                    12600020
*              CVT0VL00 - NOT ALTERED                                   12800020
         SPACE 2                                                        13000020
*        EXTERNAL REFERENCES -                                          13200020
*              IEACVTPC - WORK AREA FOR STORE CLOCK AND MNIGHT          13400020
*              IEA0VL00 - VALIDITY CHECK ROUTINE                        13600020
         SPACE 2                                                        13800020
*        NOTES                                                          14000020
*              THE FOLLOWING VALUES ARE USED IN COMPUTING               14200020
*              THE TIME OF DAY                                          14400020
         SPACE 2                                                        14600020
**********************************************************************  14800020
*                                                                       15000020
*                                                                       15200020
*        UNIT                     DEC                 HEX               15400020
*                                                                       15600020
*        ONE TIMER UNIT           26.04166667 MICS    1A.0AAAAB         15800020
*        TIMER UNITS/DAY          3,317,759,575       C5C10000          16000020
*        MICS/DAY                 86,400,000,000      141DD76000        16200020
*        TUS/12 HRS                                   62E08000          16400020
*        MICS/12 HRS              43,200,000,000      A0EEBB000         16600020
*                                                                       16800020
***************      BIT 31 OF TOD CLOCK = 1.048576 SECONDS *********** 17000020
***************      BIT 51 OF TOD CLOCK = 1 MICROSECOND    *********** 17200020
*                                                                       17400020
*********************************************************************** 17600020
         EJECT                                                          17800020
         ENTRY IGC011A0                                                 18000020
         ENTRY IGC011A1                                                 18200020
         EXTRN IEACLOCK                                                 18400020
         EXTRN IEA0TIDT                                                 18600020
IGC011A0 EQU   *                                                        18800020
         EJECT                                                          19000020
         BALR  BASE,R0                  ESTABLISH                       19200020
         USING *,BASE                   ADDRESSABILITY                  19400020
         USING CVTSECT,CVTREG           CVT DSECT                       19600020
         LR    PARAM,R1                 SAVE INPUT PARAMETER            19800020
FINDTIME EQU   *                                                        20000020
         L     CVTPCREG,CVTTPC          GET PTR TO IEACVTPC             20200020
         L     R1,CVTDATE               GET DATE                        20400020
         SPACE 3                                                        20600020
**********************************************************************  20800020
*                                                                       21000020
*        THE FOLLOWING CODE CHECKS IF CVTDATE NEEDS TO BE UPDATED AND   21200020
*        IF NOT, DEVELOPS THE TIME OF DAY IN MICROSECONDS USING         21400020
*        86,400,000,000-(MNIGHT-TODCLOCK)                               21600020
*                                                                       21800020
**********************************************************************  22000020
         SPACE 3                                                        22200020
         L     CLREG,ADDCLOCK           GET ADDR TO STORE CLOCK         22400020
         STCK  ZERO(CLREG)              STORE CONTENTS OF CLOCK         22600020
         BC    3,NOTSET             CLOCK IN ERROR OR NOT SET BH A53465 22650021
         L     MNIGHT,MIDELM(CVTPCREG)  GET ADDRESS OF MIDNIGHT         22800020
*                                       ELEMENT EXTENTION-IC            23000020
         ICM   MNIGHT,ALL,TQEWORK(MNIGHT)   GET EXPECTED MIDNIGHT TOD   23200020
*                                       EXPIRATION                      23400020
         BZ    NOTSET                   BRANCH IF DATE NOT SET          23600020
         SL    MNIGHT,ZERO(CLREG)       GET TIME REMAINING IN DAY       23800020
         BC    6,UPDATE              BRANCH IF RESULT NEG/0    @SA67395 24000021
*                                       INDICATING MIDNIGHT PASSED      24200020
         LM    SECSREG,MICSREG,MICSECS  GET NUMBER OF MICROSECONDS      24400020
*                                       IN ONE DAY                      24600020
         AL    MICSREG,FOUR(CLREG)      ADD MICROSECOND PORTION         24800020
         BC    NOCARRY,CARRY1           BRANCH IF NO CARRY              25000020
         LA    SECSREG,ONE(SECSREG)     ADD BECAUSE OF CARRY            25200020
CARRY1   EQU   *                                                        25400020
         SLR   SECSREG,MNIGHT           SECSREG AND MICSREG HAVE        25600020
*                                       TOD IN MICROS-CLOCK FORMAT      25800020
**********************************************************************  26000020
         EJECT                                                          26200020
         LTR   PARAM,PARAM              Q. TU OPTION SPECIFIED          26400020
         BZ    TUCONV                   YES-BRANCH                      26600020
         CLM   PARAM,ONE,CVTEXIT+ONE    Q. MIC OPTION SPECIFIED         26800020
         BNE   BINCONV                  NO-BRANCH                       27000020
         TM    SVCOPSW+ONE,SUPV         Q. CALLER IN SUP KEY            27200020
         BZ    NOVALCK                  YES-BYPASS VALIDITY CHECK       27400020
         SPACE 3                                                        27600020
**********************************************************************  27800020
*                                                                       28000020
*        THE FOLLOWING ROUTINE IS THE INTERFACE TO THE SYSTEM VALIDITY  28200020
*        CHECK.  INPUT REGISTERS ARE-                                   28400020
*              REGISTER 7 - ADDRESS TO VALIDITY CHECK                   28600020
*              REGISTER 8 - ADDRESS OF VALIDITY CHECK ROUTINE           28800020
*              REGISTER 9 - ADDRESS OF TCB OR ZERO                      29000020
*              REGISTER 10- RETURN REGISTER                             29200020
*                                                                       29400020
**********************************************************************  29600020
         SPACE 3                                                        29800020
         LA    CTR,TWO                  INITIALIZE COUNTER REG          30000020
         LR    R7,R0                    GET ADDRESS TO CHECK            30200020
LOOP     EQU   *                                                        30400020
         L     R8,CVT0VL00              GET ADDRESS OF VALIDITY RTN     30600020
         SR    R9,R9                    ZERO REG 9                      30800020
         BALR  R10,R8                   GO TO VALIDITY CHECK            31000020
*                                       IEACVTPC ADDRESS DESTROYED      31200020
         BNE   INVALID                  BRANCH IF ADDRESS INVALID       31400020
         LR    R7,R0                    SET INPUT REG TO VAL CHECK      31600020
         LA    R7,SEVEN(R7)             TEST END OF ADDRESS             31800020
         BCT   CTR,LOOP                 CHECK BEGINNING AND END ADDR    32000020
NOVALCK  EQU   *                                                        32200020
         LR    ADDREG,R0                GET ADDRESS TO STORE TOD        32400020
         STM   SECSREG,MICSREG,ZERO(ADDREG)  STORE TOD                  32600020
         SR    RETCODE,RETCODE          INDICATE SUCCESSFUL STORE       32800020
*                                       DUE TO MIC REQUEST              33000020
         LR    R0,RETCODE               CLEAR REG FOR MIC REQUEST       33200020
         BR    RETURN                   RETURN TO CALLER                33400020
         SPACE 3                                                        33600020
INVALID  EQU   *                                                        33800020
         LA    RETCODE,FOUR             INDICATE ADDRESS GIVEN ON       34000020
*                                       MIC REQUEST INVALID             34200020
         SR    R0,R0                    CLEAR RETURN REG                34400020
         BR    RETURN                   RETURN TO CALLER                34600020
         EJECT                                                          34800020
**********************************************************************  35000020
*                                                                       35200020
*        THE FOLLOWING CODE IS THE INTERFACE WITH THE CVTDATE UPDATE    35400020
*        ROUTINE WHICH RESIDES IN THE TIMER SLIH. INPUT REGISTERS ARE   35600020
*              REGISTER 1 - MIDNIGHT ELEMENT ADDRESS                    35800020
*              REGISTER 3 - CVT ADDRESS - MVT                           36000020
*              REGISTER 4 - RETURN ADDRESS                              36200020
*              REGISTER 5 - CVT ADDRESS - MFT                           36400020
*              REGISTER 10- ADDRESS OF IEACVTPC                         36600020
*              REGISTER 14- ENTRY POINT ADDRESS                         36800020
*                                                                       37000020
*        REGISTERS 6, 7 AND 8 ARE DESTROYED BY THE ROUTINE              37200020
*                                                                       37400020
**********************************************************************  37600020
         SPACE 3                                                        37800020
UPDATE   EQU   *                                                        38000020
         LA    R1,MIDELM(CVTPCREG)      GET ADDRESS OF MIDNIGHT TQE     38200020
         LR    R13,RETURN               SAVE CALLERS RETURN ADDRESS     38400020
         L     R14,DATERTN              GET ITS ENTRY POINT             38600020
         LR    R5,CVTREG                INITIALIZE REG FOR MFT          38800020
         BALR  R4,RETURN                GO UPDATE CVTDATE               39000020
         LR    RETURN,R13               RESTORE REG                     39200020
         B     FINDTIME                 RETURN TO GET TOD               39400020
         EJECT                                                          39600020
**********************************************************************  39800020
*                                                                       40000020
*        THE FOLLOWING ROUTINE IS ENTERED FOR TU REQUESTS. THE TIME     40200020
*        OF DAY DERIVED BY 86,400,000,000-(MNIGHT-TODCLOCK) IS          40400020
*        CONVERTED TO TIMER UNITS BY DIVIDING BY 26.04167               40600020
*        DECIMAL (1A.0AAAAB HEX)                                        40800020
*                                                                       41000020
**********************************************************************  41200020
         SPACE 3                                                        41400020
TUCONV   EQU   *                                                        41600020
         SR    HALFREG,HALFREG          INDICATE VALUE LESS THAN 12HRS  41800020
         C     SECSREG,HALFDAY          Q. TOD GREATER THAN 12HRS       42000020
         BNH   LESSHALF                 NO-BRANCH                       42200020
         SL    MICSREG,HALFDAY+FOUR     SUBTRACT HALF DAY OF MICS       42400020
         BNM   CARRY2                   BRANCH IF RESULT POSITIVE       42600020
         BCTR  SECSREG,R0               SUBTRACT 1 FROM SECS            42800020
CARRY2   EQU   *                                                        43000020
         SL    SECSREG,HALFDAY          SUBTRACT HALF DAY FROM SECS     43200020
         L     HALFREG,TUHALF           GET HALF DAY IN TIMER UNITS     43400020
LESSHALF EQU   *                                                        43600020
         SLDL  SECSREG,TWELVE           TOD HAS ALREADY BEEN SHIFTED    43800020
*                                       12 BITS DUE TO CLOCK FORMAT.    44000020
*                                       SHIFT ADDITIONAL 12 BITS DUE    44200020
*                                       TO DIVISOR HAVING 6 DIGITS      44400020
*                                       TO RIGHT OF HEXIDECIMAL POINT   44600020
         D     SECSREG,MICPERTU         DIVIDE TOD IN MICROSECONDS BY   44800020
*                                       NUMBER OF MICROSECONDS IN ONE   45000020
*                                       UNIT TO GET NUMBER OF           45200020
*                                       TIMER UNITS                     45400020
         ALR   HALFREG,MICSREG          ADD ANY 12 HOUR FACTOR          45600020
         BR    RETURN                   RETURN TO CALLER                45800020
         EJECT                                                          46000020
**********************************************************************  46200020
*                                                                       46400020
*        THE FOLLOWING ROUTINE IS ENTERED FOR BIN AND DEC REQUESTS.     46600020
*        THE TOD DERIVED BY 86,400,000,000-(MNIGHT-TODCLOCK)            46800020
*        IS DIVIDED BY 10,000 TO CONVERT TO BIN UNITS                   47000020
*                                                                       47200020
**********************************************************************  47400020
         SPACE 3                                                        47600020
BINCONV  EQU   *                                                        47800020
         SRDL  SECSREG,TWELVE           MOVE CLOCK FORMATTED MICROS     48000020
*                                       TO RIGHT ADJUSTED VALUE         48200020
         D     SECSREG,BINARY           DIVIDE BY 10,000 TO GET         48400020
*                                       HUNDRETHS OF A SECOND           48600020
         LR    R0,MICSREG               INITIALIZE OUTPUT REGISTER      48800020
         SRA   PARAM,ONE                Q. BIN REQUEST                  49000020
         BCR   Z,RETURN                 YES-RETURN                      49200020
         EJECT                                                          49400020
**********************************************************************  49600020
*                                                                       49800020
*        THE FOLLOWING ROUTINE CONVERTS THE BINARY VALUE TO             50000020
*        DECIMAL FORMAT HHMMSSTH                                        50200020
*                                                                       50400020
**********************************************************************  50600020
         SPACE 3                                                        50800020
         LA    INDEXREG,THIRTY2         INITIALIZE REG                  51000020
         LA    EXCLSREG,TWELVE          INITIALIZE REG                  51200020
         LA    DIVREG,TEN               START DIVIDE WITH 10            51400020
DIVLOOP  EQU   *                                                        51600020
         SR    REMAIND,REMAIND          CLEAR REMAINDER                 51800020
         DR    REMAIND,DIVREG           DIVIDE BY 10 OR 6               52000020
         LR    EVENREG,REMAIND          GET REMAINDER - NEW DEC DIGIT   52200020
HALF4    EQU   *+2                                                      52400020
         SRDL  EVENREG,FOUR             SHIFT DIGIT INTO REG            52600020
         SH    INDEXREG,HALF4           DECREMENT BY FOUR               52800020
         LTR   DIVIDEND,DIVIDEND        Q. DIVIDEND ZERO                53000020
         BZ    DIVEND                   YES-BRANCH                      53200020
         CLM   INDEXREG,ONE,TWENTY4     Q. IS COUNT = 24 OR 28          53400020
         BNL   DIVLOOP                  YES-BRANCH                      53600020
         XR    DIVREG,EXCLSREG          CHANGE DIVISOR TO 6 OR 10       53800020
         B     DIVLOOP                  LOOP UNTIL DONE                 54000020
DIVEND   EQU   *                                                        54200020
         SRL   ODDREG,ZERO(INDEXREG)    SHIFT APPROPRIATE AMOUNT        54400020
*                                       TO DECIMAL FORMAT               54600020
TWENTY4  EQU   *                        HEX 18 USED FOR COMPARE         54800020
         LR    R0,ODDREG                INITIALIZE OUTPUT REG           55000020
         BR    RETURN                   RETURN TO CALLER                55200020
         SPACE 5                                                        55400020
NOTSET   EQU   *                                                        55600020
         SR    R0,R0                 TIME AND DATE NOT SET     @SA67744 55800021
         LA    R1,FOX                   GET F IN REG IN CASE            56000020
*                                       OF UNPACK                       56200020
         BR    RETURN                   RETURN TO CALLER                56400020
         EJECT                                                          56600020
*********************          CONSTANTS           ***************      56800020
         SPACE 2                                                        57000020
         DS    0F                                                       57200020
BINARY   DC    FL4'10000'               USED TO CONVERT MICS TO BIN     57400020
MICPERTU DC    X'1A0AAAAB'              1A.0AAAAB IS NUMBER OF          57600020
*                                       MICROSECONDS PER TIMER UNIT     57800020
TUHALF   DC    X'62E08000'              NUMBER OF TIMER UNITS           58000020
*                                       IN HALF DAY                     58200020
MICSECS  DC    X'000141DD76000000'      NUMBER OF MICROSECONDS IN       58400020
*                                       ONE DAY - CLOCK FORMAT          58600020
HALFDAY  DC    X'0000A0EEBB000000'      NUMBER OF MICROSECONDS IN       58800020
*                                       HALF DAY IN CLOCK FORMAT        59000020
*                                       (LEFT ADJUSTED)                 59200020
         SPACE 3                                                        59400020
ADDCLOCK DC    AL4(IEACLOCK)            ADDRESS TO STORE CLOCK          59600020
*                                       CLOCK IS NOT REFERENCED VIA     59800020
*                                       DSECT DUE TO ITS REPOSITIONING  60000020
*                                       IN SMF SYSTEMS                  60200020
DATERTN  DC    AL4(IEA0TIDT)            ADDRESS OF CVTDATE UPDATE RTN   60400020
         EJECT                                                          60600020
*********************          REGISTERS           ****************     60800020
         SPACE 2                                                        61000020
R0       EQU   0                        INPUT REG IF MIC REQUEST        61200020
HALFREG  EQU   0                        USED IN TU CONVERSION           61400020
R1       EQU   1                        INPUT REGISTER                  61600020
PARAM    EQU   2                        SAVE REGISTER FOR R1            61800020
CVTREG   EQU   3                        CVT ADDRESS                     62000020
R4       EQU   4                        RETURN REG FROM UPDATE RTN      62200020
SECSREG  EQU   4                        FIRST REG IN PAIR FOR           62400020
*                                       MICROSECONDS IN ONE DAY         62600020
REMAIND  EQU   4                        USED IN DECIMAL CONVERSION      62800020
R5       EQU   5                        INPUT TO UPDATE RTN FOR MFT     63000020
MICSREG  EQU   5                        SECOND REG IN PAIR FOR          63200020
*                                       MICROSECONDS IN ONE DAY         63400020
DIVIDEND EQU   5                        USED IN DECIMAL CONVERSION      63600020
DIVREG   EQU   6                        DIVISOR IN DECIMAL CONVERSION   63800020
INDEXREG EQU   7                        COUNT OF DECIMAL DIGITS         64000020
*                                       TO SHIFT                        64200020
R7       EQU   7                        INPUT TO VALIDITY CHECK RTN     64400020
ADDREG   EQU   7                        ADDR TO STORE TIME IF MICS      64600020
R8       EQU   8                        INPUT TO VALIDITY CHECK RTN     64800020
EVENREG  EQU   8                        SAVE REG IN DECIMAL CONVERSION  65000020
R9       EQU   9                        INPUT TO VALIDITY CHECK RTN     65200020
MNIGHT   EQU   9                        EXPECTED TIME AT MIDNIGHT       65400020
ODDREG   EQU   9                        SAVE REG IN DECIMAL CONVERSION  65600020
R10      EQU   10                       INPUT REG TO VAL CHECK RTN      65800020
CVTPCREG EQU   10                       ADDRESS OF TIMER AREA           66000020
CLREG    EQU   11                       ADDRESS TO STORE TOD CLOCK      66200020
CTR      EQU   12                       LOOP CONTROL FOR VAL CHECK      66400020
EXCLSREG EQU   12                       USED TO CHANGE DIVISOR          66600020
*                                       IN DECIMAL CONVERSION           66800020
R13      EQU   13                       SAVE REG OVER UPDATE RTN        67000020
R14      EQU   14                       INPUT TO UPDATE RTN             67200020
RETURN   EQU   14                       RETURN REGISTER                 67400020
BASE     EQU   15                       BASE REGISTER                   67600020
RETCODE  EQU   15                       RETURN CODE REG FOR MICS        67800020
         SPACE 3                                                        68000020
*        THE FOLLOWING REGISTERS MUST BE EVEN-ODD PAIRS                 68200020
*                                                                       68400020
*        SECSREG             REMAIND             EVENREG                68600020
*        MICSREG             DIVIDEND            ODDREG                 68800020
         EJECT                                                          69000020
*********************          EQUATES             ****************     69200020
         SPACE 2                                                        69400020
ZERO     EQU   0                        NUMERIC ZERO                    69600020
ONE      EQU   1                        NUMERIC ONE                     69800020
TWO      EQU   2                        NUMERIC TWO                     70000020
FOUR     EQU   4                        NUMERIC FOUR                    70200020
SEVEN    EQU   7                        NUMERIC SEVEN                   70400020
Z        EQU   8                        FOR BCR CONDITION 8             70600020
TEN      EQU   10                       NUMERIC TEN                     70800020
TWELVE   EQU   12                       NUMERIC TWELVE                  71000020
NOCARRY  EQU   12                       FOR BC CONDITION 12             71200020
ALL      EQU   15                       USED AS MASK IN CLM             71400020
FOX      EQU   15                       USED IF DATE NOT SET            71600020
TQEWORK  EQU   32                       USED TO FIND MNIGHT             71800020
SVCOPSW  EQU   32                       ADDRESS OF SVC OLD PSW          72000020
THIRTY2  EQU   32                       NUMERIC THIRTY TWO              72200020
MIDELM   EQU   40                       USED TO FIND MNIGHT             72400020
SUPV     EQU   X'F0'                    TEST FOR SUPERVISOR STATE       72600020
IGC011A1 EQU   *                                                        72800020
         EJECT                                                          73000020
CVTSECT  DSECT                                                          73200020
         CVT   SYS=MVT                                                  73400020
         END                                                            73600020
