         TITLE 'TIMER SLIH AND ENQUEUE AND DEQUEUE ROUTINES'            00020000
IEAQTI00 START 0                                                        00040000
         SPACE                                                          00060000
*...DETAILED COMMENTARY WILL PRECEED EACH FUNCTION LISTED BELOW.        00080000
* ROUTINE NAME .IEAQTI00, TIMER SLIH AND ENQUEUE AND DEQUEUE RTNS.      00100000
         SPACE                                                          00120000
* MODULE       .TIMER SECOND LEVEL INTERRUPT HANDLING.                  00140000
* FUNCTION     .ENQUEUING TIMER ELEMENTS.                               00160000
*              .DEQUEUING TIMER ELEMENTS.                               00180000
*              .CONTAINS RUDIMENTARY TIMER QUEUE.                       00200000
         SPACE                                                          00220000
* ENTRY POINT  .IEAQTD00- NORMAL DEQUEUING RTN ENTRY                    00240000
* NAMES        .TSPECIAL- CANCEL DEQUEUING RTN ENTRY                    00260000
*              .IEA0TI00- NORMAL ENTRY TO TIMER SLIH.                   00280000
*              .TSENTIME- DQ RTN ENTRY TO TIMER SLIH.                   00300000
*              .IEAQTE00- ENTRY TO ENQUEUING RTN.                       00320000
*              .IEATPC-   ADDR OF SHPC.                                 00340000
         SPACE                                                          00360000
* CONTAINED IN .IEA0TI10                                                00380000
* MODULE                                                                00400000
*              INTEGRATION                                              00415016
         SPACE                                                          00420000
* ATTRIBUTES   .SEE COMMENTARY PRECEEDING EACH ROUTINE.                 00440000
*              .ALL CODE SUPERVISORY STATE, DISABLED FOR SYSTEM         00460000
*               INTERRUPTS, AND RESIDENT.                               00480000
         SPACE                                                          00500000
* APPLICABILITY .PCP OR OPTION 2 SYSTEMS USING OPTION 6B.               00520000
         SPACE                                                          00540000
* EXTERNAL     .NONE                                                    00560000
* REFERENCES                                                            00580000
         SPACE                                                          00600000
* SVC USAGE    .POST                                                    00620000
         SPACE                                                          00640000
* INPUT        .SEE COMMENTARY PRECEEDING EACH ROUTINE.                 00660000
         SPACE                                                          00680000
* OUTPUT       .SEE COMMENTARY PRECEEDING EACH ROUTINE.                 00700000
         SPACE                                                          00720000
* ENTRY POINTS .SEE COMMENTARY PRECEEDING EACH ROUTINE.                 00740000
         SPACE                                                          00760000
* EXIT POINTS  .SEE COMMENTARY PRECEEDING EACH ROUTINE.                 00780000
         SPACE                                                          00800000
* ERROR EXITS  .SEE COMMENTARY PRECEEDING EACH ROUTINE.                 00820000
         SPACE                                                          00840000
* TABLES AND                                                            00860000
* CONTROL BLKS .SEE COMMENTARY PRECEEDING EACH ROUTINE.                 00880000
* REFERENCED                                                            00900000
         SPACE                                                          00920000
* LIST ORIGINS   .TIMER PSEUDO CLOCKS.                                  00940000
* TABLES,CONTROL   .IEATPC IS ADDR OF SHPC FOUND IN CVT. THE T4PC AND   00960000
* BLKS INCLUDED     LTPC FOLLOW THE SHPC                                00980000
*                  .THE TQPTR CONTAINS THE ADDR OF THE TOP TQE IN THE   01000000
*                   TIMER QUEUE. INITIALLY A RUDIMENTARY QUEUE EXISTS,  01020000
*                   ASSEMBLED AS A PART OF THIS MODULE.                 01040000
*...THE CVTSECT IS USED TO DETERMINE CVT OFFSETS...                     01060000
CVTSECT  DSECT                                                          01080000
         CVT                                                            01100000
         EJECT                                                          01120000
IEAQTI00 CSECT                                                          01140000
*OWNERSHIP - 19572                                                  MCH 01140219
*052660-052730,061800,066850-066950,090460-090520,096850-096950   19018 01140419
*JOB STEP TIMING - 19018                                                01140619
*060000,060400                                                   A29092 01140719
*076600-076800                                                   A24887 01140819
* A24887,A29092                                                         01140919
         ENTRY IEAQTIA0                                             MCH 01141019
         ENTRY IEAQTIA1                                             MCH 01142019
* ROUTINE NAME .IEAQTD00, TIMER DEQUEUE ROUTINE.                        01160000
         SPACE                                                          01180000
* FUNCTION     .THIS RTN. IS USED TO DEQUEUE TIMER QUEUE ELEMENTS (TQE) 01200000
*               AND CONVERT THE TIME OF EXPIRATION (TOX) VALUE TO AN    01220000
*               ABSOLUTE INTERVAL. THIS IS DONE, FOR EXAMPLE, WHEN THE  01240000
*               DISPATCHER DETERMINES A TASK SWITCH FOR A TASK WHICH    01260000
*               HAS A TASK TYPE INTERVAL SET.                           01280000
*              .A SPECIAL ENTRY POINT IS PROVIDED FOR PERMANENTLY       01300000
*               DEQUEUING TQE'S, E.G., TTIMER CANCEL.                   01320000
         SPACE                                                          01340000
* ENTRY POINT  .IEAQTD00- CANCELL DEQUEUING.                            01360000
* NAMES        .IEAQTD01- NORMAL DEQUEUING.                             01380000
         SPACE                                                          01400000
* CONTAINED IN .IEA0TI10                                                01420000
* MODULE                                                                01440000
         SPACE                                                          01460000
* ATTRIBUTES   .REENTRANT,SUPERVISOR STATE,DISABLED FOR I/O AND         01480000
*               EXTERNAL INTERRUPTS,RESIDENT.                           01500000
         SPACE                                                          01520000
* APPLICABILITY .ON PCP, OR OPTION 2 SYSTEMS USING OPTION 6B.           01540000
         SPACE                                                          01560000
* EXTERNAL     .NONE                                                    01580000
* REFERENCES                                                            01600000
         SPACE                                                          01620000
* SVC USAGE    .NONE                                                    01640000
         SPACE                                                          01660000
* INPUT        .ENTRY IS MADE ONLY FROM SUPERVISORY CODE.               01680000
*              .REGISTER 1 MUST CONTAIN THE ADDRESS OF THE TQE TO BE    01700000
*               DEQUEUED                                                01720000
         SPACE                                                          01740000
* OUTPUT       .NONE                                                    01760000
         SPACE                                                          01780000
* ENTRY POINTS .IEAQTD01- DEQUEUES TQE FROM TIMER QUEUE AND CONVERTS    01800000
*               TOX TO ABSOLUTE INTERVAL (26 USEC UNITS). A CHECK IS    01820000
*               MADE TO DETERMINE IF INTERVAL HAS EXPIRED. IF SO, ZERO  01840000
*               IS STORED IN THE TQE VALUE TO CAUSE IMMEDIATE           01860000
*               EXPIRATION WHEN THE TQE IS SUBSEQUENTLY ENQUEUED. A     01880000
*               CHECK IS MADE TO DETERMINE IF THE TOP (NEXT TO EXPIRE)  01900000
*               TQE WAS DEQUEUED. IF SO, THE TIMER SLIH IS ENTERED TO   01920000
*               INSTATE THE NEW TOP TQE ON THE HARDWARE TIMER AND TO    01940000
*               UPDATE THE SHPC. THE EP MUST BE AN EXTRN'D ADCON  M4928 01950019
*               IN THE USER.                                      M4928 01960019
*              .IEAQTD00- DEQUEUES THE TQE WITHOUT CONVERTING TOX TO    01980000
*               ABSOLUTE VALUE. CHECK FOR DEQUEUING TOP TQE AND HANDLES 02000000
*               AS ABOVE. THE EP IS IN THE CVT.                   M4928 02020019
*              .REG 1 MUST CONTAIN THE TQE ADDRESS.                     02040000
*              .REG 2 MUST CONTAIN THE RETURN ADDRESS IN THE CALLER.    02060000
*              .REG 10 MUST CONTAIN THE ADDRESS OF IEACVTPC,THE  A29450 02063019
*               PSEUDO CLOCK AREA, POINTED TO BY CVTTPC.         A29450 02066019
*              .NO REGISTERS ARE SAVED, AND SO THEY MAY BE       A29450 02072019
*               VOLATILE.                                        A29450 02075019
*              .THE PSW MUST BE DISABLED FOR SYSTEM INTERRUPTS AND IN   02080000
*               THE SUPERVISOR STATE.                                   02100000
         SPACE                                                          02120000
* EXIT POINTS  .TWO EXITS POINTS EXIST CONSISTING OF A BRANCH BACK TO   02140000
*               THE CALLER USING THE ADDRESS IN REG. 2.                 02160000
*              .ONE EXIT POINT BRANCHES TO THE TIMER SLIH. (NOTE THAT   02180000
*               REG 2 IS NEEDED IN THE SLIH TO RETURN TO THE CALLER OF  02200000
*               DEQUEUE). THIS EXIT IS USED WHEN THE TOP TQE IS DQ'D.   02220000
         SPACE                                                          02240000
* ERROR EXIT POINTS .NONE                                               02260000
         SPACE                                                          02280000
* TABLES AND   .THE TQE WHOSE ADDRESS IS PASSED IN REG 1.               02300000
* CONTROL BLKS  FIELDS REF'D- TQEFLGS,TQEVAL,TQEFLNK,TQEBLNK            02320000
* REFERENCED   .SHPC                                                    02340000
         SPACE                                                          02360000
* LIST ORIGINS .NONE                                                    02380000
* TABLES ETC                                                            02400000
         SPACE                                                          02420000
* RESTRICTIONS .NONE                                                    02440000
         SPACE                                                          02460000
* NOTES        .THE IEAQTD00 CODE MUST PRECEED THE TIMER SLIH CODE      02480000
*               IN ORDER TO USE THE LA INSTRUCTION TO GET SLIH          02500000
*               ADDRESSABILITY.                                         02520000
         EJECT                                                          02540000
*...EQUATES...                                                          02560000
XDQ1     EQU   4                                                        02580000
XDQ2     EQU   5                                                        02600000
XELM     EQU   1                                                        02620000
XDBASE   EQU   15                                                       02640000
XRETRN   EQU   2                                                        02660000
XDQI     EQU   6                                                        02680000
XR10     EQU   10                                                  REFR 02690017
*                                                                       02700000
PCPTR    EQU   88                                                  REFR 02710017
TIMER    EQU   80                                                       02720000
VELMFLG  EQU   0                                                        02740000
VELMCHN  EQU   4                                                        02760000
VELMVAL  EQU   12                                                       02780000
POSTFLAG EQU   X'80'                   POST CYCLE FLAG        GF A50267 02782021
SAVEREG  EQU   2                   SAVE AREA REG PTR             A31240 02786020
         USING *,XDBASE                                          M0496  02792020
         ENTRY IEAQTD00                                                 02800000
         ENTRY IEAQTD01                                                 02820000
*                                                                       02840000
IEAQTIA0 EQU   *                                                    MCH 02850019
IEAQTD01 BALR  XDBASE,0                                                 02860000
         USING *,XDBASE                                                 02880000
*                                                                       02900000
         TM    VELMFLG(XELM),X'80' .IS ELEMENT OFF QUEUE                02920000
         BCR   7,XRETRN      IF NOT, RETURN.                            02940000
         LR    XDQI,XR10           .SAVE REG 10                   REFR  02942017
         L     XR10,CVTPTR         .ADDRESS OF CVT                 REFR 02946017
         TM    PCPTR(XR10),POSTFLAG IS POST CYCLE FLAG ON ?   GF A50267 02948021
         L     XR10,PCPTR(XR10)    .BASE FOR PSEUDO CLOCKS         REFR 02950017
         USING TPC,10                                                   02955017
         BNO   NOCYCLE             NOT ON, SO SAVE REGS NORM  GF A50267 02955421
         ST    XDQI,POSTSA         IF ON,SAVE R10 FOR POST    GF A50267 02956221
         B     INCYCLE             CONTINUE PROCESSING        GF A50267 02956621
NOCYCLE  ST    XDQI,SAVER10        SAVE REG 6 IN TPC               REFR 02957021
INCYCLE  L     XDQI,TIMER          .GET VALUE ON TIMER AND SHIFT TO     02960021
         SRA   XDQI,1               DEVELOP 26 USEC UNITS               02980000
* DEVELOP REMAINING TIME.                                               03000000
* = TOX - (SHPC - TIMER)                                                03020000
         LCR   XDQI,XDQI           .-TIMER                              03040000
         AL    XDQI,SHPC           .SHPC-TIMER                          03060000
         LCR   XDQI,XDQI           .-(SHPC-TIMER)                       03080000
         AL    XDQI,VELMVAL(XELM)  .TOX-(SHPC-TIMER)                    03100000
*                                                                       03120000
         BC    3,*+6              .IF TOX IS GREATER THAN 6 HR TOD,     03140000
*                                 OVERFLOW WILL OCCUR AND BR ON CARRY   03160000
*                                 WILL BY-PASS SETTING PAST-DUE INTVL   03180000
*                                 TO ZERO.                              03200000
        SR    XDQI,XDQI          .SET PAST-DUE INTVL. TO ZERO           03220000
        ST    XDQI,VELMVAL(XELM) .STORE INTVL. IN ELEMENT.              03240000
*...DEQUEUE ELEMENT...                                                  03260000
IEAQTD00 BALR  XDBASE,0            RE-ESTABLISH ADDRESSABILITY    M4928 03270019
         USING *,XDBASE                                           M2407 03272021
         L     XR10,CVTPTR         GET ADDRESS OF CVT         GF A50267 03274021
         TM    PCPTR(XR10),POSTFLAG IS POST CYCLE FLAG ON ?   GF A50267 03274421
         L     XR10,PCPTR(XR10)    RESTORE REG 10, WE USED IT GF A50267 03274821
         BO    DODEQUE             IF IN CYCLE, DON'T SV REGS GF A50267 03275221
         STM   R11,R9,TSLIHSAV     SAVE CALLER'S REGS         GF A50267 03276021
DODEQUE  LM    XDQ1,XDQ2,VELMCHN(XELM) DEQUEUE THE TQE        GF A50267 03290021
         ST    XDQ1,VELMCHN(XDQ2)                                       03300000
         ST    XDQ2,VELMCHN+4(XDQ1)                                     03320000
         OI    VELMFLG(XELM),X'80' .SET 'OFF QUEUE' FLAG                03340000
         L     XR10,CVTPTR         GET ADDRESS OF CVT         GF A50267 03350021
         TM    PCPTR(XR10),POSTFLAG IS POST CYCLE FLAG ON ?   GF A50267 03352021
         L     XR10,PCPTR(XR10)    RESTORE REG 10, WE USED IT GF A50267 03354021
         BNO   TOPOFF              IF FLAG NOT ON - NORM PROC GF A50267 03356021
         L     XR10,POSTSA         OTHERWISE GET R10 FOR POST GF A50267 03358021
         BR    XRETRN                AND RETURN.              GF A50267 03358421
TOPOFF   CL    XDQ2,TOPQ           .WAS TOP ELEMENT DEQUEUED            03360021
         BC    6,RETURN            .IF NOT RETURN                  REFR 03380017
* TOP ELEMENT DEQUEUED- SET UP NEXT ELEMENT ON TIMER AND SHPC           03400000
         LA    XDBASE,TSLIHLP      .SET ADDRBILTY FOR SLIH              03420000
         DROP  XDBASE                                                   03440021
         USING TSLIHLP,XSBASE                                           03460021
         B     TSENTIME           .TO SLIH CODE.                        03480021
RETURN   LM    R11,R9,TSLIHSAV     RESTORE CALLER'S REGS      GF A50267 03481021
         L     XR10,SAVER10        RESTORE REG 10                REFR   03482021
         BR    XRETRN              .RETURN TO CALLER               RERF 03492017
         SPACE                                                          03500000
*...CONSTANT...                                                         03520000
         TITLE 'TIMER SECOND LEVEL INTERRUPT HANDLER'                   03560000
         SPACE 2                                                        03580000
* ROUTINE NAME .IEA0TI00, TIMER SECOND LEVEL INTERRUPT HANDLER (SLIH).  03600000
         SPACE                                                          03620000
* FUNCTION     .RECIEVES CONTROL WHEN TIMER INTERRUPTS OCCUR. BASED     03640000
*               UPON TYPE OF INTERVAL THAT EXPIRED, INTERRUPT PROCESS'G 03660000
*               IS PERFORMED. THIS MAY CONSIST OF POSTING A COMPLETED   03680000
*               WAIT, SCHEDULING AN ASYCHRONOUS EXIT, OR UPDATING THE   03700000
*               TIMER QUEUES UPON EXPIRATION OF A SIX HR SUPR TQE.      03720000
*               AT MIDNIGHT THE CVT DATE IS UPDATED. MANIPULATES TIMER  03740000
*               QUEUE.                                                  03760000
         SPACE                                                          03780000
* ENTRY POINT  .IEA0TI00- ENTRY FROM T/EX FLIH WHEN TIMER INTERRUPT     03800000
* NAMES         OCCURS.                                                 03820000
*              .TSENTIME- ENTRY FROM TIMER DEQUEUE RTN. WHEN TOP TQE    03840000
*               IS DEQUEUED. (THIS DOES NOT REQUIRE AN ENTRY STATEMENT) 03860000
         SPACE                                                          03880000
* CONTAINED IN .IEAQTI10                                                03900000
* MODULE                                                                03920000
         SPACE                                                          03940000
* ATTRIBUTES   .SERIALLY REUSABLE,SUPERVISOR STATE,DISABLED FOR SYSTEM  03960000
*               INTERRUPTS,RESIDENT.                                    03980000
         SPACE                                                          04000000
* APPLICABILITY .ON PCP,OR OPTION 2 SYSTEMS USING OPTION 6B.            04020000
         SPACE                                                          04040000
* EXTERNAL     .NONE                                                    04060000
* REFERENCES                                                            04080000
         SPACE                                                          04100000
* SVC USAGE    .POST                                                    04120000
         SPACE                                                          04140000
* INPUT        .NO EXPLICIT DATA. INTERNAL TQE POINTER INDICATES TQE    04160000
*               THAT EXPIRED.                                           04180000
         SPACE                                                          04200000
* OUTPUT       .NONE                                                    04220000
         SPACE                                                          04240000
* ENTRY POINTS .IEA0TI00- ENTRY FROM T/EX FLIH.                         04260000
*               REG 2 MUST CONTAIN RETURN ADDR. OTHER REGS NOT SIGNIF.  04280000
*               PSW MUST BE DISABLED FOR SYSTEM INTERRUPTS AND IN       04300000
*               SUPERVISER STATE.                                       04320000
*              .TSENTIME- ENTRY FROM DEQUEUE RTN.                       04340000
*               REG 2 MUST CONTAIN RETURN ADDR TO CALLER OF DEQUEUE     04360000
*               RTN. OTHER REGS ARE NOT SIGNIFICANT.                    04380000
*               PSW MUST BE AS ABOVE.                                   04400000
         SPACE                                                          04420000
* EXITS POINTS .A BRANCH TO THE ADDRESS CONTAINED IN REG 2 RETURNS TO   04440000
*               THE CALLER AFTER SLIH PROCESSING IS COMPLETE.           04460000
*               PSW IS DISABLED FOR SYSTEM INTERRUPTS AND IN            04480000
*               SUPERVISORY STATE. REG SETTINGS ARE NOT SIGNIFICANT.    04500000
*              .A BALR INTERFACE WITH THE EXIT EFFECTOR(STAGE 2).       04520000
*                REG 1- COMPLEMENTED ADDR. OF IQE                       04540000
*                REG 13-SAVES CONTENTS OF REG 1 OVER EXIT EFFECTOR.     04560000
*                REG 14-RETURN ADDR.                                    04580000
*                REG 15-ADDR OF EXIT EFFECTOR                           04600000
*               .OTHER REGS ARE NOT REQUIRED TO BE TRANSPARENT OVER     04620000
*                EXIT EFFECTOR AND ARE NOT SIGNIFICANT.                 04640000
*               .PSW IS DISABLED FOR SYSTEM INTERRUPTS AND IS IN        04660000
*                SUPERVISORY STATE.                                     04680000
*              .A BAL INTERFACE WITH TIMER ENQUEUE RTN.                 04700000
*                REG 1- ADDR OF TQE TO BE ENQUEUED.                     04720000
*                REG 2- RETURN ADDR TO SLIH.                            04740000
*                REG 8- SAVES CONTENTS OF REG 2 OVER ENQUEUE.           04760000
*               .OTHER REGS ARE NOT SIGNIFICANT.                        04780000
*               .PSW IS DISABLED FOR SYSTEM INTERRUPTS AND IS IN        04800000
*                SUPERVISORY STATE.                                     04820000
         SPACE                                                          04840000
* ERROR EXIT   .NONE                                                    04860000
* POINTS                                                                04880000
         SPACE                                                          04900000
* TABLES AND   .TQE'S IN THE TIMER QUEUE.                               04920000
* CONTROL BLKS  FIELDS REFERENCED-TQEFLGS(TESTED/SET),TQEFLNK(SET),     04940000
* REFERENCED    TQEBLNK(SET),TQEVAL(TESTED/SET),TQEEXIT(TESTED)         04960000
*              .CVT- CVTDATE(SET),CVT0EF00(LOADED)                      04980000
*              .TCB(OF TASK WITH EXPIRING INTERVAL)- TOBRBP(LOADED)     05000000
*              .SVRB(OF TASK IN WAIT)- 1ST WORD OF EXTENDED SAVE AREA   05020000
*               BEING USED AS AN ECB(LOADED).                           05040000
         SPACE                                                          05060000
* LIST ORIGINS  .NONE                                                   05080000
* TABLES,CONTROL                                                        05100000
* BLOCKS                                                                05120000
         SPACE                                                          05140000
* RESTRICTIONS .NONE                                                    05160000
         SPACE                                                          05180000
* NOTES        .NONE                                                    05200000
* EQUATES *                                                             05220000
XS1      EQU   6                                                        05240000
XS2      EQU   XS1+1                                                    05260000
XS3      EQU   3                   REG 3 EQUATE               GF A50267 05270021
XSQPTR   EQU   1                                                        05280000
XSCMMTBL EQU   5                                                        05300000
XSEXTEFT EQU   5                                                        05320000
XSRETRN  EQU   2                                                        05340000
XSBASE   EQU   15                                                       05360000
X6HR     EQU   4                                                        05380000
XSNBASE  EQU   13                                                       05400000
XSVRTRN  EQU   8                                                        05420000
XPTR     EQU   8                                                        05440000
XYEAR    EQU   7                                                        05445016
XDAY     EQU   6                                                        05450016
XMASK    EQU   8                                                        05455016
R9       EQU   9                   REG EQUATE                    A31240 05456020
R14      EQU   14                                                 25064 05457000
VXTFR    EQU   4                                                        05460000
VSTAB    EQU   10                                                       05480000
VTCBFLAG EQU   33                                                       05500000
VEXIT    EQU   12                                                       05520000
VTMPXT   EQU   28                                                       05540000
VCMPTR   EQU   16                                                       05560000
VDATE    EQU   56                                                       05580000
*                                                                       05600000
*                                                                       05620000
* REGISTER EQUATES *                                              19018 05621019
*                                                                 19018 05622019
R0       EQU   0                        .WORK REGISTER            19018 05623019
XS8      EQU   8                        .WORK REGISTER            19018 05624019
PIBPTR   EQU   9                        .PIB ADDRESS              19018 05625019
JSTQEADR EQU   9                        .J/S TQE ADDRESS          19018 05626019
XSSAVE   EQU   11                       .SAVE REGISTER            19018 05627019
*                                                                 19018 05628019
* MISCELLANEOUS EQUATES *                                         19018 05629019
*                                                                 19018 05630019
ZERO     EQU   0                                                 A29092 05630219
TQEECB   EQU   96                                                A29092 05630419
R11      EQU   11                                                A29092 05630619
PIBJSTQE EQU   40                       .PIB J/S TQE DISPL        19018 05631019
TCBPIB   EQU   124                      .PIB IN TCB               19018 05632019
*                                                                 19018 05633019
*                                                                 19018 05634019
         ENTRY IEA0TI00                                                 05640000
IEA0TI00 EQU   *                                                        05660000
TSLIH    LR    XPTR,XR10           .SAVE REG 10                    REFR 05666017
         L     XSCMMTBL,CVTPTR     .ADDRESS OF CVT                 REFR 05672017
         L     XR10,PCPTR(XSCMMTBL) .BASE FOR PSEUDO CLOCKS        REFR 05678017
         STM   R11,R9,TSLIHSAV     SAVE CALLERS REGS             A31240 05684020
         BALR  XSBASE,0                                            REFR 05690017
TSLIHLP  L     XS1,TIMER                                                05700000
         LTR   XS1,XS1             .TEST TIMER VAL. IF POSITIVE, RETURN 05720000
         BC    10,SRETURN          .RETURN TO CALLER               REFR 05740017
         L     XSCMMTBL,CVTPTR    .GET ADDR OF CVT                      05760000
         L     XR10,PCPTR(XSCMMTBL) .BASE FOR PSEUDO CLOCKS        REFR 05770017
         L     XSQPTR,TQPTR        .GET PTR TO QUEUE                    05780000
* DEQUEUE ELEMENT                                                       05800000
         LM    XS1,XS2,VELMCHN(XSQPTR)                                  05820000
         ST    XS1,VELMCHN(XS2)                                         05840000
         ST    XS2,VELMCHN+4(XS1)                                       05860000
*                                                                       05880000
         L     XS2,VELMFLG(XSQPTR) .GET ELM TCB ADDR                    05900000
         LA    XS2,0(0,XS2)        CLEAR HI ORDER BYTE             5737 05910016
*********************************************************************   05912021
* IF ABEND FLAG ON, THEN THE JOB IS FINISHING, SO EFFECTIVELY WE    *   05914021
* SHOULD IGNORE THE TIME EXPIRATION IN ORDER TO AVOID HAVING        *   05916021
* NORMAL TERMINATION FOLLOWED BY A 522 OR 322 ABEND BECAUSE OF THE  *   05918021
* TQE POPPING WHILE DOING ABEND PROCESSING.                         *   05918421
*********************************************************************   05918821
         TM    VELMFLG(XSQPTR),X'04' SUPERVISOR ELEMENT        @SA66787 05918921
         BO    NOABTOUT            YES, SKIP 322/522 TEST      @SA66787 05919021
         TM    29(XS2),X'A0'       ABEND OR ABTERM FLAG ON     @SA63113 05919221
         BZ    NOABTOUT            NO, CONTINUE                @SA63113 05919321
         XC    VELMVAL(4,XSQPTR),VELMVAL(XSQPTR) TIME LEFT=0   @SA63113 05919421
         B     TSETOFF             IGNORE INTERVAL EXP         @SA63113 05919521
NOABTOUT EQU   *                                               @SA63113 05919621
         TM    VELMFLG(XSQPTR),X'06'    .TEST ELM TYPE                  05920000
         BC    12,TNWT             .BR IF NOT WAIT                      05940000
* WAIT INTERVAL EXPIRED                                                 05960000
         LR    XS3,XSQPTR         .SAVE Q PTR OVER POST.      GF A50267 05980021
         LR    XS2,XSBASE         .SAVE BASE REG.                       06020000
         L     XR10,CVTPTR         GET ADDRESS OF CVT         GF A50267 06022021
         OI    PCPTR(XR10),POSTFLAG TURN ON POST CYCLE FLAG   GF A50267 06022421
         SR    XR10,XR10           R10 = COMPLETION CODE OF ZERO A29092 06024019
         L     VEXIT,ZERO(XSQPTR)  R12 = TCB ADDR                A29092 06028019
         LA    VEXIT,ZERO(VEXIT)   CLEAR FLAG BYTE               A29092 06032019
         LA    R11,TQEECB(XSQPTR)  R11 = ECB ADDR                A29092 06036019
         USING CVTSECT,XSCMMTBL                                  A29092 06040019
         L     XSBASE,CVT0PT01     R15 = POST ADDR               A29092 06044019
         DROP  XSCMMTBL                                          A29092 06048019
         BAL   R14,VXTFR(XSBASE)   BR TO POST                    A29092 06052019
         LR    XSBASE,XS2         .RESTORE BASE REG.                    06060000
         L     XR10,CVTPTR         .ADDRESS OF CVT                 REFR 06066017
         NI    PCPTR(XR10),X'FF'-POSTFLAG TURN OFF POST FLAG  GF A50267 06068021
         L     XR10,PCPTR(XR10)    .BASE FOR PSEUDO CLOCKS         REFR 06072017
         LR    XSQPTR,XS3         .RESTORE Q PTR.             GF A50267 06080021
         B     TSETOFF                                                  06100000
SRETURN  LM    R11,R9,TSLIHSAV RESTORE CALLER'S REGS          GF A50267 06101021
         L     XR10,SAVER10        RESTORE REG 10                  REFR 06102021
         BR    XSRETRN             .RETURN TO CALLER               REFR 06112017
*                                                                       06120000
TNWT     BM    TSIH                .BR IF SUPV INT EXPIRED              06140000
         TM    VELMFLG(XSQPTR),X'10'    .TEST FOR EXIT (TASK OR REAL)   06160000
         BZ    CHECKJST                 .CHK J/S TQE EXPIRATION   19018 06180019
* INITIALIZE ELEMENT AS IRB & IQE FOR STD INTERFACE WITH EXIT EFFECTOR  06200000
         MVC   8(4,XSQPTR),RBSZSTAB  INIT SIZE AND STAB IN IRB          06220000
         MVC   1(3,XSQPTR),101(XSQPTR) .PLACE SAVE AREA ADDR.IN IRB.    06240000
         MVC   VEXIT(4,XSQPTR),VTMPXT(XSQPTR)     .MOVE ENTRY POINT     06260000
         ST    XS2,108(XSQPTR)     INIT TCB ADDRESS IN IRB              06280000
         ST    XSQPTR,104(XSQPTR)  INIT IRB ADDRESS IN IRB              06300000
        SR    XS2,XS2             CLEAR IQE PTR IN IRB                  06320000
         ST    XS2,24(XSQPTR)          FOR EXIT EFFECTOR                06340000
         LR    XS2,XSQPTR          .SAVE XSQPTR OVER EXIT EFFECTOR      06360000
         LR    XS1,XR10            SAVE XR10 OVER EXIT EFFECTOR    9741 06370017
         LR    XPTR,R14            SAVE REG 14 OVER EXIT EFFECTOR 25064 06375000
         LA    XSQPTR,96(XSQPTR)   GET ADDR OF IQE                      06380000
         LCR   XSQPTR,XSQPTR       COMPLEMENT TO INDICATE 4 BYTE LINK   06400000
         USING CVTSECT,XSCMMTBL                                         06420000
         L     XSEXTEFT,CVT0EF00  .GET ADDR OF EXIT EFFECTOR.           06440000
         DROP  XSCMMTBL                                                 06460000
         BALR  14,XSEXTEFT         .GO TO EXIT EFFECTOR                 06480000
         LR    R14,XPTR            RESTORE REG 14                 25064 06490000
         LR    XSQPTR,XS2               .RESTORE REG                    06500000
         LR    XR10,XS1            RESTORE REG                     9741 06510017
*                                                                       06520000
TSETOFF  OI    VELMFLG(XSQPTR),X'83'  .SET ELM NOT IN USE.              06540000
TSENTIME L     XSQPTR,TQPTR        .GET PTR TO NEW ELEMENT AT HEAD OF   06560000
*                                   QUEUE                               06580000
* DEVELOP INTERVAL TO PLACE ON TIMER                                    06600000
* = NEW ELEMENT TOX - PREVIOUS SHPC                                     06620000
         L     XS2,VELMVAL(XSQPTR) .GET NEW TOX                         06640000
         LR    XS1,XS2                                                  06660000
         SL    XS1,SHPC            .TOX - SHPC = NEW INTERVAL           06680000
         ALR   XS1,XS1             DBLE TO OBTAIN 13 USEC UNITS  A31240 06700020
         AL    XS1,TIMER           .UPDATE TIMER                        06720000
         ST    XS1,TIMER                                                06740000
         ST    XS2,SHPC            .STORE NEW SHPC VALUE                06760000
         B     TSLIHLP                                                  06780000
* SUPERVISOR INTERVAL ROUTINE                                           06800000
TSIH     EQU   *                                               BH 58509 06810021
         TM    VELMFLG(XSQPTR),X'03' PREV. EXP JST TQE         BH 58509 06812021
         BO    CHECKJST              YES CHECK JST EXP.        BH 58509 06814021
         TM    VELMFLG(XSQPTR),X'01'    .TEST FOR MIDNIGHT INTERVAL     06820021
         BO    TDARKNES                                                 06840000
         L     X6HR,TS6HRS         .SET UP REG = 6 HRS FOR LATER USE    06860000
         LR    XPTR,XSQPTR              .INITIALIZE REG WITH TQE ADDR.  06880000
TSUBTLP  L     XPTR,VELMCHN(XPTR)       .REF NEXT TQE.                  06900000
         CLI   VELMVAL(XPTR),X'FF' .TO TQEND WHEN ALL INTERVALS HAVE    06920000
         BC    8,TQEND             .BEEN CORRECTED FOR SH EXPIRATION.   06940000
         L     XS2,VELMVAL(XPTR)        .SUBT 6 HRS FROM INTERVAL.      06960000
         SLR   XS2,X6HR                                                 06980000
         ST    XS2,VELMVAL(XPTR)        .STORE NEW TOX IN TQE.          07000000
         B     TSUBTLP                                                  07020000
*                                                                       07040000
TQEND    L     XS2,T4PC                                                 07060000
         LTR   XS2,XS2                  .TEST T4PC FOR 18 HRS           07080000
         BC    10,*+10                  .BR IF NOT 18 HRS               07100000
         SR    XS2,XS2                  .RESET TO STORE ZERO            07120000
         B     *+6                                                      07140000
         ALR   XS2,X6HR                 .ADD 6 HRS TO T4PC              07160000
         ST    XS2,T4PC                 .STORE NEW VALUE INTO T4PC      07180000
         SR    XS2,XS2             .SET SHPC TO ZERO                    07200000
         ST    XS2,SHPC                                                 07220000
*                                                                       07240000
TSNQUEUE LR    XSVRTRN,XSRETRN     .SAVE RETURN REG                     07260000
         OI    VELMFLG(XSQPTR),X'80'    .SET TQE NOT ON QUEUE.          07280000
         BAL   XSRETRN,IEAQTE00         .TO QUEUING RTN.                07300000
         LR    XSRETRN,XSVRTRN     .RESTORE RETRN REG                   07320000
         B     TSENTIME                                                 07340000
*                                                                       07360000
* MIDNIGHT INT HANDLER                                                  07380000
         USING CVTSECT,XSCMMTBL                                         07388016
TDARKNES MVC   TSDBLDAT+4(4),CVTDATE    MOVE DATE TO WORK AREA          07396016
         CVB   XYEAR-1,TSDBLDAT         GET BINARY VALUE OF DATE        07404016
         SRDL  XYEAR-1,32               PROPAGATE SIGN THRU EVEN REG    07412016
         D     XYEAR-1,TONETHOU         SEPARATE YR AND DAY IN 7 & 6    07420016
         L     XMASK,TMASK              ARE LAST 3 BITS OF YEAR = ZERO  07428016
         NR    XMASK,XYEAR              IF SO THIS IS A LEAP YEAR       07436016
         BC    8,TLEAPYR                                                07444016
         C     XDAY,T365                Q. YEAR'S END                   07452016
TDAYCOMP BL    TADDAY                     NO ADD A DAY TO DAY COUNT     07460016
         LA    XYEAR,1(XYEAR)             YES,INCREMENT YEAR            07468016
         LA    XDAY,1                         SET DAY TO ONE            07476016
TDAYRAD  LR    XMASK,XDAY               SAVE DAY IN SPARE REGISTER      07484016
         M     XYEAR-1,TONETHOU         RECREATE YEAR                   07492016
         AR    XYEAR,XMASK              AND ADD TO YEAR,DAYS            07500016
         CVD   XYEAR,TSDBLDAT                                           07508016
         OI    TSDBLDAT+7,X'0F'         INSURE THAT SIGN IS F           07516016
         MVC   CVTDATE(4),TSDBLDAT+4    MOVE NEW DATE TO CVT            07524016
         MVC   VELMVAL(4,XSQPTR),TS24HRS RE-ESTABLISH THE MIDNIGHT INTV 07532016
         B     TSNQUEUE                                                 07540016
TLEAPYR  C     XDAY,T366                                                07548016
         B     TDAYCOMP                                                 07556016
TADDAY   LA    XDAY,1(XDAY)             INCREMENT DAY                   07564016
         B     TDAYRAD                                                  07572016
CHECKJST EQU   *                                                  19018 07572719
         LTR   XS2,XS2             .Q. IS THERE A TCB ADDR        M4814 07572919
         BZ    TSETOFF             .BRANCH IF NO                  M4814 07573119
         L     PIBPTR,TCBPIB(XS2)       .LOAD PIB ADDR            19018 07573419
         LA    PIBPTR,0(PIBPTR)         .CLEAR HI-ORDER BYTE      19018 07574119
         LTR   PIBPTR,PIBPTR            .Q. IS THERE A PIB        19018 07574819
         BZ    TSETOFF                  .NO. CONT PROCESSING      19018 07575519
         L     JSTQEADR,PIBJSTQE(PIBPTR) .LOAD J/S TQE ADDR       19018 07576219
         LA    JSTQEADR,0(JSTQEADR)     .CLEAR HI-ORDER BYTE      19018 07576919
         LTR   JSTQEADR,JSTQEADR        .Q. IS THERE A J/S TQE    19018 07577619
         BZ    TSETOFF                  .NO. CONT PROCESSING      19018 07578319
         CR    XSQPTR,JSTQEADR          .Q. DID J/S TQE EXPIRE    19018 07579019
         BNE   TSETOFF                  .NO. CONT PROCESSING      19018 07579719
         L     PIBPTR,TCBPIB(XS2)       .LOAD PIB ADDRESS         19018 07580419
         NI    PIBJSTQE(PIBPTR),X'7F'   .TURN OFF FLAG INDICATING 19018 07581119
*                                       .VALID J/S TQE            19018 07581819
         TM    VELMFLG(XSQPTR),X'08'    .Q. REAL(WAIT) TQE        19018 07582519
         LR    XSSAVE,XSQPTR            .SAVE TQE POINTER         19018 07583219
         BO    REALEXP                  .YES. EXPIRED WAIT TQE    19018 07583919
         OI    VELMFLG(XSQPTR),X'83'    .SET COMPLETE FLAG        19018 07584619
         L     XSQPTR,ABEND322          .SET J/S ABEND CODE       19018 07585319
         B     CONTINUE                 .TO SET TASK TO ABTERM    19018 07586019
REALEXP  NI    VELMFLG(XSQPTR),X'F7'    .CHANGE TO TASK           19018 07586719
         OI    VELMFLG(XSQPTR),X'80'    .SET OFF-QUEUE BIT        19018 07587419
         MVC   VELMVAL(4,XSQPTR),20(XSQPTR) .MOVE TIME FIELD      19018 07588119
         L     PIBPTR,TCBPIB(XS2)       .LOAD PIB ADDRESS         19018 07588819
         OI    PIBJSTQE(PIBPTR),X'80'   .TURN ON FLAG INDICATING  19018 07589519
*                                       .VALID J/S TQE            19018 07590219
         L     XSQPTR,ABEND522          .SET WAIT ABEND CODE      19018 07590919
CONTINUE LR    XS8,R0                   .SAVE REGISTER 0          19018 07591619
         L     R0,0(XSSAVE)             .J/S TCB TO ABTERM        19018 07592319
         LR    XS1,XSBASE               .SAVE BASE REGISTER       19018 07593019
         USING CVTSECT,XSCMMTBL         .DSECT REG FOR CVT        19018 07593719
         L     XSBASE,CVTBTERM          .LOAD ABTERM ADDRESS      19018 07594419
         BALR  R14,XSBASE               .ABTERM THE TASK          19018 07595119
         LR    XSBASE,XS1               .RESTORE BASE REGISTER    19018 07595819
         L     XR10,PCPTR(XSCMMTBL)     .BASE FOR TPC             19018 07596519
         LR    XSQPTR,XSSAVE            .RESTORE TQE POINTER      19018 07597219
         LR    R0,XS8                   .RESTORE REGISTER 0       19018 07597919
         B     TSENTIME                 .DON'T SET EXPIRED BIT    19018 07598619
*                                                                       07600000
*CONSTANTS                                                              07620000
         DS    0F                                                       07640017
TS6HRS   DC    X'31704000'         6 HOURS IN TIMER UNITS        A24887 07650019
TS24HRS  DC    X'C5C10000'         24 HOURS IN TIMER UNITS       A24887 07660019
ABEND322 DC    X'80322000'              .J/S TQE EXPIRATION       19018 07686019
ABEND522 DC    X'80522000'              .WAIT TQE EXPIRATION      19018 07692019
RBSZSTAB DC    X'000E'            .RB SIZE                              07700000
         DC    X'400C'             .RB STAB                             07720000
TONETHOU DC    F'1000'                                                  07724016
TMASK    DC    F'3'                                                     07728016
T365     DC    F'365'                                                   07732016
T366     DC    F'366'                                                   07736016
         TITLE 'TIMER ENQUEUE ROUTINE'                                  07740000
* ROUTIN NAME  .IEAQTE00- TIMER ENQUEUE ROUTINE.                        07760000
         SPACE                                                          07780000
* FUNCTION     .USING ADDRESS OF TQE IN REG 1, THE ROUTINE CONVERTS     07800000
*               THE ABSOLUTE TIME VALUE IN THE TQE TO A TOX BASED UPON  07820000
*               THE 6 HR TOD. THE RTN. THEN ENQUEUES THE TQE ON THE     07840000
*               TIMER QUEUE USING THE TOX AS A SEARCH ARGUMENT. IF THE  07860000
*               NEW TQE IS PLACED 1ST IN THE QUEUE, THE TIMER AND SHPC  07880000
*               ARE ADJUSTED TO THE NEW TOP TQE VALUES.                 07900000
         SPACE                                                          07920000
* ENTRY POINT  .IEAQTE00- TIMER ENQUEUE                                 07940000
* NAMES                                                                 07960000
         SPACE                                                          07980000
* CONTAINED IN .IEA0TI10                                                08000000
* MODULE                                                                08020000
         SPACE                                                          08040000
* ATTRIBUTES   .REENTRANT,SUPERVISOR STATE,DISABLED FOR SYSTEM          08060000
*               INTERRUPTS,RESIDENT.                                    08080000
         SPACE                                                          08100000
* APPLICABILITY .ALL SYSTEMS HAVING OPTION 6B                           08120000
         SPACE                                                          08140000
* EXTERNAL     .NONE                                                    08160000
* REFERENCES                                                            08180000
         SPACE                                                          08200000
* SVC USAGE    .NONE                                                    08220000
         SPACE                                                          08240000
* INPUT        .ENTRY IS MADE ONLY FROM SUPERVISORY CODE.               08260000
*                REG 1 MUST CONTAIN THE ADDRESS OF THE TQE TO BE        08280000
*                ENQUEUED                                               08300000
         SPACE                                                          08320000
* OUTPUT       .NONE                                                    08340000
         SPACE                                                          08360000
* ENTRY POINTS .IEAQTE00- ONLY ENTRY TO CODE- ADDR IS FOUND IN CVT.     08380000
*               .REG 1 MUST CONTAIN ADDRESS OF TQE TO BE ENQUEUED.      08400000
*                REG 2 CONTAINS RETURN ADDRESS OF CALLER.               08420000
*                OTHER REGISTERS NOT SIGNIFCANT.                        08440000
*               .PSW IS IN SUPERVISOR STATE AND DISABLED FOR SYSTEM     08460000
*                INTERRUPTS.                                            08480000
         SPACE                                                          08500000
* EXIT POINTS  .A SINGLE BRANCH TO THE ADDRESS IN REG 2 RETURNS TO THE  08520000
*               CALLER. ALL REGISTERS EXCEPT 4,5,6, AND 13 ARE          08540000
*               TRANSPARENT OVER THE RTN. REGS 10,11,12 ARE INSIGNIF.   08560000
*              .THE PSW IS IN SUPERVISOR STATE AND DISABLED FOR SYSTEM  08580000
*               INTERRUPTS.                                             08600000
         SPACE                                                          08620000
* ERROR EXIT   .NONE                                                    08640000
* POINTS                                                                08660000
         SPACE                                                          08680000
* TABLES AND   .TQE'S- TQEFLGS(TEST, SETS),TQEFLNK(SETS),TQEBLNK(SETS), 08700000
* CONTROL BLKS         TQEVAL(SETS)                                     08720000
* REFERENCED   .SHPC(SETS)                                              08740000
         SPACE                                                          08760000
* LIST ORIGINS,  .NONE                                                  08780000
* TABLES,CONTROL                                                        08800000
* BLOCKS INCLUDED                                                       08820000
         SPACE                                                          08840000
* RESTRICTIONS .NONE                                                    08860000
         SPACE                                                          08880000
* NOTES        .NONE                                                    08900000
         EJECT                                                          08920000
* EQUATES *                                                             08940000
XNELM    EQU   1                                                        08960000
XNRETRN  EQU   2                                                        08980000
XN1      EQU   4                                                        09000000
XN2      EQU   5                                                        09020000
XN3      EQU   6                                                        09040000
XNBASE   EQU   13                                                       09060000
*                                                                       09080000
*                                                                       09100000
         ENTRY IEAQTE00                                                 09120000
*                                                                       09140000
IEAQTE00 BALR  XNBASE,0                                                 09160000
         USING *,XNBASE                                                 09180000
         TM    VELMFLG(XNELM),X'80'     .IS ELEMENT IN QUEUE            09200000
         BCR   8,XNRETRN          .IF YES, EXIT                         09220000
         L     XR10,CVTPTR         .ADDRES OF CVT                  REFR 09226017
         L     XR10,PCPTR(XR10)    .BASE FOR PSEUDO CLOCKS         REFR 09232017
* DETERMINE IF INTERVAL IS SMALLER THEN  CURRENT INTERVAL IN TIMER      09240000
         L     XN1,VELMVAL(XNELM)       .GET INT VAL                    09260000
         LR    XN3,XN1                  .SAVE INT                       09280000
         L     XN2,TIMER                .GET TIMER VALUE                09300000
         SRA   XN2,1                    .DEV 26 USEC UNITS              09320000
         SLR   XN1,XN2             .INTERVAL - TIMER                    09340000
         BC    4,TNQLOWVL    .BR IF INTERVAL IS LESS THAN TIMER VALUE.  09360000
TNQTOX   AL    XN1,SHPC       .NEW TOX = SHPC + (INT - TIMER)           09380000
         ST    XN1,VELMVAL(XNELM)  .STORE TOX IN ELM                    09400000
         LA    XN2,TQPTR-4         .SET UP TQPTR-4 ADDR FOR INIT LOAD.  09420000
TNQSRLP  L     XN2,VELMCHN(XN2)    .SEARCH FOR INSERTION POINT          09440000
         CL    XN1,VELMVAL(XN2)    .COMPARE TOX'S. INSERT BEFORE AN     09460000
         BH    TNQSRLP              EQUAL                               09480000
         L     XN3,VELMCHN+4(XN2)  .PLACE ELEMENT IN QUEUE              09500000
         STM   XN2,XN3,VELMCHN(XNELM)                                   09520000
         ST    XNELM,VELMCHN+4(XN2)                                     09540000
         ST    XNELM,VELMCHN(XN3)                                       09560000
         NI    VELMFLG(XNELM),X'7F'     .SET 'ON QUEUE' FLAG            09580000
         BR    XNRETRN                  .RETURN                         09600000
*                                                                       09620000
TNQLOWVL LTR   XN2,XN2        .TEST FOR NEG TIMER                       09640000
         BC    4,TNQTOX       .IF NEG, HANDLE AS THOUGH NEW INTERVAL IS 09660000
*                              LARGER                                   09680000
         AL    XN1,SHPC       .NEW TOX = SHPC + (INT - TIMER)           09700000
         ST    XN1,SHPC       .STORE NEW TOX IN SHPC                    09720000
         ALR   XN3,XN3                                                  09740000
         ST    XN3,TIMER      .PLACE NEW INTERVAL IN TIMER              09760000
         B     TNQTOX+4                                                 09780000
IEAQTIA1 EQU   *                                                    MCH 09790019
*                                                                       09800000
         TITLE 'PSEUDO CLOCKS AND RUDIMENTARY QUEUE'                    09820000
* * * * * * * * * * *                                                   10420000
         IEACVTPC                                                       10430017
         END                                                            10440000
