 TITLE  'IGC011 - IEA0RT02 TIME SERVICE ROUTINE FOR TOD CLOCK - SVC 11 *00200020
               - TIMER=TIME'                                            00400020
IGC011   START 0                                                        00600020
         SPACE 2                                                        00800020
*        ROUTINE NAME -                                                 01000020
*              TIME SVC SERVICE ROUTINE FOR TIME-OF-DAY CLOCK           01200020
         SPACE 2                                                        01400020
*        FUNCTION -                                                     01600020
*              RETURN CURRENT DATE IN REGISTER 1 AND LOCAL TIME         01800020
*              OF DAY IN REGISTER 0 UNLESS THE TIME WAS REQUESTED       02000020
*              IN MICROSECONDS IN WHICH CASE THE VALUE IS STORED        02200020
*              IN THE DESIGNATED DOUBLEWORD.                            02400020
         SPACE 2                                                        02600020
*        ENTRY POINT -                                                  02800020
*              IGC011                                                   03000020
*              IGC011A0                                                 03200020
         SPACE 2                                                        03400020
*        CONTAINED IN MODULE -                                          03600020
*              IEA0RT02                                                 03800020
         SPACE 2                                                        04000020
*        ATTRIBUTES -                                                   04200020
*              TYPE 1 SVC, REENTRANT, DISABLED, RESIDENT, IN            04400020
*              SUPERVISOR STATE AND KEY                                 04600020
         SPACE 2                                                        04800020
*        APPLICABILITY -                                                05000020
*              OPTION 2 SYSTEMS (MFT) ON CPU'S WITH                     05200020
*              THE TIME-OF-DAY CLOCK AND SYSGENED FOR                   05400020
*              TIMER=TIME                                               05600020
         SPACE 2                                                        05800020
*        INPUT -                                                        06000020
*            - REGISTER 0 CONTAINS THE ADDRESS OF A DOUBLEWORD          06200020
*              INTO WHICH THE TIME OF DAY IS STORED IF MIC              06400020
*              WAS SPECIFIED. (TOD IN CLOCK FORMAT-LEFT ADJUSTED)       06600020
*            - REGISTER 1 CONTAINS 0 IF TU  WAS SPECIFIED               06800020
*            - REGISTER 1 CONTAINS 1 IF BIN WAS SPECIFIED               07000020
*            - REGISTER 1 CONTAINS 2 IF DEC WAS SPECIFIED               07200020
*            - REGISTER 1 CONTAINS 3 IF MIC WAS SPECIFIED               07400020
*            - REGISTER 3 CONTAINS THE ADDRESS OF THE CVT               07600020
*            - REGISTER 4 CONTAINS THE TCB ADDRESS (MIC REQUESTS)       07800020
*            - REGISTER 14 CONTAINS THE RETURN ADDRESS                  08000020
         EJECT                                                          08200020
*        OUTPUT -                                                       08400020
*            - REGISTER 0 CONTAINS TIME OF DAY IN REQUESTED FORMAT      08600020
*              IF TU, BIN OR DEC WAS SPECIFIED.                         08800020
*            - REGISTER 0 CONTAINS A 0 IF TIME OF DAY WAS RETURNED      09000020
*              AS A RESULT OF A MIC REQUEST.                            09200020
*            - REGISTER 1 CONTAINS DATE IN PACKED DECIMAL - 00YYDDDF    09400020
*            - ADDRESS SPECIFIED IF TIME REQUESTED IN MIC HAS TIME      09600020
*              OF DAY IN MICROSECONDS IN CLOCK FORMAT - LEFT ADJUSTED.  09800020
*            - REGISTER 15 CONTAINS A 0 IF THE TIME OF DAY WAS          10000020
*              RETURNED AS A RESULT OF A MIC REQUEST. IF THE            10200020
*              ADDRESS SPECIFIED ON A MIC REQUEST WAS INVALID           10400020
*              REGISTER 15 CONTAINS A 4.                                10600020
         SPACE 2                                                        10800020
*            - REGISTER 0 WILL CONTAIN 0 AND REGISTER 1 A HEX 'F'       11000020
*              IF A TIME REQUEST IS MADE PRIOR TO SETTING               11200020
*              THE DATE AND TIME.                                       11400020
         SPACE 2                                                        11600020
*        EXITS -                                                        11800020
*              RETURN ON REGISTER 14                                    12000020
         SPACE 2                                                        12200020
*        TABLES AND CONTROL BLOCKS REFERENCED -                         12400020
*           CVT                                                         12600020
*              CVTTPC  - NOT ALTERED                                    12800020
*              CVTDATE - NOT ALTERED                                    13000020
*              CVT0PL00 - NOT ALTERED                                   13200020
         SPACE 2                                                        13400020
*        EXTERNAL REFERENCES -                                          13600020
*              IEACVTPC - WORK AREA FOR STORE CLOCK AND MNIGHT          13800020
         EJECT                                                          14000020
*        NOTES                                                          14200020
*              THE FOLLOWING VALUES ARE USED IN COMPUTING               14400020
*              THE TIME OF DAY                                          14600020
         SPACE 2                                                        14800020
**********************************************************************  15000020
*                                                                       15200020
*                                                                       15400020
*        UNIT                     DEC                 HEX               15600020
*                                                                       15800020
*        ONE TIMER UNIT           26.04166667 MICS    1A.0AAAAB         16000020
*        TIMER UNITS/DAY          3,317,759,575       C5C10000          16200020
*        MICS/DAY                 86,400,000,000      141DD76000        16400020
*        TUS/12 HRS                                   62E08000          16600020
*        MICS/12 HRS              43,200,000,000      A0EEBB000         16800020
*                                                                       17000020
***************      BIT 31 OF TOD CLOCK = 1.048576 SECONDS *********** 17200020
***************      BIT 51 OF TOD CLOCK = 1 MICROSECOND    *********** 17400020
*                                                                       17600020
*********************************************************************** 17800020
         SPACE 5                                                        18000020
         ENTRY IGC011A0                                                 18200020
         ENTRY IGC011A1                                                 18400020
IGC011A0 EQU   *                                                        18600020
         EJECT                                                          18800020
         BALR  BASE,R0                  ESTABLISH                       19000020
         USING *,BASE                   ADDRESSABILITY                  19200020
         USING CVTSECT,CVTREG           CVT DSECT                       19400020
         USING IEATPC,TPCREG            IEACVTPC DSECT                  19600020
         L     TPCREG,CVTTPC            GET PTR TO IEACVTPC             19800020
         LR    PARAM,R1                 SAVE INPUT PARAMETER            20000020
         L     R1,CVTDATE               GET DATE                        20200020
         SPACE 3                                                        20400020
**********************************************************************  20600020
*                                                                       20800020
*        THE FOLLOWING CODE CHECKS IF CVTDATE NEEDS TO BE UPDATED AND   21000020
*        IF NOT, DEVELOPS THE TIME OF DAY IN MICROSECONDS USING         21200020
*        86,400,000,000-(MNIGHT-TODCLOCK)                               21400020
*                                                                       21600020
**********************************************************************  21800020
         SPACE 3                                                        22000020
         STCK  CLOCK                    STORE CONTENTS OF CLOCK         22200020
         BC    3,NOTSET            CLOCK IN ERROR OR NOT SET  BH A53465 22250021
         ICM   MNREG,ALL,MNIGHT         GET EXPECTED MIDNIGHT VALUE     22400020
         BZ    NOTSET                   BRANCH IF DATE NOT SET          22600020
         SL    MNREG,CLOCK              GET TIME REMAINING IN DAY       22800020
         BC    6,UPDATE              BRANCH IF RESULT NEG/0    @SA67395 23000021
*                                       INDICATING MIDNIGHT PASSED      23200020
MAINLINE EQU   *                                                        23400020
         LM    SECSREG,MICSREG,MICSECS  GET NUMBER OF MICROSECONDS      23600020
*                                       IN ONE DAY                      23800020
         AL    MICSREG,CLOCK+FOUR       ADD MICROSECOND PORTION         24000020
         BC    NOCARRY,CARRY1           BRANCH IF NO CARRY              24200020
         LA    SECSREG,ONE(SECSREG)     ADD 1 FOR CARRY                 24400020
CARRY1   EQU   *                                                        24600020
         SLR   SECSREG,MNREG            SECSREG AND MICSREG HAVE        24800020
*                                       TOD IN MICROS-CLOCK FORMAT      25000020
**********************************************************************  25200020
         EJECT                                                          25400020
         LTR   PARAM,PARAM              Q. TU OPTION SPECIFIED          25600020
         BZ    TUCONV                   YES-BRANCH                      25800020
         CLM   PARAM,ONE,CVTEXIT+ONE    Q. MIC OPTION SPECIFIED         26000020
         BNE   BINCONV                  NO-BRANCH                       26200020
         TM    SVCOPSW+ONE,SUPV         Q. CALLER IN SUP KEY            26400020
         BZ    NOVALCK                  YES-BYPASS VALIDITY CHECK       26600020
         SPACE 3                                                        26800020
**********************************************************************  27000020
*                                                                       27200020
*        THE FOLLOWING ROUTINE IS THE INTERFACE TO THE SYSTEM VALIDITY  27400020
*        CHECK.  INPUT REGISTERS ARE-                                   27600020
*              REGISTER 7 - ADDRESS TO VALIDITY CHECK                   27800020
*              REGISTER 8 - ADDRESS OF VALIDITY CHECK ROUTINE           28000020
*              REGISTER 9 - ADDRESS OF TCB OR ZERO                      28200020
*              REGISTER 10- RETURN REGISTER                             28400020
*                                                                       28600020
**********************************************************************  28800020
         SPACE 3                                                        29000020
         LA    CTR,TWO                  INITIALIZE COUNTER REG          29200020
         LR    R7,R0                    GET ADDRESS TO CHECK            29400020
LOOP     EQU   *                                                        29600020
         L     R8,CVT0VL00              GET ADDRESS OF VALIDITY RTN     29800020
         SR    R9,R9                    ZERO REG 9                      30000020
         BALR  R10,R8                   GO TO VALIDITY CHECK            30200020
*                                       IEACVTPC ADDRESS DESTROYED      30400020
         BNE   INVALID                  BRANCH IF ADDRESS INVALID       30600020
         LR    R7,R0                    SET INPUT REG TO VAL CHECK      30800020
         LA    R7,SEVEN(R7)             TEST END OF ADDRESS             31000020
         BCT   CTR,LOOP                 CHECK BEGINNING AND END ADDR    31200020
NOVALCK  EQU   *                                                        31400020
         LR    ADDREG,R0                GET ADDRESS TO STORE TOD        31600020
         STM   SECSREG,MICSREG,ZERO(ADDREG)  STORE TOD                  31800020
         SR    RETCODE,RETCODE          INDICATE SUCCESSFUL STORE       32000020
*                                       DUE TO MIC REQUEST              32200020
         LR    R0,RETCODE               CLEAR REG FOR MIC REQUEST       32400020
         BR    RETURN                   RETURN TO CALLER                32600020
         SPACE 3                                                        32800020
INVALID  EQU   *                                                        33000020
         LA    RETCODE,FOUR             INDICATE ADDRESS GIVEN ON       33200020
*                                       MIC REQUEST INVALID             33400020
         SR    R0,R0                    CLEAR OUTPUT REG                33600020
         BR    RETURN                   RETURN TO CALLER                33800020
         EJECT                                                          34000020
**********************************************************************  34200020
*                                                                       34400020
*        THE FOLLOWING ROUTINE IS ENTERED WHENEVER THE CVTDATE          34600020
*        DOES NOT AGREE WITH THE DATE BASED ON THE                      34800020
*        TIME-OF-DAY CLOCK.  THE DATE BASED ON THE TOD CLOCK            35000020
*        IS RETURNED TO THE CALLER HOWEVER THE CVTDATE                  35200020
*        FIELD IS NOT UPDATED.                                          35400020
*                                                                       35600020
**********************************************************************  35800020
         SPACE 3                                                        36000020
UPDATE   EQU   *                                                        36200020
         SR    INDREG,INDREG            CLEAR NUMBER OF DAYS COUNT      36400020
         ST    INDREG,TSDBLDAT          INIT FIRST WORD TO ZERO         36600020
         LR    DATEREG,INDREG           INIT REG TO ZERO                36800020
UPDATE1  EQU   *                                                        37000020
         LA    INDREG,ONE(INDREG)       ADD 1 TO NUMBER OF DAYS         37200020
         A     MNREG,MICSECS            ADD MICROSECONDS IN 1 DAY       37400020
         BM    UPDATE1                  BRANCH IF RESULT NEGATIVE       37600020
         ST    R1,TSDBLDAT+FOUR         STORE CURRENT DATE              37800020
         CVB   YRREG,TSDBLDAT           CONVERT DATE TO BINARY          38000020
         D     DATEREG,ONETHOU          SEPERATE YR AND DAYS            38200020
*                                       DATEREG=DAYS, YRREG=YEARS       38400020
         AR    DATEREG,INDREG           ADD NUMBER OF DAYS              38600020
         LA    WKREG,THREE              INITIALIZE REG                  38800020
         LA    FACTOR,THREE66           INITIALIZE MAX DAYS IN YR       39000020
         NR    WKREG,YRREG              Q. LEAP YEAR                    39200020
         BZ    LEAPYR                   YES-BRANCH                      39400020
         BCTR  FACTOR,R0                SET MAX DAYS TO 365             39600020
LEAPYR   EQU   *                                                        39800020
         CR    DATEREG,FACTOR           Q. YEAR HAVE TO CHANGE          40000020
         BNH   YROK                     NO-BRANCH                       40200020
         SR    DATEREG,FACTOR           REDUCE DAY CNT BY DAYS IN YEAR  40400020
         LA    YRREG,ONE(YRREG)         INCREASE YEAR COUNT             40600020
         B     LEAPYR                   CHECK FOR ANOTHER YEAR          40800020
YROK     EQU   *                                                        41000020
         LR    WKREG,DATEREG            SAVE DAY CNT OVER MULTIPLY      41200020
         M     DATEREG,ONETHOU          PUT YEAR BACK TO POSITION       41400020
         AR    YRREG,WKREG              PUT DATE TOGETHER IN BINARY     41600020
         CVD   YRREG,TSDBLDAT           CONVERT DATE TO DECIMAL         41800020
         OI    TSDBLDAT+SEVEN,SIGN      INSURE SIGN BIT                 42000020
         L     R1,TSDBLDAT+FOUR         GET NEW DATE                    42200020
         CL    R1,MAXDATE               Q. MAXIMUM DATE REACHED         42400020
         BNH   MAINLINE                 NO-BRANCH                       42600020
         L     R1,MAXDATE               GET MAXIMUM DATE                42800020
         B     MAINLINE                 REENTER MAINLINE CODE           43000020
         EJECT                                                          43200020
**********************************************************************  43400020
*                                                                       43600020
*        THE FOLLOWING ROUTINE IS ENTERED FOR TU REQUESTS. THE TIME     43800020
*        OF DAY DERIVED BY 86,400,000,000-(MNIGHT-TODCLOCK) IS          44000020
*        CONVERTED TO TIMER UNITS BY DIVIDING BY 26.04167               44200020
*        DECIMAL (1A.0AAAAB HEX)                                        44400020
*                                                                       44600020
**********************************************************************  44800020
         SPACE 3                                                        45000020
TUCONV   EQU   *                                                        45200020
         SR    HALFREG,HALFREG          INDICATE VALUE LESS THAN 12HRS  45400020
         C     SECSREG,HALFDAY          Q. TOD GREATER THAN 12HRS       45600020
         BNH   LESSHALF                 NO-BRANCH                       45800020
         SL    MICSREG,HALFDAY+FOUR     SUBTRACT HALF DAY OF MICS       46000020
         BNM   CARRY2                   BRANCH IF RESULT POSITIVE       46200020
         BCTR  SECSREG,R0               SUBTRACT 1 FROM SECS            46400020
CARRY2   EQU   *                                                        46600020
         SL    SECSREG,HALFDAY          SUBTRACT HALF DAY FROM SECS     46800020
         L     HALFREG,TUHALF           GET HALF DAY IN TIMER UNITS     47000020
LESSHALF EQU   *                                                        47200020
         SLDL  SECSREG,TWELVE           TOD HAS ALREADY BEEN SHIFTED    47400020
*                                       12 BITS DUE TO CLOCK FORMAT.    47600020
*                                       SHIFT ADDITIONAL 12 BITS DUE    47800020
*                                       TO DIVISOR HAVING 6 DIGITS      48000020
*                                       TO RIGHT OF HEXIDECIMAL POINT   48200020
         D     SECSREG,MICPERTU         DIVIDE TOD IN MICROSECONDS BY   48400020
*                                       NUMBER OF MICROSECONDS IN ONE   48600020
*                                       UNIT TO GET NUMBER OF           48800020
*                                       TIMER UNITS                     49000020
         ALR   HALFREG,MICSREG          ADD ANY 12 HOUR FACTOR          49200020
         BR    RETURN                   RETURN TO CALLER                49400020
         EJECT                                                          49600020
**********************************************************************  49800020
*                                                                       50000020
*        THE FOLLOWING ROUTINE IS ENTERED FOR BIN AND DEC REQUESTS.     50200020
*        THE TOD DERIVED BY 86,400,000,000-(MNIGHT-TODCLOCK)            50400020
*        IS DIVIDED BY 10,000 TO CONVERT TO BIN UNITS                   50600020
*                                                                       50800020
**********************************************************************  51000020
         SPACE 3                                                        51200020
BINCONV  EQU   *                                                        51400020
         SRDL  SECSREG,TWELVE           MOVE CLOCK FORMATTED MICROS     51600020
*                                       TO RIGHT ADJUSTED VALUE         51800020
         D     SECSREG,BINARY           DIVIDE BY 10,000 TO GET         52000020
*                                       HUNDRETHS OF A SECOND           52200020
         LR    R0,MICSREG               INITIALIZE OUTPUT REGISTER      52400020
         SRA   PARAM,ONE                Q. BIN REQUEST                  52600020
         BCR   Z,RETURN                 YES-RETURN                      52800020
         EJECT                                                          53000020
**********************************************************************  53200020
*                                                                       53400020
*        THE FOLLOWING ROUTINE CONVERTS THE BINARY VALUE TO             53600020
*        DECIMAL FORMAT HHMMSSTH                                        53800020
*                                                                       54000020
**********************************************************************  54200020
         SPACE 3                                                        54400020
         LA    INDEXREG,THIRTY2         INITIALIZE REG                  54600020
         LA    EXCLSREG,TWELVE          INITIALIZE REG                  54800020
         LA    DIVREG,TEN               START DIVIDE WITH 10            55000020
DIVLOOP  EQU   *                                                        55200020
         SR    REMAIND,REMAIND          CLEAR REMAINDER                 55400020
         DR    REMAIND,DIVREG           DIVIDE BY 10 OR 6               55600020
         LR    EVENREG,REMAIND          GET REMAINDER - NEW DEC DIGIT   55800020
HALF4    EQU   *+2                                                      56000020
         SRDL  EVENREG,FOUR             SHIFT DIGIT INTO REG            56200020
         SH    INDEXREG,HALF4           DECREMENT BY FOUR               56400020
         LTR   DIVIDEND,DIVIDEND        Q. DIVIDEND ZERO                56600020
         BZ    DIVEND                   YES-BRANCH                      56800020
         CLM   INDEXREG,ONE,TWENTY4     Q. IS COUNT = 24 OR 28          57000020
         BNL   DIVLOOP                  YES-BRANCH                      57200020
         XR    DIVREG,EXCLSREG          CHANGE DIVISOR TO 6 OR 10       57400020
         B     DIVLOOP                  LOOP UNTIL DONE                 57600020
DIVEND   EQU   *                                                        57800020
         SRL   ODDREG,ZERO(INDEXREG)    SHIFT APPROPRIATE AMOUNT        58000020
*                                       TO DECIMAL FORMAT               58200020
TWENTY4  EQU   *                        HEX 18 USED FOR COMPARE         58400020
         LR    R0,ODDREG                INITIALIZE OUTPUT REG           58600020
         BR    RETURN                   RETURN TO CALLER                58800020
         SPACE 5                                                        59000020
NOTSET   EQU   *                                                        59200020
         SR    R0,R0                 TIME AND DATE NOT SET     @SA67744 59400021
         LA    R1,FOX                   GET F IN REG IN CASE            59600020
*                                       OF UNPACK                       59800020
         BR    RETURN                   RETURN TO CALLER                60000020
         EJECT                                                          60200020
*********************          CONSTANTS           ***************      60400020
         SPACE 2                                                        60600020
         DS    0F                                                       60800020
ONETHOU  DC    FL4'1000'                USED TO UPDATE DATE             61000020
BINARY   DC    FL4'10000'               USED TO CONVERT MICS TO BIN     61200020
MICPERTU DC    X'1A0AAAAB'              1A.0AAAAB IS NUMBER OF          61400020
*                                       MICROSECONDS PER TIMER UNIT     61600020
TUHALF   DC    X'62E08000'              NUMBER OF TIMER UNITS           61800020
*                                       IN HALF DAY                     62000020
MICSECS  DC    X'000141DD76000000'      NUMBER OF MICROSECONDS IN       62200020
*                                       ONE DAY - CLOCK FORMAT          62400020
HALFDAY  DC    X'0000A0EEBB000000'      NUMBER OF MICROSECONDS IN       62600020
*                                       HALF DAY IN CLOCK FORMAT        62800020
*                                       (LEFT ADJUSTED)                 63000020
MAXDATE  DC    X'0099366F'              MAXIMUM DATE                    63200020
         EJECT                                                          63400020
*********************          REGISTERS           ****************     63600020
         SPACE 2                                                        63800020
R0       EQU   0                        INPUT REG IF MIC REQUEST        64000020
R1       EQU   1                        INPUT REGISTER TO SVC 11        64200020
PARAM    EQU   2                        SAVE REGISTER FOR R1            64400020
CVTREG   EQU   3                        ADDRESS OF CVT                  64600020
SECSREG  EQU   4                        FIRST REG IN PAIR CONTAINING    64800020
*                                       MICROSECONDS IN 1 DAY           65000020
REMAIND  EQU   4                        USED IN DECIMAL CONVERSION      65200020
MICSREG  EQU   5                        SECOND REG IN PAIR CONTAINING   65400020
*                                       MICROSECONDS IN 1 DAY           65600020
DIVIDEND EQU   5                        USED IN DECIMAL CONVERSION      65800020
WKREG    EQU   6                        WORK REGISTER                   66000020
R7       EQU   7                        INPUT REG TO VAL CHECK          66200020
MNREG    EQU   8                        EXPECTED CLOCK VALUE            66400020
*                                       AT MIDNIGHT                     66600020
R8       EQU   8                        ADDR OF VAL CHECK RTN           66800020
EVENREG  EQU   8                        USED IN DECIMAL CONVERSION      67000020
ODDREG   EQU   9                        USED IN DECIMAL CONVERSION      67200020
FACTOR   EQU   9                        USED IN UPDATE RTN              67400020
R9       EQU   9                        INPUT REG TO VAL CHECK          67600020
R10      EQU   10                       RETURN REG FROM VAL CHECK       67800020
TPCREG   EQU   10                       ADDRESS OF TIMER AREA           68000020
HALFREG  EQU   11                       USED IN TU CONVERSION           68200020
INDEXREG EQU   11                       USED IN DECIMAL CONVERSION      68400020
INDREG   EQU   11                       USED IN UPDATE ROUTINE          68600020
CTR      EQU   11                       LOOP CONTROL FOR VAL CHECK      68800020
EXCLSREG EQU   12                       USED TO CHANGE DIVISOR          69000020
*                                       IN DECIMAL CONVERSION           69200020
DATEREG  EQU   12                       USED TO CONVERT DATE            69400020
*                                       IN UPDATE ROUTINE               69600020
ADDREG   EQU   13                       ADDR TO STORE TIME IF MICS      69800020
YRREG    EQU   13                       USED TO CONVERT DATE            70000020
*                                       IN UPDATE ROUTINE               70200020
DIVREG   EQU   13                       DIVISOR IN DECIMAL CONVERSION   70400020
RETURN   EQU   14                       RETURN REGISTER                 70600020
BASE     EQU   15                       BASE REGISTER                   70800020
RETCODE  EQU   15                       RETURN CODE IF MIC REQUEST      71000020
         SPACE 3                                                        71200020
*        THE FOLLOWING REGISTERS MUST BE PAIRED IN EVEN-ODD SEQUENCE    71400020
*                                                                       71600020
*        SECSREG            REMAIND             EVENREG        DATEREG  71800020
*        MICSREG            DIVIDEND            ODDREG         YRREG    72000020
         EJECT                                                          72200020
*********************          EQUATES             ****************     72400020
         SPACE 2                                                        72600020
ZERO     EQU   0                        NUMERIC ZERO                    72800020
ONE      EQU   1                        NUMERIC ONE                     73000020
TWO      EQU   2                        NUMERIC TWO                     73200020
THREE    EQU   3                        NUMERIC THREE                   73400020
FOUR     EQU   4                        NUMERIC FOUR                    73600020
SEVEN    EQU   7                        NUMERIC SEVEN                   73800020
Z        EQU   8                        FOR BCR 8                       74000020
TEN      EQU   10                       NUMERIC TEN                     74200020
TWELVE   EQU   12                       NUMERIC TWELVE                  74400020
NOCARRY  EQU   12                       USED FOR BC 12                  74600020
FOX      EQU   15                       DATE RETURNED IF TIME NOT SET   74800020
ALL      EQU   15                       MASK FOR CLM                    75000020
SVCOPSW  EQU   32                       ADDR OF SVC OLD PSW             75200020
THIRTY2  EQU   32                       NUMERIC THIRTY TWO              75400020
THREE66  EQU   366                      USED TO CHECK IF YEAR PASSED    75600020
SIGN     EQU   X'0F'                    INSURING SIGN IN DATE           75800020
SUPV     EQU   X'F0'                    CHECK FOR SUPERVISOR STATE      76000020
IGC011A1 EQU   *                                                        76200020
         EJECT                                                          76400020
CVTSECT  DSECT                                                          76600020
         CVT   SYS=MFT                                                  76800020
         IEACVTPC  T,,,D,,0,1                                           77000020
         END                                                            77200020
