IGC0005A CSECT                                                          00020000
*0241054200,055020-055100,060800                                   RF0B 00026016
*02410770000-077800                                                4029 00032016
*2500047000                                                        7786 00036017
*038200,041800,047000-047600,054700,066400-066600,067400,          I250 00037019
*067800-081200,082400-093200,113400,114000,115400-121600,123400,   I250 00038019
*130800                                                            I250 00039019
*066800-073600                                                    M2154 00039500
         TITLE  'IEAAAD00 / ABDUMP LOAD 1 / IGC0005A'                   00040000
*STATUS  CHANGE LEVEL  001                                              00060000
*        IEAAAD00 / ABDUMP LOAD 1 / IGC0005A                            00080000
*         GENERAL ABDUMP INFORMATION                                    00100000
*        THE ABDUMP SVC ROUTINE (SVC 51) PRODUCES A VARIABLE DISPLAY OF 00120000
*        SYSTEM AND PROBLEM PROGRAM INFORMATION.  IT IS A TYPE 4 SVC    00140000
*        AND CONSISTS OF TWELVE TRANSIENT LOADS. IT IS CALLED BY ABEND  00160019
*        OR BY THE USER (VIA THE SNAP MACRO).                           00180019
*        THE FIRST LOAD OF ABDUMP IS REFERRED TO AS ABDUMP1, THE SECOND 00200000
*        AS ABDUMP2, ETC.  TO FACILITATE EASIER UNDERSTANDING OF THE    00220000
*        DESCRIPTIONS OF THE MODULES.                                   00240000
*        THE MODULE AND SVC LIBRARY NAMES ARE AS FOLLOWS:               00260000
*        ABDUMP NAME          MODULE NAME          SVC LIBRARY NAME     00280000
*          ABDUMP1             IEAAAD00                IGC0005A         00290019
*          ABDUMP2             IEAAAD0D                IGC0D05A         00300019
*          ABDUMP3             IEAAAD0A                IGC0A05A         00310019
*          ABDUMP4             IEAAAD01                IGC0105A         00320019
*          ABDUMP5             IEAAAD02                IGC0205A         00330019
*          ABDUMP6             IEAAAD03                IGC0305A         00340019
*          ABDUMP7             IEAAAD0B                IGC0B05A         00350019
*          ABDUMP8             IEAAAD04                IGC0405A         00360019
*          ABDUMP9             IEAAAD05                IGC0505A         00370019
*          ABDUMP10            IEAAAD0E                IGC0E05A         00380019
*          ABDUMP11            IEAAAD0C                IGC0C05A         00390019
*          ABDUMP12            IEAAAD0F                IGC0F05A         00400019
         SPACE 2                                                        00420000
*  FIRST TRANSIENT LOAD OF ABDUMP, HEREIN REFERRED TO AS ABDUMP1.     * 00440000
         SPACE 2                                                        00460000
*FUNCTION-                                                            * 00480000
*        ABDUMP1 IS THE FIRST TRANSIENT LOAD OF ABDUMP WHICH IS A     * 00500000
*        TYPE IV SVC ROUTINE.  ABDUMP1 INSURES THAT ABDUMP            * 00520000
*        REQUIREMENTS HAVE BEEN MET (E.G.,BSAM DCB HAS BEEN           * 00540000
*        OPENED AND CONTAINS THE REQUIRED ATTRIBUTES) AND OBTAINS AND * 00570019
*        INITIALIZES A WORK AREA USED BY EACH TRANSIENT LOAD OF ABDUMP* 00600019
         SPACE 2                                                        00640000
*ENTRY-                                                               * 00660000
*        ABDUMP1 IS ENTERED AT ENTRY POINT NAME IGC0005A WHEN THE       00680000
*        ABDUMP SVC INSTRUCTION (SVC 51) IS EXECUTED.  ABDUMP1 IS     * 00700000
*        ENTERED IN SUPERVISOR STATE, WITH SUPERVISOR PROTECTION KEY, * 00720000
*        AND WITH INPUT/OUTPUT AND EXTERNAL INTERRUPTS DISABLED.      * 00740000
         SPACE 2                                                        00760000
*INPUT-                                                               * 00780000
*        ABDUMP1 IS PASSED A POINTER TO THE PARAMETER LIST IN REG 1     00800000
*        THE PARAM.LIST FORMAT IS DESCRIBED BY THE DSECT CALLED         00820000
*        'PARDSECT'. ABDUMP1 IS ALSO PASSED A POINTER TO THE TCB OF   * 00830019
*        THE CURRENT TASK IN REG 4 AND A POINTER TO ABDUMP'S SVRB IN    00840019
*        REG 5.                                                         00850019
         SPACE 2                                                        00860000
*OUTPUT-                                                              * 00880000
*        NONE                                                           00980019
         SPACE 2                                                        01120000
*EXTERNAL REFERENCES-                                                 * 01140000
*        ABDUMP1 REFERENCES ENTRIES IN THE COMMUNICATIONS VECTOR      * 01160000
*        TABLE (CVT), THE TCB OF THE CURRENT TASK, THE TCB OF THE TASK* 01190019
*        BEING DUMPED, AND THE DCB ASSOCIATED WITH THE DUMP DATA SET. * 01220019
*        A)  CVT                                                      * 01260000
*        SYMBOLIC OFFSET - CVTDCB, FROM WHICH IT IS DETERMINED WHETHER* 01280019
*                                  SYSTEM BEING USED IS PCP OR MFT    * 01300019
*        B)  TCB                                                      * 01340000
*        SYMBOLIC OFFSET - TCBMSS, PTR TO BOUNDARY BOX                * 01350019
*                        - TCBPKF, STORAGE PROTECTION KEY             * 01360019
*                        - TCBFLGS, FLAG BYTES                        * 01370019
*                        - TCBFLGS2, FLAG BYTES                       * 01380019
*                        - TCBJSTCB, PTR TO JOBSTEP TCB               * 01390019
*                        - TCBNTC, PTR TO PREVIOUS TCB ON SUBTASK Q   * 01400019
*                        - TCBOTC, PTR TO TCB OF ORIGINATING TASK     * 01410019
*                        - TCBLTC, PTR TO LAST TCB ON SUBTASK Q       * 01420019
*        C) DCB                                                       * 01440019
*        SYMBOLIC OFFSET - DCBOFLGS, FROM WHICH IT IS DETERMINED      * 01460019
*                                    WHETHER OR NOT THE DATA SET IS   * 01480019
*                                    OPEN                             * 01500019
*                        - DCBDSORG, DATA SET ORGANIZATION            * 01520019
*                        - DCBRECFM, RECORD FORMAT                    * 01540019
*                        - DCBLRECL, LOGICAL RECORD LENGTH            * 01560019
*                        - DCBMACRF, MACRO INSTRUCTION REFERENCE      * 01580019
*                        - DCBBLKSI, MAXIMUM BLOCKSIZE                * 01600019
         SPACE 2                                                        01700000
*EXITS-                                                               * 01720000
*        A)  IF ABDUMP REQUIREMENTS HAVE BEEN MET, ABDUMP1 TRANSFERS  * 01740000
*            CONTROL (XCTL'S) TO THE SECOND TRANSIENT LOAD OF ABDUMP. * 01760000
*        B)  IF ABDUMP REQUIREMENTS HAVE NOT BEEN MET, ABDUMP1 EXITS  * 01780000
*            (SVC 3) WITH A RETURN CODE IN THE RETURN CODE REGISTER   * 01800000
*            (REGISTER 15).                                           * 01820000
*            RETURN CODE = 4 INDICATES BSAM DCB HAS NOT BEEN OPENED   * 01840000
*            RETURN CODE = 12 INDICATES DCB DOES NOT HAVE THE         * 01844019
*                             REQUIRED ATTRIBUTES.                    * 01848019
*            RETURN CODE = 8 INDICATES THAT THE TCB FOR THE TASK TO   * 01852019
*                            BE DUMPED IS NOT IN THE CURRENT JOBSTEP  * 01856019
         SPACE 2                                                        01860000
*TABLES/WORK AREAS-                                                   * 01880000
*        A)  TABLES                                                   * 01900000
*            SEE EXTERNAL REFERENCES ABOVE                            * 01920000
*        B)  WORK AREAS                                               * 01940000
*            ABDUMP1 OBTAINS A WORK AREA OF 672 BYTES VIA GETMAIN     * 01960019
*            AND MAINTAINS A PTR TO THE AREA IN REGISTER 13.  THE     * 01980000
*            AREA IS USED BY EACH TRANSIENT LOAD OF ABDUMP, AND IS    * 02000000
*            DESCRIBED BY THE DSECT NAMED 'ABDAREA'                   * 02200019
         SPACE 2                                                        02420000
*OPERATION-                                                           * 02440000
*        ABDUMP1 PERFORMS THE FOLLOWING FUNCTIONS -                   * 02460000
*        - CHECKS FOR OPEN DCB. IF NOT OPEN, ERROR EXIT.              * 02480019
*        - CHECKS DCB FOR REQUIRED ATTRIBUTES. IF REQUIRED ATTRIBUTES * 02500019
*          ARE NOT PRESENT, ERROR EXIT.                               * 02520019
*        - CHECKS TCB ADDRESS, IF DUMP IS FOR OTHER THAN CURRENT TASK,* 02540019
*          TO INSURE THAT IT IS IN THE CURRENT JOBSTEP. IF NOT, ERROR * 02560019
*          EXIT. (APPLIES ONLY TO MFT ATTACH SYSTEMS)                   02580019
*        - ISSUES UNCONDITIONAL GETMAIN FOR WORK AREA.                * 02600019
*        - INITIALIZES PORTIONS OF WORK AREA.                         * 02620019
*        - ISSUES CONDITIONAL GETMAIN FOR BUFFER TO ALLOW FOR         * 02640019
*          BLOCKING.                                                  * 02660019
*        - SETS JOBSTEP NON-DISPATCHABLE, EXCEPT CURRENT TASK, IF     * 02680019
*          DUMP OF OTHER THAN CURRENT TASK IS SPECIFIED. (APPLIES     * 02700019
*          ONLY TO MFT ATTACH SYSTEMS)                                * 02720019
*        - ENQ'S ON DUMP DATA SET IF NOT ENTERED FROM ABEND. (APPLIES * 02740019
*          ONLY TO MFT ATTACH SYSTEMS)                                * 02760019
*        - ENABLES I/O AND EXTERNAL INTERRUPTS.                       * 02780019
*        - TURNS OFF TRACE IF NOT ENTERED FROM ABEND AND TRACE TABLE  * 02800019
*          IS REQUESTED.                                              * 02820019
*        - XCTL'S TO ABDUMP2.                                         * 02840019
         SPACE 2                                                        02920000
*REMARKS-                                                             * 02940000
*        ABDUMP IS AN ABNORMAL END DUMP, CALLED BY ABEND TO PROVIDE   * 02960000
*        A POST MORTEM DUMP.  HOWEVER, ABDUMP MAY ALSO BE USED BY THE * 02980000
*        PROBLEM PROGRAMMER VIA SNAP MACRO(SEE OPTION FLAGS).           03000000
        EJECT                                                           03020000
*        REGISTERS                                                      03040000
R0       EQU   0         ACCUMULATOR                                    03060000
R1       EQU   1         PTR TO PARAMETER LIST                          03080000
R2       EQU   2         PTR TO TCB                                     03100000
R3       EQU   3         RB PTR                                         03120000
R4       EQU   4         PTR TO PARAMETER LIST,RB PTR                   03140000
R5       EQU   5         INTERNAL LINKAGE REGISTER                      03160000
R6       EQU   6         PTR TO CONSTANTS,...                           03180000
R7       EQU   7         PTR TO OUTPUT LINE                             03200000
PARREG   EQU   7                                                        03220000
R8       EQU   8         PTR TO INFO TO BE FORMATTED                    03240000
R9       EQU   9         PTR TO BLOCKING BUFFER                         03260000
RA       EQU   10        WORK REGISTER                                  03280000
RB       EQU   11        WORK REGISTER                                  03300000
RC       EQU   12        BASE REGISTER                                  03320000
RD       EQU   13        POINTER TO AREA OBTAINED VIA GETMAIN           03340000
RE       EQU   14                                                       03360000
RF       EQU   15        RETURN CODE REGISTER                           03380000
*                                                                       03400000
* ERROR RETORN CODE                                                     03420000
BADDCB   EQU   4                       DCB NOT OPENED                   03440000
BADTCB   EQU   8                   INVALID TCB ADDRESS GIVEN       I250 03450019
WRONGDCB EQU   12                  INCORRECT DCB TYPE RETURN CODE       03460000
VBA      EQU   X'54'               PROPER DCB RECFM FIELD               03480000
NOTPS    EQU   X'BF'               NOT PS ORG MASK FOR DCB              03500000
CUR      EQU   4                                                        03520000
EXIT     EQU   3                                                        03540000
FLAGS    EQU   0         DISPLACEMENT FROM BEGIN OF PARA.LIST TO FLAGS  03560000
DVTYPE   EQU   17        DCB DISPLACEMENT TO DEVICE TYPE                03580000
OFLGS    EQU   48        DCB DISPLACEMENT TO OPEN FLAGS                 03600000
IOBSYNAD EQU   56        DCB DISPLACEMENT TO IOB LENGTH, SYNAD          03620000
OPEN     EQU   X'10'     MASK TO TEST OPEN FLAG                         03640000
TCBFX    EQU   X'01'     MASK USED TO PREVENT ASYNCHRONOUS EXITS   I250 03641019
MFTATTCH EQU   X'08'     MASK TO TEST FOR MFT ATTACH               I250 03642019
TCBNDUMP EQU   X'80'     MASK USED TO SET TASK NON-DISPATCHABLE    I250 03643019
TCBNDISP EQU   X'01'     MASK TO SET OTHER NON-DISP BIT            I250 03644019
TESTTASK EQU   X'80'     ON-DUMP IS FOR TASK OTHER THAN CURRENT    I250 03645019
TERMBIT  EQU   X'80'     ON-TASK HAS BEEN TERMINATED               I250 03646019
TESTRBS  EQU   X'40'     MASK TO TEST IF RB CHAIN EXISTS           I250 03647019
XFF      EQU   X'FF'                                               I250 03648019
NDBYTE   EQU   4                                                   I250 03649019
ZERO     EQU   0                                                   I250 03650019
ONE      EQU   1                                                   I250 03651019
TWO      EQU   2                                                   I250 03652019
THREE    EQU   3                                                   I250 03653019
FOUR     EQU   4                                                   I250 03654019
EIGHT    EQU   8                                                   I250 03655019
TWELVE EQU     12                                                  I250 03656019
* DISPLACEMENTS FROM BEGINNING OF TIOT TO                               03660000
TIOTJOB  EQU   0         JOB NAME                                       03680000
TIOTSTEP EQU   8         STEP NAME                                      03700000
* DISPLACEMENTS FROM BEGINNING OF TCB TO                                03720000
TCBRBP   EQU   0         PTR TO ACTIVE RB CHAIN                         03740000
TCBPIE   EQU   4         PTR TO PROG INTERRUPT ELEMENT                  03760000
TCBTIOT  EQU   12        PTR TO TIOT                                    03780000
TCBCMP   EQU   16        TASK COMPLETION CODE                           03800000
TCBMSS   EQU   24        PTR TO BOUNDARY BOX                       I250 03806019
TCBPKF   EQU   28        STORAGE PROTECTION KEY                    I250 03812019
TCBFLGS  EQU   29        TCB FLAGS                                 I250 03818019
TCBFLGS2 EQU   174       TCB FLAGS                                 I250 03824019
TCBNDSP2 EQU   173       TCB NON-DISPATCHABILITY BYTES             I250 03830019
TCBLL    EQU   36        PTR TO LIST OF LOADED PROGRAMS                 03840000
TCBJSTCB EQU   44        PTR TO JOBSTEP TCB                        I250 03844019
TCBNTC   EQU   128       PTR TO PREVIOUS TCB ON SUBTASK Q          I250 03848019
TCBOTC   EQU   132       PTR TO TCB OF ORIGINATING TASK            I250 03852019
TCBLTC   EQU   136       PTR TO LAST TCB ON SUBTASK Q              I250 03856019
* DISPLACEMENTS FROM BEGINNING OF RB TO                                 03860000
RBSIZE   EQU   8         SIZE OF RB/PROG                                03880000
RBSTAB   EQU   10        RB STATUS AND ATTRIBUTE BITS                   03900000
RBOPSW   EQU   16        PSW SAVE AREA                                  03920000
RBLINK   EQU   28        RB CHAIN ADDR                                  03940000
RBREG    EQU   32                                                       03960000
* EXTENDED ASA CARRIAGE CONTROL CHARACTERS FOR                          03980000
HDCC     EQU   C'0'                     HEADING LINE                    04000000
COMPCC   EQU   C'0'                     COMPLETION CODE LINE            04020000
PSWCC    EQU   C'0'                     PSW LINE                        04040000
MSGCC    EQU   C'0'                     MESSAGE LINE                    04060000
*                                                                       04080000
* OPTION FLAGS                                                          04100000
*                                                                       04120000
* FIRST FLAG BYTE                                                       04140000
PFABEND  EQU   X'80'                   OFF-ABEND,ON-SNAP IS THE CALLER  04160000
PFTCB    EQU   X'40'                   ON-TCB ADDR IS FIVEN        I250 04180019
PFSUPDAT EQU   X'20'                   ON-ALL SUPRV DATA                04200000
PFTRACE  EQU   X'10'                   ON-PRINT TRACE TABLE             04220000
PFNUC    EQU   X'08'                   ON-PRINT NUCLEUS                 04240000
PFSNAP   EQU   X'04'                   ON-SNAPSHOT LIST GIVEN           04260000
PFID     EQU   X'02'                   ON-AN ID GIVEN                   04280000
PFQCB    EQU   X'01'                   NOT USED IN SSS SYSTEM           04300000
* SECOND FLAG BYTE                                                      04320000
PFSAVE   EQU   X'80'                   ON-SAVE AREA(SEE PFSAVE2)        04340000
PFSAVE2  EQU   X'40'                   OFF-ENTIRE SA,ON-HEADINGS ONLY   04360000
PFREGS   EQU   X'20'                   ON-REGS AT ENTRY TO(SEE PFABEND) 04380000
PFLPA    EQU   X'10'              NOT USED IN SSS                       04400000
PFJPA    EQU   X'08'              ON- PRINT P/P PARTITION               04420000
PFPSW    EQU   X'04'                   ON--PSW AT ENTRY TO(SEE PFABEND) 04440000
PFSPALL  EQU   X'02'                   ON-P/P PARTITION                 04460000
*        EQU   X'01'              NOT USED IN SSS                       04480000
         EJECT                                                          04500000
* INITIALIZATION                                                        04520000
*       1)  DETERMINE IF ABDUMP REQUIREMENTS HAVE BEEN MET (OPENED      04540000
*           DCB AND SUFFICIENT CORE AVAILABLE).                         04560000
*       2)  ENABLE FOR I/O AND EXTERNAL INTERRUPTS.                     04580000
*       3)  INITIALIZE OUTPUT AREA.                                     04600000
*                                                                       04620000
ENTRY   BALR  RC,0                     ESTABLISH ADDRESSABILITY         04640000
         USING *,RC                                                     04660000
         USING PARDSECT,PARREG                                          04680000
         LA    R4,ZERO(R4)             CLEAR TOP BYTE OF TCB REG   I250 04690019
         LR    R2,R4                   R2 POINTS TO TCB OF CURR    I250 04700019
*                                        TASK IN THE EVENT THE     I250 04710019
*                                        CURR TASK IS THE ONE TO   I250 04720019
*                                        BE DUMPED                 I250 04730019
         LR    PARREG,R1               SET UP BASE FOR PARDSECT    I250 04740019
         L     R6,PDCBPTR              GET PTR TO DCB              I250 04750019
        TM    OFLGS(R6),OPEN           TEST FOR OPENED DCB              04780000
         BC    1,DCBOK                 BRANCH,DCB OPENED                04800000
         LA    RF,BADDCB               GET ERROR CODE                   04820000
         EJECT                                                          04840000
*********************************************************************** 04860000
*                                                                     * 04880000
*        THE FOLLOWING CODE IS ADDED TO ALLOW ABDUMP1 TO VALIDITY     * 04900000
*        CHECK THE DCB THAT IS PASSED BY THE USER FOR 'SNAP'.         * 04920000
*        THE ROUTINE CHECKS FOR THE FOLLOWING ATTRIBUTES-             * 04940000
*                  DSORG = PS                                         * 04960000
*                  MACRF = W                                          * 04980000
*                  RECFM = VBA                                        * 05000000
*                  LRECL = 125                                        * 05020000
*        MFT2 BLKSIZE = 882                                           * 05030017
*        PCP  BLKSIZE = 1632 OR 882                                   * 05040017
*        IF ANY OF THESE ATTRIBUTES FAIL TO APPEAR IN THE DCB,        * 05060000
*        A CONDITION CODE = 12 IS RETURNED IN REGISTER 15.            * 05080017
*                                                                     * 05100000
*********************************************************************** 05120000
         SPACE 2                                                        05140000
ERREXIT  EQU   *                   EXIT TO CALLER                       05160000
         SVC   EXIT                                                     05180000
         USING IHADCB,R6                                                05200000
DCBOK    TM    DCBDSORG,NOTPS          SEE IF DSORG IS CORRECT          05240015
         BM    SICKDCB             IF NOT, RETURN CONDITION CODE=8.     05280000
         CLI   DCBRECFM,VBA        SEE IF RECFM IS CORRECT              05300000
         BNE   SICKDCB             IF NOT, GO EXIT                      05320000
         CLC   DCBLRECL,PHYLOG+4   SEE IF LOGICAL RECORD LENGTH IS 125. 05340000
         BNE   SICKDCB             IF NOT, BRANCH                       05360000
         CLC   DCBMACRF,=H'32'     SEE IF CORRECT MACRO FORM            05380000
         BNE   SICKDCB             GO RETURN ERROR CODE IF NOT          05400000
         L     R1,CVTPTR                POINT TO CVT               M00A 05404015
         USING CVTDSECT,R1                                         M00A 05408015
         TM    CVTDCB,X'20'             IS THIS MFT2               M00A 05412015
         BO    MFT2RUN                  YES                        M00A 05416015
         LA    RB,MINMAX           GET ADDRESS OF PCP LIMITS       RF0B 05424016
         CLC   DCBBLKSI,MINMAX+6   IS BLOCK SIZE 1632              RFOB 05432017
         BE GETCORE                IF SO, GO TO GETMAIN SVC             05440000
MFT2RUN  LA    RB,MINMAX2          GET ADDR OF BLOCK LIMITS        BLKZ 05450017
         CLC   DCBBLKSI,MINMAX2+6  IS BLOCK SIZE 882 - MFT2        BLKZ 05460017
         BE    TSTATTCH            YES,DCB IS GOOD                 I250 05470019
SICKDCB  LA    RF,WRONGDCB         ERROR CODE = 12 FOR WRONG DCB   BLKZ 05480017
         B     ERREXIT             RETURN TO USER                  BLKZ 05490017
         LTORG                                                          05520000
         DROP  R6                                                       05540000
TSTATTCH EQU   *                                                   I250 05540719
         L     R1,CVTPTR           GET PTR TO CVT                  I250 05541419
         TM    CVTOPTA,MFTATTCH    IS THIS AN MFT ATTACH SYSTEM    I250 05542119
         BNO   GETCORE             NO,BRANCH                       I250 05542819
         TM    PFLAGS,PFTCB        IS TCB ADDR IN PARAMETER LIST   I250 05543519
         BZ    CURRTCB             NO,DUMP IS FOR CURRENT TASK     I250 05544219
*                                                                  I250 05544919
* VALIDITY CHECK TCB ADDRESS IN PARAMETER LIST                     I250 05545619
*                                                                  I250 05546319
         L     R3,PTCBPTR          GET TCB ADDR FROM PARAM LIST    I250 05547019
         LA    R3,ZERO(R3)         CLEAR TOP BYTE                  I250 05547719
         LTR   R3,R3               IS TCB ADDR ZERO                I250 05548419
         BZ    CURRTCB             YES,DUMP IS FOR CURRENT TASK    I250 05549119
         LR    R2,R3               NO,MAKE R2 POINT TO TCB OF      I250 05549819
*                                  TASK TO BE DUMPED               I250 05550519
         CLI   TCBPKF(R4),ZERO     WAS ABDUMP CALLED BY SPVR RTN   I250 05551219
         BNE   PPRTN               NO,BRANCH                       I250 05551919
         OI    TCBFLGS2(R2),TCBNDUMP  SET TASK NON-DISPATCHABLE    I250 05552619
         OI    TCBFLGS+NDBYTE(R2),TCBNDISP                         I250 05553319
         B     GETCORE                                             I250 05554019
PPRTN    CLC   TCBJSTCB(FOUR,R2),TCBJSTCB(R4)  IS PASSED TCB IN    I250 05554719
*                                              CURRENT JOBSTEP     I250 05555419
         BE    GETCORE             YES,BRANCH                      I250 05556119
         LA    RF,BADTCB           NO,GET ERROR RETURN CODE        I250 05556819
         SVC   EXIT                RETURN TO CALLER                I250 05557519
CURRTCB  OI    TCBFLGS(R4),TCBFX   PREVENT ASYNCHRONOUS EXITS      I250 05558219
*                                    FOR CURRENT TASK              I250 05558919
         EJECT                                                          05560000
GETCORE  EQU   *                                                        05580000
* GETMAIN FOR OUTPUT AREA, SAVE AREA, DECB, WORK AREA, SPACE FOR        05600000
* OUTPUT ROUTINE, PRINT LINE                                            05620000
         LA    R0,672         TOTAL CORE REQUIRED ABDAREA DSECT PTM 893 05640017
         GETMAIN   R,LV=(0)                                             05660000
* POINTER TO AREA ALLOCATED IS RETURNED IN REGISTER 1.                  05680000
         LR    RD,R1                                                    05700000
         USING ABDAREA,RD                                               05720000
         ST    PARREG,ABDPARA      SAVE PTR TO PARAM LIST          I250 05721019
*                                                                  I250 05722019
* IN PCP SYSTEMS AND MFT SYSTEMS WITHOUT THE ATTACH OPTION, THE    I250 05723019
* BOUNDARY BOX ADDRESS IS GOTTEN FROM THE TCBMSS FIELD OF THE      I250 05724019
* CURRENT TCB. IN MFT ATTACH SYSTEMS, IT IS GOTTEN FROM THE        I250 05725019
* TCBMSS FIELD OF THE JOBSTEP TCB.                                 I250 05726019
*                                                                  I250 05727019
         L     R1,CVTPTR           GET PTR TO CVT                  I250 05728019
         TM    CVTOPTA,MFTATTCH    IS THIS AN MFT ATTACH SYSTEM    I250 05729019
         LR    R1,R2                                               I250 05730019
         BNO   GETBBPTR            NO,BRANCH                       I250 05731019
         L     R1,TCBJSTCB(R2)     GET ADDR OF JOBSTEP TCB         I250 05732019
GETBBPTR L     R1,TCBMSS(R1)       GET PTR TO BOUNDARY BOX         I250 05733019
         ST    R1,BBADDR           SAVE IT FOR LATER               I250 05734019
* INITIALIZE BSAM DECB                                                  05740000
         LA    R6,0(R6)                 DCB PTR, CLEAR HI-ORDER BITS    05760000
         LA    R7,ABDCC-8               PTR TO OUTPUT LINE              05780000
         STM   R6,R7,ABDDCB             BSAM PARAMETERS TO DECB         05800000
         SR    R9,R9                    PTR TO BUFFER SET TO ZERO       05820000
         TM    DVTYPE(R6),X'48'         TEST, BR, IF OUTPUT DEVICE      05840000
         BC    14,ABD004                IS NOT A PRINTER                05860000
* DEVICE IS A PRINTER, ESTABLISH SYNAD.                                 05880000
         LA    R1,ABDOUT+210     *****                                  05900000
         ST    R1,ABDWORK1                                              05920000
         MVC   IOBSYNAD+1(3,R6),ABDWORK1+1   SYNAD TO DCB               05940000
         B     ABD005                                                   05960000
*                                                                       05980000
* A VARIABLE, CONDITIONAL REQUEST IS ISSUED TO OBTAIN A BUFFER FOR      06000000
* BLOCKING.                                                             06020000
ABD004   EQU   *                                                        06040000
        LA    R1,ABDOUT+8                                               06060000
         GETMAIN  VC,LA=(RB),A=ABDOUT,SP=0,MF=(E,(1))              RF0B 06080016
         LTR   RF,RF                    TEST, BR, IF REQUEST FOR        06100000
         BC    7,ABD005-4(RF)           BUFFER NOT SATISFIED            06120000
         LM    R9,RA,ABDOUT             PTR TO BUFFER, SIZE             06140000
         ST    R9,ABDPTR                BUFFER ADDRESS TO DECB          06160000
         LA    RB,0(R9,RA)              END OF BUFFER                   06180000
         LA    RA,4(R9)                 PTR TO NEXT SLOT IN BUFFER      06200000
ABD005   STM   R9,RB,ABDPTRS                                            06220000
         L     PARREG,ABDPARA      SET UP BASE FOR PARDSECT       M4417 06220119
         L     R1,CVTPTR           GET PTR TO CVT                  I250 06221019
         TM    CVTOPTA,MFTATTCH    IS THIS AN MFT ATTACH SYSTEM    I250 06222019
         BNO   FLAGOFF             NO,BRANCH                       I250 06223019
         TM    PFLAGS,PFABEND      IS ABEND THE CALLER             I250 06223319
         BZ    DONTENQ             YES,BYPASS ENQ                  I250 06223619
*                                                                  I250 06223719
* ENQ ON DUMP DATA SET                                             I250 06223819
*                                                                  I250 06223919
         LA    R1,ABDWORK3         POINT TO ENQ PARAM LIST         I250 06224019
         MVI   TWO(R1),ZERO        ZERO FLAGS IN ENQ PARAM LIST    I250 06224119
         MVC   TWELVE(EIGHT,R1),QNAME  MOVE QNAME OUT OF           I250 06224219
*                                      TRANSIENT AREA              I250 06224319
         LA    RE,TWELVE(R1)       GET ADDR OF QNAME               I250 06224419
         LA    RF,PDCBPTR          GET ADDR OF RNAME (DCB ADDR)    I250 06224519
         LA    R3,FOUR             LENGTH OF RNAME = 4 BYTES       I250 06224619
         MVI   ZERO(R1),XFF        SET LAST ENTRY INDICATOR        I250 06224719
         ENQ   ((RE),(RF),E,(R3),),MF=(E,(1))                      I250 06224819
DONTENQ  EQU   *                                                   I250 06224919
         TM    PFLAGS,PFTCB        IS TCB ADDR IN PARAMETER LIST   I250 06225119
         BZ    FLAGOFF             NO,DUMP IS FOR CURRENT TASK     I250 06226019
         NC    PTCBPTR,PTCBPTR     IS GIVEN TCB ADDR ZERO          I250 06227019
         BZ    FLAGOFF             YES,BRANCH-DUMP FOR CURR TASK   I250 06228019
         OI    ABDFLAG,X'80'       SET FLAG TO INDICATE ATTACH     I250 06229019
*                                    FUNCTION IS BEING USED AND    I250 06230019
*                                    DUMP IS FOR TASK OTHER THAN   I250 06231019
*                                    CURRENT ONE                   I250 06232019
*                                                                  I250 06233019
* TO AVOID ANY DYNAMIC MODIFICATION OF THE SUPERVISOR'S Q'S, THE   I250 06234019
* CURRENT JOBSTEP WILL BE SET NON-DISPATCHABLE (EXCEPT CURRENT     I250 06235019
* TASK).                                                           I250 06236019
*                                                                  I250 06237019
         L     RE,TCBJSTCB(R4)     GET JOBSTEP TCB ADDR            I250 06238019
SETNDISP OI    TCBFLGS2(RE),TCBNDUMP  SET TASK NON-DISPATCHABLE    I250 06239019
         OI    TCBFLGS+NDBYTE(RE),TCBNDISP                         I250 06240019
         LR    RF,RE               SAVE TCB ADDR                   I250 06241019
         L     RE,TCBLTC(RF)       GET ADDR DAUGHTER TASK'S TCB    I250 06242019
TESTDATR LTR   RE,RE               IS THERE A DAUGHTER TASK        I250 06243019
         BNZ   SETNDISP            YES,BRANCH                      I250 06244019
         L     RE,TCBNTC(RF)       NO,GET ADDR SISTER TASK'S TCB   I250 06245019
         C     RF,TCBJSTCB(RF)     IS SCAN OF SUBTASKS COMPLETED   I250 06246019
         BE    SETCURR             YES,BRANCH                      I250 06247019
         L     RF,TCBOTC(RF)       NO,GET ADDR MOTHER TASK'S TCB   I250 06248019
         B     TESTDATR            TEST DAUGHTER TASK              I250 06249019
SETCURR  NI    TCBFLGS2(R4),XFF-TCBNDUMP  SET CURRENT TASK DISP    I250 06250019
         CLC   TCBNDSP2(THREE,R4),ALLZERO  ANY NON-DISP BITS ON    I250 06251019
*                                          IN TCBNDSP2 FIELD       I250 06252019
         BNE   ENABLE                       YES,BRANCH             I250 06253019
         NI    TCBFLGS+NDBYTE(R4),XFF-TCBNDISP  TURN OFF OTHER     I250 06254019
*                                               N-DISP BIT         I250 06255019
         B     ENABLE                                              I250 06256019
FLAGOFF  NI    ABDFLAG,XFF-TESTTASK  SET FLAG TO INDICATE DUMP     I250 06257019
*                                    IS FOR CURRENT TASK           I250 06258019
*                                                                       06276019
ENABLE   EQU   *                                                   I250 06277019
         SSM   SYSMASK                 ENABLE                           06280000
*                                                                       06300000
* INITIALIZE OUTPUT AREA                                                06320000
*       1)  BSAM PARAMETERS IN DECB ( DCB PTR, AREA ADDRESS ) HAVE      06340000
*           BEEN ESTABLISHED.                                           06360000
*       2)  ESTABLISH RECORD COUNTS PRIOR TO OUTPUT LINE                06380000
*       3)  MOVE OUTPUT ROUTINE TO WORK AREA (AREA OBTAINED - GETMAIN)  06400000
*       4)  CLEAR OUTPUT LINE.                                          06420000
*       5)  SET LINE COUNT TO 6, PAGE COUNT TO 1.                       06440000
*       6)  STORE POINTER TO PARAMETER LIST IN WORK AREA.               06460000
*                                                                       06480000
* ESTABLISH BSAM RECORD LENGTH FIELDS                                   06500000
         MVC   ABDPHY(8),PHYLOG                                         06520000
* MOVE OUTPUT ROUTINE TO AREA OBTAINED VIA GETMAIN.                     06540000
         MVC   ABDOUT(LAST-OUTPUT),OUTPUT                               06560000
         MVI   ABDLINE,C' '                                             06580000
         MVC   ABDLINE+1(119),ABDLINE   CLEAR OUTPUT LINE TO BLANKS     06600000
         MVC   ABDCTR1(L'COUNTS),COUNTS     LINE, PAGE COUNTS           06620000
*                                                                  I250 06622019
* IN AN MFT ATTACH SYSTEM IN WHICH THE DUMP REQUEST IS FOR A       I250 06624019
* TASK OTHER THAN THE CURRENT ONE, IT IS POSSIBLE THAT THIS TASK   I250 06626019
* HAS NO RB'S CHAINED OFF OF ITS TCB.                              I250 06628019
*                                                                  I250 06630019
         TM    ABDFLAG,TESTTASK    IS CURRENT TASK BEING DUMPED    I250 06632019
         BZ    RBSOK               YES,RB CHAIN EXISTS             I250 06634019
         TM    TCBFLGS2+ONE(R2),TERMBIT  IS TASK ALREADY           I250 06636019
*                                        TERMINATED                I250 06638019
         BO    NORBS               YES,RB CHAIN DOESN'T EXIST      I250 06640019
         L     R1,TCBRBP(R2)       GET RB FIELD FROM TCB           I250 06642019
         LA    R1,ZERO(R1)         CLEAR TOP BYTE                  I250 06644019
         LTR   R1,R1               IS IT ZERO                      I250 06646019
         BZ    NORBS               YES,RB CHAIN DOESN'T EXIST      I250 06648019
         CR    R1,R2               DOES RB FIELD POINT TO TCB      I250 06650019
         BE    NORBS               YES,RB CHAIN DOESN'T EXIST      I250 06652019
RBSOK    NI    ABDFLAG,XFF-TESTRBS SET FLAG INDICATING RB CHAIN    I250 06654019
*                                    EXISTS                        I250 06656019
         B     AROUND                                              I250 06658019
NORBS    OI    ABDFLAG,TESTRBS     SET FLAG INDICATING RB CHAIN    I250 06660019
*                                    DOESN'T EXIST                 I250 06662019
AROUND   EQU   *                                                   I250 06664019
         LA    RA,NMLOAD2              GET NAME OF LOAD 2               08140000
        LA    RF,ABDWORK3                                               08160000
        XCTL  EPLOC=(10),SF=(E,(15))                                    08180000
*                                                                       08200000
         EJECT                                                          08220000
* OUTPUT ROUTINE                                                        09340000
*      THIS ROUTINE IS USED BY EACH LOAD OF ABDUMP TO WRITE A           09360000
*      PRINTABLE RECORD.  IT IS ASSEMBLED WITH ABDUMP1, BUT IS MOVED    09380000
*      TO AN AREA WITHIN ABDUMP'S WORK AREA(POINTED TO BY REGISTER 13). 09400000
*      WHEN THE ROUTINE GETS CONTROL, A PRINTABLE RECORD IS IN THE AREA 09420000
*      RESERVED FOR AN OUTPUT LINE.                                     09440000
*      IF THE RECORDS ARE NOT TO BE BLOCKED ,I.E.  OUTPUT DEVICE IS A   09460000
*      PRINTER OR NO BUFFER IS AVAILABLE FOR BLOCKING, THE RECORD IN    09480000
*      THE OUTPUT LINE IS WRITTEN.                                      09500000
*      IF THE RECORDS ARE TO BE BLOCKED, THE RECORD IN THE OUTPUT LINE  09520000
*      IS MOVED TO THE BUFFER.  WHEN THERE REMAINS LESS THAN 125 BYTES  09540000
*      IN THE BUFFER, THE BLOCK IS WRITTEN.                             09560000
*      PAGINATION IS CONTROLLED BY THE ROUTINE, BASED UPON 56 LINES     09580000
*      PER PAGE.                                                        09600000
*      THE ROUTINE RETURNS CONTROL VIA 'BR R5'.                         09620000
         SPACE 2                                                        09640000
* DISPLACEMENTS FROM BEGINNING OF ABDUMP'S WORK AREA TO                 09660000
DECB     EQU   72                       DECB FOR BSAM                   09680000
LINECTR  EQU   92                       LINE COUNTER                    09700000
PAGECTR  EQU   94                       PAGE COUNTER                    09720000
DBLWORD  EQU   336                      DBL WORD USED TO CONVERT-DEC.   09740000
PTRBUF   EQU   348                PTR TO BUFFER FOR BLOCK RECORD        09760000
PTRNEXT  EQU   352                PTR TO NEXT SLOT W/IN BLOCK BUFFER    09780000
PTREOB   EQU   356                PTR TO END OF BLOCK BUFFER            09800000
PHYSICAL EQU   360                      PHYSICAL RECORD LENGTH          09820000
LOGICAL  EQU   364                      LOGICAL RECORD LENGTH           09840000
CCCHAR   EQU   368                      CARRIAGE CONTROL CHARACTER      09860000
         SPACE 2                                                        09880000
* REGISTER 13 IS THE BASE REG FOR THE OUTPUT ROUTINE                    09900000
         USING *-96,RD                                                  09920000
*                                                                       09940000
OUTPUT   LM    RE,R0,PTRBUF(RD)                                         09960000
* RE = PTR TO BUFFER                                                    09980000
* RF = PTR TO NEXT AVAILABLE SLOT IN BUFFER                             10000000
* R0 = END OF BUFFER (RE + SIZE)                                        10020000
         LTR   RE,RE                    TEST, BR, IF RECORDS ARE NOT    10040000
         BC    8,OUTPUT2                TO BE BLOCKED.                  10060000
         MVC   0(125,RF),LOGICAL(RD)    LOGICAL RECORD COUNT, CC CHAR,  10080000
*                                       AND RECORD TO BUFFER.           10100000
         LA    RF,125(RF)               INC PTR TO NEXT SLOT IN BUFFER  10120000
         ST    RF,PTRNEXT(RD)                                           10140000
         LA    R1,125(RF)               CHECK FOR END OF BUFFER         10160000
         CR    R1,R0                    BR IF THERE IS ROOM IN BUFFER   10180000
         BC    12,OUTPUT3               FOR ANOTHER LINE.               10200000
OUTPUT1  SR    RF,RE                    PHYSICAL RECORD LENGTH, AND     10220000
         STH   RF,PHYSICAL(RD)          SYSTEM RESERVED CHARACTERS TO   10240000
         MVC   0(4,RE),PHYSICAL(RD)     BUFFER.                         10260000
         LA    RF,4(RE)                 RESET PTR TO NEXT SLOT AVAIL.   10280000
         ST    RF,PTRNEXT(RD)           IN BUFFER.                      10300000
         SPACE 2                                                        10320000
OUTPUT2  LA    R1,DECB(RD)              ADDRESS OF DECB                 10340000
        WRITE  (1),SF,MF=E                                              10360000
         LA    R1,DECB(RD)              ADDRESS OF DECB                 10380000
        CHECK  (1)                                                      10400000
OUTPUT3  LA    R1,1                     DETERMINE AMOUNT BY WHICH THE   10420000
         LH    R0,LINECTR(RD)           LINE COUNTER IS TO BE BUMPED.   10440000
         CLI   CCCHAR(RD),C'-'                                          10460000
         BL    INCBYONE                 BR IF SPACE 1 , CCCHAR = X'40'  10480000
         BH    INCBYTWO                 BR IF SPACE2 OR EJECT,'F0'-'F1' 10500000
         AR    R0,R1                    SPACE 3, CC CHAR = X'60'        10520000
INCBYTWO AR    R0,R1           *** NOTE-IF EJECT,LINE CT = -1 +2 = 1    10540000
INCBYONE AR    R0,R1                                                    10560000
         MVI   CCCHAR(RD),X'40'         SET CC CHAR,OUTPUT LINE TO      10580000
         MVC   CCCHAR+1(120,RD),CCCHAR(RD)        BLANKS.               10600000
         LA    R1,56                                                    10620000
         CR    R0,R1                    TEST, BR, IF LINE COUNT IS GT   10640000
         BC    10,OUTPUT4               OR EQ TO 56.                    10660000
         STH   R0,LINECTR(RD)                                           10680000
         BR    R5                       EXIT FROM OUTPUT ROUTINE        10700000
         SPACE 2                                                        10720000
OUTPUT4  LH    R1,PAGECTR(RD)           NEW PAGE, BUMP PAGE COUNT BY 1  10740000
         LA    R1,1(R1)                 PUT OUT PAGE LINE.              10760000
         STH   R1,PAGECTR(RD)                                           10780000
         MVI   CCCHAR(RD),C'1'          CC CHAR FOR 'PAGE DDDD'         10800000
         MVC   CCCHAR+109(4,RD),PAGE                                    10820000
         CVD   R1,DBLWORD(RD)           CONVERT PAGE NO. TO DECIMAL     10840000
         UNPK  CCCHAR+114(4,RD),DBLWORD+4(4,RD)                         10860000
         OI    CCCHAR+117(RD),X'F0'     GET RID OF SIGN                 10880000
         MVC   LINECTR(2,RD),MINUSONE   RESET LINE COUNTER              10900000
         B     OUTPUT                                                   10920000
         SPACE 2                                                        10940000
* IF OUTPUT5 CHANGED FROM A DISPLACEMENT OF 280 FROM THE BEGINNING      10960000
* OF ABDUMP'S WORK AREA, A CHANGE IN LOAD 4 OF ABDUMP(IEAAAD03) WILL    10980000
* BE NECESSARY.  (LTOUTPUT  EQU  280)                                   11000000
OUTPUT5  LM    RE,R0,PTRBUF(RD)         LAST TIME ENTRY - CHECK IF      11020000
         LTR   RE,RE                    NECESSARY TO WRITE BUFFER.      11040000
         BCR   8,R5                     NO BUFFER USED, RETURN          11060000
         LA    R1,4(RE)                 BUFFER USED                     11080000
         CR    R1,RF                                                    11100000
         BCR   8,R5                     LAST WRITE EMPTIED BUFFER,EXIT. 11120000
         B     OUTPUT1                  INFO REMAINS TO BE WRITTEN.     11140000
*                                                                       11160000
PAGE     DC    C'PAGE'                                                  11180000
MINUSONE DC    X'FFFF'                                                  11200000
* SYNCHRONOUS EXIT ROUTINE - ENTERED ONLY IF DEVICE IS A PRINTER.       11220000
         RETURN                                                         11240000
*                                                                       11260000
LAST     EQU   *    THIS SYMBOL USED TO DETERMINE SIZE OF OUTPUT RTN.   11280000
         DROP  RD                                                       11300000
         EJECT                                                          11320000
MINMAX  DC    A(256)    MINIMUM BUFFER LENGTH FOR BLOCKING              11360000
         DC    A(1632)   MAXIMUM BUFFER LENGTH FOR BLOCKING (13 LINES)  11380000
*        THE ABOVE MINMAX VALUES ARE BLOCKING LENGTHS FOR PCP           11385016
MINMAX2  DC    A(256)              MFT2  MIN BLOCKING LENGTH       RF0B 11390016
         DC    A(882)              MFT2  MAX BLOCKING LENGTH       RF0B 11395016
NMLOAD2  DC    CL8'IGC0D05A'       NAME OF NEXT LOAD OF ABDUMP     ATCH 11405019
PHYLOG   DC    H'129'                   PHYSICAL RECORD LENGTH          11420000
         DC    C'  '                    SYSTEM-RESERVED CHARACTER       11440000
         DC    H'125'                                                   11460000
         DC    C'  '                    SYSTEM-RESERVED CHARACTER       11480000
         DC    X'0000'             SYSTEM RESERVED CHARACTER       6900 11490017
SYSMASK  DC    X'FF'                                                    11500000
COUNTS   DC    X'00060001'         LINE, PAGE COUNTS USED BY OUTPUT RTN 11520000
QNAME    DC    C'SYSIEA01'         QNAME FOR ENQ MACRO             I250 11720019
ALLZERO  DC    AL3(0)              ZEROES USED FOR COMPARING       I250 11920019
         EJECT                                                          12180000
         DCBD  DSORG=BS,DEVD=PR                                         12200000
         EJECT                                                          12220000
PARDSECT DSECT                                                          12240000
PID      DS    1C                      ID NUMBER LT 128                 12260000
         DS    1C                      RESERVED                         12280000
PFLAGS   DS    2C                      OPTION FLAGS                     12300000
PDCBPTR  DS    1F                      DCB ADDRESS                      12320000
PTCBPTR  DS    1F                      TCB ADDRESS                 I250 12340019
PSNAPPTR DS    1F                      ADDRESS OF SNAPSHOT LIST         12360000
         EJECT                                                          12380000
ABDAREA  DSECT                                                          12400000
ABDSAVE  DS    18F       SAVE AREA                                      12420000
ABDECB   DS    1F        DECB-ECB                                       12440000
ABDTYPE  DS    1H              TYPE FIELD                               12460000
ABDLEN   DS    1H              LENGTH FIELD                             12480000
ABDDCB   DS    1F              PTR TO DCB                               12500000
ABDPTR   DS    1F              AREA ADDRESS                             12520000
ABDSTAT  DS    1F              PTR TO STATUS INDICATORS                 12540000
*                                                                       12560000
*                                                                       12580000
ABDCTR1  DS    1H        LINE CTR                                       12600000
ABDCTR2  DS    1H        PAGE CTR                                       12620000
*                        OUTPUT ROUTINE                                 12640000
ABDOUT  DS    55F       220 BYTES RESERVED FOR OUTPUT ROUTINE           12660000
*                                                                       12680000
ABDPARA  DS    1F        PTR TO PARAMETER LIST SAVED HERE               12700000
ABDENDLL DS    1F        COMPARAND TO END LOAD LIST TRACE               12720000
ABDWORK3 DS    1C        USED TO MAINTAIN RB SEQUENCE COUNT PREFIX      12740000
ABDWORK4 DS    11C       9 BYTES USED FOR UNPACK AREA                   12760000
ABDWORK1 DS    1D        CONVERT TO DECIMAL AREA,SAVE AREA              12780000
ABDWORK2 DS    1F                 SAVE AREA FOR LINK ADDRESS            12800000
ABDPTRS  DS    3F        BUFFER POINTERS USED BY OUTPUT ROUTINE         12820000
*                        OUTPUT LINE                                    12840000
ABDPHY   DS    2C        PHYSICAL RECORD LENGTH                         12860000
ABDSRC1  DS    2C        SYSTEM-RESERVED CHAR                           12880000
ABDLOG   DS    2C        LOGICAL RECORD LENGTH                          12900000
ABDSRC2  DS    2C        SYSTEM-RESERVED CHAR                           12920000
ABDCC    DS    1C        CARRIAGE-CONTROL CHAR                          12940000
ABDLINE  DS    CL32      120 CHAR PRINT LINE                            12960000
         DS    CL32                                                     12980000
         DS    CL32                                                     13000000
         DS    CL24                                                     13020000
         DS    1C        ONE BYTE FOLLOWING OUTPUT LINE TO BE USED AS   13040000
*                        'OVERFLOW' BYTE WHEN UNPACKING INTO LINE       13060000
         DS    2C                                                       13064019
ABDFLAG  DS    1C        BIT 0 = 1 MEANS DUMP IS FOR TASK OTHER    I250 13070019
*                                  THAN CURRENT ONE                I250 13076019
*                              = 0 MEANS DUMP IS FOR CURRENT TASK  I250 13082019
*                        BIT 1 = 1 MEANS RB CHAIN DOESN'T EXIST    I250 13088019
*                                  FOR TASK BEING DUMPED           I250 13094019
*                              = 0 MEANS RB CHAIN DOES EXIST       I250 13100019
         DS    171C                                                I250 13106019
BBADDR   DS    1F        SAVE BOUNDARY BOX ADDRESS                 I250 13112019
         EJECT                                                          13120000
CVTDSECT DSECT                                                          13140000
         CVT     SYS=INT                                                13160000
         END                                                            13180000
