         TITLE 'TTIMER AND STIMER CODE FOR PRIMARY AND OPT 2 SYSTEMS'   00020000
IGC046   START 0                                                        00040000
*022660,022720                                                          00045019
* A24887                                                                00046019
* A40478                                                                00048020
* STATEMENTS FLAGGED WITH MCH ARE BEING SUBMITTED FOR CODE        19572 00050019
* SUBMITTED FOR MFT ATTACH                                         I250 00055019
*R19 CHANGES: M3432                                                     00056019
*R20 CHANGES- 20272....USE OF THE 'OTHER' PARM ON THE TTIMER      20272 00058020
* MACRO HAS BEEN REMOVED.                                         20272 00058420
*...THIS MODULE CONTAINS CODE FOR TTIMER AND STIMER SVC'S USING OPTION  00060000
*   6B. A FEW ADCONS ARE SHARE BY THE RTNS, AND REGISTER AND OFFSET     00080000
*   SYMBOLISM IS SHARED BETWEEN THE TWO RTNS.                           00100000
         SPACE                                                          00120000
         SPACE                                                          00140000
*...REGISTERS USED BY TTIMER AND STIMER CODE...                         00160000
XDQ      EQU   2        .RETURN REG FROM DEQUEUE RTN.                   00180000
XCVT     EQU   3        .ADDR OF CVT.                                   00200000
XTCB     EQU   4        .ADDR OF CURRENT TCB.                           00220000
XRB      EQU   5        .ADDR OF CURRENT RB.                            00240000
XRETRN   EQU   14       .RETURN ADDR.                                   00260000
         SPACE                                                          00280000
*...OFFSETS USED BY TTIMER AND STIMER CODE...                           00300000
VSHPC    EQU   0        .OFFSET FROM PSEUDO CLOCK PTR OF SHPC           00320000
VT4PC    EQU   4        .OFFSET FROM PSEUDO CLOCK PTR OF T4PC           00340000
VLTPC    EQU   8        .OFFSET FROM PSEUDO CLOCK PTR OF LTPC           00360000
         SPACE                                                          00380000
TQEFLGS  EQU   0        .TIMER ELM FLAGS.                               00400000
TQETCB   EQU   1        .TIMER ELM TCB.                                 00420000
TQEFLNK  EQU   4        .FORWARD LINK ADDR.                             00440000
TQEBLNK  EQU   8        .BACKWARD LINK ADDR.                            00460000
TQEVAL   EQU   12       .INTERVAL VALUE.                                00480000
TQEPSW   EQU   16       .PSW.                                           00500000
TQEEXIT  EQU   28       .ASYNCH. EXIT ADDR.                             00520000
TQEECB   EQU   96       .ECB FOR WAIT.                                  00540000
         SPACE                                                          00560000
*...RB OFFSETS...                                                       00580000
RBSIZE   EQU   8        .RB SIZE.                                       00600000
RBSTAB   EQU   10       .RB STAB.                                       00620000
RBOPSW   EQU   16       .RB OLD PSW.                                    00640000
RBLINK   EQU   28       .RB LINK FIELD.                                 00660000
RBGRSAV  EQU   32       .1ST WORD OF RB REGISTER SAVE AREA (REG 0).     00680000
RBEXTSAV EQU   96       .1ST WORD OF RB EXTEND SAVE AREA.               00700000
         SPACE                                                          00720000
*...MISC EQUATES...                                                     00740000
TIMER    EQU   80       .HARDWARE TIMER.                                00760000
VTCBELM  EQU   120      .TQE ADDR IN TCB.                               00780000
SAVDISP  EQU   X'48'                                               REFR 00790017
         SPACE                                                          00800000
         TITLE 'TTIMER FOR PRIMARY AND OPTION 2 SYSTEMS'                00820000
         SPACE 2                                                        00840000
*...COMMENTARY FOR TTIMER...                                            00860000
         SPACE                                                          00880000
* ROUTINE NAME- IGC046,TTIMER SVC SERVICE ROUTINE.                      00900000
         SPACE                                                          00920000
* FUNCTION-    CALCULATES REMAINING TIME IN TASK'S INTERVAL. ALSO       00940000
*              PROVIDES OPTION TO CANCEL INTERVAL.                      00960000
         SPACE                                                          00980000
* ENTRY POINT NAME- IGC046                                              01000000
         SPACE                                                          01020000
* CONTAINED IN MODULE- IEA0ST00, TTIMER/STIMER SVC ROUTINES.            01040000
         SPACE                                                          01060000
* ATTRIBUTES-  RESIDENT,REENTRANT,SUPERVISOR STATE,I/O AND EXTERNAL     01080000
*              DISABLED,TYPE 1 SVC ROUTINE.                             01100000
         SPACE                                                          01120000
* APPLICABILITY- PRIMARY AND OPTION 2 SYSTEMS EMPLOYING OPTION 6B.      01140000
         SPACE                                                          01160000
* EXTERNAL REFERENCES- IEAQTD00, ENTRY POINT TO TIMER DEQUEUE RTN.      01180000
*                    - TSPECIAL, SPECIAL DEQUEUE ENTRY POINT.           01200000
         SPACE                                                          01220000
* SVC USAGE-   NONE                                                     01240000
         SPACE                                                          01260000
* INPUT-       CANCEL OPTION SPECIFIED BY REG 1 NOT ZERO.               01280000
         SPACE                                                          01300000
* OUTPUT-      REMAINING TIME IN INTERVAL PLACED IN REG 0.              01320000
         SPACE                                                          01340000
* ENTRY POINT- .IGC046. ONLY ENTRY POINT IN CODE-GIVEN CONTROL BY SVC   01360000
*               FLIH.                                                   01380000
*              .THE PSW AT ENTRY MUST BE IN SUPERVISORY MODE & DISABLED 01400000
*              .FOR I/O AND EXTERNAL INTERRUPTS.                        01420000
*              .REG 1 CONTAINS THE CANCEL OPTION INDICATION             01440000
*              .REG 3 CONTAINS THE CVT ADDRESS.                         01460000
*              .REG 4 CONTAINS THE CURRENT TCB ADDRESS.                 01480000
*              .REG 5 CONTAINS THE CURRENT RB ADDRESS.                  01500000
*              .REG 14 CONTAINS THE ADDRESS OF TYPE 1 SVC EXIT.         01520000
*               .REGS 0,2,6-13 CONTAIN THE INFO AT THE POINT OF SVC.    01540000
         SPACE                                                          01560000
* EXIT POINT- .TO TYPE 1 SVC EXIT WHEN RTN IS COMPLETE.                 01580000
*             .THE PSW IS UNCHANGED FROM ENTRY.                         01600000
*             .REG 1 CONTAINS THE REMAINING TIME.                       01620000
*             .REGS   2-9,11,13-15 REMAIN UNCHANGED                     01640000
*             .REGS 0,10,12 CONTAIN MEANINGLESS INFO.                   01660000
         SPACE                                                          01680000
* ERROR EXIT POINTS- NONE                                               01700000
         SPACE                                                          01720000
* TABLES AND CONTROL- .THE TCB OF THE CURRENT TASK TO OBTAIN THE        01740000
*  BLOCKS REFERENCED   TIMER QUEUE ELEMENT ADDRESS.                     01760000
*                     .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDRESS.      01780000
         SPACE                                                          01800000
* LIST ORIGINS,     .NONE                                               01820000
* TABLES, CONTROL                                                       01840000
* BLOCKS INCLUDED                                                       01860000
         SPACE                                                          01880000
* RESTRICTIONS-     .NONE                                               01900000
         SPACE                                                          01920000
* NOTES-            .NONE                                               01940000
         SPACE 3                                                        01960000
*...EQUATES FOR TASK CONTROL BLOCK                                 I250 01966019
TCBTCB   EQU   116                                                 I250 01972019
*...REGISTERS UNIQUE TO IGC046 CODE...                                  01980000
XGT0     EQU   0        .WORK REG.                                      02000000
XPARA    EQU   1        .CONTAINS INPUT PARAM & REMAINING TIME ON EXIT. 02020000
XTPSEUDO EQU   9        .CONTAINS ADDR OF PSEUDO CLOCK.                 02040000
XELE     EQU   10       .CONTAINS ADDRESS OF TIMER QUEUE ELEMENT.       02060000
XGT1     EQU   12       .WORK REG.                                      02080000
XTBASE   EQU   15       .BASE REG.                                      02100000
         SPACE                                                          02120000
*...MISC...                                                             02140000
KEXP     EQU   X'83'    .TO TEST FOR EXPIRED INTERVALS.                 02160000
TTIMSAV  EQU   X'4C'                                               REFR 02170017
         SPACE 2                                                        02180000
CVTSECT DSECT                                                           02200000
         CVT                                                            02220000
         SPACE 2                                                        02240000
IGC046   CSECT                                                          02260000
         ENTRY IGC046A0                                             MCH 02261019
         ENTRY IGC046A1                                             MCH 02262019
IGC046A0 EQU   *                                                    MCH 02263019
         SPACE                                                          02280000
         BALR  XTBASE,0                                                 02300000
         USING *,XTBASE                                                 02320000
         USING CVTSECT,XCVT                                        REFR 02325017
         L     XTPSEUDO,CVTTPC     .ADDRESS OF PSEUDO CLOCKS       REFR 02330017
         ST    XRETRN,TTIMSAV(XTPSEUDO) .SAVE RETURN REG IN TPC    REFR 02335017
         L     XELE,VTCBELM(XTCB) .GET ELM ADDR FROM TCB.               02340000
         LTR   XELE,XELE          .IS THERE AN ELEMENT.                 02360000
         BC    6,TESTEXP          .BR IF YES.                           02380000
TSET0    SR    XGT0,XGT0          .SET REMAINING TIME TO ZERO.          02400000
         B     TEXITX                                                   02420000
         DROP  XCVT                                                     02430017
         SPACE                                                          02440000
TESTEXP  TM    TQEFLGS(XELE),KEXP .HAS INTERVAL EXPIRED.                02460000
         BO    TSET0              .BR IF YES                            02480000
         SPACE                                                          02500000
*...DEVELOP REMAINING TIME IN INTERVAL...                               02520000
*...    = TOX - (SHPC - TIMER)                                          02540000
         USING CVTSECT,XCVT                                             02560000
         L     XTPSEUDO,CVTTPC    .GET ADDR OF PSEUDO CLOCKS.           02580000
         DROP  XCVT                                                     02600000
         L     XGT0,TIMER         .GET TIMER VALUE.                     02620000
         SRA   XGT0,1             .DEV 26 USEC UNITS.                   02640000
         LCR   XGT0,XGT0          . -TIMER                              02660000
         AL    XGT0,VSHPC(XTPSEUDO) .(SHPC-TIMER)                       02680000
         LCR   XGT0,XGT0          . -(SHPC-TIMER)                       02700000
         AL    XGT0,TQEVAL(XELE)  . TOX-(SHPC-TIMER)                    02720000
         BC    3,*+6              .BR IF INTVL NOT PAST DUE.            02740000
         SR    XGT0,XGT0          .SET REMAINING TIME TO ZERO.          02760000
         LTR   XPARA,XPARA        .TEST FOR CANCEL OPTION.              02780000
         BC    8,TEXITX           .BR IF CANCEL NOT SPECIFIED.          02800000
         SPACE                                                          02820000
*...CANCEL INTERVAL...                                                  02840000
         MVI   TQEFLGS(XELE),KEXP .SET TQE 'NOT IN USE'.                02860000
         LR    XPARA,XELE         .SET ELM ADDR IN REG FOR DEQUEUE.     02880000
         L     XDQ,ADQSPCL        .GET SPECIAL ENTRY TO DEQUEUE.        02900000
         ST    XELE,SAVDISP(XTPSEUDO) .SAVE REG 10 IN TPC          REFR 02906017
         LR    XELE,XTPSEUDO       .BASE FOR PSEUDO CLOCKS         REFR 02912017
         L     XTBASE,DQBASE      .SET DQ ADDRESSABILITY.               02920000
         BALR  XDQ,XDQ            .TO DEQUEUE RTN.                      02940000
*...NOTE THAT REG XGT0 AND XRETRN ARE ASSUMED TRANSPARENT OVER DQ RT.   02960000
TEXITX   LR    XPARA,XGT0         .SET REMAINING INTERVAL IN REG 1.     02980000
         L     XRETRN,TTIMSAV(XTPSEUDO) .RESTORE RETURN REG        REFR 02990017
         BR    XRETRN             .EXIT                                 03000000
         DROP  XTBASE                                                   03020000
         TITLE 'STIMER FOR PRIMARY AND OPTION 2 SYSTEM'                 03040000
*...COMMENTARY FOR STIMER...                                            03060000
         SPACE                                                          03080000
* ROUTINE NAME .IGC047- STIMER SVC SERVICE ROUTINE.                     03100000
         SPACE                                                          03120000
* FUNCTION     .INITIALIZES AND ENQUEUE TIMER QUEUE ELEMENT(TQE) FOR    03140000
*               THE PURPOSE OF TIMING REQUESTED INTERVALS.              03160000
*              .PERFORMS CONVERSION TO TU'S WHEN INPUT TIME VALUE IS    03180000
*               IN BIN OR DEC UNITS.                                    03200000
*              .CHECKS WHETHER  TQE IS BEING USED AS IRB FOR PREVIOUSLY 03220000
*               SPECIFIED INTERVAL. IF SO, STIMER REQUEST IS IGNORED.   03240000
*              .CHECKS WHETHER TQE IS CURRENT IN USE. IF SO, EXISTING   03260000
*               INTERVAL IS CANCELLED AND NEW INTERVAL INSTATED.        03280000
         SPACE                                                          03300000
* ENTRY POINT NAME  .IGC047                                             03320000
         SPACE                                                          03340000
* CONTAINED IN MODULE   .IEA0ST00, TTIMER/STIMER SVC ROUTINES.          03360000
         SPACE                                                          03380000
* ATTRIBUTES   .TYPE 2 SVC RTN.,RESIDENT,REENTRANT,SUPERVISOR STATE,    03400000
*               I/O AND EXTERNAL DISABLED.                              03420000
         SPACE                                                          03440000
* APPLICABILITY     .PRIMARY AND OPTION 2 SYSTEMS EMPLOYING OPTION 6B.  03460000
         SPACE                                                          03480000
* EXTERNAL REFERENCES   .IEAQTD00, ENTRY POINT TO TIMER DEQUEUE RTN.    03500000
*                       .TSPECIAL, SPECIAL ENTRY POINT TO TIMER DEQUEUE 03520000
*                        ROUTINE. REGS 3-5 MUST BE TRANSPARENT OVER     03540000
*                        THIS PATH. RETURN IS MADE VIA BR 2.            03560000
         SPACE                                                          03580000
* SVC USEAGE   .WAIT. ECB USED IS CONTAINED IN SVRB EXTENDED SAVE AREA. 03600000
         SPACE                                                          03620000
* INPUT        .REG 0 CONTAINS OPTION FLAGS IN HI ORDER BYTE AND EXIT   03640000
*               ADDR. IN LOW ORDER 3 BYTES.                             03660000
*              .REG 1 CONTAINS THE ADDRESS OF THE TIME VALUE.           03680000
*              .THE LEFT HALF OF THE PSW STORED IN THE SVRB (RBOPSW)    03700000
*               OF THE STIMER CODE.                                     03720000
         SPACE                                                          03740000
* OUTPUT       .AN INITIAIZED AND ENQUEUED TIMER QUEUE ELEMENT. THE     03760000
*               ELEMENT ADDRESS IS IN THE TCB. EXCEPTION- IF A REQUEST  03780000
*               FOR A NEW INTERVAL IS MADE IN AN ASYNCHRONOUS EXIT      03800000
*               ROUTINE, RETURN WILL BE MADE IMMEDIATELY TO THE CALLER  03820000
*               WITH NO CHANGE TO THE TQE OR TIMER QUEUE.               03840000
         SPACE                                                          03860000
* ENTRY POINTS .IGC047, ENTRY FROM SVC FLIH.                            03880000
*              .REG 0 CONTAINS OPTION FLAG AND EXIT ADDRESS.            03900000
*              .REG 1 CONTAINS ADDR OF TIME VALUE.                      03920000
*              .REG 3 CONTAINS CVT ADDR                                 03940000
*              .REG 4 CONTAINS CURRENT TCB ADDR.                        03960000
*              .REG 5 CONTAINS CURRENT RB ADDR.                         03980000
*              .REGS 2,6-13 & 15 REFLECT CONTENTS WHEN SVC ISSUED.      04000000
*              .REG 14 CONTAINS ADDR OF SVC 3 (TYPE 2 EXIT)             04020000
*              .THE PSW IS IN SUPERVISOR STATE AND IS I/O AND EXTERNAL  04040000
*               DISABLED.                                               04060000
         SPACE                                                          04080000
* EXIT POINTS  .TO TYPE 2 EXIT VIA BR 14                                04100000
*              .THE PSW STATUS IS UNCHANGED                             04120000
*              .REG 14 CONTAINS THE EXITING ADDR. OTHER REGS ARE        04140000
*               MEANINGLESS.                                            04160000
         SPACE                                                          04180000
* ERROR EXIT POINTS .NONE                                               04200000
         SPACE                                                          04220000
* TABLES & CONTROL  .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDR AND        04240000
* BLOCKS REFERENCED  TIMER DEQUEUE AN TIMER ENQUEUE RTNS.               04260000
*                   .THE CURRENT TCB TO OBTAIN THE TQE ADDR.            04280000
*                   .THE CURRENT RB TO REFERENCE INPUT REGS 0 & 1 WHICH 04300000
*                    ARE SAVED IN THE RBGRSAV AREA AND THE PSW IN       04320000
*                    EFFECT WHEN THE SVC WAS ISSUED. ALSO, AN EXTENDED  04340000
*                    SAVE AREA APPENDED TO THE SVRB IS USED FOR AN ECB. 04360000
*                    A WORK AREA FOR A PACK INSTRUCTION, AND AS TEMP.   04380000
*                    REGISTER STORAGE OVER THE TIMER DEQUEUE RTN.       04400000
*                   .THE TQE IS REFERENCED AND INITIALIZED FOR THE NEW  04420000
*                    INTERVAL.                                          04440000
         SPACE                                                          04460000
* LIST ORIGINS,TABLES    .A CONVERSION TABLE TMTABLE FOR CONVERTING     04480000
* & CONTROL BLOCKS        DEC DIGITS TO BIN UNITS.                      04500000
* INCLUDED                                                              04520000
         SPACE                                                          04540000
* RESTRICTIONS ON USE    .AN ASYNCHRONOUS EXIT ROUTINE SPECIFIED BY A   04560000
*                         PREVIOUS STIMER MACRO SHOULD NOT ISSUE A      04580000
*                         STIMER MACRO. AN EFFECT NOP WILL OCCUR IF     04600000
*                         STIMER IS ISSUED IN SUCH A ROUTINE.           04620000
         SPACE                                                          04640000
* NOTES        NOTE CVB INSTRUCTION DEPENDS UPON RBEXTSAV+0 TO BE ON A  04660000
*              DOUBLE WORD BOUNDARY.                                    04680000
         SPACE 3                                                        04700000
*...REGISTERS UNIQUE TO STIMER CODE...                                  04720000
XPARA0   EQU   0                                                        04740000
XTIME    EQU   1                                                        04760000
XNQPTR   EQU   1                                                        04780000
XECB     EQU   1                                                        04800000
XTMPTR   EQU   2                                                        04820000
XELM     EQU   2                                                        04840000
XNQ      EQU   2                                                        04860000
XLPCTL   EQU   9                                                        04880000
XPSEUDO  EQU   9                                                        04900000
XGR2     EQU   10                                                       04920000
XINCR    EQU   10                                                       04940000
XCMPR    EQU   XINCR+1                                                  04960000
XPRD     EQU   12                                                       04980000
XCAND    EQU   XPRD+1                                                   05000000
XGR1     EQU   13                                                       05020000
XEXIT    EQU   13                                                       05040000
XBASE    EQU   15                                                       05060000
         SPACE                                                          05080000
*...MASKS FOR TESTING FLAGS...                                          05100000
*   INPUT FLAGS                                                         05120000
DINTVL   EQU   X'30'         .DECIMAL OPTION                            05140000
TOD      EQU   X'40'         .TOD OPTION                                05160000
         SPACE                                                          05180000
*   TQE FLAGS                                                           05200000
EXIT     EQU   X'10'                                                    05220000
OFFQ     EQU   X'80'                                                    05240000
WAIT     EQU   X'06'                                                    05260000
REAL     EQU   X'08'                                                    05280000
TASK     EQU   X'00'                                                    05300000
         SPACE                                                          05320000
*   MISC                                                                05340000
ACTIRB   EQU   X'40'                                                    05360000
         SPACE                                                          05380000
         SPACE                                                          05400000
         ENTRY IGC047                                                   05420000
         EXTRN IEAQTD00,IEAQTD01                                        05440000
         SPACE                                                          05460000
IGC047   DS    0D                                                       05480000
         BALR  XBASE,0                                                  05500000
         USING *,XBASE                                                  05520000
         L     XELM,VTCBELM(XTCB)  R2 = ELM ADDR                  M3432 05530019
         LTR   XELM,XELM           Q. IS THERE AN ELM             M3432 05531019
         BE    TEXIT               NO,EXIT                        M3432 05532019
*...NOTE THAT INPUT PARAMETER REGS 0 & 1 ARE SAVED IN THE SVRB SAVE     05540000
*   AREA AT SVRB+32 & SVRB+36 RESPECTIVELY.                             05560000
         TM    RBGRSAV+0(XRB),DINTVL .TEST FOR DECIMAL OPTION.          05580000
         BC    12,TLDTIME         .BR IF NOT DECIMAL OPTION.            05600000
         SPACE                                                          05620000
*...CONVERT DEC. VALUE TO BIN UNITS...                                  05640000
         LR    XTMPTR,XTIME       .LOAD REG WITH ADDR OF TIME VALUE     05660000
         SR    XLPCTL,XLPCTL      .INITIALIZE CONVERSION LOOP.          05680000
         SR    XTIME,XTIME                                              05700000
         LA    XINCR,4                                                  05720000
         LA    XCMPR,16                                                 05740000
TMDECLP  BXH   XLPCTL,XINCR,TMCNVTU .LOOP 4 TIMES BEFORE BRANCHING.     05760000
         PACK  RBEXTSAV+0(8,XRB),0(2,XTMPTR) .PACK 2 DEC DIGITS.        05780000
         CVB   XCAND,RBEXTSAV+0(XRB) .CONVERT 2 DIGITS TO BINARY UNITS. 05800000
         M     XPRD,TMTABLE-4(XLPCTL) .EXPAND TO BIN UNITS.             05820000
         ALR   XTIME,XCAND        .ACCUM BIN TIME UNITS.                05840000
         LA    XTMPTR,2(XTMPTR)   .REF NEXT TWO DIGITS.                 05860000
         B     TMDECLP                                                  05880000
         SPACE                                                          05900000
*...TUINTVL OR BINTVL OPTIONS...                                        05920000
TLDTIME  L     XTIME,0(XTIME)     .GET TIME VALUE.                      05940000
         BZ    TLOCTST            .BR IF TUINTVL OPTION.                05960000
         SPACE                                                          05980000
*...CONVERT BIN UNITS TO TU'S...                                        06000000
TMCNVTU  CL    XTIME,TBINMAX       CHECK FOR EXCESSIVE BIN VALUE        06020020
         BNH   *+8                                                      06040000
         L     XTIME,TBINMAX      .USE MAX BIN VALUE.                   06060000
         M     XPARA0,TMTUCNV     .CONVERT TO 52 USEC UNITS.            06080000
         D     XPARA0,TM10E7                                            06100000
         ALR   XTIME,XTIME        .DOUBLE TO OBTAIN 26 USEC UNITS.      06120000
*...TU TIME VALUE NOW IN XTIME...                                       06140000
         SPACE                                                          06160000
         SPACE                                                          06220000
*...CONVERT TO ABS INTERVAL BASED ON 6 HR TOD                           06240000
         USING CVTSECT,XCVT                                             06260000
TLOCTST  L     XPSEUDO,CVTTPC      .GET ADDR OF PSEUDO CLOCKS      REFR 06280017
         DROP  XCVT                                                     06300000
         TM    RBGRSAV+0(XRB),TOD  .TEST FOR TOD OPTION            REFR 06306017
         BZ    TCHKMAX            .BR IF NOT TOD OPTION.                06312017
*        ABS INT = NEW TIME-(T4PC+LTPC+SHPC-TIMER)                      06320000
         L     XGR1,TIMER         .GET TIMER VALUE.                     06340000
         SRA   XGR1,1             .DEV 26 USEC UNITS.                   06360000
         LCR   XGR1,XGR1          .-TIMER.                              06380000
         AL    XGR1,VSHPC(XPSEUDO) .SHPC-TIMER.                         06400000
         AL    XGR1,VT4PC(XPSEUDO) .T4PC+SHPC-TIMER.                    06420000
         AL    XGR1,VLTPC(XPSEUDO) .LTPC+T4PC+SHPC-TIMER.               06440000
         L     XGR2,TM24          .SET UP COMPARAND OF 24 HRS.          06460000
         BC    12,*+8             .DID OVERFLOW OCCUR.                  06480000
         B     *+10               .BR IF YES.                           06500000
         CLR   XGR1,XGR2          .IS VALUE LESS THAN 24 HRS.           06520000
         BL    *+6                .BR IF YES.                           06540000
         SLR   XGR1,XGR2          .SUBTRACT 24 HR ADJUSTMENT.           06560000
         SLR   XTIME,XGR1         .NEW LTOD - CURRENT LTOD.             06580000
         BC    3,*+6              .BR IF NO UNDERFLOW OCCURRED.         06600000
         ALR   XTIME,XGR2         .ADD 24 HR ADJUSTMENT.                06620000
         SPACE                                                          06640000
TCHKMAX  CL    XTIME,TMAX         .CHECK FOR MAX VALUE EXCEEDED.        06660000
         BL    *+8                                                      06680000
         L     XTIME,TMAX         .USE MAX VALUE.                       06700000
         SPACE                                                          06720000
*...CHECK CURRENT STATUS OF TIMER ELEMENT...                            06740000
         L     XELM,VTCBELM(XTCB) .GET ELM ADDR FROM TCB.               06760000
         TM    TQEFLGS(XELM),OFFQ .IS TQE OFF Q (NOT IN USE)            06780000
         BO    TIRBTST            .BR IF NOT IN USE TO TEST IF IRB.     06800000
         SPACE                                                          06820000
*...ELM IS IN USE. CANCEL EXISTING INTERVAL.                            06840000
*  .USE SPECIAL ENTRY TO DEQUEUE RTN.                                   06860000
*  .SAVE REGS XTIME,XELM,XBASE,XRB                                      06880000
         STM   15,5,RBEXTSAV(XRB) .SAVE REGS IN SVRB EXT SAVE AREA.     06900000
         LR    XGR2,XRB                .SAVE RB ADDR OVER DQ.           06920000
         LR    1,XELM             .SET ELM ADDR FOR DQ RTN.             06940000
         L     XDQ,ADQSPCL        .GET ADDR. OF SPECIAL ENTRY.          06960000
         ST    XGR2,SAVDISP(XPSEUDO) .SAVE REG 10 IN TPC           REFR 06966017
         LR    XGR2,XPSEUDO        .BASE FOR PSEUDO CLOCKS         REFR 06972017
         L     XBASE,DQBASE       .EST. ADDRESSABILITY FOR DQ RTN.      06980000
         BALR  XDQ,XDQ            .TO DQ RTN TO CANCEL INTERVAL.        07000000
         L     XGR2,SAVDISP(XPSEUDO) .RESTORE REG 10               REFR 07010017
         LM    15,5,RBEXTSAV(XGR2)     .RESTORE REGS.                   07020000
         B     TSTORTCB                                                 07040000
         SPACE                                                          07060000
TIRBTST  TM    TQEFLGS(XELM),EXIT .WAS EXIT SPECIFIED.                  07080000
         BC    12,TSTORTCB        .BR IF NOT.                           07100000
         TM    RBSTAB+1(XELM),ACTIRB .IS ELM AN ACTIVE IRB.             07120000
         BC    1,TEXIT            .BR IF YES TO RETURN. STIMER REQUESTS 07140000
*                                  ARE NOT HONORED FROM TIMER ASYNCH.   07160000
*                                  EXIT RTNS.                           07180000
TSTORTCB EQU   *                                                        07200000
         ST    XTCB,0(XELM)    RESTORE TCB ADDR IN TQE                  07220000
         MVI   TQEFLGS(XELM),TOD  .SET UP MASK FOR ANDING TOD BIT.      07240000
         NC    TQEFLGS(1,XELM),RBGRSAV+0(XRB) .AND TOD BITS.            07260000
         TM    RBGRSAV+0(XRB),X'03' .TEST REQUEST TYPE.                 07280000
         BZ    TFLGTASK                                                 07300000
         BO    TREAL                                                    07320000
*...WAIT TYPE REQUEST...                                                07340000
         OI    TQEFLGS(XELM),OFFQ+WAIT .FLAG ELM AS WAIT TYPE.          07360000
         B     TSET                                                     07380000
         SPACE                                                          07400000
*...REAL TYPE REQUEST...                                                07420000
TREAL    OI    TQEFLGS(XELM),OFFQ+REAL .FLAG ELM AS REAL TYPE.          07440000
         SPACE                                                          07460000
*...TASK TYPE REQUEST...                                                07480000
TFLGTASK OI    TQEFLGS(XELM),OFFQ+TASK .FLAG ELM AS TASK TYPE.          07500000
         SPACE                                                          07520000
*...SET INTERVAL AND EXIT ADDRESS...                                    07540000
TSET     ST    XTIME,TQEVAL(XELM)  .STORE INTERVAL VALUE.               07560000
         L     XEXIT,RBGRSAV+0(XRB) .GET EXIT ADDR.                     07580000
         LA    XEXIT,0(XEXIT)     .ELIMINATE HI ORDER FLAG BYTE.        07600000
         LTR   XEXIT,XEXIT        .IS THERE AN EXIT ADDR SPECIFIED.     07620000
         BZ    TMNQ               .BR IF NOT TO ENQUEUE.                07640000
         ST    XEXIT,TQEEXIT(XELM)  .STORE EXIT IN ELM.                 07660000
         L     XGR2,RBLINK(0,XRB) .GET ADDR OF CALLER'S RB.             07680000
         MVC   TQEPSW(4,XELM),RBOPSW(XGR2)  .SAVE LH OF CALLER'S PSW.   07700000
         OI    TQEFLGS(XELM),EXIT .FLAG ELM AS HAVING EXIT.             07720000
         SR    0,0                .SET R0 TO ZERO                       07740000
         CL    0,100(0,XELM)       Q. SAVE AREA ALREADY EXISTS.         07760000
         BC    4,TMNQ                                                   07780000
         L     0,TMTGM72          .SET INDICATE FOR 72 BYTES HI-CORE    07800000
         LR    1,0                .SET R1 TO INDICATE GETMAIN REQUEST   07820000
         LR    10,15               .SAVE BASE ADDRESS.                  07840000
         SVC   10                  .GET SAVE AREA.                      07860000
         LR    15,10               .RESTORE BASE ADDRESS.               07880000
         ST    1,100(0,XELM)       .STORE SAVE AREA ADDRESS.            07900000
         SPACE                                                          07920000
*...INTERFACE WITH ENQUEUE RTN...                                       07940000
TMNQ     LR    XNQPTR,XELM        .SET ELM ADDR FOR ENQUEUE RTN.        07960000
         LR    XGR2,XELM          .SAVE XELM OVER ENQUEUE.              07980000
         USING CVTSECT,XCVT                                             08000000
         L     XNQ,CVTQTE00       .GET ADDR OF ENQUEUE RTN.             08020000
         DROP  XCVT                                                     08040000
         ST    XGR2,SAVDISP(XPSEUDO) .SAVE REG 10 IN TPC           REFR 08050017
         BALR  XNQ,XNQ            .TO ENQUEUING RTN.                    08060000
         L     XGR2,SAVDISP(XPSEUDO) .RESTORE REG 10               REFR 08070017
         SPACE                                                          08080000
*...IMPLEMENT WAIT IF INDICATED...                                      08100000
         TM    TQEFLGS(XGR2),WAIT .IS WAIT INDICATED.                   08120000
         BC    12,0(XRETRN)       .RETURN IF NOT.                       08140000
         LA    XECB,TQEECB(0,XGR2)     .GET ECB ADDR FOR WAIT.          08160000
         XC    TQEECB(4,XGR2),TQEECB(XGR2)  .ZERO ECB.                  08180000
         WAIT  1,ECB=(1)                                                08200000
         SPACE                                                          08220000
*...RETURN FROM STIMER...                                               08240000
TEXIT    BR    XRETRN                                                   08260000
         SPACE 2                                                        08280000
*...ADDRESSES AND CONSTANTS UNIQUE TO STIMER...                         08300000
         SPACE                                                          08320000
         DS    0F                                                       08340000
TMTUCNV  DC    X'7270E000'    .DECIMAL EQUIV=1,920,000,000.      A24887 08360019
*                                  USED TO DEVELOP 52 USEC UNITS A24887 08370019
*                                  FROM 10 MS (BIN) UNITS.EQUALS A24887 08371019
*                                  100,000 SECONDS/52 TO DEVELOP A24887 08372019
*                                  GREATEST ACCURACY. MUST DIV   A24887 08373019
*                                  BY 10,000,000                 A24887 08374019
TM10E7   DC    X'00989680'        .EQUALS 10,000,000. USED TO DEVELOP   08460000
*                                  52 USEC UNITS.                       08480000
TBINMAX  DC    X'0083D5FF'        .MAX BIN VALUE.                       08500000
TMAX     EQU   *                                                        08520000
TM24     DC    X'C5C10000'         .24 HR TU VALUE               A24887 08540019
TMTABLE  DC    F'360000'          .CONVERSION FACTORS TO DEV BIN UNITS  08560000
         DC    F'6000'             FROM DECIMAL FORMAT.                 08580000
         DC    F'100'                                                   08600000
         DC    F'1'                                                     08620000
TMTGM72  DC    X'FA000048'        .72 BYTES FROM HI-CORE SUBPOOL 250    08640000
ABCODE1  DC    X'80322000'         J/S ABEND CODE                 M4152 08650019
         SPACE                                                          08660000
*...ADCONS SHARED BY TTIMER AND STIMER                                  08680000
ADQSPCL  DC    A(IEAQTD00)        .CANCEL ENTRY TO DEQUEUE RTN.         08700000
DQBASE   DC    A(IEAQTD01+2)      .ADDRESSABILITY FOR DEQUEUE RTN.      08720000
IGC046A1 EQU   *                                                    MCH 08732019
         END                                                            08740000
