  TITLE 'IGC046-TTIMER AND STIMER CODE FOR OPT 2 SYS WITH TODC'         00150020
IGC046   START 0                                                        00200020
*022660,022720                                                          00300020
* A24887                                                                00400020
* STATEMENTS FLAGGED WITH MCH ARE BEING SUBMITTED FOR CODE        19572 00500020
* SUBMITTED FOR MFT ATTACH                                         I250 00600020
*R19 CHANGES: M3432                                                     00700020
*R20 CHANGES- 20272....USE OF THE 'OTHER' PARM ON THE TTIMER      20272 00750020
* MACRO HAS BEEN REMOVED.                                         20272 00760020
*...THIS MODULE CONTAINS CODE FOR TTIMER AND STIMER SVC'S USING OPTION  00800020
*   6B. A FEW ADCONS ARE SHARED BY THE RTNS, AND REGISTER AND OFFSET    00900020
*   SYMBOLISM IS SHARED BETWEEN THE TWO RTNS.                           01000020
         SPACE                                                          01100020
         SPACE                                                          01200020
*...REGISTERS USED BY TTIMER AND STIMER CODE...                         01300020
XDQ      EQU   2        .RETURN REG FROM DEQUEUE RTN.                   01400020
XCVT     EQU   3        .ADDR OF CVT.                                   01500020
XTCB     EQU   4        .ADDR OF CURRENT TCB.                           01600020
XRB      EQU   5        .ADDR OF CURRENT RB.                            01700020
XRETRN   EQU   14       .RETURN ADDR.                                   01800020
RCALC    EQU   13                  REG EQUATE                     20071 01900020
RCALC1   EQU   12                  REG EQUATE                     20071 02000020
X00      EQU   X'00'               TASK FLAG                      20071 02100020
X0F      EQU   X'0F'               CLEAR FLAG                     20071 02200020
S0       EQU   0                   NUMERIC EQUATE                 20071 02300020
S7       EQU   7                   NUMERIC EQUATE                 20071 02400020
S4       EQU   4                   NUMERIC EQUATE                 20071 02500020
S3       EQU   3                   NUMERIC EQUATE                 20071 02600020
S8       EQU   8                   NUMERIC EQUATE                 20071 02700020
         SPACE                                                          02800020
*...OFFSETS USED BY TTIMER AND STIMER CODE...                           02900020
VSHPC    EQU   0        .OFFSET FROM PSEUDO CLOCK PTR OF SHPC           03000020
VT4PC    EQU   4        .OFFSET FROM PSEUDO CLOCK PTR OF T4PC           03100020
VLTPC    EQU   8        .OFFSET FROM PSEUDO CLOCK PTR OF LTPC           03200020
         SPACE                                                          03300020
TQEFLGS  EQU   0        .TIMER ELM FLAGS.                               03400020
TQETCB   EQU   1        .TIMER ELM TCB.                                 03500020
TQEFLNK  EQU   4        .FORWARD LINK ADDR.                             03600020
TQEBLNK  EQU   8        .BACKWARD LINK ADDR.                            03700020
TQEVAL   EQU   12       .INTERVAL VALUE.                                03800020
TQEPSW   EQU   16       .PSW.                                           03900020
TQEEXIT  EQU   28       .ASYNCH. EXIT ADDR.                             04000020
TQEECB   EQU   96       .ECB FOR WAIT.                                  04100020
TQEWORK  EQU   X'20'     EXPCTD VAL OF TODC AT EXP OF INTV        20071 04200020
TQESYNC  EQU   X'24'     BIT ONE IS THE SYNC BIT                  20071 04300020
SYNC     EQU   X'80'     IF ON THIS TQE IS SYNCHRONIZED           20071 04400020
         SPACE                                                          04500020
*...RB OFFSETS...                                                       04600020
RBSIZE   EQU   8        .RB SIZE.                                       04700020
RBSTAB   EQU   10       .RB STAB.                                       04800020
RBOPSW   EQU   16       .RB OLD PSW.                                    04900020
RBLINK   EQU   28       .RB LINK FIELD.                                 05000020
RBGRSAV  EQU   32       .1ST WORD OF RB REGISTER SAVE AREA (REG 0).     05100020
RBEXTSAV EQU   96       .1ST WORD OF RB EXTEND SAVE AREA.               05200020
         SPACE                                                          05300020
*...MISC EQUATES...                                                     05400020
TIMER    EQU   80       .HARDWARE TIMER.                                05500020
VTCBELM  EQU   120      .TQE ADDR IN TCB.                               05600020
SAVDISP  EQU   X'48'                                               REFR 05700020
         SPACE                                                          05800020
  TITLE 'IGC046--TTIMER FOR PRIMARY AND OPTION 2 SYSTEMS'               05950020
         SPACE 2                                                        06000020
*...COMMENTARY FOR TTIMER...                                            06100020
         SPACE                                                          06200020
* ROUTINE NAME- IGC046,TTIMER SVC SERVICE ROUTINE.                      06300020
         SPACE                                                          06400020
* FUNCTION-    CALCULATES REMAINING TIME IN TASK'S INTERVAL. ALSO       06500020
*              PROVIDES OPTION TO CANCEL INTERVAL.                      06600020
         SPACE                                                          06700020
* ENTRY POINT NAME- IGC046                                              06800020
         SPACE                                                          06900020
* CONTAINED IN MODULE- IEA0ST00, TTIMER/STIMER SVC ROUTINES.            07000020
         SPACE                                                          07100020
* ATTRIBUTES-  RESIDENT,REENTRANT,SUPERVISOR STATE,I/O AND EXTERNAL     07200020
*              DISABLED,TYPE 1 SVC ROUTINE.                             07300020
         SPACE                                                          07400020
* APPLICABILITY - PRIMARY AND OPTION 2 SYSTEMS USING OPTION 6B    20071 07500020
*          AND THE TIME OF DAY CLOCK                              20071 07600020
         SPACE                                                          07700020
* EXTERNAL REFERENCES- IEAQTD00, ENTRY POINT TO TIMER DEQUEUE RTN.      07800020
*                    - TSPECIAL, SPECIAL DEQUEUE ENTRY POINT.           07900020
         SPACE                                                          08000020
* SVC USAGE-   NONE                                                     08100020
         SPACE                                                          08200020
* INPUT-       CANCEL OPTION SPECIFIED BY REG 1 NOT ZERO.               08300020
         SPACE                                                          08400020
* OUTPUT-      REMAINING TIME IN INTERVAL PLACED IN REG 0.              08500020
         SPACE                                                          08600020
* ENTRY POINT- .IGC046. ONLY ENTRY POINT IN CODE-GIVEN CONTROL BY SVC   08700020
*               FLIH.                                                   08800020
*              .THE PSW AT ENTRY MUST BE IN SUPERVISORY MODE & DISABLED 08900020
*              .FOR I/O AND EXTERNAL INTERRUPTS.                        09000020
*              .REG 1 CONTAINS THE CANCEL OPTION INDICATION             09100020
*              .REG 3 CONTAINS THE CVT ADDRESS.                         09200020
*              .REG 4 CONTAINS THE CURRENT TCB ADDRESS.                 09300020
*              .REG 5 CONTAINS THE CURRENT RB ADDRESS.                  09400020
*              .REG 14 CONTAINS THE ADDRESS OF TYPE 1 SVC EXIT.         09500020
*               .REGS 0,2,6-13 CONTAIN THE INFO AT THE POINT OF SVC.    09600020
         SPACE                                                          09700020
* EXIT POINT- .TO TYPE 1 SVC EXIT WHEN RTN IS COMPLETE.                 09800020
*             .THE PSW IS UNCHANGED FROM ENTRY.                         09900020
*             .REG 1 CONTAINS THE REMAINING TIME.                       10000020
*             .REGS   2-9,11,13-15 REMAIN UNCHANGED                     10100020
*             .REGS 0,10,12 CONTAIN MEANINGLESS INFO.                   10200020
         SPACE                                                          10300020
* ERROR EXIT POINTS- NONE                                               10400020
         SPACE                                                          10500020
* TABLES AND CONTROL- .THE TCB OF THE CURRENT TASK TO OBTAIN THE        10600020
*  BLOCKS REFERENCED   TIMER QUEUE ELEMENT ADDRESS.                     10700020
*                     .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDRESS.      10800020
         SPACE                                                          10900020
* LIST ORIGINS,     .NONE                                               11000020
* TABLES, CONTROL                                                       11100020
* BLOCKS INCLUDED                                                       11200020
         SPACE                                                          11300020
* RESTRICTIONS-     .NONE                                               11400020
         SPACE                                                          11500020
* NOTES.          THE FIRST WORD OF THE MIDNIGHT TQE              20071 11600020
*                 CONTAINS A POINTER TO X'20' BEFORE              20071 11700020
*                 AN EXTENSION TO THE TQE.  THIS EXTENSION        20071 11800020
*                 CONTAINS TWO WORDS.......                       20071 11900020
*                 THE FIRST IS USED TO CONTAIN THE MNIGHT VALUE   20071 12000020
*                 (THE EXPECTED VALUE OF THE HI-ORDER 32 BITS OF  20071 12100020
*                  THE TOD CLOCK AT THE NEXT MIDNIGHT)            20071 12200020
*                 THE SECOND IS USED TO CONTAIN THE SYNC BIT      20071 12300020
*                 (BIT ZERO OF THE FIRST BYTE)                    20071 12400020
*                 THE EXTRN FOR IEACLOCK IS A REFERENCE TO A      20071 12500020
*                 DOUBLE WORD IN THE PSEUDO CLOCK AREA USED       20071 12600020
*                 TO STORE THE TOD CLOCK VALUE WHEN NEEDED        20071 12700020
         SPACE 3                                                        12800020
*...EQUATES FOR TASK CONTROL BLOCK                                 I250 12900020
TCBTCB   EQU   116                                                 I250 13000020
*...REGISTERS UNIQUE TO IGC046 CODE...                                  13100020
XGT0     EQU   0        .WORK REG.                                      13200020
XPARA    EQU   1        .CONTAINS INPUT PARAM & REMAINING TIME ON EXIT. 13300020
XTPSEUDO EQU   9        .CONTAINS ADDR OF PSEUDO CLOCK.                 13400020
XELE     EQU   10       .CONTAINS ADDRESS OF TIMER QUEUE ELEMENT.       13500020
XGT1     EQU   12       .WORK REG.                                      13600020
XTBASE   EQU   15       .BASE REG.                                      13700020
XRC      EQU   12                  REG EQUATE                     20071 13800020
X0       EQU   0                   REG EQUATE                     20071 13900020
         SPACE                                                          14000020
*...MISC...                                                             14100020
KEXP     EQU   X'83'    .TO TEST FOR EXPIRED INTERVALS.                 14200020
TTIMSAV  EQU   X'4C'                                               REFR 14300020
         SPACE 2                                                        14400020
CVTSECT DSECT                                                           14500020
         CVT                                                            14600020
         EJECT                                                          14700020
IGC046   CSECT                                                          14800020
         SPACE 1                                                        14900020
         EXTRN IEACLOCK                                           20071 15000020
         ENTRY IGC046A0                                             MCH 15100020
         ENTRY IGC046A1                                             MCH 15200020
IGC046A0 EQU   *                                                    MCH 15300020
         SPACE                                                          15400020
         BALR  XTBASE,0                                                 15500020
         USING *,XTBASE                                                 15600020
         USING CVTSECT,XCVT                                        REFR 15700020
         L     XTPSEUDO,CVTTPC     .ADDRESS OF PSEUDO CLOCKS       REFR 17300020
         ST    XRETRN,TTIMSAV(XTPSEUDO) .SAVE RETURN REG IN TPC    REFR 17400020
         ICM   XELE,15,VTCBELM(XTCB)  GET TQE ADRS FROM TCB       20071 17500020
         BC    S7,TESTEXP         BRANCH IF THERE IS A TQE        20071 17600020
TSET0    SR    XGT0,XGT0          .SET REMAINING TIME TO ZERO.          17700020
         B     TEXITX                                                   17800020
         DROP  XCVT                                                     17900020
         SPACE                                                          18000020
TESTEXP  TM    TQEFLGS(XELE),KEXP .HAS INTERVAL EXPIRED.                18100020
         BO    TSET0              .BR IF YES                            18200020
         SPACE                                                          18300020
*...DEVELOP REMAINING TIME IN INTERVAL...                               18400020
*...    = TOX - (SHPC - TIMER)                                          18500020
*...IF THE SYNC BIT IS SET TO ONE THE REMAINING INTERVAL          20071 18600020
*...IS CALCULATED AS FOLLOWS                                      20071 18700020
*...    TQEWORK - TODC                                            20071 18800020
         SPACE                                                          18900020
         USING CVTSECT,XCVT                                             19000020
         L     XTPSEUDO,CVTTPC    .GET ADDR OF PSEUDO CLOCKS.           19100020
         DROP  XCVT                                                     19200020
         TM    TQESYNC(XELE),SYNC      IS SYNC BIT SET            20071 19300020
         BZ    TNORM                   NO - HANDLE AS NORMAL      20071 19400020
         L     XRC,CLOCKAD             GET ADRS OF STCK WORK AREA 20071 19500020
         STCK  S0(XRC)                 GET CURRENT VALUE OF CLOCK 20071 19600020
         L     RCALC,TQEWORK(S0,XELE)  GET TQEWORK VALUE          20071 19700020
         SL    RCALC,X0(XRC)           CALCULATE TO 32 BITS       20071 19800020
*                                      TQEWORK-TODC               20071 19900020
         BC    S4,SYNCOVR              NO CARRY - INTVL PAST DUE  20071 20000020
         M     RCALC1,FOURTYTH         CONVERT TO 26 MS TU        20071 20100020
         LR    XGT0,RCALC              PUT IN CORRECT REG         20071 20200020
         B     TCAN                    GO TEST FOR CANCEL OPTN    20071 20300020
TNORM    L     XGT0,TIMER              GET TIMER VALUE            20071 20400020
         SRA   XGT0,1             .DEV 26 USEC UNITS.                   20500020
         LCR   XGT0,XGT0          . -TIMER                              20600020
         AL    XGT0,VSHPC(XTPSEUDO) .(SHPC-TIMER)                       20700020
         LCR   XGT0,XGT0          . -(SHPC-TIMER)                       20800020
         AL    XGT0,TQEVAL(XELE)  . TOX-(SHPC-TIMER)                    20900020
         BC    3,*+6              .BR IF INTVL NOT PAST DUE.            21000020
SYNCOVR  SR    XGT0,XGT0       .SET REMAINING TIME TO ZERO        20071 21100020
TCAN     LTR   XPARA,XPARA        .TEST FOR CANCEL OPTION.        20071 21200020
         BC    8,TEXITX           .BR IF CANCEL NOT SPECIFIED.          21300020
         SPACE                                                          21400020
*...CANCEL INTERVAL...                                                  21500020
         MVI   TQEFLGS(XELE),KEXP .SET TQE 'NOT IN USE'.                21600020
         LR    XPARA,XELE         .SET ELM ADDR IN REG FOR DEQUEUE.     21700020
         L     XDQ,ADQSPCL        .GET SPECIAL ENTRY TO DEQUEUE.        21800020
         ST    XELE,SAVDISP(XTPSEUDO) .SAVE REG 10 IN TPC          REFR 21900020
         LR    XELE,XTPSEUDO       .BASE FOR PSEUDO CLOCKS         REFR 22000020
         L     XTBASE,DQBASE      .SET DQ ADDRESSABILITY.               22100020
         BALR  XDQ,XDQ            .TO DEQUEUE RTN.                      22200020
*...NOTE THAT REG XGT0 AND XRETRN ARE ASSUMED TRANSPARENT OVER DQ RT.   22300020
TEXITX   LR    XPARA,XGT0         .SET REMAINING INTERVAL IN REG 1.     22400020
         L     XRETRN,TTIMSAV(XTPSEUDO) .RESTORE RETURN REG        REFR 22500020
         BR    XRETRN             .EXIT                                 22600020
         DROP  XTBASE                                                   22700020
SECTU    DC    F'40265'                TU IN 1.04 SEC             20071 22800020
         TITLE 'IGC046--STIMER FOR PRIMARY AND OPTION 2 SYSTEM'         22960020
*...COMENTARY FOR STIMER....                                            22970020
         SPACE                                                          23100020
* ROUTINE NAME .IGC047- STIMER SVC SERVICE ROUTINE.                     23200020
         SPACE                                                          23300020
* FUNCTION     .INITIALIZES AND ENQUEUE TIMER QUEUE ELEMENT(TQE) FOR    23400020
*               THE PURPOSE OF TIMING REQUESTED INTERVALS.              23500020
*              .PERFORMS CONVERSION TO TU'S WHEN INPUT TIME VALUE IS    23600020
*               IN BIN OR DEC UNITS.                                    23700020
*              .CHECKS WHETHER  TQE IS BEING USED AS IRB FOR PREVIOUSLY 23800020
*               SPECIFIED INTERVAL. IF SO, STIMER REQUEST IS IGNORED.   23900020
*              .CHECKS WHETHER TQE IS CURRENT IN USE. IF SO, EXISTING   24000020
*               INTERVAL IS CANCELLED AND NEW INTERVAL INSTATED.        24100020
         SPACE                                                          24200020
* ENTRY POINT NAME  .IGC047                                             24300020
         SPACE                                                          24400020
* CONTAINED IN MODULE   .IEA0ST00, TTIMER/STIMER SVC ROUTINES.          24500020
         SPACE                                                          24600020
* ATTRIBUTES   .TYPE 2 SVC RTN.,RESIDENT,REENTRANT,SUPERVISOR STATE,    24700020
*               I/O AND EXTERNAL DISABLED.                              24800020
         SPACE                                                          24900020
* APPLICABILTIY - PRIMARY AND OPTION 2 SYSTEMS USING OPTION 6B    20071 25000020
*           AND THE TIME OF DAY CLOCK,                            20071 25100020
         SPACE                                                          25200020
* EXTERNAL REFERENCES   .IEAQTD00, ENTRY POINT TO TIMER DEQUEUE RTN.    25300020
*                       .TSPECIAL, SPECIAL ENTRY POINT TO TIMER DEQUEUE 25400020
*                        ROUTINE. REGS 3-5 MUST BE TRANSPARENT OVER     25500020
*                        THIS PATH. RETURN IS MADE VIA BR 2.            25600020
         SPACE                                                          25700020
* SVC USEAGE   .WAIT. ECB USED IS CONTAINED IN SVRB EXTENDED SAVE AREA. 25800020
         SPACE                                                          25900020
* INPUT        .REG 0 CONTAINS OPTION FLAGS IN HI ORDER BYTE AND EXIT   26000020
*               ADDR. IN LOW ORDER 3 BYTES.                             26100020
*              .REG 1 CONTAINS THE ADDRESS OF THE TIME VALUE.           26200020
*              .THE LEFT HALF OF THE PSW STORED IN THE SVRB (RBOPSW)    26300020
*               OF THE STIMER CODE.                                     26400020
         SPACE                                                          26500020
* OUTPUT       .AN INITIAIZED AND ENQUEUED TIMER QUEUE ELEMENT. THE     26600020
*               ELEMENT ADDRESS IS IN THE TCB. EXCEPTION- IF A REQUEST  26700020
*               FOR A NEW INTERVAL IS MADE IN AN ASYNCHRONOUS EXIT      26800020
*               ROUTINE, RETURN WILL BE MADE IMMEDIATELY TO THE CALLER  26900020
*               WITH NO CHANGE TO THE TQE OR TIMER QUEUE.               27000020
         SPACE                                                          27100020
* ENTRY POINTS .IGC047, ENTRY FROM SVC FLIH.                            27200020
*              .REG 0 CONTAINS OPTION FLAG AND EXIT ADDRESS.            27300020
*              .REG 1 CONTAINS ADDR OF TIME VALUE.                      27400020
*              .REG 3 CONTAINS CVT ADDR                                 27500020
*              .REG 4 CONTAINS CURRENT TCB ADDR.                        27600020
*              .REG 5 CONTAINS CURRENT RB ADDR.                         27700020
*              .REGS 2,6-13 & 15 REFLECT CONTENTS WHEN SVC ISSUED.      27800020
*              .REG 14 CONTAINS ADDR OF SVC 3 (TYPE 2 EXIT)             27900020
*              .THE PSW IS IN SUPERVISOR STATE AND IS I/O AND EXTERNAL  28000020
*               DISABLED.                                               28100020
         SPACE                                                          28200020
* EXIT POINTS  .TO TYPE 2 EXIT VIA BR 14                                28300020
*              .THE PSW STATUS IS UNCHANGED                             28400020
*              .REG 14 CONTAINS THE EXITING ADDR. OTHER REGS ARE        28500020
*               MEANINGLESS.                                            28600020
         SPACE                                                          28700020
* ERROR EXIT POINTS .NONE                                               28800020
         SPACE                                                          28900020
* TABLES & CONTROL  .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDR AND        29000020
* BLOCKS REFERENCED  TIMER DEQUEUE AN TIMER ENQUEUE RTNS.               29100020
*                   .THE CURRENT TCB TO OBTAIN THE TQE ADDR.            29200020
*                   .THE CURRENT RB TO REFERENCE INPUT REGS 0 & 1 WHICH 29300020
*                    ARE SAVED IN THE RBGRSAV AREA AND THE PSW IN       29400020
*                    EFFECT WHEN THE SVC WAS ISSUED. ALSO, AN EXTENDED  29500020
*                    SAVE AREA APPENDED TO THE SVRB IS USED FOR AN ECB. 29600020
*                    A WORK AREA FOR A PACK INSTRUCTION, AND AS TEMP.   29700020
*                    REGISTER STORAGE OVER THE TIMER DEQUEUE RTN.       29800020
*                   .THE TQE IS REFERENCED AND INITIALIZED FOR THE NEW  29900020
*                    INTERVAL.                                          30000020
         SPACE                                                          30100020
* LIST ORIGINS,TABLES    .A CONVERSION TABLE TMTABLE FOR CONVERTING     30200020
* & CONTROL BLOCKS        DEC DIGITS TO BIN UNITS.                      30300020
* INCLUDED                                                              30400020
         SPACE                                                          30500020
* RESTRICTIONS ON USE    .AN ASYNCHRONOUS EXIT ROUTINE SPECIFIED BY A   30600020
*                         PREVIOUS STIMER MACRO SHOULD NOT ISSUE A      30700020
*                         STIMER MACRO. AN EFFECT NOP WILL OCCUR IF     30800020
*                         STIMER IS ISSUED IN SUCH A ROUTINE.           30900020
         SPACE                                                          31000020
* NOTES        NOTE CVB INSTRUCTION DEPENDS UPON RBEXTSAV+0 TO BE ON A  31100020
*              DOUBLE WORD BOUNDARY.                                    31200020
*                .THE FIRST WORD OF THE MIDNIGHT TQE              20071 31300020
*                 CONTAINS A POINTER TO X'20' BEFORE              20071 31400020
*                 AN EXTENSION TO THE TQE.  THIS EXTENSION        20071 31500020
*                 CONTAINS TWO WORDS.......                       20071 31600020
*                .THE FIRST IS USED TO CONTAIN THE MNIGHT VALUE   20071 31700020
*                 (THE EXPECTED VALUE OF THE HI-ORDER 32 BITS OF  20071 31800020
*                  THE TOD CLOCK AT THE NEXT MIDNIGHT)            20071 31900020
*                .THE SECOND  IS USED TO CONTAIN THE SYNC BIT     20071 32000020
*                 (BIT ZERO OF THE FIRST BYTE)                    20071 32100020
*                 THE EXTERN FOR IEACLOCK IS A REFERENCE TO A     20071 32200020
*                 DOUBLE WORD IN THE PSEUDO CLOCK AREA USED       20071 32300020
*                 TO STORE THE TOD CLOCK VALUE WHEN NEEDED        20071 32400020
         SPACE 3                                                        32500020
*...REGISTERS UNIQUE TO STIMER CODE...                                  32600020
XPARA0   EQU   0                                                        32700020
XTIME    EQU   1                                                        32800020
XNQPTR   EQU   1                                                        32900020
XECB     EQU   1                                                        33000020
XTMPTR   EQU   2                                                        33100020
XELM     EQU   2                                                        33200020
XNQ      EQU   2                                                        33300020
XLPCTL   EQU   9                                                        33400020
XPSEUDO  EQU   9                                                        33500020
XGR2     EQU   10                                                       33600020
XINCR    EQU   10                                                       33700020
XCMPR    EQU   XINCR+1                                                  33800020
XPRD     EQU   12                                                       33900020
XCAND    EQU   XPRD+1                                                   34000020
XGR1     EQU   13                                                       34100020
XEXIT    EQU   13                                                       34200020
XBASE    EQU   15                                                       34300020
XR8      EQU   8                   REGISTER EQUATE                20071 34400020
REG      EQU   7                   REGISTER EQUATE                20071 34500020
SAV      EQU   6                   REGISTER EQUATE                20071 34600020
REGP1    EQU   REG-1               REGISTER EQUATE                20071 34700020
XTIMEP1  EQU   XTIME-1             REGISTER EQAITE                20071 34800020
XRA      EQU   10                  REGISTER EQUATE                20071 34900020
SAVTIM   EQU   13                  REGISTER EQUATE                20071 35000020
         SPACE                                                          35100020
*...MASKS FOR TESTING FLAGS...                                          35200020
*   INPUT FLAGS                                                         35300020
DINTVL   EQU   X'30'         .DECIMAL OPTION                            35400020
TOD      EQU   X'40'         .TOD OPTION                                35500020
         SPACE                                                          35600020
*   TQE FLAGS                                                           35700020
EXIT     EQU   X'10'                                                    35800020
OFFQ     EQU   X'80'                                                    35900020
WAIT     EQU   X'06'                                                    36000020
REAL     EQU   X'08'                                                    36100020
TASK     EQU   X'00'                                                    36200020
         SPACE                                                          36300020
*   MISC                                                                36400020
ACTIRB   EQU   X'40'                                                    36500020
MNIGHT   EQU   X'20'                                              20071 36600020
MIDELM   EQU   X'28'                                              20071 36700020
         EJECT                                                          36800020
         ENTRY IGC047                                                   36900020
         EXTRN IEAQTD00,IEAQTD01                                        37000020
         SPACE                                                          37100020
IGC047   DS    0D                                                       37200020
         BALR  XBASE,0                                                  37300020
         USING *,XBASE                                                  37400020
         ICM   XELM,15,VTCBELM(XTCB)  R2 = ELM ADR                20071 37500020
         BC    S8,TEXIT           IF NO ELEM  EXIT                20071 37600020
*...NOTE THAT INPUT PARAMETER REGS 0 & 1 ARE SAVED IN THE SVRB SAVE     37700020
*   AREA AT SVRB+32 & SVRB+36 RESPECTIVELY.                             37800020
         TM    RBGRSAV+0(XRB),DINTVL .TEST FOR DECIMAL OPTION.          37900020
         BC    12,TLDTIME         .BR IF NOT DECIMAL OPTION.            38000020
         SPACE                                                          38100020
*...CONVERT DEC. VALUE TO BIN UNITS...                                  38200020
         LR    XTMPTR,XTIME       .LOAD REG WITH ADDR OF TIME VALUE     38300020
         SR    XLPCTL,XLPCTL      .INITIALIZE CONVERSION LOOP.          38400020
         SR    XTIME,XTIME                                              38500020
         LA    XINCR,4                                                  38600020
         LA    XCMPR,16                                                 38700020
TMDECLP  BXH   XLPCTL,XINCR,TMCNVTU .LOOP 4 TIMES BEFORE BRANCHING.     38800020
         PACK  RBEXTSAV+0(8,XRB),0(2,XTMPTR) .PACK 2 DEC DIGITS.        38900020
         CVB   XCAND,RBEXTSAV+0(XRB) .CONVERT 2 DIGITS TO BINARY UNITS. 39000020
         M     XPRD,TMTABLE-4(XLPCTL) .EXPAND TO BIN UNITS.             39100020
         ALR   XTIME,XCAND        .ACCUM BIN TIME UNITS.                39200020
         LA    XTMPTR,2(XTMPTR)   .REF NEXT TWO DIGITS.                 39300020
         B     TMDECLP                                                  39400020
         SPACE                                                          39500020
*...TUINTVL OR BINTVL OPTIONS...                                        39600020
TLDTIME  L     XTIME,0(XTIME)     .GET TIME VALUE.                      39700020
         BZ    TLOCTST            .BR IF TUINTVL OPTION.                39800020
         SPACE                                                          39900020
*...CONVERT BIN UNITS TO TU'S...                                        40000020
TMCNVTU  CL    XTIME,TBINMAX       CHECK FOR EXCESSIVE BIN VALUE        40100020
         BNH   *+8                                                      40200020
         L     XTIME,TBINMAX      .USE MAX BIN VALUE.                   40300020
         M     XPARA0,TMTUCNV     .CONVERT TO 52 USEC UNITS.            40400020
         D     XPARA0,TM10E7                                            40500020
         ALR   XTIME,XTIME        .DOUBLE TO OBTAIN 26 USEC UNITS.      40600020
*...TU TIME VALUE NOW IN XTIME...                                       40700020
         SPACE                                                          40800020
         SPACE                                                          40900020
*...CONVERT TO ABS INTERVAL BASED ON 6 HR TOD                           41000020
         USING CVTSECT,XCVT                                             41100020
TLOCTST  L     XPSEUDO,CVTTPC      .GET ADDR OF PSEUDO CLOCKS      REFR 41200020
         DROP  XCVT                                                     41300020
         TM    RBGRSAV+0(XRB),TOD  .TEST FOR TOD OPTION            REFR 41400020
         BZ    TCHKMAX            .BR IF NOT TOD OPTION.                41500020
*  HAVE TU REQUESTED IN REG 1                                     20071 41600020
*  TO GET AN ABSOLUTE INTERVAL MUST CALCULATE                     20071 41700020
*  TAM - TOD                                                      20071 41800020
*  TAM = REQUESTED TU PAST LAST MIDNIGHT                          20071 41900020
*  TOD = ACTUAL TU ALREADY EXPIRED SINCE LAST MIDNIGHT            20071 42000020
         SPACE 2                                                        42100020
         L     XR8,CLOCKAD             GET ADRS OF STCK WORK AREA 20071 42200020
*        THE FIRST WORD OF THE MIDNIGHT ELEMENT POINTS TO         20071 42300020
*        X'20' BEFORE AN EXTENSION WHICH CONTAINS THE SYNC        20071 42400020
*        BIT AND THE MNIGHT FIELD.                                20071 42500020
         L     XRA,MIDELM(XPSEUDO)     GET ADRS TO DUMMY ELEM     20071 42600020
         STCK  0(XR8)                  GET CURENT VALUE OF CLOCK  20071 42700020
         L     REG,MNIGHT(XRA)         GET MNIGHT VALUE           20071 42800020
         LR    SAV,REG                 SAVE VALUE                 20071 42900020
REDO     SL    REG,X0(XR8)             CALC MNIGHT-TODC           20071 43000020
         BC    S3,TOK                  IF CARRY, OK - BRANCH      20071 43100020
         AL    SAV,TWNT4HRS            RESULT NEG - ADD 1 DAY     20071 43200020
*                                      TO MNIGHT VAL              20071 43300020
         LR    REG,SAV                 *                          20071 43400020
         B     REDO                    DO CALC AGAIN              20071 43500020
TOK      LCR   REG,REG                 -(MNIGHT-CLOCK)            20071 43600020
         A     REG,TWNT4HRS            82397-(MNIGHT-CLOCK)       20071 43700020
         M     REGP1,FOURTYTH        (82397-(MNIGHT-CLOCK))*40000 20071 43800020
*  NOW HAVE TOD VALUE IN REG                                      20071 43900020
         SLR   XTIME,REG               TAM-TOD                    20071 44000020
         BC    S3,TOK2                 IF CARRY  OK  BRANCH       20071 44100020
         AL    XTIME,TM24         ADD 24 HRS TO GET CORRECT INTV  20071 44200020
TOK2     EQU   *                                                  20071 44300020
         SPACE                                                          44400020
TCHKMAX  CL    XTIME,TMAX         .CHECK FOR MAX VALUE EXCEEDED.        44500020
         BL    *+8                                                      44600020
         L     XTIME,TMAX         .USE MAX VALUE.                       44700020
         SPACE                                                          44800020
*...CHECK CURRENT STATUS OF TIMER ELEMENT...                            44900020
         L     XELM,VTCBELM(XTCB) .GET ELM ADDR FROM TCB.               45000020
         TM    TQEFLGS(XELM),OFFQ .IS TQE OFF Q (NOT IN USE)            45100020
         BO    TIRBTST            .BR IF NOT IN USE TO TEST IF IRB.     45200020
         SPACE                                                          45300020
*...ELM IS IN USE. CANCEL EXISTING INTERVAL.                            45400020
*  .USE SPECIAL ENTRY TO DEQUEUE RTN.                                   45500020
*  .SAVE REGS XTIME,XELM,XBASE,XRB                                      45600020
         STM   15,5,RBEXTSAV(XRB) .SAVE REGS IN SVRB EXT SAVE AREA.     45700020
         LR    XGR2,XRB                .SAVE RB ADDR OVER DQ.           45800020
         LR    1,XELM             .SET ELM ADDR FOR DQ RTN.             45900020
         L     XDQ,ADQSPCL        .GET ADDR. OF SPECIAL ENTRY.          46000020
         ST    XGR2,SAVDISP(XPSEUDO) .SAVE REG 10 IN TPC           REFR 46100020
         LR    XGR2,XPSEUDO        .BASE FOR PSEUDO CLOCKS         REFR 46200020
         L     XBASE,DQBASE       .EST. ADDRESSABILITY FOR DQ RTN.      46300020
         BALR  XDQ,XDQ            .TO DQ RTN TO CANCEL INTERVAL.        46400020
         L     XGR2,SAVDISP(XPSEUDO) .RESTORE REG 10               REFR 46500020
         LM    15,5,RBEXTSAV(XGR2)     .RESTORE REGS.                   46600020
         B     TSTORTCB                                                 46700020
         SPACE                                                          46800020
TIRBTST  TM    TQEFLGS(XELM),EXIT .WAS EXIT SPECIFIED.                  46900020
         BC    12,TSTORTCB        .BR IF NOT.                           47000020
         TM    RBSTAB+1(XELM),ACTIRB .IS ELM AN ACTIVE IRB.             47100020
         BC    1,TEXIT            .BR IF YES TO RETURN. STIMER REQUESTS 47200020
*                                  ARE NOT HONORED FROM TIMER ASYNCH.   47300020
*                                  EXIT RTNS.                           47400020
TSTORTCB EQU   *                                                        47500020
         ST    XTCB,0(XELM)    RESTORE TCB ADDR IN TQE                  47600020
         MVI   TQEFLGS(XELM),TOD  .SET UP MASK FOR ANDING TOD BIT.      47700020
         NC    TQEFLGS(1,XELM),RBGRSAV+0(XRB) .AND TOD BITS.            47800020
         TM    RBGRSAV+0(XRB),X'03' .TEST REQUEST TYPE.                 47900020
         BZ    TFLGTASK                                                 48000020
         BO    TREAL                                                    48100020
*...WAIT TYPE REQUEST...                                                48200020
         OI    TQEFLGS(XELM),OFFQ+WAIT .FLAG ELM AS WAIT TYPE.          48300020
         B     TSET                                                     48400020
         SPACE                                                          48500020
*...REAL TYPE REQUEST...                                                48600020
TREAL    OI    TQEFLGS(XELM),OFFQ+REAL .FLAG ELM AS REAL TYPE.          48700020
         SPACE                                                          48800020
*...TASK TYPE REQUEST...                                                48900020
TFLGTASK OI    TQEFLGS(XELM),OFFQ+TASK .FLAG ELM AS TASK TYPE.          49000020
         SPACE                                                          49100020
*...SET INTERVAL AND EXIT ADDRESS...                                    49200020
TSET     NI    TQESYNC(XELM),X00       CLEAR HI BYTE              20071 49300020
         LR    SAVTIM,XTIME       SAVE INTVL REQUESTED            20071 49400020
         TM    TQEFLGS(XELM),X0F       IS THIS A 'TASK' REQST     20071 49500020
         BZ    NOSYNC                  YES - CAN NOT BE SYNC'ED   20071 49600020
         L     XR8,CLOCKAD          GET CLCOK WRKAREA ADRS        20071 49700020
         STCK  0(XR8)                  GET CURRENT VALUE OF CLOCK 20071 49800020
         SR    XTIMEP1,XTIMEP1         ZERO FOR DIV               20071 49900020
         D     XTIMEP1,FOURTYTH      GET INTRVL IN 1.04 SEC UNITS 20071 50000020
         AL    XTIME,X0(XR8)            ADD AND STORE AS          20071 50100020
         ST    XTIME,TQEWORK(S0,XELM)  TQEWORK                    20071 50200020
         CL    SAVTIM,ONEHR       IS INTRVL GT ONE HOUR           20071 50300020
         BNH   NOSYNC              NO  DO NOT SYNC THE TQE        20071 50400020
         L     SAVTIM,ONEHR        SET INTVL TO ONE HOUR          20071 50500020
         OI    TQESYNC(XELM),SYNC    TURN ON SYNC BIT             20071 50600020
NOSYNC   EQU   *                                                  20071 50700020
         ST    SAVTIM,TQEVAL(S0,XELM) SET INTVL TIME IN TQE       20071 50800020
         SR    XEXIT,XEXIT             ZERO FOR EXIT ADRS         20071 50900020
         ICM   XEXIT,7,RBGRSAV+1(XRB)  GET EXIT ADRS              20071 51000020
         BZ    TMNQ                    BRANCH IF ZERO             20071 51100020
         ST    XEXIT,TQEEXIT(XELM)     STORE IN TQE               20071 51200020
         L     XGR2,RBLINK(0,XRB) .GET ADDR OF CALLER'S RB.             51300020
         MVC   TQEPSW(4,XELM),RBOPSW(XGR2)  .SAVE LH OF CALLER'S PSW.   51400020
         OI    TQEFLGS(XELM),EXIT .FLAG ELM AS HAVING EXIT.             51500020
         SR    0,0                .SET R0 TO ZERO                       51600020
         CL    0,100(0,XELM)       Q. SAVE AREA ALREADY EXISTS.         51700020
         BC    4,TMNQ                                                   51800020
         L     0,TMTGM72          .SET INDICATE FOR 72 BYTES HI-CORE    51900020
         LR    1,0                .SET R1 TO INDICATE GETMAIN REQUEST   52000020
         LR    10,15               .SAVE BASE ADDRESS.                  52100020
         SVC   10                  .GET SAVE AREA.                      52200020
         LR    15,10               .RESTORE BASE ADDRESS.               52300020
         ST    1,100(0,XELM)       .STORE SAVE AREA ADDRESS.            52400020
         SPACE                                                          52500020
*...INTERFACE WITH ENQUEUE RTN...                                       52600020
TMNQ     LR    XNQPTR,XELM        .SET ELM ADDR FOR ENQUEUE RTN.        52700020
         LR    XGR2,XELM          .SAVE XELM OVER ENQUEUE.              52800020
         USING CVTSECT,XCVT                                             52900020
         L     XNQ,CVTQTE00       .GET ADDR OF ENQUEUE RTN.             53000020
         DROP  XCVT                                                     53100020
         ST    XGR2,SAVDISP(XPSEUDO) .SAVE REG 10 IN TPC           REFR 53200020
         BALR  XNQ,XNQ            .TO ENQUEUING RTN.                    53300020
         L     XGR2,SAVDISP(XPSEUDO) .RESTORE REG 10               REFR 53400020
         SPACE                                                          53500020
*...IMPLEMENT WAIT IF INDICATED...                                      53600020
         TM    TQEFLGS(XGR2),WAIT .IS WAIT INDICATED.                   53700020
         BC    12,0(XRETRN)       .RETURN IF NOT.                       53800020
         LA    XECB,TQEECB(0,XGR2)     .GET ECB ADDR FOR WAIT.          53900020
         XC    TQEECB(4,XGR2),TQEECB(XGR2)  .ZERO ECB.                  54000020
         WAIT  1,ECB=(1)                                                54100020
         SPACE                                                          54200020
*...RETURN FROM STIMER...                                               54300020
TEXIT    BR    XRETRN                                                   54400020
         SPACE 2                                                        54500020
*...ADDRESSES AND CONSTANTS UNIQUE TO STIMER...                         54600020
         SPACE                                                          54700020
         DS    0F                                                       54800020
TMTUCNV  DC    X'7270E000'    .DECIMAL EQUIV=1,920,000,000.      A24887 54900020
*                                  USED TO DEVELOP 52 USEC UNITS A24887 55000020
*                                  FROM 10 MS (BIN) UNITS.EQUALS A24887 55100020
*                                  100,000 SECONDS/52 TO DEVELOP A24887 55200020
*                                  GREATEST ACCURACY. MUST DIV   A24887 55300020
*                                  BY 10,000,000                 A24887 55400020
TM10E7   DC    X'00989680'        .EQUALS 10,000,000. USED TO DEVELOP   55500020
*                                  52 USEC UNITS.                       55600020
TBINMAX  DC    X'0083D5FF'        .MAX BIN VALUE.                       55700020
TMAX     EQU   *                                                        55800020
TM24     DC    X'C5C10000'         .24 HR TU VALUE               A24887 55900020
TMTABLE  DC    F'360000'          .CONVERSION FACTORS TO DEV BIN UNITS  56000020
         DC    F'6000'             FROM DECIMAL FORMAT.                 56100020
         DC    F'100'                                                   56200020
         DC    F'1'                                                     56300020
FOURTYTH DC    F'40265'                TU IN 1.04 SEC             20071 56400020
TWNT4HRS DC    F'82397'                1.04 SEC UNITS IN A DAY    20071 56500020
ONEHR    DC    F'138240000'            TU IN ONE HR               20071 56600020
TMTGM72  DC    X'FA000048'        .72 BYTES FROM HI-CORE SUBPOOL 250    56700020
         SPACE                                                          56800020
*...ADCONS SHARED BY TTIMER AND STIMER                                  56900020
ADQSPCL  DC    A(IEAQTD00)        .CANCEL ENTRY TO DEQUEUE RTN.         57000020
DQBASE   DC    A(IEAQTD01+2)      .ADDRESSABILITY FOR DEQUEUE RTN.      57100020
ADMSTCB  DC    V(IEAMSTCB)        ADDR OF MS TCB                   I250 57200020
CLOCKAD  DC    A(IEACLOCK)             ADDRESS OF STCK WORK AREA  20071 57300020
IGC046A1 EQU   *                                                    MCH 57400020
         END                                                            57500020
